src/HOL/Fun.thy
author hoelzl
Thu Sep 02 10:36:45 2010 +0200 (2010-09-02)
changeset 39074 211e4f6aad63
parent 38620 b40524b74f77
child 39075 a18e5946d63c
permissions -rw-r--r--
bij <--> bij_betw
     1 (*  Title:      HOL/Fun.thy
     2     Author:     Tobias Nipkow, Cambridge University Computer Laboratory
     3     Copyright   1994  University of Cambridge
     4 *)
     5 
     6 header {* Notions about functions *}
     7 
     8 theory Fun
     9 imports Complete_Lattice
    10 begin
    11 
    12 text{*As a simplification rule, it replaces all function equalities by
    13   first-order equalities.*}
    14 lemma expand_fun_eq: "f = g \<longleftrightarrow> (\<forall>x. f x = g x)"
    15 apply (rule iffI)
    16 apply (simp (no_asm_simp))
    17 apply (rule ext)
    18 apply (simp (no_asm_simp))
    19 done
    20 
    21 lemma apply_inverse:
    22   "f x = u \<Longrightarrow> (\<And>x. P x \<Longrightarrow> g (f x) = x) \<Longrightarrow> P x \<Longrightarrow> x = g u"
    23   by auto
    24 
    25 
    26 subsection {* The Identity Function @{text id} *}
    27 
    28 definition
    29   id :: "'a \<Rightarrow> 'a"
    30 where
    31   "id = (\<lambda>x. x)"
    32 
    33 lemma id_apply [simp]: "id x = x"
    34   by (simp add: id_def)
    35 
    36 lemma image_ident [simp]: "(%x. x) ` Y = Y"
    37 by blast
    38 
    39 lemma image_id [simp]: "id ` Y = Y"
    40 by (simp add: id_def)
    41 
    42 lemma vimage_ident [simp]: "(%x. x) -` Y = Y"
    43 by blast
    44 
    45 lemma vimage_id [simp]: "id -` A = A"
    46 by (simp add: id_def)
    47 
    48 
    49 subsection {* The Composition Operator @{text "f \<circ> g"} *}
    50 
    51 definition
    52   comp :: "('b \<Rightarrow> 'c) \<Rightarrow> ('a \<Rightarrow> 'b) \<Rightarrow> 'a \<Rightarrow> 'c" (infixl "o" 55)
    53 where
    54   "f o g = (\<lambda>x. f (g x))"
    55 
    56 notation (xsymbols)
    57   comp  (infixl "\<circ>" 55)
    58 
    59 notation (HTML output)
    60   comp  (infixl "\<circ>" 55)
    61 
    62 text{*compatibility*}
    63 lemmas o_def = comp_def
    64 
    65 lemma o_apply [simp]: "(f o g) x = f (g x)"
    66 by (simp add: comp_def)
    67 
    68 lemma o_assoc: "f o (g o h) = f o g o h"
    69 by (simp add: comp_def)
    70 
    71 lemma id_o [simp]: "id o g = g"
    72 by (simp add: comp_def)
    73 
    74 lemma o_id [simp]: "f o id = f"
    75 by (simp add: comp_def)
    76 
    77 lemma o_eq_dest:
    78   "a o b = c o d \<Longrightarrow> a (b v) = c (d v)"
    79   by (simp only: o_def) (fact fun_cong)
    80 
    81 lemma o_eq_elim:
    82   "a o b = c o d \<Longrightarrow> ((\<And>v. a (b v) = c (d v)) \<Longrightarrow> R) \<Longrightarrow> R"
    83   by (erule meta_mp) (fact o_eq_dest) 
    84 
    85 lemma image_compose: "(f o g) ` r = f`(g`r)"
    86 by (simp add: comp_def, blast)
    87 
    88 lemma vimage_compose: "(g \<circ> f) -` x = f -` (g -` x)"
    89   by auto
    90 
    91 lemma UN_o: "UNION A (g o f) = UNION (f`A) g"
    92 by (unfold comp_def, blast)
    93 
    94 
    95 subsection {* The Forward Composition Operator @{text fcomp} *}
    96 
    97 definition
    98   fcomp :: "('a \<Rightarrow> 'b) \<Rightarrow> ('b \<Rightarrow> 'c) \<Rightarrow> 'a \<Rightarrow> 'c" (infixl "\<circ>>" 60)
    99 where
   100   "f \<circ>> g = (\<lambda>x. g (f x))"
   101 
   102 lemma fcomp_apply [simp]:  "(f \<circ>> g) x = g (f x)"
   103   by (simp add: fcomp_def)
   104 
   105 lemma fcomp_assoc: "(f \<circ>> g) \<circ>> h = f \<circ>> (g \<circ>> h)"
   106   by (simp add: fcomp_def)
   107 
   108 lemma id_fcomp [simp]: "id \<circ>> g = g"
   109   by (simp add: fcomp_def)
   110 
   111 lemma fcomp_id [simp]: "f \<circ>> id = f"
   112   by (simp add: fcomp_def)
   113 
   114 code_const fcomp
   115   (Eval infixl 1 "#>")
   116 
   117 no_notation fcomp (infixl "\<circ>>" 60)
   118 
   119 
   120 subsection {* Injectivity and Surjectivity *}
   121 
   122 definition
   123   inj_on :: "['a => 'b, 'a set] => bool" where
   124   -- "injective"
   125   "inj_on f A == ! x:A. ! y:A. f(x)=f(y) --> x=y"
   126 
   127 text{*A common special case: functions injective over the entire domain type.*}
   128 
   129 abbreviation
   130   "inj f == inj_on f UNIV"
   131 
   132 definition
   133   bij_betw :: "('a => 'b) => 'a set => 'b set => bool" where -- "bijective"
   134   "bij_betw f A B \<longleftrightarrow> inj_on f A & f ` A = B"
   135 
   136 definition
   137   surj :: "('a => 'b) => bool" where
   138   -- "surjective"
   139   "surj f == ! y. ? x. y=f(x)"
   140 
   141 definition
   142   bij :: "('a => 'b) => bool" where
   143   -- "bijective"
   144   "bij f == inj f & surj f"
   145 
   146 lemma injI:
   147   assumes "\<And>x y. f x = f y \<Longrightarrow> x = y"
   148   shows "inj f"
   149   using assms unfolding inj_on_def by auto
   150 
   151 text{*For Proofs in @{text "Tools/Datatype/datatype_rep_proofs"}*}
   152 lemma datatype_injI:
   153     "(!! x. ALL y. f(x) = f(y) --> x=y) ==> inj(f)"
   154 by (simp add: inj_on_def)
   155 
   156 theorem range_ex1_eq: "inj f \<Longrightarrow> b : range f = (EX! x. b = f x)"
   157   by (unfold inj_on_def, blast)
   158 
   159 lemma injD: "[| inj(f); f(x) = f(y) |] ==> x=y"
   160 by (simp add: inj_on_def)
   161 
   162 lemma inj_on_eq_iff: "inj_on f A ==> x:A ==> y:A ==> (f(x) = f(y)) = (x=y)"
   163 by (force simp add: inj_on_def)
   164 
   165 lemma inj_comp:
   166   "inj f \<Longrightarrow> inj g \<Longrightarrow> inj (f \<circ> g)"
   167   by (simp add: inj_on_def)
   168 
   169 lemma inj_fun: "inj f \<Longrightarrow> inj (\<lambda>x y. f x)"
   170   by (simp add: inj_on_def expand_fun_eq)
   171 
   172 lemma inj_eq: "inj f ==> (f(x) = f(y)) = (x=y)"
   173 by (simp add: inj_on_eq_iff)
   174 
   175 lemma inj_on_id[simp]: "inj_on id A"
   176   by (simp add: inj_on_def) 
   177 
   178 lemma inj_on_id2[simp]: "inj_on (%x. x) A"
   179 by (simp add: inj_on_def) 
   180 
   181 lemma surj_id[simp]: "surj id"
   182 by (simp add: surj_def) 
   183 
   184 lemma bij_id[simp]: "bij id"
   185 by (simp add: bij_def)
   186 
   187 lemma inj_onI:
   188     "(!! x y. [|  x:A;  y:A;  f(x) = f(y) |] ==> x=y) ==> inj_on f A"
   189 by (simp add: inj_on_def)
   190 
   191 lemma inj_on_inverseI: "(!!x. x:A ==> g(f(x)) = x) ==> inj_on f A"
   192 by (auto dest:  arg_cong [of concl: g] simp add: inj_on_def)
   193 
   194 lemma inj_onD: "[| inj_on f A;  f(x)=f(y);  x:A;  y:A |] ==> x=y"
   195 by (unfold inj_on_def, blast)
   196 
   197 lemma inj_on_iff: "[| inj_on f A;  x:A;  y:A |] ==> (f(x)=f(y)) = (x=y)"
   198 by (blast dest!: inj_onD)
   199 
   200 lemma comp_inj_on:
   201      "[| inj_on f A;  inj_on g (f`A) |] ==> inj_on (g o f) A"
   202 by (simp add: comp_def inj_on_def)
   203 
   204 lemma inj_on_imageI: "inj_on (g o f) A \<Longrightarrow> inj_on g (f ` A)"
   205 apply(simp add:inj_on_def image_def)
   206 apply blast
   207 done
   208 
   209 lemma inj_on_image_iff: "\<lbrakk> ALL x:A. ALL y:A. (g(f x) = g(f y)) = (g x = g y);
   210   inj_on f A \<rbrakk> \<Longrightarrow> inj_on g (f ` A) = inj_on g A"
   211 apply(unfold inj_on_def)
   212 apply blast
   213 done
   214 
   215 lemma inj_on_contraD: "[| inj_on f A;  ~x=y;  x:A;  y:A |] ==> ~ f(x)=f(y)"
   216 by (unfold inj_on_def, blast)
   217 
   218 lemma inj_singleton: "inj (%s. {s})"
   219 by (simp add: inj_on_def)
   220 
   221 lemma inj_on_empty[iff]: "inj_on f {}"
   222 by(simp add: inj_on_def)
   223 
   224 lemma subset_inj_on: "[| inj_on f B; A <= B |] ==> inj_on f A"
   225 by (unfold inj_on_def, blast)
   226 
   227 lemma inj_on_Un:
   228  "inj_on f (A Un B) =
   229   (inj_on f A & inj_on f B & f`(A-B) Int f`(B-A) = {})"
   230 apply(unfold inj_on_def)
   231 apply (blast intro:sym)
   232 done
   233 
   234 lemma inj_on_insert[iff]:
   235   "inj_on f (insert a A) = (inj_on f A & f a ~: f`(A-{a}))"
   236 apply(unfold inj_on_def)
   237 apply (blast intro:sym)
   238 done
   239 
   240 lemma inj_on_diff: "inj_on f A ==> inj_on f (A-B)"
   241 apply(unfold inj_on_def)
   242 apply (blast)
   243 done
   244 
   245 lemma surjI: "(!! x. g(f x) = x) ==> surj g"
   246 apply (simp add: surj_def)
   247 apply (blast intro: sym)
   248 done
   249 
   250 lemma surj_range: "surj f ==> range f = UNIV"
   251 by (auto simp add: surj_def)
   252 
   253 lemma surjD: "surj f ==> EX x. y = f x"
   254 by (simp add: surj_def)
   255 
   256 lemma surjE: "surj f ==> (!!x. y = f x ==> C) ==> C"
   257 by (simp add: surj_def, blast)
   258 
   259 lemma comp_surj: "[| surj f;  surj g |] ==> surj (g o f)"
   260 apply (simp add: comp_def surj_def, clarify)
   261 apply (drule_tac x = y in spec, clarify)
   262 apply (drule_tac x = x in spec, blast)
   263 done
   264 
   265 lemma surj_range_iff: "surj f \<longleftrightarrow> range f = UNIV"
   266   unfolding expand_set_eq image_iff surj_def by auto
   267 
   268 lemma bij_betw_imp_surj: "bij_betw f A UNIV \<Longrightarrow> surj f"
   269   unfolding bij_betw_def surj_range_iff by auto
   270 
   271 lemma bij_eq_bij_betw: "bij f \<longleftrightarrow> bij_betw f UNIV UNIV"
   272   unfolding bij_def surj_range_iff bij_betw_def ..
   273 
   274 lemma bijI: "[| inj f; surj f |] ==> bij f"
   275 by (simp add: bij_def)
   276 
   277 lemma bij_is_inj: "bij f ==> inj f"
   278 by (simp add: bij_def)
   279 
   280 lemma bij_is_surj: "bij f ==> surj f"
   281 by (simp add: bij_def)
   282 
   283 lemma bij_betw_imp_inj_on: "bij_betw f A B \<Longrightarrow> inj_on f A"
   284 by (simp add: bij_betw_def)
   285 
   286 lemma bij_comp: "bij f \<Longrightarrow> bij g \<Longrightarrow> bij (g o f)"
   287 by(fastsimp intro: comp_inj_on comp_surj simp: bij_def surj_range)
   288 
   289 lemma bij_betw_trans:
   290   "bij_betw f A B \<Longrightarrow> bij_betw g B C \<Longrightarrow> bij_betw (g o f) A C"
   291 by(auto simp add:bij_betw_def comp_inj_on)
   292 
   293 lemma bij_betw_inv: assumes "bij_betw f A B" shows "EX g. bij_betw g B A"
   294 proof -
   295   have i: "inj_on f A" and s: "f ` A = B"
   296     using assms by(auto simp:bij_betw_def)
   297   let ?P = "%b a. a:A \<and> f a = b" let ?g = "%b. The (?P b)"
   298   { fix a b assume P: "?P b a"
   299     hence ex1: "\<exists>a. ?P b a" using s unfolding image_def by blast
   300     hence uex1: "\<exists>!a. ?P b a" by(blast dest:inj_onD[OF i])
   301     hence " ?g b = a" using the1_equality[OF uex1, OF P] P by simp
   302   } note g = this
   303   have "inj_on ?g B"
   304   proof(rule inj_onI)
   305     fix x y assume "x:B" "y:B" "?g x = ?g y"
   306     from s `x:B` obtain a1 where a1: "?P x a1" unfolding image_def by blast
   307     from s `y:B` obtain a2 where a2: "?P y a2" unfolding image_def by blast
   308     from g[OF a1] a1 g[OF a2] a2 `?g x = ?g y` show "x=y" by simp
   309   qed
   310   moreover have "?g ` B = A"
   311   proof(auto simp:image_def)
   312     fix b assume "b:B"
   313     with s obtain a where P: "?P b a" unfolding image_def by blast
   314     thus "?g b \<in> A" using g[OF P] by auto
   315   next
   316     fix a assume "a:A"
   317     then obtain b where P: "?P b a" using s unfolding image_def by blast
   318     then have "b:B" using s unfolding image_def by blast
   319     with g[OF P] show "\<exists>b\<in>B. a = ?g b" by blast
   320   qed
   321   ultimately show ?thesis by(auto simp:bij_betw_def)
   322 qed
   323 
   324 lemma surj_image_vimage_eq: "surj f ==> f ` (f -` A) = A"
   325 by (simp add: surj_range)
   326 
   327 lemma inj_vimage_image_eq: "inj f ==> f -` (f ` A) = A"
   328 by (simp add: inj_on_def, blast)
   329 
   330 lemma vimage_subsetD: "surj f ==> f -` B <= A ==> B <= f ` A"
   331 apply (unfold surj_def)
   332 apply (blast intro: sym)
   333 done
   334 
   335 lemma vimage_subsetI: "inj f ==> B <= f ` A ==> f -` B <= A"
   336 by (unfold inj_on_def, blast)
   337 
   338 lemma vimage_subset_eq: "bij f ==> (f -` B <= A) = (B <= f ` A)"
   339 apply (unfold bij_def)
   340 apply (blast del: subsetI intro: vimage_subsetI vimage_subsetD)
   341 done
   342 
   343 lemma inj_on_Un_image_eq_iff: "inj_on f (A \<union> B) \<Longrightarrow> f ` A = f ` B \<longleftrightarrow> A = B"
   344 by(blast dest: inj_onD)
   345 
   346 lemma inj_on_image_Int:
   347    "[| inj_on f C;  A<=C;  B<=C |] ==> f`(A Int B) = f`A Int f`B"
   348 apply (simp add: inj_on_def, blast)
   349 done
   350 
   351 lemma inj_on_image_set_diff:
   352    "[| inj_on f C;  A<=C;  B<=C |] ==> f`(A-B) = f`A - f`B"
   353 apply (simp add: inj_on_def, blast)
   354 done
   355 
   356 lemma image_Int: "inj f ==> f`(A Int B) = f`A Int f`B"
   357 by (simp add: inj_on_def, blast)
   358 
   359 lemma image_set_diff: "inj f ==> f`(A-B) = f`A - f`B"
   360 by (simp add: inj_on_def, blast)
   361 
   362 lemma inj_image_mem_iff: "inj f ==> (f a : f`A) = (a : A)"
   363 by (blast dest: injD)
   364 
   365 lemma inj_image_subset_iff: "inj f ==> (f`A <= f`B) = (A<=B)"
   366 by (simp add: inj_on_def, blast)
   367 
   368 lemma inj_image_eq_iff: "inj f ==> (f`A = f`B) = (A = B)"
   369 by (blast dest: injD)
   370 
   371 (*injectivity's required.  Left-to-right inclusion holds even if A is empty*)
   372 lemma image_INT:
   373    "[| inj_on f C;  ALL x:A. B x <= C;  j:A |]
   374     ==> f ` (INTER A B) = (INT x:A. f ` B x)"
   375 apply (simp add: inj_on_def, blast)
   376 done
   377 
   378 (*Compare with image_INT: no use of inj_on, and if f is surjective then
   379   it doesn't matter whether A is empty*)
   380 lemma bij_image_INT: "bij f ==> f ` (INTER A B) = (INT x:A. f ` B x)"
   381 apply (simp add: bij_def)
   382 apply (simp add: inj_on_def surj_def, blast)
   383 done
   384 
   385 lemma surj_Compl_image_subset: "surj f ==> -(f`A) <= f`(-A)"
   386 by (auto simp add: surj_def)
   387 
   388 lemma inj_image_Compl_subset: "inj f ==> f`(-A) <= -(f`A)"
   389 by (auto simp add: inj_on_def)
   390 
   391 lemma bij_image_Compl_eq: "bij f ==> f`(-A) = -(f`A)"
   392 apply (simp add: bij_def)
   393 apply (rule equalityI)
   394 apply (simp_all (no_asm_simp) add: inj_image_Compl_subset surj_Compl_image_subset)
   395 done
   396 
   397 lemma (in ordered_ab_group_add) inj_uminus[simp, intro]: "inj_on uminus A"
   398   by (auto intro!: inj_onI)
   399 
   400 lemma (in linorder) strict_mono_imp_inj_on: "strict_mono f \<Longrightarrow> inj_on f A"
   401   by (auto intro!: inj_onI dest: strict_mono_eq)
   402 
   403 subsection{*Function Updating*}
   404 
   405 definition
   406   fun_upd :: "('a => 'b) => 'a => 'b => ('a => 'b)" where
   407   "fun_upd f a b == % x. if x=a then b else f x"
   408 
   409 nonterminals
   410   updbinds updbind
   411 syntax
   412   "_updbind" :: "['a, 'a] => updbind"             ("(2_ :=/ _)")
   413   ""         :: "updbind => updbinds"             ("_")
   414   "_updbinds":: "[updbind, updbinds] => updbinds" ("_,/ _")
   415   "_Update"  :: "['a, updbinds] => 'a"            ("_/'((_)')" [1000, 0] 900)
   416 
   417 translations
   418   "_Update f (_updbinds b bs)" == "_Update (_Update f b) bs"
   419   "f(x:=y)" == "CONST fun_upd f x y"
   420 
   421 (* Hint: to define the sum of two functions (or maps), use sum_case.
   422          A nice infix syntax could be defined (in Datatype.thy or below) by
   423 notation
   424   sum_case  (infixr "'(+')"80)
   425 *)
   426 
   427 lemma fun_upd_idem_iff: "(f(x:=y) = f) = (f x = y)"
   428 apply (simp add: fun_upd_def, safe)
   429 apply (erule subst)
   430 apply (rule_tac [2] ext, auto)
   431 done
   432 
   433 (* f x = y ==> f(x:=y) = f *)
   434 lemmas fun_upd_idem = fun_upd_idem_iff [THEN iffD2, standard]
   435 
   436 (* f(x := f x) = f *)
   437 lemmas fun_upd_triv = refl [THEN fun_upd_idem]
   438 declare fun_upd_triv [iff]
   439 
   440 lemma fun_upd_apply [simp]: "(f(x:=y))z = (if z=x then y else f z)"
   441 by (simp add: fun_upd_def)
   442 
   443 (* fun_upd_apply supersedes these two,   but they are useful
   444    if fun_upd_apply is intentionally removed from the simpset *)
   445 lemma fun_upd_same: "(f(x:=y)) x = y"
   446 by simp
   447 
   448 lemma fun_upd_other: "z~=x ==> (f(x:=y)) z = f z"
   449 by simp
   450 
   451 lemma fun_upd_upd [simp]: "f(x:=y,x:=z) = f(x:=z)"
   452 by (simp add: expand_fun_eq)
   453 
   454 lemma fun_upd_twist: "a ~= c ==> (m(a:=b))(c:=d) = (m(c:=d))(a:=b)"
   455 by (rule ext, auto)
   456 
   457 lemma inj_on_fun_updI: "\<lbrakk> inj_on f A; y \<notin> f`A \<rbrakk> \<Longrightarrow> inj_on (f(x:=y)) A"
   458 by (fastsimp simp:inj_on_def image_def)
   459 
   460 lemma fun_upd_image:
   461      "f(x:=y) ` A = (if x \<in> A then insert y (f ` (A-{x})) else f ` A)"
   462 by auto
   463 
   464 lemma fun_upd_comp: "f \<circ> (g(x := y)) = (f \<circ> g)(x := f y)"
   465 by (auto intro: ext)
   466 
   467 
   468 subsection {* @{text override_on} *}
   469 
   470 definition
   471   override_on :: "('a \<Rightarrow> 'b) \<Rightarrow> ('a \<Rightarrow> 'b) \<Rightarrow> 'a set \<Rightarrow> 'a \<Rightarrow> 'b"
   472 where
   473   "override_on f g A = (\<lambda>a. if a \<in> A then g a else f a)"
   474 
   475 lemma override_on_emptyset[simp]: "override_on f g {} = f"
   476 by(simp add:override_on_def)
   477 
   478 lemma override_on_apply_notin[simp]: "a ~: A ==> (override_on f g A) a = f a"
   479 by(simp add:override_on_def)
   480 
   481 lemma override_on_apply_in[simp]: "a : A ==> (override_on f g A) a = g a"
   482 by(simp add:override_on_def)
   483 
   484 
   485 subsection {* @{text swap} *}
   486 
   487 definition
   488   swap :: "'a \<Rightarrow> 'a \<Rightarrow> ('a \<Rightarrow> 'b) \<Rightarrow> ('a \<Rightarrow> 'b)"
   489 where
   490   "swap a b f = f (a := f b, b:= f a)"
   491 
   492 lemma swap_self [simp]: "swap a a f = f"
   493 by (simp add: swap_def)
   494 
   495 lemma swap_commute: "swap a b f = swap b a f"
   496 by (rule ext, simp add: fun_upd_def swap_def)
   497 
   498 lemma swap_nilpotent [simp]: "swap a b (swap a b f) = f"
   499 by (rule ext, simp add: fun_upd_def swap_def)
   500 
   501 lemma swap_triple:
   502   assumes "a \<noteq> c" and "b \<noteq> c"
   503   shows "swap a b (swap b c (swap a b f)) = swap a c f"
   504   using assms by (simp add: expand_fun_eq swap_def)
   505 
   506 lemma comp_swap: "f \<circ> swap a b g = swap a b (f \<circ> g)"
   507 by (rule ext, simp add: fun_upd_def swap_def)
   508 
   509 lemma inj_on_imp_inj_on_swap:
   510   "[|inj_on f A; a \<in> A; b \<in> A|] ==> inj_on (swap a b f) A"
   511 by (simp add: inj_on_def swap_def, blast)
   512 
   513 lemma inj_on_swap_iff [simp]:
   514   assumes A: "a \<in> A" "b \<in> A" shows "inj_on (swap a b f) A = inj_on f A"
   515 proof 
   516   assume "inj_on (swap a b f) A"
   517   with A have "inj_on (swap a b (swap a b f)) A" 
   518     by (iprover intro: inj_on_imp_inj_on_swap) 
   519   thus "inj_on f A" by simp 
   520 next
   521   assume "inj_on f A"
   522   with A show "inj_on (swap a b f) A" by (iprover intro: inj_on_imp_inj_on_swap)
   523 qed
   524 
   525 lemma surj_imp_surj_swap: "surj f ==> surj (swap a b f)"
   526 apply (simp add: surj_def swap_def, clarify)
   527 apply (case_tac "y = f b", blast)
   528 apply (case_tac "y = f a", auto)
   529 done
   530 
   531 lemma surj_swap_iff [simp]: "surj (swap a b f) = surj f"
   532 proof 
   533   assume "surj (swap a b f)"
   534   hence "surj (swap a b (swap a b f))" by (rule surj_imp_surj_swap) 
   535   thus "surj f" by simp 
   536 next
   537   assume "surj f"
   538   thus "surj (swap a b f)" by (rule surj_imp_surj_swap) 
   539 qed
   540 
   541 lemma bij_swap_iff: "bij (swap a b f) = bij f"
   542 by (simp add: bij_def)
   543 
   544 hide_const (open) swap
   545 
   546 
   547 subsection {* Inversion of injective functions *}
   548 
   549 definition the_inv_into :: "'a set => ('a => 'b) => ('b => 'a)" where
   550 "the_inv_into A f == %x. THE y. y : A & f y = x"
   551 
   552 lemma the_inv_into_f_f:
   553   "[| inj_on f A;  x : A |] ==> the_inv_into A f (f x) = x"
   554 apply (simp add: the_inv_into_def inj_on_def)
   555 apply blast
   556 done
   557 
   558 lemma f_the_inv_into_f:
   559   "inj_on f A ==> y : f`A  ==> f (the_inv_into A f y) = y"
   560 apply (simp add: the_inv_into_def)
   561 apply (rule the1I2)
   562  apply(blast dest: inj_onD)
   563 apply blast
   564 done
   565 
   566 lemma the_inv_into_into:
   567   "[| inj_on f A; x : f ` A; A <= B |] ==> the_inv_into A f x : B"
   568 apply (simp add: the_inv_into_def)
   569 apply (rule the1I2)
   570  apply(blast dest: inj_onD)
   571 apply blast
   572 done
   573 
   574 lemma the_inv_into_onto[simp]:
   575   "inj_on f A ==> the_inv_into A f ` (f ` A) = A"
   576 by (fast intro:the_inv_into_into the_inv_into_f_f[symmetric])
   577 
   578 lemma the_inv_into_f_eq:
   579   "[| inj_on f A; f x = y; x : A |] ==> the_inv_into A f y = x"
   580   apply (erule subst)
   581   apply (erule the_inv_into_f_f, assumption)
   582   done
   583 
   584 lemma the_inv_into_comp:
   585   "[| inj_on f (g ` A); inj_on g A; x : f ` g ` A |] ==>
   586   the_inv_into A (f o g) x = (the_inv_into A g o the_inv_into (g ` A) f) x"
   587 apply (rule the_inv_into_f_eq)
   588   apply (fast intro: comp_inj_on)
   589  apply (simp add: f_the_inv_into_f the_inv_into_into)
   590 apply (simp add: the_inv_into_into)
   591 done
   592 
   593 lemma inj_on_the_inv_into:
   594   "inj_on f A \<Longrightarrow> inj_on (the_inv_into A f) (f ` A)"
   595 by (auto intro: inj_onI simp: image_def the_inv_into_f_f)
   596 
   597 lemma bij_betw_the_inv_into:
   598   "bij_betw f A B \<Longrightarrow> bij_betw (the_inv_into A f) B A"
   599 by (auto simp add: bij_betw_def inj_on_the_inv_into the_inv_into_into)
   600 
   601 abbreviation the_inv :: "('a \<Rightarrow> 'b) \<Rightarrow> ('b \<Rightarrow> 'a)" where
   602   "the_inv f \<equiv> the_inv_into UNIV f"
   603 
   604 lemma the_inv_f_f:
   605   assumes "inj f"
   606   shows "the_inv f (f x) = x" using assms UNIV_I
   607   by (rule the_inv_into_f_f)
   608 
   609 
   610 subsection {* Proof tool setup *} 
   611 
   612 text {* simplifies terms of the form
   613   f(...,x:=y,...,x:=z,...) to f(...,x:=z,...) *}
   614 
   615 simproc_setup fun_upd2 ("f(v := w, x := y)") = {* fn _ =>
   616 let
   617   fun gen_fun_upd NONE T _ _ = NONE
   618     | gen_fun_upd (SOME f) T x y = SOME (Const (@{const_name fun_upd}, T) $ f $ x $ y)
   619   fun dest_fun_T1 (Type (_, T :: Ts)) = T
   620   fun find_double (t as Const (@{const_name fun_upd},T) $ f $ x $ y) =
   621     let
   622       fun find (Const (@{const_name fun_upd},T) $ g $ v $ w) =
   623             if v aconv x then SOME g else gen_fun_upd (find g) T v w
   624         | find t = NONE
   625     in (dest_fun_T1 T, gen_fun_upd (find f) T x y) end
   626 
   627   fun proc ss ct =
   628     let
   629       val ctxt = Simplifier.the_context ss
   630       val t = Thm.term_of ct
   631     in
   632       case find_double t of
   633         (T, NONE) => NONE
   634       | (T, SOME rhs) =>
   635           SOME (Goal.prove ctxt [] [] (Logic.mk_equals (t, rhs))
   636             (fn _ =>
   637               rtac eq_reflection 1 THEN
   638               rtac ext 1 THEN
   639               simp_tac (Simplifier.inherit_context ss @{simpset}) 1))
   640     end
   641 in proc end
   642 *}
   643 
   644 
   645 subsection {* Code generator setup *}
   646 
   647 types_code
   648   "fun"  ("(_ ->/ _)")
   649 attach (term_of) {*
   650 fun term_of_fun_type _ aT _ bT _ = Free ("<function>", aT --> bT);
   651 *}
   652 attach (test) {*
   653 fun gen_fun_type aF aT bG bT i =
   654   let
   655     val tab = Unsynchronized.ref [];
   656     fun mk_upd (x, (_, y)) t = Const ("Fun.fun_upd",
   657       (aT --> bT) --> aT --> bT --> aT --> bT) $ t $ aF x $ y ()
   658   in
   659     (fn x =>
   660        case AList.lookup op = (!tab) x of
   661          NONE =>
   662            let val p as (y, _) = bG i
   663            in (tab := (x, p) :: !tab; y) end
   664        | SOME (y, _) => y,
   665      fn () => Basics.fold mk_upd (!tab) (Const ("HOL.undefined", aT --> bT)))
   666   end;
   667 *}
   668 
   669 code_const "op \<circ>"
   670   (SML infixl 5 "o")
   671   (Haskell infixr 9 ".")
   672 
   673 code_const "id"
   674   (Haskell "id")
   675 
   676 end