src/HOL/Library/Dlist.thy
author haftmann
Mon Oct 25 13:34:58 2010 +0200 (2010-10-25)
changeset 40122 1d8ad2ff3e01
parent 39915 ecf97cf3d248
child 40603 963ee2331d20
permissions -rw-r--r--
dropped (almost) redundant distinct.induct rule; distinct_simps again named distinct.simps
     1 (* Author: Florian Haftmann, TU Muenchen *)
     2 
     3 header {* Lists with elements distinct as canonical example for datatype invariants *}
     4 
     5 theory Dlist
     6 imports Main Fset
     7 begin
     8 
     9 section {* The type of distinct lists *}
    10 
    11 typedef (open) 'a dlist = "{xs::'a list. distinct xs}"
    12   morphisms list_of_dlist Abs_dlist
    13 proof
    14   show "[] \<in> ?dlist" by simp
    15 qed
    16 
    17 lemma dlist_eq_iff:
    18   "dxs = dys \<longleftrightarrow> list_of_dlist dxs = list_of_dlist dys"
    19   by (simp add: list_of_dlist_inject)
    20 
    21 lemma dlist_eqI:
    22   "list_of_dlist dxs = list_of_dlist dys \<Longrightarrow> dxs = dys"
    23   by (simp add: dlist_eq_iff)
    24 
    25 text {* Formal, totalized constructor for @{typ "'a dlist"}: *}
    26 
    27 definition Dlist :: "'a list \<Rightarrow> 'a dlist" where
    28   "Dlist xs = Abs_dlist (remdups xs)"
    29 
    30 lemma distinct_list_of_dlist [simp, intro]:
    31   "distinct (list_of_dlist dxs)"
    32   using list_of_dlist [of dxs] by simp
    33 
    34 lemma list_of_dlist_Dlist [simp]:
    35   "list_of_dlist (Dlist xs) = remdups xs"
    36   by (simp add: Dlist_def Abs_dlist_inverse)
    37 
    38 lemma remdups_list_of_dlist [simp]:
    39   "remdups (list_of_dlist dxs) = list_of_dlist dxs"
    40   by simp
    41 
    42 lemma Dlist_list_of_dlist [simp, code abstype]:
    43   "Dlist (list_of_dlist dxs) = dxs"
    44   by (simp add: Dlist_def list_of_dlist_inverse distinct_remdups_id)
    45 
    46 
    47 text {* Fundamental operations: *}
    48 
    49 definition empty :: "'a dlist" where
    50   "empty = Dlist []"
    51 
    52 definition insert :: "'a \<Rightarrow> 'a dlist \<Rightarrow> 'a dlist" where
    53   "insert x dxs = Dlist (List.insert x (list_of_dlist dxs))"
    54 
    55 definition remove :: "'a \<Rightarrow> 'a dlist \<Rightarrow> 'a dlist" where
    56   "remove x dxs = Dlist (remove1 x (list_of_dlist dxs))"
    57 
    58 definition map :: "('a \<Rightarrow> 'b) \<Rightarrow> 'a dlist \<Rightarrow> 'b dlist" where
    59   "map f dxs = Dlist (remdups (List.map f (list_of_dlist dxs)))"
    60 
    61 definition filter :: "('a \<Rightarrow> bool) \<Rightarrow> 'a dlist \<Rightarrow> 'a dlist" where
    62   "filter P dxs = Dlist (List.filter P (list_of_dlist dxs))"
    63 
    64 
    65 text {* Derived operations: *}
    66 
    67 definition null :: "'a dlist \<Rightarrow> bool" where
    68   "null dxs = List.null (list_of_dlist dxs)"
    69 
    70 definition member :: "'a dlist \<Rightarrow> 'a \<Rightarrow> bool" where
    71   "member dxs = List.member (list_of_dlist dxs)"
    72 
    73 definition length :: "'a dlist \<Rightarrow> nat" where
    74   "length dxs = List.length (list_of_dlist dxs)"
    75 
    76 definition fold :: "('a \<Rightarrow> 'b \<Rightarrow> 'b) \<Rightarrow> 'a dlist \<Rightarrow> 'b \<Rightarrow> 'b" where
    77   "fold f dxs = More_List.fold f (list_of_dlist dxs)"
    78 
    79 definition foldr :: "('a \<Rightarrow> 'b \<Rightarrow> 'b) \<Rightarrow> 'a dlist \<Rightarrow> 'b \<Rightarrow> 'b" where
    80   "foldr f dxs = List.foldr f (list_of_dlist dxs)"
    81 
    82 
    83 section {* Executable version obeying invariant *}
    84 
    85 lemma list_of_dlist_empty [simp, code abstract]:
    86   "list_of_dlist empty = []"
    87   by (simp add: empty_def)
    88 
    89 lemma list_of_dlist_insert [simp, code abstract]:
    90   "list_of_dlist (insert x dxs) = List.insert x (list_of_dlist dxs)"
    91   by (simp add: insert_def)
    92 
    93 lemma list_of_dlist_remove [simp, code abstract]:
    94   "list_of_dlist (remove x dxs) = remove1 x (list_of_dlist dxs)"
    95   by (simp add: remove_def)
    96 
    97 lemma list_of_dlist_map [simp, code abstract]:
    98   "list_of_dlist (map f dxs) = remdups (List.map f (list_of_dlist dxs))"
    99   by (simp add: map_def)
   100 
   101 lemma list_of_dlist_filter [simp, code abstract]:
   102   "list_of_dlist (filter P dxs) = List.filter P (list_of_dlist dxs)"
   103   by (simp add: filter_def)
   104 
   105 
   106 text {* Explicit executable conversion *}
   107 
   108 definition dlist_of_list [simp]:
   109   "dlist_of_list = Dlist"
   110 
   111 lemma [code abstract]:
   112   "list_of_dlist (dlist_of_list xs) = remdups xs"
   113   by simp
   114 
   115 
   116 text {* Equality *}
   117 
   118 instantiation dlist :: (equal) equal
   119 begin
   120 
   121 definition "HOL.equal dxs dys \<longleftrightarrow> HOL.equal (list_of_dlist dxs) (list_of_dlist dys)"
   122 
   123 instance proof
   124 qed (simp add: equal_dlist_def equal list_of_dlist_inject)
   125 
   126 end
   127 
   128 lemma [code nbe]:
   129   "HOL.equal (dxs :: 'a::equal dlist) dxs \<longleftrightarrow> True"
   130   by (fact equal_refl)
   131 
   132 
   133 section {* Induction principle and case distinction *}
   134 
   135 lemma dlist_induct [case_names empty insert, induct type: dlist]:
   136   assumes empty: "P empty"
   137   assumes insrt: "\<And>x dxs. \<not> member dxs x \<Longrightarrow> P dxs \<Longrightarrow> P (insert x dxs)"
   138   shows "P dxs"
   139 proof (cases dxs)
   140   case (Abs_dlist xs)
   141   then have "distinct xs" and dxs: "dxs = Dlist xs" by (simp_all add: Dlist_def distinct_remdups_id)
   142   from `distinct xs` have "P (Dlist xs)"
   143   proof (induct xs)
   144     case Nil from empty show ?case by (simp add: empty_def)
   145   next
   146     case (Cons x xs)
   147     then have "\<not> member (Dlist xs) x" and "P (Dlist xs)"
   148       by (simp_all add: member_def List.member_def)
   149     with insrt have "P (insert x (Dlist xs))" .
   150     with Cons show ?case by (simp add: insert_def distinct_remdups_id)
   151   qed
   152   with dxs show "P dxs" by simp
   153 qed
   154 
   155 lemma dlist_case [case_names empty insert, cases type: dlist]:
   156   assumes empty: "dxs = empty \<Longrightarrow> P"
   157   assumes insert: "\<And>x dys. \<not> member dys x \<Longrightarrow> dxs = insert x dys \<Longrightarrow> P"
   158   shows P
   159 proof (cases dxs)
   160   case (Abs_dlist xs)
   161   then have dxs: "dxs = Dlist xs" and distinct: "distinct xs"
   162     by (simp_all add: Dlist_def distinct_remdups_id)
   163   show P proof (cases xs)
   164     case Nil with dxs have "dxs = empty" by (simp add: empty_def) 
   165     with empty show P .
   166   next
   167     case (Cons x xs)
   168     with dxs distinct have "\<not> member (Dlist xs) x"
   169       and "dxs = insert x (Dlist xs)"
   170       by (simp_all add: member_def List.member_def insert_def distinct_remdups_id)
   171     with insert show P .
   172   qed
   173 qed
   174 
   175 
   176 section {* Implementation of sets by distinct lists -- canonical! *}
   177 
   178 definition Set :: "'a dlist \<Rightarrow> 'a fset" where
   179   "Set dxs = Fset.Set (list_of_dlist dxs)"
   180 
   181 definition Coset :: "'a dlist \<Rightarrow> 'a fset" where
   182   "Coset dxs = Fset.Coset (list_of_dlist dxs)"
   183 
   184 code_datatype Set Coset
   185 
   186 declare member_code [code del]
   187 declare is_empty_Set [code del]
   188 declare empty_Set [code del]
   189 declare UNIV_Set [code del]
   190 declare insert_Set [code del]
   191 declare remove_Set [code del]
   192 declare compl_Set [code del]
   193 declare compl_Coset [code del]
   194 declare map_Set [code del]
   195 declare filter_Set [code del]
   196 declare forall_Set [code del]
   197 declare exists_Set [code del]
   198 declare card_Set [code del]
   199 declare inter_project [code del]
   200 declare subtract_remove [code del]
   201 declare union_insert [code del]
   202 declare Infimum_inf [code del]
   203 declare Supremum_sup [code del]
   204 
   205 lemma Set_Dlist [simp]:
   206   "Set (Dlist xs) = Fset (set xs)"
   207   by (rule fset_eqI) (simp add: Set_def)
   208 
   209 lemma Coset_Dlist [simp]:
   210   "Coset (Dlist xs) = Fset (- set xs)"
   211   by (rule fset_eqI) (simp add: Coset_def)
   212 
   213 lemma member_Set [simp]:
   214   "Fset.member (Set dxs) = List.member (list_of_dlist dxs)"
   215   by (simp add: Set_def member_set)
   216 
   217 lemma member_Coset [simp]:
   218   "Fset.member (Coset dxs) = Not \<circ> List.member (list_of_dlist dxs)"
   219   by (simp add: Coset_def member_set not_set_compl)
   220 
   221 lemma Set_dlist_of_list [code]:
   222   "Fset.Set xs = Set (dlist_of_list xs)"
   223   by (rule fset_eqI) simp
   224 
   225 lemma Coset_dlist_of_list [code]:
   226   "Fset.Coset xs = Coset (dlist_of_list xs)"
   227   by (rule fset_eqI) simp
   228 
   229 lemma is_empty_Set [code]:
   230   "Fset.is_empty (Set dxs) \<longleftrightarrow> null dxs"
   231   by (simp add: null_def List.null_def member_set)
   232 
   233 lemma bot_code [code]:
   234   "bot = Set empty"
   235   by (simp add: empty_def)
   236 
   237 lemma top_code [code]:
   238   "top = Coset empty"
   239   by (simp add: empty_def)
   240 
   241 lemma insert_code [code]:
   242   "Fset.insert x (Set dxs) = Set (insert x dxs)"
   243   "Fset.insert x (Coset dxs) = Coset (remove x dxs)"
   244   by (simp_all add: insert_def remove_def member_set not_set_compl)
   245 
   246 lemma remove_code [code]:
   247   "Fset.remove x (Set dxs) = Set (remove x dxs)"
   248   "Fset.remove x (Coset dxs) = Coset (insert x dxs)"
   249   by (auto simp add: insert_def remove_def member_set not_set_compl)
   250 
   251 lemma member_code [code]:
   252   "Fset.member (Set dxs) = member dxs"
   253   "Fset.member (Coset dxs) = Not \<circ> member dxs"
   254   by (simp_all add: member_def)
   255 
   256 lemma compl_code [code]:
   257   "- Set dxs = Coset dxs"
   258   "- Coset dxs = Set dxs"
   259   by (rule fset_eqI, simp add: member_set not_set_compl)+
   260 
   261 lemma map_code [code]:
   262   "Fset.map f (Set dxs) = Set (map f dxs)"
   263   by (rule fset_eqI) (simp add: member_set)
   264   
   265 lemma filter_code [code]:
   266   "Fset.filter f (Set dxs) = Set (filter f dxs)"
   267   by (rule fset_eqI) (simp add: member_set)
   268 
   269 lemma forall_Set [code]:
   270   "Fset.forall P (Set xs) \<longleftrightarrow> list_all P (list_of_dlist xs)"
   271   by (simp add: member_set list_all_iff)
   272 
   273 lemma exists_Set [code]:
   274   "Fset.exists P (Set xs) \<longleftrightarrow> list_ex P (list_of_dlist xs)"
   275   by (simp add: member_set list_ex_iff)
   276 
   277 lemma card_code [code]:
   278   "Fset.card (Set dxs) = length dxs"
   279   by (simp add: length_def member_set distinct_card)
   280 
   281 lemma inter_code [code]:
   282   "inf A (Set xs) = Set (filter (Fset.member A) xs)"
   283   "inf A (Coset xs) = foldr Fset.remove xs A"
   284   by (simp_all only: Set_def Coset_def foldr_def inter_project list_of_dlist_filter)
   285 
   286 lemma subtract_code [code]:
   287   "A - Set xs = foldr Fset.remove xs A"
   288   "A - Coset xs = Set (filter (Fset.member A) xs)"
   289   by (simp_all only: Set_def Coset_def foldr_def subtract_remove list_of_dlist_filter)
   290 
   291 lemma union_code [code]:
   292   "sup (Set xs) A = foldr Fset.insert xs A"
   293   "sup (Coset xs) A = Coset (filter (Not \<circ> Fset.member A) xs)"
   294   by (simp_all only: Set_def Coset_def foldr_def union_insert list_of_dlist_filter)
   295 
   296 context complete_lattice
   297 begin
   298 
   299 lemma Infimum_code [code]:
   300   "Infimum (Set As) = foldr inf As top"
   301   by (simp only: Set_def Infimum_inf foldr_def inf.commute)
   302 
   303 lemma Supremum_code [code]:
   304   "Supremum (Set As) = foldr sup As bot"
   305   by (simp only: Set_def Supremum_sup foldr_def sup.commute)
   306 
   307 end
   308 
   309 
   310 hide_const (open) member fold foldr empty insert remove map filter null member length fold
   311 
   312 end