src/HOL/Option.thy
author hoelzl
Fri Mar 22 10:41:43 2013 +0100 (2013-03-22)
changeset 51474 1e9e68247ad1
parent 51096 60e4b75fefe1
child 51703 f2e92fc0c8aa
permissions -rw-r--r--
generalize Bfun and Bseq to metric spaces; Bseq is an abbreviation for Bfun
     1 (*  Title:      HOL/Option.thy
     2     Author:     Folklore
     3 *)
     4 
     5 header {* Datatype option *}
     6 
     7 theory Option
     8 imports Datatype
     9 begin
    10 
    11 datatype 'a option = None | Some 'a
    12 
    13 lemma not_None_eq [iff]: "(x ~= None) = (EX y. x = Some y)"
    14   by (induct x) auto
    15 
    16 lemma not_Some_eq [iff]: "(ALL y. x ~= Some y) = (x = None)"
    17   by (induct x) auto
    18 
    19 text{*Although it may appear that both of these equalities are helpful
    20 only when applied to assumptions, in practice it seems better to give
    21 them the uniform iff attribute. *}
    22 
    23 lemma inj_Some [simp]: "inj_on Some A"
    24 by (rule inj_onI) simp
    25 
    26 lemma option_caseE:
    27   assumes c: "(case x of None => P | Some y => Q y)"
    28   obtains
    29     (None) "x = None" and P
    30   | (Some) y where "x = Some y" and "Q y"
    31   using c by (cases x) simp_all
    32 
    33 lemma UNIV_option_conv: "UNIV = insert None (range Some)"
    34 by(auto intro: classical)
    35 
    36 
    37 subsubsection {* Operations *}
    38 
    39 primrec the :: "'a option => 'a" where
    40 "the (Some x) = x"
    41 
    42 primrec set :: "'a option => 'a set" where
    43 "set None = {}" |
    44 "set (Some x) = {x}"
    45 
    46 lemma ospec [dest]: "(ALL x:set A. P x) ==> A = Some x ==> P x"
    47   by simp
    48 
    49 declaration {* fn _ =>
    50   Classical.map_cs (fn cs => cs addSD2 ("ospec", @{thm ospec}))
    51 *}
    52 
    53 lemma elem_set [iff]: "(x : set xo) = (xo = Some x)"
    54   by (cases xo) auto
    55 
    56 lemma set_empty_eq [simp]: "(set xo = {}) = (xo = None)"
    57   by (cases xo) auto
    58 
    59 definition map :: "('a \<Rightarrow> 'b) \<Rightarrow> 'a option \<Rightarrow> 'b option" where
    60   "map = (%f y. case y of None => None | Some x => Some (f x))"
    61 
    62 lemma option_map_None [simp, code]: "map f None = None"
    63   by (simp add: map_def)
    64 
    65 lemma option_map_Some [simp, code]: "map f (Some x) = Some (f x)"
    66   by (simp add: map_def)
    67 
    68 lemma option_map_is_None [iff]:
    69     "(map f opt = None) = (opt = None)"
    70   by (simp add: map_def split add: option.split)
    71 
    72 lemma option_map_eq_Some [iff]:
    73     "(map f xo = Some y) = (EX z. xo = Some z & f z = y)"
    74   by (simp add: map_def split add: option.split)
    75 
    76 lemma option_map_comp:
    77     "map f (map g opt) = map (f o g) opt"
    78   by (simp add: map_def split add: option.split)
    79 
    80 lemma option_map_o_sum_case [simp]:
    81     "map f o sum_case g h = sum_case (map f o g) (map f o h)"
    82   by (rule ext) (simp split: sum.split)
    83 
    84 lemma map_cong: "x = y \<Longrightarrow> (\<And>a. y = Some a \<Longrightarrow> f a = g a) \<Longrightarrow> map f x = map g y"
    85 by (cases x) auto
    86 
    87 enriched_type map: Option.map proof -
    88   fix f g
    89   show "Option.map f \<circ> Option.map g = Option.map (f \<circ> g)"
    90   proof
    91     fix x
    92     show "(Option.map f \<circ> Option.map g) x= Option.map (f \<circ> g) x"
    93       by (cases x) simp_all
    94   qed
    95 next
    96   show "Option.map id = id"
    97   proof
    98     fix x
    99     show "Option.map id x = id x"
   100       by (cases x) simp_all
   101   qed
   102 qed
   103 
   104 lemma option_case_map [simp]:
   105   "option_case g h (Option.map f x) = option_case g (h \<circ> f) x"
   106   by (cases x) simp_all
   107 
   108 primrec bind :: "'a option \<Rightarrow> ('a \<Rightarrow> 'b option) \<Rightarrow> 'b option" where
   109 bind_lzero: "bind None f = None" |
   110 bind_lunit: "bind (Some x) f = f x"
   111 
   112 lemma bind_runit[simp]: "bind x Some = x"
   113 by (cases x) auto
   114 
   115 lemma bind_assoc[simp]: "bind (bind x f) g = bind x (\<lambda>y. bind (f y) g)"
   116 by (cases x) auto
   117 
   118 lemma bind_rzero[simp]: "bind x (\<lambda>x. None) = None"
   119 by (cases x) auto
   120 
   121 lemma bind_cong: "x = y \<Longrightarrow> (\<And>a. y = Some a \<Longrightarrow> f a = g a) \<Longrightarrow> bind x f = bind y g"
   122 by (cases x) auto
   123 
   124 definition these :: "'a option set \<Rightarrow> 'a set"
   125 where
   126   "these A = the ` {x \<in> A. x \<noteq> None}"
   127 
   128 lemma these_empty [simp]:
   129   "these {} = {}"
   130   by (simp add: these_def)
   131 
   132 lemma these_insert_None [simp]:
   133   "these (insert None A) = these A"
   134   by (auto simp add: these_def)
   135 
   136 lemma these_insert_Some [simp]:
   137   "these (insert (Some x) A) = insert x (these A)"
   138 proof -
   139   have "{y \<in> insert (Some x) A. y \<noteq> None} = insert (Some x) {y \<in> A. y \<noteq> None}"
   140     by auto
   141   then show ?thesis by (simp add: these_def)
   142 qed
   143 
   144 lemma in_these_eq:
   145   "x \<in> these A \<longleftrightarrow> Some x \<in> A"
   146 proof
   147   assume "Some x \<in> A"
   148   then obtain B where "A = insert (Some x) B" by auto
   149   then show "x \<in> these A" by (auto simp add: these_def intro!: image_eqI)
   150 next
   151   assume "x \<in> these A"
   152   then show "Some x \<in> A" by (auto simp add: these_def)
   153 qed
   154 
   155 lemma these_image_Some_eq [simp]:
   156   "these (Some ` A) = A"
   157   by (auto simp add: these_def intro!: image_eqI)
   158 
   159 lemma Some_image_these_eq:
   160   "Some ` these A = {x\<in>A. x \<noteq> None}"
   161   by (auto simp add: these_def image_image intro!: image_eqI)
   162 
   163 lemma these_empty_eq:
   164   "these B = {} \<longleftrightarrow> B = {} \<or> B = {None}"
   165   by (auto simp add: these_def)
   166 
   167 lemma these_not_empty_eq:
   168   "these B \<noteq> {} \<longleftrightarrow> B \<noteq> {} \<and> B \<noteq> {None}"
   169   by (auto simp add: these_empty_eq)
   170 
   171 hide_const (open) set map bind these
   172 hide_fact (open) map_cong bind_cong
   173 
   174 
   175 subsubsection {* Code generator setup *}
   176 
   177 definition is_none :: "'a option \<Rightarrow> bool" where
   178   [code_post]: "is_none x \<longleftrightarrow> x = None"
   179 
   180 lemma is_none_code [code]:
   181   shows "is_none None \<longleftrightarrow> True"
   182     and "is_none (Some x) \<longleftrightarrow> False"
   183   unfolding is_none_def by simp_all
   184 
   185 lemma [code_unfold]:
   186   "HOL.equal x None \<longleftrightarrow> is_none x"
   187   by (simp add: equal is_none_def)
   188 
   189 hide_const (open) is_none
   190 
   191 code_type option
   192   (SML "_ option")
   193   (OCaml "_ option")
   194   (Haskell "Maybe _")
   195   (Scala "!Option[(_)]")
   196 
   197 code_const None and Some
   198   (SML "NONE" and "SOME")
   199   (OCaml "None" and "Some _")
   200   (Haskell "Nothing" and "Just")
   201   (Scala "!None" and "Some")
   202 
   203 code_instance option :: equal
   204   (Haskell -)
   205 
   206 code_const "HOL.equal \<Colon> 'a option \<Rightarrow> 'a option \<Rightarrow> bool"
   207   (Haskell infix 4 "==")
   208 
   209 code_reserved SML
   210   option NONE SOME
   211 
   212 code_reserved OCaml
   213   option None Some
   214 
   215 code_reserved Scala
   216   Option None Some
   217 
   218 end
   219