src/HOL/Orderings.thy
author hoelzl
Fri Mar 22 10:41:43 2013 +0100 (2013-03-22)
changeset 51474 1e9e68247ad1
parent 51329 4a3c453f99a1
child 51487 f4bfdee99304
permissions -rw-r--r--
generalize Bfun and Bseq to metric spaces; Bseq is an abbreviation for Bfun
     1 (*  Title:      HOL/Orderings.thy
     2     Author:     Tobias Nipkow, Markus Wenzel, and Larry Paulson
     3 *)
     4 
     5 header {* Abstract orderings *}
     6 
     7 theory Orderings
     8 imports HOL
     9 keywords "print_orders" :: diag
    10 begin
    11 
    12 ML_file "~~/src/Provers/order.ML"
    13 ML_file "~~/src/Provers/quasi.ML"  (* FIXME unused? *)
    14 
    15 subsection {* Syntactic orders *}
    16 
    17 class ord =
    18   fixes less_eq :: "'a \<Rightarrow> 'a \<Rightarrow> bool"
    19     and less :: "'a \<Rightarrow> 'a \<Rightarrow> bool"
    20 begin
    21 
    22 notation
    23   less_eq  ("op <=") and
    24   less_eq  ("(_/ <= _)" [51, 51] 50) and
    25   less  ("op <") and
    26   less  ("(_/ < _)"  [51, 51] 50)
    27   
    28 notation (xsymbols)
    29   less_eq  ("op \<le>") and
    30   less_eq  ("(_/ \<le> _)"  [51, 51] 50)
    31 
    32 notation (HTML output)
    33   less_eq  ("op \<le>") and
    34   less_eq  ("(_/ \<le> _)"  [51, 51] 50)
    35 
    36 abbreviation (input)
    37   greater_eq  (infix ">=" 50) where
    38   "x >= y \<equiv> y <= x"
    39 
    40 notation (input)
    41   greater_eq  (infix "\<ge>" 50)
    42 
    43 abbreviation (input)
    44   greater  (infix ">" 50) where
    45   "x > y \<equiv> y < x"
    46 
    47 end
    48 
    49 
    50 subsection {* Quasi orders *}
    51 
    52 class preorder = ord +
    53   assumes less_le_not_le: "x < y \<longleftrightarrow> x \<le> y \<and> \<not> (y \<le> x)"
    54   and order_refl [iff]: "x \<le> x"
    55   and order_trans: "x \<le> y \<Longrightarrow> y \<le> z \<Longrightarrow> x \<le> z"
    56 begin
    57 
    58 text {* Reflexivity. *}
    59 
    60 lemma eq_refl: "x = y \<Longrightarrow> x \<le> y"
    61     -- {* This form is useful with the classical reasoner. *}
    62 by (erule ssubst) (rule order_refl)
    63 
    64 lemma less_irrefl [iff]: "\<not> x < x"
    65 by (simp add: less_le_not_le)
    66 
    67 lemma less_imp_le: "x < y \<Longrightarrow> x \<le> y"
    68 unfolding less_le_not_le by blast
    69 
    70 
    71 text {* Asymmetry. *}
    72 
    73 lemma less_not_sym: "x < y \<Longrightarrow> \<not> (y < x)"
    74 by (simp add: less_le_not_le)
    75 
    76 lemma less_asym: "x < y \<Longrightarrow> (\<not> P \<Longrightarrow> y < x) \<Longrightarrow> P"
    77 by (drule less_not_sym, erule contrapos_np) simp
    78 
    79 
    80 text {* Transitivity. *}
    81 
    82 lemma less_trans: "x < y \<Longrightarrow> y < z \<Longrightarrow> x < z"
    83 by (auto simp add: less_le_not_le intro: order_trans) 
    84 
    85 lemma le_less_trans: "x \<le> y \<Longrightarrow> y < z \<Longrightarrow> x < z"
    86 by (auto simp add: less_le_not_le intro: order_trans) 
    87 
    88 lemma less_le_trans: "x < y \<Longrightarrow> y \<le> z \<Longrightarrow> x < z"
    89 by (auto simp add: less_le_not_le intro: order_trans) 
    90 
    91 
    92 text {* Useful for simplification, but too risky to include by default. *}
    93 
    94 lemma less_imp_not_less: "x < y \<Longrightarrow> (\<not> y < x) \<longleftrightarrow> True"
    95 by (blast elim: less_asym)
    96 
    97 lemma less_imp_triv: "x < y \<Longrightarrow> (y < x \<longrightarrow> P) \<longleftrightarrow> True"
    98 by (blast elim: less_asym)
    99 
   100 
   101 text {* Transitivity rules for calculational reasoning *}
   102 
   103 lemma less_asym': "a < b \<Longrightarrow> b < a \<Longrightarrow> P"
   104 by (rule less_asym)
   105 
   106 
   107 text {* Dual order *}
   108 
   109 lemma dual_preorder:
   110   "class.preorder (op \<ge>) (op >)"
   111 proof qed (auto simp add: less_le_not_le intro: order_trans)
   112 
   113 end
   114 
   115 
   116 subsection {* Partial orders *}
   117 
   118 class order = preorder +
   119   assumes antisym: "x \<le> y \<Longrightarrow> y \<le> x \<Longrightarrow> x = y"
   120 begin
   121 
   122 text {* Reflexivity. *}
   123 
   124 lemma less_le: "x < y \<longleftrightarrow> x \<le> y \<and> x \<noteq> y"
   125 by (auto simp add: less_le_not_le intro: antisym)
   126 
   127 lemma le_less: "x \<le> y \<longleftrightarrow> x < y \<or> x = y"
   128     -- {* NOT suitable for iff, since it can cause PROOF FAILED. *}
   129 by (simp add: less_le) blast
   130 
   131 lemma le_imp_less_or_eq: "x \<le> y \<Longrightarrow> x < y \<or> x = y"
   132 unfolding less_le by blast
   133 
   134 
   135 text {* Useful for simplification, but too risky to include by default. *}
   136 
   137 lemma less_imp_not_eq: "x < y \<Longrightarrow> (x = y) \<longleftrightarrow> False"
   138 by auto
   139 
   140 lemma less_imp_not_eq2: "x < y \<Longrightarrow> (y = x) \<longleftrightarrow> False"
   141 by auto
   142 
   143 
   144 text {* Transitivity rules for calculational reasoning *}
   145 
   146 lemma neq_le_trans: "a \<noteq> b \<Longrightarrow> a \<le> b \<Longrightarrow> a < b"
   147 by (simp add: less_le)
   148 
   149 lemma le_neq_trans: "a \<le> b \<Longrightarrow> a \<noteq> b \<Longrightarrow> a < b"
   150 by (simp add: less_le)
   151 
   152 
   153 text {* Asymmetry. *}
   154 
   155 lemma eq_iff: "x = y \<longleftrightarrow> x \<le> y \<and> y \<le> x"
   156 by (blast intro: antisym)
   157 
   158 lemma antisym_conv: "y \<le> x \<Longrightarrow> x \<le> y \<longleftrightarrow> x = y"
   159 by (blast intro: antisym)
   160 
   161 lemma less_imp_neq: "x < y \<Longrightarrow> x \<noteq> y"
   162 by (erule contrapos_pn, erule subst, rule less_irrefl)
   163 
   164 
   165 text {* Least value operator *}
   166 
   167 definition (in ord)
   168   Least :: "('a \<Rightarrow> bool) \<Rightarrow> 'a" (binder "LEAST " 10) where
   169   "Least P = (THE x. P x \<and> (\<forall>y. P y \<longrightarrow> x \<le> y))"
   170 
   171 lemma Least_equality:
   172   assumes "P x"
   173     and "\<And>y. P y \<Longrightarrow> x \<le> y"
   174   shows "Least P = x"
   175 unfolding Least_def by (rule the_equality)
   176   (blast intro: assms antisym)+
   177 
   178 lemma LeastI2_order:
   179   assumes "P x"
   180     and "\<And>y. P y \<Longrightarrow> x \<le> y"
   181     and "\<And>x. P x \<Longrightarrow> \<forall>y. P y \<longrightarrow> x \<le> y \<Longrightarrow> Q x"
   182   shows "Q (Least P)"
   183 unfolding Least_def by (rule theI2)
   184   (blast intro: assms antisym)+
   185 
   186 
   187 text {* Dual order *}
   188 
   189 lemma dual_order:
   190   "class.order (op \<ge>) (op >)"
   191 by (intro_locales, rule dual_preorder) (unfold_locales, rule antisym)
   192 
   193 end
   194 
   195 
   196 subsection {* Linear (total) orders *}
   197 
   198 class linorder = order +
   199   assumes linear: "x \<le> y \<or> y \<le> x"
   200 begin
   201 
   202 lemma less_linear: "x < y \<or> x = y \<or> y < x"
   203 unfolding less_le using less_le linear by blast
   204 
   205 lemma le_less_linear: "x \<le> y \<or> y < x"
   206 by (simp add: le_less less_linear)
   207 
   208 lemma le_cases [case_names le ge]:
   209   "(x \<le> y \<Longrightarrow> P) \<Longrightarrow> (y \<le> x \<Longrightarrow> P) \<Longrightarrow> P"
   210 using linear by blast
   211 
   212 lemma linorder_cases [case_names less equal greater]:
   213   "(x < y \<Longrightarrow> P) \<Longrightarrow> (x = y \<Longrightarrow> P) \<Longrightarrow> (y < x \<Longrightarrow> P) \<Longrightarrow> P"
   214 using less_linear by blast
   215 
   216 lemma not_less: "\<not> x < y \<longleftrightarrow> y \<le> x"
   217 apply (simp add: less_le)
   218 using linear apply (blast intro: antisym)
   219 done
   220 
   221 lemma not_less_iff_gr_or_eq:
   222  "\<not>(x < y) \<longleftrightarrow> (x > y | x = y)"
   223 apply(simp add:not_less le_less)
   224 apply blast
   225 done
   226 
   227 lemma not_le: "\<not> x \<le> y \<longleftrightarrow> y < x"
   228 apply (simp add: less_le)
   229 using linear apply (blast intro: antisym)
   230 done
   231 
   232 lemma neq_iff: "x \<noteq> y \<longleftrightarrow> x < y \<or> y < x"
   233 by (cut_tac x = x and y = y in less_linear, auto)
   234 
   235 lemma neqE: "x \<noteq> y \<Longrightarrow> (x < y \<Longrightarrow> R) \<Longrightarrow> (y < x \<Longrightarrow> R) \<Longrightarrow> R"
   236 by (simp add: neq_iff) blast
   237 
   238 lemma antisym_conv1: "\<not> x < y \<Longrightarrow> x \<le> y \<longleftrightarrow> x = y"
   239 by (blast intro: antisym dest: not_less [THEN iffD1])
   240 
   241 lemma antisym_conv2: "x \<le> y \<Longrightarrow> \<not> x < y \<longleftrightarrow> x = y"
   242 by (blast intro: antisym dest: not_less [THEN iffD1])
   243 
   244 lemma antisym_conv3: "\<not> y < x \<Longrightarrow> \<not> x < y \<longleftrightarrow> x = y"
   245 by (blast intro: antisym dest: not_less [THEN iffD1])
   246 
   247 lemma leI: "\<not> x < y \<Longrightarrow> y \<le> x"
   248 unfolding not_less .
   249 
   250 lemma leD: "y \<le> x \<Longrightarrow> \<not> x < y"
   251 unfolding not_less .
   252 
   253 (*FIXME inappropriate name (or delete altogether)*)
   254 lemma not_leE: "\<not> y \<le> x \<Longrightarrow> x < y"
   255 unfolding not_le .
   256 
   257 
   258 text {* Dual order *}
   259 
   260 lemma dual_linorder:
   261   "class.linorder (op \<ge>) (op >)"
   262 by (rule class.linorder.intro, rule dual_order) (unfold_locales, rule linear)
   263 
   264 
   265 text {* min/max *}
   266 
   267 definition (in ord) min :: "'a \<Rightarrow> 'a \<Rightarrow> 'a" where
   268   "min a b = (if a \<le> b then a else b)"
   269 
   270 definition (in ord) max :: "'a \<Rightarrow> 'a \<Rightarrow> 'a" where
   271   "max a b = (if a \<le> b then b else a)"
   272 
   273 lemma min_le_iff_disj:
   274   "min x y \<le> z \<longleftrightarrow> x \<le> z \<or> y \<le> z"
   275 unfolding min_def using linear by (auto intro: order_trans)
   276 
   277 lemma le_max_iff_disj:
   278   "z \<le> max x y \<longleftrightarrow> z \<le> x \<or> z \<le> y"
   279 unfolding max_def using linear by (auto intro: order_trans)
   280 
   281 lemma min_less_iff_disj:
   282   "min x y < z \<longleftrightarrow> x < z \<or> y < z"
   283 unfolding min_def le_less using less_linear by (auto intro: less_trans)
   284 
   285 lemma less_max_iff_disj:
   286   "z < max x y \<longleftrightarrow> z < x \<or> z < y"
   287 unfolding max_def le_less using less_linear by (auto intro: less_trans)
   288 
   289 lemma min_less_iff_conj [simp]:
   290   "z < min x y \<longleftrightarrow> z < x \<and> z < y"
   291 unfolding min_def le_less using less_linear by (auto intro: less_trans)
   292 
   293 lemma max_less_iff_conj [simp]:
   294   "max x y < z \<longleftrightarrow> x < z \<and> y < z"
   295 unfolding max_def le_less using less_linear by (auto intro: less_trans)
   296 
   297 lemma split_min [no_atp]:
   298   "P (min i j) \<longleftrightarrow> (i \<le> j \<longrightarrow> P i) \<and> (\<not> i \<le> j \<longrightarrow> P j)"
   299 by (simp add: min_def)
   300 
   301 lemma split_max [no_atp]:
   302   "P (max i j) \<longleftrightarrow> (i \<le> j \<longrightarrow> P j) \<and> (\<not> i \<le> j \<longrightarrow> P i)"
   303 by (simp add: max_def)
   304 
   305 end
   306 
   307 
   308 subsection {* Reasoning tools setup *}
   309 
   310 ML {*
   311 
   312 signature ORDERS =
   313 sig
   314   val print_structures: Proof.context -> unit
   315   val attrib_setup: theory -> theory
   316   val order_tac: Proof.context -> thm list -> int -> tactic
   317 end;
   318 
   319 structure Orders: ORDERS =
   320 struct
   321 
   322 (** Theory and context data **)
   323 
   324 fun struct_eq ((s1: string, ts1), (s2, ts2)) =
   325   (s1 = s2) andalso eq_list (op aconv) (ts1, ts2);
   326 
   327 structure Data = Generic_Data
   328 (
   329   type T = ((string * term list) * Order_Tac.less_arith) list;
   330     (* Order structures:
   331        identifier of the structure, list of operations and record of theorems
   332        needed to set up the transitivity reasoner,
   333        identifier and operations identify the structure uniquely. *)
   334   val empty = [];
   335   val extend = I;
   336   fun merge data = AList.join struct_eq (K fst) data;
   337 );
   338 
   339 fun print_structures ctxt =
   340   let
   341     val structs = Data.get (Context.Proof ctxt);
   342     fun pretty_term t = Pretty.block
   343       [Pretty.quote (Syntax.pretty_term ctxt t), Pretty.brk 1,
   344         Pretty.str "::", Pretty.brk 1,
   345         Pretty.quote (Syntax.pretty_typ ctxt (type_of t))];
   346     fun pretty_struct ((s, ts), _) = Pretty.block
   347       [Pretty.str s, Pretty.str ":", Pretty.brk 1,
   348        Pretty.enclose "(" ")" (Pretty.breaks (map pretty_term ts))];
   349   in
   350     Pretty.writeln (Pretty.big_list "Order structures:" (map pretty_struct structs))
   351   end;
   352 
   353 
   354 (** Method **)
   355 
   356 fun struct_tac ((s, [eq, le, less]), thms) ctxt prems =
   357   let
   358     fun decomp thy (@{const Trueprop} $ t) =
   359       let
   360         fun excluded t =
   361           (* exclude numeric types: linear arithmetic subsumes transitivity *)
   362           let val T = type_of t
   363           in
   364             T = HOLogic.natT orelse T = HOLogic.intT orelse T = HOLogic.realT
   365           end;
   366         fun rel (bin_op $ t1 $ t2) =
   367               if excluded t1 then NONE
   368               else if Pattern.matches thy (eq, bin_op) then SOME (t1, "=", t2)
   369               else if Pattern.matches thy (le, bin_op) then SOME (t1, "<=", t2)
   370               else if Pattern.matches thy (less, bin_op) then SOME (t1, "<", t2)
   371               else NONE
   372           | rel _ = NONE;
   373         fun dec (Const (@{const_name Not}, _) $ t) = (case rel t
   374               of NONE => NONE
   375                | SOME (t1, rel, t2) => SOME (t1, "~" ^ rel, t2))
   376           | dec x = rel x;
   377       in dec t end
   378       | decomp thy _ = NONE;
   379   in
   380     case s of
   381       "order" => Order_Tac.partial_tac decomp thms ctxt prems
   382     | "linorder" => Order_Tac.linear_tac decomp thms ctxt prems
   383     | _ => error ("Unknown kind of order `" ^ s ^ "' encountered in transitivity reasoner.")
   384   end
   385 
   386 fun order_tac ctxt prems =
   387   FIRST' (map (fn s => CHANGED o struct_tac s ctxt prems) (Data.get (Context.Proof ctxt)));
   388 
   389 
   390 (** Attribute **)
   391 
   392 fun add_struct_thm s tag =
   393   Thm.declaration_attribute
   394     (fn thm => Data.map (AList.map_default struct_eq (s, Order_Tac.empty TrueI) (Order_Tac.update tag thm)));
   395 fun del_struct s =
   396   Thm.declaration_attribute
   397     (fn _ => Data.map (AList.delete struct_eq s));
   398 
   399 val attrib_setup =
   400   Attrib.setup @{binding order}
   401     (Scan.lift ((Args.add -- Args.name >> (fn (_, s) => SOME s) || Args.del >> K NONE) --|
   402       Args.colon (* FIXME || Scan.succeed true *) ) -- Scan.lift Args.name --
   403       Scan.repeat Args.term
   404       >> (fn ((SOME tag, n), ts) => add_struct_thm (n, ts) tag
   405            | ((NONE, n), ts) => del_struct (n, ts)))
   406     "theorems controlling transitivity reasoner";
   407 
   408 
   409 (** Diagnostic command **)
   410 
   411 val _ =
   412   Outer_Syntax.improper_command @{command_spec "print_orders"}
   413     "print order structures available to transitivity reasoner"
   414     (Scan.succeed (Toplevel.no_timing o Toplevel.unknown_context o
   415         Toplevel.keep (print_structures o Toplevel.context_of)));
   416 
   417 end;
   418 
   419 *}
   420 
   421 setup Orders.attrib_setup
   422 
   423 method_setup order = {*
   424   Scan.succeed (fn ctxt => SIMPLE_METHOD' (Orders.order_tac ctxt []))
   425 *} "transitivity reasoner"
   426 
   427 
   428 text {* Declarations to set up transitivity reasoner of partial and linear orders. *}
   429 
   430 context order
   431 begin
   432 
   433 (* The type constraint on @{term op =} below is necessary since the operation
   434    is not a parameter of the locale. *)
   435 
   436 declare less_irrefl [THEN notE, order add less_reflE: order "op = :: 'a \<Rightarrow> 'a \<Rightarrow> bool" "op <=" "op <"]
   437   
   438 declare order_refl  [order add le_refl: order "op = :: 'a => 'a => bool" "op <=" "op <"]
   439   
   440 declare less_imp_le [order add less_imp_le: order "op = :: 'a => 'a => bool" "op <=" "op <"]
   441   
   442 declare antisym [order add eqI: order "op = :: 'a => 'a => bool" "op <=" "op <"]
   443 
   444 declare eq_refl [order add eqD1: order "op = :: 'a => 'a => bool" "op <=" "op <"]
   445 
   446 declare sym [THEN eq_refl, order add eqD2: order "op = :: 'a => 'a => bool" "op <=" "op <"]
   447 
   448 declare less_trans [order add less_trans: order "op = :: 'a => 'a => bool" "op <=" "op <"]
   449   
   450 declare less_le_trans [order add less_le_trans: order "op = :: 'a => 'a => bool" "op <=" "op <"]
   451   
   452 declare le_less_trans [order add le_less_trans: order "op = :: 'a => 'a => bool" "op <=" "op <"]
   453 
   454 declare order_trans [order add le_trans: order "op = :: 'a => 'a => bool" "op <=" "op <"]
   455 
   456 declare le_neq_trans [order add le_neq_trans: order "op = :: 'a => 'a => bool" "op <=" "op <"]
   457 
   458 declare neq_le_trans [order add neq_le_trans: order "op = :: 'a => 'a => bool" "op <=" "op <"]
   459 
   460 declare less_imp_neq [order add less_imp_neq: order "op = :: 'a => 'a => bool" "op <=" "op <"]
   461 
   462 declare eq_neq_eq_imp_neq [order add eq_neq_eq_imp_neq: order "op = :: 'a => 'a => bool" "op <=" "op <"]
   463 
   464 declare not_sym [order add not_sym: order "op = :: 'a => 'a => bool" "op <=" "op <"]
   465 
   466 end
   467 
   468 context linorder
   469 begin
   470 
   471 declare [[order del: order "op = :: 'a => 'a => bool" "op <=" "op <"]]
   472 
   473 declare less_irrefl [THEN notE, order add less_reflE: linorder "op = :: 'a => 'a => bool" "op <=" "op <"]
   474 
   475 declare order_refl [order add le_refl: linorder "op = :: 'a => 'a => bool" "op <=" "op <"]
   476 
   477 declare less_imp_le [order add less_imp_le: linorder "op = :: 'a => 'a => bool" "op <=" "op <"]
   478 
   479 declare not_less [THEN iffD2, order add not_lessI: linorder "op = :: 'a => 'a => bool" "op <=" "op <"]
   480 
   481 declare not_le [THEN iffD2, order add not_leI: linorder "op = :: 'a => 'a => bool" "op <=" "op <"]
   482 
   483 declare not_less [THEN iffD1, order add not_lessD: linorder "op = :: 'a => 'a => bool" "op <=" "op <"]
   484 
   485 declare not_le [THEN iffD1, order add not_leD: linorder "op = :: 'a => 'a => bool" "op <=" "op <"]
   486 
   487 declare antisym [order add eqI: linorder "op = :: 'a => 'a => bool" "op <=" "op <"]
   488 
   489 declare eq_refl [order add eqD1: linorder "op = :: 'a => 'a => bool" "op <=" "op <"]
   490 
   491 declare sym [THEN eq_refl, order add eqD2: linorder "op = :: 'a => 'a => bool" "op <=" "op <"]
   492 
   493 declare less_trans [order add less_trans: linorder "op = :: 'a => 'a => bool" "op <=" "op <"]
   494 
   495 declare less_le_trans [order add less_le_trans: linorder "op = :: 'a => 'a => bool" "op <=" "op <"]
   496 
   497 declare le_less_trans [order add le_less_trans: linorder "op = :: 'a => 'a => bool" "op <=" "op <"]
   498 
   499 declare order_trans [order add le_trans: linorder "op = :: 'a => 'a => bool" "op <=" "op <"]
   500 
   501 declare le_neq_trans [order add le_neq_trans: linorder "op = :: 'a => 'a => bool" "op <=" "op <"]
   502 
   503 declare neq_le_trans [order add neq_le_trans: linorder "op = :: 'a => 'a => bool" "op <=" "op <"]
   504 
   505 declare less_imp_neq [order add less_imp_neq: linorder "op = :: 'a => 'a => bool" "op <=" "op <"]
   506 
   507 declare eq_neq_eq_imp_neq [order add eq_neq_eq_imp_neq: linorder "op = :: 'a => 'a => bool" "op <=" "op <"]
   508 
   509 declare not_sym [order add not_sym: linorder "op = :: 'a => 'a => bool" "op <=" "op <"]
   510 
   511 end
   512 
   513 
   514 setup {*
   515 let
   516 
   517 fun prp t thm = Thm.prop_of thm = t;  (* FIXME aconv!? *)
   518 
   519 fun prove_antisym_le sg ss ((le as Const(_,T)) $ r $ s) =
   520   let val prems = Simplifier.prems_of ss;
   521       val less = Const (@{const_name less}, T);
   522       val t = HOLogic.mk_Trueprop(le $ s $ r);
   523   in case find_first (prp t) prems of
   524        NONE =>
   525          let val t = HOLogic.mk_Trueprop(HOLogic.Not $ (less $ r $ s))
   526          in case find_first (prp t) prems of
   527               NONE => NONE
   528             | SOME thm => SOME(mk_meta_eq(thm RS @{thm linorder_class.antisym_conv1}))
   529          end
   530      | SOME thm => SOME(mk_meta_eq(thm RS @{thm order_class.antisym_conv}))
   531   end
   532   handle THM _ => NONE;
   533 
   534 fun prove_antisym_less sg ss (NotC $ ((less as Const(_,T)) $ r $ s)) =
   535   let val prems = Simplifier.prems_of ss;
   536       val le = Const (@{const_name less_eq}, T);
   537       val t = HOLogic.mk_Trueprop(le $ r $ s);
   538   in case find_first (prp t) prems of
   539        NONE =>
   540          let val t = HOLogic.mk_Trueprop(NotC $ (less $ s $ r))
   541          in case find_first (prp t) prems of
   542               NONE => NONE
   543             | SOME thm => SOME(mk_meta_eq(thm RS @{thm linorder_class.antisym_conv3}))
   544          end
   545      | SOME thm => SOME(mk_meta_eq(thm RS @{thm linorder_class.antisym_conv2}))
   546   end
   547   handle THM _ => NONE;
   548 
   549 fun add_simprocs procs thy =
   550   Simplifier.map_simpset_global (fn ss => ss
   551     addsimprocs (map (fn (name, raw_ts, proc) =>
   552       Simplifier.simproc_global thy name raw_ts proc) procs)) thy;
   553 
   554 fun add_solver name tac =
   555   Simplifier.map_simpset_global (fn ss => ss addSolver
   556     mk_solver name (fn ss => tac (Simplifier.the_context ss) (Simplifier.prems_of ss)));
   557 
   558 in
   559   add_simprocs [
   560        ("antisym le", ["(x::'a::order) <= y"], prove_antisym_le),
   561        ("antisym less", ["~ (x::'a::linorder) < y"], prove_antisym_less)
   562      ]
   563   #> add_solver "Transitivity" Orders.order_tac
   564   (* Adding the transitivity reasoners also as safe solvers showed a slight
   565      speed up, but the reasoning strength appears to be not higher (at least
   566      no breaking of additional proofs in the entire HOL distribution, as
   567      of 5 March 2004, was observed). *)
   568 end
   569 *}
   570 
   571 
   572 subsection {* Bounded quantifiers *}
   573 
   574 syntax
   575   "_All_less" :: "[idt, 'a, bool] => bool"    ("(3ALL _<_./ _)"  [0, 0, 10] 10)
   576   "_Ex_less" :: "[idt, 'a, bool] => bool"    ("(3EX _<_./ _)"  [0, 0, 10] 10)
   577   "_All_less_eq" :: "[idt, 'a, bool] => bool"    ("(3ALL _<=_./ _)" [0, 0, 10] 10)
   578   "_Ex_less_eq" :: "[idt, 'a, bool] => bool"    ("(3EX _<=_./ _)" [0, 0, 10] 10)
   579 
   580   "_All_greater" :: "[idt, 'a, bool] => bool"    ("(3ALL _>_./ _)"  [0, 0, 10] 10)
   581   "_Ex_greater" :: "[idt, 'a, bool] => bool"    ("(3EX _>_./ _)"  [0, 0, 10] 10)
   582   "_All_greater_eq" :: "[idt, 'a, bool] => bool"    ("(3ALL _>=_./ _)" [0, 0, 10] 10)
   583   "_Ex_greater_eq" :: "[idt, 'a, bool] => bool"    ("(3EX _>=_./ _)" [0, 0, 10] 10)
   584 
   585 syntax (xsymbols)
   586   "_All_less" :: "[idt, 'a, bool] => bool"    ("(3\<forall>_<_./ _)"  [0, 0, 10] 10)
   587   "_Ex_less" :: "[idt, 'a, bool] => bool"    ("(3\<exists>_<_./ _)"  [0, 0, 10] 10)
   588   "_All_less_eq" :: "[idt, 'a, bool] => bool"    ("(3\<forall>_\<le>_./ _)" [0, 0, 10] 10)
   589   "_Ex_less_eq" :: "[idt, 'a, bool] => bool"    ("(3\<exists>_\<le>_./ _)" [0, 0, 10] 10)
   590 
   591   "_All_greater" :: "[idt, 'a, bool] => bool"    ("(3\<forall>_>_./ _)"  [0, 0, 10] 10)
   592   "_Ex_greater" :: "[idt, 'a, bool] => bool"    ("(3\<exists>_>_./ _)"  [0, 0, 10] 10)
   593   "_All_greater_eq" :: "[idt, 'a, bool] => bool"    ("(3\<forall>_\<ge>_./ _)" [0, 0, 10] 10)
   594   "_Ex_greater_eq" :: "[idt, 'a, bool] => bool"    ("(3\<exists>_\<ge>_./ _)" [0, 0, 10] 10)
   595 
   596 syntax (HOL)
   597   "_All_less" :: "[idt, 'a, bool] => bool"    ("(3! _<_./ _)"  [0, 0, 10] 10)
   598   "_Ex_less" :: "[idt, 'a, bool] => bool"    ("(3? _<_./ _)"  [0, 0, 10] 10)
   599   "_All_less_eq" :: "[idt, 'a, bool] => bool"    ("(3! _<=_./ _)" [0, 0, 10] 10)
   600   "_Ex_less_eq" :: "[idt, 'a, bool] => bool"    ("(3? _<=_./ _)" [0, 0, 10] 10)
   601 
   602 syntax (HTML output)
   603   "_All_less" :: "[idt, 'a, bool] => bool"    ("(3\<forall>_<_./ _)"  [0, 0, 10] 10)
   604   "_Ex_less" :: "[idt, 'a, bool] => bool"    ("(3\<exists>_<_./ _)"  [0, 0, 10] 10)
   605   "_All_less_eq" :: "[idt, 'a, bool] => bool"    ("(3\<forall>_\<le>_./ _)" [0, 0, 10] 10)
   606   "_Ex_less_eq" :: "[idt, 'a, bool] => bool"    ("(3\<exists>_\<le>_./ _)" [0, 0, 10] 10)
   607 
   608   "_All_greater" :: "[idt, 'a, bool] => bool"    ("(3\<forall>_>_./ _)"  [0, 0, 10] 10)
   609   "_Ex_greater" :: "[idt, 'a, bool] => bool"    ("(3\<exists>_>_./ _)"  [0, 0, 10] 10)
   610   "_All_greater_eq" :: "[idt, 'a, bool] => bool"    ("(3\<forall>_\<ge>_./ _)" [0, 0, 10] 10)
   611   "_Ex_greater_eq" :: "[idt, 'a, bool] => bool"    ("(3\<exists>_\<ge>_./ _)" [0, 0, 10] 10)
   612 
   613 translations
   614   "ALL x<y. P"   =>  "ALL x. x < y \<longrightarrow> P"
   615   "EX x<y. P"    =>  "EX x. x < y \<and> P"
   616   "ALL x<=y. P"  =>  "ALL x. x <= y \<longrightarrow> P"
   617   "EX x<=y. P"   =>  "EX x. x <= y \<and> P"
   618   "ALL x>y. P"   =>  "ALL x. x > y \<longrightarrow> P"
   619   "EX x>y. P"    =>  "EX x. x > y \<and> P"
   620   "ALL x>=y. P"  =>  "ALL x. x >= y \<longrightarrow> P"
   621   "EX x>=y. P"   =>  "EX x. x >= y \<and> P"
   622 
   623 print_translation {*
   624 let
   625   val All_binder = Mixfix.binder_name @{const_syntax All};
   626   val Ex_binder = Mixfix.binder_name @{const_syntax Ex};
   627   val impl = @{const_syntax HOL.implies};
   628   val conj = @{const_syntax HOL.conj};
   629   val less = @{const_syntax less};
   630   val less_eq = @{const_syntax less_eq};
   631 
   632   val trans =
   633    [((All_binder, impl, less),
   634     (@{syntax_const "_All_less"}, @{syntax_const "_All_greater"})),
   635     ((All_binder, impl, less_eq),
   636     (@{syntax_const "_All_less_eq"}, @{syntax_const "_All_greater_eq"})),
   637     ((Ex_binder, conj, less),
   638     (@{syntax_const "_Ex_less"}, @{syntax_const "_Ex_greater"})),
   639     ((Ex_binder, conj, less_eq),
   640     (@{syntax_const "_Ex_less_eq"}, @{syntax_const "_Ex_greater_eq"}))];
   641 
   642   fun matches_bound v t =
   643     (case t of
   644       Const (@{syntax_const "_bound"}, _) $ Free (v', _) => v = v'
   645     | _ => false);
   646   fun contains_var v = Term.exists_subterm (fn Free (x, _) => x = v | _ => false);
   647   fun mk x c n P = Syntax.const c $ Syntax_Trans.mark_bound_body x $ n $ P;
   648 
   649   fun tr' q = (q,
   650     fn [Const (@{syntax_const "_bound"}, _) $ Free (v, T),
   651         Const (c, _) $ (Const (d, _) $ t $ u) $ P] =>
   652         (case AList.lookup (op =) trans (q, c, d) of
   653           NONE => raise Match
   654         | SOME (l, g) =>
   655             if matches_bound v t andalso not (contains_var v u) then mk (v, T) l u P
   656             else if matches_bound v u andalso not (contains_var v t) then mk (v, T) g t P
   657             else raise Match)
   658      | _ => raise Match);
   659 in [tr' All_binder, tr' Ex_binder] end
   660 *}
   661 
   662 
   663 subsection {* Transitivity reasoning *}
   664 
   665 context ord
   666 begin
   667 
   668 lemma ord_le_eq_trans: "a \<le> b \<Longrightarrow> b = c \<Longrightarrow> a \<le> c"
   669   by (rule subst)
   670 
   671 lemma ord_eq_le_trans: "a = b \<Longrightarrow> b \<le> c \<Longrightarrow> a \<le> c"
   672   by (rule ssubst)
   673 
   674 lemma ord_less_eq_trans: "a < b \<Longrightarrow> b = c \<Longrightarrow> a < c"
   675   by (rule subst)
   676 
   677 lemma ord_eq_less_trans: "a = b \<Longrightarrow> b < c \<Longrightarrow> a < c"
   678   by (rule ssubst)
   679 
   680 end
   681 
   682 lemma order_less_subst2: "(a::'a::order) < b ==> f b < (c::'c::order) ==>
   683   (!!x y. x < y ==> f x < f y) ==> f a < c"
   684 proof -
   685   assume r: "!!x y. x < y ==> f x < f y"
   686   assume "a < b" hence "f a < f b" by (rule r)
   687   also assume "f b < c"
   688   finally (less_trans) show ?thesis .
   689 qed
   690 
   691 lemma order_less_subst1: "(a::'a::order) < f b ==> (b::'b::order) < c ==>
   692   (!!x y. x < y ==> f x < f y) ==> a < f c"
   693 proof -
   694   assume r: "!!x y. x < y ==> f x < f y"
   695   assume "a < f b"
   696   also assume "b < c" hence "f b < f c" by (rule r)
   697   finally (less_trans) show ?thesis .
   698 qed
   699 
   700 lemma order_le_less_subst2: "(a::'a::order) <= b ==> f b < (c::'c::order) ==>
   701   (!!x y. x <= y ==> f x <= f y) ==> f a < c"
   702 proof -
   703   assume r: "!!x y. x <= y ==> f x <= f y"
   704   assume "a <= b" hence "f a <= f b" by (rule r)
   705   also assume "f b < c"
   706   finally (le_less_trans) show ?thesis .
   707 qed
   708 
   709 lemma order_le_less_subst1: "(a::'a::order) <= f b ==> (b::'b::order) < c ==>
   710   (!!x y. x < y ==> f x < f y) ==> a < f c"
   711 proof -
   712   assume r: "!!x y. x < y ==> f x < f y"
   713   assume "a <= f b"
   714   also assume "b < c" hence "f b < f c" by (rule r)
   715   finally (le_less_trans) show ?thesis .
   716 qed
   717 
   718 lemma order_less_le_subst2: "(a::'a::order) < b ==> f b <= (c::'c::order) ==>
   719   (!!x y. x < y ==> f x < f y) ==> f a < c"
   720 proof -
   721   assume r: "!!x y. x < y ==> f x < f y"
   722   assume "a < b" hence "f a < f b" by (rule r)
   723   also assume "f b <= c"
   724   finally (less_le_trans) show ?thesis .
   725 qed
   726 
   727 lemma order_less_le_subst1: "(a::'a::order) < f b ==> (b::'b::order) <= c ==>
   728   (!!x y. x <= y ==> f x <= f y) ==> a < f c"
   729 proof -
   730   assume r: "!!x y. x <= y ==> f x <= f y"
   731   assume "a < f b"
   732   also assume "b <= c" hence "f b <= f c" by (rule r)
   733   finally (less_le_trans) show ?thesis .
   734 qed
   735 
   736 lemma order_subst1: "(a::'a::order) <= f b ==> (b::'b::order) <= c ==>
   737   (!!x y. x <= y ==> f x <= f y) ==> a <= f c"
   738 proof -
   739   assume r: "!!x y. x <= y ==> f x <= f y"
   740   assume "a <= f b"
   741   also assume "b <= c" hence "f b <= f c" by (rule r)
   742   finally (order_trans) show ?thesis .
   743 qed
   744 
   745 lemma order_subst2: "(a::'a::order) <= b ==> f b <= (c::'c::order) ==>
   746   (!!x y. x <= y ==> f x <= f y) ==> f a <= c"
   747 proof -
   748   assume r: "!!x y. x <= y ==> f x <= f y"
   749   assume "a <= b" hence "f a <= f b" by (rule r)
   750   also assume "f b <= c"
   751   finally (order_trans) show ?thesis .
   752 qed
   753 
   754 lemma ord_le_eq_subst: "a <= b ==> f b = c ==>
   755   (!!x y. x <= y ==> f x <= f y) ==> f a <= c"
   756 proof -
   757   assume r: "!!x y. x <= y ==> f x <= f y"
   758   assume "a <= b" hence "f a <= f b" by (rule r)
   759   also assume "f b = c"
   760   finally (ord_le_eq_trans) show ?thesis .
   761 qed
   762 
   763 lemma ord_eq_le_subst: "a = f b ==> b <= c ==>
   764   (!!x y. x <= y ==> f x <= f y) ==> a <= f c"
   765 proof -
   766   assume r: "!!x y. x <= y ==> f x <= f y"
   767   assume "a = f b"
   768   also assume "b <= c" hence "f b <= f c" by (rule r)
   769   finally (ord_eq_le_trans) show ?thesis .
   770 qed
   771 
   772 lemma ord_less_eq_subst: "a < b ==> f b = c ==>
   773   (!!x y. x < y ==> f x < f y) ==> f a < c"
   774 proof -
   775   assume r: "!!x y. x < y ==> f x < f y"
   776   assume "a < b" hence "f a < f b" by (rule r)
   777   also assume "f b = c"
   778   finally (ord_less_eq_trans) show ?thesis .
   779 qed
   780 
   781 lemma ord_eq_less_subst: "a = f b ==> b < c ==>
   782   (!!x y. x < y ==> f x < f y) ==> a < f c"
   783 proof -
   784   assume r: "!!x y. x < y ==> f x < f y"
   785   assume "a = f b"
   786   also assume "b < c" hence "f b < f c" by (rule r)
   787   finally (ord_eq_less_trans) show ?thesis .
   788 qed
   789 
   790 text {*
   791   Note that this list of rules is in reverse order of priorities.
   792 *}
   793 
   794 lemmas [trans] =
   795   order_less_subst2
   796   order_less_subst1
   797   order_le_less_subst2
   798   order_le_less_subst1
   799   order_less_le_subst2
   800   order_less_le_subst1
   801   order_subst2
   802   order_subst1
   803   ord_le_eq_subst
   804   ord_eq_le_subst
   805   ord_less_eq_subst
   806   ord_eq_less_subst
   807   forw_subst
   808   back_subst
   809   rev_mp
   810   mp
   811 
   812 lemmas (in order) [trans] =
   813   neq_le_trans
   814   le_neq_trans
   815 
   816 lemmas (in preorder) [trans] =
   817   less_trans
   818   less_asym'
   819   le_less_trans
   820   less_le_trans
   821   order_trans
   822 
   823 lemmas (in order) [trans] =
   824   antisym
   825 
   826 lemmas (in ord) [trans] =
   827   ord_le_eq_trans
   828   ord_eq_le_trans
   829   ord_less_eq_trans
   830   ord_eq_less_trans
   831 
   832 lemmas [trans] =
   833   trans
   834 
   835 lemmas order_trans_rules =
   836   order_less_subst2
   837   order_less_subst1
   838   order_le_less_subst2
   839   order_le_less_subst1
   840   order_less_le_subst2
   841   order_less_le_subst1
   842   order_subst2
   843   order_subst1
   844   ord_le_eq_subst
   845   ord_eq_le_subst
   846   ord_less_eq_subst
   847   ord_eq_less_subst
   848   forw_subst
   849   back_subst
   850   rev_mp
   851   mp
   852   neq_le_trans
   853   le_neq_trans
   854   less_trans
   855   less_asym'
   856   le_less_trans
   857   less_le_trans
   858   order_trans
   859   antisym
   860   ord_le_eq_trans
   861   ord_eq_le_trans
   862   ord_less_eq_trans
   863   ord_eq_less_trans
   864   trans
   865 
   866 text {* These support proving chains of decreasing inequalities
   867     a >= b >= c ... in Isar proofs. *}
   868 
   869 lemma xt1 [no_atp]:
   870   "a = b ==> b > c ==> a > c"
   871   "a > b ==> b = c ==> a > c"
   872   "a = b ==> b >= c ==> a >= c"
   873   "a >= b ==> b = c ==> a >= c"
   874   "(x::'a::order) >= y ==> y >= x ==> x = y"
   875   "(x::'a::order) >= y ==> y >= z ==> x >= z"
   876   "(x::'a::order) > y ==> y >= z ==> x > z"
   877   "(x::'a::order) >= y ==> y > z ==> x > z"
   878   "(a::'a::order) > b ==> b > a ==> P"
   879   "(x::'a::order) > y ==> y > z ==> x > z"
   880   "(a::'a::order) >= b ==> a ~= b ==> a > b"
   881   "(a::'a::order) ~= b ==> a >= b ==> a > b"
   882   "a = f b ==> b > c ==> (!!x y. x > y ==> f x > f y) ==> a > f c" 
   883   "a > b ==> f b = c ==> (!!x y. x > y ==> f x > f y) ==> f a > c"
   884   "a = f b ==> b >= c ==> (!!x y. x >= y ==> f x >= f y) ==> a >= f c"
   885   "a >= b ==> f b = c ==> (!! x y. x >= y ==> f x >= f y) ==> f a >= c"
   886   by auto
   887 
   888 lemma xt2 [no_atp]:
   889   "(a::'a::order) >= f b ==> b >= c ==> (!!x y. x >= y ==> f x >= f y) ==> a >= f c"
   890 by (subgoal_tac "f b >= f c", force, force)
   891 
   892 lemma xt3 [no_atp]: "(a::'a::order) >= b ==> (f b::'b::order) >= c ==>
   893     (!!x y. x >= y ==> f x >= f y) ==> f a >= c"
   894 by (subgoal_tac "f a >= f b", force, force)
   895 
   896 lemma xt4 [no_atp]: "(a::'a::order) > f b ==> (b::'b::order) >= c ==>
   897   (!!x y. x >= y ==> f x >= f y) ==> a > f c"
   898 by (subgoal_tac "f b >= f c", force, force)
   899 
   900 lemma xt5 [no_atp]: "(a::'a::order) > b ==> (f b::'b::order) >= c==>
   901     (!!x y. x > y ==> f x > f y) ==> f a > c"
   902 by (subgoal_tac "f a > f b", force, force)
   903 
   904 lemma xt6 [no_atp]: "(a::'a::order) >= f b ==> b > c ==>
   905     (!!x y. x > y ==> f x > f y) ==> a > f c"
   906 by (subgoal_tac "f b > f c", force, force)
   907 
   908 lemma xt7 [no_atp]: "(a::'a::order) >= b ==> (f b::'b::order) > c ==>
   909     (!!x y. x >= y ==> f x >= f y) ==> f a > c"
   910 by (subgoal_tac "f a >= f b", force, force)
   911 
   912 lemma xt8 [no_atp]: "(a::'a::order) > f b ==> (b::'b::order) > c ==>
   913     (!!x y. x > y ==> f x > f y) ==> a > f c"
   914 by (subgoal_tac "f b > f c", force, force)
   915 
   916 lemma xt9 [no_atp]: "(a::'a::order) > b ==> (f b::'b::order) > c ==>
   917     (!!x y. x > y ==> f x > f y) ==> f a > c"
   918 by (subgoal_tac "f a > f b", force, force)
   919 
   920 lemmas xtrans = xt1 xt2 xt3 xt4 xt5 xt6 xt7 xt8 xt9 [no_atp]
   921 
   922 (* 
   923   Since "a >= b" abbreviates "b <= a", the abbreviation "..." stands
   924   for the wrong thing in an Isar proof.
   925 
   926   The extra transitivity rules can be used as follows: 
   927 
   928 lemma "(a::'a::order) > z"
   929 proof -
   930   have "a >= b" (is "_ >= ?rhs")
   931     sorry
   932   also have "?rhs >= c" (is "_ >= ?rhs")
   933     sorry
   934   also (xtrans) have "?rhs = d" (is "_ = ?rhs")
   935     sorry
   936   also (xtrans) have "?rhs >= e" (is "_ >= ?rhs")
   937     sorry
   938   also (xtrans) have "?rhs > f" (is "_ > ?rhs")
   939     sorry
   940   also (xtrans) have "?rhs > z"
   941     sorry
   942   finally (xtrans) show ?thesis .
   943 qed
   944 
   945   Alternatively, one can use "declare xtrans [trans]" and then
   946   leave out the "(xtrans)" above.
   947 *)
   948 
   949 
   950 subsection {* Monotonicity, least value operator and min/max *}
   951 
   952 context order
   953 begin
   954 
   955 definition mono :: "('a \<Rightarrow> 'b\<Colon>order) \<Rightarrow> bool" where
   956   "mono f \<longleftrightarrow> (\<forall>x y. x \<le> y \<longrightarrow> f x \<le> f y)"
   957 
   958 lemma monoI [intro?]:
   959   fixes f :: "'a \<Rightarrow> 'b\<Colon>order"
   960   shows "(\<And>x y. x \<le> y \<Longrightarrow> f x \<le> f y) \<Longrightarrow> mono f"
   961   unfolding mono_def by iprover
   962 
   963 lemma monoD [dest?]:
   964   fixes f :: "'a \<Rightarrow> 'b\<Colon>order"
   965   shows "mono f \<Longrightarrow> x \<le> y \<Longrightarrow> f x \<le> f y"
   966   unfolding mono_def by iprover
   967 
   968 lemma monoE:
   969   fixes f :: "'a \<Rightarrow> 'b\<Colon>order"
   970   assumes "mono f"
   971   assumes "x \<le> y"
   972   obtains "f x \<le> f y"
   973 proof
   974   from assms show "f x \<le> f y" by (simp add: mono_def)
   975 qed
   976 
   977 definition strict_mono :: "('a \<Rightarrow> 'b\<Colon>order) \<Rightarrow> bool" where
   978   "strict_mono f \<longleftrightarrow> (\<forall>x y. x < y \<longrightarrow> f x < f y)"
   979 
   980 lemma strict_monoI [intro?]:
   981   assumes "\<And>x y. x < y \<Longrightarrow> f x < f y"
   982   shows "strict_mono f"
   983   using assms unfolding strict_mono_def by auto
   984 
   985 lemma strict_monoD [dest?]:
   986   "strict_mono f \<Longrightarrow> x < y \<Longrightarrow> f x < f y"
   987   unfolding strict_mono_def by auto
   988 
   989 lemma strict_mono_mono [dest?]:
   990   assumes "strict_mono f"
   991   shows "mono f"
   992 proof (rule monoI)
   993   fix x y
   994   assume "x \<le> y"
   995   show "f x \<le> f y"
   996   proof (cases "x = y")
   997     case True then show ?thesis by simp
   998   next
   999     case False with `x \<le> y` have "x < y" by simp
  1000     with assms strict_monoD have "f x < f y" by auto
  1001     then show ?thesis by simp
  1002   qed
  1003 qed
  1004 
  1005 end
  1006 
  1007 context linorder
  1008 begin
  1009 
  1010 lemma mono_invE:
  1011   fixes f :: "'a \<Rightarrow> 'b\<Colon>order"
  1012   assumes "mono f"
  1013   assumes "f x < f y"
  1014   obtains "x \<le> y"
  1015 proof
  1016   show "x \<le> y"
  1017   proof (rule ccontr)
  1018     assume "\<not> x \<le> y"
  1019     then have "y \<le> x" by simp
  1020     with `mono f` obtain "f y \<le> f x" by (rule monoE)
  1021     with `f x < f y` show False by simp
  1022   qed
  1023 qed
  1024 
  1025 lemma strict_mono_eq:
  1026   assumes "strict_mono f"
  1027   shows "f x = f y \<longleftrightarrow> x = y"
  1028 proof
  1029   assume "f x = f y"
  1030   show "x = y" proof (cases x y rule: linorder_cases)
  1031     case less with assms strict_monoD have "f x < f y" by auto
  1032     with `f x = f y` show ?thesis by simp
  1033   next
  1034     case equal then show ?thesis .
  1035   next
  1036     case greater with assms strict_monoD have "f y < f x" by auto
  1037     with `f x = f y` show ?thesis by simp
  1038   qed
  1039 qed simp
  1040 
  1041 lemma strict_mono_less_eq:
  1042   assumes "strict_mono f"
  1043   shows "f x \<le> f y \<longleftrightarrow> x \<le> y"
  1044 proof
  1045   assume "x \<le> y"
  1046   with assms strict_mono_mono monoD show "f x \<le> f y" by auto
  1047 next
  1048   assume "f x \<le> f y"
  1049   show "x \<le> y" proof (rule ccontr)
  1050     assume "\<not> x \<le> y" then have "y < x" by simp
  1051     with assms strict_monoD have "f y < f x" by auto
  1052     with `f x \<le> f y` show False by simp
  1053   qed
  1054 qed
  1055   
  1056 lemma strict_mono_less:
  1057   assumes "strict_mono f"
  1058   shows "f x < f y \<longleftrightarrow> x < y"
  1059   using assms
  1060     by (auto simp add: less_le Orderings.less_le strict_mono_eq strict_mono_less_eq)
  1061 
  1062 lemma min_of_mono:
  1063   fixes f :: "'a \<Rightarrow> 'b\<Colon>linorder"
  1064   shows "mono f \<Longrightarrow> min (f m) (f n) = f (min m n)"
  1065   by (auto simp: mono_def Orderings.min_def min_def intro: Orderings.antisym)
  1066 
  1067 lemma max_of_mono:
  1068   fixes f :: "'a \<Rightarrow> 'b\<Colon>linorder"
  1069   shows "mono f \<Longrightarrow> max (f m) (f n) = f (max m n)"
  1070   by (auto simp: mono_def Orderings.max_def max_def intro: Orderings.antisym)
  1071 
  1072 end
  1073 
  1074 lemma min_absorb1: "x \<le> y \<Longrightarrow> min x y = x"
  1075 by (simp add: min_def)
  1076 
  1077 lemma max_absorb2: "x \<le> y ==> max x y = y"
  1078 by (simp add: max_def)
  1079 
  1080 lemma min_absorb2: "(y\<Colon>'a\<Colon>order) \<le> x \<Longrightarrow> min x y = y"
  1081 by (simp add:min_def)
  1082 
  1083 lemma max_absorb1: "(y\<Colon>'a\<Colon>order) \<le> x \<Longrightarrow> max x y = x"
  1084 by (simp add: max_def)
  1085 
  1086 
  1087 
  1088 subsection {* (Unique) top and bottom elements *}
  1089 
  1090 class bot = order +
  1091   fixes bot :: 'a ("\<bottom>")
  1092   assumes bot_least [simp]: "\<bottom> \<le> a"
  1093 begin
  1094 
  1095 lemma le_bot:
  1096   "a \<le> \<bottom> \<Longrightarrow> a = \<bottom>"
  1097   by (auto intro: antisym)
  1098 
  1099 lemma bot_unique:
  1100   "a \<le> \<bottom> \<longleftrightarrow> a = \<bottom>"
  1101   by (auto intro: antisym)
  1102 
  1103 lemma not_less_bot [simp]:
  1104   "\<not> (a < \<bottom>)"
  1105   using bot_least [of a] by (auto simp: le_less)
  1106 
  1107 lemma bot_less:
  1108   "a \<noteq> \<bottom> \<longleftrightarrow> \<bottom> < a"
  1109   by (auto simp add: less_le_not_le intro!: antisym)
  1110 
  1111 end
  1112 
  1113 class top = order +
  1114   fixes top :: 'a ("\<top>")
  1115   assumes top_greatest [simp]: "a \<le> \<top>"
  1116 begin
  1117 
  1118 lemma top_le:
  1119   "\<top> \<le> a \<Longrightarrow> a = \<top>"
  1120   by (rule antisym) auto
  1121 
  1122 lemma top_unique:
  1123   "\<top> \<le> a \<longleftrightarrow> a = \<top>"
  1124   by (auto intro: antisym)
  1125 
  1126 lemma not_top_less [simp]: "\<not> (\<top> < a)"
  1127   using top_greatest [of a] by (auto simp: le_less)
  1128 
  1129 lemma less_top:
  1130   "a \<noteq> \<top> \<longleftrightarrow> a < \<top>"
  1131   by (auto simp add: less_le_not_le intro!: antisym)
  1132 
  1133 end
  1134 
  1135 
  1136 subsection {* Dense orders *}
  1137 
  1138 class inner_dense_order = order +
  1139   assumes dense: "x < y \<Longrightarrow> (\<exists>z. x < z \<and> z < y)"
  1140 
  1141 class inner_dense_linorder = linorder + inner_dense_order
  1142 begin
  1143 
  1144 lemma dense_le:
  1145   fixes y z :: 'a
  1146   assumes "\<And>x. x < y \<Longrightarrow> x \<le> z"
  1147   shows "y \<le> z"
  1148 proof (rule ccontr)
  1149   assume "\<not> ?thesis"
  1150   hence "z < y" by simp
  1151   from dense[OF this]
  1152   obtain x where "x < y" and "z < x" by safe
  1153   moreover have "x \<le> z" using assms[OF `x < y`] .
  1154   ultimately show False by auto
  1155 qed
  1156 
  1157 lemma dense_le_bounded:
  1158   fixes x y z :: 'a
  1159   assumes "x < y"
  1160   assumes *: "\<And>w. \<lbrakk> x < w ; w < y \<rbrakk> \<Longrightarrow> w \<le> z"
  1161   shows "y \<le> z"
  1162 proof (rule dense_le)
  1163   fix w assume "w < y"
  1164   from dense[OF `x < y`] obtain u where "x < u" "u < y" by safe
  1165   from linear[of u w]
  1166   show "w \<le> z"
  1167   proof (rule disjE)
  1168     assume "u \<le> w"
  1169     from less_le_trans[OF `x < u` `u \<le> w`] `w < y`
  1170     show "w \<le> z" by (rule *)
  1171   next
  1172     assume "w \<le> u"
  1173     from `w \<le> u` *[OF `x < u` `u < y`]
  1174     show "w \<le> z" by (rule order_trans)
  1175   qed
  1176 qed
  1177 
  1178 lemma dense_ge:
  1179   fixes y z :: 'a
  1180   assumes "\<And>x. z < x \<Longrightarrow> y \<le> x"
  1181   shows "y \<le> z"
  1182 proof (rule ccontr)
  1183   assume "\<not> ?thesis"
  1184   hence "z < y" by simp
  1185   from dense[OF this]
  1186   obtain x where "x < y" and "z < x" by safe
  1187   moreover have "y \<le> x" using assms[OF `z < x`] .
  1188   ultimately show False by auto
  1189 qed
  1190 
  1191 lemma dense_ge_bounded:
  1192   fixes x y z :: 'a
  1193   assumes "z < x"
  1194   assumes *: "\<And>w. \<lbrakk> z < w ; w < x \<rbrakk> \<Longrightarrow> y \<le> w"
  1195   shows "y \<le> z"
  1196 proof (rule dense_ge)
  1197   fix w assume "z < w"
  1198   from dense[OF `z < x`] obtain u where "z < u" "u < x" by safe
  1199   from linear[of u w]
  1200   show "y \<le> w"
  1201   proof (rule disjE)
  1202     assume "w \<le> u"
  1203     from `z < w` le_less_trans[OF `w \<le> u` `u < x`]
  1204     show "y \<le> w" by (rule *)
  1205   next
  1206     assume "u \<le> w"
  1207     from *[OF `z < u` `u < x`] `u \<le> w`
  1208     show "y \<le> w" by (rule order_trans)
  1209   qed
  1210 qed
  1211 
  1212 end
  1213 
  1214 class no_top = order + 
  1215   assumes gt_ex: "\<exists>y. x < y"
  1216 
  1217 class no_bot = order + 
  1218   assumes lt_ex: "\<exists>y. y < x"
  1219 
  1220 class dense_linorder = inner_dense_linorder + no_top + no_bot
  1221 
  1222 subsection {* Wellorders *}
  1223 
  1224 class wellorder = linorder +
  1225   assumes less_induct [case_names less]: "(\<And>x. (\<And>y. y < x \<Longrightarrow> P y) \<Longrightarrow> P x) \<Longrightarrow> P a"
  1226 begin
  1227 
  1228 lemma wellorder_Least_lemma:
  1229   fixes k :: 'a
  1230   assumes "P k"
  1231   shows LeastI: "P (LEAST x. P x)" and Least_le: "(LEAST x. P x) \<le> k"
  1232 proof -
  1233   have "P (LEAST x. P x) \<and> (LEAST x. P x) \<le> k"
  1234   using assms proof (induct k rule: less_induct)
  1235     case (less x) then have "P x" by simp
  1236     show ?case proof (rule classical)
  1237       assume assm: "\<not> (P (LEAST a. P a) \<and> (LEAST a. P a) \<le> x)"
  1238       have "\<And>y. P y \<Longrightarrow> x \<le> y"
  1239       proof (rule classical)
  1240         fix y
  1241         assume "P y" and "\<not> x \<le> y"
  1242         with less have "P (LEAST a. P a)" and "(LEAST a. P a) \<le> y"
  1243           by (auto simp add: not_le)
  1244         with assm have "x < (LEAST a. P a)" and "(LEAST a. P a) \<le> y"
  1245           by auto
  1246         then show "x \<le> y" by auto
  1247       qed
  1248       with `P x` have Least: "(LEAST a. P a) = x"
  1249         by (rule Least_equality)
  1250       with `P x` show ?thesis by simp
  1251     qed
  1252   qed
  1253   then show "P (LEAST x. P x)" and "(LEAST x. P x) \<le> k" by auto
  1254 qed
  1255 
  1256 -- "The following 3 lemmas are due to Brian Huffman"
  1257 lemma LeastI_ex: "\<exists>x. P x \<Longrightarrow> P (Least P)"
  1258   by (erule exE) (erule LeastI)
  1259 
  1260 lemma LeastI2:
  1261   "P a \<Longrightarrow> (\<And>x. P x \<Longrightarrow> Q x) \<Longrightarrow> Q (Least P)"
  1262   by (blast intro: LeastI)
  1263 
  1264 lemma LeastI2_ex:
  1265   "\<exists>a. P a \<Longrightarrow> (\<And>x. P x \<Longrightarrow> Q x) \<Longrightarrow> Q (Least P)"
  1266   by (blast intro: LeastI_ex)
  1267 
  1268 lemma LeastI2_wellorder:
  1269   assumes "P a"
  1270   and "\<And>a. \<lbrakk> P a; \<forall>b. P b \<longrightarrow> a \<le> b \<rbrakk> \<Longrightarrow> Q a"
  1271   shows "Q (Least P)"
  1272 proof (rule LeastI2_order)
  1273   show "P (Least P)" using `P a` by (rule LeastI)
  1274 next
  1275   fix y assume "P y" thus "Least P \<le> y" by (rule Least_le)
  1276 next
  1277   fix x assume "P x" "\<forall>y. P y \<longrightarrow> x \<le> y" thus "Q x" by (rule assms(2))
  1278 qed
  1279 
  1280 lemma not_less_Least: "k < (LEAST x. P x) \<Longrightarrow> \<not> P k"
  1281 apply (simp (no_asm_use) add: not_le [symmetric])
  1282 apply (erule contrapos_nn)
  1283 apply (erule Least_le)
  1284 done
  1285 
  1286 end
  1287 
  1288 
  1289 subsection {* Order on @{typ bool} *}
  1290 
  1291 instantiation bool :: "{bot, top, linorder}"
  1292 begin
  1293 
  1294 definition
  1295   le_bool_def [simp]: "P \<le> Q \<longleftrightarrow> P \<longrightarrow> Q"
  1296 
  1297 definition
  1298   [simp]: "(P\<Colon>bool) < Q \<longleftrightarrow> \<not> P \<and> Q"
  1299 
  1300 definition
  1301   [simp]: "\<bottom> \<longleftrightarrow> False"
  1302 
  1303 definition
  1304   [simp]: "\<top> \<longleftrightarrow> True"
  1305 
  1306 instance proof
  1307 qed auto
  1308 
  1309 end
  1310 
  1311 lemma le_boolI: "(P \<Longrightarrow> Q) \<Longrightarrow> P \<le> Q"
  1312   by simp
  1313 
  1314 lemma le_boolI': "P \<longrightarrow> Q \<Longrightarrow> P \<le> Q"
  1315   by simp
  1316 
  1317 lemma le_boolE: "P \<le> Q \<Longrightarrow> P \<Longrightarrow> (Q \<Longrightarrow> R) \<Longrightarrow> R"
  1318   by simp
  1319 
  1320 lemma le_boolD: "P \<le> Q \<Longrightarrow> P \<longrightarrow> Q"
  1321   by simp
  1322 
  1323 lemma bot_boolE: "\<bottom> \<Longrightarrow> P"
  1324   by simp
  1325 
  1326 lemma top_boolI: \<top>
  1327   by simp
  1328 
  1329 lemma [code]:
  1330   "False \<le> b \<longleftrightarrow> True"
  1331   "True \<le> b \<longleftrightarrow> b"
  1332   "False < b \<longleftrightarrow> b"
  1333   "True < b \<longleftrightarrow> False"
  1334   by simp_all
  1335 
  1336 
  1337 subsection {* Order on @{typ "_ \<Rightarrow> _"} *}
  1338 
  1339 instantiation "fun" :: (type, ord) ord
  1340 begin
  1341 
  1342 definition
  1343   le_fun_def: "f \<le> g \<longleftrightarrow> (\<forall>x. f x \<le> g x)"
  1344 
  1345 definition
  1346   "(f\<Colon>'a \<Rightarrow> 'b) < g \<longleftrightarrow> f \<le> g \<and> \<not> (g \<le> f)"
  1347 
  1348 instance ..
  1349 
  1350 end
  1351 
  1352 instance "fun" :: (type, preorder) preorder proof
  1353 qed (auto simp add: le_fun_def less_fun_def
  1354   intro: order_trans antisym)
  1355 
  1356 instance "fun" :: (type, order) order proof
  1357 qed (auto simp add: le_fun_def intro: antisym)
  1358 
  1359 instantiation "fun" :: (type, bot) bot
  1360 begin
  1361 
  1362 definition
  1363   "\<bottom> = (\<lambda>x. \<bottom>)"
  1364 
  1365 lemma bot_apply [simp, code]:
  1366   "\<bottom> x = \<bottom>"
  1367   by (simp add: bot_fun_def)
  1368 
  1369 instance proof
  1370 qed (simp add: le_fun_def)
  1371 
  1372 end
  1373 
  1374 instantiation "fun" :: (type, top) top
  1375 begin
  1376 
  1377 definition
  1378   [no_atp]: "\<top> = (\<lambda>x. \<top>)"
  1379 
  1380 lemma top_apply [simp, code]:
  1381   "\<top> x = \<top>"
  1382   by (simp add: top_fun_def)
  1383 
  1384 instance proof
  1385 qed (simp add: le_fun_def)
  1386 
  1387 end
  1388 
  1389 lemma le_funI: "(\<And>x. f x \<le> g x) \<Longrightarrow> f \<le> g"
  1390   unfolding le_fun_def by simp
  1391 
  1392 lemma le_funE: "f \<le> g \<Longrightarrow> (f x \<le> g x \<Longrightarrow> P) \<Longrightarrow> P"
  1393   unfolding le_fun_def by simp
  1394 
  1395 lemma le_funD: "f \<le> g \<Longrightarrow> f x \<le> g x"
  1396   unfolding le_fun_def by simp
  1397 
  1398 
  1399 subsection {* Order on unary and binary predicates *}
  1400 
  1401 lemma predicate1I:
  1402   assumes PQ: "\<And>x. P x \<Longrightarrow> Q x"
  1403   shows "P \<le> Q"
  1404   apply (rule le_funI)
  1405   apply (rule le_boolI)
  1406   apply (rule PQ)
  1407   apply assumption
  1408   done
  1409 
  1410 lemma predicate1D:
  1411   "P \<le> Q \<Longrightarrow> P x \<Longrightarrow> Q x"
  1412   apply (erule le_funE)
  1413   apply (erule le_boolE)
  1414   apply assumption+
  1415   done
  1416 
  1417 lemma rev_predicate1D:
  1418   "P x \<Longrightarrow> P \<le> Q \<Longrightarrow> Q x"
  1419   by (rule predicate1D)
  1420 
  1421 lemma predicate2I:
  1422   assumes PQ: "\<And>x y. P x y \<Longrightarrow> Q x y"
  1423   shows "P \<le> Q"
  1424   apply (rule le_funI)+
  1425   apply (rule le_boolI)
  1426   apply (rule PQ)
  1427   apply assumption
  1428   done
  1429 
  1430 lemma predicate2D:
  1431   "P \<le> Q \<Longrightarrow> P x y \<Longrightarrow> Q x y"
  1432   apply (erule le_funE)+
  1433   apply (erule le_boolE)
  1434   apply assumption+
  1435   done
  1436 
  1437 lemma rev_predicate2D:
  1438   "P x y \<Longrightarrow> P \<le> Q \<Longrightarrow> Q x y"
  1439   by (rule predicate2D)
  1440 
  1441 lemma bot1E [no_atp]: "\<bottom> x \<Longrightarrow> P"
  1442   by (simp add: bot_fun_def)
  1443 
  1444 lemma bot2E: "\<bottom> x y \<Longrightarrow> P"
  1445   by (simp add: bot_fun_def)
  1446 
  1447 lemma top1I: "\<top> x"
  1448   by (simp add: top_fun_def)
  1449 
  1450 lemma top2I: "\<top> x y"
  1451   by (simp add: top_fun_def)
  1452 
  1453 
  1454 subsection {* Name duplicates *}
  1455 
  1456 lemmas order_eq_refl = preorder_class.eq_refl
  1457 lemmas order_less_irrefl = preorder_class.less_irrefl
  1458 lemmas order_less_imp_le = preorder_class.less_imp_le
  1459 lemmas order_less_not_sym = preorder_class.less_not_sym
  1460 lemmas order_less_asym = preorder_class.less_asym
  1461 lemmas order_less_trans = preorder_class.less_trans
  1462 lemmas order_le_less_trans = preorder_class.le_less_trans
  1463 lemmas order_less_le_trans = preorder_class.less_le_trans
  1464 lemmas order_less_imp_not_less = preorder_class.less_imp_not_less
  1465 lemmas order_less_imp_triv = preorder_class.less_imp_triv
  1466 lemmas order_less_asym' = preorder_class.less_asym'
  1467 
  1468 lemmas order_less_le = order_class.less_le
  1469 lemmas order_le_less = order_class.le_less
  1470 lemmas order_le_imp_less_or_eq = order_class.le_imp_less_or_eq
  1471 lemmas order_less_imp_not_eq = order_class.less_imp_not_eq
  1472 lemmas order_less_imp_not_eq2 = order_class.less_imp_not_eq2
  1473 lemmas order_neq_le_trans = order_class.neq_le_trans
  1474 lemmas order_le_neq_trans = order_class.le_neq_trans
  1475 lemmas order_antisym = order_class.antisym
  1476 lemmas order_eq_iff = order_class.eq_iff
  1477 lemmas order_antisym_conv = order_class.antisym_conv
  1478 
  1479 lemmas linorder_linear = linorder_class.linear
  1480 lemmas linorder_less_linear = linorder_class.less_linear
  1481 lemmas linorder_le_less_linear = linorder_class.le_less_linear
  1482 lemmas linorder_le_cases = linorder_class.le_cases
  1483 lemmas linorder_not_less = linorder_class.not_less
  1484 lemmas linorder_not_le = linorder_class.not_le
  1485 lemmas linorder_neq_iff = linorder_class.neq_iff
  1486 lemmas linorder_neqE = linorder_class.neqE
  1487 lemmas linorder_antisym_conv1 = linorder_class.antisym_conv1
  1488 lemmas linorder_antisym_conv2 = linorder_class.antisym_conv2
  1489 lemmas linorder_antisym_conv3 = linorder_class.antisym_conv3
  1490 
  1491 end