src/Pure/ML-Systems/compiler_polyml-5.2.ML
author wenzelm
Sun May 31 14:51:21 2009 +0200 (2009-05-31)
changeset 31312 1c00e4ff3c99
child 31480 05937d6aafb5
permissions -rw-r--r--
more modular setup of runtime compilation;
     1 (*  Title:      Pure/ML-Systems/compiler_polyml-5.2.ML
     2 
     3 Runtime compilation for Poly/ML 5.2 and 5.2.1.
     4 *)
     5 
     6 local
     7 
     8 fun drop_newline s =
     9   if String.isSuffix "\n" s then String.substring (s, 0, size s - 1)
    10   else s;
    11 
    12 in
    13 
    14 fun use_text ({tune_source, name_space, str_of_pos, print, error, ...}: use_context)
    15     (start_line, name) verbose txt =
    16   let
    17     val current_line = ref start_line;
    18     val in_buffer = ref (String.explode (tune_source txt));
    19     val out_buffer = ref ([]: string list);
    20     fun output () = drop_newline (implode (rev (! out_buffer)));
    21 
    22     fun get () =
    23       (case ! in_buffer of
    24         [] => NONE
    25       | c :: cs =>
    26           (in_buffer := cs; if c = #"\n" then current_line := ! current_line + 1 else (); SOME c));
    27     fun put s = out_buffer := s :: ! out_buffer;
    28     fun message (msg, is_err, line) =
    29       (if is_err then "Error: " else "Warning: ") ^ drop_newline msg ^ str_of_pos line name ^ "\n";
    30 
    31     val parameters =
    32      [PolyML.Compiler.CPOutStream put,
    33       PolyML.Compiler.CPLineNo (fn () => ! current_line),
    34       PolyML.Compiler.CPErrorMessageProc (put o message),
    35       PolyML.Compiler.CPNameSpace name_space];
    36     val _ =
    37       (while not (List.null (! in_buffer)) do
    38         PolyML.compiler (get, parameters) ())
    39       handle exn =>
    40        (put ("Exception- " ^ General.exnMessage exn ^ " raised");
    41         error (output ()); raise exn);
    42   in if verbose then print (output ()) else () end;
    43 
    44 fun use_file context verbose name =
    45   let
    46     val instream = TextIO.openIn name;
    47     val txt = Exn.release (Exn.capture TextIO.inputAll instream before TextIO.closeIn instream);
    48   in use_text context (1, name) verbose txt end;
    49 
    50 end;
    51