src/HOL/Relation.thy
author haftmann
Wed Feb 17 21:51:56 2016 +0100 (2016-02-17)
changeset 62343 24106dc44def
parent 62087 44841d07ef1d
child 63376 4c0cc2b356f0
permissions -rw-r--r--
prefer abbreviations for compound operators INFIMUM and SUPREMUM
     1 (*  Title:      HOL/Relation.thy
     2     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory; Stefan Berghofer, TU Muenchen
     3 *)
     4 
     5 section \<open>Relations -- as sets of pairs, and binary predicates\<close>
     6 
     7 theory Relation
     8 imports Finite_Set
     9 begin
    10 
    11 text \<open>A preliminary: classical rules for reasoning on predicates\<close>
    12 
    13 declare predicate1I [Pure.intro!, intro!]
    14 declare predicate1D [Pure.dest, dest]
    15 declare predicate2I [Pure.intro!, intro!]
    16 declare predicate2D [Pure.dest, dest]
    17 declare bot1E [elim!] 
    18 declare bot2E [elim!]
    19 declare top1I [intro!]
    20 declare top2I [intro!]
    21 declare inf1I [intro!]
    22 declare inf2I [intro!]
    23 declare inf1E [elim!]
    24 declare inf2E [elim!]
    25 declare sup1I1 [intro?]
    26 declare sup2I1 [intro?]
    27 declare sup1I2 [intro?]
    28 declare sup2I2 [intro?]
    29 declare sup1E [elim!]
    30 declare sup2E [elim!]
    31 declare sup1CI [intro!]
    32 declare sup2CI [intro!]
    33 declare Inf1_I [intro!]
    34 declare INF1_I [intro!]
    35 declare Inf2_I [intro!]
    36 declare INF2_I [intro!]
    37 declare Inf1_D [elim]
    38 declare INF1_D [elim]
    39 declare Inf2_D [elim]
    40 declare INF2_D [elim]
    41 declare Inf1_E [elim]
    42 declare INF1_E [elim]
    43 declare Inf2_E [elim]
    44 declare INF2_E [elim]
    45 declare Sup1_I [intro]
    46 declare SUP1_I [intro]
    47 declare Sup2_I [intro]
    48 declare SUP2_I [intro]
    49 declare Sup1_E [elim!]
    50 declare SUP1_E [elim!]
    51 declare Sup2_E [elim!]
    52 declare SUP2_E [elim!]
    53 
    54 subsection \<open>Fundamental\<close>
    55 
    56 subsubsection \<open>Relations as sets of pairs\<close>
    57 
    58 type_synonym 'a rel = "('a * 'a) set"
    59 
    60 lemma subrelI: \<comment> \<open>Version of @{thm [source] subsetI} for binary relations\<close>
    61   "(\<And>x y. (x, y) \<in> r \<Longrightarrow> (x, y) \<in> s) \<Longrightarrow> r \<subseteq> s"
    62   by auto
    63 
    64 lemma lfp_induct2: \<comment> \<open>Version of @{thm [source] lfp_induct} for binary relations\<close>
    65   "(a, b) \<in> lfp f \<Longrightarrow> mono f \<Longrightarrow>
    66     (\<And>a b. (a, b) \<in> f (lfp f \<inter> {(x, y). P x y}) \<Longrightarrow> P a b) \<Longrightarrow> P a b"
    67   using lfp_induct_set [of "(a, b)" f "case_prod P"] by auto
    68 
    69 
    70 subsubsection \<open>Conversions between set and predicate relations\<close>
    71 
    72 lemma pred_equals_eq [pred_set_conv]: "(\<lambda>x. x \<in> R) = (\<lambda>x. x \<in> S) \<longleftrightarrow> R = S"
    73   by (simp add: set_eq_iff fun_eq_iff)
    74 
    75 lemma pred_equals_eq2 [pred_set_conv]: "(\<lambda>x y. (x, y) \<in> R) = (\<lambda>x y. (x, y) \<in> S) \<longleftrightarrow> R = S"
    76   by (simp add: set_eq_iff fun_eq_iff)
    77 
    78 lemma pred_subset_eq [pred_set_conv]: "(\<lambda>x. x \<in> R) \<le> (\<lambda>x. x \<in> S) \<longleftrightarrow> R \<subseteq> S"
    79   by (simp add: subset_iff le_fun_def)
    80 
    81 lemma pred_subset_eq2 [pred_set_conv]: "(\<lambda>x y. (x, y) \<in> R) \<le> (\<lambda>x y. (x, y) \<in> S) \<longleftrightarrow> R \<subseteq> S"
    82   by (simp add: subset_iff le_fun_def)
    83 
    84 lemma bot_empty_eq [pred_set_conv]: "\<bottom> = (\<lambda>x. x \<in> {})"
    85   by (auto simp add: fun_eq_iff)
    86 
    87 lemma bot_empty_eq2 [pred_set_conv]: "\<bottom> = (\<lambda>x y. (x, y) \<in> {})"
    88   by (auto simp add: fun_eq_iff)
    89 
    90 lemma top_empty_eq [pred_set_conv]: "\<top> = (\<lambda>x. x \<in> UNIV)"
    91   by (auto simp add: fun_eq_iff)
    92 
    93 lemma top_empty_eq2 [pred_set_conv]: "\<top> = (\<lambda>x y. (x, y) \<in> UNIV)"
    94   by (auto simp add: fun_eq_iff)
    95 
    96 lemma inf_Int_eq [pred_set_conv]: "(\<lambda>x. x \<in> R) \<sqinter> (\<lambda>x. x \<in> S) = (\<lambda>x. x \<in> R \<inter> S)"
    97   by (simp add: inf_fun_def)
    98 
    99 lemma inf_Int_eq2 [pred_set_conv]: "(\<lambda>x y. (x, y) \<in> R) \<sqinter> (\<lambda>x y. (x, y) \<in> S) = (\<lambda>x y. (x, y) \<in> R \<inter> S)"
   100   by (simp add: inf_fun_def)
   101 
   102 lemma sup_Un_eq [pred_set_conv]: "(\<lambda>x. x \<in> R) \<squnion> (\<lambda>x. x \<in> S) = (\<lambda>x. x \<in> R \<union> S)"
   103   by (simp add: sup_fun_def)
   104 
   105 lemma sup_Un_eq2 [pred_set_conv]: "(\<lambda>x y. (x, y) \<in> R) \<squnion> (\<lambda>x y. (x, y) \<in> S) = (\<lambda>x y. (x, y) \<in> R \<union> S)"
   106   by (simp add: sup_fun_def)
   107 
   108 lemma INF_INT_eq [pred_set_conv]: "(\<Sqinter>i\<in>S. (\<lambda>x. x \<in> r i)) = (\<lambda>x. x \<in> (\<Inter>i\<in>S. r i))"
   109   by (simp add: fun_eq_iff)
   110 
   111 lemma INF_INT_eq2 [pred_set_conv]: "(\<Sqinter>i\<in>S. (\<lambda>x y. (x, y) \<in> r i)) = (\<lambda>x y. (x, y) \<in> (\<Inter>i\<in>S. r i))"
   112   by (simp add: fun_eq_iff)
   113 
   114 lemma SUP_UN_eq [pred_set_conv]: "(\<Squnion>i\<in>S. (\<lambda>x. x \<in> r i)) = (\<lambda>x. x \<in> (\<Union>i\<in>S. r i))"
   115   by (simp add: fun_eq_iff)
   116 
   117 lemma SUP_UN_eq2 [pred_set_conv]: "(\<Squnion>i\<in>S. (\<lambda>x y. (x, y) \<in> r i)) = (\<lambda>x y. (x, y) \<in> (\<Union>i\<in>S. r i))"
   118   by (simp add: fun_eq_iff)
   119 
   120 lemma Inf_INT_eq [pred_set_conv]: "\<Sqinter>S = (\<lambda>x. x \<in> INTER S Collect)"
   121   by (simp add: fun_eq_iff)
   122 
   123 lemma INF_Int_eq [pred_set_conv]: "(\<Sqinter>i\<in>S. (\<lambda>x. x \<in> i)) = (\<lambda>x. x \<in> \<Inter>S)"
   124   by (simp add: fun_eq_iff)
   125 
   126 lemma Inf_INT_eq2 [pred_set_conv]: "\<Sqinter>S = (\<lambda>x y. (x, y) \<in> INTER (case_prod ` S) Collect)"
   127   by (simp add: fun_eq_iff)
   128 
   129 lemma INF_Int_eq2 [pred_set_conv]: "(\<Sqinter>i\<in>S. (\<lambda>x y. (x, y) \<in> i)) = (\<lambda>x y. (x, y) \<in> \<Inter>S)"
   130   by (simp add: fun_eq_iff)
   131 
   132 lemma Sup_SUP_eq [pred_set_conv]: "\<Squnion>S = (\<lambda>x. x \<in> UNION S Collect)"
   133   by (simp add: fun_eq_iff)
   134 
   135 lemma SUP_Sup_eq [pred_set_conv]: "(\<Squnion>i\<in>S. (\<lambda>x. x \<in> i)) = (\<lambda>x. x \<in> \<Union>S)"
   136   by (simp add: fun_eq_iff)
   137 
   138 lemma Sup_SUP_eq2 [pred_set_conv]: "\<Squnion>S = (\<lambda>x y. (x, y) \<in> UNION (case_prod ` S) Collect)"
   139   by (simp add: fun_eq_iff)
   140 
   141 lemma SUP_Sup_eq2 [pred_set_conv]: "(\<Squnion>i\<in>S. (\<lambda>x y. (x, y) \<in> i)) = (\<lambda>x y. (x, y) \<in> \<Union>S)"
   142   by (simp add: fun_eq_iff)
   143 
   144 subsection \<open>Properties of relations\<close>
   145 
   146 subsubsection \<open>Reflexivity\<close>
   147 
   148 definition refl_on :: "'a set \<Rightarrow> 'a rel \<Rightarrow> bool"
   149 where
   150   "refl_on A r \<longleftrightarrow> r \<subseteq> A \<times> A \<and> (\<forall>x\<in>A. (x, x) \<in> r)"
   151 
   152 abbreviation refl :: "'a rel \<Rightarrow> bool"
   153 where \<comment> \<open>reflexivity over a type\<close>
   154   "refl \<equiv> refl_on UNIV"
   155 
   156 definition reflp :: "('a \<Rightarrow> 'a \<Rightarrow> bool) \<Rightarrow> bool"
   157 where
   158   "reflp r \<longleftrightarrow> (\<forall>x. r x x)"
   159 
   160 lemma reflp_refl_eq [pred_set_conv]:
   161   "reflp (\<lambda>x y. (x, y) \<in> r) \<longleftrightarrow> refl r" 
   162   by (simp add: refl_on_def reflp_def)
   163 
   164 lemma refl_onI: "r \<subseteq> A \<times> A ==> (!!x. x : A ==> (x, x) : r) ==> refl_on A r"
   165   by (unfold refl_on_def) (iprover intro!: ballI)
   166 
   167 lemma refl_onD: "refl_on A r ==> a : A ==> (a, a) : r"
   168   by (unfold refl_on_def) blast
   169 
   170 lemma refl_onD1: "refl_on A r ==> (x, y) : r ==> x : A"
   171   by (unfold refl_on_def) blast
   172 
   173 lemma refl_onD2: "refl_on A r ==> (x, y) : r ==> y : A"
   174   by (unfold refl_on_def) blast
   175 
   176 lemma reflpI:
   177   "(\<And>x. r x x) \<Longrightarrow> reflp r"
   178   by (auto intro: refl_onI simp add: reflp_def)
   179 
   180 lemma reflpE:
   181   assumes "reflp r"
   182   obtains "r x x"
   183   using assms by (auto dest: refl_onD simp add: reflp_def)
   184 
   185 lemma reflpD:
   186   assumes "reflp r"
   187   shows "r x x"
   188   using assms by (auto elim: reflpE)
   189 
   190 lemma refl_on_Int: "refl_on A r ==> refl_on B s ==> refl_on (A \<inter> B) (r \<inter> s)"
   191   by (unfold refl_on_def) blast
   192 
   193 lemma reflp_inf:
   194   "reflp r \<Longrightarrow> reflp s \<Longrightarrow> reflp (r \<sqinter> s)"
   195   by (auto intro: reflpI elim: reflpE)
   196 
   197 lemma refl_on_Un: "refl_on A r ==> refl_on B s ==> refl_on (A \<union> B) (r \<union> s)"
   198   by (unfold refl_on_def) blast
   199 
   200 lemma reflp_sup:
   201   "reflp r \<Longrightarrow> reflp s \<Longrightarrow> reflp (r \<squnion> s)"
   202   by (auto intro: reflpI elim: reflpE)
   203 
   204 lemma refl_on_INTER:
   205   "ALL x:S. refl_on (A x) (r x) ==> refl_on (INTER S A) (INTER S r)"
   206   by (unfold refl_on_def) fast
   207 
   208 lemma refl_on_UNION:
   209   "ALL x:S. refl_on (A x) (r x) \<Longrightarrow> refl_on (UNION S A) (UNION S r)"
   210   by (unfold refl_on_def) blast
   211 
   212 lemma refl_on_empty [simp]: "refl_on {} {}"
   213   by (simp add:refl_on_def)
   214 
   215 lemma refl_on_def' [nitpick_unfold, code]:
   216   "refl_on A r \<longleftrightarrow> (\<forall>(x, y) \<in> r. x \<in> A \<and> y \<in> A) \<and> (\<forall>x \<in> A. (x, x) \<in> r)"
   217   by (auto intro: refl_onI dest: refl_onD refl_onD1 refl_onD2)
   218 
   219 lemma reflp_equality [simp]: "reflp op ="
   220 by(simp add: reflp_def)
   221 
   222 lemma reflp_mono: "\<lbrakk> reflp R; \<And>x y. R x y \<longrightarrow> Q x y \<rbrakk> \<Longrightarrow> reflp Q"
   223 by(auto intro: reflpI dest: reflpD)
   224 
   225 subsubsection \<open>Irreflexivity\<close>
   226 
   227 definition irrefl :: "'a rel \<Rightarrow> bool"
   228 where
   229   "irrefl r \<longleftrightarrow> (\<forall>a. (a, a) \<notin> r)"
   230 
   231 definition irreflp :: "('a \<Rightarrow> 'a \<Rightarrow> bool) \<Rightarrow> bool"
   232 where
   233   "irreflp R \<longleftrightarrow> (\<forall>a. \<not> R a a)"
   234 
   235 lemma irreflp_irrefl_eq [pred_set_conv]:
   236   "irreflp (\<lambda>a b. (a, b) \<in> R) \<longleftrightarrow> irrefl R" 
   237   by (simp add: irrefl_def irreflp_def)
   238 
   239 lemma irreflI:
   240   "(\<And>a. (a, a) \<notin> R) \<Longrightarrow> irrefl R"
   241   by (simp add: irrefl_def)
   242 
   243 lemma irreflpI:
   244   "(\<And>a. \<not> R a a) \<Longrightarrow> irreflp R"
   245   by (fact irreflI [to_pred])
   246 
   247 lemma irrefl_distinct [code]:
   248   "irrefl r \<longleftrightarrow> (\<forall>(a, b) \<in> r. a \<noteq> b)"
   249   by (auto simp add: irrefl_def)
   250 
   251 
   252 subsubsection \<open>Asymmetry\<close>
   253 
   254 inductive asym :: "'a rel \<Rightarrow> bool"
   255 where
   256   asymI: "irrefl R \<Longrightarrow> (\<And>a b. (a, b) \<in> R \<Longrightarrow> (b, a) \<notin> R) \<Longrightarrow> asym R"
   257 
   258 inductive asymp :: "('a \<Rightarrow> 'a \<Rightarrow> bool) \<Rightarrow> bool"
   259 where
   260   asympI: "irreflp R \<Longrightarrow> (\<And>a b. R a b \<Longrightarrow> \<not> R b a) \<Longrightarrow> asymp R"
   261 
   262 lemma asymp_asym_eq [pred_set_conv]:
   263   "asymp (\<lambda>a b. (a, b) \<in> R) \<longleftrightarrow> asym R" 
   264   by (auto intro!: asymI asympI elim: asym.cases asymp.cases simp add: irreflp_irrefl_eq)
   265 
   266 
   267 subsubsection \<open>Symmetry\<close>
   268 
   269 definition sym :: "'a rel \<Rightarrow> bool"
   270 where
   271   "sym r \<longleftrightarrow> (\<forall>x y. (x, y) \<in> r \<longrightarrow> (y, x) \<in> r)"
   272 
   273 definition symp :: "('a \<Rightarrow> 'a \<Rightarrow> bool) \<Rightarrow> bool"
   274 where
   275   "symp r \<longleftrightarrow> (\<forall>x y. r x y \<longrightarrow> r y x)"
   276 
   277 lemma symp_sym_eq [pred_set_conv]:
   278   "symp (\<lambda>x y. (x, y) \<in> r) \<longleftrightarrow> sym r" 
   279   by (simp add: sym_def symp_def)
   280 
   281 lemma symI:
   282   "(\<And>a b. (a, b) \<in> r \<Longrightarrow> (b, a) \<in> r) \<Longrightarrow> sym r"
   283   by (unfold sym_def) iprover
   284 
   285 lemma sympI:
   286   "(\<And>a b. r a b \<Longrightarrow> r b a) \<Longrightarrow> symp r"
   287   by (fact symI [to_pred])
   288 
   289 lemma symE:
   290   assumes "sym r" and "(b, a) \<in> r"
   291   obtains "(a, b) \<in> r"
   292   using assms by (simp add: sym_def)
   293 
   294 lemma sympE:
   295   assumes "symp r" and "r b a"
   296   obtains "r a b"
   297   using assms by (rule symE [to_pred])
   298 
   299 lemma symD:
   300   assumes "sym r" and "(b, a) \<in> r"
   301   shows "(a, b) \<in> r"
   302   using assms by (rule symE)
   303 
   304 lemma sympD:
   305   assumes "symp r" and "r b a"
   306   shows "r a b"
   307   using assms by (rule symD [to_pred])
   308 
   309 lemma sym_Int:
   310   "sym r \<Longrightarrow> sym s \<Longrightarrow> sym (r \<inter> s)"
   311   by (fast intro: symI elim: symE)
   312 
   313 lemma symp_inf:
   314   "symp r \<Longrightarrow> symp s \<Longrightarrow> symp (r \<sqinter> s)"
   315   by (fact sym_Int [to_pred])
   316 
   317 lemma sym_Un:
   318   "sym r \<Longrightarrow> sym s \<Longrightarrow> sym (r \<union> s)"
   319   by (fast intro: symI elim: symE)
   320 
   321 lemma symp_sup:
   322   "symp r \<Longrightarrow> symp s \<Longrightarrow> symp (r \<squnion> s)"
   323   by (fact sym_Un [to_pred])
   324 
   325 lemma sym_INTER:
   326   "\<forall>x\<in>S. sym (r x) \<Longrightarrow> sym (INTER S r)"
   327   by (fast intro: symI elim: symE)
   328 
   329 lemma symp_INF:
   330   "\<forall>x\<in>S. symp (r x) \<Longrightarrow> symp (INFIMUM S r)"
   331   by (fact sym_INTER [to_pred])
   332 
   333 lemma sym_UNION:
   334   "\<forall>x\<in>S. sym (r x) \<Longrightarrow> sym (UNION S r)"
   335   by (fast intro: symI elim: symE)
   336 
   337 lemma symp_SUP:
   338   "\<forall>x\<in>S. symp (r x) \<Longrightarrow> symp (SUPREMUM S r)"
   339   by (fact sym_UNION [to_pred])
   340 
   341 
   342 subsubsection \<open>Antisymmetry\<close>
   343 
   344 definition antisym :: "'a rel \<Rightarrow> bool"
   345 where
   346   "antisym r \<longleftrightarrow> (\<forall>x y. (x, y) \<in> r \<longrightarrow> (y, x) \<in> r \<longrightarrow> x = y)"
   347 
   348 abbreviation antisymP :: "('a \<Rightarrow> 'a \<Rightarrow> bool) \<Rightarrow> bool"
   349 where
   350   "antisymP r \<equiv> antisym {(x, y). r x y}"
   351 
   352 lemma antisymI:
   353   "(!!x y. (x, y) : r ==> (y, x) : r ==> x=y) ==> antisym r"
   354   by (unfold antisym_def) iprover
   355 
   356 lemma antisymD: "antisym r ==> (a, b) : r ==> (b, a) : r ==> a = b"
   357   by (unfold antisym_def) iprover
   358 
   359 lemma antisym_subset: "r \<subseteq> s ==> antisym s ==> antisym r"
   360   by (unfold antisym_def) blast
   361 
   362 lemma antisym_empty [simp]: "antisym {}"
   363   by (unfold antisym_def) blast
   364 
   365 lemma antisymP_equality [simp]: "antisymP op ="
   366 by(auto intro: antisymI)
   367 
   368 subsubsection \<open>Transitivity\<close>
   369 
   370 definition trans :: "'a rel \<Rightarrow> bool"
   371 where
   372   "trans r \<longleftrightarrow> (\<forall>x y z. (x, y) \<in> r \<longrightarrow> (y, z) \<in> r \<longrightarrow> (x, z) \<in> r)"
   373 
   374 definition transp :: "('a \<Rightarrow> 'a \<Rightarrow> bool) \<Rightarrow> bool"
   375 where
   376   "transp r \<longleftrightarrow> (\<forall>x y z. r x y \<longrightarrow> r y z \<longrightarrow> r x z)"
   377 
   378 lemma transp_trans_eq [pred_set_conv]:
   379   "transp (\<lambda>x y. (x, y) \<in> r) \<longleftrightarrow> trans r" 
   380   by (simp add: trans_def transp_def)
   381 
   382 abbreviation transP :: "('a \<Rightarrow> 'a \<Rightarrow> bool) \<Rightarrow> bool"
   383 where \<comment> \<open>FIXME drop\<close>
   384   "transP r \<equiv> trans {(x, y). r x y}"
   385 
   386 lemma transI:
   387   "(\<And>x y z. (x, y) \<in> r \<Longrightarrow> (y, z) \<in> r \<Longrightarrow> (x, z) \<in> r) \<Longrightarrow> trans r"
   388   by (unfold trans_def) iprover
   389 
   390 lemma transpI:
   391   "(\<And>x y z. r x y \<Longrightarrow> r y z \<Longrightarrow> r x z) \<Longrightarrow> transp r"
   392   by (fact transI [to_pred])
   393 
   394 lemma transE:
   395   assumes "trans r" and "(x, y) \<in> r" and "(y, z) \<in> r"
   396   obtains "(x, z) \<in> r"
   397   using assms by (unfold trans_def) iprover
   398 
   399 lemma transpE:
   400   assumes "transp r" and "r x y" and "r y z"
   401   obtains "r x z"
   402   using assms by (rule transE [to_pred])
   403 
   404 lemma transD:
   405   assumes "trans r" and "(x, y) \<in> r" and "(y, z) \<in> r"
   406   shows "(x, z) \<in> r"
   407   using assms by (rule transE)
   408 
   409 lemma transpD:
   410   assumes "transp r" and "r x y" and "r y z"
   411   shows "r x z"
   412   using assms by (rule transD [to_pred])
   413 
   414 lemma trans_Int:
   415   "trans r \<Longrightarrow> trans s \<Longrightarrow> trans (r \<inter> s)"
   416   by (fast intro: transI elim: transE)
   417 
   418 lemma transp_inf:
   419   "transp r \<Longrightarrow> transp s \<Longrightarrow> transp (r \<sqinter> s)"
   420   by (fact trans_Int [to_pred])
   421 
   422 lemma trans_INTER:
   423   "\<forall>x\<in>S. trans (r x) \<Longrightarrow> trans (INTER S r)"
   424   by (fast intro: transI elim: transD)
   425 
   426 (* FIXME thm trans_INTER [to_pred] *)
   427 
   428 lemma trans_join [code]:
   429   "trans r \<longleftrightarrow> (\<forall>(x, y1) \<in> r. \<forall>(y2, z) \<in> r. y1 = y2 \<longrightarrow> (x, z) \<in> r)"
   430   by (auto simp add: trans_def)
   431 
   432 lemma transp_trans:
   433   "transp r \<longleftrightarrow> trans {(x, y). r x y}"
   434   by (simp add: trans_def transp_def)
   435 
   436 lemma transp_equality [simp]: "transp op ="
   437 by(auto intro: transpI)
   438 
   439 subsubsection \<open>Totality\<close>
   440 
   441 definition total_on :: "'a set \<Rightarrow> 'a rel \<Rightarrow> bool"
   442 where
   443   "total_on A r \<longleftrightarrow> (\<forall>x\<in>A. \<forall>y\<in>A. x \<noteq> y \<longrightarrow> (x, y) \<in> r \<or> (y, x) \<in> r)"
   444 
   445 abbreviation "total \<equiv> total_on UNIV"
   446 
   447 lemma total_on_empty [simp]: "total_on {} r"
   448   by (simp add: total_on_def)
   449 
   450 
   451 subsubsection \<open>Single valued relations\<close>
   452 
   453 definition single_valued :: "('a \<times> 'b) set \<Rightarrow> bool"
   454 where
   455   "single_valued r \<longleftrightarrow> (\<forall>x y. (x, y) \<in> r \<longrightarrow> (\<forall>z. (x, z) \<in> r \<longrightarrow> y = z))"
   456 
   457 abbreviation single_valuedP :: "('a \<Rightarrow> 'b \<Rightarrow> bool) \<Rightarrow> bool" where
   458   "single_valuedP r \<equiv> single_valued {(x, y). r x y}"
   459 
   460 lemma single_valuedI:
   461   "ALL x y. (x,y):r --> (ALL z. (x,z):r --> y=z) ==> single_valued r"
   462   by (unfold single_valued_def)
   463 
   464 lemma single_valuedD:
   465   "single_valued r ==> (x, y) : r ==> (x, z) : r ==> y = z"
   466   by (simp add: single_valued_def)
   467 
   468 lemma single_valued_empty[simp]: "single_valued {}"
   469 by(simp add: single_valued_def)
   470 
   471 lemma single_valued_subset:
   472   "r \<subseteq> s ==> single_valued s ==> single_valued r"
   473   by (unfold single_valued_def) blast
   474 
   475 
   476 subsection \<open>Relation operations\<close>
   477 
   478 subsubsection \<open>The identity relation\<close>
   479 
   480 definition Id :: "'a rel"
   481 where
   482   [code del]: "Id = {p. \<exists>x. p = (x, x)}"
   483 
   484 lemma IdI [intro]: "(a, a) : Id"
   485   by (simp add: Id_def)
   486 
   487 lemma IdE [elim!]: "p : Id ==> (!!x. p = (x, x) ==> P) ==> P"
   488   by (unfold Id_def) (iprover elim: CollectE)
   489 
   490 lemma pair_in_Id_conv [iff]: "((a, b) : Id) = (a = b)"
   491   by (unfold Id_def) blast
   492 
   493 lemma refl_Id: "refl Id"
   494   by (simp add: refl_on_def)
   495 
   496 lemma antisym_Id: "antisym Id"
   497   \<comment> \<open>A strange result, since \<open>Id\<close> is also symmetric.\<close>
   498   by (simp add: antisym_def)
   499 
   500 lemma sym_Id: "sym Id"
   501   by (simp add: sym_def)
   502 
   503 lemma trans_Id: "trans Id"
   504   by (simp add: trans_def)
   505 
   506 lemma single_valued_Id [simp]: "single_valued Id"
   507   by (unfold single_valued_def) blast
   508 
   509 lemma irrefl_diff_Id [simp]: "irrefl (r - Id)"
   510   by (simp add:irrefl_def)
   511 
   512 lemma trans_diff_Id: "trans r \<Longrightarrow> antisym r \<Longrightarrow> trans (r - Id)"
   513   unfolding antisym_def trans_def by blast
   514 
   515 lemma total_on_diff_Id [simp]: "total_on A (r - Id) = total_on A r"
   516   by (simp add: total_on_def)
   517 
   518 lemma Id_fstsnd_eq: "Id = {x. fst x = snd x}"
   519   by force
   520 
   521 subsubsection \<open>Diagonal: identity over a set\<close>
   522 
   523 definition Id_on  :: "'a set \<Rightarrow> 'a rel"
   524 where
   525   "Id_on A = (\<Union>x\<in>A. {(x, x)})"
   526 
   527 lemma Id_on_empty [simp]: "Id_on {} = {}"
   528   by (simp add: Id_on_def) 
   529 
   530 lemma Id_on_eqI: "a = b ==> a : A ==> (a, b) : Id_on A"
   531   by (simp add: Id_on_def)
   532 
   533 lemma Id_onI [intro!]: "a : A ==> (a, a) : Id_on A"
   534   by (rule Id_on_eqI) (rule refl)
   535 
   536 lemma Id_onE [elim!]:
   537   "c : Id_on A ==> (!!x. x : A ==> c = (x, x) ==> P) ==> P"
   538   \<comment> \<open>The general elimination rule.\<close>
   539   by (unfold Id_on_def) (iprover elim!: UN_E singletonE)
   540 
   541 lemma Id_on_iff: "((x, y) : Id_on A) = (x = y & x : A)"
   542   by blast
   543 
   544 lemma Id_on_def' [nitpick_unfold]:
   545   "Id_on {x. A x} = Collect (\<lambda>(x, y). x = y \<and> A x)"
   546   by auto
   547 
   548 lemma Id_on_subset_Times: "Id_on A \<subseteq> A \<times> A"
   549   by blast
   550 
   551 lemma refl_on_Id_on: "refl_on A (Id_on A)"
   552   by (rule refl_onI [OF Id_on_subset_Times Id_onI])
   553 
   554 lemma antisym_Id_on [simp]: "antisym (Id_on A)"
   555   by (unfold antisym_def) blast
   556 
   557 lemma sym_Id_on [simp]: "sym (Id_on A)"
   558   by (rule symI) clarify
   559 
   560 lemma trans_Id_on [simp]: "trans (Id_on A)"
   561   by (fast intro: transI elim: transD)
   562 
   563 lemma single_valued_Id_on [simp]: "single_valued (Id_on A)"
   564   by (unfold single_valued_def) blast
   565 
   566 
   567 subsubsection \<open>Composition\<close>
   568 
   569 inductive_set relcomp  :: "('a \<times> 'b) set \<Rightarrow> ('b \<times> 'c) set \<Rightarrow> ('a \<times> 'c) set" (infixr "O" 75)
   570   for r :: "('a \<times> 'b) set" and s :: "('b \<times> 'c) set"
   571 where
   572   relcompI [intro]: "(a, b) \<in> r \<Longrightarrow> (b, c) \<in> s \<Longrightarrow> (a, c) \<in> r O s"
   573 
   574 notation relcompp (infixr "OO" 75)
   575 
   576 lemmas relcomppI = relcompp.intros
   577 
   578 text \<open>
   579   For historic reasons, the elimination rules are not wholly corresponding.
   580   Feel free to consolidate this.
   581 \<close>
   582 
   583 inductive_cases relcompEpair: "(a, c) \<in> r O s"
   584 inductive_cases relcomppE [elim!]: "(r OO s) a c"
   585 
   586 lemma relcompE [elim!]: "xz \<in> r O s \<Longrightarrow>
   587   (\<And>x y z. xz = (x, z) \<Longrightarrow> (x, y) \<in> r \<Longrightarrow> (y, z) \<in> s  \<Longrightarrow> P) \<Longrightarrow> P"
   588   by (cases xz) (simp, erule relcompEpair, iprover)
   589 
   590 lemma R_O_Id [simp]:
   591   "R O Id = R"
   592   by fast
   593 
   594 lemma Id_O_R [simp]:
   595   "Id O R = R"
   596   by fast
   597 
   598 lemma relcomp_empty1 [simp]:
   599   "{} O R = {}"
   600   by blast
   601 
   602 lemma relcompp_bot1 [simp]:
   603   "\<bottom> OO R = \<bottom>"
   604   by (fact relcomp_empty1 [to_pred])
   605 
   606 lemma relcomp_empty2 [simp]:
   607   "R O {} = {}"
   608   by blast
   609 
   610 lemma relcompp_bot2 [simp]:
   611   "R OO \<bottom> = \<bottom>"
   612   by (fact relcomp_empty2 [to_pred])
   613 
   614 lemma O_assoc:
   615   "(R O S) O T = R O (S O T)"
   616   by blast
   617 
   618 lemma relcompp_assoc:
   619   "(r OO s) OO t = r OO (s OO t)"
   620   by (fact O_assoc [to_pred])
   621 
   622 lemma trans_O_subset:
   623   "trans r \<Longrightarrow> r O r \<subseteq> r"
   624   by (unfold trans_def) blast
   625 
   626 lemma transp_relcompp_less_eq:
   627   "transp r \<Longrightarrow> r OO r \<le> r "
   628   by (fact trans_O_subset [to_pred])
   629 
   630 lemma relcomp_mono:
   631   "r' \<subseteq> r \<Longrightarrow> s' \<subseteq> s \<Longrightarrow> r' O s' \<subseteq> r O s"
   632   by blast
   633 
   634 lemma relcompp_mono:
   635   "r' \<le> r \<Longrightarrow> s' \<le> s \<Longrightarrow> r' OO s' \<le> r OO s "
   636   by (fact relcomp_mono [to_pred])
   637 
   638 lemma relcomp_subset_Sigma:
   639   "r \<subseteq> A \<times> B \<Longrightarrow> s \<subseteq> B \<times> C \<Longrightarrow> r O s \<subseteq> A \<times> C"
   640   by blast
   641 
   642 lemma relcomp_distrib [simp]:
   643   "R O (S \<union> T) = (R O S) \<union> (R O T)" 
   644   by auto
   645 
   646 lemma relcompp_distrib [simp]:
   647   "R OO (S \<squnion> T) = R OO S \<squnion> R OO T"
   648   by (fact relcomp_distrib [to_pred])
   649 
   650 lemma relcomp_distrib2 [simp]:
   651   "(S \<union> T) O R = (S O R) \<union> (T O R)"
   652   by auto
   653 
   654 lemma relcompp_distrib2 [simp]:
   655   "(S \<squnion> T) OO R = S OO R \<squnion> T OO R"
   656   by (fact relcomp_distrib2 [to_pred])
   657 
   658 lemma relcomp_UNION_distrib:
   659   "s O UNION I r = (\<Union>i\<in>I. s O r i) "
   660   by auto
   661 
   662 (* FIXME thm relcomp_UNION_distrib [to_pred] *)
   663 
   664 lemma relcomp_UNION_distrib2:
   665   "UNION I r O s = (\<Union>i\<in>I. r i O s) "
   666   by auto
   667 
   668 (* FIXME thm relcomp_UNION_distrib2 [to_pred] *)
   669 
   670 lemma single_valued_relcomp:
   671   "single_valued r \<Longrightarrow> single_valued s \<Longrightarrow> single_valued (r O s)"
   672   by (unfold single_valued_def) blast
   673 
   674 lemma relcomp_unfold:
   675   "r O s = {(x, z). \<exists>y. (x, y) \<in> r \<and> (y, z) \<in> s}"
   676   by (auto simp add: set_eq_iff)
   677 
   678 lemma relcompp_apply: "(R OO S) a c \<longleftrightarrow> (\<exists>b. R a b \<and> S b c)"
   679   unfolding relcomp_unfold [to_pred] ..
   680 
   681 lemma eq_OO: "op= OO R = R"
   682 by blast
   683 
   684 lemma OO_eq: "R OO op = = R"
   685 by blast
   686 
   687 subsubsection \<open>Converse\<close>
   688 
   689 inductive_set converse :: "('a \<times> 'b) set \<Rightarrow> ('b \<times> 'a) set"  ("(_\<inverse>)" [1000] 999)
   690   for r :: "('a \<times> 'b) set"
   691 where
   692   "(a, b) \<in> r \<Longrightarrow> (b, a) \<in> r\<inverse>"
   693 
   694 notation
   695   conversep  ("(_\<inverse>\<inverse>)" [1000] 1000)
   696 
   697 notation (ASCII)
   698   converse  ("(_^-1)" [1000] 999) and
   699   conversep ("(_^--1)" [1000] 1000)
   700 
   701 lemma converseI [sym]:
   702   "(a, b) \<in> r \<Longrightarrow> (b, a) \<in> r\<inverse>"
   703   by (fact converse.intros)
   704 
   705 lemma conversepI (* CANDIDATE [sym] *):
   706   "r a b \<Longrightarrow> r\<inverse>\<inverse> b a"
   707   by (fact conversep.intros)
   708 
   709 lemma converseD [sym]:
   710   "(a, b) \<in> r\<inverse> \<Longrightarrow> (b, a) \<in> r"
   711   by (erule converse.cases) iprover
   712 
   713 lemma conversepD (* CANDIDATE [sym] *):
   714   "r\<inverse>\<inverse> b a \<Longrightarrow> r a b"
   715   by (fact converseD [to_pred])
   716 
   717 lemma converseE [elim!]:
   718   \<comment> \<open>More general than \<open>converseD\<close>, as it ``splits'' the member of the relation.\<close>
   719   "yx \<in> r\<inverse> \<Longrightarrow> (\<And>x y. yx = (y, x) \<Longrightarrow> (x, y) \<in> r \<Longrightarrow> P) \<Longrightarrow> P"
   720   by (cases yx) (simp, erule converse.cases, iprover)
   721 
   722 lemmas conversepE [elim!] = conversep.cases
   723 
   724 lemma converse_iff [iff]:
   725   "(a, b) \<in> r\<inverse> \<longleftrightarrow> (b, a) \<in> r"
   726   by (auto intro: converseI)
   727 
   728 lemma conversep_iff [iff]:
   729   "r\<inverse>\<inverse> a b = r b a"
   730   by (fact converse_iff [to_pred])
   731 
   732 lemma converse_converse [simp]:
   733   "(r\<inverse>)\<inverse> = r"
   734   by (simp add: set_eq_iff)
   735 
   736 lemma conversep_conversep [simp]:
   737   "(r\<inverse>\<inverse>)\<inverse>\<inverse> = r"
   738   by (fact converse_converse [to_pred])
   739 
   740 lemma converse_empty[simp]: "{}\<inverse> = {}"
   741 by auto
   742 
   743 lemma converse_UNIV[simp]: "UNIV\<inverse> = UNIV"
   744 by auto
   745 
   746 lemma converse_relcomp: "(r O s)^-1 = s^-1 O r^-1"
   747   by blast
   748 
   749 lemma converse_relcompp: "(r OO s)^--1 = s^--1 OO r^--1"
   750   by (iprover intro: order_antisym conversepI relcomppI
   751     elim: relcomppE dest: conversepD)
   752 
   753 lemma converse_Int: "(r \<inter> s)^-1 = r^-1 \<inter> s^-1"
   754   by blast
   755 
   756 lemma converse_meet: "(r \<sqinter> s)^--1 = r^--1 \<sqinter> s^--1"
   757   by (simp add: inf_fun_def) (iprover intro: conversepI ext dest: conversepD)
   758 
   759 lemma converse_Un: "(r \<union> s)^-1 = r^-1 \<union> s^-1"
   760   by blast
   761 
   762 lemma converse_join: "(r \<squnion> s)^--1 = r^--1 \<squnion> s^--1"
   763   by (simp add: sup_fun_def) (iprover intro: conversepI ext dest: conversepD)
   764 
   765 lemma converse_INTER: "(INTER S r)^-1 = (INT x:S. (r x)^-1)"
   766   by fast
   767 
   768 lemma converse_UNION: "(UNION S r)^-1 = (UN x:S. (r x)^-1)"
   769   by blast
   770 
   771 lemma converse_mono[simp]: "r^-1 \<subseteq> s ^-1 \<longleftrightarrow> r \<subseteq> s"
   772   by auto
   773 
   774 lemma conversep_mono[simp]: "r^--1 \<le> s ^--1 \<longleftrightarrow> r \<le> s"
   775   by (fact converse_mono[to_pred])
   776 
   777 lemma converse_inject[simp]: "r^-1 = s ^-1 \<longleftrightarrow> r = s"
   778   by auto
   779 
   780 lemma conversep_inject[simp]: "r^--1 = s ^--1 \<longleftrightarrow> r = s"
   781   by (fact converse_inject[to_pred])
   782 
   783 lemma converse_subset_swap: "r \<subseteq> s ^-1 = (r ^-1 \<subseteq> s)"
   784   by auto
   785 
   786 lemma conversep_le_swap: "r \<le> s ^--1 = (r ^--1 \<le> s)"
   787   by (fact converse_subset_swap[to_pred])
   788 
   789 lemma converse_Id [simp]: "Id^-1 = Id"
   790   by blast
   791 
   792 lemma converse_Id_on [simp]: "(Id_on A)^-1 = Id_on A"
   793   by blast
   794 
   795 lemma refl_on_converse [simp]: "refl_on A (converse r) = refl_on A r"
   796   by (unfold refl_on_def) auto
   797 
   798 lemma sym_converse [simp]: "sym (converse r) = sym r"
   799   by (unfold sym_def) blast
   800 
   801 lemma antisym_converse [simp]: "antisym (converse r) = antisym r"
   802   by (unfold antisym_def) blast
   803 
   804 lemma trans_converse [simp]: "trans (converse r) = trans r"
   805   by (unfold trans_def) blast
   806 
   807 lemma sym_conv_converse_eq: "sym r = (r^-1 = r)"
   808   by (unfold sym_def) fast
   809 
   810 lemma sym_Un_converse: "sym (r \<union> r^-1)"
   811   by (unfold sym_def) blast
   812 
   813 lemma sym_Int_converse: "sym (r \<inter> r^-1)"
   814   by (unfold sym_def) blast
   815 
   816 lemma total_on_converse [simp]: "total_on A (r^-1) = total_on A r"
   817   by (auto simp: total_on_def)
   818 
   819 lemma finite_converse [iff]: "finite (r^-1) = finite r"  
   820   unfolding converse_def conversep_iff using [[simproc add: finite_Collect]]
   821   by (auto elim: finite_imageD simp: inj_on_def)
   822 
   823 lemma conversep_noteq [simp]: "(op \<noteq>)^--1 = op \<noteq>"
   824   by (auto simp add: fun_eq_iff)
   825 
   826 lemma conversep_eq [simp]: "(op =)^--1 = op ="
   827   by (auto simp add: fun_eq_iff)
   828 
   829 lemma converse_unfold [code]:
   830   "r\<inverse> = {(y, x). (x, y) \<in> r}"
   831   by (simp add: set_eq_iff)
   832 
   833 
   834 subsubsection \<open>Domain, range and field\<close>
   835 
   836 inductive_set Domain :: "('a \<times> 'b) set \<Rightarrow> 'a set"
   837   for r :: "('a \<times> 'b) set"
   838 where
   839   DomainI [intro]: "(a, b) \<in> r \<Longrightarrow> a \<in> Domain r"
   840 
   841 abbreviation (input) "DomainP \<equiv> Domainp"
   842 
   843 lemmas DomainPI = Domainp.DomainI
   844 
   845 inductive_cases DomainE [elim!]: "a \<in> Domain r"
   846 inductive_cases DomainpE [elim!]: "Domainp r a"
   847 
   848 inductive_set Range :: "('a \<times> 'b) set \<Rightarrow> 'b set"
   849   for r :: "('a \<times> 'b) set"
   850 where
   851   RangeI [intro]: "(a, b) \<in> r \<Longrightarrow> b \<in> Range r"
   852 
   853 abbreviation (input) "RangeP \<equiv> Rangep"
   854 
   855 lemmas RangePI = Rangep.RangeI
   856 
   857 inductive_cases RangeE [elim!]: "b \<in> Range r"
   858 inductive_cases RangepE [elim!]: "Rangep r b"
   859 
   860 definition Field :: "'a rel \<Rightarrow> 'a set"
   861 where
   862   "Field r = Domain r \<union> Range r"
   863 
   864 lemma Domain_fst [code]:
   865   "Domain r = fst ` r"
   866   by force
   867 
   868 lemma Range_snd [code]:
   869   "Range r = snd ` r"
   870   by force
   871 
   872 lemma fst_eq_Domain: "fst ` R = Domain R"
   873   by force
   874 
   875 lemma snd_eq_Range: "snd ` R = Range R"
   876   by force
   877 
   878 lemma range_fst [simp]: "range fst = UNIV"
   879   by (auto simp: fst_eq_Domain)
   880 
   881 lemma range_snd [simp]: "range snd = UNIV"
   882   by (auto simp: snd_eq_Range)
   883 
   884 lemma Domain_empty [simp]: "Domain {} = {}"
   885   by auto
   886 
   887 lemma Range_empty [simp]: "Range {} = {}"
   888   by auto
   889 
   890 lemma Field_empty [simp]: "Field {} = {}"
   891   by (simp add: Field_def)
   892 
   893 lemma Domain_empty_iff: "Domain r = {} \<longleftrightarrow> r = {}"
   894   by auto
   895 
   896 lemma Range_empty_iff: "Range r = {} \<longleftrightarrow> r = {}"
   897   by auto
   898 
   899 lemma Domain_insert [simp]: "Domain (insert (a, b) r) = insert a (Domain r)"
   900   by blast
   901 
   902 lemma Range_insert [simp]: "Range (insert (a, b) r) = insert b (Range r)"
   903   by blast
   904 
   905 lemma Field_insert [simp]: "Field (insert (a, b) r) = {a, b} \<union> Field r"
   906   by (auto simp add: Field_def)
   907 
   908 lemma Domain_iff: "a \<in> Domain r \<longleftrightarrow> (\<exists>y. (a, y) \<in> r)"
   909   by blast
   910 
   911 lemma Range_iff: "a \<in> Range r \<longleftrightarrow> (\<exists>y. (y, a) \<in> r)"
   912   by blast
   913 
   914 lemma Domain_Id [simp]: "Domain Id = UNIV"
   915   by blast
   916 
   917 lemma Range_Id [simp]: "Range Id = UNIV"
   918   by blast
   919 
   920 lemma Domain_Id_on [simp]: "Domain (Id_on A) = A"
   921   by blast
   922 
   923 lemma Range_Id_on [simp]: "Range (Id_on A) = A"
   924   by blast
   925 
   926 lemma Domain_Un_eq: "Domain (A \<union> B) = Domain A \<union> Domain B"
   927   by blast
   928 
   929 lemma Range_Un_eq: "Range (A \<union> B) = Range A \<union> Range B"
   930   by blast
   931 
   932 lemma Field_Un [simp]: "Field (r \<union> s) = Field r \<union> Field s"
   933   by (auto simp: Field_def)
   934 
   935 lemma Domain_Int_subset: "Domain (A \<inter> B) \<subseteq> Domain A \<inter> Domain B"
   936   by blast
   937 
   938 lemma Range_Int_subset: "Range (A \<inter> B) \<subseteq> Range A \<inter> Range B"
   939   by blast
   940 
   941 lemma Domain_Diff_subset: "Domain A - Domain B \<subseteq> Domain (A - B)"
   942   by blast
   943 
   944 lemma Range_Diff_subset: "Range A - Range B \<subseteq> Range (A - B)"
   945   by blast
   946 
   947 lemma Domain_Union: "Domain (\<Union>S) = (\<Union>A\<in>S. Domain A)"
   948   by blast
   949 
   950 lemma Range_Union: "Range (\<Union>S) = (\<Union>A\<in>S. Range A)"
   951   by blast
   952 
   953 lemma Field_Union [simp]: "Field (\<Union>R) = \<Union>(Field ` R)"
   954   by (auto simp: Field_def)
   955 
   956 lemma Domain_converse [simp]: "Domain (r\<inverse>) = Range r"
   957   by auto
   958 
   959 lemma Range_converse [simp]: "Range (r\<inverse>) = Domain r"
   960   by blast
   961 
   962 lemma Field_converse [simp]: "Field (r\<inverse>) = Field r"
   963   by (auto simp: Field_def)
   964 
   965 lemma Domain_Collect_case_prod [simp]: "Domain {(x, y). P x y} = {x. EX y. P x y}"
   966   by auto
   967 
   968 lemma Range_Collect_case_prod [simp]: "Range {(x, y). P x y} = {y. EX x. P x y}"
   969   by auto
   970 
   971 lemma finite_Domain: "finite r \<Longrightarrow> finite (Domain r)"
   972   by (induct set: finite) auto
   973 
   974 lemma finite_Range: "finite r \<Longrightarrow> finite (Range r)"
   975   by (induct set: finite) auto
   976 
   977 lemma finite_Field: "finite r \<Longrightarrow> finite (Field r)"
   978   by (simp add: Field_def finite_Domain finite_Range)
   979 
   980 lemma Domain_mono: "r \<subseteq> s \<Longrightarrow> Domain r \<subseteq> Domain s"
   981   by blast
   982 
   983 lemma Range_mono: "r \<subseteq> s \<Longrightarrow> Range r \<subseteq> Range s"
   984   by blast
   985 
   986 lemma mono_Field: "r \<subseteq> s \<Longrightarrow> Field r \<subseteq> Field s"
   987   by (auto simp: Field_def Domain_def Range_def)
   988 
   989 lemma Domain_unfold:
   990   "Domain r = {x. \<exists>y. (x, y) \<in> r}"
   991   by blast
   992 
   993 
   994 subsubsection \<open>Image of a set under a relation\<close>
   995 
   996 definition Image :: "('a \<times> 'b) set \<Rightarrow> 'a set \<Rightarrow> 'b set" (infixr "``" 90)
   997 where
   998   "r `` s = {y. \<exists>x\<in>s. (x, y) \<in> r}"
   999 
  1000 lemma Image_iff: "(b : r``A) = (EX x:A. (x, b) : r)"
  1001   by (simp add: Image_def)
  1002 
  1003 lemma Image_singleton: "r``{a} = {b. (a, b) : r}"
  1004   by (simp add: Image_def)
  1005 
  1006 lemma Image_singleton_iff [iff]: "(b : r``{a}) = ((a, b) : r)"
  1007   by (rule Image_iff [THEN trans]) simp
  1008 
  1009 lemma ImageI [intro]: "(a, b) : r ==> a : A ==> b : r``A"
  1010   by (unfold Image_def) blast
  1011 
  1012 lemma ImageE [elim!]:
  1013   "b : r `` A ==> (!!x. (x, b) : r ==> x : A ==> P) ==> P"
  1014   by (unfold Image_def) (iprover elim!: CollectE bexE)
  1015 
  1016 lemma rev_ImageI: "a : A ==> (a, b) : r ==> b : r `` A"
  1017   \<comment> \<open>This version's more effective when we already have the required \<open>a\<close>\<close>
  1018   by blast
  1019 
  1020 lemma Image_empty [simp]: "R``{} = {}"
  1021   by blast
  1022 
  1023 lemma Image_Id [simp]: "Id `` A = A"
  1024   by blast
  1025 
  1026 lemma Image_Id_on [simp]: "Id_on A `` B = A \<inter> B"
  1027   by blast
  1028 
  1029 lemma Image_Int_subset: "R `` (A \<inter> B) \<subseteq> R `` A \<inter> R `` B"
  1030   by blast
  1031 
  1032 lemma Image_Int_eq:
  1033   "single_valued (converse R) ==> R `` (A \<inter> B) = R `` A \<inter> R `` B"
  1034   by (simp add: single_valued_def, blast) 
  1035 
  1036 lemma Image_Un: "R `` (A \<union> B) = R `` A \<union> R `` B"
  1037   by blast
  1038 
  1039 lemma Un_Image: "(R \<union> S) `` A = R `` A \<union> S `` A"
  1040   by blast
  1041 
  1042 lemma Image_subset: "r \<subseteq> A \<times> B ==> r``C \<subseteq> B"
  1043   by (iprover intro!: subsetI elim!: ImageE dest!: subsetD SigmaD2)
  1044 
  1045 lemma Image_eq_UN: "r``B = (\<Union>y\<in> B. r``{y})"
  1046   \<comment> \<open>NOT suitable for rewriting\<close>
  1047   by blast
  1048 
  1049 lemma Image_mono: "r' \<subseteq> r ==> A' \<subseteq> A ==> (r' `` A') \<subseteq> (r `` A)"
  1050   by blast
  1051 
  1052 lemma Image_UN: "(r `` (UNION A B)) = (\<Union>x\<in>A. r `` (B x))"
  1053   by blast
  1054 
  1055 lemma UN_Image: "(\<Union>i\<in>I. X i) `` S = (\<Union>i\<in>I. X i `` S)"
  1056   by auto
  1057 
  1058 lemma Image_INT_subset: "(r `` INTER A B) \<subseteq> (\<Inter>x\<in>A. r `` (B x))"
  1059   by blast
  1060 
  1061 text\<open>Converse inclusion requires some assumptions\<close>
  1062 lemma Image_INT_eq:
  1063   "single_valued (r\<inverse>) \<Longrightarrow> A \<noteq> {} \<Longrightarrow> r `` INTER A B = (\<Inter>x\<in>A. r `` B x)"
  1064 apply (rule equalityI)
  1065  apply (rule Image_INT_subset) 
  1066 apply (auto simp add: single_valued_def)
  1067 apply blast
  1068 done
  1069 
  1070 lemma Image_subset_eq: "(r``A \<subseteq> B) = (A \<subseteq> - ((r^-1) `` (-B)))"
  1071   by blast
  1072 
  1073 lemma Image_Collect_case_prod [simp]: "{(x, y). P x y} `` A = {y. EX x:A. P x y}"
  1074   by auto
  1075 
  1076 lemma Sigma_Image: "(SIGMA x:A. B x) `` X = (\<Union>x\<in>X \<inter> A. B x)"
  1077   by auto
  1078 
  1079 lemma relcomp_Image: "(X O Y) `` Z = Y `` (X `` Z)"
  1080   by auto
  1081 
  1082 subsubsection \<open>Inverse image\<close>
  1083 
  1084 definition inv_image :: "'b rel \<Rightarrow> ('a \<Rightarrow> 'b) \<Rightarrow> 'a rel"
  1085 where
  1086   "inv_image r f = {(x, y). (f x, f y) \<in> r}"
  1087 
  1088 definition inv_imagep :: "('b \<Rightarrow> 'b \<Rightarrow> bool) \<Rightarrow> ('a \<Rightarrow> 'b) \<Rightarrow> 'a \<Rightarrow> 'a \<Rightarrow> bool"
  1089 where
  1090   "inv_imagep r f = (\<lambda>x y. r (f x) (f y))"
  1091 
  1092 lemma [pred_set_conv]: "inv_imagep (\<lambda>x y. (x, y) \<in> r) f = (\<lambda>x y. (x, y) \<in> inv_image r f)"
  1093   by (simp add: inv_image_def inv_imagep_def)
  1094 
  1095 lemma sym_inv_image: "sym r ==> sym (inv_image r f)"
  1096   by (unfold sym_def inv_image_def) blast
  1097 
  1098 lemma trans_inv_image: "trans r ==> trans (inv_image r f)"
  1099   apply (unfold trans_def inv_image_def)
  1100   apply (simp (no_asm))
  1101   apply blast
  1102   done
  1103 
  1104 lemma in_inv_image[simp]: "((x,y) : inv_image r f) = ((f x, f y) : r)"
  1105   by (auto simp:inv_image_def)
  1106 
  1107 lemma converse_inv_image[simp]: "(inv_image R f)^-1 = inv_image (R^-1) f"
  1108   unfolding inv_image_def converse_unfold by auto
  1109 
  1110 lemma in_inv_imagep [simp]: "inv_imagep r f x y = r (f x) (f y)"
  1111   by (simp add: inv_imagep_def)
  1112 
  1113 
  1114 subsubsection \<open>Powerset\<close>
  1115 
  1116 definition Powp :: "('a \<Rightarrow> bool) \<Rightarrow> 'a set \<Rightarrow> bool"
  1117 where
  1118   "Powp A = (\<lambda>B. \<forall>x \<in> B. A x)"
  1119 
  1120 lemma Powp_Pow_eq [pred_set_conv]: "Powp (\<lambda>x. x \<in> A) = (\<lambda>x. x \<in> Pow A)"
  1121   by (auto simp add: Powp_def fun_eq_iff)
  1122 
  1123 lemmas Powp_mono [mono] = Pow_mono [to_pred]
  1124 
  1125 subsubsection \<open>Expressing relation operations via @{const Finite_Set.fold}\<close>
  1126 
  1127 lemma Id_on_fold:
  1128   assumes "finite A"
  1129   shows "Id_on A = Finite_Set.fold (\<lambda>x. Set.insert (Pair x x)) {} A"
  1130 proof -
  1131   interpret comp_fun_commute "\<lambda>x. Set.insert (Pair x x)" by standard auto
  1132   show ?thesis using assms unfolding Id_on_def by (induct A) simp_all
  1133 qed
  1134 
  1135 lemma comp_fun_commute_Image_fold:
  1136   "comp_fun_commute (\<lambda>(x,y) A. if x \<in> S then Set.insert y A else A)"
  1137 proof -
  1138   interpret comp_fun_idem Set.insert
  1139       by (fact comp_fun_idem_insert)
  1140   show ?thesis 
  1141   by standard (auto simp add: fun_eq_iff comp_fun_commute split:prod.split)
  1142 qed
  1143 
  1144 lemma Image_fold:
  1145   assumes "finite R"
  1146   shows "R `` S = Finite_Set.fold (\<lambda>(x,y) A. if x \<in> S then Set.insert y A else A) {} R"
  1147 proof -
  1148   interpret comp_fun_commute "(\<lambda>(x,y) A. if x \<in> S then Set.insert y A else A)" 
  1149     by (rule comp_fun_commute_Image_fold)
  1150   have *: "\<And>x F. Set.insert x F `` S = (if fst x \<in> S then Set.insert (snd x) (F `` S) else (F `` S))"
  1151     by (force intro: rev_ImageI)
  1152   show ?thesis using assms by (induct R) (auto simp: *)
  1153 qed
  1154 
  1155 lemma insert_relcomp_union_fold:
  1156   assumes "finite S"
  1157   shows "{x} O S \<union> X = Finite_Set.fold (\<lambda>(w,z) A'. if snd x = w then Set.insert (fst x,z) A' else A') X S"
  1158 proof -
  1159   interpret comp_fun_commute "\<lambda>(w,z) A'. if snd x = w then Set.insert (fst x,z) A' else A'"
  1160   proof - 
  1161     interpret comp_fun_idem Set.insert by (fact comp_fun_idem_insert)
  1162     show "comp_fun_commute (\<lambda>(w,z) A'. if snd x = w then Set.insert (fst x,z) A' else A')"
  1163     by standard (auto simp add: fun_eq_iff split:prod.split)
  1164   qed
  1165   have *: "{x} O S = {(x', z). x' = fst x \<and> (snd x,z) \<in> S}" by (auto simp: relcomp_unfold intro!: exI)
  1166   show ?thesis unfolding *
  1167   using \<open>finite S\<close> by (induct S) (auto split: prod.split)
  1168 qed
  1169 
  1170 lemma insert_relcomp_fold:
  1171   assumes "finite S"
  1172   shows "Set.insert x R O S = 
  1173     Finite_Set.fold (\<lambda>(w,z) A'. if snd x = w then Set.insert (fst x,z) A' else A') (R O S) S"
  1174 proof -
  1175   have "Set.insert x R O S = ({x} O S) \<union> (R O S)" by auto
  1176   then show ?thesis by (auto simp: insert_relcomp_union_fold[OF assms])
  1177 qed
  1178 
  1179 lemma comp_fun_commute_relcomp_fold:
  1180   assumes "finite S"
  1181   shows "comp_fun_commute (\<lambda>(x,y) A. 
  1182     Finite_Set.fold (\<lambda>(w,z) A'. if y = w then Set.insert (x,z) A' else A') A S)"
  1183 proof -
  1184   have *: "\<And>a b A. 
  1185     Finite_Set.fold (\<lambda>(w, z) A'. if b = w then Set.insert (a, z) A' else A') A S = {(a,b)} O S \<union> A"
  1186     by (auto simp: insert_relcomp_union_fold[OF assms] cong: if_cong)
  1187   show ?thesis by standard (auto simp: *)
  1188 qed
  1189 
  1190 lemma relcomp_fold:
  1191   assumes "finite R"
  1192   assumes "finite S"
  1193   shows "R O S = Finite_Set.fold 
  1194     (\<lambda>(x,y) A. Finite_Set.fold (\<lambda>(w,z) A'. if y = w then Set.insert (x,z) A' else A') A S) {} R"
  1195   using assms by (induct R)
  1196     (auto simp: comp_fun_commute.fold_insert comp_fun_commute_relcomp_fold insert_relcomp_fold
  1197       cong: if_cong)
  1198 
  1199 end