src/Pure/sign.ML
author wenzelm
Tue Mar 03 18:32:01 2009 +0100 (2009-03-03)
changeset 30223 24d975352879
parent 30218 cdd82ba2b4fd
child 30242 aea5d7fa7ef5
permissions -rw-r--r--
renamed Binding.name_pos to Binding.make, renamed Binding.base_name to Binding.name_of, renamed Binding.map_base to Binding.map_name, added mandatory flag to Binding.qualify;
minor tuning;
     1 (*  Title:      Pure/sign.ML
     2     Author:     Lawrence C Paulson and Markus Wenzel
     3 
     4 Logical signature content: naming conventions, concrete syntax, type
     5 signature, polymorphic constants.
     6 *)
     7 
     8 signature SIGN =
     9 sig
    10   val rep_sg: theory ->
    11    {naming: NameSpace.naming,
    12     syn: Syntax.syntax,
    13     tsig: Type.tsig,
    14     consts: Consts.T}
    15   val naming_of: theory -> NameSpace.naming
    16   val full_name: theory -> binding -> string
    17   val base_name: string -> bstring
    18   val full_bname: theory -> bstring -> string
    19   val full_bname_path: theory -> string -> bstring -> string
    20   val syn_of: theory -> Syntax.syntax
    21   val tsig_of: theory -> Type.tsig
    22   val classes_of: theory -> Sorts.algebra
    23   val all_classes: theory -> class list
    24   val super_classes: theory -> class -> class list
    25   val minimize_sort: theory -> sort -> sort
    26   val complete_sort: theory -> sort -> sort
    27   val defaultS: theory -> sort
    28   val subsort: theory -> sort * sort -> bool
    29   val of_sort: theory -> typ * sort -> bool
    30   val witness_sorts: theory -> sort list -> sort list -> (typ * sort) list
    31   val is_logtype: theory -> string -> bool
    32   val typ_instance: theory -> typ * typ -> bool
    33   val typ_equiv: theory -> typ * typ -> bool
    34   val typ_match: theory -> typ * typ -> Type.tyenv -> Type.tyenv
    35   val typ_unify: theory -> typ * typ -> Type.tyenv * int -> Type.tyenv * int
    36   val consts_of: theory -> Consts.T
    37   val the_const_constraint: theory -> string -> typ
    38   val const_type: theory -> string -> typ option
    39   val the_const_type: theory -> string -> typ
    40   val declared_tyname: theory -> string -> bool
    41   val declared_const: theory -> string -> bool
    42   val const_monomorphic: theory -> string -> bool
    43   val const_syntax_name: theory -> string -> string
    44   val const_typargs: theory -> string * typ -> typ list
    45   val const_instance: theory -> string * typ list -> typ
    46   val mk_const: theory -> string * typ list -> term
    47   val class_space: theory -> NameSpace.T
    48   val type_space: theory -> NameSpace.T
    49   val const_space: theory -> NameSpace.T
    50   val intern_class: theory -> xstring -> string
    51   val extern_class: theory -> string -> xstring
    52   val intern_type: theory -> xstring -> string
    53   val extern_type: theory -> string -> xstring
    54   val intern_const: theory -> xstring -> string
    55   val extern_const: theory -> string -> xstring
    56   val intern_sort: theory -> sort -> sort
    57   val extern_sort: theory -> sort -> sort
    58   val intern_typ: theory -> typ -> typ
    59   val extern_typ: theory -> typ -> typ
    60   val intern_term: theory -> term -> term
    61   val extern_term: (string -> xstring) -> theory -> term -> term
    62   val intern_tycons: theory -> typ -> typ
    63   val arity_number: theory -> string -> int
    64   val arity_sorts: theory -> string -> sort -> sort list
    65   val certify_class: theory -> class -> class
    66   val certify_sort: theory -> sort -> sort
    67   val certify_typ: theory -> typ -> typ
    68   val certify_typ_mode: Type.mode -> theory -> typ -> typ
    69   val certify': bool -> Pretty.pp -> bool -> Consts.T -> theory -> term -> term * typ * int
    70   val certify_term: theory -> term -> term * typ * int
    71   val certify_prop: theory -> term -> term * typ * int
    72   val cert_term: theory -> term -> term
    73   val cert_prop: theory -> term -> term
    74   val no_frees: Pretty.pp -> term -> term
    75   val no_vars: Pretty.pp -> term -> term
    76   val cert_def: Proof.context -> term -> (string * typ) * term
    77   val read_class: theory -> xstring -> class
    78   val read_arity: theory -> xstring * string list * string -> arity
    79   val cert_arity: theory -> arity -> arity
    80   val add_defsort: string -> theory -> theory
    81   val add_defsort_i: sort -> theory -> theory
    82   val add_types: (bstring * int * mixfix) list -> theory -> theory
    83   val add_nonterminals: bstring list -> theory -> theory
    84   val add_tyabbrs: (bstring * string list * string * mixfix) list -> theory -> theory
    85   val add_tyabbrs_i: (bstring * string list * typ * mixfix) list -> theory -> theory
    86   val add_syntax: (bstring * string * mixfix) list -> theory -> theory
    87   val add_syntax_i: (bstring * typ * mixfix) list -> theory -> theory
    88   val add_modesyntax: Syntax.mode -> (bstring * string * mixfix) list -> theory -> theory
    89   val add_modesyntax_i: Syntax.mode -> (bstring * typ * mixfix) list -> theory -> theory
    90   val del_modesyntax: Syntax.mode -> (bstring * string * mixfix) list -> theory -> theory
    91   val del_modesyntax_i: Syntax.mode -> (bstring * typ * mixfix) list -> theory -> theory
    92   val notation: bool -> Syntax.mode -> (term * mixfix) list -> theory -> theory
    93   val declare_const: Properties.T -> (binding * typ) * mixfix -> theory -> term * theory
    94   val add_consts: (bstring * string * mixfix) list -> theory -> theory
    95   val add_consts_i: (bstring * typ * mixfix) list -> theory -> theory
    96   val add_abbrev: string -> Properties.T -> binding * term -> theory -> (term * term) * theory
    97   val revert_abbrev: string -> string -> theory -> theory
    98   val add_const_constraint: string * typ option -> theory -> theory
    99   val primitive_class: string * class list -> theory -> theory
   100   val primitive_classrel: class * class -> theory -> theory
   101   val primitive_arity: arity -> theory -> theory
   102   val add_trfuns:
   103     (string * (ast list -> ast)) list *
   104     (string * (term list -> term)) list *
   105     (string * (term list -> term)) list *
   106     (string * (ast list -> ast)) list -> theory -> theory
   107   val add_trfunsT:
   108     (string * (bool -> typ -> term list -> term)) list -> theory -> theory
   109   val add_advanced_trfuns:
   110     (string * (Proof.context -> ast list -> ast)) list *
   111     (string * (Proof.context -> term list -> term)) list *
   112     (string * (Proof.context -> term list -> term)) list *
   113     (string * (Proof.context -> ast list -> ast)) list -> theory -> theory
   114   val add_advanced_trfunsT:
   115     (string * (Proof.context -> bool -> typ -> term list -> term)) list -> theory -> theory
   116   val add_tokentrfuns:
   117     (string * string * (Proof.context -> string -> Pretty.T)) list -> theory -> theory
   118   val add_mode_tokentrfuns: string -> (string * (Proof.context -> string -> Pretty.T)) list
   119     -> theory -> theory
   120   val add_trrules: (xstring * string) Syntax.trrule list -> theory -> theory
   121   val del_trrules: (xstring * string) Syntax.trrule list -> theory -> theory
   122   val add_trrules_i: ast Syntax.trrule list -> theory -> theory
   123   val del_trrules_i: ast Syntax.trrule list -> theory -> theory
   124   val add_path: string -> theory -> theory
   125   val parent_path: theory -> theory
   126   val root_path: theory -> theory
   127   val absolute_path: theory -> theory
   128   val local_path: theory -> theory
   129   val no_base_names: theory -> theory
   130   val qualified_names: theory -> theory
   131   val sticky_prefix: string -> theory -> theory
   132   val restore_naming: theory -> theory -> theory
   133   val hide_class: bool -> string -> theory -> theory
   134   val hide_type: bool -> string -> theory -> theory
   135   val hide_const: bool -> string -> theory -> theory
   136 end
   137 
   138 structure Sign: SIGN =
   139 struct
   140 
   141 (** datatype sign **)
   142 
   143 datatype sign = Sign of
   144  {naming: NameSpace.naming,     (*common naming conventions*)
   145   syn: Syntax.syntax,           (*concrete syntax for terms, types, sorts*)
   146   tsig: Type.tsig,              (*order-sorted signature of types*)
   147   consts: Consts.T};            (*polymorphic constants*)
   148 
   149 fun make_sign (naming, syn, tsig, consts) =
   150   Sign {naming = naming, syn = syn, tsig = tsig, consts = consts};
   151 
   152 structure SignData = TheoryDataFun
   153 (
   154   type T = sign;
   155   val copy = I;
   156   fun extend (Sign {syn, tsig, consts, ...}) =
   157     make_sign (NameSpace.default_naming, syn, tsig, consts);
   158 
   159   val empty =
   160     make_sign (NameSpace.default_naming, Syntax.basic_syn, Type.empty_tsig, Consts.empty);
   161 
   162   fun merge pp (sign1, sign2) =
   163     let
   164       val Sign {naming = _, syn = syn1, tsig = tsig1, consts = consts1} = sign1;
   165       val Sign {naming = _, syn = syn2, tsig = tsig2, consts = consts2} = sign2;
   166 
   167       val naming = NameSpace.default_naming;
   168       val syn = Syntax.merge_syntaxes syn1 syn2;
   169       val tsig = Type.merge_tsigs pp (tsig1, tsig2);
   170       val consts = Consts.merge (consts1, consts2);
   171     in make_sign (naming, syn, tsig, consts) end;
   172 );
   173 
   174 fun rep_sg thy = SignData.get thy |> (fn Sign args => args);
   175 
   176 fun map_sign f = SignData.map (fn Sign {naming, syn, tsig, consts} =>
   177   make_sign (f (naming, syn, tsig, consts)));
   178 
   179 fun map_naming f = map_sign (fn (naming, syn, tsig, consts) => (f naming, syn, tsig, consts));
   180 fun map_syn f = map_sign (fn (naming, syn, tsig, consts) => (naming, f syn, tsig, consts));
   181 fun map_tsig f = map_sign (fn (naming, syn, tsig, consts) => (naming, syn, f tsig, consts));
   182 fun map_consts f = map_sign (fn (naming, syn, tsig, consts) => (naming, syn, tsig, f consts));
   183 
   184 
   185 (* naming *)
   186 
   187 val naming_of = #naming o rep_sg;
   188 val base_name = NameSpace.base;
   189 
   190 val full_name = NameSpace.full_name o naming_of;
   191 fun full_bname thy = NameSpace.full_name (naming_of thy) o Binding.name;
   192 fun full_bname_path thy elems =
   193   NameSpace.full_name (NameSpace.add_path elems (naming_of thy)) o Binding.name;
   194 
   195 
   196 (* syntax *)
   197 
   198 val syn_of = #syn o rep_sg;
   199 
   200 
   201 (* type signature *)
   202 
   203 val tsig_of = #tsig o rep_sg;
   204 
   205 val classes_of = #2 o #classes o Type.rep_tsig o tsig_of;
   206 val all_classes = Sorts.all_classes o classes_of;
   207 val super_classes = Sorts.super_classes o classes_of;
   208 val minimize_sort = Sorts.minimize_sort o classes_of;
   209 val complete_sort = Sorts.complete_sort o classes_of;
   210 
   211 val defaultS = Type.defaultS o tsig_of;
   212 val subsort = Type.subsort o tsig_of;
   213 val of_sort = Type.of_sort o tsig_of;
   214 val witness_sorts = Type.witness_sorts o tsig_of;
   215 val is_logtype = member (op =) o Type.logical_types o tsig_of;
   216 
   217 val typ_instance = Type.typ_instance o tsig_of;
   218 fun typ_equiv thy (T, U) = typ_instance thy (T, U) andalso typ_instance thy (U, T);
   219 val typ_match = Type.typ_match o tsig_of;
   220 val typ_unify = Type.unify o tsig_of;
   221 
   222 
   223 (* polymorphic constants *)
   224 
   225 val consts_of = #consts o rep_sg;
   226 val the_const_constraint = Consts.the_constraint o consts_of;
   227 val the_const_type = Consts.the_type o consts_of;
   228 val const_type = try o the_const_type;
   229 val const_monomorphic = Consts.is_monomorphic o consts_of;
   230 val const_syntax_name = Consts.syntax_name o consts_of;
   231 val const_typargs = Consts.typargs o consts_of;
   232 val const_instance = Consts.instance o consts_of;
   233 
   234 fun mk_const thy (c, Ts) = Const (c, const_instance thy (c, Ts));
   235 
   236 val declared_tyname = Symtab.defined o #2 o #types o Type.rep_tsig o tsig_of;
   237 val declared_const = can o the_const_constraint;
   238 
   239 
   240 
   241 (** intern / extern names **)
   242 
   243 val class_space = #1 o #classes o Type.rep_tsig o tsig_of;
   244 val type_space = #1 o #types o Type.rep_tsig o tsig_of;
   245 val const_space = Consts.space_of o consts_of;
   246 
   247 val intern_class = NameSpace.intern o class_space;
   248 val extern_class = NameSpace.extern o class_space;
   249 val intern_type = NameSpace.intern o type_space;
   250 val extern_type = NameSpace.extern o type_space;
   251 val intern_const = NameSpace.intern o const_space;
   252 val extern_const = NameSpace.extern o const_space;
   253 
   254 val intern_sort = map o intern_class;
   255 val extern_sort = map o extern_class;
   256 
   257 local
   258 
   259 fun map_typ f g (Type (c, Ts)) = Type (g c, map (map_typ f g) Ts)
   260   | map_typ f _ (TFree (x, S)) = TFree (x, map f S)
   261   | map_typ f _ (TVar (xi, S)) = TVar (xi, map f S);
   262 
   263 fun map_term f g h (Const (c, T)) = Const (h c, map_typ f g T)
   264   | map_term f g _ (Free (x, T)) = Free (x, map_typ f g T)
   265   | map_term f g _ (Var (xi, T)) = Var (xi, map_typ f g T)
   266   | map_term _ _ _ (t as Bound _) = t
   267   | map_term f g h (Abs (x, T, t)) = Abs (x, map_typ f g T, map_term f g h t)
   268   | map_term f g h (t $ u) = map_term f g h t $ map_term f g h u;
   269 
   270 val add_classesT = Term.fold_atyps
   271   (fn TFree (_, S) => fold (insert (op =)) S
   272     | TVar (_, S) => fold (insert (op =)) S
   273     | _ => I);
   274 
   275 fun add_tyconsT (Type (c, Ts)) = insert (op =) c #> fold add_tyconsT Ts
   276   | add_tyconsT _ = I;
   277 
   278 val add_consts = Term.fold_aterms (fn Const (c, _) => insert (op =) c | _ => I);
   279 
   280 fun mapping add_names f t =
   281   let
   282     fun f' (x: string) = let val y = f x in if x = y then NONE else SOME (x, y) end;
   283     val tab = map_filter f' (add_names t []);
   284     fun get x = the_default x (AList.lookup (op =) tab x);
   285   in get end;
   286 
   287 fun typ_mapping f g thy T =
   288   T |> map_typ
   289     (mapping add_classesT (f thy) T)
   290     (mapping add_tyconsT (g thy) T);
   291 
   292 fun term_mapping f g h thy t =
   293   t |> map_term
   294     (mapping (Term.fold_types add_classesT) (f thy) t)
   295     (mapping (Term.fold_types add_tyconsT) (g thy) t)
   296     (mapping add_consts (h thy) t);
   297 
   298 in
   299 
   300 val intern_typ = typ_mapping intern_class intern_type;
   301 val extern_typ = typ_mapping extern_class extern_type;
   302 val intern_term = term_mapping intern_class intern_type intern_const;
   303 fun extern_term h = term_mapping extern_class extern_type (K h);
   304 val intern_tycons = typ_mapping (K I) intern_type;
   305 
   306 end;
   307 
   308 
   309 
   310 (** certify entities **)    (*exception TYPE*)
   311 
   312 (* certify wrt. type signature *)
   313 
   314 val arity_number = Type.arity_number o tsig_of;
   315 fun arity_sorts thy = Type.arity_sorts (Syntax.pp_global thy) (tsig_of thy);
   316 
   317 val certify_class         = Type.cert_class o tsig_of;
   318 val certify_sort          = Type.cert_sort o tsig_of;
   319 val certify_typ           = Type.cert_typ o tsig_of;
   320 fun certify_typ_mode mode = Type.cert_typ_mode mode o tsig_of;
   321 
   322 
   323 (* certify term/prop *)
   324 
   325 local
   326 
   327 fun type_check pp tm =
   328   let
   329     fun err_appl why bs t T u U =
   330       let
   331         val xs = map Free bs;           (*we do not rename here*)
   332         val t' = subst_bounds (xs, t);
   333         val u' = subst_bounds (xs, u);
   334         val msg = cat_lines
   335           (TypeInfer.appl_error (Syntax.pp_show_brackets pp) why t' T u' U);
   336       in raise TYPE (msg, [T, U], [t', u']) end;
   337 
   338     fun typ_of (_, Const (_, T)) = T
   339       | typ_of (_, Free  (_, T)) = T
   340       | typ_of (_, Var (_, T)) = T
   341       | typ_of (bs, Bound i) = snd (nth bs i handle Subscript =>
   342           raise TYPE ("Loose bound variable: B." ^ string_of_int i, [], [Bound i]))
   343       | typ_of (bs, Abs (x, T, body)) = T --> typ_of ((x, T) :: bs, body)
   344       | typ_of (bs, t $ u) =
   345           let val T = typ_of (bs, t) and U = typ_of (bs, u) in
   346             (case T of
   347               Type ("fun", [T1, T2]) =>
   348                 if T1 = U then T2 else err_appl "Incompatible operand type" bs t T u U
   349             | _ => err_appl "Operator not of function type" bs t T u U)
   350           end;
   351   in typ_of ([], tm) end;
   352 
   353 fun err msg = raise TYPE (msg, [], []);
   354 
   355 fun check_vars (t $ u) = (check_vars t; check_vars u)
   356   | check_vars (Abs (_, _, t)) = check_vars t
   357   | check_vars (Free (x, _)) =
   358       if NameSpace.is_qualified x then err ("Malformed variable: " ^ quote x) else ()
   359   | check_vars (Var (xi as (_, i), _)) =
   360       if i < 0 then err ("Malformed variable: " ^ quote (Term.string_of_vname xi)) else ()
   361   | check_vars _ = ();
   362 
   363 in
   364 
   365 fun certify' prop pp do_expand consts thy tm =
   366   let
   367     val _ = check_vars tm;
   368     val tm' = Term.map_types (certify_typ thy) tm;
   369     val T = type_check pp tm';
   370     val _ = if prop andalso T <> propT then err "Term not of type prop" else ();
   371     val tm'' = Consts.certify pp (tsig_of thy) do_expand consts tm';
   372   in (if tm = tm'' then tm else tm'', T, Term.maxidx_of_term tm'') end;
   373 
   374 fun certify_term thy = certify' false (Syntax.pp_global thy) true (consts_of thy) thy;
   375 fun certify_prop thy = certify' true (Syntax.pp_global thy) true (consts_of thy) thy;
   376 
   377 fun cert_term_abbrev thy = #1 o certify' false (Syntax.pp_global thy) false (consts_of thy) thy;
   378 val cert_term = #1 oo certify_term;
   379 val cert_prop = #1 oo certify_prop;
   380 
   381 end;
   382 
   383 
   384 (* specifications *)
   385 
   386 fun no_variables kind add addT mk mkT pp tm =
   387   (case (add tm [], addT tm []) of
   388     ([], []) => tm
   389   | (frees, tfrees) => error (Pretty.string_of (Pretty.block
   390       (Pretty.str ("Illegal " ^ kind ^ " variable(s) in term:") :: Pretty.brk 1 ::
   391        Pretty.commas (map (Pretty.term pp o mk) frees @ map (Pretty.typ pp o mkT) tfrees)))));
   392 
   393 val no_frees = no_variables "free" Term.add_frees Term.add_tfrees Free TFree;
   394 val no_vars = no_variables "schematic" Term.add_vars Term.add_tvars Var TVar;
   395 
   396 fun cert_def ctxt tm =
   397   let val ((lhs, rhs), _) = tm
   398     |> no_vars (Syntax.pp ctxt)
   399     |> Logic.strip_imp_concl
   400     |> PrimitiveDefs.dest_def ctxt Term.is_Const (K false) (K false)
   401   in (Term.dest_Const (Term.head_of lhs), rhs) end
   402   handle TERM (msg, _) => error msg;
   403 
   404 
   405 
   406 (** read and certify entities **)    (*exception ERROR*)
   407 
   408 (* classes *)
   409 
   410 fun read_class thy c = certify_class thy (intern_class thy c)
   411   handle TYPE (msg, _, _) => error msg;
   412 
   413 
   414 (* type arities *)
   415 
   416 fun prep_arity prep_tycon prep_sort thy (t, Ss, S) =
   417   let val arity = (prep_tycon thy t, map (prep_sort thy) Ss, prep_sort thy S)
   418   in Type.add_arity (Syntax.pp_global thy) arity (tsig_of thy); arity end;
   419 
   420 val read_arity = prep_arity intern_type Syntax.read_sort_global;
   421 val cert_arity = prep_arity (K I) certify_sort;
   422 
   423 
   424 
   425 (** signature extension functions **)  (*exception ERROR/TYPE*)
   426 
   427 (* add default sort *)
   428 
   429 fun gen_add_defsort prep_sort s thy =
   430   thy |> map_tsig (Type.set_defsort (prep_sort thy s));
   431 
   432 val add_defsort = gen_add_defsort Syntax.read_sort_global;
   433 val add_defsort_i = gen_add_defsort certify_sort;
   434 
   435 
   436 (* add type constructors *)
   437 
   438 fun add_types types thy = thy |> map_sign (fn (naming, syn, tsig, consts) =>
   439   let
   440     val syn' = Syntax.update_type_gram types syn;
   441     val decls = map (fn (a, n, mx) => (Syntax.type_name a mx, n)) types;
   442     val tags = [(Markup.theory_nameN, Context.theory_name thy)];
   443     val tsig' = fold (Type.add_type naming tags) decls tsig;
   444   in (naming, syn', tsig', consts) end);
   445 
   446 
   447 (* add nonterminals *)
   448 
   449 fun add_nonterminals ns thy = thy |> map_sign (fn (naming, syn, tsig, consts) =>
   450   let
   451     val syn' = Syntax.update_consts ns syn;
   452     val tsig' = fold (Type.add_nonterminal naming []) ns tsig;
   453   in (naming, syn', tsig', consts) end);
   454 
   455 
   456 (* add type abbreviations *)
   457 
   458 fun gen_add_tyabbr parse_typ (a, vs, rhs, mx) thy =
   459   thy |> map_sign (fn (naming, syn, tsig, consts) =>
   460     let
   461       val ctxt = ProofContext.init thy;
   462       val syn' = Syntax.update_type_gram [(a, length vs, mx)] syn;
   463       val a' = Syntax.type_name a mx;
   464       val abbr = (a', vs, certify_typ_mode Type.mode_syntax thy (parse_typ ctxt rhs))
   465         handle ERROR msg => cat_error msg ("in type abbreviation " ^ quote a');
   466       val tsig' = Type.add_abbrev naming [] abbr tsig;
   467     in (naming, syn', tsig', consts) end);
   468 
   469 val add_tyabbrs = fold (gen_add_tyabbr Syntax.parse_typ);
   470 val add_tyabbrs_i = fold (gen_add_tyabbr (K I));
   471 
   472 
   473 (* modify syntax *)
   474 
   475 fun gen_syntax change_gram parse_typ mode args thy =
   476   let
   477     val ctxt = ProofContext.init thy;
   478     fun prep (c, T, mx) = (c, certify_typ_mode Type.mode_syntax thy (parse_typ ctxt T), mx)
   479       handle ERROR msg =>
   480         cat_error msg ("in syntax declaration " ^ quote (Syntax.const_name c mx));
   481   in thy |> map_syn (change_gram (is_logtype thy) mode (map prep args)) end;
   482 
   483 fun gen_add_syntax x = gen_syntax Syntax.update_const_gram x;
   484 
   485 val add_modesyntax = gen_add_syntax Syntax.parse_typ;
   486 val add_modesyntax_i = gen_add_syntax (K I);
   487 val add_syntax = add_modesyntax Syntax.mode_default;
   488 val add_syntax_i = add_modesyntax_i Syntax.mode_default;
   489 val del_modesyntax = gen_syntax Syntax.remove_const_gram Syntax.parse_typ;
   490 val del_modesyntax_i = gen_syntax Syntax.remove_const_gram (K I);
   491 
   492 fun notation add mode args thy =
   493   let
   494     val change_gram = if add then Syntax.update_const_gram else Syntax.remove_const_gram;
   495     fun const_syntax (Const (c, _), mx) = try (Consts.syntax (consts_of thy)) (c, mx)
   496       | const_syntax _ = NONE;
   497   in gen_syntax change_gram (K I) mode (map_filter const_syntax args) thy end;
   498 
   499 
   500 (* add constants *)
   501 
   502 local
   503 
   504 fun gen_add_consts parse_typ authentic tags raw_args thy =
   505   let
   506     val ctxt = ProofContext.init thy;
   507     val prepT = Type.no_tvars o Term.no_dummyT o certify_typ thy o parse_typ ctxt;
   508     fun prep (raw_b, raw_T, raw_mx) =
   509       let
   510         val (mx_name, mx) = Syntax.const_mixfix (Binding.name_of raw_b) raw_mx;
   511         val b = Binding.map_name (K mx_name) raw_b;
   512         val c = full_name thy b;
   513         val c_syn = if authentic then Syntax.constN ^ c else Binding.name_of b;
   514         val T = (prepT raw_T handle TYPE (msg, _, _) => error msg) handle ERROR msg =>
   515           cat_error msg ("in declaration of constant " ^ quote (Binding.str_of b));
   516         val T' = Logic.varifyT T;
   517       in ((b, T'), (c_syn, T', mx), Const (c, T)) end;
   518     val args = map prep raw_args;
   519     val tags' = tags |> Properties.put (Markup.theory_nameN, Context.theory_name thy);
   520   in
   521     thy
   522     |> map_consts (fold (Consts.declare authentic (naming_of thy) tags' o #1) args)
   523     |> add_syntax_i (map #2 args)
   524     |> pair (map #3 args)
   525   end;
   526 
   527 fun bindify (name, T, mx) = (Binding.name name, T, mx);
   528 
   529 in
   530 
   531 fun add_consts args = snd o gen_add_consts Syntax.parse_typ false [] (map bindify args);
   532 fun add_consts_i args = snd o gen_add_consts (K I) false [] (map bindify args);
   533 
   534 fun declare_const tags ((b, T), mx) thy =
   535   let
   536     val pos = Binding.pos_of b;
   537     val tags' = Position.default_properties pos tags;
   538     val ([const as Const (c, _)], thy') = gen_add_consts (K I) true tags' [(b, T, mx)] thy;
   539     val _ = Position.report (Markup.const_decl c) pos;
   540   in (const, thy') end;
   541 
   542 end;
   543 
   544 
   545 (* abbreviations *)
   546 
   547 fun add_abbrev mode tags (b, raw_t) thy =
   548   let
   549     val pp = Syntax.pp_global thy;
   550     val prep_tm = no_frees pp o Term.no_dummy_patterns o cert_term_abbrev thy;
   551     val t = (prep_tm raw_t handle TYPE (msg, _, _) => error msg | TERM (msg, _) => error msg)
   552       handle ERROR msg => cat_error msg ("in constant abbreviation " ^ quote (Binding.str_of b));
   553     val (res, consts') = consts_of thy
   554       |> Consts.abbreviate pp (tsig_of thy) (naming_of thy) mode tags (b, t);
   555   in (res, thy |> map_consts (K consts')) end;
   556 
   557 fun revert_abbrev mode c = map_consts (Consts.revert_abbrev mode c);
   558 
   559 
   560 (* add constraints *)
   561 
   562 fun add_const_constraint (c, opt_T) thy =
   563   let
   564     fun prepT raw_T =
   565       let val T = Logic.varifyT (Type.no_tvars (Term.no_dummyT (certify_typ thy raw_T)))
   566       in cert_term thy (Const (c, T)); T end
   567       handle TYPE (msg, _, _) => error msg;
   568   in thy |> map_consts (Consts.constrain (c, Option.map prepT opt_T)) end;
   569 
   570 
   571 (* primitive classes and arities *)
   572 
   573 fun primitive_class (bclass, classes) thy =
   574   thy |> map_sign (fn (naming, syn, tsig, consts) =>
   575     let
   576       val syn' = Syntax.update_consts [bclass] syn;
   577       val tsig' = Type.add_class (Syntax.pp_global thy) naming (bclass, classes) tsig;
   578     in (naming, syn', tsig', consts) end)
   579   |> add_consts_i [(Logic.const_of_class bclass, Term.a_itselfT --> propT, NoSyn)];
   580 
   581 fun primitive_classrel arg thy = thy |> map_tsig (Type.add_classrel (Syntax.pp_global thy) arg);
   582 fun primitive_arity arg thy = thy |> map_tsig (Type.add_arity (Syntax.pp_global thy) arg);
   583 
   584 
   585 (* add translation functions *)
   586 
   587 local
   588 
   589 fun mk trs = map Syntax.mk_trfun trs;
   590 
   591 fun gen_add_trfuns ext non_typed (atrs, trs, tr's, atr's) =
   592   map_syn (ext (mk atrs, mk trs, mk (map (apsnd non_typed) tr's), mk atr's));
   593 
   594 fun gen_add_trfunsT ext tr's = map_syn (ext ([], [], mk tr's, []));
   595 
   596 in
   597 
   598 val add_trfuns = gen_add_trfuns Syntax.update_trfuns Syntax.non_typed_tr';
   599 val add_trfunsT = gen_add_trfunsT Syntax.update_trfuns;
   600 val add_advanced_trfuns = gen_add_trfuns Syntax.update_advanced_trfuns Syntax.non_typed_tr'';
   601 val add_advanced_trfunsT = gen_add_trfunsT Syntax.update_advanced_trfuns;
   602 
   603 end;
   604 
   605 val add_tokentrfuns = map_syn o Syntax.extend_tokentrfuns;
   606 fun add_mode_tokentrfuns m = add_tokentrfuns o map (fn (s, f) => (m, s, f));
   607 
   608 
   609 (* translation rules *)
   610 
   611 fun gen_trrules f args thy = thy |> map_syn (fn syn =>
   612   let val rules = map (Syntax.map_trrule (apfst (intern_type thy))) args
   613   in f (ProofContext.init thy) (is_logtype thy) syn rules syn end);
   614 
   615 val add_trrules = gen_trrules Syntax.update_trrules;
   616 val del_trrules = gen_trrules Syntax.remove_trrules;
   617 val add_trrules_i = map_syn o Syntax.update_trrules_i;
   618 val del_trrules_i = map_syn o Syntax.remove_trrules_i;
   619 
   620 
   621 (* naming *)
   622 
   623 val add_path        = map_naming o NameSpace.add_path;
   624 val no_base_names   = map_naming NameSpace.no_base_names;
   625 val qualified_names = map_naming NameSpace.qualified_names;
   626 val sticky_prefix   = map_naming o NameSpace.sticky_prefix;
   627 val restore_naming  = map_naming o K o naming_of;
   628 
   629 val parent_path   = add_path "..";
   630 val root_path     = add_path "/";
   631 val absolute_path = add_path "//";
   632 
   633 fun local_path thy = thy |> root_path |> add_path (Context.theory_name thy);
   634 
   635 
   636 (* hide names *)
   637 
   638 val hide_class = map_tsig oo Type.hide_class;
   639 val hide_type = map_tsig oo Type.hide_type;
   640 val hide_const = map_consts oo Consts.hide;
   641 
   642 end;