src/HOL/List.ML
author wenzelm
Fri Nov 03 21:32:41 2000 +0100 (2000-11-03)
changeset 10385 22836e4c5f4e
parent 9853 5c6425d83501
child 10709 7a29b71d6352
permissions -rw-r--r--
rev_exhaust: rulify;
     1 (*  Title:      HOL/List
     2     ID:         $Id$
     3     Author:     Tobias Nipkow
     4     Copyright   1994 TU Muenchen
     5 
     6 List lemmas
     7 *)
     8 
     9 Goal "!x. xs ~= x#xs";
    10 by (induct_tac "xs" 1);
    11 by Auto_tac;
    12 qed_spec_mp "not_Cons_self";
    13 bind_thm("not_Cons_self2",not_Cons_self RS not_sym);
    14 Addsimps [not_Cons_self,not_Cons_self2];
    15 
    16 Goal "(xs ~= []) = (? y ys. xs = y#ys)";
    17 by (induct_tac "xs" 1);
    18 by Auto_tac;
    19 qed "neq_Nil_conv";
    20 
    21 (* Induction over the length of a list: *)
    22 val [prem] = Goal
    23   "(!!xs. (!ys. length ys < length xs --> P ys) ==> P xs) ==> P(xs)";
    24 by (rtac measure_induct 1 THEN etac prem 1);
    25 qed "length_induct";
    26 
    27 
    28 (** "lists": the list-forming operator over sets **)
    29 
    30 Goalw lists.defs "A<=B ==> lists A <= lists B";
    31 by (rtac lfp_mono 1);
    32 by (REPEAT (ares_tac basic_monos 1));
    33 qed "lists_mono";
    34 
    35 bind_thm ("listsE", lists.mk_cases "x#l : lists A");
    36 AddSEs [listsE];
    37 AddSIs lists.intrs;
    38 
    39 Goal "l: lists A ==> l: lists B --> l: lists (A Int B)";
    40 by (etac lists.induct 1);
    41 by (ALLGOALS Blast_tac);
    42 qed_spec_mp "lists_IntI";
    43 
    44 Goal "lists (A Int B) = lists A Int lists B";
    45 by (rtac (mono_Int RS equalityI) 1);
    46 by (simp_tac (simpset() addsimps [mono_def, lists_mono]) 1);
    47 by (blast_tac (claset() addSIs [lists_IntI]) 1);
    48 qed "lists_Int_eq";
    49 Addsimps [lists_Int_eq];
    50 
    51 Goal "(xs@ys : lists A) = (xs : lists A & ys : lists A)";
    52 by(induct_tac "xs" 1);
    53 by(Auto_tac);
    54 qed "append_in_lists_conv";
    55 AddIffs [append_in_lists_conv];
    56 
    57 (** length **)
    58 (* needs to come before "@" because of thm append_eq_append_conv *)
    59 
    60 section "length";
    61 
    62 Goal "length(xs@ys) = length(xs)+length(ys)";
    63 by (induct_tac "xs" 1);
    64 by Auto_tac;
    65 qed"length_append";
    66 Addsimps [length_append];
    67 
    68 Goal "length (map f xs) = length xs";
    69 by (induct_tac "xs" 1);
    70 by Auto_tac;
    71 qed "length_map";
    72 Addsimps [length_map];
    73 
    74 Goal "length(rev xs) = length(xs)";
    75 by (induct_tac "xs" 1);
    76 by Auto_tac;
    77 qed "length_rev";
    78 Addsimps [length_rev];
    79 
    80 Goal "length(tl xs) = (length xs) - 1";
    81 by (case_tac "xs" 1);
    82 by Auto_tac;
    83 qed "length_tl";
    84 Addsimps [length_tl];
    85 
    86 Goal "(length xs = 0) = (xs = [])";
    87 by (induct_tac "xs" 1);
    88 by Auto_tac;
    89 qed "length_0_conv";
    90 AddIffs [length_0_conv];
    91 
    92 Goal "(0 = length xs) = (xs = [])";
    93 by (induct_tac "xs" 1);
    94 by Auto_tac;
    95 qed "zero_length_conv";
    96 AddIffs [zero_length_conv];
    97 
    98 Goal "(0 < length xs) = (xs ~= [])";
    99 by (induct_tac "xs" 1);
   100 by Auto_tac;
   101 qed "length_greater_0_conv";
   102 AddIffs [length_greater_0_conv];
   103 
   104 Goal "(length xs = Suc n) = (? y ys. xs = y#ys & length ys = n)";
   105 by (induct_tac "xs" 1);
   106 by Auto_tac;
   107 qed "length_Suc_conv";
   108 
   109 (** @ - append **)
   110 
   111 section "@ - append";
   112 
   113 Goal "(xs@ys)@zs = xs@(ys@zs)";
   114 by (induct_tac "xs" 1);
   115 by Auto_tac;
   116 qed "append_assoc";
   117 Addsimps [append_assoc];
   118 
   119 Goal "xs @ [] = xs";
   120 by (induct_tac "xs" 1);
   121 by Auto_tac;
   122 qed "append_Nil2";
   123 Addsimps [append_Nil2];
   124 
   125 Goal "(xs@ys = []) = (xs=[] & ys=[])";
   126 by (induct_tac "xs" 1);
   127 by Auto_tac;
   128 qed "append_is_Nil_conv";
   129 AddIffs [append_is_Nil_conv];
   130 
   131 Goal "([] = xs@ys) = (xs=[] & ys=[])";
   132 by (induct_tac "xs" 1);
   133 by Auto_tac;
   134 qed "Nil_is_append_conv";
   135 AddIffs [Nil_is_append_conv];
   136 
   137 Goal "(xs @ ys = xs) = (ys=[])";
   138 by (induct_tac "xs" 1);
   139 by Auto_tac;
   140 qed "append_self_conv";
   141 
   142 Goal "(xs = xs @ ys) = (ys=[])";
   143 by (induct_tac "xs" 1);
   144 by Auto_tac;
   145 qed "self_append_conv";
   146 AddIffs [append_self_conv,self_append_conv];
   147 
   148 Goal "!ys. length xs = length ys | length us = length vs \
   149 \              --> (xs@us = ys@vs) = (xs=ys & us=vs)";
   150 by (induct_tac "xs" 1);
   151  by (rtac allI 1);
   152  by (case_tac "ys" 1);
   153   by (Asm_simp_tac 1);
   154  by (Force_tac 1);
   155 by (rtac allI 1);
   156 by (case_tac "ys" 1);
   157 by (Force_tac 1);
   158 by (Asm_simp_tac 1);
   159 qed_spec_mp "append_eq_append_conv";
   160 Addsimps [append_eq_append_conv];
   161 
   162 Goal "(xs @ ys = xs @ zs) = (ys=zs)";
   163 by (Simp_tac 1);
   164 qed "same_append_eq";
   165 
   166 Goal "(xs @ [x] = ys @ [y]) = (xs = ys & x = y)"; 
   167 by (Simp_tac 1);
   168 qed "append1_eq_conv";
   169 
   170 Goal "(ys @ xs = zs @ xs) = (ys=zs)";
   171 by (Simp_tac 1);
   172 qed "append_same_eq";
   173 
   174 AddIffs [same_append_eq, append1_eq_conv, append_same_eq];
   175 
   176 Goal "(xs @ ys = ys) = (xs=[])";
   177 by (cut_inst_tac [("zs","[]")] append_same_eq 1);
   178 by Auto_tac;
   179 qed "append_self_conv2";
   180 
   181 Goal "(ys = xs @ ys) = (xs=[])";
   182 by (simp_tac (simpset() addsimps
   183      [simplify (simpset()) (read_instantiate[("ys","[]")]append_same_eq)]) 1);
   184 by (Blast_tac 1);
   185 qed "self_append_conv2";
   186 AddIffs [append_self_conv2,self_append_conv2];
   187 
   188 Goal "xs ~= [] --> hd xs # tl xs = xs";
   189 by (induct_tac "xs" 1);
   190 by Auto_tac;
   191 qed_spec_mp "hd_Cons_tl";
   192 Addsimps [hd_Cons_tl];
   193 
   194 Goal "hd(xs@ys) = (if xs=[] then hd ys else hd xs)";
   195 by (induct_tac "xs" 1);
   196 by Auto_tac;
   197 qed "hd_append";
   198 
   199 Goal "xs ~= [] ==> hd(xs @ ys) = hd xs";
   200 by (asm_simp_tac (simpset() addsimps [hd_append]
   201                            addsplits [list.split]) 1);
   202 qed "hd_append2";
   203 Addsimps [hd_append2];
   204 
   205 Goal "tl(xs@ys) = (case xs of [] => tl(ys) | z#zs => zs@ys)";
   206 by (simp_tac (simpset() addsplits [list.split]) 1);
   207 qed "tl_append";
   208 
   209 Goal "xs ~= [] ==> tl(xs @ ys) = (tl xs) @ ys";
   210 by (asm_simp_tac (simpset() addsimps [tl_append]
   211                            addsplits [list.split]) 1);
   212 qed "tl_append2";
   213 Addsimps [tl_append2];
   214 
   215 (* trivial rules for solving @-equations automatically *)
   216 
   217 Goal "xs = ys ==> xs = [] @ ys";
   218 by (Asm_simp_tac 1);
   219 qed "eq_Nil_appendI";
   220 
   221 Goal "[| x#xs1 = ys; xs = xs1 @ zs |] ==> x#xs = ys@zs";
   222 by (dtac sym 1);
   223 by (Asm_simp_tac 1);
   224 qed "Cons_eq_appendI";
   225 
   226 Goal "[| xs@xs1 = zs; ys = xs1 @ us |] ==> xs@ys = zs@us";
   227 by (dtac sym 1);
   228 by (Asm_simp_tac 1);
   229 qed "append_eq_appendI";
   230 
   231 
   232 (***
   233 Simplification procedure for all list equalities.
   234 Currently only tries to rearranges @ to see if
   235 - both lists end in a singleton list,
   236 - or both lists end in the same list.
   237 ***)
   238 local
   239 
   240 val list_eq_pattern =
   241   Thm.read_cterm (Theory.sign_of (the_context ())) ("(xs::'a list) = ys",HOLogic.boolT);
   242 
   243 fun last (cons as Const("List.list.Cons",_) $ _ $ xs) =
   244       (case xs of Const("List.list.Nil",_) => cons | _ => last xs)
   245   | last (Const("List.op @",_) $ _ $ ys) = last ys
   246   | last t = t;
   247 
   248 fun list1 (Const("List.list.Cons",_) $ _ $ Const("List.list.Nil",_)) = true
   249   | list1 _ = false;
   250 
   251 fun butlast ((cons as Const("List.list.Cons",_) $ x) $ xs) =
   252       (case xs of Const("List.list.Nil",_) => xs | _ => cons $ butlast xs)
   253   | butlast ((app as Const("List.op @",_) $ xs) $ ys) = app $ butlast ys
   254   | butlast xs = Const("List.list.Nil",fastype_of xs);
   255 
   256 val rearr_tac =
   257   simp_tac (HOL_basic_ss addsimps [append_assoc,append_Nil,append_Cons]);
   258 
   259 fun list_eq sg _ (F as (eq as Const(_,eqT)) $ lhs $ rhs) =
   260   let
   261     val lastl = last lhs and lastr = last rhs
   262     fun rearr conv =
   263       let val lhs1 = butlast lhs and rhs1 = butlast rhs
   264           val Type(_,listT::_) = eqT
   265           val appT = [listT,listT] ---> listT
   266           val app = Const("List.op @",appT)
   267           val F2 = eq $ (app$lhs1$lastl) $ (app$rhs1$lastr)
   268           val ct = cterm_of sg (HOLogic.mk_Trueprop(HOLogic.mk_eq(F,F2)))
   269           val thm = prove_goalw_cterm [] ct (K [rearr_tac 1])
   270             handle ERROR =>
   271             error("The error(s) above occurred while trying to prove " ^
   272                   string_of_cterm ct)
   273       in Some((conv RS (thm RS trans)) RS eq_reflection) end
   274 
   275   in if list1 lastl andalso list1 lastr
   276      then rearr append1_eq_conv
   277      else
   278      if lastl aconv lastr
   279      then rearr append_same_eq
   280      else None
   281   end;
   282 in
   283 val list_eq_simproc = mk_simproc "list_eq" [list_eq_pattern] list_eq;
   284 end;
   285 
   286 Addsimprocs [list_eq_simproc];
   287 
   288 
   289 (** map **)
   290 
   291 section "map";
   292 
   293 Goal "(!x. x : set xs --> f x = g x) --> map f xs = map g xs";
   294 by (induct_tac "xs" 1);
   295 by Auto_tac;
   296 bind_thm("map_ext", impI RS (allI RS (result() RS mp)));
   297 
   298 Goal "map (%x. x) = (%xs. xs)";
   299 by (rtac ext 1);
   300 by (induct_tac "xs" 1);
   301 by Auto_tac;
   302 qed "map_ident";
   303 Addsimps[map_ident];
   304 
   305 Goal "map f (xs@ys) = map f xs @ map f ys";
   306 by (induct_tac "xs" 1);
   307 by Auto_tac;
   308 qed "map_append";
   309 Addsimps[map_append];
   310 
   311 Goalw [o_def] "map (f o g) xs = map f (map g xs)";
   312 by (induct_tac "xs" 1);
   313 by Auto_tac;
   314 qed "map_compose";
   315 (*Addsimps[map_compose];*)
   316 
   317 Goal "rev(map f xs) = map f (rev xs)";
   318 by (induct_tac "xs" 1);
   319 by Auto_tac;
   320 qed "rev_map";
   321 
   322 (* a congruence rule for map: *)
   323 Goal "xs=ys ==> (!x. x : set ys --> f x = g x) --> map f xs = map g ys";
   324 by (hyp_subst_tac 1);
   325 by (induct_tac "ys" 1);
   326 by Auto_tac;
   327 bind_thm("map_cong", impI RSN (2,allI RSN (2, result() RS mp)));
   328 
   329 Goal "(map f xs = []) = (xs = [])";
   330 by (case_tac "xs" 1);
   331 by Auto_tac;
   332 qed "map_is_Nil_conv";
   333 AddIffs [map_is_Nil_conv];
   334 
   335 Goal "([] = map f xs) = (xs = [])";
   336 by (case_tac "xs" 1);
   337 by Auto_tac;
   338 qed "Nil_is_map_conv";
   339 AddIffs [Nil_is_map_conv];
   340 
   341 Goal "(map f xs = y#ys) = (? x xs'. xs = x#xs' & f x = y & map f xs' = ys)";
   342 by (case_tac "xs" 1);
   343 by (ALLGOALS Asm_simp_tac);
   344 qed "map_eq_Cons";
   345 
   346 Goal "!xs. map f xs = map f ys --> (!x y. f x = f y --> x=y) --> xs=ys";
   347 by (induct_tac "ys" 1);
   348  by (Asm_simp_tac 1);
   349 by (fast_tac (claset() addss (simpset() addsimps [map_eq_Cons])) 1);
   350 qed_spec_mp "map_injective";
   351 
   352 Goal "inj f ==> inj (map f)";
   353 by (blast_tac (claset() addDs [map_injective,injD] addIs [injI]) 1);
   354 qed "inj_mapI";
   355 
   356 Goalw [inj_on_def] "inj (map f) ==> inj f";
   357 by (Clarify_tac 1);
   358 by (eres_inst_tac [("x","[x]")] ballE 1);
   359  by (eres_inst_tac [("x","[y]")] ballE 1);
   360   by (Asm_full_simp_tac 1);
   361  by (Blast_tac 1);
   362 by (Blast_tac 1);
   363 qed "inj_mapD";
   364 
   365 Goal "inj (map f) = inj f";
   366 by (blast_tac (claset() addDs [inj_mapD] addIs [inj_mapI]) 1);
   367 qed "inj_map";
   368 
   369 (** rev **)
   370 
   371 section "rev";
   372 
   373 Goal "rev(xs@ys) = rev(ys) @ rev(xs)";
   374 by (induct_tac "xs" 1);
   375 by Auto_tac;
   376 qed "rev_append";
   377 Addsimps[rev_append];
   378 
   379 Goal "rev(rev l) = l";
   380 by (induct_tac "l" 1);
   381 by Auto_tac;
   382 qed "rev_rev_ident";
   383 Addsimps[rev_rev_ident];
   384 
   385 Goal "(rev xs = []) = (xs = [])";
   386 by (induct_tac "xs" 1);
   387 by Auto_tac;
   388 qed "rev_is_Nil_conv";
   389 AddIffs [rev_is_Nil_conv];
   390 
   391 Goal "([] = rev xs) = (xs = [])";
   392 by (induct_tac "xs" 1);
   393 by Auto_tac;
   394 qed "Nil_is_rev_conv";
   395 AddIffs [Nil_is_rev_conv];
   396 
   397 Goal "!ys. (rev xs = rev ys) = (xs = ys)";
   398 by (induct_tac "xs" 1);
   399  by (Force_tac 1);
   400 by (rtac allI 1);
   401 by (case_tac "ys" 1);
   402  by (Asm_simp_tac 1);
   403 by (Force_tac 1);
   404 qed_spec_mp "rev_is_rev_conv";
   405 AddIffs [rev_is_rev_conv];
   406 
   407 val prems = Goal "[| P []; !!x xs. P xs ==> P(xs@[x]) |] ==> P xs";
   408 by (stac (rev_rev_ident RS sym) 1);
   409 by (res_inst_tac [("list", "rev xs")] list.induct 1);
   410 by (ALLGOALS Simp_tac);
   411 by (resolve_tac prems 1);
   412 by (eresolve_tac prems 1);
   413 qed "rev_induct";
   414 
   415 val rev_induct_tac = induct_thm_tac rev_induct;
   416 
   417 Goal  "(xs = [] --> P) -->  (!ys y. xs = ys@[y] --> P) --> P";
   418 by (rev_induct_tac "xs" 1);
   419 by Auto_tac;
   420 qed "rev_exhaust_aux";
   421 
   422 bind_thm ("rev_exhaust", Rulify.rulify rev_exhaust_aux);
   423 
   424 
   425 (** set **)
   426 
   427 section "set";
   428 
   429 Goal "finite (set xs)";
   430 by (induct_tac "xs" 1);
   431 by Auto_tac;
   432 qed "finite_set";
   433 AddIffs [finite_set];
   434 
   435 Goal "set (xs@ys) = (set xs Un set ys)";
   436 by (induct_tac "xs" 1);
   437 by Auto_tac;
   438 qed "set_append";
   439 Addsimps[set_append];
   440 
   441 Goal "set l <= set (x#l)";
   442 by Auto_tac;
   443 qed "set_subset_Cons";
   444 
   445 Goal "(set xs = {}) = (xs = [])";
   446 by (induct_tac "xs" 1);
   447 by Auto_tac;
   448 qed "set_empty";
   449 Addsimps [set_empty];
   450 
   451 Goal "set(rev xs) = set(xs)";
   452 by (induct_tac "xs" 1);
   453 by Auto_tac;
   454 qed "set_rev";
   455 Addsimps [set_rev];
   456 
   457 Goal "set(map f xs) = f``(set xs)";
   458 by (induct_tac "xs" 1);
   459 by Auto_tac;
   460 qed "set_map";
   461 Addsimps [set_map];
   462 
   463 Goal "set(filter P xs) = {x. x : set xs & P x}";
   464 by (induct_tac "xs" 1);
   465 by Auto_tac;
   466 qed "set_filter";
   467 Addsimps [set_filter];
   468 
   469 Goal "set[i..j(] = {k. i <= k & k < j}";
   470 by (induct_tac "j" 1);
   471 by (ALLGOALS Asm_simp_tac);
   472 by (etac ssubst 1);
   473 by Auto_tac;
   474 by (arith_tac 1);
   475 qed "set_upt";
   476 Addsimps [set_upt];
   477 
   478 Goal "(x : set xs) = (? ys zs. xs = ys@x#zs)";
   479 by (induct_tac "xs" 1);
   480  by (Simp_tac 1);
   481 by (Asm_simp_tac 1);
   482 by (rtac iffI 1);
   483 by (blast_tac (claset() addIs [eq_Nil_appendI,Cons_eq_appendI]) 1);
   484 by (REPEAT(etac exE 1));
   485 by (case_tac "ys" 1);
   486 by Auto_tac;
   487 qed "in_set_conv_decomp";
   488 
   489 
   490 (* eliminate `lists' in favour of `set' *)
   491 
   492 Goal "(xs : lists A) = (!x : set xs. x : A)";
   493 by (induct_tac "xs" 1);
   494 by Auto_tac;
   495 qed "in_lists_conv_set";
   496 
   497 bind_thm("in_listsD",in_lists_conv_set RS iffD1);
   498 AddSDs [in_listsD];
   499 bind_thm("in_listsI",in_lists_conv_set RS iffD2);
   500 AddSIs [in_listsI];
   501 
   502 (** mem **)
   503  
   504 section "mem";
   505 
   506 Goal "(x mem xs) = (x: set xs)";
   507 by (induct_tac "xs" 1);
   508 by Auto_tac;
   509 qed "set_mem_eq";
   510 
   511 
   512 (** list_all **)
   513 
   514 section "list_all";
   515 
   516 Goal "list_all P xs = (!x:set xs. P x)";
   517 by (induct_tac "xs" 1);
   518 by Auto_tac;
   519 qed "list_all_conv";
   520 
   521 Goal "list_all P (xs@ys) = (list_all P xs & list_all P ys)";
   522 by (induct_tac "xs" 1);
   523 by Auto_tac;
   524 qed "list_all_append";
   525 Addsimps [list_all_append];
   526 
   527 
   528 (** filter **)
   529 
   530 section "filter";
   531 
   532 Goal "filter P (xs@ys) = filter P xs @ filter P ys";
   533 by (induct_tac "xs" 1);
   534 by Auto_tac;
   535 qed "filter_append";
   536 Addsimps [filter_append];
   537 
   538 Goal "filter (%x. True) xs = xs";
   539 by (induct_tac "xs" 1);
   540 by Auto_tac;
   541 qed "filter_True";
   542 Addsimps [filter_True];
   543 
   544 Goal "filter (%x. False) xs = []";
   545 by (induct_tac "xs" 1);
   546 by Auto_tac;
   547 qed "filter_False";
   548 Addsimps [filter_False];
   549 
   550 Goal "length (filter P xs) <= length xs";
   551 by (induct_tac "xs" 1);
   552 by Auto_tac;
   553 by (asm_simp_tac (simpset() addsimps [le_SucI]) 1);
   554 qed "length_filter";
   555 Addsimps[length_filter];
   556 
   557 Goal "set (filter P xs) <= set xs";
   558 by Auto_tac;
   559 qed "filter_is_subset";
   560 Addsimps [filter_is_subset];
   561 
   562 
   563 section "concat";
   564 
   565 Goal  "concat(xs@ys) = concat(xs)@concat(ys)";
   566 by (induct_tac "xs" 1);
   567 by Auto_tac;
   568 qed"concat_append";
   569 Addsimps [concat_append];
   570 
   571 Goal "(concat xss = []) = (!xs:set xss. xs=[])";
   572 by (induct_tac "xss" 1);
   573 by Auto_tac;
   574 qed "concat_eq_Nil_conv";
   575 AddIffs [concat_eq_Nil_conv];
   576 
   577 Goal "([] = concat xss) = (!xs:set xss. xs=[])";
   578 by (induct_tac "xss" 1);
   579 by Auto_tac;
   580 qed "Nil_eq_concat_conv";
   581 AddIffs [Nil_eq_concat_conv];
   582 
   583 Goal  "set(concat xs) = Union(set `` set xs)";
   584 by (induct_tac "xs" 1);
   585 by Auto_tac;
   586 qed"set_concat";
   587 Addsimps [set_concat];
   588 
   589 Goal "map f (concat xs) = concat (map (map f) xs)"; 
   590 by (induct_tac "xs" 1);
   591 by Auto_tac;
   592 qed "map_concat";
   593 
   594 Goal "filter p (concat xs) = concat (map (filter p) xs)"; 
   595 by (induct_tac "xs" 1);
   596 by Auto_tac;
   597 qed"filter_concat"; 
   598 
   599 Goal "rev(concat xs) = concat (map rev (rev xs))";
   600 by (induct_tac "xs" 1);
   601 by Auto_tac;
   602 qed "rev_concat";
   603 
   604 (** nth **)
   605 
   606 section "nth";
   607 
   608 Goal "(x#xs)!0 = x";
   609 by Auto_tac;
   610 qed "nth_Cons_0";
   611 Addsimps [nth_Cons_0];
   612 
   613 Goal "(x#xs)!(Suc n) = xs!n";
   614 by Auto_tac;
   615 qed "nth_Cons_Suc";
   616 Addsimps [nth_Cons_Suc];
   617 
   618 Delsimps (thms "nth.simps");
   619 
   620 Goal "!n. (xs@ys)!n = (if n < length xs then xs!n else ys!(n - length xs))";
   621 by (induct_tac "xs" 1);
   622  by (Asm_simp_tac 1);
   623  by (rtac allI 1);
   624  by (case_tac "n" 1);
   625   by Auto_tac;
   626 qed_spec_mp "nth_append";
   627 
   628 Goal "!n. n < length xs --> (map f xs)!n = f(xs!n)";
   629 by (induct_tac "xs" 1);
   630  by (Asm_full_simp_tac 1);
   631 by (rtac allI 1);
   632 by (induct_tac "n" 1);
   633 by Auto_tac;
   634 qed_spec_mp "nth_map";
   635 Addsimps [nth_map];
   636 
   637 Goal "set xs = {xs!i |i. i < length xs}";
   638 by (induct_tac "xs" 1);
   639  by (Simp_tac 1);
   640 by (Asm_simp_tac 1);
   641 by Safe_tac;
   642   by (res_inst_tac [("x","0")] exI 1);
   643   by (Simp_tac 1);
   644  by (res_inst_tac [("x","Suc i")] exI 1);
   645  by (Asm_simp_tac 1);
   646 by (case_tac "i" 1);
   647  by (Asm_full_simp_tac 1);
   648 by (rename_tac "j" 1);
   649  by (res_inst_tac [("x","j")] exI 1);
   650 by (Asm_simp_tac 1);
   651 qed "set_conv_nth";
   652 
   653 Goal "n < length xs ==> Ball (set xs) P --> P(xs!n)";
   654 by (simp_tac (simpset() addsimps [set_conv_nth]) 1);
   655 by (Blast_tac 1);
   656 qed_spec_mp "list_ball_nth";
   657 
   658 Goal "n < length xs ==> xs!n : set xs";
   659 by (simp_tac (simpset() addsimps [set_conv_nth]) 1);
   660 by (Blast_tac 1);
   661 qed_spec_mp "nth_mem";
   662 Addsimps [nth_mem];
   663 
   664 Goal "(!i. i < length xs --> P(xs!i)) --> (!x : set xs. P x)";
   665 by (simp_tac (simpset() addsimps [set_conv_nth]) 1);
   666 by (Blast_tac 1);
   667 qed_spec_mp "all_nth_imp_all_set";
   668 
   669 Goal "(!x : set xs. P x) = (!i. i<length xs --> P (xs ! i))";
   670 by (simp_tac (simpset() addsimps [set_conv_nth]) 1);
   671 by (Blast_tac 1);
   672 qed_spec_mp "all_set_conv_all_nth";
   673 
   674 
   675 (** list update **)
   676 
   677 section "list update";
   678 
   679 Goal "!i. length(xs[i:=x]) = length xs";
   680 by (induct_tac "xs" 1);
   681 by (Simp_tac 1);
   682 by (asm_full_simp_tac (simpset() addsplits [nat.split]) 1);
   683 qed_spec_mp "length_list_update";
   684 Addsimps [length_list_update];
   685 
   686 Goal "!i j. i < length xs  --> (xs[i:=x])!j = (if i=j then x else xs!j)";
   687 by (induct_tac "xs" 1);
   688  by (Simp_tac 1);
   689 by (auto_tac (claset(), simpset() addsimps [nth_Cons] addsplits [nat.split]));
   690 qed_spec_mp "nth_list_update";
   691 
   692 Goal "i < length xs  ==> (xs[i:=x])!i = x";
   693 by (asm_simp_tac (simpset() addsimps [nth_list_update]) 1);
   694 qed "nth_list_update_eq";
   695 Addsimps [nth_list_update_eq];
   696 
   697 Goal "!i j. i ~= j --> xs[i:=x]!j = xs!j";
   698 by (induct_tac "xs" 1);
   699  by (Simp_tac 1);
   700 by (auto_tac (claset(), simpset() addsimps [nth_Cons] addsplits [nat.split]));
   701 qed_spec_mp "nth_list_update_neq";
   702 Addsimps [nth_list_update_neq];
   703 
   704 Goal "!i. i < size xs --> xs[i:=x, i:=y] = xs[i:=y]";
   705 by (induct_tac "xs" 1);
   706  by (Simp_tac 1);
   707 by (asm_simp_tac (simpset() addsplits [nat.split]) 1);
   708 qed_spec_mp "list_update_overwrite";
   709 Addsimps [list_update_overwrite];
   710 
   711 Goal "!i < length xs. (xs[i := x] = xs) = (xs!i = x)";
   712 by (induct_tac "xs" 1);
   713  by (Simp_tac 1);
   714 by (simp_tac (simpset() addsplits [nat.split]) 1);
   715 by (Blast_tac 1);
   716 qed_spec_mp "list_update_same_conv";
   717 
   718 Goal "!i xy xs. length xs = length ys --> \
   719 \     (zip xs ys)[i:=xy] = zip (xs[i:=fst xy]) (ys[i:=snd xy])";
   720 by (induct_tac "ys" 1);
   721  by Auto_tac;
   722 by (case_tac "xs" 1);
   723  by (auto_tac (claset(), simpset() addsplits [nat.split]));
   724 qed_spec_mp "update_zip";
   725 
   726 Goal "!i. set(xs[i:=x]) <= insert x (set xs)";
   727 by (induct_tac "xs" 1);
   728  by (asm_full_simp_tac (simpset() addsimps []) 1);
   729 by (asm_full_simp_tac (simpset() addsplits [nat.split]) 1);
   730 by (Fast_tac  1);
   731 qed_spec_mp "set_update_subset_insert";
   732 
   733 Goal "[| set xs <= A; x:A |] ==> set(xs[i := x]) <= A";
   734 by(fast_tac (claset() addSDs [set_update_subset_insert RS subsetD]) 1);
   735 qed "set_update_subsetI";
   736 
   737 (** last & butlast **)
   738 
   739 section "last / butlast";
   740 
   741 Goal "last(xs@[x]) = x";
   742 by (induct_tac "xs" 1);
   743 by Auto_tac;
   744 qed "last_snoc";
   745 Addsimps [last_snoc];
   746 
   747 Goal "butlast(xs@[x]) = xs";
   748 by (induct_tac "xs" 1);
   749 by Auto_tac;
   750 qed "butlast_snoc";
   751 Addsimps [butlast_snoc];
   752 
   753 Goal "length(butlast xs) = length xs - 1";
   754 by (rev_induct_tac "xs" 1);
   755 by Auto_tac;
   756 qed "length_butlast";
   757 Addsimps [length_butlast];
   758 
   759 Goal "!ys. butlast (xs@ys) = (if ys=[] then butlast xs else xs@butlast ys)";
   760 by (induct_tac "xs" 1);
   761 by Auto_tac;
   762 qed_spec_mp "butlast_append";
   763 
   764 Goal "xs ~= [] --> butlast xs @ [last xs] = xs";
   765 by (induct_tac "xs" 1);
   766 by (ALLGOALS Asm_simp_tac);
   767 qed_spec_mp "append_butlast_last_id";
   768 Addsimps [append_butlast_last_id];
   769 
   770 Goal "x:set(butlast xs) --> x:set xs";
   771 by (induct_tac "xs" 1);
   772 by Auto_tac;
   773 qed_spec_mp "in_set_butlastD";
   774 
   775 Goal "x:set(butlast xs) | x:set(butlast ys) ==> x:set(butlast(xs@ys))";
   776 by (auto_tac (claset() addDs [in_set_butlastD],
   777 	      simpset() addsimps [butlast_append]));
   778 qed "in_set_butlast_appendI";
   779 
   780 (** take  & drop **)
   781 section "take & drop";
   782 
   783 Goal "take 0 xs = []";
   784 by (induct_tac "xs" 1);
   785 by Auto_tac;
   786 qed "take_0";
   787 
   788 Goal "drop 0 xs = xs";
   789 by (induct_tac "xs" 1);
   790 by Auto_tac;
   791 qed "drop_0";
   792 
   793 Goal "take (Suc n) (x#xs) = x # take n xs";
   794 by (Simp_tac 1);
   795 qed "take_Suc_Cons";
   796 
   797 Goal "drop (Suc n) (x#xs) = drop n xs";
   798 by (Simp_tac 1);
   799 qed "drop_Suc_Cons";
   800 
   801 Delsimps [take_Cons,drop_Cons];
   802 Addsimps [take_0,take_Suc_Cons,drop_0,drop_Suc_Cons];
   803 
   804 Goal "!xs. length(take n xs) = min (length xs) n";
   805 by (induct_tac "n" 1);
   806  by Auto_tac;
   807 by (case_tac "xs" 1);
   808  by Auto_tac;
   809 qed_spec_mp "length_take";
   810 Addsimps [length_take];
   811 
   812 Goal "!xs. length(drop n xs) = (length xs - n)";
   813 by (induct_tac "n" 1);
   814  by Auto_tac;
   815 by (case_tac "xs" 1);
   816  by Auto_tac;
   817 qed_spec_mp "length_drop";
   818 Addsimps [length_drop];
   819 
   820 Goal "!xs. length xs <= n --> take n xs = xs";
   821 by (induct_tac "n" 1);
   822  by Auto_tac;
   823 by (case_tac "xs" 1);
   824  by Auto_tac;
   825 qed_spec_mp "take_all";
   826 Addsimps [take_all];
   827 
   828 Goal "!xs. length xs <= n --> drop n xs = []";
   829 by (induct_tac "n" 1);
   830  by Auto_tac;
   831 by (case_tac "xs" 1);
   832  by Auto_tac;
   833 qed_spec_mp "drop_all";
   834 Addsimps [drop_all];
   835 
   836 Goal "!xs. take n (xs @ ys) = (take n xs @ take (n - length xs) ys)";
   837 by (induct_tac "n" 1);
   838  by Auto_tac;
   839 by (case_tac "xs" 1);
   840  by Auto_tac;
   841 qed_spec_mp "take_append";
   842 Addsimps [take_append];
   843 
   844 Goal "!xs. drop n (xs@ys) = drop n xs @ drop (n - length xs) ys"; 
   845 by (induct_tac "n" 1);
   846  by Auto_tac;
   847 by (case_tac "xs" 1);
   848  by Auto_tac;
   849 qed_spec_mp "drop_append";
   850 Addsimps [drop_append];
   851 
   852 Goal "!xs n. take n (take m xs) = take (min n m) xs"; 
   853 by (induct_tac "m" 1);
   854  by Auto_tac;
   855 by (case_tac "xs" 1);
   856  by Auto_tac;
   857 by (case_tac "na" 1);
   858  by Auto_tac;
   859 qed_spec_mp "take_take";
   860 Addsimps [take_take];
   861 
   862 Goal "!xs. drop n (drop m xs) = drop (n + m) xs"; 
   863 by (induct_tac "m" 1);
   864  by Auto_tac;
   865 by (case_tac "xs" 1);
   866  by Auto_tac;
   867 qed_spec_mp "drop_drop";
   868 Addsimps [drop_drop];
   869 
   870 Goal "!xs n. take n (drop m xs) = drop m (take (n + m) xs)"; 
   871 by (induct_tac "m" 1);
   872  by Auto_tac;
   873 by (case_tac "xs" 1);
   874  by Auto_tac;
   875 qed_spec_mp "take_drop";
   876 
   877 Goal "!xs. take n xs @ drop n xs = xs";
   878 by (induct_tac "n" 1);
   879  by Auto_tac;
   880 by (case_tac "xs" 1);
   881  by Auto_tac;
   882 qed_spec_mp "append_take_drop_id";
   883 Addsimps [append_take_drop_id];
   884 
   885 Goal "!xs. take n (map f xs) = map f (take n xs)"; 
   886 by (induct_tac "n" 1);
   887  by Auto_tac;
   888 by (case_tac "xs" 1);
   889  by Auto_tac;
   890 qed_spec_mp "take_map"; 
   891 
   892 Goal "!xs. drop n (map f xs) = map f (drop n xs)"; 
   893 by (induct_tac "n" 1);
   894  by Auto_tac;
   895 by (case_tac "xs" 1);
   896  by Auto_tac;
   897 qed_spec_mp "drop_map";
   898 
   899 Goal "!n i. i < n --> (take n xs)!i = xs!i";
   900 by (induct_tac "xs" 1);
   901  by Auto_tac;
   902 by (case_tac "n" 1);
   903  by (Blast_tac 1);
   904 by (case_tac "i" 1);
   905  by Auto_tac;
   906 qed_spec_mp "nth_take";
   907 Addsimps [nth_take];
   908 
   909 Goal  "!xs i. n + i <= length xs --> (drop n xs)!i = xs!(n+i)";
   910 by (induct_tac "n" 1);
   911  by Auto_tac;
   912 by (case_tac "xs" 1);
   913  by Auto_tac;
   914 qed_spec_mp "nth_drop";
   915 Addsimps [nth_drop];
   916 
   917 
   918 Goal
   919  "!zs. (xs@ys = zs) = (xs = take (length xs) zs & ys = drop (length xs) zs)";
   920 by (induct_tac "xs" 1);
   921  by (Simp_tac 1);
   922 by (Asm_full_simp_tac 1);
   923 by (Clarify_tac 1);
   924 by (case_tac "zs" 1);
   925 by (Auto_tac);
   926 qed_spec_mp "append_eq_conv_conj";
   927 
   928 (** takeWhile & dropWhile **)
   929 
   930 section "takeWhile & dropWhile";
   931 
   932 Goal "takeWhile P xs @ dropWhile P xs = xs";
   933 by (induct_tac "xs" 1);
   934 by Auto_tac;
   935 qed "takeWhile_dropWhile_id";
   936 Addsimps [takeWhile_dropWhile_id];
   937 
   938 Goal  "x:set xs & ~P(x) --> takeWhile P (xs @ ys) = takeWhile P xs";
   939 by (induct_tac "xs" 1);
   940 by Auto_tac;
   941 bind_thm("takeWhile_append1", conjI RS (result() RS mp));
   942 Addsimps [takeWhile_append1];
   943 
   944 Goal "(!x:set xs. P(x)) --> takeWhile P (xs @ ys) = xs @ takeWhile P ys";
   945 by (induct_tac "xs" 1);
   946 by Auto_tac;
   947 bind_thm("takeWhile_append2", ballI RS (result() RS mp));
   948 Addsimps [takeWhile_append2];
   949 
   950 Goal "x:set xs & ~P(x) --> dropWhile P (xs @ ys) = (dropWhile P xs)@ys";
   951 by (induct_tac "xs" 1);
   952 by Auto_tac;
   953 bind_thm("dropWhile_append1", conjI RS (result() RS mp));
   954 Addsimps [dropWhile_append1];
   955 
   956 Goal "(!x:set xs. P(x)) --> dropWhile P (xs @ ys) = dropWhile P ys";
   957 by (induct_tac "xs" 1);
   958 by Auto_tac;
   959 bind_thm("dropWhile_append2", ballI RS (result() RS mp));
   960 Addsimps [dropWhile_append2];
   961 
   962 Goal "x:set(takeWhile P xs) --> x:set xs & P x";
   963 by (induct_tac "xs" 1);
   964 by Auto_tac;
   965 qed_spec_mp"set_take_whileD";
   966 
   967 (** zip **)
   968 section "zip";
   969 
   970 Goal "zip [] ys = []";
   971 by (induct_tac "ys" 1);
   972 by Auto_tac;
   973 qed "zip_Nil";
   974 Addsimps [zip_Nil];
   975 
   976 Goal "zip (x#xs) (y#ys) = (x,y)#zip xs ys";
   977 by (Simp_tac 1);
   978 qed "zip_Cons_Cons";
   979 Addsimps [zip_Cons_Cons];
   980 
   981 Delsimps(tl (thms"zip.simps"));
   982 
   983 Goal "!xs. length (zip xs ys) = min (length xs) (length ys)";
   984 by (induct_tac "ys" 1);
   985  by (Simp_tac 1);
   986 by (Clarify_tac 1);
   987 by (case_tac "xs" 1);
   988  by (Auto_tac);
   989 qed_spec_mp "length_zip";
   990 Addsimps [length_zip];
   991 
   992 Goal
   993  "!xs. zip (xs@ys) zs = \
   994 \      zip xs (take (length xs) zs) @ zip ys (drop (length xs) zs)";
   995 by (induct_tac "zs" 1);
   996  by (Simp_tac 1);
   997 by (Clarify_tac 1);
   998 by (case_tac "xs" 1);
   999  by (Asm_simp_tac 1);
  1000 by (Asm_simp_tac 1);
  1001 qed_spec_mp "zip_append1";
  1002 
  1003 Goal
  1004  "!ys. zip xs (ys@zs) = \
  1005 \      zip (take (length ys) xs) ys @ zip (drop (length ys) xs) zs";
  1006 by (induct_tac "xs" 1);
  1007  by (Simp_tac 1);
  1008 by (Clarify_tac 1);
  1009 by (case_tac "ys" 1);
  1010  by (Asm_simp_tac 1);
  1011 by (Asm_simp_tac 1);
  1012 qed_spec_mp "zip_append2";
  1013 
  1014 Goal
  1015  "[| length xs = length us; length ys = length vs |] ==> \
  1016 \ zip (xs@ys) (us@vs) = zip xs us @ zip ys vs";
  1017 by (asm_simp_tac (simpset() addsimps [zip_append1]) 1);
  1018 qed_spec_mp "zip_append";
  1019 Addsimps [zip_append];
  1020 
  1021 Goal "!xs. length xs = length ys --> zip (rev xs) (rev ys) = rev (zip xs ys)";
  1022 by (induct_tac "ys" 1);
  1023  by (Asm_full_simp_tac 1);
  1024 by (Asm_full_simp_tac 1);
  1025 by (Clarify_tac 1);
  1026 by (case_tac "xs" 1);
  1027  by (Auto_tac);
  1028 qed_spec_mp "zip_rev";
  1029 
  1030 
  1031 Goal
  1032 "!i xs. i < length xs --> i < length ys --> (zip xs ys)!i = (xs!i, ys!i)";
  1033 by (induct_tac "ys" 1);
  1034  by (Simp_tac 1);
  1035 by (Clarify_tac 1);
  1036 by (case_tac "xs" 1);
  1037  by (Auto_tac);
  1038 by (asm_full_simp_tac (simpset() addsimps (thms"nth.simps") addsplits [nat.split]) 1);
  1039 qed_spec_mp "nth_zip";
  1040 Addsimps [nth_zip];
  1041 
  1042 Goal "set(zip xs ys) = {(xs!i,ys!i) |i. i < min (length xs) (length ys)}";
  1043 by (simp_tac (simpset() addsimps [set_conv_nth]addcongs [rev_conj_cong]) 1);
  1044 qed_spec_mp "set_zip";
  1045 
  1046 Goal
  1047  "length xs = length ys ==> zip (xs[i:=x]) (ys[i:=y]) = (zip xs ys)[i:=(x,y)]";
  1048 by (rtac sym 1);
  1049 by (asm_simp_tac (simpset() addsimps [update_zip]) 1);
  1050 qed_spec_mp "zip_update";
  1051 
  1052 Goal "!j. zip (replicate i x) (replicate j y) = replicate (min i j) (x,y)";
  1053 by (induct_tac "i" 1);
  1054  by (Auto_tac);
  1055 by (case_tac "j" 1);
  1056  by (Auto_tac);
  1057 qed "zip_replicate";
  1058 Addsimps [zip_replicate];
  1059 
  1060 (** list_all2 **)
  1061 section "list_all2";
  1062 
  1063 Goalw [list_all2_def] "list_all2 P xs ys ==> length xs = length ys";
  1064 by (Asm_simp_tac 1);
  1065 qed "list_all2_lengthD";
  1066 
  1067 Goalw [list_all2_def] "list_all2 P [] ys = (ys=[])";
  1068 by (Simp_tac 1);
  1069 qed "list_all2_Nil";
  1070 AddIffs [list_all2_Nil];
  1071 
  1072 Goalw [list_all2_def] "list_all2 P xs [] = (xs=[])";
  1073 by (Simp_tac 1);
  1074 qed "list_all2_Nil2";
  1075 AddIffs [list_all2_Nil2];
  1076 
  1077 Goalw [list_all2_def]
  1078  "list_all2 P (x#xs) (y#ys) = (P x y & list_all2 P xs ys)";
  1079 by (Auto_tac);
  1080 qed "list_all2_Cons";
  1081 AddIffs[list_all2_Cons];
  1082 
  1083 Goalw [list_all2_def]
  1084  "list_all2 P (x#xs) ys = (? z zs. ys = z#zs & P x z & list_all2 P xs zs)";
  1085 by (case_tac "ys" 1);
  1086 by (Auto_tac);
  1087 qed "list_all2_Cons1";
  1088 
  1089 Goalw [list_all2_def]
  1090  "list_all2 P xs (y#ys) = (? z zs. xs = z#zs & P z y & list_all2 P zs ys)";
  1091 by (case_tac "xs" 1);
  1092 by (Auto_tac);
  1093 qed "list_all2_Cons2";
  1094 
  1095 Goalw [list_all2_def]
  1096  "list_all2 P (xs@ys) zs = \
  1097 \ (EX us vs. zs = us@vs & length us = length xs & length vs = length ys & \
  1098 \            list_all2 P xs us & list_all2 P ys vs)";
  1099 by (simp_tac (simpset() addsimps [zip_append1]) 1);
  1100 by (rtac iffI 1);
  1101  by (res_inst_tac [("x","take (length xs) zs")] exI 1);
  1102  by (res_inst_tac [("x","drop (length xs) zs")] exI 1);
  1103  by (asm_full_simp_tac (simpset() addsimps [min_def,eq_sym_conv]) 1);
  1104 by (Clarify_tac 1);
  1105 by (asm_full_simp_tac (simpset() addsimps [ball_Un]) 1);
  1106 qed "list_all2_append1";
  1107 
  1108 Goalw [list_all2_def]
  1109  "list_all2 P xs (ys@zs) = \
  1110 \ (EX us vs. xs = us@vs & length us = length ys & length vs = length zs & \
  1111 \            list_all2 P us ys & list_all2 P vs zs)";
  1112 by (simp_tac (simpset() addsimps [zip_append2]) 1);
  1113 by (rtac iffI 1);
  1114  by (res_inst_tac [("x","take (length ys) xs")] exI 1);
  1115  by (res_inst_tac [("x","drop (length ys) xs")] exI 1);
  1116  by (asm_full_simp_tac (simpset() addsimps [min_def,eq_sym_conv]) 1);
  1117 by (Clarify_tac 1);
  1118 by (asm_full_simp_tac (simpset() addsimps [ball_Un]) 1);
  1119 qed "list_all2_append2";
  1120 
  1121 Goalw [list_all2_def]
  1122   "list_all2 P xs ys = \
  1123 \  (length xs = length ys & (!i<length xs. P (xs!i) (ys!i)))";
  1124 by (force_tac (claset(), simpset() addsimps [set_zip]) 1);
  1125 qed "list_all2_conv_all_nth";
  1126 
  1127 (** foldl **)
  1128 section "foldl";
  1129 
  1130 Goal "!a. foldl f a (xs @ ys) = foldl f (foldl f a xs) ys";
  1131 by (induct_tac "xs" 1);
  1132 by Auto_tac;
  1133 qed_spec_mp "foldl_append";
  1134 Addsimps [foldl_append];
  1135 
  1136 (* Note: `n <= foldl op+ n ns' looks simpler, but is more difficult to use
  1137    because it requires an additional transitivity step
  1138 *)
  1139 Goal "!n::nat. m <= n --> m <= foldl op+ n ns";
  1140 by (induct_tac "ns" 1);
  1141 by Auto_tac;
  1142 qed_spec_mp "start_le_sum";
  1143 
  1144 Goal "!!n::nat. n : set ns ==> n <= foldl op+ 0 ns";
  1145 by (force_tac (claset() addIs [start_le_sum],
  1146               simpset() addsimps [in_set_conv_decomp]) 1);
  1147 qed "elem_le_sum";
  1148 
  1149 Goal "!m::nat. (foldl op+ m ns = 0) = (m=0 & (!n : set ns. n=0))";
  1150 by (induct_tac "ns" 1);
  1151 by Auto_tac;
  1152 qed_spec_mp "sum_eq_0_conv";
  1153 AddIffs [sum_eq_0_conv];
  1154 
  1155 (** upto **)
  1156 
  1157 (* Does not terminate! *)
  1158 Goal "[i..j(] = (if i<j then i#[Suc i..j(] else [])";
  1159 by (induct_tac "j" 1);
  1160 by Auto_tac;
  1161 qed "upt_rec";
  1162 
  1163 Goal "j<=i ==> [i..j(] = []";
  1164 by (stac upt_rec 1);
  1165 by (Asm_simp_tac 1);
  1166 qed "upt_conv_Nil";
  1167 Addsimps [upt_conv_Nil];
  1168 
  1169 (*Only needed if upt_Suc is deleted from the simpset*)
  1170 Goal "i<=j ==> [i..(Suc j)(] = [i..j(]@[j]";
  1171 by (Asm_simp_tac 1);
  1172 qed "upt_Suc_append";
  1173 
  1174 Goal "i<j ==> [i..j(] = i#[Suc i..j(]";
  1175 by (rtac trans 1);
  1176 by (stac upt_rec 1);
  1177 by (rtac refl 2);
  1178 by (Asm_simp_tac 1);
  1179 qed "upt_conv_Cons";
  1180 
  1181 (*LOOPS as a simprule, since j<=j*)
  1182 Goal "i<=j ==> [i..j+k(] = [i..j(]@[j..j+k(]";
  1183 by (induct_tac "k" 1);
  1184 by Auto_tac;
  1185 qed "upt_add_eq_append";
  1186 
  1187 Goal "length [i..j(] = j-i";
  1188 by (induct_tac "j" 1);
  1189  by (Simp_tac 1);
  1190 by (asm_simp_tac (simpset() addsimps [Suc_diff_le]) 1);
  1191 qed "length_upt";
  1192 Addsimps [length_upt];
  1193 
  1194 Goal "i+k < j --> [i..j(] ! k = i+k";
  1195 by (induct_tac "j" 1);
  1196  by (asm_simp_tac (simpset() addsimps [less_Suc_eq, nth_append] 
  1197                              addsplits [nat_diff_split]) 2);
  1198 by (Simp_tac 1);
  1199 qed_spec_mp "nth_upt";
  1200 Addsimps [nth_upt];
  1201 
  1202 Goal "!i. i+m <= n --> take m [i..n(] = [i..i+m(]";
  1203 by (induct_tac "m" 1);
  1204  by (Simp_tac 1);
  1205 by (Clarify_tac 1);
  1206 by (stac upt_rec 1);
  1207 by (rtac sym 1);
  1208 by (stac upt_rec 1);
  1209 by (asm_simp_tac (simpset() delsimps (thms"upt.simps")) 1);
  1210 qed_spec_mp "take_upt";
  1211 Addsimps [take_upt];
  1212 
  1213 Goal "map Suc [m..n(] = [Suc m..n]";
  1214 by (induct_tac "n" 1);
  1215 by Auto_tac;
  1216 qed "map_Suc_upt";
  1217 
  1218 Goal "ALL i. i < n-m --> (map f [m..n(]) ! i = f(m+i)";
  1219 by (induct_thm_tac diff_induct "n m" 1);
  1220 by (stac (map_Suc_upt RS sym) 3);
  1221 by (auto_tac (claset(), simpset() addsimps [less_diff_conv, nth_upt]));
  1222 qed_spec_mp "nth_map_upt";
  1223 
  1224 Goal "ALL xs ys. k <= length xs --> k <= length ys -->  \
  1225 \        (ALL i. i < k --> xs!i = ys!i)  \
  1226 \     --> take k xs = take k ys";
  1227 by (induct_tac "k" 1);
  1228 by (ALLGOALS (asm_simp_tac (simpset() addsimps [less_Suc_eq_0_disj, 
  1229 						all_conj_distrib])));
  1230 by (Clarify_tac 1);
  1231 (*Both lists must be non-empty*)
  1232 by (case_tac "xs" 1);
  1233 by (case_tac "ys" 2);
  1234 by (ALLGOALS Clarify_tac);
  1235 (*prenexing's needed, not miniscoping*)
  1236 by (ALLGOALS (full_simp_tac (simpset() addsimps (all_simps RL [sym])  
  1237                                        delsimps (all_simps))));
  1238 by (Blast_tac 1);
  1239 qed_spec_mp "nth_take_lemma";
  1240 
  1241 Goal "[| length xs = length ys;  \
  1242 \        ALL i. i < length xs --> xs!i = ys!i |]  \
  1243 \     ==> xs = ys";
  1244 by (forward_tac [[le_refl, eq_imp_le] MRS nth_take_lemma] 1);
  1245 by (ALLGOALS (asm_full_simp_tac (simpset() addsimps [take_all])));
  1246 qed_spec_mp "nth_equalityI";
  1247 
  1248 (*The famous take-lemma*)
  1249 Goal "(ALL i. take i xs = take i ys) ==> xs = ys";
  1250 by (dres_inst_tac [("x", "max (length xs) (length ys)")] spec 1);
  1251 by (full_simp_tac (simpset() addsimps [le_max_iff_disj, take_all]) 1);
  1252 qed_spec_mp "take_equalityI";
  1253 
  1254 
  1255 (** nodups & remdups **)
  1256 section "nodups & remdups";
  1257 
  1258 Goal "set(remdups xs) = set xs";
  1259 by (induct_tac "xs" 1);
  1260  by (Simp_tac 1);
  1261 by (asm_full_simp_tac (simpset() addsimps [insert_absorb]) 1);
  1262 qed "set_remdups";
  1263 Addsimps [set_remdups];
  1264 
  1265 Goal "nodups(remdups xs)";
  1266 by (induct_tac "xs" 1);
  1267 by Auto_tac;
  1268 qed "nodups_remdups";
  1269 
  1270 Goal "nodups xs --> nodups (filter P xs)";
  1271 by (induct_tac "xs" 1);
  1272 by Auto_tac;
  1273 qed_spec_mp "nodups_filter";
  1274 
  1275 (** replicate **)
  1276 section "replicate";
  1277 
  1278 Goal "length(replicate n x) = n";
  1279 by (induct_tac "n" 1);
  1280 by Auto_tac;
  1281 qed "length_replicate";
  1282 Addsimps [length_replicate];
  1283 
  1284 Goal "map f (replicate n x) = replicate n (f x)";
  1285 by (induct_tac "n" 1);
  1286 by Auto_tac;
  1287 qed "map_replicate";
  1288 Addsimps [map_replicate];
  1289 
  1290 Goal "(replicate n x) @ (x#xs) = x # replicate n x @ xs";
  1291 by (induct_tac "n" 1);
  1292 by Auto_tac;
  1293 qed "replicate_app_Cons_same";
  1294 
  1295 Goal "rev(replicate n x) = replicate n x";
  1296 by (induct_tac "n" 1);
  1297  by (Simp_tac 1);
  1298 by (asm_simp_tac (simpset() addsimps [replicate_app_Cons_same]) 1);
  1299 qed "rev_replicate";
  1300 Addsimps [rev_replicate];
  1301 
  1302 Goal "replicate (n+m) x = replicate n x @ replicate m x";
  1303 by (induct_tac "n" 1);
  1304 by Auto_tac;
  1305 qed "replicate_add";
  1306 
  1307 Goal"n ~= 0 --> hd(replicate n x) = x";
  1308 by (induct_tac "n" 1);
  1309 by Auto_tac;
  1310 qed_spec_mp "hd_replicate";
  1311 Addsimps [hd_replicate];
  1312 
  1313 Goal "n ~= 0 --> tl(replicate n x) = replicate (n-1) x";
  1314 by (induct_tac "n" 1);
  1315 by Auto_tac;
  1316 qed_spec_mp "tl_replicate";
  1317 Addsimps [tl_replicate];
  1318 
  1319 Goal "n ~= 0 --> last(replicate n x) = x";
  1320 by (induct_tac "n" 1);
  1321 by Auto_tac;
  1322 qed_spec_mp "last_replicate";
  1323 Addsimps [last_replicate];
  1324 
  1325 Goal "!i. i<n --> (replicate n x)!i = x";
  1326 by (induct_tac "n" 1);
  1327  by (Simp_tac 1);
  1328 by (asm_simp_tac (simpset() addsimps [nth_Cons] addsplits [nat.split]) 1);
  1329 qed_spec_mp "nth_replicate";
  1330 Addsimps [nth_replicate];
  1331 
  1332 Goal "set(replicate (Suc n) x) = {x}";
  1333 by (induct_tac "n" 1);
  1334 by Auto_tac;
  1335 val lemma = result();
  1336 
  1337 Goal "n ~= 0 ==> set(replicate n x) = {x}";
  1338 by (fast_tac (claset() addSDs [not0_implies_Suc] addSIs [lemma]) 1);
  1339 qed "set_replicate";
  1340 Addsimps [set_replicate];
  1341 
  1342 Goal "set(replicate n x) = (if n=0 then {} else {x})";
  1343 by (Auto_tac);
  1344 qed "set_replicate_conv_if";
  1345 
  1346 Goal "x : set(replicate n y) --> x=y";
  1347 by (asm_simp_tac (simpset() addsimps [set_replicate_conv_if]) 1);
  1348 qed_spec_mp "in_set_replicateD";
  1349 
  1350 
  1351 (*** Lexcicographic orderings on lists ***)
  1352 section"Lexcicographic orderings on lists";
  1353 
  1354 Goal "wf r ==> wf(lexn r n)";
  1355 by (induct_tac "n" 1);
  1356 by (Simp_tac 1);
  1357 by (Simp_tac 1);
  1358 by (rtac wf_subset 1);
  1359 by (rtac Int_lower1 2);
  1360 by (rtac wf_prod_fun_image 1);
  1361 by (rtac injI 2);
  1362 by Auto_tac;
  1363 qed "wf_lexn";
  1364 
  1365 Goal "!xs ys. (xs,ys) : lexn r n --> length xs = n & length ys = n";
  1366 by (induct_tac "n" 1);
  1367 by Auto_tac;
  1368 qed_spec_mp "lexn_length";
  1369 
  1370 Goalw [lex_def] "wf r ==> wf(lex r)";
  1371 by (rtac wf_UN 1);
  1372 by (blast_tac (claset() addIs [wf_lexn]) 1);
  1373 by (Clarify_tac 1);
  1374 by (rename_tac "m n" 1);
  1375 by (subgoal_tac "m ~= n" 1);
  1376  by (Blast_tac 2);
  1377 by (blast_tac (claset() addDs [lexn_length,not_sym]) 1);
  1378 qed "wf_lex";
  1379 AddSIs [wf_lex];
  1380 
  1381 Goal
  1382  "lexn r n = \
  1383 \ {(xs,ys). length xs = n & length ys = n & \
  1384 \           (? xys x y xs' ys'. xs= xys @ x#xs' & ys= xys @ y#ys' & (x,y):r)}";
  1385 by (induct_tac "n" 1);
  1386  by (Simp_tac 1);
  1387  by (Blast_tac 1);
  1388 by (asm_full_simp_tac (simpset() 
  1389 				addsimps [lex_prod_def]) 1);
  1390 by (auto_tac (claset(), simpset()));
  1391   by (Blast_tac 1);
  1392  by (rename_tac "a xys x xs' y ys'" 1);
  1393  by (res_inst_tac [("x","a#xys")] exI 1);
  1394  by (Simp_tac 1);
  1395 by (case_tac "xys" 1);
  1396  by (ALLGOALS (asm_full_simp_tac (simpset())));
  1397 by (Blast_tac 1);
  1398 qed "lexn_conv";
  1399 
  1400 Goalw [lex_def]
  1401  "lex r = \
  1402 \ {(xs,ys). length xs = length ys & \
  1403 \           (? xys x y xs' ys'. xs= xys @ x#xs' & ys= xys @ y#ys' & (x,y):r)}";
  1404 by (force_tac (claset(), simpset() addsimps [lexn_conv]) 1);
  1405 qed "lex_conv";
  1406 
  1407 Goalw [lexico_def] "wf r ==> wf(lexico r)";
  1408 by (Blast_tac 1);
  1409 qed "wf_lexico";
  1410 AddSIs [wf_lexico];
  1411 
  1412 Goalw
  1413  [lexico_def,diag_def,lex_prod_def,measure_def,inv_image_def]
  1414 "lexico r = {(xs,ys). length xs < length ys | \
  1415 \                     length xs = length ys & (xs,ys) : lex r}";
  1416 by (Simp_tac 1);
  1417 qed "lexico_conv";
  1418 
  1419 Goal "([],ys) ~: lex r";
  1420 by (simp_tac (simpset() addsimps [lex_conv]) 1);
  1421 qed "Nil_notin_lex";
  1422 
  1423 Goal "(xs,[]) ~: lex r";
  1424 by (simp_tac (simpset() addsimps [lex_conv]) 1);
  1425 qed "Nil2_notin_lex";
  1426 
  1427 AddIffs [Nil_notin_lex,Nil2_notin_lex];
  1428 
  1429 Goal "((x#xs,y#ys) : lex r) = \
  1430 \     ((x,y) : r & length xs = length ys | x=y & (xs,ys) : lex r)";
  1431 by (simp_tac (simpset() addsimps [lex_conv]) 1);
  1432 by (rtac iffI 1);
  1433  by (blast_tac (claset() addIs [Cons_eq_appendI]) 2);
  1434 by (REPEAT(eresolve_tac [conjE, exE] 1));
  1435 by (case_tac "xys" 1);
  1436 by (Asm_full_simp_tac 1);
  1437 by (Asm_full_simp_tac 1);
  1438 by (Blast_tac 1);
  1439 qed "Cons_in_lex";
  1440 AddIffs [Cons_in_lex];
  1441 
  1442 
  1443 (*** sublist (a generalization of nth to sets) ***)
  1444 
  1445 Goalw [sublist_def] "sublist l {} = []";
  1446 by Auto_tac;
  1447 qed "sublist_empty";
  1448 
  1449 Goalw [sublist_def] "sublist [] A = []";
  1450 by Auto_tac;
  1451 qed "sublist_nil";
  1452 
  1453 Goal "map fst [p:zip xs [i..i + length xs(] . snd p : A] =     \
  1454 \     map fst [p:zip xs [0..length xs(] . snd p + i : A]";
  1455 by (rev_induct_tac "xs" 1);
  1456  by (asm_simp_tac (simpset() addsimps [add_commute]) 2);
  1457 by (Simp_tac 1);
  1458 qed "sublist_shift_lemma";
  1459 
  1460 Goalw [sublist_def]
  1461      "sublist (l@l') A = sublist l A @ sublist l' {j. j + length l : A}";
  1462 by (rev_induct_tac "l'" 1);
  1463 by (Simp_tac 1);
  1464 by (asm_simp_tac (simpset() addsimps [inst "i" "0" upt_add_eq_append, 
  1465 	                              zip_append, sublist_shift_lemma]) 1);
  1466 by (asm_simp_tac (simpset() addsimps [add_commute]) 1);
  1467 qed "sublist_append";
  1468 
  1469 Addsimps [sublist_empty, sublist_nil];
  1470 
  1471 Goal "sublist (x#l) A = (if 0:A then [x] else []) @ sublist l {j. Suc j : A}";
  1472 by (rev_induct_tac "l" 1);
  1473  by (asm_simp_tac (simpset() delsimps [append_Cons]
  1474 	 		     addsimps [append_Cons RS sym, sublist_append]) 2);
  1475 by (simp_tac (simpset() addsimps [sublist_def]) 1);
  1476 qed "sublist_Cons";
  1477 
  1478 Goal "sublist [x] A = (if 0 : A then [x] else [])";
  1479 by (simp_tac (simpset() addsimps [sublist_Cons]) 1);
  1480 qed "sublist_singleton";
  1481 Addsimps [sublist_singleton];
  1482 
  1483 Goal "sublist l {..n(} = take n l";
  1484 by (rev_induct_tac "l" 1);
  1485  by (asm_simp_tac (simpset() addsplits [nat_diff_split]
  1486                              addsimps [sublist_append]) 2);
  1487 by (Simp_tac 1);
  1488 qed "sublist_upt_eq_take";
  1489 Addsimps [sublist_upt_eq_take];
  1490 
  1491 
  1492 (*** Versions of some theorems above using binary numerals ***)
  1493 
  1494 AddIffs (map rename_numerals
  1495 	  [length_0_conv, zero_length_conv, length_greater_0_conv,
  1496 	   sum_eq_0_conv]);
  1497 
  1498 Goal "take n (x#xs) = (if n = #0 then [] else x # take (n-#1) xs)";
  1499 by (case_tac "n" 1);
  1500 by (ALLGOALS 
  1501     (asm_simp_tac (simpset() addsimps [numeral_0_eq_0, numeral_1_eq_1])));
  1502 qed "take_Cons'";
  1503 
  1504 Goal "drop n (x#xs) = (if n = #0 then x#xs else drop (n-#1) xs)";
  1505 by (case_tac "n" 1);
  1506 by (ALLGOALS
  1507     (asm_simp_tac (simpset() addsimps [numeral_0_eq_0, numeral_1_eq_1])));
  1508 qed "drop_Cons'";
  1509 
  1510 Goal "(x#xs)!n = (if n = #0 then x else xs!(n-#1))";
  1511 by (case_tac "n" 1);
  1512 by (ALLGOALS
  1513     (asm_simp_tac (simpset() addsimps [numeral_0_eq_0, numeral_1_eq_1])));
  1514 qed "nth_Cons'";
  1515 
  1516 Addsimps (map (inst "n" "number_of ?v") [take_Cons', drop_Cons', nth_Cons']);
  1517