src/HOL/Set.ML
author paulson
Thu Aug 06 10:47:13 1998 +0200 (1998-08-06)
changeset 5266 1d11c7e4b999
parent 5256 e6983301ce5e
child 5305 513925de8962
permissions -rw-r--r--
Now recognizes both {}= and ={}
     1 (*  Title:      HOL/set
     2     ID:         $Id$
     3     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     4     Copyright   1991  University of Cambridge
     5 
     6 Set theory for higher-order logic.  A set is simply a predicate.
     7 *)
     8 
     9 open Set;
    10 
    11 section "Relating predicates and sets";
    12 
    13 Addsimps [Collect_mem_eq];
    14 AddIffs  [mem_Collect_eq];
    15 
    16 Goal "P(a) ==> a : {x. P(x)}";
    17 by (Asm_simp_tac 1);
    18 qed "CollectI";
    19 
    20 val prems = goal Set.thy "!!a. a : {x. P(x)} ==> P(a)";
    21 by (Asm_full_simp_tac 1);
    22 qed "CollectD";
    23 
    24 val [prem] = goal Set.thy "[| !!x. (x:A) = (x:B) |] ==> A = B";
    25 by (rtac (prem RS ext RS arg_cong RS box_equals) 1);
    26 by (rtac Collect_mem_eq 1);
    27 by (rtac Collect_mem_eq 1);
    28 qed "set_ext";
    29 
    30 val [prem] = goal Set.thy "[| !!x. P(x)=Q(x) |] ==> {x. P(x)} = {x. Q(x)}";
    31 by (rtac (prem RS ext RS arg_cong) 1);
    32 qed "Collect_cong";
    33 
    34 val CollectE = make_elim CollectD;
    35 
    36 AddSIs [CollectI];
    37 AddSEs [CollectE];
    38 
    39 
    40 section "Bounded quantifiers";
    41 
    42 val prems = goalw Set.thy [Ball_def]
    43     "[| !!x. x:A ==> P(x) |] ==> ! x:A. P(x)";
    44 by (REPEAT (ares_tac (prems @ [allI,impI]) 1));
    45 qed "ballI";
    46 
    47 val [major,minor] = goalw Set.thy [Ball_def]
    48     "[| ! x:A. P(x);  x:A |] ==> P(x)";
    49 by (rtac (minor RS (major RS spec RS mp)) 1);
    50 qed "bspec";
    51 
    52 val major::prems = goalw Set.thy [Ball_def]
    53     "[| ! x:A. P(x);  P(x) ==> Q;  x~:A ==> Q |] ==> Q";
    54 by (rtac (major RS spec RS impCE) 1);
    55 by (REPEAT (eresolve_tac prems 1));
    56 qed "ballE";
    57 
    58 (*Takes assumptions ! x:A.P(x) and a:A; creates assumption P(a)*)
    59 fun ball_tac i = etac ballE i THEN contr_tac (i+1);
    60 
    61 AddSIs [ballI];
    62 AddEs  [ballE];
    63 
    64 val prems = goalw Set.thy [Bex_def]
    65     "[| P(x);  x:A |] ==> ? x:A. P(x)";
    66 by (REPEAT (ares_tac (prems @ [exI,conjI]) 1));
    67 qed "bexI";
    68 
    69 qed_goal "bexCI" Set.thy 
    70    "[| ! x:A. ~P(x) ==> P(a);  a:A |] ==> ? x:A. P(x)"
    71  (fn prems=>
    72   [ (rtac classical 1),
    73     (REPEAT (ares_tac (prems@[bexI,ballI,notI,notE]) 1))  ]);
    74 
    75 val major::prems = goalw Set.thy [Bex_def]
    76     "[| ? x:A. P(x);  !!x. [| x:A; P(x) |] ==> Q  |] ==> Q";
    77 by (rtac (major RS exE) 1);
    78 by (REPEAT (eresolve_tac (prems @ [asm_rl,conjE]) 1));
    79 qed "bexE";
    80 
    81 AddIs  [bexI];
    82 AddSEs [bexE];
    83 
    84 (*Trival rewrite rule*)
    85 Goal "(! x:A. P) = ((? x. x:A) --> P)";
    86 by (simp_tac (simpset() addsimps [Ball_def]) 1);
    87 qed "ball_triv";
    88 
    89 (*Dual form for existentials*)
    90 Goal "(? x:A. P) = ((? x. x:A) & P)";
    91 by (simp_tac (simpset() addsimps [Bex_def]) 1);
    92 qed "bex_triv";
    93 
    94 Addsimps [ball_triv, bex_triv];
    95 
    96 (** Congruence rules **)
    97 
    98 val prems = goal Set.thy
    99     "[| A=B;  !!x. x:B ==> P(x) = Q(x) |] ==> \
   100 \    (! x:A. P(x)) = (! x:B. Q(x))";
   101 by (resolve_tac (prems RL [ssubst]) 1);
   102 by (REPEAT (ares_tac [ballI,iffI] 1
   103      ORELSE eresolve_tac ([make_elim bspec, mp] @ (prems RL [iffE])) 1));
   104 qed "ball_cong";
   105 
   106 val prems = goal Set.thy
   107     "[| A=B;  !!x. x:B ==> P(x) = Q(x) |] ==> \
   108 \    (? x:A. P(x)) = (? x:B. Q(x))";
   109 by (resolve_tac (prems RL [ssubst]) 1);
   110 by (REPEAT (etac bexE 1
   111      ORELSE ares_tac ([bexI,iffI] @ (prems RL [iffD1,iffD2])) 1));
   112 qed "bex_cong";
   113 
   114 section "Subsets";
   115 
   116 val prems = goalw Set.thy [subset_def] "(!!x. x:A ==> x:B) ==> A <= B";
   117 by (REPEAT (ares_tac (prems @ [ballI]) 1));
   118 qed "subsetI";
   119 
   120 Blast.overloaded ("op <=", domain_type); (*The <= relation is overloaded*)
   121 
   122 (*While (:) is not, its type must be kept
   123   for overloading of = to work.*)
   124 Blast.overloaded ("op :", domain_type);
   125 seq (fn a => Blast.overloaded (a, HOLogic.dest_setT o domain_type))
   126     ["Ball", "Bex"];
   127 (*need UNION, INTER also?*)
   128 
   129 (*Image: retain the type of the set being expressed*)
   130 Blast.overloaded ("op ``", domain_type o domain_type);
   131 
   132 (*Rule in Modus Ponens style*)
   133 val major::prems = goalw Set.thy [subset_def] "[| A <= B;  c:A |] ==> c:B";
   134 by (rtac (major RS bspec) 1);
   135 by (resolve_tac prems 1);
   136 qed "subsetD";
   137 
   138 (*The same, with reversed premises for use with etac -- cf rev_mp*)
   139 qed_goal "rev_subsetD" Set.thy "[| c:A;  A <= B |] ==> c:B"
   140  (fn prems=>  [ (REPEAT (resolve_tac (prems@[subsetD]) 1)) ]);
   141 
   142 (*Converts A<=B to x:A ==> x:B*)
   143 fun impOfSubs th = th RSN (2, rev_subsetD);
   144 
   145 qed_goal "contra_subsetD" Set.thy "!!c. [| A <= B; c ~: B |] ==> c ~: A"
   146  (fn prems=>  [ (REPEAT (eresolve_tac [asm_rl, contrapos, subsetD] 1)) ]);
   147 
   148 qed_goal "rev_contra_subsetD" Set.thy "!!c. [| c ~: B;  A <= B |] ==> c ~: A"
   149  (fn prems=>  [ (REPEAT (eresolve_tac [asm_rl, contrapos, subsetD] 1)) ]);
   150 
   151 (*Classical elimination rule*)
   152 val major::prems = goalw Set.thy [subset_def] 
   153     "[| A <= B;  c~:A ==> P;  c:B ==> P |] ==> P";
   154 by (rtac (major RS ballE) 1);
   155 by (REPEAT (eresolve_tac prems 1));
   156 qed "subsetCE";
   157 
   158 (*Takes assumptions A<=B; c:A and creates the assumption c:B *)
   159 fun set_mp_tac i = etac subsetCE i  THEN  mp_tac i;
   160 
   161 AddSIs [subsetI];
   162 AddEs  [subsetD, subsetCE];
   163 
   164 qed_goal "subset_refl" Set.thy "A <= (A::'a set)"
   165  (fn _=> [Fast_tac 1]);		(*Blast_tac would try order_refl and fail*)
   166 
   167 val prems = goal Set.thy "!!B. [| A<=B;  B<=C |] ==> A<=(C::'a set)";
   168 by (Blast_tac 1);
   169 qed "subset_trans";
   170 
   171 
   172 section "Equality";
   173 
   174 (*Anti-symmetry of the subset relation*)
   175 val prems = goal Set.thy "[| A <= B;  B <= A |] ==> A = (B::'a set)";
   176 by (rtac (iffI RS set_ext) 1);
   177 by (REPEAT (ares_tac (prems RL [subsetD]) 1));
   178 qed "subset_antisym";
   179 val equalityI = subset_antisym;
   180 
   181 AddSIs [equalityI];
   182 
   183 (* Equality rules from ZF set theory -- are they appropriate here? *)
   184 val prems = goal Set.thy "A = B ==> A<=(B::'a set)";
   185 by (resolve_tac (prems RL [subst]) 1);
   186 by (rtac subset_refl 1);
   187 qed "equalityD1";
   188 
   189 val prems = goal Set.thy "A = B ==> B<=(A::'a set)";
   190 by (resolve_tac (prems RL [subst]) 1);
   191 by (rtac subset_refl 1);
   192 qed "equalityD2";
   193 
   194 val prems = goal Set.thy
   195     "[| A = B;  [| A<=B; B<=(A::'a set) |] ==> P |]  ==>  P";
   196 by (resolve_tac prems 1);
   197 by (REPEAT (resolve_tac (prems RL [equalityD1,equalityD2]) 1));
   198 qed "equalityE";
   199 
   200 val major::prems = goal Set.thy
   201     "[| A = B;  [| c:A; c:B |] ==> P;  [| c~:A; c~:B |] ==> P |]  ==>  P";
   202 by (rtac (major RS equalityE) 1);
   203 by (REPEAT (contr_tac 1 ORELSE eresolve_tac ([asm_rl,subsetCE]@prems) 1));
   204 qed "equalityCE";
   205 
   206 (*Lemma for creating induction formulae -- for "pattern matching" on p
   207   To make the induction hypotheses usable, apply "spec" or "bspec" to
   208   put universal quantifiers over the free variables in p. *)
   209 val prems = goal Set.thy 
   210     "[| p:A;  !!z. z:A ==> p=z --> R |] ==> R";
   211 by (rtac mp 1);
   212 by (REPEAT (resolve_tac (refl::prems) 1));
   213 qed "setup_induction";
   214 
   215 
   216 section "The universal set -- UNIV";
   217 
   218 qed_goalw "UNIV_I" Set.thy [UNIV_def] "x : UNIV"
   219   (fn _ => [rtac CollectI 1, rtac TrueI 1]);
   220 
   221 Addsimps [UNIV_I];
   222 AddIs    [UNIV_I];  (*unsafe makes it less likely to cause problems*)
   223 
   224 qed_goal "subset_UNIV" Set.thy "A <= UNIV"
   225   (fn _ => [rtac subsetI 1, rtac UNIV_I 1]);
   226 
   227 (** Eta-contracting these two rules (to remove P) causes them to be ignored
   228     because of their interaction with congruence rules. **)
   229 
   230 Goalw [Ball_def] "Ball UNIV P = All P";
   231 by (Simp_tac 1);
   232 qed "ball_UNIV";
   233 
   234 Goalw [Bex_def] "Bex UNIV P = Ex P";
   235 by (Simp_tac 1);
   236 qed "bex_UNIV";
   237 Addsimps [ball_UNIV, bex_UNIV];
   238 
   239 
   240 section "The empty set -- {}";
   241 
   242 qed_goalw "empty_iff" Set.thy [empty_def] "(c : {}) = False"
   243  (fn _ => [ (Blast_tac 1) ]);
   244 
   245 Addsimps [empty_iff];
   246 
   247 qed_goal "emptyE" Set.thy "!!a. a:{} ==> P"
   248  (fn _ => [Full_simp_tac 1]);
   249 
   250 AddSEs [emptyE];
   251 
   252 qed_goal "empty_subsetI" Set.thy "{} <= A"
   253  (fn _ => [ (Blast_tac 1) ]);
   254 
   255 (*One effect is to delete the ASSUMPTION {} <= A*)
   256 AddIffs [empty_subsetI];
   257 
   258 qed_goal "equals0I" Set.thy "[| !!y. y:A ==> False |] ==> A={}"
   259  (fn [prem]=>
   260   [ (blast_tac (claset() addIs [prem RS FalseE]) 1) ]);
   261 
   262 (*Use for reasoning about disjointness: A Int B = {} *)
   263 qed_goal "equals0E" Set.thy "!!a. [| A={};  a:A |] ==> P"
   264  (fn _ => [ (Blast_tac 1) ]);
   265 
   266 AddEs [equals0E, sym RS equals0E];
   267 
   268 Goalw [Ball_def] "Ball {} P = True";
   269 by (Simp_tac 1);
   270 qed "ball_empty";
   271 
   272 Goalw [Bex_def] "Bex {} P = False";
   273 by (Simp_tac 1);
   274 qed "bex_empty";
   275 Addsimps [ball_empty, bex_empty];
   276 
   277 Goal "UNIV ~= {}";
   278 by (blast_tac (claset() addEs [equalityE]) 1);
   279 qed "UNIV_not_empty";
   280 AddIffs [UNIV_not_empty];
   281 
   282 
   283 
   284 section "The Powerset operator -- Pow";
   285 
   286 qed_goalw "Pow_iff" Set.thy [Pow_def] "(A : Pow(B)) = (A <= B)"
   287  (fn _ => [ (Asm_simp_tac 1) ]);
   288 
   289 AddIffs [Pow_iff]; 
   290 
   291 qed_goalw "PowI" Set.thy [Pow_def] "!!A B. A <= B ==> A : Pow(B)"
   292  (fn _ => [ (etac CollectI 1) ]);
   293 
   294 qed_goalw "PowD" Set.thy [Pow_def] "!!A B. A : Pow(B)  ==>  A<=B"
   295  (fn _=> [ (etac CollectD 1) ]);
   296 
   297 val Pow_bottom = empty_subsetI RS PowI;        (* {}: Pow(B) *)
   298 val Pow_top = subset_refl RS PowI;             (* A : Pow(A) *)
   299 
   300 
   301 section "Set complement -- Compl";
   302 
   303 qed_goalw "Compl_iff" Set.thy [Compl_def] "(c : Compl(A)) = (c~:A)"
   304  (fn _ => [ (Blast_tac 1) ]);
   305 
   306 Addsimps [Compl_iff];
   307 
   308 val prems = goalw Set.thy [Compl_def]
   309     "[| c:A ==> False |] ==> c : Compl(A)";
   310 by (REPEAT (ares_tac (prems @ [CollectI,notI]) 1));
   311 qed "ComplI";
   312 
   313 (*This form, with negated conclusion, works well with the Classical prover.
   314   Negated assumptions behave like formulae on the right side of the notional
   315   turnstile...*)
   316 val major::prems = goalw Set.thy [Compl_def]
   317     "c : Compl(A) ==> c~:A";
   318 by (rtac (major RS CollectD) 1);
   319 qed "ComplD";
   320 
   321 val ComplE = make_elim ComplD;
   322 
   323 AddSIs [ComplI];
   324 AddSEs [ComplE];
   325 
   326 
   327 section "Binary union -- Un";
   328 
   329 qed_goalw "Un_iff" Set.thy [Un_def] "(c : A Un B) = (c:A | c:B)"
   330  (fn _ => [ Blast_tac 1 ]);
   331 
   332 Addsimps [Un_iff];
   333 
   334 Goal "c:A ==> c : A Un B";
   335 by (Asm_simp_tac 1);
   336 qed "UnI1";
   337 
   338 Goal "c:B ==> c : A Un B";
   339 by (Asm_simp_tac 1);
   340 qed "UnI2";
   341 
   342 (*Classical introduction rule: no commitment to A vs B*)
   343 qed_goal "UnCI" Set.thy "(c~:B ==> c:A) ==> c : A Un B"
   344  (fn prems=>
   345   [ (Simp_tac 1),
   346     (REPEAT (ares_tac (prems@[disjCI]) 1)) ]);
   347 
   348 val major::prems = goalw Set.thy [Un_def]
   349     "[| c : A Un B;  c:A ==> P;  c:B ==> P |] ==> P";
   350 by (rtac (major RS CollectD RS disjE) 1);
   351 by (REPEAT (eresolve_tac prems 1));
   352 qed "UnE";
   353 
   354 AddSIs [UnCI];
   355 AddSEs [UnE];
   356 
   357 
   358 section "Binary intersection -- Int";
   359 
   360 qed_goalw "Int_iff" Set.thy [Int_def] "(c : A Int B) = (c:A & c:B)"
   361  (fn _ => [ (Blast_tac 1) ]);
   362 
   363 Addsimps [Int_iff];
   364 
   365 Goal "[| c:A;  c:B |] ==> c : A Int B";
   366 by (Asm_simp_tac 1);
   367 qed "IntI";
   368 
   369 Goal "c : A Int B ==> c:A";
   370 by (Asm_full_simp_tac 1);
   371 qed "IntD1";
   372 
   373 Goal "c : A Int B ==> c:B";
   374 by (Asm_full_simp_tac 1);
   375 qed "IntD2";
   376 
   377 val [major,minor] = goal Set.thy
   378     "[| c : A Int B;  [| c:A; c:B |] ==> P |] ==> P";
   379 by (rtac minor 1);
   380 by (rtac (major RS IntD1) 1);
   381 by (rtac (major RS IntD2) 1);
   382 qed "IntE";
   383 
   384 AddSIs [IntI];
   385 AddSEs [IntE];
   386 
   387 section "Set difference";
   388 
   389 qed_goalw "Diff_iff" Set.thy [set_diff_def] "(c : A-B) = (c:A & c~:B)"
   390  (fn _ => [ (Blast_tac 1) ]);
   391 
   392 Addsimps [Diff_iff];
   393 
   394 qed_goal "DiffI" Set.thy "!!c. [| c : A;  c ~: B |] ==> c : A - B"
   395  (fn _=> [ Asm_simp_tac 1 ]);
   396 
   397 qed_goal "DiffD1" Set.thy "!!c. c : A - B ==> c : A"
   398  (fn _=> [ (Asm_full_simp_tac 1) ]);
   399 
   400 qed_goal "DiffD2" Set.thy "!!c. [| c : A - B;  c : B |] ==> P"
   401  (fn _=> [ (Asm_full_simp_tac 1) ]);
   402 
   403 qed_goal "DiffE" Set.thy "[| c : A - B;  [| c:A; c~:B |] ==> P |] ==> P"
   404  (fn prems=>
   405   [ (resolve_tac prems 1),
   406     (REPEAT (ares_tac (prems RL [DiffD1, DiffD2 RS notI]) 1)) ]);
   407 
   408 AddSIs [DiffI];
   409 AddSEs [DiffE];
   410 
   411 
   412 section "Augmenting a set -- insert";
   413 
   414 qed_goalw "insert_iff" Set.thy [insert_def] "a : insert b A = (a=b | a:A)"
   415  (fn _ => [Blast_tac 1]);
   416 
   417 Addsimps [insert_iff];
   418 
   419 qed_goal "insertI1" Set.thy "a : insert a B"
   420  (fn _ => [Simp_tac 1]);
   421 
   422 qed_goal "insertI2" Set.thy "!!a. a : B ==> a : insert b B"
   423  (fn _=> [Asm_simp_tac 1]);
   424 
   425 qed_goalw "insertE" Set.thy [insert_def]
   426     "[| a : insert b A;  a=b ==> P;  a:A ==> P |] ==> P"
   427  (fn major::prems=>
   428   [ (rtac (major RS UnE) 1),
   429     (REPEAT (eresolve_tac (prems @ [CollectE]) 1)) ]);
   430 
   431 (*Classical introduction rule*)
   432 qed_goal "insertCI" Set.thy "(a~:B ==> a=b) ==> a: insert b B"
   433  (fn prems=>
   434   [ (Simp_tac 1),
   435     (REPEAT (ares_tac (prems@[disjCI]) 1)) ]);
   436 
   437 AddSIs [insertCI]; 
   438 AddSEs [insertE];
   439 
   440 section "Singletons, using insert";
   441 
   442 qed_goal "singletonI" Set.thy "a : {a}"
   443  (fn _=> [ (rtac insertI1 1) ]);
   444 
   445 Goal "b : {a} ==> b=a";
   446 by (Blast_tac 1);
   447 qed "singletonD";
   448 
   449 bind_thm ("singletonE", make_elim singletonD);
   450 
   451 qed_goal "singleton_iff" thy "(b : {a}) = (b=a)" 
   452 (fn _ => [Blast_tac 1]);
   453 
   454 Goal "{a}={b} ==> a=b";
   455 by (blast_tac (claset() addEs [equalityE]) 1);
   456 qed "singleton_inject";
   457 
   458 (*Redundant? But unlike insertCI, it proves the subgoal immediately!*)
   459 AddSIs [singletonI];   
   460 AddSDs [singleton_inject];
   461 AddSEs [singletonE];
   462 
   463 Goal "{x. x=a} = {a}";
   464 by (Blast_tac 1);
   465 qed "singleton_conv";
   466 Addsimps [singleton_conv];
   467 
   468 
   469 section "Unions of families -- UNION x:A. B(x) is Union(B``A)";
   470 
   471 Goalw [UNION_def] "(b: (UN x:A. B(x))) = (EX x:A. b: B(x))";
   472 by (Blast_tac 1);
   473 qed "UN_iff";
   474 
   475 Addsimps [UN_iff];
   476 
   477 (*The order of the premises presupposes that A is rigid; b may be flexible*)
   478 Goal "[| a:A;  b: B(a) |] ==> b: (UN x:A. B(x))";
   479 by Auto_tac;
   480 qed "UN_I";
   481 
   482 val major::prems = goalw Set.thy [UNION_def]
   483     "[| b : (UN x:A. B(x));  !!x.[| x:A;  b: B(x) |] ==> R |] ==> R";
   484 by (rtac (major RS CollectD RS bexE) 1);
   485 by (REPEAT (ares_tac prems 1));
   486 qed "UN_E";
   487 
   488 AddIs  [UN_I];
   489 AddSEs [UN_E];
   490 
   491 val prems = goal Set.thy
   492     "[| A=B;  !!x. x:B ==> C(x) = D(x) |] ==> \
   493 \    (UN x:A. C(x)) = (UN x:B. D(x))";
   494 by (REPEAT (etac UN_E 1
   495      ORELSE ares_tac ([UN_I,equalityI,subsetI] @ 
   496                       (prems RL [equalityD1,equalityD2] RL [subsetD])) 1));
   497 qed "UN_cong";
   498 
   499 
   500 section "Intersections of families -- INTER x:A. B(x) is Inter(B``A)";
   501 
   502 Goalw [INTER_def] "(b: (INT x:A. B(x))) = (ALL x:A. b: B(x))";
   503 by Auto_tac;
   504 qed "INT_iff";
   505 
   506 Addsimps [INT_iff];
   507 
   508 val prems = goalw Set.thy [INTER_def]
   509     "(!!x. x:A ==> b: B(x)) ==> b : (INT x:A. B(x))";
   510 by (REPEAT (ares_tac ([CollectI,ballI] @ prems) 1));
   511 qed "INT_I";
   512 
   513 Goal "[| b : (INT x:A. B(x));  a:A |] ==> b: B(a)";
   514 by Auto_tac;
   515 qed "INT_D";
   516 
   517 (*"Classical" elimination -- by the Excluded Middle on a:A *)
   518 val major::prems = goalw Set.thy [INTER_def]
   519     "[| b : (INT x:A. B(x));  b: B(a) ==> R;  a~:A ==> R |] ==> R";
   520 by (rtac (major RS CollectD RS ballE) 1);
   521 by (REPEAT (eresolve_tac prems 1));
   522 qed "INT_E";
   523 
   524 AddSIs [INT_I];
   525 AddEs  [INT_D, INT_E];
   526 
   527 val prems = goal Set.thy
   528     "[| A=B;  !!x. x:B ==> C(x) = D(x) |] ==> \
   529 \    (INT x:A. C(x)) = (INT x:B. D(x))";
   530 by (REPEAT_FIRST (resolve_tac [INT_I,equalityI,subsetI]));
   531 by (REPEAT (dtac INT_D 1
   532      ORELSE ares_tac (prems RL [equalityD1,equalityD2] RL [subsetD]) 1));
   533 qed "INT_cong";
   534 
   535 
   536 section "Union";
   537 
   538 Goalw [Union_def] "(A : Union(C)) = (EX X:C. A:X)";
   539 by (Blast_tac 1);
   540 qed "Union_iff";
   541 
   542 Addsimps [Union_iff];
   543 
   544 (*The order of the premises presupposes that C is rigid; A may be flexible*)
   545 Goal "[| X:C;  A:X |] ==> A : Union(C)";
   546 by Auto_tac;
   547 qed "UnionI";
   548 
   549 val major::prems = goalw Set.thy [Union_def]
   550     "[| A : Union(C);  !!X.[| A:X;  X:C |] ==> R |] ==> R";
   551 by (rtac (major RS UN_E) 1);
   552 by (REPEAT (ares_tac prems 1));
   553 qed "UnionE";
   554 
   555 AddIs  [UnionI];
   556 AddSEs [UnionE];
   557 
   558 
   559 section "Inter";
   560 
   561 Goalw [Inter_def] "(A : Inter(C)) = (ALL X:C. A:X)";
   562 by (Blast_tac 1);
   563 qed "Inter_iff";
   564 
   565 Addsimps [Inter_iff];
   566 
   567 val prems = goalw Set.thy [Inter_def]
   568     "[| !!X. X:C ==> A:X |] ==> A : Inter(C)";
   569 by (REPEAT (ares_tac ([INT_I] @ prems) 1));
   570 qed "InterI";
   571 
   572 (*A "destruct" rule -- every X in C contains A as an element, but
   573   A:X can hold when X:C does not!  This rule is analogous to "spec". *)
   574 Goal "[| A : Inter(C);  X:C |] ==> A:X";
   575 by Auto_tac;
   576 qed "InterD";
   577 
   578 (*"Classical" elimination rule -- does not require proving X:C *)
   579 val major::prems = goalw Set.thy [Inter_def]
   580     "[| A : Inter(C);  X~:C ==> R;  A:X ==> R |] ==> R";
   581 by (rtac (major RS INT_E) 1);
   582 by (REPEAT (eresolve_tac prems 1));
   583 qed "InterE";
   584 
   585 AddSIs [InterI];
   586 AddEs  [InterD, InterE];
   587 
   588 
   589 (*** Image of a set under a function ***)
   590 
   591 (*Frequently b does not have the syntactic form of f(x).*)
   592 val prems = goalw thy [image_def] "[| b=f(x);  x:A |] ==> b : f``A";
   593 by (REPEAT (resolve_tac (prems @ [CollectI,bexI,prem]) 1));
   594 qed "image_eqI";
   595 Addsimps [image_eqI];
   596 
   597 bind_thm ("imageI", refl RS image_eqI);
   598 
   599 (*The eta-expansion gives variable-name preservation.*)
   600 val major::prems = goalw thy [image_def]
   601     "[| b : (%x. f(x))``A;  !!x.[| b=f(x);  x:A |] ==> P |] ==> P"; 
   602 by (rtac (major RS CollectD RS bexE) 1);
   603 by (REPEAT (ares_tac prems 1));
   604 qed "imageE";
   605 
   606 AddIs  [image_eqI];
   607 AddSEs [imageE]; 
   608 
   609 Goalw [o_def] "(f o g)``r = f``(g``r)";
   610 by (Blast_tac 1);
   611 qed "image_compose";
   612 
   613 Goal "f``(A Un B) = f``A Un f``B";
   614 by (Blast_tac 1);
   615 qed "image_Un";
   616 
   617 Goal "(z : f``A) = (EX x:A. z = f x)";
   618 by (Blast_tac 1);
   619 qed "image_iff";
   620 
   621 (*This rewrite rule would confuse users if made default.*)
   622 Goal "(f``A <= B) = (ALL x:A. f(x): B)";
   623 by (Blast_tac 1);
   624 qed "image_subset_iff";
   625 
   626 (*Replaces the three steps subsetI, imageE, hyp_subst_tac, but breaks too
   627   many existing proofs.*)
   628 val prems = goal thy "(!!x. x:A ==> f(x) : B) ==> f``A <= B";
   629 by (blast_tac (claset() addIs prems) 1);
   630 qed "image_subsetI";
   631 
   632 
   633 (*** Range of a function -- just a translation for image! ***)
   634 
   635 Goal "b=f(x) ==> b : range(f)";
   636 by (EVERY1 [etac image_eqI, rtac UNIV_I]);
   637 bind_thm ("range_eqI", UNIV_I RSN (2,image_eqI));
   638 
   639 bind_thm ("rangeI", UNIV_I RS imageI);
   640 
   641 val [major,minor] = goal thy 
   642     "[| b : range(%x. f(x));  !!x. b=f(x) ==> P |] ==> P"; 
   643 by (rtac (major RS imageE) 1);
   644 by (etac minor 1);
   645 qed "rangeE";
   646 
   647 
   648 (*** Set reasoning tools ***)
   649 
   650 
   651 (** Rewrite rules for boolean case-splitting: faster than 
   652 	addsplits[split_if]
   653 **)
   654 
   655 bind_thm ("split_if_eq1", read_instantiate [("P", "%x. x = ?b")] split_if);
   656 bind_thm ("split_if_eq2", read_instantiate [("P", "%x. ?a = x")] split_if);
   657 
   658 (*Split ifs on either side of the membership relation.
   659 	Not for Addsimps -- can cause goals to blow up!*)
   660 bind_thm ("split_if_mem1", 
   661     read_instantiate_sg (sign_of Set.thy) [("P", "%x. x : ?b")] split_if);
   662 bind_thm ("split_if_mem2", 
   663     read_instantiate_sg (sign_of Set.thy) [("P", "%x. ?a : x")] split_if);
   664 
   665 val split_ifs = [if_bool_eq_conj, split_if_eq1, split_if_eq2,
   666 		  split_if_mem1, split_if_mem2];
   667 
   668 
   669 (*Each of these has ALREADY been added to simpset() above.*)
   670 val mem_simps = [insert_iff, empty_iff, Un_iff, Int_iff, Compl_iff, Diff_iff, 
   671                  mem_Collect_eq, UN_iff, Union_iff, INT_iff, Inter_iff];
   672 
   673 val mksimps_pairs = ("Ball",[bspec]) :: mksimps_pairs;
   674 
   675 simpset_ref() := simpset() addcongs [ball_cong,bex_cong]
   676                     setmksimps (mksimps mksimps_pairs);
   677 
   678 Addsimps[subset_UNIV, subset_refl];
   679 
   680 
   681 (*** < ***)
   682 
   683 Goalw [psubset_def] "!!A::'a set. [| A <= B; A ~= B |] ==> A<B";
   684 by (Blast_tac 1);
   685 qed "psubsetI";
   686 
   687 Goalw [psubset_def] "A < insert x B ==> (x ~: A) & A<=B | x:A & A-{x}<B";
   688 by Auto_tac;
   689 qed "psubset_insertD";
   690 
   691 bind_thm ("psubset_eq", psubset_def RS meta_eq_to_obj_eq);