src/HOL/SEQ.thy
author hoelzl
Tue Dec 21 14:50:53 2010 +0100 (2010-12-21)
changeset 41367 1b65137d598c
parent 40811 ab0a8cc7976a
child 41972 8885ba629692
permissions -rw-r--r--
generalized monoseq, decseq and incseq; simplified proof for seq_monosub
     1 (*  Title:      HOL/SEQ.thy
     2     Author:     Jacques D. Fleuriot, University of Cambridge
     3     Author:     Lawrence C Paulson
     4     Author:     Jeremy Avigad
     5     Author:     Brian Huffman
     6 
     7 Convergence of sequences and series.
     8 *)
     9 
    10 header {* Sequences and Convergence *}
    11 
    12 theory SEQ
    13 imports Limits RComplete
    14 begin
    15 
    16 abbreviation
    17   LIMSEQ :: "[nat \<Rightarrow> 'a::topological_space, 'a] \<Rightarrow> bool"
    18     ("((_)/ ----> (_))" [60, 60] 60) where
    19   "X ----> L \<equiv> (X ---> L) sequentially"
    20 
    21 definition
    22   lim :: "(nat \<Rightarrow> 'a::metric_space) \<Rightarrow> 'a" where
    23     --{*Standard definition of limit using choice operator*}
    24   "lim X = (THE L. X ----> L)"
    25 
    26 definition
    27   convergent :: "(nat \<Rightarrow> 'a::metric_space) \<Rightarrow> bool" where
    28     --{*Standard definition of convergence*}
    29   "convergent X = (\<exists>L. X ----> L)"
    30 
    31 definition
    32   Bseq :: "(nat => 'a::real_normed_vector) => bool" where
    33     --{*Standard definition for bounded sequence*}
    34   "Bseq X = (\<exists>K>0.\<forall>n. norm (X n) \<le> K)"
    35 
    36 definition
    37   monoseq :: "(nat \<Rightarrow> 'a::order) \<Rightarrow> bool" where
    38     --{*Definition of monotonicity.
    39         The use of disjunction here complicates proofs considerably.
    40         One alternative is to add a Boolean argument to indicate the direction.
    41         Another is to develop the notions of increasing and decreasing first.*}
    42   "monoseq X = ((\<forall>m. \<forall>n\<ge>m. X m \<le> X n) | (\<forall>m. \<forall>n\<ge>m. X n \<le> X m))"
    43 
    44 definition
    45   incseq :: "(nat \<Rightarrow> 'a::order) \<Rightarrow> bool" where
    46     --{*Increasing sequence*}
    47   "incseq X \<longleftrightarrow> (\<forall>m. \<forall>n\<ge>m. X m \<le> X n)"
    48 
    49 definition
    50   decseq :: "(nat \<Rightarrow> 'a::order) \<Rightarrow> bool" where
    51     --{*Decreasing sequence*}
    52   "decseq X \<longleftrightarrow> (\<forall>m. \<forall>n\<ge>m. X n \<le> X m)"
    53 
    54 definition
    55   subseq :: "(nat \<Rightarrow> nat) \<Rightarrow> bool" where
    56     --{*Definition of subsequence*}
    57   "subseq f \<longleftrightarrow> (\<forall>m. \<forall>n>m. f m < f n)"
    58 
    59 definition
    60   Cauchy :: "(nat \<Rightarrow> 'a::metric_space) \<Rightarrow> bool" where
    61     --{*Standard definition of the Cauchy condition*}
    62   "Cauchy X = (\<forall>e>0. \<exists>M. \<forall>m \<ge> M. \<forall>n \<ge> M. dist (X m) (X n) < e)"
    63 
    64 
    65 subsection {* Bounded Sequences *}
    66 
    67 lemma BseqI': assumes K: "\<And>n. norm (X n) \<le> K" shows "Bseq X"
    68 unfolding Bseq_def
    69 proof (intro exI conjI allI)
    70   show "0 < max K 1" by simp
    71 next
    72   fix n::nat
    73   have "norm (X n) \<le> K" by (rule K)
    74   thus "norm (X n) \<le> max K 1" by simp
    75 qed
    76 
    77 lemma BseqE: "\<lbrakk>Bseq X; \<And>K. \<lbrakk>0 < K; \<forall>n. norm (X n) \<le> K\<rbrakk> \<Longrightarrow> Q\<rbrakk> \<Longrightarrow> Q"
    78 unfolding Bseq_def by auto
    79 
    80 lemma BseqI2': assumes K: "\<forall>n\<ge>N. norm (X n) \<le> K" shows "Bseq X"
    81 proof (rule BseqI')
    82   let ?A = "norm ` X ` {..N}"
    83   have 1: "finite ?A" by simp
    84   fix n::nat
    85   show "norm (X n) \<le> max K (Max ?A)"
    86   proof (cases rule: linorder_le_cases)
    87     assume "n \<ge> N"
    88     hence "norm (X n) \<le> K" using K by simp
    89     thus "norm (X n) \<le> max K (Max ?A)" by simp
    90   next
    91     assume "n \<le> N"
    92     hence "norm (X n) \<in> ?A" by simp
    93     with 1 have "norm (X n) \<le> Max ?A" by (rule Max_ge)
    94     thus "norm (X n) \<le> max K (Max ?A)" by simp
    95   qed
    96 qed
    97 
    98 lemma Bseq_ignore_initial_segment: "Bseq X \<Longrightarrow> Bseq (\<lambda>n. X (n + k))"
    99 unfolding Bseq_def by auto
   100 
   101 lemma Bseq_offset: "Bseq (\<lambda>n. X (n + k)) \<Longrightarrow> Bseq X"
   102 apply (erule BseqE)
   103 apply (rule_tac N="k" and K="K" in BseqI2')
   104 apply clarify
   105 apply (drule_tac x="n - k" in spec, simp)
   106 done
   107 
   108 lemma Bseq_conv_Bfun: "Bseq X \<longleftrightarrow> Bfun X sequentially"
   109 unfolding Bfun_def eventually_sequentially
   110 apply (rule iffI)
   111 apply (simp add: Bseq_def)
   112 apply (auto intro: BseqI2')
   113 done
   114 
   115 
   116 subsection {* Limits of Sequences *}
   117 
   118 lemma [trans]: "X=Y ==> Y ----> z ==> X ----> z"
   119   by simp
   120 
   121 lemma LIMSEQ_def: "X ----> L = (\<forall>r>0. \<exists>no. \<forall>n\<ge>no. dist (X n) L < r)"
   122 unfolding tendsto_iff eventually_sequentially ..
   123 
   124 lemma LIMSEQ_iff:
   125   fixes L :: "'a::real_normed_vector"
   126   shows "(X ----> L) = (\<forall>r>0. \<exists>no. \<forall>n \<ge> no. norm (X n - L) < r)"
   127 unfolding LIMSEQ_def dist_norm ..
   128 
   129 lemma LIMSEQ_iff_nz: "X ----> L = (\<forall>r>0. \<exists>no>0. \<forall>n\<ge>no. dist (X n) L < r)"
   130   unfolding LIMSEQ_def by (metis Suc_leD zero_less_Suc)
   131 
   132 lemma LIMSEQ_Zfun_iff: "((\<lambda>n. X n) ----> L) = Zfun (\<lambda>n. X n - L) sequentially"
   133 by (rule tendsto_Zfun_iff)
   134 
   135 lemma metric_LIMSEQ_I:
   136   "(\<And>r. 0 < r \<Longrightarrow> \<exists>no. \<forall>n\<ge>no. dist (X n) L < r) \<Longrightarrow> X ----> L"
   137 by (simp add: LIMSEQ_def)
   138 
   139 lemma metric_LIMSEQ_D:
   140   "\<lbrakk>X ----> L; 0 < r\<rbrakk> \<Longrightarrow> \<exists>no. \<forall>n\<ge>no. dist (X n) L < r"
   141 by (simp add: LIMSEQ_def)
   142 
   143 lemma LIMSEQ_I:
   144   fixes L :: "'a::real_normed_vector"
   145   shows "(\<And>r. 0 < r \<Longrightarrow> \<exists>no. \<forall>n\<ge>no. norm (X n - L) < r) \<Longrightarrow> X ----> L"
   146 by (simp add: LIMSEQ_iff)
   147 
   148 lemma LIMSEQ_D:
   149   fixes L :: "'a::real_normed_vector"
   150   shows "\<lbrakk>X ----> L; 0 < r\<rbrakk> \<Longrightarrow> \<exists>no. \<forall>n\<ge>no. norm (X n - L) < r"
   151 by (simp add: LIMSEQ_iff)
   152 
   153 lemma LIMSEQ_const: "(\<lambda>n. k) ----> k"
   154 by (rule tendsto_const)
   155 
   156 lemma LIMSEQ_const_iff:
   157   fixes k l :: "'a::metric_space"
   158   shows "(\<lambda>n. k) ----> l \<longleftrightarrow> k = l"
   159 by (rule tendsto_const_iff, rule sequentially_bot)
   160 
   161 lemma LIMSEQ_norm:
   162   fixes a :: "'a::real_normed_vector"
   163   shows "X ----> a \<Longrightarrow> (\<lambda>n. norm (X n)) ----> norm a"
   164 by (rule tendsto_norm)
   165 
   166 lemma LIMSEQ_ignore_initial_segment:
   167   "f ----> a \<Longrightarrow> (\<lambda>n. f (n + k)) ----> a"
   168 apply (rule topological_tendstoI)
   169 apply (drule (2) topological_tendstoD)
   170 apply (simp only: eventually_sequentially)
   171 apply (erule exE, rename_tac N)
   172 apply (rule_tac x=N in exI)
   173 apply simp
   174 done
   175 
   176 lemma LIMSEQ_offset:
   177   "(\<lambda>n. f (n + k)) ----> a \<Longrightarrow> f ----> a"
   178 apply (rule topological_tendstoI)
   179 apply (drule (2) topological_tendstoD)
   180 apply (simp only: eventually_sequentially)
   181 apply (erule exE, rename_tac N)
   182 apply (rule_tac x="N + k" in exI)
   183 apply clarify
   184 apply (drule_tac x="n - k" in spec)
   185 apply (simp add: le_diff_conv2)
   186 done
   187 
   188 lemma LIMSEQ_Suc: "f ----> l \<Longrightarrow> (\<lambda>n. f (Suc n)) ----> l"
   189 by (drule_tac k="Suc 0" in LIMSEQ_ignore_initial_segment, simp)
   190 
   191 lemma LIMSEQ_imp_Suc: "(\<lambda>n. f (Suc n)) ----> l \<Longrightarrow> f ----> l"
   192 by (rule_tac k="Suc 0" in LIMSEQ_offset, simp)
   193 
   194 lemma LIMSEQ_Suc_iff: "(\<lambda>n. f (Suc n)) ----> l = f ----> l"
   195 by (blast intro: LIMSEQ_imp_Suc LIMSEQ_Suc)
   196 
   197 lemma LIMSEQ_linear: "\<lbrakk> X ----> x ; l > 0 \<rbrakk> \<Longrightarrow> (\<lambda> n. X (n * l)) ----> x"
   198   unfolding tendsto_def eventually_sequentially
   199   by (metis div_le_dividend div_mult_self1_is_m le_trans nat_mult_commute)
   200 
   201 lemma LIMSEQ_add:
   202   fixes a b :: "'a::real_normed_vector"
   203   shows "\<lbrakk>X ----> a; Y ----> b\<rbrakk> \<Longrightarrow> (\<lambda>n. X n + Y n) ----> a + b"
   204 by (rule tendsto_add)
   205 
   206 lemma LIMSEQ_minus:
   207   fixes a :: "'a::real_normed_vector"
   208   shows "X ----> a \<Longrightarrow> (\<lambda>n. - X n) ----> - a"
   209 by (rule tendsto_minus)
   210 
   211 lemma LIMSEQ_minus_cancel:
   212   fixes a :: "'a::real_normed_vector"
   213   shows "(\<lambda>n. - X n) ----> - a \<Longrightarrow> X ----> a"
   214 by (rule tendsto_minus_cancel)
   215 
   216 lemma LIMSEQ_diff:
   217   fixes a b :: "'a::real_normed_vector"
   218   shows "\<lbrakk>X ----> a; Y ----> b\<rbrakk> \<Longrightarrow> (\<lambda>n. X n - Y n) ----> a - b"
   219 by (rule tendsto_diff)
   220 
   221 lemma LIMSEQ_unique:
   222   fixes a b :: "'a::metric_space"
   223   shows "\<lbrakk>X ----> a; X ----> b\<rbrakk> \<Longrightarrow> a = b"
   224 by (drule (1) tendsto_dist, simp add: LIMSEQ_const_iff)
   225 
   226 lemma (in bounded_linear) LIMSEQ:
   227   "X ----> a \<Longrightarrow> (\<lambda>n. f (X n)) ----> f a"
   228 by (rule tendsto)
   229 
   230 lemma (in bounded_bilinear) LIMSEQ:
   231   "\<lbrakk>X ----> a; Y ----> b\<rbrakk> \<Longrightarrow> (\<lambda>n. X n ** Y n) ----> a ** b"
   232 by (rule tendsto)
   233 
   234 lemma LIMSEQ_mult:
   235   fixes a b :: "'a::real_normed_algebra"
   236   shows "[| X ----> a; Y ----> b |] ==> (%n. X n * Y n) ----> a * b"
   237 by (rule mult.tendsto)
   238 
   239 lemma increasing_LIMSEQ:
   240   fixes f :: "nat \<Rightarrow> real"
   241   assumes inc: "!!n. f n \<le> f (Suc n)"
   242       and bdd: "!!n. f n \<le> l"
   243       and en: "!!e. 0 < e \<Longrightarrow> \<exists>n. l \<le> f n + e"
   244   shows "f ----> l"
   245 proof (auto simp add: LIMSEQ_def)
   246   fix e :: real
   247   assume e: "0 < e"
   248   then obtain N where "l \<le> f N + e/2"
   249     by (metis half_gt_zero e en that)
   250   hence N: "l < f N + e" using e
   251     by simp
   252   { fix k
   253     have [simp]: "!!n. \<bar>f n - l\<bar> = l - f n"
   254       by (simp add: bdd) 
   255     have "\<bar>f (N+k) - l\<bar> < e"
   256     proof (induct k)
   257       case 0 show ?case using N
   258         by simp   
   259     next
   260       case (Suc k) thus ?case using N inc [of "N+k"]
   261         by simp
   262     qed 
   263   } note 1 = this
   264   { fix n
   265     have "N \<le> n \<Longrightarrow> \<bar>f n - l\<bar> < e" using 1 [of "n-N"]
   266       by simp 
   267   } note [intro] = this
   268   show " \<exists>no. \<forall>n\<ge>no. dist (f n) l < e"
   269     by (auto simp add: dist_real_def) 
   270   qed
   271 
   272 lemma Bseq_inverse_lemma:
   273   fixes x :: "'a::real_normed_div_algebra"
   274   shows "\<lbrakk>r \<le> norm x; 0 < r\<rbrakk> \<Longrightarrow> norm (inverse x) \<le> inverse r"
   275 apply (subst nonzero_norm_inverse, clarsimp)
   276 apply (erule (1) le_imp_inverse_le)
   277 done
   278 
   279 lemma Bseq_inverse:
   280   fixes a :: "'a::real_normed_div_algebra"
   281   shows "\<lbrakk>X ----> a; a \<noteq> 0\<rbrakk> \<Longrightarrow> Bseq (\<lambda>n. inverse (X n))"
   282 unfolding Bseq_conv_Bfun by (rule Bfun_inverse)
   283 
   284 lemma LIMSEQ_inverse:
   285   fixes a :: "'a::real_normed_div_algebra"
   286   shows "\<lbrakk>X ----> a; a \<noteq> 0\<rbrakk> \<Longrightarrow> (\<lambda>n. inverse (X n)) ----> inverse a"
   287 by (rule tendsto_inverse)
   288 
   289 lemma LIMSEQ_divide:
   290   fixes a b :: "'a::real_normed_field"
   291   shows "\<lbrakk>X ----> a; Y ----> b; b \<noteq> 0\<rbrakk> \<Longrightarrow> (\<lambda>n. X n / Y n) ----> a / b"
   292 by (rule tendsto_divide)
   293 
   294 lemma LIMSEQ_pow:
   295   fixes a :: "'a::{power, real_normed_algebra}"
   296   shows "X ----> a \<Longrightarrow> (\<lambda>n. (X n) ^ m) ----> a ^ m"
   297 by (induct m) (simp_all add: LIMSEQ_const LIMSEQ_mult)
   298 
   299 lemma LIMSEQ_setsum:
   300   fixes L :: "'a \<Rightarrow> 'b::real_normed_vector"
   301   assumes n: "\<And>n. n \<in> S \<Longrightarrow> X n ----> L n"
   302   shows "(\<lambda>m. \<Sum>n\<in>S. X n m) ----> (\<Sum>n\<in>S. L n)"
   303 using assms by (rule tendsto_setsum)
   304 
   305 lemma LIMSEQ_setprod:
   306   fixes L :: "'a \<Rightarrow> 'b::{real_normed_algebra,comm_ring_1}"
   307   assumes n: "\<And>n. n \<in> S \<Longrightarrow> X n ----> L n"
   308   shows "(\<lambda>m. \<Prod>n\<in>S. X n m) ----> (\<Prod>n\<in>S. L n)"
   309 proof (cases "finite S")
   310   case True
   311   thus ?thesis using n
   312   proof (induct)
   313     case empty
   314     show ?case
   315       by (simp add: LIMSEQ_const)
   316   next
   317     case insert
   318     thus ?case
   319       by (simp add: LIMSEQ_mult)
   320   qed
   321 next
   322   case False
   323   thus ?thesis
   324     by (simp add: setprod_def LIMSEQ_const)
   325 qed
   326 
   327 lemma LIMSEQ_add_const: (* FIXME: delete *)
   328   fixes a :: "'a::real_normed_vector"
   329   shows "f ----> a ==> (%n.(f n + b)) ----> a + b"
   330 by (intro tendsto_intros)
   331 
   332 (* FIXME: delete *)
   333 lemma LIMSEQ_add_minus:
   334   fixes a b :: "'a::real_normed_vector"
   335   shows "[| X ----> a; Y ----> b |] ==> (%n. X n + -Y n) ----> a + -b"
   336 by (intro tendsto_intros)
   337 
   338 lemma LIMSEQ_diff_const: (* FIXME: delete *)
   339   fixes a b :: "'a::real_normed_vector"
   340   shows "f ----> a ==> (%n.(f n  - b)) ----> a - b"
   341 by (intro tendsto_intros)
   342 
   343 lemma LIMSEQ_diff_approach_zero:
   344   fixes L :: "'a::real_normed_vector"
   345   shows "g ----> L ==> (%x. f x - g x) ----> 0 ==> f ----> L"
   346 by (drule (1) LIMSEQ_add, simp)
   347 
   348 lemma LIMSEQ_diff_approach_zero2:
   349   fixes L :: "'a::real_normed_vector"
   350   shows "f ----> L ==> (%x. f x - g x) ----> 0 ==> g ----> L"
   351 by (drule (1) LIMSEQ_diff, simp)
   352 
   353 text{*A sequence tends to zero iff its abs does*}
   354 lemma LIMSEQ_norm_zero:
   355   fixes X :: "nat \<Rightarrow> 'a::real_normed_vector"
   356   shows "((\<lambda>n. norm (X n)) ----> 0) \<longleftrightarrow> (X ----> 0)"
   357 by (simp add: LIMSEQ_iff)
   358 
   359 lemma LIMSEQ_rabs_zero: "((%n. \<bar>f n\<bar>) ----> 0) = (f ----> (0::real))"
   360 by (simp add: LIMSEQ_iff)
   361 
   362 lemma LIMSEQ_imp_rabs: "f ----> (l::real) ==> (%n. \<bar>f n\<bar>) ----> \<bar>l\<bar>"
   363 by (drule LIMSEQ_norm, simp)
   364 
   365 text{*An unbounded sequence's inverse tends to 0*}
   366 
   367 lemma LIMSEQ_inverse_zero:
   368   "\<forall>r::real. \<exists>N. \<forall>n\<ge>N. r < X n \<Longrightarrow> (\<lambda>n. inverse (X n)) ----> 0"
   369 apply (rule LIMSEQ_I)
   370 apply (drule_tac x="inverse r" in spec, safe)
   371 apply (rule_tac x="N" in exI, safe)
   372 apply (drule_tac x="n" in spec, safe)
   373 apply (frule positive_imp_inverse_positive)
   374 apply (frule (1) less_imp_inverse_less)
   375 apply (subgoal_tac "0 < X n", simp)
   376 apply (erule (1) order_less_trans)
   377 done
   378 
   379 text{*The sequence @{term "1/n"} tends to 0 as @{term n} tends to infinity*}
   380 
   381 lemma LIMSEQ_inverse_real_of_nat: "(%n. inverse(real(Suc n))) ----> 0"
   382 apply (rule LIMSEQ_inverse_zero, safe)
   383 apply (cut_tac x = r in reals_Archimedean2)
   384 apply (safe, rule_tac x = n in exI)
   385 apply (auto simp add: real_of_nat_Suc)
   386 done
   387 
   388 text{*The sequence @{term "r + 1/n"} tends to @{term r} as @{term n} tends to
   389 infinity is now easily proved*}
   390 
   391 lemma LIMSEQ_inverse_real_of_nat_add:
   392      "(%n. r + inverse(real(Suc n))) ----> r"
   393 by (cut_tac LIMSEQ_add [OF LIMSEQ_const LIMSEQ_inverse_real_of_nat], auto)
   394 
   395 lemma LIMSEQ_inverse_real_of_nat_add_minus:
   396      "(%n. r + -inverse(real(Suc n))) ----> r"
   397 by (cut_tac LIMSEQ_add_minus [OF LIMSEQ_const LIMSEQ_inverse_real_of_nat], auto)
   398 
   399 lemma LIMSEQ_inverse_real_of_nat_add_minus_mult:
   400      "(%n. r*( 1 + -inverse(real(Suc n)))) ----> r"
   401 by (cut_tac b=1 in
   402         LIMSEQ_mult [OF LIMSEQ_const LIMSEQ_inverse_real_of_nat_add_minus], auto)
   403 
   404 lemma LIMSEQ_le_const:
   405   "\<lbrakk>X ----> (x::real); \<exists>N. \<forall>n\<ge>N. a \<le> X n\<rbrakk> \<Longrightarrow> a \<le> x"
   406 apply (rule ccontr, simp only: linorder_not_le)
   407 apply (drule_tac r="a - x" in LIMSEQ_D, simp)
   408 apply clarsimp
   409 apply (drule_tac x="max N no" in spec, drule mp, rule le_maxI1)
   410 apply (drule_tac x="max N no" in spec, drule mp, rule le_maxI2)
   411 apply simp
   412 done
   413 
   414 lemma LIMSEQ_le_const2:
   415   "\<lbrakk>X ----> (x::real); \<exists>N. \<forall>n\<ge>N. X n \<le> a\<rbrakk> \<Longrightarrow> x \<le> a"
   416 apply (subgoal_tac "- a \<le> - x", simp)
   417 apply (rule LIMSEQ_le_const)
   418 apply (erule LIMSEQ_minus)
   419 apply simp
   420 done
   421 
   422 lemma LIMSEQ_le:
   423   "\<lbrakk>X ----> x; Y ----> y; \<exists>N. \<forall>n\<ge>N. X n \<le> Y n\<rbrakk> \<Longrightarrow> x \<le> (y::real)"
   424 apply (subgoal_tac "0 \<le> y - x", simp)
   425 apply (rule LIMSEQ_le_const)
   426 apply (erule (1) LIMSEQ_diff)
   427 apply (simp add: le_diff_eq)
   428 done
   429 
   430 
   431 subsection {* Convergence *}
   432 
   433 lemma limI: "X ----> L ==> lim X = L"
   434 apply (simp add: lim_def)
   435 apply (blast intro: LIMSEQ_unique)
   436 done
   437 
   438 lemma convergentD: "convergent X ==> \<exists>L. (X ----> L)"
   439 by (simp add: convergent_def)
   440 
   441 lemma convergentI: "(X ----> L) ==> convergent X"
   442 by (auto simp add: convergent_def)
   443 
   444 lemma convergent_LIMSEQ_iff: "convergent X = (X ----> lim X)"
   445 by (auto intro: theI LIMSEQ_unique simp add: convergent_def lim_def)
   446 
   447 lemma convergent_const: "convergent (\<lambda>n. c)"
   448 by (rule convergentI, rule LIMSEQ_const)
   449 
   450 lemma convergent_add:
   451   fixes X Y :: "nat \<Rightarrow> 'a::real_normed_vector"
   452   assumes "convergent (\<lambda>n. X n)"
   453   assumes "convergent (\<lambda>n. Y n)"
   454   shows "convergent (\<lambda>n. X n + Y n)"
   455 using assms unfolding convergent_def by (fast intro: LIMSEQ_add)
   456 
   457 lemma convergent_setsum:
   458   fixes X :: "'a \<Rightarrow> nat \<Rightarrow> 'b::real_normed_vector"
   459   assumes "\<And>i. i \<in> A \<Longrightarrow> convergent (\<lambda>n. X i n)"
   460   shows "convergent (\<lambda>n. \<Sum>i\<in>A. X i n)"
   461 proof (cases "finite A")
   462   case True from this and assms show ?thesis
   463     by (induct A set: finite) (simp_all add: convergent_const convergent_add)
   464 qed (simp add: convergent_const)
   465 
   466 lemma (in bounded_linear) convergent:
   467   assumes "convergent (\<lambda>n. X n)"
   468   shows "convergent (\<lambda>n. f (X n))"
   469 using assms unfolding convergent_def by (fast intro: LIMSEQ)
   470 
   471 lemma (in bounded_bilinear) convergent:
   472   assumes "convergent (\<lambda>n. X n)" and "convergent (\<lambda>n. Y n)"
   473   shows "convergent (\<lambda>n. X n ** Y n)"
   474 using assms unfolding convergent_def by (fast intro: LIMSEQ)
   475 
   476 lemma convergent_minus_iff:
   477   fixes X :: "nat \<Rightarrow> 'a::real_normed_vector"
   478   shows "convergent X \<longleftrightarrow> convergent (\<lambda>n. - X n)"
   479 apply (simp add: convergent_def)
   480 apply (auto dest: LIMSEQ_minus)
   481 apply (drule LIMSEQ_minus, auto)
   482 done
   483 
   484 lemma lim_le:
   485   fixes x :: real
   486   assumes f: "convergent f" and fn_le: "!!n. f n \<le> x"
   487   shows "lim f \<le> x"
   488 proof (rule classical)
   489   assume "\<not> lim f \<le> x"
   490   hence 0: "0 < lim f - x" by arith
   491   have 1: "f----> lim f"
   492     by (metis convergent_LIMSEQ_iff f) 
   493   thus ?thesis
   494     proof (simp add: LIMSEQ_iff)
   495       assume "\<forall>r>0. \<exists>no. \<forall>n\<ge>no. \<bar>f n - lim f\<bar> < r"
   496       hence "\<exists>no. \<forall>n\<ge>no. \<bar>f n - lim f\<bar> < lim f - x"
   497         by (metis 0)
   498       from this obtain no where "\<forall>n\<ge>no. \<bar>f n - lim f\<bar> < lim f - x"
   499         by blast
   500       thus "lim f \<le> x"
   501         by (metis 1 LIMSEQ_le_const2 fn_le)
   502     qed
   503 qed
   504 
   505 text{*Subsequence (alternative definition, (e.g. Hoskins)*}
   506 
   507 lemma subseq_Suc_iff: "subseq f = (\<forall>n. (f n) < (f (Suc n)))"
   508 apply (simp add: subseq_def)
   509 apply (auto dest!: less_imp_Suc_add)
   510 apply (induct_tac k)
   511 apply (auto intro: less_trans)
   512 done
   513 
   514 lemma monoseq_Suc:
   515   "monoseq X \<longleftrightarrow> (\<forall>n. X n \<le> X (Suc n)) \<or> (\<forall>n. X (Suc n) \<le> X n)"
   516 apply (simp add: monoseq_def)
   517 apply (auto dest!: le_imp_less_or_eq)
   518 apply (auto intro!: lessI [THEN less_imp_le] dest!: less_imp_Suc_add)
   519 apply (induct_tac "ka")
   520 apply (auto intro: order_trans)
   521 apply (erule contrapos_np)
   522 apply (induct_tac "k")
   523 apply (auto intro: order_trans)
   524 done
   525 
   526 lemma monoI1: "\<forall>m. \<forall> n \<ge> m. X m \<le> X n ==> monoseq X"
   527 by (simp add: monoseq_def)
   528 
   529 lemma monoI2: "\<forall>m. \<forall> n \<ge> m. X n \<le> X m ==> monoseq X"
   530 by (simp add: monoseq_def)
   531 
   532 lemma mono_SucI1: "\<forall>n. X n \<le> X (Suc n) ==> monoseq X"
   533 by (simp add: monoseq_Suc)
   534 
   535 lemma mono_SucI2: "\<forall>n. X (Suc n) \<le> X n ==> monoseq X"
   536 by (simp add: monoseq_Suc)
   537 
   538 lemma monoseq_minus:
   539   fixes a :: "nat \<Rightarrow> 'a::ordered_ab_group_add"
   540   assumes "monoseq a"
   541   shows "monoseq (\<lambda> n. - a n)"
   542 proof (cases "\<forall> m. \<forall> n \<ge> m. a m \<le> a n")
   543   case True
   544   hence "\<forall> m. \<forall> n \<ge> m. - a n \<le> - a m" by auto
   545   thus ?thesis by (rule monoI2)
   546 next
   547   case False
   548   hence "\<forall> m. \<forall> n \<ge> m. - a m \<le> - a n" using `monoseq a`[unfolded monoseq_def] by auto
   549   thus ?thesis by (rule monoI1)
   550 qed
   551 
   552 lemma monoseq_le:
   553   fixes a :: "nat \<Rightarrow> real"
   554   assumes "monoseq a" and "a ----> x"
   555   shows "((\<forall> n. a n \<le> x) \<and> (\<forall>m. \<forall>n\<ge>m. a m \<le> a n)) \<or> 
   556          ((\<forall> n. x \<le> a n) \<and> (\<forall>m. \<forall>n\<ge>m. a n \<le> a m))"
   557 proof -
   558   { fix x n fix a :: "nat \<Rightarrow> real"
   559     assume "a ----> x" and "\<forall> m. \<forall> n \<ge> m. a m \<le> a n"
   560     hence monotone: "\<And> m n. m \<le> n \<Longrightarrow> a m \<le> a n" by auto
   561     have "a n \<le> x"
   562     proof (rule ccontr)
   563       assume "\<not> a n \<le> x" hence "x < a n" by auto
   564       hence "0 < a n - x" by auto
   565       from `a ----> x`[THEN LIMSEQ_D, OF this]
   566       obtain no where "\<And>n'. no \<le> n' \<Longrightarrow> norm (a n' - x) < a n - x" by blast
   567       hence "norm (a (max no n) - x) < a n - x" by auto
   568       moreover
   569       { fix n' have "n \<le> n' \<Longrightarrow> x < a n'" using monotone[where m=n and n=n'] and `x < a n` by auto }
   570       hence "x < a (max no n)" by auto
   571       ultimately
   572       have "a (max no n) < a n" by auto
   573       with monotone[where m=n and n="max no n"]
   574       show False by (auto simp:max_def split:split_if_asm)
   575     qed
   576   } note top_down = this
   577   { fix x n m fix a :: "nat \<Rightarrow> real"
   578     assume "a ----> x" and "monoseq a" and "a m < x"
   579     have "a n \<le> x \<and> (\<forall> m. \<forall> n \<ge> m. a m \<le> a n)"
   580     proof (cases "\<forall> m. \<forall> n \<ge> m. a m \<le> a n")
   581       case True with top_down and `a ----> x` show ?thesis by auto
   582     next
   583       case False with `monoseq a`[unfolded monoseq_def] have "\<forall> m. \<forall> n \<ge> m. - a m \<le> - a n" by auto
   584       hence "- a m \<le> - x" using top_down[OF LIMSEQ_minus[OF `a ----> x`]] by blast
   585       hence False using `a m < x` by auto
   586       thus ?thesis ..
   587     qed
   588   } note when_decided = this
   589 
   590   show ?thesis
   591   proof (cases "\<exists> m. a m \<noteq> x")
   592     case True then obtain m where "a m \<noteq> x" by auto
   593     show ?thesis
   594     proof (cases "a m < x")
   595       case True with when_decided[OF `a ----> x` `monoseq a`, where m2=m]
   596       show ?thesis by blast
   597     next
   598       case False hence "- a m < - x" using `a m \<noteq> x` by auto
   599       with when_decided[OF LIMSEQ_minus[OF `a ----> x`] monoseq_minus[OF `monoseq a`], where m2=m]
   600       show ?thesis by auto
   601     qed
   602   qed auto
   603 qed
   604 
   605 text{* for any sequence, there is a monotonic subsequence *}
   606 lemma seq_monosub:
   607   fixes s :: "nat => 'a::linorder"
   608   shows "\<exists>f. subseq f \<and> monoseq (\<lambda> n. (s (f n)))"
   609 proof cases
   610   let "?P p n" = "p > n \<and> (\<forall>m\<ge>p. s m \<le> s p)"
   611   assume *: "\<forall>n. \<exists>p. ?P p n"
   612   def f \<equiv> "nat_rec (SOME p. ?P p 0) (\<lambda>_ n. SOME p. ?P p n)"
   613   have f_0: "f 0 = (SOME p. ?P p 0)" unfolding f_def by simp
   614   have f_Suc: "\<And>i. f (Suc i) = (SOME p. ?P p (f i))" unfolding f_def nat_rec_Suc ..
   615   have P_0: "?P (f 0) 0" unfolding f_0 using *[rule_format] by (rule someI2_ex) auto
   616   have P_Suc: "\<And>i. ?P (f (Suc i)) (f i)" unfolding f_Suc using *[rule_format] by (rule someI2_ex) auto
   617   then have "subseq f" unfolding subseq_Suc_iff by auto
   618   moreover have "monoseq (\<lambda>n. s (f n))" unfolding monoseq_Suc
   619   proof (intro disjI2 allI)
   620     fix n show "s (f (Suc n)) \<le> s (f n)"
   621     proof (cases n)
   622       case 0 with P_Suc[of 0] P_0 show ?thesis by auto
   623     next
   624       case (Suc m)
   625       from P_Suc[of n] Suc have "f (Suc m) \<le> f (Suc (Suc m))" by simp
   626       with P_Suc Suc show ?thesis by simp
   627     qed
   628   qed
   629   ultimately show ?thesis by auto
   630 next
   631   let "?P p m" = "m < p \<and> s m < s p"
   632   assume "\<not> (\<forall>n. \<exists>p>n. (\<forall>m\<ge>p. s m \<le> s p))"
   633   then obtain N where N: "\<And>p. p > N \<Longrightarrow> \<exists>m>p. s p < s m" by (force simp: not_le le_less)
   634   def f \<equiv> "nat_rec (SOME p. ?P p (Suc N)) (\<lambda>_ n. SOME p. ?P p n)"
   635   have f_0: "f 0 = (SOME p. ?P p (Suc N))" unfolding f_def by simp
   636   have f_Suc: "\<And>i. f (Suc i) = (SOME p. ?P p (f i))" unfolding f_def nat_rec_Suc ..
   637   have P_0: "?P (f 0) (Suc N)"
   638     unfolding f_0 some_eq_ex[of "\<lambda>p. ?P p (Suc N)"] using N[of "Suc N"] by auto
   639   { fix i have "N < f i \<Longrightarrow> ?P (f (Suc i)) (f i)"
   640       unfolding f_Suc some_eq_ex[of "\<lambda>p. ?P p (f i)"] using N[of "f i"] . }
   641   note P' = this
   642   { fix i have "N < f i \<and> ?P (f (Suc i)) (f i)"
   643       by (induct i) (insert P_0 P', auto) }
   644   then have "subseq f" "monoseq (\<lambda>x. s (f x))"
   645     unfolding subseq_Suc_iff monoseq_Suc by (auto simp: not_le intro: less_imp_le)
   646   then show ?thesis by auto
   647 qed
   648 
   649 lemma seq_suble: assumes sf: "subseq f" shows "n \<le> f n"
   650 proof(induct n)
   651   case 0 thus ?case by simp
   652 next
   653   case (Suc n)
   654   from sf[unfolded subseq_Suc_iff, rule_format, of n] Suc.hyps
   655   have "n < f (Suc n)" by arith
   656   thus ?case by arith
   657 qed
   658 
   659 lemma LIMSEQ_subseq_LIMSEQ:
   660   "\<lbrakk> X ----> L; subseq f \<rbrakk> \<Longrightarrow> (X o f) ----> L"
   661 apply (rule topological_tendstoI)
   662 apply (drule (2) topological_tendstoD)
   663 apply (simp only: eventually_sequentially)
   664 apply (clarify, rule_tac x=N in exI, clarsimp)
   665 apply (blast intro: seq_suble le_trans dest!: spec) 
   666 done
   667 
   668 subsection {* Bounded Monotonic Sequences *}
   669 
   670 
   671 text{*Bounded Sequence*}
   672 
   673 lemma BseqD: "Bseq X ==> \<exists>K. 0 < K & (\<forall>n. norm (X n) \<le> K)"
   674 by (simp add: Bseq_def)
   675 
   676 lemma BseqI: "[| 0 < K; \<forall>n. norm (X n) \<le> K |] ==> Bseq X"
   677 by (auto simp add: Bseq_def)
   678 
   679 lemma lemma_NBseq_def:
   680      "(\<exists>K > 0. \<forall>n. norm (X n) \<le> K) =
   681       (\<exists>N. \<forall>n. norm (X n) \<le> real(Suc N))"
   682 proof auto
   683   fix K :: real
   684   from reals_Archimedean2 obtain n :: nat where "K < real n" ..
   685   then have "K \<le> real (Suc n)" by auto
   686   assume "\<forall>m. norm (X m) \<le> K"
   687   have "\<forall>m. norm (X m) \<le> real (Suc n)"
   688   proof
   689     fix m :: 'a
   690     from `\<forall>m. norm (X m) \<le> K` have "norm (X m) \<le> K" ..
   691     with `K \<le> real (Suc n)` show "norm (X m) \<le> real (Suc n)" by auto
   692   qed
   693   then show "\<exists>N. \<forall>n. norm (X n) \<le> real (Suc N)" ..
   694 next
   695   fix N :: nat
   696   have "real (Suc N) > 0" by (simp add: real_of_nat_Suc)
   697   moreover assume "\<forall>n. norm (X n) \<le> real (Suc N)"
   698   ultimately show "\<exists>K>0. \<forall>n. norm (X n) \<le> K" by blast
   699 qed
   700 
   701 
   702 text{* alternative definition for Bseq *}
   703 lemma Bseq_iff: "Bseq X = (\<exists>N. \<forall>n. norm (X n) \<le> real(Suc N))"
   704 apply (simp add: Bseq_def)
   705 apply (simp (no_asm) add: lemma_NBseq_def)
   706 done
   707 
   708 lemma lemma_NBseq_def2:
   709      "(\<exists>K > 0. \<forall>n. norm (X n) \<le> K) = (\<exists>N. \<forall>n. norm (X n) < real(Suc N))"
   710 apply (subst lemma_NBseq_def, auto)
   711 apply (rule_tac x = "Suc N" in exI)
   712 apply (rule_tac [2] x = N in exI)
   713 apply (auto simp add: real_of_nat_Suc)
   714  prefer 2 apply (blast intro: order_less_imp_le)
   715 apply (drule_tac x = n in spec, simp)
   716 done
   717 
   718 (* yet another definition for Bseq *)
   719 lemma Bseq_iff1a: "Bseq X = (\<exists>N. \<forall>n. norm (X n) < real(Suc N))"
   720 by (simp add: Bseq_def lemma_NBseq_def2)
   721 
   722 subsubsection{*Upper Bounds and Lubs of Bounded Sequences*}
   723 
   724 lemma Bseq_isUb:
   725   "!!(X::nat=>real). Bseq X ==> \<exists>U. isUb (UNIV::real set) {x. \<exists>n. X n = x} U"
   726 by (auto intro: isUbI setleI simp add: Bseq_def abs_le_iff)
   727 
   728 
   729 text{* Use completeness of reals (supremum property)
   730    to show that any bounded sequence has a least upper bound*}
   731 
   732 lemma Bseq_isLub:
   733   "!!(X::nat=>real). Bseq X ==>
   734    \<exists>U. isLub (UNIV::real set) {x. \<exists>n. X n = x} U"
   735 by (blast intro: reals_complete Bseq_isUb)
   736 
   737 subsubsection{*A Bounded and Monotonic Sequence Converges*}
   738 
   739 lemma lemma_converg1:
   740      "!!(X::nat=>real). [| \<forall>m. \<forall> n \<ge> m. X m \<le> X n;
   741                   isLub (UNIV::real set) {x. \<exists>n. X n = x} (X ma)
   742                |] ==> \<forall>n \<ge> ma. X n = X ma"
   743 apply safe
   744 apply (drule_tac y = "X n" in isLubD2)
   745 apply (blast dest: order_antisym)+
   746 done
   747 
   748 lemma Bmonoseq_LIMSEQ: "\<forall>n. m \<le> n --> X n = X m ==> \<exists>L. (X ----> L)"
   749 unfolding tendsto_def eventually_sequentially
   750 apply (rule_tac x = "X m" in exI, safe)
   751 apply (rule_tac x = m in exI, safe)
   752 apply (drule spec, erule impE, auto)
   753 done
   754 
   755 lemma lemma_converg2:
   756    "!!(X::nat=>real).
   757     [| \<forall>m. X m ~= U;  isLub UNIV {x. \<exists>n. X n = x} U |] ==> \<forall>m. X m < U"
   758 apply safe
   759 apply (drule_tac y = "X m" in isLubD2)
   760 apply (auto dest!: order_le_imp_less_or_eq)
   761 done
   762 
   763 lemma lemma_converg3: "!!(X ::nat=>real). \<forall>m. X m \<le> U ==> isUb UNIV {x. \<exists>n. X n = x} U"
   764 by (rule setleI [THEN isUbI], auto)
   765 
   766 text{* FIXME: @{term "U - T < U"} is redundant *}
   767 lemma lemma_converg4: "!!(X::nat=> real).
   768                [| \<forall>m. X m ~= U;
   769                   isLub UNIV {x. \<exists>n. X n = x} U;
   770                   0 < T;
   771                   U + - T < U
   772                |] ==> \<exists>m. U + -T < X m & X m < U"
   773 apply (drule lemma_converg2, assumption)
   774 apply (rule ccontr, simp)
   775 apply (simp add: linorder_not_less)
   776 apply (drule lemma_converg3)
   777 apply (drule isLub_le_isUb, assumption)
   778 apply (auto dest: order_less_le_trans)
   779 done
   780 
   781 text{*A standard proof of the theorem for monotone increasing sequence*}
   782 
   783 lemma Bseq_mono_convergent:
   784      "[| Bseq X; \<forall>m. \<forall>n \<ge> m. X m \<le> X n |] ==> convergent (X::nat=>real)"
   785 apply (simp add: convergent_def)
   786 apply (frule Bseq_isLub, safe)
   787 apply (case_tac "\<exists>m. X m = U", auto)
   788 apply (blast dest: lemma_converg1 Bmonoseq_LIMSEQ)
   789 (* second case *)
   790 apply (rule_tac x = U in exI)
   791 apply (subst LIMSEQ_iff, safe)
   792 apply (frule lemma_converg2, assumption)
   793 apply (drule lemma_converg4, auto)
   794 apply (rule_tac x = m in exI, safe)
   795 apply (subgoal_tac "X m \<le> X n")
   796  prefer 2 apply blast
   797 apply (drule_tac x=n and P="%m. X m < U" in spec, arith)
   798 done
   799 
   800 lemma Bseq_minus_iff: "Bseq (%n. -(X n)) = Bseq X"
   801 by (simp add: Bseq_def)
   802 
   803 text{*Main monotonicity theorem*}
   804 lemma Bseq_monoseq_convergent: "[| Bseq X; monoseq X |] ==> convergent (X::nat\<Rightarrow>real)"
   805 apply (simp add: monoseq_def, safe)
   806 apply (rule_tac [2] convergent_minus_iff [THEN ssubst])
   807 apply (drule_tac [2] Bseq_minus_iff [THEN ssubst])
   808 apply (auto intro!: Bseq_mono_convergent)
   809 done
   810 
   811 subsubsection{*Increasing and Decreasing Series*}
   812 
   813 lemma incseq_imp_monoseq:  "incseq X \<Longrightarrow> monoseq X"
   814   by (simp add: incseq_def monoseq_def)
   815 
   816 lemma incseq_le:
   817   fixes X :: "nat \<Rightarrow> real"
   818   assumes inc: "incseq X" and lim: "X ----> L" shows "X n \<le> L"
   819   using monoseq_le [OF incseq_imp_monoseq [OF inc] lim]
   820 proof
   821   assume "(\<forall>n. X n \<le> L) \<and> (\<forall>m n. m \<le> n \<longrightarrow> X m \<le> X n)"
   822   thus ?thesis by simp
   823 next
   824   assume "(\<forall>n. L \<le> X n) \<and> (\<forall>m n. m \<le> n \<longrightarrow> X n \<le> X m)"
   825   hence const: "(!!m n. m \<le> n \<Longrightarrow> X n = X m)" using inc
   826     by (auto simp add: incseq_def intro: order_antisym)
   827   have X: "!!n. X n = X 0"
   828     by (blast intro: const [of 0]) 
   829   have "X = (\<lambda>n. X 0)"
   830     by (blast intro: ext X)
   831   hence "L = X 0" using LIMSEQ_const [of "X 0"]
   832     by (auto intro: LIMSEQ_unique lim) 
   833   thus ?thesis
   834     by (blast intro: eq_refl X)
   835 qed
   836 
   837 lemma incseq_SucI:
   838   assumes "\<And>n. X n \<le> X (Suc n)"
   839   shows "incseq X" unfolding incseq_def
   840 proof safe
   841   fix m n :: nat
   842   { fix d m :: nat
   843     have "X m \<le> X (m + d)"
   844     proof (induct d)
   845       case (Suc d)
   846       also have "X (m + d) \<le> X (m + Suc d)"
   847         using assms by simp
   848       finally show ?case .
   849     qed simp }
   850   note this[of m "n - m"]
   851   moreover assume "m \<le> n"
   852   ultimately show "X m \<le> X n" by simp
   853 qed
   854 
   855 lemma decseq_imp_monoseq:  "decseq X \<Longrightarrow> monoseq X"
   856   by (simp add: decseq_def monoseq_def)
   857 
   858 lemma decseq_eq_incseq:
   859   fixes X :: "nat \<Rightarrow> 'a::ordered_ab_group_add" shows "decseq X = incseq (\<lambda>n. - X n)" 
   860   by (simp add: decseq_def incseq_def)
   861 
   862 
   863 lemma decseq_le:
   864   fixes X :: "nat \<Rightarrow> real" assumes dec: "decseq X" and lim: "X ----> L" shows "L \<le> X n"
   865 proof -
   866   have inc: "incseq (\<lambda>n. - X n)" using dec
   867     by (simp add: decseq_eq_incseq)
   868   have "- X n \<le> - L" 
   869     by (blast intro: incseq_le [OF inc] LIMSEQ_minus lim) 
   870   thus ?thesis
   871     by simp
   872 qed
   873 
   874 subsubsection{*A Few More Equivalence Theorems for Boundedness*}
   875 
   876 text{*alternative formulation for boundedness*}
   877 lemma Bseq_iff2: "Bseq X = (\<exists>k > 0. \<exists>x. \<forall>n. norm (X(n) + -x) \<le> k)"
   878 apply (unfold Bseq_def, safe)
   879 apply (rule_tac [2] x = "k + norm x" in exI)
   880 apply (rule_tac x = K in exI, simp)
   881 apply (rule exI [where x = 0], auto)
   882 apply (erule order_less_le_trans, simp)
   883 apply (drule_tac x=n in spec, fold diff_minus)
   884 apply (drule order_trans [OF norm_triangle_ineq2])
   885 apply simp
   886 done
   887 
   888 text{*alternative formulation for boundedness*}
   889 lemma Bseq_iff3: "Bseq X = (\<exists>k > 0. \<exists>N. \<forall>n. norm(X(n) + -X(N)) \<le> k)"
   890 apply safe
   891 apply (simp add: Bseq_def, safe)
   892 apply (rule_tac x = "K + norm (X N)" in exI)
   893 apply auto
   894 apply (erule order_less_le_trans, simp)
   895 apply (rule_tac x = N in exI, safe)
   896 apply (drule_tac x = n in spec)
   897 apply (rule order_trans [OF norm_triangle_ineq], simp)
   898 apply (auto simp add: Bseq_iff2)
   899 done
   900 
   901 lemma BseqI2: "(\<forall>n. k \<le> f n & f n \<le> (K::real)) ==> Bseq f"
   902 apply (simp add: Bseq_def)
   903 apply (rule_tac x = " (\<bar>k\<bar> + \<bar>K\<bar>) + 1" in exI, auto)
   904 apply (drule_tac x = n in spec, arith)
   905 done
   906 
   907 
   908 subsection {* Cauchy Sequences *}
   909 
   910 lemma metric_CauchyI:
   911   "(\<And>e. 0 < e \<Longrightarrow> \<exists>M. \<forall>m\<ge>M. \<forall>n\<ge>M. dist (X m) (X n) < e) \<Longrightarrow> Cauchy X"
   912 by (simp add: Cauchy_def)
   913 
   914 lemma metric_CauchyD:
   915   "\<lbrakk>Cauchy X; 0 < e\<rbrakk> \<Longrightarrow> \<exists>M. \<forall>m\<ge>M. \<forall>n\<ge>M. dist (X m) (X n) < e"
   916 by (simp add: Cauchy_def)
   917 
   918 lemma Cauchy_iff:
   919   fixes X :: "nat \<Rightarrow> 'a::real_normed_vector"
   920   shows "Cauchy X \<longleftrightarrow> (\<forall>e>0. \<exists>M. \<forall>m\<ge>M. \<forall>n\<ge>M. norm (X m - X n) < e)"
   921 unfolding Cauchy_def dist_norm ..
   922 
   923 lemma Cauchy_iff2:
   924      "Cauchy X =
   925       (\<forall>j. (\<exists>M. \<forall>m \<ge> M. \<forall>n \<ge> M. \<bar>X m - X n\<bar> < inverse(real (Suc j))))"
   926 apply (simp add: Cauchy_iff, auto)
   927 apply (drule reals_Archimedean, safe)
   928 apply (drule_tac x = n in spec, auto)
   929 apply (rule_tac x = M in exI, auto)
   930 apply (drule_tac x = m in spec, simp)
   931 apply (drule_tac x = na in spec, auto)
   932 done
   933 
   934 lemma CauchyI:
   935   fixes X :: "nat \<Rightarrow> 'a::real_normed_vector"
   936   shows "(\<And>e. 0 < e \<Longrightarrow> \<exists>M. \<forall>m\<ge>M. \<forall>n\<ge>M. norm (X m - X n) < e) \<Longrightarrow> Cauchy X"
   937 by (simp add: Cauchy_iff)
   938 
   939 lemma CauchyD:
   940   fixes X :: "nat \<Rightarrow> 'a::real_normed_vector"
   941   shows "\<lbrakk>Cauchy X; 0 < e\<rbrakk> \<Longrightarrow> \<exists>M. \<forall>m\<ge>M. \<forall>n\<ge>M. norm (X m - X n) < e"
   942 by (simp add: Cauchy_iff)
   943 
   944 lemma Cauchy_subseq_Cauchy:
   945   "\<lbrakk> Cauchy X; subseq f \<rbrakk> \<Longrightarrow> Cauchy (X o f)"
   946 apply (auto simp add: Cauchy_def)
   947 apply (drule_tac x=e in spec, clarify)
   948 apply (rule_tac x=M in exI, clarify)
   949 apply (blast intro: le_trans [OF _ seq_suble] dest!: spec)
   950 done
   951 
   952 subsubsection {* Cauchy Sequences are Bounded *}
   953 
   954 text{*A Cauchy sequence is bounded -- this is the standard
   955   proof mechanization rather than the nonstandard proof*}
   956 
   957 lemma lemmaCauchy: "\<forall>n \<ge> M. norm (X M - X n) < (1::real)
   958           ==>  \<forall>n \<ge> M. norm (X n :: 'a::real_normed_vector) < 1 + norm (X M)"
   959 apply (clarify, drule spec, drule (1) mp)
   960 apply (simp only: norm_minus_commute)
   961 apply (drule order_le_less_trans [OF norm_triangle_ineq2])
   962 apply simp
   963 done
   964 
   965 lemma Cauchy_Bseq: "Cauchy X ==> Bseq X"
   966 apply (simp add: Cauchy_iff)
   967 apply (drule spec, drule mp, rule zero_less_one, safe)
   968 apply (drule_tac x="M" in spec, simp)
   969 apply (drule lemmaCauchy)
   970 apply (rule_tac k="M" in Bseq_offset)
   971 apply (simp add: Bseq_def)
   972 apply (rule_tac x="1 + norm (X M)" in exI)
   973 apply (rule conjI, rule order_less_le_trans [OF zero_less_one], simp)
   974 apply (simp add: order_less_imp_le)
   975 done
   976 
   977 subsubsection {* Cauchy Sequences are Convergent *}
   978 
   979 class complete_space =
   980   assumes Cauchy_convergent: "Cauchy X \<Longrightarrow> convergent X"
   981 
   982 class banach = real_normed_vector + complete_space
   983 
   984 theorem LIMSEQ_imp_Cauchy:
   985   assumes X: "X ----> a" shows "Cauchy X"
   986 proof (rule metric_CauchyI)
   987   fix e::real assume "0 < e"
   988   hence "0 < e/2" by simp
   989   with X have "\<exists>N. \<forall>n\<ge>N. dist (X n) a < e/2" by (rule metric_LIMSEQ_D)
   990   then obtain N where N: "\<forall>n\<ge>N. dist (X n) a < e/2" ..
   991   show "\<exists>N. \<forall>m\<ge>N. \<forall>n\<ge>N. dist (X m) (X n) < e"
   992   proof (intro exI allI impI)
   993     fix m assume "N \<le> m"
   994     hence m: "dist (X m) a < e/2" using N by fast
   995     fix n assume "N \<le> n"
   996     hence n: "dist (X n) a < e/2" using N by fast
   997     have "dist (X m) (X n) \<le> dist (X m) a + dist (X n) a"
   998       by (rule dist_triangle2)
   999     also from m n have "\<dots> < e" by simp
  1000     finally show "dist (X m) (X n) < e" .
  1001   qed
  1002 qed
  1003 
  1004 lemma convergent_Cauchy: "convergent X \<Longrightarrow> Cauchy X"
  1005 unfolding convergent_def
  1006 by (erule exE, erule LIMSEQ_imp_Cauchy)
  1007 
  1008 lemma Cauchy_convergent_iff:
  1009   fixes X :: "nat \<Rightarrow> 'a::complete_space"
  1010   shows "Cauchy X = convergent X"
  1011 by (fast intro: Cauchy_convergent convergent_Cauchy)
  1012 
  1013 lemma convergent_subseq_convergent:
  1014   fixes X :: "nat \<Rightarrow> 'a::complete_space"
  1015   shows "\<lbrakk> convergent X; subseq f \<rbrakk> \<Longrightarrow> convergent (X o f)"
  1016   by (simp add: Cauchy_subseq_Cauchy Cauchy_convergent_iff [symmetric])
  1017 
  1018 text {*
  1019 Proof that Cauchy sequences converge based on the one from
  1020 http://pirate.shu.edu/~wachsmut/ira/numseq/proofs/cauconv.html
  1021 *}
  1022 
  1023 text {*
  1024   If sequence @{term "X"} is Cauchy, then its limit is the lub of
  1025   @{term "{r::real. \<exists>N. \<forall>n\<ge>N. r < X n}"}
  1026 *}
  1027 
  1028 lemma isUb_UNIV_I: "(\<And>y. y \<in> S \<Longrightarrow> y \<le> u) \<Longrightarrow> isUb UNIV S u"
  1029 by (simp add: isUbI setleI)
  1030 
  1031 locale real_Cauchy =
  1032   fixes X :: "nat \<Rightarrow> real"
  1033   assumes X: "Cauchy X"
  1034   fixes S :: "real set"
  1035   defines S_def: "S \<equiv> {x::real. \<exists>N. \<forall>n\<ge>N. x < X n}"
  1036 
  1037 lemma real_CauchyI:
  1038   assumes "Cauchy X"
  1039   shows "real_Cauchy X"
  1040   proof qed (fact assms)
  1041 
  1042 lemma (in real_Cauchy) mem_S: "\<forall>n\<ge>N. x < X n \<Longrightarrow> x \<in> S"
  1043 by (unfold S_def, auto)
  1044 
  1045 lemma (in real_Cauchy) bound_isUb:
  1046   assumes N: "\<forall>n\<ge>N. X n < x"
  1047   shows "isUb UNIV S x"
  1048 proof (rule isUb_UNIV_I)
  1049   fix y::real assume "y \<in> S"
  1050   hence "\<exists>M. \<forall>n\<ge>M. y < X n"
  1051     by (simp add: S_def)
  1052   then obtain M where "\<forall>n\<ge>M. y < X n" ..
  1053   hence "y < X (max M N)" by simp
  1054   also have "\<dots> < x" using N by simp
  1055   finally show "y \<le> x"
  1056     by (rule order_less_imp_le)
  1057 qed
  1058 
  1059 lemma (in real_Cauchy) isLub_ex: "\<exists>u. isLub UNIV S u"
  1060 proof (rule reals_complete)
  1061   obtain N where "\<forall>m\<ge>N. \<forall>n\<ge>N. norm (X m - X n) < 1"
  1062     using CauchyD [OF X zero_less_one] by auto
  1063   hence N: "\<forall>n\<ge>N. norm (X n - X N) < 1" by simp
  1064   show "\<exists>x. x \<in> S"
  1065   proof
  1066     from N have "\<forall>n\<ge>N. X N - 1 < X n"
  1067       by (simp add: abs_diff_less_iff)
  1068     thus "X N - 1 \<in> S" by (rule mem_S)
  1069   qed
  1070   show "\<exists>u. isUb UNIV S u"
  1071   proof
  1072     from N have "\<forall>n\<ge>N. X n < X N + 1"
  1073       by (simp add: abs_diff_less_iff)
  1074     thus "isUb UNIV S (X N + 1)"
  1075       by (rule bound_isUb)
  1076   qed
  1077 qed
  1078 
  1079 lemma (in real_Cauchy) isLub_imp_LIMSEQ:
  1080   assumes x: "isLub UNIV S x"
  1081   shows "X ----> x"
  1082 proof (rule LIMSEQ_I)
  1083   fix r::real assume "0 < r"
  1084   hence r: "0 < r/2" by simp
  1085   obtain N where "\<forall>n\<ge>N. \<forall>m\<ge>N. norm (X n - X m) < r/2"
  1086     using CauchyD [OF X r] by auto
  1087   hence "\<forall>n\<ge>N. norm (X n - X N) < r/2" by simp
  1088   hence N: "\<forall>n\<ge>N. X N - r/2 < X n \<and> X n < X N + r/2"
  1089     by (simp only: real_norm_def abs_diff_less_iff)
  1090 
  1091   from N have "\<forall>n\<ge>N. X N - r/2 < X n" by fast
  1092   hence "X N - r/2 \<in> S" by (rule mem_S)
  1093   hence 1: "X N - r/2 \<le> x" using x isLub_isUb isUbD by fast
  1094 
  1095   from N have "\<forall>n\<ge>N. X n < X N + r/2" by fast
  1096   hence "isUb UNIV S (X N + r/2)" by (rule bound_isUb)
  1097   hence 2: "x \<le> X N + r/2" using x isLub_le_isUb by fast
  1098 
  1099   show "\<exists>N. \<forall>n\<ge>N. norm (X n - x) < r"
  1100   proof (intro exI allI impI)
  1101     fix n assume n: "N \<le> n"
  1102     from N n have "X n < X N + r/2" and "X N - r/2 < X n" by simp+
  1103     thus "norm (X n - x) < r" using 1 2
  1104       by (simp add: abs_diff_less_iff)
  1105   qed
  1106 qed
  1107 
  1108 lemma (in real_Cauchy) LIMSEQ_ex: "\<exists>x. X ----> x"
  1109 proof -
  1110   obtain x where "isLub UNIV S x"
  1111     using isLub_ex by fast
  1112   hence "X ----> x"
  1113     by (rule isLub_imp_LIMSEQ)
  1114   thus ?thesis ..
  1115 qed
  1116 
  1117 lemma real_Cauchy_convergent:
  1118   fixes X :: "nat \<Rightarrow> real"
  1119   shows "Cauchy X \<Longrightarrow> convergent X"
  1120 unfolding convergent_def
  1121 by (rule real_Cauchy.LIMSEQ_ex)
  1122  (rule real_CauchyI)
  1123 
  1124 instance real :: banach
  1125 by intro_classes (rule real_Cauchy_convergent)
  1126 
  1127 
  1128 subsection {* Power Sequences *}
  1129 
  1130 text{*The sequence @{term "x^n"} tends to 0 if @{term "0\<le>x"} and @{term
  1131 "x<1"}.  Proof will use (NS) Cauchy equivalence for convergence and
  1132   also fact that bounded and monotonic sequence converges.*}
  1133 
  1134 lemma Bseq_realpow: "[| 0 \<le> (x::real); x \<le> 1 |] ==> Bseq (%n. x ^ n)"
  1135 apply (simp add: Bseq_def)
  1136 apply (rule_tac x = 1 in exI)
  1137 apply (simp add: power_abs)
  1138 apply (auto dest: power_mono)
  1139 done
  1140 
  1141 lemma monoseq_realpow: fixes x :: real shows "[| 0 \<le> x; x \<le> 1 |] ==> monoseq (%n. x ^ n)"
  1142 apply (clarify intro!: mono_SucI2)
  1143 apply (cut_tac n = n and N = "Suc n" and a = x in power_decreasing, auto)
  1144 done
  1145 
  1146 lemma convergent_realpow:
  1147   "[| 0 \<le> (x::real); x \<le> 1 |] ==> convergent (%n. x ^ n)"
  1148 by (blast intro!: Bseq_monoseq_convergent Bseq_realpow monoseq_realpow)
  1149 
  1150 lemma LIMSEQ_inverse_realpow_zero_lemma:
  1151   fixes x :: real
  1152   assumes x: "0 \<le> x"
  1153   shows "real n * x + 1 \<le> (x + 1) ^ n"
  1154 apply (induct n)
  1155 apply simp
  1156 apply simp
  1157 apply (rule order_trans)
  1158 prefer 2
  1159 apply (erule mult_left_mono)
  1160 apply (rule add_increasing [OF x], simp)
  1161 apply (simp add: real_of_nat_Suc)
  1162 apply (simp add: ring_distribs)
  1163 apply (simp add: mult_nonneg_nonneg x)
  1164 done
  1165 
  1166 lemma LIMSEQ_inverse_realpow_zero:
  1167   "1 < (x::real) \<Longrightarrow> (\<lambda>n. inverse (x ^ n)) ----> 0"
  1168 proof (rule LIMSEQ_inverse_zero [rule_format])
  1169   fix y :: real
  1170   assume x: "1 < x"
  1171   hence "0 < x - 1" by simp
  1172   hence "\<forall>y. \<exists>N::nat. y < real N * (x - 1)"
  1173     by (rule reals_Archimedean3)
  1174   hence "\<exists>N::nat. y < real N * (x - 1)" ..
  1175   then obtain N::nat where "y < real N * (x - 1)" ..
  1176   also have "\<dots> \<le> real N * (x - 1) + 1" by simp
  1177   also have "\<dots> \<le> (x - 1 + 1) ^ N"
  1178     by (rule LIMSEQ_inverse_realpow_zero_lemma, cut_tac x, simp)
  1179   also have "\<dots> = x ^ N" by simp
  1180   finally have "y < x ^ N" .
  1181   hence "\<forall>n\<ge>N. y < x ^ n"
  1182     apply clarify
  1183     apply (erule order_less_le_trans)
  1184     apply (erule power_increasing)
  1185     apply (rule order_less_imp_le [OF x])
  1186     done
  1187   thus "\<exists>N. \<forall>n\<ge>N. y < x ^ n" ..
  1188 qed
  1189 
  1190 lemma LIMSEQ_realpow_zero:
  1191   "\<lbrakk>0 \<le> (x::real); x < 1\<rbrakk> \<Longrightarrow> (\<lambda>n. x ^ n) ----> 0"
  1192 proof (cases)
  1193   assume "x = 0"
  1194   hence "(\<lambda>n. x ^ Suc n) ----> 0" by (simp add: LIMSEQ_const)
  1195   thus ?thesis by (rule LIMSEQ_imp_Suc)
  1196 next
  1197   assume "0 \<le> x" and "x \<noteq> 0"
  1198   hence x0: "0 < x" by simp
  1199   assume x1: "x < 1"
  1200   from x0 x1 have "1 < inverse x"
  1201     by (rule one_less_inverse)
  1202   hence "(\<lambda>n. inverse (inverse x ^ n)) ----> 0"
  1203     by (rule LIMSEQ_inverse_realpow_zero)
  1204   thus ?thesis by (simp add: power_inverse)
  1205 qed
  1206 
  1207 lemma LIMSEQ_power_zero:
  1208   fixes x :: "'a::{real_normed_algebra_1}"
  1209   shows "norm x < 1 \<Longrightarrow> (\<lambda>n. x ^ n) ----> 0"
  1210 apply (drule LIMSEQ_realpow_zero [OF norm_ge_zero])
  1211 apply (simp only: LIMSEQ_Zfun_iff, erule Zfun_le)
  1212 apply (simp add: power_abs norm_power_ineq)
  1213 done
  1214 
  1215 lemma LIMSEQ_divide_realpow_zero:
  1216   "1 < (x::real) ==> (%n. a / (x ^ n)) ----> 0"
  1217 apply (cut_tac a = a and x1 = "inverse x" in
  1218         LIMSEQ_mult [OF LIMSEQ_const LIMSEQ_realpow_zero])
  1219 apply (auto simp add: divide_inverse power_inverse)
  1220 apply (simp add: inverse_eq_divide pos_divide_less_eq)
  1221 done
  1222 
  1223 text{*Limit of @{term "c^n"} for @{term"\<bar>c\<bar> < 1"}*}
  1224 
  1225 lemma LIMSEQ_rabs_realpow_zero: "\<bar>c\<bar> < (1::real) ==> (%n. \<bar>c\<bar> ^ n) ----> 0"
  1226 by (rule LIMSEQ_realpow_zero [OF abs_ge_zero])
  1227 
  1228 lemma LIMSEQ_rabs_realpow_zero2: "\<bar>c\<bar> < (1::real) ==> (%n. c ^ n) ----> 0"
  1229 apply (rule LIMSEQ_rabs_zero [THEN iffD1])
  1230 apply (auto intro: LIMSEQ_rabs_realpow_zero simp add: power_abs)
  1231 done
  1232 
  1233 end