src/HOL/Library/FuncSet.thy
author nipkow
Tue Jun 23 05:57:35 2009 +0200 (2009-06-23)
changeset 31759 1e652c39d617
parent 31754 b5260f5272a4
child 31770 ba52fcfaec28
permissions -rw-r--r--
fixed name
     1 (*  Title:      HOL/Library/FuncSet.thy
     2     Author:     Florian Kammueller and Lawrence C Paulson
     3 *)
     4 
     5 header {* Pi and Function Sets *}
     6 
     7 theory FuncSet
     8 imports Hilbert_Choice Main
     9 begin
    10 
    11 definition
    12   Pi :: "['a set, 'a => 'b set] => ('a => 'b) set" where
    13   "Pi A B = {f. \<forall>x. x \<in> A --> f x \<in> B x}"
    14 
    15 definition
    16   extensional :: "'a set => ('a => 'b) set" where
    17   "extensional A = {f. \<forall>x. x~:A --> f x = undefined}"
    18 
    19 definition
    20   "restrict" :: "['a => 'b, 'a set] => ('a => 'b)" where
    21   "restrict f A = (%x. if x \<in> A then f x else undefined)"
    22 
    23 abbreviation
    24   funcset :: "['a set, 'b set] => ('a => 'b) set"
    25     (infixr "->" 60) where
    26   "A -> B == Pi A (%_. B)"
    27 
    28 notation (xsymbols)
    29   funcset  (infixr "\<rightarrow>" 60)
    30 
    31 syntax
    32   "_Pi"  :: "[pttrn, 'a set, 'b set] => ('a => 'b) set"  ("(3PI _:_./ _)" 10)
    33   "_lam" :: "[pttrn, 'a set, 'a => 'b] => ('a=>'b)"  ("(3%_:_./ _)" [0,0,3] 3)
    34 
    35 syntax (xsymbols)
    36   "_Pi" :: "[pttrn, 'a set, 'b set] => ('a => 'b) set"  ("(3\<Pi> _\<in>_./ _)"   10)
    37   "_lam" :: "[pttrn, 'a set, 'a => 'b] => ('a=>'b)"  ("(3\<lambda>_\<in>_./ _)" [0,0,3] 3)
    38 
    39 syntax (HTML output)
    40   "_Pi" :: "[pttrn, 'a set, 'b set] => ('a => 'b) set"  ("(3\<Pi> _\<in>_./ _)"   10)
    41   "_lam" :: "[pttrn, 'a set, 'a => 'b] => ('a=>'b)"  ("(3\<lambda>_\<in>_./ _)" [0,0,3] 3)
    42 
    43 translations
    44   "PI x:A. B" == "CONST Pi A (%x. B)"
    45   "%x:A. f" == "CONST restrict (%x. f) A"
    46 
    47 definition
    48   "compose" :: "['a set, 'b => 'c, 'a => 'b] => ('a => 'c)" where
    49   "compose A g f = (\<lambda>x\<in>A. g (f x))"
    50 
    51 
    52 subsection{*Basic Properties of @{term Pi}*}
    53 
    54 lemma Pi_I[intro!]: "(!!x. x \<in> A ==> f x \<in> B x) ==> f \<in> Pi A B"
    55   by (simp add: Pi_def)
    56 
    57 lemma Pi_I'[simp]: "(!!x. x : A --> f x : B x) ==> f : Pi A B"
    58 by(simp add:Pi_def)
    59 
    60 lemma funcsetI: "(!!x. x \<in> A ==> f x \<in> B) ==> f \<in> A -> B"
    61   by (simp add: Pi_def)
    62 
    63 lemma Pi_mem: "[|f: Pi A B; x \<in> A|] ==> f x \<in> B x"
    64   by (simp add: Pi_def)
    65 
    66 lemma PiE [elim]:
    67   "f : Pi A B ==> (f x : B x ==> Q) ==> (x ~: A ==> Q) ==> Q"
    68 by(auto simp: Pi_def)
    69 
    70 lemma funcset_mem: "[|f \<in> A -> B; x \<in> A|] ==> f x \<in> B"
    71   by (simp add: Pi_def)
    72 
    73 lemma funcset_image: "f \<in> A\<rightarrow>B ==> f ` A \<subseteq> B"
    74 by auto
    75 
    76 lemma Pi_eq_empty[simp]: "((PI x: A. B x) = {}) = (\<exists>x\<in>A. B(x) = {})"
    77 apply (simp add: Pi_def, auto)
    78 txt{*Converse direction requires Axiom of Choice to exhibit a function
    79 picking an element from each non-empty @{term "B x"}*}
    80 apply (drule_tac x = "%u. SOME y. y \<in> B u" in spec, auto)
    81 apply (cut_tac P= "%y. y \<in> B x" in some_eq_ex, auto)
    82 done
    83 
    84 lemma Pi_empty [simp]: "Pi {} B = UNIV"
    85 by (simp add: Pi_def)
    86 
    87 lemma Pi_UNIV [simp]: "A -> UNIV = UNIV"
    88 by (simp add: Pi_def)
    89 (*
    90 lemma funcset_id [simp]: "(%x. x): A -> A"
    91   by (simp add: Pi_def)
    92 *)
    93 text{*Covariance of Pi-sets in their second argument*}
    94 lemma Pi_mono: "(!!x. x \<in> A ==> B x <= C x) ==> Pi A B <= Pi A C"
    95 by auto
    96 
    97 text{*Contravariance of Pi-sets in their first argument*}
    98 lemma Pi_anti_mono: "A' <= A ==> Pi A B <= Pi A' B"
    99 by auto
   100 
   101 
   102 subsection{*Composition With a Restricted Domain: @{term compose}*}
   103 
   104 lemma funcset_compose:
   105   "[| f \<in> A -> B; g \<in> B -> C |]==> compose A g f \<in> A -> C"
   106 by (simp add: Pi_def compose_def restrict_def)
   107 
   108 lemma compose_assoc:
   109     "[| f \<in> A -> B; g \<in> B -> C; h \<in> C -> D |]
   110       ==> compose A h (compose A g f) = compose A (compose B h g) f"
   111 by (simp add: expand_fun_eq Pi_def compose_def restrict_def)
   112 
   113 lemma compose_eq: "x \<in> A ==> compose A g f x = g(f(x))"
   114 by (simp add: compose_def restrict_def)
   115 
   116 lemma surj_compose: "[| f ` A = B; g ` B = C |] ==> compose A g f ` A = C"
   117   by (auto simp add: image_def compose_eq)
   118 
   119 
   120 subsection{*Bounded Abstraction: @{term restrict}*}
   121 
   122 lemma restrict_in_funcset: "(!!x. x \<in> A ==> f x \<in> B) ==> (\<lambda>x\<in>A. f x) \<in> A -> B"
   123   by (simp add: Pi_def restrict_def)
   124 
   125 lemma restrictI[intro!]: "(!!x. x \<in> A ==> f x \<in> B x) ==> (\<lambda>x\<in>A. f x) \<in> Pi A B"
   126   by (simp add: Pi_def restrict_def)
   127 
   128 lemma restrict_apply [simp]:
   129     "(\<lambda>y\<in>A. f y) x = (if x \<in> A then f x else undefined)"
   130   by (simp add: restrict_def)
   131 
   132 lemma restrict_ext:
   133     "(!!x. x \<in> A ==> f x = g x) ==> (\<lambda>x\<in>A. f x) = (\<lambda>x\<in>A. g x)"
   134   by (simp add: expand_fun_eq Pi_def restrict_def)
   135 
   136 lemma inj_on_restrict_eq [simp]: "inj_on (restrict f A) A = inj_on f A"
   137   by (simp add: inj_on_def restrict_def)
   138 
   139 lemma Id_compose:
   140     "[|f \<in> A -> B;  f \<in> extensional A|] ==> compose A (\<lambda>y\<in>B. y) f = f"
   141   by (auto simp add: expand_fun_eq compose_def extensional_def Pi_def)
   142 
   143 lemma compose_Id:
   144     "[|g \<in> A -> B;  g \<in> extensional A|] ==> compose A g (\<lambda>x\<in>A. x) = g"
   145   by (auto simp add: expand_fun_eq compose_def extensional_def Pi_def)
   146 
   147 lemma image_restrict_eq [simp]: "(restrict f A) ` A = f ` A"
   148   by (auto simp add: restrict_def)
   149 
   150 
   151 subsection{*Bijections Between Sets*}
   152 
   153 text{*The definition of @{const bij_betw} is in @{text "Fun.thy"}, but most of
   154 the theorems belong here, or need at least @{term Hilbert_Choice}.*}
   155 
   156 lemma bij_betw_imp_funcset: "bij_betw f A B \<Longrightarrow> f \<in> A \<rightarrow> B"
   157 by (auto simp add: bij_betw_def inj_on_Inv)
   158 
   159 lemma inj_on_compose:
   160   "[| bij_betw f A B; inj_on g B |] ==> inj_on (compose A g f) A"
   161 by (auto simp add: bij_betw_def inj_on_def compose_eq)
   162 
   163 lemma bij_betw_compose:
   164   "[| bij_betw f A B; bij_betw g B C |] ==> bij_betw (compose A g f) A C"
   165 apply (simp add: bij_betw_def compose_eq inj_on_compose)
   166 apply (auto simp add: compose_def image_def)
   167 done
   168 
   169 lemma bij_betw_restrict_eq [simp]:
   170   "bij_betw (restrict f A) A B = bij_betw f A B"
   171 by (simp add: bij_betw_def)
   172 
   173 
   174 subsection{*Extensionality*}
   175 
   176 lemma extensional_arb: "[|f \<in> extensional A; x\<notin> A|] ==> f x = undefined"
   177 by (simp add: extensional_def)
   178 
   179 lemma restrict_extensional [simp]: "restrict f A \<in> extensional A"
   180 by (simp add: restrict_def extensional_def)
   181 
   182 lemma compose_extensional [simp]: "compose A f g \<in> extensional A"
   183 by (simp add: compose_def)
   184 
   185 lemma extensionalityI:
   186   "[| f \<in> extensional A; g \<in> extensional A;
   187       !!x. x\<in>A ==> f x = g x |] ==> f = g"
   188 by (force simp add: expand_fun_eq extensional_def)
   189 
   190 lemma Inv_funcset: "f ` A = B ==> (\<lambda>x\<in>B. Inv A f x) : B -> A"
   191 by (unfold Inv_def) (fast intro: someI2)
   192 
   193 lemma compose_Inv_id:
   194   "bij_betw f A B ==> compose A (\<lambda>y\<in>B. Inv A f y) f = (\<lambda>x\<in>A. x)"
   195 apply (simp add: bij_betw_def compose_def)
   196 apply (rule restrict_ext, auto)
   197 apply (erule subst)
   198 apply (simp add: Inv_f_f)
   199 done
   200 
   201 lemma compose_id_Inv:
   202   "f ` A = B ==> compose B f (\<lambda>y\<in>B. Inv A f y) = (\<lambda>x\<in>B. x)"
   203 apply (simp add: compose_def)
   204 apply (rule restrict_ext)
   205 apply (simp add: f_Inv_f)
   206 done
   207 
   208 
   209 subsection{*Cardinality*}
   210 
   211 lemma card_inj: "[|f \<in> A\<rightarrow>B; inj_on f A; finite B|] ==> card(A) \<le> card(B)"
   212 by (rule card_inj_on_le) auto
   213 
   214 lemma card_bij:
   215   "[|f \<in> A\<rightarrow>B; inj_on f A;
   216      g \<in> B\<rightarrow>A; inj_on g B; finite A; finite B|] ==> card(A) = card(B)"
   217 by (blast intro: card_inj order_antisym)
   218 
   219 end