src/HOL/Num.thy
author wenzelm
Mon May 27 21:00:30 2013 +0200 (2013-05-27)
changeset 52187 1f7b3aadec69
parent 52143 36ffe23b25f8
child 52210 0226035df99d
permissions -rw-r--r--
tuned;
     1 (*  Title:      HOL/Num.thy
     2     Author:     Florian Haftmann
     3     Author:     Brian Huffman
     4 *)
     5 
     6 header {* Binary Numerals *}
     7 
     8 theory Num
     9 imports Datatype
    10 begin
    11 
    12 subsection {* The @{text num} type *}
    13 
    14 datatype num = One | Bit0 num | Bit1 num
    15 
    16 text {* Increment function for type @{typ num} *}
    17 
    18 primrec inc :: "num \<Rightarrow> num" where
    19   "inc One = Bit0 One" |
    20   "inc (Bit0 x) = Bit1 x" |
    21   "inc (Bit1 x) = Bit0 (inc x)"
    22 
    23 text {* Converting between type @{typ num} and type @{typ nat} *}
    24 
    25 primrec nat_of_num :: "num \<Rightarrow> nat" where
    26   "nat_of_num One = Suc 0" |
    27   "nat_of_num (Bit0 x) = nat_of_num x + nat_of_num x" |
    28   "nat_of_num (Bit1 x) = Suc (nat_of_num x + nat_of_num x)"
    29 
    30 primrec num_of_nat :: "nat \<Rightarrow> num" where
    31   "num_of_nat 0 = One" |
    32   "num_of_nat (Suc n) = (if 0 < n then inc (num_of_nat n) else One)"
    33 
    34 lemma nat_of_num_pos: "0 < nat_of_num x"
    35   by (induct x) simp_all
    36 
    37 lemma nat_of_num_neq_0: " nat_of_num x \<noteq> 0"
    38   by (induct x) simp_all
    39 
    40 lemma nat_of_num_inc: "nat_of_num (inc x) = Suc (nat_of_num x)"
    41   by (induct x) simp_all
    42 
    43 lemma num_of_nat_double:
    44   "0 < n \<Longrightarrow> num_of_nat (n + n) = Bit0 (num_of_nat n)"
    45   by (induct n) simp_all
    46 
    47 text {*
    48   Type @{typ num} is isomorphic to the strictly positive
    49   natural numbers.
    50 *}
    51 
    52 lemma nat_of_num_inverse: "num_of_nat (nat_of_num x) = x"
    53   by (induct x) (simp_all add: num_of_nat_double nat_of_num_pos)
    54 
    55 lemma num_of_nat_inverse: "0 < n \<Longrightarrow> nat_of_num (num_of_nat n) = n"
    56   by (induct n) (simp_all add: nat_of_num_inc)
    57 
    58 lemma num_eq_iff: "x = y \<longleftrightarrow> nat_of_num x = nat_of_num y"
    59   apply safe
    60   apply (drule arg_cong [where f=num_of_nat])
    61   apply (simp add: nat_of_num_inverse)
    62   done
    63 
    64 lemma num_induct [case_names One inc]:
    65   fixes P :: "num \<Rightarrow> bool"
    66   assumes One: "P One"
    67     and inc: "\<And>x. P x \<Longrightarrow> P (inc x)"
    68   shows "P x"
    69 proof -
    70   obtain n where n: "Suc n = nat_of_num x"
    71     by (cases "nat_of_num x", simp_all add: nat_of_num_neq_0)
    72   have "P (num_of_nat (Suc n))"
    73   proof (induct n)
    74     case 0 show ?case using One by simp
    75   next
    76     case (Suc n)
    77     then have "P (inc (num_of_nat (Suc n)))" by (rule inc)
    78     then show "P (num_of_nat (Suc (Suc n)))" by simp
    79   qed
    80   with n show "P x"
    81     by (simp add: nat_of_num_inverse)
    82 qed
    83 
    84 text {*
    85   From now on, there are two possible models for @{typ num}:
    86   as positive naturals (rule @{text "num_induct"})
    87   and as digit representation (rules @{text "num.induct"}, @{text "num.cases"}).
    88 *}
    89 
    90 
    91 subsection {* Numeral operations *}
    92 
    93 instantiation num :: "{plus,times,linorder}"
    94 begin
    95 
    96 definition [code del]:
    97   "m + n = num_of_nat (nat_of_num m + nat_of_num n)"
    98 
    99 definition [code del]:
   100   "m * n = num_of_nat (nat_of_num m * nat_of_num n)"
   101 
   102 definition [code del]:
   103   "m \<le> n \<longleftrightarrow> nat_of_num m \<le> nat_of_num n"
   104 
   105 definition [code del]:
   106   "m < n \<longleftrightarrow> nat_of_num m < nat_of_num n"
   107 
   108 instance
   109   by (default, auto simp add: less_num_def less_eq_num_def num_eq_iff)
   110 
   111 end
   112 
   113 lemma nat_of_num_add: "nat_of_num (x + y) = nat_of_num x + nat_of_num y"
   114   unfolding plus_num_def
   115   by (intro num_of_nat_inverse add_pos_pos nat_of_num_pos)
   116 
   117 lemma nat_of_num_mult: "nat_of_num (x * y) = nat_of_num x * nat_of_num y"
   118   unfolding times_num_def
   119   by (intro num_of_nat_inverse mult_pos_pos nat_of_num_pos)
   120 
   121 lemma add_num_simps [simp, code]:
   122   "One + One = Bit0 One"
   123   "One + Bit0 n = Bit1 n"
   124   "One + Bit1 n = Bit0 (n + One)"
   125   "Bit0 m + One = Bit1 m"
   126   "Bit0 m + Bit0 n = Bit0 (m + n)"
   127   "Bit0 m + Bit1 n = Bit1 (m + n)"
   128   "Bit1 m + One = Bit0 (m + One)"
   129   "Bit1 m + Bit0 n = Bit1 (m + n)"
   130   "Bit1 m + Bit1 n = Bit0 (m + n + One)"
   131   by (simp_all add: num_eq_iff nat_of_num_add)
   132 
   133 lemma mult_num_simps [simp, code]:
   134   "m * One = m"
   135   "One * n = n"
   136   "Bit0 m * Bit0 n = Bit0 (Bit0 (m * n))"
   137   "Bit0 m * Bit1 n = Bit0 (m * Bit1 n)"
   138   "Bit1 m * Bit0 n = Bit0 (Bit1 m * n)"
   139   "Bit1 m * Bit1 n = Bit1 (m + n + Bit0 (m * n))"
   140   by (simp_all add: num_eq_iff nat_of_num_add
   141     nat_of_num_mult distrib_right distrib_left)
   142 
   143 lemma eq_num_simps:
   144   "One = One \<longleftrightarrow> True"
   145   "One = Bit0 n \<longleftrightarrow> False"
   146   "One = Bit1 n \<longleftrightarrow> False"
   147   "Bit0 m = One \<longleftrightarrow> False"
   148   "Bit1 m = One \<longleftrightarrow> False"
   149   "Bit0 m = Bit0 n \<longleftrightarrow> m = n"
   150   "Bit0 m = Bit1 n \<longleftrightarrow> False"
   151   "Bit1 m = Bit0 n \<longleftrightarrow> False"
   152   "Bit1 m = Bit1 n \<longleftrightarrow> m = n"
   153   by simp_all
   154 
   155 lemma le_num_simps [simp, code]:
   156   "One \<le> n \<longleftrightarrow> True"
   157   "Bit0 m \<le> One \<longleftrightarrow> False"
   158   "Bit1 m \<le> One \<longleftrightarrow> False"
   159   "Bit0 m \<le> Bit0 n \<longleftrightarrow> m \<le> n"
   160   "Bit0 m \<le> Bit1 n \<longleftrightarrow> m \<le> n"
   161   "Bit1 m \<le> Bit1 n \<longleftrightarrow> m \<le> n"
   162   "Bit1 m \<le> Bit0 n \<longleftrightarrow> m < n"
   163   using nat_of_num_pos [of n] nat_of_num_pos [of m]
   164   by (auto simp add: less_eq_num_def less_num_def)
   165 
   166 lemma less_num_simps [simp, code]:
   167   "m < One \<longleftrightarrow> False"
   168   "One < Bit0 n \<longleftrightarrow> True"
   169   "One < Bit1 n \<longleftrightarrow> True"
   170   "Bit0 m < Bit0 n \<longleftrightarrow> m < n"
   171   "Bit0 m < Bit1 n \<longleftrightarrow> m \<le> n"
   172   "Bit1 m < Bit1 n \<longleftrightarrow> m < n"
   173   "Bit1 m < Bit0 n \<longleftrightarrow> m < n"
   174   using nat_of_num_pos [of n] nat_of_num_pos [of m]
   175   by (auto simp add: less_eq_num_def less_num_def)
   176 
   177 text {* Rules using @{text One} and @{text inc} as constructors *}
   178 
   179 lemma add_One: "x + One = inc x"
   180   by (simp add: num_eq_iff nat_of_num_add nat_of_num_inc)
   181 
   182 lemma add_One_commute: "One + n = n + One"
   183   by (induct n) simp_all
   184 
   185 lemma add_inc: "x + inc y = inc (x + y)"
   186   by (simp add: num_eq_iff nat_of_num_add nat_of_num_inc)
   187 
   188 lemma mult_inc: "x * inc y = x * y + x"
   189   by (simp add: num_eq_iff nat_of_num_mult nat_of_num_add nat_of_num_inc)
   190 
   191 text {* The @{const num_of_nat} conversion *}
   192 
   193 lemma num_of_nat_One:
   194   "n \<le> 1 \<Longrightarrow> num_of_nat n = One"
   195   by (cases n) simp_all
   196 
   197 lemma num_of_nat_plus_distrib:
   198   "0 < m \<Longrightarrow> 0 < n \<Longrightarrow> num_of_nat (m + n) = num_of_nat m + num_of_nat n"
   199   by (induct n) (auto simp add: add_One add_One_commute add_inc)
   200 
   201 text {* A double-and-decrement function *}
   202 
   203 primrec BitM :: "num \<Rightarrow> num" where
   204   "BitM One = One" |
   205   "BitM (Bit0 n) = Bit1 (BitM n)" |
   206   "BitM (Bit1 n) = Bit1 (Bit0 n)"
   207 
   208 lemma BitM_plus_one: "BitM n + One = Bit0 n"
   209   by (induct n) simp_all
   210 
   211 lemma one_plus_BitM: "One + BitM n = Bit0 n"
   212   unfolding add_One_commute BitM_plus_one ..
   213 
   214 text {* Squaring and exponentiation *}
   215 
   216 primrec sqr :: "num \<Rightarrow> num" where
   217   "sqr One = One" |
   218   "sqr (Bit0 n) = Bit0 (Bit0 (sqr n))" |
   219   "sqr (Bit1 n) = Bit1 (Bit0 (sqr n + n))"
   220 
   221 primrec pow :: "num \<Rightarrow> num \<Rightarrow> num" where
   222   "pow x One = x" |
   223   "pow x (Bit0 y) = sqr (pow x y)" |
   224   "pow x (Bit1 y) = sqr (pow x y) * x"
   225 
   226 lemma nat_of_num_sqr: "nat_of_num (sqr x) = nat_of_num x * nat_of_num x"
   227   by (induct x, simp_all add: algebra_simps nat_of_num_add)
   228 
   229 lemma sqr_conv_mult: "sqr x = x * x"
   230   by (simp add: num_eq_iff nat_of_num_sqr nat_of_num_mult)
   231 
   232 
   233 subsection {* Binary numerals *}
   234 
   235 text {*
   236   We embed binary representations into a generic algebraic
   237   structure using @{text numeral}.
   238 *}
   239 
   240 class numeral = one + semigroup_add
   241 begin
   242 
   243 primrec numeral :: "num \<Rightarrow> 'a" where
   244   numeral_One: "numeral One = 1" |
   245   numeral_Bit0: "numeral (Bit0 n) = numeral n + numeral n" |
   246   numeral_Bit1: "numeral (Bit1 n) = numeral n + numeral n + 1"
   247 
   248 lemma numeral_code [code]:
   249   "numeral One = 1"
   250   "numeral (Bit0 n) = (let m = numeral n in m + m)"
   251   "numeral (Bit1 n) = (let m = numeral n in m + m + 1)"
   252   by (simp_all add: Let_def)
   253   
   254 lemma one_plus_numeral_commute: "1 + numeral x = numeral x + 1"
   255   apply (induct x)
   256   apply simp
   257   apply (simp add: add_assoc [symmetric], simp add: add_assoc)
   258   apply (simp add: add_assoc [symmetric], simp add: add_assoc)
   259   done
   260 
   261 lemma numeral_inc: "numeral (inc x) = numeral x + 1"
   262 proof (induct x)
   263   case (Bit1 x)
   264   have "numeral x + (1 + numeral x) + 1 = numeral x + (numeral x + 1) + 1"
   265     by (simp only: one_plus_numeral_commute)
   266   with Bit1 show ?case
   267     by (simp add: add_assoc)
   268 qed simp_all
   269 
   270 declare numeral.simps [simp del]
   271 
   272 abbreviation "Numeral1 \<equiv> numeral One"
   273 
   274 declare numeral_One [code_post]
   275 
   276 end
   277 
   278 text {* Negative numerals. *}
   279 
   280 class neg_numeral = numeral + group_add
   281 begin
   282 
   283 definition neg_numeral :: "num \<Rightarrow> 'a" where
   284   "neg_numeral k = - numeral k"
   285 
   286 end
   287 
   288 text {* Numeral syntax. *}
   289 
   290 syntax
   291   "_Numeral" :: "num_const \<Rightarrow> 'a"    ("_")
   292 
   293 parse_translation {*
   294   let
   295     fun num_of_int n =
   296       if n > 0 then
   297         (case IntInf.quotRem (n, 2) of
   298           (0, 1) => Syntax.const @{const_name One}
   299         | (n, 0) => Syntax.const @{const_name Bit0} $ num_of_int n
   300         | (n, 1) => Syntax.const @{const_name Bit1} $ num_of_int n)
   301       else raise Match
   302     val pos = Syntax.const @{const_name numeral}
   303     val neg = Syntax.const @{const_name neg_numeral}
   304     val one = Syntax.const @{const_name Groups.one}
   305     val zero = Syntax.const @{const_name Groups.zero}
   306     fun numeral_tr [(c as Const (@{syntax_const "_constrain"}, _)) $ t $ u] =
   307           c $ numeral_tr [t] $ u
   308       | numeral_tr [Const (num, _)] =
   309           let
   310             val {value, ...} = Lexicon.read_xnum num;
   311           in
   312             if value = 0 then zero else
   313             if value > 0
   314             then pos $ num_of_int value
   315             else neg $ num_of_int (~value)
   316           end
   317       | numeral_tr ts = raise TERM ("numeral_tr", ts);
   318   in [("_Numeral", K numeral_tr)] end
   319 *}
   320 
   321 typed_print_translation {*
   322   let
   323     fun dest_num (Const (@{const_syntax Bit0}, _) $ n) = 2 * dest_num n
   324       | dest_num (Const (@{const_syntax Bit1}, _) $ n) = 2 * dest_num n + 1
   325       | dest_num (Const (@{const_syntax One}, _)) = 1;
   326     fun num_tr' sign ctxt T [n] =
   327       let
   328         val k = dest_num n;
   329         val t' =
   330           Syntax.const @{syntax_const "_Numeral"} $
   331             Syntax.free (sign ^ string_of_int k);
   332       in
   333         (case T of
   334           Type (@{type_name fun}, [_, T']) =>
   335             if not (Printer.show_type_constraint ctxt) andalso can Term.dest_Type T' then t'
   336             else Syntax.const @{syntax_const "_constrain"} $ t' $ Syntax_Phases.term_of_typ ctxt T'
   337         | _ => if T = dummyT then t' else raise Match)
   338       end;
   339   in
   340    [(@{const_syntax numeral}, num_tr' ""),
   341     (@{const_syntax neg_numeral}, num_tr' "-")]
   342   end
   343 *}
   344 
   345 ML_file "Tools/numeral.ML"
   346 
   347 
   348 subsection {* Class-specific numeral rules *}
   349 
   350 text {*
   351   @{const numeral} is a morphism.
   352 *}
   353 
   354 subsubsection {* Structures with addition: class @{text numeral} *}
   355 
   356 context numeral
   357 begin
   358 
   359 lemma numeral_add: "numeral (m + n) = numeral m + numeral n"
   360   by (induct n rule: num_induct)
   361      (simp_all only: numeral_One add_One add_inc numeral_inc add_assoc)
   362 
   363 lemma numeral_plus_numeral: "numeral m + numeral n = numeral (m + n)"
   364   by (rule numeral_add [symmetric])
   365 
   366 lemma numeral_plus_one: "numeral n + 1 = numeral (n + One)"
   367   using numeral_add [of n One] by (simp add: numeral_One)
   368 
   369 lemma one_plus_numeral: "1 + numeral n = numeral (One + n)"
   370   using numeral_add [of One n] by (simp add: numeral_One)
   371 
   372 lemma one_add_one: "1 + 1 = 2"
   373   using numeral_add [of One One] by (simp add: numeral_One)
   374 
   375 lemmas add_numeral_special =
   376   numeral_plus_one one_plus_numeral one_add_one
   377 
   378 end
   379 
   380 subsubsection {*
   381   Structures with negation: class @{text neg_numeral}
   382 *}
   383 
   384 context neg_numeral
   385 begin
   386 
   387 text {* Numerals form an abelian subgroup. *}
   388 
   389 inductive is_num :: "'a \<Rightarrow> bool" where
   390   "is_num 1" |
   391   "is_num x \<Longrightarrow> is_num (- x)" |
   392   "\<lbrakk>is_num x; is_num y\<rbrakk> \<Longrightarrow> is_num (x + y)"
   393 
   394 lemma is_num_numeral: "is_num (numeral k)"
   395   by (induct k, simp_all add: numeral.simps is_num.intros)
   396 
   397 lemma is_num_add_commute:
   398   "\<lbrakk>is_num x; is_num y\<rbrakk> \<Longrightarrow> x + y = y + x"
   399   apply (induct x rule: is_num.induct)
   400   apply (induct y rule: is_num.induct)
   401   apply simp
   402   apply (rule_tac a=x in add_left_imp_eq)
   403   apply (rule_tac a=x in add_right_imp_eq)
   404   apply (simp add: add_assoc minus_add_cancel)
   405   apply (simp add: add_assoc [symmetric], simp add: add_assoc)
   406   apply (rule_tac a=x in add_left_imp_eq)
   407   apply (rule_tac a=x in add_right_imp_eq)
   408   apply (simp add: add_assoc minus_add_cancel add_minus_cancel)
   409   apply (simp add: add_assoc, simp add: add_assoc [symmetric])
   410   done
   411 
   412 lemma is_num_add_left_commute:
   413   "\<lbrakk>is_num x; is_num y\<rbrakk> \<Longrightarrow> x + (y + z) = y + (x + z)"
   414   by (simp only: add_assoc [symmetric] is_num_add_commute)
   415 
   416 lemmas is_num_normalize =
   417   add_assoc is_num_add_commute is_num_add_left_commute
   418   is_num.intros is_num_numeral
   419   diff_minus minus_add add_minus_cancel minus_add_cancel
   420 
   421 definition dbl :: "'a \<Rightarrow> 'a" where "dbl x = x + x"
   422 definition dbl_inc :: "'a \<Rightarrow> 'a" where "dbl_inc x = x + x + 1"
   423 definition dbl_dec :: "'a \<Rightarrow> 'a" where "dbl_dec x = x + x - 1"
   424 
   425 definition sub :: "num \<Rightarrow> num \<Rightarrow> 'a" where
   426   "sub k l = numeral k - numeral l"
   427 
   428 lemma numeral_BitM: "numeral (BitM n) = numeral (Bit0 n) - 1"
   429   by (simp only: BitM_plus_one [symmetric] numeral_add numeral_One eq_diff_eq)
   430 
   431 lemma dbl_simps [simp]:
   432   "dbl (neg_numeral k) = neg_numeral (Bit0 k)"
   433   "dbl 0 = 0"
   434   "dbl 1 = 2"
   435   "dbl (numeral k) = numeral (Bit0 k)"
   436   unfolding dbl_def neg_numeral_def numeral.simps
   437   by (simp_all add: minus_add)
   438 
   439 lemma dbl_inc_simps [simp]:
   440   "dbl_inc (neg_numeral k) = neg_numeral (BitM k)"
   441   "dbl_inc 0 = 1"
   442   "dbl_inc 1 = 3"
   443   "dbl_inc (numeral k) = numeral (Bit1 k)"
   444   unfolding dbl_inc_def neg_numeral_def numeral.simps numeral_BitM
   445   by (simp_all add: is_num_normalize)
   446 
   447 lemma dbl_dec_simps [simp]:
   448   "dbl_dec (neg_numeral k) = neg_numeral (Bit1 k)"
   449   "dbl_dec 0 = -1"
   450   "dbl_dec 1 = 1"
   451   "dbl_dec (numeral k) = numeral (BitM k)"
   452   unfolding dbl_dec_def neg_numeral_def numeral.simps numeral_BitM
   453   by (simp_all add: is_num_normalize)
   454 
   455 lemma sub_num_simps [simp]:
   456   "sub One One = 0"
   457   "sub One (Bit0 l) = neg_numeral (BitM l)"
   458   "sub One (Bit1 l) = neg_numeral (Bit0 l)"
   459   "sub (Bit0 k) One = numeral (BitM k)"
   460   "sub (Bit1 k) One = numeral (Bit0 k)"
   461   "sub (Bit0 k) (Bit0 l) = dbl (sub k l)"
   462   "sub (Bit0 k) (Bit1 l) = dbl_dec (sub k l)"
   463   "sub (Bit1 k) (Bit0 l) = dbl_inc (sub k l)"
   464   "sub (Bit1 k) (Bit1 l) = dbl (sub k l)"
   465   unfolding dbl_def dbl_dec_def dbl_inc_def sub_def
   466   unfolding neg_numeral_def numeral.simps numeral_BitM
   467   by (simp_all add: is_num_normalize)
   468 
   469 lemma add_neg_numeral_simps:
   470   "numeral m + neg_numeral n = sub m n"
   471   "neg_numeral m + numeral n = sub n m"
   472   "neg_numeral m + neg_numeral n = neg_numeral (m + n)"
   473   unfolding sub_def diff_minus neg_numeral_def numeral_add numeral.simps
   474   by (simp_all add: is_num_normalize)
   475 
   476 lemma add_neg_numeral_special:
   477   "1 + neg_numeral m = sub One m"
   478   "neg_numeral m + 1 = sub One m"
   479   unfolding sub_def diff_minus neg_numeral_def numeral_add numeral.simps
   480   by (simp_all add: is_num_normalize)
   481 
   482 lemma diff_numeral_simps:
   483   "numeral m - numeral n = sub m n"
   484   "numeral m - neg_numeral n = numeral (m + n)"
   485   "neg_numeral m - numeral n = neg_numeral (m + n)"
   486   "neg_numeral m - neg_numeral n = sub n m"
   487   unfolding neg_numeral_def sub_def diff_minus numeral_add numeral.simps
   488   by (simp_all add: is_num_normalize)
   489 
   490 lemma diff_numeral_special:
   491   "1 - numeral n = sub One n"
   492   "1 - neg_numeral n = numeral (One + n)"
   493   "numeral m - 1 = sub m One"
   494   "neg_numeral m - 1 = neg_numeral (m + One)"
   495   unfolding neg_numeral_def sub_def diff_minus numeral_add numeral.simps
   496   by (simp_all add: is_num_normalize)
   497 
   498 lemma minus_one: "- 1 = -1"
   499   unfolding neg_numeral_def numeral.simps ..
   500 
   501 lemma minus_numeral: "- numeral n = neg_numeral n"
   502   unfolding neg_numeral_def ..
   503 
   504 lemma minus_neg_numeral: "- neg_numeral n = numeral n"
   505   unfolding neg_numeral_def by simp
   506 
   507 lemmas minus_numeral_simps [simp] =
   508   minus_one minus_numeral minus_neg_numeral
   509 
   510 end
   511 
   512 subsubsection {*
   513   Structures with multiplication: class @{text semiring_numeral}
   514 *}
   515 
   516 class semiring_numeral = semiring + monoid_mult
   517 begin
   518 
   519 subclass numeral ..
   520 
   521 lemma numeral_mult: "numeral (m * n) = numeral m * numeral n"
   522   apply (induct n rule: num_induct)
   523   apply (simp add: numeral_One)
   524   apply (simp add: mult_inc numeral_inc numeral_add distrib_left)
   525   done
   526 
   527 lemma numeral_times_numeral: "numeral m * numeral n = numeral (m * n)"
   528   by (rule numeral_mult [symmetric])
   529 
   530 end
   531 
   532 subsubsection {*
   533   Structures with a zero: class @{text semiring_1}
   534 *}
   535 
   536 context semiring_1
   537 begin
   538 
   539 subclass semiring_numeral ..
   540 
   541 lemma of_nat_numeral [simp]: "of_nat (numeral n) = numeral n"
   542   by (induct n,
   543     simp_all only: numeral.simps numeral_class.numeral.simps of_nat_add of_nat_1)
   544 
   545 lemma mult_2: "2 * z = z + z"
   546   unfolding one_add_one [symmetric] distrib_right by simp
   547 
   548 lemma mult_2_right: "z * 2 = z + z"
   549   unfolding one_add_one [symmetric] distrib_left by simp
   550 
   551 end
   552 
   553 lemma nat_of_num_numeral [code_abbrev]:
   554   "nat_of_num = numeral"
   555 proof
   556   fix n
   557   have "numeral n = nat_of_num n"
   558     by (induct n) (simp_all add: numeral.simps)
   559   then show "nat_of_num n = numeral n" by simp
   560 qed
   561 
   562 lemma nat_of_num_code [code]:
   563   "nat_of_num One = 1"
   564   "nat_of_num (Bit0 n) = (let m = nat_of_num n in m + m)"
   565   "nat_of_num (Bit1 n) = (let m = nat_of_num n in Suc (m + m))"
   566   by (simp_all add: Let_def)
   567 
   568 subsubsection {*
   569   Equality: class @{text semiring_char_0}
   570 *}
   571 
   572 context semiring_char_0
   573 begin
   574 
   575 lemma numeral_eq_iff: "numeral m = numeral n \<longleftrightarrow> m = n"
   576   unfolding of_nat_numeral [symmetric] nat_of_num_numeral [symmetric]
   577     of_nat_eq_iff num_eq_iff ..
   578 
   579 lemma numeral_eq_one_iff: "numeral n = 1 \<longleftrightarrow> n = One"
   580   by (rule numeral_eq_iff [of n One, unfolded numeral_One])
   581 
   582 lemma one_eq_numeral_iff: "1 = numeral n \<longleftrightarrow> One = n"
   583   by (rule numeral_eq_iff [of One n, unfolded numeral_One])
   584 
   585 lemma numeral_neq_zero: "numeral n \<noteq> 0"
   586   unfolding of_nat_numeral [symmetric] nat_of_num_numeral [symmetric]
   587   by (simp add: nat_of_num_pos)
   588 
   589 lemma zero_neq_numeral: "0 \<noteq> numeral n"
   590   unfolding eq_commute [of 0] by (rule numeral_neq_zero)
   591 
   592 lemmas eq_numeral_simps [simp] =
   593   numeral_eq_iff
   594   numeral_eq_one_iff
   595   one_eq_numeral_iff
   596   numeral_neq_zero
   597   zero_neq_numeral
   598 
   599 end
   600 
   601 subsubsection {*
   602   Comparisons: class @{text linordered_semidom}
   603 *}
   604 
   605 text {*  Could be perhaps more general than here. *}
   606 
   607 context linordered_semidom
   608 begin
   609 
   610 lemma numeral_le_iff: "numeral m \<le> numeral n \<longleftrightarrow> m \<le> n"
   611 proof -
   612   have "of_nat (numeral m) \<le> of_nat (numeral n) \<longleftrightarrow> m \<le> n"
   613     unfolding less_eq_num_def nat_of_num_numeral of_nat_le_iff ..
   614   then show ?thesis by simp
   615 qed
   616 
   617 lemma one_le_numeral: "1 \<le> numeral n"
   618 using numeral_le_iff [of One n] by (simp add: numeral_One)
   619 
   620 lemma numeral_le_one_iff: "numeral n \<le> 1 \<longleftrightarrow> n \<le> One"
   621 using numeral_le_iff [of n One] by (simp add: numeral_One)
   622 
   623 lemma numeral_less_iff: "numeral m < numeral n \<longleftrightarrow> m < n"
   624 proof -
   625   have "of_nat (numeral m) < of_nat (numeral n) \<longleftrightarrow> m < n"
   626     unfolding less_num_def nat_of_num_numeral of_nat_less_iff ..
   627   then show ?thesis by simp
   628 qed
   629 
   630 lemma not_numeral_less_one: "\<not> numeral n < 1"
   631   using numeral_less_iff [of n One] by (simp add: numeral_One)
   632 
   633 lemma one_less_numeral_iff: "1 < numeral n \<longleftrightarrow> One < n"
   634   using numeral_less_iff [of One n] by (simp add: numeral_One)
   635 
   636 lemma zero_le_numeral: "0 \<le> numeral n"
   637   by (induct n) (simp_all add: numeral.simps)
   638 
   639 lemma zero_less_numeral: "0 < numeral n"
   640   by (induct n) (simp_all add: numeral.simps add_pos_pos)
   641 
   642 lemma not_numeral_le_zero: "\<not> numeral n \<le> 0"
   643   by (simp add: not_le zero_less_numeral)
   644 
   645 lemma not_numeral_less_zero: "\<not> numeral n < 0"
   646   by (simp add: not_less zero_le_numeral)
   647 
   648 lemmas le_numeral_extra =
   649   zero_le_one not_one_le_zero
   650   order_refl [of 0] order_refl [of 1]
   651 
   652 lemmas less_numeral_extra =
   653   zero_less_one not_one_less_zero
   654   less_irrefl [of 0] less_irrefl [of 1]
   655 
   656 lemmas le_numeral_simps [simp] =
   657   numeral_le_iff
   658   one_le_numeral
   659   numeral_le_one_iff
   660   zero_le_numeral
   661   not_numeral_le_zero
   662 
   663 lemmas less_numeral_simps [simp] =
   664   numeral_less_iff
   665   one_less_numeral_iff
   666   not_numeral_less_one
   667   zero_less_numeral
   668   not_numeral_less_zero
   669 
   670 end
   671 
   672 subsubsection {*
   673   Multiplication and negation: class @{text ring_1}
   674 *}
   675 
   676 context ring_1
   677 begin
   678 
   679 subclass neg_numeral ..
   680 
   681 lemma mult_neg_numeral_simps:
   682   "neg_numeral m * neg_numeral n = numeral (m * n)"
   683   "neg_numeral m * numeral n = neg_numeral (m * n)"
   684   "numeral m * neg_numeral n = neg_numeral (m * n)"
   685   unfolding neg_numeral_def mult_minus_left mult_minus_right
   686   by (simp_all only: minus_minus numeral_mult)
   687 
   688 lemma mult_minus1 [simp]: "-1 * z = - z"
   689   unfolding neg_numeral_def numeral.simps mult_minus_left by simp
   690 
   691 lemma mult_minus1_right [simp]: "z * -1 = - z"
   692   unfolding neg_numeral_def numeral.simps mult_minus_right by simp
   693 
   694 end
   695 
   696 subsubsection {*
   697   Equality using @{text iszero} for rings with non-zero characteristic
   698 *}
   699 
   700 context ring_1
   701 begin
   702 
   703 definition iszero :: "'a \<Rightarrow> bool"
   704   where "iszero z \<longleftrightarrow> z = 0"
   705 
   706 lemma iszero_0 [simp]: "iszero 0"
   707   by (simp add: iszero_def)
   708 
   709 lemma not_iszero_1 [simp]: "\<not> iszero 1"
   710   by (simp add: iszero_def)
   711 
   712 lemma not_iszero_Numeral1: "\<not> iszero Numeral1"
   713   by (simp add: numeral_One)
   714 
   715 lemma iszero_neg_numeral [simp]:
   716   "iszero (neg_numeral w) \<longleftrightarrow> iszero (numeral w)"
   717   unfolding iszero_def neg_numeral_def
   718   by (rule neg_equal_0_iff_equal)
   719 
   720 lemma eq_iff_iszero_diff: "x = y \<longleftrightarrow> iszero (x - y)"
   721   unfolding iszero_def by (rule eq_iff_diff_eq_0)
   722 
   723 text {* The @{text "eq_numeral_iff_iszero"} lemmas are not declared
   724 @{text "[simp]"} by default, because for rings of characteristic zero,
   725 better simp rules are possible. For a type like integers mod @{text
   726 "n"}, type-instantiated versions of these rules should be added to the
   727 simplifier, along with a type-specific rule for deciding propositions
   728 of the form @{text "iszero (numeral w)"}.
   729 
   730 bh: Maybe it would not be so bad to just declare these as simp
   731 rules anyway? I should test whether these rules take precedence over
   732 the @{text "ring_char_0"} rules in the simplifier.
   733 *}
   734 
   735 lemma eq_numeral_iff_iszero:
   736   "numeral x = numeral y \<longleftrightarrow> iszero (sub x y)"
   737   "numeral x = neg_numeral y \<longleftrightarrow> iszero (numeral (x + y))"
   738   "neg_numeral x = numeral y \<longleftrightarrow> iszero (numeral (x + y))"
   739   "neg_numeral x = neg_numeral y \<longleftrightarrow> iszero (sub y x)"
   740   "numeral x = 1 \<longleftrightarrow> iszero (sub x One)"
   741   "1 = numeral y \<longleftrightarrow> iszero (sub One y)"
   742   "neg_numeral x = 1 \<longleftrightarrow> iszero (numeral (x + One))"
   743   "1 = neg_numeral y \<longleftrightarrow> iszero (numeral (One + y))"
   744   "numeral x = 0 \<longleftrightarrow> iszero (numeral x)"
   745   "0 = numeral y \<longleftrightarrow> iszero (numeral y)"
   746   "neg_numeral x = 0 \<longleftrightarrow> iszero (numeral x)"
   747   "0 = neg_numeral y \<longleftrightarrow> iszero (numeral y)"
   748   unfolding eq_iff_iszero_diff diff_numeral_simps diff_numeral_special
   749   by simp_all
   750 
   751 end
   752 
   753 subsubsection {*
   754   Equality and negation: class @{text ring_char_0}
   755 *}
   756 
   757 class ring_char_0 = ring_1 + semiring_char_0
   758 begin
   759 
   760 lemma not_iszero_numeral [simp]: "\<not> iszero (numeral w)"
   761   by (simp add: iszero_def)
   762 
   763 lemma neg_numeral_eq_iff: "neg_numeral m = neg_numeral n \<longleftrightarrow> m = n"
   764   by (simp only: neg_numeral_def neg_equal_iff_equal numeral_eq_iff)
   765 
   766 lemma numeral_neq_neg_numeral: "numeral m \<noteq> neg_numeral n"
   767   unfolding neg_numeral_def eq_neg_iff_add_eq_0
   768   by (simp add: numeral_plus_numeral)
   769 
   770 lemma neg_numeral_neq_numeral: "neg_numeral m \<noteq> numeral n"
   771   by (rule numeral_neq_neg_numeral [symmetric])
   772 
   773 lemma zero_neq_neg_numeral: "0 \<noteq> neg_numeral n"
   774   unfolding neg_numeral_def neg_0_equal_iff_equal by simp
   775 
   776 lemma neg_numeral_neq_zero: "neg_numeral n \<noteq> 0"
   777   unfolding neg_numeral_def neg_equal_0_iff_equal by simp
   778 
   779 lemma one_neq_neg_numeral: "1 \<noteq> neg_numeral n"
   780   using numeral_neq_neg_numeral [of One n] by (simp add: numeral_One)
   781 
   782 lemma neg_numeral_neq_one: "neg_numeral n \<noteq> 1"
   783   using neg_numeral_neq_numeral [of n One] by (simp add: numeral_One)
   784 
   785 lemmas eq_neg_numeral_simps [simp] =
   786   neg_numeral_eq_iff
   787   numeral_neq_neg_numeral neg_numeral_neq_numeral
   788   one_neq_neg_numeral neg_numeral_neq_one
   789   zero_neq_neg_numeral neg_numeral_neq_zero
   790 
   791 end
   792 
   793 subsubsection {*
   794   Structures with negation and order: class @{text linordered_idom}
   795 *}
   796 
   797 context linordered_idom
   798 begin
   799 
   800 subclass ring_char_0 ..
   801 
   802 lemma neg_numeral_le_iff: "neg_numeral m \<le> neg_numeral n \<longleftrightarrow> n \<le> m"
   803   by (simp only: neg_numeral_def neg_le_iff_le numeral_le_iff)
   804 
   805 lemma neg_numeral_less_iff: "neg_numeral m < neg_numeral n \<longleftrightarrow> n < m"
   806   by (simp only: neg_numeral_def neg_less_iff_less numeral_less_iff)
   807 
   808 lemma neg_numeral_less_zero: "neg_numeral n < 0"
   809   by (simp only: neg_numeral_def neg_less_0_iff_less zero_less_numeral)
   810 
   811 lemma neg_numeral_le_zero: "neg_numeral n \<le> 0"
   812   by (simp only: neg_numeral_def neg_le_0_iff_le zero_le_numeral)
   813 
   814 lemma not_zero_less_neg_numeral: "\<not> 0 < neg_numeral n"
   815   by (simp only: not_less neg_numeral_le_zero)
   816 
   817 lemma not_zero_le_neg_numeral: "\<not> 0 \<le> neg_numeral n"
   818   by (simp only: not_le neg_numeral_less_zero)
   819 
   820 lemma neg_numeral_less_numeral: "neg_numeral m < numeral n"
   821   using neg_numeral_less_zero zero_less_numeral by (rule less_trans)
   822 
   823 lemma neg_numeral_le_numeral: "neg_numeral m \<le> numeral n"
   824   by (simp only: less_imp_le neg_numeral_less_numeral)
   825 
   826 lemma not_numeral_less_neg_numeral: "\<not> numeral m < neg_numeral n"
   827   by (simp only: not_less neg_numeral_le_numeral)
   828 
   829 lemma not_numeral_le_neg_numeral: "\<not> numeral m \<le> neg_numeral n"
   830   by (simp only: not_le neg_numeral_less_numeral)
   831   
   832 lemma neg_numeral_less_one: "neg_numeral m < 1"
   833   by (rule neg_numeral_less_numeral [of m One, unfolded numeral_One])
   834 
   835 lemma neg_numeral_le_one: "neg_numeral m \<le> 1"
   836   by (rule neg_numeral_le_numeral [of m One, unfolded numeral_One])
   837 
   838 lemma not_one_less_neg_numeral: "\<not> 1 < neg_numeral m"
   839   by (simp only: not_less neg_numeral_le_one)
   840 
   841 lemma not_one_le_neg_numeral: "\<not> 1 \<le> neg_numeral m"
   842   by (simp only: not_le neg_numeral_less_one)
   843 
   844 lemma sub_non_negative:
   845   "sub n m \<ge> 0 \<longleftrightarrow> n \<ge> m"
   846   by (simp only: sub_def le_diff_eq) simp
   847 
   848 lemma sub_positive:
   849   "sub n m > 0 \<longleftrightarrow> n > m"
   850   by (simp only: sub_def less_diff_eq) simp
   851 
   852 lemma sub_non_positive:
   853   "sub n m \<le> 0 \<longleftrightarrow> n \<le> m"
   854   by (simp only: sub_def diff_le_eq) simp
   855 
   856 lemma sub_negative:
   857   "sub n m < 0 \<longleftrightarrow> n < m"
   858   by (simp only: sub_def diff_less_eq) simp
   859 
   860 lemmas le_neg_numeral_simps [simp] =
   861   neg_numeral_le_iff
   862   neg_numeral_le_numeral not_numeral_le_neg_numeral
   863   neg_numeral_le_zero not_zero_le_neg_numeral
   864   neg_numeral_le_one not_one_le_neg_numeral
   865 
   866 lemmas less_neg_numeral_simps [simp] =
   867   neg_numeral_less_iff
   868   neg_numeral_less_numeral not_numeral_less_neg_numeral
   869   neg_numeral_less_zero not_zero_less_neg_numeral
   870   neg_numeral_less_one not_one_less_neg_numeral
   871 
   872 lemma abs_numeral [simp]: "abs (numeral n) = numeral n"
   873   by simp
   874 
   875 lemma abs_neg_numeral [simp]: "abs (neg_numeral n) = numeral n"
   876   by (simp only: neg_numeral_def abs_minus_cancel abs_numeral)
   877 
   878 end
   879 
   880 subsubsection {*
   881   Natural numbers
   882 *}
   883 
   884 lemma Suc_1 [simp]: "Suc 1 = 2"
   885   unfolding Suc_eq_plus1 by (rule one_add_one)
   886 
   887 lemma Suc_numeral [simp]: "Suc (numeral n) = numeral (n + One)"
   888   unfolding Suc_eq_plus1 by (rule numeral_plus_one)
   889 
   890 definition pred_numeral :: "num \<Rightarrow> nat"
   891   where [code del]: "pred_numeral k = numeral k - 1"
   892 
   893 lemma numeral_eq_Suc: "numeral k = Suc (pred_numeral k)"
   894   unfolding pred_numeral_def by simp
   895 
   896 lemma eval_nat_numeral:
   897   "numeral One = Suc 0"
   898   "numeral (Bit0 n) = Suc (numeral (BitM n))"
   899   "numeral (Bit1 n) = Suc (numeral (Bit0 n))"
   900   by (simp_all add: numeral.simps BitM_plus_one)
   901 
   902 lemma pred_numeral_simps [simp]:
   903   "pred_numeral One = 0"
   904   "pred_numeral (Bit0 k) = numeral (BitM k)"
   905   "pred_numeral (Bit1 k) = numeral (Bit0 k)"
   906   unfolding pred_numeral_def eval_nat_numeral
   907   by (simp_all only: diff_Suc_Suc diff_0)
   908 
   909 lemma numeral_2_eq_2: "2 = Suc (Suc 0)"
   910   by (simp add: eval_nat_numeral)
   911 
   912 lemma numeral_3_eq_3: "3 = Suc (Suc (Suc 0))"
   913   by (simp add: eval_nat_numeral)
   914 
   915 lemma numeral_1_eq_Suc_0: "Numeral1 = Suc 0"
   916   by (simp only: numeral_One One_nat_def)
   917 
   918 lemma Suc_nat_number_of_add:
   919   "Suc (numeral v + n) = numeral (v + One) + n"
   920   by simp
   921 
   922 (*Maps #n to n for n = 1, 2*)
   923 lemmas numerals = numeral_One [where 'a=nat] numeral_2_eq_2
   924 
   925 text {* Comparisons involving @{term Suc}. *}
   926 
   927 lemma eq_numeral_Suc [simp]: "numeral k = Suc n \<longleftrightarrow> pred_numeral k = n"
   928   by (simp add: numeral_eq_Suc)
   929 
   930 lemma Suc_eq_numeral [simp]: "Suc n = numeral k \<longleftrightarrow> n = pred_numeral k"
   931   by (simp add: numeral_eq_Suc)
   932 
   933 lemma less_numeral_Suc [simp]: "numeral k < Suc n \<longleftrightarrow> pred_numeral k < n"
   934   by (simp add: numeral_eq_Suc)
   935 
   936 lemma less_Suc_numeral [simp]: "Suc n < numeral k \<longleftrightarrow> n < pred_numeral k"
   937   by (simp add: numeral_eq_Suc)
   938 
   939 lemma le_numeral_Suc [simp]: "numeral k \<le> Suc n \<longleftrightarrow> pred_numeral k \<le> n"
   940   by (simp add: numeral_eq_Suc)
   941 
   942 lemma le_Suc_numeral [simp]: "Suc n \<le> numeral k \<longleftrightarrow> n \<le> pred_numeral k"
   943   by (simp add: numeral_eq_Suc)
   944 
   945 lemma diff_Suc_numeral [simp]: "Suc n - numeral k = n - pred_numeral k"
   946   by (simp add: numeral_eq_Suc)
   947 
   948 lemma diff_numeral_Suc [simp]: "numeral k - Suc n = pred_numeral k - n"
   949   by (simp add: numeral_eq_Suc)
   950 
   951 lemma max_Suc_numeral [simp]:
   952   "max (Suc n) (numeral k) = Suc (max n (pred_numeral k))"
   953   by (simp add: numeral_eq_Suc)
   954 
   955 lemma max_numeral_Suc [simp]:
   956   "max (numeral k) (Suc n) = Suc (max (pred_numeral k) n)"
   957   by (simp add: numeral_eq_Suc)
   958 
   959 lemma min_Suc_numeral [simp]:
   960   "min (Suc n) (numeral k) = Suc (min n (pred_numeral k))"
   961   by (simp add: numeral_eq_Suc)
   962 
   963 lemma min_numeral_Suc [simp]:
   964   "min (numeral k) (Suc n) = Suc (min (pred_numeral k) n)"
   965   by (simp add: numeral_eq_Suc)
   966 
   967 text {* For @{term nat_case} and @{term nat_rec}. *}
   968 
   969 lemma nat_case_numeral [simp]:
   970   "nat_case a f (numeral v) = (let pv = pred_numeral v in f pv)"
   971   by (simp add: numeral_eq_Suc)
   972 
   973 lemma nat_case_add_eq_if [simp]:
   974   "nat_case a f ((numeral v) + n) = (let pv = pred_numeral v in f (pv + n))"
   975   by (simp add: numeral_eq_Suc)
   976 
   977 lemma nat_rec_numeral [simp]:
   978   "nat_rec a f (numeral v) =
   979     (let pv = pred_numeral v in f pv (nat_rec a f pv))"
   980   by (simp add: numeral_eq_Suc Let_def)
   981 
   982 lemma nat_rec_add_eq_if [simp]:
   983   "nat_rec a f (numeral v + n) =
   984     (let pv = pred_numeral v in f (pv + n) (nat_rec a f (pv + n)))"
   985   by (simp add: numeral_eq_Suc Let_def)
   986 
   987 text {* Case analysis on @{term "n < 2"} *}
   988 
   989 lemma less_2_cases: "n < 2 \<Longrightarrow> n = 0 \<or> n = Suc 0"
   990   by (auto simp add: numeral_2_eq_2)
   991 
   992 text {* Removal of Small Numerals: 0, 1 and (in additive positions) 2 *}
   993 text {* bh: Are these rules really a good idea? *}
   994 
   995 lemma add_2_eq_Suc [simp]: "2 + n = Suc (Suc n)"
   996   by simp
   997 
   998 lemma add_2_eq_Suc' [simp]: "n + 2 = Suc (Suc n)"
   999   by simp
  1000 
  1001 text {* Can be used to eliminate long strings of Sucs, but not by default. *}
  1002 
  1003 lemma Suc3_eq_add_3: "Suc (Suc (Suc n)) = 3 + n"
  1004   by simp
  1005 
  1006 lemmas nat_1_add_1 = one_add_one [where 'a=nat] (* legacy *)
  1007 
  1008 
  1009 subsection {* Numeral equations as default simplification rules *}
  1010 
  1011 declare (in numeral) numeral_One [simp]
  1012 declare (in numeral) numeral_plus_numeral [simp]
  1013 declare (in numeral) add_numeral_special [simp]
  1014 declare (in neg_numeral) add_neg_numeral_simps [simp]
  1015 declare (in neg_numeral) add_neg_numeral_special [simp]
  1016 declare (in neg_numeral) diff_numeral_simps [simp]
  1017 declare (in neg_numeral) diff_numeral_special [simp]
  1018 declare (in semiring_numeral) numeral_times_numeral [simp]
  1019 declare (in ring_1) mult_neg_numeral_simps [simp]
  1020 
  1021 subsection {* Setting up simprocs *}
  1022 
  1023 lemma mult_numeral_1: "Numeral1 * a = (a::'a::semiring_numeral)"
  1024   by simp
  1025 
  1026 lemma mult_numeral_1_right: "a * Numeral1 = (a::'a::semiring_numeral)"
  1027   by simp
  1028 
  1029 lemma divide_numeral_1: "a / Numeral1 = (a::'a::field)"
  1030   by simp
  1031 
  1032 lemma inverse_numeral_1:
  1033   "inverse Numeral1 = (Numeral1::'a::division_ring)"
  1034   by simp
  1035 
  1036 text{*Theorem lists for the cancellation simprocs. The use of a binary
  1037 numeral for 1 reduces the number of special cases.*}
  1038 
  1039 lemmas mult_1s =
  1040   mult_numeral_1 mult_numeral_1_right 
  1041   mult_minus1 mult_minus1_right
  1042 
  1043 setup {*
  1044   Reorient_Proc.add
  1045     (fn Const (@{const_name numeral}, _) $ _ => true
  1046     | Const (@{const_name neg_numeral}, _) $ _ => true
  1047     | _ => false)
  1048 *}
  1049 
  1050 simproc_setup reorient_numeral
  1051   ("numeral w = x" | "neg_numeral w = y") = Reorient_Proc.proc
  1052 
  1053 
  1054 subsubsection {* Simplification of arithmetic operations on integer constants. *}
  1055 
  1056 lemmas arith_special = (* already declared simp above *)
  1057   add_numeral_special add_neg_numeral_special
  1058   diff_numeral_special minus_one
  1059 
  1060 (* rules already in simpset *)
  1061 lemmas arith_extra_simps =
  1062   numeral_plus_numeral add_neg_numeral_simps add_0_left add_0_right
  1063   minus_numeral minus_neg_numeral minus_zero minus_one
  1064   diff_numeral_simps diff_0 diff_0_right
  1065   numeral_times_numeral mult_neg_numeral_simps
  1066   mult_zero_left mult_zero_right
  1067   abs_numeral abs_neg_numeral
  1068 
  1069 text {*
  1070   For making a minimal simpset, one must include these default simprules.
  1071   Also include @{text simp_thms}.
  1072 *}
  1073 
  1074 lemmas arith_simps =
  1075   add_num_simps mult_num_simps sub_num_simps
  1076   BitM.simps dbl_simps dbl_inc_simps dbl_dec_simps
  1077   abs_zero abs_one arith_extra_simps
  1078 
  1079 text {* Simplification of relational operations *}
  1080 
  1081 lemmas eq_numeral_extra =
  1082   zero_neq_one one_neq_zero
  1083 
  1084 lemmas rel_simps =
  1085   le_num_simps less_num_simps eq_num_simps
  1086   le_numeral_simps le_neg_numeral_simps le_numeral_extra
  1087   less_numeral_simps less_neg_numeral_simps less_numeral_extra
  1088   eq_numeral_simps eq_neg_numeral_simps eq_numeral_extra
  1089 
  1090 
  1091 subsubsection {* Simplification of arithmetic when nested to the right. *}
  1092 
  1093 lemma add_numeral_left [simp]:
  1094   "numeral v + (numeral w + z) = (numeral(v + w) + z)"
  1095   by (simp_all add: add_assoc [symmetric])
  1096 
  1097 lemma add_neg_numeral_left [simp]:
  1098   "numeral v + (neg_numeral w + y) = (sub v w + y)"
  1099   "neg_numeral v + (numeral w + y) = (sub w v + y)"
  1100   "neg_numeral v + (neg_numeral w + y) = (neg_numeral(v + w) + y)"
  1101   by (simp_all add: add_assoc [symmetric])
  1102 
  1103 lemma mult_numeral_left [simp]:
  1104   "numeral v * (numeral w * z) = (numeral(v * w) * z :: 'a::semiring_numeral)"
  1105   "neg_numeral v * (numeral w * y) = (neg_numeral(v * w) * y :: 'b::ring_1)"
  1106   "numeral v * (neg_numeral w * y) = (neg_numeral(v * w) * y :: 'b::ring_1)"
  1107   "neg_numeral v * (neg_numeral w * y) = (numeral(v * w) * y :: 'b::ring_1)"
  1108   by (simp_all add: mult_assoc [symmetric])
  1109 
  1110 hide_const (open) One Bit0 Bit1 BitM inc pow sqr sub dbl dbl_inc dbl_dec
  1111 
  1112 
  1113 subsection {* code module namespace *}
  1114 
  1115 code_modulename SML
  1116   Num Arith
  1117 
  1118 code_modulename OCaml
  1119   Num Arith
  1120 
  1121 code_modulename Haskell
  1122   Num Arith
  1123 
  1124 end
  1125 
  1126