src/HOL/Nat.thy
author nipkow
Mon Sep 12 07:55:43 2011 +0200 (2011-09-12)
changeset 44890 22f665a2e91c
parent 44848 f4d0b060c7ca
child 45231 d85a2fdc586c
permissions -rw-r--r--
new fastforce replacing fastsimp - less confusing name
     1 (*  Title:      HOL/Nat.thy
     2     Author:     Tobias Nipkow and Lawrence C Paulson and Markus Wenzel
     3 
     4 Type "nat" is a linear order, and a datatype; arithmetic operators + -
     5 and * (for div and mod, see theory Divides).
     6 *)
     7 
     8 header {* Natural numbers *}
     9 
    10 theory Nat
    11 imports Inductive Typedef Fun Fields
    12 uses
    13   "~~/src/Tools/rat.ML"
    14   "~~/src/Provers/Arith/cancel_sums.ML"
    15   "Tools/arith_data.ML"
    16   ("Tools/nat_arith.ML")
    17   "~~/src/Provers/Arith/fast_lin_arith.ML"
    18   ("Tools/lin_arith.ML")
    19 begin
    20 
    21 subsection {* Type @{text ind} *}
    22 
    23 typedecl ind
    24 
    25 axiomatization Zero_Rep :: ind and Suc_Rep :: "ind => ind" where
    26   -- {* the axiom of infinity in 2 parts *}
    27   Suc_Rep_inject:       "Suc_Rep x = Suc_Rep y ==> x = y" and
    28   Suc_Rep_not_Zero_Rep: "Suc_Rep x \<noteq> Zero_Rep"
    29 
    30 subsection {* Type nat *}
    31 
    32 text {* Type definition *}
    33 
    34 inductive Nat :: "ind \<Rightarrow> bool" where
    35   Zero_RepI: "Nat Zero_Rep"
    36 | Suc_RepI: "Nat i \<Longrightarrow> Nat (Suc_Rep i)"
    37 
    38 typedef (open Nat) nat = "{n. Nat n}"
    39   using Nat.Zero_RepI by auto
    40 
    41 lemma Nat_Rep_Nat:
    42   "Nat (Rep_Nat n)"
    43   using Rep_Nat by simp
    44 
    45 lemma Nat_Abs_Nat_inverse:
    46   "Nat n \<Longrightarrow> Rep_Nat (Abs_Nat n) = n"
    47   using Abs_Nat_inverse by simp
    48 
    49 lemma Nat_Abs_Nat_inject:
    50   "Nat n \<Longrightarrow> Nat m \<Longrightarrow> Abs_Nat n = Abs_Nat m \<longleftrightarrow> n = m"
    51   using Abs_Nat_inject by simp
    52 
    53 instantiation nat :: zero
    54 begin
    55 
    56 definition Zero_nat_def:
    57   "0 = Abs_Nat Zero_Rep"
    58 
    59 instance ..
    60 
    61 end
    62 
    63 definition Suc :: "nat \<Rightarrow> nat" where
    64   "Suc n = Abs_Nat (Suc_Rep (Rep_Nat n))"
    65 
    66 lemma Suc_not_Zero: "Suc m \<noteq> 0"
    67   by (simp add: Zero_nat_def Suc_def Suc_RepI Zero_RepI Nat_Abs_Nat_inject Suc_Rep_not_Zero_Rep Nat_Rep_Nat)
    68 
    69 lemma Zero_not_Suc: "0 \<noteq> Suc m"
    70   by (rule not_sym, rule Suc_not_Zero not_sym)
    71 
    72 lemma Suc_Rep_inject': "Suc_Rep x = Suc_Rep y \<longleftrightarrow> x = y"
    73   by (rule iffI, rule Suc_Rep_inject) simp_all
    74 
    75 rep_datatype "0 \<Colon> nat" Suc
    76   apply (unfold Zero_nat_def Suc_def)
    77   apply (rule Rep_Nat_inverse [THEN subst]) -- {* types force good instantiation *}
    78    apply (erule Nat_Rep_Nat [THEN Nat.induct])
    79    apply (iprover elim: Nat_Abs_Nat_inverse [THEN subst])
    80     apply (simp_all add: Nat_Abs_Nat_inject Nat_Rep_Nat
    81       Suc_RepI Zero_RepI Suc_Rep_not_Zero_Rep
    82       Suc_Rep_not_Zero_Rep [symmetric]
    83       Suc_Rep_inject' Rep_Nat_inject)
    84   done
    85 
    86 lemma nat_induct [case_names 0 Suc, induct type: nat]:
    87   -- {* for backward compatibility -- names of variables differ *}
    88   fixes n
    89   assumes "P 0"
    90     and "\<And>n. P n \<Longrightarrow> P (Suc n)"
    91   shows "P n"
    92   using assms by (rule nat.induct)
    93 
    94 declare nat.exhaust [case_names 0 Suc, cases type: nat]
    95 
    96 lemmas nat_rec_0 = nat.recs(1)
    97   and nat_rec_Suc = nat.recs(2)
    98 
    99 lemmas nat_case_0 = nat.cases(1)
   100   and nat_case_Suc = nat.cases(2)
   101    
   102 
   103 text {* Injectiveness and distinctness lemmas *}
   104 
   105 lemma inj_Suc[simp]: "inj_on Suc N"
   106   by (simp add: inj_on_def)
   107 
   108 lemma Suc_neq_Zero: "Suc m = 0 \<Longrightarrow> R"
   109 by (rule notE, rule Suc_not_Zero)
   110 
   111 lemma Zero_neq_Suc: "0 = Suc m \<Longrightarrow> R"
   112 by (rule Suc_neq_Zero, erule sym)
   113 
   114 lemma Suc_inject: "Suc x = Suc y \<Longrightarrow> x = y"
   115 by (rule inj_Suc [THEN injD])
   116 
   117 lemma n_not_Suc_n: "n \<noteq> Suc n"
   118 by (induct n) simp_all
   119 
   120 lemma Suc_n_not_n: "Suc n \<noteq> n"
   121 by (rule not_sym, rule n_not_Suc_n)
   122 
   123 text {* A special form of induction for reasoning
   124   about @{term "m < n"} and @{term "m - n"} *}
   125 
   126 lemma diff_induct: "(!!x. P x 0) ==> (!!y. P 0 (Suc y)) ==>
   127     (!!x y. P x y ==> P (Suc x) (Suc y)) ==> P m n"
   128   apply (rule_tac x = m in spec)
   129   apply (induct n)
   130   prefer 2
   131   apply (rule allI)
   132   apply (induct_tac x, iprover+)
   133   done
   134 
   135 
   136 subsection {* Arithmetic operators *}
   137 
   138 instantiation nat :: "{minus, comm_monoid_add}"
   139 begin
   140 
   141 primrec plus_nat where
   142   add_0:      "0 + n = (n\<Colon>nat)"
   143 | add_Suc:  "Suc m + n = Suc (m + n)"
   144 
   145 lemma add_0_right [simp]: "m + 0 = (m::nat)"
   146   by (induct m) simp_all
   147 
   148 lemma add_Suc_right [simp]: "m + Suc n = Suc (m + n)"
   149   by (induct m) simp_all
   150 
   151 declare add_0 [code]
   152 
   153 lemma add_Suc_shift [code]: "Suc m + n = m + Suc n"
   154   by simp
   155 
   156 primrec minus_nat where
   157   diff_0 [code]: "m - 0 = (m\<Colon>nat)"
   158 | diff_Suc: "m - Suc n = (case m - n of 0 => 0 | Suc k => k)"
   159 
   160 declare diff_Suc [simp del]
   161 
   162 lemma diff_0_eq_0 [simp, code]: "0 - n = (0::nat)"
   163   by (induct n) (simp_all add: diff_Suc)
   164 
   165 lemma diff_Suc_Suc [simp, code]: "Suc m - Suc n = m - n"
   166   by (induct n) (simp_all add: diff_Suc)
   167 
   168 instance proof
   169   fix n m q :: nat
   170   show "(n + m) + q = n + (m + q)" by (induct n) simp_all
   171   show "n + m = m + n" by (induct n) simp_all
   172   show "0 + n = n" by simp
   173 qed
   174 
   175 end
   176 
   177 hide_fact (open) add_0 add_0_right diff_0
   178 
   179 instantiation nat :: comm_semiring_1_cancel
   180 begin
   181 
   182 definition
   183   One_nat_def [simp]: "1 = Suc 0"
   184 
   185 primrec times_nat where
   186   mult_0:     "0 * n = (0\<Colon>nat)"
   187 | mult_Suc: "Suc m * n = n + (m * n)"
   188 
   189 lemma mult_0_right [simp]: "(m::nat) * 0 = 0"
   190   by (induct m) simp_all
   191 
   192 lemma mult_Suc_right [simp]: "m * Suc n = m + (m * n)"
   193   by (induct m) (simp_all add: add_left_commute)
   194 
   195 lemma add_mult_distrib: "(m + n) * k = (m * k) + ((n * k)::nat)"
   196   by (induct m) (simp_all add: add_assoc)
   197 
   198 instance proof
   199   fix n m q :: nat
   200   show "0 \<noteq> (1::nat)" unfolding One_nat_def by simp
   201   show "1 * n = n" unfolding One_nat_def by simp
   202   show "n * m = m * n" by (induct n) simp_all
   203   show "(n * m) * q = n * (m * q)" by (induct n) (simp_all add: add_mult_distrib)
   204   show "(n + m) * q = n * q + m * q" by (rule add_mult_distrib)
   205   assume "n + m = n + q" thus "m = q" by (induct n) simp_all
   206 qed
   207 
   208 end
   209 
   210 subsubsection {* Addition *}
   211 
   212 lemma nat_add_assoc: "(m + n) + k = m + ((n + k)::nat)"
   213   by (rule add_assoc)
   214 
   215 lemma nat_add_commute: "m + n = n + (m::nat)"
   216   by (rule add_commute)
   217 
   218 lemma nat_add_left_commute: "x + (y + z) = y + ((x + z)::nat)"
   219   by (rule add_left_commute)
   220 
   221 lemma nat_add_left_cancel [simp]: "(k + m = k + n) = (m = (n::nat))"
   222   by (rule add_left_cancel)
   223 
   224 lemma nat_add_right_cancel [simp]: "(m + k = n + k) = (m=(n::nat))"
   225   by (rule add_right_cancel)
   226 
   227 text {* Reasoning about @{text "m + 0 = 0"}, etc. *}
   228 
   229 lemma add_is_0 [iff]:
   230   fixes m n :: nat
   231   shows "(m + n = 0) = (m = 0 & n = 0)"
   232   by (cases m) simp_all
   233 
   234 lemma add_is_1:
   235   "(m+n= Suc 0) = (m= Suc 0 & n=0 | m=0 & n= Suc 0)"
   236   by (cases m) simp_all
   237 
   238 lemma one_is_add:
   239   "(Suc 0 = m + n) = (m = Suc 0 & n = 0 | m = 0 & n = Suc 0)"
   240   by (rule trans, rule eq_commute, rule add_is_1)
   241 
   242 lemma add_eq_self_zero:
   243   fixes m n :: nat
   244   shows "m + n = m \<Longrightarrow> n = 0"
   245   by (induct m) simp_all
   246 
   247 lemma inj_on_add_nat[simp]: "inj_on (%n::nat. n+k) N"
   248   apply (induct k)
   249    apply simp
   250   apply(drule comp_inj_on[OF _ inj_Suc])
   251   apply (simp add:o_def)
   252   done
   253 
   254 
   255 subsubsection {* Difference *}
   256 
   257 lemma diff_self_eq_0 [simp]: "(m\<Colon>nat) - m = 0"
   258   by (induct m) simp_all
   259 
   260 lemma diff_diff_left: "(i::nat) - j - k = i - (j + k)"
   261   by (induct i j rule: diff_induct) simp_all
   262 
   263 lemma Suc_diff_diff [simp]: "(Suc m - n) - Suc k = m - n - k"
   264   by (simp add: diff_diff_left)
   265 
   266 lemma diff_commute: "(i::nat) - j - k = i - k - j"
   267   by (simp add: diff_diff_left add_commute)
   268 
   269 lemma diff_add_inverse: "(n + m) - n = (m::nat)"
   270   by (induct n) simp_all
   271 
   272 lemma diff_add_inverse2: "(m + n) - n = (m::nat)"
   273   by (simp add: diff_add_inverse add_commute [of m n])
   274 
   275 lemma diff_cancel: "(k + m) - (k + n) = m - (n::nat)"
   276   by (induct k) simp_all
   277 
   278 lemma diff_cancel2: "(m + k) - (n + k) = m - (n::nat)"
   279   by (simp add: diff_cancel add_commute)
   280 
   281 lemma diff_add_0: "n - (n + m) = (0::nat)"
   282   by (induct n) simp_all
   283 
   284 lemma diff_Suc_1 [simp]: "Suc n - 1 = n"
   285   unfolding One_nat_def by simp
   286 
   287 text {* Difference distributes over multiplication *}
   288 
   289 lemma diff_mult_distrib: "((m::nat) - n) * k = (m * k) - (n * k)"
   290 by (induct m n rule: diff_induct) (simp_all add: diff_cancel)
   291 
   292 lemma diff_mult_distrib2: "k * ((m::nat) - n) = (k * m) - (k * n)"
   293 by (simp add: diff_mult_distrib mult_commute [of k])
   294   -- {* NOT added as rewrites, since sometimes they are used from right-to-left *}
   295 
   296 
   297 subsubsection {* Multiplication *}
   298 
   299 lemma nat_mult_assoc: "(m * n) * k = m * ((n * k)::nat)"
   300   by (rule mult_assoc)
   301 
   302 lemma nat_mult_commute: "m * n = n * (m::nat)"
   303   by (rule mult_commute)
   304 
   305 lemma add_mult_distrib2: "k * (m + n) = (k * m) + ((k * n)::nat)"
   306   by (rule right_distrib)
   307 
   308 lemma mult_is_0 [simp]: "((m::nat) * n = 0) = (m=0 | n=0)"
   309   by (induct m) auto
   310 
   311 lemmas nat_distrib =
   312   add_mult_distrib add_mult_distrib2 diff_mult_distrib diff_mult_distrib2
   313 
   314 lemma mult_eq_1_iff [simp]: "(m * n = Suc 0) = (m = Suc 0 & n = Suc 0)"
   315   apply (induct m)
   316    apply simp
   317   apply (induct n)
   318    apply auto
   319   done
   320 
   321 lemma one_eq_mult_iff [simp,no_atp]: "(Suc 0 = m * n) = (m = Suc 0 & n = Suc 0)"
   322   apply (rule trans)
   323   apply (rule_tac [2] mult_eq_1_iff, fastforce)
   324   done
   325 
   326 lemma nat_mult_eq_1_iff [simp]: "m * n = (1::nat) \<longleftrightarrow> m = 1 \<and> n = 1"
   327   unfolding One_nat_def by (rule mult_eq_1_iff)
   328 
   329 lemma nat_1_eq_mult_iff [simp]: "(1::nat) = m * n \<longleftrightarrow> m = 1 \<and> n = 1"
   330   unfolding One_nat_def by (rule one_eq_mult_iff)
   331 
   332 lemma mult_cancel1 [simp]: "(k * m = k * n) = (m = n | (k = (0::nat)))"
   333 proof -
   334   have "k \<noteq> 0 \<Longrightarrow> k * m = k * n \<Longrightarrow> m = n"
   335   proof (induct n arbitrary: m)
   336     case 0 then show "m = 0" by simp
   337   next
   338     case (Suc n) then show "m = Suc n"
   339       by (cases m) (simp_all add: eq_commute [of "0"])
   340   qed
   341   then show ?thesis by auto
   342 qed
   343 
   344 lemma mult_cancel2 [simp]: "(m * k = n * k) = (m = n | (k = (0::nat)))"
   345   by (simp add: mult_commute)
   346 
   347 lemma Suc_mult_cancel1: "(Suc k * m = Suc k * n) = (m = n)"
   348   by (subst mult_cancel1) simp
   349 
   350 
   351 subsection {* Orders on @{typ nat} *}
   352 
   353 subsubsection {* Operation definition *}
   354 
   355 instantiation nat :: linorder
   356 begin
   357 
   358 primrec less_eq_nat where
   359   "(0\<Colon>nat) \<le> n \<longleftrightarrow> True"
   360 | "Suc m \<le> n \<longleftrightarrow> (case n of 0 \<Rightarrow> False | Suc n \<Rightarrow> m \<le> n)"
   361 
   362 declare less_eq_nat.simps [simp del]
   363 lemma [code]: "(0\<Colon>nat) \<le> n \<longleftrightarrow> True" by (simp add: less_eq_nat.simps)
   364 lemma le0 [iff]: "0 \<le> (n\<Colon>nat)" by (simp add: less_eq_nat.simps)
   365 
   366 definition less_nat where
   367   less_eq_Suc_le: "n < m \<longleftrightarrow> Suc n \<le> m"
   368 
   369 lemma Suc_le_mono [iff]: "Suc n \<le> Suc m \<longleftrightarrow> n \<le> m"
   370   by (simp add: less_eq_nat.simps(2))
   371 
   372 lemma Suc_le_eq [code]: "Suc m \<le> n \<longleftrightarrow> m < n"
   373   unfolding less_eq_Suc_le ..
   374 
   375 lemma le_0_eq [iff]: "(n\<Colon>nat) \<le> 0 \<longleftrightarrow> n = 0"
   376   by (induct n) (simp_all add: less_eq_nat.simps(2))
   377 
   378 lemma not_less0 [iff]: "\<not> n < (0\<Colon>nat)"
   379   by (simp add: less_eq_Suc_le)
   380 
   381 lemma less_nat_zero_code [code]: "n < (0\<Colon>nat) \<longleftrightarrow> False"
   382   by simp
   383 
   384 lemma Suc_less_eq [iff]: "Suc m < Suc n \<longleftrightarrow> m < n"
   385   by (simp add: less_eq_Suc_le)
   386 
   387 lemma less_Suc_eq_le [code]: "m < Suc n \<longleftrightarrow> m \<le> n"
   388   by (simp add: less_eq_Suc_le)
   389 
   390 lemma le_SucI: "m \<le> n \<Longrightarrow> m \<le> Suc n"
   391   by (induct m arbitrary: n)
   392     (simp_all add: less_eq_nat.simps(2) split: nat.splits)
   393 
   394 lemma Suc_leD: "Suc m \<le> n \<Longrightarrow> m \<le> n"
   395   by (cases n) (auto intro: le_SucI)
   396 
   397 lemma less_SucI: "m < n \<Longrightarrow> m < Suc n"
   398   by (simp add: less_eq_Suc_le) (erule Suc_leD)
   399 
   400 lemma Suc_lessD: "Suc m < n \<Longrightarrow> m < n"
   401   by (simp add: less_eq_Suc_le) (erule Suc_leD)
   402 
   403 instance
   404 proof
   405   fix n m :: nat
   406   show "n < m \<longleftrightarrow> n \<le> m \<and> \<not> m \<le> n" 
   407   proof (induct n arbitrary: m)
   408     case 0 then show ?case by (cases m) (simp_all add: less_eq_Suc_le)
   409   next
   410     case (Suc n) then show ?case by (cases m) (simp_all add: less_eq_Suc_le)
   411   qed
   412 next
   413   fix n :: nat show "n \<le> n" by (induct n) simp_all
   414 next
   415   fix n m :: nat assume "n \<le> m" and "m \<le> n"
   416   then show "n = m"
   417     by (induct n arbitrary: m)
   418       (simp_all add: less_eq_nat.simps(2) split: nat.splits)
   419 next
   420   fix n m q :: nat assume "n \<le> m" and "m \<le> q"
   421   then show "n \<le> q"
   422   proof (induct n arbitrary: m q)
   423     case 0 show ?case by simp
   424   next
   425     case (Suc n) then show ?case
   426       by (simp_all (no_asm_use) add: less_eq_nat.simps(2) split: nat.splits, clarify,
   427         simp_all (no_asm_use) add: less_eq_nat.simps(2) split: nat.splits, clarify,
   428         simp_all (no_asm_use) add: less_eq_nat.simps(2) split: nat.splits)
   429   qed
   430 next
   431   fix n m :: nat show "n \<le> m \<or> m \<le> n"
   432     by (induct n arbitrary: m)
   433       (simp_all add: less_eq_nat.simps(2) split: nat.splits)
   434 qed
   435 
   436 end
   437 
   438 instantiation nat :: bot
   439 begin
   440 
   441 definition bot_nat :: nat where
   442   "bot_nat = 0"
   443 
   444 instance proof
   445 qed (simp add: bot_nat_def)
   446 
   447 end
   448 
   449 subsubsection {* Introduction properties *}
   450 
   451 lemma lessI [iff]: "n < Suc n"
   452   by (simp add: less_Suc_eq_le)
   453 
   454 lemma zero_less_Suc [iff]: "0 < Suc n"
   455   by (simp add: less_Suc_eq_le)
   456 
   457 
   458 subsubsection {* Elimination properties *}
   459 
   460 lemma less_not_refl: "~ n < (n::nat)"
   461   by (rule order_less_irrefl)
   462 
   463 lemma less_not_refl2: "n < m ==> m \<noteq> (n::nat)"
   464   by (rule not_sym) (rule less_imp_neq) 
   465 
   466 lemma less_not_refl3: "(s::nat) < t ==> s \<noteq> t"
   467   by (rule less_imp_neq)
   468 
   469 lemma less_irrefl_nat: "(n::nat) < n ==> R"
   470   by (rule notE, rule less_not_refl)
   471 
   472 lemma less_zeroE: "(n::nat) < 0 ==> R"
   473   by (rule notE) (rule not_less0)
   474 
   475 lemma less_Suc_eq: "(m < Suc n) = (m < n | m = n)"
   476   unfolding less_Suc_eq_le le_less ..
   477 
   478 lemma less_Suc0 [iff]: "(n < Suc 0) = (n = 0)"
   479   by (simp add: less_Suc_eq)
   480 
   481 lemma less_one [iff, no_atp]: "(n < (1::nat)) = (n = 0)"
   482   unfolding One_nat_def by (rule less_Suc0)
   483 
   484 lemma Suc_mono: "m < n ==> Suc m < Suc n"
   485   by simp
   486 
   487 text {* "Less than" is antisymmetric, sort of *}
   488 lemma less_antisym: "\<lbrakk> \<not> n < m; n < Suc m \<rbrakk> \<Longrightarrow> m = n"
   489   unfolding not_less less_Suc_eq_le by (rule antisym)
   490 
   491 lemma nat_neq_iff: "((m::nat) \<noteq> n) = (m < n | n < m)"
   492   by (rule linorder_neq_iff)
   493 
   494 lemma nat_less_cases: assumes major: "(m::nat) < n ==> P n m"
   495   and eqCase: "m = n ==> P n m" and lessCase: "n<m ==> P n m"
   496   shows "P n m"
   497   apply (rule less_linear [THEN disjE])
   498   apply (erule_tac [2] disjE)
   499   apply (erule lessCase)
   500   apply (erule sym [THEN eqCase])
   501   apply (erule major)
   502   done
   503 
   504 
   505 subsubsection {* Inductive (?) properties *}
   506 
   507 lemma Suc_lessI: "m < n ==> Suc m \<noteq> n ==> Suc m < n"
   508   unfolding less_eq_Suc_le [of m] le_less by simp 
   509 
   510 lemma lessE:
   511   assumes major: "i < k"
   512   and p1: "k = Suc i ==> P" and p2: "!!j. i < j ==> k = Suc j ==> P"
   513   shows P
   514 proof -
   515   from major have "\<exists>j. i \<le> j \<and> k = Suc j"
   516     unfolding less_eq_Suc_le by (induct k) simp_all
   517   then have "(\<exists>j. i < j \<and> k = Suc j) \<or> k = Suc i"
   518     by (clarsimp simp add: less_le)
   519   with p1 p2 show P by auto
   520 qed
   521 
   522 lemma less_SucE: assumes major: "m < Suc n"
   523   and less: "m < n ==> P" and eq: "m = n ==> P" shows P
   524   apply (rule major [THEN lessE])
   525   apply (rule eq, blast)
   526   apply (rule less, blast)
   527   done
   528 
   529 lemma Suc_lessE: assumes major: "Suc i < k"
   530   and minor: "!!j. i < j ==> k = Suc j ==> P" shows P
   531   apply (rule major [THEN lessE])
   532   apply (erule lessI [THEN minor])
   533   apply (erule Suc_lessD [THEN minor], assumption)
   534   done
   535 
   536 lemma Suc_less_SucD: "Suc m < Suc n ==> m < n"
   537   by simp
   538 
   539 lemma less_trans_Suc:
   540   assumes le: "i < j" shows "j < k ==> Suc i < k"
   541   apply (induct k, simp_all)
   542   apply (insert le)
   543   apply (simp add: less_Suc_eq)
   544   apply (blast dest: Suc_lessD)
   545   done
   546 
   547 text {* Can be used with @{text less_Suc_eq} to get @{term "n = m | n < m"} *}
   548 lemma not_less_eq: "\<not> m < n \<longleftrightarrow> n < Suc m"
   549   unfolding not_less less_Suc_eq_le ..
   550 
   551 lemma not_less_eq_eq: "\<not> m \<le> n \<longleftrightarrow> Suc n \<le> m"
   552   unfolding not_le Suc_le_eq ..
   553 
   554 text {* Properties of "less than or equal" *}
   555 
   556 lemma le_imp_less_Suc: "m \<le> n ==> m < Suc n"
   557   unfolding less_Suc_eq_le .
   558 
   559 lemma Suc_n_not_le_n: "~ Suc n \<le> n"
   560   unfolding not_le less_Suc_eq_le ..
   561 
   562 lemma le_Suc_eq: "(m \<le> Suc n) = (m \<le> n | m = Suc n)"
   563   by (simp add: less_Suc_eq_le [symmetric] less_Suc_eq)
   564 
   565 lemma le_SucE: "m \<le> Suc n ==> (m \<le> n ==> R) ==> (m = Suc n ==> R) ==> R"
   566   by (drule le_Suc_eq [THEN iffD1], iprover+)
   567 
   568 lemma Suc_leI: "m < n ==> Suc(m) \<le> n"
   569   unfolding Suc_le_eq .
   570 
   571 text {* Stronger version of @{text Suc_leD} *}
   572 lemma Suc_le_lessD: "Suc m \<le> n ==> m < n"
   573   unfolding Suc_le_eq .
   574 
   575 lemma less_imp_le_nat: "m < n ==> m \<le> (n::nat)"
   576   unfolding less_eq_Suc_le by (rule Suc_leD)
   577 
   578 text {* For instance, @{text "(Suc m < Suc n) = (Suc m \<le> n) = (m < n)"} *}
   579 lemmas le_simps = less_imp_le_nat less_Suc_eq_le Suc_le_eq
   580 
   581 
   582 text {* Equivalence of @{term "m \<le> n"} and @{term "m < n | m = n"} *}
   583 
   584 lemma less_or_eq_imp_le: "m < n | m = n ==> m \<le> (n::nat)"
   585   unfolding le_less .
   586 
   587 lemma le_eq_less_or_eq: "(m \<le> (n::nat)) = (m < n | m=n)"
   588   by (rule le_less)
   589 
   590 text {* Useful with @{text blast}. *}
   591 lemma eq_imp_le: "(m::nat) = n ==> m \<le> n"
   592   by auto
   593 
   594 lemma le_refl: "n \<le> (n::nat)"
   595   by simp
   596 
   597 lemma le_trans: "[| i \<le> j; j \<le> k |] ==> i \<le> (k::nat)"
   598   by (rule order_trans)
   599 
   600 lemma le_antisym: "[| m \<le> n; n \<le> m |] ==> m = (n::nat)"
   601   by (rule antisym)
   602 
   603 lemma nat_less_le: "((m::nat) < n) = (m \<le> n & m \<noteq> n)"
   604   by (rule less_le)
   605 
   606 lemma le_neq_implies_less: "(m::nat) \<le> n ==> m \<noteq> n ==> m < n"
   607   unfolding less_le ..
   608 
   609 lemma nat_le_linear: "(m::nat) \<le> n | n \<le> m"
   610   by (rule linear)
   611 
   612 lemmas linorder_neqE_nat = linorder_neqE [where 'a = nat]
   613 
   614 lemma le_less_Suc_eq: "m \<le> n ==> (n < Suc m) = (n = m)"
   615   unfolding less_Suc_eq_le by auto
   616 
   617 lemma not_less_less_Suc_eq: "~ n < m ==> (n < Suc m) = (n = m)"
   618   unfolding not_less by (rule le_less_Suc_eq)
   619 
   620 lemmas not_less_simps = not_less_less_Suc_eq le_less_Suc_eq
   621 
   622 text {* These two rules ease the use of primitive recursion.
   623 NOTE USE OF @{text "=="} *}
   624 lemma def_nat_rec_0: "(!!n. f n == nat_rec c h n) ==> f 0 = c"
   625 by simp
   626 
   627 lemma def_nat_rec_Suc: "(!!n. f n == nat_rec c h n) ==> f (Suc n) = h n (f n)"
   628 by simp
   629 
   630 lemma not0_implies_Suc: "n \<noteq> 0 ==> \<exists>m. n = Suc m"
   631 by (cases n) simp_all
   632 
   633 lemma gr0_implies_Suc: "n > 0 ==> \<exists>m. n = Suc m"
   634 by (cases n) simp_all
   635 
   636 lemma gr_implies_not0: fixes n :: nat shows "m<n ==> n \<noteq> 0"
   637 by (cases n) simp_all
   638 
   639 lemma neq0_conv[iff]: fixes n :: nat shows "(n \<noteq> 0) = (0 < n)"
   640 by (cases n) simp_all
   641 
   642 text {* This theorem is useful with @{text blast} *}
   643 lemma gr0I: "((n::nat) = 0 ==> False) ==> 0 < n"
   644 by (rule neq0_conv[THEN iffD1], iprover)
   645 
   646 lemma gr0_conv_Suc: "(0 < n) = (\<exists>m. n = Suc m)"
   647 by (fast intro: not0_implies_Suc)
   648 
   649 lemma not_gr0 [iff,no_atp]: "!!n::nat. (~ (0 < n)) = (n = 0)"
   650 using neq0_conv by blast
   651 
   652 lemma Suc_le_D: "(Suc n \<le> m') ==> (? m. m' = Suc m)"
   653 by (induct m') simp_all
   654 
   655 text {* Useful in certain inductive arguments *}
   656 lemma less_Suc_eq_0_disj: "(m < Suc n) = (m = 0 | (\<exists>j. m = Suc j & j < n))"
   657 by (cases m) simp_all
   658 
   659 
   660 subsubsection {* Monotonicity of Addition *}
   661 
   662 lemma Suc_pred [simp]: "n>0 ==> Suc (n - Suc 0) = n"
   663 by (simp add: diff_Suc split: nat.split)
   664 
   665 lemma Suc_diff_1 [simp]: "0 < n ==> Suc (n - 1) = n"
   666 unfolding One_nat_def by (rule Suc_pred)
   667 
   668 lemma nat_add_left_cancel_le [simp]: "(k + m \<le> k + n) = (m\<le>(n::nat))"
   669 by (induct k) simp_all
   670 
   671 lemma nat_add_left_cancel_less [simp]: "(k + m < k + n) = (m<(n::nat))"
   672 by (induct k) simp_all
   673 
   674 lemma add_gr_0 [iff]: "!!m::nat. (m + n > 0) = (m>0 | n>0)"
   675 by(auto dest:gr0_implies_Suc)
   676 
   677 text {* strict, in 1st argument *}
   678 lemma add_less_mono1: "i < j ==> i + k < j + (k::nat)"
   679 by (induct k) simp_all
   680 
   681 text {* strict, in both arguments *}
   682 lemma add_less_mono: "[|i < j; k < l|] ==> i + k < j + (l::nat)"
   683   apply (rule add_less_mono1 [THEN less_trans], assumption+)
   684   apply (induct j, simp_all)
   685   done
   686 
   687 text {* Deleted @{text less_natE}; use @{text "less_imp_Suc_add RS exE"} *}
   688 lemma less_imp_Suc_add: "m < n ==> (\<exists>k. n = Suc (m + k))"
   689   apply (induct n)
   690   apply (simp_all add: order_le_less)
   691   apply (blast elim!: less_SucE
   692                intro!: Nat.add_0_right [symmetric] add_Suc_right [symmetric])
   693   done
   694 
   695 text {* strict, in 1st argument; proof is by induction on @{text "k > 0"} *}
   696 lemma mult_less_mono2: "(i::nat) < j ==> 0<k ==> k * i < k * j"
   697 apply(auto simp: gr0_conv_Suc)
   698 apply (induct_tac m)
   699 apply (simp_all add: add_less_mono)
   700 done
   701 
   702 text{*The naturals form an ordered @{text comm_semiring_1_cancel}*}
   703 instance nat :: linordered_semidom
   704 proof
   705   fix i j k :: nat
   706   show "0 < (1::nat)" by simp
   707   show "i \<le> j ==> k + i \<le> k + j" by simp
   708   show "i < j ==> 0 < k ==> k * i < k * j" by (simp add: mult_less_mono2)
   709 qed
   710 
   711 instance nat :: no_zero_divisors
   712 proof
   713   fix a::nat and b::nat show "a ~= 0 \<Longrightarrow> b ~= 0 \<Longrightarrow> a * b ~= 0" by auto
   714 qed
   715 
   716 
   717 subsubsection {* @{term min} and @{term max} *}
   718 
   719 lemma mono_Suc: "mono Suc"
   720 by (rule monoI) simp
   721 
   722 lemma min_0L [simp]: "min 0 n = (0::nat)"
   723 by (rule min_leastL) simp
   724 
   725 lemma min_0R [simp]: "min n 0 = (0::nat)"
   726 by (rule min_leastR) simp
   727 
   728 lemma min_Suc_Suc [simp]: "min (Suc m) (Suc n) = Suc (min m n)"
   729 by (simp add: mono_Suc min_of_mono)
   730 
   731 lemma min_Suc1:
   732    "min (Suc n) m = (case m of 0 => 0 | Suc m' => Suc(min n m'))"
   733 by (simp split: nat.split)
   734 
   735 lemma min_Suc2:
   736    "min m (Suc n) = (case m of 0 => 0 | Suc m' => Suc(min m' n))"
   737 by (simp split: nat.split)
   738 
   739 lemma max_0L [simp]: "max 0 n = (n::nat)"
   740 by (rule max_leastL) simp
   741 
   742 lemma max_0R [simp]: "max n 0 = (n::nat)"
   743 by (rule max_leastR) simp
   744 
   745 lemma max_Suc_Suc [simp]: "max (Suc m) (Suc n) = Suc(max m n)"
   746 by (simp add: mono_Suc max_of_mono)
   747 
   748 lemma max_Suc1:
   749    "max (Suc n) m = (case m of 0 => Suc n | Suc m' => Suc(max n m'))"
   750 by (simp split: nat.split)
   751 
   752 lemma max_Suc2:
   753    "max m (Suc n) = (case m of 0 => Suc n | Suc m' => Suc(max m' n))"
   754 by (simp split: nat.split)
   755 
   756 lemma nat_mult_min_left:
   757   fixes m n q :: nat
   758   shows "min m n * q = min (m * q) (n * q)"
   759   by (simp add: min_def not_le) (auto dest: mult_right_le_imp_le mult_right_less_imp_less le_less_trans)
   760 
   761 lemma nat_mult_min_right:
   762   fixes m n q :: nat
   763   shows "m * min n q = min (m * n) (m * q)"
   764   by (simp add: min_def not_le) (auto dest: mult_left_le_imp_le mult_left_less_imp_less le_less_trans)
   765 
   766 lemma nat_add_max_left:
   767   fixes m n q :: nat
   768   shows "max m n + q = max (m + q) (n + q)"
   769   by (simp add: max_def)
   770 
   771 lemma nat_add_max_right:
   772   fixes m n q :: nat
   773   shows "m + max n q = max (m + n) (m + q)"
   774   by (simp add: max_def)
   775 
   776 lemma nat_mult_max_left:
   777   fixes m n q :: nat
   778   shows "max m n * q = max (m * q) (n * q)"
   779   by (simp add: max_def not_le) (auto dest: mult_right_le_imp_le mult_right_less_imp_less le_less_trans)
   780 
   781 lemma nat_mult_max_right:
   782   fixes m n q :: nat
   783   shows "m * max n q = max (m * n) (m * q)"
   784   by (simp add: max_def not_le) (auto dest: mult_left_le_imp_le mult_left_less_imp_less le_less_trans)
   785 
   786 
   787 subsubsection {* Additional theorems about @{term "op \<le>"} *}
   788 
   789 text {* Complete induction, aka course-of-values induction *}
   790 
   791 instance nat :: wellorder proof
   792   fix P and n :: nat
   793   assume step: "\<And>n::nat. (\<And>m. m < n \<Longrightarrow> P m) \<Longrightarrow> P n"
   794   have "\<And>q. q \<le> n \<Longrightarrow> P q"
   795   proof (induct n)
   796     case (0 n)
   797     have "P 0" by (rule step) auto
   798     thus ?case using 0 by auto
   799   next
   800     case (Suc m n)
   801     then have "n \<le> m \<or> n = Suc m" by (simp add: le_Suc_eq)
   802     thus ?case
   803     proof
   804       assume "n \<le> m" thus "P n" by (rule Suc(1))
   805     next
   806       assume n: "n = Suc m"
   807       show "P n"
   808         by (rule step) (rule Suc(1), simp add: n le_simps)
   809     qed
   810   qed
   811   then show "P n" by auto
   812 qed
   813 
   814 lemma Least_Suc:
   815      "[| P n; ~ P 0 |] ==> (LEAST n. P n) = Suc (LEAST m. P(Suc m))"
   816   apply (case_tac "n", auto)
   817   apply (frule LeastI)
   818   apply (drule_tac P = "%x. P (Suc x) " in LeastI)
   819   apply (subgoal_tac " (LEAST x. P x) \<le> Suc (LEAST x. P (Suc x))")
   820   apply (erule_tac [2] Least_le)
   821   apply (case_tac "LEAST x. P x", auto)
   822   apply (drule_tac P = "%x. P (Suc x) " in Least_le)
   823   apply (blast intro: order_antisym)
   824   done
   825 
   826 lemma Least_Suc2:
   827    "[|P n; Q m; ~P 0; !k. P (Suc k) = Q k|] ==> Least P = Suc (Least Q)"
   828   apply (erule (1) Least_Suc [THEN ssubst])
   829   apply simp
   830   done
   831 
   832 lemma ex_least_nat_le: "\<not>P(0) \<Longrightarrow> P(n::nat) \<Longrightarrow> \<exists>k\<le>n. (\<forall>i<k. \<not>P i) & P(k)"
   833   apply (cases n)
   834    apply blast
   835   apply (rule_tac x="LEAST k. P(k)" in exI)
   836   apply (blast intro: Least_le dest: not_less_Least intro: LeastI_ex)
   837   done
   838 
   839 lemma ex_least_nat_less: "\<not>P(0) \<Longrightarrow> P(n::nat) \<Longrightarrow> \<exists>k<n. (\<forall>i\<le>k. \<not>P i) & P(k+1)"
   840   unfolding One_nat_def
   841   apply (cases n)
   842    apply blast
   843   apply (frule (1) ex_least_nat_le)
   844   apply (erule exE)
   845   apply (case_tac k)
   846    apply simp
   847   apply (rename_tac k1)
   848   apply (rule_tac x=k1 in exI)
   849   apply (auto simp add: less_eq_Suc_le)
   850   done
   851 
   852 lemma nat_less_induct:
   853   assumes "!!n. \<forall>m::nat. m < n --> P m ==> P n" shows "P n"
   854   using assms less_induct by blast
   855 
   856 lemma measure_induct_rule [case_names less]:
   857   fixes f :: "'a \<Rightarrow> nat"
   858   assumes step: "\<And>x. (\<And>y. f y < f x \<Longrightarrow> P y) \<Longrightarrow> P x"
   859   shows "P a"
   860 by (induct m\<equiv>"f a" arbitrary: a rule: less_induct) (auto intro: step)
   861 
   862 text {* old style induction rules: *}
   863 lemma measure_induct:
   864   fixes f :: "'a \<Rightarrow> nat"
   865   shows "(\<And>x. \<forall>y. f y < f x \<longrightarrow> P y \<Longrightarrow> P x) \<Longrightarrow> P a"
   866   by (rule measure_induct_rule [of f P a]) iprover
   867 
   868 lemma full_nat_induct:
   869   assumes step: "(!!n. (ALL m. Suc m <= n --> P m) ==> P n)"
   870   shows "P n"
   871   by (rule less_induct) (auto intro: step simp:le_simps)
   872 
   873 text{*An induction rule for estabilishing binary relations*}
   874 lemma less_Suc_induct:
   875   assumes less:  "i < j"
   876      and  step:  "!!i. P i (Suc i)"
   877      and  trans: "!!i j k. i < j ==> j < k ==>  P i j ==> P j k ==> P i k"
   878   shows "P i j"
   879 proof -
   880   from less obtain k where j: "j = Suc (i + k)" by (auto dest: less_imp_Suc_add)
   881   have "P i (Suc (i + k))"
   882   proof (induct k)
   883     case 0
   884     show ?case by (simp add: step)
   885   next
   886     case (Suc k)
   887     have "0 + i < Suc k + i" by (rule add_less_mono1) simp
   888     hence "i < Suc (i + k)" by (simp add: add_commute)
   889     from trans[OF this lessI Suc step]
   890     show ?case by simp
   891   qed
   892   thus "P i j" by (simp add: j)
   893 qed
   894 
   895 text {* The method of infinite descent, frequently used in number theory.
   896 Provided by Roelof Oosterhuis.
   897 $P(n)$ is true for all $n\in\mathbb{N}$ if
   898 \begin{itemize}
   899   \item case ``0'': given $n=0$ prove $P(n)$,
   900   \item case ``smaller'': given $n>0$ and $\neg P(n)$ prove there exists
   901         a smaller integer $m$ such that $\neg P(m)$.
   902 \end{itemize} *}
   903 
   904 text{* A compact version without explicit base case: *}
   905 lemma infinite_descent:
   906   "\<lbrakk> !!n::nat. \<not> P n \<Longrightarrow>  \<exists>m<n. \<not>  P m \<rbrakk> \<Longrightarrow>  P n"
   907 by (induct n rule: less_induct, auto)
   908 
   909 lemma infinite_descent0[case_names 0 smaller]: 
   910   "\<lbrakk> P 0; !!n. n>0 \<Longrightarrow> \<not> P n \<Longrightarrow> (\<exists>m::nat. m < n \<and> \<not>P m) \<rbrakk> \<Longrightarrow> P n"
   911 by (rule infinite_descent) (case_tac "n>0", auto)
   912 
   913 text {*
   914 Infinite descent using a mapping to $\mathbb{N}$:
   915 $P(x)$ is true for all $x\in D$ if there exists a $V: D \to \mathbb{N}$ and
   916 \begin{itemize}
   917 \item case ``0'': given $V(x)=0$ prove $P(x)$,
   918 \item case ``smaller'': given $V(x)>0$ and $\neg P(x)$ prove there exists a $y \in D$ such that $V(y)<V(x)$ and $~\neg P(y)$.
   919 \end{itemize}
   920 NB: the proof also shows how to use the previous lemma. *}
   921 
   922 corollary infinite_descent0_measure [case_names 0 smaller]:
   923   assumes A0: "!!x. V x = (0::nat) \<Longrightarrow> P x"
   924     and   A1: "!!x. V x > 0 \<Longrightarrow> \<not>P x \<Longrightarrow> (\<exists>y. V y < V x \<and> \<not>P y)"
   925   shows "P x"
   926 proof -
   927   obtain n where "n = V x" by auto
   928   moreover have "\<And>x. V x = n \<Longrightarrow> P x"
   929   proof (induct n rule: infinite_descent0)
   930     case 0 -- "i.e. $V(x) = 0$"
   931     with A0 show "P x" by auto
   932   next -- "now $n>0$ and $P(x)$ does not hold for some $x$ with $V(x)=n$"
   933     case (smaller n)
   934     then obtain x where vxn: "V x = n " and "V x > 0 \<and> \<not> P x" by auto
   935     with A1 obtain y where "V y < V x \<and> \<not> P y" by auto
   936     with vxn obtain m where "m = V y \<and> m<n \<and> \<not> P y" by auto
   937     then show ?case by auto
   938   qed
   939   ultimately show "P x" by auto
   940 qed
   941 
   942 text{* Again, without explicit base case: *}
   943 lemma infinite_descent_measure:
   944 assumes "!!x. \<not> P x \<Longrightarrow> \<exists>y. (V::'a\<Rightarrow>nat) y < V x \<and> \<not> P y" shows "P x"
   945 proof -
   946   from assms obtain n where "n = V x" by auto
   947   moreover have "!!x. V x = n \<Longrightarrow> P x"
   948   proof (induct n rule: infinite_descent, auto)
   949     fix x assume "\<not> P x"
   950     with assms show "\<exists>m < V x. \<exists>y. V y = m \<and> \<not> P y" by auto
   951   qed
   952   ultimately show "P x" by auto
   953 qed
   954 
   955 text {* A [clumsy] way of lifting @{text "<"}
   956   monotonicity to @{text "\<le>"} monotonicity *}
   957 lemma less_mono_imp_le_mono:
   958   "\<lbrakk> !!i j::nat. i < j \<Longrightarrow> f i < f j; i \<le> j \<rbrakk> \<Longrightarrow> f i \<le> ((f j)::nat)"
   959 by (simp add: order_le_less) (blast)
   960 
   961 
   962 text {* non-strict, in 1st argument *}
   963 lemma add_le_mono1: "i \<le> j ==> i + k \<le> j + (k::nat)"
   964 by (rule add_right_mono)
   965 
   966 text {* non-strict, in both arguments *}
   967 lemma add_le_mono: "[| i \<le> j;  k \<le> l |] ==> i + k \<le> j + (l::nat)"
   968 by (rule add_mono)
   969 
   970 lemma le_add2: "n \<le> ((m + n)::nat)"
   971 by (insert add_right_mono [of 0 m n], simp)
   972 
   973 lemma le_add1: "n \<le> ((n + m)::nat)"
   974 by (simp add: add_commute, rule le_add2)
   975 
   976 lemma less_add_Suc1: "i < Suc (i + m)"
   977 by (rule le_less_trans, rule le_add1, rule lessI)
   978 
   979 lemma less_add_Suc2: "i < Suc (m + i)"
   980 by (rule le_less_trans, rule le_add2, rule lessI)
   981 
   982 lemma less_iff_Suc_add: "(m < n) = (\<exists>k. n = Suc (m + k))"
   983 by (iprover intro!: less_add_Suc1 less_imp_Suc_add)
   984 
   985 lemma trans_le_add1: "(i::nat) \<le> j ==> i \<le> j + m"
   986 by (rule le_trans, assumption, rule le_add1)
   987 
   988 lemma trans_le_add2: "(i::nat) \<le> j ==> i \<le> m + j"
   989 by (rule le_trans, assumption, rule le_add2)
   990 
   991 lemma trans_less_add1: "(i::nat) < j ==> i < j + m"
   992 by (rule less_le_trans, assumption, rule le_add1)
   993 
   994 lemma trans_less_add2: "(i::nat) < j ==> i < m + j"
   995 by (rule less_le_trans, assumption, rule le_add2)
   996 
   997 lemma add_lessD1: "i + j < (k::nat) ==> i < k"
   998 apply (rule le_less_trans [of _ "i+j"])
   999 apply (simp_all add: le_add1)
  1000 done
  1001 
  1002 lemma not_add_less1 [iff]: "~ (i + j < (i::nat))"
  1003 apply (rule notI)
  1004 apply (drule add_lessD1)
  1005 apply (erule less_irrefl [THEN notE])
  1006 done
  1007 
  1008 lemma not_add_less2 [iff]: "~ (j + i < (i::nat))"
  1009 by (simp add: add_commute)
  1010 
  1011 lemma add_leD1: "m + k \<le> n ==> m \<le> (n::nat)"
  1012 apply (rule order_trans [of _ "m+k"])
  1013 apply (simp_all add: le_add1)
  1014 done
  1015 
  1016 lemma add_leD2: "m + k \<le> n ==> k \<le> (n::nat)"
  1017 apply (simp add: add_commute)
  1018 apply (erule add_leD1)
  1019 done
  1020 
  1021 lemma add_leE: "(m::nat) + k \<le> n ==> (m \<le> n ==> k \<le> n ==> R) ==> R"
  1022 by (blast dest: add_leD1 add_leD2)
  1023 
  1024 text {* needs @{text "!!k"} for @{text add_ac} to work *}
  1025 lemma less_add_eq_less: "!!k::nat. k < l ==> m + l = k + n ==> m < n"
  1026 by (force simp del: add_Suc_right
  1027     simp add: less_iff_Suc_add add_Suc_right [symmetric] add_ac)
  1028 
  1029 
  1030 subsubsection {* More results about difference *}
  1031 
  1032 text {* Addition is the inverse of subtraction:
  1033   if @{term "n \<le> m"} then @{term "n + (m - n) = m"}. *}
  1034 lemma add_diff_inverse: "~  m < n ==> n + (m - n) = (m::nat)"
  1035 by (induct m n rule: diff_induct) simp_all
  1036 
  1037 lemma le_add_diff_inverse [simp]: "n \<le> m ==> n + (m - n) = (m::nat)"
  1038 by (simp add: add_diff_inverse linorder_not_less)
  1039 
  1040 lemma le_add_diff_inverse2 [simp]: "n \<le> m ==> (m - n) + n = (m::nat)"
  1041 by (simp add: add_commute)
  1042 
  1043 lemma Suc_diff_le: "n \<le> m ==> Suc m - n = Suc (m - n)"
  1044 by (induct m n rule: diff_induct) simp_all
  1045 
  1046 lemma diff_less_Suc: "m - n < Suc m"
  1047 apply (induct m n rule: diff_induct)
  1048 apply (erule_tac [3] less_SucE)
  1049 apply (simp_all add: less_Suc_eq)
  1050 done
  1051 
  1052 lemma diff_le_self [simp]: "m - n \<le> (m::nat)"
  1053 by (induct m n rule: diff_induct) (simp_all add: le_SucI)
  1054 
  1055 lemma le_iff_add: "(m::nat) \<le> n = (\<exists>k. n = m + k)"
  1056   by (auto simp: le_add1 dest!: le_add_diff_inverse sym [of _ n])
  1057 
  1058 lemma less_imp_diff_less: "(j::nat) < k ==> j - n < k"
  1059 by (rule le_less_trans, rule diff_le_self)
  1060 
  1061 lemma diff_Suc_less [simp]: "0<n ==> n - Suc i < n"
  1062 by (cases n) (auto simp add: le_simps)
  1063 
  1064 lemma diff_add_assoc: "k \<le> (j::nat) ==> (i + j) - k = i + (j - k)"
  1065 by (induct j k rule: diff_induct) simp_all
  1066 
  1067 lemma diff_add_assoc2: "k \<le> (j::nat) ==> (j + i) - k = (j - k) + i"
  1068 by (simp add: add_commute diff_add_assoc)
  1069 
  1070 lemma le_imp_diff_is_add: "i \<le> (j::nat) ==> (j - i = k) = (j = k + i)"
  1071 by (auto simp add: diff_add_inverse2)
  1072 
  1073 lemma diff_is_0_eq [simp]: "((m::nat) - n = 0) = (m \<le> n)"
  1074 by (induct m n rule: diff_induct) simp_all
  1075 
  1076 lemma diff_is_0_eq' [simp]: "m \<le> n ==> (m::nat) - n = 0"
  1077 by (rule iffD2, rule diff_is_0_eq)
  1078 
  1079 lemma zero_less_diff [simp]: "(0 < n - (m::nat)) = (m < n)"
  1080 by (induct m n rule: diff_induct) simp_all
  1081 
  1082 lemma less_imp_add_positive:
  1083   assumes "i < j"
  1084   shows "\<exists>k::nat. 0 < k & i + k = j"
  1085 proof
  1086   from assms show "0 < j - i & i + (j - i) = j"
  1087     by (simp add: order_less_imp_le)
  1088 qed
  1089 
  1090 text {* a nice rewrite for bounded subtraction *}
  1091 lemma nat_minus_add_max:
  1092   fixes n m :: nat
  1093   shows "n - m + m = max n m"
  1094     by (simp add: max_def not_le order_less_imp_le)
  1095 
  1096 lemma nat_diff_split:
  1097   "P(a - b::nat) = ((a<b --> P 0) & (ALL d. a = b + d --> P d))"
  1098     -- {* elimination of @{text -} on @{text nat} *}
  1099 by (cases "a < b")
  1100   (auto simp add: diff_is_0_eq [THEN iffD2] diff_add_inverse
  1101     not_less le_less dest!: sym [of a] sym [of b] add_eq_self_zero)
  1102 
  1103 lemma nat_diff_split_asm:
  1104   "P(a - b::nat) = (~ (a < b & ~ P 0 | (EX d. a = b + d & ~ P d)))"
  1105     -- {* elimination of @{text -} on @{text nat} in assumptions *}
  1106 by (auto split: nat_diff_split)
  1107 
  1108 
  1109 subsubsection {* Monotonicity of Multiplication *}
  1110 
  1111 lemma mult_le_mono1: "i \<le> (j::nat) ==> i * k \<le> j * k"
  1112 by (simp add: mult_right_mono)
  1113 
  1114 lemma mult_le_mono2: "i \<le> (j::nat) ==> k * i \<le> k * j"
  1115 by (simp add: mult_left_mono)
  1116 
  1117 text {* @{text "\<le>"} monotonicity, BOTH arguments *}
  1118 lemma mult_le_mono: "i \<le> (j::nat) ==> k \<le> l ==> i * k \<le> j * l"
  1119 by (simp add: mult_mono)
  1120 
  1121 lemma mult_less_mono1: "(i::nat) < j ==> 0 < k ==> i * k < j * k"
  1122 by (simp add: mult_strict_right_mono)
  1123 
  1124 text{*Differs from the standard @{text zero_less_mult_iff} in that
  1125       there are no negative numbers.*}
  1126 lemma nat_0_less_mult_iff [simp]: "(0 < (m::nat) * n) = (0 < m & 0 < n)"
  1127   apply (induct m)
  1128    apply simp
  1129   apply (case_tac n)
  1130    apply simp_all
  1131   done
  1132 
  1133 lemma one_le_mult_iff [simp]: "(Suc 0 \<le> m * n) = (Suc 0 \<le> m & Suc 0 \<le> n)"
  1134   apply (induct m)
  1135    apply simp
  1136   apply (case_tac n)
  1137    apply simp_all
  1138   done
  1139 
  1140 lemma mult_less_cancel2 [simp]: "((m::nat) * k < n * k) = (0 < k & m < n)"
  1141   apply (safe intro!: mult_less_mono1)
  1142   apply (case_tac k, auto)
  1143   apply (simp del: le_0_eq add: linorder_not_le [symmetric])
  1144   apply (blast intro: mult_le_mono1)
  1145   done
  1146 
  1147 lemma mult_less_cancel1 [simp]: "(k * (m::nat) < k * n) = (0 < k & m < n)"
  1148 by (simp add: mult_commute [of k])
  1149 
  1150 lemma mult_le_cancel1 [simp]: "(k * (m::nat) \<le> k * n) = (0 < k --> m \<le> n)"
  1151 by (simp add: linorder_not_less [symmetric], auto)
  1152 
  1153 lemma mult_le_cancel2 [simp]: "((m::nat) * k \<le> n * k) = (0 < k --> m \<le> n)"
  1154 by (simp add: linorder_not_less [symmetric], auto)
  1155 
  1156 lemma Suc_mult_less_cancel1: "(Suc k * m < Suc k * n) = (m < n)"
  1157 by (subst mult_less_cancel1) simp
  1158 
  1159 lemma Suc_mult_le_cancel1: "(Suc k * m \<le> Suc k * n) = (m \<le> n)"
  1160 by (subst mult_le_cancel1) simp
  1161 
  1162 lemma le_square: "m \<le> m * (m::nat)"
  1163   by (cases m) (auto intro: le_add1)
  1164 
  1165 lemma le_cube: "(m::nat) \<le> m * (m * m)"
  1166   by (cases m) (auto intro: le_add1)
  1167 
  1168 text {* Lemma for @{text gcd} *}
  1169 lemma mult_eq_self_implies_10: "(m::nat) = m * n ==> n = 1 | m = 0"
  1170   apply (drule sym)
  1171   apply (rule disjCI)
  1172   apply (rule nat_less_cases, erule_tac [2] _)
  1173    apply (drule_tac [2] mult_less_mono2)
  1174     apply (auto)
  1175   done
  1176 
  1177 text {* the lattice order on @{typ nat} *}
  1178 
  1179 instantiation nat :: distrib_lattice
  1180 begin
  1181 
  1182 definition
  1183   "(inf \<Colon> nat \<Rightarrow> nat \<Rightarrow> nat) = min"
  1184 
  1185 definition
  1186   "(sup \<Colon> nat \<Rightarrow> nat \<Rightarrow> nat) = max"
  1187 
  1188 instance by intro_classes
  1189   (auto simp add: inf_nat_def sup_nat_def max_def not_le min_def
  1190     intro: order_less_imp_le antisym elim!: order_trans order_less_trans)
  1191 
  1192 end
  1193 
  1194 
  1195 subsection {* Natural operation of natural numbers on functions *}
  1196 
  1197 text {*
  1198   We use the same logical constant for the power operations on
  1199   functions and relations, in order to share the same syntax.
  1200 *}
  1201 
  1202 consts compow :: "nat \<Rightarrow> ('a \<Rightarrow> 'b) \<Rightarrow> ('a \<Rightarrow> 'b)"
  1203 
  1204 abbreviation compower :: "('a \<Rightarrow> 'b) \<Rightarrow> nat \<Rightarrow> 'a \<Rightarrow> 'b" (infixr "^^" 80) where
  1205   "f ^^ n \<equiv> compow n f"
  1206 
  1207 notation (latex output)
  1208   compower ("(_\<^bsup>_\<^esup>)" [1000] 1000)
  1209 
  1210 notation (HTML output)
  1211   compower ("(_\<^bsup>_\<^esup>)" [1000] 1000)
  1212 
  1213 text {* @{text "f ^^ n = f o ... o f"}, the n-fold composition of @{text f} *}
  1214 
  1215 overloading
  1216   funpow == "compow :: nat \<Rightarrow> ('a \<Rightarrow> 'a) \<Rightarrow> ('a \<Rightarrow> 'a)"
  1217 begin
  1218 
  1219 primrec funpow :: "nat \<Rightarrow> ('a \<Rightarrow> 'a) \<Rightarrow> 'a \<Rightarrow> 'a" where
  1220   "funpow 0 f = id"
  1221 | "funpow (Suc n) f = f o funpow n f"
  1222 
  1223 end
  1224 
  1225 text {* for code generation *}
  1226 
  1227 definition funpow :: "nat \<Rightarrow> ('a \<Rightarrow> 'a) \<Rightarrow> 'a \<Rightarrow> 'a" where
  1228   funpow_code_def [code_post]: "funpow = compow"
  1229 
  1230 lemmas [code_unfold] = funpow_code_def [symmetric]
  1231 
  1232 lemma [code]:
  1233   "funpow (Suc n) f = f o funpow n f"
  1234   "funpow 0 f = id"
  1235   by (simp_all add: funpow_code_def)
  1236 
  1237 hide_const (open) funpow
  1238 
  1239 lemma funpow_add:
  1240   "f ^^ (m + n) = f ^^ m \<circ> f ^^ n"
  1241   by (induct m) simp_all
  1242 
  1243 lemma funpow_mult:
  1244   fixes f :: "'a \<Rightarrow> 'a"
  1245   shows "(f ^^ m) ^^ n = f ^^ (m * n)"
  1246   by (induct n) (simp_all add: funpow_add)
  1247 
  1248 lemma funpow_swap1:
  1249   "f ((f ^^ n) x) = (f ^^ n) (f x)"
  1250 proof -
  1251   have "f ((f ^^ n) x) = (f ^^ (n + 1)) x" by simp
  1252   also have "\<dots>  = (f ^^ n o f ^^ 1) x" by (simp only: funpow_add)
  1253   also have "\<dots> = (f ^^ n) (f x)" by simp
  1254   finally show ?thesis .
  1255 qed
  1256 
  1257 lemma comp_funpow:
  1258   fixes f :: "'a \<Rightarrow> 'a"
  1259   shows "comp f ^^ n = comp (f ^^ n)"
  1260   by (induct n) simp_all
  1261 
  1262 
  1263 subsection {* Embedding of the Naturals into any @{text semiring_1}: @{term of_nat} *}
  1264 
  1265 context semiring_1
  1266 begin
  1267 
  1268 definition of_nat :: "nat \<Rightarrow> 'a" where
  1269   "of_nat n = (plus 1 ^^ n) 0"
  1270 
  1271 lemma of_nat_simps [simp]:
  1272   shows of_nat_0: "of_nat 0 = 0"
  1273     and of_nat_Suc: "of_nat (Suc m) = 1 + of_nat m"
  1274   by (simp_all add: of_nat_def)
  1275 
  1276 lemma of_nat_1 [simp]: "of_nat 1 = 1"
  1277   by (simp add: of_nat_def)
  1278 
  1279 lemma of_nat_add [simp]: "of_nat (m + n) = of_nat m + of_nat n"
  1280   by (induct m) (simp_all add: add_ac)
  1281 
  1282 lemma of_nat_mult: "of_nat (m * n) = of_nat m * of_nat n"
  1283   by (induct m) (simp_all add: add_ac left_distrib)
  1284 
  1285 primrec of_nat_aux :: "('a \<Rightarrow> 'a) \<Rightarrow> nat \<Rightarrow> 'a \<Rightarrow> 'a" where
  1286   "of_nat_aux inc 0 i = i"
  1287 | "of_nat_aux inc (Suc n) i = of_nat_aux inc n (inc i)" -- {* tail recursive *}
  1288 
  1289 lemma of_nat_code:
  1290   "of_nat n = of_nat_aux (\<lambda>i. i + 1) n 0"
  1291 proof (induct n)
  1292   case 0 then show ?case by simp
  1293 next
  1294   case (Suc n)
  1295   have "\<And>i. of_nat_aux (\<lambda>i. i + 1) n (i + 1) = of_nat_aux (\<lambda>i. i + 1) n i + 1"
  1296     by (induct n) simp_all
  1297   from this [of 0] have "of_nat_aux (\<lambda>i. i + 1) n 1 = of_nat_aux (\<lambda>i. i + 1) n 0 + 1"
  1298     by simp
  1299   with Suc show ?case by (simp add: add_commute)
  1300 qed
  1301 
  1302 end
  1303 
  1304 declare of_nat_code [code, code_unfold, code_inline del]
  1305 
  1306 text{*Class for unital semirings with characteristic zero.
  1307  Includes non-ordered rings like the complex numbers.*}
  1308 
  1309 class semiring_char_0 = semiring_1 +
  1310   assumes inj_of_nat: "inj of_nat"
  1311 begin
  1312 
  1313 lemma of_nat_eq_iff [simp]: "of_nat m = of_nat n \<longleftrightarrow> m = n"
  1314   by (auto intro: inj_of_nat injD)
  1315 
  1316 text{*Special cases where either operand is zero*}
  1317 
  1318 lemma of_nat_0_eq_iff [simp, no_atp]: "0 = of_nat n \<longleftrightarrow> 0 = n"
  1319   by (fact of_nat_eq_iff [of 0 n, unfolded of_nat_0])
  1320 
  1321 lemma of_nat_eq_0_iff [simp, no_atp]: "of_nat m = 0 \<longleftrightarrow> m = 0"
  1322   by (fact of_nat_eq_iff [of m 0, unfolded of_nat_0])
  1323 
  1324 end
  1325 
  1326 context linordered_semidom
  1327 begin
  1328 
  1329 lemma zero_le_imp_of_nat: "0 \<le> of_nat m"
  1330   by (induct m) simp_all
  1331 
  1332 lemma less_imp_of_nat_less: "m < n \<Longrightarrow> of_nat m < of_nat n"
  1333   apply (induct m n rule: diff_induct, simp_all)
  1334   apply (rule add_pos_nonneg [OF zero_less_one zero_le_imp_of_nat])
  1335   done
  1336 
  1337 lemma of_nat_less_imp_less: "of_nat m < of_nat n \<Longrightarrow> m < n"
  1338   apply (induct m n rule: diff_induct, simp_all)
  1339   apply (insert zero_le_imp_of_nat)
  1340   apply (force simp add: not_less [symmetric])
  1341   done
  1342 
  1343 lemma of_nat_less_iff [simp]: "of_nat m < of_nat n \<longleftrightarrow> m < n"
  1344   by (blast intro: of_nat_less_imp_less less_imp_of_nat_less)
  1345 
  1346 lemma of_nat_le_iff [simp]: "of_nat m \<le> of_nat n \<longleftrightarrow> m \<le> n"
  1347   by (simp add: not_less [symmetric] linorder_not_less [symmetric])
  1348 
  1349 text{*Every @{text linordered_semidom} has characteristic zero.*}
  1350 
  1351 subclass semiring_char_0 proof
  1352 qed (auto intro!: injI simp add: eq_iff)
  1353 
  1354 text{*Special cases where either operand is zero*}
  1355 
  1356 lemma of_nat_0_le_iff [simp]: "0 \<le> of_nat n"
  1357   by (rule of_nat_le_iff [of 0, simplified])
  1358 
  1359 lemma of_nat_le_0_iff [simp, no_atp]: "of_nat m \<le> 0 \<longleftrightarrow> m = 0"
  1360   by (rule of_nat_le_iff [of _ 0, simplified])
  1361 
  1362 lemma of_nat_0_less_iff [simp]: "0 < of_nat n \<longleftrightarrow> 0 < n"
  1363   by (rule of_nat_less_iff [of 0, simplified])
  1364 
  1365 lemma of_nat_less_0_iff [simp]: "\<not> of_nat m < 0"
  1366   by (rule of_nat_less_iff [of _ 0, simplified])
  1367 
  1368 end
  1369 
  1370 context ring_1
  1371 begin
  1372 
  1373 lemma of_nat_diff: "n \<le> m \<Longrightarrow> of_nat (m - n) = of_nat m - of_nat n"
  1374 by (simp add: algebra_simps of_nat_add [symmetric])
  1375 
  1376 end
  1377 
  1378 context linordered_idom
  1379 begin
  1380 
  1381 lemma abs_of_nat [simp]: "\<bar>of_nat n\<bar> = of_nat n"
  1382   unfolding abs_if by auto
  1383 
  1384 end
  1385 
  1386 lemma of_nat_id [simp]: "of_nat n = n"
  1387   by (induct n) simp_all
  1388 
  1389 lemma of_nat_eq_id [simp]: "of_nat = id"
  1390   by (auto simp add: fun_eq_iff)
  1391 
  1392 
  1393 subsection {* The Set of Natural Numbers *}
  1394 
  1395 context semiring_1
  1396 begin
  1397 
  1398 definition Nats  :: "'a set" where
  1399   "Nats = range of_nat"
  1400 
  1401 notation (xsymbols)
  1402   Nats  ("\<nat>")
  1403 
  1404 lemma of_nat_in_Nats [simp]: "of_nat n \<in> \<nat>"
  1405   by (simp add: Nats_def)
  1406 
  1407 lemma Nats_0 [simp]: "0 \<in> \<nat>"
  1408 apply (simp add: Nats_def)
  1409 apply (rule range_eqI)
  1410 apply (rule of_nat_0 [symmetric])
  1411 done
  1412 
  1413 lemma Nats_1 [simp]: "1 \<in> \<nat>"
  1414 apply (simp add: Nats_def)
  1415 apply (rule range_eqI)
  1416 apply (rule of_nat_1 [symmetric])
  1417 done
  1418 
  1419 lemma Nats_add [simp]: "a \<in> \<nat> \<Longrightarrow> b \<in> \<nat> \<Longrightarrow> a + b \<in> \<nat>"
  1420 apply (auto simp add: Nats_def)
  1421 apply (rule range_eqI)
  1422 apply (rule of_nat_add [symmetric])
  1423 done
  1424 
  1425 lemma Nats_mult [simp]: "a \<in> \<nat> \<Longrightarrow> b \<in> \<nat> \<Longrightarrow> a * b \<in> \<nat>"
  1426 apply (auto simp add: Nats_def)
  1427 apply (rule range_eqI)
  1428 apply (rule of_nat_mult [symmetric])
  1429 done
  1430 
  1431 lemma Nats_cases [cases set: Nats]:
  1432   assumes "x \<in> \<nat>"
  1433   obtains (of_nat) n where "x = of_nat n"
  1434   unfolding Nats_def
  1435 proof -
  1436   from `x \<in> \<nat>` have "x \<in> range of_nat" unfolding Nats_def .
  1437   then obtain n where "x = of_nat n" ..
  1438   then show thesis ..
  1439 qed
  1440 
  1441 lemma Nats_induct [case_names of_nat, induct set: Nats]:
  1442   "x \<in> \<nat> \<Longrightarrow> (\<And>n. P (of_nat n)) \<Longrightarrow> P x"
  1443   by (rule Nats_cases) auto
  1444 
  1445 end
  1446 
  1447 
  1448 subsection {* Further Arithmetic Facts Concerning the Natural Numbers *}
  1449 
  1450 lemma subst_equals:
  1451   assumes 1: "t = s" and 2: "u = t"
  1452   shows "u = s"
  1453   using 2 1 by (rule trans)
  1454 
  1455 setup Arith_Data.setup
  1456 
  1457 use "Tools/nat_arith.ML"
  1458 declaration {* K Nat_Arith.setup *}
  1459 
  1460 use "Tools/lin_arith.ML"
  1461 setup {* Lin_Arith.global_setup *}
  1462 declaration {* K Lin_Arith.setup *}
  1463 
  1464 simproc_setup fast_arith_nat ("(m::nat) < n" | "(m::nat) <= n" | "(m::nat) = n") =
  1465   {* fn _ => fn ss => fn ct => Lin_Arith.simproc ss (term_of ct) *}
  1466 (* Because of this simproc, the arithmetic solver is really only
  1467 useful to detect inconsistencies among the premises for subgoals which are
  1468 *not* themselves (in)equalities, because the latter activate
  1469 fast_nat_arith_simproc anyway. However, it seems cheaper to activate the
  1470 solver all the time rather than add the additional check. *)
  1471 
  1472 
  1473 lemmas [arith_split] = nat_diff_split split_min split_max
  1474 
  1475 context order
  1476 begin
  1477 
  1478 lemma lift_Suc_mono_le:
  1479   assumes mono: "!!n. f n \<le> f(Suc n)" and "n\<le>n'"
  1480   shows "f n \<le> f n'"
  1481 proof (cases "n < n'")
  1482   case True
  1483   thus ?thesis
  1484     by (induct n n' rule: less_Suc_induct[consumes 1]) (auto intro: mono)
  1485 qed (insert `n \<le> n'`, auto) -- {*trivial for @{prop "n = n'"} *}
  1486 
  1487 lemma lift_Suc_mono_less:
  1488   assumes mono: "!!n. f n < f(Suc n)" and "n < n'"
  1489   shows "f n < f n'"
  1490 using `n < n'`
  1491 by (induct n n' rule: less_Suc_induct[consumes 1]) (auto intro: mono)
  1492 
  1493 lemma lift_Suc_mono_less_iff:
  1494   "(!!n. f n < f(Suc n)) \<Longrightarrow> f(n) < f(m) \<longleftrightarrow> n<m"
  1495 by(blast intro: less_asym' lift_Suc_mono_less[of f]
  1496          dest: linorder_not_less[THEN iffD1] le_eq_less_or_eq[THEN iffD1])
  1497 
  1498 end
  1499 
  1500 lemma mono_iff_le_Suc: "mono f = (\<forall>n. f n \<le> f (Suc n))"
  1501   unfolding mono_def by (auto intro: lift_Suc_mono_le [of f])
  1502 
  1503 lemma mono_nat_linear_lb:
  1504   "(!!m n::nat. m<n \<Longrightarrow> f m < f n) \<Longrightarrow> f(m)+k \<le> f(m+k)"
  1505 apply(induct_tac k)
  1506  apply simp
  1507 apply(erule_tac x="m+n" in meta_allE)
  1508 apply(erule_tac x="Suc(m+n)" in meta_allE)
  1509 apply simp
  1510 done
  1511 
  1512 
  1513 text{*Subtraction laws, mostly by Clemens Ballarin*}
  1514 
  1515 lemma diff_less_mono: "[| a < (b::nat); c \<le> a |] ==> a-c < b-c"
  1516 by arith
  1517 
  1518 lemma less_diff_conv: "(i < j-k) = (i+k < (j::nat))"
  1519 by arith
  1520 
  1521 lemma le_diff_conv: "(j-k \<le> (i::nat)) = (j \<le> i+k)"
  1522 by arith
  1523 
  1524 lemma le_diff_conv2: "k \<le> j ==> (i \<le> j-k) = (i+k \<le> (j::nat))"
  1525 by arith
  1526 
  1527 lemma diff_diff_cancel [simp]: "i \<le> (n::nat) ==> n - (n - i) = i"
  1528 by arith
  1529 
  1530 lemma le_add_diff: "k \<le> (n::nat) ==> m \<le> n + m - k"
  1531 by arith
  1532 
  1533 (*Replaces the previous diff_less and le_diff_less, which had the stronger
  1534   second premise n\<le>m*)
  1535 lemma diff_less[simp]: "!!m::nat. [| 0<n; 0<m |] ==> m - n < m"
  1536 by arith
  1537 
  1538 text {* Simplification of relational expressions involving subtraction *}
  1539 
  1540 lemma diff_diff_eq: "[| k \<le> m;  k \<le> (n::nat) |] ==> ((m-k) - (n-k)) = (m-n)"
  1541 by (simp split add: nat_diff_split)
  1542 
  1543 hide_fact (open) diff_diff_eq
  1544 
  1545 lemma eq_diff_iff: "[| k \<le> m;  k \<le> (n::nat) |] ==> (m-k = n-k) = (m=n)"
  1546 by (auto split add: nat_diff_split)
  1547 
  1548 lemma less_diff_iff: "[| k \<le> m;  k \<le> (n::nat) |] ==> (m-k < n-k) = (m<n)"
  1549 by (auto split add: nat_diff_split)
  1550 
  1551 lemma le_diff_iff: "[| k \<le> m;  k \<le> (n::nat) |] ==> (m-k \<le> n-k) = (m\<le>n)"
  1552 by (auto split add: nat_diff_split)
  1553 
  1554 text{*(Anti)Monotonicity of subtraction -- by Stephan Merz*}
  1555 
  1556 (* Monotonicity of subtraction in first argument *)
  1557 lemma diff_le_mono: "m \<le> (n::nat) ==> (m-l) \<le> (n-l)"
  1558 by (simp split add: nat_diff_split)
  1559 
  1560 lemma diff_le_mono2: "m \<le> (n::nat) ==> (l-n) \<le> (l-m)"
  1561 by (simp split add: nat_diff_split)
  1562 
  1563 lemma diff_less_mono2: "[| m < (n::nat); m<l |] ==> (l-n) < (l-m)"
  1564 by (simp split add: nat_diff_split)
  1565 
  1566 lemma diffs0_imp_equal: "!!m::nat. [| m-n = 0; n-m = 0 |] ==>  m=n"
  1567 by (simp split add: nat_diff_split)
  1568 
  1569 lemma min_diff: "min (m - (i::nat)) (n - i) = min m n - i"
  1570 by auto
  1571 
  1572 lemma inj_on_diff_nat: 
  1573   assumes k_le_n: "\<forall>n \<in> N. k \<le> (n::nat)"
  1574   shows "inj_on (\<lambda>n. n - k) N"
  1575 proof (rule inj_onI)
  1576   fix x y
  1577   assume a: "x \<in> N" "y \<in> N" "x - k = y - k"
  1578   with k_le_n have "x - k + k = y - k + k" by auto
  1579   with a k_le_n show "x = y" by auto
  1580 qed
  1581 
  1582 text{*Rewriting to pull differences out*}
  1583 
  1584 lemma diff_diff_right [simp]: "k\<le>j --> i - (j - k) = i + (k::nat) - j"
  1585 by arith
  1586 
  1587 lemma diff_Suc_diff_eq1 [simp]: "k \<le> j ==> m - Suc (j - k) = m + k - Suc j"
  1588 by arith
  1589 
  1590 lemma diff_Suc_diff_eq2 [simp]: "k \<le> j ==> Suc (j - k) - m = Suc j - (k + m)"
  1591 by arith
  1592 
  1593 text{*Lemmas for ex/Factorization*}
  1594 
  1595 lemma one_less_mult: "[| Suc 0 < n; Suc 0 < m |] ==> Suc 0 < m*n"
  1596 by (cases m) auto
  1597 
  1598 lemma n_less_m_mult_n: "[| Suc 0 < n; Suc 0 < m |] ==> n<m*n"
  1599 by (cases m) auto
  1600 
  1601 lemma n_less_n_mult_m: "[| Suc 0 < n; Suc 0 < m |] ==> n<n*m"
  1602 by (cases m) auto
  1603 
  1604 text {* Specialized induction principles that work "backwards": *}
  1605 
  1606 lemma inc_induct[consumes 1, case_names base step]:
  1607   assumes less: "i <= j"
  1608   assumes base: "P j"
  1609   assumes step: "!!i. [| i < j; P (Suc i) |] ==> P i"
  1610   shows "P i"
  1611   using less
  1612 proof (induct d=="j - i" arbitrary: i)
  1613   case (0 i)
  1614   hence "i = j" by simp
  1615   with base show ?case by simp
  1616 next
  1617   case (Suc d i)
  1618   hence "i < j" "P (Suc i)"
  1619     by simp_all
  1620   thus "P i" by (rule step)
  1621 qed
  1622 
  1623 lemma strict_inc_induct[consumes 1, case_names base step]:
  1624   assumes less: "i < j"
  1625   assumes base: "!!i. j = Suc i ==> P i"
  1626   assumes step: "!!i. [| i < j; P (Suc i) |] ==> P i"
  1627   shows "P i"
  1628   using less
  1629 proof (induct d=="j - i - 1" arbitrary: i)
  1630   case (0 i)
  1631   with `i < j` have "j = Suc i" by simp
  1632   with base show ?case by simp
  1633 next
  1634   case (Suc d i)
  1635   hence "i < j" "P (Suc i)"
  1636     by simp_all
  1637   thus "P i" by (rule step)
  1638 qed
  1639 
  1640 lemma zero_induct_lemma: "P k ==> (!!n. P (Suc n) ==> P n) ==> P (k - i)"
  1641   using inc_induct[of "k - i" k P, simplified] by blast
  1642 
  1643 lemma zero_induct: "P k ==> (!!n. P (Suc n) ==> P n) ==> P 0"
  1644   using inc_induct[of 0 k P] by blast
  1645 
  1646 (*The others are
  1647       i - j - k = i - (j + k),
  1648       k \<le> j ==> j - k + i = j + i - k,
  1649       k \<le> j ==> i + (j - k) = i + j - k *)
  1650 lemmas add_diff_assoc = diff_add_assoc [symmetric]
  1651 lemmas add_diff_assoc2 = diff_add_assoc2[symmetric]
  1652 declare diff_diff_left [simp]  add_diff_assoc [simp] add_diff_assoc2[simp]
  1653 
  1654 text{*At present we prove no analogue of @{text not_less_Least} or @{text
  1655 Least_Suc}, since there appears to be no need.*}
  1656 
  1657 
  1658 subsection {* The divides relation on @{typ nat} *}
  1659 
  1660 lemma dvd_1_left [iff]: "Suc 0 dvd k"
  1661 unfolding dvd_def by simp
  1662 
  1663 lemma dvd_1_iff_1 [simp]: "(m dvd Suc 0) = (m = Suc 0)"
  1664 by (simp add: dvd_def)
  1665 
  1666 lemma nat_dvd_1_iff_1 [simp]: "m dvd (1::nat) \<longleftrightarrow> m = 1"
  1667 by (simp add: dvd_def)
  1668 
  1669 lemma dvd_antisym: "[| m dvd n; n dvd m |] ==> m = (n::nat)"
  1670   unfolding dvd_def
  1671   by (force dest: mult_eq_self_implies_10 simp add: mult_assoc)
  1672 
  1673 text {* @{term "op dvd"} is a partial order *}
  1674 
  1675 interpretation dvd: order "op dvd" "\<lambda>n m \<Colon> nat. n dvd m \<and> \<not> m dvd n"
  1676   proof qed (auto intro: dvd_refl dvd_trans dvd_antisym)
  1677 
  1678 lemma dvd_diff_nat[simp]: "[| k dvd m; k dvd n |] ==> k dvd (m-n :: nat)"
  1679 unfolding dvd_def
  1680 by (blast intro: diff_mult_distrib2 [symmetric])
  1681 
  1682 lemma dvd_diffD: "[| k dvd m-n; k dvd n; n\<le>m |] ==> k dvd (m::nat)"
  1683   apply (erule linorder_not_less [THEN iffD2, THEN add_diff_inverse, THEN subst])
  1684   apply (blast intro: dvd_add)
  1685   done
  1686 
  1687 lemma dvd_diffD1: "[| k dvd m-n; k dvd m; n\<le>m |] ==> k dvd (n::nat)"
  1688 by (drule_tac m = m in dvd_diff_nat, auto)
  1689 
  1690 lemma dvd_reduce: "(k dvd n + k) = (k dvd (n::nat))"
  1691   apply (rule iffI)
  1692    apply (erule_tac [2] dvd_add)
  1693    apply (rule_tac [2] dvd_refl)
  1694   apply (subgoal_tac "n = (n+k) -k")
  1695    prefer 2 apply simp
  1696   apply (erule ssubst)
  1697   apply (erule dvd_diff_nat)
  1698   apply (rule dvd_refl)
  1699   done
  1700 
  1701 lemma dvd_mult_cancel: "!!k::nat. [| k*m dvd k*n; 0<k |] ==> m dvd n"
  1702   unfolding dvd_def
  1703   apply (erule exE)
  1704   apply (simp add: mult_ac)
  1705   done
  1706 
  1707 lemma dvd_mult_cancel1: "0<m ==> (m*n dvd m) = (n = (1::nat))"
  1708   apply auto
  1709    apply (subgoal_tac "m*n dvd m*1")
  1710    apply (drule dvd_mult_cancel, auto)
  1711   done
  1712 
  1713 lemma dvd_mult_cancel2: "0<m ==> (n*m dvd m) = (n = (1::nat))"
  1714   apply (subst mult_commute)
  1715   apply (erule dvd_mult_cancel1)
  1716   done
  1717 
  1718 lemma dvd_imp_le: "[| k dvd n; 0 < n |] ==> k \<le> (n::nat)"
  1719 by (auto elim!: dvdE) (auto simp add: gr0_conv_Suc)
  1720 
  1721 lemma nat_dvd_not_less:
  1722   fixes m n :: nat
  1723   shows "0 < m \<Longrightarrow> m < n \<Longrightarrow> \<not> n dvd m"
  1724 by (auto elim!: dvdE) (auto simp add: gr0_conv_Suc)
  1725 
  1726 
  1727 subsection {* aliasses *}
  1728 
  1729 lemma nat_mult_1: "(1::nat) * n = n"
  1730   by simp
  1731  
  1732 lemma nat_mult_1_right: "n * (1::nat) = n"
  1733   by simp
  1734 
  1735 
  1736 subsection {* size of a datatype value *}
  1737 
  1738 class size =
  1739   fixes size :: "'a \<Rightarrow> nat" -- {* see further theory @{text Wellfounded} *}
  1740 
  1741 
  1742 subsection {* code module namespace *}
  1743 
  1744 code_modulename SML
  1745   Nat Arith
  1746 
  1747 code_modulename OCaml
  1748   Nat Arith
  1749 
  1750 code_modulename Haskell
  1751   Nat Arith
  1752 
  1753 end