src/Pure/display.ML
author wenzelm
Thu Jul 23 16:52:16 2009 +0200 (2009-07-23)
changeset 32145 220c9e439d39
parent 32090 39acf19e9f3a
child 32187 cca43ca13f4f
permissions -rw-r--r--
clarified pretty_goals, pretty_thm_aux: plain context;
explicit pretty_goals_without_context, print_goals_without_context;
tuned;
     1 (*  Title:      Pure/display.ML
     2     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     3     Author:     Makarius
     4 
     5 Printing of theorems, results etc.
     6 *)
     7 
     8 signature BASIC_DISPLAY =
     9 sig
    10   val goals_limit: int ref
    11   val show_consts: bool ref
    12   val show_hyps: bool ref
    13   val show_tags: bool ref
    14 end;
    15 
    16 signature DISPLAY =
    17 sig
    18   include BASIC_DISPLAY
    19   val pretty_thm_raw: Proof.context -> {quote: bool, show_hyps: bool, show_status: bool} ->
    20     thm -> Pretty.T
    21   val pretty_thm_aux: Proof.context -> bool -> thm -> Pretty.T
    22   val pretty_thm: Proof.context -> thm -> Pretty.T
    23   val pretty_thm_global: theory -> thm -> Pretty.T
    24   val pretty_thm_without_context: thm -> Pretty.T
    25   val string_of_thm: Proof.context -> thm -> string
    26   val string_of_thm_global: theory -> thm -> string
    27   val string_of_thm_without_context: thm -> string
    28   val pretty_thms_aux: Proof.context -> bool -> thm list -> Pretty.T
    29   val pretty_thms: Proof.context -> thm list -> Pretty.T
    30   val pretty_ctyp: ctyp -> Pretty.T
    31   val string_of_ctyp: ctyp -> string
    32   val print_ctyp: ctyp -> unit
    33   val pretty_cterm: cterm -> Pretty.T
    34   val string_of_cterm: cterm -> string
    35   val print_cterm: cterm -> unit
    36   val print_syntax: theory -> unit
    37   val pretty_full_theory: bool -> theory -> Pretty.T list
    38 end;
    39 
    40 structure Display: DISPLAY =
    41 struct
    42 
    43 (** options **)
    44 
    45 val goals_limit = Display_Goal.goals_limit;
    46 val show_consts = Display_Goal.show_consts;
    47 
    48 val show_hyps = ref false;      (*false: print meta-hypotheses as dots*)
    49 val show_tags = ref false;      (*false: suppress tags*)
    50 
    51 
    52 
    53 (** print thm **)
    54 
    55 fun pretty_tag (name, arg) = Pretty.strs [name, quote arg];
    56 val pretty_tags = Pretty.list "[" "]" o map pretty_tag;
    57 
    58 fun display_status false _ = ""
    59   | display_status true th =
    60       let
    61         val {oracle = oracle0, unfinished, failed} = Thm.status_of th;
    62         val oracle = oracle0 andalso (not (! quick_and_dirty) orelse ! show_hyps);
    63       in
    64         if failed then "!!"
    65         else if oracle andalso unfinished then "!?"
    66         else if oracle then "!"
    67         else if unfinished then "?"
    68         else ""
    69       end;
    70 
    71 fun pretty_thm_raw ctxt {quote, show_hyps = show_hyps', show_status} raw_th =
    72   let
    73     val th = Thm.strip_shyps raw_th;
    74     val {hyps, tpairs, prop, ...} = Thm.rep_thm th;
    75     val xshyps = Thm.extra_shyps th;
    76     val tags = Thm.get_tags th;
    77 
    78     val q = if quote then Pretty.quote else I;
    79     val prt_term = q o Syntax.pretty_term ctxt;
    80 
    81     val asms = map Thm.term_of (Assumption.all_assms_of ctxt);
    82     val hyps' = if ! show_hyps then hyps else subtract (op aconv) asms hyps;
    83     val status = display_status show_status th;
    84 
    85     val hlen = length xshyps + length hyps' + length tpairs;
    86     val hsymbs =
    87       if hlen = 0 andalso status = "" then []
    88       else if ! show_hyps orelse show_hyps' then
    89         [Pretty.brk 2, Pretty.list "[" "]"
    90           (map (q o Display_Goal.pretty_flexpair ctxt) tpairs @ map prt_term hyps' @
    91            map (Syntax.pretty_sort ctxt) xshyps @
    92             (if status = "" then [] else [Pretty.str status]))]
    93       else [Pretty.brk 2, Pretty.str ("[" ^ implode (replicate hlen ".") ^ status ^ "]")];
    94     val tsymbs =
    95       if null tags orelse not (! show_tags) then []
    96       else [Pretty.brk 1, pretty_tags tags];
    97   in Pretty.block (prt_term prop :: (hsymbs @ tsymbs)) end;
    98 
    99 fun pretty_thm_aux ctxt show_status =
   100   pretty_thm_raw ctxt {quote = false, show_hyps = true, show_status = show_status};
   101 
   102 fun pretty_thm ctxt = pretty_thm_aux ctxt true;
   103 
   104 fun pretty_thm_global thy =
   105   pretty_thm_raw (Syntax.init_pretty_global thy)
   106     {quote = false, show_hyps = false, show_status = true};
   107 
   108 fun pretty_thm_without_context th = pretty_thm_global (Thm.theory_of_thm th) th;
   109 
   110 val string_of_thm = Pretty.string_of oo pretty_thm;
   111 val string_of_thm_global = Pretty.string_of oo pretty_thm_global;
   112 val string_of_thm_without_context = Pretty.string_of o pretty_thm_without_context;
   113 
   114 
   115 (* multiple theorems *)
   116 
   117 fun pretty_thms_aux ctxt flag [th] = pretty_thm_aux ctxt flag th
   118   | pretty_thms_aux ctxt flag ths =
   119       Pretty.blk (0, Pretty.fbreaks (map (pretty_thm_aux ctxt flag) ths));
   120 
   121 fun pretty_thms ctxt = pretty_thms_aux ctxt true;
   122 
   123 
   124 (* other printing commands *)
   125 
   126 fun pretty_ctyp cT = Syntax.pretty_typ_global (Thm.theory_of_ctyp cT) (Thm.typ_of cT);
   127 fun string_of_ctyp cT = Syntax.string_of_typ_global (Thm.theory_of_ctyp cT) (Thm.typ_of cT);
   128 val print_ctyp = writeln o string_of_ctyp;
   129 
   130 fun pretty_cterm ct = Syntax.pretty_term_global (Thm.theory_of_cterm ct) (Thm.term_of ct);
   131 fun string_of_cterm ct = Syntax.string_of_term_global (Thm.theory_of_cterm ct) (Thm.term_of ct);
   132 val print_cterm = writeln o string_of_cterm;
   133 
   134 
   135 
   136 (** print theory **)
   137 
   138 val print_syntax = Syntax.print_syntax o Sign.syn_of;
   139 
   140 
   141 (* pretty_full_theory *)
   142 
   143 fun pretty_full_theory verbose thy =
   144   let
   145     val ctxt = ProofContext.init thy;
   146 
   147     fun prt_cls c = Syntax.pretty_sort ctxt [c];
   148     fun prt_sort S = Syntax.pretty_sort ctxt S;
   149     fun prt_arity t (c, (_, Ss)) = Syntax.pretty_arity ctxt (t, Ss, [c]);
   150     fun prt_typ ty = Pretty.quote (Syntax.pretty_typ ctxt ty);
   151     val prt_typ_no_tvars = prt_typ o Logic.unvarifyT;
   152     fun prt_term t = Pretty.quote (Syntax.pretty_term ctxt t);
   153     val prt_term_no_vars = prt_term o Logic.unvarify;
   154     fun prt_const (c, ty) = [Pretty.str c, Pretty.str " ::", Pretty.brk 1, prt_typ_no_tvars ty];
   155     val prt_const' = Defs.pretty_const (Syntax.pp ctxt);
   156 
   157     fun pretty_classrel (c, []) = prt_cls c
   158       | pretty_classrel (c, cs) = Pretty.block
   159           (prt_cls c :: Pretty.str " <" :: Pretty.brk 1 ::
   160             Pretty.commas (map prt_cls cs));
   161 
   162     fun pretty_default S = Pretty.block
   163       [Pretty.str "default sort:", Pretty.brk 1, prt_sort S];
   164 
   165     val tfrees = map (fn v => TFree (v, []));
   166     fun pretty_type syn (t, ((Type.LogicalType n, _), _)) =
   167           if syn then NONE
   168           else SOME (prt_typ (Type (t, tfrees (Name.invents Name.context Name.aT n))))
   169       | pretty_type syn (t, ((Type.Abbreviation (vs, U, syn'), _), _)) =
   170           if syn <> syn' then NONE
   171           else SOME (Pretty.block
   172             [prt_typ (Type (t, tfrees vs)), Pretty.str " =", Pretty.brk 1, prt_typ U])
   173       | pretty_type syn (t, ((Type.Nonterminal, _), _)) =
   174           if not syn then NONE
   175           else SOME (prt_typ (Type (t, [])));
   176 
   177     val pretty_arities = maps (fn (t, ars) => map (prt_arity t) ars);
   178 
   179     fun pretty_abbrev (c, (ty, t)) = Pretty.block
   180       (prt_const (c, ty) @ [Pretty.str " ==", Pretty.brk 1, prt_term_no_vars t]);
   181 
   182     fun pretty_axm (a, t) = Pretty.block [Pretty.str (a ^ ":"), Pretty.brk 1, prt_term_no_vars t];
   183 
   184     fun pretty_finals reds = Pretty.block
   185       (Pretty.str "final:" :: Pretty.brk 1 :: Pretty.commas (map (prt_const' o fst) reds));
   186 
   187     fun pretty_reduct (lhs, rhs) = Pretty.block
   188       ([prt_const' lhs, Pretty.str "  ->", Pretty.brk 2] @
   189         Pretty.commas (map prt_const' (sort_wrt #1 rhs)));
   190 
   191     fun pretty_restrict (const, name) =
   192       Pretty.block ([prt_const' const, Pretty.brk 2, Pretty.str ("(from " ^ quote name ^ ")")]);
   193 
   194     val axioms = (Theory.axiom_space thy, Theory.axiom_table thy);
   195     val defs = Theory.defs_of thy;
   196     val {restricts, reducts} = Defs.dest defs;
   197     val {naming, syn = _, tsig, consts} = Sign.rep_sg thy;
   198     val {constants, constraints} = Consts.dest consts;
   199     val extern_const = NameSpace.extern (#1 constants);
   200     val {classes, default, types, ...} = Type.rep_tsig tsig;
   201     val (class_space, class_algebra) = classes;
   202     val {classes, arities} = Sorts.rep_algebra class_algebra;
   203 
   204     val clsses = NameSpace.dest_table (class_space, Symtab.make (Graph.dest classes));
   205     val tdecls = NameSpace.dest_table types;
   206     val arties = NameSpace.dest_table (Sign.type_space thy, arities);
   207 
   208     fun prune_const c = not verbose andalso
   209       member (op =) (Consts.the_tags consts c) Markup.property_internal;
   210     val cnsts = NameSpace.extern_table (#1 constants,
   211       Symtab.make (filter_out (prune_const o fst) (Symtab.dest (#2 constants))));
   212 
   213     val log_cnsts = map_filter (fn (c, (ty, NONE)) => SOME (c, ty) | _ => NONE) cnsts;
   214     val abbrevs = map_filter (fn (c, (ty, SOME t)) => SOME (c, (ty, t)) | _ => NONE) cnsts;
   215     val cnstrs = NameSpace.extern_table constraints;
   216 
   217     val axms = NameSpace.extern_table axioms;
   218 
   219     val (reds0, (reds1, reds2)) = filter_out (prune_const o fst o fst) reducts
   220       |> map (fn (lhs, rhs) =>
   221         (apfst extern_const lhs, map (apfst extern_const) (filter_out (prune_const o fst) rhs)))
   222       |> sort_wrt (#1 o #1)
   223       |> List.partition (null o #2)
   224       ||> List.partition (Defs.plain_args o #2 o #1);
   225     val rests = restricts |> map (apfst (apfst extern_const)) |> sort_wrt (#1 o #1);
   226   in
   227     [Pretty.strs ("names:" :: Context.display_names thy)] @
   228     [Pretty.big_list "classes:" (map pretty_classrel clsses),
   229       pretty_default default,
   230       Pretty.big_list "syntactic types:" (map_filter (pretty_type true) tdecls),
   231       Pretty.big_list "logical types:" (map_filter (pretty_type false) tdecls),
   232       Pretty.big_list "type arities:" (pretty_arities arties),
   233       Pretty.big_list "logical consts:" (map (Pretty.block o prt_const) log_cnsts),
   234       Pretty.big_list "abbreviations:" (map pretty_abbrev abbrevs),
   235       Pretty.big_list "constraints:" (map (Pretty.block o prt_const) cnstrs),
   236       Pretty.big_list "axioms:" (map pretty_axm axms),
   237       Pretty.strs ("oracles:" :: Thm.extern_oracles thy),
   238       Pretty.big_list "definitions:"
   239         [pretty_finals reds0,
   240          Pretty.big_list "non-overloaded:" (map pretty_reduct reds1),
   241          Pretty.big_list "overloaded:" (map pretty_reduct reds2),
   242          Pretty.big_list "pattern restrictions:" (map pretty_restrict rests)]]
   243   end;
   244 
   245 end;
   246 
   247 structure Basic_Display: BASIC_DISPLAY = Display;
   248 open Basic_Display;