src/HOL/Tools/datatype_package.ML
author wenzelm
Wed Apr 05 21:05:20 2000 +0200 (2000-04-05)
changeset 8672 1f51c411da5a
parent 8645 40036a2ab646
child 8686 5893f2952e4f
permissions -rw-r--r--
induct/case_tac emulation: optional rule;
add_cases_induct: fixed case names;
     1 (*  Title:      HOL/Tools/datatype_package.ML
     2     ID:         $Id$
     3     Author:     Stefan Berghofer
     4     Copyright   1998  TU Muenchen
     5 
     6 Datatype package for Isabelle/HOL.
     7 *)
     8 
     9 signature BASIC_DATATYPE_PACKAGE =
    10 sig
    11   val induct_tac : string -> int -> tactic
    12   val case_tac : string -> int -> tactic
    13   val distinct_simproc : simproc
    14 end;
    15 
    16 signature DATATYPE_PACKAGE =
    17 sig
    18   include BASIC_DATATYPE_PACKAGE
    19   val quiet_mode : bool ref
    20   val add_datatype : bool -> string list -> (string list * bstring * mixfix *
    21     (bstring * string list * mixfix) list) list -> theory -> theory *
    22       {distinct : thm list list,
    23        inject : thm list list,
    24        exhaustion : thm list,
    25        rec_thms : thm list,
    26        case_thms : thm list list,
    27        split_thms : (thm * thm) list,
    28        induction : thm,
    29        size : thm list,
    30        simps : thm list}
    31   val add_datatype_i : bool -> string list -> (string list * bstring * mixfix *
    32     (bstring * typ list * mixfix) list) list -> theory -> theory *
    33       {distinct : thm list list,
    34        inject : thm list list,
    35        exhaustion : thm list,
    36        rec_thms : thm list,
    37        case_thms : thm list list,
    38        split_thms : (thm * thm) list,
    39        induction : thm,
    40        size : thm list,
    41        simps : thm list}
    42   val rep_datatype_i : string list option -> (thm * theory attribute list) list list ->
    43     (thm * theory attribute list) list list -> (thm * theory attribute list) -> theory -> theory *
    44       {distinct : thm list list,
    45        inject : thm list list,
    46        exhaustion : thm list,
    47        rec_thms : thm list,
    48        case_thms : thm list list,
    49        split_thms : (thm * thm) list,
    50        induction : thm,
    51        size : thm list,
    52        simps : thm list}
    53   val rep_datatype : string list option -> (xstring * Args.src list) list list ->
    54     (xstring * Args.src list) list list -> xstring * Args.src list -> theory -> theory *
    55       {distinct : thm list list,
    56        inject : thm list list,
    57        exhaustion : thm list,
    58        rec_thms : thm list,
    59        case_thms : thm list list,
    60        split_thms : (thm * thm) list,
    61        induction : thm,
    62        size : thm list,
    63        simps : thm list}
    64   val get_datatypes : theory -> DatatypeAux.datatype_info Symtab.table
    65   val print_datatypes : theory -> unit
    66   val datatype_info_sg : Sign.sg -> string -> DatatypeAux.datatype_info option
    67   val datatype_info : theory -> string -> DatatypeAux.datatype_info option
    68   val datatype_info_sg_err : Sign.sg -> string -> DatatypeAux.datatype_info
    69   val datatype_info_err : theory -> string -> DatatypeAux.datatype_info
    70   val constrs_of : theory -> string -> term list option
    71   val constrs_of_sg : Sign.sg -> string -> term list option
    72   val case_const_of : theory -> string -> term option
    73   val setup: (theory -> theory) list
    74 end;
    75 
    76 structure DatatypePackage : DATATYPE_PACKAGE =
    77 struct
    78 
    79 open DatatypeAux;
    80 
    81 val quiet_mode = quiet_mode;
    82 
    83 
    84 (* data kind 'HOL/datatypes' *)
    85 
    86 structure DatatypesArgs =
    87 struct
    88   val name = "HOL/datatypes";
    89   type T = datatype_info Symtab.table;
    90 
    91   val empty = Symtab.empty;
    92   val copy = I;
    93   val prep_ext = I;
    94   val merge: T * T -> T = Symtab.merge (K true);
    95 
    96   fun print sg tab =
    97     Pretty.writeln (Pretty.strs ("datatypes:" ::
    98       map #1 (Sign.cond_extern_table sg Sign.typeK tab)));
    99 end;
   100 
   101 structure DatatypesData = TheoryDataFun(DatatypesArgs);
   102 val get_datatypes_sg = DatatypesData.get_sg;
   103 val get_datatypes = DatatypesData.get;
   104 val put_datatypes = DatatypesData.put;
   105 val print_datatypes = DatatypesData.print;
   106 
   107 
   108 (** theory information about datatypes **)
   109 
   110 fun datatype_info_sg sg name = Symtab.lookup (get_datatypes_sg sg, name);
   111 
   112 fun datatype_info_sg_err sg name = (case datatype_info_sg sg name of
   113       Some info => info
   114     | None => error ("Unknown datatype " ^ quote name));
   115 
   116 val datatype_info = datatype_info_sg o Theory.sign_of;
   117 
   118 fun datatype_info_err thy name = (case datatype_info thy name of
   119       Some info => info
   120     | None => error ("Unknown datatype " ^ quote name));
   121 
   122 fun constrs_of_sg sg tname = (case datatype_info_sg sg tname of
   123    Some {index, descr, ...} =>
   124      let val (_, _, constrs) = the (assoc (descr, index))
   125      in Some (map (fn (cname, _) => Const (cname, the (Sign.const_type sg cname))) constrs)
   126      end
   127  | _ => None);
   128 
   129 val constrs_of = constrs_of_sg o Theory.sign_of;
   130 
   131 fun case_const_of thy tname = (case datatype_info thy tname of
   132    Some {case_name, ...} => Some (Const (case_name, the (Sign.const_type
   133      (Theory.sign_of thy) case_name)))
   134  | _ => None);
   135 
   136 fun find_tname var Bi =
   137   let val frees = map dest_Free (term_frees Bi)
   138       val params = Logic.strip_params Bi;
   139   in case assoc (frees @ params, var) of
   140        None => error ("No such variable in subgoal: " ^ quote var)
   141      | Some(Type (tn, _)) => tn
   142      | _ => error ("Cannot determine type of " ^ quote var)
   143   end;
   144 
   145 fun infer_tname state i aterm =
   146   let
   147     val sign = Thm.sign_of_thm state;
   148     val (_, _, Bi, _) = Thm.dest_state (state, i)
   149     val params = Logic.strip_params Bi;   (*params of subgoal i*)
   150     val params = rev (rename_wrt_term Bi params);   (*as they are printed*)
   151     val (types, sorts) = types_sorts state;
   152     fun types' (a, ~1) = (case assoc (params, a) of None => types(a, ~1) | sm => sm)
   153       | types' ixn = types ixn;
   154     val (ct, _) = read_def_cterm (sign, types', sorts) [] false (aterm, TypeInfer.logicT);
   155   in case #T (rep_cterm ct) of
   156        Type (tn, _) => tn
   157      | _ => error ("Cannot determine type of " ^ quote aterm)
   158   end;
   159 
   160 (*Warn if the (induction) variable occurs Free among the premises, which
   161   usually signals a mistake.  But calls the tactic either way!*)
   162 fun occs_in_prems tacf vars =
   163   SUBGOAL (fn (Bi, i) =>
   164            (if  exists (fn Free (a, _) => a mem vars)
   165                       (foldr add_term_frees (#2 (strip_context Bi), []))
   166              then warning "Induction variable occurs also among premises!"
   167              else ();
   168             tacf i));
   169 
   170 (* generic induction tactic for datatypes *)
   171 
   172 fun gen_induct_tac (vars, opt_rule) i state =
   173   let
   174     val (_, _, Bi, _) = dest_state (state, i);
   175     val {sign, ...} = rep_thm state;
   176     val (rule, rule_name) =
   177       (case opt_rule of
   178         Some r => (r, "Induction rule")
   179       | None =>
   180           let val tn = find_tname (hd vars) Bi
   181           in (#induction (datatype_info_sg_err sign tn), "Induction rule for type " ^ tn) end);
   182     val ind_vnames = map (fn (_ $ Var (ixn, _)) =>
   183       implode (tl (explode (Syntax.string_of_vname ixn))))
   184         (HOLogic.dest_conj (HOLogic.dest_Trueprop (Thm.concl_of rule)));
   185     val insts = (ind_vnames ~~ vars) handle LIST _ =>
   186       error (rule_name ^ " has different number of variables");
   187   in occs_in_prems (Tactic.res_inst_tac insts rule) vars i state end;
   188 
   189 fun induct_tac s = gen_induct_tac (Syntax.read_idents s, None);
   190 
   191 
   192 (* generic case tactic for datatypes *)
   193 
   194 fun case_inst_tac t rule i state =
   195   let
   196     val _ $ Var (ixn, _) $ _ = HOLogic.dest_Trueprop
   197       (hd (Logic.strip_assums_hyp (hd (Thm.prems_of rule))));
   198     val exh_vname = implode (tl (explode (Syntax.string_of_vname ixn)));
   199   in Tactic.res_inst_tac [(exh_vname, t)] rule i state end;
   200 
   201 fun gen_case_tac (t, Some rule) i state = case_inst_tac t rule i state
   202   | gen_case_tac (t, None) i state =
   203       let val tn = infer_tname state i t in
   204         if tn = HOLogic.boolN then Tactic.res_inst_tac [("P", t)] case_split_thm i state
   205         else case_inst_tac t (#exhaustion (datatype_info_sg_err (Thm.sign_of_thm state) tn)) i state
   206       end;
   207 
   208 fun case_tac t = gen_case_tac (t, None);
   209 
   210 
   211 
   212 (** Isar tactic emulations **)
   213 
   214 local
   215 
   216 val rule_spec = Scan.option (Scan.lift (Args.$$$ "rule" -- Args.$$$ ":") |-- Attrib.local_thm);
   217 
   218 fun tactic_syntax args tac =
   219   #2 oo Method.syntax (Args.goal_spec HEADGOAL -- (Scan.lift args -- rule_spec) >>
   220     (fn (quant, x) => Method.METHOD (fn facts => quant (Method.insert_tac facts THEN' tac x))));
   221 
   222 in
   223 
   224 val tactic_emulations =
   225  [("induct_tac", tactic_syntax (Scan.repeat1 Args.name) gen_induct_tac,
   226     "induct_tac emulation (dynamic instantiation!)"),
   227   ("case_tac", tactic_syntax Args.name gen_case_tac,
   228     "case_tac emulation (dynamic instantiation!)")];
   229 
   230 end;
   231 
   232 
   233 
   234 (** induct method setup **)
   235 
   236 (* case names *)
   237 
   238 local
   239 
   240 fun dt_recs (DtTFree _) = []
   241   | dt_recs (DtType (_, dts)) = flat (map dt_recs dts)
   242   | dt_recs (DtRec i) = [i];
   243 
   244 fun dt_cases (descr: descr) (_, args, constrs) =
   245   let
   246     fun the_bname i = Sign.base_name (#1 (the (assoc (descr, i))));
   247     val bnames = map the_bname (distinct (flat (map dt_recs args)));
   248   in map (fn (c, _) => space_implode "_" (Sign.base_name c :: bnames)) constrs end;
   249 
   250 
   251 fun induct_cases descr =
   252   DatatypeProp.indexify_names (flat (map (dt_cases descr) (map #2 descr)));
   253 
   254 fun exhaust_cases descr i = dt_cases descr (the (assoc (descr, i)));
   255 
   256 in
   257 
   258 fun mk_case_names_induct descr = RuleCases.case_names (induct_cases descr);
   259 
   260 fun mk_case_names_exhausts descr new =
   261   map (RuleCases.case_names o exhaust_cases descr o #1)
   262     (filter (fn ((_, (name, _, _))) => name mem_string new) descr);
   263 
   264 end;
   265 
   266 
   267 (* add_cases_induct *)
   268 
   269 fun add_cases_induct infos =
   270   let
   271     fun proj _ 1 thm = thm
   272       | proj i n thm =
   273           (if i + 1 < n then (fn th => th RS conjunct1) else I)
   274             (Library.funpow i (fn th => th RS conjunct2) thm)
   275           |> Drule.standard
   276           |> RuleCases.name (RuleCases.get thm);
   277 
   278     fun add (ths, (name, {index, descr, induction, exhaustion, ...}: datatype_info)) =
   279       (("", proj index (length descr) induction), [InductMethod.induct_type_global name]) ::
   280       (("", exhaustion), [InductMethod.cases_type_global name]) :: ths;
   281   in #1 o PureThy.add_thms (foldl add ([], infos)) end;
   282 
   283 
   284 
   285 (**** simplification procedure for showing distinctness of constructors ****)
   286 
   287 fun stripT (i, Type ("fun", [_, T])) = stripT (i + 1, T)
   288   | stripT p = p;
   289 
   290 fun stripC (i, f $ x) = stripC (i + 1, f)
   291   | stripC p = p;
   292 
   293 val distinctN = "constr_distinct";
   294 
   295 exception ConstrDistinct of term;
   296 
   297 fun distinct_proc sg _ (t as Const ("op =", _) $ t1 $ t2) =
   298   (case (stripC (0, t1), stripC (0, t2)) of
   299      ((i, Const (cname1, T1)), (j, Const (cname2, T2))) =>
   300          (case (stripT (0, T1), stripT (0, T2)) of
   301             ((i', Type (tname1, _)), (j', Type (tname2, _))) =>
   302                 if tname1 = tname2 andalso not (cname1 = cname2) andalso i = i' andalso j = j' then
   303                    (case (constrs_of_sg sg tname1) of
   304                       Some constrs => let val cnames = map (fst o dest_Const) constrs
   305                         in if cname1 mem cnames andalso cname2 mem cnames then
   306                              let val eq_t = Logic.mk_equals (t, Const ("False", HOLogic.boolT));
   307                                  val eq_ct = cterm_of sg eq_t;
   308                                  val Datatype_thy = theory "Datatype";
   309                                  val [In0_inject, In1_inject, In0_not_In1, In1_not_In0] =
   310                                    map (get_thm Datatype_thy)
   311                                      ["In0_inject", "In1_inject", "In0_not_In1", "In1_not_In0"]
   312                              in (case (#distinct (datatype_info_sg_err sg tname1)) of
   313                                  QuickAndDirty => Some (Thm.invoke_oracle
   314                                    Datatype_thy distinctN (sg, ConstrDistinct eq_t))
   315                                | FewConstrs thms => Some (prove_goalw_cterm [] eq_ct (K
   316                                    [rtac eq_reflection 1, rtac iffI 1, rtac notE 1,
   317                                     atac 2, resolve_tac thms 1, etac FalseE 1]))
   318                                | ManyConstrs (thm, ss) => Some (prove_goalw_cterm [] eq_ct (K
   319                                    [rtac eq_reflection 1, rtac iffI 1, dtac thm 1,
   320                                     full_simp_tac ss 1,
   321                                     REPEAT (dresolve_tac [In0_inject, In1_inject] 1),
   322                                     eresolve_tac [In0_not_In1 RS notE, In1_not_In0 RS notE] 1,
   323                                     etac FalseE 1])))
   324                              end
   325                            else None
   326                         end
   327                     | None => None)
   328                 else None
   329           | _ => None)
   330    | _ => None)
   331   | distinct_proc sg _ _ = None;
   332 
   333 val distinct_pats = [Thm.read_cterm (Theory.sign_of HOL.thy) ("s = t", HOLogic.termT)];
   334 val distinct_simproc = mk_simproc distinctN distinct_pats distinct_proc;
   335 
   336 val dist_ss = HOL_ss addsimprocs [distinct_simproc];
   337 
   338 val simproc_setup =
   339   [Theory.add_oracle (distinctN, fn (_, ConstrDistinct t) => t),
   340    fn thy => (simpset_ref_of thy := simpset_of thy addsimprocs [distinct_simproc]; thy)];
   341 
   342 
   343 (* prepare types *)
   344 
   345 fun read_typ sign ((Ts, sorts), str) =
   346   let
   347     val T = Type.no_tvars (Sign.read_typ (sign, (curry assoc)
   348       (map (apfst (rpair ~1)) sorts)) str) handle TYPE (msg, _, _) => error msg
   349   in (Ts @ [T], add_typ_tfrees (T, sorts)) end;
   350 
   351 fun cert_typ sign ((Ts, sorts), raw_T) =
   352   let
   353     val T = Type.no_tvars (Sign.certify_typ sign raw_T) handle
   354       TYPE (msg, _, _) => error msg;
   355     val sorts' = add_typ_tfrees (T, sorts)
   356   in (Ts @ [T],
   357       case duplicates (map fst sorts') of
   358          [] => sorts'
   359        | dups => error ("Inconsistent sort constraints for " ^ commas dups))
   360   end;
   361 
   362 
   363 (**** make datatype info ****)
   364 
   365 fun make_dt_info descr induct reccomb_names rec_thms
   366   ((((((((i, (_, (tname, _, _))), case_name), case_thms),
   367     exhaustion_thm), distinct_thm), inject), nchotomy), case_cong) = (tname,
   368       {index = i,
   369        descr = descr,
   370        rec_names = reccomb_names,
   371        rec_rewrites = rec_thms,
   372        case_name = case_name,
   373        case_rewrites = case_thms,
   374        induction = induct,
   375        exhaustion = exhaustion_thm,
   376        distinct = distinct_thm,
   377        inject = inject,
   378        nchotomy = nchotomy,
   379        case_cong = case_cong});
   380 
   381 
   382 (********************* axiomatic introduction of datatypes ********************)
   383 
   384 fun add_and_get_axioms_atts label tnames attss ts thy =
   385   foldr (fn (((tname, atts), t), (thy', axs)) =>
   386     let
   387       val (thy'', [ax]) = thy' |>
   388         Theory.add_path tname |>
   389         PureThy.add_axioms_i [((label, t), atts)];
   390     in (Theory.parent_path thy'', ax::axs)
   391     end) (tnames ~~ attss ~~ ts, (thy, []));
   392 
   393 fun add_and_get_axioms label tnames =
   394   add_and_get_axioms_atts label tnames (replicate (length tnames) []);
   395 
   396 fun add_and_get_axiomss label tnames tss thy =
   397   foldr (fn ((tname, ts), (thy', axss)) =>
   398     let
   399       val (thy'', [axs]) = thy' |>
   400         Theory.add_path tname |>
   401         PureThy.add_axiomss_i [((label, ts), [])];
   402     in (Theory.parent_path thy'', axs::axss)
   403     end) (tnames ~~ tss, (thy, []));
   404 
   405 fun add_datatype_axm flat_names new_type_names descr sorts types_syntax constr_syntax dt_info
   406     case_names_induct case_names_exhausts thy =
   407   let
   408     val descr' = flat descr;
   409     val recTs = get_rec_types descr' sorts;
   410     val used = foldr add_typ_tfree_names (recTs, []);
   411     val newTs = take (length (hd descr), recTs);
   412 
   413     val no_size = exists (fn (_, (_, _, constrs)) => exists (fn (_, cargs) => exists
   414       (fn (DtType ("fun", [_, DtRec _])) => true | _ => false) cargs) constrs) descr';
   415 
   416     (**** declare new types and constants ****)
   417 
   418     val tyvars = map (fn (_, (_, Ts, _)) => map dest_DtTFree Ts) (hd descr);
   419 
   420     val constr_decls = map (fn (((_, (_, _, constrs)), T), constr_syntax') =>
   421       map (fn ((_, cargs), (cname, mx)) =>
   422         (cname, map (typ_of_dtyp descr' sorts) cargs ---> T, mx))
   423           (constrs ~~ constr_syntax')) ((hd descr) ~~ newTs ~~ constr_syntax);
   424 
   425     val rec_result_Ts = map TFree (variantlist (replicate (length descr') "'t", used) ~~
   426       replicate (length descr') HOLogic.termS);
   427 
   428     val reccomb_fn_Ts = flat (map (fn (i, (_, _, constrs)) =>
   429       map (fn (_, cargs) =>
   430         let
   431           val Ts = map (typ_of_dtyp descr' sorts) cargs;
   432           val recs = filter (is_rec_type o fst) (cargs ~~ Ts);
   433 
   434           fun mk_argT (DtRec k, _) = nth_elem (k, rec_result_Ts)
   435             | mk_argT (DtType ("fun", [_, DtRec k]), Type ("fun", [T, _])) =
   436                T --> nth_elem (k, rec_result_Ts);
   437 
   438           val argTs = Ts @ map mk_argT recs
   439         in argTs ---> nth_elem (i, rec_result_Ts)
   440         end) constrs) descr');
   441 
   442     val big_reccomb_name = (space_implode "_" new_type_names) ^ "_rec";
   443     val reccomb_names = if length descr' = 1 then [big_reccomb_name] else
   444       (map ((curry (op ^) (big_reccomb_name ^ "_")) o string_of_int)
   445         (1 upto (length descr')));
   446 
   447     val big_size_name = space_implode "_" new_type_names ^ "_size";
   448     val size_names = if length (flat (tl descr)) = 1 then [big_size_name] else
   449       map (fn i => big_size_name ^ "_" ^ string_of_int i)
   450         (1 upto length (flat (tl descr)));
   451 
   452     val freeT = TFree (variant used "'t", HOLogic.termS);
   453     val case_fn_Ts = map (fn (i, (_, _, constrs)) =>
   454       map (fn (_, cargs) =>
   455         let val Ts = map (typ_of_dtyp descr' sorts) cargs
   456         in Ts ---> freeT end) constrs) (hd descr);
   457 
   458     val case_names = map (fn s => (s ^ "_case")) new_type_names;
   459 
   460     val thy2' = thy |>
   461 
   462       (** new types **)
   463 
   464       curry (foldr (fn (((name, mx), tvs), thy') => thy' |>
   465           TypedefPackage.add_typedecls [(name, tvs, mx)]))
   466         (types_syntax ~~ tyvars) |>
   467       add_path flat_names (space_implode "_" new_type_names) |>
   468 
   469       (** primrec combinators **)
   470 
   471       Theory.add_consts_i (map (fn ((name, T), T') =>
   472         (name, reccomb_fn_Ts @ [T] ---> T', NoSyn))
   473           (reccomb_names ~~ recTs ~~ rec_result_Ts)) |>
   474 
   475       (** case combinators **)
   476 
   477       Theory.add_consts_i (map (fn ((name, T), Ts) =>
   478         (name, Ts @ [T] ---> freeT, NoSyn))
   479           (case_names ~~ newTs ~~ case_fn_Ts)) |>
   480       Theory.add_trrules_i (DatatypeProp.make_case_trrules new_type_names descr);
   481 
   482     val reccomb_names' = map (Sign.intern_const (Theory.sign_of thy2')) reccomb_names;
   483     val case_names' = map (Sign.intern_const (Theory.sign_of thy2')) case_names;
   484 
   485     val thy2 = thy2' |>
   486 
   487       (** size functions **)
   488 
   489       (if no_size then I else Theory.add_consts_i (map (fn (s, T) =>
   490         (Sign.base_name s, T --> HOLogic.natT, NoSyn))
   491           (size_names ~~ drop (length (hd descr), recTs)))) |>
   492 
   493       (** constructors **)
   494 
   495       parent_path flat_names |>
   496       curry (foldr (fn (((((_, (_, _, constrs)), T), tname),
   497         constr_syntax'), thy') => thy' |>
   498           add_path flat_names tname |>
   499             Theory.add_consts_i (map (fn ((_, cargs), (cname, mx)) =>
   500               (cname, map (typ_of_dtyp descr' sorts) cargs ---> T, mx))
   501                 (constrs ~~ constr_syntax')) |>
   502           parent_path flat_names))
   503             (hd descr ~~ newTs ~~ new_type_names ~~ constr_syntax);
   504 
   505     (**** introduction of axioms ****)
   506 
   507     val rec_axs = DatatypeProp.make_primrecs new_type_names descr sorts thy2;
   508     val size_axs = if no_size then [] else DatatypeProp.make_size new_type_names descr sorts thy2;
   509 
   510     val (thy3, (([induct], [rec_thms]), inject)) =
   511       thy2 |>
   512       Theory.add_path (space_implode "_" new_type_names) |>
   513       PureThy.add_axioms_i [(("induct", DatatypeProp.make_ind descr sorts), [case_names_induct])] |>>>
   514       PureThy.add_axiomss_i [(("recs", rec_axs), [])] |>>
   515       (if no_size then I else #1 o PureThy.add_axiomss_i [(("size", size_axs), [])]) |>>
   516       Theory.parent_path |>>>
   517       add_and_get_axiomss "inject" new_type_names
   518         (DatatypeProp.make_injs descr sorts);
   519     val size_thms = if no_size then [] else get_thms thy3 "size";
   520     val (thy4, distinct) = add_and_get_axiomss "distinct" new_type_names
   521       (DatatypeProp.make_distincts new_type_names descr sorts thy3) thy3;
   522 
   523     val exhaust_ts = DatatypeProp.make_casedists descr sorts;
   524     val (thy5, exhaustion) = add_and_get_axioms_atts "exhaust" new_type_names
   525       (map Library.single case_names_exhausts) exhaust_ts thy4;
   526     val (thy6, case_thms) = add_and_get_axiomss "cases" new_type_names
   527       (DatatypeProp.make_cases new_type_names descr sorts thy5) thy5;
   528     val (split_ts, split_asm_ts) = ListPair.unzip
   529       (DatatypeProp.make_splits new_type_names descr sorts thy6);
   530     val (thy7, split) = add_and_get_axioms "split" new_type_names split_ts thy6;
   531     val (thy8, split_asm) = add_and_get_axioms "split_asm" new_type_names
   532       split_asm_ts thy7;
   533     val (thy9, nchotomys) = add_and_get_axioms "nchotomy" new_type_names
   534       (DatatypeProp.make_nchotomys descr sorts) thy8;
   535     val (thy10, case_congs) = add_and_get_axioms "case_cong" new_type_names
   536       (DatatypeProp.make_case_congs new_type_names descr sorts thy9) thy9;
   537     val (thy11, weak_case_congs) = add_and_get_axioms "weak_case_cong" new_type_names
   538       (DatatypeProp.make_weak_case_congs new_type_names descr sorts thy10) thy10;
   539 
   540     val dt_infos = map (make_dt_info descr' induct reccomb_names' rec_thms)
   541       ((0 upto length (hd descr) - 1) ~~ (hd descr) ~~ case_names' ~~ case_thms ~~
   542         exhaustion ~~ replicate (length (hd descr)) QuickAndDirty ~~ inject ~~
   543           nchotomys ~~ case_congs);
   544 
   545     val simps = flat (distinct @ inject @ case_thms) @ size_thms @ rec_thms;
   546 
   547     val thy12 = thy11 |>
   548       Theory.add_path (space_implode "_" new_type_names) |>
   549       (#1 o PureThy.add_thmss [(("simps", simps), []),
   550         (("", flat case_thms @ size_thms @ rec_thms), [Simplifier.simp_add_global]),
   551         (("", flat (inject @ distinct)), [iff_add_global]),
   552         (("", weak_case_congs), [cong_add_global])]) |>
   553       put_datatypes (foldr Symtab.update (dt_infos, dt_info)) |>
   554       add_cases_induct dt_infos |>
   555       Theory.parent_path;
   556 
   557   in
   558     (thy12,
   559      {distinct = distinct,
   560       inject = inject,
   561       exhaustion = exhaustion,
   562       rec_thms = rec_thms,
   563       case_thms = case_thms,
   564       split_thms = split ~~ split_asm,
   565       induction = induct,
   566       size = size_thms,
   567       simps = simps})
   568   end;
   569 
   570 
   571 (******************* definitional introduction of datatypes *******************)
   572 
   573 fun add_datatype_def flat_names new_type_names descr sorts types_syntax constr_syntax dt_info
   574     case_names_induct case_names_exhausts thy =
   575   let
   576     val _ = message ("Proofs for datatype(s) " ^ commas_quote new_type_names);
   577 
   578     val (thy2, inject, distinct, dist_rewrites, simproc_dists, induct) = thy |>
   579       DatatypeRepProofs.representation_proofs flat_names dt_info new_type_names descr sorts
   580         types_syntax constr_syntax case_names_induct;
   581 
   582     val (thy3, casedist_thms) = DatatypeAbsProofs.prove_casedist_thms new_type_names descr
   583       sorts induct case_names_exhausts thy2;
   584     val (thy4, (reccomb_names, rec_thms)) = DatatypeAbsProofs.prove_primrec_thms
   585       flat_names new_type_names descr sorts dt_info inject dist_rewrites dist_ss induct thy3;
   586     val (thy6, (case_thms, case_names)) = DatatypeAbsProofs.prove_case_thms
   587       flat_names new_type_names descr sorts reccomb_names rec_thms thy4;
   588     val (thy7, split_thms) = DatatypeAbsProofs.prove_split_thms new_type_names
   589       descr sorts inject dist_rewrites casedist_thms case_thms thy6;
   590     val (thy8, nchotomys) = DatatypeAbsProofs.prove_nchotomys new_type_names
   591       descr sorts casedist_thms thy7;
   592     val (thy9, case_congs) = DatatypeAbsProofs.prove_case_congs new_type_names
   593       descr sorts nchotomys case_thms thy8;
   594     val (thy10, weak_case_congs) = DatatypeAbsProofs.prove_weak_case_congs new_type_names
   595       descr sorts thy9;
   596     val (thy11, size_thms) = DatatypeAbsProofs.prove_size_thms flat_names new_type_names
   597       descr sorts reccomb_names rec_thms thy10;
   598 
   599     val dt_infos = map (make_dt_info (flat descr) induct reccomb_names rec_thms)
   600       ((0 upto length (hd descr) - 1) ~~ (hd descr) ~~ case_names ~~ case_thms ~~
   601         casedist_thms ~~ simproc_dists ~~ inject ~~ nchotomys ~~ case_congs);
   602 
   603     val simps = flat (distinct @ inject @ case_thms) @ size_thms @ rec_thms;
   604 
   605     val thy12 = thy11 |>
   606       Theory.add_path (space_implode "_" new_type_names) |>
   607       (#1 o PureThy.add_thmss [(("simps", simps), []),
   608         (("", flat case_thms @ size_thms @ rec_thms), [Simplifier.simp_add_global]),
   609         (("", flat (inject @ distinct)), [iff_add_global]),
   610         (("", weak_case_congs), [Simplifier.change_global_ss (op addcongs)])]) |>
   611       put_datatypes (foldr Symtab.update (dt_infos, dt_info)) |>
   612       add_cases_induct dt_infos |>
   613       Theory.parent_path;
   614 
   615   in
   616     (thy12,
   617      {distinct = distinct,
   618       inject = inject,
   619       exhaustion = casedist_thms,
   620       rec_thms = rec_thms,
   621       case_thms = case_thms,
   622       split_thms = split_thms,
   623       induction = induct,
   624       size = size_thms,
   625       simps = simps})
   626   end;
   627 
   628 
   629 (*********************** declare existing type as datatype *********************)
   630 
   631 fun gen_rep_datatype apply_theorems alt_names raw_distinct raw_inject raw_induction thy0 =
   632   let
   633     fun app_thmss srcs thy = foldl_map (fn (thy, x) => apply_theorems x thy) (thy, srcs);
   634     fun app_thm src thy = apsnd Library.hd (apply_theorems [src] thy);
   635 
   636     val (((thy1, induction), inject), distinct) = thy0
   637       |> app_thmss raw_distinct
   638       |> apfst (app_thmss raw_inject)
   639       |> apfst (apfst (app_thm raw_induction));
   640     val sign = Theory.sign_of thy1;
   641 
   642     val induction' = freezeT induction;
   643 
   644     fun err t = error ("Ill-formed predicate in induction rule: " ^
   645       Sign.string_of_term sign t);
   646 
   647     fun get_typ (t as _ $ Var (_, Type (tname, Ts))) =
   648           ((tname, map dest_TFree Ts) handle TERM _ => err t)
   649       | get_typ t = err t;
   650 
   651     val dtnames = map get_typ (HOLogic.dest_conj (HOLogic.dest_Trueprop (Thm.concl_of induction')));
   652     val new_type_names = if_none alt_names (map fst dtnames);
   653 
   654     fun get_constr t = (case Logic.strip_assums_concl t of
   655         _ $ (_ $ t') => (case head_of t' of
   656             Const (cname, cT) => (case strip_type cT of
   657                 (Ts, Type (tname, _)) => (tname, (cname, map (dtyp_of_typ dtnames) Ts))
   658               | _ => err t)
   659           | _ => err t)
   660       | _ => err t);
   661 
   662     fun make_dt_spec [] _ _ = []
   663       | make_dt_spec ((tname, tvs)::dtnames') i constrs =
   664           let val (constrs', constrs'') = take_prefix (equal tname o fst) constrs
   665           in (i, (tname, map DtTFree tvs, map snd constrs'))::
   666             (make_dt_spec dtnames' (i + 1) constrs'')
   667           end;
   668 
   669     val descr = make_dt_spec dtnames 0 (map get_constr (prems_of induction'));
   670     val sorts = add_term_tfrees (concl_of induction', []);
   671     val dt_info = get_datatypes thy1;
   672 
   673     val case_names_induct = mk_case_names_induct descr;
   674     val case_names_exhausts = mk_case_names_exhausts descr (map #1 dtnames);
   675     
   676 
   677     val _ = message ("Proofs for datatype(s) " ^ commas_quote new_type_names);
   678 
   679     val (thy2, casedist_thms) = thy1 |>
   680       DatatypeAbsProofs.prove_casedist_thms new_type_names [descr] sorts induction
   681         case_names_exhausts;
   682     val (thy3, (reccomb_names, rec_thms)) = DatatypeAbsProofs.prove_primrec_thms
   683       false new_type_names [descr] sorts dt_info inject distinct dist_ss induction thy2;
   684     val (thy4, (case_thms, case_names)) = DatatypeAbsProofs.prove_case_thms false
   685       new_type_names [descr] sorts reccomb_names rec_thms thy3;
   686     val (thy5, split_thms) = DatatypeAbsProofs.prove_split_thms
   687       new_type_names [descr] sorts inject distinct casedist_thms case_thms thy4;
   688     val (thy6, nchotomys) = DatatypeAbsProofs.prove_nchotomys new_type_names
   689       [descr] sorts casedist_thms thy5;
   690     val (thy7, case_congs) = DatatypeAbsProofs.prove_case_congs new_type_names
   691       [descr] sorts nchotomys case_thms thy6;
   692     val (thy8, weak_case_congs) = DatatypeAbsProofs.prove_weak_case_congs new_type_names
   693       [descr] sorts thy7;
   694     val (thy9, size_thms) =
   695       if exists (equal "Arith") (Sign.stamp_names_of (Theory.sign_of thy8)) then
   696         DatatypeAbsProofs.prove_size_thms false new_type_names
   697           [descr] sorts reccomb_names rec_thms thy8
   698       else (thy8, []);
   699 
   700     val dt_infos = map (make_dt_info descr induction reccomb_names rec_thms)
   701       ((0 upto length descr - 1) ~~ descr ~~ case_names ~~ case_thms ~~
   702         casedist_thms ~~ map FewConstrs distinct ~~ inject ~~ nchotomys ~~ case_congs);
   703 
   704     val simps = flat (distinct @ inject @ case_thms) @ size_thms @ rec_thms;
   705 
   706     val (thy10, [induction']) = thy9 |>
   707       (#1 o store_thmss "inject" new_type_names inject) |>
   708       (#1 o store_thmss "distinct" new_type_names distinct) |>
   709       Theory.add_path (space_implode "_" new_type_names) |>
   710       PureThy.add_thms [(("induct", induction), [case_names_induct])] |>>
   711       (#1 o PureThy.add_thmss [(("simps", simps), []),
   712         (("", flat case_thms @ size_thms @ rec_thms), [Simplifier.simp_add_global]),
   713         (("", flat (inject @ distinct)), [iff_add_global]),
   714         (("", weak_case_congs), [Simplifier.change_global_ss (op addcongs)])]) |>>
   715       put_datatypes (foldr Symtab.update (dt_infos, dt_info)) |>>
   716       add_cases_induct dt_infos |>>
   717       Theory.parent_path;
   718 
   719   in
   720     (thy10,
   721      {distinct = distinct,
   722       inject = inject,
   723       exhaustion = casedist_thms,
   724       rec_thms = rec_thms,
   725       case_thms = case_thms,
   726       split_thms = split_thms,
   727       induction = induction',
   728       size = size_thms,
   729       simps = simps})
   730   end;
   731 
   732 val rep_datatype = gen_rep_datatype IsarThy.apply_theorems;
   733 val rep_datatype_i = gen_rep_datatype IsarThy.apply_theorems_i;
   734 
   735 
   736 (******************************** add datatype ********************************)
   737 
   738 fun gen_add_datatype prep_typ flat_names new_type_names dts thy =
   739   let
   740     val _ = Theory.requires thy "Datatype" "datatype definitions";
   741 
   742     (* this theory is used just for parsing *)
   743 
   744     val tmp_thy = thy |>
   745       Theory.copy |>
   746       Theory.add_types (map (fn (tvs, tname, mx, _) =>
   747         (tname, length tvs, mx)) dts);
   748 
   749     val sign = Theory.sign_of tmp_thy;
   750 
   751     val (tyvars, _, _, _)::_ = dts;
   752     val (new_dts, types_syntax) = ListPair.unzip (map (fn (tvs, tname, mx, _) =>
   753       let val full_tname = Sign.full_name sign (Syntax.type_name tname mx)
   754       in (case duplicates tvs of
   755             [] => if eq_set (tyvars, tvs) then ((full_tname, tvs), (tname, mx))
   756                   else error ("Mutually recursive datatypes must have same type parameters")
   757           | dups => error ("Duplicate parameter(s) for datatype " ^ full_tname ^
   758               " : " ^ commas dups))
   759       end) dts);
   760 
   761     val _ = (case duplicates (map fst new_dts) @ duplicates new_type_names of
   762       [] => () | dups => error ("Duplicate datatypes: " ^ commas dups));
   763 
   764     fun prep_dt_spec ((dts', constr_syntax, sorts, i), (tvs, tname, mx, constrs)) =
   765       let
   766         fun prep_constr ((constrs, constr_syntax', sorts'), (cname, cargs, mx')) =
   767           let
   768             val (cargs', sorts'') = foldl (prep_typ sign) (([], sorts'), cargs);
   769             val _ = (case foldr add_typ_tfree_names (cargs', []) \\ tvs of
   770                 [] => ()
   771               | vs => error ("Extra type variables on rhs: " ^ commas vs))
   772           in (constrs @ [((if flat_names then Sign.full_name sign else
   773                 Sign.full_name_path sign tname) (Syntax.const_name cname mx'),
   774                    map (dtyp_of_typ new_dts) cargs')],
   775               constr_syntax' @ [(cname, mx')], sorts'')
   776           end handle ERROR =>
   777             error ("The error above occured in constructor " ^ cname ^
   778               " of datatype " ^ tname);
   779 
   780         val (constrs', constr_syntax', sorts') =
   781           foldl prep_constr (([], [], sorts), constrs)
   782 
   783       in
   784         case duplicates (map fst constrs') of
   785            [] =>
   786              (dts' @ [(i, (Sign.full_name sign (Syntax.type_name tname mx),
   787                 map DtTFree tvs, constrs'))],
   788               constr_syntax @ [constr_syntax'], sorts', i + 1)
   789          | dups => error ("Duplicate constructors " ^ commas dups ^
   790              " in datatype " ^ tname)
   791       end;
   792 
   793     val (dts', constr_syntax, sorts', i) = foldl prep_dt_spec (([], [], [], 0), dts);
   794     val sorts = sorts' @ (map (rpair (Sign.defaultS sign)) (tyvars \\ map fst sorts'));
   795     val dt_info = get_datatypes thy;
   796     val (descr, _) = unfold_datatypes sign dts' sorts dt_info dts' i;
   797     val _ = check_nonempty descr;
   798 
   799     val descr' = flat descr;
   800     val case_names_induct = mk_case_names_induct descr';
   801     val case_names_exhausts = mk_case_names_exhausts descr' (map #1 new_dts);
   802   in
   803     (if (!quick_and_dirty) then add_datatype_axm else add_datatype_def)
   804       flat_names new_type_names descr sorts types_syntax constr_syntax dt_info
   805       case_names_induct case_names_exhausts thy
   806   end;
   807 
   808 val add_datatype_i = gen_add_datatype cert_typ;
   809 val add_datatype = gen_add_datatype read_typ;
   810 
   811 
   812 (** package setup **)
   813 
   814 (* setup theory *)
   815 
   816 val setup = [DatatypesData.init, Method.add_methods tactic_emulations] @ simproc_setup;
   817 
   818 
   819 (* outer syntax *)
   820 
   821 local structure P = OuterParse and K = OuterSyntax.Keyword in
   822 
   823 val datatype_decl =
   824   Scan.option (P.$$$ "(" |-- P.name --| P.$$$ ")") -- P.type_args -- P.name -- P.opt_infix --
   825     (P.$$$ "=" |-- P.enum1 "|" (P.name -- Scan.repeat P.typ -- P.opt_mixfix --| P.marg_comment));
   826 
   827 fun mk_datatype args =
   828   let
   829     val names = map (fn ((((None, _), t), _), _) => t | ((((Some t, _), _), _), _) => t) args;
   830     val specs = map (fn ((((_, vs), t), mx), cons) => (vs, t, mx, map (fn ((x, y), z) => (x, y, z)) cons)) args;
   831   in #1 o add_datatype false names specs end;
   832 
   833 val datatypeP =
   834   OuterSyntax.command "datatype" "define inductive datatypes" K.thy_decl
   835     (P.and_list1 datatype_decl >> (Toplevel.theory o mk_datatype));
   836 
   837 
   838 val rep_datatype_decl =
   839   Scan.option (Scan.repeat1 P.name) --
   840     Scan.optional (P.$$$ "distinct" |-- P.!!! (P.and_list1 P.xthms1)) [] --
   841     Scan.optional (P.$$$ "inject" |-- P.!!! (P.and_list1 P.xthms1)) [] --
   842     (P.$$$ "induction" |-- P.!!! P.xthm);
   843 
   844 fun mk_rep_datatype (((opt_ts, dss), iss), ind) = #1 o rep_datatype opt_ts dss iss ind;
   845 
   846 val rep_datatypeP =
   847   OuterSyntax.command "rep_datatype" "represent existing types inductively" K.thy_decl
   848     (rep_datatype_decl >> (Toplevel.theory o mk_rep_datatype));
   849 
   850 
   851 val _ = OuterSyntax.add_keywords ["distinct", "inject", "induction"];
   852 val _ = OuterSyntax.add_parsers [datatypeP, rep_datatypeP];
   853 
   854 end;
   855 
   856 
   857 end;
   858 
   859 structure BasicDatatypePackage: BASIC_DATATYPE_PACKAGE = DatatypePackage;
   860 open BasicDatatypePackage;