src/Pure/PIDE/command.ML
author wenzelm
Mon Mar 10 21:15:29 2014 +0100 (2014-03-10)
changeset 56034 1c59b555ac4a
parent 55798 985bd3a325ab
child 56265 785569927666
permissions -rw-r--r--
some Markup.language_path to prevent completion of symbols (notably "~") -- always "delimited" for simplicity in contrast to 42ac3cfb89f6;
     1 (*  Title:      Pure/PIDE/command.ML
     2     Author:     Makarius
     3 
     4 Prover command execution: read -- eval -- print.
     5 *)
     6 
     7 signature COMMAND =
     8 sig
     9   type blob = (string * (SHA1.digest * string list) option) Exn.result
    10   val read_file: Path.T -> Position.T -> Path.T -> Token.file
    11   val read: (unit -> theory) -> Path.T -> blob list -> Token.T list -> Toplevel.transition
    12   type eval
    13   val eval_eq: eval * eval -> bool
    14   val eval_running: eval -> bool
    15   val eval_finished: eval -> bool
    16   val eval_result_state: eval -> Toplevel.state
    17   val eval: (unit -> theory) -> Path.T -> blob list -> Token.T list -> eval -> eval
    18   type print
    19   val print: bool -> (string * string list) list -> string ->
    20     eval -> print list -> print list option
    21   type print_fn = Toplevel.transition -> Toplevel.state -> unit
    22   type print_function =
    23     {command_name: string, args: string list} ->
    24       {delay: Time.time option, pri: int, persistent: bool, strict: bool, print_fn: print_fn} option
    25   val print_function: string -> print_function -> unit
    26   val no_print_function: string -> unit
    27   type exec = eval * print list
    28   val no_exec: exec
    29   val exec_ids: exec option -> Document_ID.exec list
    30   val exec: Document_ID.execution -> exec -> unit
    31 end;
    32 
    33 structure Command: COMMAND =
    34 struct
    35 
    36 (** memo results **)
    37 
    38 datatype 'a expr =
    39   Expr of Document_ID.exec * (unit -> 'a) |
    40   Result of 'a Exn.result;
    41 
    42 abstype 'a memo = Memo of 'a expr Synchronized.var
    43 with
    44 
    45 fun memo exec_id e = Memo (Synchronized.var "Command.memo" (Expr (exec_id, e)));
    46 fun memo_value a = Memo (Synchronized.var "Command.memo" (Result (Exn.Res a)));
    47 
    48 fun memo_result (Memo v) =
    49   (case Synchronized.value v of
    50     Expr (exec_id, _) => error ("Unfinished execution result: " ^ Document_ID.print exec_id)
    51   | Result res => Exn.release res);
    52 
    53 fun memo_finished (Memo v) =
    54   (case Synchronized.value v of Expr _ => false | Result _ => true);
    55 
    56 fun memo_exec execution_id (Memo v) =
    57   Synchronized.timed_access v (K (SOME Time.zeroTime))
    58     (fn expr =>
    59       (case expr of
    60         Expr (exec_id, body) =>
    61           uninterruptible (fn restore_attributes => fn () =>
    62             let val group = Future.worker_subgroup () in
    63               if Execution.running execution_id exec_id [group] then
    64                 let
    65                   val res =
    66                     (body
    67                       |> restore_attributes
    68                       |> Future.task_context "Command.memo_exec" group
    69                       |> Exn.interruptible_capture) ();
    70                 in SOME ((), Result res) end
    71               else SOME ((), expr)
    72             end) ()
    73       | Result _ => SOME ((), expr)))
    74   |> (fn NONE => error "Conflicting command execution" | _ => ());
    75 
    76 fun memo_fork params execution_id (Memo v) =
    77   (case Synchronized.value v of
    78     Result _ => ()
    79   | _ => ignore ((singleton o Future.forks) params (fn () => memo_exec execution_id (Memo v))));
    80 
    81 end;
    82 
    83 
    84 
    85 (** main phases of execution **)
    86 
    87 (* read *)
    88 
    89 type blob =
    90   (string * (SHA1.digest * string list) option) Exn.result;  (*file node name, digest, lines*)
    91 
    92 fun read_file master_dir pos src_path =
    93   let
    94     val _ = Position.report pos Markup.language_path;
    95     val full_path = File.check_file (File.full_path master_dir src_path);
    96     val _ = Position.report pos (Markup.path (Path.implode full_path));
    97     val text = File.read full_path;
    98     val lines = split_lines text;
    99     val digest = SHA1.digest text;
   100   in {src_path = src_path, lines = lines, digest = digest, pos = Path.position full_path} end;
   101 
   102 local
   103 
   104 fun blob_file src_path lines digest file =
   105   let
   106     val file_pos =
   107       Position.file file (*sic!*) |>
   108       (case Position.get_id (Position.thread_data ()) of
   109         NONE => I
   110       | SOME exec_id => Position.put_id exec_id);
   111   in {src_path = src_path, lines = lines, digest = digest, pos = file_pos} end
   112 
   113 fun resolve_files master_dir blobs toks =
   114   (case Thy_Syntax.parse_spans toks of
   115     [span] => span
   116       |> Thy_Syntax.resolve_files (fn cmd => fn (path, pos) =>
   117         let
   118           fun make_file src_path (Exn.Res (_, NONE)) =
   119                 Exn.interruptible_capture (fn () => read_file master_dir pos src_path) ()
   120             | make_file src_path (Exn.Res (file, SOME (digest, lines))) =
   121                (Position.reports [(pos, Markup.language_path), (pos, Markup.path file)];
   122                 Exn.Res (blob_file src_path lines digest file))
   123             | make_file _ (Exn.Exn e) = Exn.Exn e;
   124           val src_paths = Keyword.command_files cmd path;
   125         in
   126           if null blobs then
   127             map2 make_file src_paths (map (K (Exn.Res ("", NONE))) src_paths)
   128           else if length src_paths = length blobs then
   129             map2 make_file src_paths blobs
   130           else error ("Misalignment of inlined files" ^ Position.here pos)
   131         end)
   132       |> Thy_Syntax.span_content
   133   | _ => toks);
   134 
   135 in
   136 
   137 fun read init master_dir blobs span =
   138   let
   139     val outer_syntax = #2 (Outer_Syntax.get_syntax ());
   140     val command_reports = Outer_Syntax.command_reports outer_syntax;
   141 
   142     val proper_range = Token.range_of (#1 (take_suffix Token.is_improper span));
   143     val pos =
   144       (case find_first Token.is_command span of
   145         SOME tok => Token.pos_of tok
   146       | NONE => #1 proper_range);
   147 
   148     val (is_malformed, token_reports) = Thy_Syntax.reports_of_tokens span;
   149     val _ = Position.reports_text (token_reports @ maps command_reports span);
   150   in
   151     if is_malformed then Toplevel.malformed pos "Malformed command syntax"
   152     else
   153       (case Outer_Syntax.read_spans outer_syntax (resolve_files master_dir blobs span) of
   154         [tr] =>
   155           if Keyword.is_control (Toplevel.name_of tr) then
   156             Toplevel.malformed pos "Illegal control command"
   157           else Toplevel.modify_init init tr
   158       | [] => Toplevel.ignored (#1 (Token.range_of span))
   159       | _ => Toplevel.malformed (#1 proper_range) "Exactly one command expected")
   160       handle ERROR msg => Toplevel.malformed (#1 proper_range) msg
   161   end;
   162 
   163 end;
   164 
   165 
   166 (* eval *)
   167 
   168 type eval_state =
   169   {failed: bool, malformed: bool, command: Toplevel.transition, state: Toplevel.state};
   170 val init_eval_state =
   171   {failed = false, malformed = false, command = Toplevel.empty, state = Toplevel.toplevel};
   172 
   173 datatype eval = Eval of {exec_id: Document_ID.exec, eval_process: eval_state memo};
   174 
   175 fun eval_eq (Eval {exec_id, ...}, Eval {exec_id = exec_id', ...}) = exec_id = exec_id';
   176 
   177 fun eval_running (Eval {exec_id, ...}) = Execution.is_running_exec exec_id;
   178 fun eval_finished (Eval {eval_process, ...}) = memo_finished eval_process;
   179 
   180 fun eval_result (Eval {eval_process, ...}) = memo_result eval_process;
   181 val eval_result_state = #state o eval_result;
   182 
   183 local
   184 
   185 fun run int tr st =
   186   if Goal.future_enabled 1 andalso Keyword.is_diag (Toplevel.name_of tr) then
   187     (Execution.fork {name = "Toplevel.diag", pos = Toplevel.pos_of tr, pri = ~1}
   188       (fn () => Toplevel.command_exception int tr st); ([], SOME st))
   189   else Toplevel.command_errors int tr st;
   190 
   191 fun check_cmts span tr st' =
   192   Toplevel.setmp_thread_position tr
   193     (fn () =>
   194       Outer_Syntax.side_comments span |> maps (fn cmt =>
   195         (Thy_Output.check_text (Token.source_position_of cmt) st'; [])
   196           handle exn =>
   197             if Exn.is_interrupt exn then reraise exn
   198             else ML_Compiler.exn_messages_ids exn)) ();
   199 
   200 fun report tr m =
   201   Toplevel.setmp_thread_position tr (fn () => Output.report (Markup.markup_only m)) ();
   202 
   203 fun status tr m =
   204   Toplevel.setmp_thread_position tr (fn () => Output.status (Markup.markup_only m)) ();
   205 
   206 fun proof_status tr st =
   207   (case try Toplevel.proof_of st of
   208     SOME prf => status tr (Proof.status_markup prf)
   209   | NONE => ());
   210 
   211 fun eval_state span tr ({malformed, state = st, ...}: eval_state) =
   212   if malformed then
   213     {failed = true, malformed = malformed, command = tr, state = Toplevel.toplevel}
   214   else
   215     let
   216       val malformed' = Toplevel.is_malformed tr;
   217       val is_init = Toplevel.is_init tr;
   218       val is_proof = Keyword.is_proof (Toplevel.name_of tr);
   219 
   220       val _ = Multithreading.interrupted ();
   221       val _ = status tr Markup.running;
   222       val (errs1, result) = run (is_init orelse is_proof) (Toplevel.set_print false tr) st;
   223       val errs2 = (case result of NONE => [] | SOME st' => check_cmts span tr st');
   224       val errs = errs1 @ errs2;
   225       val _ = List.app (Future.error_msg (Toplevel.pos_of tr)) errs;
   226     in
   227       (case result of
   228         NONE =>
   229           let
   230             val _ = status tr Markup.failed;
   231             val _ = status tr Markup.finished;
   232             val _ = if null errs then (report tr Markup.bad; Exn.interrupt ()) else ();
   233           in {failed = true, malformed = malformed', command = tr, state = st} end
   234       | SOME st' =>
   235           let
   236             val _ = proof_status tr st';
   237             val _ = status tr Markup.finished;
   238           in {failed = false, malformed = malformed', command = tr, state = st'} end)
   239     end;
   240 
   241 in
   242 
   243 fun eval init master_dir blobs span eval0 =
   244   let
   245     val exec_id = Document_ID.make ();
   246     fun process () =
   247       let
   248         val tr =
   249           Position.setmp_thread_data (Position.id_only (Document_ID.print exec_id))
   250             (fn () => read init master_dir blobs span |> Toplevel.exec_id exec_id) ();
   251       in eval_state span tr (eval_result eval0) end;
   252   in Eval {exec_id = exec_id, eval_process = memo exec_id process} end;
   253 
   254 end;
   255 
   256 
   257 (* print *)
   258 
   259 datatype print = Print of
   260  {name: string, args: string list, delay: Time.time option, pri: int, persistent: bool,
   261   exec_id: Document_ID.exec, print_process: unit memo};
   262 
   263 type print_fn = Toplevel.transition -> Toplevel.state -> unit;
   264 
   265 type print_function =
   266   {command_name: string, args: string list} ->
   267     {delay: Time.time option, pri: int, persistent: bool, strict: bool, print_fn: print_fn} option;
   268 
   269 local
   270 
   271 val print_functions =
   272   Synchronized.var "Command.print_functions" ([]: (string * print_function) list);
   273 
   274 fun print_error tr e =
   275   (Toplevel.setmp_thread_position tr o Toplevel.controlled_execution) e ()
   276     handle exn =>
   277       if Exn.is_interrupt exn then reraise exn
   278       else List.app (Future.error_msg (Toplevel.pos_of tr)) (ML_Compiler.exn_messages_ids exn);
   279 
   280 fun print_eq (Print {exec_id, ...}, Print {exec_id = exec_id', ...}) = exec_id = exec_id';
   281 
   282 fun print_finished (Print {print_process, ...}) = memo_finished print_process;
   283 
   284 fun print_persistent (Print {persistent, ...}) = persistent;
   285 
   286 val overlay_ord = prod_ord string_ord (list_ord string_ord);
   287 
   288 in
   289 
   290 fun print command_visible command_overlays command_name eval old_prints =
   291   let
   292     val print_functions = Synchronized.value print_functions;
   293 
   294     fun make_print name args {delay, pri, persistent, strict, print_fn} =
   295       let
   296         val exec_id = Document_ID.make ();
   297         fun process () =
   298           let
   299             val {failed, command, state = st', ...} = eval_result eval;
   300             val tr = Toplevel.exec_id exec_id command;
   301           in
   302             if failed andalso strict then ()
   303             else print_error tr (fn () => print_fn tr st')
   304           end;
   305       in
   306         Print {
   307           name = name, args = args, delay = delay, pri = pri, persistent = persistent,
   308           exec_id = exec_id, print_process = memo exec_id process}
   309       end;
   310 
   311     fun bad_print name args exn =
   312       make_print name args {delay = NONE, pri = 0, persistent = false,
   313         strict = false, print_fn = fn _ => fn _ => reraise exn};
   314 
   315     fun new_print name args get_pr =
   316       let
   317         val params = {command_name = command_name, args = args};
   318       in
   319         (case Exn.capture (Toplevel.controlled_execution get_pr) params of
   320           Exn.Res NONE => NONE
   321         | Exn.Res (SOME pr) => SOME (make_print name args pr)
   322         | Exn.Exn exn => SOME (bad_print name args exn))
   323       end;
   324 
   325     fun get_print (a, b) =
   326       (case find_first (fn Print {name, args, ...} => name = a andalso args = b) old_prints of
   327         NONE =>
   328           (case AList.lookup (op =) print_functions a of
   329             NONE => SOME (bad_print a b (ERROR ("Missing print function " ^ quote a)))
   330           | SOME get_pr => new_print a b get_pr)
   331       | some => some);
   332 
   333     val new_prints =
   334       if command_visible then
   335         fold (fn (a, _) => cons (a, [])) print_functions command_overlays
   336         |> sort_distinct overlay_ord
   337         |> map_filter get_print
   338       else filter (fn print => print_finished print andalso print_persistent print) old_prints;
   339   in
   340     if eq_list print_eq (old_prints, new_prints) then NONE else SOME new_prints
   341   end;
   342 
   343 fun print_function name f =
   344   Synchronized.change print_functions (fn funs =>
   345    (if not (AList.defined (op =) funs name) then ()
   346     else warning ("Redefining command print function: " ^ quote name);
   347     AList.update (op =) (name, f) funs));
   348 
   349 fun no_print_function name =
   350   Synchronized.change print_functions (filter_out (equal name o #1));
   351 
   352 end;
   353 
   354 val _ =
   355   print_function "print_state"
   356     (fn {command_name, ...} =>
   357       SOME {delay = NONE, pri = 1, persistent = false, strict = true,
   358         print_fn = fn tr => fn st' =>
   359           let
   360             val is_init = Keyword.is_theory_begin command_name;
   361             val is_proof = Keyword.is_proof command_name;
   362             val do_print =
   363               not is_init andalso
   364                 (Toplevel.print_of tr orelse (is_proof andalso Toplevel.is_proof st'));
   365           in if do_print then Toplevel.print_state false st' else () end});
   366 
   367 
   368 (* combined execution *)
   369 
   370 type exec = eval * print list;
   371 val no_exec: exec =
   372   (Eval {exec_id = Document_ID.none, eval_process = memo_value init_eval_state}, []);
   373 
   374 fun exec_ids NONE = []
   375   | exec_ids (SOME (Eval {exec_id, ...}, prints)) =
   376       exec_id :: map (fn Print {exec_id, ...} => exec_id) prints;
   377 
   378 local
   379 
   380 fun run_print execution_id (Print {name, delay, pri, print_process, ...}) =
   381   if Multithreading.enabled () orelse pri <= 0 then
   382     let
   383       val group = Future.worker_subgroup ();
   384       fun fork () =
   385         memo_fork {name = name, group = SOME group, deps = [], pri = pri, interrupts = true}
   386           execution_id print_process;
   387     in
   388       (case delay of
   389         NONE => fork ()
   390       | SOME d => ignore (Event_Timer.request (Time.+ (Time.now (), d)) fork))
   391     end
   392   else memo_exec execution_id print_process;
   393 
   394 in
   395 
   396 fun exec execution_id (Eval {eval_process, ...}, prints) =
   397   (memo_exec execution_id eval_process; List.app (run_print execution_id) prints);
   398 
   399 end;
   400 
   401 end;
   402