src/HOL/Power.thy
author haftmann
Wed Feb 17 21:51:57 2016 +0100 (2016-02-17)
changeset 62347 2230b7047376
parent 62083 7582b39f51ed
child 62366 95c6cf433c91
permissions -rw-r--r--
generalized some lemmas;
moved some lemmas in more appropriate places;
deleted potentially dangerous simp rule
     1 (*  Title:      HOL/Power.thy
     2     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     3     Copyright   1997  University of Cambridge
     4 *)
     5 
     6 section \<open>Exponentiation\<close>
     7 
     8 theory Power
     9 imports Num Equiv_Relations
    10 begin
    11 
    12 subsection \<open>Powers for Arbitrary Monoids\<close>
    13 
    14 class power = one + times
    15 begin
    16 
    17 primrec power :: "'a \<Rightarrow> nat \<Rightarrow> 'a"  (infixr "^" 80)
    18 where
    19   power_0: "a ^ 0 = 1"
    20 | power_Suc: "a ^ Suc n = a * a ^ n"
    21 
    22 notation (latex output)
    23   power ("(_\<^bsup>_\<^esup>)" [1000] 1000)
    24 
    25 text \<open>Special syntax for squares.\<close>
    26 abbreviation power2 :: "'a \<Rightarrow> 'a"  ("(_\<^sup>2)" [1000] 999)
    27   where "x\<^sup>2 \<equiv> x ^ 2"
    28 
    29 end
    30 
    31 context monoid_mult
    32 begin
    33 
    34 subclass power .
    35 
    36 lemma power_one [simp]:
    37   "1 ^ n = 1"
    38   by (induct n) simp_all
    39 
    40 lemma power_one_right [simp]:
    41   "a ^ 1 = a"
    42   by simp
    43 
    44 lemma power_Suc0_right [simp]:
    45   "a ^ Suc 0 = a"
    46   by simp
    47 
    48 lemma power_commutes:
    49   "a ^ n * a = a * a ^ n"
    50   by (induct n) (simp_all add: mult.assoc)
    51 
    52 lemma power_Suc2:
    53   "a ^ Suc n = a ^ n * a"
    54   by (simp add: power_commutes)
    55 
    56 lemma power_add:
    57   "a ^ (m + n) = a ^ m * a ^ n"
    58   by (induct m) (simp_all add: algebra_simps)
    59 
    60 lemma power_mult:
    61   "a ^ (m * n) = (a ^ m) ^ n"
    62   by (induct n) (simp_all add: power_add)
    63 
    64 lemma power2_eq_square: "a\<^sup>2 = a * a"
    65   by (simp add: numeral_2_eq_2)
    66 
    67 lemma power3_eq_cube: "a ^ 3 = a * a * a"
    68   by (simp add: numeral_3_eq_3 mult.assoc)
    69 
    70 lemma power_even_eq:
    71   "a ^ (2 * n) = (a ^ n)\<^sup>2"
    72   by (subst mult.commute) (simp add: power_mult)
    73 
    74 lemma power_odd_eq:
    75   "a ^ Suc (2*n) = a * (a ^ n)\<^sup>2"
    76   by (simp add: power_even_eq)
    77 
    78 lemma power_numeral_even:
    79   "z ^ numeral (Num.Bit0 w) = (let w = z ^ (numeral w) in w * w)"
    80   unfolding numeral_Bit0 power_add Let_def ..
    81 
    82 lemma power_numeral_odd:
    83   "z ^ numeral (Num.Bit1 w) = (let w = z ^ (numeral w) in z * w * w)"
    84   unfolding numeral_Bit1 One_nat_def add_Suc_right add_0_right
    85   unfolding power_Suc power_add Let_def mult.assoc ..
    86 
    87 lemma funpow_times_power:
    88   "(times x ^^ f x) = times (x ^ f x)"
    89 proof (induct "f x" arbitrary: f)
    90   case 0 then show ?case by (simp add: fun_eq_iff)
    91 next
    92   case (Suc n)
    93   def g \<equiv> "\<lambda>x. f x - 1"
    94   with Suc have "n = g x" by simp
    95   with Suc have "times x ^^ g x = times (x ^ g x)" by simp
    96   moreover from Suc g_def have "f x = g x + 1" by simp
    97   ultimately show ?case by (simp add: power_add funpow_add fun_eq_iff mult.assoc)
    98 qed
    99 
   100 lemma power_commuting_commutes:
   101   assumes "x * y = y * x"
   102   shows "x ^ n * y = y * x ^n"
   103 proof (induct n)
   104   case (Suc n)
   105   have "x ^ Suc n * y = x ^ n * y * x"
   106     by (subst power_Suc2) (simp add: assms ac_simps)
   107   also have "\<dots> = y * x ^ Suc n"
   108     unfolding Suc power_Suc2
   109     by (simp add: ac_simps)
   110   finally show ?case .
   111 qed simp
   112 
   113 lemma power_minus_mult:
   114   "0 < n \<Longrightarrow> a ^ (n - 1) * a = a ^ n"
   115   by (simp add: power_commutes split add: nat_diff_split)
   116 
   117 end
   118 
   119 context comm_monoid_mult
   120 begin
   121 
   122 lemma power_mult_distrib [field_simps]:
   123   "(a * b) ^ n = (a ^ n) * (b ^ n)"
   124   by (induct n) (simp_all add: ac_simps)
   125 
   126 end
   127 
   128 text\<open>Extract constant factors from powers\<close>
   129 declare power_mult_distrib [where a = "numeral w" for w, simp]
   130 declare power_mult_distrib [where b = "numeral w" for w, simp]
   131 
   132 lemma power_add_numeral [simp]:
   133   fixes a :: "'a :: monoid_mult"
   134   shows "a^numeral m * a^numeral n = a^numeral (m + n)"
   135   by (simp add: power_add [symmetric])
   136 
   137 lemma power_add_numeral2 [simp]:
   138   fixes a :: "'a :: monoid_mult"
   139   shows "a^numeral m * (a^numeral n * b) = a^numeral (m + n) * b"
   140   by (simp add: mult.assoc [symmetric])
   141 
   142 lemma power_mult_numeral [simp]:
   143   fixes a :: "'a :: monoid_mult"
   144   shows"(a^numeral m)^numeral n = a^numeral (m * n)"
   145   by (simp only: numeral_mult power_mult)
   146 
   147 context semiring_numeral
   148 begin
   149 
   150 lemma numeral_sqr: "numeral (Num.sqr k) = numeral k * numeral k"
   151   by (simp only: sqr_conv_mult numeral_mult)
   152 
   153 lemma numeral_pow: "numeral (Num.pow k l) = numeral k ^ numeral l"
   154   by (induct l, simp_all only: numeral_class.numeral.simps pow.simps
   155     numeral_sqr numeral_mult power_add power_one_right)
   156 
   157 lemma power_numeral [simp]: "numeral k ^ numeral l = numeral (Num.pow k l)"
   158   by (rule numeral_pow [symmetric])
   159 
   160 end
   161 
   162 context semiring_1
   163 begin
   164 
   165 lemma of_nat_power [simp]:
   166   "of_nat (m ^ n) = of_nat m ^ n"
   167   by (induct n) (simp_all add: of_nat_mult)
   168 
   169 lemma zero_power:
   170   "0 < n \<Longrightarrow> 0 ^ n = 0"
   171   by (cases n) simp_all
   172 
   173 lemma power_zero_numeral [simp]:
   174   "0 ^ numeral k = 0"
   175   by (simp add: numeral_eq_Suc)
   176 
   177 lemma zero_power2: "0\<^sup>2 = 0" (* delete? *)
   178   by (rule power_zero_numeral)
   179 
   180 lemma one_power2: "1\<^sup>2 = 1" (* delete? *)
   181   by (rule power_one)
   182 
   183 lemma power_0_Suc [simp]:
   184   "0 ^ Suc n = 0"
   185   by simp
   186 
   187 text\<open>It looks plausible as a simprule, but its effect can be strange.\<close>
   188 lemma power_0_left:
   189   "0 ^ n = (if n = 0 then 1 else 0)"
   190   by (cases n) simp_all
   191 
   192 end
   193 
   194 context comm_semiring_1
   195 begin
   196 
   197 text \<open>The divides relation\<close>
   198 
   199 lemma le_imp_power_dvd:
   200   assumes "m \<le> n" shows "a ^ m dvd a ^ n"
   201 proof
   202   have "a ^ n = a ^ (m + (n - m))"
   203     using \<open>m \<le> n\<close> by simp
   204   also have "\<dots> = a ^ m * a ^ (n - m)"
   205     by (rule power_add)
   206   finally show "a ^ n = a ^ m * a ^ (n - m)" .
   207 qed
   208 
   209 lemma power_le_dvd:
   210   "a ^ n dvd b \<Longrightarrow> m \<le> n \<Longrightarrow> a ^ m dvd b"
   211   by (rule dvd_trans [OF le_imp_power_dvd])
   212 
   213 lemma dvd_power_same:
   214   "x dvd y \<Longrightarrow> x ^ n dvd y ^ n"
   215   by (induct n) (auto simp add: mult_dvd_mono)
   216 
   217 lemma dvd_power_le:
   218   "x dvd y \<Longrightarrow> m \<ge> n \<Longrightarrow> x ^ n dvd y ^ m"
   219   by (rule power_le_dvd [OF dvd_power_same])
   220 
   221 lemma dvd_power [simp]:
   222   assumes "n > (0::nat) \<or> x = 1"
   223   shows "x dvd (x ^ n)"
   224 using assms proof
   225   assume "0 < n"
   226   then have "x ^ n = x ^ Suc (n - 1)" by simp
   227   then show "x dvd (x ^ n)" by simp
   228 next
   229   assume "x = 1"
   230   then show "x dvd (x ^ n)" by simp
   231 qed
   232 
   233 end
   234 
   235 class semiring_1_no_zero_divisors = semiring_1 + semiring_no_zero_divisors
   236 begin
   237 
   238 subclass power .
   239 
   240 lemma power_eq_0_iff [simp]:
   241   "a ^ n = 0 \<longleftrightarrow> a = 0 \<and> n > 0"
   242   by (induct n) auto
   243 
   244 lemma power_not_zero:
   245   "a \<noteq> 0 \<Longrightarrow> a ^ n \<noteq> 0"
   246   by (induct n) auto
   247 
   248 lemma zero_eq_power2 [simp]:
   249   "a\<^sup>2 = 0 \<longleftrightarrow> a = 0"
   250   unfolding power2_eq_square by simp
   251 
   252 end
   253 
   254 context semidom
   255 begin
   256 
   257 subclass semiring_1_no_zero_divisors ..
   258 
   259 end
   260 
   261 context ring_1
   262 begin
   263 
   264 lemma power_minus:
   265   "(- a) ^ n = (- 1) ^ n * a ^ n"
   266 proof (induct n)
   267   case 0 show ?case by simp
   268 next
   269   case (Suc n) then show ?case
   270     by (simp del: power_Suc add: power_Suc2 mult.assoc)
   271 qed
   272 
   273 lemma power_minus': "NO_MATCH 1 x \<Longrightarrow> (-x) ^ n = (-1)^n * x ^ n"
   274   by (rule power_minus)
   275 
   276 lemma power_minus_Bit0:
   277   "(- x) ^ numeral (Num.Bit0 k) = x ^ numeral (Num.Bit0 k)"
   278   by (induct k, simp_all only: numeral_class.numeral.simps power_add
   279     power_one_right mult_minus_left mult_minus_right minus_minus)
   280 
   281 lemma power_minus_Bit1:
   282   "(- x) ^ numeral (Num.Bit1 k) = - (x ^ numeral (Num.Bit1 k))"
   283   by (simp only: eval_nat_numeral(3) power_Suc power_minus_Bit0 mult_minus_left)
   284 
   285 lemma power2_minus [simp]:
   286   "(- a)\<^sup>2 = a\<^sup>2"
   287   by (fact power_minus_Bit0)
   288 
   289 lemma power_minus1_even [simp]:
   290   "(- 1) ^ (2*n) = 1"
   291 proof (induct n)
   292   case 0 show ?case by simp
   293 next
   294   case (Suc n) then show ?case by (simp add: power_add power2_eq_square)
   295 qed
   296 
   297 lemma power_minus1_odd:
   298   "(- 1) ^ Suc (2*n) = -1"
   299   by simp
   300 
   301 lemma power_minus_even [simp]:
   302   "(-a) ^ (2*n) = a ^ (2*n)"
   303   by (simp add: power_minus [of a])
   304 
   305 end
   306 
   307 context ring_1_no_zero_divisors
   308 begin
   309 
   310 subclass semiring_1_no_zero_divisors ..
   311 
   312 lemma power2_eq_1_iff:
   313   "a\<^sup>2 = 1 \<longleftrightarrow> a = 1 \<or> a = - 1"
   314   using square_eq_1_iff [of a] by (simp add: power2_eq_square)
   315 
   316 end
   317 
   318 context idom
   319 begin
   320 
   321 lemma power2_eq_iff: "x\<^sup>2 = y\<^sup>2 \<longleftrightarrow> x = y \<or> x = - y"
   322   unfolding power2_eq_square by (rule square_eq_iff)
   323 
   324 end
   325 
   326 context algebraic_semidom
   327 begin
   328 
   329 lemma div_power:
   330   assumes "b dvd a"
   331   shows "(a div b) ^ n = a ^ n div b ^ n"
   332   using assms by (induct n) (simp_all add: div_mult_div_if_dvd dvd_power_same)
   333 
   334 end
   335 
   336 context normalization_semidom
   337 begin
   338 
   339 lemma normalize_power:
   340   "normalize (a ^ n) = normalize a ^ n"
   341   by (induct n) (simp_all add: normalize_mult)
   342 
   343 lemma unit_factor_power:
   344   "unit_factor (a ^ n) = unit_factor a ^ n"
   345   by (induct n) (simp_all add: unit_factor_mult)
   346 
   347 end
   348 
   349 context division_ring
   350 begin
   351 
   352 text\<open>Perhaps these should be simprules.\<close>
   353 lemma power_inverse [field_simps, divide_simps]:
   354   "inverse a ^ n = inverse (a ^ n)"
   355 proof (cases "a = 0")
   356   case True then show ?thesis by (simp add: power_0_left)
   357 next
   358   case False then have "inverse (a ^ n) = inverse a ^ n"
   359     by (induct n) (simp_all add: nonzero_inverse_mult_distrib power_commutes)
   360   then show ?thesis by simp
   361 qed
   362 
   363 lemma power_one_over [field_simps, divide_simps]:
   364   "(1 / a) ^ n = 1 / a ^ n"
   365   using power_inverse [of a] by (simp add: divide_inverse)
   366 
   367 end
   368 
   369 context field
   370 begin
   371 
   372 lemma power_diff:
   373   assumes nz: "a \<noteq> 0"
   374   shows "n \<le> m \<Longrightarrow> a ^ (m - n) = a ^ m / a ^ n"
   375   by (induct m n rule: diff_induct) (simp_all add: nz power_not_zero)
   376 
   377 lemma power_divide [field_simps, divide_simps]:
   378   "(a / b) ^ n = a ^ n / b ^ n"
   379   by (induct n) simp_all
   380 
   381 end
   382 
   383 
   384 subsection \<open>Exponentiation on ordered types\<close>
   385 
   386 context linordered_semidom
   387 begin
   388 
   389 lemma zero_less_power [simp]:
   390   "0 < a \<Longrightarrow> 0 < a ^ n"
   391   by (induct n) simp_all
   392 
   393 lemma zero_le_power [simp]:
   394   "0 \<le> a \<Longrightarrow> 0 \<le> a ^ n"
   395   by (induct n) simp_all
   396 
   397 lemma power_mono:
   398   "a \<le> b \<Longrightarrow> 0 \<le> a \<Longrightarrow> a ^ n \<le> b ^ n"
   399   by (induct n) (auto intro: mult_mono order_trans [of 0 a b])
   400 
   401 lemma one_le_power [simp]: "1 \<le> a \<Longrightarrow> 1 \<le> a ^ n"
   402   using power_mono [of 1 a n] by simp
   403 
   404 lemma power_le_one: "\<lbrakk>0 \<le> a; a \<le> 1\<rbrakk> \<Longrightarrow> a ^ n \<le> 1"
   405   using power_mono [of a 1 n] by simp
   406 
   407 lemma power_gt1_lemma:
   408   assumes gt1: "1 < a"
   409   shows "1 < a * a ^ n"
   410 proof -
   411   from gt1 have "0 \<le> a"
   412     by (fact order_trans [OF zero_le_one less_imp_le])
   413   have "1 * 1 < a * 1" using gt1 by simp
   414   also have "\<dots> \<le> a * a ^ n" using gt1
   415     by (simp only: mult_mono \<open>0 \<le> a\<close> one_le_power order_less_imp_le
   416         zero_le_one order_refl)
   417   finally show ?thesis by simp
   418 qed
   419 
   420 lemma power_gt1:
   421   "1 < a \<Longrightarrow> 1 < a ^ Suc n"
   422   by (simp add: power_gt1_lemma)
   423 
   424 lemma one_less_power [simp]:
   425   "1 < a \<Longrightarrow> 0 < n \<Longrightarrow> 1 < a ^ n"
   426   by (cases n) (simp_all add: power_gt1_lemma)
   427 
   428 lemma power_le_imp_le_exp:
   429   assumes gt1: "1 < a"
   430   shows "a ^ m \<le> a ^ n \<Longrightarrow> m \<le> n"
   431 proof (induct m arbitrary: n)
   432   case 0
   433   show ?case by simp
   434 next
   435   case (Suc m)
   436   show ?case
   437   proof (cases n)
   438     case 0
   439     with Suc.prems Suc.hyps have "a * a ^ m \<le> 1" by simp
   440     with gt1 show ?thesis
   441       by (force simp only: power_gt1_lemma
   442           not_less [symmetric])
   443   next
   444     case (Suc n)
   445     with Suc.prems Suc.hyps show ?thesis
   446       by (force dest: mult_left_le_imp_le
   447           simp add: less_trans [OF zero_less_one gt1])
   448   qed
   449 qed
   450 
   451 lemma of_nat_zero_less_power_iff [simp]:
   452   "of_nat x ^ n > 0 \<longleftrightarrow> x > 0 \<or> n = 0"
   453   by (induct n) auto
   454 
   455 text\<open>Surely we can strengthen this? It holds for \<open>0<a<1\<close> too.\<close>
   456 lemma power_inject_exp [simp]:
   457   "1 < a \<Longrightarrow> a ^ m = a ^ n \<longleftrightarrow> m = n"
   458   by (force simp add: order_antisym power_le_imp_le_exp)
   459 
   460 text\<open>Can relax the first premise to @{term "0<a"} in the case of the
   461 natural numbers.\<close>
   462 lemma power_less_imp_less_exp:
   463   "1 < a \<Longrightarrow> a ^ m < a ^ n \<Longrightarrow> m < n"
   464   by (simp add: order_less_le [of m n] less_le [of "a^m" "a^n"]
   465     power_le_imp_le_exp)
   466 
   467 lemma power_strict_mono [rule_format]:
   468   "a < b \<Longrightarrow> 0 \<le> a \<Longrightarrow> 0 < n \<longrightarrow> a ^ n < b ^ n"
   469   by (induct n)
   470    (auto simp add: mult_strict_mono le_less_trans [of 0 a b])
   471 
   472 text\<open>Lemma for \<open>power_strict_decreasing\<close>\<close>
   473 lemma power_Suc_less:
   474   "0 < a \<Longrightarrow> a < 1 \<Longrightarrow> a * a ^ n < a ^ n"
   475   by (induct n)
   476     (auto simp add: mult_strict_left_mono)
   477 
   478 lemma power_strict_decreasing [rule_format]:
   479   "n < N \<Longrightarrow> 0 < a \<Longrightarrow> a < 1 \<longrightarrow> a ^ N < a ^ n"
   480 proof (induct N)
   481   case 0 then show ?case by simp
   482 next
   483   case (Suc N) then show ?case
   484   apply (auto simp add: power_Suc_less less_Suc_eq)
   485   apply (subgoal_tac "a * a^N < 1 * a^n")
   486   apply simp
   487   apply (rule mult_strict_mono) apply auto
   488   done
   489 qed
   490 
   491 text\<open>Proof resembles that of \<open>power_strict_decreasing\<close>\<close>
   492 lemma power_decreasing [rule_format]:
   493   "n \<le> N \<Longrightarrow> 0 \<le> a \<Longrightarrow> a \<le> 1 \<longrightarrow> a ^ N \<le> a ^ n"
   494 proof (induct N)
   495   case 0 then show ?case by simp
   496 next
   497   case (Suc N) then show ?case
   498   apply (auto simp add: le_Suc_eq)
   499   apply (subgoal_tac "a * a^N \<le> 1 * a^n", simp)
   500   apply (rule mult_mono) apply auto
   501   done
   502 qed
   503 
   504 lemma power_Suc_less_one:
   505   "0 < a \<Longrightarrow> a < 1 \<Longrightarrow> a ^ Suc n < 1"
   506   using power_strict_decreasing [of 0 "Suc n" a] by simp
   507 
   508 text\<open>Proof again resembles that of \<open>power_strict_decreasing\<close>\<close>
   509 lemma power_increasing [rule_format]:
   510   "n \<le> N \<Longrightarrow> 1 \<le> a \<Longrightarrow> a ^ n \<le> a ^ N"
   511 proof (induct N)
   512   case 0 then show ?case by simp
   513 next
   514   case (Suc N) then show ?case
   515   apply (auto simp add: le_Suc_eq)
   516   apply (subgoal_tac "1 * a^n \<le> a * a^N", simp)
   517   apply (rule mult_mono) apply (auto simp add: order_trans [OF zero_le_one])
   518   done
   519 qed
   520 
   521 text\<open>Lemma for \<open>power_strict_increasing\<close>\<close>
   522 lemma power_less_power_Suc:
   523   "1 < a \<Longrightarrow> a ^ n < a * a ^ n"
   524   by (induct n) (auto simp add: mult_strict_left_mono less_trans [OF zero_less_one])
   525 
   526 lemma power_strict_increasing [rule_format]:
   527   "n < N \<Longrightarrow> 1 < a \<longrightarrow> a ^ n < a ^ N"
   528 proof (induct N)
   529   case 0 then show ?case by simp
   530 next
   531   case (Suc N) then show ?case
   532   apply (auto simp add: power_less_power_Suc less_Suc_eq)
   533   apply (subgoal_tac "1 * a^n < a * a^N", simp)
   534   apply (rule mult_strict_mono) apply (auto simp add: less_trans [OF zero_less_one] less_imp_le)
   535   done
   536 qed
   537 
   538 lemma power_increasing_iff [simp]:
   539   "1 < b \<Longrightarrow> b ^ x \<le> b ^ y \<longleftrightarrow> x \<le> y"
   540   by (blast intro: power_le_imp_le_exp power_increasing less_imp_le)
   541 
   542 lemma power_strict_increasing_iff [simp]:
   543   "1 < b \<Longrightarrow> b ^ x < b ^ y \<longleftrightarrow> x < y"
   544 by (blast intro: power_less_imp_less_exp power_strict_increasing)
   545 
   546 lemma power_le_imp_le_base:
   547   assumes le: "a ^ Suc n \<le> b ^ Suc n"
   548     and ynonneg: "0 \<le> b"
   549   shows "a \<le> b"
   550 proof (rule ccontr)
   551   assume "~ a \<le> b"
   552   then have "b < a" by (simp only: linorder_not_le)
   553   then have "b ^ Suc n < a ^ Suc n"
   554     by (simp only: assms power_strict_mono)
   555   from le and this show False
   556     by (simp add: linorder_not_less [symmetric])
   557 qed
   558 
   559 lemma power_less_imp_less_base:
   560   assumes less: "a ^ n < b ^ n"
   561   assumes nonneg: "0 \<le> b"
   562   shows "a < b"
   563 proof (rule contrapos_pp [OF less])
   564   assume "~ a < b"
   565   hence "b \<le> a" by (simp only: linorder_not_less)
   566   hence "b ^ n \<le> a ^ n" using nonneg by (rule power_mono)
   567   thus "\<not> a ^ n < b ^ n" by (simp only: linorder_not_less)
   568 qed
   569 
   570 lemma power_inject_base:
   571   "a ^ Suc n = b ^ Suc n \<Longrightarrow> 0 \<le> a \<Longrightarrow> 0 \<le> b \<Longrightarrow> a = b"
   572 by (blast intro: power_le_imp_le_base antisym eq_refl sym)
   573 
   574 lemma power_eq_imp_eq_base:
   575   "a ^ n = b ^ n \<Longrightarrow> 0 \<le> a \<Longrightarrow> 0 \<le> b \<Longrightarrow> 0 < n \<Longrightarrow> a = b"
   576   by (cases n) (simp_all del: power_Suc, rule power_inject_base)
   577 
   578 lemma power_eq_iff_eq_base:
   579   "0 < n \<Longrightarrow> 0 \<le> a \<Longrightarrow> 0 \<le> b \<Longrightarrow> a ^ n = b ^ n \<longleftrightarrow> a = b"
   580   using power_eq_imp_eq_base [of a n b] by auto
   581 
   582 lemma power2_le_imp_le:
   583   "x\<^sup>2 \<le> y\<^sup>2 \<Longrightarrow> 0 \<le> y \<Longrightarrow> x \<le> y"
   584   unfolding numeral_2_eq_2 by (rule power_le_imp_le_base)
   585 
   586 lemma power2_less_imp_less:
   587   "x\<^sup>2 < y\<^sup>2 \<Longrightarrow> 0 \<le> y \<Longrightarrow> x < y"
   588   by (rule power_less_imp_less_base)
   589 
   590 lemma power2_eq_imp_eq:
   591   "x\<^sup>2 = y\<^sup>2 \<Longrightarrow> 0 \<le> x \<Longrightarrow> 0 \<le> y \<Longrightarrow> x = y"
   592   unfolding numeral_2_eq_2 by (erule (2) power_eq_imp_eq_base) simp
   593 
   594 lemma power_Suc_le_self:
   595   shows "0 \<le> a \<Longrightarrow> a \<le> 1 \<Longrightarrow> a ^ Suc n \<le> a"
   596   using power_decreasing [of 1 "Suc n" a] by simp
   597 
   598 end
   599 
   600 context linordered_ring_strict
   601 begin
   602 
   603 lemma sum_squares_eq_zero_iff:
   604   "x * x + y * y = 0 \<longleftrightarrow> x = 0 \<and> y = 0"
   605   by (simp add: add_nonneg_eq_0_iff)
   606 
   607 lemma sum_squares_le_zero_iff:
   608   "x * x + y * y \<le> 0 \<longleftrightarrow> x = 0 \<and> y = 0"
   609   by (simp add: le_less not_sum_squares_lt_zero sum_squares_eq_zero_iff)
   610 
   611 lemma sum_squares_gt_zero_iff:
   612   "0 < x * x + y * y \<longleftrightarrow> x \<noteq> 0 \<or> y \<noteq> 0"
   613   by (simp add: not_le [symmetric] sum_squares_le_zero_iff)
   614 
   615 end
   616 
   617 context linordered_idom
   618 begin
   619 
   620 lemma power_abs: "\<bar>a ^ n\<bar> = \<bar>a\<bar> ^ n"
   621   by (induct n) (auto simp add: abs_mult)
   622 
   623 lemma abs_power_minus [simp]: "\<bar>(-a) ^ n\<bar> = \<bar>a ^ n\<bar>"
   624   by (simp add: power_abs)
   625 
   626 lemma zero_less_power_abs_iff [simp]: "0 < \<bar>a\<bar> ^ n \<longleftrightarrow> a \<noteq> 0 \<or> n = 0"
   627 proof (induct n)
   628   case 0 show ?case by simp
   629 next
   630   case (Suc n) show ?case by (auto simp add: Suc zero_less_mult_iff)
   631 qed
   632 
   633 lemma zero_le_power_abs [simp]: "0 \<le> \<bar>a\<bar> ^ n"
   634   by (rule zero_le_power [OF abs_ge_zero])
   635 
   636 lemma zero_le_power2 [simp]:
   637   "0 \<le> a\<^sup>2"
   638   by (simp add: power2_eq_square)
   639 
   640 lemma zero_less_power2 [simp]:
   641   "0 < a\<^sup>2 \<longleftrightarrow> a \<noteq> 0"
   642   by (force simp add: power2_eq_square zero_less_mult_iff linorder_neq_iff)
   643 
   644 lemma power2_less_0 [simp]:
   645   "\<not> a\<^sup>2 < 0"
   646   by (force simp add: power2_eq_square mult_less_0_iff)
   647 
   648 lemma power2_less_eq_zero_iff [simp]:
   649   "a\<^sup>2 \<le> 0 \<longleftrightarrow> a = 0"
   650   by (simp add: le_less)
   651 
   652 lemma abs_power2 [simp]: "\<bar>a\<^sup>2\<bar> = a\<^sup>2"
   653   by (simp add: power2_eq_square abs_mult abs_mult_self)
   654 
   655 lemma power2_abs [simp]: "\<bar>a\<bar>\<^sup>2 = a\<^sup>2"
   656   by (simp add: power2_eq_square abs_mult_self)
   657 
   658 lemma odd_power_less_zero:
   659   "a < 0 \<Longrightarrow> a ^ Suc (2*n) < 0"
   660 proof (induct n)
   661   case 0
   662   then show ?case by simp
   663 next
   664   case (Suc n)
   665   have "a ^ Suc (2 * Suc n) = (a*a) * a ^ Suc(2*n)"
   666     by (simp add: ac_simps power_add power2_eq_square)
   667   thus ?case
   668     by (simp del: power_Suc add: Suc mult_less_0_iff mult_neg_neg)
   669 qed
   670 
   671 lemma odd_0_le_power_imp_0_le:
   672   "0 \<le> a ^ Suc (2*n) \<Longrightarrow> 0 \<le> a"
   673   using odd_power_less_zero [of a n]
   674     by (force simp add: linorder_not_less [symmetric])
   675 
   676 lemma zero_le_even_power'[simp]:
   677   "0 \<le> a ^ (2*n)"
   678 proof (induct n)
   679   case 0
   680     show ?case by simp
   681 next
   682   case (Suc n)
   683     have "a ^ (2 * Suc n) = (a*a) * a ^ (2*n)"
   684       by (simp add: ac_simps power_add power2_eq_square)
   685     thus ?case
   686       by (simp add: Suc zero_le_mult_iff)
   687 qed
   688 
   689 lemma sum_power2_ge_zero:
   690   "0 \<le> x\<^sup>2 + y\<^sup>2"
   691   by (intro add_nonneg_nonneg zero_le_power2)
   692 
   693 lemma not_sum_power2_lt_zero:
   694   "\<not> x\<^sup>2 + y\<^sup>2 < 0"
   695   unfolding not_less by (rule sum_power2_ge_zero)
   696 
   697 lemma sum_power2_eq_zero_iff:
   698   "x\<^sup>2 + y\<^sup>2 = 0 \<longleftrightarrow> x = 0 \<and> y = 0"
   699   unfolding power2_eq_square by (simp add: add_nonneg_eq_0_iff)
   700 
   701 lemma sum_power2_le_zero_iff:
   702   "x\<^sup>2 + y\<^sup>2 \<le> 0 \<longleftrightarrow> x = 0 \<and> y = 0"
   703   by (simp add: le_less sum_power2_eq_zero_iff not_sum_power2_lt_zero)
   704 
   705 lemma sum_power2_gt_zero_iff:
   706   "0 < x\<^sup>2 + y\<^sup>2 \<longleftrightarrow> x \<noteq> 0 \<or> y \<noteq> 0"
   707   unfolding not_le [symmetric] by (simp add: sum_power2_le_zero_iff)
   708 
   709 lemma abs_le_square_iff:
   710    "\<bar>x\<bar> \<le> \<bar>y\<bar> \<longleftrightarrow> x\<^sup>2 \<le> y\<^sup>2"
   711 proof
   712   assume "\<bar>x\<bar> \<le> \<bar>y\<bar>"
   713   then have "\<bar>x\<bar>\<^sup>2 \<le> \<bar>y\<bar>\<^sup>2" by (rule power_mono, simp)
   714   then show "x\<^sup>2 \<le> y\<^sup>2" by simp
   715 next
   716   assume "x\<^sup>2 \<le> y\<^sup>2"
   717   then show "\<bar>x\<bar> \<le> \<bar>y\<bar>"
   718     by (auto intro!: power2_le_imp_le [OF _ abs_ge_zero])
   719 qed
   720 
   721 lemma abs_square_le_1:"x\<^sup>2 \<le> 1 \<longleftrightarrow> \<bar>x\<bar> \<le> 1"
   722   using abs_le_square_iff [of x 1]
   723   by simp
   724 
   725 lemma abs_square_eq_1: "x\<^sup>2 = 1 \<longleftrightarrow> \<bar>x\<bar> = 1"
   726   by (auto simp add: abs_if power2_eq_1_iff)
   727 
   728 lemma abs_square_less_1: "x\<^sup>2 < 1 \<longleftrightarrow> \<bar>x\<bar> < 1"
   729   using  abs_square_eq_1 [of x] abs_square_le_1 [of x]
   730   by (auto simp add: le_less)
   731 
   732 end
   733 
   734 
   735 subsection \<open>Miscellaneous rules\<close>
   736 
   737 lemma (in linordered_semidom) self_le_power:
   738   "1 \<le> a \<Longrightarrow> 0 < n \<Longrightarrow> a \<le> a ^ n"
   739   using power_increasing [of 1 n a] power_one_right [of a] by auto
   740 
   741 lemma (in power) power_eq_if:
   742   "p ^ m = (if m=0 then 1 else p * (p ^ (m - 1)))"
   743   unfolding One_nat_def by (cases m) simp_all
   744 
   745 lemma (in comm_semiring_1) power2_sum:
   746   "(x + y)\<^sup>2 = x\<^sup>2 + y\<^sup>2 + 2 * x * y"
   747   by (simp add: algebra_simps power2_eq_square mult_2_right)
   748 
   749 lemma (in comm_ring_1) power2_diff:
   750   "(x - y)\<^sup>2 = x\<^sup>2 + y\<^sup>2 - 2 * x * y"
   751   by (simp add: algebra_simps power2_eq_square mult_2_right)
   752 
   753 lemma (in comm_ring_1) power2_commute:
   754   "(x - y)\<^sup>2 = (y - x)\<^sup>2"
   755   by (simp add: algebra_simps power2_eq_square)
   756 
   757 text \<open>Simprules for comparisons where common factors can be cancelled.\<close>
   758 
   759 lemmas zero_compare_simps =
   760     add_strict_increasing add_strict_increasing2 add_increasing
   761     zero_le_mult_iff zero_le_divide_iff
   762     zero_less_mult_iff zero_less_divide_iff
   763     mult_le_0_iff divide_le_0_iff
   764     mult_less_0_iff divide_less_0_iff
   765     zero_le_power2 power2_less_0
   766 
   767 
   768 subsection \<open>Exponentiation for the Natural Numbers\<close>
   769 
   770 lemma nat_one_le_power [simp]:
   771   "Suc 0 \<le> i \<Longrightarrow> Suc 0 \<le> i ^ n"
   772   by (rule one_le_power [of i n, unfolded One_nat_def])
   773 
   774 lemma nat_zero_less_power_iff [simp]:
   775   "x ^ n > 0 \<longleftrightarrow> x > (0::nat) \<or> n = 0"
   776   by (induct n) auto
   777 
   778 lemma nat_power_eq_Suc_0_iff [simp]:
   779   "x ^ m = Suc 0 \<longleftrightarrow> m = 0 \<or> x = Suc 0"
   780   by (induct m) auto
   781 
   782 lemma power_Suc_0 [simp]:
   783   "Suc 0 ^ n = Suc 0"
   784   by simp
   785 
   786 text\<open>Valid for the naturals, but what if \<open>0<i<1\<close>?
   787 Premises cannot be weakened: consider the case where @{term "i=0"},
   788 @{term "m=1"} and @{term "n=0"}.\<close>
   789 lemma nat_power_less_imp_less:
   790   assumes nonneg: "0 < (i::nat)"
   791   assumes less: "i ^ m < i ^ n"
   792   shows "m < n"
   793 proof (cases "i = 1")
   794   case True with less power_one [where 'a = nat] show ?thesis by simp
   795 next
   796   case False with nonneg have "1 < i" by auto
   797   from power_strict_increasing_iff [OF this] less show ?thesis ..
   798 qed
   799 
   800 lemma power_dvd_imp_le:
   801   "i ^ m dvd i ^ n \<Longrightarrow> (1::nat) < i \<Longrightarrow> m \<le> n"
   802   apply (rule power_le_imp_le_exp, assumption)
   803   apply (erule dvd_imp_le, simp)
   804   done
   805 
   806 lemma power2_nat_le_eq_le:
   807   fixes m n :: nat
   808   shows "m\<^sup>2 \<le> n\<^sup>2 \<longleftrightarrow> m \<le> n"
   809   by (auto intro: power2_le_imp_le power_mono)
   810 
   811 lemma power2_nat_le_imp_le:
   812   fixes m n :: nat
   813   assumes "m\<^sup>2 \<le> n"
   814   shows "m \<le> n"
   815 proof (cases m)
   816   case 0 then show ?thesis by simp
   817 next
   818   case (Suc k)
   819   show ?thesis
   820   proof (rule ccontr)
   821     assume "\<not> m \<le> n"
   822     then have "n < m" by simp
   823     with assms Suc show False
   824       by (simp add: power2_eq_square)
   825   qed
   826 qed
   827 
   828 subsubsection \<open>Cardinality of the Powerset\<close>
   829 
   830 lemma card_UNIV_bool [simp]: "card (UNIV :: bool set) = 2"
   831   unfolding UNIV_bool by simp
   832 
   833 lemma card_Pow: "finite A \<Longrightarrow> card (Pow A) = 2 ^ card A"
   834 proof (induct rule: finite_induct)
   835   case empty
   836     show ?case by auto
   837 next
   838   case (insert x A)
   839   then have "inj_on (insert x) (Pow A)"
   840     unfolding inj_on_def by (blast elim!: equalityE)
   841   then have "card (Pow A) + card (insert x ` Pow A) = 2 * 2 ^ card A"
   842     by (simp add: mult_2 card_image Pow_insert insert.hyps)
   843   then show ?case using insert
   844     apply (simp add: Pow_insert)
   845     apply (subst card_Un_disjoint, auto)
   846     done
   847 qed
   848 
   849 
   850 subsubsection \<open>Generalized sum over a set\<close>
   851 
   852 lemma setsum_zero_power [simp]:
   853   fixes c :: "nat \<Rightarrow> 'a::division_ring"
   854   shows "(\<Sum>i\<in>A. c i * 0^i) = (if finite A \<and> 0 \<in> A then c 0 else 0)"
   855 apply (cases "finite A")
   856   by (induction A rule: finite_induct) auto
   857 
   858 lemma setsum_zero_power' [simp]:
   859   fixes c :: "nat \<Rightarrow> 'a::field"
   860   shows "(\<Sum>i\<in>A. c i * 0^i / d i) = (if finite A \<and> 0 \<in> A then c 0 / d 0 else 0)"
   861   using setsum_zero_power [of "\<lambda>i. c i / d i" A]
   862   by auto
   863 
   864 
   865 subsubsection \<open>Generalized product over a set\<close>
   866 
   867 lemma setprod_constant: "finite A ==> (\<Prod>x\<in> A. (y::'a::{comm_monoid_mult})) = y^(card A)"
   868 apply (erule finite_induct)
   869 apply auto
   870 done
   871 
   872 lemma setprod_power_distrib:
   873   fixes f :: "'a \<Rightarrow> 'b::comm_semiring_1"
   874   shows "setprod f A ^ n = setprod (\<lambda>x. (f x) ^ n) A"
   875 proof (cases "finite A")
   876   case True then show ?thesis
   877     by (induct A rule: finite_induct) (auto simp add: power_mult_distrib)
   878 next
   879   case False then show ?thesis
   880     by simp
   881 qed
   882 
   883 lemma power_setsum:
   884   "c ^ (\<Sum>a\<in>A. f a) = (\<Prod>a\<in>A. c ^ f a)"
   885   by (induct A rule: infinite_finite_induct) (simp_all add: power_add)
   886 
   887 lemma setprod_gen_delta:
   888   assumes fS: "finite S"
   889   shows "setprod (\<lambda>k. if k=a then b k else c) S = (if a \<in> S then (b a ::'a::comm_monoid_mult) * c^ (card S - 1) else c^ card S)"
   890 proof-
   891   let ?f = "(\<lambda>k. if k=a then b k else c)"
   892   {assume a: "a \<notin> S"
   893     hence "\<forall> k\<in> S. ?f k = c" by simp
   894     hence ?thesis  using a setprod_constant[OF fS, of c] by simp }
   895   moreover
   896   {assume a: "a \<in> S"
   897     let ?A = "S - {a}"
   898     let ?B = "{a}"
   899     have eq: "S = ?A \<union> ?B" using a by blast
   900     have dj: "?A \<inter> ?B = {}" by simp
   901     from fS have fAB: "finite ?A" "finite ?B" by auto
   902     have fA0:"setprod ?f ?A = setprod (\<lambda>i. c) ?A"
   903       apply (rule setprod.cong) by auto
   904     have cA: "card ?A = card S - 1" using fS a by auto
   905     have fA1: "setprod ?f ?A = c ^ card ?A"  unfolding fA0 apply (rule setprod_constant) using fS by auto
   906     have "setprod ?f ?A * setprod ?f ?B = setprod ?f S"
   907       using setprod.union_disjoint[OF fAB dj, of ?f, unfolded eq[symmetric]]
   908       by simp
   909     then have ?thesis using a cA
   910       by (simp add: fA1 field_simps cong add: setprod.cong cong del: if_weak_cong)}
   911   ultimately show ?thesis by blast
   912 qed
   913 
   914 subsection \<open>Code generator tweak\<close>
   915 
   916 code_identifier
   917   code_module Power \<rightharpoonup> (SML) Arith and (OCaml) Arith and (Haskell) Arith
   918 
   919 end