src/HOL/Orderings.thy
author wenzelm
Tue Apr 09 15:29:25 2013 +0200 (2013-04-09)
changeset 51658 21c10672633b
parent 51579 ec3b78ce0758
child 51717 9e7d1c139569
permissions -rw-r--r--
discontinued Toplevel.no_timing complication -- also recovers timing of diagnostic commands, e.g. 'find_theorems';
print timing as tracing, to keep it out of the way in Proof General;
no timing of control commands, especially relevant for Proof General;
     1 (*  Title:      HOL/Orderings.thy
     2     Author:     Tobias Nipkow, Markus Wenzel, and Larry Paulson
     3 *)
     4 
     5 header {* Abstract orderings *}
     6 
     7 theory Orderings
     8 imports HOL
     9 keywords "print_orders" :: diag
    10 begin
    11 
    12 ML_file "~~/src/Provers/order.ML"
    13 ML_file "~~/src/Provers/quasi.ML"  (* FIXME unused? *)
    14 
    15 subsection {* Abstract ordering *}
    16 
    17 locale ordering =
    18   fixes less_eq :: "'a \<Rightarrow> 'a \<Rightarrow> bool" (infix "\<preceq>" 50)
    19    and less :: "'a \<Rightarrow> 'a \<Rightarrow> bool" (infix "\<prec>" 50)
    20   assumes strict_iff_order: "a \<prec> b \<longleftrightarrow> a \<preceq> b \<and> a \<noteq> b"
    21   assumes refl: "a \<preceq> a" -- {* not @{text iff}: makes problems due to multiple (dual) interpretations *}
    22     and antisym: "a \<preceq> b \<Longrightarrow> b \<preceq> a \<Longrightarrow> a = b"
    23     and trans: "a \<preceq> b \<Longrightarrow> b \<preceq> c \<Longrightarrow> a \<preceq> c"
    24 begin
    25 
    26 lemma strict_implies_order:
    27   "a \<prec> b \<Longrightarrow> a \<preceq> b"
    28   by (simp add: strict_iff_order)
    29 
    30 lemma strict_implies_not_eq:
    31   "a \<prec> b \<Longrightarrow> a \<noteq> b"
    32   by (simp add: strict_iff_order)
    33 
    34 lemma not_eq_order_implies_strict:
    35   "a \<noteq> b \<Longrightarrow> a \<preceq> b \<Longrightarrow> a \<prec> b"
    36   by (simp add: strict_iff_order)
    37 
    38 lemma order_iff_strict:
    39   "a \<preceq> b \<longleftrightarrow> a \<prec> b \<or> a = b"
    40   by (auto simp add: strict_iff_order refl)
    41 
    42 lemma irrefl: -- {* not @{text iff}: makes problems due to multiple (dual) interpretations *}
    43   "\<not> a \<prec> a"
    44   by (simp add: strict_iff_order)
    45 
    46 lemma asym:
    47   "a \<prec> b \<Longrightarrow> b \<prec> a \<Longrightarrow> False"
    48   by (auto simp add: strict_iff_order intro: antisym)
    49 
    50 lemma strict_trans1:
    51   "a \<preceq> b \<Longrightarrow> b \<prec> c \<Longrightarrow> a \<prec> c"
    52   by (auto simp add: strict_iff_order intro: trans antisym)
    53 
    54 lemma strict_trans2:
    55   "a \<prec> b \<Longrightarrow> b \<preceq> c \<Longrightarrow> a \<prec> c"
    56   by (auto simp add: strict_iff_order intro: trans antisym)
    57 
    58 lemma strict_trans:
    59   "a \<prec> b \<Longrightarrow> b \<prec> c \<Longrightarrow> a \<prec> c"
    60   by (auto intro: strict_trans1 strict_implies_order)
    61 
    62 end
    63 
    64 locale ordering_top = ordering +
    65   fixes top :: "'a"
    66   assumes extremum [simp]: "a \<preceq> top"
    67 begin
    68 
    69 lemma extremum_uniqueI:
    70   "top \<preceq> a \<Longrightarrow> a = top"
    71   by (rule antisym) auto
    72 
    73 lemma extremum_unique:
    74   "top \<preceq> a \<longleftrightarrow> a = top"
    75   by (auto intro: antisym)
    76 
    77 lemma extremum_strict [simp]:
    78   "\<not> (top \<prec> a)"
    79   using extremum [of a] by (auto simp add: order_iff_strict intro: asym irrefl)
    80 
    81 lemma not_eq_extremum:
    82   "a \<noteq> top \<longleftrightarrow> a \<prec> top"
    83   by (auto simp add: order_iff_strict intro: not_eq_order_implies_strict extremum)
    84 
    85 end  
    86 
    87 
    88 subsection {* Syntactic orders *}
    89 
    90 class ord =
    91   fixes less_eq :: "'a \<Rightarrow> 'a \<Rightarrow> bool"
    92     and less :: "'a \<Rightarrow> 'a \<Rightarrow> bool"
    93 begin
    94 
    95 notation
    96   less_eq  ("op <=") and
    97   less_eq  ("(_/ <= _)" [51, 51] 50) and
    98   less  ("op <") and
    99   less  ("(_/ < _)"  [51, 51] 50)
   100   
   101 notation (xsymbols)
   102   less_eq  ("op \<le>") and
   103   less_eq  ("(_/ \<le> _)"  [51, 51] 50)
   104 
   105 notation (HTML output)
   106   less_eq  ("op \<le>") and
   107   less_eq  ("(_/ \<le> _)"  [51, 51] 50)
   108 
   109 abbreviation (input)
   110   greater_eq  (infix ">=" 50) where
   111   "x >= y \<equiv> y <= x"
   112 
   113 notation (input)
   114   greater_eq  (infix "\<ge>" 50)
   115 
   116 abbreviation (input)
   117   greater  (infix ">" 50) where
   118   "x > y \<equiv> y < x"
   119 
   120 end
   121 
   122 
   123 subsection {* Quasi orders *}
   124 
   125 class preorder = ord +
   126   assumes less_le_not_le: "x < y \<longleftrightarrow> x \<le> y \<and> \<not> (y \<le> x)"
   127   and order_refl [iff]: "x \<le> x"
   128   and order_trans: "x \<le> y \<Longrightarrow> y \<le> z \<Longrightarrow> x \<le> z"
   129 begin
   130 
   131 text {* Reflexivity. *}
   132 
   133 lemma eq_refl: "x = y \<Longrightarrow> x \<le> y"
   134     -- {* This form is useful with the classical reasoner. *}
   135 by (erule ssubst) (rule order_refl)
   136 
   137 lemma less_irrefl [iff]: "\<not> x < x"
   138 by (simp add: less_le_not_le)
   139 
   140 lemma less_imp_le: "x < y \<Longrightarrow> x \<le> y"
   141 unfolding less_le_not_le by blast
   142 
   143 
   144 text {* Asymmetry. *}
   145 
   146 lemma less_not_sym: "x < y \<Longrightarrow> \<not> (y < x)"
   147 by (simp add: less_le_not_le)
   148 
   149 lemma less_asym: "x < y \<Longrightarrow> (\<not> P \<Longrightarrow> y < x) \<Longrightarrow> P"
   150 by (drule less_not_sym, erule contrapos_np) simp
   151 
   152 
   153 text {* Transitivity. *}
   154 
   155 lemma less_trans: "x < y \<Longrightarrow> y < z \<Longrightarrow> x < z"
   156 by (auto simp add: less_le_not_le intro: order_trans) 
   157 
   158 lemma le_less_trans: "x \<le> y \<Longrightarrow> y < z \<Longrightarrow> x < z"
   159 by (auto simp add: less_le_not_le intro: order_trans) 
   160 
   161 lemma less_le_trans: "x < y \<Longrightarrow> y \<le> z \<Longrightarrow> x < z"
   162 by (auto simp add: less_le_not_le intro: order_trans) 
   163 
   164 
   165 text {* Useful for simplification, but too risky to include by default. *}
   166 
   167 lemma less_imp_not_less: "x < y \<Longrightarrow> (\<not> y < x) \<longleftrightarrow> True"
   168 by (blast elim: less_asym)
   169 
   170 lemma less_imp_triv: "x < y \<Longrightarrow> (y < x \<longrightarrow> P) \<longleftrightarrow> True"
   171 by (blast elim: less_asym)
   172 
   173 
   174 text {* Transitivity rules for calculational reasoning *}
   175 
   176 lemma less_asym': "a < b \<Longrightarrow> b < a \<Longrightarrow> P"
   177 by (rule less_asym)
   178 
   179 
   180 text {* Dual order *}
   181 
   182 lemma dual_preorder:
   183   "class.preorder (op \<ge>) (op >)"
   184 proof qed (auto simp add: less_le_not_le intro: order_trans)
   185 
   186 end
   187 
   188 
   189 subsection {* Partial orders *}
   190 
   191 class order = preorder +
   192   assumes antisym: "x \<le> y \<Longrightarrow> y \<le> x \<Longrightarrow> x = y"
   193 begin
   194 
   195 lemma less_le: "x < y \<longleftrightarrow> x \<le> y \<and> x \<noteq> y"
   196   by (auto simp add: less_le_not_le intro: antisym)
   197 
   198 end
   199 
   200 sublocale order < order!: ordering less_eq less +  dual_order!: ordering greater_eq greater
   201   by default (auto intro: antisym order_trans simp add: less_le)
   202 
   203 context order
   204 begin
   205 
   206 text {* Reflexivity. *}
   207 
   208 lemma le_less: "x \<le> y \<longleftrightarrow> x < y \<or> x = y"
   209     -- {* NOT suitable for iff, since it can cause PROOF FAILED. *}
   210 by (fact order.order_iff_strict)
   211 
   212 lemma le_imp_less_or_eq: "x \<le> y \<Longrightarrow> x < y \<or> x = y"
   213 unfolding less_le by blast
   214 
   215 
   216 text {* Useful for simplification, but too risky to include by default. *}
   217 
   218 lemma less_imp_not_eq: "x < y \<Longrightarrow> (x = y) \<longleftrightarrow> False"
   219 by auto
   220 
   221 lemma less_imp_not_eq2: "x < y \<Longrightarrow> (y = x) \<longleftrightarrow> False"
   222 by auto
   223 
   224 
   225 text {* Transitivity rules for calculational reasoning *}
   226 
   227 lemma neq_le_trans: "a \<noteq> b \<Longrightarrow> a \<le> b \<Longrightarrow> a < b"
   228 by (fact order.not_eq_order_implies_strict)
   229 
   230 lemma le_neq_trans: "a \<le> b \<Longrightarrow> a \<noteq> b \<Longrightarrow> a < b"
   231 by (rule order.not_eq_order_implies_strict)
   232 
   233 
   234 text {* Asymmetry. *}
   235 
   236 lemma eq_iff: "x = y \<longleftrightarrow> x \<le> y \<and> y \<le> x"
   237 by (blast intro: antisym)
   238 
   239 lemma antisym_conv: "y \<le> x \<Longrightarrow> x \<le> y \<longleftrightarrow> x = y"
   240 by (blast intro: antisym)
   241 
   242 lemma less_imp_neq: "x < y \<Longrightarrow> x \<noteq> y"
   243 by (fact order.strict_implies_not_eq)
   244 
   245 
   246 text {* Least value operator *}
   247 
   248 definition (in ord)
   249   Least :: "('a \<Rightarrow> bool) \<Rightarrow> 'a" (binder "LEAST " 10) where
   250   "Least P = (THE x. P x \<and> (\<forall>y. P y \<longrightarrow> x \<le> y))"
   251 
   252 lemma Least_equality:
   253   assumes "P x"
   254     and "\<And>y. P y \<Longrightarrow> x \<le> y"
   255   shows "Least P = x"
   256 unfolding Least_def by (rule the_equality)
   257   (blast intro: assms antisym)+
   258 
   259 lemma LeastI2_order:
   260   assumes "P x"
   261     and "\<And>y. P y \<Longrightarrow> x \<le> y"
   262     and "\<And>x. P x \<Longrightarrow> \<forall>y. P y \<longrightarrow> x \<le> y \<Longrightarrow> Q x"
   263   shows "Q (Least P)"
   264 unfolding Least_def by (rule theI2)
   265   (blast intro: assms antisym)+
   266 
   267 
   268 text {* Dual order *}
   269 
   270 lemma dual_order:
   271   "class.order (op \<ge>) (op >)"
   272 by (intro_locales, rule dual_preorder) (unfold_locales, rule antisym)
   273 
   274 end
   275 
   276 
   277 subsection {* Linear (total) orders *}
   278 
   279 class linorder = order +
   280   assumes linear: "x \<le> y \<or> y \<le> x"
   281 begin
   282 
   283 lemma less_linear: "x < y \<or> x = y \<or> y < x"
   284 unfolding less_le using less_le linear by blast
   285 
   286 lemma le_less_linear: "x \<le> y \<or> y < x"
   287 by (simp add: le_less less_linear)
   288 
   289 lemma le_cases [case_names le ge]:
   290   "(x \<le> y \<Longrightarrow> P) \<Longrightarrow> (y \<le> x \<Longrightarrow> P) \<Longrightarrow> P"
   291 using linear by blast
   292 
   293 lemma linorder_cases [case_names less equal greater]:
   294   "(x < y \<Longrightarrow> P) \<Longrightarrow> (x = y \<Longrightarrow> P) \<Longrightarrow> (y < x \<Longrightarrow> P) \<Longrightarrow> P"
   295 using less_linear by blast
   296 
   297 lemma not_less: "\<not> x < y \<longleftrightarrow> y \<le> x"
   298 apply (simp add: less_le)
   299 using linear apply (blast intro: antisym)
   300 done
   301 
   302 lemma not_less_iff_gr_or_eq:
   303  "\<not>(x < y) \<longleftrightarrow> (x > y | x = y)"
   304 apply(simp add:not_less le_less)
   305 apply blast
   306 done
   307 
   308 lemma not_le: "\<not> x \<le> y \<longleftrightarrow> y < x"
   309 apply (simp add: less_le)
   310 using linear apply (blast intro: antisym)
   311 done
   312 
   313 lemma neq_iff: "x \<noteq> y \<longleftrightarrow> x < y \<or> y < x"
   314 by (cut_tac x = x and y = y in less_linear, auto)
   315 
   316 lemma neqE: "x \<noteq> y \<Longrightarrow> (x < y \<Longrightarrow> R) \<Longrightarrow> (y < x \<Longrightarrow> R) \<Longrightarrow> R"
   317 by (simp add: neq_iff) blast
   318 
   319 lemma antisym_conv1: "\<not> x < y \<Longrightarrow> x \<le> y \<longleftrightarrow> x = y"
   320 by (blast intro: antisym dest: not_less [THEN iffD1])
   321 
   322 lemma antisym_conv2: "x \<le> y \<Longrightarrow> \<not> x < y \<longleftrightarrow> x = y"
   323 by (blast intro: antisym dest: not_less [THEN iffD1])
   324 
   325 lemma antisym_conv3: "\<not> y < x \<Longrightarrow> \<not> x < y \<longleftrightarrow> x = y"
   326 by (blast intro: antisym dest: not_less [THEN iffD1])
   327 
   328 lemma leI: "\<not> x < y \<Longrightarrow> y \<le> x"
   329 unfolding not_less .
   330 
   331 lemma leD: "y \<le> x \<Longrightarrow> \<not> x < y"
   332 unfolding not_less .
   333 
   334 (*FIXME inappropriate name (or delete altogether)*)
   335 lemma not_leE: "\<not> y \<le> x \<Longrightarrow> x < y"
   336 unfolding not_le .
   337 
   338 
   339 text {* Dual order *}
   340 
   341 lemma dual_linorder:
   342   "class.linorder (op \<ge>) (op >)"
   343 by (rule class.linorder.intro, rule dual_order) (unfold_locales, rule linear)
   344 
   345 
   346 text {* min/max *}
   347 
   348 definition (in ord) min :: "'a \<Rightarrow> 'a \<Rightarrow> 'a" where
   349   "min a b = (if a \<le> b then a else b)"
   350 
   351 definition (in ord) max :: "'a \<Rightarrow> 'a \<Rightarrow> 'a" where
   352   "max a b = (if a \<le> b then b else a)"
   353 
   354 lemma min_le_iff_disj:
   355   "min x y \<le> z \<longleftrightarrow> x \<le> z \<or> y \<le> z"
   356 unfolding min_def using linear by (auto intro: order_trans)
   357 
   358 lemma le_max_iff_disj:
   359   "z \<le> max x y \<longleftrightarrow> z \<le> x \<or> z \<le> y"
   360 unfolding max_def using linear by (auto intro: order_trans)
   361 
   362 lemma min_less_iff_disj:
   363   "min x y < z \<longleftrightarrow> x < z \<or> y < z"
   364 unfolding min_def le_less using less_linear by (auto intro: less_trans)
   365 
   366 lemma less_max_iff_disj:
   367   "z < max x y \<longleftrightarrow> z < x \<or> z < y"
   368 unfolding max_def le_less using less_linear by (auto intro: less_trans)
   369 
   370 lemma min_less_iff_conj [simp]:
   371   "z < min x y \<longleftrightarrow> z < x \<and> z < y"
   372 unfolding min_def le_less using less_linear by (auto intro: less_trans)
   373 
   374 lemma max_less_iff_conj [simp]:
   375   "max x y < z \<longleftrightarrow> x < z \<and> y < z"
   376 unfolding max_def le_less using less_linear by (auto intro: less_trans)
   377 
   378 lemma split_min [no_atp]:
   379   "P (min i j) \<longleftrightarrow> (i \<le> j \<longrightarrow> P i) \<and> (\<not> i \<le> j \<longrightarrow> P j)"
   380 by (simp add: min_def)
   381 
   382 lemma split_max [no_atp]:
   383   "P (max i j) \<longleftrightarrow> (i \<le> j \<longrightarrow> P j) \<and> (\<not> i \<le> j \<longrightarrow> P i)"
   384 by (simp add: max_def)
   385 
   386 end
   387 
   388 
   389 subsection {* Reasoning tools setup *}
   390 
   391 ML {*
   392 
   393 signature ORDERS =
   394 sig
   395   val print_structures: Proof.context -> unit
   396   val attrib_setup: theory -> theory
   397   val order_tac: Proof.context -> thm list -> int -> tactic
   398 end;
   399 
   400 structure Orders: ORDERS =
   401 struct
   402 
   403 (** Theory and context data **)
   404 
   405 fun struct_eq ((s1: string, ts1), (s2, ts2)) =
   406   (s1 = s2) andalso eq_list (op aconv) (ts1, ts2);
   407 
   408 structure Data = Generic_Data
   409 (
   410   type T = ((string * term list) * Order_Tac.less_arith) list;
   411     (* Order structures:
   412        identifier of the structure, list of operations and record of theorems
   413        needed to set up the transitivity reasoner,
   414        identifier and operations identify the structure uniquely. *)
   415   val empty = [];
   416   val extend = I;
   417   fun merge data = AList.join struct_eq (K fst) data;
   418 );
   419 
   420 fun print_structures ctxt =
   421   let
   422     val structs = Data.get (Context.Proof ctxt);
   423     fun pretty_term t = Pretty.block
   424       [Pretty.quote (Syntax.pretty_term ctxt t), Pretty.brk 1,
   425         Pretty.str "::", Pretty.brk 1,
   426         Pretty.quote (Syntax.pretty_typ ctxt (type_of t))];
   427     fun pretty_struct ((s, ts), _) = Pretty.block
   428       [Pretty.str s, Pretty.str ":", Pretty.brk 1,
   429        Pretty.enclose "(" ")" (Pretty.breaks (map pretty_term ts))];
   430   in
   431     Pretty.writeln (Pretty.big_list "order structures:" (map pretty_struct structs))
   432   end;
   433 
   434 
   435 (** Method **)
   436 
   437 fun struct_tac ((s, [eq, le, less]), thms) ctxt prems =
   438   let
   439     fun decomp thy (@{const Trueprop} $ t) =
   440       let
   441         fun excluded t =
   442           (* exclude numeric types: linear arithmetic subsumes transitivity *)
   443           let val T = type_of t
   444           in
   445             T = HOLogic.natT orelse T = HOLogic.intT orelse T = HOLogic.realT
   446           end;
   447         fun rel (bin_op $ t1 $ t2) =
   448               if excluded t1 then NONE
   449               else if Pattern.matches thy (eq, bin_op) then SOME (t1, "=", t2)
   450               else if Pattern.matches thy (le, bin_op) then SOME (t1, "<=", t2)
   451               else if Pattern.matches thy (less, bin_op) then SOME (t1, "<", t2)
   452               else NONE
   453           | rel _ = NONE;
   454         fun dec (Const (@{const_name Not}, _) $ t) = (case rel t
   455               of NONE => NONE
   456                | SOME (t1, rel, t2) => SOME (t1, "~" ^ rel, t2))
   457           | dec x = rel x;
   458       in dec t end
   459       | decomp thy _ = NONE;
   460   in
   461     case s of
   462       "order" => Order_Tac.partial_tac decomp thms ctxt prems
   463     | "linorder" => Order_Tac.linear_tac decomp thms ctxt prems
   464     | _ => error ("Unknown kind of order `" ^ s ^ "' encountered in transitivity reasoner.")
   465   end
   466 
   467 fun order_tac ctxt prems =
   468   FIRST' (map (fn s => CHANGED o struct_tac s ctxt prems) (Data.get (Context.Proof ctxt)));
   469 
   470 
   471 (** Attribute **)
   472 
   473 fun add_struct_thm s tag =
   474   Thm.declaration_attribute
   475     (fn thm => Data.map (AList.map_default struct_eq (s, Order_Tac.empty TrueI) (Order_Tac.update tag thm)));
   476 fun del_struct s =
   477   Thm.declaration_attribute
   478     (fn _ => Data.map (AList.delete struct_eq s));
   479 
   480 val attrib_setup =
   481   Attrib.setup @{binding order}
   482     (Scan.lift ((Args.add -- Args.name >> (fn (_, s) => SOME s) || Args.del >> K NONE) --|
   483       Args.colon (* FIXME || Scan.succeed true *) ) -- Scan.lift Args.name --
   484       Scan.repeat Args.term
   485       >> (fn ((SOME tag, n), ts) => add_struct_thm (n, ts) tag
   486            | ((NONE, n), ts) => del_struct (n, ts)))
   487     "theorems controlling transitivity reasoner";
   488 
   489 
   490 (** Diagnostic command **)
   491 
   492 val _ =
   493   Outer_Syntax.improper_command @{command_spec "print_orders"}
   494     "print order structures available to transitivity reasoner"
   495     (Scan.succeed (Toplevel.unknown_context o
   496       Toplevel.keep (print_structures o Toplevel.context_of)));
   497 
   498 end;
   499 
   500 *}
   501 
   502 setup Orders.attrib_setup
   503 
   504 method_setup order = {*
   505   Scan.succeed (fn ctxt => SIMPLE_METHOD' (Orders.order_tac ctxt []))
   506 *} "transitivity reasoner"
   507 
   508 
   509 text {* Declarations to set up transitivity reasoner of partial and linear orders. *}
   510 
   511 context order
   512 begin
   513 
   514 (* The type constraint on @{term op =} below is necessary since the operation
   515    is not a parameter of the locale. *)
   516 
   517 declare less_irrefl [THEN notE, order add less_reflE: order "op = :: 'a \<Rightarrow> 'a \<Rightarrow> bool" "op <=" "op <"]
   518   
   519 declare order_refl  [order add le_refl: order "op = :: 'a => 'a => bool" "op <=" "op <"]
   520   
   521 declare less_imp_le [order add less_imp_le: order "op = :: 'a => 'a => bool" "op <=" "op <"]
   522   
   523 declare antisym [order add eqI: order "op = :: 'a => 'a => bool" "op <=" "op <"]
   524 
   525 declare eq_refl [order add eqD1: order "op = :: 'a => 'a => bool" "op <=" "op <"]
   526 
   527 declare sym [THEN eq_refl, order add eqD2: order "op = :: 'a => 'a => bool" "op <=" "op <"]
   528 
   529 declare less_trans [order add less_trans: order "op = :: 'a => 'a => bool" "op <=" "op <"]
   530   
   531 declare less_le_trans [order add less_le_trans: order "op = :: 'a => 'a => bool" "op <=" "op <"]
   532   
   533 declare le_less_trans [order add le_less_trans: order "op = :: 'a => 'a => bool" "op <=" "op <"]
   534 
   535 declare order_trans [order add le_trans: order "op = :: 'a => 'a => bool" "op <=" "op <"]
   536 
   537 declare le_neq_trans [order add le_neq_trans: order "op = :: 'a => 'a => bool" "op <=" "op <"]
   538 
   539 declare neq_le_trans [order add neq_le_trans: order "op = :: 'a => 'a => bool" "op <=" "op <"]
   540 
   541 declare less_imp_neq [order add less_imp_neq: order "op = :: 'a => 'a => bool" "op <=" "op <"]
   542 
   543 declare eq_neq_eq_imp_neq [order add eq_neq_eq_imp_neq: order "op = :: 'a => 'a => bool" "op <=" "op <"]
   544 
   545 declare not_sym [order add not_sym: order "op = :: 'a => 'a => bool" "op <=" "op <"]
   546 
   547 end
   548 
   549 context linorder
   550 begin
   551 
   552 declare [[order del: order "op = :: 'a => 'a => bool" "op <=" "op <"]]
   553 
   554 declare less_irrefl [THEN notE, order add less_reflE: linorder "op = :: 'a => 'a => bool" "op <=" "op <"]
   555 
   556 declare order_refl [order add le_refl: linorder "op = :: 'a => 'a => bool" "op <=" "op <"]
   557 
   558 declare less_imp_le [order add less_imp_le: linorder "op = :: 'a => 'a => bool" "op <=" "op <"]
   559 
   560 declare not_less [THEN iffD2, order add not_lessI: linorder "op = :: 'a => 'a => bool" "op <=" "op <"]
   561 
   562 declare not_le [THEN iffD2, order add not_leI: linorder "op = :: 'a => 'a => bool" "op <=" "op <"]
   563 
   564 declare not_less [THEN iffD1, order add not_lessD: linorder "op = :: 'a => 'a => bool" "op <=" "op <"]
   565 
   566 declare not_le [THEN iffD1, order add not_leD: linorder "op = :: 'a => 'a => bool" "op <=" "op <"]
   567 
   568 declare antisym [order add eqI: linorder "op = :: 'a => 'a => bool" "op <=" "op <"]
   569 
   570 declare eq_refl [order add eqD1: linorder "op = :: 'a => 'a => bool" "op <=" "op <"]
   571 
   572 declare sym [THEN eq_refl, order add eqD2: linorder "op = :: 'a => 'a => bool" "op <=" "op <"]
   573 
   574 declare less_trans [order add less_trans: linorder "op = :: 'a => 'a => bool" "op <=" "op <"]
   575 
   576 declare less_le_trans [order add less_le_trans: linorder "op = :: 'a => 'a => bool" "op <=" "op <"]
   577 
   578 declare le_less_trans [order add le_less_trans: linorder "op = :: 'a => 'a => bool" "op <=" "op <"]
   579 
   580 declare order_trans [order add le_trans: linorder "op = :: 'a => 'a => bool" "op <=" "op <"]
   581 
   582 declare le_neq_trans [order add le_neq_trans: linorder "op = :: 'a => 'a => bool" "op <=" "op <"]
   583 
   584 declare neq_le_trans [order add neq_le_trans: linorder "op = :: 'a => 'a => bool" "op <=" "op <"]
   585 
   586 declare less_imp_neq [order add less_imp_neq: linorder "op = :: 'a => 'a => bool" "op <=" "op <"]
   587 
   588 declare eq_neq_eq_imp_neq [order add eq_neq_eq_imp_neq: linorder "op = :: 'a => 'a => bool" "op <=" "op <"]
   589 
   590 declare not_sym [order add not_sym: linorder "op = :: 'a => 'a => bool" "op <=" "op <"]
   591 
   592 end
   593 
   594 
   595 setup {*
   596 let
   597 
   598 fun prp t thm = Thm.prop_of thm = t;  (* FIXME aconv!? *)
   599 
   600 fun prove_antisym_le sg ss ((le as Const(_,T)) $ r $ s) =
   601   let val prems = Simplifier.prems_of ss;
   602       val less = Const (@{const_name less}, T);
   603       val t = HOLogic.mk_Trueprop(le $ s $ r);
   604   in case find_first (prp t) prems of
   605        NONE =>
   606          let val t = HOLogic.mk_Trueprop(HOLogic.Not $ (less $ r $ s))
   607          in case find_first (prp t) prems of
   608               NONE => NONE
   609             | SOME thm => SOME(mk_meta_eq(thm RS @{thm linorder_class.antisym_conv1}))
   610          end
   611      | SOME thm => SOME(mk_meta_eq(thm RS @{thm order_class.antisym_conv}))
   612   end
   613   handle THM _ => NONE;
   614 
   615 fun prove_antisym_less sg ss (NotC $ ((less as Const(_,T)) $ r $ s)) =
   616   let val prems = Simplifier.prems_of ss;
   617       val le = Const (@{const_name less_eq}, T);
   618       val t = HOLogic.mk_Trueprop(le $ r $ s);
   619   in case find_first (prp t) prems of
   620        NONE =>
   621          let val t = HOLogic.mk_Trueprop(NotC $ (less $ s $ r))
   622          in case find_first (prp t) prems of
   623               NONE => NONE
   624             | SOME thm => SOME(mk_meta_eq(thm RS @{thm linorder_class.antisym_conv3}))
   625          end
   626      | SOME thm => SOME(mk_meta_eq(thm RS @{thm linorder_class.antisym_conv2}))
   627   end
   628   handle THM _ => NONE;
   629 
   630 fun add_simprocs procs thy =
   631   Simplifier.map_simpset_global (fn ss => ss
   632     addsimprocs (map (fn (name, raw_ts, proc) =>
   633       Simplifier.simproc_global thy name raw_ts proc) procs)) thy;
   634 
   635 fun add_solver name tac =
   636   Simplifier.map_simpset_global (fn ss => ss addSolver
   637     mk_solver name (fn ss => tac (Simplifier.the_context ss) (Simplifier.prems_of ss)));
   638 
   639 in
   640   add_simprocs [
   641        ("antisym le", ["(x::'a::order) <= y"], prove_antisym_le),
   642        ("antisym less", ["~ (x::'a::linorder) < y"], prove_antisym_less)
   643      ]
   644   #> add_solver "Transitivity" Orders.order_tac
   645   (* Adding the transitivity reasoners also as safe solvers showed a slight
   646      speed up, but the reasoning strength appears to be not higher (at least
   647      no breaking of additional proofs in the entire HOL distribution, as
   648      of 5 March 2004, was observed). *)
   649 end
   650 *}
   651 
   652 
   653 subsection {* Bounded quantifiers *}
   654 
   655 syntax
   656   "_All_less" :: "[idt, 'a, bool] => bool"    ("(3ALL _<_./ _)"  [0, 0, 10] 10)
   657   "_Ex_less" :: "[idt, 'a, bool] => bool"    ("(3EX _<_./ _)"  [0, 0, 10] 10)
   658   "_All_less_eq" :: "[idt, 'a, bool] => bool"    ("(3ALL _<=_./ _)" [0, 0, 10] 10)
   659   "_Ex_less_eq" :: "[idt, 'a, bool] => bool"    ("(3EX _<=_./ _)" [0, 0, 10] 10)
   660 
   661   "_All_greater" :: "[idt, 'a, bool] => bool"    ("(3ALL _>_./ _)"  [0, 0, 10] 10)
   662   "_Ex_greater" :: "[idt, 'a, bool] => bool"    ("(3EX _>_./ _)"  [0, 0, 10] 10)
   663   "_All_greater_eq" :: "[idt, 'a, bool] => bool"    ("(3ALL _>=_./ _)" [0, 0, 10] 10)
   664   "_Ex_greater_eq" :: "[idt, 'a, bool] => bool"    ("(3EX _>=_./ _)" [0, 0, 10] 10)
   665 
   666 syntax (xsymbols)
   667   "_All_less" :: "[idt, 'a, bool] => bool"    ("(3\<forall>_<_./ _)"  [0, 0, 10] 10)
   668   "_Ex_less" :: "[idt, 'a, bool] => bool"    ("(3\<exists>_<_./ _)"  [0, 0, 10] 10)
   669   "_All_less_eq" :: "[idt, 'a, bool] => bool"    ("(3\<forall>_\<le>_./ _)" [0, 0, 10] 10)
   670   "_Ex_less_eq" :: "[idt, 'a, bool] => bool"    ("(3\<exists>_\<le>_./ _)" [0, 0, 10] 10)
   671 
   672   "_All_greater" :: "[idt, 'a, bool] => bool"    ("(3\<forall>_>_./ _)"  [0, 0, 10] 10)
   673   "_Ex_greater" :: "[idt, 'a, bool] => bool"    ("(3\<exists>_>_./ _)"  [0, 0, 10] 10)
   674   "_All_greater_eq" :: "[idt, 'a, bool] => bool"    ("(3\<forall>_\<ge>_./ _)" [0, 0, 10] 10)
   675   "_Ex_greater_eq" :: "[idt, 'a, bool] => bool"    ("(3\<exists>_\<ge>_./ _)" [0, 0, 10] 10)
   676 
   677 syntax (HOL)
   678   "_All_less" :: "[idt, 'a, bool] => bool"    ("(3! _<_./ _)"  [0, 0, 10] 10)
   679   "_Ex_less" :: "[idt, 'a, bool] => bool"    ("(3? _<_./ _)"  [0, 0, 10] 10)
   680   "_All_less_eq" :: "[idt, 'a, bool] => bool"    ("(3! _<=_./ _)" [0, 0, 10] 10)
   681   "_Ex_less_eq" :: "[idt, 'a, bool] => bool"    ("(3? _<=_./ _)" [0, 0, 10] 10)
   682 
   683 syntax (HTML output)
   684   "_All_less" :: "[idt, 'a, bool] => bool"    ("(3\<forall>_<_./ _)"  [0, 0, 10] 10)
   685   "_Ex_less" :: "[idt, 'a, bool] => bool"    ("(3\<exists>_<_./ _)"  [0, 0, 10] 10)
   686   "_All_less_eq" :: "[idt, 'a, bool] => bool"    ("(3\<forall>_\<le>_./ _)" [0, 0, 10] 10)
   687   "_Ex_less_eq" :: "[idt, 'a, bool] => bool"    ("(3\<exists>_\<le>_./ _)" [0, 0, 10] 10)
   688 
   689   "_All_greater" :: "[idt, 'a, bool] => bool"    ("(3\<forall>_>_./ _)"  [0, 0, 10] 10)
   690   "_Ex_greater" :: "[idt, 'a, bool] => bool"    ("(3\<exists>_>_./ _)"  [0, 0, 10] 10)
   691   "_All_greater_eq" :: "[idt, 'a, bool] => bool"    ("(3\<forall>_\<ge>_./ _)" [0, 0, 10] 10)
   692   "_Ex_greater_eq" :: "[idt, 'a, bool] => bool"    ("(3\<exists>_\<ge>_./ _)" [0, 0, 10] 10)
   693 
   694 translations
   695   "ALL x<y. P"   =>  "ALL x. x < y \<longrightarrow> P"
   696   "EX x<y. P"    =>  "EX x. x < y \<and> P"
   697   "ALL x<=y. P"  =>  "ALL x. x <= y \<longrightarrow> P"
   698   "EX x<=y. P"   =>  "EX x. x <= y \<and> P"
   699   "ALL x>y. P"   =>  "ALL x. x > y \<longrightarrow> P"
   700   "EX x>y. P"    =>  "EX x. x > y \<and> P"
   701   "ALL x>=y. P"  =>  "ALL x. x >= y \<longrightarrow> P"
   702   "EX x>=y. P"   =>  "EX x. x >= y \<and> P"
   703 
   704 print_translation {*
   705 let
   706   val All_binder = Mixfix.binder_name @{const_syntax All};
   707   val Ex_binder = Mixfix.binder_name @{const_syntax Ex};
   708   val impl = @{const_syntax HOL.implies};
   709   val conj = @{const_syntax HOL.conj};
   710   val less = @{const_syntax less};
   711   val less_eq = @{const_syntax less_eq};
   712 
   713   val trans =
   714    [((All_binder, impl, less),
   715     (@{syntax_const "_All_less"}, @{syntax_const "_All_greater"})),
   716     ((All_binder, impl, less_eq),
   717     (@{syntax_const "_All_less_eq"}, @{syntax_const "_All_greater_eq"})),
   718     ((Ex_binder, conj, less),
   719     (@{syntax_const "_Ex_less"}, @{syntax_const "_Ex_greater"})),
   720     ((Ex_binder, conj, less_eq),
   721     (@{syntax_const "_Ex_less_eq"}, @{syntax_const "_Ex_greater_eq"}))];
   722 
   723   fun matches_bound v t =
   724     (case t of
   725       Const (@{syntax_const "_bound"}, _) $ Free (v', _) => v = v'
   726     | _ => false);
   727   fun contains_var v = Term.exists_subterm (fn Free (x, _) => x = v | _ => false);
   728   fun mk x c n P = Syntax.const c $ Syntax_Trans.mark_bound_body x $ n $ P;
   729 
   730   fun tr' q = (q,
   731     fn [Const (@{syntax_const "_bound"}, _) $ Free (v, T),
   732         Const (c, _) $ (Const (d, _) $ t $ u) $ P] =>
   733         (case AList.lookup (op =) trans (q, c, d) of
   734           NONE => raise Match
   735         | SOME (l, g) =>
   736             if matches_bound v t andalso not (contains_var v u) then mk (v, T) l u P
   737             else if matches_bound v u andalso not (contains_var v t) then mk (v, T) g t P
   738             else raise Match)
   739      | _ => raise Match);
   740 in [tr' All_binder, tr' Ex_binder] end
   741 *}
   742 
   743 
   744 subsection {* Transitivity reasoning *}
   745 
   746 context ord
   747 begin
   748 
   749 lemma ord_le_eq_trans: "a \<le> b \<Longrightarrow> b = c \<Longrightarrow> a \<le> c"
   750   by (rule subst)
   751 
   752 lemma ord_eq_le_trans: "a = b \<Longrightarrow> b \<le> c \<Longrightarrow> a \<le> c"
   753   by (rule ssubst)
   754 
   755 lemma ord_less_eq_trans: "a < b \<Longrightarrow> b = c \<Longrightarrow> a < c"
   756   by (rule subst)
   757 
   758 lemma ord_eq_less_trans: "a = b \<Longrightarrow> b < c \<Longrightarrow> a < c"
   759   by (rule ssubst)
   760 
   761 end
   762 
   763 lemma order_less_subst2: "(a::'a::order) < b ==> f b < (c::'c::order) ==>
   764   (!!x y. x < y ==> f x < f y) ==> f a < c"
   765 proof -
   766   assume r: "!!x y. x < y ==> f x < f y"
   767   assume "a < b" hence "f a < f b" by (rule r)
   768   also assume "f b < c"
   769   finally (less_trans) show ?thesis .
   770 qed
   771 
   772 lemma order_less_subst1: "(a::'a::order) < f b ==> (b::'b::order) < c ==>
   773   (!!x y. x < y ==> f x < f y) ==> a < f c"
   774 proof -
   775   assume r: "!!x y. x < y ==> f x < f y"
   776   assume "a < f b"
   777   also assume "b < c" hence "f b < f c" by (rule r)
   778   finally (less_trans) show ?thesis .
   779 qed
   780 
   781 lemma order_le_less_subst2: "(a::'a::order) <= b ==> f b < (c::'c::order) ==>
   782   (!!x y. x <= y ==> f x <= f y) ==> f a < c"
   783 proof -
   784   assume r: "!!x y. x <= y ==> f x <= f y"
   785   assume "a <= b" hence "f a <= f b" by (rule r)
   786   also assume "f b < c"
   787   finally (le_less_trans) show ?thesis .
   788 qed
   789 
   790 lemma order_le_less_subst1: "(a::'a::order) <= f b ==> (b::'b::order) < c ==>
   791   (!!x y. x < y ==> f x < f y) ==> a < f c"
   792 proof -
   793   assume r: "!!x y. x < y ==> f x < f y"
   794   assume "a <= f b"
   795   also assume "b < c" hence "f b < f c" by (rule r)
   796   finally (le_less_trans) show ?thesis .
   797 qed
   798 
   799 lemma order_less_le_subst2: "(a::'a::order) < b ==> f b <= (c::'c::order) ==>
   800   (!!x y. x < y ==> f x < f y) ==> f a < c"
   801 proof -
   802   assume r: "!!x y. x < y ==> f x < f y"
   803   assume "a < b" hence "f a < f b" by (rule r)
   804   also assume "f b <= c"
   805   finally (less_le_trans) show ?thesis .
   806 qed
   807 
   808 lemma order_less_le_subst1: "(a::'a::order) < f b ==> (b::'b::order) <= c ==>
   809   (!!x y. x <= y ==> f x <= f y) ==> a < f c"
   810 proof -
   811   assume r: "!!x y. x <= y ==> f x <= f y"
   812   assume "a < f b"
   813   also assume "b <= c" hence "f b <= f c" by (rule r)
   814   finally (less_le_trans) show ?thesis .
   815 qed
   816 
   817 lemma order_subst1: "(a::'a::order) <= f b ==> (b::'b::order) <= c ==>
   818   (!!x y. x <= y ==> f x <= f y) ==> a <= f c"
   819 proof -
   820   assume r: "!!x y. x <= y ==> f x <= f y"
   821   assume "a <= f b"
   822   also assume "b <= c" hence "f b <= f c" by (rule r)
   823   finally (order_trans) show ?thesis .
   824 qed
   825 
   826 lemma order_subst2: "(a::'a::order) <= b ==> f b <= (c::'c::order) ==>
   827   (!!x y. x <= y ==> f x <= f y) ==> f a <= c"
   828 proof -
   829   assume r: "!!x y. x <= y ==> f x <= f y"
   830   assume "a <= b" hence "f a <= f b" by (rule r)
   831   also assume "f b <= c"
   832   finally (order_trans) show ?thesis .
   833 qed
   834 
   835 lemma ord_le_eq_subst: "a <= b ==> f b = c ==>
   836   (!!x y. x <= y ==> f x <= f y) ==> f a <= c"
   837 proof -
   838   assume r: "!!x y. x <= y ==> f x <= f y"
   839   assume "a <= b" hence "f a <= f b" by (rule r)
   840   also assume "f b = c"
   841   finally (ord_le_eq_trans) show ?thesis .
   842 qed
   843 
   844 lemma ord_eq_le_subst: "a = f b ==> b <= c ==>
   845   (!!x y. x <= y ==> f x <= f y) ==> a <= f c"
   846 proof -
   847   assume r: "!!x y. x <= y ==> f x <= f y"
   848   assume "a = f b"
   849   also assume "b <= c" hence "f b <= f c" by (rule r)
   850   finally (ord_eq_le_trans) show ?thesis .
   851 qed
   852 
   853 lemma ord_less_eq_subst: "a < b ==> f b = c ==>
   854   (!!x y. x < y ==> f x < f y) ==> f a < c"
   855 proof -
   856   assume r: "!!x y. x < y ==> f x < f y"
   857   assume "a < b" hence "f a < f b" by (rule r)
   858   also assume "f b = c"
   859   finally (ord_less_eq_trans) show ?thesis .
   860 qed
   861 
   862 lemma ord_eq_less_subst: "a = f b ==> b < c ==>
   863   (!!x y. x < y ==> f x < f y) ==> a < f c"
   864 proof -
   865   assume r: "!!x y. x < y ==> f x < f y"
   866   assume "a = f b"
   867   also assume "b < c" hence "f b < f c" by (rule r)
   868   finally (ord_eq_less_trans) show ?thesis .
   869 qed
   870 
   871 text {*
   872   Note that this list of rules is in reverse order of priorities.
   873 *}
   874 
   875 lemmas [trans] =
   876   order_less_subst2
   877   order_less_subst1
   878   order_le_less_subst2
   879   order_le_less_subst1
   880   order_less_le_subst2
   881   order_less_le_subst1
   882   order_subst2
   883   order_subst1
   884   ord_le_eq_subst
   885   ord_eq_le_subst
   886   ord_less_eq_subst
   887   ord_eq_less_subst
   888   forw_subst
   889   back_subst
   890   rev_mp
   891   mp
   892 
   893 lemmas (in order) [trans] =
   894   neq_le_trans
   895   le_neq_trans
   896 
   897 lemmas (in preorder) [trans] =
   898   less_trans
   899   less_asym'
   900   le_less_trans
   901   less_le_trans
   902   order_trans
   903 
   904 lemmas (in order) [trans] =
   905   antisym
   906 
   907 lemmas (in ord) [trans] =
   908   ord_le_eq_trans
   909   ord_eq_le_trans
   910   ord_less_eq_trans
   911   ord_eq_less_trans
   912 
   913 lemmas [trans] =
   914   trans
   915 
   916 lemmas order_trans_rules =
   917   order_less_subst2
   918   order_less_subst1
   919   order_le_less_subst2
   920   order_le_less_subst1
   921   order_less_le_subst2
   922   order_less_le_subst1
   923   order_subst2
   924   order_subst1
   925   ord_le_eq_subst
   926   ord_eq_le_subst
   927   ord_less_eq_subst
   928   ord_eq_less_subst
   929   forw_subst
   930   back_subst
   931   rev_mp
   932   mp
   933   neq_le_trans
   934   le_neq_trans
   935   less_trans
   936   less_asym'
   937   le_less_trans
   938   less_le_trans
   939   order_trans
   940   antisym
   941   ord_le_eq_trans
   942   ord_eq_le_trans
   943   ord_less_eq_trans
   944   ord_eq_less_trans
   945   trans
   946 
   947 text {* These support proving chains of decreasing inequalities
   948     a >= b >= c ... in Isar proofs. *}
   949 
   950 lemma xt1 [no_atp]:
   951   "a = b ==> b > c ==> a > c"
   952   "a > b ==> b = c ==> a > c"
   953   "a = b ==> b >= c ==> a >= c"
   954   "a >= b ==> b = c ==> a >= c"
   955   "(x::'a::order) >= y ==> y >= x ==> x = y"
   956   "(x::'a::order) >= y ==> y >= z ==> x >= z"
   957   "(x::'a::order) > y ==> y >= z ==> x > z"
   958   "(x::'a::order) >= y ==> y > z ==> x > z"
   959   "(a::'a::order) > b ==> b > a ==> P"
   960   "(x::'a::order) > y ==> y > z ==> x > z"
   961   "(a::'a::order) >= b ==> a ~= b ==> a > b"
   962   "(a::'a::order) ~= b ==> a >= b ==> a > b"
   963   "a = f b ==> b > c ==> (!!x y. x > y ==> f x > f y) ==> a > f c" 
   964   "a > b ==> f b = c ==> (!!x y. x > y ==> f x > f y) ==> f a > c"
   965   "a = f b ==> b >= c ==> (!!x y. x >= y ==> f x >= f y) ==> a >= f c"
   966   "a >= b ==> f b = c ==> (!! x y. x >= y ==> f x >= f y) ==> f a >= c"
   967   by auto
   968 
   969 lemma xt2 [no_atp]:
   970   "(a::'a::order) >= f b ==> b >= c ==> (!!x y. x >= y ==> f x >= f y) ==> a >= f c"
   971 by (subgoal_tac "f b >= f c", force, force)
   972 
   973 lemma xt3 [no_atp]: "(a::'a::order) >= b ==> (f b::'b::order) >= c ==>
   974     (!!x y. x >= y ==> f x >= f y) ==> f a >= c"
   975 by (subgoal_tac "f a >= f b", force, force)
   976 
   977 lemma xt4 [no_atp]: "(a::'a::order) > f b ==> (b::'b::order) >= c ==>
   978   (!!x y. x >= y ==> f x >= f y) ==> a > f c"
   979 by (subgoal_tac "f b >= f c", force, force)
   980 
   981 lemma xt5 [no_atp]: "(a::'a::order) > b ==> (f b::'b::order) >= c==>
   982     (!!x y. x > y ==> f x > f y) ==> f a > c"
   983 by (subgoal_tac "f a > f b", force, force)
   984 
   985 lemma xt6 [no_atp]: "(a::'a::order) >= f b ==> b > c ==>
   986     (!!x y. x > y ==> f x > f y) ==> a > f c"
   987 by (subgoal_tac "f b > f c", force, force)
   988 
   989 lemma xt7 [no_atp]: "(a::'a::order) >= b ==> (f b::'b::order) > c ==>
   990     (!!x y. x >= y ==> f x >= f y) ==> f a > c"
   991 by (subgoal_tac "f a >= f b", force, force)
   992 
   993 lemma xt8 [no_atp]: "(a::'a::order) > f b ==> (b::'b::order) > c ==>
   994     (!!x y. x > y ==> f x > f y) ==> a > f c"
   995 by (subgoal_tac "f b > f c", force, force)
   996 
   997 lemma xt9 [no_atp]: "(a::'a::order) > b ==> (f b::'b::order) > c ==>
   998     (!!x y. x > y ==> f x > f y) ==> f a > c"
   999 by (subgoal_tac "f a > f b", force, force)
  1000 
  1001 lemmas xtrans = xt1 xt2 xt3 xt4 xt5 xt6 xt7 xt8 xt9 [no_atp]
  1002 
  1003 (* 
  1004   Since "a >= b" abbreviates "b <= a", the abbreviation "..." stands
  1005   for the wrong thing in an Isar proof.
  1006 
  1007   The extra transitivity rules can be used as follows: 
  1008 
  1009 lemma "(a::'a::order) > z"
  1010 proof -
  1011   have "a >= b" (is "_ >= ?rhs")
  1012     sorry
  1013   also have "?rhs >= c" (is "_ >= ?rhs")
  1014     sorry
  1015   also (xtrans) have "?rhs = d" (is "_ = ?rhs")
  1016     sorry
  1017   also (xtrans) have "?rhs >= e" (is "_ >= ?rhs")
  1018     sorry
  1019   also (xtrans) have "?rhs > f" (is "_ > ?rhs")
  1020     sorry
  1021   also (xtrans) have "?rhs > z"
  1022     sorry
  1023   finally (xtrans) show ?thesis .
  1024 qed
  1025 
  1026   Alternatively, one can use "declare xtrans [trans]" and then
  1027   leave out the "(xtrans)" above.
  1028 *)
  1029 
  1030 
  1031 subsection {* Monotonicity, least value operator and min/max *}
  1032 
  1033 context order
  1034 begin
  1035 
  1036 definition mono :: "('a \<Rightarrow> 'b\<Colon>order) \<Rightarrow> bool" where
  1037   "mono f \<longleftrightarrow> (\<forall>x y. x \<le> y \<longrightarrow> f x \<le> f y)"
  1038 
  1039 lemma monoI [intro?]:
  1040   fixes f :: "'a \<Rightarrow> 'b\<Colon>order"
  1041   shows "(\<And>x y. x \<le> y \<Longrightarrow> f x \<le> f y) \<Longrightarrow> mono f"
  1042   unfolding mono_def by iprover
  1043 
  1044 lemma monoD [dest?]:
  1045   fixes f :: "'a \<Rightarrow> 'b\<Colon>order"
  1046   shows "mono f \<Longrightarrow> x \<le> y \<Longrightarrow> f x \<le> f y"
  1047   unfolding mono_def by iprover
  1048 
  1049 lemma monoE:
  1050   fixes f :: "'a \<Rightarrow> 'b\<Colon>order"
  1051   assumes "mono f"
  1052   assumes "x \<le> y"
  1053   obtains "f x \<le> f y"
  1054 proof
  1055   from assms show "f x \<le> f y" by (simp add: mono_def)
  1056 qed
  1057 
  1058 definition strict_mono :: "('a \<Rightarrow> 'b\<Colon>order) \<Rightarrow> bool" where
  1059   "strict_mono f \<longleftrightarrow> (\<forall>x y. x < y \<longrightarrow> f x < f y)"
  1060 
  1061 lemma strict_monoI [intro?]:
  1062   assumes "\<And>x y. x < y \<Longrightarrow> f x < f y"
  1063   shows "strict_mono f"
  1064   using assms unfolding strict_mono_def by auto
  1065 
  1066 lemma strict_monoD [dest?]:
  1067   "strict_mono f \<Longrightarrow> x < y \<Longrightarrow> f x < f y"
  1068   unfolding strict_mono_def by auto
  1069 
  1070 lemma strict_mono_mono [dest?]:
  1071   assumes "strict_mono f"
  1072   shows "mono f"
  1073 proof (rule monoI)
  1074   fix x y
  1075   assume "x \<le> y"
  1076   show "f x \<le> f y"
  1077   proof (cases "x = y")
  1078     case True then show ?thesis by simp
  1079   next
  1080     case False with `x \<le> y` have "x < y" by simp
  1081     with assms strict_monoD have "f x < f y" by auto
  1082     then show ?thesis by simp
  1083   qed
  1084 qed
  1085 
  1086 end
  1087 
  1088 context linorder
  1089 begin
  1090 
  1091 lemma mono_invE:
  1092   fixes f :: "'a \<Rightarrow> 'b\<Colon>order"
  1093   assumes "mono f"
  1094   assumes "f x < f y"
  1095   obtains "x \<le> y"
  1096 proof
  1097   show "x \<le> y"
  1098   proof (rule ccontr)
  1099     assume "\<not> x \<le> y"
  1100     then have "y \<le> x" by simp
  1101     with `mono f` obtain "f y \<le> f x" by (rule monoE)
  1102     with `f x < f y` show False by simp
  1103   qed
  1104 qed
  1105 
  1106 lemma strict_mono_eq:
  1107   assumes "strict_mono f"
  1108   shows "f x = f y \<longleftrightarrow> x = y"
  1109 proof
  1110   assume "f x = f y"
  1111   show "x = y" proof (cases x y rule: linorder_cases)
  1112     case less with assms strict_monoD have "f x < f y" by auto
  1113     with `f x = f y` show ?thesis by simp
  1114   next
  1115     case equal then show ?thesis .
  1116   next
  1117     case greater with assms strict_monoD have "f y < f x" by auto
  1118     with `f x = f y` show ?thesis by simp
  1119   qed
  1120 qed simp
  1121 
  1122 lemma strict_mono_less_eq:
  1123   assumes "strict_mono f"
  1124   shows "f x \<le> f y \<longleftrightarrow> x \<le> y"
  1125 proof
  1126   assume "x \<le> y"
  1127   with assms strict_mono_mono monoD show "f x \<le> f y" by auto
  1128 next
  1129   assume "f x \<le> f y"
  1130   show "x \<le> y" proof (rule ccontr)
  1131     assume "\<not> x \<le> y" then have "y < x" by simp
  1132     with assms strict_monoD have "f y < f x" by auto
  1133     with `f x \<le> f y` show False by simp
  1134   qed
  1135 qed
  1136   
  1137 lemma strict_mono_less:
  1138   assumes "strict_mono f"
  1139   shows "f x < f y \<longleftrightarrow> x < y"
  1140   using assms
  1141     by (auto simp add: less_le Orderings.less_le strict_mono_eq strict_mono_less_eq)
  1142 
  1143 lemma min_of_mono:
  1144   fixes f :: "'a \<Rightarrow> 'b\<Colon>linorder"
  1145   shows "mono f \<Longrightarrow> min (f m) (f n) = f (min m n)"
  1146   by (auto simp: mono_def Orderings.min_def min_def intro: Orderings.antisym)
  1147 
  1148 lemma max_of_mono:
  1149   fixes f :: "'a \<Rightarrow> 'b\<Colon>linorder"
  1150   shows "mono f \<Longrightarrow> max (f m) (f n) = f (max m n)"
  1151   by (auto simp: mono_def Orderings.max_def max_def intro: Orderings.antisym)
  1152 
  1153 end
  1154 
  1155 lemma min_absorb1: "x \<le> y \<Longrightarrow> min x y = x"
  1156 by (simp add: min_def)
  1157 
  1158 lemma max_absorb2: "x \<le> y ==> max x y = y"
  1159 by (simp add: max_def)
  1160 
  1161 lemma min_absorb2: "(y\<Colon>'a\<Colon>order) \<le> x \<Longrightarrow> min x y = y"
  1162 by (simp add:min_def)
  1163 
  1164 lemma max_absorb1: "(y\<Colon>'a\<Colon>order) \<le> x \<Longrightarrow> max x y = x"
  1165 by (simp add: max_def)
  1166 
  1167 
  1168 subsection {* (Unique) top and bottom elements *}
  1169 
  1170 class bot = order +
  1171   fixes bot :: 'a ("\<bottom>")
  1172   assumes bot_least: "\<bottom> \<le> a"
  1173 
  1174 sublocale bot < bot!: ordering_top greater_eq greater bot
  1175   by default (fact bot_least)
  1176 
  1177 context bot
  1178 begin
  1179 
  1180 lemma le_bot:
  1181   "a \<le> \<bottom> \<Longrightarrow> a = \<bottom>"
  1182   by (fact bot.extremum_uniqueI)
  1183 
  1184 lemma bot_unique:
  1185   "a \<le> \<bottom> \<longleftrightarrow> a = \<bottom>"
  1186   by (fact bot.extremum_unique)
  1187 
  1188 lemma not_less_bot:
  1189   "\<not> a < \<bottom>"
  1190   by (fact bot.extremum_strict)
  1191 
  1192 lemma bot_less:
  1193   "a \<noteq> \<bottom> \<longleftrightarrow> \<bottom> < a"
  1194   by (fact bot.not_eq_extremum)
  1195 
  1196 end
  1197 
  1198 class top = order +
  1199   fixes top :: 'a ("\<top>")
  1200   assumes top_greatest: "a \<le> \<top>"
  1201 
  1202 sublocale top < top!: ordering_top less_eq less top
  1203   by default (fact top_greatest)
  1204 
  1205 context top
  1206 begin
  1207 
  1208 lemma top_le:
  1209   "\<top> \<le> a \<Longrightarrow> a = \<top>"
  1210   by (fact top.extremum_uniqueI)
  1211 
  1212 lemma top_unique:
  1213   "\<top> \<le> a \<longleftrightarrow> a = \<top>"
  1214   by (fact top.extremum_unique)
  1215 
  1216 lemma not_top_less:
  1217   "\<not> \<top> < a"
  1218   by (fact top.extremum_strict)
  1219 
  1220 lemma less_top:
  1221   "a \<noteq> \<top> \<longleftrightarrow> a < \<top>"
  1222   by (fact top.not_eq_extremum)
  1223 
  1224 end
  1225 
  1226 
  1227 subsection {* Dense orders *}
  1228 
  1229 class inner_dense_order = order +
  1230   assumes dense: "x < y \<Longrightarrow> (\<exists>z. x < z \<and> z < y)"
  1231 
  1232 class inner_dense_linorder = linorder + inner_dense_order
  1233 begin
  1234 
  1235 lemma dense_le:
  1236   fixes y z :: 'a
  1237   assumes "\<And>x. x < y \<Longrightarrow> x \<le> z"
  1238   shows "y \<le> z"
  1239 proof (rule ccontr)
  1240   assume "\<not> ?thesis"
  1241   hence "z < y" by simp
  1242   from dense[OF this]
  1243   obtain x where "x < y" and "z < x" by safe
  1244   moreover have "x \<le> z" using assms[OF `x < y`] .
  1245   ultimately show False by auto
  1246 qed
  1247 
  1248 lemma dense_le_bounded:
  1249   fixes x y z :: 'a
  1250   assumes "x < y"
  1251   assumes *: "\<And>w. \<lbrakk> x < w ; w < y \<rbrakk> \<Longrightarrow> w \<le> z"
  1252   shows "y \<le> z"
  1253 proof (rule dense_le)
  1254   fix w assume "w < y"
  1255   from dense[OF `x < y`] obtain u where "x < u" "u < y" by safe
  1256   from linear[of u w]
  1257   show "w \<le> z"
  1258   proof (rule disjE)
  1259     assume "u \<le> w"
  1260     from less_le_trans[OF `x < u` `u \<le> w`] `w < y`
  1261     show "w \<le> z" by (rule *)
  1262   next
  1263     assume "w \<le> u"
  1264     from `w \<le> u` *[OF `x < u` `u < y`]
  1265     show "w \<le> z" by (rule order_trans)
  1266   qed
  1267 qed
  1268 
  1269 lemma dense_ge:
  1270   fixes y z :: 'a
  1271   assumes "\<And>x. z < x \<Longrightarrow> y \<le> x"
  1272   shows "y \<le> z"
  1273 proof (rule ccontr)
  1274   assume "\<not> ?thesis"
  1275   hence "z < y" by simp
  1276   from dense[OF this]
  1277   obtain x where "x < y" and "z < x" by safe
  1278   moreover have "y \<le> x" using assms[OF `z < x`] .
  1279   ultimately show False by auto
  1280 qed
  1281 
  1282 lemma dense_ge_bounded:
  1283   fixes x y z :: 'a
  1284   assumes "z < x"
  1285   assumes *: "\<And>w. \<lbrakk> z < w ; w < x \<rbrakk> \<Longrightarrow> y \<le> w"
  1286   shows "y \<le> z"
  1287 proof (rule dense_ge)
  1288   fix w assume "z < w"
  1289   from dense[OF `z < x`] obtain u where "z < u" "u < x" by safe
  1290   from linear[of u w]
  1291   show "y \<le> w"
  1292   proof (rule disjE)
  1293     assume "w \<le> u"
  1294     from `z < w` le_less_trans[OF `w \<le> u` `u < x`]
  1295     show "y \<le> w" by (rule *)
  1296   next
  1297     assume "u \<le> w"
  1298     from *[OF `z < u` `u < x`] `u \<le> w`
  1299     show "y \<le> w" by (rule order_trans)
  1300   qed
  1301 qed
  1302 
  1303 end
  1304 
  1305 class no_top = order + 
  1306   assumes gt_ex: "\<exists>y. x < y"
  1307 
  1308 class no_bot = order + 
  1309   assumes lt_ex: "\<exists>y. y < x"
  1310 
  1311 class dense_linorder = inner_dense_linorder + no_top + no_bot
  1312 
  1313 
  1314 subsection {* Wellorders *}
  1315 
  1316 class wellorder = linorder +
  1317   assumes less_induct [case_names less]: "(\<And>x. (\<And>y. y < x \<Longrightarrow> P y) \<Longrightarrow> P x) \<Longrightarrow> P a"
  1318 begin
  1319 
  1320 lemma wellorder_Least_lemma:
  1321   fixes k :: 'a
  1322   assumes "P k"
  1323   shows LeastI: "P (LEAST x. P x)" and Least_le: "(LEAST x. P x) \<le> k"
  1324 proof -
  1325   have "P (LEAST x. P x) \<and> (LEAST x. P x) \<le> k"
  1326   using assms proof (induct k rule: less_induct)
  1327     case (less x) then have "P x" by simp
  1328     show ?case proof (rule classical)
  1329       assume assm: "\<not> (P (LEAST a. P a) \<and> (LEAST a. P a) \<le> x)"
  1330       have "\<And>y. P y \<Longrightarrow> x \<le> y"
  1331       proof (rule classical)
  1332         fix y
  1333         assume "P y" and "\<not> x \<le> y"
  1334         with less have "P (LEAST a. P a)" and "(LEAST a. P a) \<le> y"
  1335           by (auto simp add: not_le)
  1336         with assm have "x < (LEAST a. P a)" and "(LEAST a. P a) \<le> y"
  1337           by auto
  1338         then show "x \<le> y" by auto
  1339       qed
  1340       with `P x` have Least: "(LEAST a. P a) = x"
  1341         by (rule Least_equality)
  1342       with `P x` show ?thesis by simp
  1343     qed
  1344   qed
  1345   then show "P (LEAST x. P x)" and "(LEAST x. P x) \<le> k" by auto
  1346 qed
  1347 
  1348 -- "The following 3 lemmas are due to Brian Huffman"
  1349 lemma LeastI_ex: "\<exists>x. P x \<Longrightarrow> P (Least P)"
  1350   by (erule exE) (erule LeastI)
  1351 
  1352 lemma LeastI2:
  1353   "P a \<Longrightarrow> (\<And>x. P x \<Longrightarrow> Q x) \<Longrightarrow> Q (Least P)"
  1354   by (blast intro: LeastI)
  1355 
  1356 lemma LeastI2_ex:
  1357   "\<exists>a. P a \<Longrightarrow> (\<And>x. P x \<Longrightarrow> Q x) \<Longrightarrow> Q (Least P)"
  1358   by (blast intro: LeastI_ex)
  1359 
  1360 lemma LeastI2_wellorder:
  1361   assumes "P a"
  1362   and "\<And>a. \<lbrakk> P a; \<forall>b. P b \<longrightarrow> a \<le> b \<rbrakk> \<Longrightarrow> Q a"
  1363   shows "Q (Least P)"
  1364 proof (rule LeastI2_order)
  1365   show "P (Least P)" using `P a` by (rule LeastI)
  1366 next
  1367   fix y assume "P y" thus "Least P \<le> y" by (rule Least_le)
  1368 next
  1369   fix x assume "P x" "\<forall>y. P y \<longrightarrow> x \<le> y" thus "Q x" by (rule assms(2))
  1370 qed
  1371 
  1372 lemma not_less_Least: "k < (LEAST x. P x) \<Longrightarrow> \<not> P k"
  1373 apply (simp (no_asm_use) add: not_le [symmetric])
  1374 apply (erule contrapos_nn)
  1375 apply (erule Least_le)
  1376 done
  1377 
  1378 end
  1379 
  1380 
  1381 subsection {* Order on @{typ bool} *}
  1382 
  1383 instantiation bool :: "{bot, top, linorder}"
  1384 begin
  1385 
  1386 definition
  1387   le_bool_def [simp]: "P \<le> Q \<longleftrightarrow> P \<longrightarrow> Q"
  1388 
  1389 definition
  1390   [simp]: "(P\<Colon>bool) < Q \<longleftrightarrow> \<not> P \<and> Q"
  1391 
  1392 definition
  1393   [simp]: "\<bottom> \<longleftrightarrow> False"
  1394 
  1395 definition
  1396   [simp]: "\<top> \<longleftrightarrow> True"
  1397 
  1398 instance proof
  1399 qed auto
  1400 
  1401 end
  1402 
  1403 lemma le_boolI: "(P \<Longrightarrow> Q) \<Longrightarrow> P \<le> Q"
  1404   by simp
  1405 
  1406 lemma le_boolI': "P \<longrightarrow> Q \<Longrightarrow> P \<le> Q"
  1407   by simp
  1408 
  1409 lemma le_boolE: "P \<le> Q \<Longrightarrow> P \<Longrightarrow> (Q \<Longrightarrow> R) \<Longrightarrow> R"
  1410   by simp
  1411 
  1412 lemma le_boolD: "P \<le> Q \<Longrightarrow> P \<longrightarrow> Q"
  1413   by simp
  1414 
  1415 lemma bot_boolE: "\<bottom> \<Longrightarrow> P"
  1416   by simp
  1417 
  1418 lemma top_boolI: \<top>
  1419   by simp
  1420 
  1421 lemma [code]:
  1422   "False \<le> b \<longleftrightarrow> True"
  1423   "True \<le> b \<longleftrightarrow> b"
  1424   "False < b \<longleftrightarrow> b"
  1425   "True < b \<longleftrightarrow> False"
  1426   by simp_all
  1427 
  1428 
  1429 subsection {* Order on @{typ "_ \<Rightarrow> _"} *}
  1430 
  1431 instantiation "fun" :: (type, ord) ord
  1432 begin
  1433 
  1434 definition
  1435   le_fun_def: "f \<le> g \<longleftrightarrow> (\<forall>x. f x \<le> g x)"
  1436 
  1437 definition
  1438   "(f\<Colon>'a \<Rightarrow> 'b) < g \<longleftrightarrow> f \<le> g \<and> \<not> (g \<le> f)"
  1439 
  1440 instance ..
  1441 
  1442 end
  1443 
  1444 instance "fun" :: (type, preorder) preorder proof
  1445 qed (auto simp add: le_fun_def less_fun_def
  1446   intro: order_trans antisym)
  1447 
  1448 instance "fun" :: (type, order) order proof
  1449 qed (auto simp add: le_fun_def intro: antisym)
  1450 
  1451 instantiation "fun" :: (type, bot) bot
  1452 begin
  1453 
  1454 definition
  1455   "\<bottom> = (\<lambda>x. \<bottom>)"
  1456 
  1457 lemma bot_apply [simp, code]:
  1458   "\<bottom> x = \<bottom>"
  1459   by (simp add: bot_fun_def)
  1460 
  1461 instance proof
  1462 qed (simp add: le_fun_def)
  1463 
  1464 end
  1465 
  1466 instantiation "fun" :: (type, top) top
  1467 begin
  1468 
  1469 definition
  1470   [no_atp]: "\<top> = (\<lambda>x. \<top>)"
  1471 
  1472 lemma top_apply [simp, code]:
  1473   "\<top> x = \<top>"
  1474   by (simp add: top_fun_def)
  1475 
  1476 instance proof
  1477 qed (simp add: le_fun_def)
  1478 
  1479 end
  1480 
  1481 lemma le_funI: "(\<And>x. f x \<le> g x) \<Longrightarrow> f \<le> g"
  1482   unfolding le_fun_def by simp
  1483 
  1484 lemma le_funE: "f \<le> g \<Longrightarrow> (f x \<le> g x \<Longrightarrow> P) \<Longrightarrow> P"
  1485   unfolding le_fun_def by simp
  1486 
  1487 lemma le_funD: "f \<le> g \<Longrightarrow> f x \<le> g x"
  1488   unfolding le_fun_def by simp
  1489 
  1490 
  1491 subsection {* Order on unary and binary predicates *}
  1492 
  1493 lemma predicate1I:
  1494   assumes PQ: "\<And>x. P x \<Longrightarrow> Q x"
  1495   shows "P \<le> Q"
  1496   apply (rule le_funI)
  1497   apply (rule le_boolI)
  1498   apply (rule PQ)
  1499   apply assumption
  1500   done
  1501 
  1502 lemma predicate1D:
  1503   "P \<le> Q \<Longrightarrow> P x \<Longrightarrow> Q x"
  1504   apply (erule le_funE)
  1505   apply (erule le_boolE)
  1506   apply assumption+
  1507   done
  1508 
  1509 lemma rev_predicate1D:
  1510   "P x \<Longrightarrow> P \<le> Q \<Longrightarrow> Q x"
  1511   by (rule predicate1D)
  1512 
  1513 lemma predicate2I:
  1514   assumes PQ: "\<And>x y. P x y \<Longrightarrow> Q x y"
  1515   shows "P \<le> Q"
  1516   apply (rule le_funI)+
  1517   apply (rule le_boolI)
  1518   apply (rule PQ)
  1519   apply assumption
  1520   done
  1521 
  1522 lemma predicate2D:
  1523   "P \<le> Q \<Longrightarrow> P x y \<Longrightarrow> Q x y"
  1524   apply (erule le_funE)+
  1525   apply (erule le_boolE)
  1526   apply assumption+
  1527   done
  1528 
  1529 lemma rev_predicate2D:
  1530   "P x y \<Longrightarrow> P \<le> Q \<Longrightarrow> Q x y"
  1531   by (rule predicate2D)
  1532 
  1533 lemma bot1E [no_atp]: "\<bottom> x \<Longrightarrow> P"
  1534   by (simp add: bot_fun_def)
  1535 
  1536 lemma bot2E: "\<bottom> x y \<Longrightarrow> P"
  1537   by (simp add: bot_fun_def)
  1538 
  1539 lemma top1I: "\<top> x"
  1540   by (simp add: top_fun_def)
  1541 
  1542 lemma top2I: "\<top> x y"
  1543   by (simp add: top_fun_def)
  1544 
  1545 
  1546 subsection {* Name duplicates *}
  1547 
  1548 lemmas order_eq_refl = preorder_class.eq_refl
  1549 lemmas order_less_irrefl = preorder_class.less_irrefl
  1550 lemmas order_less_imp_le = preorder_class.less_imp_le
  1551 lemmas order_less_not_sym = preorder_class.less_not_sym
  1552 lemmas order_less_asym = preorder_class.less_asym
  1553 lemmas order_less_trans = preorder_class.less_trans
  1554 lemmas order_le_less_trans = preorder_class.le_less_trans
  1555 lemmas order_less_le_trans = preorder_class.less_le_trans
  1556 lemmas order_less_imp_not_less = preorder_class.less_imp_not_less
  1557 lemmas order_less_imp_triv = preorder_class.less_imp_triv
  1558 lemmas order_less_asym' = preorder_class.less_asym'
  1559 
  1560 lemmas order_less_le = order_class.less_le
  1561 lemmas order_le_less = order_class.le_less
  1562 lemmas order_le_imp_less_or_eq = order_class.le_imp_less_or_eq
  1563 lemmas order_less_imp_not_eq = order_class.less_imp_not_eq
  1564 lemmas order_less_imp_not_eq2 = order_class.less_imp_not_eq2
  1565 lemmas order_neq_le_trans = order_class.neq_le_trans
  1566 lemmas order_le_neq_trans = order_class.le_neq_trans
  1567 lemmas order_antisym = order_class.antisym
  1568 lemmas order_eq_iff = order_class.eq_iff
  1569 lemmas order_antisym_conv = order_class.antisym_conv
  1570 
  1571 lemmas linorder_linear = linorder_class.linear
  1572 lemmas linorder_less_linear = linorder_class.less_linear
  1573 lemmas linorder_le_less_linear = linorder_class.le_less_linear
  1574 lemmas linorder_le_cases = linorder_class.le_cases
  1575 lemmas linorder_not_less = linorder_class.not_less
  1576 lemmas linorder_not_le = linorder_class.not_le
  1577 lemmas linorder_neq_iff = linorder_class.neq_iff
  1578 lemmas linorder_neqE = linorder_class.neqE
  1579 lemmas linorder_antisym_conv1 = linorder_class.antisym_conv1
  1580 lemmas linorder_antisym_conv2 = linorder_class.antisym_conv2
  1581 lemmas linorder_antisym_conv3 = linorder_class.antisym_conv3
  1582 
  1583 end
  1584