src/Pure/library.ML
author wenzelm
Wed Jun 08 15:56:57 2011 +0200 (2011-06-08)
changeset 43278 1fbdcebb364b
parent 42403 38b29c9fc742
child 43559 c1966f322105
permissions -rw-r--r--
more robust exception pattern General.Subscript;
     1 (*  Title:      Pure/library.ML
     2     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     3     Author:     Markus Wenzel, TU Muenchen
     4 
     5 Basic library: functions, pairs, booleans, lists, integers,
     6 strings, lists as sets, orders, current directory, misc.
     7 
     8 See also General/basics.ML for the most fundamental concepts.
     9 *)
    10 
    11 infix 2 ?
    12 infix 3 o oo ooo oooo
    13 infix 4 ~~ upto downto
    14 infix orf andf
    15 
    16 signature BASIC_LIBRARY =
    17 sig
    18   (*functions*)
    19   val undefined: 'a -> 'b
    20   val I: 'a -> 'a
    21   val K: 'a -> 'b -> 'a
    22   val curry: ('a * 'b -> 'c) -> 'a -> 'b -> 'c
    23   val uncurry: ('a -> 'b -> 'c) -> 'a * 'b -> 'c
    24   val ? : bool * ('a -> 'a) -> 'a -> 'a
    25   val oo: ('a -> 'b) * ('c -> 'd -> 'a) -> 'c -> 'd -> 'b
    26   val ooo: ('a -> 'b) * ('c -> 'd -> 'e -> 'a) -> 'c -> 'd -> 'e -> 'b
    27   val oooo: ('a -> 'b) * ('c -> 'd -> 'e -> 'f -> 'a) -> 'c -> 'd -> 'e -> 'f -> 'b
    28   val funpow: int -> ('a -> 'a) -> 'a -> 'a
    29   val funpow_yield: int -> ('a -> 'b * 'a) -> 'a -> 'b list * 'a
    30 
    31   (*errors*)
    32   exception ERROR of string
    33   val error: string -> 'a
    34   val cat_error: string -> string -> 'a
    35   val assert_all: ('a -> bool) -> 'a list -> ('a -> string) -> unit
    36 
    37   (*pairs*)
    38   val pair: 'a -> 'b -> 'a * 'b
    39   val rpair: 'a -> 'b -> 'b * 'a
    40   val fst: 'a * 'b -> 'a
    41   val snd: 'a * 'b -> 'b
    42   val eq_fst: ('a * 'c -> bool) -> ('a * 'b) * ('c * 'd) -> bool
    43   val eq_snd: ('b * 'd -> bool) -> ('a * 'b) * ('c * 'd) -> bool
    44   val eq_pair: ('a * 'c -> bool) -> ('b * 'd -> bool) -> ('a * 'b) * ('c * 'd) -> bool
    45   val swap: 'a * 'b -> 'b * 'a
    46   val apfst: ('a -> 'b) -> 'a * 'c -> 'b * 'c
    47   val apsnd: ('a -> 'b) -> 'c * 'a -> 'c * 'b
    48   val pairself: ('a -> 'b) -> 'a * 'a -> 'b * 'b
    49 
    50   (*booleans*)
    51   val equal: ''a -> ''a -> bool
    52   val not_equal: ''a -> ''a -> bool
    53   val orf: ('a -> bool) * ('a -> bool) -> 'a -> bool
    54   val andf: ('a -> bool) * ('a -> bool) -> 'a -> bool
    55   val exists: ('a -> bool) -> 'a list -> bool
    56   val forall: ('a -> bool) -> 'a list -> bool
    57   val setmp_CRITICAL: 'a Unsynchronized.ref -> 'a -> ('b -> 'c) -> 'b -> 'c
    58   val setmp_thread_data: 'a Universal.tag -> 'a -> 'a -> ('b -> 'c) -> 'b -> 'c
    59 
    60   (*lists*)
    61   val single: 'a -> 'a list
    62   val the_single: 'a list -> 'a
    63   val singleton: ('a list -> 'b list) -> 'a -> 'b
    64   val yield_singleton: ('a list -> 'c -> 'b list * 'c) -> 'a -> 'c -> 'b * 'c
    65   val apply: ('a -> 'a) list -> 'a -> 'a
    66   val perhaps_apply: ('a -> 'a option) list -> 'a -> 'a option
    67   val perhaps_loop: ('a -> 'a option) -> 'a -> 'a option
    68   val foldl1: ('a * 'a -> 'a) -> 'a list -> 'a
    69   val foldr1: ('a * 'a -> 'a) -> 'a list -> 'a
    70   val flat: 'a list list -> 'a list
    71   val unflat: 'a list list -> 'b list -> 'b list list
    72   val burrow: ('a list -> 'b list) -> 'a list list -> 'b list list
    73   val burrow_options: ('a list -> 'b list) -> 'a option list -> 'b option list
    74   val burrow_fst: ('a list -> 'b list) -> ('a * 'c) list -> ('b * 'c) list
    75   val fold_burrow: ('a list -> 'c -> 'b list * 'd) -> 'a list list -> 'c -> 'b list list * 'd
    76   val maps: ('a -> 'b list) -> 'a list -> 'b list
    77   val filter: ('a -> bool) -> 'a list -> 'a list
    78   val filter_out: ('a -> bool) -> 'a list -> 'a list
    79   val map_filter: ('a -> 'b option) -> 'a list -> 'b list
    80   val take: int -> 'a list -> 'a list
    81   val drop: int -> 'a list -> 'a list
    82   val chop: int -> 'a list -> 'a list * 'a list
    83   val chop_while: ('a -> bool) -> 'a list -> 'a list * 'a list
    84   val nth: 'a list -> int -> 'a
    85   val nth_map: int -> ('a -> 'a) -> 'a list -> 'a list
    86   val nth_drop: int -> 'a list -> 'a list
    87   val nth_list: 'a list list -> int -> 'a list
    88   val map_index: (int * 'a -> 'b) -> 'a list -> 'b list
    89   val fold_index: (int * 'a -> 'b -> 'b) -> 'a list -> 'b -> 'b
    90   val map_range: (int -> 'a) -> int -> 'a list
    91   val split_last: 'a list -> 'a list * 'a
    92   val find_index: ('a -> bool) -> 'a list -> int
    93   val find_first: ('a -> bool) -> 'a list -> 'a option
    94   val get_index: ('a -> 'b option) -> 'a list -> (int * 'b) option
    95   val get_first: ('a -> 'b option) -> 'a list -> 'b option
    96   val eq_list: ('a * 'a -> bool) -> 'a list * 'a list -> bool
    97   val map2: ('a -> 'b -> 'c) -> 'a list -> 'b list -> 'c list
    98   val fold2: ('a -> 'b -> 'c -> 'c) -> 'a list -> 'b list -> 'c -> 'c
    99   val fold_rev2: ('a -> 'b -> 'c -> 'c) -> 'a list -> 'b list -> 'c -> 'c
   100   val forall2: ('a -> 'b -> bool) -> 'a list -> 'b list -> bool
   101   val zip_options: 'a list -> 'b option list -> ('a * 'b) list
   102   val ~~ : 'a list * 'b list -> ('a * 'b) list
   103   val map_split: ('a -> 'b * 'c) -> 'a list -> 'b list * 'c list
   104   val split_list: ('a * 'b) list -> 'a list * 'b list
   105   val map_product: ('a -> 'b -> 'c) -> 'a list -> 'b list -> 'c list
   106   val fold_product: ('a -> 'b -> 'c -> 'c) -> 'a list -> 'b list -> 'c -> 'c
   107   val map_transpose: ('a list -> 'b) -> 'a list list -> 'b list
   108   val separate: 'a -> 'a list -> 'a list
   109   val surround: 'a -> 'a list -> 'a list
   110   val replicate: int -> 'a -> 'a list
   111   val is_prefix: ('a * 'a -> bool) -> 'a list -> 'a list -> bool
   112   val take_prefix: ('a -> bool) -> 'a list -> 'a list * 'a list
   113   val chop_prefix: ('a * 'b -> bool) -> 'a list * 'b list -> 'a list * ('a list * 'b list)
   114   val take_suffix: ('a -> bool) -> 'a list -> 'a list * 'a list
   115   val prefixes1: 'a list -> 'a list list
   116   val prefixes: 'a list -> 'a list list
   117   val suffixes1: 'a list -> 'a list list
   118   val suffixes: 'a list -> 'a list list
   119 
   120   (*integers*)
   121   val upto: int * int -> int list
   122   val downto: int * int -> int list
   123   val radixpand: int * int -> int list
   124   val radixstring: int * string * int -> string
   125   val string_of_int: int -> string
   126   val signed_string_of_int: int -> string
   127   val string_of_indexname: string * int -> string
   128   val read_radix_int: int -> string list -> int * string list
   129   val read_int: string list -> int * string list
   130   val oct_char: string -> string
   131 
   132   (*strings*)
   133   val nth_string: string -> int -> string
   134   val fold_string: (string -> 'a -> 'a) -> string -> 'a -> 'a
   135   val exists_string: (string -> bool) -> string -> bool
   136   val forall_string: (string -> bool) -> string -> bool
   137   val first_field: string -> string -> (string * string) option
   138   val enclose: string -> string -> string -> string
   139   val unenclose: string -> string
   140   val quote: string -> string
   141   val space_implode: string -> string list -> string
   142   val commas: string list -> string
   143   val commas_quote: string list -> string
   144   val cat_lines: string list -> string
   145   val space_explode: string -> string -> string list
   146   val split_lines: string -> string list
   147   val prefix_lines: string -> string -> string
   148   val prefix: string -> string -> string
   149   val suffix: string -> string -> string
   150   val unprefix: string -> string -> string
   151   val unsuffix: string -> string -> string
   152   val replicate_string: int -> string -> string
   153   val translate_string: (string -> string) -> string -> string
   154   val match_string: string -> string -> bool
   155 
   156   (*reals*)
   157   val string_of_real: real -> string
   158   val signed_string_of_real: real -> string
   159   val smart_string_of_real: real -> string
   160 
   161   (*lists as sets -- see also Pure/General/ord_list.ML*)
   162   val member: ('b * 'a -> bool) -> 'a list -> 'b -> bool
   163   val insert: ('a * 'a -> bool) -> 'a -> 'a list -> 'a list
   164   val remove: ('b * 'a -> bool) -> 'b -> 'a list -> 'a list
   165   val update: ('a * 'a -> bool) -> 'a -> 'a list -> 'a list
   166   val union: ('a * 'a -> bool) -> 'a list -> 'a list -> 'a list
   167   val subtract: ('b * 'a -> bool) -> 'b list -> 'a list -> 'a list
   168   val inter: ('a * 'b -> bool) -> 'b list -> 'a list -> 'a list
   169   val merge: ('a * 'a -> bool) -> 'a list * 'a list -> 'a list
   170   val subset: ('a * 'b -> bool) -> 'a list * 'b list -> bool
   171   val eq_set: ('a * 'a -> bool) -> 'a list * 'a list -> bool
   172   val distinct: ('a * 'a -> bool) -> 'a list -> 'a list
   173   val duplicates: ('a * 'a -> bool) -> 'a list -> 'a list
   174   val has_duplicates: ('a * 'a -> bool) -> 'a list -> bool
   175 
   176   (*lists as multisets*)
   177   val remove1: ('b * 'a -> bool) -> 'b -> 'a list -> 'a list
   178   val combine: ('a * 'a -> bool) -> 'a list -> 'a list -> 'a list
   179   val submultiset: ('a * 'b -> bool) -> 'a list * 'b list -> bool
   180 
   181   (*orders*)
   182   val is_equal: order -> bool
   183   val rev_order: order -> order
   184   val make_ord: ('a * 'a -> bool) -> 'a * 'a -> order
   185   val bool_ord: bool * bool -> order
   186   val int_ord: int * int -> order
   187   val string_ord: string * string -> order
   188   val fast_string_ord: string * string -> order
   189   val option_ord: ('a * 'b -> order) -> 'a option * 'b option -> order
   190   val prod_ord: ('a * 'b -> order) -> ('c * 'd -> order) -> ('a * 'c) * ('b * 'd) -> order
   191   val dict_ord: ('a * 'b -> order) -> 'a list * 'b list -> order
   192   val list_ord: ('a * 'b -> order) -> 'a list * 'b list -> order
   193   val sort: ('a * 'a -> order) -> 'a list -> 'a list
   194   val sort_distinct: ('a * 'a -> order) -> 'a list -> 'a list
   195   val sort_strings: string list -> string list
   196   val sort_wrt: ('a -> string) -> 'a list -> 'a list
   197   val tag_list: int -> 'a list -> (int * 'a) list
   198   val untag_list: (int * 'a) list -> 'a list
   199   val order_list: (int * 'a) list -> 'a list
   200 
   201   (*random numbers*)
   202   exception RANDOM
   203   val random: unit -> real
   204   val random_range: int -> int -> int
   205   val one_of: 'a list -> 'a
   206   val frequency: (int * 'a) list -> 'a
   207 
   208   (*misc*)
   209   val divide_and_conquer: ('a -> 'a list * ('b list -> 'b)) -> 'a -> 'b
   210   val divide_and_conquer': ('a -> 'b -> ('a list * ('c list * 'b -> 'c * 'b)) * 'b) ->
   211     'a -> 'b -> 'c * 'b
   212   val partition_eq: ('a * 'a -> bool) -> 'a list -> 'a list list
   213   val partition_list: (int -> 'a -> bool) -> int -> int -> 'a list -> 'a list list
   214   val gensym: string -> string
   215   type stamp = unit Unsynchronized.ref
   216   val stamp: unit -> stamp
   217   type serial = int
   218   val serial: unit -> serial
   219   val serial_string: unit -> string
   220   structure Object: sig type T = exn end
   221 end;
   222 
   223 signature LIBRARY =
   224 sig
   225   include BASIC_LIBRARY
   226   val foldl: ('a * 'b -> 'a) -> 'a * 'b list -> 'a
   227   val foldr: ('a * 'b -> 'b) -> 'a list * 'b -> 'b
   228   val foldl_map: ('a * 'b -> 'a * 'c) -> 'a * 'b list -> 'a * 'c list
   229 end;
   230 
   231 structure Library: LIBRARY =
   232 struct
   233 
   234 (* functions *)
   235 
   236 fun undefined _ = raise Match;
   237 
   238 fun I x = x;
   239 fun K x = fn _ => x;
   240 fun curry f x y = f (x, y);
   241 fun uncurry f (x, y) = f x y;
   242 
   243 (*conditional application*)
   244 fun b ? f = fn x => if b then f x else x;
   245 
   246 (*composition with multiple args*)
   247 fun (f oo g) x y = f (g x y);
   248 fun (f ooo g) x y z = f (g x y z);
   249 fun (f oooo g) x y z w = f (g x y z w);
   250 
   251 (*function exponentiation: f (... (f x) ...) with n applications of f*)
   252 fun funpow (0 : int) _ = I
   253   | funpow n f = f #> funpow (n - 1) f;
   254 
   255 fun funpow_yield (0 : int) _ x = ([], x)
   256   | funpow_yield n f x = x |> f ||>> funpow_yield (n - 1) f |>> op ::;
   257 
   258 
   259 (* errors *)
   260 
   261 exception ERROR of string;
   262 fun error msg = raise ERROR msg;
   263 
   264 fun cat_error "" msg = error msg
   265   | cat_error msg1 msg2 = error (msg1 ^ "\n" ^ msg2);
   266 
   267 fun assert_all pred list msg =
   268   let
   269     fun ass [] = ()
   270       | ass (x :: xs) = if pred x then ass xs else error (msg x);
   271   in ass list end;
   272 
   273 
   274 (* pairs *)
   275 
   276 fun pair x y = (x, y);
   277 fun rpair x y = (y, x);
   278 
   279 fun fst (x, y) = x;
   280 fun snd (x, y) = y;
   281 
   282 fun eq_fst eq ((x1, _), (x2, _)) = eq (x1, x2);
   283 fun eq_snd eq ((_, y1), (_, y2)) = eq (y1, y2);
   284 fun eq_pair eqx eqy ((x1, y1), (x2, y2)) = eqx (x1, x2) andalso eqy (y1, y2);
   285 
   286 fun swap (x, y) = (y, x);
   287 
   288 fun apfst f (x, y) = (f x, y);
   289 fun apsnd f (x, y) = (x, f y);
   290 fun pairself f (x, y) = (f x, f y);
   291 
   292 
   293 (* booleans *)
   294 
   295 (*polymorphic equality*)
   296 fun equal x y = x = y;
   297 fun not_equal x y = x <> y;
   298 
   299 (*combining predicates*)
   300 fun p orf q = fn x => p x orelse q x;
   301 fun p andf q = fn x => p x andalso q x;
   302 
   303 val exists = List.exists;
   304 val forall = List.all;
   305 
   306 
   307 (* flags *)
   308 
   309 fun setmp_CRITICAL flag value f x =
   310   NAMED_CRITICAL "setmp" (fn () => Unsynchronized.setmp flag value f x);
   311 
   312 fun setmp_thread_data tag orig_data data f x =
   313   uninterruptible (fn restore_attributes => fn () =>
   314     let
   315       val _ = Thread.setLocal (tag, data);
   316       val result = Exn.capture (restore_attributes f) x;
   317       val _ = Thread.setLocal (tag, orig_data);
   318     in Exn.release result end) ();
   319 
   320 
   321 
   322 (** lists **)
   323 
   324 fun single x = [x];
   325 
   326 fun the_single [x] = x
   327   | the_single _ = raise Empty;
   328 
   329 fun singleton f x = the_single (f [x]);
   330 
   331 fun yield_singleton f x = f [x] #>> the_single;
   332 
   333 fun apply [] x = x
   334   | apply (f :: fs) x = apply fs (f x);
   335 
   336 fun perhaps_apply funs arg =
   337   let
   338     fun app [] res = res
   339       | app (f :: fs) (changed, x) =
   340           (case f x of
   341             NONE => app fs (changed, x)
   342           | SOME x' => app fs (true, x'));
   343   in (case app funs (false, arg) of (false, _) => NONE | (true, arg') => SOME arg') end;
   344 
   345 fun perhaps_loop f arg =
   346   let
   347     fun loop (changed, x) =
   348       (case f x of
   349         NONE => (changed, x)
   350       | SOME x' => loop (true, x'));
   351   in (case loop (false, arg) of (false, _) => NONE | (true, arg') => SOME arg') end;
   352 
   353 
   354 (* fold -- old versions *)
   355 
   356 (*the following versions of fold are designed to fit nicely with infixes*)
   357 
   358 (*  (op @) (e, [x1, ..., xn])  ===>  ((e @ x1) @ x2) ... @ xn
   359     for operators that associate to the left (TAIL RECURSIVE)*)
   360 fun foldl (f: 'a * 'b -> 'a) : 'a * 'b list -> 'a =
   361   let fun itl (e, [])  = e
   362         | itl (e, a::l) = itl (f(e, a), l)
   363   in  itl end;
   364 
   365 (*  (op @) ([x1, ..., xn], e)  ===>   x1 @ (x2 ... @ (xn @ e))
   366     for operators that associate to the right (not tail recursive)*)
   367 fun foldr f (l, e) =
   368   let fun itr [] = e
   369         | itr (a::l) = f(a, itr l)
   370   in  itr l  end;
   371 
   372 (*  (op @) [x1, ..., xn]  ===>  ((x1 @ x2) @ x3) ... @ xn
   373     for operators that associate to the left (TAIL RECURSIVE)*)
   374 fun foldl1 f [] = raise Empty
   375   | foldl1 f (x :: xs) = foldl f (x, xs);
   376 
   377 (*  (op @) [x1, ..., xn]  ===>   x1 @ (x2 ... @ (x[n-1] @ xn))
   378     for n > 0, operators that associate to the right (not tail recursive)*)
   379 fun foldr1 f [] = raise Empty
   380   | foldr1 f l =
   381       let fun itr [x] = x
   382             | itr (x::l) = f(x, itr l)
   383       in  itr l  end;
   384 
   385 fun foldl_map f =
   386   let
   387     fun fold_aux (x, []) = (x, [])
   388       | fold_aux (x, y :: ys) =
   389           let
   390             val (x', y') = f (x, y);
   391             val (x'', ys') = fold_aux (x', ys);
   392           in (x'', y' :: ys') end;
   393   in fold_aux end;
   394 
   395 
   396 (* basic list functions *)
   397 
   398 fun eq_list eq (list1, list2) =
   399   pointer_eq (list1, list2) orelse
   400     let
   401       fun eq_lst (x :: xs, y :: ys) = eq (x, y) andalso eq_lst (xs, ys)
   402         | eq_lst _ = true;
   403     in length list1 = length list2 andalso eq_lst (list1, list2) end;
   404 
   405 fun maps f [] = []
   406   | maps f (x :: xs) = f x @ maps f xs;
   407 
   408 val filter = List.filter;
   409 fun filter_out f = filter (not o f);
   410 val map_filter = List.mapPartial;
   411 
   412 fun take (0: int) xs = []
   413   | take _ [] = []
   414   | take n (x :: xs) = x :: take (n - 1) xs;
   415 
   416 fun drop (0: int) xs = xs
   417   | drop _ [] = []
   418   | drop n (x :: xs) = drop (n - 1) xs;
   419 
   420 fun chop (0: int) xs = ([], xs)
   421   | chop _ [] = ([], [])
   422   | chop n (x :: xs) = chop (n - 1) xs |>> cons x;
   423 
   424 fun chop_while P [] = ([], [])
   425   | chop_while P (ys as x :: xs) =
   426       if P x then chop_while P xs |>> cons x else ([], ys);
   427 
   428 (*return nth element of a list, where 0 designates the first element;
   429   raise Subscript if list too short*)
   430 fun nth xs i = List.nth (xs, i);
   431 
   432 fun nth_list xss i = nth xss i handle General.Subscript => [];
   433 
   434 fun nth_map 0 f (x :: xs) = f x :: xs
   435   | nth_map n f (x :: xs) = x :: nth_map (n - 1) f xs
   436   | nth_map (_: int) _ [] = raise Subscript;
   437 
   438 fun nth_drop n xs =
   439   List.take (xs, n) @ List.drop (xs, n + 1);
   440 
   441 fun map_index f =
   442   let
   443     fun mapp (_: int) [] = []
   444       | mapp i (x :: xs) = f (i, x) :: mapp (i + 1) xs
   445   in mapp 0 end;
   446 
   447 fun fold_index f =
   448   let
   449     fun fold_aux (_: int) [] y = y
   450       | fold_aux i (x :: xs) y = fold_aux (i + 1) xs (f (i, x) y);
   451   in fold_aux 0 end;
   452 
   453 fun map_range f i =
   454   let
   455     fun mapp (k: int) =
   456       if k < i then f k :: mapp (k + 1) else [];
   457   in mapp 0 end;
   458 
   459 (*rear decomposition*)
   460 fun split_last [] = raise Empty
   461   | split_last [x] = ([], x)
   462   | split_last (x :: xs) = apfst (cons x) (split_last xs);
   463 
   464 (*find position of first element satisfying a predicate*)
   465 fun find_index pred =
   466   let fun find (_: int) [] = ~1
   467         | find n (x :: xs) = if pred x then n else find (n + 1) xs;
   468   in find 0 end;
   469 
   470 (*find first element satisfying predicate*)
   471 val find_first = List.find;
   472 
   473 (*get first element by lookup function*)
   474 fun get_first _ [] = NONE
   475   | get_first f (x :: xs) =
   476       (case f x of
   477         NONE => get_first f xs
   478       | some => some);
   479 
   480 fun get_index f =
   481   let
   482     fun get (_: int) [] = NONE
   483       | get i (x :: xs) =
   484           case f x
   485            of NONE => get (i + 1) xs
   486             | SOME y => SOME (i, y)
   487   in get 0 end;
   488 
   489 val flat = List.concat;
   490 
   491 fun unflat (xs :: xss) ys =
   492       let val (ps, qs) = chop (length xs) ys
   493       in ps :: unflat xss qs end
   494   | unflat [] [] = []
   495   | unflat _ _ = raise ListPair.UnequalLengths;
   496 
   497 fun burrow f xss = unflat xss (f (flat xss));
   498 
   499 fun burrow_options f os = map (try hd) (burrow f (map the_list os));
   500 
   501 fun fold_burrow f xss s =
   502   apfst (unflat xss) (f (flat xss) s);
   503 
   504 (*separate s [x1, x2, ..., xn]  ===>  [x1, s, x2, s, ..., s, xn]*)
   505 fun separate s (x :: (xs as _ :: _)) = x :: s :: separate s xs
   506   | separate _ xs = xs;
   507 
   508 fun surround s (x :: xs) = s :: x :: surround s xs
   509   | surround s [] = [s];
   510 
   511 (*make the list [x, x, ..., x] of length n*)
   512 fun replicate (n: int) x =
   513   let fun rep (0, xs) = xs
   514         | rep (n, xs) = rep (n - 1, x :: xs)
   515   in
   516     if n < 0 then raise Subscript
   517     else rep (n, [])
   518   end;
   519 
   520 
   521 (* direct product *)
   522 
   523 fun map_product f _ [] = []
   524   | map_product f [] _ = []
   525   | map_product f (x :: xs) ys = map (f x) ys @ map_product f xs ys;
   526 
   527 fun fold_product f _ [] z = z
   528   | fold_product f [] _ z = z
   529   | fold_product f (x :: xs) ys z = z |> fold (f x) ys |> fold_product f xs ys;
   530 
   531 
   532 (* lists of pairs *)
   533 
   534 fun map2 _ [] [] = []
   535   | map2 f (x :: xs) (y :: ys) = f x y :: map2 f xs ys
   536   | map2 _ _ _ = raise ListPair.UnequalLengths;
   537 
   538 fun fold2 f [] [] z = z
   539   | fold2 f (x :: xs) (y :: ys) z = fold2 f xs ys (f x y z)
   540   | fold2 f _ _ _ = raise ListPair.UnequalLengths;
   541 
   542 fun fold_rev2 f [] [] z = z
   543   | fold_rev2 f (x :: xs) (y :: ys) z = f x y (fold_rev2 f xs ys z)
   544   | fold_rev2 f _ _ _ = raise ListPair.UnequalLengths;
   545 
   546 fun forall2 P [] [] = true
   547   | forall2 P (x :: xs) (y :: ys) = P x y andalso forall2 P xs ys
   548   | forall2 P _ _ = raise ListPair.UnequalLengths;
   549 
   550 fun map_split f [] = ([], [])
   551   | map_split f (x :: xs) =
   552       let
   553         val (y, w) = f x;
   554         val (ys, ws) = map_split f xs;
   555       in (y :: ys, w :: ws) end;
   556 
   557 fun zip_options (x :: xs) (SOME y :: ys) = (x, y) :: zip_options xs ys
   558   | zip_options (_ :: xs) (NONE :: ys) = zip_options xs ys
   559   | zip_options _ [] = []
   560   | zip_options [] _ = raise ListPair.UnequalLengths;
   561 
   562 (*combine two lists forming a list of pairs:
   563   [x1, ..., xn] ~~ [y1, ..., yn]  ===>  [(x1, y1), ..., (xn, yn)]*)
   564 fun [] ~~ [] = []
   565   | (x :: xs) ~~ (y :: ys) = (x, y) :: (xs ~~ ys)
   566   | _ ~~ _ = raise ListPair.UnequalLengths;
   567 
   568 (*inverse of ~~; the old 'split':
   569   [(x1, y1), ..., (xn, yn)]  ===>  ([x1, ..., xn], [y1, ..., yn])*)
   570 val split_list = ListPair.unzip;
   571 
   572 fun burrow_fst f xs = split_list xs |>> f |> op ~~;
   573 
   574 
   575 (* prefixes, suffixes *)
   576 
   577 fun is_prefix _ [] _ = true
   578   | is_prefix eq (x :: xs) (y :: ys) = eq (x, y) andalso is_prefix eq xs ys
   579   | is_prefix eq _ _ = false;
   580 
   581 (* [x1, ..., xi, ..., xn]  --->  ([x1, ..., x(i-1)], [xi, ..., xn])
   582    where xi is the first element that does not satisfy the predicate*)
   583 fun take_prefix (pred : 'a -> bool)  (xs: 'a list) : 'a list * 'a list =
   584   let fun take (rxs, []) = (rev rxs, [])
   585         | take (rxs, x :: xs) =
   586             if  pred x  then  take(x :: rxs, xs)  else  (rev rxs, x :: xs)
   587   in  take([], xs)  end;
   588 
   589 fun chop_prefix eq ([], ys) = ([], ([], ys))
   590   | chop_prefix eq (xs, []) = ([], (xs, []))
   591   | chop_prefix eq (xs as x :: xs', ys as y :: ys') =
   592       if eq (x, y) then
   593         let val (ps', xys'') = chop_prefix eq (xs', ys')
   594         in (x :: ps', xys'') end
   595       else ([], (xs, ys));
   596 
   597 (* [x1, ..., xi, ..., xn]  --->  ([x1, ..., xi], [x(i+1), ..., xn])
   598    where xi is the last element that does not satisfy the predicate*)
   599 fun take_suffix _ [] = ([], [])
   600   | take_suffix pred (x :: xs) =
   601       (case take_suffix pred xs of
   602         ([], sffx) => if pred x then ([], x :: sffx) else ([x], sffx)
   603       | (prfx, sffx) => (x :: prfx, sffx));
   604 
   605 fun prefixes1 [] = []
   606   | prefixes1 (x :: xs) = map (cons x) ([] :: prefixes1 xs);
   607 
   608 fun prefixes xs = [] :: prefixes1 xs;
   609 
   610 fun suffixes1 xs = map rev (prefixes1 (rev xs));
   611 fun suffixes xs = [] :: suffixes1 xs;
   612 
   613 
   614 
   615 (** integers **)
   616 
   617 (* lists of integers *)
   618 
   619 (*make the list [from, from + 1, ..., to]*)
   620 fun ((i: int) upto j) =
   621   if i > j then [] else i :: (i + 1 upto j);
   622 
   623 (*make the list [from, from - 1, ..., to]*)
   624 fun ((i: int) downto j) =
   625   if i < j then [] else i :: (i - 1 downto j);
   626 
   627 
   628 (* convert integers to strings *)
   629 
   630 (*expand the number in the given base;
   631   example: radixpand (2, 8) gives [1, 0, 0, 0]*)
   632 fun radixpand (base, num) : int list =
   633   let
   634     fun radix (n, tail) =
   635       if n < base then n :: tail
   636       else radix (n div base, (n mod base) :: tail)
   637   in radix (num, []) end;
   638 
   639 (*expands a number into a string of characters starting from "zerochar";
   640   example: radixstring (2, "0", 8) gives "1000"*)
   641 fun radixstring (base, zerochar, num) =
   642   let val offset = ord zerochar;
   643       fun chrof n = chr (offset + n)
   644   in implode (map chrof (radixpand (base, num))) end;
   645 
   646 
   647 local
   648   val zero = ord "0";
   649   val small = 10000: int;
   650   val small_table = Vector.tabulate (small, Int.toString);
   651 in
   652 
   653 fun string_of_int i =
   654   if i < 0 then Int.toString i
   655   else if i < 10 then chr (zero + i)
   656   else if i < small then Vector.sub (small_table, i)
   657   else Int.toString i;
   658 
   659 end;
   660 
   661 fun signed_string_of_int i =
   662   if i < 0 then "-" ^ string_of_int (~ i) else string_of_int i;
   663 
   664 fun string_of_indexname (a, 0) = a
   665   | string_of_indexname (a, i) = a ^ "_" ^ string_of_int i;
   666 
   667 
   668 (* read integers *)
   669 
   670 fun read_radix_int radix cs =
   671   let
   672     val zero = ord "0";
   673     val limit = zero + radix;
   674     fun scan (num, []) = (num, [])
   675       | scan (num, c :: cs) =
   676         if zero <= ord c andalso ord c < limit then
   677           scan (radix * num + (ord c - zero), cs)
   678         else (num, c :: cs);
   679   in scan (0, cs) end;
   680 
   681 val read_int = read_radix_int 10;
   682 
   683 fun oct_char s = chr (#1 (read_radix_int 8 (raw_explode s)));
   684 
   685 
   686 
   687 (** strings **)
   688 
   689 (* functions tuned for strings, avoiding explode *)
   690 
   691 fun nth_string str i =
   692   (case try String.substring (str, i, 1) of
   693     SOME s => s
   694   | NONE => raise Subscript);
   695 
   696 fun fold_string f str x0 =
   697   let
   698     val n = size str;
   699     fun iter (x, i) =
   700       if i < n then iter (f (String.substring (str, i, 1)) x, i + 1) else x;
   701   in iter (x0, 0) end;
   702 
   703 fun exists_string pred str =
   704   let
   705     val n = size str;
   706     fun ex i = i < n andalso (pred (String.substring (str, i, 1)) orelse ex (i + 1));
   707   in ex 0 end;
   708 
   709 fun forall_string pred = not o exists_string (not o pred);
   710 
   711 fun first_field sep str =
   712   let
   713     val n = size sep;
   714     val len = size str;
   715     fun find i =
   716       if i + n > len then NONE
   717       else if String.substring (str, i, n) = sep then SOME i
   718       else find (i + 1);
   719   in
   720     (case find 0 of
   721       NONE => NONE
   722     | SOME i => SOME (String.substring (str, 0, i), String.extract (str, i + n, NONE)))
   723   end;
   724 
   725 (*enclose in brackets*)
   726 fun enclose lpar rpar str = lpar ^ str ^ rpar;
   727 fun unenclose str = String.substring (str, 1, size str - 2);
   728 
   729 (*simple quoting (does not escape special chars)*)
   730 val quote = enclose "\"" "\"";
   731 
   732 fun space_implode a bs = implode (separate a bs);
   733 
   734 val commas = space_implode ", ";
   735 val commas_quote = commas o map quote;
   736 
   737 val cat_lines = space_implode "\n";
   738 
   739 (*space_explode "." "h.e..l.lo" = ["h", "e", "", "l", "lo"]*)
   740 fun space_explode _ "" = []
   741   | space_explode sep s = String.fields (fn c => str c = sep) s;
   742 
   743 val split_lines = space_explode "\n";
   744 
   745 fun prefix_lines "" txt = txt
   746   | prefix_lines prfx txt = txt |> split_lines |> map (fn s => prfx ^ s) |> cat_lines;
   747 
   748 fun prefix prfx s = prfx ^ s;
   749 fun suffix sffx s = s ^ sffx;
   750 
   751 fun unprefix prfx s =
   752   if String.isPrefix prfx s then String.substring (s, size prfx, size s - size prfx)
   753   else raise Fail "unprefix";
   754 
   755 fun unsuffix sffx s =
   756   if String.isSuffix sffx s then String.substring (s, 0, size s - size sffx)
   757   else raise Fail "unsuffix";
   758 
   759 fun replicate_string (0: int) _ = ""
   760   | replicate_string 1 a = a
   761   | replicate_string k a =
   762       if k mod 2 = 0 then replicate_string (k div 2) (a ^ a)
   763       else replicate_string (k div 2) (a ^ a) ^ a;
   764 
   765 fun translate_string f = String.translate (f o String.str);
   766 
   767 (*crude matching of str against simple glob pat*)
   768 fun match_string pat str =
   769   let
   770     fun match [] _ = true
   771       | match (p :: ps) s =
   772           size p <= size s andalso
   773             (case try (unprefix p) s of
   774               SOME s' => match ps s'
   775             | NONE => match (p :: ps) (String.substring (s, 1, size s - 1)));
   776   in match (space_explode "*" pat) str end;
   777 
   778 
   779 (** reals **)
   780 
   781 val string_of_real = Real.fmt (StringCvt.GEN NONE);
   782 
   783 fun signed_string_of_real x =
   784   if x < 0.0 then "-" ^ string_of_real (~ x) else string_of_real x;
   785 
   786 fun smart_string_of_real x =
   787   let
   788     val s = signed_string_of_real x;
   789   in
   790     (case space_explode "." s of
   791       [a, b] => if forall_string (fn c => c = "0") b then a else s
   792     | _ => s)
   793   end;
   794 
   795 
   796 
   797 (** lists as sets -- see also Pure/General/ord_list.ML **)
   798 
   799 (* canonical operations *)
   800 
   801 fun member eq list x =
   802   let
   803     fun memb [] = false
   804       | memb (y :: ys) = eq (x, y) orelse memb ys;
   805   in memb list end;
   806 
   807 fun insert eq x xs = if member eq xs x then xs else x :: xs;
   808 fun remove eq x xs = if member eq xs x then filter_out (fn y => eq (x, y)) xs else xs;
   809 fun update eq x xs = cons x (remove eq x xs);
   810 
   811 fun inter eq xs = filter (member eq xs);
   812 
   813 fun union eq = fold (insert eq);
   814 fun subtract eq = fold (remove eq);
   815 
   816 fun merge eq (xs, ys) =
   817   if pointer_eq (xs, ys) then xs
   818   else if null xs then ys
   819   else fold_rev (insert eq) ys xs;
   820 
   821 
   822 (* subset and set equality *)
   823 
   824 fun subset eq (xs, ys) = forall (member eq ys) xs;
   825 
   826 fun eq_set eq (xs, ys) =
   827   eq_list eq (xs, ys) orelse
   828     (subset eq (xs, ys) andalso subset (eq o swap) (ys, xs));
   829 
   830 
   831 (*makes a list of the distinct members of the input; preserves order, takes
   832   first of equal elements*)
   833 fun distinct eq lst =
   834   let
   835     fun dist (rev_seen, []) = rev rev_seen
   836       | dist (rev_seen, x :: xs) =
   837           if member eq rev_seen x then dist (rev_seen, xs)
   838           else dist (x :: rev_seen, xs);
   839   in dist ([], lst) end;
   840 
   841 (*returns a list containing all repeated elements exactly once; preserves
   842   order, takes first of equal elements*)
   843 fun duplicates eq lst =
   844   let
   845     fun dups (rev_dups, []) = rev rev_dups
   846       | dups (rev_dups, x :: xs) =
   847           if member eq rev_dups x orelse not (member eq xs x) then
   848             dups (rev_dups, xs)
   849           else dups (x :: rev_dups, xs);
   850   in dups ([], lst) end;
   851 
   852 fun has_duplicates eq =
   853   let
   854     fun dups [] = false
   855       | dups (x :: xs) = member eq xs x orelse dups xs;
   856   in dups end;
   857 
   858 
   859 (* matrices *)
   860 
   861 fun map_transpose f xss =
   862   let
   863     val n =
   864       (case distinct (op =) (map length xss) of
   865         [] => 0
   866       | [n] => n
   867       | _ => raise ListPair.UnequalLengths);
   868   in map_range (fn m => f (map (fn xs => nth xs m) xss)) n end;
   869 
   870 
   871 
   872 (** lists as multisets **)
   873 
   874 fun remove1 eq x [] = []
   875   | remove1 eq x (y :: ys) = if eq (x, y) then ys else y :: remove1 eq x ys;
   876 
   877 fun combine eq xs ys = fold (remove1 eq) ys xs @ ys;
   878 
   879 fun submultiset _ ([], _)  = true
   880   | submultiset eq (x :: xs, ys) = member eq ys x andalso submultiset eq (xs, remove1 eq x ys);
   881 
   882 
   883 
   884 (** orders **)
   885 
   886 fun is_equal EQUAL = true
   887   | is_equal _ = false;
   888 
   889 fun rev_order LESS = GREATER
   890   | rev_order EQUAL = EQUAL
   891   | rev_order GREATER = LESS;
   892 
   893 (*assume rel is a linear strict order*)
   894 fun make_ord rel (x, y) =
   895   if rel (x, y) then LESS
   896   else if rel (y, x) then GREATER
   897   else EQUAL;
   898 
   899 fun bool_ord (false, true) = LESS
   900   | bool_ord (true, false) = GREATER
   901   | bool_ord _ = EQUAL;
   902 
   903 val int_ord = Int.compare;
   904 val string_ord = String.compare;
   905 
   906 fun fast_string_ord (s1, s2) =
   907   (case int_ord (size s1, size s2) of EQUAL => string_ord (s1, s2) | ord => ord);
   908 
   909 fun option_ord ord (SOME x, SOME y) = ord (x, y)
   910   | option_ord _ (NONE, NONE) = EQUAL
   911   | option_ord _ (NONE, SOME _) = LESS
   912   | option_ord _ (SOME _, NONE) = GREATER;
   913 
   914 (*lexicographic product*)
   915 fun prod_ord a_ord b_ord ((x, y), (x', y')) =
   916   (case a_ord (x, x') of EQUAL => b_ord (y, y') | ord => ord);
   917 
   918 (*dictionary order -- in general NOT well-founded!*)
   919 fun dict_ord elem_ord (x :: xs, y :: ys) =
   920       (case elem_ord (x, y) of EQUAL => dict_ord elem_ord (xs, ys) | ord => ord)
   921   | dict_ord _ ([], []) = EQUAL
   922   | dict_ord _ ([], _ :: _) = LESS
   923   | dict_ord _ (_ :: _, []) = GREATER;
   924 
   925 (*lexicographic product of lists*)
   926 fun list_ord elem_ord (xs, ys) =
   927   (case int_ord (length xs, length ys) of EQUAL => dict_ord elem_ord (xs, ys) | ord => ord);
   928 
   929 
   930 (* sorting *)
   931 
   932 (*quicksort -- stable, i.e. does not reorder equal elements*)
   933 fun quicksort unique ord =
   934   let
   935     fun qsort [] = []
   936       | qsort (xs as [_]) = xs
   937       | qsort (xs as [x, y]) =
   938           (case ord (x, y) of
   939             LESS => xs
   940           | EQUAL => if unique then [x] else xs
   941           | GREATER => [y, x])
   942       | qsort xs =
   943           let val (lts, eqs, gts) = part (nth xs (length xs div 2)) xs
   944           in qsort lts @ eqs @ qsort gts end
   945     and part _ [] = ([], [], [])
   946       | part pivot (x :: xs) = add (ord (x, pivot)) x (part pivot xs)
   947     and add LESS x (lts, eqs, gts) = (x :: lts, eqs, gts)
   948       | add EQUAL x (lts, [], gts) = (lts, [x], gts)
   949       | add EQUAL x (res as (lts, eqs, gts)) = if unique then res else (lts, x :: eqs, gts)
   950       | add GREATER x (lts, eqs, gts) = (lts, eqs, x :: gts);
   951   in qsort end;
   952 
   953 fun sort ord = quicksort false ord;
   954 fun sort_distinct ord = quicksort true ord;
   955 
   956 val sort_strings = sort string_ord;
   957 fun sort_wrt sel xs = sort (string_ord o pairself sel) xs;
   958 
   959 
   960 (* items tagged by integer index *)
   961 
   962 (*insert tags*)
   963 fun tag_list k [] = []
   964   | tag_list k (x :: xs) = (k:int, x) :: tag_list (k + 1) xs;
   965 
   966 (*remove tags and suppress duplicates -- list is assumed sorted!*)
   967 fun untag_list [] = []
   968   | untag_list [(k: int, x)] = [x]
   969   | untag_list ((k, x) :: (rest as (k', x') :: _)) =
   970       if k = k' then untag_list rest
   971       else x :: untag_list rest;
   972 
   973 (*return list elements in original order*)
   974 fun order_list list = untag_list (sort (int_ord o pairself fst) list);
   975 
   976 
   977 
   978 (** random numbers **)
   979 
   980 exception RANDOM;
   981 
   982 fun rmod x y = x - y * Real.realFloor (x / y);
   983 
   984 local
   985   val a = 16807.0;
   986   val m = 2147483647.0;
   987   val random_seed = Unsynchronized.ref 1.0;
   988 in
   989 
   990 fun random () = CRITICAL (fn () =>
   991   let val r = rmod (a * ! random_seed) m
   992   in (random_seed := r; r) end);
   993 
   994 end;
   995 
   996 fun random_range l h =
   997   if h < l orelse l < 0 then raise RANDOM
   998   else l + Real.floor (rmod (random ()) (real (h - l + 1)));
   999 
  1000 fun one_of xs = nth xs (random_range 0 (length xs - 1));
  1001 
  1002 fun frequency xs =
  1003   let
  1004     val sum = foldl op + (0, map fst xs);
  1005     fun pick n ((k: int, x) :: xs) =
  1006       if n <= k then x else pick (n - k) xs
  1007   in pick (random_range 1 sum) xs end;
  1008 
  1009 
  1010 
  1011 (** misc **)
  1012 
  1013 fun divide_and_conquer decomp x =
  1014   let val (ys, recomb) = decomp x
  1015   in recomb (map (divide_and_conquer decomp) ys) end;
  1016 
  1017 fun divide_and_conquer' decomp x s =
  1018   let val ((ys, recomb), s') = decomp x s
  1019   in recomb (fold_map (divide_and_conquer' decomp) ys s') end;
  1020 
  1021 
  1022 (*Partition a list into buckets  [ bi, b(i+1), ..., bj ]
  1023    putting x in bk if p(k)(x) holds.  Preserve order of elements if possible.*)
  1024 fun partition_list p i j =
  1025   let
  1026     fun part (k: int) xs =
  1027       if k > j then
  1028         (case xs of
  1029           [] => []
  1030         | _ => raise Fail "partition_list")
  1031       else
  1032         let val (ns, rest) = List.partition (p k) xs
  1033         in ns :: part (k + 1) rest end;
  1034   in part (i: int) end;
  1035 
  1036 fun partition_eq (eq: 'a * 'a -> bool) =
  1037   let
  1038     fun part [] = []
  1039       | part (x :: ys) =
  1040           let val (xs, xs') = List.partition (fn y => eq (x, y)) ys
  1041           in (x :: xs) :: part xs' end;
  1042   in part end;
  1043 
  1044 
  1045 
  1046 (* generating identifiers *)
  1047 
  1048 (** Freshly generated identifiers; supplied prefix MUST start with a letter **)
  1049 local
  1050 (*Maps 0-61 to A-Z, a-z, 0-9; exclude _ or ' to avoid clash with internal/unusual indentifiers*)
  1051 fun gensym_char i =
  1052   if i<26 then chr (ord "A" + i)
  1053   else if i<52 then chr (ord "a" + i - 26)
  1054   else chr (ord "0" + i - 52);
  1055 
  1056 val char_vec = Vector.tabulate (62, gensym_char);
  1057 fun newid n = implode (map (fn i => Vector.sub (char_vec, i)) (radixpand (62, n)));
  1058 
  1059 val gensym_seed = Unsynchronized.ref (0: int);
  1060 
  1061 in
  1062   fun gensym pre =
  1063     pre ^ newid (NAMED_CRITICAL "gensym" (fn () => Unsynchronized.inc gensym_seed));
  1064 end;
  1065 
  1066 
  1067 (* stamps and serial numbers *)
  1068 
  1069 type stamp = unit Unsynchronized.ref;
  1070 val stamp: unit -> stamp = Unsynchronized.ref;
  1071 
  1072 type serial = int;
  1073 val serial = Multithreading.serial;
  1074 val serial_string = string_of_int o serial;
  1075 
  1076 
  1077 (* generic objects *)
  1078 
  1079 (*note that the builtin exception datatype may be extended by new
  1080   constructors at any time*)
  1081 structure Object = struct type T = exn end;
  1082 
  1083 end;
  1084 
  1085 structure Basic_Library: BASIC_LIBRARY = Library;
  1086 open Basic_Library;
  1087 
  1088 datatype legacy = UnequalLengths;