src/HOL/Transcendental.thy
author hoelzl
Fri Mar 22 10:41:43 2013 +0100 (2013-03-22)
changeset 51474 1e9e68247ad1
parent 50347 77e3effa50b6
child 51477 2990382dc066
permissions -rw-r--r--
generalize Bfun and Bseq to metric spaces; Bseq is an abbreviation for Bfun
     1 (*  Title:      HOL/Transcendental.thy
     2     Author:     Jacques D. Fleuriot, University of Cambridge, University of Edinburgh
     3     Author:     Lawrence C Paulson
     4 *)
     5 
     6 header{*Power Series, Transcendental Functions etc.*}
     7 
     8 theory Transcendental
     9 imports Fact Series Deriv NthRoot
    10 begin
    11 
    12 subsection {* Properties of Power Series *}
    13 
    14 lemma lemma_realpow_diff:
    15   fixes y :: "'a::monoid_mult"
    16   shows "p \<le> n \<Longrightarrow> y ^ (Suc n - p) = (y ^ (n - p)) * y"
    17 proof -
    18   assume "p \<le> n"
    19   hence "Suc n - p = Suc (n - p)" by (rule Suc_diff_le)
    20   thus ?thesis by (simp add: power_commutes)
    21 qed
    22 
    23 lemma lemma_realpow_diff_sumr:
    24   fixes y :: "'a::{comm_semiring_0,monoid_mult}" shows
    25      "(\<Sum>p=0..<Suc n. (x ^ p) * y ^ (Suc n - p)) =
    26       y * (\<Sum>p=0..<Suc n. (x ^ p) * y ^ (n - p))"
    27 by (simp add: setsum_right_distrib lemma_realpow_diff mult_ac
    28          del: setsum_op_ivl_Suc)
    29 
    30 lemma lemma_realpow_diff_sumr2:
    31   fixes y :: "'a::{comm_ring,monoid_mult}" shows
    32      "x ^ (Suc n) - y ^ (Suc n) =
    33       (x - y) * (\<Sum>p=0..<Suc n. (x ^ p) * y ^ (n - p))"
    34 apply (induct n, simp)
    35 apply (simp del: setsum_op_ivl_Suc)
    36 apply (subst setsum_op_ivl_Suc)
    37 apply (subst lemma_realpow_diff_sumr)
    38 apply (simp add: distrib_left del: setsum_op_ivl_Suc)
    39 apply (subst mult_left_commute [of "x - y"])
    40 apply (erule subst)
    41 apply (simp add: algebra_simps)
    42 done
    43 
    44 lemma lemma_realpow_rev_sumr:
    45      "(\<Sum>p=0..<Suc n. (x ^ p) * (y ^ (n - p))) =
    46       (\<Sum>p=0..<Suc n. (x ^ (n - p)) * (y ^ p))"
    47 apply (rule setsum_reindex_cong [where f="\<lambda>i. n - i"])
    48 apply (rule inj_onI, simp)
    49 apply auto
    50 apply (rule_tac x="n - x" in image_eqI, simp, simp)
    51 done
    52 
    53 text{*Power series has a `circle` of convergence, i.e. if it sums for @{term
    54 x}, then it sums absolutely for @{term z} with @{term "\<bar>z\<bar> < \<bar>x\<bar>"}.*}
    55 
    56 lemma powser_insidea:
    57   fixes x z :: "'a::real_normed_field"
    58   assumes 1: "summable (\<lambda>n. f n * x ^ n)"
    59   assumes 2: "norm z < norm x"
    60   shows "summable (\<lambda>n. norm (f n * z ^ n))"
    61 proof -
    62   from 2 have x_neq_0: "x \<noteq> 0" by clarsimp
    63   from 1 have "(\<lambda>n. f n * x ^ n) ----> 0"
    64     by (rule summable_LIMSEQ_zero)
    65   hence "convergent (\<lambda>n. f n * x ^ n)"
    66     by (rule convergentI)
    67   hence "Cauchy (\<lambda>n. f n * x ^ n)"
    68     by (rule convergent_Cauchy)
    69   hence "Bseq (\<lambda>n. f n * x ^ n)"
    70     by (rule Cauchy_Bseq)
    71   then obtain K where 3: "0 < K" and 4: "\<forall>n. norm (f n * x ^ n) \<le> K"
    72     by (simp add: Bseq_def, safe)
    73   have "\<exists>N. \<forall>n\<ge>N. norm (norm (f n * z ^ n)) \<le>
    74                    K * norm (z ^ n) * inverse (norm (x ^ n))"
    75   proof (intro exI allI impI)
    76     fix n::nat assume "0 \<le> n"
    77     have "norm (norm (f n * z ^ n)) * norm (x ^ n) =
    78           norm (f n * x ^ n) * norm (z ^ n)"
    79       by (simp add: norm_mult abs_mult)
    80     also have "\<dots> \<le> K * norm (z ^ n)"
    81       by (simp only: mult_right_mono 4 norm_ge_zero)
    82     also have "\<dots> = K * norm (z ^ n) * (inverse (norm (x ^ n)) * norm (x ^ n))"
    83       by (simp add: x_neq_0)
    84     also have "\<dots> = K * norm (z ^ n) * inverse (norm (x ^ n)) * norm (x ^ n)"
    85       by (simp only: mult_assoc)
    86     finally show "norm (norm (f n * z ^ n)) \<le>
    87                   K * norm (z ^ n) * inverse (norm (x ^ n))"
    88       by (simp add: mult_le_cancel_right x_neq_0)
    89   qed
    90   moreover have "summable (\<lambda>n. K * norm (z ^ n) * inverse (norm (x ^ n)))"
    91   proof -
    92     from 2 have "norm (norm (z * inverse x)) < 1"
    93       using x_neq_0
    94       by (simp add: nonzero_norm_divide divide_inverse [symmetric])
    95     hence "summable (\<lambda>n. norm (z * inverse x) ^ n)"
    96       by (rule summable_geometric)
    97     hence "summable (\<lambda>n. K * norm (z * inverse x) ^ n)"
    98       by (rule summable_mult)
    99     thus "summable (\<lambda>n. K * norm (z ^ n) * inverse (norm (x ^ n)))"
   100       using x_neq_0
   101       by (simp add: norm_mult nonzero_norm_inverse power_mult_distrib
   102                     power_inverse norm_power mult_assoc)
   103   qed
   104   ultimately show "summable (\<lambda>n. norm (f n * z ^ n))"
   105     by (rule summable_comparison_test)
   106 qed
   107 
   108 lemma powser_inside:
   109   fixes f :: "nat \<Rightarrow> 'a::{real_normed_field,banach}" shows
   110      "[| summable (%n. f(n) * (x ^ n)); norm z < norm x |]
   111       ==> summable (%n. f(n) * (z ^ n))"
   112 by (rule powser_insidea [THEN summable_norm_cancel])
   113 
   114 lemma sum_split_even_odd: fixes f :: "nat \<Rightarrow> real" shows
   115   "(\<Sum> i = 0 ..< 2 * n. if even i then f i else g i) =
   116    (\<Sum> i = 0 ..< n. f (2 * i)) + (\<Sum> i = 0 ..< n. g (2 * i + 1))"
   117 proof (induct n)
   118   case (Suc n)
   119   have "(\<Sum> i = 0 ..< 2 * Suc n. if even i then f i else g i) =
   120         (\<Sum> i = 0 ..< n. f (2 * i)) + (\<Sum> i = 0 ..< n. g (2 * i + 1)) + (f (2 * n) + g (2 * n + 1))"
   121     using Suc.hyps unfolding One_nat_def by auto
   122   also have "\<dots> = (\<Sum> i = 0 ..< Suc n. f (2 * i)) + (\<Sum> i = 0 ..< Suc n. g (2 * i + 1))" by auto
   123   finally show ?case .
   124 qed auto
   125 
   126 lemma sums_if': fixes g :: "nat \<Rightarrow> real" assumes "g sums x"
   127   shows "(\<lambda> n. if even n then 0 else g ((n - 1) div 2)) sums x"
   128   unfolding sums_def
   129 proof (rule LIMSEQ_I)
   130   fix r :: real assume "0 < r"
   131   from `g sums x`[unfolded sums_def, THEN LIMSEQ_D, OF this]
   132   obtain no where no_eq: "\<And> n. n \<ge> no \<Longrightarrow> (norm (setsum g { 0..<n } - x) < r)" by blast
   133 
   134   let ?SUM = "\<lambda> m. \<Sum> i = 0 ..< m. if even i then 0 else g ((i - 1) div 2)"
   135   { fix m assume "m \<ge> 2 * no" hence "m div 2 \<ge> no" by auto
   136     have sum_eq: "?SUM (2 * (m div 2)) = setsum g { 0 ..< m div 2 }"
   137       using sum_split_even_odd by auto
   138     hence "(norm (?SUM (2 * (m div 2)) - x) < r)" using no_eq unfolding sum_eq using `m div 2 \<ge> no` by auto
   139     moreover
   140     have "?SUM (2 * (m div 2)) = ?SUM m"
   141     proof (cases "even m")
   142       case True show ?thesis unfolding even_nat_div_two_times_two[OF True, unfolded numeral_2_eq_2[symmetric]] ..
   143     next
   144       case False hence "even (Suc m)" by auto
   145       from even_nat_div_two_times_two[OF this, unfolded numeral_2_eq_2[symmetric]] odd_nat_plus_one_div_two[OF False, unfolded numeral_2_eq_2[symmetric]]
   146       have eq: "Suc (2 * (m div 2)) = m" by auto
   147       hence "even (2 * (m div 2))" using `odd m` by auto
   148       have "?SUM m = ?SUM (Suc (2 * (m div 2)))" unfolding eq ..
   149       also have "\<dots> = ?SUM (2 * (m div 2))" using `even (2 * (m div 2))` by auto
   150       finally show ?thesis by auto
   151     qed
   152     ultimately have "(norm (?SUM m - x) < r)" by auto
   153   }
   154   thus "\<exists> no. \<forall> m \<ge> no. norm (?SUM m - x) < r" by blast
   155 qed
   156 
   157 lemma sums_if: fixes g :: "nat \<Rightarrow> real" assumes "g sums x" and "f sums y"
   158   shows "(\<lambda> n. if even n then f (n div 2) else g ((n - 1) div 2)) sums (x + y)"
   159 proof -
   160   let ?s = "\<lambda> n. if even n then 0 else f ((n - 1) div 2)"
   161   { fix B T E have "(if B then (0 :: real) else E) + (if B then T else 0) = (if B then T else E)"
   162       by (cases B) auto } note if_sum = this
   163   have g_sums: "(\<lambda> n. if even n then 0 else g ((n - 1) div 2)) sums x" using sums_if'[OF `g sums x`] .
   164   {
   165     have "?s 0 = 0" by auto
   166     have Suc_m1: "\<And> n. Suc n - 1 = n" by auto
   167     have if_eq: "\<And>B T E. (if \<not> B then T else E) = (if B then E else T)" by auto
   168 
   169     have "?s sums y" using sums_if'[OF `f sums y`] .
   170     from this[unfolded sums_def, THEN LIMSEQ_Suc]
   171     have "(\<lambda> n. if even n then f (n div 2) else 0) sums y"
   172       unfolding sums_def setsum_shift_lb_Suc0_0_upt[where f="?s", OF `?s 0 = 0`, symmetric]
   173                 image_Suc_atLeastLessThan[symmetric] setsum_reindex[OF inj_Suc, unfolded comp_def]
   174                 even_Suc Suc_m1 if_eq .
   175   } from sums_add[OF g_sums this]
   176   show ?thesis unfolding if_sum .
   177 qed
   178 
   179 subsection {* Alternating series test / Leibniz formula *}
   180 
   181 lemma sums_alternating_upper_lower:
   182   fixes a :: "nat \<Rightarrow> real"
   183   assumes mono: "\<And>n. a (Suc n) \<le> a n" and a_pos: "\<And>n. 0 \<le> a n" and "a ----> 0"
   184   shows "\<exists>l. ((\<forall>n. (\<Sum>i=0..<2*n. -1^i*a i) \<le> l) \<and> (\<lambda> n. \<Sum>i=0..<2*n. -1^i*a i) ----> l) \<and>
   185              ((\<forall>n. l \<le> (\<Sum>i=0..<2*n + 1. -1^i*a i)) \<and> (\<lambda> n. \<Sum>i=0..<2*n + 1. -1^i*a i) ----> l)"
   186   (is "\<exists>l. ((\<forall>n. ?f n \<le> l) \<and> _) \<and> ((\<forall>n. l \<le> ?g n) \<and> _)")
   187 proof -
   188   have fg_diff: "\<And>n. ?f n - ?g n = - a (2 * n)" unfolding One_nat_def by auto
   189 
   190   have "\<forall> n. ?f n \<le> ?f (Suc n)"
   191   proof fix n show "?f n \<le> ?f (Suc n)" using mono[of "2*n"] by auto qed
   192   moreover
   193   have "\<forall> n. ?g (Suc n) \<le> ?g n"
   194   proof fix n show "?g (Suc n) \<le> ?g n" using mono[of "Suc (2*n)"]
   195     unfolding One_nat_def by auto qed
   196   moreover
   197   have "\<forall> n. ?f n \<le> ?g n"
   198   proof fix n show "?f n \<le> ?g n" using fg_diff a_pos
   199     unfolding One_nat_def by auto qed
   200   moreover
   201   have "(\<lambda> n. ?f n - ?g n) ----> 0" unfolding fg_diff
   202   proof (rule LIMSEQ_I)
   203     fix r :: real assume "0 < r"
   204     with `a ----> 0`[THEN LIMSEQ_D]
   205     obtain N where "\<And> n. n \<ge> N \<Longrightarrow> norm (a n - 0) < r" by auto
   206     hence "\<forall> n \<ge> N. norm (- a (2 * n) - 0) < r" by auto
   207     thus "\<exists> N. \<forall> n \<ge> N. norm (- a (2 * n) - 0) < r" by auto
   208   qed
   209   ultimately
   210   show ?thesis by (rule lemma_nest_unique)
   211 qed
   212 
   213 lemma summable_Leibniz': fixes a :: "nat \<Rightarrow> real"
   214   assumes a_zero: "a ----> 0" and a_pos: "\<And> n. 0 \<le> a n"
   215   and a_monotone: "\<And> n. a (Suc n) \<le> a n"
   216   shows summable: "summable (\<lambda> n. (-1)^n * a n)"
   217   and "\<And>n. (\<Sum>i=0..<2*n. (-1)^i*a i) \<le> (\<Sum>i. (-1)^i*a i)"
   218   and "(\<lambda>n. \<Sum>i=0..<2*n. (-1)^i*a i) ----> (\<Sum>i. (-1)^i*a i)"
   219   and "\<And>n. (\<Sum>i. (-1)^i*a i) \<le> (\<Sum>i=0..<2*n+1. (-1)^i*a i)"
   220   and "(\<lambda>n. \<Sum>i=0..<2*n+1. (-1)^i*a i) ----> (\<Sum>i. (-1)^i*a i)"
   221 proof -
   222   let "?S n" = "(-1)^n * a n"
   223   let "?P n" = "\<Sum>i=0..<n. ?S i"
   224   let "?f n" = "?P (2 * n)"
   225   let "?g n" = "?P (2 * n + 1)"
   226   obtain l :: real where below_l: "\<forall> n. ?f n \<le> l" and "?f ----> l" and above_l: "\<forall> n. l \<le> ?g n" and "?g ----> l"
   227     using sums_alternating_upper_lower[OF a_monotone a_pos a_zero] by blast
   228 
   229   let ?Sa = "\<lambda> m. \<Sum> n = 0..<m. ?S n"
   230   have "?Sa ----> l"
   231   proof (rule LIMSEQ_I)
   232     fix r :: real assume "0 < r"
   233 
   234     with `?f ----> l`[THEN LIMSEQ_D]
   235     obtain f_no where f: "\<And> n. n \<ge> f_no \<Longrightarrow> norm (?f n - l) < r" by auto
   236 
   237     from `0 < r` `?g ----> l`[THEN LIMSEQ_D]
   238     obtain g_no where g: "\<And> n. n \<ge> g_no \<Longrightarrow> norm (?g n - l) < r" by auto
   239 
   240     { fix n :: nat
   241       assume "n \<ge> (max (2 * f_no) (2 * g_no))" hence "n \<ge> 2 * f_no" and "n \<ge> 2 * g_no" by auto
   242       have "norm (?Sa n - l) < r"
   243       proof (cases "even n")
   244         case True from even_nat_div_two_times_two[OF this]
   245         have n_eq: "2 * (n div 2) = n" unfolding numeral_2_eq_2[symmetric] by auto
   246         with `n \<ge> 2 * f_no` have "n div 2 \<ge> f_no" by auto
   247         from f[OF this]
   248         show ?thesis unfolding n_eq atLeastLessThanSuc_atLeastAtMost .
   249       next
   250         case False hence "even (n - 1)" by simp
   251         from even_nat_div_two_times_two[OF this]
   252         have n_eq: "2 * ((n - 1) div 2) = n - 1" unfolding numeral_2_eq_2[symmetric] by auto
   253         hence range_eq: "n - 1 + 1 = n" using odd_pos[OF False] by auto
   254 
   255         from n_eq `n \<ge> 2 * g_no` have "(n - 1) div 2 \<ge> g_no" by auto
   256         from g[OF this]
   257         show ?thesis unfolding n_eq atLeastLessThanSuc_atLeastAtMost range_eq .
   258       qed
   259     }
   260     thus "\<exists> no. \<forall> n \<ge> no. norm (?Sa n - l) < r" by blast
   261   qed
   262   hence sums_l: "(\<lambda>i. (-1)^i * a i) sums l" unfolding sums_def atLeastLessThanSuc_atLeastAtMost[symmetric] .
   263   thus "summable ?S" using summable_def by auto
   264 
   265   have "l = suminf ?S" using sums_unique[OF sums_l] .
   266 
   267   { fix n show "suminf ?S \<le> ?g n" unfolding sums_unique[OF sums_l, symmetric] using above_l by auto }
   268   { fix n show "?f n \<le> suminf ?S" unfolding sums_unique[OF sums_l, symmetric] using below_l by auto }
   269   show "?g ----> suminf ?S" using `?g ----> l` `l = suminf ?S` by auto
   270   show "?f ----> suminf ?S" using `?f ----> l` `l = suminf ?S` by auto
   271 qed
   272 
   273 theorem summable_Leibniz: fixes a :: "nat \<Rightarrow> real"
   274   assumes a_zero: "a ----> 0" and "monoseq a"
   275   shows "summable (\<lambda> n. (-1)^n * a n)" (is "?summable")
   276   and "0 < a 0 \<longrightarrow> (\<forall>n. (\<Sum>i. -1^i*a i) \<in> { \<Sum>i=0..<2*n. -1^i * a i .. \<Sum>i=0..<2*n+1. -1^i * a i})" (is "?pos")
   277   and "a 0 < 0 \<longrightarrow> (\<forall>n. (\<Sum>i. -1^i*a i) \<in> { \<Sum>i=0..<2*n+1. -1^i * a i .. \<Sum>i=0..<2*n. -1^i * a i})" (is "?neg")
   278   and "(\<lambda>n. \<Sum>i=0..<2*n. -1^i*a i) ----> (\<Sum>i. -1^i*a i)" (is "?f")
   279   and "(\<lambda>n. \<Sum>i=0..<2*n+1. -1^i*a i) ----> (\<Sum>i. -1^i*a i)" (is "?g")
   280 proof -
   281   have "?summable \<and> ?pos \<and> ?neg \<and> ?f \<and> ?g"
   282   proof (cases "(\<forall> n. 0 \<le> a n) \<and> (\<forall>m. \<forall>n\<ge>m. a n \<le> a m)")
   283     case True
   284     hence ord: "\<And>n m. m \<le> n \<Longrightarrow> a n \<le> a m" and ge0: "\<And> n. 0 \<le> a n" by auto
   285     { fix n have "a (Suc n) \<le> a n" using ord[where n="Suc n" and m=n] by auto }
   286     note leibniz = summable_Leibniz'[OF `a ----> 0` ge0] and mono = this
   287     from leibniz[OF mono]
   288     show ?thesis using `0 \<le> a 0` by auto
   289   next
   290     let ?a = "\<lambda> n. - a n"
   291     case False
   292     with monoseq_le[OF `monoseq a` `a ----> 0`]
   293     have "(\<forall> n. a n \<le> 0) \<and> (\<forall>m. \<forall>n\<ge>m. a m \<le> a n)" by auto
   294     hence ord: "\<And>n m. m \<le> n \<Longrightarrow> ?a n \<le> ?a m" and ge0: "\<And> n. 0 \<le> ?a n" by auto
   295     { fix n have "?a (Suc n) \<le> ?a n" using ord[where n="Suc n" and m=n] by auto }
   296     note monotone = this
   297     note leibniz = summable_Leibniz'[OF _ ge0, of "\<lambda>x. x", OF tendsto_minus[OF `a ----> 0`, unfolded minus_zero] monotone]
   298     have "summable (\<lambda> n. (-1)^n * ?a n)" using leibniz(1) by auto
   299     then obtain l where "(\<lambda> n. (-1)^n * ?a n) sums l" unfolding summable_def by auto
   300     from this[THEN sums_minus]
   301     have "(\<lambda> n. (-1)^n * a n) sums -l" by auto
   302     hence ?summable unfolding summable_def by auto
   303     moreover
   304     have "\<And> a b :: real. \<bar> - a - - b \<bar> = \<bar>a - b\<bar>" unfolding minus_diff_minus by auto
   305 
   306     from suminf_minus[OF leibniz(1), unfolded mult_minus_right minus_minus]
   307     have move_minus: "(\<Sum>n. - (-1 ^ n * a n)) = - (\<Sum>n. -1 ^ n * a n)" by auto
   308 
   309     have ?pos using `0 \<le> ?a 0` by auto
   310     moreover have ?neg using leibniz(2,4) unfolding mult_minus_right setsum_negf move_minus neg_le_iff_le by auto
   311     moreover have ?f and ?g using leibniz(3,5)[unfolded mult_minus_right setsum_negf move_minus, THEN tendsto_minus_cancel] by auto
   312     ultimately show ?thesis by auto
   313   qed
   314   from this[THEN conjunct1] this[THEN conjunct2, THEN conjunct1] this[THEN conjunct2, THEN conjunct2, THEN conjunct1] this[THEN conjunct2, THEN conjunct2, THEN conjunct2, THEN conjunct1]
   315        this[THEN conjunct2, THEN conjunct2, THEN conjunct2, THEN conjunct2]
   316   show ?summable and ?pos and ?neg and ?f and ?g .
   317 qed
   318 
   319 subsection {* Term-by-Term Differentiability of Power Series *}
   320 
   321 definition
   322   diffs :: "(nat => 'a::ring_1) => nat => 'a" where
   323   "diffs c = (%n. of_nat (Suc n) * c(Suc n))"
   324 
   325 text{*Lemma about distributing negation over it*}
   326 lemma diffs_minus: "diffs (%n. - c n) = (%n. - diffs c n)"
   327 by (simp add: diffs_def)
   328 
   329 lemma sums_Suc_imp:
   330   assumes f: "f 0 = 0"
   331   shows "(\<lambda>n. f (Suc n)) sums s \<Longrightarrow> (\<lambda>n. f n) sums s"
   332 unfolding sums_def
   333 apply (rule LIMSEQ_imp_Suc)
   334 apply (subst setsum_shift_lb_Suc0_0_upt [where f=f, OF f, symmetric])
   335 apply (simp only: setsum_shift_bounds_Suc_ivl)
   336 done
   337 
   338 lemma diffs_equiv:
   339   fixes x :: "'a::{real_normed_vector, ring_1}"
   340   shows "summable (%n. (diffs c)(n) * (x ^ n)) ==>
   341       (%n. of_nat n * c(n) * (x ^ (n - Suc 0))) sums
   342          (\<Sum>n. (diffs c)(n) * (x ^ n))"
   343 unfolding diffs_def
   344 apply (drule summable_sums)
   345 apply (rule sums_Suc_imp, simp_all)
   346 done
   347 
   348 lemma lemma_termdiff1:
   349   fixes z :: "'a :: {monoid_mult,comm_ring}" shows
   350   "(\<Sum>p=0..<m. (((z + h) ^ (m - p)) * (z ^ p)) - (z ^ m)) =
   351    (\<Sum>p=0..<m. (z ^ p) * (((z + h) ^ (m - p)) - (z ^ (m - p))))"
   352 by(auto simp add: algebra_simps power_add [symmetric])
   353 
   354 lemma sumr_diff_mult_const2:
   355   "setsum f {0..<n} - of_nat n * (r::'a::ring_1) = (\<Sum>i = 0..<n. f i - r)"
   356 by (simp add: setsum_subtractf)
   357 
   358 lemma lemma_termdiff2:
   359   fixes h :: "'a :: {field}"
   360   assumes h: "h \<noteq> 0" shows
   361   "((z + h) ^ n - z ^ n) / h - of_nat n * z ^ (n - Suc 0) =
   362    h * (\<Sum>p=0..< n - Suc 0. \<Sum>q=0..< n - Suc 0 - p.
   363         (z + h) ^ q * z ^ (n - 2 - q))" (is "?lhs = ?rhs")
   364 apply (subgoal_tac "h * ?lhs = h * ?rhs", simp add: h)
   365 apply (simp add: right_diff_distrib diff_divide_distrib h)
   366 apply (simp add: mult_assoc [symmetric])
   367 apply (cases "n", simp)
   368 apply (simp add: lemma_realpow_diff_sumr2 h
   369                  right_diff_distrib [symmetric] mult_assoc
   370             del: power_Suc setsum_op_ivl_Suc of_nat_Suc)
   371 apply (subst lemma_realpow_rev_sumr)
   372 apply (subst sumr_diff_mult_const2)
   373 apply simp
   374 apply (simp only: lemma_termdiff1 setsum_right_distrib)
   375 apply (rule setsum_cong [OF refl])
   376 apply (simp add: diff_minus [symmetric] less_iff_Suc_add)
   377 apply (clarify)
   378 apply (simp add: setsum_right_distrib lemma_realpow_diff_sumr2 mult_ac
   379             del: setsum_op_ivl_Suc power_Suc)
   380 apply (subst mult_assoc [symmetric], subst power_add [symmetric])
   381 apply (simp add: mult_ac)
   382 done
   383 
   384 lemma real_setsum_nat_ivl_bounded2:
   385   fixes K :: "'a::linordered_semidom"
   386   assumes f: "\<And>p::nat. p < n \<Longrightarrow> f p \<le> K"
   387   assumes K: "0 \<le> K"
   388   shows "setsum f {0..<n-k} \<le> of_nat n * K"
   389 apply (rule order_trans [OF setsum_mono])
   390 apply (rule f, simp)
   391 apply (simp add: mult_right_mono K)
   392 done
   393 
   394 lemma lemma_termdiff3:
   395   fixes h z :: "'a::{real_normed_field}"
   396   assumes 1: "h \<noteq> 0"
   397   assumes 2: "norm z \<le> K"
   398   assumes 3: "norm (z + h) \<le> K"
   399   shows "norm (((z + h) ^ n - z ^ n) / h - of_nat n * z ^ (n - Suc 0))
   400           \<le> of_nat n * of_nat (n - Suc 0) * K ^ (n - 2) * norm h"
   401 proof -
   402   have "norm (((z + h) ^ n - z ^ n) / h - of_nat n * z ^ (n - Suc 0)) =
   403         norm (\<Sum>p = 0..<n - Suc 0. \<Sum>q = 0..<n - Suc 0 - p.
   404           (z + h) ^ q * z ^ (n - 2 - q)) * norm h"
   405     apply (subst lemma_termdiff2 [OF 1])
   406     apply (subst norm_mult)
   407     apply (rule mult_commute)
   408     done
   409   also have "\<dots> \<le> of_nat n * (of_nat (n - Suc 0) * K ^ (n - 2)) * norm h"
   410   proof (rule mult_right_mono [OF _ norm_ge_zero])
   411     from norm_ge_zero 2 have K: "0 \<le> K" by (rule order_trans)
   412     have le_Kn: "\<And>i j n. i + j = n \<Longrightarrow> norm ((z + h) ^ i * z ^ j) \<le> K ^ n"
   413       apply (erule subst)
   414       apply (simp only: norm_mult norm_power power_add)
   415       apply (intro mult_mono power_mono 2 3 norm_ge_zero zero_le_power K)
   416       done
   417     show "norm (\<Sum>p = 0..<n - Suc 0. \<Sum>q = 0..<n - Suc 0 - p.
   418               (z + h) ^ q * z ^ (n - 2 - q))
   419           \<le> of_nat n * (of_nat (n - Suc 0) * K ^ (n - 2))"
   420       apply (intro
   421          order_trans [OF norm_setsum]
   422          real_setsum_nat_ivl_bounded2
   423          mult_nonneg_nonneg
   424          of_nat_0_le_iff
   425          zero_le_power K)
   426       apply (rule le_Kn, simp)
   427       done
   428   qed
   429   also have "\<dots> = of_nat n * of_nat (n - Suc 0) * K ^ (n - 2) * norm h"
   430     by (simp only: mult_assoc)
   431   finally show ?thesis .
   432 qed
   433 
   434 lemma lemma_termdiff4:
   435   fixes f :: "'a::{real_normed_field} \<Rightarrow>
   436               'b::real_normed_vector"
   437   assumes k: "0 < (k::real)"
   438   assumes le: "\<And>h. \<lbrakk>h \<noteq> 0; norm h < k\<rbrakk> \<Longrightarrow> norm (f h) \<le> K * norm h"
   439   shows "f -- 0 --> 0"
   440 unfolding LIM_eq diff_0_right
   441 proof (safe)
   442   let ?h = "of_real (k / 2)::'a"
   443   have "?h \<noteq> 0" and "norm ?h < k" using k by simp_all
   444   hence "norm (f ?h) \<le> K * norm ?h" by (rule le)
   445   hence "0 \<le> K * norm ?h" by (rule order_trans [OF norm_ge_zero])
   446   hence zero_le_K: "0 \<le> K" using k by (simp add: zero_le_mult_iff)
   447 
   448   fix r::real assume r: "0 < r"
   449   show "\<exists>s. 0 < s \<and> (\<forall>x. x \<noteq> 0 \<and> norm x < s \<longrightarrow> norm (f x) < r)"
   450   proof (cases)
   451     assume "K = 0"
   452     with k r le have "0 < k \<and> (\<forall>x. x \<noteq> 0 \<and> norm x < k \<longrightarrow> norm (f x) < r)"
   453       by simp
   454     thus "\<exists>s. 0 < s \<and> (\<forall>x. x \<noteq> 0 \<and> norm x < s \<longrightarrow> norm (f x) < r)" ..
   455   next
   456     assume K_neq_zero: "K \<noteq> 0"
   457     with zero_le_K have K: "0 < K" by simp
   458     show "\<exists>s. 0 < s \<and> (\<forall>x. x \<noteq> 0 \<and> norm x < s \<longrightarrow> norm (f x) < r)"
   459     proof (rule exI, safe)
   460       from k r K show "0 < min k (r * inverse K / 2)"
   461         by (simp add: mult_pos_pos positive_imp_inverse_positive)
   462     next
   463       fix x::'a
   464       assume x1: "x \<noteq> 0" and x2: "norm x < min k (r * inverse K / 2)"
   465       from x2 have x3: "norm x < k" and x4: "norm x < r * inverse K / 2"
   466         by simp_all
   467       from x1 x3 le have "norm (f x) \<le> K * norm x" by simp
   468       also from x4 K have "K * norm x < K * (r * inverse K / 2)"
   469         by (rule mult_strict_left_mono)
   470       also have "\<dots> = r / 2"
   471         using K_neq_zero by simp
   472       also have "r / 2 < r"
   473         using r by simp
   474       finally show "norm (f x) < r" .
   475     qed
   476   qed
   477 qed
   478 
   479 lemma lemma_termdiff5:
   480   fixes g :: "'a::{real_normed_field} \<Rightarrow>
   481               nat \<Rightarrow> 'b::banach"
   482   assumes k: "0 < (k::real)"
   483   assumes f: "summable f"
   484   assumes le: "\<And>h n. \<lbrakk>h \<noteq> 0; norm h < k\<rbrakk> \<Longrightarrow> norm (g h n) \<le> f n * norm h"
   485   shows "(\<lambda>h. suminf (g h)) -- 0 --> 0"
   486 proof (rule lemma_termdiff4 [OF k])
   487   fix h::'a assume "h \<noteq> 0" and "norm h < k"
   488   hence A: "\<forall>n. norm (g h n) \<le> f n * norm h"
   489     by (simp add: le)
   490   hence "\<exists>N. \<forall>n\<ge>N. norm (norm (g h n)) \<le> f n * norm h"
   491     by simp
   492   moreover from f have B: "summable (\<lambda>n. f n * norm h)"
   493     by (rule summable_mult2)
   494   ultimately have C: "summable (\<lambda>n. norm (g h n))"
   495     by (rule summable_comparison_test)
   496   hence "norm (suminf (g h)) \<le> (\<Sum>n. norm (g h n))"
   497     by (rule summable_norm)
   498   also from A C B have "(\<Sum>n. norm (g h n)) \<le> (\<Sum>n. f n * norm h)"
   499     by (rule summable_le)
   500   also from f have "(\<Sum>n. f n * norm h) = suminf f * norm h"
   501     by (rule suminf_mult2 [symmetric])
   502   finally show "norm (suminf (g h)) \<le> suminf f * norm h" .
   503 qed
   504 
   505 
   506 text{* FIXME: Long proofs*}
   507 
   508 lemma termdiffs_aux:
   509   fixes x :: "'a::{real_normed_field,banach}"
   510   assumes 1: "summable (\<lambda>n. diffs (diffs c) n * K ^ n)"
   511   assumes 2: "norm x < norm K"
   512   shows "(\<lambda>h. \<Sum>n. c n * (((x + h) ^ n - x ^ n) / h
   513              - of_nat n * x ^ (n - Suc 0))) -- 0 --> 0"
   514 proof -
   515   from dense [OF 2]
   516   obtain r where r1: "norm x < r" and r2: "r < norm K" by fast
   517   from norm_ge_zero r1 have r: "0 < r"
   518     by (rule order_le_less_trans)
   519   hence r_neq_0: "r \<noteq> 0" by simp
   520   show ?thesis
   521   proof (rule lemma_termdiff5)
   522     show "0 < r - norm x" using r1 by simp
   523   next
   524     from r r2 have "norm (of_real r::'a) < norm K"
   525       by simp
   526     with 1 have "summable (\<lambda>n. norm (diffs (diffs c) n * (of_real r ^ n)))"
   527       by (rule powser_insidea)
   528     hence "summable (\<lambda>n. diffs (diffs (\<lambda>n. norm (c n))) n * r ^ n)"
   529       using r
   530       by (simp add: diffs_def norm_mult norm_power del: of_nat_Suc)
   531     hence "summable (\<lambda>n. of_nat n * diffs (\<lambda>n. norm (c n)) n * r ^ (n - Suc 0))"
   532       by (rule diffs_equiv [THEN sums_summable])
   533     also have "(\<lambda>n. of_nat n * diffs (\<lambda>n. norm (c n)) n * r ^ (n - Suc 0))
   534       = (\<lambda>n. diffs (%m. of_nat (m - Suc 0) * norm (c m) * inverse r) n * (r ^ n))"
   535       apply (rule ext)
   536       apply (simp add: diffs_def)
   537       apply (case_tac n, simp_all add: r_neq_0)
   538       done
   539     finally have "summable
   540       (\<lambda>n. of_nat n * (of_nat (n - Suc 0) * norm (c n) * inverse r) * r ^ (n - Suc 0))"
   541       by (rule diffs_equiv [THEN sums_summable])
   542     also have
   543       "(\<lambda>n. of_nat n * (of_nat (n - Suc 0) * norm (c n) * inverse r) *
   544            r ^ (n - Suc 0)) =
   545        (\<lambda>n. norm (c n) * of_nat n * of_nat (n - Suc 0) * r ^ (n - 2))"
   546       apply (rule ext)
   547       apply (case_tac "n", simp)
   548       apply (case_tac "nat", simp)
   549       apply (simp add: r_neq_0)
   550       done
   551     finally show
   552       "summable (\<lambda>n. norm (c n) * of_nat n * of_nat (n - Suc 0) * r ^ (n - 2))" .
   553   next
   554     fix h::'a and n::nat
   555     assume h: "h \<noteq> 0"
   556     assume "norm h < r - norm x"
   557     hence "norm x + norm h < r" by simp
   558     with norm_triangle_ineq have xh: "norm (x + h) < r"
   559       by (rule order_le_less_trans)
   560     show "norm (c n * (((x + h) ^ n - x ^ n) / h - of_nat n * x ^ (n - Suc 0)))
   561           \<le> norm (c n) * of_nat n * of_nat (n - Suc 0) * r ^ (n - 2) * norm h"
   562       apply (simp only: norm_mult mult_assoc)
   563       apply (rule mult_left_mono [OF _ norm_ge_zero])
   564       apply (simp (no_asm) add: mult_assoc [symmetric])
   565       apply (rule lemma_termdiff3)
   566       apply (rule h)
   567       apply (rule r1 [THEN order_less_imp_le])
   568       apply (rule xh [THEN order_less_imp_le])
   569       done
   570   qed
   571 qed
   572 
   573 lemma termdiffs:
   574   fixes K x :: "'a::{real_normed_field,banach}"
   575   assumes 1: "summable (\<lambda>n. c n * K ^ n)"
   576   assumes 2: "summable (\<lambda>n. (diffs c) n * K ^ n)"
   577   assumes 3: "summable (\<lambda>n. (diffs (diffs c)) n * K ^ n)"
   578   assumes 4: "norm x < norm K"
   579   shows "DERIV (\<lambda>x. \<Sum>n. c n * x ^ n) x :> (\<Sum>n. (diffs c) n * x ^ n)"
   580 unfolding deriv_def
   581 proof (rule LIM_zero_cancel)
   582   show "(\<lambda>h. (suminf (\<lambda>n. c n * (x + h) ^ n) - suminf (\<lambda>n. c n * x ^ n)) / h
   583             - suminf (\<lambda>n. diffs c n * x ^ n)) -- 0 --> 0"
   584   proof (rule LIM_equal2)
   585     show "0 < norm K - norm x" using 4 by (simp add: less_diff_eq)
   586   next
   587     fix h :: 'a
   588     assume "h \<noteq> 0"
   589     assume "norm (h - 0) < norm K - norm x"
   590     hence "norm x + norm h < norm K" by simp
   591     hence 5: "norm (x + h) < norm K"
   592       by (rule norm_triangle_ineq [THEN order_le_less_trans])
   593     have A: "summable (\<lambda>n. c n * x ^ n)"
   594       by (rule powser_inside [OF 1 4])
   595     have B: "summable (\<lambda>n. c n * (x + h) ^ n)"
   596       by (rule powser_inside [OF 1 5])
   597     have C: "summable (\<lambda>n. diffs c n * x ^ n)"
   598       by (rule powser_inside [OF 2 4])
   599     show "((\<Sum>n. c n * (x + h) ^ n) - (\<Sum>n. c n * x ^ n)) / h
   600              - (\<Sum>n. diffs c n * x ^ n) =
   601           (\<Sum>n. c n * (((x + h) ^ n - x ^ n) / h - of_nat n * x ^ (n - Suc 0)))"
   602       apply (subst sums_unique [OF diffs_equiv [OF C]])
   603       apply (subst suminf_diff [OF B A])
   604       apply (subst suminf_divide [symmetric])
   605       apply (rule summable_diff [OF B A])
   606       apply (subst suminf_diff)
   607       apply (rule summable_divide)
   608       apply (rule summable_diff [OF B A])
   609       apply (rule sums_summable [OF diffs_equiv [OF C]])
   610       apply (rule arg_cong [where f="suminf"], rule ext)
   611       apply (simp add: algebra_simps)
   612       done
   613   next
   614     show "(\<lambda>h. \<Sum>n. c n * (((x + h) ^ n - x ^ n) / h -
   615                of_nat n * x ^ (n - Suc 0))) -- 0 --> 0"
   616         by (rule termdiffs_aux [OF 3 4])
   617   qed
   618 qed
   619 
   620 
   621 subsection {* Derivability of power series *}
   622 
   623 lemma DERIV_series': fixes f :: "real \<Rightarrow> nat \<Rightarrow> real"
   624   assumes DERIV_f: "\<And> n. DERIV (\<lambda> x. f x n) x0 :> (f' x0 n)"
   625   and allf_summable: "\<And> x. x \<in> {a <..< b} \<Longrightarrow> summable (f x)" and x0_in_I: "x0 \<in> {a <..< b}"
   626   and "summable (f' x0)"
   627   and "summable L" and L_def: "\<And> n x y. \<lbrakk> x \<in> { a <..< b} ; y \<in> { a <..< b} \<rbrakk> \<Longrightarrow> \<bar> f x n - f y n \<bar> \<le> L n * \<bar> x - y \<bar>"
   628   shows "DERIV (\<lambda> x. suminf (f x)) x0 :> (suminf (f' x0))"
   629   unfolding deriv_def
   630 proof (rule LIM_I)
   631   fix r :: real assume "0 < r" hence "0 < r/3" by auto
   632 
   633   obtain N_L where N_L: "\<And> n. N_L \<le> n \<Longrightarrow> \<bar> \<Sum> i. L (i + n) \<bar> < r/3"
   634     using suminf_exist_split[OF `0 < r/3` `summable L`] by auto
   635 
   636   obtain N_f' where N_f': "\<And> n. N_f' \<le> n \<Longrightarrow> \<bar> \<Sum> i. f' x0 (i + n) \<bar> < r/3"
   637     using suminf_exist_split[OF `0 < r/3` `summable (f' x0)`] by auto
   638 
   639   let ?N = "Suc (max N_L N_f')"
   640   have "\<bar> \<Sum> i. f' x0 (i + ?N) \<bar> < r/3" (is "?f'_part < r/3") and
   641     L_estimate: "\<bar> \<Sum> i. L (i + ?N) \<bar> < r/3" using N_L[of "?N"] and N_f' [of "?N"] by auto
   642 
   643   let "?diff i x" = "(f (x0 + x) i - f x0 i) / x"
   644 
   645   let ?r = "r / (3 * real ?N)"
   646   have "0 < 3 * real ?N" by auto
   647   from divide_pos_pos[OF `0 < r` this]
   648   have "0 < ?r" .
   649 
   650   let "?s n" = "SOME s. 0 < s \<and> (\<forall> x. x \<noteq> 0 \<and> \<bar> x \<bar> < s \<longrightarrow> \<bar> ?diff n x - f' x0 n \<bar> < ?r)"
   651   def S' \<equiv> "Min (?s ` { 0 ..< ?N })"
   652 
   653   have "0 < S'" unfolding S'_def
   654   proof (rule iffD2[OF Min_gr_iff])
   655     show "\<forall> x \<in> (?s ` { 0 ..< ?N }). 0 < x"
   656     proof (rule ballI)
   657       fix x assume "x \<in> ?s ` {0..<?N}"
   658       then obtain n where "x = ?s n" and "n \<in> {0..<?N}" using image_iff[THEN iffD1] by blast
   659       from DERIV_D[OF DERIV_f[where n=n], THEN LIM_D, OF `0 < ?r`, unfolded real_norm_def]
   660       obtain s where s_bound: "0 < s \<and> (\<forall>x. x \<noteq> 0 \<and> \<bar>x\<bar> < s \<longrightarrow> \<bar>?diff n x - f' x0 n\<bar> < ?r)" by auto
   661       have "0 < ?s n" by (rule someI2[where a=s], auto simp add: s_bound)
   662       thus "0 < x" unfolding `x = ?s n` .
   663     qed
   664   qed auto
   665 
   666   def S \<equiv> "min (min (x0 - a) (b - x0)) S'"
   667   hence "0 < S" and S_a: "S \<le> x0 - a" and S_b: "S \<le> b - x0" and "S \<le> S'" using x0_in_I and `0 < S'`
   668     by auto
   669 
   670   { fix x assume "x \<noteq> 0" and "\<bar> x \<bar> < S"
   671     hence x_in_I: "x0 + x \<in> { a <..< b }" using S_a S_b by auto
   672 
   673     note diff_smbl = summable_diff[OF allf_summable[OF x_in_I] allf_summable[OF x0_in_I]]
   674     note div_smbl = summable_divide[OF diff_smbl]
   675     note all_smbl = summable_diff[OF div_smbl `summable (f' x0)`]
   676     note ign = summable_ignore_initial_segment[where k="?N"]
   677     note diff_shft_smbl = summable_diff[OF ign[OF allf_summable[OF x_in_I]] ign[OF allf_summable[OF x0_in_I]]]
   678     note div_shft_smbl = summable_divide[OF diff_shft_smbl]
   679     note all_shft_smbl = summable_diff[OF div_smbl ign[OF `summable (f' x0)`]]
   680 
   681     { fix n
   682       have "\<bar> ?diff (n + ?N) x \<bar> \<le> L (n + ?N) * \<bar> (x0 + x) - x0 \<bar> / \<bar> x \<bar>"
   683         using divide_right_mono[OF L_def[OF x_in_I x0_in_I] abs_ge_zero] unfolding abs_divide .
   684       hence "\<bar> ( \<bar> ?diff (n + ?N) x \<bar>) \<bar> \<le> L (n + ?N)" using `x \<noteq> 0` by auto
   685     } note L_ge = summable_le2[OF allI[OF this] ign[OF `summable L`]]
   686     from order_trans[OF summable_rabs[OF conjunct1[OF L_ge]] L_ge[THEN conjunct2]]
   687     have "\<bar> \<Sum> i. ?diff (i + ?N) x \<bar> \<le> (\<Sum> i. L (i + ?N))" .
   688     hence "\<bar> \<Sum> i. ?diff (i + ?N) x \<bar> \<le> r / 3" (is "?L_part \<le> r/3") using L_estimate by auto
   689 
   690     have "\<bar>\<Sum>n \<in> { 0 ..< ?N}. ?diff n x - f' x0 n \<bar> \<le> (\<Sum>n \<in> { 0 ..< ?N}. \<bar>?diff n x - f' x0 n \<bar>)" ..
   691     also have "\<dots> < (\<Sum>n \<in> { 0 ..< ?N}. ?r)"
   692     proof (rule setsum_strict_mono)
   693       fix n assume "n \<in> { 0 ..< ?N}"
   694       have "\<bar> x \<bar> < S" using `\<bar> x \<bar> < S` .
   695       also have "S \<le> S'" using `S \<le> S'` .
   696       also have "S' \<le> ?s n" unfolding S'_def
   697       proof (rule Min_le_iff[THEN iffD2])
   698         have "?s n \<in> (?s ` {0..<?N}) \<and> ?s n \<le> ?s n" using `n \<in> { 0 ..< ?N}` by auto
   699         thus "\<exists> a \<in> (?s ` {0..<?N}). a \<le> ?s n" by blast
   700       qed auto
   701       finally have "\<bar> x \<bar> < ?s n" .
   702 
   703       from DERIV_D[OF DERIV_f[where n=n], THEN LIM_D, OF `0 < ?r`, unfolded real_norm_def diff_0_right, unfolded some_eq_ex[symmetric], THEN conjunct2]
   704       have "\<forall>x. x \<noteq> 0 \<and> \<bar>x\<bar> < ?s n \<longrightarrow> \<bar>?diff n x - f' x0 n\<bar> < ?r" .
   705       with `x \<noteq> 0` and `\<bar>x\<bar> < ?s n`
   706       show "\<bar>?diff n x - f' x0 n\<bar> < ?r" by blast
   707     qed auto
   708     also have "\<dots> = of_nat (card {0 ..< ?N}) * ?r" by (rule setsum_constant)
   709     also have "\<dots> = real ?N * ?r" unfolding real_eq_of_nat by auto
   710     also have "\<dots> = r/3" by auto
   711     finally have "\<bar>\<Sum>n \<in> { 0 ..< ?N}. ?diff n x - f' x0 n \<bar> < r / 3" (is "?diff_part < r / 3") .
   712 
   713     from suminf_diff[OF allf_summable[OF x_in_I] allf_summable[OF x0_in_I]]
   714     have "\<bar> (suminf (f (x0 + x)) - (suminf (f x0))) / x - suminf (f' x0) \<bar> =
   715                     \<bar> \<Sum>n. ?diff n x - f' x0 n \<bar>" unfolding suminf_diff[OF div_smbl `summable (f' x0)`, symmetric] using suminf_divide[OF diff_smbl, symmetric] by auto
   716     also have "\<dots> \<le> ?diff_part + \<bar> (\<Sum>n. ?diff (n + ?N) x) - (\<Sum> n. f' x0 (n + ?N)) \<bar>" unfolding suminf_split_initial_segment[OF all_smbl, where k="?N"] unfolding suminf_diff[OF div_shft_smbl ign[OF `summable (f' x0)`]] by (rule abs_triangle_ineq)
   717     also have "\<dots> \<le> ?diff_part + ?L_part + ?f'_part" using abs_triangle_ineq4 by auto
   718     also have "\<dots> < r /3 + r/3 + r/3"
   719       using `?diff_part < r/3` `?L_part \<le> r/3` and `?f'_part < r/3`
   720       by (rule add_strict_mono [OF add_less_le_mono])
   721     finally have "\<bar> (suminf (f (x0 + x)) - (suminf (f x0))) / x - suminf (f' x0) \<bar> < r"
   722       by auto
   723   } thus "\<exists> s > 0. \<forall> x. x \<noteq> 0 \<and> norm (x - 0) < s \<longrightarrow>
   724       norm (((\<Sum>n. f (x0 + x) n) - (\<Sum>n. f x0 n)) / x - (\<Sum>n. f' x0 n)) < r" using `0 < S`
   725     unfolding real_norm_def diff_0_right by blast
   726 qed
   727 
   728 lemma DERIV_power_series': fixes f :: "nat \<Rightarrow> real"
   729   assumes converges: "\<And> x. x \<in> {-R <..< R} \<Longrightarrow> summable (\<lambda> n. f n * real (Suc n) * x^n)"
   730   and x0_in_I: "x0 \<in> {-R <..< R}" and "0 < R"
   731   shows "DERIV (\<lambda> x. (\<Sum> n. f n * x^(Suc n))) x0 :> (\<Sum> n. f n * real (Suc n) * x0^n)"
   732   (is "DERIV (\<lambda> x. (suminf (?f x))) x0 :> (suminf (?f' x0))")
   733 proof -
   734   { fix R' assume "0 < R'" and "R' < R" and "-R' < x0" and "x0 < R'"
   735     hence "x0 \<in> {-R' <..< R'}" and "R' \<in> {-R <..< R}" and "x0 \<in> {-R <..< R}" by auto
   736     have "DERIV (\<lambda> x. (suminf (?f x))) x0 :> (suminf (?f' x0))"
   737     proof (rule DERIV_series')
   738       show "summable (\<lambda> n. \<bar>f n * real (Suc n) * R'^n\<bar>)"
   739       proof -
   740         have "(R' + R) / 2 < R" and "0 < (R' + R) / 2" using `0 < R'` `0 < R` `R' < R` by auto
   741         hence in_Rball: "(R' + R) / 2 \<in> {-R <..< R}" using `R' < R` by auto
   742         have "norm R' < norm ((R' + R) / 2)" using `0 < R'` `0 < R` `R' < R` by auto
   743         from powser_insidea[OF converges[OF in_Rball] this] show ?thesis by auto
   744       qed
   745       { fix n x y assume "x \<in> {-R' <..< R'}" and "y \<in> {-R' <..< R'}"
   746         show "\<bar>?f x n - ?f y n\<bar> \<le> \<bar>f n * real (Suc n) * R'^n\<bar> * \<bar>x-y\<bar>"
   747         proof -
   748           have "\<bar>f n * x ^ (Suc n) - f n * y ^ (Suc n)\<bar> = (\<bar>f n\<bar> * \<bar>x-y\<bar>) * \<bar>\<Sum>p = 0..<Suc n. x ^ p * y ^ (n - p)\<bar>"
   749             unfolding right_diff_distrib[symmetric] lemma_realpow_diff_sumr2 abs_mult by auto
   750           also have "\<dots> \<le> (\<bar>f n\<bar> * \<bar>x-y\<bar>) * (\<bar>real (Suc n)\<bar> * \<bar>R' ^ n\<bar>)"
   751           proof (rule mult_left_mono)
   752             have "\<bar>\<Sum>p = 0..<Suc n. x ^ p * y ^ (n - p)\<bar> \<le> (\<Sum>p = 0..<Suc n. \<bar>x ^ p * y ^ (n - p)\<bar>)" by (rule setsum_abs)
   753             also have "\<dots> \<le> (\<Sum>p = 0..<Suc n. R' ^ n)"
   754             proof (rule setsum_mono)
   755               fix p assume "p \<in> {0..<Suc n}" hence "p \<le> n" by auto
   756               { fix n fix x :: real assume "x \<in> {-R'<..<R'}"
   757                 hence "\<bar>x\<bar> \<le> R'"  by auto
   758                 hence "\<bar>x^n\<bar> \<le> R'^n" unfolding power_abs by (rule power_mono, auto)
   759               } from mult_mono[OF this[OF `x \<in> {-R'<..<R'}`, of p] this[OF `y \<in> {-R'<..<R'}`, of "n-p"]] `0 < R'`
   760               have "\<bar>x^p * y^(n-p)\<bar> \<le> R'^p * R'^(n-p)" unfolding abs_mult by auto
   761               thus "\<bar>x^p * y^(n-p)\<bar> \<le> R'^n" unfolding power_add[symmetric] using `p \<le> n` by auto
   762             qed
   763             also have "\<dots> = real (Suc n) * R' ^ n" unfolding setsum_constant card_atLeastLessThan real_of_nat_def by auto
   764             finally show "\<bar>\<Sum>p = 0..<Suc n. x ^ p * y ^ (n - p)\<bar> \<le> \<bar>real (Suc n)\<bar> * \<bar>R' ^ n\<bar>" unfolding abs_real_of_nat_cancel abs_of_nonneg[OF zero_le_power[OF less_imp_le[OF `0 < R'`]]] .
   765             show "0 \<le> \<bar>f n\<bar> * \<bar>x - y\<bar>" unfolding abs_mult[symmetric] by auto
   766           qed
   767           also have "\<dots> = \<bar>f n * real (Suc n) * R' ^ n\<bar> * \<bar>x - y\<bar>" unfolding abs_mult mult_assoc[symmetric] by algebra
   768           finally show ?thesis .
   769         qed }
   770       { fix n show "DERIV (\<lambda> x. ?f x n) x0 :> (?f' x0 n)"
   771           by (auto intro!: DERIV_intros simp del: power_Suc) }
   772       { fix x assume "x \<in> {-R' <..< R'}" hence "R' \<in> {-R <..< R}" and "norm x < norm R'" using assms `R' < R` by auto
   773         have "summable (\<lambda> n. f n * x^n)"
   774         proof (rule summable_le2[THEN conjunct1, OF _ powser_insidea[OF converges[OF `R' \<in> {-R <..< R}`] `norm x < norm R'`]], rule allI)
   775           fix n
   776           have le: "\<bar>f n\<bar> * 1 \<le> \<bar>f n\<bar> * real (Suc n)" by (rule mult_left_mono, auto)
   777           show "\<bar>f n * x ^ n\<bar> \<le> norm (f n * real (Suc n) * x ^ n)" unfolding real_norm_def abs_mult
   778             by (rule mult_right_mono, auto simp add: le[unfolded mult_1_right])
   779         qed
   780         from this[THEN summable_mult2[where c=x], unfolded mult_assoc, unfolded mult_commute]
   781         show "summable (?f x)" by auto }
   782       show "summable (?f' x0)" using converges[OF `x0 \<in> {-R <..< R}`] .
   783       show "x0 \<in> {-R' <..< R'}" using `x0 \<in> {-R' <..< R'}` .
   784     qed
   785   } note for_subinterval = this
   786   let ?R = "(R + \<bar>x0\<bar>) / 2"
   787   have "\<bar>x0\<bar> < ?R" using assms by auto
   788   hence "- ?R < x0"
   789   proof (cases "x0 < 0")
   790     case True
   791     hence "- x0 < ?R" using `\<bar>x0\<bar> < ?R` by auto
   792     thus ?thesis unfolding neg_less_iff_less[symmetric, of "- x0"] by auto
   793   next
   794     case False
   795     have "- ?R < 0" using assms by auto
   796     also have "\<dots> \<le> x0" using False by auto
   797     finally show ?thesis .
   798   qed
   799   hence "0 < ?R" "?R < R" "- ?R < x0" and "x0 < ?R" using assms by auto
   800   from for_subinterval[OF this]
   801   show ?thesis .
   802 qed
   803 
   804 subsection {* Exponential Function *}
   805 
   806 definition exp :: "'a \<Rightarrow> 'a::{real_normed_field,banach}" where
   807   "exp = (\<lambda>x. \<Sum>n. x ^ n /\<^sub>R real (fact n))"
   808 
   809 lemma summable_exp_generic:
   810   fixes x :: "'a::{real_normed_algebra_1,banach}"
   811   defines S_def: "S \<equiv> \<lambda>n. x ^ n /\<^sub>R real (fact n)"
   812   shows "summable S"
   813 proof -
   814   have S_Suc: "\<And>n. S (Suc n) = (x * S n) /\<^sub>R real (Suc n)"
   815     unfolding S_def by (simp del: mult_Suc)
   816   obtain r :: real where r0: "0 < r" and r1: "r < 1"
   817     using dense [OF zero_less_one] by fast
   818   obtain N :: nat where N: "norm x < real N * r"
   819     using reals_Archimedean3 [OF r0] by fast
   820   from r1 show ?thesis
   821   proof (rule ratio_test [rule_format])
   822     fix n :: nat
   823     assume n: "N \<le> n"
   824     have "norm x \<le> real N * r"
   825       using N by (rule order_less_imp_le)
   826     also have "real N * r \<le> real (Suc n) * r"
   827       using r0 n by (simp add: mult_right_mono)
   828     finally have "norm x * norm (S n) \<le> real (Suc n) * r * norm (S n)"
   829       using norm_ge_zero by (rule mult_right_mono)
   830     hence "norm (x * S n) \<le> real (Suc n) * r * norm (S n)"
   831       by (rule order_trans [OF norm_mult_ineq])
   832     hence "norm (x * S n) / real (Suc n) \<le> r * norm (S n)"
   833       by (simp add: pos_divide_le_eq mult_ac)
   834     thus "norm (S (Suc n)) \<le> r * norm (S n)"
   835       by (simp add: S_Suc inverse_eq_divide)
   836   qed
   837 qed
   838 
   839 lemma summable_norm_exp:
   840   fixes x :: "'a::{real_normed_algebra_1,banach}"
   841   shows "summable (\<lambda>n. norm (x ^ n /\<^sub>R real (fact n)))"
   842 proof (rule summable_norm_comparison_test [OF exI, rule_format])
   843   show "summable (\<lambda>n. norm x ^ n /\<^sub>R real (fact n))"
   844     by (rule summable_exp_generic)
   845 next
   846   fix n show "norm (x ^ n /\<^sub>R real (fact n)) \<le> norm x ^ n /\<^sub>R real (fact n)"
   847     by (simp add: norm_power_ineq)
   848 qed
   849 
   850 lemma summable_exp: "summable (%n. inverse (real (fact n)) * x ^ n)"
   851 by (insert summable_exp_generic [where x=x], simp)
   852 
   853 lemma exp_converges: "(\<lambda>n. x ^ n /\<^sub>R real (fact n)) sums exp x"
   854 unfolding exp_def by (rule summable_exp_generic [THEN summable_sums])
   855 
   856 
   857 lemma exp_fdiffs:
   858       "diffs (%n. inverse(real (fact n))) = (%n. inverse(real (fact n)))"
   859 by (simp add: diffs_def mult_assoc [symmetric] real_of_nat_def of_nat_mult
   860          del: mult_Suc of_nat_Suc)
   861 
   862 lemma diffs_of_real: "diffs (\<lambda>n. of_real (f n)) = (\<lambda>n. of_real (diffs f n))"
   863 by (simp add: diffs_def)
   864 
   865 lemma DERIV_exp [simp]: "DERIV exp x :> exp(x)"
   866 unfolding exp_def scaleR_conv_of_real
   867 apply (rule DERIV_cong)
   868 apply (rule termdiffs [where K="of_real (1 + norm x)"])
   869 apply (simp_all only: diffs_of_real scaleR_conv_of_real exp_fdiffs)
   870 apply (rule exp_converges [THEN sums_summable, unfolded scaleR_conv_of_real])+
   871 apply (simp del: of_real_add)
   872 done
   873 
   874 lemma isCont_exp: "isCont exp x"
   875   by (rule DERIV_exp [THEN DERIV_isCont])
   876 
   877 lemma isCont_exp' [simp]: "isCont f a \<Longrightarrow> isCont (\<lambda>x. exp (f x)) a"
   878   by (rule isCont_o2 [OF _ isCont_exp])
   879 
   880 lemma tendsto_exp [tendsto_intros]:
   881   "(f ---> a) F \<Longrightarrow> ((\<lambda>x. exp (f x)) ---> exp a) F"
   882   by (rule isCont_tendsto_compose [OF isCont_exp])
   883 
   884 subsubsection {* Properties of the Exponential Function *}
   885 
   886 lemma powser_zero:
   887   fixes f :: "nat \<Rightarrow> 'a::{real_normed_algebra_1}"
   888   shows "(\<Sum>n. f n * 0 ^ n) = f 0"
   889 proof -
   890   have "(\<Sum>n = 0..<1. f n * 0 ^ n) = (\<Sum>n. f n * 0 ^ n)"
   891     by (rule sums_unique [OF series_zero], simp add: power_0_left)
   892   thus ?thesis unfolding One_nat_def by simp
   893 qed
   894 
   895 lemma exp_zero [simp]: "exp 0 = 1"
   896 unfolding exp_def by (simp add: scaleR_conv_of_real powser_zero)
   897 
   898 lemma setsum_cl_ivl_Suc2:
   899   "(\<Sum>i=m..Suc n. f i) = (if Suc n < m then 0 else f m + (\<Sum>i=m..n. f (Suc i)))"
   900 by (simp add: setsum_head_Suc setsum_shift_bounds_cl_Suc_ivl
   901          del: setsum_cl_ivl_Suc)
   902 
   903 lemma exp_series_add:
   904   fixes x y :: "'a::{real_field}"
   905   defines S_def: "S \<equiv> \<lambda>x n. x ^ n /\<^sub>R real (fact n)"
   906   shows "S (x + y) n = (\<Sum>i=0..n. S x i * S y (n - i))"
   907 proof (induct n)
   908   case 0
   909   show ?case
   910     unfolding S_def by simp
   911 next
   912   case (Suc n)
   913   have S_Suc: "\<And>x n. S x (Suc n) = (x * S x n) /\<^sub>R real (Suc n)"
   914     unfolding S_def by (simp del: mult_Suc)
   915   hence times_S: "\<And>x n. x * S x n = real (Suc n) *\<^sub>R S x (Suc n)"
   916     by simp
   917 
   918   have "real (Suc n) *\<^sub>R S (x + y) (Suc n) = (x + y) * S (x + y) n"
   919     by (simp only: times_S)
   920   also have "\<dots> = (x + y) * (\<Sum>i=0..n. S x i * S y (n-i))"
   921     by (simp only: Suc)
   922   also have "\<dots> = x * (\<Sum>i=0..n. S x i * S y (n-i))
   923                 + y * (\<Sum>i=0..n. S x i * S y (n-i))"
   924     by (rule distrib_right)
   925   also have "\<dots> = (\<Sum>i=0..n. (x * S x i) * S y (n-i))
   926                 + (\<Sum>i=0..n. S x i * (y * S y (n-i)))"
   927     by (simp only: setsum_right_distrib mult_ac)
   928   also have "\<dots> = (\<Sum>i=0..n. real (Suc i) *\<^sub>R (S x (Suc i) * S y (n-i)))
   929                 + (\<Sum>i=0..n. real (Suc n-i) *\<^sub>R (S x i * S y (Suc n-i)))"
   930     by (simp add: times_S Suc_diff_le)
   931   also have "(\<Sum>i=0..n. real (Suc i) *\<^sub>R (S x (Suc i) * S y (n-i))) =
   932              (\<Sum>i=0..Suc n. real i *\<^sub>R (S x i * S y (Suc n-i)))"
   933     by (subst setsum_cl_ivl_Suc2, simp)
   934   also have "(\<Sum>i=0..n. real (Suc n-i) *\<^sub>R (S x i * S y (Suc n-i))) =
   935              (\<Sum>i=0..Suc n. real (Suc n-i) *\<^sub>R (S x i * S y (Suc n-i)))"
   936     by (subst setsum_cl_ivl_Suc, simp)
   937   also have "(\<Sum>i=0..Suc n. real i *\<^sub>R (S x i * S y (Suc n-i))) +
   938              (\<Sum>i=0..Suc n. real (Suc n-i) *\<^sub>R (S x i * S y (Suc n-i))) =
   939              (\<Sum>i=0..Suc n. real (Suc n) *\<^sub>R (S x i * S y (Suc n-i)))"
   940     by (simp only: setsum_addf [symmetric] scaleR_left_distrib [symmetric]
   941               real_of_nat_add [symmetric], simp)
   942   also have "\<dots> = real (Suc n) *\<^sub>R (\<Sum>i=0..Suc n. S x i * S y (Suc n-i))"
   943     by (simp only: scaleR_right.setsum)
   944   finally show
   945     "S (x + y) (Suc n) = (\<Sum>i=0..Suc n. S x i * S y (Suc n - i))"
   946     by (simp del: setsum_cl_ivl_Suc)
   947 qed
   948 
   949 lemma exp_add: "exp (x + y) = exp x * exp y"
   950 unfolding exp_def
   951 by (simp only: Cauchy_product summable_norm_exp exp_series_add)
   952 
   953 lemma mult_exp_exp: "exp x * exp y = exp (x + y)"
   954 by (rule exp_add [symmetric])
   955 
   956 lemma exp_of_real: "exp (of_real x) = of_real (exp x)"
   957 unfolding exp_def
   958 apply (subst suminf_of_real)
   959 apply (rule summable_exp_generic)
   960 apply (simp add: scaleR_conv_of_real)
   961 done
   962 
   963 lemma exp_not_eq_zero [simp]: "exp x \<noteq> 0"
   964 proof
   965   have "exp x * exp (- x) = 1" by (simp add: mult_exp_exp)
   966   also assume "exp x = 0"
   967   finally show "False" by simp
   968 qed
   969 
   970 lemma exp_minus: "exp (- x) = inverse (exp x)"
   971 by (rule inverse_unique [symmetric], simp add: mult_exp_exp)
   972 
   973 lemma exp_diff: "exp (x - y) = exp x / exp y"
   974   unfolding diff_minus divide_inverse
   975   by (simp add: exp_add exp_minus)
   976 
   977 
   978 subsubsection {* Properties of the Exponential Function on Reals *}
   979 
   980 text {* Comparisons of @{term "exp x"} with zero. *}
   981 
   982 text{*Proof: because every exponential can be seen as a square.*}
   983 lemma exp_ge_zero [simp]: "0 \<le> exp (x::real)"
   984 proof -
   985   have "0 \<le> exp (x/2) * exp (x/2)" by simp
   986   thus ?thesis by (simp add: exp_add [symmetric])
   987 qed
   988 
   989 lemma exp_gt_zero [simp]: "0 < exp (x::real)"
   990 by (simp add: order_less_le)
   991 
   992 lemma not_exp_less_zero [simp]: "\<not> exp (x::real) < 0"
   993 by (simp add: not_less)
   994 
   995 lemma not_exp_le_zero [simp]: "\<not> exp (x::real) \<le> 0"
   996 by (simp add: not_le)
   997 
   998 lemma abs_exp_cancel [simp]: "\<bar>exp x::real\<bar> = exp x"
   999 by simp
  1000 
  1001 lemma exp_real_of_nat_mult: "exp(real n * x) = exp(x) ^ n"
  1002 apply (induct "n")
  1003 apply (auto simp add: real_of_nat_Suc distrib_left exp_add mult_commute)
  1004 done
  1005 
  1006 text {* Strict monotonicity of exponential. *}
  1007 
  1008 lemma exp_ge_add_one_self_aux: "0 \<le> (x::real) ==> (1 + x) \<le> exp(x)"
  1009 apply (drule order_le_imp_less_or_eq, auto)
  1010 apply (simp add: exp_def)
  1011 apply (rule order_trans)
  1012 apply (rule_tac [2] n = 2 and f = "(%n. inverse (real (fact n)) * x ^ n)" in series_pos_le)
  1013 apply (auto intro: summable_exp simp add: numeral_2_eq_2 zero_le_mult_iff)
  1014 done
  1015 
  1016 lemma exp_gt_one: "0 < (x::real) \<Longrightarrow> 1 < exp x"
  1017 proof -
  1018   assume x: "0 < x"
  1019   hence "1 < 1 + x" by simp
  1020   also from x have "1 + x \<le> exp x"
  1021     by (simp add: exp_ge_add_one_self_aux)
  1022   finally show ?thesis .
  1023 qed
  1024 
  1025 lemma exp_less_mono:
  1026   fixes x y :: real
  1027   assumes "x < y" shows "exp x < exp y"
  1028 proof -
  1029   from `x < y` have "0 < y - x" by simp
  1030   hence "1 < exp (y - x)" by (rule exp_gt_one)
  1031   hence "1 < exp y / exp x" by (simp only: exp_diff)
  1032   thus "exp x < exp y" by simp
  1033 qed
  1034 
  1035 lemma exp_less_cancel: "exp (x::real) < exp y ==> x < y"
  1036 apply (simp add: linorder_not_le [symmetric])
  1037 apply (auto simp add: order_le_less exp_less_mono)
  1038 done
  1039 
  1040 lemma exp_less_cancel_iff [iff]: "exp (x::real) < exp y \<longleftrightarrow> x < y"
  1041 by (auto intro: exp_less_mono exp_less_cancel)
  1042 
  1043 lemma exp_le_cancel_iff [iff]: "exp (x::real) \<le> exp y \<longleftrightarrow> x \<le> y"
  1044 by (auto simp add: linorder_not_less [symmetric])
  1045 
  1046 lemma exp_inj_iff [iff]: "exp (x::real) = exp y \<longleftrightarrow> x = y"
  1047 by (simp add: order_eq_iff)
  1048 
  1049 text {* Comparisons of @{term "exp x"} with one. *}
  1050 
  1051 lemma one_less_exp_iff [simp]: "1 < exp (x::real) \<longleftrightarrow> 0 < x"
  1052   using exp_less_cancel_iff [where x=0 and y=x] by simp
  1053 
  1054 lemma exp_less_one_iff [simp]: "exp (x::real) < 1 \<longleftrightarrow> x < 0"
  1055   using exp_less_cancel_iff [where x=x and y=0] by simp
  1056 
  1057 lemma one_le_exp_iff [simp]: "1 \<le> exp (x::real) \<longleftrightarrow> 0 \<le> x"
  1058   using exp_le_cancel_iff [where x=0 and y=x] by simp
  1059 
  1060 lemma exp_le_one_iff [simp]: "exp (x::real) \<le> 1 \<longleftrightarrow> x \<le> 0"
  1061   using exp_le_cancel_iff [where x=x and y=0] by simp
  1062 
  1063 lemma exp_eq_one_iff [simp]: "exp (x::real) = 1 \<longleftrightarrow> x = 0"
  1064   using exp_inj_iff [where x=x and y=0] by simp
  1065 
  1066 lemma lemma_exp_total: "1 \<le> y ==> \<exists>x. 0 \<le> x & x \<le> y - 1 & exp(x::real) = y"
  1067 proof (rule IVT)
  1068   assume "1 \<le> y"
  1069   hence "0 \<le> y - 1" by simp
  1070   hence "1 + (y - 1) \<le> exp (y - 1)" by (rule exp_ge_add_one_self_aux)
  1071   thus "y \<le> exp (y - 1)" by simp
  1072 qed (simp_all add: le_diff_eq)
  1073 
  1074 lemma exp_total: "0 < (y::real) ==> \<exists>x. exp x = y"
  1075 proof (rule linorder_le_cases [of 1 y])
  1076   assume "1 \<le> y" thus "\<exists>x. exp x = y"
  1077     by (fast dest: lemma_exp_total)
  1078 next
  1079   assume "0 < y" and "y \<le> 1"
  1080   hence "1 \<le> inverse y" by (simp add: one_le_inverse_iff)
  1081   then obtain x where "exp x = inverse y" by (fast dest: lemma_exp_total)
  1082   hence "exp (- x) = y" by (simp add: exp_minus)
  1083   thus "\<exists>x. exp x = y" ..
  1084 qed
  1085 
  1086 
  1087 subsection {* Natural Logarithm *}
  1088 
  1089 definition ln :: "real \<Rightarrow> real" where
  1090   "ln x = (THE u. exp u = x)"
  1091 
  1092 lemma ln_exp [simp]: "ln (exp x) = x"
  1093   by (simp add: ln_def)
  1094 
  1095 lemma exp_ln [simp]: "0 < x \<Longrightarrow> exp (ln x) = x"
  1096   by (auto dest: exp_total)
  1097 
  1098 lemma exp_ln_iff [simp]: "exp (ln x) = x \<longleftrightarrow> 0 < x"
  1099   by (metis exp_gt_zero exp_ln)
  1100 
  1101 lemma ln_unique: "exp y = x \<Longrightarrow> ln x = y"
  1102   by (erule subst, rule ln_exp)
  1103 
  1104 lemma ln_one [simp]: "ln 1 = 0"
  1105   by (rule ln_unique, simp)
  1106 
  1107 lemma ln_mult: "\<lbrakk>0 < x; 0 < y\<rbrakk> \<Longrightarrow> ln (x * y) = ln x + ln y"
  1108   by (rule ln_unique, simp add: exp_add)
  1109 
  1110 lemma ln_inverse: "0 < x \<Longrightarrow> ln (inverse x) = - ln x"
  1111   by (rule ln_unique, simp add: exp_minus)
  1112 
  1113 lemma ln_div: "\<lbrakk>0 < x; 0 < y\<rbrakk> \<Longrightarrow> ln (x / y) = ln x - ln y"
  1114   by (rule ln_unique, simp add: exp_diff)
  1115 
  1116 lemma ln_realpow: "0 < x \<Longrightarrow> ln (x ^ n) = real n * ln x"
  1117   by (rule ln_unique, simp add: exp_real_of_nat_mult)
  1118 
  1119 lemma ln_less_cancel_iff [simp]: "\<lbrakk>0 < x; 0 < y\<rbrakk> \<Longrightarrow> ln x < ln y \<longleftrightarrow> x < y"
  1120   by (subst exp_less_cancel_iff [symmetric], simp)
  1121 
  1122 lemma ln_le_cancel_iff [simp]: "\<lbrakk>0 < x; 0 < y\<rbrakk> \<Longrightarrow> ln x \<le> ln y \<longleftrightarrow> x \<le> y"
  1123   by (simp add: linorder_not_less [symmetric])
  1124 
  1125 lemma ln_inj_iff [simp]: "\<lbrakk>0 < x; 0 < y\<rbrakk> \<Longrightarrow> ln x = ln y \<longleftrightarrow> x = y"
  1126   by (simp add: order_eq_iff)
  1127 
  1128 lemma ln_add_one_self_le_self [simp]: "0 \<le> x \<Longrightarrow> ln (1 + x) \<le> x"
  1129   apply (rule exp_le_cancel_iff [THEN iffD1])
  1130   apply (simp add: exp_ge_add_one_self_aux)
  1131   done
  1132 
  1133 lemma ln_less_self [simp]: "0 < x \<Longrightarrow> ln x < x"
  1134   by (rule order_less_le_trans [where y="ln (1 + x)"]) simp_all
  1135 
  1136 lemma ln_ge_zero [simp]: "1 \<le> x \<Longrightarrow> 0 \<le> ln x"
  1137   using ln_le_cancel_iff [of 1 x] by simp
  1138 
  1139 lemma ln_ge_zero_imp_ge_one: "\<lbrakk>0 \<le> ln x; 0 < x\<rbrakk> \<Longrightarrow> 1 \<le> x"
  1140   using ln_le_cancel_iff [of 1 x] by simp
  1141 
  1142 lemma ln_ge_zero_iff [simp]: "0 < x \<Longrightarrow> (0 \<le> ln x) = (1 \<le> x)"
  1143   using ln_le_cancel_iff [of 1 x] by simp
  1144 
  1145 lemma ln_less_zero_iff [simp]: "0 < x \<Longrightarrow> (ln x < 0) = (x < 1)"
  1146   using ln_less_cancel_iff [of x 1] by simp
  1147 
  1148 lemma ln_gt_zero: "1 < x \<Longrightarrow> 0 < ln x"
  1149   using ln_less_cancel_iff [of 1 x] by simp
  1150 
  1151 lemma ln_gt_zero_imp_gt_one: "\<lbrakk>0 < ln x; 0 < x\<rbrakk> \<Longrightarrow> 1 < x"
  1152   using ln_less_cancel_iff [of 1 x] by simp
  1153 
  1154 lemma ln_gt_zero_iff [simp]: "0 < x \<Longrightarrow> (0 < ln x) = (1 < x)"
  1155   using ln_less_cancel_iff [of 1 x] by simp
  1156 
  1157 lemma ln_eq_zero_iff [simp]: "0 < x \<Longrightarrow> (ln x = 0) = (x = 1)"
  1158   using ln_inj_iff [of x 1] by simp
  1159 
  1160 lemma ln_less_zero: "\<lbrakk>0 < x; x < 1\<rbrakk> \<Longrightarrow> ln x < 0"
  1161   by simp
  1162 
  1163 lemma isCont_ln: "0 < x \<Longrightarrow> isCont ln x"
  1164   apply (subgoal_tac "isCont ln (exp (ln x))", simp)
  1165   apply (rule isCont_inverse_function [where f=exp], simp_all)
  1166   done
  1167 
  1168 lemma tendsto_ln [tendsto_intros]:
  1169   "\<lbrakk>(f ---> a) F; 0 < a\<rbrakk> \<Longrightarrow> ((\<lambda>x. ln (f x)) ---> ln a) F"
  1170   by (rule isCont_tendsto_compose [OF isCont_ln])
  1171 
  1172 lemma DERIV_ln: "0 < x \<Longrightarrow> DERIV ln x :> inverse x"
  1173   apply (rule DERIV_inverse_function [where f=exp and a=0 and b="x+1"])
  1174   apply (erule DERIV_cong [OF DERIV_exp exp_ln])
  1175   apply (simp_all add: abs_if isCont_ln)
  1176   done
  1177 
  1178 lemma DERIV_ln_divide: "0 < x ==> DERIV ln x :> 1 / x"
  1179   by (rule DERIV_ln[THEN DERIV_cong], simp, simp add: divide_inverse)
  1180 
  1181 lemma ln_series: assumes "0 < x" and "x < 2"
  1182   shows "ln x = (\<Sum> n. (-1)^n * (1 / real (n + 1)) * (x - 1)^(Suc n))" (is "ln x = suminf (?f (x - 1))")
  1183 proof -
  1184   let "?f' x n" = "(-1)^n * (x - 1)^n"
  1185 
  1186   have "ln x - suminf (?f (x - 1)) = ln 1 - suminf (?f (1 - 1))"
  1187   proof (rule DERIV_isconst3[where x=x])
  1188     fix x :: real assume "x \<in> {0 <..< 2}" hence "0 < x" and "x < 2" by auto
  1189     have "norm (1 - x) < 1" using `0 < x` and `x < 2` by auto
  1190     have "1 / x = 1 / (1 - (1 - x))" by auto
  1191     also have "\<dots> = (\<Sum> n. (1 - x)^n)" using geometric_sums[OF `norm (1 - x) < 1`] by (rule sums_unique)
  1192     also have "\<dots> = suminf (?f' x)" unfolding power_mult_distrib[symmetric] by (rule arg_cong[where f=suminf], rule arg_cong[where f="op ^"], auto)
  1193     finally have "DERIV ln x :> suminf (?f' x)" using DERIV_ln[OF `0 < x`] unfolding divide_inverse by auto
  1194     moreover
  1195     have repos: "\<And> h x :: real. h - 1 + x = h + x - 1" by auto
  1196     have "DERIV (\<lambda>x. suminf (?f x)) (x - 1) :> (\<Sum>n. (-1)^n * (1 / real (n + 1)) * real (Suc n) * (x - 1) ^ n)"
  1197     proof (rule DERIV_power_series')
  1198       show "x - 1 \<in> {- 1<..<1}" and "(0 :: real) < 1" using `0 < x` `x < 2` by auto
  1199       { fix x :: real assume "x \<in> {- 1<..<1}" hence "norm (-x) < 1" by auto
  1200         show "summable (\<lambda>n. -1 ^ n * (1 / real (n + 1)) * real (Suc n) * x ^ n)"
  1201           unfolding One_nat_def
  1202           by (auto simp add: power_mult_distrib[symmetric] summable_geometric[OF `norm (-x) < 1`])
  1203       }
  1204     qed
  1205     hence "DERIV (\<lambda>x. suminf (?f x)) (x - 1) :> suminf (?f' x)" unfolding One_nat_def by auto
  1206     hence "DERIV (\<lambda>x. suminf (?f (x - 1))) x :> suminf (?f' x)" unfolding DERIV_iff repos .
  1207     ultimately have "DERIV (\<lambda>x. ln x - suminf (?f (x - 1))) x :> (suminf (?f' x) - suminf (?f' x))"
  1208       by (rule DERIV_diff)
  1209     thus "DERIV (\<lambda>x. ln x - suminf (?f (x - 1))) x :> 0" by auto
  1210   qed (auto simp add: assms)
  1211   thus ?thesis by auto
  1212 qed
  1213 
  1214 lemma exp_first_two_terms: "exp x = 1 + x + (\<Sum> n. inverse(fact (n+2)) * (x ^ (n+2)))"
  1215 proof -
  1216   have "exp x = suminf (%n. inverse(fact n) * (x ^ n))"
  1217     by (simp add: exp_def)
  1218   also from summable_exp have "... = (\<Sum> n::nat = 0 ..< 2. inverse(fact n) * (x ^ n)) +
  1219       (\<Sum> n. inverse(fact(n+2)) * (x ^ (n+2)))" (is "_ = ?a + _")
  1220     by (rule suminf_split_initial_segment)
  1221   also have "?a = 1 + x"
  1222     by (simp add: numeral_2_eq_2)
  1223   finally show ?thesis .
  1224 qed
  1225 
  1226 lemma exp_bound: "0 <= (x::real) ==> x <= 1 ==> exp x <= 1 + x + x^2"
  1227 proof -
  1228   assume a: "0 <= x"
  1229   assume b: "x <= 1"
  1230   { fix n :: nat
  1231     have "2 * 2 ^ n \<le> fact (n + 2)"
  1232       by (induct n, simp, simp)
  1233     hence "real ((2::nat) * 2 ^ n) \<le> real (fact (n + 2))"
  1234       by (simp only: real_of_nat_le_iff)
  1235     hence "2 * 2 ^ n \<le> real (fact (n + 2))"
  1236       by simp
  1237     hence "inverse (fact (n + 2)) \<le> inverse (2 * 2 ^ n)"
  1238       by (rule le_imp_inverse_le) simp
  1239     hence "inverse (fact (n + 2)) \<le> 1/2 * (1/2)^n"
  1240       by (simp add: inverse_mult_distrib power_inverse)
  1241     hence "inverse (fact (n + 2)) * (x^n * x\<twosuperior>) \<le> 1/2 * (1/2)^n * (1 * x\<twosuperior>)"
  1242       by (rule mult_mono)
  1243         (rule mult_mono, simp_all add: power_le_one a b mult_nonneg_nonneg)
  1244     hence "inverse (fact (n + 2)) * x ^ (n + 2) \<le> (x\<twosuperior>/2) * ((1/2)^n)"
  1245       unfolding power_add by (simp add: mult_ac del: fact_Suc) }
  1246   note aux1 = this
  1247   have "(\<lambda>n. x\<twosuperior> / 2 * (1 / 2) ^ n) sums (x\<twosuperior> / 2 * (1 / (1 - 1 / 2)))"
  1248     by (intro sums_mult geometric_sums, simp)
  1249   hence aux2: "(\<lambda>n. (x::real) ^ 2 / 2 * (1 / 2) ^ n) sums x^2"
  1250     by simp
  1251   have "suminf (%n. inverse(fact (n+2)) * (x ^ (n+2))) <= x^2"
  1252   proof -
  1253     have "suminf (%n. inverse(fact (n+2)) * (x ^ (n+2))) <=
  1254         suminf (%n. (x^2/2) * ((1/2)^n))"
  1255       apply (rule summable_le)
  1256       apply (rule allI, rule aux1)
  1257       apply (rule summable_exp [THEN summable_ignore_initial_segment])
  1258       by (rule sums_summable, rule aux2)
  1259     also have "... = x^2"
  1260       by (rule sums_unique [THEN sym], rule aux2)
  1261     finally show ?thesis .
  1262   qed
  1263   thus ?thesis unfolding exp_first_two_terms by auto
  1264 qed
  1265 
  1266 lemma ln_one_minus_pos_upper_bound: "0 <= x ==> x < 1 ==> ln (1 - x) <= - x"
  1267 proof -
  1268   assume a: "0 <= (x::real)" and b: "x < 1"
  1269   have "(1 - x) * (1 + x + x^2) = (1 - x^3)"
  1270     by (simp add: algebra_simps power2_eq_square power3_eq_cube)
  1271   also have "... <= 1"
  1272     by (auto simp add: a)
  1273   finally have "(1 - x) * (1 + x + x ^ 2) <= 1" .
  1274   moreover have c: "0 < 1 + x + x\<twosuperior>"
  1275     by (simp add: add_pos_nonneg a)
  1276   ultimately have "1 - x <= 1 / (1 + x + x^2)"
  1277     by (elim mult_imp_le_div_pos)
  1278   also have "... <= 1 / exp x"
  1279     apply (rule divide_left_mono)
  1280     apply (rule exp_bound, rule a)
  1281     apply (rule b [THEN less_imp_le])
  1282     apply simp
  1283     apply (rule mult_pos_pos)
  1284     apply (rule c)
  1285     apply simp
  1286     done
  1287   also have "... = exp (-x)"
  1288     by (auto simp add: exp_minus divide_inverse)
  1289   finally have "1 - x <= exp (- x)" .
  1290   also have "1 - x = exp (ln (1 - x))"
  1291   proof -
  1292     have "0 < 1 - x"
  1293       by (insert b, auto)
  1294     thus ?thesis
  1295       by (auto simp only: exp_ln_iff [THEN sym])
  1296   qed
  1297   finally have "exp (ln (1 - x)) <= exp (- x)" .
  1298   thus ?thesis by (auto simp only: exp_le_cancel_iff)
  1299 qed
  1300 
  1301 lemma exp_ge_add_one_self [simp]: "1 + (x::real) <= exp x"
  1302   apply (case_tac "0 <= x")
  1303   apply (erule exp_ge_add_one_self_aux)
  1304   apply (case_tac "x <= -1")
  1305   apply (subgoal_tac "1 + x <= 0")
  1306   apply (erule order_trans)
  1307   apply simp
  1308   apply simp
  1309   apply (subgoal_tac "1 + x = exp(ln (1 + x))")
  1310   apply (erule ssubst)
  1311   apply (subst exp_le_cancel_iff)
  1312   apply (subgoal_tac "ln (1 - (- x)) <= - (- x)")
  1313   apply simp
  1314   apply (rule ln_one_minus_pos_upper_bound)
  1315   apply auto
  1316 done
  1317 
  1318 lemma exp_at_bot: "(exp ---> (0::real)) at_bot"
  1319   unfolding tendsto_Zfun_iff
  1320 proof (rule ZfunI, simp add: eventually_at_bot_dense)
  1321   fix r :: real assume "0 < r"
  1322   { fix x assume "x < ln r"
  1323     then have "exp x < exp (ln r)"
  1324       by simp
  1325     with `0 < r` have "exp x < r"
  1326       by simp }
  1327   then show "\<exists>k. \<forall>n<k. exp n < r" by auto
  1328 qed
  1329 
  1330 lemma exp_at_top: "LIM x at_top. exp x :: real :> at_top"
  1331   by (rule filterlim_at_top_at_top[where Q="\<lambda>x. True" and P="\<lambda>x. 0 < x" and g="ln"])
  1332      (auto intro: eventually_gt_at_top)
  1333 
  1334 lemma ln_at_0: "LIM x at_right 0. ln x :> at_bot"
  1335   by (rule filterlim_at_bot_at_right[where Q="\<lambda>x. 0 < x" and P="\<lambda>x. True" and g="exp"])
  1336      (auto simp: eventually_within)
  1337 
  1338 lemma ln_at_top: "LIM x at_top. ln x :> at_top"
  1339   by (rule filterlim_at_top_at_top[where Q="\<lambda>x. 0 < x" and P="\<lambda>x. True" and g="exp"])
  1340      (auto intro: eventually_gt_at_top)
  1341 
  1342 lemma tendsto_power_div_exp_0: "((\<lambda>x. x ^ k / exp x) ---> (0::real)) at_top"
  1343 proof (induct k)
  1344   show "((\<lambda>x. x ^ 0 / exp x) ---> (0::real)) at_top"
  1345     by (simp add: inverse_eq_divide[symmetric])
  1346        (metis filterlim_compose[OF tendsto_inverse_0] exp_at_top filterlim_mono
  1347               at_top_le_at_infinity order_refl)
  1348 next
  1349   case (Suc k)
  1350   show ?case
  1351   proof (rule lhospital_at_top_at_top)
  1352     show "eventually (\<lambda>x. DERIV (\<lambda>x. x ^ Suc k) x :> (real (Suc k) * x^k)) at_top"
  1353       by eventually_elim (intro DERIV_intros, simp, simp)
  1354     show "eventually (\<lambda>x. DERIV exp x :> exp x) at_top"
  1355       by eventually_elim (auto intro!: DERIV_intros)
  1356     show "eventually (\<lambda>x. exp x \<noteq> 0) at_top"
  1357       by auto
  1358     from tendsto_mult[OF tendsto_const Suc, of "real (Suc k)"]
  1359     show "((\<lambda>x. real (Suc k) * x ^ k / exp x) ---> 0) at_top"
  1360       by simp
  1361   qed (rule exp_at_top)
  1362 qed
  1363 
  1364 subsection {* Sine and Cosine *}
  1365 
  1366 definition sin_coeff :: "nat \<Rightarrow> real" where
  1367   "sin_coeff = (\<lambda>n. if even n then 0 else -1 ^ ((n - Suc 0) div 2) / real (fact n))"
  1368 
  1369 definition cos_coeff :: "nat \<Rightarrow> real" where
  1370   "cos_coeff = (\<lambda>n. if even n then (-1 ^ (n div 2)) / real (fact n) else 0)"
  1371 
  1372 definition sin :: "real \<Rightarrow> real" where
  1373   "sin = (\<lambda>x. \<Sum>n. sin_coeff n * x ^ n)"
  1374 
  1375 definition cos :: "real \<Rightarrow> real" where
  1376   "cos = (\<lambda>x. \<Sum>n. cos_coeff n * x ^ n)"
  1377 
  1378 lemma sin_coeff_0 [simp]: "sin_coeff 0 = 0"
  1379   unfolding sin_coeff_def by simp
  1380 
  1381 lemma cos_coeff_0 [simp]: "cos_coeff 0 = 1"
  1382   unfolding cos_coeff_def by simp
  1383 
  1384 lemma sin_coeff_Suc: "sin_coeff (Suc n) = cos_coeff n / real (Suc n)"
  1385   unfolding cos_coeff_def sin_coeff_def
  1386   by (simp del: mult_Suc)
  1387 
  1388 lemma cos_coeff_Suc: "cos_coeff (Suc n) = - sin_coeff n / real (Suc n)"
  1389   unfolding cos_coeff_def sin_coeff_def
  1390   by (simp del: mult_Suc, auto simp add: odd_Suc_mult_two_ex)
  1391 
  1392 lemma summable_sin: "summable (\<lambda>n. sin_coeff n * x ^ n)"
  1393 unfolding sin_coeff_def
  1394 apply (rule summable_comparison_test [OF _ summable_exp [where x="\<bar>x\<bar>"]])
  1395 apply (auto simp add: divide_inverse abs_mult power_abs [symmetric] zero_le_mult_iff)
  1396 done
  1397 
  1398 lemma summable_cos: "summable (\<lambda>n. cos_coeff n * x ^ n)"
  1399 unfolding cos_coeff_def
  1400 apply (rule summable_comparison_test [OF _ summable_exp [where x="\<bar>x\<bar>"]])
  1401 apply (auto simp add: divide_inverse abs_mult power_abs [symmetric] zero_le_mult_iff)
  1402 done
  1403 
  1404 lemma sin_converges: "(\<lambda>n. sin_coeff n * x ^ n) sums sin(x)"
  1405 unfolding sin_def by (rule summable_sin [THEN summable_sums])
  1406 
  1407 lemma cos_converges: "(\<lambda>n. cos_coeff n * x ^ n) sums cos(x)"
  1408 unfolding cos_def by (rule summable_cos [THEN summable_sums])
  1409 
  1410 lemma diffs_sin_coeff: "diffs sin_coeff = cos_coeff"
  1411   by (simp add: diffs_def sin_coeff_Suc real_of_nat_def del: of_nat_Suc)
  1412 
  1413 lemma diffs_cos_coeff: "diffs cos_coeff = (\<lambda>n. - sin_coeff n)"
  1414   by (simp add: diffs_def cos_coeff_Suc real_of_nat_def del: of_nat_Suc)
  1415 
  1416 text{*Now at last we can get the derivatives of exp, sin and cos*}
  1417 
  1418 lemma DERIV_sin [simp]: "DERIV sin x :> cos(x)"
  1419   unfolding sin_def cos_def
  1420   apply (rule DERIV_cong, rule termdiffs [where K="1 + \<bar>x\<bar>"])
  1421   apply (simp_all add: diffs_sin_coeff diffs_cos_coeff
  1422     summable_minus summable_sin summable_cos)
  1423   done
  1424 
  1425 lemma DERIV_cos [simp]: "DERIV cos x :> -sin(x)"
  1426   unfolding cos_def sin_def
  1427   apply (rule DERIV_cong, rule termdiffs [where K="1 + \<bar>x\<bar>"])
  1428   apply (simp_all add: diffs_sin_coeff diffs_cos_coeff diffs_minus
  1429     summable_minus summable_sin summable_cos suminf_minus)
  1430   done
  1431 
  1432 lemma isCont_sin: "isCont sin x"
  1433   by (rule DERIV_sin [THEN DERIV_isCont])
  1434 
  1435 lemma isCont_cos: "isCont cos x"
  1436   by (rule DERIV_cos [THEN DERIV_isCont])
  1437 
  1438 lemma isCont_sin' [simp]: "isCont f a \<Longrightarrow> isCont (\<lambda>x. sin (f x)) a"
  1439   by (rule isCont_o2 [OF _ isCont_sin])
  1440 
  1441 lemma isCont_cos' [simp]: "isCont f a \<Longrightarrow> isCont (\<lambda>x. cos (f x)) a"
  1442   by (rule isCont_o2 [OF _ isCont_cos])
  1443 
  1444 lemma tendsto_sin [tendsto_intros]:
  1445   "(f ---> a) F \<Longrightarrow> ((\<lambda>x. sin (f x)) ---> sin a) F"
  1446   by (rule isCont_tendsto_compose [OF isCont_sin])
  1447 
  1448 lemma tendsto_cos [tendsto_intros]:
  1449   "(f ---> a) F \<Longrightarrow> ((\<lambda>x. cos (f x)) ---> cos a) F"
  1450   by (rule isCont_tendsto_compose [OF isCont_cos])
  1451 
  1452 declare
  1453   DERIV_exp[THEN DERIV_chain2, THEN DERIV_cong, DERIV_intros]
  1454   DERIV_ln_divide[THEN DERIV_chain2, THEN DERIV_cong, DERIV_intros]
  1455   DERIV_sin[THEN DERIV_chain2, THEN DERIV_cong, DERIV_intros]
  1456   DERIV_cos[THEN DERIV_chain2, THEN DERIV_cong, DERIV_intros]
  1457 
  1458 subsection {* Properties of Sine and Cosine *}
  1459 
  1460 lemma sin_zero [simp]: "sin 0 = 0"
  1461   unfolding sin_def sin_coeff_def by (simp add: powser_zero)
  1462 
  1463 lemma cos_zero [simp]: "cos 0 = 1"
  1464   unfolding cos_def cos_coeff_def by (simp add: powser_zero)
  1465 
  1466 lemma sin_cos_squared_add [simp]: "(sin x)\<twosuperior> + (cos x)\<twosuperior> = 1"
  1467 proof -
  1468   have "\<forall>x. DERIV (\<lambda>x. (sin x)\<twosuperior> + (cos x)\<twosuperior>) x :> 0"
  1469     by (auto intro!: DERIV_intros)
  1470   hence "(sin x)\<twosuperior> + (cos x)\<twosuperior> = (sin 0)\<twosuperior> + (cos 0)\<twosuperior>"
  1471     by (rule DERIV_isconst_all)
  1472   thus "(sin x)\<twosuperior> + (cos x)\<twosuperior> = 1" by simp
  1473 qed
  1474 
  1475 lemma sin_cos_squared_add2 [simp]: "(cos x)\<twosuperior> + (sin x)\<twosuperior> = 1"
  1476   by (subst add_commute, rule sin_cos_squared_add)
  1477 
  1478 lemma sin_cos_squared_add3 [simp]: "cos x * cos x + sin x * sin x = 1"
  1479   using sin_cos_squared_add2 [unfolded power2_eq_square] .
  1480 
  1481 lemma sin_squared_eq: "(sin x)\<twosuperior> = 1 - (cos x)\<twosuperior>"
  1482   unfolding eq_diff_eq by (rule sin_cos_squared_add)
  1483 
  1484 lemma cos_squared_eq: "(cos x)\<twosuperior> = 1 - (sin x)\<twosuperior>"
  1485   unfolding eq_diff_eq by (rule sin_cos_squared_add2)
  1486 
  1487 lemma abs_sin_le_one [simp]: "\<bar>sin x\<bar> \<le> 1"
  1488   by (rule power2_le_imp_le, simp_all add: sin_squared_eq)
  1489 
  1490 lemma sin_ge_minus_one [simp]: "-1 \<le> sin x"
  1491   using abs_sin_le_one [of x] unfolding abs_le_iff by simp
  1492 
  1493 lemma sin_le_one [simp]: "sin x \<le> 1"
  1494   using abs_sin_le_one [of x] unfolding abs_le_iff by simp
  1495 
  1496 lemma abs_cos_le_one [simp]: "\<bar>cos x\<bar> \<le> 1"
  1497   by (rule power2_le_imp_le, simp_all add: cos_squared_eq)
  1498 
  1499 lemma cos_ge_minus_one [simp]: "-1 \<le> cos x"
  1500   using abs_cos_le_one [of x] unfolding abs_le_iff by simp
  1501 
  1502 lemma cos_le_one [simp]: "cos x \<le> 1"
  1503   using abs_cos_le_one [of x] unfolding abs_le_iff by simp
  1504 
  1505 lemma DERIV_fun_pow: "DERIV g x :> m ==>
  1506       DERIV (%x. (g x) ^ n) x :> real n * (g x) ^ (n - 1) * m"
  1507   by (auto intro!: DERIV_intros)
  1508 
  1509 lemma DERIV_fun_exp:
  1510      "DERIV g x :> m ==> DERIV (%x. exp(g x)) x :> exp(g x) * m"
  1511   by (auto intro!: DERIV_intros)
  1512 
  1513 lemma DERIV_fun_sin:
  1514      "DERIV g x :> m ==> DERIV (%x. sin(g x)) x :> cos(g x) * m"
  1515   by (auto intro!: DERIV_intros)
  1516 
  1517 lemma DERIV_fun_cos:
  1518      "DERIV g x :> m ==> DERIV (%x. cos(g x)) x :> -sin(g x) * m"
  1519   by (auto intro!: DERIV_intros)
  1520 
  1521 lemma sin_cos_add_lemma:
  1522      "(sin (x + y) - (sin x * cos y + cos x * sin y)) ^ 2 +
  1523       (cos (x + y) - (cos x * cos y - sin x * sin y)) ^ 2 = 0"
  1524   (is "?f x = 0")
  1525 proof -
  1526   have "\<forall>x. DERIV (\<lambda>x. ?f x) x :> 0"
  1527     by (auto intro!: DERIV_intros simp add: algebra_simps)
  1528   hence "?f x = ?f 0"
  1529     by (rule DERIV_isconst_all)
  1530   thus ?thesis by simp
  1531 qed
  1532 
  1533 lemma sin_add: "sin (x + y) = sin x * cos y + cos x * sin y"
  1534   using sin_cos_add_lemma unfolding realpow_two_sum_zero_iff by simp
  1535 
  1536 lemma cos_add: "cos (x + y) = cos x * cos y - sin x * sin y"
  1537   using sin_cos_add_lemma unfolding realpow_two_sum_zero_iff by simp
  1538 
  1539 lemma sin_cos_minus_lemma:
  1540   "(sin(-x) + sin(x))\<twosuperior> + (cos(-x) - cos(x))\<twosuperior> = 0" (is "?f x = 0")
  1541 proof -
  1542   have "\<forall>x. DERIV (\<lambda>x. ?f x) x :> 0"
  1543     by (auto intro!: DERIV_intros simp add: algebra_simps)
  1544   hence "?f x = ?f 0"
  1545     by (rule DERIV_isconst_all)
  1546   thus ?thesis by simp
  1547 qed
  1548 
  1549 lemma sin_minus [simp]: "sin (-x) = -sin(x)"
  1550   using sin_cos_minus_lemma [where x=x] by simp
  1551 
  1552 lemma cos_minus [simp]: "cos (-x) = cos(x)"
  1553   using sin_cos_minus_lemma [where x=x] by simp
  1554 
  1555 lemma sin_diff: "sin (x - y) = sin x * cos y - cos x * sin y"
  1556   by (simp add: diff_minus sin_add)
  1557 
  1558 lemma sin_diff2: "sin (x - y) = cos y * sin x - sin y * cos x"
  1559   by (simp add: sin_diff mult_commute)
  1560 
  1561 lemma cos_diff: "cos (x - y) = cos x * cos y + sin x * sin y"
  1562   by (simp add: diff_minus cos_add)
  1563 
  1564 lemma cos_diff2: "cos (x - y) = cos y * cos x + sin y * sin x"
  1565   by (simp add: cos_diff mult_commute)
  1566 
  1567 lemma sin_double [simp]: "sin(2 * x) = 2* sin x * cos x"
  1568   using sin_add [where x=x and y=x] by simp
  1569 
  1570 lemma cos_double: "cos(2* x) = ((cos x)\<twosuperior>) - ((sin x)\<twosuperior>)"
  1571   using cos_add [where x=x and y=x]
  1572   by (simp add: power2_eq_square)
  1573 
  1574 
  1575 subsection {* The Constant Pi *}
  1576 
  1577 definition pi :: "real" where
  1578   "pi = 2 * (THE x. 0 \<le> (x::real) & x \<le> 2 & cos x = 0)"
  1579 
  1580 text{*Show that there's a least positive @{term x} with @{term "cos(x) = 0"};
  1581    hence define pi.*}
  1582 
  1583 lemma sin_paired:
  1584      "(%n. -1 ^ n /(real (fact (2 * n + 1))) * x ^ (2 * n + 1))
  1585       sums  sin x"
  1586 proof -
  1587   have "(\<lambda>n. \<Sum>k = n * 2..<n * 2 + 2. sin_coeff k * x ^ k) sums sin x"
  1588     by (rule sin_converges [THEN sums_group], simp)
  1589   thus ?thesis unfolding One_nat_def sin_coeff_def by (simp add: mult_ac)
  1590 qed
  1591 
  1592 lemma sin_gt_zero:
  1593   assumes "0 < x" and "x < 2" shows "0 < sin x"
  1594 proof -
  1595   let ?f = "\<lambda>n. \<Sum>k = n*2..<n*2+2. -1 ^ k / real (fact (2*k+1)) * x^(2*k+1)"
  1596   have pos: "\<forall>n. 0 < ?f n"
  1597   proof
  1598     fix n :: nat
  1599     let ?k2 = "real (Suc (Suc (4 * n)))"
  1600     let ?k3 = "real (Suc (Suc (Suc (4 * n))))"
  1601     have "x * x < ?k2 * ?k3"
  1602       using assms by (intro mult_strict_mono', simp_all)
  1603     hence "x * x * x * x ^ (n * 4) < ?k2 * ?k3 * x * x ^ (n * 4)"
  1604       by (intro mult_strict_right_mono zero_less_power `0 < x`)
  1605     thus "0 < ?f n"
  1606       by (simp del: mult_Suc,
  1607         simp add: less_divide_eq mult_pos_pos field_simps del: mult_Suc)
  1608   qed
  1609   have sums: "?f sums sin x"
  1610     by (rule sin_paired [THEN sums_group], simp)
  1611   show "0 < sin x"
  1612     unfolding sums_unique [OF sums]
  1613     using sums_summable [OF sums] pos
  1614     by (rule suminf_gt_zero)
  1615 qed
  1616 
  1617 lemma cos_double_less_one: "[| 0 < x; x < 2 |] ==> cos (2 * x) < 1"
  1618 apply (cut_tac x = x in sin_gt_zero)
  1619 apply (auto simp add: cos_squared_eq cos_double)
  1620 done
  1621 
  1622 lemma cos_paired:
  1623      "(%n. -1 ^ n /(real (fact (2 * n))) * x ^ (2 * n)) sums cos x"
  1624 proof -
  1625   have "(\<lambda>n. \<Sum>k = n * 2..<n * 2 + 2. cos_coeff k * x ^ k) sums cos x"
  1626     by (rule cos_converges [THEN sums_group], simp)
  1627   thus ?thesis unfolding cos_coeff_def by (simp add: mult_ac)
  1628 qed
  1629 
  1630 lemma real_mult_inverse_cancel:
  1631      "[|(0::real) < x; 0 < x1; x1 * y < x * u |]
  1632       ==> inverse x * y < inverse x1 * u"
  1633 apply (rule_tac c=x in mult_less_imp_less_left)
  1634 apply (auto simp add: mult_assoc [symmetric])
  1635 apply (simp (no_asm) add: mult_ac)
  1636 apply (rule_tac c=x1 in mult_less_imp_less_right)
  1637 apply (auto simp add: mult_ac)
  1638 done
  1639 
  1640 lemma real_mult_inverse_cancel2:
  1641      "[|(0::real) < x;0 < x1; x1 * y < x * u |] ==> y * inverse x < u * inverse x1"
  1642 apply (auto dest: real_mult_inverse_cancel simp add: mult_ac)
  1643 done
  1644 
  1645 lemma realpow_num_eq_if:
  1646   fixes m :: "'a::power"
  1647   shows "m ^ n = (if n=0 then 1 else m * m ^ (n - 1))"
  1648 by (cases n, auto)
  1649 
  1650 lemma cos_two_less_zero [simp]: "cos (2) < 0"
  1651 apply (cut_tac x = 2 in cos_paired)
  1652 apply (drule sums_minus)
  1653 apply (rule neg_less_iff_less [THEN iffD1])
  1654 apply (frule sums_unique, auto)
  1655 apply (rule_tac y =
  1656  "\<Sum>n=0..< Suc(Suc(Suc 0)). - (-1 ^ n / (real(fact (2*n))) * 2 ^ (2*n))"
  1657        in order_less_trans)
  1658 apply (simp (no_asm) add: fact_num_eq_if_nat realpow_num_eq_if del: fact_Suc)
  1659 apply (simp (no_asm) add: mult_assoc del: setsum_op_ivl_Suc)
  1660 apply (rule sumr_pos_lt_pair)
  1661 apply (erule sums_summable, safe)
  1662 unfolding One_nat_def
  1663 apply (simp (no_asm) add: divide_inverse real_0_less_add_iff mult_assoc [symmetric]
  1664             del: fact_Suc)
  1665 apply (simp add: inverse_eq_divide less_divide_eq del: fact_Suc)
  1666 apply (subst fact_Suc [of "Suc (Suc (Suc (Suc (Suc (Suc (Suc (4 * d)))))))"])
  1667 apply (simp only: real_of_nat_mult)
  1668 apply (rule mult_strict_mono, force)
  1669   apply (rule_tac [3] real_of_nat_ge_zero)
  1670  prefer 2 apply force
  1671 apply (rule real_of_nat_less_iff [THEN iffD2])
  1672 apply (rule fact_less_mono_nat, auto)
  1673 done
  1674 
  1675 lemmas cos_two_neq_zero [simp] = cos_two_less_zero [THEN less_imp_neq]
  1676 lemmas cos_two_le_zero [simp] = cos_two_less_zero [THEN order_less_imp_le]
  1677 
  1678 lemma cos_is_zero: "EX! x. 0 \<le> x & x \<le> 2 & cos x = 0"
  1679 proof (rule ex_ex1I)
  1680   show "\<exists>x. 0 \<le> x & x \<le> 2 & cos x = 0"
  1681     by (rule IVT2, simp_all)
  1682 next
  1683   fix x y
  1684   assume x: "0 \<le> x \<and> x \<le> 2 \<and> cos x = 0"
  1685   assume y: "0 \<le> y \<and> y \<le> 2 \<and> cos y = 0"
  1686   have [simp]: "\<forall>x. cos differentiable x"
  1687     unfolding differentiable_def by (auto intro: DERIV_cos)
  1688   from x y show "x = y"
  1689     apply (cut_tac less_linear [of x y], auto)
  1690     apply (drule_tac f = cos in Rolle)
  1691     apply (drule_tac [5] f = cos in Rolle)
  1692     apply (auto dest!: DERIV_cos [THEN DERIV_unique])
  1693     apply (metis order_less_le_trans less_le sin_gt_zero)
  1694     apply (metis order_less_le_trans less_le sin_gt_zero)
  1695     done
  1696 qed
  1697 
  1698 lemma pi_half: "pi/2 = (THE x. 0 \<le> x & x \<le> 2 & cos x = 0)"
  1699 by (simp add: pi_def)
  1700 
  1701 lemma cos_pi_half [simp]: "cos (pi / 2) = 0"
  1702 by (simp add: pi_half cos_is_zero [THEN theI'])
  1703 
  1704 lemma pi_half_gt_zero [simp]: "0 < pi / 2"
  1705 apply (rule order_le_neq_trans)
  1706 apply (simp add: pi_half cos_is_zero [THEN theI'])
  1707 apply (rule notI, drule arg_cong [where f=cos], simp)
  1708 done
  1709 
  1710 lemmas pi_half_neq_zero [simp] = pi_half_gt_zero [THEN less_imp_neq, symmetric]
  1711 lemmas pi_half_ge_zero [simp] = pi_half_gt_zero [THEN order_less_imp_le]
  1712 
  1713 lemma pi_half_less_two [simp]: "pi / 2 < 2"
  1714 apply (rule order_le_neq_trans)
  1715 apply (simp add: pi_half cos_is_zero [THEN theI'])
  1716 apply (rule notI, drule arg_cong [where f=cos], simp)
  1717 done
  1718 
  1719 lemmas pi_half_neq_two [simp] = pi_half_less_two [THEN less_imp_neq]
  1720 lemmas pi_half_le_two [simp] =  pi_half_less_two [THEN order_less_imp_le]
  1721 
  1722 lemma pi_gt_zero [simp]: "0 < pi"
  1723 by (insert pi_half_gt_zero, simp)
  1724 
  1725 lemma pi_ge_zero [simp]: "0 \<le> pi"
  1726 by (rule pi_gt_zero [THEN order_less_imp_le])
  1727 
  1728 lemma pi_neq_zero [simp]: "pi \<noteq> 0"
  1729 by (rule pi_gt_zero [THEN less_imp_neq, THEN not_sym])
  1730 
  1731 lemma pi_not_less_zero [simp]: "\<not> pi < 0"
  1732 by (simp add: linorder_not_less)
  1733 
  1734 lemma minus_pi_half_less_zero: "-(pi/2) < 0"
  1735 by simp
  1736 
  1737 lemma m2pi_less_pi: "- (2 * pi) < pi"
  1738 by simp
  1739 
  1740 lemma sin_pi_half [simp]: "sin(pi/2) = 1"
  1741 apply (cut_tac x = "pi/2" in sin_cos_squared_add2)
  1742 apply (cut_tac sin_gt_zero [OF pi_half_gt_zero pi_half_less_two])
  1743 apply (simp add: power2_eq_1_iff)
  1744 done
  1745 
  1746 lemma cos_pi [simp]: "cos pi = -1"
  1747 by (cut_tac x = "pi/2" and y = "pi/2" in cos_add, simp)
  1748 
  1749 lemma sin_pi [simp]: "sin pi = 0"
  1750 by (cut_tac x = "pi/2" and y = "pi/2" in sin_add, simp)
  1751 
  1752 lemma sin_cos_eq: "sin x = cos (pi/2 - x)"
  1753 by (simp add: cos_diff)
  1754 
  1755 lemma minus_sin_cos_eq: "-sin x = cos (x + pi/2)"
  1756 by (simp add: cos_add)
  1757 
  1758 lemma cos_sin_eq: "cos x = sin (pi/2 - x)"
  1759 by (simp add: sin_diff)
  1760 
  1761 lemma sin_periodic_pi [simp]: "sin (x + pi) = - sin x"
  1762 by (simp add: sin_add)
  1763 
  1764 lemma sin_periodic_pi2 [simp]: "sin (pi + x) = - sin x"
  1765 by (simp add: sin_add)
  1766 
  1767 lemma cos_periodic_pi [simp]: "cos (x + pi) = - cos x"
  1768 by (simp add: cos_add)
  1769 
  1770 lemma sin_periodic [simp]: "sin (x + 2*pi) = sin x"
  1771 by (simp add: sin_add cos_double)
  1772 
  1773 lemma cos_periodic [simp]: "cos (x + 2*pi) = cos x"
  1774 by (simp add: cos_add cos_double)
  1775 
  1776 lemma cos_npi [simp]: "cos (real n * pi) = -1 ^ n"
  1777 apply (induct "n")
  1778 apply (auto simp add: real_of_nat_Suc distrib_right)
  1779 done
  1780 
  1781 lemma cos_npi2 [simp]: "cos (pi * real n) = -1 ^ n"
  1782 proof -
  1783   have "cos (pi * real n) = cos (real n * pi)" by (simp only: mult_commute)
  1784   also have "... = -1 ^ n" by (rule cos_npi)
  1785   finally show ?thesis .
  1786 qed
  1787 
  1788 lemma sin_npi [simp]: "sin (real (n::nat) * pi) = 0"
  1789 apply (induct "n")
  1790 apply (auto simp add: real_of_nat_Suc distrib_right)
  1791 done
  1792 
  1793 lemma sin_npi2 [simp]: "sin (pi * real (n::nat)) = 0"
  1794 by (simp add: mult_commute [of pi])
  1795 
  1796 lemma cos_two_pi [simp]: "cos (2 * pi) = 1"
  1797 by (simp add: cos_double)
  1798 
  1799 lemma sin_two_pi [simp]: "sin (2 * pi) = 0"
  1800 by simp
  1801 
  1802 lemma sin_gt_zero2: "[| 0 < x; x < pi/2 |] ==> 0 < sin x"
  1803 apply (rule sin_gt_zero, assumption)
  1804 apply (rule order_less_trans, assumption)
  1805 apply (rule pi_half_less_two)
  1806 done
  1807 
  1808 lemma sin_less_zero:
  1809   assumes lb: "- pi/2 < x" and "x < 0" shows "sin x < 0"
  1810 proof -
  1811   have "0 < sin (- x)" using assms by (simp only: sin_gt_zero2)
  1812   thus ?thesis by simp
  1813 qed
  1814 
  1815 lemma pi_less_4: "pi < 4"
  1816 by (cut_tac pi_half_less_two, auto)
  1817 
  1818 lemma cos_gt_zero: "[| 0 < x; x < pi/2 |] ==> 0 < cos x"
  1819 apply (cut_tac pi_less_4)
  1820 apply (cut_tac f = cos and a = 0 and b = x and y = 0 in IVT2_objl, safe, simp_all)
  1821 apply (cut_tac cos_is_zero, safe)
  1822 apply (rename_tac y z)
  1823 apply (drule_tac x = y in spec)
  1824 apply (drule_tac x = "pi/2" in spec, simp)
  1825 done
  1826 
  1827 lemma cos_gt_zero_pi: "[| -(pi/2) < x; x < pi/2 |] ==> 0 < cos x"
  1828 apply (rule_tac x = x and y = 0 in linorder_cases)
  1829 apply (rule cos_minus [THEN subst])
  1830 apply (rule cos_gt_zero)
  1831 apply (auto intro: cos_gt_zero)
  1832 done
  1833 
  1834 lemma cos_ge_zero: "[| -(pi/2) \<le> x; x \<le> pi/2 |] ==> 0 \<le> cos x"
  1835 apply (auto simp add: order_le_less cos_gt_zero_pi)
  1836 apply (subgoal_tac "x = pi/2", auto)
  1837 done
  1838 
  1839 lemma sin_gt_zero_pi: "[| 0 < x; x < pi  |] ==> 0 < sin x"
  1840 by (simp add: sin_cos_eq cos_gt_zero_pi)
  1841 
  1842 lemma pi_ge_two: "2 \<le> pi"
  1843 proof (rule ccontr)
  1844   assume "\<not> 2 \<le> pi" hence "pi < 2" by auto
  1845   have "\<exists>y > pi. y < 2 \<and> y < 2 * pi"
  1846   proof (cases "2 < 2 * pi")
  1847     case True with dense[OF `pi < 2`] show ?thesis by auto
  1848   next
  1849     case False have "pi < 2 * pi" by auto
  1850     from dense[OF this] and False show ?thesis by auto
  1851   qed
  1852   then obtain y where "pi < y" and "y < 2" and "y < 2 * pi" by blast
  1853   hence "0 < sin y" using sin_gt_zero by auto
  1854   moreover
  1855   have "sin y < 0" using sin_gt_zero_pi[of "y - pi"] `pi < y` and `y < 2 * pi` sin_periodic_pi[of "y - pi"] by auto
  1856   ultimately show False by auto
  1857 qed
  1858 
  1859 lemma sin_ge_zero: "[| 0 \<le> x; x \<le> pi |] ==> 0 \<le> sin x"
  1860 by (auto simp add: order_le_less sin_gt_zero_pi)
  1861 
  1862 text {* FIXME: This proof is almost identical to lemma @{text cos_is_zero}.
  1863   It should be possible to factor out some of the common parts. *}
  1864 
  1865 lemma cos_total: "[| -1 \<le> y; y \<le> 1 |] ==> EX! x. 0 \<le> x & x \<le> pi & (cos x = y)"
  1866 proof (rule ex_ex1I)
  1867   assume y: "-1 \<le> y" "y \<le> 1"
  1868   show "\<exists>x. 0 \<le> x & x \<le> pi & cos x = y"
  1869     by (rule IVT2, simp_all add: y)
  1870 next
  1871   fix a b
  1872   assume a: "0 \<le> a \<and> a \<le> pi \<and> cos a = y"
  1873   assume b: "0 \<le> b \<and> b \<le> pi \<and> cos b = y"
  1874   have [simp]: "\<forall>x. cos differentiable x"
  1875     unfolding differentiable_def by (auto intro: DERIV_cos)
  1876   from a b show "a = b"
  1877     apply (cut_tac less_linear [of a b], auto)
  1878     apply (drule_tac f = cos in Rolle)
  1879     apply (drule_tac [5] f = cos in Rolle)
  1880     apply (auto dest!: DERIV_cos [THEN DERIV_unique])
  1881     apply (metis order_less_le_trans less_le sin_gt_zero_pi)
  1882     apply (metis order_less_le_trans less_le sin_gt_zero_pi)
  1883     done
  1884 qed
  1885 
  1886 lemma sin_total:
  1887      "[| -1 \<le> y; y \<le> 1 |] ==> EX! x. -(pi/2) \<le> x & x \<le> pi/2 & (sin x = y)"
  1888 apply (rule ccontr)
  1889 apply (subgoal_tac "\<forall>x. (- (pi/2) \<le> x & x \<le> pi/2 & (sin x = y)) = (0 \<le> (x + pi/2) & (x + pi/2) \<le> pi & (cos (x + pi/2) = -y))")
  1890 apply (erule contrapos_np)
  1891 apply simp
  1892 apply (cut_tac y="-y" in cos_total, simp) apply simp
  1893 apply (erule ex1E)
  1894 apply (rule_tac a = "x - (pi/2)" in ex1I)
  1895 apply (simp (no_asm) add: add_assoc)
  1896 apply (rotate_tac 3)
  1897 apply (drule_tac x = "xa + pi/2" in spec, safe, simp_all add: cos_add)
  1898 done
  1899 
  1900 lemma reals_Archimedean4:
  1901      "[| 0 < y; 0 \<le> x |] ==> \<exists>n. real n * y \<le> x & x < real (Suc n) * y"
  1902 apply (auto dest!: reals_Archimedean3)
  1903 apply (drule_tac x = x in spec, clarify)
  1904 apply (subgoal_tac "x < real(LEAST m::nat. x < real m * y) * y")
  1905  prefer 2 apply (erule LeastI)
  1906 apply (case_tac "LEAST m::nat. x < real m * y", simp)
  1907 apply (subgoal_tac "~ x < real nat * y")
  1908  prefer 2 apply (rule not_less_Least, simp, force)
  1909 done
  1910 
  1911 (* Pre Isabelle99-2 proof was simpler- numerals arithmetic
  1912    now causes some unwanted re-arrangements of literals!   *)
  1913 lemma cos_zero_lemma:
  1914      "[| 0 \<le> x; cos x = 0 |] ==>
  1915       \<exists>n::nat. ~even n & x = real n * (pi/2)"
  1916 apply (drule pi_gt_zero [THEN reals_Archimedean4], safe)
  1917 apply (subgoal_tac "0 \<le> x - real n * pi &
  1918                     (x - real n * pi) \<le> pi & (cos (x - real n * pi) = 0) ")
  1919 apply (auto simp add: algebra_simps real_of_nat_Suc)
  1920  prefer 2 apply (simp add: cos_diff)
  1921 apply (simp add: cos_diff)
  1922 apply (subgoal_tac "EX! x. 0 \<le> x & x \<le> pi & cos x = 0")
  1923 apply (rule_tac [2] cos_total, safe)
  1924 apply (drule_tac x = "x - real n * pi" in spec)
  1925 apply (drule_tac x = "pi/2" in spec)
  1926 apply (simp add: cos_diff)
  1927 apply (rule_tac x = "Suc (2 * n)" in exI)
  1928 apply (simp add: real_of_nat_Suc algebra_simps, auto)
  1929 done
  1930 
  1931 lemma sin_zero_lemma:
  1932      "[| 0 \<le> x; sin x = 0 |] ==>
  1933       \<exists>n::nat. even n & x = real n * (pi/2)"
  1934 apply (subgoal_tac "\<exists>n::nat. ~ even n & x + pi/2 = real n * (pi/2) ")
  1935  apply (clarify, rule_tac x = "n - 1" in exI)
  1936  apply (force simp add: odd_Suc_mult_two_ex real_of_nat_Suc distrib_right)
  1937 apply (rule cos_zero_lemma)
  1938 apply (simp_all add: cos_add)
  1939 done
  1940 
  1941 
  1942 lemma cos_zero_iff:
  1943      "(cos x = 0) =
  1944       ((\<exists>n::nat. ~even n & (x = real n * (pi/2))) |
  1945        (\<exists>n::nat. ~even n & (x = -(real n * (pi/2)))))"
  1946 apply (rule iffI)
  1947 apply (cut_tac linorder_linear [of 0 x], safe)
  1948 apply (drule cos_zero_lemma, assumption+)
  1949 apply (cut_tac x="-x" in cos_zero_lemma, simp, simp)
  1950 apply (force simp add: minus_equation_iff [of x])
  1951 apply (auto simp only: odd_Suc_mult_two_ex real_of_nat_Suc distrib_right)
  1952 apply (auto simp add: cos_add)
  1953 done
  1954 
  1955 (* ditto: but to a lesser extent *)
  1956 lemma sin_zero_iff:
  1957      "(sin x = 0) =
  1958       ((\<exists>n::nat. even n & (x = real n * (pi/2))) |
  1959        (\<exists>n::nat. even n & (x = -(real n * (pi/2)))))"
  1960 apply (rule iffI)
  1961 apply (cut_tac linorder_linear [of 0 x], safe)
  1962 apply (drule sin_zero_lemma, assumption+)
  1963 apply (cut_tac x="-x" in sin_zero_lemma, simp, simp, safe)
  1964 apply (force simp add: minus_equation_iff [of x])
  1965 apply (auto simp add: even_mult_two_ex)
  1966 done
  1967 
  1968 lemma cos_monotone_0_pi: assumes "0 \<le> y" and "y < x" and "x \<le> pi"
  1969   shows "cos x < cos y"
  1970 proof -
  1971   have "- (x - y) < 0" using assms by auto
  1972 
  1973   from MVT2[OF `y < x` DERIV_cos[THEN impI, THEN allI]]
  1974   obtain z where "y < z" and "z < x" and cos_diff: "cos x - cos y = (x - y) * - sin z" by auto
  1975   hence "0 < z" and "z < pi" using assms by auto
  1976   hence "0 < sin z" using sin_gt_zero_pi by auto
  1977   hence "cos x - cos y < 0" unfolding cos_diff minus_mult_commute[symmetric] using `- (x - y) < 0` by (rule mult_pos_neg2)
  1978   thus ?thesis by auto
  1979 qed
  1980 
  1981 lemma cos_monotone_0_pi': assumes "0 \<le> y" and "y \<le> x" and "x \<le> pi" shows "cos x \<le> cos y"
  1982 proof (cases "y < x")
  1983   case True show ?thesis using cos_monotone_0_pi[OF `0 \<le> y` True `x \<le> pi`] by auto
  1984 next
  1985   case False hence "y = x" using `y \<le> x` by auto
  1986   thus ?thesis by auto
  1987 qed
  1988 
  1989 lemma cos_monotone_minus_pi_0: assumes "-pi \<le> y" and "y < x" and "x \<le> 0"
  1990   shows "cos y < cos x"
  1991 proof -
  1992   have "0 \<le> -x" and "-x < -y" and "-y \<le> pi" using assms by auto
  1993   from cos_monotone_0_pi[OF this]
  1994   show ?thesis unfolding cos_minus .
  1995 qed
  1996 
  1997 lemma cos_monotone_minus_pi_0': assumes "-pi \<le> y" and "y \<le> x" and "x \<le> 0" shows "cos y \<le> cos x"
  1998 proof (cases "y < x")
  1999   case True show ?thesis using cos_monotone_minus_pi_0[OF `-pi \<le> y` True `x \<le> 0`] by auto
  2000 next
  2001   case False hence "y = x" using `y \<le> x` by auto
  2002   thus ?thesis by auto
  2003 qed
  2004 
  2005 lemma sin_monotone_2pi': assumes "- (pi / 2) \<le> y" and "y \<le> x" and "x \<le> pi / 2" shows "sin y \<le> sin x"
  2006 proof -
  2007   have "0 \<le> y + pi / 2" and "y + pi / 2 \<le> x + pi / 2" and "x + pi /2 \<le> pi"
  2008     using pi_ge_two and assms by auto
  2009   from cos_monotone_0_pi'[OF this] show ?thesis unfolding minus_sin_cos_eq[symmetric] by auto
  2010 qed
  2011 
  2012 subsection {* Tangent *}
  2013 
  2014 definition tan :: "real \<Rightarrow> real" where
  2015   "tan = (\<lambda>x. sin x / cos x)"
  2016 
  2017 lemma tan_zero [simp]: "tan 0 = 0"
  2018   by (simp add: tan_def)
  2019 
  2020 lemma tan_pi [simp]: "tan pi = 0"
  2021   by (simp add: tan_def)
  2022 
  2023 lemma tan_npi [simp]: "tan (real (n::nat) * pi) = 0"
  2024   by (simp add: tan_def)
  2025 
  2026 lemma tan_minus [simp]: "tan (-x) = - tan x"
  2027   by (simp add: tan_def)
  2028 
  2029 lemma tan_periodic [simp]: "tan (x + 2*pi) = tan x"
  2030   by (simp add: tan_def)
  2031 
  2032 lemma lemma_tan_add1:
  2033   "\<lbrakk>cos x \<noteq> 0; cos y \<noteq> 0\<rbrakk> \<Longrightarrow> 1 - tan x * tan y = cos (x + y)/(cos x * cos y)"
  2034   by (simp add: tan_def cos_add field_simps)
  2035 
  2036 lemma add_tan_eq:
  2037   "\<lbrakk>cos x \<noteq> 0; cos y \<noteq> 0\<rbrakk> \<Longrightarrow> tan x + tan y = sin(x + y)/(cos x * cos y)"
  2038   by (simp add: tan_def sin_add field_simps)
  2039 
  2040 lemma tan_add:
  2041      "[| cos x \<noteq> 0; cos y \<noteq> 0; cos (x + y) \<noteq> 0 |]
  2042       ==> tan(x + y) = (tan(x) + tan(y))/(1 - tan(x) * tan(y))"
  2043   by (simp add: add_tan_eq lemma_tan_add1, simp add: tan_def)
  2044 
  2045 lemma tan_double:
  2046      "[| cos x \<noteq> 0; cos (2 * x) \<noteq> 0 |]
  2047       ==> tan (2 * x) = (2 * tan x)/(1 - (tan(x) ^ 2))"
  2048   using tan_add [of x x] by (simp add: power2_eq_square)
  2049 
  2050 lemma tan_gt_zero: "[| 0 < x; x < pi/2 |] ==> 0 < tan x"
  2051 by (simp add: tan_def zero_less_divide_iff sin_gt_zero2 cos_gt_zero_pi)
  2052 
  2053 lemma tan_less_zero:
  2054   assumes lb: "- pi/2 < x" and "x < 0" shows "tan x < 0"
  2055 proof -
  2056   have "0 < tan (- x)" using assms by (simp only: tan_gt_zero)
  2057   thus ?thesis by simp
  2058 qed
  2059 
  2060 lemma tan_half: "tan x = sin (2 * x) / (cos (2 * x) + 1)"
  2061   unfolding tan_def sin_double cos_double sin_squared_eq
  2062   by (simp add: power2_eq_square)
  2063 
  2064 lemma DERIV_tan [simp]: "cos x \<noteq> 0 \<Longrightarrow> DERIV tan x :> inverse ((cos x)\<twosuperior>)"
  2065   unfolding tan_def
  2066   by (auto intro!: DERIV_intros, simp add: divide_inverse power2_eq_square)
  2067 
  2068 lemma isCont_tan: "cos x \<noteq> 0 \<Longrightarrow> isCont tan x"
  2069   by (rule DERIV_tan [THEN DERIV_isCont])
  2070 
  2071 lemma isCont_tan' [simp]:
  2072   "\<lbrakk>isCont f a; cos (f a) \<noteq> 0\<rbrakk> \<Longrightarrow> isCont (\<lambda>x. tan (f x)) a"
  2073   by (rule isCont_o2 [OF _ isCont_tan])
  2074 
  2075 lemma tendsto_tan [tendsto_intros]:
  2076   "\<lbrakk>(f ---> a) F; cos a \<noteq> 0\<rbrakk> \<Longrightarrow> ((\<lambda>x. tan (f x)) ---> tan a) F"
  2077   by (rule isCont_tendsto_compose [OF isCont_tan])
  2078 
  2079 lemma LIM_cos_div_sin: "(%x. cos(x)/sin(x)) -- pi/2 --> 0"
  2080   by (rule LIM_cong_limit, (rule tendsto_intros)+, simp_all)
  2081 
  2082 lemma lemma_tan_total: "0 < y ==> \<exists>x. 0 < x & x < pi/2 & y < tan x"
  2083 apply (cut_tac LIM_cos_div_sin)
  2084 apply (simp only: LIM_eq)
  2085 apply (drule_tac x = "inverse y" in spec, safe, force)
  2086 apply (drule_tac ?d1.0 = s in pi_half_gt_zero [THEN [2] real_lbound_gt_zero], safe)
  2087 apply (rule_tac x = "(pi/2) - e" in exI)
  2088 apply (simp (no_asm_simp))
  2089 apply (drule_tac x = "(pi/2) - e" in spec)
  2090 apply (auto simp add: tan_def sin_diff cos_diff)
  2091 apply (rule inverse_less_iff_less [THEN iffD1])
  2092 apply (auto simp add: divide_inverse)
  2093 apply (rule mult_pos_pos)
  2094 apply (subgoal_tac [3] "0 < sin e & 0 < cos e")
  2095 apply (auto intro: cos_gt_zero sin_gt_zero2 simp add: mult_commute)
  2096 done
  2097 
  2098 lemma tan_total_pos: "0 \<le> y ==> \<exists>x. 0 \<le> x & x < pi/2 & tan x = y"
  2099 apply (frule order_le_imp_less_or_eq, safe)
  2100  prefer 2 apply force
  2101 apply (drule lemma_tan_total, safe)
  2102 apply (cut_tac f = tan and a = 0 and b = x and y = y in IVT_objl)
  2103 apply (auto intro!: DERIV_tan [THEN DERIV_isCont])
  2104 apply (drule_tac y = xa in order_le_imp_less_or_eq)
  2105 apply (auto dest: cos_gt_zero)
  2106 done
  2107 
  2108 lemma lemma_tan_total1: "\<exists>x. -(pi/2) < x & x < (pi/2) & tan x = y"
  2109 apply (cut_tac linorder_linear [of 0 y], safe)
  2110 apply (drule tan_total_pos)
  2111 apply (cut_tac [2] y="-y" in tan_total_pos, safe)
  2112 apply (rule_tac [3] x = "-x" in exI)
  2113 apply (auto del: exI intro!: exI)
  2114 done
  2115 
  2116 lemma tan_total: "EX! x. -(pi/2) < x & x < (pi/2) & tan x = y"
  2117 apply (cut_tac y = y in lemma_tan_total1, auto)
  2118 apply (cut_tac x = xa and y = y in linorder_less_linear, auto)
  2119 apply (subgoal_tac [2] "\<exists>z. y < z & z < xa & DERIV tan z :> 0")
  2120 apply (subgoal_tac "\<exists>z. xa < z & z < y & DERIV tan z :> 0")
  2121 apply (rule_tac [4] Rolle)
  2122 apply (rule_tac [2] Rolle)
  2123 apply (auto del: exI intro!: DERIV_tan DERIV_isCont exI
  2124             simp add: differentiable_def)
  2125 txt{*Now, simulate TRYALL*}
  2126 apply (rule_tac [!] DERIV_tan asm_rl)
  2127 apply (auto dest!: DERIV_unique [OF _ DERIV_tan]
  2128             simp add: cos_gt_zero_pi [THEN less_imp_neq, THEN not_sym])
  2129 done
  2130 
  2131 lemma tan_monotone: assumes "- (pi / 2) < y" and "y < x" and "x < pi / 2"
  2132   shows "tan y < tan x"
  2133 proof -
  2134   have "\<forall> x'. y \<le> x' \<and> x' \<le> x \<longrightarrow> DERIV tan x' :> inverse (cos x'^2)"
  2135   proof (rule allI, rule impI)
  2136     fix x' :: real assume "y \<le> x' \<and> x' \<le> x"
  2137     hence "-(pi/2) < x'" and "x' < pi/2" using assms by auto
  2138     from cos_gt_zero_pi[OF this]
  2139     have "cos x' \<noteq> 0" by auto
  2140     thus "DERIV tan x' :> inverse (cos x'^2)" by (rule DERIV_tan)
  2141   qed
  2142   from MVT2[OF `y < x` this]
  2143   obtain z where "y < z" and "z < x" and tan_diff: "tan x - tan y = (x - y) * inverse ((cos z)\<twosuperior>)" by auto
  2144   hence "- (pi / 2) < z" and "z < pi / 2" using assms by auto
  2145   hence "0 < cos z" using cos_gt_zero_pi by auto
  2146   hence inv_pos: "0 < inverse ((cos z)\<twosuperior>)" by auto
  2147   have "0 < x - y" using `y < x` by auto
  2148   from mult_pos_pos [OF this inv_pos]
  2149   have "0 < tan x - tan y" unfolding tan_diff by auto
  2150   thus ?thesis by auto
  2151 qed
  2152 
  2153 lemma tan_monotone': assumes "- (pi / 2) < y" and "y < pi / 2" and "- (pi / 2) < x" and "x < pi / 2"
  2154   shows "(y < x) = (tan y < tan x)"
  2155 proof
  2156   assume "y < x" thus "tan y < tan x" using tan_monotone and `- (pi / 2) < y` and `x < pi / 2` by auto
  2157 next
  2158   assume "tan y < tan x"
  2159   show "y < x"
  2160   proof (rule ccontr)
  2161     assume "\<not> y < x" hence "x \<le> y" by auto
  2162     hence "tan x \<le> tan y"
  2163     proof (cases "x = y")
  2164       case True thus ?thesis by auto
  2165     next
  2166       case False hence "x < y" using `x \<le> y` by auto
  2167       from tan_monotone[OF `- (pi/2) < x` this `y < pi / 2`] show ?thesis by auto
  2168     qed
  2169     thus False using `tan y < tan x` by auto
  2170   qed
  2171 qed
  2172 
  2173 lemma tan_inverse: "1 / (tan y) = tan (pi / 2 - y)" unfolding tan_def sin_cos_eq[of y] cos_sin_eq[of y] by auto
  2174 
  2175 lemma tan_periodic_pi[simp]: "tan (x + pi) = tan x"
  2176   by (simp add: tan_def)
  2177 
  2178 lemma tan_periodic_nat[simp]: fixes n :: nat shows "tan (x + real n * pi) = tan x"
  2179 proof (induct n arbitrary: x)
  2180   case (Suc n)
  2181   have split_pi_off: "x + real (Suc n) * pi = (x + real n * pi) + pi" unfolding Suc_eq_plus1 real_of_nat_add real_of_one distrib_right by auto
  2182   show ?case unfolding split_pi_off using Suc by auto
  2183 qed auto
  2184 
  2185 lemma tan_periodic_int[simp]: fixes i :: int shows "tan (x + real i * pi) = tan x"
  2186 proof (cases "0 \<le> i")
  2187   case True hence i_nat: "real i = real (nat i)" by auto
  2188   show ?thesis unfolding i_nat by auto
  2189 next
  2190   case False hence i_nat: "real i = - real (nat (-i))" by auto
  2191   have "tan x = tan (x + real i * pi - real i * pi)" by auto
  2192   also have "\<dots> = tan (x + real i * pi)" unfolding i_nat mult_minus_left diff_minus_eq_add by (rule tan_periodic_nat)
  2193   finally show ?thesis by auto
  2194 qed
  2195 
  2196 lemma tan_periodic_n[simp]: "tan (x + numeral n * pi) = tan x"
  2197   using tan_periodic_int[of _ "numeral n" ] unfolding real_numeral .
  2198 
  2199 subsection {* Inverse Trigonometric Functions *}
  2200 
  2201 definition
  2202   arcsin :: "real => real" where
  2203   "arcsin y = (THE x. -(pi/2) \<le> x & x \<le> pi/2 & sin x = y)"
  2204 
  2205 definition
  2206   arccos :: "real => real" where
  2207   "arccos y = (THE x. 0 \<le> x & x \<le> pi & cos x = y)"
  2208 
  2209 definition
  2210   arctan :: "real => real" where
  2211   "arctan y = (THE x. -(pi/2) < x & x < pi/2 & tan x = y)"
  2212 
  2213 lemma arcsin:
  2214      "[| -1 \<le> y; y \<le> 1 |]
  2215       ==> -(pi/2) \<le> arcsin y &
  2216            arcsin y \<le> pi/2 & sin(arcsin y) = y"
  2217 unfolding arcsin_def by (rule theI' [OF sin_total])
  2218 
  2219 lemma arcsin_pi:
  2220      "[| -1 \<le> y; y \<le> 1 |]
  2221       ==> -(pi/2) \<le> arcsin y & arcsin y \<le> pi & sin(arcsin y) = y"
  2222 apply (drule (1) arcsin)
  2223 apply (force intro: order_trans)
  2224 done
  2225 
  2226 lemma sin_arcsin [simp]: "[| -1 \<le> y; y \<le> 1 |] ==> sin(arcsin y) = y"
  2227 by (blast dest: arcsin)
  2228 
  2229 lemma arcsin_bounded:
  2230      "[| -1 \<le> y; y \<le> 1 |] ==> -(pi/2) \<le> arcsin y & arcsin y \<le> pi/2"
  2231 by (blast dest: arcsin)
  2232 
  2233 lemma arcsin_lbound: "[| -1 \<le> y; y \<le> 1 |] ==> -(pi/2) \<le> arcsin y"
  2234 by (blast dest: arcsin)
  2235 
  2236 lemma arcsin_ubound: "[| -1 \<le> y; y \<le> 1 |] ==> arcsin y \<le> pi/2"
  2237 by (blast dest: arcsin)
  2238 
  2239 lemma arcsin_lt_bounded:
  2240      "[| -1 < y; y < 1 |] ==> -(pi/2) < arcsin y & arcsin y < pi/2"
  2241 apply (frule order_less_imp_le)
  2242 apply (frule_tac y = y in order_less_imp_le)
  2243 apply (frule arcsin_bounded)
  2244 apply (safe, simp)
  2245 apply (drule_tac y = "arcsin y" in order_le_imp_less_or_eq)
  2246 apply (drule_tac [2] y = "pi/2" in order_le_imp_less_or_eq, safe)
  2247 apply (drule_tac [!] f = sin in arg_cong, auto)
  2248 done
  2249 
  2250 lemma arcsin_sin: "[|-(pi/2) \<le> x; x \<le> pi/2 |] ==> arcsin(sin x) = x"
  2251 apply (unfold arcsin_def)
  2252 apply (rule the1_equality)
  2253 apply (rule sin_total, auto)
  2254 done
  2255 
  2256 lemma arccos:
  2257      "[| -1 \<le> y; y \<le> 1 |]
  2258       ==> 0 \<le> arccos y & arccos y \<le> pi & cos(arccos y) = y"
  2259 unfolding arccos_def by (rule theI' [OF cos_total])
  2260 
  2261 lemma cos_arccos [simp]: "[| -1 \<le> y; y \<le> 1 |] ==> cos(arccos y) = y"
  2262 by (blast dest: arccos)
  2263 
  2264 lemma arccos_bounded: "[| -1 \<le> y; y \<le> 1 |] ==> 0 \<le> arccos y & arccos y \<le> pi"
  2265 by (blast dest: arccos)
  2266 
  2267 lemma arccos_lbound: "[| -1 \<le> y; y \<le> 1 |] ==> 0 \<le> arccos y"
  2268 by (blast dest: arccos)
  2269 
  2270 lemma arccos_ubound: "[| -1 \<le> y; y \<le> 1 |] ==> arccos y \<le> pi"
  2271 by (blast dest: arccos)
  2272 
  2273 lemma arccos_lt_bounded:
  2274      "[| -1 < y; y < 1 |]
  2275       ==> 0 < arccos y & arccos y < pi"
  2276 apply (frule order_less_imp_le)
  2277 apply (frule_tac y = y in order_less_imp_le)
  2278 apply (frule arccos_bounded, auto)
  2279 apply (drule_tac y = "arccos y" in order_le_imp_less_or_eq)
  2280 apply (drule_tac [2] y = pi in order_le_imp_less_or_eq, auto)
  2281 apply (drule_tac [!] f = cos in arg_cong, auto)
  2282 done
  2283 
  2284 lemma arccos_cos: "[|0 \<le> x; x \<le> pi |] ==> arccos(cos x) = x"
  2285 apply (simp add: arccos_def)
  2286 apply (auto intro!: the1_equality cos_total)
  2287 done
  2288 
  2289 lemma arccos_cos2: "[|x \<le> 0; -pi \<le> x |] ==> arccos(cos x) = -x"
  2290 apply (simp add: arccos_def)
  2291 apply (auto intro!: the1_equality cos_total)
  2292 done
  2293 
  2294 lemma cos_arcsin: "\<lbrakk>-1 \<le> x; x \<le> 1\<rbrakk> \<Longrightarrow> cos (arcsin x) = sqrt (1 - x\<twosuperior>)"
  2295 apply (subgoal_tac "x\<twosuperior> \<le> 1")
  2296 apply (rule power2_eq_imp_eq)
  2297 apply (simp add: cos_squared_eq)
  2298 apply (rule cos_ge_zero)
  2299 apply (erule (1) arcsin_lbound)
  2300 apply (erule (1) arcsin_ubound)
  2301 apply simp
  2302 apply (subgoal_tac "\<bar>x\<bar>\<twosuperior> \<le> 1\<twosuperior>", simp)
  2303 apply (rule power_mono, simp, simp)
  2304 done
  2305 
  2306 lemma sin_arccos: "\<lbrakk>-1 \<le> x; x \<le> 1\<rbrakk> \<Longrightarrow> sin (arccos x) = sqrt (1 - x\<twosuperior>)"
  2307 apply (subgoal_tac "x\<twosuperior> \<le> 1")
  2308 apply (rule power2_eq_imp_eq)
  2309 apply (simp add: sin_squared_eq)
  2310 apply (rule sin_ge_zero)
  2311 apply (erule (1) arccos_lbound)
  2312 apply (erule (1) arccos_ubound)
  2313 apply simp
  2314 apply (subgoal_tac "\<bar>x\<bar>\<twosuperior> \<le> 1\<twosuperior>", simp)
  2315 apply (rule power_mono, simp, simp)
  2316 done
  2317 
  2318 lemma arctan [simp]:
  2319      "- (pi/2) < arctan y  & arctan y < pi/2 & tan (arctan y) = y"
  2320 unfolding arctan_def by (rule theI' [OF tan_total])
  2321 
  2322 lemma tan_arctan: "tan(arctan y) = y"
  2323 by auto
  2324 
  2325 lemma arctan_bounded: "- (pi/2) < arctan y  & arctan y < pi/2"
  2326 by (auto simp only: arctan)
  2327 
  2328 lemma arctan_lbound: "- (pi/2) < arctan y"
  2329 by auto
  2330 
  2331 lemma arctan_ubound: "arctan y < pi/2"
  2332 by (auto simp only: arctan)
  2333 
  2334 lemma arctan_unique:
  2335   assumes "-(pi/2) < x" and "x < pi/2" and "tan x = y"
  2336   shows "arctan y = x"
  2337   using assms arctan [of y] tan_total [of y] by (fast elim: ex1E)
  2338 
  2339 lemma arctan_tan:
  2340       "[|-(pi/2) < x; x < pi/2 |] ==> arctan(tan x) = x"
  2341   by (rule arctan_unique, simp_all)
  2342 
  2343 lemma arctan_zero_zero [simp]: "arctan 0 = 0"
  2344   by (rule arctan_unique, simp_all)
  2345 
  2346 lemma arctan_minus: "arctan (- x) = - arctan x"
  2347   apply (rule arctan_unique)
  2348   apply (simp only: neg_less_iff_less arctan_ubound)
  2349   apply (metis minus_less_iff arctan_lbound)
  2350   apply simp
  2351   done
  2352 
  2353 lemma cos_arctan_not_zero [simp]: "cos (arctan x) \<noteq> 0"
  2354   by (intro less_imp_neq [symmetric] cos_gt_zero_pi
  2355     arctan_lbound arctan_ubound)
  2356 
  2357 lemma cos_arctan: "cos (arctan x) = 1 / sqrt (1 + x\<twosuperior>)"
  2358 proof (rule power2_eq_imp_eq)
  2359   have "0 < 1 + x\<twosuperior>" by (simp add: add_pos_nonneg)
  2360   show "0 \<le> 1 / sqrt (1 + x\<twosuperior>)" by simp
  2361   show "0 \<le> cos (arctan x)"
  2362     by (intro less_imp_le cos_gt_zero_pi arctan_lbound arctan_ubound)
  2363   have "(cos (arctan x))\<twosuperior> * (1 + (tan (arctan x))\<twosuperior>) = 1"
  2364     unfolding tan_def by (simp add: distrib_left power_divide)
  2365   thus "(cos (arctan x))\<twosuperior> = (1 / sqrt (1 + x\<twosuperior>))\<twosuperior>"
  2366     using `0 < 1 + x\<twosuperior>` by (simp add: power_divide eq_divide_eq)
  2367 qed
  2368 
  2369 lemma sin_arctan: "sin (arctan x) = x / sqrt (1 + x\<twosuperior>)"
  2370   using add_pos_nonneg [OF zero_less_one zero_le_power2 [of x]]
  2371   using tan_arctan [of x] unfolding tan_def cos_arctan
  2372   by (simp add: eq_divide_eq)
  2373 
  2374 lemma tan_sec: "cos x \<noteq> 0 ==> 1 + tan(x) ^ 2 = inverse(cos x) ^ 2"
  2375 apply (rule power_inverse [THEN subst])
  2376 apply (rule_tac c1 = "(cos x)\<twosuperior>" in real_mult_right_cancel [THEN iffD1])
  2377 apply (auto dest: field_power_not_zero
  2378         simp add: power_mult_distrib distrib_right power_divide tan_def
  2379                   mult_assoc power_inverse [symmetric])
  2380 done
  2381 
  2382 lemma arctan_less_iff: "arctan x < arctan y \<longleftrightarrow> x < y"
  2383   by (metis tan_monotone' arctan_lbound arctan_ubound tan_arctan)
  2384 
  2385 lemma arctan_le_iff: "arctan x \<le> arctan y \<longleftrightarrow> x \<le> y"
  2386   by (simp only: not_less [symmetric] arctan_less_iff)
  2387 
  2388 lemma arctan_eq_iff: "arctan x = arctan y \<longleftrightarrow> x = y"
  2389   by (simp only: eq_iff [where 'a=real] arctan_le_iff)
  2390 
  2391 lemma zero_less_arctan_iff [simp]: "0 < arctan x \<longleftrightarrow> 0 < x"
  2392   using arctan_less_iff [of 0 x] by simp
  2393 
  2394 lemma arctan_less_zero_iff [simp]: "arctan x < 0 \<longleftrightarrow> x < 0"
  2395   using arctan_less_iff [of x 0] by simp
  2396 
  2397 lemma zero_le_arctan_iff [simp]: "0 \<le> arctan x \<longleftrightarrow> 0 \<le> x"
  2398   using arctan_le_iff [of 0 x] by simp
  2399 
  2400 lemma arctan_le_zero_iff [simp]: "arctan x \<le> 0 \<longleftrightarrow> x \<le> 0"
  2401   using arctan_le_iff [of x 0] by simp
  2402 
  2403 lemma arctan_eq_zero_iff [simp]: "arctan x = 0 \<longleftrightarrow> x = 0"
  2404   using arctan_eq_iff [of x 0] by simp
  2405 
  2406 lemma isCont_inverse_function2:
  2407   fixes f g :: "real \<Rightarrow> real" shows
  2408   "\<lbrakk>a < x; x < b;
  2409     \<forall>z. a \<le> z \<and> z \<le> b \<longrightarrow> g (f z) = z;
  2410     \<forall>z. a \<le> z \<and> z \<le> b \<longrightarrow> isCont f z\<rbrakk>
  2411    \<Longrightarrow> isCont g (f x)"
  2412 apply (rule isCont_inverse_function
  2413        [where f=f and d="min (x - a) (b - x)"])
  2414 apply (simp_all add: abs_le_iff)
  2415 done
  2416 
  2417 lemma isCont_arcsin: "\<lbrakk>-1 < x; x < 1\<rbrakk> \<Longrightarrow> isCont arcsin x"
  2418 apply (subgoal_tac "isCont arcsin (sin (arcsin x))", simp)
  2419 apply (rule isCont_inverse_function2 [where f=sin])
  2420 apply (erule (1) arcsin_lt_bounded [THEN conjunct1])
  2421 apply (erule (1) arcsin_lt_bounded [THEN conjunct2])
  2422 apply (fast intro: arcsin_sin, simp)
  2423 done
  2424 
  2425 lemma isCont_arccos: "\<lbrakk>-1 < x; x < 1\<rbrakk> \<Longrightarrow> isCont arccos x"
  2426 apply (subgoal_tac "isCont arccos (cos (arccos x))", simp)
  2427 apply (rule isCont_inverse_function2 [where f=cos])
  2428 apply (erule (1) arccos_lt_bounded [THEN conjunct1])
  2429 apply (erule (1) arccos_lt_bounded [THEN conjunct2])
  2430 apply (fast intro: arccos_cos, simp)
  2431 done
  2432 
  2433 lemma isCont_arctan: "isCont arctan x"
  2434 apply (rule arctan_lbound [of x, THEN dense, THEN exE], clarify)
  2435 apply (rule arctan_ubound [of x, THEN dense, THEN exE], clarify)
  2436 apply (subgoal_tac "isCont arctan (tan (arctan x))", simp)
  2437 apply (erule (1) isCont_inverse_function2 [where f=tan])
  2438 apply (metis arctan_tan order_le_less_trans order_less_le_trans)
  2439 apply (metis cos_gt_zero_pi isCont_tan order_less_le_trans less_le)
  2440 done
  2441 
  2442 lemma DERIV_arcsin:
  2443   "\<lbrakk>-1 < x; x < 1\<rbrakk> \<Longrightarrow> DERIV arcsin x :> inverse (sqrt (1 - x\<twosuperior>))"
  2444 apply (rule DERIV_inverse_function [where f=sin and a="-1" and b="1"])
  2445 apply (rule DERIV_cong [OF DERIV_sin])
  2446 apply (simp add: cos_arcsin)
  2447 apply (subgoal_tac "\<bar>x\<bar>\<twosuperior> < 1\<twosuperior>", simp)
  2448 apply (rule power_strict_mono, simp, simp, simp)
  2449 apply assumption
  2450 apply assumption
  2451 apply simp
  2452 apply (erule (1) isCont_arcsin)
  2453 done
  2454 
  2455 lemma DERIV_arccos:
  2456   "\<lbrakk>-1 < x; x < 1\<rbrakk> \<Longrightarrow> DERIV arccos x :> inverse (- sqrt (1 - x\<twosuperior>))"
  2457 apply (rule DERIV_inverse_function [where f=cos and a="-1" and b="1"])
  2458 apply (rule DERIV_cong [OF DERIV_cos])
  2459 apply (simp add: sin_arccos)
  2460 apply (subgoal_tac "\<bar>x\<bar>\<twosuperior> < 1\<twosuperior>", simp)
  2461 apply (rule power_strict_mono, simp, simp, simp)
  2462 apply assumption
  2463 apply assumption
  2464 apply simp
  2465 apply (erule (1) isCont_arccos)
  2466 done
  2467 
  2468 lemma DERIV_arctan: "DERIV arctan x :> inverse (1 + x\<twosuperior>)"
  2469 apply (rule DERIV_inverse_function [where f=tan and a="x - 1" and b="x + 1"])
  2470 apply (rule DERIV_cong [OF DERIV_tan])
  2471 apply (rule cos_arctan_not_zero)
  2472 apply (simp add: power_inverse tan_sec [symmetric])
  2473 apply (subgoal_tac "0 < 1 + x\<twosuperior>", simp)
  2474 apply (simp add: add_pos_nonneg)
  2475 apply (simp, simp, simp, rule isCont_arctan)
  2476 done
  2477 
  2478 declare
  2479   DERIV_arcsin[THEN DERIV_chain2, THEN DERIV_cong, DERIV_intros]
  2480   DERIV_arccos[THEN DERIV_chain2, THEN DERIV_cong, DERIV_intros]
  2481   DERIV_arctan[THEN DERIV_chain2, THEN DERIV_cong, DERIV_intros]
  2482 
  2483 lemma filterlim_tan_at_right: "filterlim tan at_bot (at_right (- pi/2))"
  2484   by (rule filterlim_at_bot_at_right[where Q="\<lambda>x. - pi/2 < x \<and> x < pi/2" and P="\<lambda>x. True" and g=arctan])
  2485      (auto simp: le_less eventually_within_less dist_real_def simp del: less_divide_eq_numeral1
  2486            intro!: tan_monotone exI[of _ "pi/2"])
  2487 
  2488 lemma filterlim_tan_at_left: "filterlim tan at_top (at_left (pi/2))"
  2489   by (rule filterlim_at_top_at_left[where Q="\<lambda>x. - pi/2 < x \<and> x < pi/2" and P="\<lambda>x. True" and g=arctan])
  2490      (auto simp: le_less eventually_within_less dist_real_def simp del: less_divide_eq_numeral1
  2491            intro!: tan_monotone exI[of _ "pi/2"])
  2492 
  2493 lemma tendsto_arctan_at_top: "(arctan ---> (pi/2)) at_top"
  2494 proof (rule tendstoI)
  2495   fix e :: real assume "0 < e"
  2496   def y \<equiv> "pi/2 - min (pi/2) e"
  2497   then have y: "0 \<le> y" "y < pi/2" "pi/2 \<le> e + y"
  2498     using `0 < e` by auto
  2499 
  2500   show "eventually (\<lambda>x. dist (arctan x) (pi / 2) < e) at_top"
  2501   proof (intro eventually_at_top_dense[THEN iffD2] exI allI impI)
  2502     fix x assume "tan y < x"
  2503     then have "arctan (tan y) < arctan x"
  2504       by (simp add: arctan_less_iff)
  2505     with y have "y < arctan x"
  2506       by (subst (asm) arctan_tan) simp_all
  2507     with arctan_ubound[of x, arith] y `0 < e`
  2508     show "dist (arctan x) (pi / 2) < e"
  2509       by (simp add: dist_real_def)
  2510   qed
  2511 qed
  2512 
  2513 lemma tendsto_arctan_at_bot: "(arctan ---> - (pi/2)) at_bot"
  2514   unfolding filterlim_at_bot_mirror arctan_minus by (intro tendsto_minus tendsto_arctan_at_top)
  2515 
  2516 subsection {* More Theorems about Sin and Cos *}
  2517 
  2518 lemma cos_45: "cos (pi / 4) = sqrt 2 / 2"
  2519 proof -
  2520   let ?c = "cos (pi / 4)" and ?s = "sin (pi / 4)"
  2521   have nonneg: "0 \<le> ?c"
  2522     by (simp add: cos_ge_zero)
  2523   have "0 = cos (pi / 4 + pi / 4)"
  2524     by simp
  2525   also have "cos (pi / 4 + pi / 4) = ?c\<twosuperior> - ?s\<twosuperior>"
  2526     by (simp only: cos_add power2_eq_square)
  2527   also have "\<dots> = 2 * ?c\<twosuperior> - 1"
  2528     by (simp add: sin_squared_eq)
  2529   finally have "?c\<twosuperior> = (sqrt 2 / 2)\<twosuperior>"
  2530     by (simp add: power_divide)
  2531   thus ?thesis
  2532     using nonneg by (rule power2_eq_imp_eq) simp
  2533 qed
  2534 
  2535 lemma cos_30: "cos (pi / 6) = sqrt 3 / 2"
  2536 proof -
  2537   let ?c = "cos (pi / 6)" and ?s = "sin (pi / 6)"
  2538   have pos_c: "0 < ?c"
  2539     by (rule cos_gt_zero, simp, simp)
  2540   have "0 = cos (pi / 6 + pi / 6 + pi / 6)"
  2541     by simp
  2542   also have "\<dots> = (?c * ?c - ?s * ?s) * ?c - (?s * ?c + ?c * ?s) * ?s"
  2543     by (simp only: cos_add sin_add)
  2544   also have "\<dots> = ?c * (?c\<twosuperior> - 3 * ?s\<twosuperior>)"
  2545     by (simp add: algebra_simps power2_eq_square)
  2546   finally have "?c\<twosuperior> = (sqrt 3 / 2)\<twosuperior>"
  2547     using pos_c by (simp add: sin_squared_eq power_divide)
  2548   thus ?thesis
  2549     using pos_c [THEN order_less_imp_le]
  2550     by (rule power2_eq_imp_eq) simp
  2551 qed
  2552 
  2553 lemma sin_45: "sin (pi / 4) = sqrt 2 / 2"
  2554 by (simp add: sin_cos_eq cos_45)
  2555 
  2556 lemma sin_60: "sin (pi / 3) = sqrt 3 / 2"
  2557 by (simp add: sin_cos_eq cos_30)
  2558 
  2559 lemma cos_60: "cos (pi / 3) = 1 / 2"
  2560 apply (rule power2_eq_imp_eq)
  2561 apply (simp add: cos_squared_eq sin_60 power_divide)
  2562 apply (rule cos_ge_zero, rule order_trans [where y=0], simp_all)
  2563 done
  2564 
  2565 lemma sin_30: "sin (pi / 6) = 1 / 2"
  2566 by (simp add: sin_cos_eq cos_60)
  2567 
  2568 lemma tan_30: "tan (pi / 6) = 1 / sqrt 3"
  2569 unfolding tan_def by (simp add: sin_30 cos_30)
  2570 
  2571 lemma tan_45: "tan (pi / 4) = 1"
  2572 unfolding tan_def by (simp add: sin_45 cos_45)
  2573 
  2574 lemma tan_60: "tan (pi / 3) = sqrt 3"
  2575 unfolding tan_def by (simp add: sin_60 cos_60)
  2576 
  2577 lemma sin_cos_npi [simp]: "sin (real (Suc (2 * n)) * pi / 2) = (-1) ^ n"
  2578 proof -
  2579   have "sin ((real n + 1/2) * pi) = cos (real n * pi)"
  2580     by (auto simp add: algebra_simps sin_add)
  2581   thus ?thesis
  2582     by (simp add: real_of_nat_Suc distrib_right add_divide_distrib
  2583                   mult_commute [of pi])
  2584 qed
  2585 
  2586 lemma cos_2npi [simp]: "cos (2 * real (n::nat) * pi) = 1"
  2587 by (simp add: cos_double mult_assoc power_add [symmetric] numeral_2_eq_2)
  2588 
  2589 lemma cos_3over2_pi [simp]: "cos (3 / 2 * pi) = 0"
  2590 apply (subgoal_tac "cos (pi + pi/2) = 0", simp)
  2591 apply (subst cos_add, simp)
  2592 done
  2593 
  2594 lemma sin_2npi [simp]: "sin (2 * real (n::nat) * pi) = 0"
  2595 by (auto simp add: mult_assoc)
  2596 
  2597 lemma sin_3over2_pi [simp]: "sin (3 / 2 * pi) = - 1"
  2598 apply (subgoal_tac "sin (pi + pi/2) = - 1", simp)
  2599 apply (subst sin_add, simp)
  2600 done
  2601 
  2602 lemma cos_pi_eq_zero [simp]: "cos (pi * real (Suc (2 * m)) / 2) = 0"
  2603 by (simp only: cos_add sin_add real_of_nat_Suc distrib_right distrib_left add_divide_distrib, auto)
  2604 
  2605 lemma DERIV_cos_add [simp]: "DERIV (%x. cos (x + k)) xa :> - sin (xa + k)"
  2606   by (auto intro!: DERIV_intros)
  2607 
  2608 lemma sin_zero_abs_cos_one: "sin x = 0 ==> \<bar>cos x\<bar> = 1"
  2609 by (auto simp add: sin_zero_iff even_mult_two_ex)
  2610 
  2611 lemma cos_one_sin_zero: "cos x = 1 ==> sin x = 0"
  2612 by (cut_tac x = x in sin_cos_squared_add3, auto)
  2613 
  2614 subsection {* Machins formula *}
  2615 
  2616 lemma arctan_one: "arctan 1 = pi / 4"
  2617   by (rule arctan_unique, simp_all add: tan_45 m2pi_less_pi)
  2618 
  2619 lemma tan_total_pi4: assumes "\<bar>x\<bar> < 1"
  2620   shows "\<exists> z. - (pi / 4) < z \<and> z < pi / 4 \<and> tan z = x"
  2621 proof
  2622   show "- (pi / 4) < arctan x \<and> arctan x < pi / 4 \<and> tan (arctan x) = x"
  2623     unfolding arctan_one [symmetric] arctan_minus [symmetric]
  2624     unfolding arctan_less_iff using assms by auto
  2625 qed
  2626 
  2627 lemma arctan_add: assumes "\<bar>x\<bar> \<le> 1" and "\<bar>y\<bar> < 1"
  2628   shows "arctan x + arctan y = arctan ((x + y) / (1 - x * y))"
  2629 proof (rule arctan_unique [symmetric])
  2630   have "- (pi / 4) \<le> arctan x" and "- (pi / 4) < arctan y"
  2631     unfolding arctan_one [symmetric] arctan_minus [symmetric]
  2632     unfolding arctan_le_iff arctan_less_iff using assms by auto
  2633   from add_le_less_mono [OF this]
  2634   show 1: "- (pi / 2) < arctan x + arctan y" by simp
  2635   have "arctan x \<le> pi / 4" and "arctan y < pi / 4"
  2636     unfolding arctan_one [symmetric]
  2637     unfolding arctan_le_iff arctan_less_iff using assms by auto
  2638   from add_le_less_mono [OF this]
  2639   show 2: "arctan x + arctan y < pi / 2" by simp
  2640   show "tan (arctan x + arctan y) = (x + y) / (1 - x * y)"
  2641     using cos_gt_zero_pi [OF 1 2] by (simp add: tan_add)
  2642 qed
  2643 
  2644 theorem machin: "pi / 4 = 4 * arctan (1/5) - arctan (1 / 239)"
  2645 proof -
  2646   have "\<bar>1 / 5\<bar> < (1 :: real)" by auto
  2647   from arctan_add[OF less_imp_le[OF this] this]
  2648   have "2 * arctan (1 / 5) = arctan (5 / 12)" by auto
  2649   moreover
  2650   have "\<bar>5 / 12\<bar> < (1 :: real)" by auto
  2651   from arctan_add[OF less_imp_le[OF this] this]
  2652   have "2 * arctan (5 / 12) = arctan (120 / 119)" by auto
  2653   moreover
  2654   have "\<bar>1\<bar> \<le> (1::real)" and "\<bar>1 / 239\<bar> < (1::real)" by auto
  2655   from arctan_add[OF this]
  2656   have "arctan 1 + arctan (1 / 239) = arctan (120 / 119)" by auto
  2657   ultimately have "arctan 1 + arctan (1 / 239) = 4 * arctan (1 / 5)" by auto
  2658   thus ?thesis unfolding arctan_one by algebra
  2659 qed
  2660 
  2661 subsection {* Introducing the arcus tangens power series *}
  2662 
  2663 lemma monoseq_arctan_series: fixes x :: real
  2664   assumes "\<bar>x\<bar> \<le> 1" shows "monoseq (\<lambda> n. 1 / real (n*2+1) * x^(n*2+1))" (is "monoseq ?a")
  2665 proof (cases "x = 0") case True thus ?thesis unfolding monoseq_def One_nat_def by auto
  2666 next
  2667   case False
  2668   have "norm x \<le> 1" and "x \<le> 1" and "-1 \<le> x" using assms by auto
  2669   show "monoseq ?a"
  2670   proof -
  2671     { fix n fix x :: real assume "0 \<le> x" and "x \<le> 1"
  2672       have "1 / real (Suc (Suc n * 2)) * x ^ Suc (Suc n * 2) \<le> 1 / real (Suc (n * 2)) * x ^ Suc (n * 2)"
  2673       proof (rule mult_mono)
  2674         show "1 / real (Suc (Suc n * 2)) \<le> 1 / real (Suc (n * 2))" by (rule frac_le) simp_all
  2675         show "0 \<le> 1 / real (Suc (n * 2))" by auto
  2676         show "x ^ Suc (Suc n * 2) \<le> x ^ Suc (n * 2)" by (rule power_decreasing) (simp_all add: `0 \<le> x` `x \<le> 1`)
  2677         show "0 \<le> x ^ Suc (Suc n * 2)" by (rule zero_le_power) (simp add: `0 \<le> x`)
  2678       qed
  2679     } note mono = this
  2680 
  2681     show ?thesis
  2682     proof (cases "0 \<le> x")
  2683       case True from mono[OF this `x \<le> 1`, THEN allI]
  2684       show ?thesis unfolding Suc_eq_plus1[symmetric] by (rule mono_SucI2)
  2685     next
  2686       case False hence "0 \<le> -x" and "-x \<le> 1" using `-1 \<le> x` by auto
  2687       from mono[OF this]
  2688       have "\<And>n. 1 / real (Suc (Suc n * 2)) * x ^ Suc (Suc n * 2) \<ge> 1 / real (Suc (n * 2)) * x ^ Suc (n * 2)" using `0 \<le> -x` by auto
  2689       thus ?thesis unfolding Suc_eq_plus1[symmetric] by (rule mono_SucI1[OF allI])
  2690     qed
  2691   qed
  2692 qed
  2693 
  2694 lemma zeroseq_arctan_series: fixes x :: real
  2695   assumes "\<bar>x\<bar> \<le> 1" shows "(\<lambda> n. 1 / real (n*2+1) * x^(n*2+1)) ----> 0" (is "?a ----> 0")
  2696 proof (cases "x = 0") case True thus ?thesis unfolding One_nat_def by (auto simp add: tendsto_const)
  2697 next
  2698   case False
  2699   have "norm x \<le> 1" and "x \<le> 1" and "-1 \<le> x" using assms by auto
  2700   show "?a ----> 0"
  2701   proof (cases "\<bar>x\<bar> < 1")
  2702     case True hence "norm x < 1" by auto
  2703     from tendsto_mult[OF LIMSEQ_inverse_real_of_nat LIMSEQ_power_zero[OF `norm x < 1`, THEN LIMSEQ_Suc]]
  2704     have "(\<lambda>n. 1 / real (n + 1) * x ^ (n + 1)) ----> 0"
  2705       unfolding inverse_eq_divide Suc_eq_plus1 by simp
  2706     then show ?thesis using pos2 by (rule LIMSEQ_linear)
  2707   next
  2708     case False hence "x = -1 \<or> x = 1" using `\<bar>x\<bar> \<le> 1` by auto
  2709     hence n_eq: "\<And> n. x ^ (n * 2 + 1) = x" unfolding One_nat_def by auto
  2710     from tendsto_mult[OF LIMSEQ_inverse_real_of_nat[THEN LIMSEQ_linear, OF pos2, unfolded inverse_eq_divide] tendsto_const[of x]]
  2711     show ?thesis unfolding n_eq Suc_eq_plus1 by auto
  2712   qed
  2713 qed
  2714 
  2715 lemma summable_arctan_series: fixes x :: real and n :: nat
  2716   assumes "\<bar>x\<bar> \<le> 1" shows "summable (\<lambda> k. (-1)^k * (1 / real (k*2+1) * x ^ (k*2+1)))" (is "summable (?c x)")
  2717   by (rule summable_Leibniz(1), rule zeroseq_arctan_series[OF assms], rule monoseq_arctan_series[OF assms])
  2718 
  2719 lemma less_one_imp_sqr_less_one: fixes x :: real assumes "\<bar>x\<bar> < 1" shows "x^2 < 1"
  2720 proof -
  2721   from mult_left_mono[OF less_imp_le[OF `\<bar>x\<bar> < 1`] abs_ge_zero[of x]]
  2722   have "\<bar> x^2 \<bar> < 1" using `\<bar> x \<bar> < 1` unfolding numeral_2_eq_2 power_Suc2 by auto
  2723   thus ?thesis using zero_le_power2 by auto
  2724 qed
  2725 
  2726 lemma DERIV_arctan_series: assumes "\<bar> x \<bar> < 1"
  2727   shows "DERIV (\<lambda> x'. \<Sum> k. (-1)^k * (1 / real (k*2+1) * x' ^ (k*2+1))) x :> (\<Sum> k. (-1)^k * x^(k*2))" (is "DERIV ?arctan _ :> ?Int")
  2728 proof -
  2729   let "?f n" = "if even n then (-1)^(n div 2) * 1 / real (Suc n) else 0"
  2730 
  2731   { fix n :: nat assume "even n" hence "2 * (n div 2) = n" by presburger } note n_even=this
  2732   have if_eq: "\<And> n x'. ?f n * real (Suc n) * x'^n = (if even n then (-1)^(n div 2) * x'^(2 * (n div 2)) else 0)" using n_even by auto
  2733 
  2734   { fix x :: real assume "\<bar>x\<bar> < 1" hence "x^2 < 1" by (rule less_one_imp_sqr_less_one)
  2735     have "summable (\<lambda> n. -1 ^ n * (x^2) ^n)"
  2736       by (rule summable_Leibniz(1), auto intro!: LIMSEQ_realpow_zero monoseq_realpow `x^2 < 1` order_less_imp_le[OF `x^2 < 1`])
  2737     hence "summable (\<lambda> n. -1 ^ n * x^(2*n))" unfolding power_mult .
  2738   } note summable_Integral = this
  2739 
  2740   { fix f :: "nat \<Rightarrow> real"
  2741     have "\<And> x. f sums x = (\<lambda> n. if even n then f (n div 2) else 0) sums x"
  2742     proof
  2743       fix x :: real assume "f sums x"
  2744       from sums_if[OF sums_zero this]
  2745       show "(\<lambda> n. if even n then f (n div 2) else 0) sums x" by auto
  2746     next
  2747       fix x :: real assume "(\<lambda> n. if even n then f (n div 2) else 0) sums x"
  2748       from LIMSEQ_linear[OF this[unfolded sums_def] pos2, unfolded sum_split_even_odd[unfolded mult_commute]]
  2749       show "f sums x" unfolding sums_def by auto
  2750     qed
  2751     hence "op sums f = op sums (\<lambda> n. if even n then f (n div 2) else 0)" ..
  2752   } note sums_even = this
  2753 
  2754   have Int_eq: "(\<Sum> n. ?f n * real (Suc n) * x^n) = ?Int" unfolding if_eq mult_commute[of _ 2] suminf_def sums_even[of "\<lambda> n. -1 ^ n * x ^ (2 * n)", symmetric]
  2755     by auto
  2756 
  2757   { fix x :: real
  2758     have if_eq': "\<And> n. (if even n then -1 ^ (n div 2) * 1 / real (Suc n) else 0) * x ^ Suc n =
  2759       (if even n then -1 ^ (n div 2) * (1 / real (Suc (2 * (n div 2))) * x ^ Suc (2 * (n div 2))) else 0)"
  2760       using n_even by auto
  2761     have idx_eq: "\<And> n. n * 2 + 1 = Suc (2 * n)" by auto
  2762     have "(\<Sum> n. ?f n * x^(Suc n)) = ?arctan x" unfolding if_eq' idx_eq suminf_def sums_even[of "\<lambda> n. -1 ^ n * (1 / real (Suc (2 * n)) * x ^ Suc (2 * n))", symmetric]
  2763       by auto
  2764   } note arctan_eq = this
  2765 
  2766   have "DERIV (\<lambda> x. \<Sum> n. ?f n * x^(Suc n)) x :> (\<Sum> n. ?f n * real (Suc n) * x^n)"
  2767   proof (rule DERIV_power_series')
  2768     show "x \<in> {- 1 <..< 1}" using `\<bar> x \<bar> < 1` by auto
  2769     { fix x' :: real assume x'_bounds: "x' \<in> {- 1 <..< 1}"
  2770       hence "\<bar>x'\<bar> < 1" by auto
  2771 
  2772       let ?S = "\<Sum> n. (-1)^n * x'^(2 * n)"
  2773       show "summable (\<lambda> n. ?f n * real (Suc n) * x'^n)" unfolding if_eq
  2774         by (rule sums_summable[where l="0 + ?S"], rule sums_if, rule sums_zero, rule summable_sums, rule summable_Integral[OF `\<bar>x'\<bar> < 1`])
  2775     }
  2776   qed auto
  2777   thus ?thesis unfolding Int_eq arctan_eq .
  2778 qed
  2779 
  2780 lemma arctan_series: assumes "\<bar> x \<bar> \<le> 1"
  2781   shows "arctan x = (\<Sum> k. (-1)^k * (1 / real (k*2+1) * x ^ (k*2+1)))" (is "_ = suminf (\<lambda> n. ?c x n)")
  2782 proof -
  2783   let "?c' x n" = "(-1)^n * x^(n*2)"
  2784 
  2785   { fix r x :: real assume "0 < r" and "r < 1" and "\<bar> x \<bar> < r"
  2786     have "\<bar>x\<bar> < 1" using `r < 1` and `\<bar>x\<bar> < r` by auto
  2787     from DERIV_arctan_series[OF this]
  2788     have "DERIV (\<lambda> x. suminf (?c x)) x :> (suminf (?c' x))" .
  2789   } note DERIV_arctan_suminf = this
  2790 
  2791   { fix x :: real assume "\<bar>x\<bar> \<le> 1" note summable_Leibniz[OF zeroseq_arctan_series[OF this] monoseq_arctan_series[OF this]] }
  2792   note arctan_series_borders = this
  2793 
  2794   { fix x :: real assume "\<bar>x\<bar> < 1" have "arctan x = (\<Sum> k. ?c x k)"
  2795   proof -
  2796     obtain r where "\<bar>x\<bar> < r" and "r < 1" using dense[OF `\<bar>x\<bar> < 1`] by blast
  2797     hence "0 < r" and "-r < x" and "x < r" by auto
  2798 
  2799     have suminf_eq_arctan_bounded: "\<And> x a b. \<lbrakk> -r < a ; b < r ; a < b ; a \<le> x ; x \<le> b \<rbrakk> \<Longrightarrow> suminf (?c x) - arctan x = suminf (?c a) - arctan a"
  2800     proof -
  2801       fix x a b assume "-r < a" and "b < r" and "a < b" and "a \<le> x" and "x \<le> b"
  2802       hence "\<bar>x\<bar> < r" by auto
  2803       show "suminf (?c x) - arctan x = suminf (?c a) - arctan a"
  2804       proof (rule DERIV_isconst2[of "a" "b"])
  2805         show "a < b" and "a \<le> x" and "x \<le> b" using `a < b` `a \<le> x` `x \<le> b` by auto
  2806         have "\<forall> x. -r < x \<and> x < r \<longrightarrow> DERIV (\<lambda> x. suminf (?c x) - arctan x) x :> 0"
  2807         proof (rule allI, rule impI)
  2808           fix x assume "-r < x \<and> x < r" hence "\<bar>x\<bar> < r" by auto
  2809           hence "\<bar>x\<bar> < 1" using `r < 1` by auto
  2810           have "\<bar> - (x^2) \<bar> < 1" using less_one_imp_sqr_less_one[OF `\<bar>x\<bar> < 1`] by auto
  2811           hence "(\<lambda> n. (- (x^2)) ^ n) sums (1 / (1 - (- (x^2))))" unfolding real_norm_def[symmetric] by (rule geometric_sums)
  2812           hence "(?c' x) sums (1 / (1 - (- (x^2))))" unfolding power_mult_distrib[symmetric] power_mult nat_mult_commute[of _ 2] by auto
  2813           hence suminf_c'_eq_geom: "inverse (1 + x^2) = suminf (?c' x)" using sums_unique unfolding inverse_eq_divide by auto
  2814           have "DERIV (\<lambda> x. suminf (?c x)) x :> (inverse (1 + x^2))" unfolding suminf_c'_eq_geom
  2815             by (rule DERIV_arctan_suminf[OF `0 < r` `r < 1` `\<bar>x\<bar> < r`])
  2816           from DERIV_add_minus[OF this DERIV_arctan]
  2817           show "DERIV (\<lambda> x. suminf (?c x) - arctan x) x :> 0" unfolding diff_minus by auto
  2818         qed
  2819         hence DERIV_in_rball: "\<forall> y. a \<le> y \<and> y \<le> b \<longrightarrow> DERIV (\<lambda> x. suminf (?c x) - arctan x) y :> 0" using `-r < a` `b < r` by auto
  2820         thus "\<forall> y. a < y \<and> y < b \<longrightarrow> DERIV (\<lambda> x. suminf (?c x) - arctan x) y :> 0" using `\<bar>x\<bar> < r` by auto
  2821         show "\<forall> y. a \<le> y \<and> y \<le> b \<longrightarrow> isCont (\<lambda> x. suminf (?c x) - arctan x) y" using DERIV_in_rball DERIV_isCont by auto
  2822       qed
  2823     qed
  2824 
  2825     have suminf_arctan_zero: "suminf (?c 0) - arctan 0 = 0"
  2826       unfolding Suc_eq_plus1[symmetric] power_Suc2 mult_zero_right arctan_zero_zero suminf_zero by auto
  2827 
  2828     have "suminf (?c x) - arctan x = 0"
  2829     proof (cases "x = 0")
  2830       case True thus ?thesis using suminf_arctan_zero by auto
  2831     next
  2832       case False hence "0 < \<bar>x\<bar>" and "- \<bar>x\<bar> < \<bar>x\<bar>" by auto
  2833       have "suminf (?c (-\<bar>x\<bar>)) - arctan (-\<bar>x\<bar>) = suminf (?c 0) - arctan 0"
  2834         by (rule suminf_eq_arctan_bounded[where x="0" and a="-\<bar>x\<bar>" and b="\<bar>x\<bar>", symmetric])
  2835           (simp_all only: `\<bar>x\<bar> < r` `-\<bar>x\<bar> < \<bar>x\<bar>` neg_less_iff_less)
  2836       moreover
  2837       have "suminf (?c x) - arctan x = suminf (?c (-\<bar>x\<bar>)) - arctan (-\<bar>x\<bar>)"
  2838         by (rule suminf_eq_arctan_bounded[where x="x" and a="-\<bar>x\<bar>" and b="\<bar>x\<bar>"])
  2839           (simp_all only: `\<bar>x\<bar> < r` `-\<bar>x\<bar> < \<bar>x\<bar>` neg_less_iff_less)
  2840       ultimately
  2841       show ?thesis using suminf_arctan_zero by auto
  2842     qed
  2843     thus ?thesis by auto
  2844   qed } note when_less_one = this
  2845 
  2846   show "arctan x = suminf (\<lambda> n. ?c x n)"
  2847   proof (cases "\<bar>x\<bar> < 1")
  2848     case True thus ?thesis by (rule when_less_one)
  2849   next case False hence "\<bar>x\<bar> = 1" using `\<bar>x\<bar> \<le> 1` by auto
  2850     let "?a x n" = "\<bar>1 / real (n*2+1) * x^(n*2+1)\<bar>"
  2851     let "?diff x n" = "\<bar> arctan x - (\<Sum> i = 0..<n. ?c x i)\<bar>"
  2852     { fix n :: nat
  2853       have "0 < (1 :: real)" by auto
  2854       moreover
  2855       { fix x :: real assume "0 < x" and "x < 1" hence "\<bar>x\<bar> \<le> 1" and "\<bar>x\<bar> < 1" by auto
  2856         from `0 < x` have "0 < 1 / real (0 * 2 + (1::nat)) * x ^ (0 * 2 + 1)" by auto
  2857         note bounds = mp[OF arctan_series_borders(2)[OF `\<bar>x\<bar> \<le> 1`] this, unfolded when_less_one[OF `\<bar>x\<bar> < 1`, symmetric], THEN spec]
  2858         have "0 < 1 / real (n*2+1) * x^(n*2+1)" by (rule mult_pos_pos, auto simp only: zero_less_power[OF `0 < x`], auto)
  2859         hence a_pos: "?a x n = 1 / real (n*2+1) * x^(n*2+1)" by (rule abs_of_pos)
  2860         have "?diff x n \<le> ?a x n"
  2861         proof (cases "even n")
  2862           case True hence sgn_pos: "(-1)^n = (1::real)" by auto
  2863           from `even n` obtain m where "2 * m = n" unfolding even_mult_two_ex by auto
  2864           from bounds[of m, unfolded this atLeastAtMost_iff]
  2865           have "\<bar>arctan x - (\<Sum>i = 0..<n. (?c x i))\<bar> \<le> (\<Sum>i = 0..<n + 1. (?c x i)) - (\<Sum>i = 0..<n. (?c x i))" by auto
  2866           also have "\<dots> = ?c x n" unfolding One_nat_def by auto
  2867           also have "\<dots> = ?a x n" unfolding sgn_pos a_pos by auto
  2868           finally show ?thesis .
  2869         next
  2870           case False hence sgn_neg: "(-1)^n = (-1::real)" by auto
  2871           from `odd n` obtain m where m_def: "2 * m + 1 = n" unfolding odd_Suc_mult_two_ex by auto
  2872           hence m_plus: "2 * (m + 1) = n + 1" by auto
  2873           from bounds[of "m + 1", unfolded this atLeastAtMost_iff, THEN conjunct1] bounds[of m, unfolded m_def atLeastAtMost_iff, THEN conjunct2]
  2874           have "\<bar>arctan x - (\<Sum>i = 0..<n. (?c x i))\<bar> \<le> (\<Sum>i = 0..<n. (?c x i)) - (\<Sum>i = 0..<n+1. (?c x i))" by auto
  2875           also have "\<dots> = - ?c x n" unfolding One_nat_def by auto
  2876           also have "\<dots> = ?a x n" unfolding sgn_neg a_pos by auto
  2877           finally show ?thesis .
  2878         qed
  2879         hence "0 \<le> ?a x n - ?diff x n" by auto
  2880       }
  2881       hence "\<forall> x \<in> { 0 <..< 1 }. 0 \<le> ?a x n - ?diff x n" by auto
  2882       moreover have "\<And>x. isCont (\<lambda> x. ?a x n - ?diff x n) x"
  2883         unfolding diff_minus divide_inverse
  2884         by (auto intro!: isCont_add isCont_rabs isCont_ident isCont_minus isCont_arctan isCont_inverse isCont_mult isCont_power isCont_const isCont_setsum)
  2885       ultimately have "0 \<le> ?a 1 n - ?diff 1 n" by (rule LIM_less_bound)
  2886       hence "?diff 1 n \<le> ?a 1 n" by auto
  2887     }
  2888     have "?a 1 ----> 0"
  2889       unfolding tendsto_rabs_zero_iff power_one divide_inverse One_nat_def
  2890       by (auto intro!: tendsto_mult LIMSEQ_linear LIMSEQ_inverse_real_of_nat)
  2891     have "?diff 1 ----> 0"
  2892     proof (rule LIMSEQ_I)
  2893       fix r :: real assume "0 < r"
  2894       obtain N :: nat where N_I: "\<And> n. N \<le> n \<Longrightarrow> ?a 1 n < r" using LIMSEQ_D[OF `?a 1 ----> 0` `0 < r`] by auto
  2895       { fix n assume "N \<le> n" from `?diff 1 n \<le> ?a 1 n` N_I[OF this]
  2896         have "norm (?diff 1 n - 0) < r" by auto }
  2897       thus "\<exists> N. \<forall> n \<ge> N. norm (?diff 1 n - 0) < r" by blast
  2898     qed
  2899     from this [unfolded tendsto_rabs_zero_iff, THEN tendsto_add [OF _ tendsto_const], of "- arctan 1", THEN tendsto_minus]
  2900     have "(?c 1) sums (arctan 1)" unfolding sums_def by auto
  2901     hence "arctan 1 = (\<Sum> i. ?c 1 i)" by (rule sums_unique)
  2902 
  2903     show ?thesis
  2904     proof (cases "x = 1", simp add: `arctan 1 = (\<Sum> i. ?c 1 i)`)
  2905       assume "x \<noteq> 1" hence "x = -1" using `\<bar>x\<bar> = 1` by auto
  2906 
  2907       have "- (pi / 2) < 0" using pi_gt_zero by auto
  2908       have "- (2 * pi) < 0" using pi_gt_zero by auto
  2909 
  2910       have c_minus_minus: "\<And> i. ?c (- 1) i = - ?c 1 i" unfolding One_nat_def by auto
  2911 
  2912       have "arctan (- 1) = arctan (tan (-(pi / 4)))" unfolding tan_45 tan_minus ..
  2913       also have "\<dots> = - (pi / 4)" by (rule arctan_tan, auto simp add: order_less_trans[OF `- (pi / 2) < 0` pi_gt_zero])
  2914       also have "\<dots> = - (arctan (tan (pi / 4)))" unfolding neg_equal_iff_equal by (rule arctan_tan[symmetric], auto simp add: order_less_trans[OF `- (2 * pi) < 0` pi_gt_zero])
  2915       also have "\<dots> = - (arctan 1)" unfolding tan_45 ..
  2916       also have "\<dots> = - (\<Sum> i. ?c 1 i)" using `arctan 1 = (\<Sum> i. ?c 1 i)` by auto
  2917       also have "\<dots> = (\<Sum> i. ?c (- 1) i)" using suminf_minus[OF sums_summable[OF `(?c 1) sums (arctan 1)`]] unfolding c_minus_minus by auto
  2918       finally show ?thesis using `x = -1` by auto
  2919     qed
  2920   qed
  2921 qed
  2922 
  2923 lemma arctan_half: fixes x :: real
  2924   shows "arctan x = 2 * arctan (x / (1 + sqrt(1 + x^2)))"
  2925 proof -
  2926   obtain y where low: "- (pi / 2) < y" and high: "y < pi / 2" and y_eq: "tan y = x" using tan_total by blast
  2927   hence low2: "- (pi / 2) < y / 2" and high2: "y / 2 < pi / 2" by auto
  2928 
  2929   have divide_nonzero_divide: "\<And> A B C :: real. C \<noteq> 0 \<Longrightarrow> A / B = (A / C) / (B / C)" by auto
  2930 
  2931   have "0 < cos y" using cos_gt_zero_pi[OF low high] .
  2932   hence "cos y \<noteq> 0" and cos_sqrt: "sqrt ((cos y) ^ 2) = cos y" by auto
  2933 
  2934   have "1 + (tan y)^2 = 1 + sin y^2 / cos y^2" unfolding tan_def power_divide ..
  2935   also have "\<dots> = cos y^2 / cos y^2 + sin y^2 / cos y^2" using `cos y \<noteq> 0` by auto
  2936   also have "\<dots> = 1 / cos y^2" unfolding add_divide_distrib[symmetric] sin_cos_squared_add2 ..
  2937   finally have "1 + (tan y)^2 = 1 / cos y^2" .
  2938 
  2939   have "sin y / (cos y + 1) = tan y / ((cos y + 1) / cos y)" unfolding tan_def divide_nonzero_divide[OF `cos y \<noteq> 0`, symmetric] ..
  2940   also have "\<dots> = tan y / (1 + 1 / cos y)" using `cos y \<noteq> 0` unfolding add_divide_distrib by auto
  2941   also have "\<dots> = tan y / (1 + 1 / sqrt(cos y^2))" unfolding cos_sqrt ..
  2942   also have "\<dots> = tan y / (1 + sqrt(1 / cos y^2))" unfolding real_sqrt_divide by auto
  2943   finally have eq: "sin y / (cos y + 1) = tan y / (1 + sqrt(1 + (tan y)^2))" unfolding `1 + (tan y)^2 = 1 / cos y^2` .
  2944 
  2945   have "arctan x = y" using arctan_tan low high y_eq by auto
  2946   also have "\<dots> = 2 * (arctan (tan (y/2)))" using arctan_tan[OF low2 high2] by auto
  2947   also have "\<dots> = 2 * (arctan (sin y / (cos y + 1)))" unfolding tan_half by auto
  2948   finally show ?thesis unfolding eq `tan y = x` .
  2949 qed
  2950 
  2951 lemma arctan_monotone: assumes "x < y"
  2952   shows "arctan x < arctan y"
  2953   using assms by (simp only: arctan_less_iff)
  2954 
  2955 lemma arctan_monotone': assumes "x \<le> y" shows "arctan x \<le> arctan y"
  2956   using assms by (simp only: arctan_le_iff)
  2957 
  2958 lemma arctan_inverse:
  2959   assumes "x \<noteq> 0" shows "arctan (1 / x) = sgn x * pi / 2 - arctan x"
  2960 proof (rule arctan_unique)
  2961   show "- (pi / 2) < sgn x * pi / 2 - arctan x"
  2962     using arctan_bounded [of x] assms
  2963     unfolding sgn_real_def
  2964     apply (auto simp add: algebra_simps)
  2965     apply (drule zero_less_arctan_iff [THEN iffD2])
  2966     apply arith
  2967     done
  2968   show "sgn x * pi / 2 - arctan x < pi / 2"
  2969     using arctan_bounded [of "- x"] assms
  2970     unfolding sgn_real_def arctan_minus
  2971     by auto
  2972   show "tan (sgn x * pi / 2 - arctan x) = 1 / x"
  2973     unfolding tan_inverse [of "arctan x", unfolded tan_arctan]
  2974     unfolding sgn_real_def
  2975     by (simp add: tan_def cos_arctan sin_arctan sin_diff cos_diff)
  2976 qed
  2977 
  2978 theorem pi_series: "pi / 4 = (\<Sum> k. (-1)^k * 1 / real (k*2+1))" (is "_ = ?SUM")
  2979 proof -
  2980   have "pi / 4 = arctan 1" using arctan_one by auto
  2981   also have "\<dots> = ?SUM" using arctan_series[of 1] by auto
  2982   finally show ?thesis by auto
  2983 qed
  2984 
  2985 subsection {* Existence of Polar Coordinates *}
  2986 
  2987 lemma cos_x_y_le_one: "\<bar>x / sqrt (x\<twosuperior> + y\<twosuperior>)\<bar> \<le> 1"
  2988 apply (rule power2_le_imp_le [OF _ zero_le_one])
  2989 apply (simp add: power_divide divide_le_eq not_sum_power2_lt_zero)
  2990 done
  2991 
  2992 lemma cos_arccos_abs: "\<bar>y\<bar> \<le> 1 \<Longrightarrow> cos (arccos y) = y"
  2993 by (simp add: abs_le_iff)
  2994 
  2995 lemma sin_arccos_abs: "\<bar>y\<bar> \<le> 1 \<Longrightarrow> sin (arccos y) = sqrt (1 - y\<twosuperior>)"
  2996 by (simp add: sin_arccos abs_le_iff)
  2997 
  2998 lemmas cos_arccos_lemma1 = cos_arccos_abs [OF cos_x_y_le_one]
  2999 
  3000 lemmas sin_arccos_lemma1 = sin_arccos_abs [OF cos_x_y_le_one]
  3001 
  3002 lemma polar_ex1:
  3003      "0 < y ==> \<exists>r a. x = r * cos a & y = r * sin a"
  3004 apply (rule_tac x = "sqrt (x\<twosuperior> + y\<twosuperior>)" in exI)
  3005 apply (rule_tac x = "arccos (x / sqrt (x\<twosuperior> + y\<twosuperior>))" in exI)
  3006 apply (simp add: cos_arccos_lemma1)
  3007 apply (simp add: sin_arccos_lemma1)
  3008 apply (simp add: power_divide)
  3009 apply (simp add: real_sqrt_mult [symmetric])
  3010 apply (simp add: right_diff_distrib)
  3011 done
  3012 
  3013 lemma polar_ex2:
  3014      "y < 0 ==> \<exists>r a. x = r * cos a & y = r * sin a"
  3015 apply (insert polar_ex1 [where x=x and y="-y"], simp, clarify)
  3016 apply (metis cos_minus minus_minus minus_mult_right sin_minus)
  3017 done
  3018 
  3019 lemma polar_Ex: "\<exists>r a. x = r * cos a & y = r * sin a"
  3020 apply (rule_tac x=0 and y=y in linorder_cases)
  3021 apply (erule polar_ex1)
  3022 apply (rule_tac x=x in exI, rule_tac x=0 in exI, simp)
  3023 apply (erule polar_ex2)
  3024 done
  3025 
  3026 end