src/HOL/Limits.thy
author huffman
Sun Apr 25 11:58:39 2010 -0700 (2010-04-25)
changeset 36358 246493d61204
parent 31902 862ae16a799d
child 36360 9d8f7efd9289
permissions -rw-r--r--
define nets directly as filters, instead of as filter bases
     1 (*  Title       : Limits.thy
     2     Author      : Brian Huffman
     3 *)
     4 
     5 header {* Filters and Limits *}
     6 
     7 theory Limits
     8 imports RealVector RComplete
     9 begin
    10 
    11 subsection {* Nets *}
    12 
    13 text {*
    14   A net is now defined simply as a filter.
    15   The definition also allows non-proper filters.
    16 *}
    17 
    18 locale is_filter =
    19   fixes net :: "('a \<Rightarrow> bool) \<Rightarrow> bool"
    20   assumes True: "net (\<lambda>x. True)"
    21   assumes conj: "net (\<lambda>x. P x) \<Longrightarrow> net (\<lambda>x. Q x) \<Longrightarrow> net (\<lambda>x. P x \<and> Q x)"
    22   assumes mono: "\<forall>x. P x \<longrightarrow> Q x \<Longrightarrow> net (\<lambda>x. P x) \<Longrightarrow> net (\<lambda>x. Q x)"
    23 
    24 typedef (open) 'a net =
    25   "{net :: ('a \<Rightarrow> bool) \<Rightarrow> bool. is_filter net}"
    26 proof
    27   show "(\<lambda>x. True) \<in> ?net" by (auto intro: is_filter.intro)
    28 qed
    29 
    30 lemma is_filter_Rep_net: "is_filter (Rep_net net)"
    31 using Rep_net [of net] by simp
    32 
    33 lemma Abs_net_inverse':
    34   assumes "is_filter net" shows "Rep_net (Abs_net net) = net"
    35 using assms by (simp add: Abs_net_inverse)
    36 
    37 
    38 subsection {* Eventually *}
    39 
    40 definition
    41   eventually :: "('a \<Rightarrow> bool) \<Rightarrow> 'a net \<Rightarrow> bool" where
    42   [code del]: "eventually P net \<longleftrightarrow> Rep_net net P"
    43 
    44 lemma eventually_Abs_net:
    45   assumes "is_filter net" shows "eventually P (Abs_net net) = net P"
    46 unfolding eventually_def using assms by (simp add: Abs_net_inverse)
    47 
    48 lemma eventually_True [simp]: "eventually (\<lambda>x. True) net"
    49 unfolding eventually_def
    50 by (rule is_filter.True [OF is_filter_Rep_net])
    51 
    52 lemma eventually_mono:
    53   "(\<forall>x. P x \<longrightarrow> Q x) \<Longrightarrow> eventually P net \<Longrightarrow> eventually Q net"
    54 unfolding eventually_def
    55 by (rule is_filter.mono [OF is_filter_Rep_net])
    56 
    57 lemma eventually_conj:
    58   assumes P: "eventually (\<lambda>x. P x) net"
    59   assumes Q: "eventually (\<lambda>x. Q x) net"
    60   shows "eventually (\<lambda>x. P x \<and> Q x) net"
    61 using assms unfolding eventually_def
    62 by (rule is_filter.conj [OF is_filter_Rep_net])
    63 
    64 lemma eventually_mp:
    65   assumes "eventually (\<lambda>x. P x \<longrightarrow> Q x) net"
    66   assumes "eventually (\<lambda>x. P x) net"
    67   shows "eventually (\<lambda>x. Q x) net"
    68 proof (rule eventually_mono)
    69   show "\<forall>x. (P x \<longrightarrow> Q x) \<and> P x \<longrightarrow> Q x" by simp
    70   show "eventually (\<lambda>x. (P x \<longrightarrow> Q x) \<and> P x) net"
    71     using assms by (rule eventually_conj)
    72 qed
    73 
    74 lemma eventually_rev_mp:
    75   assumes "eventually (\<lambda>x. P x) net"
    76   assumes "eventually (\<lambda>x. P x \<longrightarrow> Q x) net"
    77   shows "eventually (\<lambda>x. Q x) net"
    78 using assms(2) assms(1) by (rule eventually_mp)
    79 
    80 lemma eventually_conj_iff:
    81   "eventually (\<lambda>x. P x \<and> Q x) net \<longleftrightarrow> eventually P net \<and> eventually Q net"
    82 by (auto intro: eventually_conj elim: eventually_rev_mp)
    83 
    84 lemma eventually_elim1:
    85   assumes "eventually (\<lambda>i. P i) net"
    86   assumes "\<And>i. P i \<Longrightarrow> Q i"
    87   shows "eventually (\<lambda>i. Q i) net"
    88 using assms by (auto elim!: eventually_rev_mp)
    89 
    90 lemma eventually_elim2:
    91   assumes "eventually (\<lambda>i. P i) net"
    92   assumes "eventually (\<lambda>i. Q i) net"
    93   assumes "\<And>i. P i \<Longrightarrow> Q i \<Longrightarrow> R i"
    94   shows "eventually (\<lambda>i. R i) net"
    95 using assms by (auto elim!: eventually_rev_mp)
    96 
    97 
    98 subsection {* Standard Nets *}
    99 
   100 definition
   101   sequentially :: "nat net"
   102 where [code del]:
   103   "sequentially = Abs_net (\<lambda>P. \<exists>k. \<forall>n\<ge>k. P n)"
   104 
   105 definition
   106   within :: "'a net \<Rightarrow> 'a set \<Rightarrow> 'a net" (infixr "within" 70)
   107 where [code del]:
   108   "net within S = Abs_net (\<lambda>P. eventually (\<lambda>x. x \<in> S \<longrightarrow> P x) net)"
   109 
   110 definition
   111   at :: "'a::topological_space \<Rightarrow> 'a net"
   112 where [code del]:
   113   "at a = Abs_net (\<lambda>P. \<exists>S. open S \<and> a \<in> S \<and> (\<forall>x\<in>S. x \<noteq> a \<longrightarrow> P x))"
   114 
   115 lemma eventually_sequentially:
   116   "eventually P sequentially \<longleftrightarrow> (\<exists>N. \<forall>n\<ge>N. P n)"
   117 unfolding sequentially_def
   118 proof (rule eventually_Abs_net, rule is_filter.intro)
   119   fix P Q :: "nat \<Rightarrow> bool"
   120   assume "\<exists>i. \<forall>n\<ge>i. P n" and "\<exists>j. \<forall>n\<ge>j. Q n"
   121   then obtain i j where "\<forall>n\<ge>i. P n" and "\<forall>n\<ge>j. Q n" by auto
   122   then have "\<forall>n\<ge>max i j. P n \<and> Q n" by simp
   123   then show "\<exists>k. \<forall>n\<ge>k. P n \<and> Q n" ..
   124 qed auto
   125 
   126 lemma eventually_within:
   127   "eventually P (net within S) = eventually (\<lambda>x. x \<in> S \<longrightarrow> P x) net"
   128 unfolding within_def
   129 by (rule eventually_Abs_net, rule is_filter.intro)
   130    (auto elim!: eventually_rev_mp)
   131 
   132 lemma eventually_at_topological:
   133   "eventually P (at a) \<longleftrightarrow> (\<exists>S. open S \<and> a \<in> S \<and> (\<forall>x\<in>S. x \<noteq> a \<longrightarrow> P x))"
   134 unfolding at_def
   135 proof (rule eventually_Abs_net, rule is_filter.intro)
   136   have "open UNIV \<and> a \<in> UNIV \<and> (\<forall>x\<in>UNIV. x \<noteq> a \<longrightarrow> True)" by simp
   137   thus "\<exists>S. open S \<and> a \<in> S \<and> (\<forall>x\<in>S. x \<noteq> a \<longrightarrow> True)" by - rule
   138 next
   139   fix P Q
   140   assume "\<exists>S. open S \<and> a \<in> S \<and> (\<forall>x\<in>S. x \<noteq> a \<longrightarrow> P x)"
   141      and "\<exists>T. open T \<and> a \<in> T \<and> (\<forall>x\<in>T. x \<noteq> a \<longrightarrow> Q x)"
   142   then obtain S T where
   143     "open S \<and> a \<in> S \<and> (\<forall>x\<in>S. x \<noteq> a \<longrightarrow> P x)"
   144     "open T \<and> a \<in> T \<and> (\<forall>x\<in>T. x \<noteq> a \<longrightarrow> Q x)" by auto
   145   hence "open (S \<inter> T) \<and> a \<in> S \<inter> T \<and> (\<forall>x\<in>(S \<inter> T). x \<noteq> a \<longrightarrow> P x \<and> Q x)"
   146     by (simp add: open_Int)
   147   thus "\<exists>S. open S \<and> a \<in> S \<and> (\<forall>x\<in>S. x \<noteq> a \<longrightarrow> P x \<and> Q x)" by - rule
   148 qed auto
   149 
   150 lemma eventually_at:
   151   fixes a :: "'a::metric_space"
   152   shows "eventually P (at a) \<longleftrightarrow> (\<exists>d>0. \<forall>x. x \<noteq> a \<and> dist x a < d \<longrightarrow> P x)"
   153 unfolding eventually_at_topological open_dist
   154 apply safe
   155 apply fast
   156 apply (rule_tac x="{x. dist x a < d}" in exI, simp)
   157 apply clarsimp
   158 apply (rule_tac x="d - dist x a" in exI, clarsimp)
   159 apply (simp only: less_diff_eq)
   160 apply (erule le_less_trans [OF dist_triangle])
   161 done
   162 
   163 
   164 subsection {* Boundedness *}
   165 
   166 definition
   167   Bfun :: "('a \<Rightarrow> 'b::real_normed_vector) \<Rightarrow> 'a net \<Rightarrow> bool" where
   168   [code del]: "Bfun f net = (\<exists>K>0. eventually (\<lambda>x. norm (f x) \<le> K) net)"
   169 
   170 lemma BfunI:
   171   assumes K: "eventually (\<lambda>x. norm (f x) \<le> K) net" shows "Bfun f net"
   172 unfolding Bfun_def
   173 proof (intro exI conjI allI)
   174   show "0 < max K 1" by simp
   175 next
   176   show "eventually (\<lambda>x. norm (f x) \<le> max K 1) net"
   177     using K by (rule eventually_elim1, simp)
   178 qed
   179 
   180 lemma BfunE:
   181   assumes "Bfun f net"
   182   obtains B where "0 < B" and "eventually (\<lambda>x. norm (f x) \<le> B) net"
   183 using assms unfolding Bfun_def by fast
   184 
   185 
   186 subsection {* Convergence to Zero *}
   187 
   188 definition
   189   Zfun :: "('a \<Rightarrow> 'b::real_normed_vector) \<Rightarrow> 'a net \<Rightarrow> bool" where
   190   [code del]: "Zfun f net = (\<forall>r>0. eventually (\<lambda>x. norm (f x) < r) net)"
   191 
   192 lemma ZfunI:
   193   "(\<And>r. 0 < r \<Longrightarrow> eventually (\<lambda>x. norm (f x) < r) net) \<Longrightarrow> Zfun f net"
   194 unfolding Zfun_def by simp
   195 
   196 lemma ZfunD:
   197   "\<lbrakk>Zfun f net; 0 < r\<rbrakk> \<Longrightarrow> eventually (\<lambda>x. norm (f x) < r) net"
   198 unfolding Zfun_def by simp
   199 
   200 lemma Zfun_ssubst:
   201   "eventually (\<lambda>x. f x = g x) net \<Longrightarrow> Zfun g net \<Longrightarrow> Zfun f net"
   202 unfolding Zfun_def by (auto elim!: eventually_rev_mp)
   203 
   204 lemma Zfun_zero: "Zfun (\<lambda>x. 0) net"
   205 unfolding Zfun_def by simp
   206 
   207 lemma Zfun_norm_iff: "Zfun (\<lambda>x. norm (f x)) net = Zfun (\<lambda>x. f x) net"
   208 unfolding Zfun_def by simp
   209 
   210 lemma Zfun_imp_Zfun:
   211   assumes f: "Zfun f net"
   212   assumes g: "eventually (\<lambda>x. norm (g x) \<le> norm (f x) * K) net"
   213   shows "Zfun (\<lambda>x. g x) net"
   214 proof (cases)
   215   assume K: "0 < K"
   216   show ?thesis
   217   proof (rule ZfunI)
   218     fix r::real assume "0 < r"
   219     hence "0 < r / K"
   220       using K by (rule divide_pos_pos)
   221     then have "eventually (\<lambda>x. norm (f x) < r / K) net"
   222       using ZfunD [OF f] by fast
   223     with g show "eventually (\<lambda>x. norm (g x) < r) net"
   224     proof (rule eventually_elim2)
   225       fix x
   226       assume *: "norm (g x) \<le> norm (f x) * K"
   227       assume "norm (f x) < r / K"
   228       hence "norm (f x) * K < r"
   229         by (simp add: pos_less_divide_eq K)
   230       thus "norm (g x) < r"
   231         by (simp add: order_le_less_trans [OF *])
   232     qed
   233   qed
   234 next
   235   assume "\<not> 0 < K"
   236   hence K: "K \<le> 0" by (simp only: not_less)
   237   show ?thesis
   238   proof (rule ZfunI)
   239     fix r :: real
   240     assume "0 < r"
   241     from g show "eventually (\<lambda>x. norm (g x) < r) net"
   242     proof (rule eventually_elim1)
   243       fix x
   244       assume "norm (g x) \<le> norm (f x) * K"
   245       also have "\<dots> \<le> norm (f x) * 0"
   246         using K norm_ge_zero by (rule mult_left_mono)
   247       finally show "norm (g x) < r"
   248         using `0 < r` by simp
   249     qed
   250   qed
   251 qed
   252 
   253 lemma Zfun_le: "\<lbrakk>Zfun g net; \<forall>x. norm (f x) \<le> norm (g x)\<rbrakk> \<Longrightarrow> Zfun f net"
   254 by (erule_tac K="1" in Zfun_imp_Zfun, simp)
   255 
   256 lemma Zfun_add:
   257   assumes f: "Zfun f net" and g: "Zfun g net"
   258   shows "Zfun (\<lambda>x. f x + g x) net"
   259 proof (rule ZfunI)
   260   fix r::real assume "0 < r"
   261   hence r: "0 < r / 2" by simp
   262   have "eventually (\<lambda>x. norm (f x) < r/2) net"
   263     using f r by (rule ZfunD)
   264   moreover
   265   have "eventually (\<lambda>x. norm (g x) < r/2) net"
   266     using g r by (rule ZfunD)
   267   ultimately
   268   show "eventually (\<lambda>x. norm (f x + g x) < r) net"
   269   proof (rule eventually_elim2)
   270     fix x
   271     assume *: "norm (f x) < r/2" "norm (g x) < r/2"
   272     have "norm (f x + g x) \<le> norm (f x) + norm (g x)"
   273       by (rule norm_triangle_ineq)
   274     also have "\<dots> < r/2 + r/2"
   275       using * by (rule add_strict_mono)
   276     finally show "norm (f x + g x) < r"
   277       by simp
   278   qed
   279 qed
   280 
   281 lemma Zfun_minus: "Zfun f net \<Longrightarrow> Zfun (\<lambda>x. - f x) net"
   282 unfolding Zfun_def by simp
   283 
   284 lemma Zfun_diff: "\<lbrakk>Zfun f net; Zfun g net\<rbrakk> \<Longrightarrow> Zfun (\<lambda>x. f x - g x) net"
   285 by (simp only: diff_minus Zfun_add Zfun_minus)
   286 
   287 lemma (in bounded_linear) Zfun:
   288   assumes g: "Zfun g net"
   289   shows "Zfun (\<lambda>x. f (g x)) net"
   290 proof -
   291   obtain K where "\<And>x. norm (f x) \<le> norm x * K"
   292     using bounded by fast
   293   then have "eventually (\<lambda>x. norm (f (g x)) \<le> norm (g x) * K) net"
   294     by simp
   295   with g show ?thesis
   296     by (rule Zfun_imp_Zfun)
   297 qed
   298 
   299 lemma (in bounded_bilinear) Zfun:
   300   assumes f: "Zfun f net"
   301   assumes g: "Zfun g net"
   302   shows "Zfun (\<lambda>x. f x ** g x) net"
   303 proof (rule ZfunI)
   304   fix r::real assume r: "0 < r"
   305   obtain K where K: "0 < K"
   306     and norm_le: "\<And>x y. norm (x ** y) \<le> norm x * norm y * K"
   307     using pos_bounded by fast
   308   from K have K': "0 < inverse K"
   309     by (rule positive_imp_inverse_positive)
   310   have "eventually (\<lambda>x. norm (f x) < r) net"
   311     using f r by (rule ZfunD)
   312   moreover
   313   have "eventually (\<lambda>x. norm (g x) < inverse K) net"
   314     using g K' by (rule ZfunD)
   315   ultimately
   316   show "eventually (\<lambda>x. norm (f x ** g x) < r) net"
   317   proof (rule eventually_elim2)
   318     fix x
   319     assume *: "norm (f x) < r" "norm (g x) < inverse K"
   320     have "norm (f x ** g x) \<le> norm (f x) * norm (g x) * K"
   321       by (rule norm_le)
   322     also have "norm (f x) * norm (g x) * K < r * inverse K * K"
   323       by (intro mult_strict_right_mono mult_strict_mono' norm_ge_zero * K)
   324     also from K have "r * inverse K * K = r"
   325       by simp
   326     finally show "norm (f x ** g x) < r" .
   327   qed
   328 qed
   329 
   330 lemma (in bounded_bilinear) Zfun_left:
   331   "Zfun f net \<Longrightarrow> Zfun (\<lambda>x. f x ** a) net"
   332 by (rule bounded_linear_left [THEN bounded_linear.Zfun])
   333 
   334 lemma (in bounded_bilinear) Zfun_right:
   335   "Zfun f net \<Longrightarrow> Zfun (\<lambda>x. a ** f x) net"
   336 by (rule bounded_linear_right [THEN bounded_linear.Zfun])
   337 
   338 lemmas Zfun_mult = mult.Zfun
   339 lemmas Zfun_mult_right = mult.Zfun_right
   340 lemmas Zfun_mult_left = mult.Zfun_left
   341 
   342 
   343 subsection {* Limits *}
   344 
   345 definition
   346   tendsto :: "('a \<Rightarrow> 'b::topological_space) \<Rightarrow> 'b \<Rightarrow> 'a net \<Rightarrow> bool"
   347     (infixr "--->" 55)
   348 where [code del]:
   349   "(f ---> l) net \<longleftrightarrow> (\<forall>S. open S \<longrightarrow> l \<in> S \<longrightarrow> eventually (\<lambda>x. f x \<in> S) net)"
   350 
   351 ML {*
   352 structure Tendsto_Intros = Named_Thms
   353 (
   354   val name = "tendsto_intros"
   355   val description = "introduction rules for tendsto"
   356 )
   357 *}
   358 
   359 setup Tendsto_Intros.setup
   360 
   361 lemma topological_tendstoI:
   362   "(\<And>S. open S \<Longrightarrow> l \<in> S \<Longrightarrow> eventually (\<lambda>x. f x \<in> S) net)
   363     \<Longrightarrow> (f ---> l) net"
   364   unfolding tendsto_def by auto
   365 
   366 lemma topological_tendstoD:
   367   "(f ---> l) net \<Longrightarrow> open S \<Longrightarrow> l \<in> S \<Longrightarrow> eventually (\<lambda>x. f x \<in> S) net"
   368   unfolding tendsto_def by auto
   369 
   370 lemma tendstoI:
   371   assumes "\<And>e. 0 < e \<Longrightarrow> eventually (\<lambda>x. dist (f x) l < e) net"
   372   shows "(f ---> l) net"
   373 apply (rule topological_tendstoI)
   374 apply (simp add: open_dist)
   375 apply (drule (1) bspec, clarify)
   376 apply (drule assms)
   377 apply (erule eventually_elim1, simp)
   378 done
   379 
   380 lemma tendstoD:
   381   "(f ---> l) net \<Longrightarrow> 0 < e \<Longrightarrow> eventually (\<lambda>x. dist (f x) l < e) net"
   382 apply (drule_tac S="{x. dist x l < e}" in topological_tendstoD)
   383 apply (clarsimp simp add: open_dist)
   384 apply (rule_tac x="e - dist x l" in exI, clarsimp)
   385 apply (simp only: less_diff_eq)
   386 apply (erule le_less_trans [OF dist_triangle])
   387 apply simp
   388 apply simp
   389 done
   390 
   391 lemma tendsto_iff:
   392   "(f ---> l) net \<longleftrightarrow> (\<forall>e>0. eventually (\<lambda>x. dist (f x) l < e) net)"
   393 using tendstoI tendstoD by fast
   394 
   395 lemma tendsto_Zfun_iff: "(f ---> a) net = Zfun (\<lambda>x. f x - a) net"
   396 by (simp only: tendsto_iff Zfun_def dist_norm)
   397 
   398 lemma tendsto_ident_at [tendsto_intros]: "((\<lambda>x. x) ---> a) (at a)"
   399 unfolding tendsto_def eventually_at_topological by auto
   400 
   401 lemma tendsto_ident_at_within [tendsto_intros]:
   402   "a \<in> S \<Longrightarrow> ((\<lambda>x. x) ---> a) (at a within S)"
   403 unfolding tendsto_def eventually_within eventually_at_topological by auto
   404 
   405 lemma tendsto_const [tendsto_intros]: "((\<lambda>x. k) ---> k) net"
   406 by (simp add: tendsto_def)
   407 
   408 lemma tendsto_dist [tendsto_intros]:
   409   assumes f: "(f ---> l) net" and g: "(g ---> m) net"
   410   shows "((\<lambda>x. dist (f x) (g x)) ---> dist l m) net"
   411 proof (rule tendstoI)
   412   fix e :: real assume "0 < e"
   413   hence e2: "0 < e/2" by simp
   414   from tendstoD [OF f e2] tendstoD [OF g e2]
   415   show "eventually (\<lambda>x. dist (dist (f x) (g x)) (dist l m) < e) net"
   416   proof (rule eventually_elim2)
   417     fix x assume "dist (f x) l < e/2" "dist (g x) m < e/2"
   418     then show "dist (dist (f x) (g x)) (dist l m) < e"
   419       unfolding dist_real_def
   420       using dist_triangle2 [of "f x" "g x" "l"]
   421       using dist_triangle2 [of "g x" "l" "m"]
   422       using dist_triangle3 [of "l" "m" "f x"]
   423       using dist_triangle [of "f x" "m" "g x"]
   424       by arith
   425   qed
   426 qed
   427 
   428 lemma tendsto_norm [tendsto_intros]:
   429   "(f ---> a) net \<Longrightarrow> ((\<lambda>x. norm (f x)) ---> norm a) net"
   430 apply (simp add: tendsto_iff dist_norm, safe)
   431 apply (drule_tac x="e" in spec, safe)
   432 apply (erule eventually_elim1)
   433 apply (erule order_le_less_trans [OF norm_triangle_ineq3])
   434 done
   435 
   436 lemma add_diff_add:
   437   fixes a b c d :: "'a::ab_group_add"
   438   shows "(a + c) - (b + d) = (a - b) + (c - d)"
   439 by simp
   440 
   441 lemma minus_diff_minus:
   442   fixes a b :: "'a::ab_group_add"
   443   shows "(- a) - (- b) = - (a - b)"
   444 by simp
   445 
   446 lemma tendsto_add [tendsto_intros]:
   447   fixes a b :: "'a::real_normed_vector"
   448   shows "\<lbrakk>(f ---> a) net; (g ---> b) net\<rbrakk> \<Longrightarrow> ((\<lambda>x. f x + g x) ---> a + b) net"
   449 by (simp only: tendsto_Zfun_iff add_diff_add Zfun_add)
   450 
   451 lemma tendsto_minus [tendsto_intros]:
   452   fixes a :: "'a::real_normed_vector"
   453   shows "(f ---> a) net \<Longrightarrow> ((\<lambda>x. - f x) ---> - a) net"
   454 by (simp only: tendsto_Zfun_iff minus_diff_minus Zfun_minus)
   455 
   456 lemma tendsto_minus_cancel:
   457   fixes a :: "'a::real_normed_vector"
   458   shows "((\<lambda>x. - f x) ---> - a) net \<Longrightarrow> (f ---> a) net"
   459 by (drule tendsto_minus, simp)
   460 
   461 lemma tendsto_diff [tendsto_intros]:
   462   fixes a b :: "'a::real_normed_vector"
   463   shows "\<lbrakk>(f ---> a) net; (g ---> b) net\<rbrakk> \<Longrightarrow> ((\<lambda>x. f x - g x) ---> a - b) net"
   464 by (simp add: diff_minus tendsto_add tendsto_minus)
   465 
   466 lemma tendsto_setsum [tendsto_intros]:
   467   fixes f :: "'a \<Rightarrow> 'b \<Rightarrow> 'c::real_normed_vector"
   468   assumes "\<And>i. i \<in> S \<Longrightarrow> (f i ---> a i) net"
   469   shows "((\<lambda>x. \<Sum>i\<in>S. f i x) ---> (\<Sum>i\<in>S. a i)) net"
   470 proof (cases "finite S")
   471   assume "finite S" thus ?thesis using assms
   472   proof (induct set: finite)
   473     case empty show ?case
   474       by (simp add: tendsto_const)
   475   next
   476     case (insert i F) thus ?case
   477       by (simp add: tendsto_add)
   478   qed
   479 next
   480   assume "\<not> finite S" thus ?thesis
   481     by (simp add: tendsto_const)
   482 qed
   483 
   484 lemma (in bounded_linear) tendsto [tendsto_intros]:
   485   "(g ---> a) net \<Longrightarrow> ((\<lambda>x. f (g x)) ---> f a) net"
   486 by (simp only: tendsto_Zfun_iff diff [symmetric] Zfun)
   487 
   488 lemma (in bounded_bilinear) tendsto [tendsto_intros]:
   489   "\<lbrakk>(f ---> a) net; (g ---> b) net\<rbrakk> \<Longrightarrow> ((\<lambda>x. f x ** g x) ---> a ** b) net"
   490 by (simp only: tendsto_Zfun_iff prod_diff_prod
   491                Zfun_add Zfun Zfun_left Zfun_right)
   492 
   493 
   494 subsection {* Continuity of Inverse *}
   495 
   496 lemma (in bounded_bilinear) Zfun_prod_Bfun:
   497   assumes f: "Zfun f net"
   498   assumes g: "Bfun g net"
   499   shows "Zfun (\<lambda>x. f x ** g x) net"
   500 proof -
   501   obtain K where K: "0 \<le> K"
   502     and norm_le: "\<And>x y. norm (x ** y) \<le> norm x * norm y * K"
   503     using nonneg_bounded by fast
   504   obtain B where B: "0 < B"
   505     and norm_g: "eventually (\<lambda>x. norm (g x) \<le> B) net"
   506     using g by (rule BfunE)
   507   have "eventually (\<lambda>x. norm (f x ** g x) \<le> norm (f x) * (B * K)) net"
   508   using norm_g proof (rule eventually_elim1)
   509     fix x
   510     assume *: "norm (g x) \<le> B"
   511     have "norm (f x ** g x) \<le> norm (f x) * norm (g x) * K"
   512       by (rule norm_le)
   513     also have "\<dots> \<le> norm (f x) * B * K"
   514       by (intro mult_mono' order_refl norm_g norm_ge_zero
   515                 mult_nonneg_nonneg K *)
   516     also have "\<dots> = norm (f x) * (B * K)"
   517       by (rule mult_assoc)
   518     finally show "norm (f x ** g x) \<le> norm (f x) * (B * K)" .
   519   qed
   520   with f show ?thesis
   521     by (rule Zfun_imp_Zfun)
   522 qed
   523 
   524 lemma (in bounded_bilinear) flip:
   525   "bounded_bilinear (\<lambda>x y. y ** x)"
   526 apply default
   527 apply (rule add_right)
   528 apply (rule add_left)
   529 apply (rule scaleR_right)
   530 apply (rule scaleR_left)
   531 apply (subst mult_commute)
   532 using bounded by fast
   533 
   534 lemma (in bounded_bilinear) Bfun_prod_Zfun:
   535   assumes f: "Bfun f net"
   536   assumes g: "Zfun g net"
   537   shows "Zfun (\<lambda>x. f x ** g x) net"
   538 using flip g f by (rule bounded_bilinear.Zfun_prod_Bfun)
   539 
   540 lemma inverse_diff_inverse:
   541   "\<lbrakk>(a::'a::division_ring) \<noteq> 0; b \<noteq> 0\<rbrakk>
   542    \<Longrightarrow> inverse a - inverse b = - (inverse a * (a - b) * inverse b)"
   543 by (simp add: algebra_simps)
   544 
   545 lemma Bfun_inverse_lemma:
   546   fixes x :: "'a::real_normed_div_algebra"
   547   shows "\<lbrakk>r \<le> norm x; 0 < r\<rbrakk> \<Longrightarrow> norm (inverse x) \<le> inverse r"
   548 apply (subst nonzero_norm_inverse, clarsimp)
   549 apply (erule (1) le_imp_inverse_le)
   550 done
   551 
   552 lemma Bfun_inverse:
   553   fixes a :: "'a::real_normed_div_algebra"
   554   assumes f: "(f ---> a) net"
   555   assumes a: "a \<noteq> 0"
   556   shows "Bfun (\<lambda>x. inverse (f x)) net"
   557 proof -
   558   from a have "0 < norm a" by simp
   559   hence "\<exists>r>0. r < norm a" by (rule dense)
   560   then obtain r where r1: "0 < r" and r2: "r < norm a" by fast
   561   have "eventually (\<lambda>x. dist (f x) a < r) net"
   562     using tendstoD [OF f r1] by fast
   563   hence "eventually (\<lambda>x. norm (inverse (f x)) \<le> inverse (norm a - r)) net"
   564   proof (rule eventually_elim1)
   565     fix x
   566     assume "dist (f x) a < r"
   567     hence 1: "norm (f x - a) < r"
   568       by (simp add: dist_norm)
   569     hence 2: "f x \<noteq> 0" using r2 by auto
   570     hence "norm (inverse (f x)) = inverse (norm (f x))"
   571       by (rule nonzero_norm_inverse)
   572     also have "\<dots> \<le> inverse (norm a - r)"
   573     proof (rule le_imp_inverse_le)
   574       show "0 < norm a - r" using r2 by simp
   575     next
   576       have "norm a - norm (f x) \<le> norm (a - f x)"
   577         by (rule norm_triangle_ineq2)
   578       also have "\<dots> = norm (f x - a)"
   579         by (rule norm_minus_commute)
   580       also have "\<dots> < r" using 1 .
   581       finally show "norm a - r \<le> norm (f x)" by simp
   582     qed
   583     finally show "norm (inverse (f x)) \<le> inverse (norm a - r)" .
   584   qed
   585   thus ?thesis by (rule BfunI)
   586 qed
   587 
   588 lemma tendsto_inverse_lemma:
   589   fixes a :: "'a::real_normed_div_algebra"
   590   shows "\<lbrakk>(f ---> a) net; a \<noteq> 0; eventually (\<lambda>x. f x \<noteq> 0) net\<rbrakk>
   591          \<Longrightarrow> ((\<lambda>x. inverse (f x)) ---> inverse a) net"
   592 apply (subst tendsto_Zfun_iff)
   593 apply (rule Zfun_ssubst)
   594 apply (erule eventually_elim1)
   595 apply (erule (1) inverse_diff_inverse)
   596 apply (rule Zfun_minus)
   597 apply (rule Zfun_mult_left)
   598 apply (rule mult.Bfun_prod_Zfun)
   599 apply (erule (1) Bfun_inverse)
   600 apply (simp add: tendsto_Zfun_iff)
   601 done
   602 
   603 lemma tendsto_inverse [tendsto_intros]:
   604   fixes a :: "'a::real_normed_div_algebra"
   605   assumes f: "(f ---> a) net"
   606   assumes a: "a \<noteq> 0"
   607   shows "((\<lambda>x. inverse (f x)) ---> inverse a) net"
   608 proof -
   609   from a have "0 < norm a" by simp
   610   with f have "eventually (\<lambda>x. dist (f x) a < norm a) net"
   611     by (rule tendstoD)
   612   then have "eventually (\<lambda>x. f x \<noteq> 0) net"
   613     unfolding dist_norm by (auto elim!: eventually_elim1)
   614   with f a show ?thesis
   615     by (rule tendsto_inverse_lemma)
   616 qed
   617 
   618 lemma tendsto_divide [tendsto_intros]:
   619   fixes a b :: "'a::real_normed_field"
   620   shows "\<lbrakk>(f ---> a) net; (g ---> b) net; b \<noteq> 0\<rbrakk>
   621     \<Longrightarrow> ((\<lambda>x. f x / g x) ---> a / b) net"
   622 by (simp add: mult.tendsto tendsto_inverse divide_inverse)
   623 
   624 end