src/HOL/SetInterval.thy
author nipkow
Thu Jul 07 12:39:17 2005 +0200 (2005-07-07)
changeset 16733 236dfafbeb63
parent 16102 c5f6726d9bb1
child 17149 e2b19c92ef51
permissions -rw-r--r--
linear arithmetic now takes "&" in assumptions apart.
     1 (*  Title:      HOL/SetInterval.thy
     2     ID:         $Id$
     3     Author:     Tobias Nipkow and Clemens Ballarin
     4                 Additions by Jeremy Avigad in March 2004
     5     Copyright   2000  TU Muenchen
     6 
     7 lessThan, greaterThan, atLeast, atMost and two-sided intervals
     8 *)
     9 
    10 header {* Set intervals *}
    11 
    12 theory SetInterval
    13 imports IntArith
    14 begin
    15 
    16 constdefs
    17   lessThan    :: "('a::ord) => 'a set"	("(1{..<_})")
    18   "{..<u} == {x. x<u}"
    19 
    20   atMost      :: "('a::ord) => 'a set"	("(1{.._})")
    21   "{..u} == {x. x<=u}"
    22 
    23   greaterThan :: "('a::ord) => 'a set"	("(1{_<..})")
    24   "{l<..} == {x. l<x}"
    25 
    26   atLeast     :: "('a::ord) => 'a set"	("(1{_..})")
    27   "{l..} == {x. l<=x}"
    28 
    29   greaterThanLessThan :: "['a::ord, 'a] => 'a set"  ("(1{_<..<_})")
    30   "{l<..<u} == {l<..} Int {..<u}"
    31 
    32   atLeastLessThan :: "['a::ord, 'a] => 'a set"      ("(1{_..<_})")
    33   "{l..<u} == {l..} Int {..<u}"
    34 
    35   greaterThanAtMost :: "['a::ord, 'a] => 'a set"    ("(1{_<.._})")
    36   "{l<..u} == {l<..} Int {..u}"
    37 
    38   atLeastAtMost :: "['a::ord, 'a] => 'a set"        ("(1{_.._})")
    39   "{l..u} == {l..} Int {..u}"
    40 
    41 (* Old syntax, will disappear! *)
    42 syntax
    43   "_lessThan"    :: "('a::ord) => 'a set"	("(1{.._'(})")
    44   "_greaterThan" :: "('a::ord) => 'a set"	("(1{')_..})")
    45   "_greaterThanLessThan" :: "['a::ord, 'a] => 'a set"  ("(1{')_.._'(})")
    46   "_atLeastLessThan" :: "['a::ord, 'a] => 'a set"      ("(1{_.._'(})")
    47   "_greaterThanAtMost" :: "['a::ord, 'a] => 'a set"    ("(1{')_.._})")
    48 translations
    49   "{..m(}" => "{..<m}"
    50   "{)m..}" => "{m<..}"
    51   "{)m..n(}" => "{m<..<n}"
    52   "{m..n(}" => "{m..<n}"
    53   "{)m..n}" => "{m<..n}"
    54 
    55 
    56 text{* A note of warning when using @{term"{..<n}"} on type @{typ
    57 nat}: it is equivalent to @{term"{0::nat..<n}"} but some lemmas involving
    58 @{term"{m..<n}"} may not exist in @{term"{..<n}"}-form as well. *}
    59 
    60 syntax
    61   "@UNION_le"   :: "nat => nat => 'b set => 'b set"       ("(3UN _<=_./ _)" 10)
    62   "@UNION_less" :: "nat => nat => 'b set => 'b set"       ("(3UN _<_./ _)" 10)
    63   "@INTER_le"   :: "nat => nat => 'b set => 'b set"       ("(3INT _<=_./ _)" 10)
    64   "@INTER_less" :: "nat => nat => 'b set => 'b set"       ("(3INT _<_./ _)" 10)
    65 
    66 syntax (input)
    67   "@UNION_le"   :: "nat => nat => 'b set => 'b set"       ("(3\<Union> _\<le>_./ _)" 10)
    68   "@UNION_less" :: "nat => nat => 'b set => 'b set"       ("(3\<Union> _<_./ _)" 10)
    69   "@INTER_le"   :: "nat => nat => 'b set => 'b set"       ("(3\<Inter> _\<le>_./ _)" 10)
    70   "@INTER_less" :: "nat => nat => 'b set => 'b set"       ("(3\<Inter> _<_./ _)" 10)
    71 
    72 syntax (xsymbols)
    73   "@UNION_le"   :: "nat \<Rightarrow> nat => 'b set => 'b set"       ("(3\<Union>(00\<^bsub>_ \<le> _\<^esub>)/ _)" 10)
    74   "@UNION_less" :: "nat \<Rightarrow> nat => 'b set => 'b set"       ("(3\<Union>(00\<^bsub>_ < _\<^esub>)/ _)" 10)
    75   "@INTER_le"   :: "nat \<Rightarrow> nat => 'b set => 'b set"       ("(3\<Inter>(00\<^bsub>_ \<le> _\<^esub>)/ _)" 10)
    76   "@INTER_less" :: "nat \<Rightarrow> nat => 'b set => 'b set"       ("(3\<Inter>(00\<^bsub>_ < _\<^esub>)/ _)" 10)
    77 
    78 translations
    79   "UN i<=n. A"  == "UN i:{..n}. A"
    80   "UN i<n. A"   == "UN i:{..<n}. A"
    81   "INT i<=n. A" == "INT i:{..n}. A"
    82   "INT i<n. A"  == "INT i:{..<n}. A"
    83 
    84 
    85 subsection {* Various equivalences *}
    86 
    87 lemma lessThan_iff [iff]: "(i: lessThan k) = (i<k)"
    88 by (simp add: lessThan_def)
    89 
    90 lemma Compl_lessThan [simp]:
    91     "!!k:: 'a::linorder. -lessThan k = atLeast k"
    92 apply (auto simp add: lessThan_def atLeast_def)
    93 done
    94 
    95 lemma single_Diff_lessThan [simp]: "!!k:: 'a::order. {k} - lessThan k = {k}"
    96 by auto
    97 
    98 lemma greaterThan_iff [iff]: "(i: greaterThan k) = (k<i)"
    99 by (simp add: greaterThan_def)
   100 
   101 lemma Compl_greaterThan [simp]:
   102     "!!k:: 'a::linorder. -greaterThan k = atMost k"
   103 apply (simp add: greaterThan_def atMost_def le_def, auto)
   104 done
   105 
   106 lemma Compl_atMost [simp]: "!!k:: 'a::linorder. -atMost k = greaterThan k"
   107 apply (subst Compl_greaterThan [symmetric])
   108 apply (rule double_complement)
   109 done
   110 
   111 lemma atLeast_iff [iff]: "(i: atLeast k) = (k<=i)"
   112 by (simp add: atLeast_def)
   113 
   114 lemma Compl_atLeast [simp]:
   115     "!!k:: 'a::linorder. -atLeast k = lessThan k"
   116 apply (simp add: lessThan_def atLeast_def le_def, auto)
   117 done
   118 
   119 lemma atMost_iff [iff]: "(i: atMost k) = (i<=k)"
   120 by (simp add: atMost_def)
   121 
   122 lemma atMost_Int_atLeast: "!!n:: 'a::order. atMost n Int atLeast n = {n}"
   123 by (blast intro: order_antisym)
   124 
   125 
   126 subsection {* Logical Equivalences for Set Inclusion and Equality *}
   127 
   128 lemma atLeast_subset_iff [iff]:
   129      "(atLeast x \<subseteq> atLeast y) = (y \<le> (x::'a::order))"
   130 by (blast intro: order_trans)
   131 
   132 lemma atLeast_eq_iff [iff]:
   133      "(atLeast x = atLeast y) = (x = (y::'a::linorder))"
   134 by (blast intro: order_antisym order_trans)
   135 
   136 lemma greaterThan_subset_iff [iff]:
   137      "(greaterThan x \<subseteq> greaterThan y) = (y \<le> (x::'a::linorder))"
   138 apply (auto simp add: greaterThan_def)
   139  apply (subst linorder_not_less [symmetric], blast)
   140 done
   141 
   142 lemma greaterThan_eq_iff [iff]:
   143      "(greaterThan x = greaterThan y) = (x = (y::'a::linorder))"
   144 apply (rule iffI)
   145  apply (erule equalityE)
   146  apply (simp_all add: greaterThan_subset_iff)
   147 done
   148 
   149 lemma atMost_subset_iff [iff]: "(atMost x \<subseteq> atMost y) = (x \<le> (y::'a::order))"
   150 by (blast intro: order_trans)
   151 
   152 lemma atMost_eq_iff [iff]: "(atMost x = atMost y) = (x = (y::'a::linorder))"
   153 by (blast intro: order_antisym order_trans)
   154 
   155 lemma lessThan_subset_iff [iff]:
   156      "(lessThan x \<subseteq> lessThan y) = (x \<le> (y::'a::linorder))"
   157 apply (auto simp add: lessThan_def)
   158  apply (subst linorder_not_less [symmetric], blast)
   159 done
   160 
   161 lemma lessThan_eq_iff [iff]:
   162      "(lessThan x = lessThan y) = (x = (y::'a::linorder))"
   163 apply (rule iffI)
   164  apply (erule equalityE)
   165  apply (simp_all add: lessThan_subset_iff)
   166 done
   167 
   168 
   169 subsection {*Two-sided intervals*}
   170 
   171 lemma greaterThanLessThan_iff [simp]:
   172   "(i : {l<..<u}) = (l < i & i < u)"
   173 by (simp add: greaterThanLessThan_def)
   174 
   175 lemma atLeastLessThan_iff [simp]:
   176   "(i : {l..<u}) = (l <= i & i < u)"
   177 by (simp add: atLeastLessThan_def)
   178 
   179 lemma greaterThanAtMost_iff [simp]:
   180   "(i : {l<..u}) = (l < i & i <= u)"
   181 by (simp add: greaterThanAtMost_def)
   182 
   183 lemma atLeastAtMost_iff [simp]:
   184   "(i : {l..u}) = (l <= i & i <= u)"
   185 by (simp add: atLeastAtMost_def)
   186 
   187 text {* The above four lemmas could be declared as iffs.
   188   If we do so, a call to blast in Hyperreal/Star.ML, lemma @{text STAR_Int}
   189   seems to take forever (more than one hour). *}
   190 
   191 subsubsection{* Emptyness and singletons *}
   192 
   193 lemma atLeastAtMost_empty [simp]: "n < m ==> {m::'a::order..n} = {}";
   194   by (auto simp add: atLeastAtMost_def atMost_def atLeast_def);
   195 
   196 lemma atLeastLessThan_empty[simp]: "n \<le> m ==> {m..<n::'a::order} = {}"
   197 by (auto simp add: atLeastLessThan_def)
   198 
   199 lemma atLeastAtMost_singleton [simp]: "{a::'a::order..a} = {a}";
   200   by (auto simp add: atLeastAtMost_def atMost_def atLeast_def);
   201 
   202 subsection {* Intervals of natural numbers *}
   203 
   204 subsubsection {* The Constant @{term lessThan} *}
   205 
   206 lemma lessThan_0 [simp]: "lessThan (0::nat) = {}"
   207 by (simp add: lessThan_def)
   208 
   209 lemma lessThan_Suc: "lessThan (Suc k) = insert k (lessThan k)"
   210 by (simp add: lessThan_def less_Suc_eq, blast)
   211 
   212 lemma lessThan_Suc_atMost: "lessThan (Suc k) = atMost k"
   213 by (simp add: lessThan_def atMost_def less_Suc_eq_le)
   214 
   215 lemma UN_lessThan_UNIV: "(UN m::nat. lessThan m) = UNIV"
   216 by blast
   217 
   218 subsubsection {* The Constant @{term greaterThan} *}
   219 
   220 lemma greaterThan_0 [simp]: "greaterThan 0 = range Suc"
   221 apply (simp add: greaterThan_def)
   222 apply (blast dest: gr0_conv_Suc [THEN iffD1])
   223 done
   224 
   225 lemma greaterThan_Suc: "greaterThan (Suc k) = greaterThan k - {Suc k}"
   226 apply (simp add: greaterThan_def)
   227 apply (auto elim: linorder_neqE)
   228 done
   229 
   230 lemma INT_greaterThan_UNIV: "(INT m::nat. greaterThan m) = {}"
   231 by blast
   232 
   233 subsubsection {* The Constant @{term atLeast} *}
   234 
   235 lemma atLeast_0 [simp]: "atLeast (0::nat) = UNIV"
   236 by (unfold atLeast_def UNIV_def, simp)
   237 
   238 lemma atLeast_Suc: "atLeast (Suc k) = atLeast k - {k}"
   239 apply (simp add: atLeast_def)
   240 apply (simp add: Suc_le_eq)
   241 apply (simp add: order_le_less, blast)
   242 done
   243 
   244 lemma atLeast_Suc_greaterThan: "atLeast (Suc k) = greaterThan k"
   245   by (auto simp add: greaterThan_def atLeast_def less_Suc_eq_le)
   246 
   247 lemma UN_atLeast_UNIV: "(UN m::nat. atLeast m) = UNIV"
   248 by blast
   249 
   250 subsubsection {* The Constant @{term atMost} *}
   251 
   252 lemma atMost_0 [simp]: "atMost (0::nat) = {0}"
   253 by (simp add: atMost_def)
   254 
   255 lemma atMost_Suc: "atMost (Suc k) = insert (Suc k) (atMost k)"
   256 apply (simp add: atMost_def)
   257 apply (simp add: less_Suc_eq order_le_less, blast)
   258 done
   259 
   260 lemma UN_atMost_UNIV: "(UN m::nat. atMost m) = UNIV"
   261 by blast
   262 
   263 subsubsection {* The Constant @{term atLeastLessThan} *}
   264 
   265 text{*But not a simprule because some concepts are better left in terms
   266   of @{term atLeastLessThan}*}
   267 lemma atLeast0LessThan: "{0::nat..<n} = {..<n}"
   268 by(simp add:lessThan_def atLeastLessThan_def)
   269 (*
   270 lemma atLeastLessThan0 [simp]: "{m..<0::nat} = {}"
   271 by (simp add: atLeastLessThan_def)
   272 *)
   273 subsubsection {* Intervals of nats with @{term Suc} *}
   274 
   275 text{*Not a simprule because the RHS is too messy.*}
   276 lemma atLeastLessThanSuc:
   277     "{m..<Suc n} = (if m \<le> n then insert n {m..<n} else {})"
   278 by (auto simp add: atLeastLessThan_def)
   279 
   280 lemma atLeastLessThan_singleton [simp]: "{m..<Suc m} = {m}"
   281 by (auto simp add: atLeastLessThan_def)
   282 (*
   283 lemma atLeast_sum_LessThan [simp]: "{m + k..<k::nat} = {}"
   284 by (induct k, simp_all add: atLeastLessThanSuc)
   285 
   286 lemma atLeastSucLessThan [simp]: "{Suc n..<n} = {}"
   287 by (auto simp add: atLeastLessThan_def)
   288 *)
   289 lemma atLeastLessThanSuc_atLeastAtMost: "{l..<Suc u} = {l..u}"
   290   by (simp add: lessThan_Suc_atMost atLeastAtMost_def atLeastLessThan_def)
   291 
   292 lemma atLeastSucAtMost_greaterThanAtMost: "{Suc l..u} = {l<..u}"
   293   by (simp add: atLeast_Suc_greaterThan atLeastAtMost_def
   294     greaterThanAtMost_def)
   295 
   296 lemma atLeastSucLessThan_greaterThanLessThan: "{Suc l..<u} = {l<..<u}"
   297   by (simp add: atLeast_Suc_greaterThan atLeastLessThan_def
   298     greaterThanLessThan_def)
   299 
   300 lemma atLeastAtMostSuc_conv: "m \<le> Suc n \<Longrightarrow> {m..Suc n} = insert (Suc n) {m..n}"
   301 by (auto simp add: atLeastAtMost_def)
   302 
   303 subsubsection {* Image *}
   304 
   305 lemma image_add_atLeastAtMost:
   306   "(%n::nat. n+k) ` {i..j} = {i+k..j+k}" (is "?A = ?B")
   307 proof
   308   show "?A \<subseteq> ?B" by auto
   309 next
   310   show "?B \<subseteq> ?A"
   311   proof
   312     fix n assume a: "n : ?B"
   313     hence "n - k : {i..j}" by auto arith+
   314     moreover have "n = (n - k) + k" using a by auto
   315     ultimately show "n : ?A" by blast
   316   qed
   317 qed
   318 
   319 lemma image_add_atLeastLessThan:
   320   "(%n::nat. n+k) ` {i..<j} = {i+k..<j+k}" (is "?A = ?B")
   321 proof
   322   show "?A \<subseteq> ?B" by auto
   323 next
   324   show "?B \<subseteq> ?A"
   325   proof
   326     fix n assume a: "n : ?B"
   327     hence "n - k : {i..<j}" by auto arith+
   328     moreover have "n = (n - k) + k" using a by auto
   329     ultimately show "n : ?A" by blast
   330   qed
   331 qed
   332 
   333 corollary image_Suc_atLeastAtMost[simp]:
   334   "Suc ` {i..j} = {Suc i..Suc j}"
   335 using image_add_atLeastAtMost[where k=1] by simp
   336 
   337 corollary image_Suc_atLeastLessThan[simp]:
   338   "Suc ` {i..<j} = {Suc i..<Suc j}"
   339 using image_add_atLeastLessThan[where k=1] by simp
   340 
   341 lemma image_add_int_atLeastLessThan:
   342     "(%x. x + (l::int)) ` {0..<u-l} = {l..<u}"
   343   apply (auto simp add: image_def)
   344   apply (rule_tac x = "x - l" in bexI)
   345   apply auto
   346   done
   347 
   348 
   349 subsubsection {* Finiteness *}
   350 
   351 lemma finite_lessThan [iff]: fixes k :: nat shows "finite {..<k}"
   352   by (induct k) (simp_all add: lessThan_Suc)
   353 
   354 lemma finite_atMost [iff]: fixes k :: nat shows "finite {..k}"
   355   by (induct k) (simp_all add: atMost_Suc)
   356 
   357 lemma finite_greaterThanLessThan [iff]:
   358   fixes l :: nat shows "finite {l<..<u}"
   359 by (simp add: greaterThanLessThan_def)
   360 
   361 lemma finite_atLeastLessThan [iff]:
   362   fixes l :: nat shows "finite {l..<u}"
   363 by (simp add: atLeastLessThan_def)
   364 
   365 lemma finite_greaterThanAtMost [iff]:
   366   fixes l :: nat shows "finite {l<..u}"
   367 by (simp add: greaterThanAtMost_def)
   368 
   369 lemma finite_atLeastAtMost [iff]:
   370   fixes l :: nat shows "finite {l..u}"
   371 by (simp add: atLeastAtMost_def)
   372 
   373 lemma bounded_nat_set_is_finite:
   374     "(ALL i:N. i < (n::nat)) ==> finite N"
   375   -- {* A bounded set of natural numbers is finite. *}
   376   apply (rule finite_subset)
   377    apply (rule_tac [2] finite_lessThan, auto)
   378   done
   379 
   380 subsubsection {* Cardinality *}
   381 
   382 lemma card_lessThan [simp]: "card {..<u} = u"
   383   by (induct u, simp_all add: lessThan_Suc)
   384 
   385 lemma card_atMost [simp]: "card {..u} = Suc u"
   386   by (simp add: lessThan_Suc_atMost [THEN sym])
   387 
   388 lemma card_atLeastLessThan [simp]: "card {l..<u} = u - l"
   389   apply (subgoal_tac "card {l..<u} = card {..<u-l}")
   390   apply (erule ssubst, rule card_lessThan)
   391   apply (subgoal_tac "(%x. x + l) ` {..<u-l} = {l..<u}")
   392   apply (erule subst)
   393   apply (rule card_image)
   394   apply (simp add: inj_on_def)
   395   apply (auto simp add: image_def atLeastLessThan_def lessThan_def)
   396   apply arith
   397   apply (rule_tac x = "x - l" in exI)
   398   apply arith
   399   done
   400 
   401 lemma card_atLeastAtMost [simp]: "card {l..u} = Suc u - l"
   402   by (subst atLeastLessThanSuc_atLeastAtMost [THEN sym], simp)
   403 
   404 lemma card_greaterThanAtMost [simp]: "card {l<..u} = u - l"
   405   by (subst atLeastSucAtMost_greaterThanAtMost [THEN sym], simp)
   406 
   407 lemma card_greaterThanLessThan [simp]: "card {l<..<u} = u - Suc l"
   408   by (subst atLeastSucLessThan_greaterThanLessThan [THEN sym], simp)
   409 
   410 subsection {* Intervals of integers *}
   411 
   412 lemma atLeastLessThanPlusOne_atLeastAtMost_int: "{l..<u+1} = {l..(u::int)}"
   413   by (auto simp add: atLeastAtMost_def atLeastLessThan_def)
   414 
   415 lemma atLeastPlusOneAtMost_greaterThanAtMost_int: "{l+1..u} = {l<..(u::int)}"
   416   by (auto simp add: atLeastAtMost_def greaterThanAtMost_def)
   417 
   418 lemma atLeastPlusOneLessThan_greaterThanLessThan_int:
   419     "{l+1..<u} = {l<..<u::int}"
   420   by (auto simp add: atLeastLessThan_def greaterThanLessThan_def)
   421 
   422 subsubsection {* Finiteness *}
   423 
   424 lemma image_atLeastZeroLessThan_int: "0 \<le> u ==>
   425     {(0::int)..<u} = int ` {..<nat u}"
   426   apply (unfold image_def lessThan_def)
   427   apply auto
   428   apply (rule_tac x = "nat x" in exI)
   429   apply (auto simp add: zless_nat_conj zless_nat_eq_int_zless [THEN sym])
   430   done
   431 
   432 lemma finite_atLeastZeroLessThan_int: "finite {(0::int)..<u}"
   433   apply (case_tac "0 \<le> u")
   434   apply (subst image_atLeastZeroLessThan_int, assumption)
   435   apply (rule finite_imageI)
   436   apply auto
   437   done
   438 
   439 lemma finite_atLeastLessThan_int [iff]: "finite {l..<u::int}"
   440   apply (subgoal_tac "(%x. x + l) ` {0..<u-l} = {l..<u}")
   441   apply (erule subst)
   442   apply (rule finite_imageI)
   443   apply (rule finite_atLeastZeroLessThan_int)
   444   apply (rule image_add_int_atLeastLessThan)
   445   done
   446 
   447 lemma finite_atLeastAtMost_int [iff]: "finite {l..(u::int)}"
   448   by (subst atLeastLessThanPlusOne_atLeastAtMost_int [THEN sym], simp)
   449 
   450 lemma finite_greaterThanAtMost_int [iff]: "finite {l<..(u::int)}"
   451   by (subst atLeastPlusOneAtMost_greaterThanAtMost_int [THEN sym], simp)
   452 
   453 lemma finite_greaterThanLessThan_int [iff]: "finite {l<..<u::int}"
   454   by (subst atLeastPlusOneLessThan_greaterThanLessThan_int [THEN sym], simp)
   455 
   456 subsubsection {* Cardinality *}
   457 
   458 lemma card_atLeastZeroLessThan_int: "card {(0::int)..<u} = nat u"
   459   apply (case_tac "0 \<le> u")
   460   apply (subst image_atLeastZeroLessThan_int, assumption)
   461   apply (subst card_image)
   462   apply (auto simp add: inj_on_def)
   463   done
   464 
   465 lemma card_atLeastLessThan_int [simp]: "card {l..<u} = nat (u - l)"
   466   apply (subgoal_tac "card {l..<u} = card {0..<u-l}")
   467   apply (erule ssubst, rule card_atLeastZeroLessThan_int)
   468   apply (subgoal_tac "(%x. x + l) ` {0..<u-l} = {l..<u}")
   469   apply (erule subst)
   470   apply (rule card_image)
   471   apply (simp add: inj_on_def)
   472   apply (rule image_add_int_atLeastLessThan)
   473   done
   474 
   475 lemma card_atLeastAtMost_int [simp]: "card {l..u} = nat (u - l + 1)"
   476   apply (subst atLeastLessThanPlusOne_atLeastAtMost_int [THEN sym])
   477   apply (auto simp add: compare_rls)
   478   done
   479 
   480 lemma card_greaterThanAtMost_int [simp]: "card {l<..u} = nat (u - l)"
   481   by (subst atLeastPlusOneAtMost_greaterThanAtMost_int [THEN sym], simp)
   482 
   483 lemma card_greaterThanLessThan_int [simp]: "card {l<..<u} = nat (u - (l + 1))"
   484   by (subst atLeastPlusOneLessThan_greaterThanLessThan_int [THEN sym], simp)
   485 
   486 
   487 subsection {*Lemmas useful with the summation operator setsum*}
   488 
   489 text {* For examples, see Algebra/poly/UnivPoly2.thy *}
   490 
   491 subsubsection {* Disjoint Unions *}
   492 
   493 text {* Singletons and open intervals *}
   494 
   495 lemma ivl_disj_un_singleton:
   496   "{l::'a::linorder} Un {l<..} = {l..}"
   497   "{..<u} Un {u::'a::linorder} = {..u}"
   498   "(l::'a::linorder) < u ==> {l} Un {l<..<u} = {l..<u}"
   499   "(l::'a::linorder) < u ==> {l<..<u} Un {u} = {l<..u}"
   500   "(l::'a::linorder) <= u ==> {l} Un {l<..u} = {l..u}"
   501   "(l::'a::linorder) <= u ==> {l..<u} Un {u} = {l..u}"
   502 by auto
   503 
   504 text {* One- and two-sided intervals *}
   505 
   506 lemma ivl_disj_un_one:
   507   "(l::'a::linorder) < u ==> {..l} Un {l<..<u} = {..<u}"
   508   "(l::'a::linorder) <= u ==> {..<l} Un {l..<u} = {..<u}"
   509   "(l::'a::linorder) <= u ==> {..l} Un {l<..u} = {..u}"
   510   "(l::'a::linorder) <= u ==> {..<l} Un {l..u} = {..u}"
   511   "(l::'a::linorder) <= u ==> {l<..u} Un {u<..} = {l<..}"
   512   "(l::'a::linorder) < u ==> {l<..<u} Un {u..} = {l<..}"
   513   "(l::'a::linorder) <= u ==> {l..u} Un {u<..} = {l..}"
   514   "(l::'a::linorder) <= u ==> {l..<u} Un {u..} = {l..}"
   515 by auto
   516 
   517 text {* Two- and two-sided intervals *}
   518 
   519 lemma ivl_disj_un_two:
   520   "[| (l::'a::linorder) < m; m <= u |] ==> {l<..<m} Un {m..<u} = {l<..<u}"
   521   "[| (l::'a::linorder) <= m; m < u |] ==> {l<..m} Un {m<..<u} = {l<..<u}"
   522   "[| (l::'a::linorder) <= m; m <= u |] ==> {l..<m} Un {m..<u} = {l..<u}"
   523   "[| (l::'a::linorder) <= m; m < u |] ==> {l..m} Un {m<..<u} = {l..<u}"
   524   "[| (l::'a::linorder) < m; m <= u |] ==> {l<..<m} Un {m..u} = {l<..u}"
   525   "[| (l::'a::linorder) <= m; m <= u |] ==> {l<..m} Un {m<..u} = {l<..u}"
   526   "[| (l::'a::linorder) <= m; m <= u |] ==> {l..<m} Un {m..u} = {l..u}"
   527   "[| (l::'a::linorder) <= m; m <= u |] ==> {l..m} Un {m<..u} = {l..u}"
   528 by auto
   529 
   530 lemmas ivl_disj_un = ivl_disj_un_singleton ivl_disj_un_one ivl_disj_un_two
   531 
   532 subsubsection {* Disjoint Intersections *}
   533 
   534 text {* Singletons and open intervals *}
   535 
   536 lemma ivl_disj_int_singleton:
   537   "{l::'a::order} Int {l<..} = {}"
   538   "{..<u} Int {u} = {}"
   539   "{l} Int {l<..<u} = {}"
   540   "{l<..<u} Int {u} = {}"
   541   "{l} Int {l<..u} = {}"
   542   "{l..<u} Int {u} = {}"
   543   by simp+
   544 
   545 text {* One- and two-sided intervals *}
   546 
   547 lemma ivl_disj_int_one:
   548   "{..l::'a::order} Int {l<..<u} = {}"
   549   "{..<l} Int {l..<u} = {}"
   550   "{..l} Int {l<..u} = {}"
   551   "{..<l} Int {l..u} = {}"
   552   "{l<..u} Int {u<..} = {}"
   553   "{l<..<u} Int {u..} = {}"
   554   "{l..u} Int {u<..} = {}"
   555   "{l..<u} Int {u..} = {}"
   556   by auto
   557 
   558 text {* Two- and two-sided intervals *}
   559 
   560 lemma ivl_disj_int_two:
   561   "{l::'a::order<..<m} Int {m..<u} = {}"
   562   "{l<..m} Int {m<..<u} = {}"
   563   "{l..<m} Int {m..<u} = {}"
   564   "{l..m} Int {m<..<u} = {}"
   565   "{l<..<m} Int {m..u} = {}"
   566   "{l<..m} Int {m<..u} = {}"
   567   "{l..<m} Int {m..u} = {}"
   568   "{l..m} Int {m<..u} = {}"
   569   by auto
   570 
   571 lemmas ivl_disj_int = ivl_disj_int_singleton ivl_disj_int_one ivl_disj_int_two
   572 
   573 subsubsection {* Some Differences *}
   574 
   575 lemma ivl_diff[simp]:
   576  "i \<le> n \<Longrightarrow> {i..<m} - {i..<n} = {n..<(m::'a::linorder)}"
   577 by(auto)
   578 
   579 
   580 subsubsection {* Some Subset Conditions *}
   581 
   582 lemma ivl_subset[simp]:
   583  "({i..<j} \<subseteq> {m..<n}) = (j \<le> i | m \<le> i & j \<le> (n::'a::linorder))"
   584 apply(auto simp:linorder_not_le)
   585 apply(rule ccontr)
   586 apply(insert linorder_le_less_linear[of i n])
   587 apply(clarsimp simp:linorder_not_le)
   588 apply(fastsimp)
   589 done
   590 
   591 
   592 subsection {* Summation indexed over intervals *}
   593 
   594 syntax
   595   "_from_to_setsum" :: "idt \<Rightarrow> 'a \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(SUM _ = _.._./ _)" [0,0,0,10] 10)
   596   "_from_upto_setsum" :: "idt \<Rightarrow> 'a \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(SUM _ = _..<_./ _)" [0,0,0,10] 10)
   597   "_upt_setsum" :: "idt \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(SUM _<_./ _)" [0,0,10] 10)
   598   "_upto_setsum" :: "idt \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(SUM _<=_./ _)" [0,0,10] 10)
   599 syntax (xsymbols)
   600   "_from_to_setsum" :: "idt \<Rightarrow> 'a \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(3\<Sum>_ = _.._./ _)" [0,0,0,10] 10)
   601   "_from_upto_setsum" :: "idt \<Rightarrow> 'a \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(3\<Sum>_ = _..<_./ _)" [0,0,0,10] 10)
   602   "_upt_setsum" :: "idt \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(3\<Sum>_<_./ _)" [0,0,10] 10)
   603   "_upto_setsum" :: "idt \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(3\<Sum>_\<le>_./ _)" [0,0,10] 10)
   604 syntax (HTML output)
   605   "_from_to_setsum" :: "idt \<Rightarrow> 'a \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(3\<Sum>_ = _.._./ _)" [0,0,0,10] 10)
   606   "_from_upto_setsum" :: "idt \<Rightarrow> 'a \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(3\<Sum>_ = _..<_./ _)" [0,0,0,10] 10)
   607   "_upt_setsum" :: "idt \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(3\<Sum>_<_./ _)" [0,0,10] 10)
   608   "_upto_setsum" :: "idt \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(3\<Sum>_\<le>_./ _)" [0,0,10] 10)
   609 syntax (latex_sum output)
   610   "_from_to_setsum" :: "idt \<Rightarrow> 'a \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b"
   611  ("(3\<^raw:$\sum_{>_ = _\<^raw:}^{>_\<^raw:}$> _)" [0,0,0,10] 10)
   612   "_from_upto_setsum" :: "idt \<Rightarrow> 'a \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b"
   613  ("(3\<^raw:$\sum_{>_ = _\<^raw:}^{<>_\<^raw:}$> _)" [0,0,0,10] 10)
   614   "_upt_setsum" :: "idt \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b"
   615  ("(3\<^raw:$\sum_{>_ < _\<^raw:}$> _)" [0,0,10] 10)
   616   "_upto_setsum" :: "idt \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b"
   617  ("(3\<^raw:$\sum_{>_ \<le> _\<^raw:}$> _)" [0,0,10] 10)
   618 
   619 translations
   620   "\<Sum>x=a..b. t" == "setsum (%x. t) {a..b}"
   621   "\<Sum>x=a..<b. t" == "setsum (%x. t) {a..<b}"
   622   "\<Sum>i\<le>n. t" == "setsum (\<lambda>i. t) {..n}"
   623   "\<Sum>i<n. t" == "setsum (\<lambda>i. t) {..<n}"
   624 
   625 text{* The above introduces some pretty alternative syntaxes for
   626 summation over intervals:
   627 \begin{center}
   628 \begin{tabular}{lll}
   629 Old & New & \LaTeX\\
   630 @{term[source]"\<Sum>x\<in>{a..b}. e"} & @{term"\<Sum>x=a..b. e"} & @{term[mode=latex_sum]"\<Sum>x=a..b. e"}\\
   631 @{term[source]"\<Sum>x\<in>{a..<b}. e"} & @{term"\<Sum>x=a..<b. e"} & @{term[mode=latex_sum]"\<Sum>x=a..<b. e"}\\
   632 @{term[source]"\<Sum>x\<in>{..b}. e"} & @{term"\<Sum>x\<le>b. e"} & @{term[mode=latex_sum]"\<Sum>x\<le>b. e"}\\
   633 @{term[source]"\<Sum>x\<in>{..<b}. e"} & @{term"\<Sum>x<b. e"} & @{term[mode=latex_sum]"\<Sum>x<b. e"}
   634 \end{tabular}
   635 \end{center}
   636 The left column shows the term before introduction of the new syntax,
   637 the middle column shows the new (default) syntax, and the right column
   638 shows a special syntax. The latter is only meaningful for latex output
   639 and has to be activated explicitly by setting the print mode to
   640 \texttt{latex\_sum} (e.g.\ via \texttt{mode=latex\_sum} in
   641 antiquotations). It is not the default \LaTeX\ output because it only
   642 works well with italic-style formulae, not tt-style.
   643 
   644 Note that for uniformity on @{typ nat} it is better to use
   645 @{term"\<Sum>x::nat=0..<n. e"} rather than @{text"\<Sum>x<n. e"}: @{text setsum} may
   646 not provide all lemmas available for @{term"{m..<n}"} also in the
   647 special form for @{term"{..<n}"}. *}
   648 
   649 text{* This congruence rule should be used for sums over intervals as
   650 the standard theorem @{text[source]setsum_cong} does not work well
   651 with the simplifier who adds the unsimplified premise @{term"x:B"} to
   652 the context. *}
   653 
   654 lemma setsum_ivl_cong:
   655  "\<lbrakk>a = c; b = d; !!x. \<lbrakk> c \<le> x; x < d \<rbrakk> \<Longrightarrow> f x = g x \<rbrakk> \<Longrightarrow>
   656  setsum f {a..<b} = setsum g {c..<d}"
   657 by(rule setsum_cong, simp_all)
   658 
   659 (* FIXME why are the following simp rules but the corresponding eqns
   660 on intervals are not? *)
   661 
   662 lemma setsum_atMost_Suc[simp]: "(\<Sum>i \<le> Suc n. f i) = (\<Sum>i \<le> n. f i) + f(Suc n)"
   663 by (simp add:atMost_Suc add_ac)
   664 
   665 lemma setsum_lessThan_Suc[simp]: "(\<Sum>i < Suc n. f i) = (\<Sum>i < n. f i) + f n"
   666 by (simp add:lessThan_Suc add_ac)
   667 
   668 lemma setsum_cl_ivl_Suc[simp]:
   669   "setsum f {m..Suc n} = (if Suc n < m then 0 else setsum f {m..n} + f(Suc n))"
   670 by (auto simp:add_ac atLeastAtMostSuc_conv)
   671 
   672 lemma setsum_op_ivl_Suc[simp]:
   673   "setsum f {m..<Suc n} = (if n < m then 0 else setsum f {m..<n} + f(n))"
   674 by (auto simp:add_ac atLeastLessThanSuc)
   675 (*
   676 lemma setsum_cl_ivl_add_one_nat: "(n::nat) <= m + 1 ==>
   677     (\<Sum>i=n..m+1. f i) = (\<Sum>i=n..m. f i) + f(m + 1)"
   678 by (auto simp:add_ac atLeastAtMostSuc_conv)
   679 *)
   680 lemma setsum_add_nat_ivl: "\<lbrakk> m \<le> n; n \<le> p \<rbrakk> \<Longrightarrow>
   681   setsum f {m..<n} + setsum f {n..<p} = setsum f {m..<p::nat}"
   682 by (simp add:setsum_Un_disjoint[symmetric] ivl_disj_int ivl_disj_un)
   683 
   684 lemma setsum_diff_nat_ivl:
   685 fixes f :: "nat \<Rightarrow> 'a::ab_group_add"
   686 shows "\<lbrakk> m \<le> n; n \<le> p \<rbrakk> \<Longrightarrow>
   687   setsum f {m..<p} - setsum f {m..<n} = setsum f {n..<p}"
   688 using setsum_add_nat_ivl [of m n p f,symmetric]
   689 apply (simp add: add_ac)
   690 done
   691 
   692 subsection{* Shifting bounds *}
   693 
   694 lemma setsum_shift_bounds_nat_ivl:
   695   "setsum f {m+k..<n+k} = setsum (%i. f(i + k)){m..<n::nat}"
   696 by (induct "n", auto simp:atLeastLessThanSuc)
   697 
   698 lemma setsum_shift_bounds_cl_nat_ivl:
   699   "setsum f {m+k..n+k} = setsum (%i. f(i + k)){m..n::nat}"
   700 apply (insert setsum_reindex[OF inj_on_add_nat, where h=f and B = "{m..n}"])
   701 apply (simp add:image_add_atLeastAtMost o_def)
   702 done
   703 
   704 corollary setsum_shift_bounds_cl_Suc_ivl:
   705   "setsum f {Suc m..Suc n} = setsum (%i. f(Suc i)){m..n}"
   706 by (simp add:setsum_shift_bounds_cl_nat_ivl[where k=1,simplified])
   707 
   708 corollary setsum_shift_bounds_Suc_ivl:
   709   "setsum f {Suc m..<Suc n} = setsum (%i. f(Suc i)){m..<n}"
   710 by (simp add:setsum_shift_bounds_nat_ivl[where k=1,simplified])
   711 
   712 
   713 ML
   714 {*
   715 val Compl_atLeast = thm "Compl_atLeast";
   716 val Compl_atMost = thm "Compl_atMost";
   717 val Compl_greaterThan = thm "Compl_greaterThan";
   718 val Compl_lessThan = thm "Compl_lessThan";
   719 val INT_greaterThan_UNIV = thm "INT_greaterThan_UNIV";
   720 val UN_atLeast_UNIV = thm "UN_atLeast_UNIV";
   721 val UN_atMost_UNIV = thm "UN_atMost_UNIV";
   722 val UN_lessThan_UNIV = thm "UN_lessThan_UNIV";
   723 val atLeastAtMost_def = thm "atLeastAtMost_def";
   724 val atLeastAtMost_iff = thm "atLeastAtMost_iff";
   725 val atLeastLessThan_def  = thm "atLeastLessThan_def";
   726 val atLeastLessThan_iff = thm "atLeastLessThan_iff";
   727 val atLeast_0 = thm "atLeast_0";
   728 val atLeast_Suc = thm "atLeast_Suc";
   729 val atLeast_def      = thm "atLeast_def";
   730 val atLeast_iff = thm "atLeast_iff";
   731 val atMost_0 = thm "atMost_0";
   732 val atMost_Int_atLeast = thm "atMost_Int_atLeast";
   733 val atMost_Suc = thm "atMost_Suc";
   734 val atMost_def       = thm "atMost_def";
   735 val atMost_iff = thm "atMost_iff";
   736 val greaterThanAtMost_def  = thm "greaterThanAtMost_def";
   737 val greaterThanAtMost_iff = thm "greaterThanAtMost_iff";
   738 val greaterThanLessThan_def  = thm "greaterThanLessThan_def";
   739 val greaterThanLessThan_iff = thm "greaterThanLessThan_iff";
   740 val greaterThan_0 = thm "greaterThan_0";
   741 val greaterThan_Suc = thm "greaterThan_Suc";
   742 val greaterThan_def  = thm "greaterThan_def";
   743 val greaterThan_iff = thm "greaterThan_iff";
   744 val ivl_disj_int = thms "ivl_disj_int";
   745 val ivl_disj_int_one = thms "ivl_disj_int_one";
   746 val ivl_disj_int_singleton = thms "ivl_disj_int_singleton";
   747 val ivl_disj_int_two = thms "ivl_disj_int_two";
   748 val ivl_disj_un = thms "ivl_disj_un";
   749 val ivl_disj_un_one = thms "ivl_disj_un_one";
   750 val ivl_disj_un_singleton = thms "ivl_disj_un_singleton";
   751 val ivl_disj_un_two = thms "ivl_disj_un_two";
   752 val lessThan_0 = thm "lessThan_0";
   753 val lessThan_Suc = thm "lessThan_Suc";
   754 val lessThan_Suc_atMost = thm "lessThan_Suc_atMost";
   755 val lessThan_def     = thm "lessThan_def";
   756 val lessThan_iff = thm "lessThan_iff";
   757 val single_Diff_lessThan = thm "single_Diff_lessThan";
   758 
   759 val bounded_nat_set_is_finite = thm "bounded_nat_set_is_finite";
   760 val finite_atMost = thm "finite_atMost";
   761 val finite_lessThan = thm "finite_lessThan";
   762 *}
   763 
   764 end