src/HOL/NanoJava/OpSem.thy
author berghofe
Wed Jul 11 11:28:13 2007 +0200 (2007-07-11)
changeset 23755 1c4672d130b1
parent 16417 9bc16273c2d4
child 32960 69916a850301
permissions -rw-r--r--
Adapted to new inductive definition package.
     1 (*  Title:      HOL/NanoJava/OpSem.thy
     2     ID:         $Id$
     3     Author:     David von Oheimb
     4     Copyright   2001 Technische Universitaet Muenchen
     5 *)
     6 
     7 header "Operational Evaluation Semantics"
     8 
     9 theory OpSem imports State begin
    10 
    11 inductive
    12   exec :: "[state,stmt,    nat,state] => bool" ("_ -_-_\<rightarrow> _"  [98,90,   65,98] 89)
    13   and eval :: "[state,expr,val,nat,state] => bool" ("_ -_\<succ>_-_\<rightarrow> _"[98,95,99,65,98] 89)
    14 where
    15   Skip: "   s -Skip-n\<rightarrow> s"
    16 
    17 | Comp: "[| s0 -c1-n\<rightarrow> s1; s1 -c2-n\<rightarrow> s2 |] ==>
    18             s0 -c1;; c2-n\<rightarrow> s2"
    19 
    20 | Cond: "[| s0 -e\<succ>v-n\<rightarrow> s1; s1 -(if v\<noteq>Null then c1 else c2)-n\<rightarrow> s2 |] ==>
    21             s0 -If(e) c1 Else c2-n\<rightarrow> s2"
    22 
    23 | LoopF:"   s0<x> = Null ==>
    24             s0 -While(x) c-n\<rightarrow> s0"
    25 | LoopT:"[| s0<x> \<noteq> Null; s0 -c-n\<rightarrow> s1; s1 -While(x) c-n\<rightarrow> s2 |] ==>
    26             s0 -While(x) c-n\<rightarrow> s2"
    27 
    28 | LAcc: "   s -LAcc x\<succ>s<x>-n\<rightarrow> s"
    29 
    30 | LAss: "   s -e\<succ>v-n\<rightarrow> s' ==>
    31             s -x:==e-n\<rightarrow> lupd(x\<mapsto>v) s'"
    32 
    33 | FAcc: "   s -e\<succ>Addr a-n\<rightarrow> s' ==>
    34             s -e..f\<succ>get_field s' a f-n\<rightarrow> s'"
    35 
    36 | FAss: "[| s0 -e1\<succ>Addr a-n\<rightarrow> s1;  s1 -e2\<succ>v-n\<rightarrow> s2 |] ==>
    37             s0 -e1..f:==e2-n\<rightarrow> upd_obj a f v s2"
    38 
    39 | NewC: "   new_Addr s = Addr a ==>
    40             s -new C\<succ>Addr a-n\<rightarrow> new_obj a C s"
    41 
    42 | Cast: "[| s -e\<succ>v-n\<rightarrow> s';
    43             case v of Null => True | Addr a => obj_class s' a \<preceq>C C |] ==>
    44             s -Cast C e\<succ>v-n\<rightarrow> s'"
    45 
    46 | Call: "[| s0 -e1\<succ>a-n\<rightarrow> s1; s1 -e2\<succ>p-n\<rightarrow> s2; 
    47             lupd(This\<mapsto>a)(lupd(Par\<mapsto>p)(del_locs s2)) -Meth (C,m)-n\<rightarrow> s3
    48      |] ==> s0 -{C}e1..m(e2)\<succ>s3<Res>-n\<rightarrow> set_locs s2 s3"
    49 
    50 | Meth: "[| s<This> = Addr a; D = obj_class s a; D\<preceq>C C;
    51             init_locs D m s -Impl (D,m)-n\<rightarrow> s' |] ==>
    52             s -Meth (C,m)-n\<rightarrow> s'"
    53 
    54 | Impl: "   s -body Cm-    n\<rightarrow> s' ==>
    55             s -Impl Cm-Suc n\<rightarrow> s'"
    56 
    57 
    58 inductive_cases exec_elim_cases':
    59 				  "s -Skip            -n\<rightarrow> t"
    60 				  "s -c1;; c2         -n\<rightarrow> t"
    61 				  "s -If(e) c1 Else c2-n\<rightarrow> t"
    62 				  "s -While(x) c      -n\<rightarrow> t"
    63 				  "s -x:==e           -n\<rightarrow> t"
    64 				  "s -e1..f:==e2      -n\<rightarrow> t"
    65 inductive_cases Meth_elim_cases:  "s -Meth Cm         -n\<rightarrow> t"
    66 inductive_cases Impl_elim_cases:  "s -Impl Cm         -n\<rightarrow> t"
    67 lemmas exec_elim_cases = exec_elim_cases' Meth_elim_cases Impl_elim_cases
    68 inductive_cases eval_elim_cases:
    69 				  "s -new C         \<succ>v-n\<rightarrow> t"
    70 				  "s -Cast C e      \<succ>v-n\<rightarrow> t"
    71 				  "s -LAcc x        \<succ>v-n\<rightarrow> t"
    72 				  "s -e..f          \<succ>v-n\<rightarrow> t"
    73 				  "s -{C}e1..m(e2)  \<succ>v-n\<rightarrow> t"
    74 
    75 lemma exec_eval_mono [rule_format]: 
    76   "(s -c  -n\<rightarrow> t \<longrightarrow> (\<forall>m. n \<le> m \<longrightarrow> s -c  -m\<rightarrow> t)) \<and>
    77    (s -e\<succ>v-n\<rightarrow> t \<longrightarrow> (\<forall>m. n \<le> m \<longrightarrow> s -e\<succ>v-m\<rightarrow> t))"
    78 apply (rule exec_eval.induct)
    79 prefer 14 (* Impl *)
    80 apply clarify
    81 apply (rename_tac n)
    82 apply (case_tac n)
    83 apply (blast intro:exec_eval.intros)+
    84 done
    85 lemmas exec_mono = exec_eval_mono [THEN conjunct1, rule_format]
    86 lemmas eval_mono = exec_eval_mono [THEN conjunct2, rule_format]
    87 
    88 lemma exec_exec_max: "\<lbrakk>s1 -c1-    n1   \<rightarrow> t1 ; s2 -c2-       n2\<rightarrow> t2\<rbrakk> \<Longrightarrow> 
    89                        s1 -c1-max n1 n2\<rightarrow> t1 \<and> s2 -c2-max n1 n2\<rightarrow> t2"
    90 by (fast intro: exec_mono le_maxI1 le_maxI2)
    91 
    92 lemma eval_exec_max: "\<lbrakk>s1 -c-    n1   \<rightarrow> t1 ; s2 -e\<succ>v-       n2\<rightarrow> t2\<rbrakk> \<Longrightarrow> 
    93                        s1 -c-max n1 n2\<rightarrow> t1 \<and> s2 -e\<succ>v-max n1 n2\<rightarrow> t2"
    94 by (fast intro: eval_mono exec_mono le_maxI1 le_maxI2)
    95 
    96 lemma eval_eval_max: "\<lbrakk>s1 -e1\<succ>v1-    n1   \<rightarrow> t1 ; s2 -e2\<succ>v2-       n2\<rightarrow> t2\<rbrakk> \<Longrightarrow> 
    97                        s1 -e1\<succ>v1-max n1 n2\<rightarrow> t1 \<and> s2 -e2\<succ>v2-max n1 n2\<rightarrow> t2"
    98 by (fast intro: eval_mono le_maxI1 le_maxI2)
    99 
   100 lemma eval_eval_exec_max: 
   101  "\<lbrakk>s1 -e1\<succ>v1-n1\<rightarrow> t1; s2 -e2\<succ>v2-n2\<rightarrow> t2; s3 -c-n3\<rightarrow> t3\<rbrakk> \<Longrightarrow> 
   102    s1 -e1\<succ>v1-max (max n1 n2) n3\<rightarrow> t1 \<and> 
   103    s2 -e2\<succ>v2-max (max n1 n2) n3\<rightarrow> t2 \<and> 
   104    s3 -c    -max (max n1 n2) n3\<rightarrow> t3"
   105 apply (drule (1) eval_eval_max, erule thin_rl)
   106 by (fast intro: exec_mono eval_mono le_maxI1 le_maxI2)
   107 
   108 lemma Impl_body_eq: "(\<lambda>t. \<exists>n. Z -Impl M-n\<rightarrow> t) = (\<lambda>t. \<exists>n. Z -body M-n\<rightarrow> t)"
   109 apply (rule ext)
   110 apply (fast elim: exec_elim_cases intro: exec_eval.Impl)
   111 done
   112 
   113 end