src/Pure/Isar/proof.ML
author wenzelm
Fri Feb 10 02:22:46 2006 +0100 (2006-02-10)
changeset 19000 1f73a35743f4
parent 18908 fb080097e436
child 19078 97971a84f0c7
permissions -rw-r--r--
tuned comment;
     1 (*  Title:      Pure/Isar/proof.ML
     2     ID:         $Id$
     3     Author:     Markus Wenzel, TU Muenchen
     4 
     5 The Isar/VM proof language interpreter: maintains a structured flow of
     6 context elements, goals, refinements, and facts.
     7 *)
     8 
     9 signature PROOF =
    10 sig
    11   type context (*= Context.proof*)
    12   type method (*= Method.method*)
    13   type state
    14   val init: context -> state
    15   val level: state -> int
    16   val assert_bottom: bool -> state -> state
    17   val context_of: state -> context
    18   val theory_of: state -> theory
    19   val sign_of: state -> theory    (*obsolete*)
    20   val map_context: (context -> context) -> state -> state
    21   val warn_extra_tfrees: state -> state -> state
    22   val add_binds_i: (indexname * term option) list -> state -> state
    23   val put_thms: string * thm list option -> state -> state
    24   val the_facts: state -> thm list
    25   val the_fact: state -> thm
    26   val put_facts: thm list option -> state -> state
    27   val assert_forward: state -> state
    28   val assert_chain: state -> state
    29   val assert_forward_or_chain: state -> state
    30   val assert_backward: state -> state
    31   val assert_no_chain: state -> state
    32   val enter_forward: state -> state
    33   val get_goal: state -> context * (thm list * thm)
    34   val show_main_goal: bool ref
    35   val verbose: bool ref
    36   val pretty_state: int -> state -> Pretty.T list
    37   val pretty_goals: bool -> state -> Pretty.T list
    38   val refine: Method.text -> state -> state Seq.seq
    39   val refine_end: Method.text -> state -> state Seq.seq
    40   val refine_insert: thm list -> state -> state
    41   val refine_goals: (context -> thm -> unit) -> context -> thm list -> state -> state Seq.seq
    42   val match_bind: (string list * string) list -> state -> state
    43   val match_bind_i: (term list * term) list -> state -> state
    44   val let_bind: (string list * string) list -> state -> state
    45   val let_bind_i: (term list * term) list -> state -> state
    46   val fix: (string * string option) list -> state -> state
    47   val fix_i: (string * typ option) list -> state -> state
    48   val assm: ProofContext.export ->
    49     ((string * Attrib.src list) * (string * (string list * string list)) list) list ->
    50     state -> state
    51   val assm_i: ProofContext.export ->
    52     ((string * attribute list) * (term * (term list * term list)) list) list
    53     -> state -> state
    54   val assume: ((string * Attrib.src list) * (string * (string list * string list)) list) list ->
    55     state -> state
    56   val assume_i: ((string * attribute list) * (term * (term list * term list)) list) list
    57     -> state -> state
    58   val presume: ((string * Attrib.src list) * (string * (string list * string list)) list) list
    59     -> state -> state
    60   val presume_i: ((string * attribute list) * (term * (term list * term list)) list) list
    61     -> state -> state
    62   val def: ((string * Attrib.src list) * (string * (string * string list))) list ->
    63     state -> state
    64   val def_i: ((string * attribute list) * (string * (term * term list))) list ->
    65     state -> state
    66   val chain: state -> state
    67   val chain_facts: thm list -> state -> state
    68   val get_thmss: state -> (thmref * Attrib.src list) list -> thm list
    69   val simple_note_thms: string -> thm list -> state -> state
    70   val note_thmss: ((string * Attrib.src list) *
    71     (thmref * Attrib.src list) list) list -> state -> state
    72   val note_thmss_i: ((string * attribute list) *
    73     (thm list * attribute list) list) list -> state -> state
    74   val from_thmss: ((thmref * Attrib.src list) list) list -> state -> state
    75   val from_thmss_i: ((thm list * attribute list) list) list -> state -> state
    76   val with_thmss: ((thmref * Attrib.src list) list) list -> state -> state
    77   val with_thmss_i: ((thm list * attribute list) list) list -> state -> state
    78   val using: ((thmref * Attrib.src list) list) list -> state -> state
    79   val using_i: ((thm list * attribute list) list) list -> state -> state
    80   val unfolding: ((thmref * Attrib.src list) list) list -> state -> state
    81   val unfolding_i: ((thm list * attribute list) list) list -> state -> state
    82   val invoke_case: string * string option list * Attrib.src list -> state -> state
    83   val invoke_case_i: string * string option list * attribute list -> state -> state
    84   val begin_block: state -> state
    85   val next_block: state -> state
    86   val end_block: state -> state Seq.seq
    87   val proof: Method.text option -> state -> state Seq.seq
    88   val defer: int option -> state -> state Seq.seq
    89   val prefer: int -> state -> state Seq.seq
    90   val apply: Method.text -> state -> state Seq.seq
    91   val apply_end: Method.text -> state -> state Seq.seq
    92   val goal_names: string option -> string -> string list -> string
    93   val local_goal: (context -> ((string * string) * (string * thm list) list) -> unit) ->
    94     (theory -> 'a -> attribute) ->
    95     (context * 'b list -> context * (term list list * (context -> context))) ->
    96     string -> Method.text option -> (thm list list -> state -> state Seq.seq) ->
    97     ((string * 'a list) * 'b) list -> state -> state
    98   val local_qed: Method.text option * bool -> state -> state Seq.seq
    99   val global_goal: (context -> (string * string) * (string * thm list) list -> unit) ->
   100     (theory -> 'a -> attribute) ->
   101     (context * 'b list -> context * (term list list * (context -> context))) ->
   102     string -> Method.text option -> (thm list list -> theory -> theory) ->
   103     string option -> string * 'a list -> ((string * 'a list) * 'b) list -> context -> state
   104   val global_qed: Method.text option * bool -> state -> context * theory
   105   val local_terminal_proof: Method.text * Method.text option -> state -> state Seq.seq
   106   val local_default_proof: state -> state Seq.seq
   107   val local_immediate_proof: state -> state Seq.seq
   108   val local_done_proof: state -> state Seq.seq
   109   val local_skip_proof: bool -> state -> state Seq.seq
   110   val global_terminal_proof: Method.text * Method.text option -> state -> context * theory
   111   val global_default_proof: state -> context * theory
   112   val global_immediate_proof: state -> context * theory
   113   val global_done_proof: state -> context * theory
   114   val global_skip_proof: bool -> state -> context * theory
   115   val have: Method.text option -> (thm list list -> state -> state Seq.seq) ->
   116     ((string * Attrib.src list) * (string * (string list * string list)) list) list ->
   117     bool -> state -> state
   118   val have_i: Method.text option -> (thm list list -> state -> state Seq.seq) ->
   119     ((string * attribute list) * (term * (term list * term list)) list) list ->
   120     bool -> state -> state
   121   val show: Method.text option -> (thm list list -> state -> state Seq.seq) ->
   122     ((string * Attrib.src list) * (string * (string list * string list)) list) list ->
   123     bool -> state -> state
   124   val show_i: Method.text option -> (thm list list -> state -> state Seq.seq) ->
   125     ((string * attribute list) * (term * (term list * term list)) list) list ->
   126     bool -> state -> state
   127   val theorem: string -> Method.text option -> (thm list list -> theory -> theory) ->
   128     string option -> string * Attrib.src list ->
   129     ((string * Attrib.src list) * (string * (string list * string list)) list) list ->
   130     context -> state
   131   val theorem_i: string -> Method.text option -> (thm list list -> theory -> theory) ->
   132     string option -> string * attribute list ->
   133     ((string * attribute list) * (term * (term list * term list)) list) list ->
   134     context -> state
   135 end;
   136 
   137 structure Proof: PROOF =
   138 struct
   139 
   140 type context = ProofContext.context;
   141 type method = Method.method;
   142 
   143 
   144 (** proof state **)
   145 
   146 (* datatype state *)
   147 
   148 datatype mode = Forward | Chain | Backward;
   149 
   150 datatype state =
   151   State of node Stack.T
   152 and node =
   153   Node of
   154    {context: context,
   155     facts: thm list option,
   156     mode: mode,
   157     goal: goal option}
   158 and goal =
   159   Goal of
   160    {statement: string * term list list,     (*goal kind and statement*)
   161     using: thm list,                        (*goal facts*)
   162     goal: thm,                              (*subgoals ==> statement*)
   163     before_qed: Method.text option,
   164     after_qed:
   165       (thm list list -> state -> state Seq.seq) *
   166       (thm list list -> theory -> theory)};
   167 
   168 fun make_goal (statement, using, goal, before_qed, after_qed) =
   169   Goal {statement = statement, using = using, goal = goal,
   170     before_qed = before_qed, after_qed = after_qed};
   171 
   172 fun make_node (context, facts, mode, goal) =
   173   Node {context = context, facts = facts, mode = mode, goal = goal};
   174 
   175 fun map_node f (Node {context, facts, mode, goal}) =
   176   make_node (f (context, facts, mode, goal));
   177 
   178 fun init ctxt = State (Stack.init (make_node (ctxt, NONE, Forward, NONE)));
   179 
   180 fun current (State st) = Stack.top st |> (fn Node node => node);
   181 fun map_current f (State st) = State (Stack.map (map_node f) st);
   182 
   183 
   184 
   185 (** basic proof state operations **)
   186 
   187 (* block structure *)
   188 
   189 fun open_block (State st) = State (Stack.push st);
   190 
   191 fun close_block (State st) = State (Stack.pop st)
   192   handle Empty => error "Unbalanced block parentheses";
   193 
   194 fun level (State st) = Stack.level st;
   195 
   196 fun assert_bottom b state =
   197   let val b' = (level state <= 2) in
   198     if b andalso not b' then error "Not at bottom of proof!"
   199     else if not b andalso b' then error "Already at bottom of proof!"
   200     else state
   201   end;
   202 
   203 
   204 (* context *)
   205 
   206 val context_of = #context o current;
   207 val theory_of = ProofContext.theory_of o context_of;
   208 val sign_of = theory_of;
   209 
   210 fun map_context f =
   211   map_current (fn (ctxt, facts, mode, goal) => (f ctxt, facts, mode, goal));
   212 
   213 fun map_context_result f state =
   214   f (context_of state) ||> (fn ctxt => map_context (K ctxt) state);
   215 
   216 val warn_extra_tfrees = map_context o ProofContext.warn_extra_tfrees o context_of;
   217 val add_binds_i = map_context o ProofContext.add_binds_i;
   218 val put_thms = map_context o ProofContext.put_thms;
   219 val get_case = ProofContext.get_case o context_of;
   220 
   221 
   222 (* facts *)
   223 
   224 val get_facts = #facts o current;
   225 
   226 fun the_facts state =
   227   (case get_facts state of SOME facts => facts
   228   | NONE => error "No current facts available");
   229 
   230 fun the_fact state =
   231   (case the_facts state of [thm] => thm
   232   | _ => error "Single theorem expected");
   233 
   234 fun put_facts facts =
   235   map_current (fn (ctxt, _, mode, goal) => (ctxt, facts, mode, goal))
   236   #> put_thms (AutoBind.thisN, facts);
   237 
   238 fun these_factss more_facts (named_factss, state) =
   239   (named_factss, state |> put_facts (SOME (List.concat (map snd named_factss) @ more_facts)));
   240 
   241 fun export_facts inner outer =
   242   (case get_facts inner of
   243     NONE => Seq.single (put_facts NONE outer)
   244   | SOME thms =>
   245       thms
   246       |> Seq.map_list (ProofContext.exports (context_of inner) (context_of outer))
   247       |> Seq.map (fn ths => put_facts (SOME ths) outer));
   248 
   249 
   250 (* mode *)
   251 
   252 val get_mode = #mode o current;
   253 fun put_mode mode = map_current (fn (ctxt, facts, _, goal) => (ctxt, facts, mode, goal));
   254 
   255 val mode_name = (fn Forward => "state" | Chain => "chain" | Backward => "prove");
   256 
   257 fun assert_mode pred state =
   258   let val mode = get_mode state in
   259     if pred mode then state
   260     else error ("Illegal application of proof command in " ^ quote (mode_name mode) ^ " mode")
   261   end;
   262 
   263 val assert_forward = assert_mode (equal Forward);
   264 val assert_chain = assert_mode (equal Chain);
   265 val assert_forward_or_chain = assert_mode (equal Forward orf equal Chain);
   266 val assert_backward = assert_mode (equal Backward);
   267 val assert_no_chain = assert_mode (not_equal Chain);
   268 
   269 val enter_forward = put_mode Forward;
   270 val enter_chain = put_mode Chain;
   271 val enter_backward = put_mode Backward;
   272 
   273 
   274 (* current goal *)
   275 
   276 fun current_goal state =
   277   (case current state of
   278     {context, goal = SOME (Goal goal), ...} => (context, goal)
   279   | _ => error "No current goal!");
   280 
   281 fun assert_current_goal g state =
   282   let val g' = can current_goal state in
   283     if g andalso not g' then error "No goal in this block!"
   284     else if not g andalso g' then error "Goal present in this block!"
   285     else state
   286   end;
   287 
   288 fun put_goal goal = map_current (fn (ctxt, using, mode, _) => (ctxt, using, mode, goal));
   289 
   290 val before_qed = #before_qed o #2 o current_goal;
   291 
   292 
   293 (* nested goal *)
   294 
   295 fun map_goal f g (State (Node {context, facts, mode, goal = SOME goal}, nodes)) =
   296       let
   297         val Goal {statement, using, goal, before_qed, after_qed} = goal;
   298         val goal' = make_goal (g (statement, using, goal, before_qed, after_qed));
   299       in State (make_node (f context, facts, mode, SOME goal'), nodes) end
   300   | map_goal f g (State (nd, node :: nodes)) =
   301       let val State (node', nodes') = map_goal f g (State (node, nodes))
   302       in map_context f (State (nd, node' :: nodes')) end
   303   | map_goal _ _ state = state;
   304 
   305 fun using_facts using = map_goal I (fn (statement, _, goal, before_qed, after_qed) =>
   306   (statement, using, goal, before_qed, after_qed));
   307 
   308 local
   309   fun find i state =
   310     (case try current_goal state of
   311       SOME (ctxt, goal) => (ctxt, (i, goal))
   312     | NONE => find (i + 1) (close_block state handle ERROR _ => error "No goal present"));
   313 in val find_goal = find 0 end;
   314 
   315 fun get_goal state =
   316   let val (ctxt, (_, {using, goal, ...})) = find_goal state
   317   in (ctxt, (using, goal)) end;
   318 
   319 
   320 
   321 (** pretty_state **)
   322 
   323 val show_main_goal = ref false;
   324 val verbose = ProofContext.verbose;
   325 
   326 val pretty_goals_local = Display.pretty_goals_aux o ProofContext.pp;
   327 
   328 fun pretty_facts _ _ NONE = []
   329   | pretty_facts s ctxt (SOME ths) =
   330       [Pretty.big_list (s ^ "this:") (map (ProofContext.pretty_thm ctxt) ths), Pretty.str ""];
   331 
   332 fun pretty_state nr state =
   333   let
   334     val {context, facts, mode, goal = _} = current state;
   335     val ref (_, _, bg) = Display.current_goals_markers;
   336 
   337     fun levels_up 0 = ""
   338       | levels_up 1 = "1 level up"
   339       | levels_up i = string_of_int i ^ " levels up";
   340 
   341     fun subgoals 0 = ""
   342       | subgoals 1 = "1 subgoal"
   343       | subgoals n = string_of_int n ^ " subgoals";
   344 
   345     fun description strs =
   346       (case filter_out (equal "") strs of [] => ""
   347       | strs' => enclose " (" ")" (commas strs'));
   348 
   349     fun prt_goal (SOME (ctxt, (i, {statement = (kind, _), using, goal, before_qed, after_qed}))) =
   350           pretty_facts "using " ctxt
   351             (if mode <> Backward orelse null using then NONE else SOME using) @
   352           [Pretty.str ("goal" ^ description [kind, levels_up (i div 2),
   353               subgoals (Thm.nprems_of goal)] ^ ":")] @
   354           pretty_goals_local ctxt bg (true, ! show_main_goal) (! Display.goals_limit) goal
   355       | prt_goal NONE = [];
   356 
   357     val prt_ctxt =
   358       if ! verbose orelse mode = Forward then ProofContext.pretty_context context
   359       else if mode = Backward then ProofContext.pretty_ctxt context
   360       else [];
   361   in
   362     [Pretty.str ("proof (" ^ mode_name mode ^ "): step " ^ string_of_int nr ^
   363       (if ! verbose then ", depth " ^ string_of_int (level state div 2 - 1) else "")),
   364       Pretty.str ""] @
   365     (if null prt_ctxt then [] else prt_ctxt @ [Pretty.str ""]) @
   366     (if ! verbose orelse mode = Forward then
   367        pretty_facts "" context facts @ prt_goal (try find_goal state)
   368      else if mode = Chain then pretty_facts "picking " context facts
   369      else prt_goal (try find_goal state))
   370   end;
   371 
   372 fun pretty_goals main state =
   373   let val (ctxt, (_, {goal, ...})) = find_goal state
   374   in pretty_goals_local ctxt "" (false, main) (! Display.goals_limit) goal end;
   375 
   376 
   377 
   378 (** proof steps **)
   379 
   380 (* refine via method *)
   381 
   382 local
   383 
   384 fun goalN i = "goal" ^ string_of_int i;
   385 fun goals st = map goalN (1 upto Thm.nprems_of st);
   386 
   387 fun no_goal_cases st = map (rpair NONE) (goals st);
   388 
   389 fun goal_cases st =
   390   RuleCases.make_common true (Thm.theory_of_thm st, Thm.prop_of st) (map (rpair []) (goals st));
   391 
   392 fun check_theory thy state =
   393   if subthy (thy, theory_of state) then state
   394   else error ("Bad theory of method result: " ^ Context.str_of_thy thy);
   395 
   396 fun apply_method current_context meth_fun state =
   397   let
   398     val (goal_ctxt, (_, {statement, using, goal, before_qed, after_qed})) = find_goal state;
   399     val meth = meth_fun (if current_context then context_of state else goal_ctxt);
   400   in
   401     Method.apply meth using goal |> Seq.map (fn (meth_cases, goal') =>
   402       state
   403       |> check_theory (Thm.theory_of_thm goal')
   404       |> map_goal
   405           (ProofContext.add_cases false (no_goal_cases goal @ goal_cases goal') #>
   406            ProofContext.add_cases true meth_cases)
   407           (K (statement, using, goal', before_qed, after_qed)))
   408   end;
   409 
   410 fun apply_text cc text state =
   411   let
   412     val thy = theory_of state;
   413 
   414     fun eval (Method.Basic m) = apply_method cc m
   415       | eval (Method.Source src) = apply_method cc (Method.method thy src)
   416       | eval (Method.Then txts) = Seq.EVERY (map eval txts)
   417       | eval (Method.Orelse txts) = Seq.FIRST (map eval txts)
   418       | eval (Method.Try txt) = Seq.TRY (eval txt)
   419       | eval (Method.Repeat1 txt) = Seq.REPEAT1 (eval txt);
   420   in eval text state end;
   421 
   422 in
   423 
   424 val refine = apply_text true;
   425 val refine_end = apply_text false;
   426 
   427 fun refine_insert [] = I
   428   | refine_insert ths = Seq.hd o refine (Method.Basic (K (Method.insert ths)));
   429 
   430 end;
   431 
   432 
   433 (* refine via sub-proof *)
   434 
   435 local
   436 
   437 fun refine_tac rule =
   438   Tactic.norm_hhf_tac THEN' Tactic.rtac rule THEN_ALL_NEW
   439     (Tactic.norm_hhf_tac THEN' (SUBGOAL (fn (goal, i) =>
   440       if can Logic.unprotect (Logic.strip_assums_concl goal) then
   441         Tactic.etac Drule.protectI i
   442       else all_tac)));
   443 
   444 fun refine_goal print_rule inner raw_rule state =
   445   let val (outer, (_, {statement, using, goal, before_qed, after_qed})) = find_goal state in
   446     raw_rule
   447     |> ProofContext.goal_exports inner outer
   448     |> Seq.maps (fn rule =>
   449       (print_rule outer rule;
   450         goal
   451         |> FINDGOAL (refine_tac rule)
   452         |> Seq.map (fn goal' =>
   453           map_goal I (K (statement, using, goal', before_qed, after_qed)) state)))
   454   end;
   455 
   456 in
   457 
   458 fun refine_goals print_rule inner raw_rules =
   459   Seq.EVERY (map (refine_goal print_rule inner) raw_rules);
   460 
   461 end;
   462 
   463 
   464 (* conclude_goal *)
   465 
   466 fun conclude_goal state goal propss =
   467   let
   468     val ctxt = context_of state;
   469 
   470     val ngoals = Thm.nprems_of goal;
   471     val _ = conditional (ngoals > 0) (fn () =>
   472       error (Pretty.string_of (Pretty.chunks
   473         (pretty_goals_local ctxt "" (true, ! show_main_goal) (! Display.goals_limit) goal @
   474           [Pretty.str (string_of_int ngoals ^ " unsolved goal(s)!")]))));
   475 
   476     val {hyps, thy, ...} = Thm.rep_thm goal;
   477     val bad_hyps = fold (remove (op aconv)) (ProofContext.assms_of ctxt) hyps;
   478     val _ = conditional (not (null bad_hyps)) (fn () => error ("Additional hypotheses:\n" ^
   479         cat_lines (map (ProofContext.string_of_term ctxt) bad_hyps)));
   480 
   481     val th = Goal.conclude goal;
   482     val _ = conditional (not (Pattern.matches thy
   483         (Logic.mk_conjunction_list2 propss, Thm.prop_of th))) (fn () =>
   484       error ("Proved a different theorem:\n" ^ ProofContext.string_of_thm ctxt th));
   485   in Drule.conj_elim_precise (map length propss) th end;
   486 
   487 
   488 
   489 (*** structured proof commands ***)
   490 
   491 (** context elements **)
   492 
   493 (* bindings *)
   494 
   495 local
   496 
   497 fun gen_bind bind args state =
   498   state
   499   |> assert_forward
   500   |> map_context (bind args #> snd)
   501   |> put_facts NONE;
   502 
   503 in
   504 
   505 val match_bind = gen_bind (ProofContext.match_bind false);
   506 val match_bind_i = gen_bind (ProofContext.match_bind_i false);
   507 val let_bind = gen_bind (ProofContext.match_bind true);
   508 val let_bind_i = gen_bind (ProofContext.match_bind_i true);
   509 
   510 end;
   511 
   512 
   513 (* fix *)
   514 
   515 local
   516 
   517 fun gen_fix add_fixes args =
   518   assert_forward
   519   #> map_context (snd o add_fixes (map Syntax.no_syn args))
   520   #> put_facts NONE;
   521 
   522 in
   523 
   524 val fix = gen_fix ProofContext.add_fixes;
   525 val fix_i = gen_fix ProofContext.add_fixes_i;
   526 
   527 end;
   528 
   529 
   530 (* assume etc. *)
   531 
   532 local
   533 
   534 fun gen_assume asm prep_att exp args state =
   535   state
   536   |> assert_forward
   537   |> map_context_result (asm exp (Attrib.map_specs (prep_att (theory_of state)) args))
   538   |> these_factss [] |> #2;
   539 
   540 in
   541 
   542 val assm      = gen_assume ProofContext.add_assms Attrib.attribute;
   543 val assm_i    = gen_assume ProofContext.add_assms_i (K I);
   544 val assume    = assm ProofContext.assume_export;
   545 val assume_i  = assm_i ProofContext.assume_export;
   546 val presume   = assm ProofContext.presume_export;
   547 val presume_i = assm_i ProofContext.presume_export;
   548 
   549 end;
   550 
   551 
   552 (* def *)
   553 
   554 local
   555 
   556 fun gen_def fix prep_att prep_binds args state =
   557   let
   558     val _ = assert_forward state;
   559     val thy = theory_of state;
   560 
   561     val ((raw_names, raw_atts), (xs, raw_rhss)) = args |> split_list |>> split_list ||> split_list;
   562     val names = map (fn ("", x) => Thm.def_name x | (name, _) => name) (raw_names ~~ xs);
   563     val atts = map (map (prep_att thy)) raw_atts;
   564     val (rhss, state') = state |> map_context_result (prep_binds false (map swap raw_rhss));
   565     val eqs = LocalDefs.mk_def (context_of state') (xs ~~ rhss);
   566   in
   567     state'
   568     |> fix (map (rpair NONE) xs)
   569     |> assm_i LocalDefs.def_export ((names ~~ atts) ~~ map (fn eq => [(eq, ([], []))]) eqs)
   570   end;
   571 
   572 in
   573 
   574 val def = gen_def fix Attrib.attribute ProofContext.match_bind;
   575 val def_i = gen_def fix_i (K I) ProofContext.match_bind_i;
   576 
   577 end;
   578 
   579 
   580 
   581 (** facts **)
   582 
   583 (* chain *)
   584 
   585 val chain =
   586   assert_forward
   587   #> tap the_facts
   588   #> enter_chain;
   589 
   590 fun chain_facts facts =
   591   put_facts (SOME facts)
   592   #> chain;
   593 
   594 
   595 (* note etc. *)
   596 
   597 fun no_binding args = map (pair ("", [])) args;
   598 
   599 local
   600 
   601 fun gen_thmss note_ctxt more_facts opt_chain opt_result prep_atts args state =
   602   state
   603   |> assert_forward
   604   |> map_context_result (note_ctxt (Attrib.map_facts (prep_atts (theory_of state)) args))
   605   |> these_factss (more_facts state)
   606   ||> opt_chain
   607   |> opt_result;
   608 
   609 in
   610 
   611 val note_thmss = gen_thmss ProofContext.note_thmss (K []) I #2 Attrib.attribute;
   612 val note_thmss_i = gen_thmss ProofContext.note_thmss_i (K []) I #2 (K I);
   613 
   614 val from_thmss =
   615   gen_thmss ProofContext.note_thmss (K []) chain #2 Attrib.attribute o no_binding;
   616 val from_thmss_i = gen_thmss ProofContext.note_thmss_i (K []) chain #2 (K I) o no_binding;
   617 
   618 val with_thmss =
   619   gen_thmss ProofContext.note_thmss the_facts chain #2 Attrib.attribute o no_binding;
   620 val with_thmss_i = gen_thmss ProofContext.note_thmss_i the_facts chain #2 (K I) o no_binding;
   621 
   622 val local_results =
   623   gen_thmss ProofContext.note_thmss_i (K []) I I (K I) o map (apsnd Thm.simple_fact);
   624 fun global_results kind = PureThy.note_thmss_i kind o map (apsnd Thm.simple_fact);
   625 
   626 fun get_thmss state srcs = the_facts (note_thmss [(("", []), srcs)] state);
   627 fun simple_note_thms name thms = note_thmss_i [((name, []), [(thms, [])])];
   628 
   629 end;
   630 
   631 
   632 (* using/unfolding *)
   633 
   634 local
   635 
   636 fun gen_using f g note prep_atts args state =
   637   state
   638   |> assert_backward
   639   |> map_context_result (note (Attrib.map_facts (prep_atts (theory_of state)) (no_binding args)))
   640   |> (fn (named_facts, state') =>
   641     state' |> map_goal I (fn (statement, using, goal, before_qed, after_qed) =>
   642       let
   643         val ctxt = context_of state';
   644         val ths = List.concat (map snd named_facts);
   645       in (statement, f ctxt ths using, g ctxt ths goal, before_qed, after_qed) end));
   646 
   647 fun append_using _ ths using = using @ ths;
   648 fun unfold_using ctxt ths = map (LocalDefs.unfold ctxt ths);
   649 val unfold_goals = LocalDefs.unfold_goals;
   650 
   651 in
   652 
   653 val using = gen_using append_using (K (K I)) ProofContext.note_thmss Attrib.attribute;
   654 val using_i = gen_using append_using (K (K I)) ProofContext.note_thmss_i (K I);
   655 val unfolding = gen_using unfold_using unfold_goals ProofContext.note_thmss Attrib.attribute;
   656 val unfolding_i = gen_using unfold_using unfold_goals ProofContext.note_thmss_i (K I);
   657 
   658 end;
   659 
   660 
   661 (* case *)
   662 
   663 local
   664 
   665 fun gen_invoke_case prep_att (name, xs, raw_atts) state =
   666   let
   667     val atts = map (prep_att (theory_of state)) raw_atts;
   668     val (asms, state') =
   669       map_context_result (ProofContext.apply_case (get_case state name xs)) state;
   670     val assumptions = asms |> map (fn (a, ts) => ((a, atts), map (rpair ([], [])) ts));
   671   in
   672     state'
   673     |> map_context (ProofContext.qualified_names #> ProofContext.no_base_names)
   674     |> assume_i assumptions
   675     |> add_binds_i AutoBind.no_facts
   676     |> map_context (ProofContext.restore_naming (context_of state))
   677     |> `the_facts |-> simple_note_thms name
   678   end;
   679 
   680 in
   681 
   682 val invoke_case = gen_invoke_case Attrib.attribute;
   683 val invoke_case_i = gen_invoke_case (K I);
   684 
   685 end;
   686 
   687 
   688 
   689 (** proof structure **)
   690 
   691 (* blocks *)
   692 
   693 val begin_block =
   694   assert_forward
   695   #> open_block
   696   #> put_goal NONE
   697   #> open_block;
   698 
   699 val next_block =
   700   assert_forward
   701   #> close_block
   702   #> open_block
   703   #> put_goal NONE
   704   #> put_facts NONE;
   705 
   706 fun end_block state =
   707   state
   708   |> assert_forward
   709   |> close_block
   710   |> assert_current_goal false
   711   |> close_block
   712   |> export_facts state;
   713 
   714 
   715 (* sub-proofs *)
   716 
   717 fun proof opt_text =
   718   assert_backward
   719   #> refine (the_default Method.default_text opt_text)
   720   #> Seq.map (using_facts [] #> enter_forward);
   721 
   722 fun end_proof bot txt =
   723   assert_forward
   724   #> assert_bottom bot
   725   #> close_block
   726   #> assert_current_goal true
   727   #> using_facts []
   728   #> `before_qed #-> (refine o the_default Method.succeed_text)
   729   #> Seq.maps (refine (Method.finish_text txt));
   730 
   731 
   732 (* unstructured refinement *)
   733 
   734 fun defer i = assert_no_chain #> refine (Method.Basic (K (Method.defer i)));
   735 fun prefer i = assert_no_chain #> refine (Method.Basic (K (Method.prefer i)));
   736 
   737 fun apply text = assert_backward #> refine text #> Seq.map (using_facts []);
   738 fun apply_end text = assert_forward #> refine_end text;
   739 
   740 
   741 
   742 (** goals **)
   743 
   744 (* goal names *)
   745 
   746 fun prep_names prep_att stmt =
   747   let
   748     val (names_attss, propp) = split_list (Attrib.map_specs prep_att stmt);
   749     val (names, attss) = split_list names_attss;
   750   in ((names, attss), propp) end;
   751 
   752 fun goal_names target name names =
   753   (case target of NONE => "" | SOME "" => "" | SOME loc => " (in " ^ loc ^ ")") ^
   754   (if name = "" then "" else " " ^ name) ^
   755   (case filter_out (equal "") names of [] => ""
   756   | nms => " " ^ enclose "(" ")" (space_implode " and " (Library.take (7, nms) @
   757       (if length nms > 7 then ["..."] else []))));
   758 
   759 
   760 (* generic goals *)
   761 
   762 fun check_tvars props state =
   763   (case fold Term.add_tvars props [] of [] => ()
   764   | tvars => error ("Goal statement contains illegal schematic type variable(s): " ^
   765       commas (map (ProofContext.string_of_typ (context_of state) o TVar) tvars)));
   766 
   767 fun check_vars props state =
   768   (case fold Term.add_vars props [] of [] => ()
   769   | vars => warning ("Goal statement contains unbound schematic variable(s): " ^
   770       commas (map (ProofContext.string_of_term (context_of state) o Var) vars)));
   771 
   772 fun generic_goal prepp kind before_qed after_qed raw_propp state =
   773   let
   774     val thy = theory_of state;
   775     val chaining = can assert_chain state;
   776 
   777     val ((propss, after_ctxt), goal_state) =
   778       state
   779       |> assert_forward_or_chain
   780       |> enter_forward
   781       |> open_block
   782       |> map_context_result (fn ctxt => swap (prepp (ctxt, raw_propp)));
   783     val props = List.concat propss;
   784 
   785     val goal = Goal.init (Thm.cterm_of thy (Logic.mk_conjunction_list2 propss));
   786     val after_qed' = after_qed |>> (fn after_local =>
   787       fn results => map_context after_ctxt #> after_local results);
   788   in
   789     goal_state
   790     |> tap (check_tvars props)
   791     |> tap (check_vars props)
   792     |> map_context (ProofContext.set_body true)
   793     |> put_goal (SOME (make_goal ((kind, propss), [], goal, before_qed, after_qed')))
   794     |> map_context (ProofContext.add_cases false (AutoBind.cases thy props))
   795     |> map_context (ProofContext.auto_bind_goal props)
   796     |> K chaining ? (`the_facts #-> using_facts)
   797     |> put_facts NONE
   798     |> open_block
   799     |> put_goal NONE
   800     |> enter_backward
   801     |> K (null props) ? (refine (Method.Basic Method.assumption) #> Seq.hd)
   802   end;
   803 
   804 fun generic_qed state =
   805   let
   806     val (goal_ctxt, {statement = (_, stmt), using = _, goal, before_qed = _, after_qed}) =
   807       current_goal state;
   808     val outer_state = state |> close_block;
   809     val outer_ctxt = context_of outer_state;
   810 
   811     val props =
   812       List.concat stmt
   813       |> ProofContext.generalize goal_ctxt outer_ctxt;
   814     val results =
   815       stmt
   816       |> conclude_goal state goal
   817       |> (Seq.map_list o Seq.map_list) (ProofContext.exports goal_ctxt outer_ctxt);
   818   in
   819     outer_state
   820     |> map_context (ProofContext.auto_bind_facts props)
   821     |> pair (after_qed, results)
   822   end;
   823 
   824 
   825 (* local goals *)
   826 
   827 fun local_goal print_results prep_att prepp kind before_qed after_qed stmt state =
   828   let
   829     val ((names, attss), propp) = prep_names (prep_att (theory_of state)) stmt;
   830 
   831     fun after_qed' results =
   832       local_results ((names ~~ attss) ~~ results)
   833       #-> (fn res => tap (fn st => print_results (context_of st) ((kind, ""), res) : unit))
   834       #> after_qed results;
   835   in
   836     state
   837     |> generic_goal prepp (kind ^ goal_names NONE "" names) before_qed (after_qed', K I) propp
   838     |> warn_extra_tfrees state
   839   end;
   840 
   841 fun local_qed txt =
   842   end_proof false txt
   843   #> Seq.map generic_qed
   844   #> Seq.maps (uncurry (fn ((after_qed, _), results) => Seq.lifts after_qed results));
   845 
   846 
   847 (* global goals *)
   848 
   849 fun global_goal print_results prep_att prepp
   850     kind before_qed after_qed target (name, raw_atts) stmt ctxt =
   851   let
   852     val thy = ProofContext.theory_of ctxt;
   853     val thy_ctxt = ProofContext.init thy;
   854 
   855     val atts = map (prep_att thy) raw_atts;
   856     val ((names, attss), propp) = prep_names (prep_att thy) stmt;
   857 
   858     fun store_results prfx res =
   859       K (prfx <> "") ? (Sign.add_path prfx #> Sign.no_base_names)
   860       #> global_results kind ((names ~~ attss) ~~ res)
   861       #-> (fn res' =>
   862         (print_results thy_ctxt ((kind, name), res') : unit;
   863           #2 o global_results kind [((name, atts), List.concat (map #2 res'))]))
   864       #> Sign.restore_naming thy;
   865 
   866     fun after_qed' results =
   867       (case target of NONE => I
   868       | SOME prfx => store_results (NameSpace.base prfx)
   869           (map (map (ProofContext.export_standard ctxt thy_ctxt
   870             #> Drule.strip_shyps_warning)) results))
   871       #> after_qed results;
   872   in
   873     init ctxt
   874     |> generic_goal (prepp #> ProofContext.auto_fixes) (kind ^ goal_names target name names)
   875       before_qed (K Seq.single, after_qed') propp
   876   end;
   877 
   878 fun check_result msg sq =
   879   (case Seq.pull sq of
   880     NONE => error msg
   881   | SOME res => Seq.cons res);
   882 
   883 fun global_qeds txt =
   884   end_proof true txt
   885   #> Seq.map generic_qed
   886   #> Seq.maps (fn (((_, after_qed), results), state) =>
   887     Seq.lift after_qed results (theory_of state)
   888     |> Seq.map (pair (context_of state)))
   889   |> Seq.DETERM;   (*backtracking may destroy theory!*)
   890 
   891 fun global_qed txt =
   892   global_qeds txt
   893   #> check_result "Failed to finish proof"
   894   #> Seq.hd;
   895 
   896 
   897 (* concluding steps *)
   898 
   899 fun local_terminal_proof (text, opt_text) =
   900   proof (SOME text) #> Seq.maps (local_qed (opt_text, true));
   901 
   902 val local_default_proof = local_terminal_proof (Method.default_text, NONE);
   903 val local_immediate_proof = local_terminal_proof (Method.this_text, NONE);
   904 val local_done_proof = proof (SOME Method.done_text) #> Seq.maps (local_qed (NONE, false));
   905 fun local_skip_proof int = local_terminal_proof (Method.sorry_text int, NONE);
   906 
   907 fun global_term_proof immed (text, opt_text) =
   908   proof (SOME text)
   909   #> check_result "Terminal proof method failed"
   910   #> Seq.maps (global_qeds (opt_text, immed))
   911   #> check_result "Failed to finish proof (after successful terminal method)"
   912   #> Seq.hd;
   913 
   914 val global_terminal_proof = global_term_proof true;
   915 val global_default_proof = global_terminal_proof (Method.default_text, NONE);
   916 val global_immediate_proof = global_terminal_proof (Method.this_text, NONE);
   917 val global_done_proof = global_term_proof false (Method.done_text, NONE);
   918 fun global_skip_proof int = global_terminal_proof (Method.sorry_text int, NONE);
   919 
   920 
   921 (* common goal statements *)
   922 
   923 local
   924 
   925 fun gen_have prep_att prepp before_qed after_qed stmt int =
   926   local_goal (ProofDisplay.print_results int) prep_att prepp "have" before_qed after_qed stmt;
   927 
   928 fun gen_show prep_att prepp before_qed after_qed stmt int state =
   929   let
   930     val testing = ref false;
   931     val rule = ref (NONE: thm option);
   932     fun fail_msg ctxt =
   933       "Local statement will fail to solve any pending goal" ::
   934       (case ! rule of NONE => [] | SOME th => [ProofDisplay.string_of_rule ctxt "Failed" th])
   935       |> cat_lines;
   936 
   937     fun print_results ctxt res =
   938       if ! testing then () else ProofDisplay.print_results int ctxt res;
   939     fun print_rule ctxt th =
   940       if ! testing then rule := SOME th
   941       else if int then priority (ProofDisplay.string_of_rule ctxt "Successful" th)
   942       else ();
   943     val test_proof =
   944       (Seq.pull oo local_skip_proof) true
   945       |> setmp testing true
   946       |> setmp proofs 0
   947       |> capture;
   948 
   949     fun after_qed' results =
   950       refine_goals print_rule (context_of state) (List.concat results)
   951       #> Seq.maps (after_qed results);
   952   in
   953     state
   954     |> local_goal print_results prep_att prepp "show" before_qed after_qed' stmt
   955     |> K int ? (fn goal_state =>
   956       (case test_proof goal_state of
   957         Result (SOME _) => goal_state
   958       | Result NONE => error (fail_msg (context_of goal_state))
   959       | Exn Interrupt => raise Interrupt
   960       | Exn exn => raise EXCEPTION (exn, fail_msg (context_of goal_state))))
   961   end;
   962 
   963 fun gen_theorem prep_att prepp kind before_qed after_qed target a =
   964   global_goal ProofDisplay.present_results prep_att prepp kind before_qed after_qed target a;
   965 
   966 in
   967 
   968 val have = gen_have Attrib.attribute ProofContext.bind_propp;
   969 val have_i = gen_have (K I) ProofContext.bind_propp_i;
   970 val show = gen_show Attrib.attribute ProofContext.bind_propp;
   971 val show_i = gen_show (K I) ProofContext.bind_propp_i;
   972 val theorem = gen_theorem Attrib.attribute ProofContext.bind_propp_schematic;
   973 val theorem_i = gen_theorem (K I) ProofContext.bind_propp_schematic_i;
   974 
   975 end;
   976 
   977 end;