src/HOL/Probability/Probability_Mass_Function.thy
author hoelzl
Thu Apr 14 15:48:11 2016 +0200 (2016-04-14)
changeset 62975 1d066f6ab25d
parent 62390 842917225d56
child 63040 eb4ddd18d635
permissions -rw-r--r--
Probability: move emeasure and nn_integral from ereal to ennreal
     1 (*  Title:      HOL/Probability/Probability_Mass_Function.thy
     2     Author:     Johannes Hölzl, TU München
     3     Author:     Andreas Lochbihler, ETH Zurich
     4 *)
     5 
     6 section \<open> Probability mass function \<close>
     7 
     8 theory Probability_Mass_Function
     9 imports
    10   Giry_Monad
    11   "~~/src/HOL/Library/Multiset"
    12 begin
    13 
    14 lemma AE_emeasure_singleton:
    15   assumes x: "emeasure M {x} \<noteq> 0" and ae: "AE x in M. P x" shows "P x"
    16 proof -
    17   from x have x_M: "{x} \<in> sets M"
    18     by (auto intro: emeasure_notin_sets)
    19   from ae obtain N where N: "{x\<in>space M. \<not> P x} \<subseteq> N" "emeasure M N = 0" "N \<in> sets M"
    20     by (auto elim: AE_E)
    21   { assume "\<not> P x"
    22     with x_M[THEN sets.sets_into_space] N have "emeasure M {x} \<le> emeasure M N"
    23       by (intro emeasure_mono) auto
    24     with x N have False
    25       by (auto simp:) }
    26   then show "P x" by auto
    27 qed
    28 
    29 lemma AE_measure_singleton: "measure M {x} \<noteq> 0 \<Longrightarrow> AE x in M. P x \<Longrightarrow> P x"
    30   by (metis AE_emeasure_singleton measure_def emeasure_empty measure_empty)
    31 
    32 lemma (in finite_measure) AE_support_countable:
    33   assumes [simp]: "sets M = UNIV"
    34   shows "(AE x in M. measure M {x} \<noteq> 0) \<longleftrightarrow> (\<exists>S. countable S \<and> (AE x in M. x \<in> S))"
    35 proof
    36   assume "\<exists>S. countable S \<and> (AE x in M. x \<in> S)"
    37   then obtain S where S[intro]: "countable S" and ae: "AE x in M. x \<in> S"
    38     by auto
    39   then have "emeasure M (\<Union>x\<in>{x\<in>S. emeasure M {x} \<noteq> 0}. {x}) =
    40     (\<integral>\<^sup>+ x. emeasure M {x} * indicator {x\<in>S. emeasure M {x} \<noteq> 0} x \<partial>count_space UNIV)"
    41     by (subst emeasure_UN_countable)
    42        (auto simp: disjoint_family_on_def nn_integral_restrict_space[symmetric] restrict_count_space)
    43   also have "\<dots> = (\<integral>\<^sup>+ x. emeasure M {x} * indicator S x \<partial>count_space UNIV)"
    44     by (auto intro!: nn_integral_cong split: split_indicator)
    45   also have "\<dots> = emeasure M (\<Union>x\<in>S. {x})"
    46     by (subst emeasure_UN_countable)
    47        (auto simp: disjoint_family_on_def nn_integral_restrict_space[symmetric] restrict_count_space)
    48   also have "\<dots> = emeasure M (space M)"
    49     using ae by (intro emeasure_eq_AE) auto
    50   finally have "emeasure M {x \<in> space M. x\<in>S \<and> emeasure M {x} \<noteq> 0} = emeasure M (space M)"
    51     by (simp add: emeasure_single_in_space cong: rev_conj_cong)
    52   with finite_measure_compl[of "{x \<in> space M. x\<in>S \<and> emeasure M {x} \<noteq> 0}"]
    53   have "AE x in M. x \<in> S \<and> emeasure M {x} \<noteq> 0"
    54     by (intro AE_I[OF order_refl]) (auto simp: emeasure_eq_measure measure_nonneg set_diff_eq cong: conj_cong)
    55   then show "AE x in M. measure M {x} \<noteq> 0"
    56     by (auto simp: emeasure_eq_measure)
    57 qed (auto intro!: exI[of _ "{x. measure M {x} \<noteq> 0}"] countable_support)
    58 
    59 subsection \<open> PMF as measure \<close>
    60 
    61 typedef 'a pmf = "{M :: 'a measure. prob_space M \<and> sets M = UNIV \<and> (AE x in M. measure M {x} \<noteq> 0)}"
    62   morphisms measure_pmf Abs_pmf
    63   by (intro exI[of _ "uniform_measure (count_space UNIV) {undefined}"])
    64      (auto intro!: prob_space_uniform_measure AE_uniform_measureI)
    65 
    66 declare [[coercion measure_pmf]]
    67 
    68 lemma prob_space_measure_pmf: "prob_space (measure_pmf p)"
    69   using pmf.measure_pmf[of p] by auto
    70 
    71 interpretation measure_pmf: prob_space "measure_pmf M" for M
    72   by (rule prob_space_measure_pmf)
    73 
    74 interpretation measure_pmf: subprob_space "measure_pmf M" for M
    75   by (rule prob_space_imp_subprob_space) unfold_locales
    76 
    77 lemma subprob_space_measure_pmf: "subprob_space (measure_pmf x)"
    78   by unfold_locales
    79 
    80 locale pmf_as_measure
    81 begin
    82 
    83 setup_lifting type_definition_pmf
    84 
    85 end
    86 
    87 context
    88 begin
    89 
    90 interpretation pmf_as_measure .
    91 
    92 lemma sets_measure_pmf[simp]: "sets (measure_pmf p) = UNIV"
    93   by transfer blast
    94 
    95 lemma sets_measure_pmf_count_space[measurable_cong]:
    96   "sets (measure_pmf M) = sets (count_space UNIV)"
    97   by simp
    98 
    99 lemma space_measure_pmf[simp]: "space (measure_pmf p) = UNIV"
   100   using sets_eq_imp_space_eq[of "measure_pmf p" "count_space UNIV"] by simp
   101 
   102 lemma measure_pmf_UNIV [simp]: "measure (measure_pmf p) UNIV = 1"
   103 using measure_pmf.prob_space[of p] by simp
   104 
   105 lemma measure_pmf_in_subprob_algebra[measurable (raw)]: "measure_pmf x \<in> space (subprob_algebra (count_space UNIV))"
   106   by (simp add: space_subprob_algebra subprob_space_measure_pmf)
   107 
   108 lemma measurable_pmf_measure1[simp]: "measurable (M :: 'a pmf) N = UNIV \<rightarrow> space N"
   109   by (auto simp: measurable_def)
   110 
   111 lemma measurable_pmf_measure2[simp]: "measurable N (M :: 'a pmf) = measurable N (count_space UNIV)"
   112   by (intro measurable_cong_sets) simp_all
   113 
   114 lemma measurable_pair_restrict_pmf2:
   115   assumes "countable A"
   116   assumes [measurable]: "\<And>y. y \<in> A \<Longrightarrow> (\<lambda>x. f (x, y)) \<in> measurable M L"
   117   shows "f \<in> measurable (M \<Otimes>\<^sub>M restrict_space (measure_pmf N) A) L" (is "f \<in> measurable ?M _")
   118 proof -
   119   have [measurable_cong]: "sets (restrict_space (count_space UNIV) A) = sets (count_space A)"
   120     by (simp add: restrict_count_space)
   121 
   122   show ?thesis
   123     by (intro measurable_compose_countable'[where f="\<lambda>a b. f (fst b, a)" and g=snd and I=A,
   124                                             unfolded prod.collapse] assms)
   125         measurable
   126 qed
   127 
   128 lemma measurable_pair_restrict_pmf1:
   129   assumes "countable A"
   130   assumes [measurable]: "\<And>x. x \<in> A \<Longrightarrow> (\<lambda>y. f (x, y)) \<in> measurable N L"
   131   shows "f \<in> measurable (restrict_space (measure_pmf M) A \<Otimes>\<^sub>M N) L"
   132 proof -
   133   have [measurable_cong]: "sets (restrict_space (count_space UNIV) A) = sets (count_space A)"
   134     by (simp add: restrict_count_space)
   135 
   136   show ?thesis
   137     by (intro measurable_compose_countable'[where f="\<lambda>a b. f (a, snd b)" and g=fst and I=A,
   138                                             unfolded prod.collapse] assms)
   139         measurable
   140 qed
   141 
   142 lift_definition pmf :: "'a pmf \<Rightarrow> 'a \<Rightarrow> real" is "\<lambda>M x. measure M {x}" .
   143 
   144 lift_definition set_pmf :: "'a pmf \<Rightarrow> 'a set" is "\<lambda>M. {x. measure M {x} \<noteq> 0}" .
   145 declare [[coercion set_pmf]]
   146 
   147 lemma AE_measure_pmf: "AE x in (M::'a pmf). x \<in> M"
   148   by transfer simp
   149 
   150 lemma emeasure_pmf_single_eq_zero_iff:
   151   fixes M :: "'a pmf"
   152   shows "emeasure M {y} = 0 \<longleftrightarrow> y \<notin> M"
   153   unfolding set_pmf.rep_eq by (simp add: measure_pmf.emeasure_eq_measure)
   154 
   155 lemma AE_measure_pmf_iff: "(AE x in measure_pmf M. P x) \<longleftrightarrow> (\<forall>y\<in>M. P y)"
   156   using AE_measure_singleton[of M] AE_measure_pmf[of M]
   157   by (auto simp: set_pmf.rep_eq)
   158 
   159 lemma AE_pmfI: "(\<And>y. y \<in> set_pmf M \<Longrightarrow> P y) \<Longrightarrow> almost_everywhere (measure_pmf M) P"
   160 by(simp add: AE_measure_pmf_iff)
   161 
   162 lemma countable_set_pmf [simp]: "countable (set_pmf p)"
   163   by transfer (metis prob_space.finite_measure finite_measure.countable_support)
   164 
   165 lemma pmf_positive: "x \<in> set_pmf p \<Longrightarrow> 0 < pmf p x"
   166   by transfer (simp add: less_le)
   167 
   168 lemma pmf_nonneg[simp]: "0 \<le> pmf p x"
   169   by transfer simp
   170 
   171 lemma pmf_le_1: "pmf p x \<le> 1"
   172   by (simp add: pmf.rep_eq)
   173 
   174 lemma set_pmf_not_empty: "set_pmf M \<noteq> {}"
   175   using AE_measure_pmf[of M] by (intro notI) simp
   176 
   177 lemma set_pmf_iff: "x \<in> set_pmf M \<longleftrightarrow> pmf M x \<noteq> 0"
   178   by transfer simp
   179 
   180 lemma pmf_positive_iff: "0 < pmf p x \<longleftrightarrow> x \<in> set_pmf p"
   181   unfolding less_le by (simp add: set_pmf_iff)
   182 
   183 lemma set_pmf_eq: "set_pmf M = {x. pmf M x \<noteq> 0}"
   184   by (auto simp: set_pmf_iff)
   185 
   186 lemma emeasure_pmf_single:
   187   fixes M :: "'a pmf"
   188   shows "emeasure M {x} = pmf M x"
   189   by transfer (simp add: finite_measure.emeasure_eq_measure[OF prob_space.finite_measure])
   190 
   191 lemma measure_pmf_single: "measure (measure_pmf M) {x} = pmf M x"
   192   using emeasure_pmf_single[of M x] by(simp add: measure_pmf.emeasure_eq_measure pmf_nonneg measure_nonneg)
   193 
   194 lemma emeasure_measure_pmf_finite: "finite S \<Longrightarrow> emeasure (measure_pmf M) S = (\<Sum>s\<in>S. pmf M s)"
   195   by (subst emeasure_eq_setsum_singleton) (auto simp: emeasure_pmf_single pmf_nonneg)
   196 
   197 lemma measure_measure_pmf_finite: "finite S \<Longrightarrow> measure (measure_pmf M) S = setsum (pmf M) S"
   198   using emeasure_measure_pmf_finite[of S M]
   199   by (simp add: measure_pmf.emeasure_eq_measure measure_nonneg setsum_nonneg pmf_nonneg)
   200 
   201 lemma nn_integral_measure_pmf_support:
   202   fixes f :: "'a \<Rightarrow> ennreal"
   203   assumes f: "finite A" and nn: "\<And>x. x \<in> A \<Longrightarrow> 0 \<le> f x" "\<And>x. x \<in> set_pmf M \<Longrightarrow> x \<notin> A \<Longrightarrow> f x = 0"
   204   shows "(\<integral>\<^sup>+x. f x \<partial>measure_pmf M) = (\<Sum>x\<in>A. f x * pmf M x)"
   205 proof -
   206   have "(\<integral>\<^sup>+x. f x \<partial>M) = (\<integral>\<^sup>+x. f x * indicator A x \<partial>M)"
   207     using nn by (intro nn_integral_cong_AE) (auto simp: AE_measure_pmf_iff split: split_indicator)
   208   also have "\<dots> = (\<Sum>x\<in>A. f x * emeasure M {x})"
   209     using assms by (intro nn_integral_indicator_finite) auto
   210   finally show ?thesis
   211     by (simp add: emeasure_measure_pmf_finite)
   212 qed
   213 
   214 lemma nn_integral_measure_pmf_finite:
   215   fixes f :: "'a \<Rightarrow> ennreal"
   216   assumes f: "finite (set_pmf M)" and nn: "\<And>x. x \<in> set_pmf M \<Longrightarrow> 0 \<le> f x"
   217   shows "(\<integral>\<^sup>+x. f x \<partial>measure_pmf M) = (\<Sum>x\<in>set_pmf M. f x * pmf M x)"
   218   using assms by (intro nn_integral_measure_pmf_support) auto
   219 
   220 lemma integrable_measure_pmf_finite:
   221   fixes f :: "'a \<Rightarrow> 'b::{banach, second_countable_topology}"
   222   shows "finite (set_pmf M) \<Longrightarrow> integrable M f"
   223   by (auto intro!: integrableI_bounded simp: nn_integral_measure_pmf_finite ennreal_mult_less_top)
   224 
   225 lemma integral_measure_pmf:
   226   assumes [simp]: "finite A" and "\<And>a. a \<in> set_pmf M \<Longrightarrow> f a \<noteq> 0 \<Longrightarrow> a \<in> A"
   227   shows "(\<integral>x. f x \<partial>measure_pmf M) = (\<Sum>a\<in>A. f a * pmf M a)"
   228 proof -
   229   have "(\<integral>x. f x \<partial>measure_pmf M) = (\<integral>x. f x * indicator A x \<partial>measure_pmf M)"
   230     using assms(2) by (intro integral_cong_AE) (auto split: split_indicator simp: AE_measure_pmf_iff)
   231   also have "\<dots> = (\<Sum>a\<in>A. f a * pmf M a)"
   232     by (subst integral_indicator_finite_real)
   233        (auto simp: measure_def emeasure_measure_pmf_finite pmf_nonneg)
   234   finally show ?thesis .
   235 qed
   236 
   237 lemma integrable_pmf: "integrable (count_space X) (pmf M)"
   238 proof -
   239   have " (\<integral>\<^sup>+ x. pmf M x \<partial>count_space X) = (\<integral>\<^sup>+ x. pmf M x \<partial>count_space (M \<inter> X))"
   240     by (auto simp add: nn_integral_count_space_indicator set_pmf_iff intro!: nn_integral_cong split: split_indicator)
   241   then have "integrable (count_space X) (pmf M) = integrable (count_space (M \<inter> X)) (pmf M)"
   242     by (simp add: integrable_iff_bounded pmf_nonneg)
   243   then show ?thesis
   244     by (simp add: pmf.rep_eq measure_pmf.integrable_measure disjoint_family_on_def)
   245 qed
   246 
   247 lemma integral_pmf: "(\<integral>x. pmf M x \<partial>count_space X) = measure M X"
   248 proof -
   249   have "(\<integral>x. pmf M x \<partial>count_space X) = (\<integral>\<^sup>+x. pmf M x \<partial>count_space X)"
   250     by (simp add: pmf_nonneg integrable_pmf nn_integral_eq_integral)
   251   also have "\<dots> = (\<integral>\<^sup>+x. emeasure M {x} \<partial>count_space (X \<inter> M))"
   252     by (auto intro!: nn_integral_cong_AE split: split_indicator
   253              simp: pmf.rep_eq measure_pmf.emeasure_eq_measure nn_integral_count_space_indicator
   254                    AE_count_space set_pmf_iff)
   255   also have "\<dots> = emeasure M (X \<inter> M)"
   256     by (rule emeasure_countable_singleton[symmetric]) (auto intro: countable_set_pmf)
   257   also have "\<dots> = emeasure M X"
   258     by (auto intro!: emeasure_eq_AE simp: AE_measure_pmf_iff)
   259   finally show ?thesis
   260     by (simp add: measure_pmf.emeasure_eq_measure measure_nonneg integral_nonneg pmf_nonneg)
   261 qed
   262 
   263 lemma integral_pmf_restrict:
   264   "(f::'a \<Rightarrow> 'b::{banach, second_countable_topology}) \<in> borel_measurable (count_space UNIV) \<Longrightarrow>
   265     (\<integral>x. f x \<partial>measure_pmf M) = (\<integral>x. f x \<partial>restrict_space M M)"
   266   by (auto intro!: integral_cong_AE simp add: integral_restrict_space AE_measure_pmf_iff)
   267 
   268 lemma emeasure_pmf: "emeasure (M::'a pmf) M = 1"
   269 proof -
   270   have "emeasure (M::'a pmf) M = emeasure (M::'a pmf) (space M)"
   271     by (intro emeasure_eq_AE) (simp_all add: AE_measure_pmf)
   272   then show ?thesis
   273     using measure_pmf.emeasure_space_1 by simp
   274 qed
   275 
   276 lemma emeasure_pmf_UNIV [simp]: "emeasure (measure_pmf M) UNIV = 1"
   277 using measure_pmf.emeasure_space_1[of M] by simp
   278 
   279 lemma in_null_sets_measure_pmfI:
   280   "A \<inter> set_pmf p = {} \<Longrightarrow> A \<in> null_sets (measure_pmf p)"
   281 using emeasure_eq_0_AE[where ?P="\<lambda>x. x \<in> A" and M="measure_pmf p"]
   282 by(auto simp add: null_sets_def AE_measure_pmf_iff)
   283 
   284 lemma measure_subprob: "measure_pmf M \<in> space (subprob_algebra (count_space UNIV))"
   285   by (simp add: space_subprob_algebra subprob_space_measure_pmf)
   286 
   287 subsection \<open> Monad Interpretation \<close>
   288 
   289 lemma measurable_measure_pmf[measurable]:
   290   "(\<lambda>x. measure_pmf (M x)) \<in> measurable (count_space UNIV) (subprob_algebra (count_space UNIV))"
   291   by (auto simp: space_subprob_algebra intro!: prob_space_imp_subprob_space) unfold_locales
   292 
   293 lemma bind_measure_pmf_cong:
   294   assumes "\<And>x. A x \<in> space (subprob_algebra N)" "\<And>x. B x \<in> space (subprob_algebra N)"
   295   assumes "\<And>i. i \<in> set_pmf x \<Longrightarrow> A i = B i"
   296   shows "bind (measure_pmf x) A = bind (measure_pmf x) B"
   297 proof (rule measure_eqI)
   298   show "sets (measure_pmf x \<bind> A) = sets (measure_pmf x \<bind> B)"
   299     using assms by (subst (1 2) sets_bind) (auto simp: space_subprob_algebra)
   300 next
   301   fix X assume "X \<in> sets (measure_pmf x \<bind> A)"
   302   then have X: "X \<in> sets N"
   303     using assms by (subst (asm) sets_bind) (auto simp: space_subprob_algebra)
   304   show "emeasure (measure_pmf x \<bind> A) X = emeasure (measure_pmf x \<bind> B) X"
   305     using assms
   306     by (subst (1 2) emeasure_bind[where N=N, OF _ _ X])
   307        (auto intro!: nn_integral_cong_AE simp: AE_measure_pmf_iff)
   308 qed
   309 
   310 lift_definition bind_pmf :: "'a pmf \<Rightarrow> ('a \<Rightarrow> 'b pmf ) \<Rightarrow> 'b pmf" is bind
   311 proof (clarify, intro conjI)
   312   fix f :: "'a measure" and g :: "'a \<Rightarrow> 'b measure"
   313   assume "prob_space f"
   314   then interpret f: prob_space f .
   315   assume "sets f = UNIV" and ae_f: "AE x in f. measure f {x} \<noteq> 0"
   316   then have s_f[simp]: "sets f = sets (count_space UNIV)"
   317     by simp
   318   assume g: "\<And>x. prob_space (g x) \<and> sets (g x) = UNIV \<and> (AE y in g x. measure (g x) {y} \<noteq> 0)"
   319   then have g: "\<And>x. prob_space (g x)" and s_g[simp]: "\<And>x. sets (g x) = sets (count_space UNIV)"
   320     and ae_g: "\<And>x. AE y in g x. measure (g x) {y} \<noteq> 0"
   321     by auto
   322 
   323   have [measurable]: "g \<in> measurable f (subprob_algebra (count_space UNIV))"
   324     by (auto simp: measurable_def space_subprob_algebra prob_space_imp_subprob_space g)
   325 
   326   show "prob_space (f \<bind> g)"
   327     using g by (intro f.prob_space_bind[where S="count_space UNIV"]) auto
   328   then interpret fg: prob_space "f \<bind> g" .
   329   show [simp]: "sets (f \<bind> g) = UNIV"
   330     using sets_eq_imp_space_eq[OF s_f]
   331     by (subst sets_bind[where N="count_space UNIV"]) auto
   332   show "AE x in f \<bind> g. measure (f \<bind> g) {x} \<noteq> 0"
   333     apply (simp add: fg.prob_eq_0 AE_bind[where B="count_space UNIV"])
   334     using ae_f
   335     apply eventually_elim
   336     using ae_g
   337     apply eventually_elim
   338     apply (auto dest: AE_measure_singleton)
   339     done
   340 qed
   341 
   342 lemma ennreal_pmf_bind: "pmf (bind_pmf N f) i = (\<integral>\<^sup>+x. pmf (f x) i \<partial>measure_pmf N)"
   343   unfolding pmf.rep_eq bind_pmf.rep_eq
   344   by (auto simp: measure_pmf.measure_bind[where N="count_space UNIV"] measure_subprob measure_nonneg
   345            intro!: nn_integral_eq_integral[symmetric] measure_pmf.integrable_const_bound[where B=1])
   346 
   347 lemma pmf_bind: "pmf (bind_pmf N f) i = (\<integral>x. pmf (f x) i \<partial>measure_pmf N)"
   348   using ennreal_pmf_bind[of N f i]
   349   by (subst (asm) nn_integral_eq_integral)
   350      (auto simp: pmf_nonneg pmf_le_1 pmf_nonneg integral_nonneg
   351            intro!: nn_integral_eq_integral[symmetric] measure_pmf.integrable_const_bound[where B=1])
   352 
   353 lemma bind_pmf_const[simp]: "bind_pmf M (\<lambda>x. c) = c"
   354   by transfer (simp add: bind_const' prob_space_imp_subprob_space)
   355 
   356 lemma set_bind_pmf[simp]: "set_pmf (bind_pmf M N) = (\<Union>M\<in>set_pmf M. set_pmf (N M))"
   357 proof -
   358   have "set_pmf (bind_pmf M N) = {x. ennreal (pmf (bind_pmf M N) x) \<noteq> 0}"
   359     by (simp add: set_pmf_eq pmf_nonneg)
   360   also have "\<dots> = (\<Union>M\<in>set_pmf M. set_pmf (N M))"
   361     unfolding ennreal_pmf_bind
   362     by (subst nn_integral_0_iff_AE) (auto simp: AE_measure_pmf_iff pmf_nonneg set_pmf_eq)
   363   finally show ?thesis .
   364 qed
   365 
   366 lemma bind_pmf_cong:
   367   assumes "p = q"
   368   shows "(\<And>x. x \<in> set_pmf q \<Longrightarrow> f x = g x) \<Longrightarrow> bind_pmf p f = bind_pmf q g"
   369   unfolding \<open>p = q\<close>[symmetric] measure_pmf_inject[symmetric] bind_pmf.rep_eq
   370   by (auto simp: AE_measure_pmf_iff Pi_iff space_subprob_algebra subprob_space_measure_pmf
   371                  sets_bind[where N="count_space UNIV"] emeasure_bind[where N="count_space UNIV"]
   372            intro!: nn_integral_cong_AE measure_eqI)
   373 
   374 lemma bind_pmf_cong_simp:
   375   "p = q \<Longrightarrow> (\<And>x. x \<in> set_pmf q =simp=> f x = g x) \<Longrightarrow> bind_pmf p f = bind_pmf q g"
   376   by (simp add: simp_implies_def cong: bind_pmf_cong)
   377 
   378 lemma measure_pmf_bind: "measure_pmf (bind_pmf M f) = (measure_pmf M \<bind> (\<lambda>x. measure_pmf (f x)))"
   379   by transfer simp
   380 
   381 lemma nn_integral_bind_pmf[simp]: "(\<integral>\<^sup>+x. f x \<partial>bind_pmf M N) = (\<integral>\<^sup>+x. \<integral>\<^sup>+y. f y \<partial>N x \<partial>M)"
   382   using measurable_measure_pmf[of N]
   383   unfolding measure_pmf_bind
   384   apply (intro nn_integral_bind[where B="count_space UNIV"])
   385   apply auto
   386   done
   387 
   388 lemma emeasure_bind_pmf[simp]: "emeasure (bind_pmf M N) X = (\<integral>\<^sup>+x. emeasure (N x) X \<partial>M)"
   389   using measurable_measure_pmf[of N]
   390   unfolding measure_pmf_bind
   391   by (subst emeasure_bind[where N="count_space UNIV"]) auto
   392 
   393 lift_definition return_pmf :: "'a \<Rightarrow> 'a pmf" is "return (count_space UNIV)"
   394   by (auto intro!: prob_space_return simp: AE_return measure_return)
   395 
   396 lemma bind_return_pmf: "bind_pmf (return_pmf x) f = f x"
   397   by transfer
   398      (auto intro!: prob_space_imp_subprob_space bind_return[where N="count_space UNIV"]
   399            simp: space_subprob_algebra)
   400 
   401 lemma set_return_pmf[simp]: "set_pmf (return_pmf x) = {x}"
   402   by transfer (auto simp add: measure_return split: split_indicator)
   403 
   404 lemma bind_return_pmf': "bind_pmf N return_pmf = N"
   405 proof (transfer, clarify)
   406   fix N :: "'a measure" assume "sets N = UNIV" then show "N \<bind> return (count_space UNIV) = N"
   407     by (subst return_sets_cong[where N=N]) (simp_all add: bind_return')
   408 qed
   409 
   410 lemma bind_assoc_pmf: "bind_pmf (bind_pmf A B) C = bind_pmf A (\<lambda>x. bind_pmf (B x) C)"
   411   by transfer
   412      (auto intro!: bind_assoc[where N="count_space UNIV" and R="count_space UNIV"]
   413            simp: measurable_def space_subprob_algebra prob_space_imp_subprob_space)
   414 
   415 definition "map_pmf f M = bind_pmf M (\<lambda>x. return_pmf (f x))"
   416 
   417 lemma map_bind_pmf: "map_pmf f (bind_pmf M g) = bind_pmf M (\<lambda>x. map_pmf f (g x))"
   418   by (simp add: map_pmf_def bind_assoc_pmf)
   419 
   420 lemma bind_map_pmf: "bind_pmf (map_pmf f M) g = bind_pmf M (\<lambda>x. g (f x))"
   421   by (simp add: map_pmf_def bind_assoc_pmf bind_return_pmf)
   422 
   423 lemma map_pmf_transfer[transfer_rule]:
   424   "rel_fun op = (rel_fun cr_pmf cr_pmf) (\<lambda>f M. distr M (count_space UNIV) f) map_pmf"
   425 proof -
   426   have "rel_fun op = (rel_fun pmf_as_measure.cr_pmf pmf_as_measure.cr_pmf)
   427      (\<lambda>f M. M \<bind> (return (count_space UNIV) o f)) map_pmf"
   428     unfolding map_pmf_def[abs_def] comp_def by transfer_prover
   429   then show ?thesis
   430     by (force simp: rel_fun_def cr_pmf_def bind_return_distr)
   431 qed
   432 
   433 lemma map_pmf_rep_eq:
   434   "measure_pmf (map_pmf f M) = distr (measure_pmf M) (count_space UNIV) f"
   435   unfolding map_pmf_def bind_pmf.rep_eq comp_def return_pmf.rep_eq
   436   using bind_return_distr[of M f "count_space UNIV"] by (simp add: comp_def)
   437 
   438 lemma map_pmf_id[simp]: "map_pmf id = id"
   439   by (rule, transfer) (auto simp: emeasure_distr measurable_def intro!: measure_eqI)
   440 
   441 lemma map_pmf_ident[simp]: "map_pmf (\<lambda>x. x) = (\<lambda>x. x)"
   442   using map_pmf_id unfolding id_def .
   443 
   444 lemma map_pmf_compose: "map_pmf (f \<circ> g) = map_pmf f \<circ> map_pmf g"
   445   by (rule, transfer) (simp add: distr_distr[symmetric, where N="count_space UNIV"] measurable_def)
   446 
   447 lemma map_pmf_comp: "map_pmf f (map_pmf g M) = map_pmf (\<lambda>x. f (g x)) M"
   448   using map_pmf_compose[of f g] by (simp add: comp_def)
   449 
   450 lemma map_pmf_cong: "p = q \<Longrightarrow> (\<And>x. x \<in> set_pmf q \<Longrightarrow> f x = g x) \<Longrightarrow> map_pmf f p = map_pmf g q"
   451   unfolding map_pmf_def by (rule bind_pmf_cong) auto
   452 
   453 lemma pmf_set_map: "set_pmf \<circ> map_pmf f = op ` f \<circ> set_pmf"
   454   by (auto simp add: comp_def fun_eq_iff map_pmf_def)
   455 
   456 lemma set_map_pmf[simp]: "set_pmf (map_pmf f M) = f`set_pmf M"
   457   using pmf_set_map[of f] by (auto simp: comp_def fun_eq_iff)
   458 
   459 lemma emeasure_map_pmf[simp]: "emeasure (map_pmf f M) X = emeasure M (f -` X)"
   460   unfolding map_pmf_rep_eq by (subst emeasure_distr) auto
   461 
   462 lemma measure_map_pmf[simp]: "measure (map_pmf f M) X = measure M (f -` X)"
   463 using emeasure_map_pmf[of f M X] by(simp add: measure_pmf.emeasure_eq_measure measure_nonneg)
   464 
   465 lemma nn_integral_map_pmf[simp]: "(\<integral>\<^sup>+x. f x \<partial>map_pmf g M) = (\<integral>\<^sup>+x. f (g x) \<partial>M)"
   466   unfolding map_pmf_rep_eq by (intro nn_integral_distr) auto
   467 
   468 lemma ennreal_pmf_map: "pmf (map_pmf f p) x = (\<integral>\<^sup>+ y. indicator (f -` {x}) y \<partial>measure_pmf p)"
   469 proof (transfer fixing: f x)
   470   fix p :: "'b measure"
   471   presume "prob_space p"
   472   then interpret prob_space p .
   473   presume "sets p = UNIV"
   474   then show "ennreal (measure (distr p (count_space UNIV) f) {x}) = integral\<^sup>N p (indicator (f -` {x}))"
   475     by(simp add: measure_distr measurable_def emeasure_eq_measure)
   476 qed simp_all
   477 
   478 lemma pmf_map: "pmf (map_pmf f p) x = measure p (f -` {x})"
   479 proof (transfer fixing: f x)
   480   fix p :: "'b measure"
   481   presume "prob_space p"
   482   then interpret prob_space p .
   483   presume "sets p = UNIV"
   484   then show "measure (distr p (count_space UNIV) f) {x} = measure p (f -` {x})"
   485     by(simp add: measure_distr measurable_def emeasure_eq_measure)
   486 qed simp_all
   487 
   488 lemma nn_integral_pmf: "(\<integral>\<^sup>+ x. pmf p x \<partial>count_space A) = emeasure (measure_pmf p) A"
   489 proof -
   490   have "(\<integral>\<^sup>+ x. pmf p x \<partial>count_space A) = (\<integral>\<^sup>+ x. pmf p x \<partial>count_space (A \<inter> set_pmf p))"
   491     by(auto simp add: nn_integral_count_space_indicator indicator_def set_pmf_iff intro: nn_integral_cong)
   492   also have "\<dots> = emeasure (measure_pmf p) (\<Union>x\<in>A \<inter> set_pmf p. {x})"
   493     by(subst emeasure_UN_countable)(auto simp add: emeasure_pmf_single disjoint_family_on_def)
   494   also have "\<dots> = emeasure (measure_pmf p) ((\<Union>x\<in>A \<inter> set_pmf p. {x}) \<union> {x. x \<in> A \<and> x \<notin> set_pmf p})"
   495     by(rule emeasure_Un_null_set[symmetric])(auto intro: in_null_sets_measure_pmfI)
   496   also have "\<dots> = emeasure (measure_pmf p) A"
   497     by(auto intro: arg_cong2[where f=emeasure])
   498   finally show ?thesis .
   499 qed
   500 
   501 lemma integral_map_pmf[simp]:
   502   fixes f :: "'a \<Rightarrow> 'b::{banach, second_countable_topology}"
   503   shows "integral\<^sup>L (map_pmf g p) f = integral\<^sup>L p (\<lambda>x. f (g x))"
   504   by (simp add: integral_distr map_pmf_rep_eq)
   505 
   506 lemma map_return_pmf [simp]: "map_pmf f (return_pmf x) = return_pmf (f x)"
   507   by transfer (simp add: distr_return)
   508 
   509 lemma map_pmf_const[simp]: "map_pmf (\<lambda>_. c) M = return_pmf c"
   510   by transfer (auto simp: prob_space.distr_const)
   511 
   512 lemma pmf_return [simp]: "pmf (return_pmf x) y = indicator {y} x"
   513   by transfer (simp add: measure_return)
   514 
   515 lemma nn_integral_return_pmf[simp]: "0 \<le> f x \<Longrightarrow> (\<integral>\<^sup>+x. f x \<partial>return_pmf x) = f x"
   516   unfolding return_pmf.rep_eq by (intro nn_integral_return) auto
   517 
   518 lemma emeasure_return_pmf[simp]: "emeasure (return_pmf x) X = indicator X x"
   519   unfolding return_pmf.rep_eq by (intro emeasure_return) auto
   520 
   521 lemma return_pmf_inj[simp]: "return_pmf x = return_pmf y \<longleftrightarrow> x = y"
   522   by (metis insertI1 set_return_pmf singletonD)
   523 
   524 lemma map_pmf_eq_return_pmf_iff:
   525   "map_pmf f p = return_pmf x \<longleftrightarrow> (\<forall>y \<in> set_pmf p. f y = x)"
   526 proof
   527   assume "map_pmf f p = return_pmf x"
   528   then have "set_pmf (map_pmf f p) = set_pmf (return_pmf x)" by simp
   529   then show "\<forall>y \<in> set_pmf p. f y = x" by auto
   530 next
   531   assume "\<forall>y \<in> set_pmf p. f y = x"
   532   then show "map_pmf f p = return_pmf x"
   533     unfolding map_pmf_const[symmetric, of _ p] by (intro map_pmf_cong) auto
   534 qed
   535 
   536 definition "pair_pmf A B = bind_pmf A (\<lambda>x. bind_pmf B (\<lambda>y. return_pmf (x, y)))"
   537 
   538 lemma pmf_pair: "pmf (pair_pmf M N) (a, b) = pmf M a * pmf N b"
   539   unfolding pair_pmf_def pmf_bind pmf_return
   540   apply (subst integral_measure_pmf[where A="{b}"])
   541   apply (auto simp: indicator_eq_0_iff)
   542   apply (subst integral_measure_pmf[where A="{a}"])
   543   apply (auto simp: indicator_eq_0_iff setsum_nonneg_eq_0_iff pmf_nonneg)
   544   done
   545 
   546 lemma set_pair_pmf[simp]: "set_pmf (pair_pmf A B) = set_pmf A \<times> set_pmf B"
   547   unfolding pair_pmf_def set_bind_pmf set_return_pmf by auto
   548 
   549 lemma measure_pmf_in_subprob_space[measurable (raw)]:
   550   "measure_pmf M \<in> space (subprob_algebra (count_space UNIV))"
   551   by (simp add: space_subprob_algebra) intro_locales
   552 
   553 lemma nn_integral_pair_pmf': "(\<integral>\<^sup>+x. f x \<partial>pair_pmf A B) = (\<integral>\<^sup>+a. \<integral>\<^sup>+b. f (a, b) \<partial>B \<partial>A)"
   554 proof -
   555   have "(\<integral>\<^sup>+x. f x \<partial>pair_pmf A B) = (\<integral>\<^sup>+x. f x * indicator (A \<times> B) x \<partial>pair_pmf A B)"
   556     by (auto simp: AE_measure_pmf_iff intro!: nn_integral_cong_AE)
   557   also have "\<dots> = (\<integral>\<^sup>+a. \<integral>\<^sup>+b. f (a, b) * indicator (A \<times> B) (a, b) \<partial>B \<partial>A)"
   558     by (simp add: pair_pmf_def)
   559   also have "\<dots> = (\<integral>\<^sup>+a. \<integral>\<^sup>+b. f (a, b) \<partial>B \<partial>A)"
   560     by (auto intro!: nn_integral_cong_AE simp: AE_measure_pmf_iff)
   561   finally show ?thesis .
   562 qed
   563 
   564 lemma bind_pair_pmf:
   565   assumes M[measurable]: "M \<in> measurable (count_space UNIV \<Otimes>\<^sub>M count_space UNIV) (subprob_algebra N)"
   566   shows "measure_pmf (pair_pmf A B) \<bind> M = (measure_pmf A \<bind> (\<lambda>x. measure_pmf B \<bind> (\<lambda>y. M (x, y))))"
   567     (is "?L = ?R")
   568 proof (rule measure_eqI)
   569   have M'[measurable]: "M \<in> measurable (pair_pmf A B) (subprob_algebra N)"
   570     using M[THEN measurable_space] by (simp_all add: space_pair_measure)
   571 
   572   note measurable_bind[where N="count_space UNIV", measurable]
   573   note measure_pmf_in_subprob_space[simp]
   574 
   575   have sets_eq_N: "sets ?L = N"
   576     by (subst sets_bind[OF sets_kernel[OF M']]) auto
   577   show "sets ?L = sets ?R"
   578     using measurable_space[OF M]
   579     by (simp add: sets_eq_N space_pair_measure space_subprob_algebra)
   580   fix X assume "X \<in> sets ?L"
   581   then have X[measurable]: "X \<in> sets N"
   582     unfolding sets_eq_N .
   583   then show "emeasure ?L X = emeasure ?R X"
   584     apply (simp add: emeasure_bind[OF _ M' X])
   585     apply (simp add: nn_integral_bind[where B="count_space UNIV"] pair_pmf_def measure_pmf_bind[of A]
   586                      nn_integral_measure_pmf_finite)
   587     apply (subst emeasure_bind[OF _ _ X])
   588     apply measurable
   589     apply (subst emeasure_bind[OF _ _ X])
   590     apply measurable
   591     done
   592 qed
   593 
   594 lemma map_fst_pair_pmf: "map_pmf fst (pair_pmf A B) = A"
   595   by (simp add: pair_pmf_def map_pmf_def bind_assoc_pmf bind_return_pmf bind_return_pmf')
   596 
   597 lemma map_snd_pair_pmf: "map_pmf snd (pair_pmf A B) = B"
   598   by (simp add: pair_pmf_def map_pmf_def bind_assoc_pmf bind_return_pmf bind_return_pmf')
   599 
   600 lemma nn_integral_pmf':
   601   "inj_on f A \<Longrightarrow> (\<integral>\<^sup>+x. pmf p (f x) \<partial>count_space A) = emeasure p (f ` A)"
   602   by (subst nn_integral_bij_count_space[where g=f and B="f`A"])
   603      (auto simp: bij_betw_def nn_integral_pmf)
   604 
   605 lemma pmf_le_0_iff[simp]: "pmf M p \<le> 0 \<longleftrightarrow> pmf M p = 0"
   606   using pmf_nonneg[of M p] by arith
   607 
   608 lemma min_pmf_0[simp]: "min (pmf M p) 0 = 0" "min 0 (pmf M p) = 0"
   609   using pmf_nonneg[of M p] by arith+
   610 
   611 lemma pmf_eq_0_set_pmf: "pmf M p = 0 \<longleftrightarrow> p \<notin> set_pmf M"
   612   unfolding set_pmf_iff by simp
   613 
   614 lemma pmf_map_inj: "inj_on f (set_pmf M) \<Longrightarrow> x \<in> set_pmf M \<Longrightarrow> pmf (map_pmf f M) (f x) = pmf M x"
   615   by (auto simp: pmf.rep_eq map_pmf_rep_eq measure_distr AE_measure_pmf_iff inj_onD
   616            intro!: measure_pmf.finite_measure_eq_AE)
   617 
   618 lemma pmf_map_inj': "inj f \<Longrightarrow> pmf (map_pmf f M) (f x) = pmf M x"
   619 apply(cases "x \<in> set_pmf M")
   620  apply(simp add: pmf_map_inj[OF subset_inj_on])
   621 apply(simp add: pmf_eq_0_set_pmf[symmetric])
   622 apply(auto simp add: pmf_eq_0_set_pmf dest: injD)
   623 done
   624 
   625 lemma pmf_map_outside: "x \<notin> f ` set_pmf M \<Longrightarrow> pmf (map_pmf f M) x = 0"
   626 unfolding pmf_eq_0_set_pmf by simp
   627 
   628 subsection \<open> PMFs as function \<close>
   629 
   630 context
   631   fixes f :: "'a \<Rightarrow> real"
   632   assumes nonneg: "\<And>x. 0 \<le> f x"
   633   assumes prob: "(\<integral>\<^sup>+x. f x \<partial>count_space UNIV) = 1"
   634 begin
   635 
   636 lift_definition embed_pmf :: "'a pmf" is "density (count_space UNIV) (ennreal \<circ> f)"
   637 proof (intro conjI)
   638   have *[simp]: "\<And>x y. ennreal (f y) * indicator {x} y = ennreal (f x) * indicator {x} y"
   639     by (simp split: split_indicator)
   640   show "AE x in density (count_space UNIV) (ennreal \<circ> f).
   641     measure (density (count_space UNIV) (ennreal \<circ> f)) {x} \<noteq> 0"
   642     by (simp add: AE_density nonneg measure_def emeasure_density max_def)
   643   show "prob_space (density (count_space UNIV) (ennreal \<circ> f))"
   644     by standard (simp add: emeasure_density prob)
   645 qed simp
   646 
   647 lemma pmf_embed_pmf: "pmf embed_pmf x = f x"
   648 proof transfer
   649   have *[simp]: "\<And>x y. ennreal (f y) * indicator {x} y = ennreal (f x) * indicator {x} y"
   650     by (simp split: split_indicator)
   651   fix x show "measure (density (count_space UNIV) (ennreal \<circ> f)) {x} = f x"
   652     by transfer (simp add: measure_def emeasure_density nonneg max_def)
   653 qed
   654 
   655 lemma set_embed_pmf: "set_pmf embed_pmf = {x. f x \<noteq> 0}"
   656 by(auto simp add: set_pmf_eq assms pmf_embed_pmf)
   657 
   658 end
   659 
   660 lemma embed_pmf_transfer:
   661   "rel_fun (eq_onp (\<lambda>f. (\<forall>x. 0 \<le> f x) \<and> (\<integral>\<^sup>+x. ennreal (f x) \<partial>count_space UNIV) = 1)) pmf_as_measure.cr_pmf (\<lambda>f. density (count_space UNIV) (ennreal \<circ> f)) embed_pmf"
   662   by (auto simp: rel_fun_def eq_onp_def embed_pmf.transfer)
   663 
   664 lemma measure_pmf_eq_density: "measure_pmf p = density (count_space UNIV) (pmf p)"
   665 proof (transfer, elim conjE)
   666   fix M :: "'a measure" assume [simp]: "sets M = UNIV" and ae: "AE x in M. measure M {x} \<noteq> 0"
   667   assume "prob_space M" then interpret prob_space M .
   668   show "M = density (count_space UNIV) (\<lambda>x. ennreal (measure M {x}))"
   669   proof (rule measure_eqI)
   670     fix A :: "'a set"
   671     have "(\<integral>\<^sup>+ x. ennreal (measure M {x}) * indicator A x \<partial>count_space UNIV) =
   672       (\<integral>\<^sup>+ x. emeasure M {x} * indicator (A \<inter> {x. measure M {x} \<noteq> 0}) x \<partial>count_space UNIV)"
   673       by (auto intro!: nn_integral_cong simp: emeasure_eq_measure split: split_indicator)
   674     also have "\<dots> = (\<integral>\<^sup>+ x. emeasure M {x} \<partial>count_space (A \<inter> {x. measure M {x} \<noteq> 0}))"
   675       by (subst nn_integral_restrict_space[symmetric]) (auto simp: restrict_count_space)
   676     also have "\<dots> = emeasure M (\<Union>x\<in>(A \<inter> {x. measure M {x} \<noteq> 0}). {x})"
   677       by (intro emeasure_UN_countable[symmetric] countable_Int2 countable_support)
   678          (auto simp: disjoint_family_on_def)
   679     also have "\<dots> = emeasure M A"
   680       using ae by (intro emeasure_eq_AE) auto
   681     finally show " emeasure M A = emeasure (density (count_space UNIV) (\<lambda>x. ennreal (measure M {x}))) A"
   682       using emeasure_space_1 by (simp add: emeasure_density)
   683   qed simp
   684 qed
   685 
   686 lemma td_pmf_embed_pmf:
   687   "type_definition pmf embed_pmf {f::'a \<Rightarrow> real. (\<forall>x. 0 \<le> f x) \<and> (\<integral>\<^sup>+x. ennreal (f x) \<partial>count_space UNIV) = 1}"
   688   unfolding type_definition_def
   689 proof safe
   690   fix p :: "'a pmf"
   691   have "(\<integral>\<^sup>+ x. 1 \<partial>measure_pmf p) = 1"
   692     using measure_pmf.emeasure_space_1[of p] by simp
   693   then show *: "(\<integral>\<^sup>+ x. ennreal (pmf p x) \<partial>count_space UNIV) = 1"
   694     by (simp add: measure_pmf_eq_density nn_integral_density pmf_nonneg del: nn_integral_const)
   695 
   696   show "embed_pmf (pmf p) = p"
   697     by (intro measure_pmf_inject[THEN iffD1])
   698        (simp add: * embed_pmf.rep_eq pmf_nonneg measure_pmf_eq_density[of p] comp_def)
   699 next
   700   fix f :: "'a \<Rightarrow> real" assume "\<forall>x. 0 \<le> f x" "(\<integral>\<^sup>+x. f x \<partial>count_space UNIV) = 1"
   701   then show "pmf (embed_pmf f) = f"
   702     by (auto intro!: pmf_embed_pmf)
   703 qed (rule pmf_nonneg)
   704 
   705 end
   706 
   707 lemma nn_integral_measure_pmf: "(\<integral>\<^sup>+ x. f x \<partial>measure_pmf p) = \<integral>\<^sup>+ x. ennreal (pmf p x) * f x \<partial>count_space UNIV"
   708 by(simp add: measure_pmf_eq_density nn_integral_density pmf_nonneg)
   709 
   710 locale pmf_as_function
   711 begin
   712 
   713 setup_lifting td_pmf_embed_pmf
   714 
   715 lemma set_pmf_transfer[transfer_rule]:
   716   assumes "bi_total A"
   717   shows "rel_fun (pcr_pmf A) (rel_set A) (\<lambda>f. {x. f x \<noteq> 0}) set_pmf"
   718   using \<open>bi_total A\<close>
   719   by (auto simp: pcr_pmf_def cr_pmf_def rel_fun_def rel_set_def bi_total_def Bex_def set_pmf_iff)
   720      metis+
   721 
   722 end
   723 
   724 context
   725 begin
   726 
   727 interpretation pmf_as_function .
   728 
   729 lemma pmf_eqI: "(\<And>i. pmf M i = pmf N i) \<Longrightarrow> M = N"
   730   by transfer auto
   731 
   732 lemma pmf_eq_iff: "M = N \<longleftrightarrow> (\<forall>i. pmf M i = pmf N i)"
   733   by (auto intro: pmf_eqI)
   734 
   735 lemma bind_commute_pmf: "bind_pmf A (\<lambda>x. bind_pmf B (C x)) = bind_pmf B (\<lambda>y. bind_pmf A (\<lambda>x. C x y))"
   736   unfolding pmf_eq_iff pmf_bind
   737 proof
   738   fix i
   739   interpret B: prob_space "restrict_space B B"
   740     by (intro prob_space_restrict_space measure_pmf.emeasure_eq_1_AE)
   741        (auto simp: AE_measure_pmf_iff)
   742   interpret A: prob_space "restrict_space A A"
   743     by (intro prob_space_restrict_space measure_pmf.emeasure_eq_1_AE)
   744        (auto simp: AE_measure_pmf_iff)
   745 
   746   interpret AB: pair_prob_space "restrict_space A A" "restrict_space B B"
   747     by unfold_locales
   748 
   749   have "(\<integral> x. \<integral> y. pmf (C x y) i \<partial>B \<partial>A) = (\<integral> x. (\<integral> y. pmf (C x y) i \<partial>restrict_space B B) \<partial>A)"
   750     by (rule integral_cong) (auto intro!: integral_pmf_restrict)
   751   also have "\<dots> = (\<integral> x. (\<integral> y. pmf (C x y) i \<partial>restrict_space B B) \<partial>restrict_space A A)"
   752     by (intro integral_pmf_restrict B.borel_measurable_lebesgue_integral measurable_pair_restrict_pmf2
   753               countable_set_pmf borel_measurable_count_space)
   754   also have "\<dots> = (\<integral> y. \<integral> x. pmf (C x y) i \<partial>restrict_space A A \<partial>restrict_space B B)"
   755     by (rule AB.Fubini_integral[symmetric])
   756        (auto intro!: AB.integrable_const_bound[where B=1] measurable_pair_restrict_pmf2
   757              simp: pmf_nonneg pmf_le_1 measurable_restrict_space1)
   758   also have "\<dots> = (\<integral> y. \<integral> x. pmf (C x y) i \<partial>restrict_space A A \<partial>B)"
   759     by (intro integral_pmf_restrict[symmetric] A.borel_measurable_lebesgue_integral measurable_pair_restrict_pmf2
   760               countable_set_pmf borel_measurable_count_space)
   761   also have "\<dots> = (\<integral> y. \<integral> x. pmf (C x y) i \<partial>A \<partial>B)"
   762     by (rule integral_cong) (auto intro!: integral_pmf_restrict[symmetric])
   763   finally show "(\<integral> x. \<integral> y. pmf (C x y) i \<partial>B \<partial>A) = (\<integral> y. \<integral> x. pmf (C x y) i \<partial>A \<partial>B)" .
   764 qed
   765 
   766 lemma pair_map_pmf1: "pair_pmf (map_pmf f A) B = map_pmf (apfst f) (pair_pmf A B)"
   767 proof (safe intro!: pmf_eqI)
   768   fix a :: "'a" and b :: "'b"
   769   have [simp]: "\<And>c d. indicator (apfst f -` {(a, b)}) (c, d) = indicator (f -` {a}) c * (indicator {b} d::ennreal)"
   770     by (auto split: split_indicator)
   771 
   772   have "ennreal (pmf (pair_pmf (map_pmf f A) B) (a, b)) =
   773          ennreal (pmf (map_pmf (apfst f) (pair_pmf A B)) (a, b))"
   774     unfolding pmf_pair ennreal_pmf_map
   775     by (simp add: nn_integral_pair_pmf' max_def emeasure_pmf_single nn_integral_multc pmf_nonneg
   776                   emeasure_map_pmf[symmetric] ennreal_mult del: emeasure_map_pmf)
   777   then show "pmf (pair_pmf (map_pmf f A) B) (a, b) = pmf (map_pmf (apfst f) (pair_pmf A B)) (a, b)"
   778     by (simp add: pmf_nonneg)
   779 qed
   780 
   781 lemma pair_map_pmf2: "pair_pmf A (map_pmf f B) = map_pmf (apsnd f) (pair_pmf A B)"
   782 proof (safe intro!: pmf_eqI)
   783   fix a :: "'a" and b :: "'b"
   784   have [simp]: "\<And>c d. indicator (apsnd f -` {(a, b)}) (c, d) = indicator {a} c * (indicator (f -` {b}) d::ennreal)"
   785     by (auto split: split_indicator)
   786 
   787   have "ennreal (pmf (pair_pmf A (map_pmf f B)) (a, b)) =
   788          ennreal (pmf (map_pmf (apsnd f) (pair_pmf A B)) (a, b))"
   789     unfolding pmf_pair ennreal_pmf_map
   790     by (simp add: nn_integral_pair_pmf' max_def emeasure_pmf_single nn_integral_cmult nn_integral_multc pmf_nonneg
   791                   emeasure_map_pmf[symmetric] ennreal_mult del: emeasure_map_pmf)
   792   then show "pmf (pair_pmf A (map_pmf f B)) (a, b) = pmf (map_pmf (apsnd f) (pair_pmf A B)) (a, b)"
   793     by (simp add: pmf_nonneg)
   794 qed
   795 
   796 lemma map_pair: "map_pmf (\<lambda>(a, b). (f a, g b)) (pair_pmf A B) = pair_pmf (map_pmf f A) (map_pmf g B)"
   797   by (simp add: pair_map_pmf2 pair_map_pmf1 map_pmf_comp split_beta')
   798 
   799 end
   800 
   801 lemma pair_return_pmf1: "pair_pmf (return_pmf x) y = map_pmf (Pair x) y"
   802 by(simp add: pair_pmf_def bind_return_pmf map_pmf_def)
   803 
   804 lemma pair_return_pmf2: "pair_pmf x (return_pmf y) = map_pmf (\<lambda>x. (x, y)) x"
   805 by(simp add: pair_pmf_def bind_return_pmf map_pmf_def)
   806 
   807 lemma pair_pair_pmf: "pair_pmf (pair_pmf u v) w = map_pmf (\<lambda>(x, (y, z)). ((x, y), z)) (pair_pmf u (pair_pmf v w))"
   808 by(simp add: pair_pmf_def bind_return_pmf map_pmf_def bind_assoc_pmf)
   809 
   810 lemma pair_commute_pmf: "pair_pmf x y = map_pmf (\<lambda>(x, y). (y, x)) (pair_pmf y x)"
   811 unfolding pair_pmf_def by(subst bind_commute_pmf)(simp add: map_pmf_def bind_assoc_pmf bind_return_pmf)
   812 
   813 lemma set_pmf_subset_singleton: "set_pmf p \<subseteq> {x} \<longleftrightarrow> p = return_pmf x"
   814 proof(intro iffI pmf_eqI)
   815   fix i
   816   assume x: "set_pmf p \<subseteq> {x}"
   817   hence *: "set_pmf p = {x}" using set_pmf_not_empty[of p] by auto
   818   have "ennreal (pmf p x) = \<integral>\<^sup>+ i. indicator {x} i \<partial>p" by(simp add: emeasure_pmf_single)
   819   also have "\<dots> = \<integral>\<^sup>+ i. 1 \<partial>p" by(rule nn_integral_cong_AE)(simp add: AE_measure_pmf_iff * )
   820   also have "\<dots> = 1" by simp
   821   finally show "pmf p i = pmf (return_pmf x) i" using x
   822     by(auto split: split_indicator simp add: pmf_eq_0_set_pmf)
   823 qed auto
   824 
   825 lemma bind_eq_return_pmf:
   826   "bind_pmf p f = return_pmf x \<longleftrightarrow> (\<forall>y\<in>set_pmf p. f y = return_pmf x)"
   827   (is "?lhs \<longleftrightarrow> ?rhs")
   828 proof(intro iffI strip)
   829   fix y
   830   assume y: "y \<in> set_pmf p"
   831   assume "?lhs"
   832   hence "set_pmf (bind_pmf p f) = {x}" by simp
   833   hence "(\<Union>y\<in>set_pmf p. set_pmf (f y)) = {x}" by simp
   834   hence "set_pmf (f y) \<subseteq> {x}" using y by auto
   835   thus "f y = return_pmf x" by(simp add: set_pmf_subset_singleton)
   836 next
   837   assume *: ?rhs
   838   show ?lhs
   839   proof(rule pmf_eqI)
   840     fix i
   841     have "ennreal (pmf (bind_pmf p f) i) = \<integral>\<^sup>+ y. ennreal (pmf (f y) i) \<partial>p"
   842       by (simp add: ennreal_pmf_bind)
   843     also have "\<dots> = \<integral>\<^sup>+ y. ennreal (pmf (return_pmf x) i) \<partial>p"
   844       by(rule nn_integral_cong_AE)(simp add: AE_measure_pmf_iff * )
   845     also have "\<dots> = ennreal (pmf (return_pmf x) i)"
   846       by simp
   847     finally show "pmf (bind_pmf p f) i = pmf (return_pmf x) i"
   848       by (simp add: pmf_nonneg)
   849   qed
   850 qed
   851 
   852 lemma pmf_False_conv_True: "pmf p False = 1 - pmf p True"
   853 proof -
   854   have "pmf p False + pmf p True = measure p {False} + measure p {True}"
   855     by(simp add: measure_pmf_single)
   856   also have "\<dots> = measure p ({False} \<union> {True})"
   857     by(subst measure_pmf.finite_measure_Union) simp_all
   858   also have "{False} \<union> {True} = space p" by auto
   859   finally show ?thesis by simp
   860 qed
   861 
   862 lemma pmf_True_conv_False: "pmf p True = 1 - pmf p False"
   863 by(simp add: pmf_False_conv_True)
   864 
   865 subsection \<open> Conditional Probabilities \<close>
   866 
   867 lemma measure_pmf_zero_iff: "measure (measure_pmf p) s = 0 \<longleftrightarrow> set_pmf p \<inter> s = {}"
   868   by (subst measure_pmf.prob_eq_0) (auto simp: AE_measure_pmf_iff)
   869 
   870 context
   871   fixes p :: "'a pmf" and s :: "'a set"
   872   assumes not_empty: "set_pmf p \<inter> s \<noteq> {}"
   873 begin
   874 
   875 interpretation pmf_as_measure .
   876 
   877 lemma emeasure_measure_pmf_not_zero: "emeasure (measure_pmf p) s \<noteq> 0"
   878 proof
   879   assume "emeasure (measure_pmf p) s = 0"
   880   then have "AE x in measure_pmf p. x \<notin> s"
   881     by (rule AE_I[rotated]) auto
   882   with not_empty show False
   883     by (auto simp: AE_measure_pmf_iff)
   884 qed
   885 
   886 lemma measure_measure_pmf_not_zero: "measure (measure_pmf p) s \<noteq> 0"
   887   using emeasure_measure_pmf_not_zero by (simp add: measure_pmf.emeasure_eq_measure measure_nonneg)
   888 
   889 lift_definition cond_pmf :: "'a pmf" is
   890   "uniform_measure (measure_pmf p) s"
   891 proof (intro conjI)
   892   show "prob_space (uniform_measure (measure_pmf p) s)"
   893     by (intro prob_space_uniform_measure) (auto simp: emeasure_measure_pmf_not_zero)
   894   show "AE x in uniform_measure (measure_pmf p) s. measure (uniform_measure (measure_pmf p) s) {x} \<noteq> 0"
   895     by (simp add: emeasure_measure_pmf_not_zero measure_measure_pmf_not_zero AE_uniform_measure
   896                   AE_measure_pmf_iff set_pmf.rep_eq less_top[symmetric])
   897 qed simp
   898 
   899 lemma pmf_cond: "pmf cond_pmf x = (if x \<in> s then pmf p x / measure p s else 0)"
   900   by transfer (simp add: emeasure_measure_pmf_not_zero pmf.rep_eq)
   901 
   902 lemma set_cond_pmf[simp]: "set_pmf cond_pmf = set_pmf p \<inter> s"
   903   by (auto simp add: set_pmf_iff pmf_cond measure_measure_pmf_not_zero split: if_split_asm)
   904 
   905 end
   906 
   907 lemma cond_map_pmf:
   908   assumes "set_pmf p \<inter> f -` s \<noteq> {}"
   909   shows "cond_pmf (map_pmf f p) s = map_pmf f (cond_pmf p (f -` s))"
   910 proof -
   911   have *: "set_pmf (map_pmf f p) \<inter> s \<noteq> {}"
   912     using assms by auto
   913   { fix x
   914     have "ennreal (pmf (map_pmf f (cond_pmf p (f -` s))) x) =
   915       emeasure p (f -` s \<inter> f -` {x}) / emeasure p (f -` s)"
   916       unfolding ennreal_pmf_map cond_pmf.rep_eq[OF assms] by (simp add: nn_integral_uniform_measure)
   917     also have "f -` s \<inter> f -` {x} = (if x \<in> s then f -` {x} else {})"
   918       by auto
   919     also have "emeasure p (if x \<in> s then f -` {x} else {}) / emeasure p (f -` s) =
   920       ennreal (pmf (cond_pmf (map_pmf f p) s) x)"
   921       using measure_measure_pmf_not_zero[OF *]
   922       by (simp add: pmf_cond[OF *] ennreal_pmf_map measure_pmf.emeasure_eq_measure
   923                     divide_ennreal pmf_nonneg measure_nonneg zero_less_measure_iff pmf_map)
   924     finally have "ennreal (pmf (cond_pmf (map_pmf f p) s) x) = ennreal (pmf (map_pmf f (cond_pmf p (f -` s))) x)"
   925       by simp }
   926   then show ?thesis
   927     by (intro pmf_eqI) (simp add: pmf_nonneg)
   928 qed
   929 
   930 lemma bind_cond_pmf_cancel:
   931   assumes [simp]: "\<And>x. x \<in> set_pmf p \<Longrightarrow> set_pmf q \<inter> {y. R x y} \<noteq> {}"
   932   assumes [simp]: "\<And>y. y \<in> set_pmf q \<Longrightarrow> set_pmf p \<inter> {x. R x y} \<noteq> {}"
   933   assumes [simp]: "\<And>x y. x \<in> set_pmf p \<Longrightarrow> y \<in> set_pmf q \<Longrightarrow> R x y \<Longrightarrow> measure q {y. R x y} = measure p {x. R x y}"
   934   shows "bind_pmf p (\<lambda>x. cond_pmf q {y. R x y}) = q"
   935 proof (rule pmf_eqI)
   936   fix i
   937   have "ennreal (pmf (bind_pmf p (\<lambda>x. cond_pmf q {y. R x y})) i) =
   938     (\<integral>\<^sup>+x. ennreal (pmf q i / measure p {x. R x i}) * ennreal (indicator {x. R x i} x) \<partial>p)"
   939     by (auto simp add: ennreal_pmf_bind AE_measure_pmf_iff pmf_cond pmf_eq_0_set_pmf pmf_nonneg measure_nonneg
   940              intro!: nn_integral_cong_AE)
   941   also have "\<dots> = (pmf q i * measure p {x. R x i}) / measure p {x. R x i}"
   942     by (simp add: pmf_nonneg measure_nonneg zero_ennreal_def[symmetric] ennreal_indicator
   943                   nn_integral_cmult measure_pmf.emeasure_eq_measure ennreal_mult[symmetric])
   944   also have "\<dots> = pmf q i"
   945     by (cases "pmf q i = 0")
   946        (simp_all add: pmf_eq_0_set_pmf measure_measure_pmf_not_zero pmf_nonneg)
   947   finally show "pmf (bind_pmf p (\<lambda>x. cond_pmf q {y. R x y})) i = pmf q i"
   948     by (simp add: pmf_nonneg)
   949 qed
   950 
   951 subsection \<open> Relator \<close>
   952 
   953 inductive rel_pmf :: "('a \<Rightarrow> 'b \<Rightarrow> bool) \<Rightarrow> 'a pmf \<Rightarrow> 'b pmf \<Rightarrow> bool"
   954 for R p q
   955 where
   956   "\<lbrakk> \<And>x y. (x, y) \<in> set_pmf pq \<Longrightarrow> R x y;
   957      map_pmf fst pq = p; map_pmf snd pq = q \<rbrakk>
   958   \<Longrightarrow> rel_pmf R p q"
   959 
   960 lemma rel_pmfI:
   961   assumes R: "rel_set R (set_pmf p) (set_pmf q)"
   962   assumes eq: "\<And>x y. x \<in> set_pmf p \<Longrightarrow> y \<in> set_pmf q \<Longrightarrow> R x y \<Longrightarrow>
   963     measure p {x. R x y} = measure q {y. R x y}"
   964   shows "rel_pmf R p q"
   965 proof
   966   let ?pq = "bind_pmf p (\<lambda>x. bind_pmf (cond_pmf q {y. R x y}) (\<lambda>y. return_pmf (x, y)))"
   967   have "\<And>x. x \<in> set_pmf p \<Longrightarrow> set_pmf q \<inter> {y. R x y} \<noteq> {}"
   968     using R by (auto simp: rel_set_def)
   969   then show "\<And>x y. (x, y) \<in> set_pmf ?pq \<Longrightarrow> R x y"
   970     by auto
   971   show "map_pmf fst ?pq = p"
   972     by (simp add: map_bind_pmf bind_return_pmf')
   973 
   974   show "map_pmf snd ?pq = q"
   975     using R eq
   976     apply (simp add: bind_cond_pmf_cancel map_bind_pmf bind_return_pmf')
   977     apply (rule bind_cond_pmf_cancel)
   978     apply (auto simp: rel_set_def)
   979     done
   980 qed
   981 
   982 lemma rel_pmf_imp_rel_set: "rel_pmf R p q \<Longrightarrow> rel_set R (set_pmf p) (set_pmf q)"
   983   by (force simp add: rel_pmf.simps rel_set_def)
   984 
   985 lemma rel_pmfD_measure:
   986   assumes rel_R: "rel_pmf R p q" and R: "\<And>a b. R a b \<Longrightarrow> R a y \<longleftrightarrow> R x b"
   987   assumes "x \<in> set_pmf p" "y \<in> set_pmf q"
   988   shows "measure p {x. R x y} = measure q {y. R x y}"
   989 proof -
   990   from rel_R obtain pq where pq: "\<And>x y. (x, y) \<in> set_pmf pq \<Longrightarrow> R x y"
   991     and eq: "p = map_pmf fst pq" "q = map_pmf snd pq"
   992     by (auto elim: rel_pmf.cases)
   993   have "measure p {x. R x y} = measure pq {x. R (fst x) y}"
   994     by (simp add: eq map_pmf_rep_eq measure_distr)
   995   also have "\<dots> = measure pq {y. R x (snd y)}"
   996     by (intro measure_pmf.finite_measure_eq_AE)
   997        (auto simp: AE_measure_pmf_iff R dest!: pq)
   998   also have "\<dots> = measure q {y. R x y}"
   999     by (simp add: eq map_pmf_rep_eq measure_distr)
  1000   finally show "measure p {x. R x y} = measure q {y. R x y}" .
  1001 qed
  1002 
  1003 lemma rel_pmf_measureD:
  1004   assumes "rel_pmf R p q"
  1005   shows "measure (measure_pmf p) A \<le> measure (measure_pmf q) {y. \<exists>x\<in>A. R x y}" (is "?lhs \<le> ?rhs")
  1006 using assms
  1007 proof cases
  1008   fix pq
  1009   assume R: "\<And>x y. (x, y) \<in> set_pmf pq \<Longrightarrow> R x y"
  1010     and p[symmetric]: "map_pmf fst pq = p"
  1011     and q[symmetric]: "map_pmf snd pq = q"
  1012   have "?lhs = measure (measure_pmf pq) (fst -` A)" by(simp add: p)
  1013   also have "\<dots> \<le> measure (measure_pmf pq) {y. \<exists>x\<in>A. R x (snd y)}"
  1014     by(rule measure_pmf.finite_measure_mono_AE)(auto 4 3 simp add: AE_measure_pmf_iff dest: R)
  1015   also have "\<dots> = ?rhs" by(simp add: q)
  1016   finally show ?thesis .
  1017 qed
  1018 
  1019 lemma rel_pmf_iff_measure:
  1020   assumes "symp R" "transp R"
  1021   shows "rel_pmf R p q \<longleftrightarrow>
  1022     rel_set R (set_pmf p) (set_pmf q) \<and>
  1023     (\<forall>x\<in>set_pmf p. \<forall>y\<in>set_pmf q. R x y \<longrightarrow> measure p {x. R x y} = measure q {y. R x y})"
  1024   by (safe intro!: rel_pmf_imp_rel_set rel_pmfI)
  1025      (auto intro!: rel_pmfD_measure dest: sympD[OF \<open>symp R\<close>] transpD[OF \<open>transp R\<close>])
  1026 
  1027 lemma quotient_rel_set_disjoint:
  1028   "equivp R \<Longrightarrow> C \<in> UNIV // {(x, y). R x y} \<Longrightarrow> rel_set R A B \<Longrightarrow> A \<inter> C = {} \<longleftrightarrow> B \<inter> C = {}"
  1029   using in_quotient_imp_closed[of UNIV "{(x, y). R x y}" C]
  1030   by (auto 0 0 simp: equivp_equiv rel_set_def set_eq_iff elim: equivpE)
  1031      (blast dest: equivp_symp)+
  1032 
  1033 lemma quotientD: "equiv X R \<Longrightarrow> A \<in> X // R \<Longrightarrow> x \<in> A \<Longrightarrow> A = R `` {x}"
  1034   by (metis Image_singleton_iff equiv_class_eq_iff quotientE)
  1035 
  1036 lemma rel_pmf_iff_equivp:
  1037   assumes "equivp R"
  1038   shows "rel_pmf R p q \<longleftrightarrow> (\<forall>C\<in>UNIV // {(x, y). R x y}. measure p C = measure q C)"
  1039     (is "_ \<longleftrightarrow>   (\<forall>C\<in>_//?R. _)")
  1040 proof (subst rel_pmf_iff_measure, safe)
  1041   show "symp R" "transp R"
  1042     using assms by (auto simp: equivp_reflp_symp_transp)
  1043 next
  1044   fix C assume C: "C \<in> UNIV // ?R" and R: "rel_set R (set_pmf p) (set_pmf q)"
  1045   assume eq: "\<forall>x\<in>set_pmf p. \<forall>y\<in>set_pmf q. R x y \<longrightarrow> measure p {x. R x y} = measure q {y. R x y}"
  1046 
  1047   show "measure p C = measure q C"
  1048   proof cases
  1049     assume "p \<inter> C = {}"
  1050     moreover then have "q \<inter> C = {}"
  1051       using quotient_rel_set_disjoint[OF assms C R] by simp
  1052     ultimately show ?thesis
  1053       unfolding measure_pmf_zero_iff[symmetric] by simp
  1054   next
  1055     assume "p \<inter> C \<noteq> {}"
  1056     moreover then have "q \<inter> C \<noteq> {}"
  1057       using quotient_rel_set_disjoint[OF assms C R] by simp
  1058     ultimately obtain x y where in_set: "x \<in> set_pmf p" "y \<in> set_pmf q" and in_C: "x \<in> C" "y \<in> C"
  1059       by auto
  1060     then have "R x y"
  1061       using in_quotient_imp_in_rel[of UNIV ?R C x y] C assms
  1062       by (simp add: equivp_equiv)
  1063     with in_set eq have "measure p {x. R x y} = measure q {y. R x y}"
  1064       by auto
  1065     moreover have "{y. R x y} = C"
  1066       using assms \<open>x \<in> C\<close> C quotientD[of UNIV ?R C x] by (simp add: equivp_equiv)
  1067     moreover have "{x. R x y} = C"
  1068       using assms \<open>y \<in> C\<close> C quotientD[of UNIV "?R" C y] sympD[of R]
  1069       by (auto simp add: equivp_equiv elim: equivpE)
  1070     ultimately show ?thesis
  1071       by auto
  1072   qed
  1073 next
  1074   assume eq: "\<forall>C\<in>UNIV // ?R. measure p C = measure q C"
  1075   show "rel_set R (set_pmf p) (set_pmf q)"
  1076     unfolding rel_set_def
  1077   proof safe
  1078     fix x assume x: "x \<in> set_pmf p"
  1079     have "{y. R x y} \<in> UNIV // ?R"
  1080       by (auto simp: quotient_def)
  1081     with eq have *: "measure q {y. R x y} = measure p {y. R x y}"
  1082       by auto
  1083     have "measure q {y. R x y} \<noteq> 0"
  1084       using x assms unfolding * by (auto simp: measure_pmf_zero_iff set_eq_iff dest: equivp_reflp)
  1085     then show "\<exists>y\<in>set_pmf q. R x y"
  1086       unfolding measure_pmf_zero_iff by auto
  1087   next
  1088     fix y assume y: "y \<in> set_pmf q"
  1089     have "{x. R x y} \<in> UNIV // ?R"
  1090       using assms by (auto simp: quotient_def dest: equivp_symp)
  1091     with eq have *: "measure p {x. R x y} = measure q {x. R x y}"
  1092       by auto
  1093     have "measure p {x. R x y} \<noteq> 0"
  1094       using y assms unfolding * by (auto simp: measure_pmf_zero_iff set_eq_iff dest: equivp_reflp)
  1095     then show "\<exists>x\<in>set_pmf p. R x y"
  1096       unfolding measure_pmf_zero_iff by auto
  1097   qed
  1098 
  1099   fix x y assume "x \<in> set_pmf p" "y \<in> set_pmf q" "R x y"
  1100   have "{y. R x y} \<in> UNIV // ?R" "{x. R x y} = {y. R x y}"
  1101     using assms \<open>R x y\<close> by (auto simp: quotient_def dest: equivp_symp equivp_transp)
  1102   with eq show "measure p {x. R x y} = measure q {y. R x y}"
  1103     by auto
  1104 qed
  1105 
  1106 bnf pmf: "'a pmf" map: map_pmf sets: set_pmf bd : "natLeq" rel: rel_pmf
  1107 proof -
  1108   show "map_pmf id = id" by (rule map_pmf_id)
  1109   show "\<And>f g. map_pmf (f \<circ> g) = map_pmf f \<circ> map_pmf g" by (rule map_pmf_compose)
  1110   show "\<And>f g::'a \<Rightarrow> 'b. \<And>p. (\<And>x. x \<in> set_pmf p \<Longrightarrow> f x = g x) \<Longrightarrow> map_pmf f p = map_pmf g p"
  1111     by (intro map_pmf_cong refl)
  1112 
  1113   show "\<And>f::'a \<Rightarrow> 'b. set_pmf \<circ> map_pmf f = op ` f \<circ> set_pmf"
  1114     by (rule pmf_set_map)
  1115 
  1116   show "(card_of (set_pmf p), natLeq) \<in> ordLeq" for p :: "'s pmf"
  1117   proof -
  1118     have "(card_of (set_pmf p), card_of (UNIV :: nat set)) \<in> ordLeq"
  1119       by (rule card_of_ordLeqI[where f="to_nat_on (set_pmf p)"])
  1120          (auto intro: countable_set_pmf)
  1121     also have "(card_of (UNIV :: nat set), natLeq) \<in> ordLeq"
  1122       by (metis Field_natLeq card_of_least natLeq_Well_order)
  1123     finally show ?thesis .
  1124   qed
  1125 
  1126   show "\<And>R. rel_pmf R = (\<lambda>x y. \<exists>z. set_pmf z \<subseteq> {(x, y). R x y} \<and>
  1127     map_pmf fst z = x \<and> map_pmf snd z = y)"
  1128      by (auto simp add: fun_eq_iff rel_pmf.simps)
  1129 
  1130   show "rel_pmf R OO rel_pmf S \<le> rel_pmf (R OO S)"
  1131     for R :: "'a \<Rightarrow> 'b \<Rightarrow> bool" and S :: "'b \<Rightarrow> 'c \<Rightarrow> bool"
  1132   proof -
  1133     { fix p q r
  1134       assume pq: "rel_pmf R p q"
  1135         and qr:"rel_pmf S q r"
  1136       from pq obtain pq where pq: "\<And>x y. (x, y) \<in> set_pmf pq \<Longrightarrow> R x y"
  1137         and p: "p = map_pmf fst pq" and q: "q = map_pmf snd pq" by cases auto
  1138       from qr obtain qr where qr: "\<And>y z. (y, z) \<in> set_pmf qr \<Longrightarrow> S y z"
  1139         and q': "q = map_pmf fst qr" and r: "r = map_pmf snd qr" by cases auto
  1140 
  1141       def pr \<equiv> "bind_pmf pq (\<lambda>xy. bind_pmf (cond_pmf qr {yz. fst yz = snd xy}) (\<lambda>yz. return_pmf (fst xy, snd yz)))"
  1142       have pr_welldefined: "\<And>y. y \<in> q \<Longrightarrow> qr \<inter> {yz. fst yz = y} \<noteq> {}"
  1143         by (force simp: q')
  1144 
  1145       have "rel_pmf (R OO S) p r"
  1146       proof (rule rel_pmf.intros)
  1147         fix x z assume "(x, z) \<in> pr"
  1148         then have "\<exists>y. (x, y) \<in> pq \<and> (y, z) \<in> qr"
  1149           by (auto simp: q pr_welldefined pr_def split_beta)
  1150         with pq qr show "(R OO S) x z"
  1151           by blast
  1152       next
  1153         have "map_pmf snd pr = map_pmf snd (bind_pmf q (\<lambda>y. cond_pmf qr {yz. fst yz = y}))"
  1154           by (simp add: pr_def q split_beta bind_map_pmf map_pmf_def[symmetric] map_bind_pmf map_pmf_comp)
  1155         then show "map_pmf snd pr = r"
  1156           unfolding r q' bind_map_pmf by (subst (asm) bind_cond_pmf_cancel) (auto simp: eq_commute)
  1157       qed (simp add: pr_def map_bind_pmf split_beta map_pmf_def[symmetric] p map_pmf_comp)
  1158     }
  1159     then show ?thesis
  1160       by(auto simp add: le_fun_def)
  1161   qed
  1162 qed (fact natLeq_card_order natLeq_cinfinite)+
  1163 
  1164 lemma map_pmf_idI: "(\<And>x. x \<in> set_pmf p \<Longrightarrow> f x = x) \<Longrightarrow> map_pmf f p = p"
  1165 by(simp cong: pmf.map_cong)
  1166 
  1167 lemma rel_pmf_conj[simp]:
  1168   "rel_pmf (\<lambda>x y. P \<and> Q x y) x y \<longleftrightarrow> P \<and> rel_pmf Q x y"
  1169   "rel_pmf (\<lambda>x y. Q x y \<and> P) x y \<longleftrightarrow> P \<and> rel_pmf Q x y"
  1170   using set_pmf_not_empty by (fastforce simp: pmf.in_rel subset_eq)+
  1171 
  1172 lemma rel_pmf_top[simp]: "rel_pmf top = top"
  1173   by (auto simp: pmf.in_rel[abs_def] fun_eq_iff map_fst_pair_pmf map_snd_pair_pmf
  1174            intro: exI[of _ "pair_pmf x y" for x y])
  1175 
  1176 lemma rel_pmf_return_pmf1: "rel_pmf R (return_pmf x) M \<longleftrightarrow> (\<forall>a\<in>M. R x a)"
  1177 proof safe
  1178   fix a assume "a \<in> M" "rel_pmf R (return_pmf x) M"
  1179   then obtain pq where *: "\<And>a b. (a, b) \<in> set_pmf pq \<Longrightarrow> R a b"
  1180     and eq: "return_pmf x = map_pmf fst pq" "M = map_pmf snd pq"
  1181     by (force elim: rel_pmf.cases)
  1182   moreover have "set_pmf (return_pmf x) = {x}"
  1183     by simp
  1184   with \<open>a \<in> M\<close> have "(x, a) \<in> pq"
  1185     by (force simp: eq)
  1186   with * show "R x a"
  1187     by auto
  1188 qed (auto intro!: rel_pmf.intros[where pq="pair_pmf (return_pmf x) M"]
  1189           simp: map_fst_pair_pmf map_snd_pair_pmf)
  1190 
  1191 lemma rel_pmf_return_pmf2: "rel_pmf R M (return_pmf x) \<longleftrightarrow> (\<forall>a\<in>M. R a x)"
  1192   by (subst pmf.rel_flip[symmetric]) (simp add: rel_pmf_return_pmf1)
  1193 
  1194 lemma rel_return_pmf[simp]: "rel_pmf R (return_pmf x1) (return_pmf x2) = R x1 x2"
  1195   unfolding rel_pmf_return_pmf2 set_return_pmf by simp
  1196 
  1197 lemma rel_pmf_False[simp]: "rel_pmf (\<lambda>x y. False) x y = False"
  1198   unfolding pmf.in_rel fun_eq_iff using set_pmf_not_empty by fastforce
  1199 
  1200 lemma rel_pmf_rel_prod:
  1201   "rel_pmf (rel_prod R S) (pair_pmf A A') (pair_pmf B B') \<longleftrightarrow> rel_pmf R A B \<and> rel_pmf S A' B'"
  1202 proof safe
  1203   assume "rel_pmf (rel_prod R S) (pair_pmf A A') (pair_pmf B B')"
  1204   then obtain pq where pq: "\<And>a b c d. ((a, c), (b, d)) \<in> set_pmf pq \<Longrightarrow> R a b \<and> S c d"
  1205     and eq: "map_pmf fst pq = pair_pmf A A'" "map_pmf snd pq = pair_pmf B B'"
  1206     by (force elim: rel_pmf.cases)
  1207   show "rel_pmf R A B"
  1208   proof (rule rel_pmf.intros)
  1209     let ?f = "\<lambda>(a, b). (fst a, fst b)"
  1210     have [simp]: "(\<lambda>x. fst (?f x)) = fst o fst" "(\<lambda>x. snd (?f x)) = fst o snd"
  1211       by auto
  1212 
  1213     show "map_pmf fst (map_pmf ?f pq) = A"
  1214       by (simp add: map_pmf_comp pmf.map_comp[symmetric] eq map_fst_pair_pmf)
  1215     show "map_pmf snd (map_pmf ?f pq) = B"
  1216       by (simp add: map_pmf_comp pmf.map_comp[symmetric] eq map_fst_pair_pmf)
  1217 
  1218     fix a b assume "(a, b) \<in> set_pmf (map_pmf ?f pq)"
  1219     then obtain c d where "((a, c), (b, d)) \<in> set_pmf pq"
  1220       by auto
  1221     from pq[OF this] show "R a b" ..
  1222   qed
  1223   show "rel_pmf S A' B'"
  1224   proof (rule rel_pmf.intros)
  1225     let ?f = "\<lambda>(a, b). (snd a, snd b)"
  1226     have [simp]: "(\<lambda>x. fst (?f x)) = snd o fst" "(\<lambda>x. snd (?f x)) = snd o snd"
  1227       by auto
  1228 
  1229     show "map_pmf fst (map_pmf ?f pq) = A'"
  1230       by (simp add: map_pmf_comp pmf.map_comp[symmetric] eq map_snd_pair_pmf)
  1231     show "map_pmf snd (map_pmf ?f pq) = B'"
  1232       by (simp add: map_pmf_comp pmf.map_comp[symmetric] eq map_snd_pair_pmf)
  1233 
  1234     fix c d assume "(c, d) \<in> set_pmf (map_pmf ?f pq)"
  1235     then obtain a b where "((a, c), (b, d)) \<in> set_pmf pq"
  1236       by auto
  1237     from pq[OF this] show "S c d" ..
  1238   qed
  1239 next
  1240   assume "rel_pmf R A B" "rel_pmf S A' B'"
  1241   then obtain Rpq Spq
  1242     where Rpq: "\<And>a b. (a, b) \<in> set_pmf Rpq \<Longrightarrow> R a b"
  1243         "map_pmf fst Rpq = A" "map_pmf snd Rpq = B"
  1244       and Spq: "\<And>a b. (a, b) \<in> set_pmf Spq \<Longrightarrow> S a b"
  1245         "map_pmf fst Spq = A'" "map_pmf snd Spq = B'"
  1246     by (force elim: rel_pmf.cases)
  1247 
  1248   let ?f = "(\<lambda>((a, c), (b, d)). ((a, b), (c, d)))"
  1249   let ?pq = "map_pmf ?f (pair_pmf Rpq Spq)"
  1250   have [simp]: "(\<lambda>x. fst (?f x)) = (\<lambda>(a, b). (fst a, fst b))" "(\<lambda>x. snd (?f x)) = (\<lambda>(a, b). (snd a, snd b))"
  1251     by auto
  1252 
  1253   show "rel_pmf (rel_prod R S) (pair_pmf A A') (pair_pmf B B')"
  1254     by (rule rel_pmf.intros[where pq="?pq"])
  1255        (auto simp: map_snd_pair_pmf map_fst_pair_pmf map_pmf_comp Rpq Spq
  1256                    map_pair)
  1257 qed
  1258 
  1259 lemma rel_pmf_reflI:
  1260   assumes "\<And>x. x \<in> set_pmf p \<Longrightarrow> P x x"
  1261   shows "rel_pmf P p p"
  1262   by (rule rel_pmf.intros[where pq="map_pmf (\<lambda>x. (x, x)) p"])
  1263      (auto simp add: pmf.map_comp o_def assms)
  1264 
  1265 lemma rel_pmf_bij_betw:
  1266   assumes f: "bij_betw f (set_pmf p) (set_pmf q)"
  1267   and eq: "\<And>x. x \<in> set_pmf p \<Longrightarrow> pmf p x = pmf q (f x)"
  1268   shows "rel_pmf (\<lambda>x y. f x = y) p q"
  1269 proof(rule rel_pmf.intros)
  1270   let ?pq = "map_pmf (\<lambda>x. (x, f x)) p"
  1271   show "map_pmf fst ?pq = p" by(simp add: pmf.map_comp o_def)
  1272 
  1273   have "map_pmf f p = q"
  1274   proof(rule pmf_eqI)
  1275     fix i
  1276     show "pmf (map_pmf f p) i = pmf q i"
  1277     proof(cases "i \<in> set_pmf q")
  1278       case True
  1279       with f obtain j where "i = f j" "j \<in> set_pmf p"
  1280         by(auto simp add: bij_betw_def image_iff)
  1281       thus ?thesis using f by(simp add: bij_betw_def pmf_map_inj eq)
  1282     next
  1283       case False thus ?thesis
  1284         by(subst pmf_map_outside)(auto simp add: set_pmf_iff eq[symmetric])
  1285     qed
  1286   qed
  1287   then show "map_pmf snd ?pq = q" by(simp add: pmf.map_comp o_def)
  1288 qed auto
  1289 
  1290 context
  1291 begin
  1292 
  1293 interpretation pmf_as_measure .
  1294 
  1295 definition "join_pmf M = bind_pmf M (\<lambda>x. x)"
  1296 
  1297 lemma bind_eq_join_pmf: "bind_pmf M f = join_pmf (map_pmf f M)"
  1298   unfolding join_pmf_def bind_map_pmf ..
  1299 
  1300 lemma join_eq_bind_pmf: "join_pmf M = bind_pmf M id"
  1301   by (simp add: join_pmf_def id_def)
  1302 
  1303 lemma pmf_join: "pmf (join_pmf N) i = (\<integral>M. pmf M i \<partial>measure_pmf N)"
  1304   unfolding join_pmf_def pmf_bind ..
  1305 
  1306 lemma ennreal_pmf_join: "ennreal (pmf (join_pmf N) i) = (\<integral>\<^sup>+M. pmf M i \<partial>measure_pmf N)"
  1307   unfolding join_pmf_def ennreal_pmf_bind ..
  1308 
  1309 lemma set_pmf_join_pmf[simp]: "set_pmf (join_pmf f) = (\<Union>p\<in>set_pmf f. set_pmf p)"
  1310   by (simp add: join_pmf_def)
  1311 
  1312 lemma join_return_pmf: "join_pmf (return_pmf M) = M"
  1313   by (simp add: integral_return pmf_eq_iff pmf_join return_pmf.rep_eq)
  1314 
  1315 lemma map_join_pmf: "map_pmf f (join_pmf AA) = join_pmf (map_pmf (map_pmf f) AA)"
  1316   by (simp add: join_pmf_def map_pmf_def bind_assoc_pmf bind_return_pmf)
  1317 
  1318 lemma join_map_return_pmf: "join_pmf (map_pmf return_pmf A) = A"
  1319   by (simp add: join_pmf_def map_pmf_def bind_assoc_pmf bind_return_pmf bind_return_pmf')
  1320 
  1321 end
  1322 
  1323 lemma rel_pmf_joinI:
  1324   assumes "rel_pmf (rel_pmf P) p q"
  1325   shows "rel_pmf P (join_pmf p) (join_pmf q)"
  1326 proof -
  1327   from assms obtain pq where p: "p = map_pmf fst pq"
  1328     and q: "q = map_pmf snd pq"
  1329     and P: "\<And>x y. (x, y) \<in> set_pmf pq \<Longrightarrow> rel_pmf P x y"
  1330     by cases auto
  1331   from P obtain PQ
  1332     where PQ: "\<And>x y a b. \<lbrakk> (x, y) \<in> set_pmf pq; (a, b) \<in> set_pmf (PQ x y) \<rbrakk> \<Longrightarrow> P a b"
  1333     and x: "\<And>x y. (x, y) \<in> set_pmf pq \<Longrightarrow> map_pmf fst (PQ x y) = x"
  1334     and y: "\<And>x y. (x, y) \<in> set_pmf pq \<Longrightarrow> map_pmf snd (PQ x y) = y"
  1335     by(metis rel_pmf.simps)
  1336 
  1337   let ?r = "bind_pmf pq (\<lambda>(x, y). PQ x y)"
  1338   have "\<And>a b. (a, b) \<in> set_pmf ?r \<Longrightarrow> P a b" by (auto intro: PQ)
  1339   moreover have "map_pmf fst ?r = join_pmf p" "map_pmf snd ?r = join_pmf q"
  1340     by (simp_all add: p q x y join_pmf_def map_bind_pmf bind_map_pmf split_def cong: bind_pmf_cong)
  1341   ultimately show ?thesis ..
  1342 qed
  1343 
  1344 lemma rel_pmf_bindI:
  1345   assumes pq: "rel_pmf R p q"
  1346   and fg: "\<And>x y. R x y \<Longrightarrow> rel_pmf P (f x) (g y)"
  1347   shows "rel_pmf P (bind_pmf p f) (bind_pmf q g)"
  1348   unfolding bind_eq_join_pmf
  1349   by (rule rel_pmf_joinI)
  1350      (auto simp add: pmf.rel_map intro: pmf.rel_mono[THEN le_funD, THEN le_funD, THEN le_boolD, THEN mp, OF _ pq] fg)
  1351 
  1352 text \<open>
  1353   Proof that @{const rel_pmf} preserves orders.
  1354   Antisymmetry proof follows Thm. 1 in N. Saheb-Djahromi, Cpo's of measures for nondeterminism,
  1355   Theoretical Computer Science 12(1):19--37, 1980,
  1356   @{url "http://dx.doi.org/10.1016/0304-3975(80)90003-1"}
  1357 \<close>
  1358 
  1359 lemma
  1360   assumes *: "rel_pmf R p q"
  1361   and refl: "reflp R" and trans: "transp R"
  1362   shows measure_Ici: "measure p {y. R x y} \<le> measure q {y. R x y}" (is ?thesis1)
  1363   and measure_Ioi: "measure p {y. R x y \<and> \<not> R y x} \<le> measure q {y. R x y \<and> \<not> R y x}" (is ?thesis2)
  1364 proof -
  1365   from * obtain pq
  1366     where pq: "\<And>x y. (x, y) \<in> set_pmf pq \<Longrightarrow> R x y"
  1367     and p: "p = map_pmf fst pq"
  1368     and q: "q = map_pmf snd pq"
  1369     by cases auto
  1370   show ?thesis1 ?thesis2 unfolding p q map_pmf_rep_eq using refl trans
  1371     by(auto 4 3 simp add: measure_distr reflpD AE_measure_pmf_iff intro!: measure_pmf.finite_measure_mono_AE dest!: pq elim: transpE)
  1372 qed
  1373 
  1374 lemma rel_pmf_inf:
  1375   fixes p q :: "'a pmf"
  1376   assumes 1: "rel_pmf R p q"
  1377   assumes 2: "rel_pmf R q p"
  1378   and refl: "reflp R" and trans: "transp R"
  1379   shows "rel_pmf (inf R R\<inverse>\<inverse>) p q"
  1380 proof (subst rel_pmf_iff_equivp, safe)
  1381   show "equivp (inf R R\<inverse>\<inverse>)"
  1382     using trans refl by (auto simp: equivp_reflp_symp_transp intro: sympI transpI reflpI dest: transpD reflpD)
  1383 
  1384   fix C assume "C \<in> UNIV // {(x, y). inf R R\<inverse>\<inverse> x y}"
  1385   then obtain x where C: "C = {y. R x y \<and> R y x}"
  1386     by (auto elim: quotientE)
  1387 
  1388   let ?R = "\<lambda>x y. R x y \<and> R y x"
  1389   let ?\<mu>R = "\<lambda>y. measure q {x. ?R x y}"
  1390   have "measure p {y. ?R x y} = measure p ({y. R x y} - {y. R x y \<and> \<not> R y x})"
  1391     by(auto intro!: arg_cong[where f="measure p"])
  1392   also have "\<dots> = measure p {y. R x y} - measure p {y. R x y \<and> \<not> R y x}"
  1393     by (rule measure_pmf.finite_measure_Diff) auto
  1394   also have "measure p {y. R x y \<and> \<not> R y x} = measure q {y. R x y \<and> \<not> R y x}"
  1395     using 1 2 refl trans by(auto intro!: Orderings.antisym measure_Ioi)
  1396   also have "measure p {y. R x y} = measure q {y. R x y}"
  1397     using 1 2 refl trans by(auto intro!: Orderings.antisym measure_Ici)
  1398   also have "measure q {y. R x y} - measure q {y. R x y \<and> \<not> R y x} =
  1399     measure q ({y. R x y} - {y. R x y \<and> \<not> R y x})"
  1400     by(rule measure_pmf.finite_measure_Diff[symmetric]) auto
  1401   also have "\<dots> = ?\<mu>R x"
  1402     by(auto intro!: arg_cong[where f="measure q"])
  1403   finally show "measure p C = measure q C"
  1404     by (simp add: C conj_commute)
  1405 qed
  1406 
  1407 lemma rel_pmf_antisym:
  1408   fixes p q :: "'a pmf"
  1409   assumes 1: "rel_pmf R p q"
  1410   assumes 2: "rel_pmf R q p"
  1411   and refl: "reflp R" and trans: "transp R" and antisym: "antisymP R"
  1412   shows "p = q"
  1413 proof -
  1414   from 1 2 refl trans have "rel_pmf (inf R R\<inverse>\<inverse>) p q" by(rule rel_pmf_inf)
  1415   also have "inf R R\<inverse>\<inverse> = op ="
  1416     using refl antisym by (auto intro!: ext simp add: reflpD dest: antisymD)
  1417   finally show ?thesis unfolding pmf.rel_eq .
  1418 qed
  1419 
  1420 lemma reflp_rel_pmf: "reflp R \<Longrightarrow> reflp (rel_pmf R)"
  1421 by(blast intro: reflpI rel_pmf_reflI reflpD)
  1422 
  1423 lemma antisymP_rel_pmf:
  1424   "\<lbrakk> reflp R; transp R; antisymP R \<rbrakk>
  1425   \<Longrightarrow> antisymP (rel_pmf R)"
  1426 by(rule antisymI)(blast intro: rel_pmf_antisym)
  1427 
  1428 lemma transp_rel_pmf:
  1429   assumes "transp R"
  1430   shows "transp (rel_pmf R)"
  1431 proof (rule transpI)
  1432   fix x y z
  1433   assume "rel_pmf R x y" and "rel_pmf R y z"
  1434   hence "rel_pmf (R OO R) x z" by (simp add: pmf.rel_compp relcompp.relcompI)
  1435   thus "rel_pmf R x z"
  1436     using assms by (metis (no_types) pmf.rel_mono rev_predicate2D transp_relcompp_less_eq)
  1437 qed
  1438 
  1439 subsection \<open> Distributions \<close>
  1440 
  1441 context
  1442 begin
  1443 
  1444 interpretation pmf_as_function .
  1445 
  1446 subsubsection \<open> Bernoulli Distribution \<close>
  1447 
  1448 lift_definition bernoulli_pmf :: "real \<Rightarrow> bool pmf" is
  1449   "\<lambda>p b. ((\<lambda>p. if b then p else 1 - p) \<circ> min 1 \<circ> max 0) p"
  1450   by (auto simp: nn_integral_count_space_finite[where A="{False, True}"] UNIV_bool
  1451            split: split_max split_min)
  1452 
  1453 lemma pmf_bernoulli_True[simp]: "0 \<le> p \<Longrightarrow> p \<le> 1 \<Longrightarrow> pmf (bernoulli_pmf p) True = p"
  1454   by transfer simp
  1455 
  1456 lemma pmf_bernoulli_False[simp]: "0 \<le> p \<Longrightarrow> p \<le> 1 \<Longrightarrow> pmf (bernoulli_pmf p) False = 1 - p"
  1457   by transfer simp
  1458 
  1459 lemma set_pmf_bernoulli[simp]: "0 < p \<Longrightarrow> p < 1 \<Longrightarrow> set_pmf (bernoulli_pmf p) = UNIV"
  1460   by (auto simp add: set_pmf_iff UNIV_bool)
  1461 
  1462 lemma nn_integral_bernoulli_pmf[simp]:
  1463   assumes [simp]: "0 \<le> p" "p \<le> 1" "\<And>x. 0 \<le> f x"
  1464   shows "(\<integral>\<^sup>+x. f x \<partial>bernoulli_pmf p) = f True * p + f False * (1 - p)"
  1465   by (subst nn_integral_measure_pmf_support[of UNIV])
  1466      (auto simp: UNIV_bool field_simps)
  1467 
  1468 lemma integral_bernoulli_pmf[simp]:
  1469   assumes [simp]: "0 \<le> p" "p \<le> 1"
  1470   shows "(\<integral>x. f x \<partial>bernoulli_pmf p) = f True * p + f False * (1 - p)"
  1471   by (subst integral_measure_pmf[of UNIV]) (auto simp: UNIV_bool)
  1472 
  1473 lemma pmf_bernoulli_half [simp]: "pmf (bernoulli_pmf (1 / 2)) x = 1 / 2"
  1474 by(cases x) simp_all
  1475 
  1476 lemma measure_pmf_bernoulli_half: "measure_pmf (bernoulli_pmf (1 / 2)) = uniform_count_measure UNIV"
  1477   by (rule measure_eqI)
  1478      (simp_all add: nn_integral_pmf[symmetric] emeasure_uniform_count_measure ennreal_divide_numeral[symmetric]
  1479                     nn_integral_count_space_finite sets_uniform_count_measure divide_ennreal_def mult_ac
  1480                     ennreal_of_nat_eq_real_of_nat)
  1481 
  1482 subsubsection \<open> Geometric Distribution \<close>
  1483 
  1484 context
  1485   fixes p :: real assumes p[arith]: "0 < p" "p \<le> 1"
  1486 begin
  1487 
  1488 lift_definition geometric_pmf :: "nat pmf" is "\<lambda>n. (1 - p)^n * p"
  1489 proof
  1490   have "(\<Sum>i. ennreal (p * (1 - p) ^ i)) = ennreal (p * (1 / (1 - (1 - p))))"
  1491     by (intro suminf_ennreal_eq sums_mult geometric_sums) auto
  1492   then show "(\<integral>\<^sup>+ x. ennreal ((1 - p)^x * p) \<partial>count_space UNIV) = 1"
  1493     by (simp add: nn_integral_count_space_nat field_simps)
  1494 qed simp
  1495 
  1496 lemma pmf_geometric[simp]: "pmf geometric_pmf n = (1 - p)^n * p"
  1497   by transfer rule
  1498 
  1499 end
  1500 
  1501 lemma set_pmf_geometric: "0 < p \<Longrightarrow> p < 1 \<Longrightarrow> set_pmf (geometric_pmf p) = UNIV"
  1502   by (auto simp: set_pmf_iff)
  1503 
  1504 subsubsection \<open> Uniform Multiset Distribution \<close>
  1505 
  1506 context
  1507   fixes M :: "'a multiset" assumes M_not_empty: "M \<noteq> {#}"
  1508 begin
  1509 
  1510 lift_definition pmf_of_multiset :: "'a pmf" is "\<lambda>x. count M x / size M"
  1511 proof
  1512   show "(\<integral>\<^sup>+ x. ennreal (real (count M x) / real (size M)) \<partial>count_space UNIV) = 1"
  1513     using M_not_empty
  1514     by (simp add: zero_less_divide_iff nn_integral_count_space nonempty_has_size
  1515                   setsum_divide_distrib[symmetric])
  1516        (auto simp: size_multiset_overloaded_eq intro!: setsum.cong)
  1517 qed simp
  1518 
  1519 lemma pmf_of_multiset[simp]: "pmf pmf_of_multiset x = count M x / size M"
  1520   by transfer rule
  1521 
  1522 lemma set_pmf_of_multiset[simp]: "set_pmf pmf_of_multiset = set_mset M"
  1523   by (auto simp: set_pmf_iff)
  1524 
  1525 end
  1526 
  1527 subsubsection \<open> Uniform Distribution \<close>
  1528 
  1529 context
  1530   fixes S :: "'a set" assumes S_not_empty: "S \<noteq> {}" and S_finite: "finite S"
  1531 begin
  1532 
  1533 lift_definition pmf_of_set :: "'a pmf" is "\<lambda>x. indicator S x / card S"
  1534 proof
  1535   show "(\<integral>\<^sup>+ x. ennreal (indicator S x / real (card S)) \<partial>count_space UNIV) = 1"
  1536     using S_not_empty S_finite
  1537     by (subst nn_integral_count_space'[of S])
  1538        (auto simp: ennreal_of_nat_eq_real_of_nat ennreal_mult[symmetric])
  1539 qed simp
  1540 
  1541 lemma pmf_of_set[simp]: "pmf pmf_of_set x = indicator S x / card S"
  1542   by transfer rule
  1543 
  1544 lemma set_pmf_of_set[simp]: "set_pmf pmf_of_set = S"
  1545   using S_finite S_not_empty by (auto simp: set_pmf_iff)
  1546 
  1547 lemma emeasure_pmf_of_set_space[simp]: "emeasure pmf_of_set S = 1"
  1548   by (rule measure_pmf.emeasure_eq_1_AE) (auto simp: AE_measure_pmf_iff)
  1549 
  1550 lemma nn_integral_pmf_of_set: "nn_integral (measure_pmf pmf_of_set) f = setsum f S / card S"
  1551   by (subst nn_integral_measure_pmf_finite)
  1552      (simp_all add: setsum_left_distrib[symmetric] card_gt_0_iff S_not_empty S_finite divide_ennreal_def
  1553                 divide_ennreal[symmetric] ennreal_of_nat_eq_real_of_nat[symmetric] ennreal_times_divide)
  1554 
  1555 lemma integral_pmf_of_set: "integral\<^sup>L (measure_pmf pmf_of_set) f = setsum f S / card S"
  1556   by (subst integral_measure_pmf[of S]) (auto simp: S_finite setsum_divide_distrib)
  1557 
  1558 lemma emeasure_pmf_of_set: "emeasure (measure_pmf pmf_of_set) A = card (S \<inter> A) / card S"
  1559   by (subst nn_integral_indicator[symmetric], simp)
  1560      (simp add: S_finite S_not_empty card_gt_0_iff indicator_def setsum.If_cases divide_ennreal
  1561                 ennreal_of_nat_eq_real_of_nat nn_integral_pmf_of_set)
  1562 
  1563 lemma measure_pmf_of_set: "measure (measure_pmf pmf_of_set) A = card (S \<inter> A) / card S"
  1564   using emeasure_pmf_of_set[OF assms, of A]
  1565   by (simp add: measure_nonneg measure_pmf.emeasure_eq_measure)
  1566 
  1567 end
  1568 
  1569 lemma pmf_of_set_singleton: "pmf_of_set {x} = return_pmf x"
  1570 by(rule pmf_eqI)(simp add: indicator_def)
  1571 
  1572 lemma map_pmf_of_set_inj:
  1573   assumes f: "inj_on f A"
  1574   and [simp]: "A \<noteq> {}" "finite A"
  1575   shows "map_pmf f (pmf_of_set A) = pmf_of_set (f ` A)" (is "?lhs = ?rhs")
  1576 proof(rule pmf_eqI)
  1577   fix i
  1578   show "pmf ?lhs i = pmf ?rhs i"
  1579   proof(cases "i \<in> f ` A")
  1580     case True
  1581     then obtain i' where "i = f i'" "i' \<in> A" by auto
  1582     thus ?thesis using f by(simp add: card_image pmf_map_inj)
  1583   next
  1584     case False
  1585     hence "pmf ?lhs i = 0" by(simp add: pmf_eq_0_set_pmf set_map_pmf)
  1586     moreover have "pmf ?rhs i = 0" using False by simp
  1587     ultimately show ?thesis by simp
  1588   qed
  1589 qed
  1590 
  1591 lemma bernoulli_pmf_half_conv_pmf_of_set: "bernoulli_pmf (1 / 2) = pmf_of_set UNIV"
  1592   by (rule pmf_eqI) simp_all
  1593 
  1594 subsubsection \<open> Poisson Distribution \<close>
  1595 
  1596 context
  1597   fixes rate :: real assumes rate_pos: "0 < rate"
  1598 begin
  1599 
  1600 lift_definition poisson_pmf :: "nat pmf" is "\<lambda>k. rate ^ k / fact k * exp (-rate)"
  1601 proof  (* by Manuel Eberl *)
  1602   have summable: "summable (\<lambda>x::nat. rate ^ x / fact x)" using summable_exp
  1603     by (simp add: field_simps divide_inverse [symmetric])
  1604   have "(\<integral>\<^sup>+(x::nat). rate ^ x / fact x * exp (-rate) \<partial>count_space UNIV) =
  1605           exp (-rate) * (\<integral>\<^sup>+(x::nat). rate ^ x / fact x \<partial>count_space UNIV)"
  1606     by (simp add: field_simps nn_integral_cmult[symmetric] ennreal_mult'[symmetric])
  1607   also from rate_pos have "(\<integral>\<^sup>+(x::nat). rate ^ x / fact x \<partial>count_space UNIV) = (\<Sum>x. rate ^ x / fact x)"
  1608     by (simp_all add: nn_integral_count_space_nat suminf_ennreal summable ennreal_suminf_neq_top)
  1609   also have "... = exp rate" unfolding exp_def
  1610     by (simp add: field_simps divide_inverse [symmetric])
  1611   also have "ennreal (exp (-rate)) * ennreal (exp rate) = 1"
  1612     by (simp add: mult_exp_exp ennreal_mult[symmetric])
  1613   finally show "(\<integral>\<^sup>+ x. ennreal (rate ^ x / (fact x) * exp (- rate)) \<partial>count_space UNIV) = 1" .
  1614 qed (simp add: rate_pos[THEN less_imp_le])
  1615 
  1616 lemma pmf_poisson[simp]: "pmf poisson_pmf k = rate ^ k / fact k * exp (-rate)"
  1617   by transfer rule
  1618 
  1619 lemma set_pmf_poisson[simp]: "set_pmf poisson_pmf = UNIV"
  1620   using rate_pos by (auto simp: set_pmf_iff)
  1621 
  1622 end
  1623 
  1624 subsubsection \<open> Binomial Distribution \<close>
  1625 
  1626 context
  1627   fixes n :: nat and p :: real assumes p_nonneg: "0 \<le> p" and p_le_1: "p \<le> 1"
  1628 begin
  1629 
  1630 lift_definition binomial_pmf :: "nat pmf" is "\<lambda>k. (n choose k) * p^k * (1 - p)^(n - k)"
  1631 proof
  1632   have "(\<integral>\<^sup>+k. ennreal (real (n choose k) * p ^ k * (1 - p) ^ (n - k)) \<partial>count_space UNIV) =
  1633     ennreal (\<Sum>k\<le>n. real (n choose k) * p ^ k * (1 - p) ^ (n - k))"
  1634     using p_le_1 p_nonneg by (subst nn_integral_count_space') auto
  1635   also have "(\<Sum>k\<le>n. real (n choose k) * p ^ k * (1 - p) ^ (n - k)) = (p + (1 - p)) ^ n"
  1636     by (subst binomial_ring) (simp add: atLeast0AtMost)
  1637   finally show "(\<integral>\<^sup>+ x. ennreal (real (n choose x) * p ^ x * (1 - p) ^ (n - x)) \<partial>count_space UNIV) = 1"
  1638     by simp
  1639 qed (insert p_nonneg p_le_1, simp)
  1640 
  1641 lemma pmf_binomial[simp]: "pmf binomial_pmf k = (n choose k) * p^k * (1 - p)^(n - k)"
  1642   by transfer rule
  1643 
  1644 lemma set_pmf_binomial_eq: "set_pmf binomial_pmf = (if p = 0 then {0} else if p = 1 then {n} else {.. n})"
  1645   using p_nonneg p_le_1 unfolding set_eq_iff set_pmf_iff pmf_binomial by (auto simp: set_pmf_iff)
  1646 
  1647 end
  1648 
  1649 end
  1650 
  1651 lemma set_pmf_binomial_0[simp]: "set_pmf (binomial_pmf n 0) = {0}"
  1652   by (simp add: set_pmf_binomial_eq)
  1653 
  1654 lemma set_pmf_binomial_1[simp]: "set_pmf (binomial_pmf n 1) = {n}"
  1655   by (simp add: set_pmf_binomial_eq)
  1656 
  1657 lemma set_pmf_binomial[simp]: "0 < p \<Longrightarrow> p < 1 \<Longrightarrow> set_pmf (binomial_pmf n p) = {..n}"
  1658   by (simp add: set_pmf_binomial_eq)
  1659 
  1660 context begin interpretation lifting_syntax .
  1661 
  1662 lemma bind_pmf_parametric [transfer_rule]:
  1663   "(rel_pmf A ===> (A ===> rel_pmf B) ===> rel_pmf B) bind_pmf bind_pmf"
  1664 by(blast intro: rel_pmf_bindI dest: rel_funD)
  1665 
  1666 lemma return_pmf_parametric [transfer_rule]: "(A ===> rel_pmf A) return_pmf return_pmf"
  1667 by(rule rel_funI) simp
  1668 
  1669 end
  1670 
  1671 end