src/Pure/library.ML
author ballarin
Mon Apr 11 12:34:34 2005 +0200 (2005-04-11)
changeset 15696 1da4ce092c0b
parent 15670 963cd3f7976c
child 15745 33bb955b2e73
permissions -rw-r--r--
First release of interpretation commands.
     1 (*  Title:      Pure/library.ML
     2     ID:         $Id$
     3     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     4     Author:     Markus Wenzel, TU Munich
     5 
     6 Basic library: functions, options, pairs, booleans, lists, integers,
     7 rational numbers, strings, lists as sets, association lists, generic
     8 tables, balanced trees, orders, current directory, misc.
     9 *)
    10 
    11 infix |> |>> |>>> ~~ \ \\ ins ins_string ins_int orf andf prefix upto downto
    12   mem mem_int mem_string union union_int union_string inter inter_int
    13   inter_string subset subset_int subset_string;
    14 
    15 infix 3 oo ooo oooo;
    16 
    17 signature LIBRARY =
    18 sig
    19   (*functions*)
    20   val curry: ('a * 'b -> 'c) -> 'a -> 'b -> 'c
    21   val uncurry: ('a -> 'b -> 'c) -> 'a * 'b -> 'c
    22   val I: 'a -> 'a
    23   val K: 'a -> 'b -> 'a
    24   val |> : 'a * ('a -> 'b) -> 'b
    25   val |>> : ('a * 'b) * ('a -> 'c) -> 'c * 'b
    26   val |>>> : ('a * 'b) * ('a -> 'c * 'd) -> 'c * ('b * 'd)
    27   val apl: 'a * ('a * 'b -> 'c) -> 'b -> 'c
    28   val apr: ('a * 'b -> 'c) * 'b -> 'a -> 'c
    29   val funpow: int -> ('a -> 'a) -> 'a -> 'a
    30   val oo: ('a -> 'b) * ('c -> 'd -> 'a) -> 'c -> 'd -> 'b
    31   val ooo: ('a -> 'b) * ('c -> 'd -> 'e -> 'a) -> 'c -> 'd -> 'e -> 'b
    32   val oooo: ('a -> 'b) * ('c -> 'd -> 'e -> 'f -> 'a) -> 'c -> 'd -> 'e -> 'f -> 'b
    33 
    34   (*stamps*)
    35   type stamp
    36   val stamp: unit -> stamp
    37 
    38   (*options*)
    39   val is_none: 'a option -> bool
    40 
    41   (*old options -- invalidated*)
    42   datatype invalid = None of invalid
    43   exception OPTION of invalid
    44 
    45   exception ERROR
    46   val try: ('a -> 'b) -> 'a -> 'b option
    47   val can: ('a -> 'b) -> 'a -> bool
    48   datatype 'a result = Result of 'a | Exn of exn
    49   val capture: ('a -> 'b) -> 'a -> 'b result
    50   val release: 'a result -> 'a
    51   val get_result: 'a result -> 'a option
    52   val get_exn: 'a result -> exn option
    53 
    54   (*pairs*)
    55   val pair: 'a -> 'b -> 'a * 'b
    56   val rpair: 'a -> 'b -> 'b * 'a
    57   val fst: 'a * 'b -> 'a
    58   val snd: 'a * 'b -> 'b
    59   val eq_fst: (''a * 'b) * (''a * 'c) -> bool
    60   val eq_snd: ('a * ''b) * ('c * ''b) -> bool
    61   val swap: 'a * 'b -> 'b * 'a
    62   val apfst: ('a -> 'b) -> 'a * 'c -> 'b * 'c
    63   val apsnd: ('a -> 'b) -> 'c * 'a -> 'c * 'b
    64   val pairself: ('a -> 'b) -> 'a * 'a -> 'b * 'b
    65 
    66   (*booleans*)
    67   val equal: ''a -> ''a -> bool
    68   val not_equal: ''a -> ''a -> bool
    69   val orf: ('a -> bool) * ('a -> bool) -> 'a -> bool
    70   val andf: ('a -> bool) * ('a -> bool) -> 'a -> bool
    71   val exists: ('a -> bool) -> 'a list -> bool
    72   val forall: ('a -> bool) -> 'a list -> bool
    73   val set: bool ref -> bool
    74   val reset: bool ref -> bool
    75   val toggle: bool ref -> bool
    76   val change: 'a ref -> ('a -> 'a) -> unit
    77   val setmp: 'a ref -> 'a -> ('b -> 'c) -> 'b -> 'c
    78   val conditional: bool -> (unit -> unit) -> unit
    79 
    80   (*lists*)
    81   exception UnequalLengths
    82   val cons: 'a -> 'a list -> 'a list
    83   val single: 'a -> 'a list
    84   val append: 'a list -> 'a list -> 'a list
    85   val apply: ('a -> 'a) list -> 'a -> 'a
    86   val foldr1: ('a * 'a -> 'a) -> 'a list -> 'a
    87   val fold: ('a -> 'b -> 'b) -> 'a list -> 'b -> 'b
    88   val fold_rev: ('a -> 'b -> 'b) -> 'a list -> 'b -> 'b
    89   val foldl_map: ('a * 'b -> 'a * 'c) -> 'a * 'b list -> 'a * 'c list
    90   val foldln: ('a * int -> 'b -> 'b) -> 'a list -> 'b -> 'b
    91   val unflat: 'a list list -> 'b list -> 'b list list
    92   val splitAt: int * 'a list -> 'a list * 'a list
    93   val dropwhile: ('a -> bool) -> 'a list -> 'a list
    94   val map_nth_elem: int -> ('a -> 'a) -> 'a list -> 'a list
    95   val split_last: 'a list -> 'a list * 'a
    96   val nth_update: 'a -> int * 'a list -> 'a list
    97   val find_index: ('a -> bool) -> 'a list -> int
    98   val find_index_eq: ''a -> ''a list -> int
    99   val find_first: ('a -> bool) -> 'a list -> 'a option
   100   val get_first: ('a -> 'b option) -> 'a list -> 'b option
   101   val separate: 'a -> 'a list -> 'a list
   102   val replicate: int -> 'a -> 'a list
   103   val multiply: 'a list * 'a list list -> 'a list list
   104   val product: 'a list -> 'b list -> ('a * 'b) list
   105   val filter_out: ('a -> bool) -> 'a list -> 'a list
   106   val map2: ('a * 'b -> 'c) -> 'a list * 'b list -> 'c list
   107   val exists2: ('a * 'b -> bool) -> 'a list * 'b list -> bool
   108   val forall2: ('a * 'b -> bool) -> 'a list * 'b list -> bool
   109   val seq2: ('a * 'b -> unit) -> 'a list * 'b list -> unit
   110   val ~~ : 'a list * 'b list -> ('a * 'b) list
   111   val split_list: ('a * 'b) list -> 'a list * 'b list
   112   val equal_lists: ('a * 'b -> bool) -> 'a list * 'b list -> bool
   113   val prefix: ''a list * ''a list -> bool
   114   val take_prefix: ('a -> bool) -> 'a list -> 'a list * 'a list
   115   val take_suffix: ('a -> bool) -> 'a list -> 'a list * 'a list
   116   val prefixes1: 'a list -> 'a list list
   117   val suffixes1: 'a list -> 'a list list
   118 
   119   (*integers*)
   120   val gcd: int * int -> int
   121   val lcm: int * int -> int
   122   val inc: int ref -> int
   123   val dec: int ref -> int
   124   val upto: int * int -> int list
   125   val downto: int * int -> int list
   126   val downto0: int list * int -> bool
   127   val radixpand: int * int -> int list
   128   val radixstring: int * string * int -> string
   129   val string_of_int: int -> string
   130   val string_of_indexname: string * int -> string
   131     (* CB: note alternative Syntax.string_of_vname has nicer syntax *)
   132   val read_radixint: int * string list -> int * string list
   133   val read_int: string list -> int * string list
   134   val oct_char: string -> string
   135 
   136   (*rational numbers*)
   137   type rat
   138   exception RAT of string
   139   val rep_rat: rat -> int * int
   140   val ratadd: rat * rat -> rat
   141   val ratmul: rat * rat -> rat
   142   val ratinv: rat -> rat
   143   val int_ratdiv: int * int -> rat
   144   val ratneg: rat -> rat
   145   val rat_of_int: int -> rat
   146 
   147   (*strings*)
   148   val nth_elem_string: int * string -> string
   149   val foldl_string: ('a * string -> 'a) -> 'a * string -> 'a
   150   val exists_string: (string -> bool) -> string -> bool
   151   val enclose: string -> string -> string -> string
   152   val unenclose: string -> string
   153   val quote: string -> string
   154   val space_implode: string -> string list -> string
   155   val commas: string list -> string
   156   val commas_quote: string list -> string
   157   val cat_lines: string list -> string
   158   val space_explode: string -> string -> string list
   159   val split_lines: string -> string list
   160   val prefix_lines: string -> string -> string
   161   val untabify: string list -> string list
   162   val suffix: string -> string -> string
   163   val unsuffix: string -> string -> string
   164   val unprefix: string -> string -> string
   165   val replicate_string: int -> string -> string
   166   val translate_string: (string -> string) -> string -> string
   167 
   168   (*lists as sets*)
   169   val mem: ''a * ''a list -> bool
   170   val mem_int: int * int list -> bool
   171   val mem_string: string * string list -> bool
   172   val gen_mem: ('a * 'b -> bool) -> 'a * 'b list -> bool
   173   val ins: ''a * ''a list -> ''a list
   174   val ins_int: int * int list -> int list
   175   val ins_string: string * string list -> string list
   176   val gen_ins: ('a * 'a -> bool) -> 'a * 'a list -> 'a list
   177   val union: ''a list * ''a list -> ''a list
   178   val union_int: int list * int list -> int list
   179   val union_string: string list * string list -> string list
   180   val gen_union: ('a * 'a -> bool) -> 'a list * 'a list -> 'a list
   181   val gen_inter: ('a * 'b -> bool) -> 'a list * 'b list -> 'a list
   182   val inter: ''a list * ''a list -> ''a list
   183   val inter_int: int list * int list -> int list
   184   val inter_string: string list * string list -> string list
   185   val subset: ''a list * ''a list -> bool
   186   val subset_int: int list * int list -> bool
   187   val subset_string: string list * string list -> bool
   188   val eq_set: ''a list * ''a list -> bool
   189   val eq_set_string: string list * string list -> bool
   190   val gen_subset: ('a * 'b -> bool) -> 'a list * 'b list -> bool
   191   val \ : ''a list * ''a -> ''a list
   192   val \\ : ''a list * ''a list -> ''a list
   193   val gen_rem: ('a * 'b -> bool) -> 'a list * 'b -> 'a list
   194   val gen_rems: ('a * 'b -> bool) -> 'a list * 'b list -> 'a list
   195   val gen_distinct: ('a * 'a -> bool) -> 'a list -> 'a list
   196   val distinct: ''a list -> ''a list
   197   val findrep: ''a list -> ''a list
   198   val gen_duplicates: ('a * 'a -> bool) -> 'a list -> 'a list
   199   val duplicates: ''a list -> ''a list
   200 
   201   (*association lists*)
   202   val assoc: (''a * 'b) list * ''a -> 'b option
   203   val assoc_int: (int * 'a) list * int -> 'a option
   204   val assoc_string: (string * 'a) list * string -> 'a option
   205   val assoc_string_int: ((string * int) * 'a) list * (string * int) -> 'a option
   206   val assocs: (''a * 'b list) list -> ''a -> 'b list
   207   val assoc2: (''a * (''b * 'c) list) list * (''a * ''b) -> 'c option
   208   val gen_assoc: ('a * 'b -> bool) -> ('b * 'c) list * 'a -> 'c option
   209   val overwrite: (''a * 'b) list * (''a * 'b) -> (''a * 'b) list
   210   val gen_overwrite: ('a * 'a -> bool) -> ('a * 'b) list * ('a * 'b) -> ('a * 'b) list
   211 
   212   (*lists as tables*)
   213   val gen_merge_lists: ('a * 'a -> bool) -> 'a list -> 'a list -> 'a list
   214   val gen_merge_lists': ('a * 'a -> bool) -> 'a list -> 'a list -> 'a list
   215   val merge_lists: ''a list -> ''a list -> ''a list
   216   val merge_lists': ''a list -> ''a list -> ''a list
   217   val merge_alists: (''a * 'b) list -> (''a * 'b) list -> (''a * 'b) list
   218   val merge_alists': (''a * 'b) list -> (''a * 'b) list -> (''a * 'b) list
   219 
   220   (*balanced trees*)
   221   exception Balance
   222   val fold_bal: ('a * 'a -> 'a) -> 'a list -> 'a
   223   val access_bal: ('a -> 'a) * ('a -> 'a) * 'a -> int -> int -> 'a
   224   val accesses_bal: ('a -> 'a) * ('a -> 'a) * 'a -> int -> 'a list
   225 
   226   (*orders*)
   227   val rev_order: order -> order
   228   val make_ord: ('a * 'a -> bool) -> 'a * 'a -> order
   229   val int_ord: int * int -> order
   230   val string_ord: string * string -> order
   231   val prod_ord: ('a * 'b -> order) -> ('c * 'd -> order) -> ('a * 'c) * ('b * 'd) -> order
   232   val dict_ord: ('a * 'b -> order) -> 'a list * 'b list -> order
   233   val list_ord: ('a * 'b -> order) -> 'a list * 'b list -> order
   234   val sort: ('a * 'a -> order) -> 'a list -> 'a list
   235   val sort_strings: string list -> string list
   236   val sort_wrt: ('a -> string) -> 'a list -> 'a list
   237   val unique_strings: string list -> string list
   238 
   239   (*random numbers*)
   240   exception RANDOM
   241   val random: unit -> real
   242   val random_range: int -> int -> int
   243   val one_of: 'a list -> 'a
   244   val frequency: (int * 'a) list -> 'a
   245 
   246   (*current directory*)
   247   val cd: string -> unit
   248   val pwd: unit -> string
   249 
   250   (*misc*)
   251   val make_keylist: ('a -> 'b) -> 'a list -> ('a * 'b) list
   252   val keyfilter: ('a * ''b) list -> ''b -> 'a list
   253   val partition_eq: ('a * 'a -> bool) -> 'a list -> 'a list list
   254   val partition_list: (int -> 'a -> bool) -> int -> int -> 'a list -> 'a list list
   255   val gensym: string -> string
   256   val scanwords: (string -> bool) -> string list -> string list
   257 end;
   258 
   259 signature LIBRARY_CLOSED =
   260 sig
   261   include LIBRARY
   262 
   263   val the: 'a option -> 'a
   264   val if_none: 'a option -> 'a -> 'a
   265   val is_some: 'a option -> bool
   266   val apsome: ('a -> 'b) -> 'a option -> 'b option
   267 
   268   val rev_append: 'a list -> 'a list -> 'a list
   269   val foldl: ('a * 'b -> 'a) -> 'a * 'b list -> 'a
   270   val foldr: ('a * 'b -> 'b) -> 'a list * 'b -> 'b
   271   val take: int * 'a list -> 'a list
   272   val drop: int * 'a list -> 'a list
   273   val nth_elem: int * 'a list -> 'a
   274   val last_elem: 'a list -> 'a
   275   val flat: 'a list list -> 'a list
   276   val seq: ('a -> unit) -> 'a list -> unit
   277   val partition: ('a -> bool) -> 'a list -> 'a list * 'a list
   278   val filter: ('a -> bool) -> 'a list -> 'a list
   279   val mapfilter: ('a -> 'b option) -> 'a list -> 'b list
   280 end;
   281 
   282 structure Library: LIBRARY_CLOSED =
   283 struct
   284 
   285 
   286 (** functions **)
   287 
   288 (*handy combinators*)
   289 fun curry f x y = f (x, y);
   290 fun uncurry f (x, y) = f x y;
   291 fun I x = x;
   292 fun K x y = x;
   293 
   294 (*reverse apply*)
   295 fun (x |> f) = f x;
   296 fun ((x, y) |>> f) = (f x, y);
   297 fun ((x, y) |>>> f) = let val (x', z) = f x in (x', (y, z)) end;
   298 
   299 (*application of (infix) operator to its left or right argument*)
   300 fun apl (x, f) y = f (x, y);
   301 fun apr (f, y) x = f (x, y);
   302 
   303 (*function exponentiation: f(...(f x)...) with n applications of f*)
   304 fun funpow n f x =
   305   let fun rep (0, x) = x
   306         | rep (n, x) = rep (n - 1, f x)
   307   in rep (n, x) end;
   308 
   309 (*concatenation: 2 and 3 args*)
   310 fun (f oo g) x y = f (g x y);
   311 fun (f ooo g) x y z = f (g x y z);
   312 fun (f oooo g) x y z w = f (g x y z w);
   313 
   314 
   315 
   316 (** stamps **)
   317 
   318 type stamp = unit ref;
   319 val stamp: unit -> stamp = ref;
   320 
   321 
   322 
   323 (** options **)
   324 
   325 val the = valOf;
   326 fun if_none opt a = getOpt (opt, a);
   327 val is_some = isSome;
   328 fun is_none opt = not (isSome opt);
   329 val apsome = Option.map;
   330 
   331 (*invalidate former constructors to prevent accidental use as match-all patterns!*)
   332 datatype invalid = None of invalid;
   333 exception OPTION of invalid;
   334 
   335 
   336 (* exception handling *)
   337 
   338 exception ERROR;
   339 
   340 fun try f x = SOME (f x)
   341   handle Interrupt => raise Interrupt | ERROR => raise ERROR | _ => NONE;
   342 
   343 fun can f x = is_some (try f x);
   344 
   345 
   346 datatype 'a result =
   347   Result of 'a |
   348   Exn of exn;
   349 
   350 fun capture f x = Result (f x) handle e => Exn e;
   351 
   352 fun release (Result y) = y
   353   | release (Exn e) = raise e;
   354 
   355 fun get_result (Result x) = SOME x
   356   | get_result _ = NONE;
   357 
   358 fun get_exn (Exn exn) = SOME exn
   359   | get_exn _ = NONE;
   360 
   361 
   362 
   363 (** pairs **)
   364 
   365 fun pair x y = (x, y);
   366 fun rpair x y = (y, x);
   367 
   368 fun fst (x, y) = x;
   369 fun snd (x, y) = y;
   370 
   371 fun eq_fst ((x1, _), (x2, _)) = x1 = x2;
   372 fun eq_snd ((_, y1), (_, y2)) = y1 = y2;
   373 
   374 fun swap (x, y) = (y, x);
   375 
   376 (*apply function to components*)
   377 fun apfst f (x, y) = (f x, y);
   378 fun apsnd f (x, y) = (x, f y);
   379 fun pairself f (x, y) = (f x, f y);
   380 
   381 
   382 
   383 (** booleans **)
   384 
   385 (* equality *)
   386 
   387 fun equal x y = x = y;
   388 fun not_equal x y = x <> y;
   389 
   390 
   391 (* operators for combining predicates *)
   392 
   393 fun (p orf q) = fn x => p x orelse q x;
   394 fun (p andf q) = fn x => p x andalso q x;
   395 
   396 
   397 (* predicates on lists *)
   398 
   399 (*exists pred [x1, ..., xn] ===> pred x1 orelse ... orelse pred xn*)
   400 fun exists (pred: 'a -> bool) : 'a list -> bool =
   401   let fun boolf [] = false
   402         | boolf (x :: xs) = pred x orelse boolf xs
   403   in boolf end;
   404 
   405 (*forall pred [x1, ..., xn] ===> pred x1 andalso ... andalso pred xn*)
   406 fun forall (pred: 'a -> bool) : 'a list -> bool =
   407   let fun boolf [] = true
   408         | boolf (x :: xs) = pred x andalso boolf xs
   409   in boolf end;
   410 
   411 
   412 (* flags *)
   413 
   414 fun set flag = (flag := true; true);
   415 fun reset flag = (flag := false; false);
   416 fun toggle flag = (flag := not (! flag); ! flag);
   417 
   418 fun change r f = r := f (! r);
   419 
   420 (*temporarily set flag, handling exceptions*)
   421 fun setmp flag value f x =
   422   let
   423     val orig_value = ! flag;
   424     fun return y = (flag := orig_value; y);
   425   in
   426     flag := value;
   427     return (f x handle exn => (return (); raise exn))
   428   end;
   429 
   430 
   431 (* conditional execution *)
   432 
   433 fun conditional b f = if b then f () else ();
   434 
   435 
   436 
   437 (** lists **)
   438 
   439 exception UnequalLengths;
   440 
   441 fun cons x xs = x :: xs;
   442 fun single x = [x];
   443 
   444 fun append xs ys = xs @ ys;
   445 
   446 (* tail recursive version *)
   447 fun rev_append xs ys = List.revAppend(xs,ys);
   448 
   449 fun apply [] x = x
   450   | apply (f :: fs) x = apply fs (f x);
   451 
   452 
   453 (* fold *)
   454 
   455 (*the following versions of fold are designed to fit nicely with infixes*)
   456 
   457 (*  (op @) (e, [x1, ..., xn])  ===>  ((e @ x1) @ x2) ... @ xn
   458     for operators that associate to the left (TAIL RECURSIVE)*)
   459 fun foldl (f: 'a * 'b -> 'a) : 'a * 'b list -> 'a =
   460   let fun itl (e, [])  = e
   461         | itl (e, a::l) = itl (f(e, a), l)
   462   in  itl end;
   463 
   464 (*  (op @) ([x1, ..., xn], e)  ===>   x1 @ (x2 ... @ (xn @ e))
   465     for operators that associate to the right (not tail recursive)*)
   466 fun foldr f (l, e) =
   467   let fun itr [] = e
   468         | itr (a::l) = f(a, itr l)
   469   in  itr l  end;
   470 
   471 (*  (op @) [x1, ..., xn]  ===>   x1 @ (x2 ... @ (x[n-1] @ xn))
   472     for n > 0, operators that associate to the right (not tail recursive)*)
   473 fun foldr1 f l =
   474   let fun itr [x] = x
   475         | itr (x::l) = f(x, itr l)
   476   in  itr l  end;
   477 
   478 fun fold f xs y = foldl (fn (y', x) => f x y') (y, xs);
   479 fun fold_rev f xs y = foldr (fn (x, y') => f x y') (xs, y);
   480 
   481 fun foldl_map _ (x, []) = (x, [])
   482   | foldl_map f (x, y :: ys) =
   483       let
   484         val (x', y') = f (x, y);
   485         val (x'', ys') = foldl_map f (x', ys);
   486       in (x'', y' :: ys') end;
   487 
   488 fun foldln f xs e = fst (foldl (fn ((e,i), x) => (f (x,i) e, i+1)) ((e,1),xs));
   489 
   490 (* basic list functions *)
   491 
   492 (*take the first n elements from a list*)
   493 fun take (n, []) = []
   494   | take (n, x :: xs) =
   495       if n > 0 then x :: take (n - 1, xs) else [];
   496 
   497 (*drop the first n elements from a list*)
   498 fun drop (n, []) = []
   499   | drop (n, x :: xs) =
   500       if n > 0 then drop (n - 1, xs) else x :: xs;
   501 
   502 fun splitAt(n,[]) = ([],[])
   503   | splitAt(n,xs as x::ys) =
   504       if n>0 then let val (ps,qs) = splitAt(n-1,ys) in (x::ps,qs) end
   505       else ([],xs)
   506 
   507 fun dropwhile P [] = []
   508   | dropwhile P (ys as x::xs) = if P x then dropwhile P xs else ys;
   509 
   510 (*return nth element of a list, where 0 designates the first element;
   511   raise EXCEPTION if list too short*)
   512 fun nth_elem (i,xs) = List.nth(xs,i);
   513 
   514 fun map_nth_elem 0 f (x :: xs) = f x :: xs
   515   | map_nth_elem n f (x :: xs) = x :: map_nth_elem (n - 1) f xs
   516   | map_nth_elem _ _ [] = raise Subscript;
   517 
   518 (*last element of a list*)
   519 val last_elem = List.last;
   520 
   521 (*rear decomposition*)
   522 fun split_last [] = raise Empty
   523   | split_last [x] = ([], x)
   524   | split_last (x :: xs) = apfst (cons x) (split_last xs);
   525 
   526 (*update nth element*)
   527 fun nth_update x n_xs =
   528     (case splitAt n_xs of
   529       (_,[]) => raise Subscript
   530     | (prfx, _ :: sffx') => prfx @ (x :: sffx'))
   531 
   532 (*find the position of an element in a list*)
   533 fun find_index pred =
   534   let fun find _ [] = ~1
   535         | find n (x :: xs) = if pred x then n else find (n + 1) xs;
   536   in find 0 end;
   537 
   538 fun find_index_eq x = find_index (equal x);
   539 
   540 (*find first element satisfying predicate*)
   541 fun find_first _ [] = NONE
   542   | find_first pred (x :: xs) =
   543       if pred x then SOME x else find_first pred xs;
   544 
   545 (*get first element by lookup function*)
   546 fun get_first _ [] = NONE
   547   | get_first f (x :: xs) =
   548       (case f x of
   549         NONE => get_first f xs
   550       | some => some);
   551 
   552 (*flatten a list of lists to a list*)
   553 val flat = List.concat;
   554 
   555 fun unflat (xs :: xss) ys =
   556       let val (ps,qs) = splitAt(length xs,ys)
   557       in ps :: unflat xss qs end
   558   | unflat [] [] = []
   559   | unflat _ _ = raise UnequalLengths;
   560 
   561 (*like Lisp's MAPC -- seq proc [x1, ..., xn] evaluates
   562   (proc x1; ...; proc xn) for side effects*)
   563 val seq = List.app;
   564 
   565 (*separate s [x1, x2, ..., xn]  ===>  [x1, s, x2, s, ..., s, xn]*)
   566 fun separate s (x :: (xs as _ :: _)) = x :: s :: separate s xs
   567   | separate _ xs = xs;
   568 
   569 (*make the list [x, x, ..., x] of length n*)
   570 fun replicate n (x: 'a) : 'a list =
   571   let fun rep (0, xs) = xs
   572         | rep (n, xs) = rep (n - 1, x :: xs)
   573   in
   574     if n < 0 then raise Subscript
   575     else rep (n, [])
   576   end;
   577 
   578 fun translate_string f = String.translate (f o String.str);
   579 
   580 (*multiply [a, b, c, ...] * [xs, ys, zs, ...]*)
   581 fun multiply ([], _) = []
   582   | multiply (x :: xs, yss) = map (cons x) yss @ multiply (xs, yss);
   583 
   584 (*direct product*)
   585 fun product _ [] = []
   586   | product [] _ = []
   587   | product (x :: xs) ys = map (pair x) ys @ product xs ys;
   588 
   589 
   590 (* filter *)
   591 
   592 (*copy the list preserving elements that satisfy the predicate*)
   593 val filter = List.filter;
   594 fun filter_out f = filter (not o f);
   595 val mapfilter = List.mapPartial;
   596 
   597 
   598 (* lists of pairs *)
   599 
   600 exception UnequalLengths;
   601 
   602 fun map2 _ ([], []) = []
   603   | map2 f (x :: xs, y :: ys) = (f (x, y) :: map2 f (xs, ys))
   604   | map2 _ _ = raise UnequalLengths;
   605 
   606 fun exists2 _ ([], []) = false
   607   | exists2 pred (x :: xs, y :: ys) = pred (x, y) orelse exists2 pred (xs, ys)
   608   | exists2 _ _ = raise UnequalLengths;
   609 
   610 fun forall2 _ ([], []) = true
   611   | forall2 pred (x :: xs, y :: ys) = pred (x, y) andalso forall2 pred (xs, ys)
   612   | forall2 _ _ = raise UnequalLengths;
   613 
   614 fun seq2 _ ([], []) = ()
   615   | seq2 f (x :: xs, y :: ys) = (f (x, y); seq2 f (xs, ys))
   616   | seq2 _ _ = raise UnequalLengths;
   617 
   618 (*combine two lists forming a list of pairs:
   619   [x1, ..., xn] ~~ [y1, ..., yn]  ===>  [(x1, y1), ..., (xn, yn)]*)
   620 fun [] ~~ [] = []
   621   | (x :: xs) ~~ (y :: ys) = (x, y) :: (xs ~~ ys)
   622   | _ ~~ _ = raise UnequalLengths;
   623 
   624 (*inverse of ~~; the old 'split':
   625   [(x1, y1), ..., (xn, yn)]  ===>  ([x1, ..., xn], [y1, ..., yn])*)
   626 val split_list = ListPair.unzip;
   627 
   628 fun equal_lists eq (xs, ys) = length xs = length ys andalso forall2 eq (xs, ys);
   629 
   630 
   631 (* prefixes, suffixes *)
   632 
   633 fun [] prefix _ = true
   634   | (x :: xs) prefix (y :: ys) = x = y andalso (xs prefix ys)
   635   | _ prefix _ = false;
   636 
   637 (* [x1, ..., xi, ..., xn]  --->  ([x1, ..., x(i-1)], [xi, ..., xn])
   638    where xi is the first element that does not satisfy the predicate*)
   639 fun take_prefix (pred : 'a -> bool)  (xs: 'a list) : 'a list * 'a list =
   640   let fun take (rxs, []) = (rev rxs, [])
   641         | take (rxs, x :: xs) =
   642             if  pred x  then  take(x :: rxs, xs)  else  (rev rxs, x :: xs)
   643   in  take([], xs)  end;
   644 
   645 (* [x1, ..., xi, ..., xn]  --->  ([x1, ..., xi], [x(i+1), ..., xn])
   646    where xi is the last element that does not satisfy the predicate*)
   647 fun take_suffix _ [] = ([], [])
   648   | take_suffix pred (x :: xs) =
   649       (case take_suffix pred xs of
   650         ([], sffx) => if pred x then ([], x :: sffx) else ([x], sffx)
   651       | (prfx, sffx) => (x :: prfx, sffx));
   652 
   653 fun prefixes1 [] = []
   654   | prefixes1 (x :: xs) = map (cons x) ([] :: prefixes1 xs);
   655 
   656 fun suffixes1 xs = map rev (prefixes1 (rev xs));
   657 
   658 
   659 
   660 (** integers **)
   661 
   662 fun gcd(x,y) =
   663   let fun gxd x y =
   664     if y = 0 then x else gxd y (x mod y)
   665   in if x < y then gxd y x else gxd x y end;
   666 
   667 fun lcm(x,y) = (x * y) div gcd(x,y);
   668 
   669 fun inc i = (i := ! i + 1; ! i);
   670 fun dec i = (i := ! i - 1; ! i);
   671 
   672 
   673 (* lists of integers *)
   674 
   675 (*make the list [from, from + 1, ..., to]*)
   676 fun (from upto to) =
   677   if from > to then [] else from :: ((from + 1) upto to);
   678 
   679 (*make the list [from, from - 1, ..., to]*)
   680 fun (from downto to) =
   681   if from < to then [] else from :: ((from - 1) downto to);
   682 
   683 (*predicate: downto0 (is, n) <=> is = [n, n - 1, ..., 0]*)
   684 fun downto0 (i :: is, n) = i = n andalso downto0 (is, n - 1)
   685   | downto0 ([], n) = n = ~1;
   686 
   687 
   688 (* convert integers to strings *)
   689 
   690 (*expand the number in the given base;
   691   example: radixpand (2, 8) gives [1, 0, 0, 0]*)
   692 fun radixpand (base, num) : int list =
   693   let
   694     fun radix (n, tail) =
   695       if n < base then n :: tail
   696       else radix (n div base, (n mod base) :: tail)
   697   in radix (num, []) end;
   698 
   699 (*expands a number into a string of characters starting from "zerochar";
   700   example: radixstring (2, "0", 8) gives "1000"*)
   701 fun radixstring (base, zerochar, num) =
   702   let val offset = ord zerochar;
   703       fun chrof n = chr (offset + n)
   704   in implode (map chrof (radixpand (base, num))) end;
   705 
   706 
   707 val string_of_int = Int.toString;
   708 
   709 fun string_of_indexname (a,0) = a
   710   | string_of_indexname (a,i) = a ^ "_" ^ Int.toString i;
   711 
   712 
   713 (* read integers *)
   714 
   715 fun read_radixint (radix: int, cs) : int * string list =
   716   let val zero = ord"0"
   717       val limit = zero+radix
   718       fun scan (num,[]) = (num,[])
   719         | scan (num, c::cs) =
   720               if  zero <= ord c  andalso  ord c < limit
   721               then scan(radix*num + ord c - zero, cs)
   722               else (num, c::cs)
   723   in  scan(0,cs)  end;
   724 
   725 fun read_int cs = read_radixint (10, cs);
   726 
   727 fun oct_char s = chr (#1 (read_radixint (8, explode s)));
   728 
   729 
   730 
   731 (** strings **)
   732 
   733 (*functions tuned for strings, avoiding explode*)
   734 
   735 fun nth_elem_string (i, str) =
   736   (case try String.substring (str, i, 1) of
   737     SOME s => s
   738   | NONE => raise Subscript);
   739 
   740 fun foldl_string f (x0, str) =
   741   let
   742     val n = size str;
   743     fun fold (x, i) =
   744       if i < n then fold (f (x, String.substring (str, i, 1)), i + 1) else x;
   745   in fold (x0, 0) end;
   746 
   747 fun exists_string pred str =
   748   let
   749     val n = size str;
   750     fun ex i = i < n andalso (pred (String.substring (str, i, 1)) orelse ex (i + 1));
   751   in ex 0 end;
   752 
   753 (*enclose in brackets*)
   754 fun enclose lpar rpar str = lpar ^ str ^ rpar;
   755 fun unenclose str = String.substring (str, 1, size str - 2);
   756 
   757 (*simple quoting (does not escape special chars)*)
   758 val quote = enclose "\"" "\"";
   759 
   760 (*space_implode "..." (explode "hello") = "h...e...l...l...o"*)
   761 fun space_implode a bs = implode (separate a bs);
   762 
   763 val commas = space_implode ", ";
   764 val commas_quote = commas o map quote;
   765 
   766 (*concatenate messages, one per line, into a string*)
   767 val cat_lines = space_implode "\n";
   768 
   769 (*space_explode "." "h.e..l.lo" = ["h", "e", "", "l", "lo"]*)
   770 fun space_explode _ "" = []
   771   | space_explode sep str =
   772       let
   773         fun expl chs =
   774           (case take_prefix (not_equal sep) chs of
   775             (cs, []) => [implode cs]
   776           | (cs, _ :: cs') => implode cs :: expl cs');
   777       in expl (explode str) end;
   778 
   779 val split_lines = space_explode "\n";
   780 
   781 fun prefix_lines "" txt = txt
   782   | prefix_lines prfx txt = txt |> split_lines |> map (fn s => prfx ^ s) |> cat_lines;
   783 
   784 (*untabify*)
   785 fun untabify chs =
   786   let
   787     val tab_width = 8;
   788 
   789     fun untab (_, "\n") = (0, ["\n"])
   790       | untab (pos, "\t") =
   791           let val d = tab_width - (pos mod tab_width) in (pos + d, replicate d " ") end
   792       | untab (pos, c) = (pos + 1, [c]);
   793   in
   794     if not (exists (equal "\t") chs) then chs
   795     else flat (#2 (foldl_map untab (0, chs)))
   796   end;
   797 
   798 (*append suffix*)
   799 fun suffix sfx s = s ^ sfx;
   800 
   801 (*remove suffix*)
   802 fun unsuffix sfx s =
   803   let
   804     val cs = explode s;
   805     val prfx_len = size s - size sfx;
   806   in
   807     if prfx_len >= 0 andalso implode (drop (prfx_len, cs)) = sfx then
   808       implode (take (prfx_len, cs))
   809     else raise Fail "unsuffix"
   810   end;
   811 
   812 (*remove prefix*)
   813 fun unprefix prfx s =
   814   let val (prfx', sfx) = splitAt (size prfx, explode s)
   815   in
   816     if implode prfx' = prfx then implode sfx
   817     else raise Fail "unprefix"
   818   end;
   819 
   820 fun replicate_string 0 _ = ""
   821   | replicate_string 1 a = a
   822   | replicate_string k a =
   823       if k mod 2 = 0 then replicate_string (k div 2) (a ^ a)
   824       else replicate_string (k div 2) (a ^ a) ^ a;
   825 
   826 
   827 
   828 (** lists as sets **)
   829 
   830 (*membership in a list*)
   831 fun x mem [] = false
   832   | x mem (y :: ys) = x = y orelse x mem ys;
   833 
   834 (*membership in a list, optimized version for ints*)
   835 fun (x:int) mem_int [] = false
   836   | x mem_int (y :: ys) = x = y orelse x mem_int ys;
   837 
   838 (*membership in a list, optimized version for strings*)
   839 fun (x:string) mem_string [] = false
   840   | x mem_string (y :: ys) = x = y orelse x mem_string ys;
   841 
   842 (*generalized membership test*)
   843 fun gen_mem eq (x, []) = false
   844   | gen_mem eq (x, y :: ys) = eq (x, y) orelse gen_mem eq (x, ys);
   845 
   846 
   847 (*insertion into list if not already there*)
   848 fun (x ins xs) = if x mem xs then xs else x :: xs;
   849 
   850 (*insertion into list, optimized version for ints*)
   851 fun (x ins_int xs) = if x mem_int xs then xs else x :: xs;
   852 
   853 (*insertion into list, optimized version for strings*)
   854 fun (x ins_string xs) = if x mem_string xs then xs else x :: xs;
   855 
   856 (*generalized insertion*)
   857 fun gen_ins eq (x, xs) = if gen_mem eq (x, xs) then xs else x :: xs;
   858 
   859 
   860 (*union of sets represented as lists: no repetitions*)
   861 fun xs union [] = xs
   862   | [] union ys = ys
   863   | (x :: xs) union ys = xs union (x ins ys);
   864 
   865 (*union of sets, optimized version for ints*)
   866 fun (xs:int list) union_int [] = xs
   867   | [] union_int ys = ys
   868   | (x :: xs) union_int ys = xs union_int (x ins_int ys);
   869 
   870 (*union of sets, optimized version for strings*)
   871 fun (xs:string list) union_string [] = xs
   872   | [] union_string ys = ys
   873   | (x :: xs) union_string ys = xs union_string (x ins_string ys);
   874 
   875 (*generalized union*)
   876 fun gen_union eq (xs, []) = xs
   877   | gen_union eq ([], ys) = ys
   878   | gen_union eq (x :: xs, ys) = gen_union eq (xs, gen_ins eq (x, ys));
   879 
   880 
   881 (*intersection*)
   882 fun [] inter ys = []
   883   | (x :: xs) inter ys =
   884       if x mem ys then x :: (xs inter ys) else xs inter ys;
   885 
   886 (*intersection, optimized version for ints*)
   887 fun ([]:int list) inter_int ys = []
   888   | (x :: xs) inter_int ys =
   889       if x mem_int ys then x :: (xs inter_int ys) else xs inter_int ys;
   890 
   891 (*intersection, optimized version for strings *)
   892 fun ([]:string list) inter_string ys = []
   893   | (x :: xs) inter_string ys =
   894       if x mem_string ys then x :: (xs inter_string ys) else xs inter_string ys;
   895 
   896 (*generalized intersection*)
   897 fun gen_inter eq ([], ys) = []
   898   | gen_inter eq (x::xs, ys) =
   899       if gen_mem eq (x,ys) then x :: gen_inter eq (xs, ys)
   900                            else      gen_inter eq (xs, ys);
   901 
   902 
   903 (*subset*)
   904 fun [] subset ys = true
   905   | (x :: xs) subset ys = x mem ys andalso xs subset ys;
   906 
   907 (*subset, optimized version for ints*)
   908 fun ([]:int list) subset_int ys = true
   909   | (x :: xs) subset_int ys = x mem_int ys andalso xs subset_int ys;
   910 
   911 (*subset, optimized version for strings*)
   912 fun ([]:string list) subset_string ys = true
   913   | (x :: xs) subset_string ys = x mem_string ys andalso xs subset_string ys;
   914 
   915 (*set equality*)
   916 fun eq_set (xs, ys) =
   917   xs = ys orelse (xs subset ys andalso ys subset xs);
   918 
   919 (*set equality for strings*)
   920 fun eq_set_string ((xs:string list), ys) =
   921   xs = ys orelse (xs subset_string ys andalso ys subset_string xs);
   922 
   923 fun gen_subset eq (xs, ys) = forall (fn x => gen_mem eq (x, ys)) xs;
   924 
   925 
   926 (*removing an element from a list WITHOUT duplicates*)
   927 fun (y :: ys) \ x = if x = y then ys else y :: (ys \ x)
   928   | [] \ x = [];
   929 
   930 fun ys \\ xs = foldl (op \) (ys,xs);
   931 
   932 (*removing an element from a list -- possibly WITH duplicates*)
   933 fun gen_rem eq (xs, y) = filter_out (fn x => eq (x, y)) xs;
   934 fun gen_rems eq (xs, ys) = filter_out (fn x => gen_mem eq (x, ys)) xs;
   935 
   936 
   937 (*makes a list of the distinct members of the input; preserves order, takes
   938   first of equal elements*)
   939 fun gen_distinct eq lst =
   940   let
   941     val memb = gen_mem eq;
   942 
   943     fun dist (rev_seen, []) = rev rev_seen
   944       | dist (rev_seen, x :: xs) =
   945           if memb (x, rev_seen) then dist (rev_seen, xs)
   946           else dist (x :: rev_seen, xs);
   947   in
   948     dist ([], lst)
   949   end;
   950 
   951 fun distinct l = gen_distinct (op =) l;
   952 
   953 
   954 (*returns the tail beginning with the first repeated element, or []*)
   955 fun findrep [] = []
   956   | findrep (x :: xs) = if x mem xs then x :: xs else findrep xs;
   957 
   958 
   959 (*returns a list containing all repeated elements exactly once; preserves
   960   order, takes first of equal elements*)
   961 fun gen_duplicates eq lst =
   962   let
   963     val memb = gen_mem eq;
   964 
   965     fun dups (rev_dups, []) = rev rev_dups
   966       | dups (rev_dups, x :: xs) =
   967           if memb (x, rev_dups) orelse not (memb (x, xs)) then
   968             dups (rev_dups, xs)
   969           else dups (x :: rev_dups, xs);
   970   in
   971     dups ([], lst)
   972   end;
   973 
   974 fun duplicates l = gen_duplicates (op =) l;
   975 
   976 
   977 
   978 (** association lists **)
   979 
   980 (*association list lookup*)
   981 fun assoc ([], key) = NONE
   982   | assoc ((keyi, xi) :: pairs, key) =
   983       if key = keyi then SOME xi else assoc (pairs, key);
   984 
   985 (*association list lookup, optimized version for ints*)
   986 fun assoc_int ([], (key:int)) = NONE
   987   | assoc_int ((keyi, xi) :: pairs, key) =
   988       if key = keyi then SOME xi else assoc_int (pairs, key);
   989 
   990 (*association list lookup, optimized version for strings*)
   991 fun assoc_string ([], (key:string)) = NONE
   992   | assoc_string ((keyi, xi) :: pairs, key) =
   993       if key = keyi then SOME xi else assoc_string (pairs, key);
   994 
   995 (*association list lookup, optimized version for string*ints*)
   996 fun assoc_string_int ([], (key:string*int)) = NONE
   997   | assoc_string_int ((keyi, xi) :: pairs, key) =
   998       if key = keyi then SOME xi else assoc_string_int (pairs, key);
   999 
  1000 fun assocs ps x =
  1001   (case assoc (ps, x) of
  1002     NONE => []
  1003   | SOME ys => ys);
  1004 
  1005 (*two-fold association list lookup*)
  1006 fun assoc2 (aal, (key1, key2)) =
  1007   (case assoc (aal, key1) of
  1008     SOME al => assoc (al, key2)
  1009   | NONE => NONE);
  1010 
  1011 (*generalized association list lookup*)
  1012 fun gen_assoc eq ([], key) = NONE
  1013   | gen_assoc eq ((keyi, xi) :: pairs, key) =
  1014       if eq (key, keyi) then SOME xi else gen_assoc eq (pairs, key);
  1015 
  1016 (*association list update*)
  1017 fun overwrite (al, p as (key, _)) =
  1018   let fun over ((q as (keyi, _)) :: pairs) =
  1019             if keyi = key then p :: pairs else q :: (over pairs)
  1020         | over [] = [p]
  1021   in over al end;
  1022 
  1023 fun gen_overwrite eq (al, p as (key, _)) =
  1024   let fun over ((q as (keyi, _)) :: pairs) =
  1025             if eq (keyi, key) then p :: pairs else q :: (over pairs)
  1026         | over [] = [p]
  1027   in over al end;
  1028 
  1029 
  1030 (* lists as tables *)
  1031 
  1032 fun gen_merge_lists _ xs [] = xs
  1033   | gen_merge_lists _ [] ys = ys
  1034   | gen_merge_lists eq xs ys = xs @ gen_rems eq (ys, xs);
  1035 
  1036 fun gen_merge_lists' _ xs [] = xs
  1037   | gen_merge_lists' _ [] ys = ys
  1038   | gen_merge_lists' eq xs ys = gen_rems eq (ys, xs) @ xs;
  1039 
  1040 fun merge_lists xs ys = gen_merge_lists (op =) xs ys;
  1041 fun merge_lists' xs ys = gen_merge_lists' (op =) xs ys;
  1042 fun merge_alists al = gen_merge_lists eq_fst al;
  1043 fun merge_alists' al = gen_merge_lists' eq_fst al;
  1044 
  1045 
  1046 
  1047 (** balanced trees **)
  1048 
  1049 exception Balance;      (*indicates non-positive argument to balancing fun*)
  1050 
  1051 (*balanced folding; avoids deep nesting*)
  1052 fun fold_bal f [x] = x
  1053   | fold_bal f [] = raise Balance
  1054   | fold_bal f xs =
  1055       let val (ps,qs) = splitAt(length xs div 2, xs)
  1056       in  f (fold_bal f ps, fold_bal f qs)  end;
  1057 
  1058 (*construct something of the form f(...g(...(x)...)) for balanced access*)
  1059 fun access_bal (f, g, x) n i =
  1060   let fun acc n i =     (*1<=i<=n*)
  1061           if n=1 then x else
  1062           let val n2 = n div 2
  1063           in  if i<=n2 then f (acc n2 i)
  1064                        else g (acc (n-n2) (i-n2))
  1065           end
  1066   in  if 1<=i andalso i<=n then acc n i else raise Balance  end;
  1067 
  1068 (*construct ALL such accesses; could try harder to share recursive calls!*)
  1069 fun accesses_bal (f, g, x) n =
  1070   let fun acc n =
  1071           if n=1 then [x] else
  1072           let val n2 = n div 2
  1073               val acc2 = acc n2
  1074           in  if n-n2=n2 then map f acc2 @ map g acc2
  1075                          else map f acc2 @ map g (acc (n-n2)) end
  1076   in  if 1<=n then acc n else raise Balance  end;
  1077 
  1078 
  1079 
  1080 (** orders **)
  1081 
  1082 fun rev_order LESS = GREATER
  1083   | rev_order EQUAL = EQUAL
  1084   | rev_order GREATER = LESS;
  1085 
  1086 (*assume rel is a linear strict order*)
  1087 fun make_ord rel (x, y) =
  1088   if rel (x, y) then LESS
  1089   else if rel (y, x) then GREATER
  1090   else EQUAL;
  1091 
  1092 val int_ord = Int.compare;
  1093 val string_ord = String.compare;
  1094 
  1095 (*lexicographic product*)
  1096 fun prod_ord a_ord b_ord ((x, y), (x', y')) =
  1097   (case a_ord (x, x') of EQUAL => b_ord (y, y') | ord => ord);
  1098 
  1099 (*dictionary order -- in general NOT well-founded!*)
  1100 fun dict_ord _ ([], []) = EQUAL
  1101   | dict_ord _ ([], _ :: _) = LESS
  1102   | dict_ord _ (_ :: _, []) = GREATER
  1103   | dict_ord elem_ord (x :: xs, y :: ys) =
  1104       (case elem_ord (x, y) of EQUAL => dict_ord elem_ord (xs, ys) | ord => ord);
  1105 
  1106 (*lexicographic product of lists*)
  1107 fun list_ord elem_ord (xs, ys) =
  1108   prod_ord int_ord (dict_ord elem_ord) ((length xs, xs), (length ys, ys));
  1109 
  1110 
  1111 (* sorting *)
  1112 
  1113 (*quicksort (stable, i.e. does not reorder equal elements)*)
  1114 fun sort ord =
  1115   let
  1116     fun qsort xs =
  1117       let val len = length xs in
  1118         if len <= 1 then xs
  1119         else
  1120           let val (lts, eqs, gts) = part (nth_elem (len div 2, xs)) xs in
  1121             qsort lts @ eqs @ qsort gts
  1122           end
  1123       end
  1124     and part _ [] = ([], [], [])
  1125       | part pivot (x :: xs) = add (ord (x, pivot)) x (part pivot xs)
  1126     and add LESS x (lts, eqs, gts) = (x :: lts, eqs, gts)
  1127       | add EQUAL x (lts, eqs, gts) = (lts, x :: eqs, gts)
  1128       | add GREATER x (lts, eqs, gts) = (lts, eqs, x :: gts);
  1129   in qsort end;
  1130 
  1131 (*sort strings*)
  1132 val sort_strings = sort string_ord;
  1133 fun sort_wrt sel xs = sort (string_ord o pairself sel) xs;
  1134 
  1135 fun unique_strings ([]: string list) = []
  1136   | unique_strings [x] = [x]
  1137   | unique_strings (x :: y :: ys) =
  1138       if x = y then unique_strings (y :: ys)
  1139       else x :: unique_strings (y :: ys);
  1140 
  1141 
  1142 (** random numbers **)
  1143 
  1144 exception RANDOM;
  1145 
  1146 fun rmod x y = x - y * Real.realFloor (x / y);
  1147 
  1148 local
  1149   val a = 16807.0;
  1150   val m = 2147483647.0;
  1151   val random_seed = ref 1.0;
  1152 in
  1153 
  1154 fun random () =
  1155   let val r = rmod (a * !random_seed) m
  1156   in (random_seed := r; r) end;
  1157 
  1158 end;
  1159 
  1160 fun random_range l h =
  1161   if h < l orelse l < 0 then raise RANDOM
  1162   else l + Real.floor (rmod (random ()) (real (h - l + 1)));
  1163 
  1164 fun one_of xs = nth_elem (random_range 0 (length xs - 1), xs);
  1165 
  1166 fun frequency xs =
  1167   let
  1168     val sum = foldl op + (0, map fst xs);
  1169     fun pick n ((k, x) :: xs) =
  1170       if n <= k then x else pick (n - k) xs
  1171   in pick (random_range 1 sum) xs end;
  1172 
  1173 
  1174 (** current directory **)
  1175 
  1176 val cd = OS.FileSys.chDir;
  1177 val pwd = OS.FileSys.getDir;
  1178 
  1179 
  1180 
  1181 (** rational numbers **)
  1182 
  1183 datatype rat = Rat of bool * int * int
  1184 
  1185 exception RAT of string;
  1186 
  1187 fun rep_rat(Rat(a,p,q)) = (if a then p else ~p,q)
  1188 
  1189 fun ratnorm(a,p,q) = if p=0 then Rat(a,0,1) else
  1190   let val absp = abs p
  1191       val m = gcd(absp,q)
  1192   in Rat(a = (0 <= p), absp div m, q div m) end;
  1193 
  1194 fun ratadd(Rat(a,p,q),Rat(b,r,s)) =
  1195   let val den = lcm(q,s)
  1196       val p = p*(den div q) and r = r*(den div s)
  1197       val num = (if a then p else ~p) + (if b then r else ~r)
  1198   in ratnorm(true,num,den) end;
  1199 
  1200 fun ratmul(Rat(a,p,q),Rat(b,r,s)) = ratnorm(a=b,p*r,q*s)
  1201 
  1202 fun ratinv(Rat(a,p,q)) = if p=0 then raise RAT "ratinv" else Rat(a,q,p)
  1203 
  1204 fun int_ratdiv(p,q) =
  1205   if q=0 then raise RAT "int_ratdiv" else ratnorm(0<=q, p, abs q)
  1206 
  1207 fun ratneg(Rat(b,p,q)) = Rat(not b,p,q);
  1208 
  1209 fun rat_of_int i = if i < 0 then Rat(false,abs i,1) else Rat(true,i,1);
  1210 
  1211 
  1212 (** misc **)
  1213 
  1214 (*use the keyfun to make a list of (x, key) pairs*)
  1215 fun make_keylist (keyfun: 'a->'b) : 'a list -> ('a * 'b) list =
  1216   let fun keypair x = (x, keyfun x)
  1217   in map keypair end;
  1218 
  1219 (*given a list of (x, key) pairs and a searchkey
  1220   return the list of xs from each pair whose key equals searchkey*)
  1221 fun keyfilter [] searchkey = []
  1222   | keyfilter ((x, key) :: pairs) searchkey =
  1223       if key = searchkey then x :: keyfilter pairs searchkey
  1224       else keyfilter pairs searchkey;
  1225 
  1226 
  1227 (*Partition list into elements that satisfy predicate and those that don't.
  1228   Preserves order of elements in both lists.*)
  1229 val partition = List.partition;
  1230 
  1231 
  1232 fun partition_eq (eq:'a * 'a -> bool) =
  1233     let fun part [] = []
  1234           | part (x::ys) = let val (xs, xs') = partition (apl(x, eq)) ys
  1235                            in (x::xs)::(part xs') end
  1236     in part end;
  1237 
  1238 
  1239 (*Partition a list into buckets  [ bi, b(i+1), ..., bj ]
  1240    putting x in bk if p(k)(x) holds.  Preserve order of elements if possible.*)
  1241 fun partition_list p i j =
  1242   let fun part k xs =
  1243             if k>j then
  1244               (case xs of [] => []
  1245                          | _ => raise Fail "partition_list")
  1246             else
  1247             let val (ns, rest) = partition (p k) xs;
  1248             in  ns :: part(k+1)rest  end
  1249   in  part i end;
  1250 
  1251 
  1252 (* generating identifiers *)
  1253 
  1254 (** Freshly generated identifiers; supplied prefix MUST start with a letter **)
  1255 local
  1256 (*Maps 0-63 to A-Z, a-z, 0-9 or _ or ' for generating random identifiers*)
  1257 fun char i =      if i<26 then chr (ord "A" + i)
  1258              else if i<52 then chr (ord "a" + i - 26)
  1259              else if i<62 then chr (ord"0" + i - 52)
  1260              else if i=62 then "_"
  1261              else  (*i=63*)    "'";
  1262 
  1263 val charVec = Vector.tabulate (64, char);
  1264 
  1265 fun newid n =
  1266   let
  1267   in  implode (map (fn i => Vector.sub(charVec,i)) (radixpand (64,n)))  end;
  1268 
  1269 val seedr = ref 0;
  1270 
  1271 in
  1272 
  1273 fun gensym pre = pre ^ (#1(newid (!seedr), inc seedr));
  1274 
  1275 end;
  1276 
  1277 
  1278 (* lexical scanning *)
  1279 
  1280 (*scan a list of characters into "words" composed of "letters" (recognized by
  1281   is_let) and separated by any number of non-"letters"*)
  1282 fun scanwords is_let cs =
  1283   let fun scan1 [] = []
  1284         | scan1 cs =
  1285             let val (lets, rest) = take_prefix is_let cs
  1286             in implode lets :: scanwords is_let rest end;
  1287   in scan1 (#2 (take_prefix (not o is_let) cs)) end;
  1288 
  1289 
  1290 end;
  1291 
  1292 structure OpenLibrary: LIBRARY = Library;
  1293 open OpenLibrary;