src/HOL/Rings.thy
author paulson <lp15@cam.ac.uk>
Tue Jun 23 16:55:28 2015 +0100 (2015-06-23)
changeset 60562 24af00b010cf
parent 60529 24c2ef12318b
child 60570 7ed2cde6806d
permissions -rw-r--r--
Amalgamation of the class comm_semiring_1_diff_distrib into comm_semiring_1_cancel. Moving axiom le_add_diff_inverse2 from semiring_numeral_div to linordered_semidom.
     1 (*  Title:      HOL/Rings.thy
     2     Author:     Gertrud Bauer
     3     Author:     Steven Obua
     4     Author:     Tobias Nipkow
     5     Author:     Lawrence C Paulson
     6     Author:     Markus Wenzel
     7     Author:     Jeremy Avigad
     8 *)
     9 
    10 section {* Rings *}
    11 
    12 theory Rings
    13 imports Groups
    14 begin
    15 
    16 class semiring = ab_semigroup_add + semigroup_mult +
    17   assumes distrib_right[algebra_simps]: "(a + b) * c = a * c + b * c"
    18   assumes distrib_left[algebra_simps]: "a * (b + c) = a * b + a * c"
    19 begin
    20 
    21 text{*For the @{text combine_numerals} simproc*}
    22 lemma combine_common_factor:
    23   "a * e + (b * e + c) = (a + b) * e + c"
    24 by (simp add: distrib_right ac_simps)
    25 
    26 end
    27 
    28 class mult_zero = times + zero +
    29   assumes mult_zero_left [simp]: "0 * a = 0"
    30   assumes mult_zero_right [simp]: "a * 0 = 0"
    31 begin
    32 
    33 lemma mult_not_zero:
    34   "a * b \<noteq> 0 \<Longrightarrow> a \<noteq> 0 \<and> b \<noteq> 0"
    35   by auto
    36 
    37 end
    38 
    39 class semiring_0 = semiring + comm_monoid_add + mult_zero
    40 
    41 class semiring_0_cancel = semiring + cancel_comm_monoid_add
    42 begin
    43 
    44 subclass semiring_0
    45 proof
    46   fix a :: 'a
    47   have "0 * a + 0 * a = 0 * a + 0" by (simp add: distrib_right [symmetric])
    48   thus "0 * a = 0" by (simp only: add_left_cancel)
    49 next
    50   fix a :: 'a
    51   have "a * 0 + a * 0 = a * 0 + 0" by (simp add: distrib_left [symmetric])
    52   thus "a * 0 = 0" by (simp only: add_left_cancel)
    53 qed
    54 
    55 end
    56 
    57 class comm_semiring = ab_semigroup_add + ab_semigroup_mult +
    58   assumes distrib: "(a + b) * c = a * c + b * c"
    59 begin
    60 
    61 subclass semiring
    62 proof
    63   fix a b c :: 'a
    64   show "(a + b) * c = a * c + b * c" by (simp add: distrib)
    65   have "a * (b + c) = (b + c) * a" by (simp add: ac_simps)
    66   also have "... = b * a + c * a" by (simp only: distrib)
    67   also have "... = a * b + a * c" by (simp add: ac_simps)
    68   finally show "a * (b + c) = a * b + a * c" by blast
    69 qed
    70 
    71 end
    72 
    73 class comm_semiring_0 = comm_semiring + comm_monoid_add + mult_zero
    74 begin
    75 
    76 subclass semiring_0 ..
    77 
    78 end
    79 
    80 class comm_semiring_0_cancel = comm_semiring + cancel_comm_monoid_add
    81 begin
    82 
    83 subclass semiring_0_cancel ..
    84 
    85 subclass comm_semiring_0 ..
    86 
    87 end
    88 
    89 class zero_neq_one = zero + one +
    90   assumes zero_neq_one [simp]: "0 \<noteq> 1"
    91 begin
    92 
    93 lemma one_neq_zero [simp]: "1 \<noteq> 0"
    94 by (rule not_sym) (rule zero_neq_one)
    95 
    96 definition of_bool :: "bool \<Rightarrow> 'a"
    97 where
    98   "of_bool p = (if p then 1 else 0)"
    99 
   100 lemma of_bool_eq [simp, code]:
   101   "of_bool False = 0"
   102   "of_bool True = 1"
   103   by (simp_all add: of_bool_def)
   104 
   105 lemma of_bool_eq_iff:
   106   "of_bool p = of_bool q \<longleftrightarrow> p = q"
   107   by (simp add: of_bool_def)
   108 
   109 lemma split_of_bool [split]:
   110   "P (of_bool p) \<longleftrightarrow> (p \<longrightarrow> P 1) \<and> (\<not> p \<longrightarrow> P 0)"
   111   by (cases p) simp_all
   112 
   113 lemma split_of_bool_asm:
   114   "P (of_bool p) \<longleftrightarrow> \<not> (p \<and> \<not> P 1 \<or> \<not> p \<and> \<not> P 0)"
   115   by (cases p) simp_all
   116 
   117 end
   118 
   119 class semiring_1 = zero_neq_one + semiring_0 + monoid_mult
   120 
   121 text {* Abstract divisibility *}
   122 
   123 class dvd = times
   124 begin
   125 
   126 definition dvd :: "'a \<Rightarrow> 'a \<Rightarrow> bool" (infix "dvd" 50) where
   127   "b dvd a \<longleftrightarrow> (\<exists>k. a = b * k)"
   128 
   129 lemma dvdI [intro?]: "a = b * k \<Longrightarrow> b dvd a"
   130   unfolding dvd_def ..
   131 
   132 lemma dvdE [elim?]: "b dvd a \<Longrightarrow> (\<And>k. a = b * k \<Longrightarrow> P) \<Longrightarrow> P"
   133   unfolding dvd_def by blast
   134 
   135 end
   136 
   137 context comm_monoid_mult
   138 begin
   139 
   140 subclass dvd .
   141 
   142 lemma dvd_refl [simp]:
   143   "a dvd a"
   144 proof
   145   show "a = a * 1" by simp
   146 qed
   147 
   148 lemma dvd_trans:
   149   assumes "a dvd b" and "b dvd c"
   150   shows "a dvd c"
   151 proof -
   152   from assms obtain v where "b = a * v" by (auto elim!: dvdE)
   153   moreover from assms obtain w where "c = b * w" by (auto elim!: dvdE)
   154   ultimately have "c = a * (v * w)" by (simp add: mult.assoc)
   155   then show ?thesis ..
   156 qed
   157 
   158 lemma one_dvd [simp]:
   159   "1 dvd a"
   160   by (auto intro!: dvdI)
   161 
   162 lemma dvd_mult [simp]:
   163   "a dvd c \<Longrightarrow> a dvd (b * c)"
   164   by (auto intro!: mult.left_commute dvdI elim!: dvdE)
   165 
   166 lemma dvd_mult2 [simp]:
   167   "a dvd b \<Longrightarrow> a dvd (b * c)"
   168   using dvd_mult [of a b c] by (simp add: ac_simps)
   169 
   170 lemma dvd_triv_right [simp]:
   171   "a dvd b * a"
   172   by (rule dvd_mult) (rule dvd_refl)
   173 
   174 lemma dvd_triv_left [simp]:
   175   "a dvd a * b"
   176   by (rule dvd_mult2) (rule dvd_refl)
   177 
   178 lemma mult_dvd_mono:
   179   assumes "a dvd b"
   180     and "c dvd d"
   181   shows "a * c dvd b * d"
   182 proof -
   183   from `a dvd b` obtain b' where "b = a * b'" ..
   184   moreover from `c dvd d` obtain d' where "d = c * d'" ..
   185   ultimately have "b * d = (a * c) * (b' * d')" by (simp add: ac_simps)
   186   then show ?thesis ..
   187 qed
   188 
   189 lemma dvd_mult_left:
   190   "a * b dvd c \<Longrightarrow> a dvd c"
   191   by (simp add: dvd_def mult.assoc) blast
   192 
   193 lemma dvd_mult_right:
   194   "a * b dvd c \<Longrightarrow> b dvd c"
   195   using dvd_mult_left [of b a c] by (simp add: ac_simps)
   196 
   197 end
   198 
   199 class comm_semiring_1 = zero_neq_one + comm_semiring_0 + comm_monoid_mult
   200 begin
   201 
   202 subclass semiring_1 ..
   203 
   204 lemma dvd_0_left_iff [simp]:
   205   "0 dvd a \<longleftrightarrow> a = 0"
   206   by (auto intro: dvd_refl elim!: dvdE)
   207 
   208 lemma dvd_0_right [iff]:
   209   "a dvd 0"
   210 proof
   211   show "0 = a * 0" by simp
   212 qed
   213 
   214 lemma dvd_0_left:
   215   "0 dvd a \<Longrightarrow> a = 0"
   216   by simp
   217 
   218 lemma dvd_add [simp]:
   219   assumes "a dvd b" and "a dvd c"
   220   shows "a dvd (b + c)"
   221 proof -
   222   from `a dvd b` obtain b' where "b = a * b'" ..
   223   moreover from `a dvd c` obtain c' where "c = a * c'" ..
   224   ultimately have "b + c = a * (b' + c')" by (simp add: distrib_left)
   225   then show ?thesis ..
   226 qed
   227 
   228 end
   229 
   230 class semiring_1_cancel = semiring + cancel_comm_monoid_add
   231   + zero_neq_one + monoid_mult
   232 begin
   233 
   234 subclass semiring_0_cancel ..
   235 
   236 subclass semiring_1 ..
   237 
   238 end
   239 
   240 class comm_semiring_1_cancel = comm_semiring + cancel_comm_monoid_add +
   241                                zero_neq_one + comm_monoid_mult +
   242   assumes right_diff_distrib' [algebra_simps]: "a * (b - c) = a * b - a * c"
   243 begin
   244 
   245 subclass semiring_1_cancel ..
   246 subclass comm_semiring_0_cancel ..
   247 subclass comm_semiring_1 ..
   248 
   249 lemma left_diff_distrib' [algebra_simps]:
   250   "(b - c) * a = b * a - c * a"
   251   by (simp add: algebra_simps)
   252 
   253 lemma dvd_add_times_triv_left_iff [simp]:
   254   "a dvd c * a + b \<longleftrightarrow> a dvd b"
   255 proof -
   256   have "a dvd a * c + b \<longleftrightarrow> a dvd b" (is "?P \<longleftrightarrow> ?Q")
   257   proof
   258     assume ?Q then show ?P by simp
   259   next
   260     assume ?P
   261     then obtain d where "a * c + b = a * d" ..
   262     then have "a * c + b - a * c = a * d - a * c" by simp
   263     then have "b = a * d - a * c" by simp
   264     then have "b = a * (d - c)" by (simp add: algebra_simps)
   265     then show ?Q ..
   266   qed
   267   then show "a dvd c * a + b \<longleftrightarrow> a dvd b" by (simp add: ac_simps)
   268 qed
   269 
   270 lemma dvd_add_times_triv_right_iff [simp]:
   271   "a dvd b + c * a \<longleftrightarrow> a dvd b"
   272   using dvd_add_times_triv_left_iff [of a c b] by (simp add: ac_simps)
   273 
   274 lemma dvd_add_triv_left_iff [simp]:
   275   "a dvd a + b \<longleftrightarrow> a dvd b"
   276   using dvd_add_times_triv_left_iff [of a 1 b] by simp
   277 
   278 lemma dvd_add_triv_right_iff [simp]:
   279   "a dvd b + a \<longleftrightarrow> a dvd b"
   280   using dvd_add_times_triv_right_iff [of a b 1] by simp
   281 
   282 lemma dvd_add_right_iff:
   283   assumes "a dvd b"
   284   shows "a dvd b + c \<longleftrightarrow> a dvd c" (is "?P \<longleftrightarrow> ?Q")
   285 proof
   286   assume ?P then obtain d where "b + c = a * d" ..
   287   moreover from `a dvd b` obtain e where "b = a * e" ..
   288   ultimately have "a * e + c = a * d" by simp
   289   then have "a * e + c - a * e = a * d - a * e" by simp
   290   then have "c = a * d - a * e" by simp
   291   then have "c = a * (d - e)" by (simp add: algebra_simps)
   292   then show ?Q ..
   293 next
   294   assume ?Q with assms show ?P by simp
   295 qed
   296 
   297 lemma dvd_add_left_iff:
   298   assumes "a dvd c"
   299   shows "a dvd b + c \<longleftrightarrow> a dvd b"
   300   using assms dvd_add_right_iff [of a c b] by (simp add: ac_simps)
   301 
   302 end
   303 
   304 class ring = semiring + ab_group_add
   305 begin
   306 
   307 subclass semiring_0_cancel ..
   308 
   309 text {* Distribution rules *}
   310 
   311 lemma minus_mult_left: "- (a * b) = - a * b"
   312 by (rule minus_unique) (simp add: distrib_right [symmetric])
   313 
   314 lemma minus_mult_right: "- (a * b) = a * - b"
   315 by (rule minus_unique) (simp add: distrib_left [symmetric])
   316 
   317 text{*Extract signs from products*}
   318 lemmas mult_minus_left [simp] = minus_mult_left [symmetric]
   319 lemmas mult_minus_right [simp] = minus_mult_right [symmetric]
   320 
   321 lemma minus_mult_minus [simp]: "- a * - b = a * b"
   322 by simp
   323 
   324 lemma minus_mult_commute: "- a * b = a * - b"
   325 by simp
   326 
   327 lemma right_diff_distrib [algebra_simps]:
   328   "a * (b - c) = a * b - a * c"
   329   using distrib_left [of a b "-c "] by simp
   330 
   331 lemma left_diff_distrib [algebra_simps]:
   332   "(a - b) * c = a * c - b * c"
   333   using distrib_right [of a "- b" c] by simp
   334 
   335 lemmas ring_distribs =
   336   distrib_left distrib_right left_diff_distrib right_diff_distrib
   337 
   338 lemma eq_add_iff1:
   339   "a * e + c = b * e + d \<longleftrightarrow> (a - b) * e + c = d"
   340 by (simp add: algebra_simps)
   341 
   342 lemma eq_add_iff2:
   343   "a * e + c = b * e + d \<longleftrightarrow> c = (b - a) * e + d"
   344 by (simp add: algebra_simps)
   345 
   346 end
   347 
   348 lemmas ring_distribs =
   349   distrib_left distrib_right left_diff_distrib right_diff_distrib
   350 
   351 class comm_ring = comm_semiring + ab_group_add
   352 begin
   353 
   354 subclass ring ..
   355 subclass comm_semiring_0_cancel ..
   356 
   357 lemma square_diff_square_factored:
   358   "x * x - y * y = (x + y) * (x - y)"
   359   by (simp add: algebra_simps)
   360 
   361 end
   362 
   363 class ring_1 = ring + zero_neq_one + monoid_mult
   364 begin
   365 
   366 subclass semiring_1_cancel ..
   367 
   368 lemma square_diff_one_factored:
   369   "x * x - 1 = (x + 1) * (x - 1)"
   370   by (simp add: algebra_simps)
   371 
   372 end
   373 
   374 class comm_ring_1 = comm_ring + zero_neq_one + comm_monoid_mult
   375 begin
   376 
   377 subclass ring_1 ..
   378 subclass comm_semiring_1_cancel
   379   by unfold_locales (simp add: algebra_simps)
   380 
   381 lemma dvd_minus_iff [simp]: "x dvd - y \<longleftrightarrow> x dvd y"
   382 proof
   383   assume "x dvd - y"
   384   then have "x dvd - 1 * - y" by (rule dvd_mult)
   385   then show "x dvd y" by simp
   386 next
   387   assume "x dvd y"
   388   then have "x dvd - 1 * y" by (rule dvd_mult)
   389   then show "x dvd - y" by simp
   390 qed
   391 
   392 lemma minus_dvd_iff [simp]: "- x dvd y \<longleftrightarrow> x dvd y"
   393 proof
   394   assume "- x dvd y"
   395   then obtain k where "y = - x * k" ..
   396   then have "y = x * - k" by simp
   397   then show "x dvd y" ..
   398 next
   399   assume "x dvd y"
   400   then obtain k where "y = x * k" ..
   401   then have "y = - x * - k" by simp
   402   then show "- x dvd y" ..
   403 qed
   404 
   405 lemma dvd_diff [simp]:
   406   "x dvd y \<Longrightarrow> x dvd z \<Longrightarrow> x dvd (y - z)"
   407   using dvd_add [of x y "- z"] by simp
   408 
   409 end
   410 
   411 class semiring_no_zero_divisors = semiring_0 +
   412   assumes no_zero_divisors: "a \<noteq> 0 \<Longrightarrow> b \<noteq> 0 \<Longrightarrow> a * b \<noteq> 0"
   413 begin
   414 
   415 lemma divisors_zero:
   416   assumes "a * b = 0"
   417   shows "a = 0 \<or> b = 0"
   418 proof (rule classical)
   419   assume "\<not> (a = 0 \<or> b = 0)"
   420   then have "a \<noteq> 0" and "b \<noteq> 0" by auto
   421   with no_zero_divisors have "a * b \<noteq> 0" by blast
   422   with assms show ?thesis by simp
   423 qed
   424 
   425 lemma mult_eq_0_iff [simp]:
   426   shows "a * b = 0 \<longleftrightarrow> a = 0 \<or> b = 0"
   427 proof (cases "a = 0 \<or> b = 0")
   428   case False then have "a \<noteq> 0" and "b \<noteq> 0" by auto
   429     then show ?thesis using no_zero_divisors by simp
   430 next
   431   case True then show ?thesis by auto
   432 qed
   433 
   434 end
   435 
   436 class semiring_no_zero_divisors_cancel = semiring_no_zero_divisors +
   437   assumes mult_cancel_right [simp]: "a * c = b * c \<longleftrightarrow> c = 0 \<or> a = b"
   438     and mult_cancel_left [simp]: "c * a = c * b \<longleftrightarrow> c = 0 \<or> a = b"
   439 begin
   440 
   441 lemma mult_left_cancel:
   442   "c \<noteq> 0 \<Longrightarrow> c * a = c * b \<longleftrightarrow> a = b"
   443   by simp
   444 
   445 lemma mult_right_cancel:
   446   "c \<noteq> 0 \<Longrightarrow> a * c = b * c \<longleftrightarrow> a = b"
   447   by simp
   448 
   449 end
   450 
   451 class ring_no_zero_divisors = ring + semiring_no_zero_divisors
   452 begin
   453 
   454 subclass semiring_no_zero_divisors_cancel
   455 proof
   456   fix a b c
   457   have "a * c = b * c \<longleftrightarrow> (a - b) * c = 0"
   458     by (simp add: algebra_simps)
   459   also have "\<dots> \<longleftrightarrow> c = 0 \<or> a = b"
   460     by auto
   461   finally show "a * c = b * c \<longleftrightarrow> c = 0 \<or> a = b" .
   462   have "c * a = c * b \<longleftrightarrow> c * (a - b) = 0"
   463     by (simp add: algebra_simps)
   464   also have "\<dots> \<longleftrightarrow> c = 0 \<or> a = b"
   465     by auto
   466   finally show "c * a = c * b \<longleftrightarrow> c = 0 \<or> a = b" .
   467 qed
   468 
   469 end
   470 
   471 class ring_1_no_zero_divisors = ring_1 + ring_no_zero_divisors
   472 begin
   473 
   474 lemma square_eq_1_iff:
   475   "x * x = 1 \<longleftrightarrow> x = 1 \<or> x = - 1"
   476 proof -
   477   have "(x - 1) * (x + 1) = x * x - 1"
   478     by (simp add: algebra_simps)
   479   hence "x * x = 1 \<longleftrightarrow> (x - 1) * (x + 1) = 0"
   480     by simp
   481   thus ?thesis
   482     by (simp add: eq_neg_iff_add_eq_0)
   483 qed
   484 
   485 lemma mult_cancel_right1 [simp]:
   486   "c = b * c \<longleftrightarrow> c = 0 \<or> b = 1"
   487 by (insert mult_cancel_right [of 1 c b], force)
   488 
   489 lemma mult_cancel_right2 [simp]:
   490   "a * c = c \<longleftrightarrow> c = 0 \<or> a = 1"
   491 by (insert mult_cancel_right [of a c 1], simp)
   492 
   493 lemma mult_cancel_left1 [simp]:
   494   "c = c * b \<longleftrightarrow> c = 0 \<or> b = 1"
   495 by (insert mult_cancel_left [of c 1 b], force)
   496 
   497 lemma mult_cancel_left2 [simp]:
   498   "c * a = c \<longleftrightarrow> c = 0 \<or> a = 1"
   499 by (insert mult_cancel_left [of c a 1], simp)
   500 
   501 end
   502 
   503 class semidom = comm_semiring_1_cancel + semiring_no_zero_divisors
   504 
   505 class idom = comm_ring_1 + semiring_no_zero_divisors
   506 begin
   507 
   508 subclass semidom ..
   509 
   510 subclass ring_1_no_zero_divisors ..
   511 
   512 lemma dvd_mult_cancel_right [simp]:
   513   "a * c dvd b * c \<longleftrightarrow> c = 0 \<or> a dvd b"
   514 proof -
   515   have "a * c dvd b * c \<longleftrightarrow> (\<exists>k. b * c = (a * k) * c)"
   516     unfolding dvd_def by (simp add: ac_simps)
   517   also have "(\<exists>k. b * c = (a * k) * c) \<longleftrightarrow> c = 0 \<or> a dvd b"
   518     unfolding dvd_def by simp
   519   finally show ?thesis .
   520 qed
   521 
   522 lemma dvd_mult_cancel_left [simp]:
   523   "c * a dvd c * b \<longleftrightarrow> c = 0 \<or> a dvd b"
   524 proof -
   525   have "c * a dvd c * b \<longleftrightarrow> (\<exists>k. b * c = (a * k) * c)"
   526     unfolding dvd_def by (simp add: ac_simps)
   527   also have "(\<exists>k. b * c = (a * k) * c) \<longleftrightarrow> c = 0 \<or> a dvd b"
   528     unfolding dvd_def by simp
   529   finally show ?thesis .
   530 qed
   531 
   532 lemma square_eq_iff: "a * a = b * b \<longleftrightarrow> a = b \<or> a = - b"
   533 proof
   534   assume "a * a = b * b"
   535   then have "(a - b) * (a + b) = 0"
   536     by (simp add: algebra_simps)
   537   then show "a = b \<or> a = - b"
   538     by (simp add: eq_neg_iff_add_eq_0)
   539 next
   540   assume "a = b \<or> a = - b"
   541   then show "a * a = b * b" by auto
   542 qed
   543 
   544 end
   545 
   546 text {*
   547   The theory of partially ordered rings is taken from the books:
   548   \begin{itemize}
   549   \item \emph{Lattice Theory} by Garret Birkhoff, American Mathematical Society 1979
   550   \item \emph{Partially Ordered Algebraic Systems}, Pergamon Press 1963
   551   \end{itemize}
   552   Most of the used notions can also be looked up in
   553   \begin{itemize}
   554   \item @{url "http://www.mathworld.com"} by Eric Weisstein et. al.
   555   \item \emph{Algebra I} by van der Waerden, Springer.
   556   \end{itemize}
   557 *}
   558 
   559 class divide =
   560   fixes divide :: "'a \<Rightarrow> 'a \<Rightarrow> 'a"  (infixl "div" 70)
   561 
   562 setup {* Sign.add_const_constraint (@{const_name "divide"}, SOME @{typ "'a \<Rightarrow> 'a \<Rightarrow> 'a"}) *}
   563 
   564 context semiring
   565 begin
   566 
   567 lemma [field_simps]:
   568   shows distrib_left_NO_MATCH: "NO_MATCH (x div y) a \<Longrightarrow> a * (b + c) = a * b + a * c"
   569     and distrib_right_NO_MATCH: "NO_MATCH (x div y) c \<Longrightarrow> (a + b) * c = a * c + b * c"
   570   by (rule distrib_left distrib_right)+
   571 
   572 end
   573 
   574 context ring
   575 begin
   576 
   577 lemma [field_simps]:
   578   shows left_diff_distrib_NO_MATCH: "NO_MATCH (x div y) c \<Longrightarrow> (a - b) * c = a * c - b * c"
   579     and right_diff_distrib_NO_MATCH: "NO_MATCH (x div y) a \<Longrightarrow> a * (b - c) = a * b - a * c"
   580   by (rule left_diff_distrib right_diff_distrib)+
   581 
   582 end
   583 
   584 setup {* Sign.add_const_constraint (@{const_name "divide"}, SOME @{typ "'a::divide \<Rightarrow> 'a \<Rightarrow> 'a"}) *}
   585 
   586 class semidom_divide = semidom + divide +
   587   assumes nonzero_mult_divide_cancel_right [simp]: "b \<noteq> 0 \<Longrightarrow> (a * b) div b = a"
   588   assumes divide_zero [simp]: "a div 0 = 0"
   589 begin
   590 
   591 lemma nonzero_mult_divide_cancel_left [simp]:
   592   "a \<noteq> 0 \<Longrightarrow> (a * b) div a = b"
   593   using nonzero_mult_divide_cancel_right [of a b] by (simp add: ac_simps)
   594 
   595 subclass semiring_no_zero_divisors_cancel
   596 proof
   597   fix a b c
   598   { fix a b c
   599     show "a * c = b * c \<longleftrightarrow> c = 0 \<or> a = b"
   600     proof (cases "c = 0")
   601       case True then show ?thesis by simp
   602     next
   603       case False
   604       { assume "a * c = b * c"
   605         then have "a * c div c = b * c div c"
   606           by simp
   607         with False have "a = b"
   608           by simp
   609       } then show ?thesis by auto
   610     qed
   611   }
   612   from this [of a c b]
   613   show "c * a = c * b \<longleftrightarrow> c = 0 \<or> a = b"
   614     by (simp add: ac_simps)
   615 qed
   616 
   617 lemma div_self [simp]:
   618   assumes "a \<noteq> 0"
   619   shows "a div a = 1"
   620   using assms nonzero_mult_divide_cancel_left [of a 1] by simp
   621 
   622 end
   623 
   624 class idom_divide = idom + semidom_divide
   625 
   626 class algebraic_semidom = semidom_divide
   627 begin
   628 
   629 lemma dvd_div_mult_self [simp]:
   630   "a dvd b \<Longrightarrow> b div a * a = b"
   631   by (cases "a = 0") (auto elim: dvdE simp add: ac_simps)
   632 
   633 lemma dvd_mult_div_cancel [simp]:
   634   "a dvd b \<Longrightarrow> a * (b div a) = b"
   635   using dvd_div_mult_self [of a b] by (simp add: ac_simps)
   636 
   637 lemma div_mult_swap:
   638   assumes "c dvd b"
   639   shows "a * (b div c) = (a * b) div c"
   640 proof (cases "c = 0")
   641   case True then show ?thesis by simp
   642 next
   643   case False from assms obtain d where "b = c * d" ..
   644   moreover from False have "a * divide (d * c) c = ((a * d) * c) div c"
   645     by simp
   646   ultimately show ?thesis by (simp add: ac_simps)
   647 qed
   648 
   649 lemma dvd_div_mult:
   650   assumes "c dvd b"
   651   shows "b div c * a = (b * a) div c"
   652   using assms div_mult_swap [of c b a] by (simp add: ac_simps)
   653 
   654 
   655 text \<open>Units: invertible elements in a ring\<close>
   656 
   657 abbreviation is_unit :: "'a \<Rightarrow> bool"
   658 where
   659   "is_unit a \<equiv> a dvd 1"
   660 
   661 lemma not_is_unit_0 [simp]:
   662   "\<not> is_unit 0"
   663   by simp
   664 
   665 lemma unit_imp_dvd [dest]:
   666   "is_unit b \<Longrightarrow> b dvd a"
   667   by (rule dvd_trans [of _ 1]) simp_all
   668 
   669 lemma unit_dvdE:
   670   assumes "is_unit a"
   671   obtains c where "a \<noteq> 0" and "b = a * c"
   672 proof -
   673   from assms have "a dvd b" by auto
   674   then obtain c where "b = a * c" ..
   675   moreover from assms have "a \<noteq> 0" by auto
   676   ultimately show thesis using that by blast
   677 qed
   678 
   679 lemma dvd_unit_imp_unit:
   680   "a dvd b \<Longrightarrow> is_unit b \<Longrightarrow> is_unit a"
   681   by (rule dvd_trans)
   682 
   683 lemma unit_div_1_unit [simp, intro]:
   684   assumes "is_unit a"
   685   shows "is_unit (1 div a)"
   686 proof -
   687   from assms have "1 = 1 div a * a" by simp
   688   then show "is_unit (1 div a)" by (rule dvdI)
   689 qed
   690 
   691 lemma is_unitE [elim?]:
   692   assumes "is_unit a"
   693   obtains b where "a \<noteq> 0" and "b \<noteq> 0"
   694     and "is_unit b" and "1 div a = b" and "1 div b = a"
   695     and "a * b = 1" and "c div a = c * b"
   696 proof (rule that)
   697   def b \<equiv> "1 div a"
   698   then show "1 div a = b" by simp
   699   from b_def `is_unit a` show "is_unit b" by simp
   700   from `is_unit a` and `is_unit b` show "a \<noteq> 0" and "b \<noteq> 0" by auto
   701   from b_def `is_unit a` show "a * b = 1" by simp
   702   then have "1 = a * b" ..
   703   with b_def `b \<noteq> 0` show "1 div b = a" by simp
   704   from `is_unit a` have "a dvd c" ..
   705   then obtain d where "c = a * d" ..
   706   with `a \<noteq> 0` `a * b = 1` show "c div a = c * b"
   707     by (simp add: mult.assoc mult.left_commute [of a])
   708 qed
   709 
   710 lemma unit_prod [intro]:
   711   "is_unit a \<Longrightarrow> is_unit b \<Longrightarrow> is_unit (a * b)"
   712   by (subst mult_1_left [of 1, symmetric]) (rule mult_dvd_mono)
   713 
   714 lemma unit_div [intro]:
   715   "is_unit a \<Longrightarrow> is_unit b \<Longrightarrow> is_unit (a div b)"
   716   by (erule is_unitE [of b a]) (simp add: ac_simps unit_prod)
   717 
   718 lemma mult_unit_dvd_iff:
   719   assumes "is_unit b"
   720   shows "a * b dvd c \<longleftrightarrow> a dvd c"
   721 proof
   722   assume "a * b dvd c"
   723   with assms show "a dvd c"
   724     by (simp add: dvd_mult_left)
   725 next
   726   assume "a dvd c"
   727   then obtain k where "c = a * k" ..
   728   with assms have "c = (a * b) * (1 div b * k)"
   729     by (simp add: mult_ac)
   730   then show "a * b dvd c" by (rule dvdI)
   731 qed
   732 
   733 lemma dvd_mult_unit_iff:
   734   assumes "is_unit b"
   735   shows "a dvd c * b \<longleftrightarrow> a dvd c"
   736 proof
   737   assume "a dvd c * b"
   738   with assms have "c * b dvd c * (b * (1 div b))"
   739     by (subst mult_assoc [symmetric]) simp
   740   also from `is_unit b` have "b * (1 div b) = 1" by (rule is_unitE) simp
   741   finally have "c * b dvd c" by simp
   742   with `a dvd c * b` show "a dvd c" by (rule dvd_trans)
   743 next
   744   assume "a dvd c"
   745   then show "a dvd c * b" by simp
   746 qed
   747 
   748 lemma div_unit_dvd_iff:
   749   "is_unit b \<Longrightarrow> a div b dvd c \<longleftrightarrow> a dvd c"
   750   by (erule is_unitE [of _ a]) (auto simp add: mult_unit_dvd_iff)
   751 
   752 lemma dvd_div_unit_iff:
   753   "is_unit b \<Longrightarrow> a dvd c div b \<longleftrightarrow> a dvd c"
   754   by (erule is_unitE [of _ c]) (simp add: dvd_mult_unit_iff)
   755 
   756 lemmas unit_dvd_iff = mult_unit_dvd_iff div_unit_dvd_iff
   757   dvd_mult_unit_iff dvd_div_unit_iff -- \<open>FIXME consider fact collection\<close>
   758 
   759 lemma unit_mult_div_div [simp]:
   760   "is_unit a \<Longrightarrow> b * (1 div a) = b div a"
   761   by (erule is_unitE [of _ b]) simp
   762 
   763 lemma unit_div_mult_self [simp]:
   764   "is_unit a \<Longrightarrow> b div a * a = b"
   765   by (rule dvd_div_mult_self) auto
   766 
   767 lemma unit_div_1_div_1 [simp]:
   768   "is_unit a \<Longrightarrow> 1 div (1 div a) = a"
   769   by (erule is_unitE) simp
   770 
   771 lemma unit_div_mult_swap:
   772   "is_unit c \<Longrightarrow> a * (b div c) = (a * b) div c"
   773   by (erule unit_dvdE [of _ b]) (simp add: mult.left_commute [of _ c])
   774 
   775 lemma unit_div_commute:
   776   "is_unit b \<Longrightarrow> (a div b) * c = (a * c) div b"
   777   using unit_div_mult_swap [of b c a] by (simp add: ac_simps)
   778 
   779 lemma unit_eq_div1:
   780   "is_unit b \<Longrightarrow> a div b = c \<longleftrightarrow> a = c * b"
   781   by (auto elim: is_unitE)
   782 
   783 lemma unit_eq_div2:
   784   "is_unit b \<Longrightarrow> a = c div b \<longleftrightarrow> a * b = c"
   785   using unit_eq_div1 [of b c a] by auto
   786 
   787 lemma unit_mult_left_cancel:
   788   assumes "is_unit a"
   789   shows "a * b = a * c \<longleftrightarrow> b = c" (is "?P \<longleftrightarrow> ?Q")
   790   using assms mult_cancel_left [of a b c] by auto
   791 
   792 lemma unit_mult_right_cancel:
   793   "is_unit a \<Longrightarrow> b * a = c * a \<longleftrightarrow> b = c"
   794   using unit_mult_left_cancel [of a b c] by (auto simp add: ac_simps)
   795 
   796 lemma unit_div_cancel:
   797   assumes "is_unit a"
   798   shows "b div a = c div a \<longleftrightarrow> b = c"
   799 proof -
   800   from assms have "is_unit (1 div a)" by simp
   801   then have "b * (1 div a) = c * (1 div a) \<longleftrightarrow> b = c"
   802     by (rule unit_mult_right_cancel)
   803   with assms show ?thesis by simp
   804 qed
   805 
   806 
   807 text \<open>Associated elements in a ring --- an equivalence relation induced
   808   by the quasi-order divisibility.\<close>
   809 
   810 definition associated :: "'a \<Rightarrow> 'a \<Rightarrow> bool"
   811 where
   812   "associated a b \<longleftrightarrow> a dvd b \<and> b dvd a"
   813 
   814 lemma associatedI:
   815   "a dvd b \<Longrightarrow> b dvd a \<Longrightarrow> associated a b"
   816   by (simp add: associated_def)
   817 
   818 lemma associatedD1:
   819   "associated a b \<Longrightarrow> a dvd b"
   820   by (simp add: associated_def)
   821 
   822 lemma associatedD2:
   823   "associated a b \<Longrightarrow> b dvd a"
   824   by (simp add: associated_def)
   825 
   826 lemma associated_refl [simp]:
   827   "associated a a"
   828   by (auto intro: associatedI)
   829 
   830 lemma associated_sym:
   831   "associated b a \<longleftrightarrow> associated a b"
   832   by (auto intro: associatedI dest: associatedD1 associatedD2)
   833 
   834 lemma associated_trans:
   835   "associated a b \<Longrightarrow> associated b c \<Longrightarrow> associated a c"
   836   by (auto intro: associatedI dvd_trans dest: associatedD1 associatedD2)
   837 
   838 lemma associated_0 [simp]:
   839   "associated 0 b \<longleftrightarrow> b = 0"
   840   "associated a 0 \<longleftrightarrow> a = 0"
   841   by (auto dest: associatedD1 associatedD2)
   842 
   843 lemma associated_unit:
   844   "associated a b \<Longrightarrow> is_unit a \<Longrightarrow> is_unit b"
   845   using dvd_unit_imp_unit by (auto dest!: associatedD1 associatedD2)
   846 
   847 lemma is_unit_associatedI:
   848   assumes "is_unit c" and "a = c * b"
   849   shows "associated a b"
   850 proof (rule associatedI)
   851   from `a = c * b` show "b dvd a" by auto
   852   from `is_unit c` obtain d where "c * d = 1" by (rule is_unitE)
   853   moreover from `a = c * b` have "d * a = d * (c * b)" by simp
   854   ultimately have "b = a * d" by (simp add: ac_simps)
   855   then show "a dvd b" ..
   856 qed
   857 
   858 lemma associated_is_unitE:
   859   assumes "associated a b"
   860   obtains c where "is_unit c" and "a = c * b"
   861 proof (cases "b = 0")
   862   case True with assms have "is_unit 1" and "a = 1 * b" by simp_all
   863   with that show thesis .
   864 next
   865   case False
   866   from assms have "a dvd b" and "b dvd a" by (auto dest: associatedD1 associatedD2)
   867   then obtain c d where "b = a * d" and "a = b * c" by (blast elim: dvdE)
   868   then have "a = c * b" and "(c * d) * b = 1 * b" by (simp_all add: ac_simps)
   869   with False have "c * d = 1" using mult_cancel_right [of "c * d" b 1] by simp
   870   then have "is_unit c" by auto
   871   with `a = c * b` that show thesis by blast
   872 qed
   873 
   874 lemmas unit_simps = mult_unit_dvd_iff div_unit_dvd_iff dvd_mult_unit_iff
   875   dvd_div_unit_iff unit_div_mult_swap unit_div_commute
   876   unit_mult_left_cancel unit_mult_right_cancel unit_div_cancel
   877   unit_eq_div1 unit_eq_div2
   878 
   879 end
   880 
   881 class ordered_semiring = semiring + comm_monoid_add + ordered_ab_semigroup_add +
   882   assumes mult_left_mono: "a \<le> b \<Longrightarrow> 0 \<le> c \<Longrightarrow> c * a \<le> c * b"
   883   assumes mult_right_mono: "a \<le> b \<Longrightarrow> 0 \<le> c \<Longrightarrow> a * c \<le> b * c"
   884 begin
   885 
   886 lemma mult_mono:
   887   "a \<le> b \<Longrightarrow> c \<le> d \<Longrightarrow> 0 \<le> b \<Longrightarrow> 0 \<le> c \<Longrightarrow> a * c \<le> b * d"
   888 apply (erule mult_right_mono [THEN order_trans], assumption)
   889 apply (erule mult_left_mono, assumption)
   890 done
   891 
   892 lemma mult_mono':
   893   "a \<le> b \<Longrightarrow> c \<le> d \<Longrightarrow> 0 \<le> a \<Longrightarrow> 0 \<le> c \<Longrightarrow> a * c \<le> b * d"
   894 apply (rule mult_mono)
   895 apply (fast intro: order_trans)+
   896 done
   897 
   898 end
   899 
   900 class ordered_cancel_semiring = ordered_semiring + cancel_comm_monoid_add
   901 begin
   902 
   903 subclass semiring_0_cancel ..
   904 
   905 lemma mult_nonneg_nonneg[simp]: "0 \<le> a \<Longrightarrow> 0 \<le> b \<Longrightarrow> 0 \<le> a * b"
   906 using mult_left_mono [of 0 b a] by simp
   907 
   908 lemma mult_nonneg_nonpos: "0 \<le> a \<Longrightarrow> b \<le> 0 \<Longrightarrow> a * b \<le> 0"
   909 using mult_left_mono [of b 0 a] by simp
   910 
   911 lemma mult_nonpos_nonneg: "a \<le> 0 \<Longrightarrow> 0 \<le> b \<Longrightarrow> a * b \<le> 0"
   912 using mult_right_mono [of a 0 b] by simp
   913 
   914 text {* Legacy - use @{text mult_nonpos_nonneg} *}
   915 lemma mult_nonneg_nonpos2: "0 \<le> a \<Longrightarrow> b \<le> 0 \<Longrightarrow> b * a \<le> 0"
   916 by (drule mult_right_mono [of b 0], auto)
   917 
   918 lemma split_mult_neg_le: "(0 \<le> a & b \<le> 0) | (a \<le> 0 & 0 \<le> b) \<Longrightarrow> a * b \<le> 0"
   919 by (auto simp add: mult_nonneg_nonpos mult_nonneg_nonpos2)
   920 
   921 end
   922 
   923 class linordered_semiring = ordered_semiring + linordered_cancel_ab_semigroup_add
   924 begin
   925 
   926 subclass ordered_cancel_semiring ..
   927 
   928 subclass ordered_comm_monoid_add ..
   929 
   930 lemma mult_left_less_imp_less:
   931   "c * a < c * b \<Longrightarrow> 0 \<le> c \<Longrightarrow> a < b"
   932 by (force simp add: mult_left_mono not_le [symmetric])
   933 
   934 lemma mult_right_less_imp_less:
   935   "a * c < b * c \<Longrightarrow> 0 \<le> c \<Longrightarrow> a < b"
   936 by (force simp add: mult_right_mono not_le [symmetric])
   937 
   938 end
   939 
   940 class linordered_semiring_1 = linordered_semiring + semiring_1
   941 begin
   942 
   943 lemma convex_bound_le:
   944   assumes "x \<le> a" "y \<le> a" "0 \<le> u" "0 \<le> v" "u + v = 1"
   945   shows "u * x + v * y \<le> a"
   946 proof-
   947   from assms have "u * x + v * y \<le> u * a + v * a"
   948     by (simp add: add_mono mult_left_mono)
   949   thus ?thesis using assms unfolding distrib_right[symmetric] by simp
   950 qed
   951 
   952 end
   953 
   954 class linordered_semiring_strict = semiring + comm_monoid_add + linordered_cancel_ab_semigroup_add +
   955   assumes mult_strict_left_mono: "a < b \<Longrightarrow> 0 < c \<Longrightarrow> c * a < c * b"
   956   assumes mult_strict_right_mono: "a < b \<Longrightarrow> 0 < c \<Longrightarrow> a * c < b * c"
   957 begin
   958 
   959 subclass semiring_0_cancel ..
   960 
   961 subclass linordered_semiring
   962 proof
   963   fix a b c :: 'a
   964   assume A: "a \<le> b" "0 \<le> c"
   965   from A show "c * a \<le> c * b"
   966     unfolding le_less
   967     using mult_strict_left_mono by (cases "c = 0") auto
   968   from A show "a * c \<le> b * c"
   969     unfolding le_less
   970     using mult_strict_right_mono by (cases "c = 0") auto
   971 qed
   972 
   973 lemma mult_left_le_imp_le:
   974   "c * a \<le> c * b \<Longrightarrow> 0 < c \<Longrightarrow> a \<le> b"
   975 by (force simp add: mult_strict_left_mono _not_less [symmetric])
   976 
   977 lemma mult_right_le_imp_le:
   978   "a * c \<le> b * c \<Longrightarrow> 0 < c \<Longrightarrow> a \<le> b"
   979 by (force simp add: mult_strict_right_mono not_less [symmetric])
   980 
   981 lemma mult_pos_pos[simp]: "0 < a \<Longrightarrow> 0 < b \<Longrightarrow> 0 < a * b"
   982 using mult_strict_left_mono [of 0 b a] by simp
   983 
   984 lemma mult_pos_neg: "0 < a \<Longrightarrow> b < 0 \<Longrightarrow> a * b < 0"
   985 using mult_strict_left_mono [of b 0 a] by simp
   986 
   987 lemma mult_neg_pos: "a < 0 \<Longrightarrow> 0 < b \<Longrightarrow> a * b < 0"
   988 using mult_strict_right_mono [of a 0 b] by simp
   989 
   990 text {* Legacy - use @{text mult_neg_pos} *}
   991 lemma mult_pos_neg2: "0 < a \<Longrightarrow> b < 0 \<Longrightarrow> b * a < 0"
   992 by (drule mult_strict_right_mono [of b 0], auto)
   993 
   994 lemma zero_less_mult_pos:
   995   "0 < a * b \<Longrightarrow> 0 < a \<Longrightarrow> 0 < b"
   996 apply (cases "b\<le>0")
   997  apply (auto simp add: le_less not_less)
   998 apply (drule_tac mult_pos_neg [of a b])
   999  apply (auto dest: less_not_sym)
  1000 done
  1001 
  1002 lemma zero_less_mult_pos2:
  1003   "0 < b * a \<Longrightarrow> 0 < a \<Longrightarrow> 0 < b"
  1004 apply (cases "b\<le>0")
  1005  apply (auto simp add: le_less not_less)
  1006 apply (drule_tac mult_pos_neg2 [of a b])
  1007  apply (auto dest: less_not_sym)
  1008 done
  1009 
  1010 text{*Strict monotonicity in both arguments*}
  1011 lemma mult_strict_mono:
  1012   assumes "a < b" and "c < d" and "0 < b" and "0 \<le> c"
  1013   shows "a * c < b * d"
  1014   using assms apply (cases "c=0")
  1015   apply (simp)
  1016   apply (erule mult_strict_right_mono [THEN less_trans])
  1017   apply (force simp add: le_less)
  1018   apply (erule mult_strict_left_mono, assumption)
  1019   done
  1020 
  1021 text{*This weaker variant has more natural premises*}
  1022 lemma mult_strict_mono':
  1023   assumes "a < b" and "c < d" and "0 \<le> a" and "0 \<le> c"
  1024   shows "a * c < b * d"
  1025 by (rule mult_strict_mono) (insert assms, auto)
  1026 
  1027 lemma mult_less_le_imp_less:
  1028   assumes "a < b" and "c \<le> d" and "0 \<le> a" and "0 < c"
  1029   shows "a * c < b * d"
  1030   using assms apply (subgoal_tac "a * c < b * c")
  1031   apply (erule less_le_trans)
  1032   apply (erule mult_left_mono)
  1033   apply simp
  1034   apply (erule mult_strict_right_mono)
  1035   apply assumption
  1036   done
  1037 
  1038 lemma mult_le_less_imp_less:
  1039   assumes "a \<le> b" and "c < d" and "0 < a" and "0 \<le> c"
  1040   shows "a * c < b * d"
  1041   using assms apply (subgoal_tac "a * c \<le> b * c")
  1042   apply (erule le_less_trans)
  1043   apply (erule mult_strict_left_mono)
  1044   apply simp
  1045   apply (erule mult_right_mono)
  1046   apply simp
  1047   done
  1048 
  1049 end
  1050 
  1051 class linordered_semiring_1_strict = linordered_semiring_strict + semiring_1
  1052 begin
  1053 
  1054 subclass linordered_semiring_1 ..
  1055 
  1056 lemma convex_bound_lt:
  1057   assumes "x < a" "y < a" "0 \<le> u" "0 \<le> v" "u + v = 1"
  1058   shows "u * x + v * y < a"
  1059 proof -
  1060   from assms have "u * x + v * y < u * a + v * a"
  1061     by (cases "u = 0")
  1062        (auto intro!: add_less_le_mono mult_strict_left_mono mult_left_mono)
  1063   thus ?thesis using assms unfolding distrib_right[symmetric] by simp
  1064 qed
  1065 
  1066 end
  1067 
  1068 class ordered_comm_semiring = comm_semiring_0 + ordered_ab_semigroup_add +
  1069   assumes comm_mult_left_mono: "a \<le> b \<Longrightarrow> 0 \<le> c \<Longrightarrow> c * a \<le> c * b"
  1070 begin
  1071 
  1072 subclass ordered_semiring
  1073 proof
  1074   fix a b c :: 'a
  1075   assume "a \<le> b" "0 \<le> c"
  1076   thus "c * a \<le> c * b" by (rule comm_mult_left_mono)
  1077   thus "a * c \<le> b * c" by (simp only: mult.commute)
  1078 qed
  1079 
  1080 end
  1081 
  1082 class ordered_cancel_comm_semiring = ordered_comm_semiring + cancel_comm_monoid_add
  1083 begin
  1084 
  1085 subclass comm_semiring_0_cancel ..
  1086 subclass ordered_comm_semiring ..
  1087 subclass ordered_cancel_semiring ..
  1088 
  1089 end
  1090 
  1091 class linordered_comm_semiring_strict = comm_semiring_0 + linordered_cancel_ab_semigroup_add +
  1092   assumes comm_mult_strict_left_mono: "a < b \<Longrightarrow> 0 < c \<Longrightarrow> c * a < c * b"
  1093 begin
  1094 
  1095 subclass linordered_semiring_strict
  1096 proof
  1097   fix a b c :: 'a
  1098   assume "a < b" "0 < c"
  1099   thus "c * a < c * b" by (rule comm_mult_strict_left_mono)
  1100   thus "a * c < b * c" by (simp only: mult.commute)
  1101 qed
  1102 
  1103 subclass ordered_cancel_comm_semiring
  1104 proof
  1105   fix a b c :: 'a
  1106   assume "a \<le> b" "0 \<le> c"
  1107   thus "c * a \<le> c * b"
  1108     unfolding le_less
  1109     using mult_strict_left_mono by (cases "c = 0") auto
  1110 qed
  1111 
  1112 end
  1113 
  1114 class ordered_ring = ring + ordered_cancel_semiring
  1115 begin
  1116 
  1117 subclass ordered_ab_group_add ..
  1118 
  1119 lemma less_add_iff1:
  1120   "a * e + c < b * e + d \<longleftrightarrow> (a - b) * e + c < d"
  1121 by (simp add: algebra_simps)
  1122 
  1123 lemma less_add_iff2:
  1124   "a * e + c < b * e + d \<longleftrightarrow> c < (b - a) * e + d"
  1125 by (simp add: algebra_simps)
  1126 
  1127 lemma le_add_iff1:
  1128   "a * e + c \<le> b * e + d \<longleftrightarrow> (a - b) * e + c \<le> d"
  1129 by (simp add: algebra_simps)
  1130 
  1131 lemma le_add_iff2:
  1132   "a * e + c \<le> b * e + d \<longleftrightarrow> c \<le> (b - a) * e + d"
  1133 by (simp add: algebra_simps)
  1134 
  1135 lemma mult_left_mono_neg:
  1136   "b \<le> a \<Longrightarrow> c \<le> 0 \<Longrightarrow> c * a \<le> c * b"
  1137   apply (drule mult_left_mono [of _ _ "- c"])
  1138   apply simp_all
  1139   done
  1140 
  1141 lemma mult_right_mono_neg:
  1142   "b \<le> a \<Longrightarrow> c \<le> 0 \<Longrightarrow> a * c \<le> b * c"
  1143   apply (drule mult_right_mono [of _ _ "- c"])
  1144   apply simp_all
  1145   done
  1146 
  1147 lemma mult_nonpos_nonpos: "a \<le> 0 \<Longrightarrow> b \<le> 0 \<Longrightarrow> 0 \<le> a * b"
  1148 using mult_right_mono_neg [of a 0 b] by simp
  1149 
  1150 lemma split_mult_pos_le:
  1151   "(0 \<le> a \<and> 0 \<le> b) \<or> (a \<le> 0 \<and> b \<le> 0) \<Longrightarrow> 0 \<le> a * b"
  1152 by (auto simp add: mult_nonpos_nonpos)
  1153 
  1154 end
  1155 
  1156 class linordered_ring = ring + linordered_semiring + linordered_ab_group_add + abs_if
  1157 begin
  1158 
  1159 subclass ordered_ring ..
  1160 
  1161 subclass ordered_ab_group_add_abs
  1162 proof
  1163   fix a b
  1164   show "\<bar>a + b\<bar> \<le> \<bar>a\<bar> + \<bar>b\<bar>"
  1165     by (auto simp add: abs_if not_le not_less algebra_simps simp del: add.commute dest: add_neg_neg add_nonneg_nonneg)
  1166 qed (auto simp add: abs_if)
  1167 
  1168 lemma zero_le_square [simp]: "0 \<le> a * a"
  1169   using linear [of 0 a]
  1170   by (auto simp add: mult_nonpos_nonpos)
  1171 
  1172 lemma not_square_less_zero [simp]: "\<not> (a * a < 0)"
  1173   by (simp add: not_less)
  1174 
  1175 end
  1176 
  1177 class linordered_ring_strict = ring + linordered_semiring_strict
  1178   + ordered_ab_group_add + abs_if
  1179 begin
  1180 
  1181 subclass linordered_ring ..
  1182 
  1183 lemma mult_strict_left_mono_neg: "b < a \<Longrightarrow> c < 0 \<Longrightarrow> c * a < c * b"
  1184 using mult_strict_left_mono [of b a "- c"] by simp
  1185 
  1186 lemma mult_strict_right_mono_neg: "b < a \<Longrightarrow> c < 0 \<Longrightarrow> a * c < b * c"
  1187 using mult_strict_right_mono [of b a "- c"] by simp
  1188 
  1189 lemma mult_neg_neg: "a < 0 \<Longrightarrow> b < 0 \<Longrightarrow> 0 < a * b"
  1190 using mult_strict_right_mono_neg [of a 0 b] by simp
  1191 
  1192 subclass ring_no_zero_divisors
  1193 proof
  1194   fix a b
  1195   assume "a \<noteq> 0" then have A: "a < 0 \<or> 0 < a" by (simp add: neq_iff)
  1196   assume "b \<noteq> 0" then have B: "b < 0 \<or> 0 < b" by (simp add: neq_iff)
  1197   have "a * b < 0 \<or> 0 < a * b"
  1198   proof (cases "a < 0")
  1199     case True note A' = this
  1200     show ?thesis proof (cases "b < 0")
  1201       case True with A'
  1202       show ?thesis by (auto dest: mult_neg_neg)
  1203     next
  1204       case False with B have "0 < b" by auto
  1205       with A' show ?thesis by (auto dest: mult_strict_right_mono)
  1206     qed
  1207   next
  1208     case False with A have A': "0 < a" by auto
  1209     show ?thesis proof (cases "b < 0")
  1210       case True with A'
  1211       show ?thesis by (auto dest: mult_strict_right_mono_neg)
  1212     next
  1213       case False with B have "0 < b" by auto
  1214       with A' show ?thesis by auto
  1215     qed
  1216   qed
  1217   then show "a * b \<noteq> 0" by (simp add: neq_iff)
  1218 qed
  1219 
  1220 lemma zero_less_mult_iff: "0 < a * b \<longleftrightarrow> 0 < a \<and> 0 < b \<or> a < 0 \<and> b < 0"
  1221   by (cases a 0 b 0 rule: linorder_cases[case_product linorder_cases])
  1222      (auto simp add: mult_neg_neg not_less le_less dest: zero_less_mult_pos zero_less_mult_pos2)
  1223 
  1224 lemma zero_le_mult_iff: "0 \<le> a * b \<longleftrightarrow> 0 \<le> a \<and> 0 \<le> b \<or> a \<le> 0 \<and> b \<le> 0"
  1225   by (auto simp add: eq_commute [of 0] le_less not_less zero_less_mult_iff)
  1226 
  1227 lemma mult_less_0_iff:
  1228   "a * b < 0 \<longleftrightarrow> 0 < a \<and> b < 0 \<or> a < 0 \<and> 0 < b"
  1229   apply (insert zero_less_mult_iff [of "-a" b])
  1230   apply force
  1231   done
  1232 
  1233 lemma mult_le_0_iff:
  1234   "a * b \<le> 0 \<longleftrightarrow> 0 \<le> a \<and> b \<le> 0 \<or> a \<le> 0 \<and> 0 \<le> b"
  1235   apply (insert zero_le_mult_iff [of "-a" b])
  1236   apply force
  1237   done
  1238 
  1239 text{*Cancellation laws for @{term "c*a < c*b"} and @{term "a*c < b*c"},
  1240    also with the relations @{text "\<le>"} and equality.*}
  1241 
  1242 text{*These ``disjunction'' versions produce two cases when the comparison is
  1243  an assumption, but effectively four when the comparison is a goal.*}
  1244 
  1245 lemma mult_less_cancel_right_disj:
  1246   "a * c < b * c \<longleftrightarrow> 0 < c \<and> a < b \<or> c < 0 \<and>  b < a"
  1247   apply (cases "c = 0")
  1248   apply (auto simp add: neq_iff mult_strict_right_mono
  1249                       mult_strict_right_mono_neg)
  1250   apply (auto simp add: not_less
  1251                       not_le [symmetric, of "a*c"]
  1252                       not_le [symmetric, of a])
  1253   apply (erule_tac [!] notE)
  1254   apply (auto simp add: less_imp_le mult_right_mono
  1255                       mult_right_mono_neg)
  1256   done
  1257 
  1258 lemma mult_less_cancel_left_disj:
  1259   "c * a < c * b \<longleftrightarrow> 0 < c \<and> a < b \<or> c < 0 \<and>  b < a"
  1260   apply (cases "c = 0")
  1261   apply (auto simp add: neq_iff mult_strict_left_mono
  1262                       mult_strict_left_mono_neg)
  1263   apply (auto simp add: not_less
  1264                       not_le [symmetric, of "c*a"]
  1265                       not_le [symmetric, of a])
  1266   apply (erule_tac [!] notE)
  1267   apply (auto simp add: less_imp_le mult_left_mono
  1268                       mult_left_mono_neg)
  1269   done
  1270 
  1271 text{*The ``conjunction of implication'' lemmas produce two cases when the
  1272 comparison is a goal, but give four when the comparison is an assumption.*}
  1273 
  1274 lemma mult_less_cancel_right:
  1275   "a * c < b * c \<longleftrightarrow> (0 \<le> c \<longrightarrow> a < b) \<and> (c \<le> 0 \<longrightarrow> b < a)"
  1276   using mult_less_cancel_right_disj [of a c b] by auto
  1277 
  1278 lemma mult_less_cancel_left:
  1279   "c * a < c * b \<longleftrightarrow> (0 \<le> c \<longrightarrow> a < b) \<and> (c \<le> 0 \<longrightarrow> b < a)"
  1280   using mult_less_cancel_left_disj [of c a b] by auto
  1281 
  1282 lemma mult_le_cancel_right:
  1283    "a * c \<le> b * c \<longleftrightarrow> (0 < c \<longrightarrow> a \<le> b) \<and> (c < 0 \<longrightarrow> b \<le> a)"
  1284 by (simp add: not_less [symmetric] mult_less_cancel_right_disj)
  1285 
  1286 lemma mult_le_cancel_left:
  1287   "c * a \<le> c * b \<longleftrightarrow> (0 < c \<longrightarrow> a \<le> b) \<and> (c < 0 \<longrightarrow> b \<le> a)"
  1288 by (simp add: not_less [symmetric] mult_less_cancel_left_disj)
  1289 
  1290 lemma mult_le_cancel_left_pos:
  1291   "0 < c \<Longrightarrow> c * a \<le> c * b \<longleftrightarrow> a \<le> b"
  1292 by (auto simp: mult_le_cancel_left)
  1293 
  1294 lemma mult_le_cancel_left_neg:
  1295   "c < 0 \<Longrightarrow> c * a \<le> c * b \<longleftrightarrow> b \<le> a"
  1296 by (auto simp: mult_le_cancel_left)
  1297 
  1298 lemma mult_less_cancel_left_pos:
  1299   "0 < c \<Longrightarrow> c * a < c * b \<longleftrightarrow> a < b"
  1300 by (auto simp: mult_less_cancel_left)
  1301 
  1302 lemma mult_less_cancel_left_neg:
  1303   "c < 0 \<Longrightarrow> c * a < c * b \<longleftrightarrow> b < a"
  1304 by (auto simp: mult_less_cancel_left)
  1305 
  1306 end
  1307 
  1308 lemmas mult_sign_intros =
  1309   mult_nonneg_nonneg mult_nonneg_nonpos
  1310   mult_nonpos_nonneg mult_nonpos_nonpos
  1311   mult_pos_pos mult_pos_neg
  1312   mult_neg_pos mult_neg_neg
  1313 
  1314 class ordered_comm_ring = comm_ring + ordered_comm_semiring
  1315 begin
  1316 
  1317 subclass ordered_ring ..
  1318 subclass ordered_cancel_comm_semiring ..
  1319 
  1320 end
  1321 
  1322 class linordered_semidom = semidom + linordered_comm_semiring_strict +
  1323   assumes zero_less_one [simp]: "0 < 1"
  1324   assumes le_add_diff_inverse2 [simp]: "b \<le> a \<Longrightarrow> a - b + b = a"
  1325 begin
  1326 
  1327 text {* Addition is the inverse of subtraction. *}
  1328 
  1329 lemma le_add_diff_inverse [simp]: "b \<le> a \<Longrightarrow> b + (a - b) = a"
  1330   by (frule le_add_diff_inverse2) (simp add: add.commute)
  1331 
  1332 lemma add_diff_inverse: "~ a<b \<Longrightarrow> b + (a - b) = a"
  1333   by simp
  1334   
  1335 lemma pos_add_strict:
  1336   shows "0 < a \<Longrightarrow> b < c \<Longrightarrow> b < a + c"
  1337   using add_strict_mono [of 0 a b c] by simp
  1338 
  1339 lemma zero_le_one [simp]: "0 \<le> 1"
  1340 by (rule zero_less_one [THEN less_imp_le])
  1341 
  1342 lemma not_one_le_zero [simp]: "\<not> 1 \<le> 0"
  1343 by (simp add: not_le)
  1344 
  1345 lemma not_one_less_zero [simp]: "\<not> 1 < 0"
  1346 by (simp add: not_less)
  1347 
  1348 lemma less_1_mult:
  1349   assumes "1 < m" and "1 < n"
  1350   shows "1 < m * n"
  1351   using assms mult_strict_mono [of 1 m 1 n]
  1352     by (simp add:  less_trans [OF zero_less_one])
  1353 
  1354 lemma mult_left_le: "c \<le> 1 \<Longrightarrow> 0 \<le> a \<Longrightarrow> a * c \<le> a"
  1355   using mult_left_mono[of c 1 a] by simp
  1356 
  1357 lemma mult_le_one: "a \<le> 1 \<Longrightarrow> 0 \<le> b \<Longrightarrow> b \<le> 1 \<Longrightarrow> a * b \<le> 1"
  1358   using mult_mono[of a 1 b 1] by simp
  1359 
  1360 end
  1361 
  1362 class linordered_idom = comm_ring_1 +
  1363   linordered_comm_semiring_strict + ordered_ab_group_add +
  1364   abs_if + sgn_if
  1365 begin
  1366 
  1367 subclass linordered_semiring_1_strict ..
  1368 subclass linordered_ring_strict ..
  1369 subclass ordered_comm_ring ..
  1370 subclass idom ..
  1371 
  1372 subclass linordered_semidom
  1373 proof
  1374   have "0 \<le> 1 * 1" by (rule zero_le_square)
  1375   thus "0 < 1" by (simp add: le_less)
  1376   show "\<And>b a. b \<le> a \<Longrightarrow> a - b + b = a"
  1377     by simp
  1378 qed
  1379 
  1380 lemma linorder_neqE_linordered_idom:
  1381   assumes "x \<noteq> y" obtains "x < y" | "y < x"
  1382   using assms by (rule neqE)
  1383 
  1384 text {* These cancellation simprules also produce two cases when the comparison is a goal. *}
  1385 
  1386 lemma mult_le_cancel_right1:
  1387   "c \<le> b * c \<longleftrightarrow> (0 < c \<longrightarrow> 1 \<le> b) \<and> (c < 0 \<longrightarrow> b \<le> 1)"
  1388 by (insert mult_le_cancel_right [of 1 c b], simp)
  1389 
  1390 lemma mult_le_cancel_right2:
  1391   "a * c \<le> c \<longleftrightarrow> (0 < c \<longrightarrow> a \<le> 1) \<and> (c < 0 \<longrightarrow> 1 \<le> a)"
  1392 by (insert mult_le_cancel_right [of a c 1], simp)
  1393 
  1394 lemma mult_le_cancel_left1:
  1395   "c \<le> c * b \<longleftrightarrow> (0 < c \<longrightarrow> 1 \<le> b) \<and> (c < 0 \<longrightarrow> b \<le> 1)"
  1396 by (insert mult_le_cancel_left [of c 1 b], simp)
  1397 
  1398 lemma mult_le_cancel_left2:
  1399   "c * a \<le> c \<longleftrightarrow> (0 < c \<longrightarrow> a \<le> 1) \<and> (c < 0 \<longrightarrow> 1 \<le> a)"
  1400 by (insert mult_le_cancel_left [of c a 1], simp)
  1401 
  1402 lemma mult_less_cancel_right1:
  1403   "c < b * c \<longleftrightarrow> (0 \<le> c \<longrightarrow> 1 < b) \<and> (c \<le> 0 \<longrightarrow> b < 1)"
  1404 by (insert mult_less_cancel_right [of 1 c b], simp)
  1405 
  1406 lemma mult_less_cancel_right2:
  1407   "a * c < c \<longleftrightarrow> (0 \<le> c \<longrightarrow> a < 1) \<and> (c \<le> 0 \<longrightarrow> 1 < a)"
  1408 by (insert mult_less_cancel_right [of a c 1], simp)
  1409 
  1410 lemma mult_less_cancel_left1:
  1411   "c < c * b \<longleftrightarrow> (0 \<le> c \<longrightarrow> 1 < b) \<and> (c \<le> 0 \<longrightarrow> b < 1)"
  1412 by (insert mult_less_cancel_left [of c 1 b], simp)
  1413 
  1414 lemma mult_less_cancel_left2:
  1415   "c * a < c \<longleftrightarrow> (0 \<le> c \<longrightarrow> a < 1) \<and> (c \<le> 0 \<longrightarrow> 1 < a)"
  1416 by (insert mult_less_cancel_left [of c a 1], simp)
  1417 
  1418 lemma sgn_sgn [simp]:
  1419   "sgn (sgn a) = sgn a"
  1420 unfolding sgn_if by simp
  1421 
  1422 lemma sgn_0_0:
  1423   "sgn a = 0 \<longleftrightarrow> a = 0"
  1424 unfolding sgn_if by simp
  1425 
  1426 lemma sgn_1_pos:
  1427   "sgn a = 1 \<longleftrightarrow> a > 0"
  1428 unfolding sgn_if by simp
  1429 
  1430 lemma sgn_1_neg:
  1431   "sgn a = - 1 \<longleftrightarrow> a < 0"
  1432 unfolding sgn_if by auto
  1433 
  1434 lemma sgn_pos [simp]:
  1435   "0 < a \<Longrightarrow> sgn a = 1"
  1436 unfolding sgn_1_pos .
  1437 
  1438 lemma sgn_neg [simp]:
  1439   "a < 0 \<Longrightarrow> sgn a = - 1"
  1440 unfolding sgn_1_neg .
  1441 
  1442 lemma sgn_times:
  1443   "sgn (a * b) = sgn a * sgn b"
  1444 by (auto simp add: sgn_if zero_less_mult_iff)
  1445 
  1446 lemma abs_sgn: "\<bar>k\<bar> = k * sgn k"
  1447 unfolding sgn_if abs_if by auto
  1448 
  1449 lemma sgn_greater [simp]:
  1450   "0 < sgn a \<longleftrightarrow> 0 < a"
  1451   unfolding sgn_if by auto
  1452 
  1453 lemma sgn_less [simp]:
  1454   "sgn a < 0 \<longleftrightarrow> a < 0"
  1455   unfolding sgn_if by auto
  1456 
  1457 lemma abs_dvd_iff [simp]: "\<bar>m\<bar> dvd k \<longleftrightarrow> m dvd k"
  1458   by (simp add: abs_if)
  1459 
  1460 lemma dvd_abs_iff [simp]: "m dvd \<bar>k\<bar> \<longleftrightarrow> m dvd k"
  1461   by (simp add: abs_if)
  1462 
  1463 lemma dvd_if_abs_eq:
  1464   "\<bar>l\<bar> = \<bar>k\<bar> \<Longrightarrow> l dvd k"
  1465 by(subst abs_dvd_iff[symmetric]) simp
  1466 
  1467 text {* The following lemmas can be proven in more general structures, but
  1468 are dangerous as simp rules in absence of @{thm neg_equal_zero},
  1469 @{thm neg_less_pos}, @{thm neg_less_eq_nonneg}. *}
  1470 
  1471 lemma equation_minus_iff_1 [simp, no_atp]:
  1472   "1 = - a \<longleftrightarrow> a = - 1"
  1473   by (fact equation_minus_iff)
  1474 
  1475 lemma minus_equation_iff_1 [simp, no_atp]:
  1476   "- a = 1 \<longleftrightarrow> a = - 1"
  1477   by (subst minus_equation_iff, auto)
  1478 
  1479 lemma le_minus_iff_1 [simp, no_atp]:
  1480   "1 \<le> - b \<longleftrightarrow> b \<le> - 1"
  1481   by (fact le_minus_iff)
  1482 
  1483 lemma minus_le_iff_1 [simp, no_atp]:
  1484   "- a \<le> 1 \<longleftrightarrow> - 1 \<le> a"
  1485   by (fact minus_le_iff)
  1486 
  1487 lemma less_minus_iff_1 [simp, no_atp]:
  1488   "1 < - b \<longleftrightarrow> b < - 1"
  1489   by (fact less_minus_iff)
  1490 
  1491 lemma minus_less_iff_1 [simp, no_atp]:
  1492   "- a < 1 \<longleftrightarrow> - 1 < a"
  1493   by (fact minus_less_iff)
  1494 
  1495 end
  1496 
  1497 text {* Simprules for comparisons where common factors can be cancelled. *}
  1498 
  1499 lemmas mult_compare_simps =
  1500     mult_le_cancel_right mult_le_cancel_left
  1501     mult_le_cancel_right1 mult_le_cancel_right2
  1502     mult_le_cancel_left1 mult_le_cancel_left2
  1503     mult_less_cancel_right mult_less_cancel_left
  1504     mult_less_cancel_right1 mult_less_cancel_right2
  1505     mult_less_cancel_left1 mult_less_cancel_left2
  1506     mult_cancel_right mult_cancel_left
  1507     mult_cancel_right1 mult_cancel_right2
  1508     mult_cancel_left1 mult_cancel_left2
  1509 
  1510 text {* Reasoning about inequalities with division *}
  1511 
  1512 context linordered_semidom
  1513 begin
  1514 
  1515 lemma less_add_one: "a < a + 1"
  1516 proof -
  1517   have "a + 0 < a + 1"
  1518     by (blast intro: zero_less_one add_strict_left_mono)
  1519   thus ?thesis by simp
  1520 qed
  1521 
  1522 lemma zero_less_two: "0 < 1 + 1"
  1523 by (blast intro: less_trans zero_less_one less_add_one)
  1524 
  1525 end
  1526 
  1527 context linordered_idom
  1528 begin
  1529 
  1530 lemma mult_right_le_one_le:
  1531   "0 \<le> x \<Longrightarrow> 0 \<le> y \<Longrightarrow> y \<le> 1 \<Longrightarrow> x * y \<le> x"
  1532   by (rule mult_left_le)
  1533 
  1534 lemma mult_left_le_one_le:
  1535   "0 \<le> x \<Longrightarrow> 0 \<le> y \<Longrightarrow> y \<le> 1 \<Longrightarrow> y * x \<le> x"
  1536   by (auto simp add: mult_le_cancel_right2)
  1537 
  1538 end
  1539 
  1540 text {* Absolute Value *}
  1541 
  1542 context linordered_idom
  1543 begin
  1544 
  1545 lemma mult_sgn_abs:
  1546   "sgn x * \<bar>x\<bar> = x"
  1547   unfolding abs_if sgn_if by auto
  1548 
  1549 lemma abs_one [simp]:
  1550   "\<bar>1\<bar> = 1"
  1551   by (simp add: abs_if)
  1552 
  1553 end
  1554 
  1555 class ordered_ring_abs = ordered_ring + ordered_ab_group_add_abs +
  1556   assumes abs_eq_mult:
  1557     "(0 \<le> a \<or> a \<le> 0) \<and> (0 \<le> b \<or> b \<le> 0) \<Longrightarrow> \<bar>a * b\<bar> = \<bar>a\<bar> * \<bar>b\<bar>"
  1558 
  1559 context linordered_idom
  1560 begin
  1561 
  1562 subclass ordered_ring_abs proof
  1563 qed (auto simp add: abs_if not_less mult_less_0_iff)
  1564 
  1565 lemma abs_mult:
  1566   "\<bar>a * b\<bar> = \<bar>a\<bar> * \<bar>b\<bar>"
  1567   by (rule abs_eq_mult) auto
  1568 
  1569 lemma abs_mult_self:
  1570   "\<bar>a\<bar> * \<bar>a\<bar> = a * a"
  1571   by (simp add: abs_if)
  1572 
  1573 lemma abs_mult_less:
  1574   "\<bar>a\<bar> < c \<Longrightarrow> \<bar>b\<bar> < d \<Longrightarrow> \<bar>a\<bar> * \<bar>b\<bar> < c * d"
  1575 proof -
  1576   assume ac: "\<bar>a\<bar> < c"
  1577   hence cpos: "0<c" by (blast intro: le_less_trans abs_ge_zero)
  1578   assume "\<bar>b\<bar> < d"
  1579   thus ?thesis by (simp add: ac cpos mult_strict_mono)
  1580 qed
  1581 
  1582 lemma abs_less_iff:
  1583   "\<bar>a\<bar> < b \<longleftrightarrow> a < b \<and> - a < b"
  1584   by (simp add: less_le abs_le_iff) (auto simp add: abs_if)
  1585 
  1586 lemma abs_mult_pos:
  1587   "0 \<le> x \<Longrightarrow> \<bar>y\<bar> * x = \<bar>y * x\<bar>"
  1588   by (simp add: abs_mult)
  1589 
  1590 lemma abs_diff_less_iff:
  1591   "\<bar>x - a\<bar> < r \<longleftrightarrow> a - r < x \<and> x < a + r"
  1592   by (auto simp add: diff_less_eq ac_simps abs_less_iff)
  1593 
  1594 lemma abs_diff_le_iff:
  1595    "\<bar>x - a\<bar> \<le> r \<longleftrightarrow> a - r \<le> x \<and> x \<le> a + r"
  1596   by (auto simp add: diff_le_eq ac_simps abs_le_iff)
  1597 
  1598 end
  1599 
  1600 hide_fact (open) comm_mult_left_mono comm_mult_strict_left_mono distrib
  1601 
  1602 code_identifier
  1603   code_module Rings \<rightharpoonup> (SML) Arith and (OCaml) Arith and (Haskell) Arith
  1604 
  1605 end