src/HOL/Tools/datatype_package.ML
author haftmann
Wed May 28 14:48:50 2008 +0200 (2008-05-28)
changeset 27002 215d64dc971e
parent 26939 1035c89b4c02
child 27097 9a6db5d8ee8c
permissions -rw-r--r--
moved distinctness_limit to datatype_rep_proofs.ML
     1 (*  Title:      HOL/Tools/datatype_package.ML
     2     ID:         $Id$
     3     Author:     Stefan Berghofer, TU Muenchen
     4 
     5 Datatype package for Isabelle/HOL.
     6 *)
     7 
     8 signature BASIC_DATATYPE_PACKAGE =
     9 sig
    10   val induct_tac : string -> int -> tactic
    11   val induct_thm_tac : thm -> string -> int -> tactic
    12   val case_tac : string -> int -> tactic
    13   val distinct_simproc : simproc
    14 end;
    15 
    16 signature DATATYPE_PACKAGE =
    17 sig
    18   include BASIC_DATATYPE_PACKAGE
    19   val quiet_mode : bool ref
    20   val add_datatype_i : bool -> bool -> string list -> (string list * bstring * mixfix *
    21     (bstring * typ list * mixfix) list) list -> theory ->
    22       {distinct : thm list list,
    23        inject : thm list list,
    24        exhaustion : thm list,
    25        rec_thms : thm list,
    26        case_thms : thm list list,
    27        split_thms : (thm * thm) list,
    28        induction : thm,
    29        simps : thm list} * theory
    30   val add_datatype : bool -> string list -> (string list * bstring * mixfix *
    31     (bstring * string list * mixfix) list) list -> theory ->
    32       {distinct : thm list list,
    33        inject : thm list list,
    34        exhaustion : thm list,
    35        rec_thms : thm list,
    36        case_thms : thm list list,
    37        split_thms : (thm * thm) list,
    38        induction : thm,
    39        simps : thm list} * theory
    40   val rep_datatype_i : string list option -> (thm list * attribute list) list list ->
    41     (thm list * attribute list) list list -> (thm list * attribute list) ->
    42     theory ->
    43       {distinct : thm list list,
    44        inject : thm list list,
    45        exhaustion : thm list,
    46        rec_thms : thm list,
    47        case_thms : thm list list,
    48        split_thms : (thm * thm) list,
    49        induction : thm,
    50        simps : thm list} * theory
    51   val rep_datatype : string list option -> (Facts.ref * Attrib.src list) list list ->
    52     (Facts.ref * Attrib.src list) list list -> Facts.ref * Attrib.src list -> theory ->
    53       {distinct : thm list list,
    54        inject : thm list list,
    55        exhaustion : thm list,
    56        rec_thms : thm list,
    57        case_thms : thm list list,
    58        split_thms : (thm * thm) list,
    59        induction : thm,
    60        simps : thm list} * theory
    61   val get_datatypes : theory -> DatatypeAux.datatype_info Symtab.table
    62   val get_datatype : theory -> string -> DatatypeAux.datatype_info option
    63   val the_datatype : theory -> string -> DatatypeAux.datatype_info
    64   val the_datatype_spec : theory -> string -> (string * sort) list * (string * typ list) list
    65   val datatype_of_constr : theory -> string -> DatatypeAux.datatype_info option
    66   val datatype_of_case : theory -> string -> DatatypeAux.datatype_info option
    67   val get_datatype_constrs : theory -> string -> (string * typ) list option
    68   val construction_interpretation: theory
    69     -> { atom: typ -> 'a, dtyp: string -> 'a, rtyp: string -> 'a list -> 'a }
    70     -> (string * Term.sort) list -> string list
    71     -> (string * (string * 'a list) list) list
    72   val interpretation: (string list -> theory -> theory) -> theory -> theory
    73   val print_datatypes : theory -> unit
    74   val make_case :  Proof.context -> bool -> string list -> term ->
    75     (term * term) list -> term * (term * (int * bool)) list
    76   val strip_case: Proof.context -> bool ->
    77     term -> (term * (term * term) list) option
    78   val setup: theory -> theory
    79 end;
    80 
    81 structure DatatypePackage : DATATYPE_PACKAGE =
    82 struct
    83 
    84 open DatatypeAux;
    85 
    86 val quiet_mode = quiet_mode;
    87 
    88 
    89 (* theory data *)
    90 
    91 structure DatatypesData = TheoryDataFun
    92 (
    93   type T =
    94     {types: datatype_info Symtab.table,
    95      constrs: datatype_info Symtab.table,
    96      cases: datatype_info Symtab.table};
    97 
    98   val empty =
    99     {types = Symtab.empty, constrs = Symtab.empty, cases = Symtab.empty};
   100   val copy = I;
   101   val extend = I;
   102   fun merge _
   103     ({types = types1, constrs = constrs1, cases = cases1},
   104      {types = types2, constrs = constrs2, cases = cases2}) =
   105     {types = Symtab.merge (K true) (types1, types2),
   106      constrs = Symtab.merge (K true) (constrs1, constrs2),
   107      cases = Symtab.merge (K true) (cases1, cases2)};
   108 );
   109 
   110 val get_datatypes = #types o DatatypesData.get;
   111 val map_datatypes = DatatypesData.map;
   112 
   113 fun print_datatypes thy =
   114   Pretty.writeln (Pretty.strs ("datatypes:" ::
   115     map #1 (NameSpace.extern_table (Sign.type_space thy, get_datatypes thy))));
   116 
   117 
   118 (** theory information about datatypes **)
   119 
   120 fun put_dt_infos (dt_infos : (string * datatype_info) list) =
   121   map_datatypes (fn {types, constrs, cases} =>
   122     {types = fold Symtab.update dt_infos types,
   123      constrs = fold Symtab.update
   124        (maps (fn (_, info as {descr, index, ...}) => map (rpair info o fst)
   125           (#3 (the (AList.lookup op = descr index)))) dt_infos) constrs,
   126      cases = fold Symtab.update
   127        (map (fn (_, info as {case_name, ...}) => (case_name, info)) dt_infos)
   128        cases});
   129 
   130 val get_datatype = Symtab.lookup o get_datatypes;
   131 
   132 fun the_datatype thy name = (case get_datatype thy name of
   133       SOME info => info
   134     | NONE => error ("Unknown datatype " ^ quote name));
   135 
   136 val datatype_of_constr = Symtab.lookup o #constrs o DatatypesData.get;
   137 val datatype_of_case = Symtab.lookup o #cases o DatatypesData.get;
   138 
   139 fun get_datatype_descr thy dtco =
   140   get_datatype thy dtco
   141   |> Option.map (fn info as { descr, index, ... } =>
   142        (info, (((fn SOME (_, dtys, cos) => (dtys, cos)) o AList.lookup (op =) descr) index)));
   143 
   144 fun the_datatype_spec thy dtco =
   145   let
   146     val info as { descr, index, sorts = raw_sorts, ... } = the_datatype thy dtco;
   147     val SOME (_, dtys, raw_cos) = AList.lookup (op =) descr index;
   148     val sorts = map ((fn v => (v, (the o AList.lookup (op =) raw_sorts) v))
   149       o DatatypeAux.dest_DtTFree) dtys;
   150     val cos = map
   151       (fn (co, tys) => (co, map (DatatypeAux.typ_of_dtyp descr sorts) tys)) raw_cos;
   152   in (sorts, cos) end;
   153 
   154 fun get_datatype_constrs thy dtco =
   155   case try (the_datatype_spec thy) dtco
   156    of SOME (sorts, cos) =>
   157         let
   158           fun subst (v, sort) = TVar ((v, 0), sort);
   159           fun subst_ty (TFree v) = subst v
   160             | subst_ty ty = ty;
   161           val dty = Type (dtco, map subst sorts);
   162           fun mk_co (co, tys) = (co, map (Term.map_atyps subst_ty) tys ---> dty);
   163         in SOME (map mk_co cos) end
   164     | NONE => NONE;
   165 
   166 fun construction_interpretation thy { atom, dtyp, rtyp } sorts tycos =
   167   let
   168     val descr = (#descr o the_datatype thy o hd) tycos;
   169     val k = length tycos;
   170     val descr_of = the o AList.lookup (op =) descr;
   171     fun interpT (T as DtTFree _) = atom (typ_of_dtyp descr sorts T)
   172       | interpT (T as DtType (tyco, Ts)) = if is_rec_type T
   173           then rtyp tyco (map interpT Ts)
   174           else atom (typ_of_dtyp descr sorts T)
   175       | interpT (DtRec l) = if l < k then (dtyp o #1 o descr_of) l
   176           else let val (tyco, Ts, _) = descr_of l
   177           in rtyp tyco (map interpT Ts) end;
   178     fun interpC (c, Ts) = (c, map interpT Ts);
   179     fun interpK (_, (tyco, _, cs)) = (tyco, map interpC cs);
   180   in map interpK (Library.take (k, descr)) end;
   181 
   182 fun find_tname var Bi =
   183   let val frees = map dest_Free (term_frees Bi)
   184       val params = rename_wrt_term Bi (Logic.strip_params Bi);
   185   in case AList.lookup (op =) (frees @ params) var of
   186        NONE => error ("No such variable in subgoal: " ^ quote var)
   187      | SOME(Type (tn, _)) => tn
   188      | _ => error ("Cannot determine type of " ^ quote var)
   189   end;
   190 
   191 fun infer_tname state i aterm =
   192   let
   193     val sign = Thm.theory_of_thm state;
   194     val (_, _, Bi, _) = Thm.dest_state (state, i)
   195     val params = Logic.strip_params Bi;   (*params of subgoal i*)
   196     val params = rev (rename_wrt_term Bi params);   (*as they are printed*)
   197     val (types, sorts) = types_sorts state;
   198     fun types' (a, ~1) = (case AList.lookup (op =) params a of NONE => types(a, ~1) | sm => sm)
   199       | types' ixn = types ixn;
   200     val ([ct], _) = Thm.read_def_cterms (sign, types', sorts) [] false [(aterm, dummyT)];
   201   in case #T (rep_cterm ct) of
   202        Type (tn, _) => tn
   203      | _ => error ("Cannot determine type of " ^ quote aterm)
   204   end;
   205 
   206 (*Warn if the (induction) variable occurs Free among the premises, which
   207   usually signals a mistake.  But calls the tactic either way!*)
   208 fun occs_in_prems tacf vars =
   209   SUBGOAL (fn (Bi, i) =>
   210            (if exists (fn (a, _) => member (op =) vars a)
   211                       (fold Term.add_frees (#2 (strip_context Bi)) [])
   212              then warning "Induction variable occurs also among premises!"
   213              else ();
   214             tacf i));
   215 
   216 
   217 (* generic induction tactic for datatypes *)
   218 
   219 local
   220 
   221 fun prep_var (Var (ixn, _), SOME x) = SOME (ixn, x)
   222   | prep_var _ = NONE;
   223 
   224 fun prep_inst (concl, xs) = (*exception Library.UnequalLengths*)
   225   let val vs = Induct.vars_of concl
   226   in map_filter prep_var (Library.drop (length vs - length xs, vs) ~~ xs) end;
   227 
   228 in
   229 
   230 fun gen_induct_tac inst_tac (varss, opt_rule) i state =
   231   SUBGOAL (fn (Bi,_) =>
   232   let
   233     val (rule, rule_name) =
   234       case opt_rule of
   235           SOME r => (r, "Induction rule")
   236         | NONE =>
   237             let val tn = find_tname (hd (map_filter I (flat varss))) Bi
   238                 val thy = Thm.theory_of_thm state
   239             in (#induction (the_datatype thy tn), "Induction rule for type " ^ tn)
   240             end
   241     val concls = HOLogic.dest_concls (Thm.concl_of rule);
   242     val insts = maps prep_inst (concls ~~ varss) handle Library.UnequalLengths =>
   243       error (rule_name ^ " has different numbers of variables");
   244   in occs_in_prems (inst_tac insts rule) (map #2 insts) i end)
   245   i state;
   246 
   247 fun induct_tac s =
   248   gen_induct_tac Tactic.res_inst_tac'
   249     (map (single o SOME) (Syntax.read_idents s), NONE);
   250 
   251 fun induct_thm_tac th s =
   252   gen_induct_tac Tactic.res_inst_tac'
   253     ([map SOME (Syntax.read_idents s)], SOME th);
   254 
   255 end;
   256 
   257 
   258 (* generic case tactic for datatypes *)
   259 
   260 fun case_inst_tac inst_tac t rule i state =
   261   let
   262     val _ $ Var (ixn, _) $ _ = HOLogic.dest_Trueprop
   263       (hd (Logic.strip_assums_hyp (hd (Thm.prems_of rule))));
   264   in inst_tac [(ixn, t)] rule i state end;
   265 
   266 fun gen_case_tac inst_tac (t, SOME rule) i state =
   267       case_inst_tac inst_tac t rule i state
   268   | gen_case_tac inst_tac (t, NONE) i state =
   269       let val tn = infer_tname state i t in
   270         if tn = HOLogic.boolN then inst_tac [(("P", 0), t)] case_split_thm i state
   271         else case_inst_tac inst_tac t
   272                (#exhaustion (the_datatype (Thm.theory_of_thm state) tn))
   273                i state
   274       end handle THM _ => Seq.empty;
   275 
   276 fun case_tac t = gen_case_tac Tactic.res_inst_tac' (t, NONE);
   277 
   278 
   279 
   280 (** Isar tactic emulations **)
   281 
   282 local
   283 
   284 val rule_spec = Scan.lift (Args.$$$ "rule" -- Args.$$$ ":");
   285 val opt_rule = Scan.option (rule_spec |-- Attrib.thm);
   286 
   287 val varss =
   288   Args.and_list (Scan.repeat (Scan.unless rule_spec (Scan.lift (Args.maybe Args.name))));
   289 
   290 val inst_tac = RuleInsts.bires_inst_tac false;
   291 
   292 fun induct_meth ctxt (varss, opt_rule) =
   293   gen_induct_tac (inst_tac ctxt) (varss, opt_rule);
   294 fun case_meth ctxt (varss, opt_rule) =
   295   gen_case_tac (inst_tac ctxt) (varss, opt_rule);
   296 
   297 in
   298 
   299 val tactic_emulations =
   300  [("induct_tac", Method.goal_args_ctxt' (varss -- opt_rule) induct_meth,
   301     "induct_tac emulation (dynamic instantiation)"),
   302   ("case_tac", Method.goal_args_ctxt' (Scan.lift Args.name -- opt_rule) case_meth,
   303     "case_tac emulation (dynamic instantiation)")];
   304 
   305 end;
   306 
   307 
   308 
   309 (** induct method setup **)
   310 
   311 (* case names *)
   312 
   313 local
   314 
   315 fun dt_recs (DtTFree _) = []
   316   | dt_recs (DtType (_, dts)) = maps dt_recs dts
   317   | dt_recs (DtRec i) = [i];
   318 
   319 fun dt_cases (descr: descr) (_, args, constrs) =
   320   let
   321     fun the_bname i = Sign.base_name (#1 (the (AList.lookup (op =) descr i)));
   322     val bnames = map the_bname (distinct (op =) (maps dt_recs args));
   323   in map (fn (c, _) => space_implode "_" (Sign.base_name c :: bnames)) constrs end;
   324 
   325 
   326 fun induct_cases descr =
   327   DatatypeProp.indexify_names (maps (dt_cases descr) (map #2 descr));
   328 
   329 fun exhaust_cases descr i = dt_cases descr (the (AList.lookup (op =) descr i));
   330 
   331 in
   332 
   333 fun mk_case_names_induct descr = RuleCases.case_names (induct_cases descr);
   334 
   335 fun mk_case_names_exhausts descr new =
   336   map (RuleCases.case_names o exhaust_cases descr o #1)
   337     (filter (fn ((_, (name, _, _))) => member (op =) new name) descr);
   338 
   339 end;
   340 
   341 fun add_rules simps case_thms rec_thms inject distinct
   342                   weak_case_congs cong_att =
   343   PureThy.add_thmss [(("simps", simps), []),
   344     (("", flat case_thms @
   345           flat distinct @ rec_thms), [Simplifier.simp_add]),
   346     (("", rec_thms), [RecfunCodegen.add_default]),
   347     (("", flat inject), [iff_add]),
   348     (("", map (fn th => th RS notE) (flat distinct)), [Classical.safe_elim NONE]),
   349     (("", weak_case_congs), [cong_att])]
   350   #> snd;
   351 
   352 
   353 (* add_cases_induct *)
   354 
   355 fun add_cases_induct infos induction thy =
   356   let
   357     val inducts = ProjectRule.projections (ProofContext.init thy) induction;
   358 
   359     fun named_rules (name, {index, exhaustion, ...}: datatype_info) =
   360       [(("", nth inducts index), [Induct.induct_type name]),
   361        (("", exhaustion), [Induct.cases_type name])];
   362     fun unnamed_rule i =
   363       (("", nth inducts i), [PureThy.kind_internal, Induct.induct_type ""]);
   364   in
   365     thy |> PureThy.add_thms
   366       (maps named_rules infos @
   367         map unnamed_rule (length infos upto length inducts - 1)) |> snd
   368     |> PureThy.add_thmss [(("inducts", inducts), [])] |> snd
   369   end;
   370 
   371 
   372 
   373 (**** simplification procedure for showing distinctness of constructors ****)
   374 
   375 fun stripT (i, Type ("fun", [_, T])) = stripT (i + 1, T)
   376   | stripT p = p;
   377 
   378 fun stripC (i, f $ x) = stripC (i + 1, f)
   379   | stripC p = p;
   380 
   381 val distinctN = "constr_distinct";
   382 
   383 fun distinct_rule thy ss tname eq_t = case #distinct (the_datatype thy tname) of
   384     FewConstrs thms => Goal.prove (Simplifier.the_context ss) [] [] eq_t (K
   385       (EVERY [rtac eq_reflection 1, rtac iffI 1, rtac notE 1,
   386         atac 2, resolve_tac thms 1, etac FalseE 1]))
   387   | ManyConstrs (thm, simpset) =>
   388       let
   389         val [In0_inject, In1_inject, In0_not_In1, In1_not_In0] =
   390           map (PureThy.get_thm (ThyInfo.the_theory "Datatype" thy))
   391             ["In0_inject", "In1_inject", "In0_not_In1", "In1_not_In0"];
   392       in
   393         Goal.prove (Simplifier.the_context ss) [] [] eq_t (K
   394         (EVERY [rtac eq_reflection 1, rtac iffI 1, dtac thm 1,
   395           full_simp_tac (Simplifier.inherit_context ss simpset) 1,
   396           REPEAT (dresolve_tac [In0_inject, In1_inject] 1),
   397           eresolve_tac [In0_not_In1 RS notE, In1_not_In0 RS notE] 1,
   398           etac FalseE 1]))
   399       end;
   400 
   401 fun distinct_proc thy ss (t as Const ("op =", _) $ t1 $ t2) =
   402   (case (stripC (0, t1), stripC (0, t2)) of
   403      ((i, Const (cname1, T1)), (j, Const (cname2, T2))) =>
   404          (case (stripT (0, T1), stripT (0, T2)) of
   405             ((i', Type (tname1, _)), (j', Type (tname2, _))) =>
   406                 if tname1 = tname2 andalso not (cname1 = cname2) andalso i = i' andalso j = j' then
   407                    (case (get_datatype_descr thy) tname1 of
   408                       SOME (_, (_, constrs)) => let val cnames = map fst constrs
   409                         in if cname1 mem cnames andalso cname2 mem cnames then
   410                              SOME (distinct_rule thy ss tname1
   411                                (Logic.mk_equals (t, Const ("False", HOLogic.boolT))))
   412                            else NONE
   413                         end
   414                     | NONE => NONE)
   415                 else NONE
   416           | _ => NONE)
   417    | _ => NONE)
   418   | distinct_proc _ _ _ = NONE;
   419 
   420 val distinct_simproc =
   421   Simplifier.simproc HOL.thy distinctN ["s = t"] distinct_proc;
   422 
   423 val dist_ss = HOL_ss addsimprocs [distinct_simproc];
   424 
   425 val simproc_setup =
   426   Simplifier.map_simpset (fn ss => ss addsimprocs [distinct_simproc]);
   427 
   428 
   429 (**** translation rules for case ****)
   430 
   431 fun make_case ctxt = DatatypeCase.make_case
   432   (datatype_of_constr (ProofContext.theory_of ctxt)) ctxt;
   433 
   434 fun strip_case ctxt = DatatypeCase.strip_case
   435   (datatype_of_case (ProofContext.theory_of ctxt));
   436 
   437 fun add_case_tr' case_names thy =
   438   Sign.add_advanced_trfuns ([], [],
   439     map (fn case_name =>
   440       let val case_name' = Sign.const_syntax_name thy case_name
   441       in (case_name', DatatypeCase.case_tr' datatype_of_case case_name')
   442       end) case_names, []) thy;
   443 
   444 val trfun_setup =
   445   Sign.add_advanced_trfuns ([],
   446     [("_case_syntax", DatatypeCase.case_tr true datatype_of_constr)],
   447     [], []);
   448 
   449 
   450 (* prepare types *)
   451 
   452 fun read_typ sign ((Ts, sorts), str) =
   453   let
   454     val T = Type.no_tvars (Sign.read_def_typ (sign, AList.lookup (op =)
   455       (map (apfst (rpair ~1)) sorts)) str) handle TYPE (msg, _, _) => error msg
   456   in (Ts @ [T], add_typ_tfrees (T, sorts)) end;
   457 
   458 fun cert_typ sign ((Ts, sorts), raw_T) =
   459   let
   460     val T = Type.no_tvars (Sign.certify_typ sign raw_T) handle
   461       TYPE (msg, _, _) => error msg;
   462     val sorts' = add_typ_tfrees (T, sorts)
   463   in (Ts @ [T],
   464       case duplicates (op =) (map fst sorts') of
   465          [] => sorts'
   466        | dups => error ("Inconsistent sort constraints for " ^ commas dups))
   467   end;
   468 
   469 
   470 (**** make datatype info ****)
   471 
   472 fun make_dt_info alt_names descr sorts induct reccomb_names rec_thms
   473     (((((((((i, (_, (tname, _, _))), case_name), case_thms),
   474       exhaustion_thm), distinct_thm), inject), nchotomy), case_cong), weak_case_cong) =
   475   (tname,
   476    {index = i,
   477     alt_names = alt_names,
   478     descr = descr,
   479     sorts = sorts,
   480     rec_names = reccomb_names,
   481     rec_rewrites = rec_thms,
   482     case_name = case_name,
   483     case_rewrites = case_thms,
   484     induction = induct,
   485     exhaustion = exhaustion_thm,
   486     distinct = distinct_thm,
   487     inject = inject,
   488     nchotomy = nchotomy,
   489     case_cong = case_cong,
   490     weak_case_cong = weak_case_cong});
   491 
   492 structure DatatypeInterpretation = InterpretationFun(type T = string list val eq = op =);
   493 val interpretation = DatatypeInterpretation.interpretation;
   494 
   495 
   496 (******************* definitional introduction of datatypes *******************)
   497 
   498 fun add_datatype_def flat_names new_type_names descr sorts types_syntax constr_syntax dt_info
   499     case_names_induct case_names_exhausts thy =
   500   let
   501     val _ = message ("Proofs for datatype(s) " ^ commas_quote new_type_names);
   502 
   503     val ((inject, distinct, dist_rewrites, simproc_dists, induct), thy2) = thy |>
   504       DatatypeRepProofs.representation_proofs flat_names dt_info new_type_names descr sorts
   505         types_syntax constr_syntax case_names_induct;
   506 
   507     val (casedist_thms, thy3) = DatatypeAbsProofs.prove_casedist_thms new_type_names descr
   508       sorts induct case_names_exhausts thy2;
   509     val ((reccomb_names, rec_thms), thy4) = DatatypeAbsProofs.prove_primrec_thms
   510       flat_names new_type_names descr sorts dt_info inject dist_rewrites
   511       (Simplifier.theory_context thy3 dist_ss) induct thy3;
   512     val ((case_thms, case_names), thy6) = DatatypeAbsProofs.prove_case_thms
   513       flat_names new_type_names descr sorts reccomb_names rec_thms thy4;
   514     val (split_thms, thy7) = DatatypeAbsProofs.prove_split_thms new_type_names
   515       descr sorts inject dist_rewrites casedist_thms case_thms thy6;
   516     val (nchotomys, thy8) = DatatypeAbsProofs.prove_nchotomys new_type_names
   517       descr sorts casedist_thms thy7;
   518     val (case_congs, thy9) = DatatypeAbsProofs.prove_case_congs new_type_names
   519       descr sorts nchotomys case_thms thy8;
   520     val (weak_case_congs, thy10) = DatatypeAbsProofs.prove_weak_case_congs new_type_names
   521       descr sorts thy9;
   522 
   523     val dt_infos = map (make_dt_info NONE (flat descr) sorts induct reccomb_names rec_thms)
   524       ((0 upto length (hd descr) - 1) ~~ (hd descr) ~~ case_names ~~ case_thms ~~
   525         casedist_thms ~~ simproc_dists ~~ inject ~~ nchotomys ~~ case_congs ~~ weak_case_congs);
   526 
   527     val simps = flat (distinct @ inject @ case_thms) @ rec_thms;
   528 
   529     val thy12 =
   530       thy10
   531       |> add_case_tr' case_names
   532       |> Sign.add_path (space_implode "_" new_type_names)
   533       |> add_rules simps case_thms rec_thms inject distinct
   534           weak_case_congs (Simplifier.attrib (op addcongs))
   535       |> put_dt_infos dt_infos
   536       |> add_cases_induct dt_infos induct
   537       |> Sign.parent_path
   538       |> store_thmss "splits" new_type_names (map (fn (x, y) => [x, y]) split_thms) |> snd
   539       |> DatatypeInterpretation.data (map fst dt_infos);
   540   in
   541     ({distinct = distinct,
   542       inject = inject,
   543       exhaustion = casedist_thms,
   544       rec_thms = rec_thms,
   545       case_thms = case_thms,
   546       split_thms = split_thms,
   547       induction = induct,
   548       simps = simps}, thy12)
   549   end;
   550 
   551 
   552 (*********************** declare existing type as datatype *********************)
   553 
   554 fun gen_rep_datatype apply_theorems alt_names raw_distinct raw_inject raw_induction thy0 =
   555   let
   556     val (((distinct, inject), [induction]), thy1) =
   557       thy0
   558       |> fold_map apply_theorems raw_distinct
   559       ||>> fold_map apply_theorems raw_inject
   560       ||>> apply_theorems [raw_induction];
   561 
   562     val ((_, [induction']), _) =
   563       Variable.importT_thms [induction] (Variable.thm_context induction);
   564 
   565     fun err t = error ("Ill-formed predicate in induction rule: " ^
   566       Syntax.string_of_term_global thy1 t);
   567 
   568     fun get_typ (t as _ $ Var (_, Type (tname, Ts))) =
   569           ((tname, map (fst o dest_TFree) Ts) handle TERM _ => err t)
   570       | get_typ t = err t;
   571 
   572     val dtnames = map get_typ (HOLogic.dest_conj (HOLogic.dest_Trueprop (Thm.concl_of induction')));
   573     val new_type_names = getOpt (alt_names, map fst dtnames);
   574 
   575     fun get_constr t = (case Logic.strip_assums_concl t of
   576         _ $ (_ $ t') => (case head_of t' of
   577             Const (cname, cT) => (case strip_type cT of
   578                 (Ts, Type (tname, _)) => (tname, (cname, map (dtyp_of_typ dtnames) Ts))
   579               | _ => err t)
   580           | _ => err t)
   581       | _ => err t);
   582 
   583     fun make_dt_spec [] _ _ = []
   584       | make_dt_spec ((tname, tvs)::dtnames') i constrs =
   585           let val (constrs', constrs'') = take_prefix (equal tname o fst) constrs
   586           in (i, (tname, map DtTFree tvs, map snd constrs'))::
   587             (make_dt_spec dtnames' (i + 1) constrs'')
   588           end;
   589 
   590     val descr = make_dt_spec dtnames 0 (map get_constr (prems_of induction'));
   591     val sorts = add_term_tfrees (concl_of induction', []);
   592     val dt_info = get_datatypes thy1;
   593 
   594     val (case_names_induct, case_names_exhausts) =
   595       (mk_case_names_induct descr, mk_case_names_exhausts descr (map #1 dtnames));
   596 
   597     val _ = message ("Proofs for datatype(s) " ^ commas_quote new_type_names);
   598 
   599     val (casedist_thms, thy2) = thy1 |>
   600       DatatypeAbsProofs.prove_casedist_thms new_type_names [descr] sorts induction
   601         case_names_exhausts;
   602     val ((reccomb_names, rec_thms), thy3) = DatatypeAbsProofs.prove_primrec_thms
   603       false new_type_names [descr] sorts dt_info inject distinct
   604       (Simplifier.theory_context thy2 dist_ss) induction thy2;
   605     val ((case_thms, case_names), thy4) = DatatypeAbsProofs.prove_case_thms false
   606       new_type_names [descr] sorts reccomb_names rec_thms thy3;
   607     val (split_thms, thy5) = DatatypeAbsProofs.prove_split_thms
   608       new_type_names [descr] sorts inject distinct casedist_thms case_thms thy4;
   609     val (nchotomys, thy6) = DatatypeAbsProofs.prove_nchotomys new_type_names
   610       [descr] sorts casedist_thms thy5;
   611     val (case_congs, thy7) = DatatypeAbsProofs.prove_case_congs new_type_names
   612       [descr] sorts nchotomys case_thms thy6;
   613     val (weak_case_congs, thy8) = DatatypeAbsProofs.prove_weak_case_congs new_type_names
   614       [descr] sorts thy7;
   615 
   616     val ((_, [induction']), thy10) =
   617       thy8
   618       |> store_thmss "inject" new_type_names inject
   619       ||>> store_thmss "distinct" new_type_names distinct
   620       ||> Sign.add_path (space_implode "_" new_type_names)
   621       ||>> PureThy.add_thms [(("induct", induction), [case_names_induct])];
   622 
   623     val dt_infos = map (make_dt_info alt_names descr sorts induction' reccomb_names rec_thms)
   624       ((0 upto length descr - 1) ~~ descr ~~ case_names ~~ case_thms ~~ casedist_thms ~~
   625         map FewConstrs distinct ~~ inject ~~ nchotomys ~~ case_congs ~~ weak_case_congs);
   626 
   627     val simps = flat (distinct @ inject @ case_thms) @ rec_thms;
   628 
   629     val thy11 =
   630       thy10
   631       |> add_case_tr' case_names
   632       |> add_rules simps case_thms rec_thms inject distinct
   633            weak_case_congs (Simplifier.attrib (op addcongs))
   634       |> put_dt_infos dt_infos
   635       |> add_cases_induct dt_infos induction'
   636       |> Sign.parent_path
   637       |> store_thmss "splits" new_type_names (map (fn (x, y) => [x, y]) split_thms)
   638       |> snd
   639       |> DatatypeInterpretation.data (map fst dt_infos);
   640   in
   641     ({distinct = distinct,
   642       inject = inject,
   643       exhaustion = casedist_thms,
   644       rec_thms = rec_thms,
   645       case_thms = case_thms,
   646       split_thms = split_thms,
   647       induction = induction',
   648       simps = simps}, thy11)
   649   end;
   650 
   651 val rep_datatype = gen_rep_datatype IsarCmd.apply_theorems;
   652 val rep_datatype_i = gen_rep_datatype IsarCmd.apply_theorems_i;
   653 
   654 
   655 
   656 (******************************** add datatype ********************************)
   657 
   658 fun gen_add_datatype prep_typ err flat_names new_type_names dts thy =
   659   let
   660     val _ = Theory.requires thy "Datatype" "datatype definitions";
   661 
   662     (* this theory is used just for parsing *)
   663 
   664     val tmp_thy = thy |>
   665       Theory.copy |>
   666       Sign.add_types (map (fn (tvs, tname, mx, _) =>
   667         (tname, length tvs, mx)) dts);
   668 
   669     val (tyvars, _, _, _)::_ = dts;
   670     val (new_dts, types_syntax) = ListPair.unzip (map (fn (tvs, tname, mx, _) =>
   671       let val full_tname = Sign.full_name tmp_thy (Syntax.type_name tname mx)
   672       in (case duplicates (op =) tvs of
   673             [] => if eq_set (tyvars, tvs) then ((full_tname, tvs), (tname, mx))
   674                   else error ("Mutually recursive datatypes must have same type parameters")
   675           | dups => error ("Duplicate parameter(s) for datatype " ^ full_tname ^
   676               " : " ^ commas dups))
   677       end) dts);
   678 
   679     val _ = (case duplicates (op =) (map fst new_dts) @ duplicates (op =) new_type_names of
   680       [] => () | dups => error ("Duplicate datatypes: " ^ commas dups));
   681 
   682     fun prep_dt_spec (tvs, tname, mx, constrs) (dts', constr_syntax, sorts, i) =
   683       let
   684         fun prep_constr (cname, cargs, mx') (constrs, constr_syntax', sorts') =
   685           let
   686             val (cargs', sorts'') = Library.foldl (prep_typ tmp_thy) (([], sorts'), cargs);
   687             val _ = (case fold (curry add_typ_tfree_names) cargs' [] \\ tvs of
   688                 [] => ()
   689               | vs => error ("Extra type variables on rhs: " ^ commas vs))
   690           in (constrs @ [((if flat_names then Sign.full_name tmp_thy else
   691                 Sign.full_name_path tmp_thy tname) (Syntax.const_name cname mx'),
   692                    map (dtyp_of_typ new_dts) cargs')],
   693               constr_syntax' @ [(cname, mx')], sorts'')
   694           end handle ERROR msg =>
   695             cat_error msg ("The error above occured in constructor " ^ cname ^
   696               " of datatype " ^ tname);
   697 
   698         val (constrs', constr_syntax', sorts') =
   699           fold prep_constr constrs ([], [], sorts)
   700 
   701       in
   702         case duplicates (op =) (map fst constrs') of
   703            [] =>
   704              (dts' @ [(i, (Sign.full_name tmp_thy (Syntax.type_name tname mx),
   705                 map DtTFree tvs, constrs'))],
   706               constr_syntax @ [constr_syntax'], sorts', i + 1)
   707          | dups => error ("Duplicate constructors " ^ commas dups ^
   708              " in datatype " ^ tname)
   709       end;
   710 
   711     val (dts', constr_syntax, sorts', i) = fold prep_dt_spec dts ([], [], [], 0);
   712     val sorts = sorts' @ (map (rpair (Sign.defaultS tmp_thy)) (tyvars \\ map fst sorts'));
   713     val dt_info = get_datatypes thy;
   714     val (descr, _) = unfold_datatypes tmp_thy dts' sorts dt_info dts' i;
   715     val _ = check_nonempty descr handle (exn as Datatype_Empty s) =>
   716       if err then error ("Nonemptiness check failed for datatype " ^ s)
   717       else raise exn;
   718 
   719     val descr' = flat descr;
   720     val case_names_induct = mk_case_names_induct descr';
   721     val case_names_exhausts = mk_case_names_exhausts descr' (map #1 new_dts);
   722   in
   723     add_datatype_def
   724       flat_names new_type_names descr sorts types_syntax constr_syntax dt_info
   725       case_names_induct case_names_exhausts thy
   726   end;
   727 
   728 val add_datatype_i = gen_add_datatype cert_typ;
   729 val add_datatype = gen_add_datatype read_typ true;
   730 
   731 
   732 (** a datatype antiquotation **)
   733 
   734 local
   735 
   736 val sym_datatype = Pretty.str "\\isacommand{datatype}";
   737 val sym_binder = Pretty.str "{\\isacharequal}";
   738 val sym_of = Pretty.str "of";
   739 val sym_sep = Pretty.str "{\\isacharbar}";
   740 
   741 in
   742 
   743 fun args_datatype (ctxt, args) =
   744   let
   745     val (tyco, (ctxt', args')) = Args.tyname (ctxt, args);
   746     val thy = Context.theory_of ctxt';
   747     val spec = the_datatype_spec thy tyco;
   748   in ((tyco, spec), (ctxt', args')) end;
   749 
   750 fun pretty_datatype ctxt (dtco, (vs, cos)) =
   751   let
   752     val ty = Type (dtco, map TFree vs);
   753     fun pretty_typ_br ty =
   754       let
   755         val p = Syntax.pretty_typ ctxt ty;
   756         val s = explode (Pretty.str_of p);
   757       in if member (op =) s " " then Pretty.enclose "(" ")" [p]
   758         else p
   759       end;
   760     fun pretty_constr (co, []) =
   761           Syntax.pretty_term ctxt (Const (co, ty))
   762       | pretty_constr (co, [ty']) =
   763           (Pretty.block o Pretty.breaks)
   764             [Syntax.pretty_term ctxt (Const (co, ty' --> ty)),
   765               sym_of, Syntax.pretty_typ ctxt ty']
   766       | pretty_constr (co, tys) =
   767           (Pretty.block o Pretty.breaks)
   768             (Syntax.pretty_term ctxt (Const (co, tys ---> ty)) ::
   769               sym_of :: map pretty_typ_br tys);
   770   in (Pretty.block o Pretty.breaks) (
   771     sym_datatype
   772     :: Syntax.pretty_typ ctxt ty
   773     :: sym_binder
   774     :: separate sym_sep (map pretty_constr cos)
   775   ) end
   776 
   777 end;
   778 
   779 (** package setup **)
   780 
   781 (* setup theory *)
   782 
   783 val setup =
   784   DatatypeRepProofs.distinctness_limit_setup #>
   785   Method.add_methods tactic_emulations #>
   786   simproc_setup #>
   787   trfun_setup #>
   788   DatatypeInterpretation.init;
   789 
   790 
   791 (* outer syntax *)
   792 
   793 local structure P = OuterParse and K = OuterKeyword in
   794 
   795 val _ = OuterSyntax.keywords ["distinct", "inject", "induction"];
   796 
   797 val datatype_decl =
   798   Scan.option (P.$$$ "(" |-- P.name --| P.$$$ ")") -- P.type_args -- P.name -- P.opt_infix --
   799     (P.$$$ "=" |-- P.enum1 "|" (P.name -- Scan.repeat P.typ -- P.opt_mixfix));
   800 
   801 fun mk_datatype args =
   802   let
   803     val names = map (fn ((((NONE, _), t), _), _) => t | ((((SOME t, _), _), _), _) => t) args;
   804     val specs = map (fn ((((_, vs), t), mx), cons) =>
   805       (vs, t, mx, map (fn ((x, y), z) => (x, y, z)) cons)) args;
   806   in snd o add_datatype false names specs end;
   807 
   808 val _ =
   809   OuterSyntax.command "datatype" "define inductive datatypes" K.thy_decl
   810     (P.and_list1 datatype_decl >> (Toplevel.theory o mk_datatype));
   811 
   812 
   813 val rep_datatype_decl =
   814   Scan.option (Scan.repeat1 P.name) --
   815     Scan.optional (P.$$$ "distinct" |-- P.!!! (P.and_list1 SpecParse.xthms1)) [[]] --
   816     Scan.optional (P.$$$ "inject" |-- P.!!! (P.and_list1 SpecParse.xthms1)) [[]] --
   817     (P.$$$ "induction" |-- P.!!! SpecParse.xthm);
   818 
   819 fun mk_rep_datatype (((opt_ts, dss), iss), ind) = #2 o rep_datatype opt_ts dss iss ind;
   820 
   821 val _ =
   822   OuterSyntax.command "rep_datatype" "represent existing types inductively" K.thy_decl
   823     (rep_datatype_decl >> (Toplevel.theory o mk_rep_datatype));
   824 
   825 val _ =
   826   ThyOutput.add_commands [("datatype",
   827     ThyOutput.args args_datatype (ThyOutput.output pretty_datatype))];
   828 
   829 end;
   830 
   831 
   832 end;
   833 
   834 structure BasicDatatypePackage: BASIC_DATATYPE_PACKAGE = DatatypePackage;
   835 open BasicDatatypePackage;
   836