src/HOL/Nat.thy
author nipkow
Fri Aug 08 09:26:15 2008 +0200 (2008-08-08)
changeset 27789 1bf827e3258d
parent 27679 6392b92c3536
child 27823 52971512d1a2
permissions -rw-r--r--
added lemmas
     1 (*  Title:      HOL/Nat.thy
     2     ID:         $Id$
     3     Author:     Tobias Nipkow and Lawrence C Paulson and Markus Wenzel
     4 
     5 Type "nat" is a linear order, and a datatype; arithmetic operators + -
     6 and * (for div, mod and dvd, see theory Divides).
     7 *)
     8 
     9 header {* Natural numbers *}
    10 
    11 theory Nat
    12 imports Inductive Ring_and_Field
    13 uses
    14   "~~/src/Tools/rat.ML"
    15   "~~/src/Provers/Arith/cancel_sums.ML"
    16   ("arith_data.ML")
    17   "~~/src/Provers/Arith/fast_lin_arith.ML"
    18   ("Tools/lin_arith.ML")
    19 begin
    20 
    21 subsection {* Type @{text ind} *}
    22 
    23 typedecl ind
    24 
    25 axiomatization
    26   Zero_Rep :: ind and
    27   Suc_Rep :: "ind => ind"
    28 where
    29   -- {* the axiom of infinity in 2 parts *}
    30   inj_Suc_Rep:          "inj Suc_Rep" and
    31   Suc_Rep_not_Zero_Rep: "Suc_Rep x \<noteq> Zero_Rep"
    32 
    33 
    34 subsection {* Type nat *}
    35 
    36 text {* Type definition *}
    37 
    38 inductive Nat :: "ind \<Rightarrow> bool"
    39 where
    40     Zero_RepI: "Nat Zero_Rep"
    41   | Suc_RepI: "Nat i \<Longrightarrow> Nat (Suc_Rep i)"
    42 
    43 global
    44 
    45 typedef (open Nat)
    46   nat = Nat
    47   by (rule exI, unfold mem_def, rule Nat.Zero_RepI)
    48 
    49 constdefs
    50   Suc ::   "nat => nat"
    51   Suc_def: "Suc == (%n. Abs_Nat (Suc_Rep (Rep_Nat n)))"
    52 
    53 local
    54 
    55 instantiation nat :: zero
    56 begin
    57 
    58 definition Zero_nat_def [code func del]:
    59   "0 = Abs_Nat Zero_Rep"
    60 
    61 instance ..
    62 
    63 end
    64 
    65 lemma Suc_not_Zero: "Suc m \<noteq> 0"
    66   apply (simp add: Zero_nat_def Suc_def Abs_Nat_inject [unfolded mem_def]
    67     Rep_Nat [unfolded mem_def] Suc_RepI Zero_RepI Suc_Rep_not_Zero_Rep [unfolded mem_def])
    68   done
    69 
    70 lemma Zero_not_Suc: "0 \<noteq> Suc m"
    71   by (rule not_sym, rule Suc_not_Zero not_sym)
    72 
    73 rep_datatype "0 \<Colon> nat" Suc
    74   apply (unfold Zero_nat_def Suc_def)
    75      apply (rule Rep_Nat_inverse [THEN subst]) -- {* types force good instantiation *}
    76      apply (erule Rep_Nat [unfolded mem_def, THEN Nat.induct])
    77      apply (iprover elim: Abs_Nat_inverse [unfolded mem_def, THEN subst])
    78     apply (simp_all add: Abs_Nat_inject [unfolded mem_def] Rep_Nat [unfolded mem_def]
    79       Suc_RepI Zero_RepI Suc_Rep_not_Zero_Rep [unfolded mem_def]
    80       Suc_Rep_not_Zero_Rep [unfolded mem_def, symmetric]
    81       inj_Suc_Rep [THEN inj_eq] Rep_Nat_inject)
    82   done
    83 
    84 lemma nat_induct [case_names 0 Suc, induct type: nat]:
    85   -- {* for backward compatibility -- naming of variables differs *}
    86   fixes n
    87   assumes "P 0"
    88     and "\<And>n. P n \<Longrightarrow> P (Suc n)"
    89   shows "P n"
    90   using assms by (rule nat.induct) 
    91 
    92 declare nat.exhaust [case_names 0 Suc, cases type: nat]
    93 
    94 lemmas nat_rec_0 = nat.recs(1)
    95   and nat_rec_Suc = nat.recs(2)
    96 
    97 lemmas nat_case_0 = nat.cases(1)
    98   and nat_case_Suc = nat.cases(2)
    99    
   100 
   101 text {* Injectiveness and distinctness lemmas *}
   102 
   103 lemma inj_Suc[simp]: "inj_on Suc N"
   104   by (simp add: inj_on_def)
   105 
   106 lemma Suc_neq_Zero: "Suc m = 0 \<Longrightarrow> R"
   107 by (rule notE, rule Suc_not_Zero)
   108 
   109 lemma Zero_neq_Suc: "0 = Suc m \<Longrightarrow> R"
   110 by (rule Suc_neq_Zero, erule sym)
   111 
   112 lemma Suc_inject: "Suc x = Suc y \<Longrightarrow> x = y"
   113 by (rule inj_Suc [THEN injD])
   114 
   115 lemma n_not_Suc_n: "n \<noteq> Suc n"
   116 by (induct n) simp_all
   117 
   118 lemma Suc_n_not_n: "Suc n \<noteq> n"
   119 by (rule not_sym, rule n_not_Suc_n)
   120 
   121 text {* A special form of induction for reasoning
   122   about @{term "m < n"} and @{term "m - n"} *}
   123 
   124 lemma diff_induct: "(!!x. P x 0) ==> (!!y. P 0 (Suc y)) ==>
   125     (!!x y. P x y ==> P (Suc x) (Suc y)) ==> P m n"
   126   apply (rule_tac x = m in spec)
   127   apply (induct n)
   128   prefer 2
   129   apply (rule allI)
   130   apply (induct_tac x, iprover+)
   131   done
   132 
   133 
   134 subsection {* Arithmetic operators *}
   135 
   136 instantiation nat :: "{minus, comm_monoid_add}"
   137 begin
   138 
   139 primrec plus_nat
   140 where
   141   add_0:      "0 + n = (n\<Colon>nat)"
   142   | add_Suc:  "Suc m + n = Suc (m + n)"
   143 
   144 lemma add_0_right [simp]: "m + 0 = (m::nat)"
   145   by (induct m) simp_all
   146 
   147 lemma add_Suc_right [simp]: "m + Suc n = Suc (m + n)"
   148   by (induct m) simp_all
   149 
   150 lemma add_Suc_shift [code]: "Suc m + n = m + Suc n"
   151   by simp
   152 
   153 primrec minus_nat
   154 where
   155   diff_0:     "m - 0 = (m\<Colon>nat)"
   156   | diff_Suc: "m - Suc n = (case m - n of 0 => 0 | Suc k => k)"
   157 
   158 declare diff_Suc [simp del, code del]
   159 
   160 lemma diff_0_eq_0 [simp, code]: "0 - n = (0::nat)"
   161   by (induct n) (simp_all add: diff_Suc)
   162 
   163 lemma diff_Suc_Suc [simp, code]: "Suc m - Suc n = m - n"
   164   by (induct n) (simp_all add: diff_Suc)
   165 
   166 instance proof
   167   fix n m q :: nat
   168   show "(n + m) + q = n + (m + q)" by (induct n) simp_all
   169   show "n + m = m + n" by (induct n) simp_all
   170   show "0 + n = n" by simp
   171 qed
   172 
   173 end
   174 
   175 instantiation nat :: comm_semiring_1_cancel
   176 begin
   177 
   178 definition
   179   One_nat_def [simp]: "1 = Suc 0"
   180 
   181 primrec times_nat
   182 where
   183   mult_0:     "0 * n = (0\<Colon>nat)"
   184   | mult_Suc: "Suc m * n = n + (m * n)"
   185 
   186 lemma mult_0_right [simp]: "(m::nat) * 0 = 0"
   187   by (induct m) simp_all
   188 
   189 lemma mult_Suc_right [simp]: "m * Suc n = m + (m * n)"
   190   by (induct m) (simp_all add: add_left_commute)
   191 
   192 lemma add_mult_distrib: "(m + n) * k = (m * k) + ((n * k)::nat)"
   193   by (induct m) (simp_all add: add_assoc)
   194 
   195 instance proof
   196   fix n m q :: nat
   197   show "0 \<noteq> (1::nat)" by simp
   198   show "1 * n = n" by simp
   199   show "n * m = m * n" by (induct n) simp_all
   200   show "(n * m) * q = n * (m * q)" by (induct n) (simp_all add: add_mult_distrib)
   201   show "(n + m) * q = n * q + m * q" by (rule add_mult_distrib)
   202   assume "n + m = n + q" thus "m = q" by (induct n) simp_all
   203 qed
   204 
   205 end
   206 
   207 subsubsection {* Addition *}
   208 
   209 lemma nat_add_assoc: "(m + n) + k = m + ((n + k)::nat)"
   210   by (rule add_assoc)
   211 
   212 lemma nat_add_commute: "m + n = n + (m::nat)"
   213   by (rule add_commute)
   214 
   215 lemma nat_add_left_commute: "x + (y + z) = y + ((x + z)::nat)"
   216   by (rule add_left_commute)
   217 
   218 lemma nat_add_left_cancel [simp]: "(k + m = k + n) = (m = (n::nat))"
   219   by (rule add_left_cancel)
   220 
   221 lemma nat_add_right_cancel [simp]: "(m + k = n + k) = (m=(n::nat))"
   222   by (rule add_right_cancel)
   223 
   224 text {* Reasoning about @{text "m + 0 = 0"}, etc. *}
   225 
   226 lemma add_is_0 [iff]:
   227   fixes m n :: nat
   228   shows "(m + n = 0) = (m = 0 & n = 0)"
   229   by (cases m) simp_all
   230 
   231 lemma add_is_1:
   232   "(m+n= Suc 0) = (m= Suc 0 & n=0 | m=0 & n= Suc 0)"
   233   by (cases m) simp_all
   234 
   235 lemma one_is_add:
   236   "(Suc 0 = m + n) = (m = Suc 0 & n = 0 | m = 0 & n = Suc 0)"
   237   by (rule trans, rule eq_commute, rule add_is_1)
   238 
   239 lemma add_eq_self_zero:
   240   fixes m n :: nat
   241   shows "m + n = m \<Longrightarrow> n = 0"
   242   by (induct m) simp_all
   243 
   244 lemma inj_on_add_nat[simp]: "inj_on (%n::nat. n+k) N"
   245   apply (induct k)
   246    apply simp
   247   apply(drule comp_inj_on[OF _ inj_Suc])
   248   apply (simp add:o_def)
   249   done
   250 
   251 
   252 subsubsection {* Difference *}
   253 
   254 lemma diff_self_eq_0 [simp]: "(m\<Colon>nat) - m = 0"
   255   by (induct m) simp_all
   256 
   257 lemma diff_diff_left: "(i::nat) - j - k = i - (j + k)"
   258   by (induct i j rule: diff_induct) simp_all
   259 
   260 lemma Suc_diff_diff [simp]: "(Suc m - n) - Suc k = m - n - k"
   261   by (simp add: diff_diff_left)
   262 
   263 lemma diff_commute: "(i::nat) - j - k = i - k - j"
   264   by (simp add: diff_diff_left add_commute)
   265 
   266 lemma diff_add_inverse: "(n + m) - n = (m::nat)"
   267   by (induct n) simp_all
   268 
   269 lemma diff_add_inverse2: "(m + n) - n = (m::nat)"
   270   by (simp add: diff_add_inverse add_commute [of m n])
   271 
   272 lemma diff_cancel: "(k + m) - (k + n) = m - (n::nat)"
   273   by (induct k) simp_all
   274 
   275 lemma diff_cancel2: "(m + k) - (n + k) = m - (n::nat)"
   276   by (simp add: diff_cancel add_commute)
   277 
   278 lemma diff_add_0: "n - (n + m) = (0::nat)"
   279   by (induct n) simp_all
   280 
   281 text {* Difference distributes over multiplication *}
   282 
   283 lemma diff_mult_distrib: "((m::nat) - n) * k = (m * k) - (n * k)"
   284 by (induct m n rule: diff_induct) (simp_all add: diff_cancel)
   285 
   286 lemma diff_mult_distrib2: "k * ((m::nat) - n) = (k * m) - (k * n)"
   287 by (simp add: diff_mult_distrib mult_commute [of k])
   288   -- {* NOT added as rewrites, since sometimes they are used from right-to-left *}
   289 
   290 
   291 subsubsection {* Multiplication *}
   292 
   293 lemma nat_mult_assoc: "(m * n) * k = m * ((n * k)::nat)"
   294   by (rule mult_assoc)
   295 
   296 lemma nat_mult_commute: "m * n = n * (m::nat)"
   297   by (rule mult_commute)
   298 
   299 lemma add_mult_distrib2: "k * (m + n) = (k * m) + ((k * n)::nat)"
   300   by (rule right_distrib)
   301 
   302 lemma mult_is_0 [simp]: "((m::nat) * n = 0) = (m=0 | n=0)"
   303   by (induct m) auto
   304 
   305 lemmas nat_distrib =
   306   add_mult_distrib add_mult_distrib2 diff_mult_distrib diff_mult_distrib2
   307 
   308 lemma mult_eq_1_iff [simp]: "(m * n = Suc 0) = (m = 1 & n = 1)"
   309   apply (induct m)
   310    apply simp
   311   apply (induct n)
   312    apply auto
   313   done
   314 
   315 lemma one_eq_mult_iff [simp,noatp]: "(Suc 0 = m * n) = (m = 1 & n = 1)"
   316   apply (rule trans)
   317   apply (rule_tac [2] mult_eq_1_iff, fastsimp)
   318   done
   319 
   320 lemma mult_cancel1 [simp]: "(k * m = k * n) = (m = n | (k = (0::nat)))"
   321 proof -
   322   have "k \<noteq> 0 \<Longrightarrow> k * m = k * n \<Longrightarrow> m = n"
   323   proof (induct n arbitrary: m)
   324     case 0 then show "m = 0" by simp
   325   next
   326     case (Suc n) then show "m = Suc n"
   327       by (cases m) (simp_all add: eq_commute [of "0"])
   328   qed
   329   then show ?thesis by auto
   330 qed
   331 
   332 lemma mult_cancel2 [simp]: "(m * k = n * k) = (m = n | (k = (0::nat)))"
   333   by (simp add: mult_commute)
   334 
   335 lemma Suc_mult_cancel1: "(Suc k * m = Suc k * n) = (m = n)"
   336   by (subst mult_cancel1) simp
   337 
   338 
   339 subsection {* Orders on @{typ nat} *}
   340 
   341 subsubsection {* Operation definition *}
   342 
   343 instantiation nat :: linorder
   344 begin
   345 
   346 primrec less_eq_nat where
   347   "(0\<Colon>nat) \<le> n \<longleftrightarrow> True"
   348   | "Suc m \<le> n \<longleftrightarrow> (case n of 0 \<Rightarrow> False | Suc n \<Rightarrow> m \<le> n)"
   349 
   350 declare less_eq_nat.simps [simp del, code del]
   351 lemma [code]: "(0\<Colon>nat) \<le> n \<longleftrightarrow> True" by (simp add: less_eq_nat.simps)
   352 lemma le0 [iff]: "0 \<le> (n\<Colon>nat)" by (simp add: less_eq_nat.simps)
   353 
   354 definition less_nat where
   355   less_eq_Suc_le [code func del]: "n < m \<longleftrightarrow> Suc n \<le> m"
   356 
   357 lemma Suc_le_mono [iff]: "Suc n \<le> Suc m \<longleftrightarrow> n \<le> m"
   358   by (simp add: less_eq_nat.simps(2))
   359 
   360 lemma Suc_le_eq [code]: "Suc m \<le> n \<longleftrightarrow> m < n"
   361   unfolding less_eq_Suc_le ..
   362 
   363 lemma le_0_eq [iff]: "(n\<Colon>nat) \<le> 0 \<longleftrightarrow> n = 0"
   364   by (induct n) (simp_all add: less_eq_nat.simps(2))
   365 
   366 lemma not_less0 [iff]: "\<not> n < (0\<Colon>nat)"
   367   by (simp add: less_eq_Suc_le)
   368 
   369 lemma less_nat_zero_code [code]: "n < (0\<Colon>nat) \<longleftrightarrow> False"
   370   by simp
   371 
   372 lemma Suc_less_eq [iff]: "Suc m < Suc n \<longleftrightarrow> m < n"
   373   by (simp add: less_eq_Suc_le)
   374 
   375 lemma less_Suc_eq_le [code]: "m < Suc n \<longleftrightarrow> m \<le> n"
   376   by (simp add: less_eq_Suc_le)
   377 
   378 lemma le_SucI: "m \<le> n \<Longrightarrow> m \<le> Suc n"
   379   by (induct m arbitrary: n)
   380     (simp_all add: less_eq_nat.simps(2) split: nat.splits)
   381 
   382 lemma Suc_leD: "Suc m \<le> n \<Longrightarrow> m \<le> n"
   383   by (cases n) (auto intro: le_SucI)
   384 
   385 lemma less_SucI: "m < n \<Longrightarrow> m < Suc n"
   386   by (simp add: less_eq_Suc_le) (erule Suc_leD)
   387 
   388 lemma Suc_lessD: "Suc m < n \<Longrightarrow> m < n"
   389   by (simp add: less_eq_Suc_le) (erule Suc_leD)
   390 
   391 instance
   392 proof
   393   fix n m :: nat
   394   show "n < m \<longleftrightarrow> n \<le> m \<and> \<not> m \<le> n" 
   395   proof (induct n arbitrary: m)
   396     case 0 then show ?case by (cases m) (simp_all add: less_eq_Suc_le)
   397   next
   398     case (Suc n) then show ?case by (cases m) (simp_all add: less_eq_Suc_le)
   399   qed
   400 next
   401   fix n :: nat show "n \<le> n" by (induct n) simp_all
   402 next
   403   fix n m :: nat assume "n \<le> m" and "m \<le> n"
   404   then show "n = m"
   405     by (induct n arbitrary: m)
   406       (simp_all add: less_eq_nat.simps(2) split: nat.splits)
   407 next
   408   fix n m q :: nat assume "n \<le> m" and "m \<le> q"
   409   then show "n \<le> q"
   410   proof (induct n arbitrary: m q)
   411     case 0 show ?case by simp
   412   next
   413     case (Suc n) then show ?case
   414       by (simp_all (no_asm_use) add: less_eq_nat.simps(2) split: nat.splits, clarify,
   415         simp_all (no_asm_use) add: less_eq_nat.simps(2) split: nat.splits, clarify,
   416         simp_all (no_asm_use) add: less_eq_nat.simps(2) split: nat.splits)
   417   qed
   418 next
   419   fix n m :: nat show "n \<le> m \<or> m \<le> n"
   420     by (induct n arbitrary: m)
   421       (simp_all add: less_eq_nat.simps(2) split: nat.splits)
   422 qed
   423 
   424 end
   425 
   426 subsubsection {* Introduction properties *}
   427 
   428 lemma lessI [iff]: "n < Suc n"
   429   by (simp add: less_Suc_eq_le)
   430 
   431 lemma zero_less_Suc [iff]: "0 < Suc n"
   432   by (simp add: less_Suc_eq_le)
   433 
   434 
   435 subsubsection {* Elimination properties *}
   436 
   437 lemma less_not_refl: "~ n < (n::nat)"
   438   by (rule order_less_irrefl)
   439 
   440 lemma less_not_refl2: "n < m ==> m \<noteq> (n::nat)"
   441   by (rule not_sym) (rule less_imp_neq) 
   442 
   443 lemma less_not_refl3: "(s::nat) < t ==> s \<noteq> t"
   444   by (rule less_imp_neq)
   445 
   446 lemma less_irrefl_nat: "(n::nat) < n ==> R"
   447   by (rule notE, rule less_not_refl)
   448 
   449 lemma less_zeroE: "(n::nat) < 0 ==> R"
   450   by (rule notE) (rule not_less0)
   451 
   452 lemma less_Suc_eq: "(m < Suc n) = (m < n | m = n)"
   453   unfolding less_Suc_eq_le le_less ..
   454 
   455 lemma less_one [iff, noatp]: "(n < (1::nat)) = (n = 0)"
   456   by (simp add: less_Suc_eq)
   457 
   458 lemma less_Suc0 [iff]: "(n < Suc 0) = (n = 0)"
   459   by (simp add: less_Suc_eq)
   460 
   461 lemma Suc_mono: "m < n ==> Suc m < Suc n"
   462   by simp
   463 
   464 text {* "Less than" is antisymmetric, sort of *}
   465 lemma less_antisym: "\<lbrakk> \<not> n < m; n < Suc m \<rbrakk> \<Longrightarrow> m = n"
   466   unfolding not_less less_Suc_eq_le by (rule antisym)
   467 
   468 lemma nat_neq_iff: "((m::nat) \<noteq> n) = (m < n | n < m)"
   469   by (rule linorder_neq_iff)
   470 
   471 lemma nat_less_cases: assumes major: "(m::nat) < n ==> P n m"
   472   and eqCase: "m = n ==> P n m" and lessCase: "n<m ==> P n m"
   473   shows "P n m"
   474   apply (rule less_linear [THEN disjE])
   475   apply (erule_tac [2] disjE)
   476   apply (erule lessCase)
   477   apply (erule sym [THEN eqCase])
   478   apply (erule major)
   479   done
   480 
   481 
   482 subsubsection {* Inductive (?) properties *}
   483 
   484 lemma Suc_lessI: "m < n ==> Suc m \<noteq> n ==> Suc m < n"
   485   unfolding less_eq_Suc_le [of m] le_less by simp 
   486 
   487 lemma lessE:
   488   assumes major: "i < k"
   489   and p1: "k = Suc i ==> P" and p2: "!!j. i < j ==> k = Suc j ==> P"
   490   shows P
   491 proof -
   492   from major have "\<exists>j. i \<le> j \<and> k = Suc j"
   493     unfolding less_eq_Suc_le by (induct k) simp_all
   494   then have "(\<exists>j. i < j \<and> k = Suc j) \<or> k = Suc i"
   495     by (clarsimp simp add: less_le)
   496   with p1 p2 show P by auto
   497 qed
   498 
   499 lemma less_SucE: assumes major: "m < Suc n"
   500   and less: "m < n ==> P" and eq: "m = n ==> P" shows P
   501   apply (rule major [THEN lessE])
   502   apply (rule eq, blast)
   503   apply (rule less, blast)
   504   done
   505 
   506 lemma Suc_lessE: assumes major: "Suc i < k"
   507   and minor: "!!j. i < j ==> k = Suc j ==> P" shows P
   508   apply (rule major [THEN lessE])
   509   apply (erule lessI [THEN minor])
   510   apply (erule Suc_lessD [THEN minor], assumption)
   511   done
   512 
   513 lemma Suc_less_SucD: "Suc m < Suc n ==> m < n"
   514   by simp
   515 
   516 lemma less_trans_Suc:
   517   assumes le: "i < j" shows "j < k ==> Suc i < k"
   518   apply (induct k, simp_all)
   519   apply (insert le)
   520   apply (simp add: less_Suc_eq)
   521   apply (blast dest: Suc_lessD)
   522   done
   523 
   524 text {* Can be used with @{text less_Suc_eq} to get @{term "n = m | n < m"} *}
   525 lemma not_less_eq: "\<not> m < n \<longleftrightarrow> n < Suc m"
   526   unfolding not_less less_Suc_eq_le ..
   527 
   528 lemma not_less_eq_eq: "\<not> m \<le> n \<longleftrightarrow> Suc n \<le> m"
   529   unfolding not_le Suc_le_eq ..
   530 
   531 text {* Properties of "less than or equal" *}
   532 
   533 lemma le_imp_less_Suc: "m \<le> n ==> m < Suc n"
   534   unfolding less_Suc_eq_le .
   535 
   536 lemma Suc_n_not_le_n: "~ Suc n \<le> n"
   537   unfolding not_le less_Suc_eq_le ..
   538 
   539 lemma le_Suc_eq: "(m \<le> Suc n) = (m \<le> n | m = Suc n)"
   540   by (simp add: less_Suc_eq_le [symmetric] less_Suc_eq)
   541 
   542 lemma le_SucE: "m \<le> Suc n ==> (m \<le> n ==> R) ==> (m = Suc n ==> R) ==> R"
   543   by (drule le_Suc_eq [THEN iffD1], iprover+)
   544 
   545 lemma Suc_leI: "m < n ==> Suc(m) \<le> n"
   546   unfolding Suc_le_eq .
   547 
   548 text {* Stronger version of @{text Suc_leD} *}
   549 lemma Suc_le_lessD: "Suc m \<le> n ==> m < n"
   550   unfolding Suc_le_eq .
   551 
   552 lemma less_imp_le_nat: "m < n ==> m \<le> (n::nat)"
   553   unfolding less_eq_Suc_le by (rule Suc_leD)
   554 
   555 text {* For instance, @{text "(Suc m < Suc n) = (Suc m \<le> n) = (m < n)"} *}
   556 lemmas le_simps = less_imp_le_nat less_Suc_eq_le Suc_le_eq
   557 
   558 
   559 text {* Equivalence of @{term "m \<le> n"} and @{term "m < n | m = n"} *}
   560 
   561 lemma less_or_eq_imp_le: "m < n | m = n ==> m \<le> (n::nat)"
   562   unfolding le_less .
   563 
   564 lemma le_eq_less_or_eq: "(m \<le> (n::nat)) = (m < n | m=n)"
   565   by (rule le_less)
   566 
   567 text {* Useful with @{text blast}. *}
   568 lemma eq_imp_le: "(m::nat) = n ==> m \<le> n"
   569   by auto
   570 
   571 lemma le_refl: "n \<le> (n::nat)"
   572   by simp
   573 
   574 lemma le_trans: "[| i \<le> j; j \<le> k |] ==> i \<le> (k::nat)"
   575   by (rule order_trans)
   576 
   577 lemma le_anti_sym: "[| m \<le> n; n \<le> m |] ==> m = (n::nat)"
   578   by (rule antisym)
   579 
   580 lemma nat_less_le: "((m::nat) < n) = (m \<le> n & m \<noteq> n)"
   581   by (rule less_le)
   582 
   583 lemma le_neq_implies_less: "(m::nat) \<le> n ==> m \<noteq> n ==> m < n"
   584   unfolding less_le ..
   585 
   586 lemma nat_le_linear: "(m::nat) \<le> n | n \<le> m"
   587   by (rule linear)
   588 
   589 lemmas linorder_neqE_nat = linorder_neqE [where 'a = nat]
   590 
   591 lemma le_less_Suc_eq: "m \<le> n ==> (n < Suc m) = (n = m)"
   592   unfolding less_Suc_eq_le by auto
   593 
   594 lemma not_less_less_Suc_eq: "~ n < m ==> (n < Suc m) = (n = m)"
   595   unfolding not_less by (rule le_less_Suc_eq)
   596 
   597 lemmas not_less_simps = not_less_less_Suc_eq le_less_Suc_eq
   598 
   599 text {* These two rules ease the use of primitive recursion.
   600 NOTE USE OF @{text "=="} *}
   601 lemma def_nat_rec_0: "(!!n. f n == nat_rec c h n) ==> f 0 = c"
   602 by simp
   603 
   604 lemma def_nat_rec_Suc: "(!!n. f n == nat_rec c h n) ==> f (Suc n) = h n (f n)"
   605 by simp
   606 
   607 lemma not0_implies_Suc: "n \<noteq> 0 ==> \<exists>m. n = Suc m"
   608 by (cases n) simp_all
   609 
   610 lemma gr0_implies_Suc: "n > 0 ==> \<exists>m. n = Suc m"
   611 by (cases n) simp_all
   612 
   613 lemma gr_implies_not0: fixes n :: nat shows "m<n ==> n \<noteq> 0"
   614 by (cases n) simp_all
   615 
   616 lemma neq0_conv[iff]: fixes n :: nat shows "(n \<noteq> 0) = (0 < n)"
   617 by (cases n) simp_all
   618 
   619 text {* This theorem is useful with @{text blast} *}
   620 lemma gr0I: "((n::nat) = 0 ==> False) ==> 0 < n"
   621 by (rule neq0_conv[THEN iffD1], iprover)
   622 
   623 lemma gr0_conv_Suc: "(0 < n) = (\<exists>m. n = Suc m)"
   624 by (fast intro: not0_implies_Suc)
   625 
   626 lemma not_gr0 [iff,noatp]: "!!n::nat. (~ (0 < n)) = (n = 0)"
   627 using neq0_conv by blast
   628 
   629 lemma Suc_le_D: "(Suc n \<le> m') ==> (? m. m' = Suc m)"
   630 by (induct m') simp_all
   631 
   632 text {* Useful in certain inductive arguments *}
   633 lemma less_Suc_eq_0_disj: "(m < Suc n) = (m = 0 | (\<exists>j. m = Suc j & j < n))"
   634 by (cases m) simp_all
   635 
   636 
   637 subsubsection {* @{term min} and @{term max} *}
   638 
   639 lemma mono_Suc: "mono Suc"
   640 by (rule monoI) simp
   641 
   642 lemma min_0L [simp]: "min 0 n = (0::nat)"
   643 by (rule min_leastL) simp
   644 
   645 lemma min_0R [simp]: "min n 0 = (0::nat)"
   646 by (rule min_leastR) simp
   647 
   648 lemma min_Suc_Suc [simp]: "min (Suc m) (Suc n) = Suc (min m n)"
   649 by (simp add: mono_Suc min_of_mono)
   650 
   651 lemma min_Suc1:
   652    "min (Suc n) m = (case m of 0 => 0 | Suc m' => Suc(min n m'))"
   653 by (simp split: nat.split)
   654 
   655 lemma min_Suc2:
   656    "min m (Suc n) = (case m of 0 => 0 | Suc m' => Suc(min m' n))"
   657 by (simp split: nat.split)
   658 
   659 lemma max_0L [simp]: "max 0 n = (n::nat)"
   660 by (rule max_leastL) simp
   661 
   662 lemma max_0R [simp]: "max n 0 = (n::nat)"
   663 by (rule max_leastR) simp
   664 
   665 lemma max_Suc_Suc [simp]: "max (Suc m) (Suc n) = Suc(max m n)"
   666 by (simp add: mono_Suc max_of_mono)
   667 
   668 lemma max_Suc1:
   669    "max (Suc n) m = (case m of 0 => Suc n | Suc m' => Suc(max n m'))"
   670 by (simp split: nat.split)
   671 
   672 lemma max_Suc2:
   673    "max m (Suc n) = (case m of 0 => Suc n | Suc m' => Suc(max m' n))"
   674 by (simp split: nat.split)
   675 
   676 
   677 subsubsection {* Monotonicity of Addition *}
   678 
   679 lemma Suc_pred [simp]: "n>0 ==> Suc (n - Suc 0) = n"
   680 by (simp add: diff_Suc split: nat.split)
   681 
   682 lemma nat_add_left_cancel_le [simp]: "(k + m \<le> k + n) = (m\<le>(n::nat))"
   683 by (induct k) simp_all
   684 
   685 lemma nat_add_left_cancel_less [simp]: "(k + m < k + n) = (m<(n::nat))"
   686 by (induct k) simp_all
   687 
   688 lemma add_gr_0 [iff]: "!!m::nat. (m + n > 0) = (m>0 | n>0)"
   689 by(auto dest:gr0_implies_Suc)
   690 
   691 text {* strict, in 1st argument *}
   692 lemma add_less_mono1: "i < j ==> i + k < j + (k::nat)"
   693 by (induct k) simp_all
   694 
   695 text {* strict, in both arguments *}
   696 lemma add_less_mono: "[|i < j; k < l|] ==> i + k < j + (l::nat)"
   697   apply (rule add_less_mono1 [THEN less_trans], assumption+)
   698   apply (induct j, simp_all)
   699   done
   700 
   701 text {* Deleted @{text less_natE}; use @{text "less_imp_Suc_add RS exE"} *}
   702 lemma less_imp_Suc_add: "m < n ==> (\<exists>k. n = Suc (m + k))"
   703   apply (induct n)
   704   apply (simp_all add: order_le_less)
   705   apply (blast elim!: less_SucE
   706                intro!: add_0_right [symmetric] add_Suc_right [symmetric])
   707   done
   708 
   709 text {* strict, in 1st argument; proof is by induction on @{text "k > 0"} *}
   710 lemma mult_less_mono2: "(i::nat) < j ==> 0<k ==> k * i < k * j"
   711 apply(auto simp: gr0_conv_Suc)
   712 apply (induct_tac m)
   713 apply (simp_all add: add_less_mono)
   714 done
   715 
   716 text{*The naturals form an ordered @{text comm_semiring_1_cancel}*}
   717 instance nat :: ordered_semidom
   718 proof
   719   fix i j k :: nat
   720   show "0 < (1::nat)" by simp
   721   show "i \<le> j ==> k + i \<le> k + j" by simp
   722   show "i < j ==> 0 < k ==> k * i < k * j" by (simp add: mult_less_mono2)
   723 qed
   724 
   725 lemma nat_mult_1: "(1::nat) * n = n"
   726 by simp
   727 
   728 lemma nat_mult_1_right: "n * (1::nat) = n"
   729 by simp
   730 
   731 
   732 subsubsection {* Additional theorems about @{term "op \<le>"} *}
   733 
   734 text {* Complete induction, aka course-of-values induction *}
   735 
   736 lemma less_induct [case_names less]:
   737   fixes P :: "nat \<Rightarrow> bool"
   738   assumes step: "\<And>x. (\<And>y. y < x \<Longrightarrow> P y) \<Longrightarrow> P x"
   739   shows "P a"
   740 proof - 
   741   have "\<And>z. z\<le>a \<Longrightarrow> P z"
   742   proof (induct a)
   743     case (0 z)
   744     have "P 0" by (rule step) auto
   745     thus ?case using 0 by auto
   746   next
   747     case (Suc x z)
   748     then have "z \<le> x \<or> z = Suc x" by (simp add: le_Suc_eq)
   749     thus ?case
   750     proof
   751       assume "z \<le> x" thus "P z" by (rule Suc(1))
   752     next
   753       assume z: "z = Suc x"
   754       show "P z"
   755         by (rule step) (rule Suc(1), simp add: z le_simps)
   756     qed
   757   qed
   758   thus ?thesis by auto
   759 qed
   760 
   761 lemma nat_less_induct:
   762   assumes "!!n. \<forall>m::nat. m < n --> P m ==> P n" shows "P n"
   763   using assms less_induct by blast
   764 
   765 lemma measure_induct_rule [case_names less]:
   766   fixes f :: "'a \<Rightarrow> nat"
   767   assumes step: "\<And>x. (\<And>y. f y < f x \<Longrightarrow> P y) \<Longrightarrow> P x"
   768   shows "P a"
   769 by (induct m\<equiv>"f a" arbitrary: a rule: less_induct) (auto intro: step)
   770 
   771 text {* old style induction rules: *}
   772 lemma measure_induct:
   773   fixes f :: "'a \<Rightarrow> nat"
   774   shows "(\<And>x. \<forall>y. f y < f x \<longrightarrow> P y \<Longrightarrow> P x) \<Longrightarrow> P a"
   775   by (rule measure_induct_rule [of f P a]) iprover
   776 
   777 lemma full_nat_induct:
   778   assumes step: "(!!n. (ALL m. Suc m <= n --> P m) ==> P n)"
   779   shows "P n"
   780   by (rule less_induct) (auto intro: step simp:le_simps)
   781 
   782 text{*An induction rule for estabilishing binary relations*}
   783 lemma less_Suc_induct:
   784   assumes less:  "i < j"
   785      and  step:  "!!i. P i (Suc i)"
   786      and  trans: "!!i j k. P i j ==> P j k ==> P i k"
   787   shows "P i j"
   788 proof -
   789   from less obtain k where j: "j = Suc(i+k)" by (auto dest: less_imp_Suc_add)
   790   have "P i (Suc (i + k))"
   791   proof (induct k)
   792     case 0
   793     show ?case by (simp add: step)
   794   next
   795     case (Suc k)
   796     thus ?case by (auto intro: assms)
   797   qed
   798   thus "P i j" by (simp add: j)
   799 qed
   800 
   801 lemma nat_induct2: "[|P 0; P (Suc 0); !!k. P k ==> P (Suc (Suc k))|] ==> P n"
   802   apply (rule nat_less_induct)
   803   apply (case_tac n)
   804   apply (case_tac [2] nat)
   805   apply (blast intro: less_trans)+
   806   done
   807 
   808 text {* The method of infinite descent, frequently used in number theory.
   809 Provided by Roelof Oosterhuis.
   810 $P(n)$ is true for all $n\in\mathbb{N}$ if
   811 \begin{itemize}
   812   \item case ``0'': given $n=0$ prove $P(n)$,
   813   \item case ``smaller'': given $n>0$ and $\neg P(n)$ prove there exists
   814         a smaller integer $m$ such that $\neg P(m)$.
   815 \end{itemize} *}
   816 
   817 text{* A compact version without explicit base case: *}
   818 lemma infinite_descent:
   819   "\<lbrakk> !!n::nat. \<not> P n \<Longrightarrow>  \<exists>m<n. \<not>  P m \<rbrakk> \<Longrightarrow>  P n"
   820 by (induct n rule: less_induct, auto)
   821 
   822 lemma infinite_descent0[case_names 0 smaller]: 
   823   "\<lbrakk> P 0; !!n. n>0 \<Longrightarrow> \<not> P n \<Longrightarrow> (\<exists>m::nat. m < n \<and> \<not>P m) \<rbrakk> \<Longrightarrow> P n"
   824 by (rule infinite_descent) (case_tac "n>0", auto)
   825 
   826 text {*
   827 Infinite descent using a mapping to $\mathbb{N}$:
   828 $P(x)$ is true for all $x\in D$ if there exists a $V: D \to \mathbb{N}$ and
   829 \begin{itemize}
   830 \item case ``0'': given $V(x)=0$ prove $P(x)$,
   831 \item case ``smaller'': given $V(x)>0$ and $\neg P(x)$ prove there exists a $y \in D$ such that $V(y)<V(x)$ and $~\neg P(y)$.
   832 \end{itemize}
   833 NB: the proof also shows how to use the previous lemma. *}
   834 
   835 corollary infinite_descent0_measure [case_names 0 smaller]:
   836   assumes A0: "!!x. V x = (0::nat) \<Longrightarrow> P x"
   837     and   A1: "!!x. V x > 0 \<Longrightarrow> \<not>P x \<Longrightarrow> (\<exists>y. V y < V x \<and> \<not>P y)"
   838   shows "P x"
   839 proof -
   840   obtain n where "n = V x" by auto
   841   moreover have "\<And>x. V x = n \<Longrightarrow> P x"
   842   proof (induct n rule: infinite_descent0)
   843     case 0 -- "i.e. $V(x) = 0$"
   844     with A0 show "P x" by auto
   845   next -- "now $n>0$ and $P(x)$ does not hold for some $x$ with $V(x)=n$"
   846     case (smaller n)
   847     then obtain x where vxn: "V x = n " and "V x > 0 \<and> \<not> P x" by auto
   848     with A1 obtain y where "V y < V x \<and> \<not> P y" by auto
   849     with vxn obtain m where "m = V y \<and> m<n \<and> \<not> P y" by auto
   850     then show ?case by auto
   851   qed
   852   ultimately show "P x" by auto
   853 qed
   854 
   855 text{* Again, without explicit base case: *}
   856 lemma infinite_descent_measure:
   857 assumes "!!x. \<not> P x \<Longrightarrow> \<exists>y. (V::'a\<Rightarrow>nat) y < V x \<and> \<not> P y" shows "P x"
   858 proof -
   859   from assms obtain n where "n = V x" by auto
   860   moreover have "!!x. V x = n \<Longrightarrow> P x"
   861   proof (induct n rule: infinite_descent, auto)
   862     fix x assume "\<not> P x"
   863     with assms show "\<exists>m < V x. \<exists>y. V y = m \<and> \<not> P y" by auto
   864   qed
   865   ultimately show "P x" by auto
   866 qed
   867 
   868 text {* A [clumsy] way of lifting @{text "<"}
   869   monotonicity to @{text "\<le>"} monotonicity *}
   870 lemma less_mono_imp_le_mono:
   871   "\<lbrakk> !!i j::nat. i < j \<Longrightarrow> f i < f j; i \<le> j \<rbrakk> \<Longrightarrow> f i \<le> ((f j)::nat)"
   872 by (simp add: order_le_less) (blast)
   873 
   874 
   875 text {* non-strict, in 1st argument *}
   876 lemma add_le_mono1: "i \<le> j ==> i + k \<le> j + (k::nat)"
   877 by (rule add_right_mono)
   878 
   879 text {* non-strict, in both arguments *}
   880 lemma add_le_mono: "[| i \<le> j;  k \<le> l |] ==> i + k \<le> j + (l::nat)"
   881 by (rule add_mono)
   882 
   883 lemma le_add2: "n \<le> ((m + n)::nat)"
   884 by (insert add_right_mono [of 0 m n], simp)
   885 
   886 lemma le_add1: "n \<le> ((n + m)::nat)"
   887 by (simp add: add_commute, rule le_add2)
   888 
   889 lemma less_add_Suc1: "i < Suc (i + m)"
   890 by (rule le_less_trans, rule le_add1, rule lessI)
   891 
   892 lemma less_add_Suc2: "i < Suc (m + i)"
   893 by (rule le_less_trans, rule le_add2, rule lessI)
   894 
   895 lemma less_iff_Suc_add: "(m < n) = (\<exists>k. n = Suc (m + k))"
   896 by (iprover intro!: less_add_Suc1 less_imp_Suc_add)
   897 
   898 lemma trans_le_add1: "(i::nat) \<le> j ==> i \<le> j + m"
   899 by (rule le_trans, assumption, rule le_add1)
   900 
   901 lemma trans_le_add2: "(i::nat) \<le> j ==> i \<le> m + j"
   902 by (rule le_trans, assumption, rule le_add2)
   903 
   904 lemma trans_less_add1: "(i::nat) < j ==> i < j + m"
   905 by (rule less_le_trans, assumption, rule le_add1)
   906 
   907 lemma trans_less_add2: "(i::nat) < j ==> i < m + j"
   908 by (rule less_le_trans, assumption, rule le_add2)
   909 
   910 lemma add_lessD1: "i + j < (k::nat) ==> i < k"
   911 apply (rule le_less_trans [of _ "i+j"])
   912 apply (simp_all add: le_add1)
   913 done
   914 
   915 lemma not_add_less1 [iff]: "~ (i + j < (i::nat))"
   916 apply (rule notI)
   917 apply (drule add_lessD1)
   918 apply (erule less_irrefl [THEN notE])
   919 done
   920 
   921 lemma not_add_less2 [iff]: "~ (j + i < (i::nat))"
   922 by (simp add: add_commute)
   923 
   924 lemma add_leD1: "m + k \<le> n ==> m \<le> (n::nat)"
   925 apply (rule order_trans [of _ "m+k"])
   926 apply (simp_all add: le_add1)
   927 done
   928 
   929 lemma add_leD2: "m + k \<le> n ==> k \<le> (n::nat)"
   930 apply (simp add: add_commute)
   931 apply (erule add_leD1)
   932 done
   933 
   934 lemma add_leE: "(m::nat) + k \<le> n ==> (m \<le> n ==> k \<le> n ==> R) ==> R"
   935 by (blast dest: add_leD1 add_leD2)
   936 
   937 text {* needs @{text "!!k"} for @{text add_ac} to work *}
   938 lemma less_add_eq_less: "!!k::nat. k < l ==> m + l = k + n ==> m < n"
   939 by (force simp del: add_Suc_right
   940     simp add: less_iff_Suc_add add_Suc_right [symmetric] add_ac)
   941 
   942 
   943 subsubsection {* More results about difference *}
   944 
   945 text {* Addition is the inverse of subtraction:
   946   if @{term "n \<le> m"} then @{term "n + (m - n) = m"}. *}
   947 lemma add_diff_inverse: "~  m < n ==> n + (m - n) = (m::nat)"
   948 by (induct m n rule: diff_induct) simp_all
   949 
   950 lemma le_add_diff_inverse [simp]: "n \<le> m ==> n + (m - n) = (m::nat)"
   951 by (simp add: add_diff_inverse linorder_not_less)
   952 
   953 lemma le_add_diff_inverse2 [simp]: "n \<le> m ==> (m - n) + n = (m::nat)"
   954 by (simp add: add_commute)
   955 
   956 lemma Suc_diff_le: "n \<le> m ==> Suc m - n = Suc (m - n)"
   957 by (induct m n rule: diff_induct) simp_all
   958 
   959 lemma diff_less_Suc: "m - n < Suc m"
   960 apply (induct m n rule: diff_induct)
   961 apply (erule_tac [3] less_SucE)
   962 apply (simp_all add: less_Suc_eq)
   963 done
   964 
   965 lemma diff_le_self [simp]: "m - n \<le> (m::nat)"
   966 by (induct m n rule: diff_induct) (simp_all add: le_SucI)
   967 
   968 lemma le_iff_add: "(m::nat) \<le> n = (\<exists>k. n = m + k)"
   969   by (auto simp: le_add1 dest!: le_add_diff_inverse sym [of _ n])
   970 
   971 lemma less_imp_diff_less: "(j::nat) < k ==> j - n < k"
   972 by (rule le_less_trans, rule diff_le_self)
   973 
   974 lemma diff_Suc_less [simp]: "0<n ==> n - Suc i < n"
   975 by (cases n) (auto simp add: le_simps)
   976 
   977 lemma diff_add_assoc: "k \<le> (j::nat) ==> (i + j) - k = i + (j - k)"
   978 by (induct j k rule: diff_induct) simp_all
   979 
   980 lemma diff_add_assoc2: "k \<le> (j::nat) ==> (j + i) - k = (j - k) + i"
   981 by (simp add: add_commute diff_add_assoc)
   982 
   983 lemma le_imp_diff_is_add: "i \<le> (j::nat) ==> (j - i = k) = (j = k + i)"
   984 by (auto simp add: diff_add_inverse2)
   985 
   986 lemma diff_is_0_eq [simp]: "((m::nat) - n = 0) = (m \<le> n)"
   987 by (induct m n rule: diff_induct) simp_all
   988 
   989 lemma diff_is_0_eq' [simp]: "m \<le> n ==> (m::nat) - n = 0"
   990 by (rule iffD2, rule diff_is_0_eq)
   991 
   992 lemma zero_less_diff [simp]: "(0 < n - (m::nat)) = (m < n)"
   993 by (induct m n rule: diff_induct) simp_all
   994 
   995 lemma less_imp_add_positive:
   996   assumes "i < j"
   997   shows "\<exists>k::nat. 0 < k & i + k = j"
   998 proof
   999   from assms show "0 < j - i & i + (j - i) = j"
  1000     by (simp add: order_less_imp_le)
  1001 qed
  1002 
  1003 text {* a nice rewrite for bounded subtraction *}
  1004 lemma nat_minus_add_max:
  1005   fixes n m :: nat
  1006   shows "n - m + m = max n m"
  1007     by (simp add: max_def not_le order_less_imp_le)
  1008 
  1009 lemma nat_diff_split:
  1010   "P(a - b::nat) = ((a<b --> P 0) & (ALL d. a = b + d --> P d))"
  1011     -- {* elimination of @{text -} on @{text nat} *}
  1012 by (cases "a < b")
  1013   (auto simp add: diff_is_0_eq [THEN iffD2] diff_add_inverse
  1014     not_less le_less dest!: sym [of a] sym [of b] add_eq_self_zero)
  1015 
  1016 lemma nat_diff_split_asm:
  1017   "P(a - b::nat) = (~ (a < b & ~ P 0 | (EX d. a = b + d & ~ P d)))"
  1018     -- {* elimination of @{text -} on @{text nat} in assumptions *}
  1019 by (auto split: nat_diff_split)
  1020 
  1021 
  1022 subsubsection {* Monotonicity of Multiplication *}
  1023 
  1024 lemma mult_le_mono1: "i \<le> (j::nat) ==> i * k \<le> j * k"
  1025 by (simp add: mult_right_mono)
  1026 
  1027 lemma mult_le_mono2: "i \<le> (j::nat) ==> k * i \<le> k * j"
  1028 by (simp add: mult_left_mono)
  1029 
  1030 text {* @{text "\<le>"} monotonicity, BOTH arguments *}
  1031 lemma mult_le_mono: "i \<le> (j::nat) ==> k \<le> l ==> i * k \<le> j * l"
  1032 by (simp add: mult_mono)
  1033 
  1034 lemma mult_less_mono1: "(i::nat) < j ==> 0 < k ==> i * k < j * k"
  1035 by (simp add: mult_strict_right_mono)
  1036 
  1037 text{*Differs from the standard @{text zero_less_mult_iff} in that
  1038       there are no negative numbers.*}
  1039 lemma nat_0_less_mult_iff [simp]: "(0 < (m::nat) * n) = (0 < m & 0 < n)"
  1040   apply (induct m)
  1041    apply simp
  1042   apply (case_tac n)
  1043    apply simp_all
  1044   done
  1045 
  1046 lemma one_le_mult_iff [simp]: "(Suc 0 \<le> m * n) = (1 \<le> m & 1 \<le> n)"
  1047   apply (induct m)
  1048    apply simp
  1049   apply (case_tac n)
  1050    apply simp_all
  1051   done
  1052 
  1053 lemma mult_less_cancel2 [simp]: "((m::nat) * k < n * k) = (0 < k & m < n)"
  1054   apply (safe intro!: mult_less_mono1)
  1055   apply (case_tac k, auto)
  1056   apply (simp del: le_0_eq add: linorder_not_le [symmetric])
  1057   apply (blast intro: mult_le_mono1)
  1058   done
  1059 
  1060 lemma mult_less_cancel1 [simp]: "(k * (m::nat) < k * n) = (0 < k & m < n)"
  1061 by (simp add: mult_commute [of k])
  1062 
  1063 lemma mult_le_cancel1 [simp]: "(k * (m::nat) \<le> k * n) = (0 < k --> m \<le> n)"
  1064 by (simp add: linorder_not_less [symmetric], auto)
  1065 
  1066 lemma mult_le_cancel2 [simp]: "((m::nat) * k \<le> n * k) = (0 < k --> m \<le> n)"
  1067 by (simp add: linorder_not_less [symmetric], auto)
  1068 
  1069 lemma Suc_mult_less_cancel1: "(Suc k * m < Suc k * n) = (m < n)"
  1070 by (subst mult_less_cancel1) simp
  1071 
  1072 lemma Suc_mult_le_cancel1: "(Suc k * m \<le> Suc k * n) = (m \<le> n)"
  1073 by (subst mult_le_cancel1) simp
  1074 
  1075 lemma le_square: "m \<le> m * (m::nat)"
  1076   by (cases m) (auto intro: le_add1)
  1077 
  1078 lemma le_cube: "(m::nat) \<le> m * (m * m)"
  1079   by (cases m) (auto intro: le_add1)
  1080 
  1081 text {* Lemma for @{text gcd} *}
  1082 lemma mult_eq_self_implies_10: "(m::nat) = m * n ==> n = 1 | m = 0"
  1083   apply (drule sym)
  1084   apply (rule disjCI)
  1085   apply (rule nat_less_cases, erule_tac [2] _)
  1086    apply (drule_tac [2] mult_less_mono2)
  1087     apply (auto)
  1088   done
  1089 
  1090 text {* the lattice order on @{typ nat} *}
  1091 
  1092 instantiation nat :: distrib_lattice
  1093 begin
  1094 
  1095 definition
  1096   "(inf \<Colon> nat \<Rightarrow> nat \<Rightarrow> nat) = min"
  1097 
  1098 definition
  1099   "(sup \<Colon> nat \<Rightarrow> nat \<Rightarrow> nat) = max"
  1100 
  1101 instance by intro_classes
  1102   (auto simp add: inf_nat_def sup_nat_def max_def not_le min_def
  1103     intro: order_less_imp_le antisym elim!: order_trans order_less_trans)
  1104 
  1105 end
  1106 
  1107 
  1108 subsection {* Embedding of the Naturals into any
  1109   @{text semiring_1}: @{term of_nat} *}
  1110 
  1111 context semiring_1
  1112 begin
  1113 
  1114 primrec
  1115   of_nat :: "nat \<Rightarrow> 'a"
  1116 where
  1117   of_nat_0:     "of_nat 0 = 0"
  1118   | of_nat_Suc: "of_nat (Suc m) = 1 + of_nat m"
  1119 
  1120 lemma of_nat_1 [simp]: "of_nat 1 = 1"
  1121   by simp
  1122 
  1123 lemma of_nat_add [simp]: "of_nat (m + n) = of_nat m + of_nat n"
  1124   by (induct m) (simp_all add: add_ac)
  1125 
  1126 lemma of_nat_mult: "of_nat (m * n) = of_nat m * of_nat n"
  1127   by (induct m) (simp_all add: add_ac left_distrib)
  1128 
  1129 definition
  1130   of_nat_aux :: "nat \<Rightarrow> 'a \<Rightarrow> 'a"
  1131 where
  1132   [code func del]: "of_nat_aux n i = of_nat n + i"
  1133 
  1134 lemma of_nat_aux_code [code]:
  1135   "of_nat_aux 0 i = i"
  1136   "of_nat_aux (Suc n) i = of_nat_aux n (i + 1)" -- {* tail recursive *}
  1137   by (simp_all add: of_nat_aux_def add_ac)
  1138 
  1139 lemma of_nat_code [code]:
  1140   "of_nat n = of_nat_aux n 0"
  1141   by (simp add: of_nat_aux_def)
  1142 
  1143 end
  1144 
  1145 text{*Class for unital semirings with characteristic zero.
  1146  Includes non-ordered rings like the complex numbers.*}
  1147 
  1148 class semiring_char_0 = semiring_1 +
  1149   assumes of_nat_eq_iff [simp]: "of_nat m = of_nat n \<longleftrightarrow> m = n"
  1150 begin
  1151 
  1152 text{*Special cases where either operand is zero*}
  1153 
  1154 lemma of_nat_0_eq_iff [simp, noatp]: "0 = of_nat n \<longleftrightarrow> 0 = n"
  1155   by (rule of_nat_eq_iff [of 0, simplified])
  1156 
  1157 lemma of_nat_eq_0_iff [simp, noatp]: "of_nat m = 0 \<longleftrightarrow> m = 0"
  1158   by (rule of_nat_eq_iff [of _ 0, simplified])
  1159 
  1160 lemma inj_of_nat: "inj of_nat"
  1161   by (simp add: inj_on_def)
  1162 
  1163 end
  1164 
  1165 context ordered_semidom
  1166 begin
  1167 
  1168 lemma zero_le_imp_of_nat: "0 \<le> of_nat m"
  1169   apply (induct m, simp_all)
  1170   apply (erule order_trans)
  1171   apply (rule ord_le_eq_trans [OF _ add_commute])
  1172   apply (rule less_add_one [THEN less_imp_le])
  1173   done
  1174 
  1175 lemma less_imp_of_nat_less: "m < n \<Longrightarrow> of_nat m < of_nat n"
  1176   apply (induct m n rule: diff_induct, simp_all)
  1177   apply (insert add_less_le_mono [OF zero_less_one zero_le_imp_of_nat], force)
  1178   done
  1179 
  1180 lemma of_nat_less_imp_less: "of_nat m < of_nat n \<Longrightarrow> m < n"
  1181   apply (induct m n rule: diff_induct, simp_all)
  1182   apply (insert zero_le_imp_of_nat)
  1183   apply (force simp add: not_less [symmetric])
  1184   done
  1185 
  1186 lemma of_nat_less_iff [simp]: "of_nat m < of_nat n \<longleftrightarrow> m < n"
  1187   by (blast intro: of_nat_less_imp_less less_imp_of_nat_less)
  1188 
  1189 lemma of_nat_le_iff [simp]: "of_nat m \<le> of_nat n \<longleftrightarrow> m \<le> n"
  1190   by (simp add: not_less [symmetric] linorder_not_less [symmetric])
  1191 
  1192 text{*Every @{text ordered_semidom} has characteristic zero.*}
  1193 
  1194 subclass semiring_char_0
  1195   by unfold_locales (simp add: eq_iff order_eq_iff)
  1196 
  1197 text{*Special cases where either operand is zero*}
  1198 
  1199 lemma of_nat_0_le_iff [simp]: "0 \<le> of_nat n"
  1200   by (rule of_nat_le_iff [of 0, simplified])
  1201 
  1202 lemma of_nat_le_0_iff [simp, noatp]: "of_nat m \<le> 0 \<longleftrightarrow> m = 0"
  1203   by (rule of_nat_le_iff [of _ 0, simplified])
  1204 
  1205 lemma of_nat_0_less_iff [simp]: "0 < of_nat n \<longleftrightarrow> 0 < n"
  1206   by (rule of_nat_less_iff [of 0, simplified])
  1207 
  1208 lemma of_nat_less_0_iff [simp]: "\<not> of_nat m < 0"
  1209   by (rule of_nat_less_iff [of _ 0, simplified])
  1210 
  1211 end
  1212 
  1213 context ring_1
  1214 begin
  1215 
  1216 lemma of_nat_diff: "n \<le> m \<Longrightarrow> of_nat (m - n) = of_nat m - of_nat n"
  1217   by (simp add: compare_rls of_nat_add [symmetric])
  1218 
  1219 end
  1220 
  1221 context ordered_idom
  1222 begin
  1223 
  1224 lemma abs_of_nat [simp]: "\<bar>of_nat n\<bar> = of_nat n"
  1225   unfolding abs_if by auto
  1226 
  1227 end
  1228 
  1229 lemma of_nat_id [simp]: "of_nat n = n"
  1230   by (induct n) auto
  1231 
  1232 lemma of_nat_eq_id [simp]: "of_nat = id"
  1233   by (auto simp add: expand_fun_eq)
  1234 
  1235 
  1236 subsection {* The Set of Natural Numbers *}
  1237 
  1238 context semiring_1
  1239 begin
  1240 
  1241 definition
  1242   Nats  :: "'a set" where
  1243   [code func del]: "Nats = range of_nat"
  1244 
  1245 notation (xsymbols)
  1246   Nats  ("\<nat>")
  1247 
  1248 lemma of_nat_in_Nats [simp]: "of_nat n \<in> \<nat>"
  1249   by (simp add: Nats_def)
  1250 
  1251 lemma Nats_0 [simp]: "0 \<in> \<nat>"
  1252 apply (simp add: Nats_def)
  1253 apply (rule range_eqI)
  1254 apply (rule of_nat_0 [symmetric])
  1255 done
  1256 
  1257 lemma Nats_1 [simp]: "1 \<in> \<nat>"
  1258 apply (simp add: Nats_def)
  1259 apply (rule range_eqI)
  1260 apply (rule of_nat_1 [symmetric])
  1261 done
  1262 
  1263 lemma Nats_add [simp]: "a \<in> \<nat> \<Longrightarrow> b \<in> \<nat> \<Longrightarrow> a + b \<in> \<nat>"
  1264 apply (auto simp add: Nats_def)
  1265 apply (rule range_eqI)
  1266 apply (rule of_nat_add [symmetric])
  1267 done
  1268 
  1269 lemma Nats_mult [simp]: "a \<in> \<nat> \<Longrightarrow> b \<in> \<nat> \<Longrightarrow> a * b \<in> \<nat>"
  1270 apply (auto simp add: Nats_def)
  1271 apply (rule range_eqI)
  1272 apply (rule of_nat_mult [symmetric])
  1273 done
  1274 
  1275 end
  1276 
  1277 
  1278 subsection {* Further Arithmetic Facts Concerning the Natural Numbers *}
  1279 
  1280 lemma subst_equals:
  1281   assumes 1: "t = s" and 2: "u = t"
  1282   shows "u = s"
  1283   using 2 1 by (rule trans)
  1284 
  1285 use "arith_data.ML"
  1286 declaration {* K ArithData.setup *}
  1287 
  1288 use "Tools/lin_arith.ML"
  1289 declaration {* K LinArith.setup *}
  1290 
  1291 lemmas [arith_split] = nat_diff_split split_min split_max
  1292 
  1293 
  1294 context order
  1295 begin
  1296 
  1297 lemma lift_Suc_mono_le:
  1298   assumes mono: "!!n. f n \<le> f(Suc n)" and "n\<le>n'"
  1299   shows "f n \<le> f n'"
  1300 proof (cases "n < n'")
  1301   case True
  1302   thus ?thesis
  1303     by (induct n n' rule: less_Suc_induct[consumes 1]) (auto intro: mono)
  1304 qed (insert `n \<le> n'`, auto) -- {*trivial for @{prop "n = n'"} *}
  1305 
  1306 lemma lift_Suc_mono_less:
  1307   assumes mono: "!!n. f n < f(Suc n)" and "n < n'"
  1308   shows "f n < f n'"
  1309 using `n < n'`
  1310 by (induct n n' rule: less_Suc_induct[consumes 1]) (auto intro: mono)
  1311 
  1312 lemma lift_Suc_mono_less_iff:
  1313   "(!!n. f n < f(Suc n)) \<Longrightarrow> f(n) < f(m) \<longleftrightarrow> n<m"
  1314 by(blast intro: less_asym' lift_Suc_mono_less[of f]
  1315          dest: linorder_not_less[THEN iffD1] le_eq_less_or_eq[THEN iffD1])
  1316 
  1317 end
  1318 
  1319 
  1320 lemma mono_nat_linear_lb:
  1321   "(!!m n::nat. m<n \<Longrightarrow> f m < f n) \<Longrightarrow> f(m)+k \<le> f(m+k)"
  1322 apply(induct_tac k)
  1323  apply simp
  1324 apply(erule_tac x="m+n" in meta_allE)
  1325 apply(erule_tac x="m+n+1" in meta_allE)
  1326 apply simp
  1327 done
  1328 
  1329 
  1330 text{*Subtraction laws, mostly by Clemens Ballarin*}
  1331 
  1332 lemma diff_less_mono: "[| a < (b::nat); c \<le> a |] ==> a-c < b-c"
  1333 by arith
  1334 
  1335 lemma less_diff_conv: "(i < j-k) = (i+k < (j::nat))"
  1336 by arith
  1337 
  1338 lemma le_diff_conv: "(j-k \<le> (i::nat)) = (j \<le> i+k)"
  1339 by arith
  1340 
  1341 lemma le_diff_conv2: "k \<le> j ==> (i \<le> j-k) = (i+k \<le> (j::nat))"
  1342 by arith
  1343 
  1344 lemma diff_diff_cancel [simp]: "i \<le> (n::nat) ==> n - (n - i) = i"
  1345 by arith
  1346 
  1347 lemma le_add_diff: "k \<le> (n::nat) ==> m \<le> n + m - k"
  1348 by arith
  1349 
  1350 (*Replaces the previous diff_less and le_diff_less, which had the stronger
  1351   second premise n\<le>m*)
  1352 lemma diff_less[simp]: "!!m::nat. [| 0<n; 0<m |] ==> m - n < m"
  1353 by arith
  1354 
  1355 text {* Simplification of relational expressions involving subtraction *}
  1356 
  1357 lemma diff_diff_eq: "[| k \<le> m;  k \<le> (n::nat) |] ==> ((m-k) - (n-k)) = (m-n)"
  1358 by (simp split add: nat_diff_split)
  1359 
  1360 lemma eq_diff_iff: "[| k \<le> m;  k \<le> (n::nat) |] ==> (m-k = n-k) = (m=n)"
  1361 by (auto split add: nat_diff_split)
  1362 
  1363 lemma less_diff_iff: "[| k \<le> m;  k \<le> (n::nat) |] ==> (m-k < n-k) = (m<n)"
  1364 by (auto split add: nat_diff_split)
  1365 
  1366 lemma le_diff_iff: "[| k \<le> m;  k \<le> (n::nat) |] ==> (m-k \<le> n-k) = (m\<le>n)"
  1367 by (auto split add: nat_diff_split)
  1368 
  1369 text{*(Anti)Monotonicity of subtraction -- by Stephan Merz*}
  1370 
  1371 (* Monotonicity of subtraction in first argument *)
  1372 lemma diff_le_mono: "m \<le> (n::nat) ==> (m-l) \<le> (n-l)"
  1373 by (simp split add: nat_diff_split)
  1374 
  1375 lemma diff_le_mono2: "m \<le> (n::nat) ==> (l-n) \<le> (l-m)"
  1376 by (simp split add: nat_diff_split)
  1377 
  1378 lemma diff_less_mono2: "[| m < (n::nat); m<l |] ==> (l-n) < (l-m)"
  1379 by (simp split add: nat_diff_split)
  1380 
  1381 lemma diffs0_imp_equal: "!!m::nat. [| m-n = 0; n-m = 0 |] ==>  m=n"
  1382 by (simp split add: nat_diff_split)
  1383 
  1384 lemma min_diff: "min (m - (i::nat)) (n - i) = min m n - i"
  1385 unfolding min_def by auto
  1386 
  1387 lemma inj_on_diff_nat: 
  1388   assumes k_le_n: "\<forall>n \<in> N. k \<le> (n::nat)"
  1389   shows "inj_on (\<lambda>n. n - k) N"
  1390 proof (rule inj_onI)
  1391   fix x y
  1392   assume a: "x \<in> N" "y \<in> N" "x - k = y - k"
  1393   with k_le_n have "x - k + k = y - k + k" by auto
  1394   with a k_le_n show "x = y" by auto
  1395 qed
  1396 
  1397 text{*Rewriting to pull differences out*}
  1398 
  1399 lemma diff_diff_right [simp]: "k\<le>j --> i - (j - k) = i + (k::nat) - j"
  1400 by arith
  1401 
  1402 lemma diff_Suc_diff_eq1 [simp]: "k \<le> j ==> m - Suc (j - k) = m + k - Suc j"
  1403 by arith
  1404 
  1405 lemma diff_Suc_diff_eq2 [simp]: "k \<le> j ==> Suc (j - k) - m = Suc j - (k + m)"
  1406 by arith
  1407 
  1408 text{*Lemmas for ex/Factorization*}
  1409 
  1410 lemma one_less_mult: "[| Suc 0 < n; Suc 0 < m |] ==> Suc 0 < m*n"
  1411 by (cases m) auto
  1412 
  1413 lemma n_less_m_mult_n: "[| Suc 0 < n; Suc 0 < m |] ==> n<m*n"
  1414 by (cases m) auto
  1415 
  1416 lemma n_less_n_mult_m: "[| Suc 0 < n; Suc 0 < m |] ==> n<n*m"
  1417 by (cases m) auto
  1418 
  1419 text {* Specialized induction principles that work "backwards": *}
  1420 
  1421 lemma inc_induct[consumes 1, case_names base step]:
  1422   assumes less: "i <= j"
  1423   assumes base: "P j"
  1424   assumes step: "!!i. [| i < j; P (Suc i) |] ==> P i"
  1425   shows "P i"
  1426   using less
  1427 proof (induct d=="j - i" arbitrary: i)
  1428   case (0 i)
  1429   hence "i = j" by simp
  1430   with base show ?case by simp
  1431 next
  1432   case (Suc d i)
  1433   hence "i < j" "P (Suc i)"
  1434     by simp_all
  1435   thus "P i" by (rule step)
  1436 qed
  1437 
  1438 lemma strict_inc_induct[consumes 1, case_names base step]:
  1439   assumes less: "i < j"
  1440   assumes base: "!!i. j = Suc i ==> P i"
  1441   assumes step: "!!i. [| i < j; P (Suc i) |] ==> P i"
  1442   shows "P i"
  1443   using less
  1444 proof (induct d=="j - i - 1" arbitrary: i)
  1445   case (0 i)
  1446   with `i < j` have "j = Suc i" by simp
  1447   with base show ?case by simp
  1448 next
  1449   case (Suc d i)
  1450   hence "i < j" "P (Suc i)"
  1451     by simp_all
  1452   thus "P i" by (rule step)
  1453 qed
  1454 
  1455 lemma zero_induct_lemma: "P k ==> (!!n. P (Suc n) ==> P n) ==> P (k - i)"
  1456   using inc_induct[of "k - i" k P, simplified] by blast
  1457 
  1458 lemma zero_induct: "P k ==> (!!n. P (Suc n) ==> P n) ==> P 0"
  1459   using inc_induct[of 0 k P] by blast
  1460 
  1461 lemma nat_not_singleton: "(\<forall>x. x = (0::nat)) = False"
  1462   by auto
  1463 
  1464 (*The others are
  1465       i - j - k = i - (j + k),
  1466       k \<le> j ==> j - k + i = j + i - k,
  1467       k \<le> j ==> i + (j - k) = i + j - k *)
  1468 lemmas add_diff_assoc = diff_add_assoc [symmetric]
  1469 lemmas add_diff_assoc2 = diff_add_assoc2[symmetric]
  1470 declare diff_diff_left [simp]  add_diff_assoc [simp] add_diff_assoc2[simp]
  1471 
  1472 text{*At present we prove no analogue of @{text not_less_Least} or @{text
  1473 Least_Suc}, since there appears to be no need.*}
  1474 
  1475 
  1476 subsection {* size of a datatype value *}
  1477 
  1478 class size = type +
  1479   fixes size :: "'a \<Rightarrow> nat" -- {* see further theory @{text Wellfounded} *}
  1480 
  1481 end