src/Pure/library.ML
author haftmann
Tue Oct 16 23:12:38 2007 +0200 (2007-10-16)
changeset 25061 250e1da3204b
parent 25058 d8d8bac48031
child 25224 6d4d26e878f4
permissions -rw-r--r--
added yield_singleton
     1 (*  Title:      Pure/library.ML
     2     ID:         $Id$
     3     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     4     Author:     Markus Wenzel, TU Muenchen
     5 
     6 Basic library: functions, options, pairs, booleans, lists, integers,
     7 strings, lists as sets, orders, current directory, misc.
     8 
     9 See also General/basics.ML for the most fundamental concepts.
    10 *)
    11 
    12 infix 1 |>>>
    13 infix 2 ?
    14 infix 3 o oo ooo oooo
    15 infix 4 ~~ upto downto
    16 infix orf andf \ \\ mem mem_int mem_string union union_int
    17   union_string inter inter_int inter_string subset subset_int subset_string
    18 
    19 signature BASIC_LIBRARY =
    20 sig
    21   (*functions*)
    22   val undefined: 'a -> 'b
    23   val I: 'a -> 'a
    24   val K: 'a -> 'b -> 'a
    25   val curry: ('a * 'b -> 'c) -> 'a -> 'b -> 'c
    26   val uncurry: ('a -> 'b -> 'c) -> 'a * 'b -> 'c
    27   val |>>> : ('a * 'c) * ('a -> 'b * 'd) -> 'b * ('c * 'd)
    28   val ? : bool * ('a -> 'a) -> 'a -> 'a
    29   val oo: ('a -> 'b) * ('c -> 'd -> 'a) -> 'c -> 'd -> 'b
    30   val ooo: ('a -> 'b) * ('c -> 'd -> 'e -> 'a) -> 'c -> 'd -> 'e -> 'b
    31   val oooo: ('a -> 'b) * ('c -> 'd -> 'e -> 'f -> 'a) -> 'c -> 'd -> 'e -> 'f -> 'b
    32   val funpow: int -> ('a -> 'a) -> 'a -> 'a
    33 
    34   (*errors*)
    35   exception SYS_ERROR of string
    36   val sys_error: string -> 'a
    37   exception ERROR of string
    38   val error: string -> 'a
    39   val cat_error: string -> string -> 'a
    40   val assert_all: ('a -> bool) -> 'a list -> ('a -> string) -> unit
    41 
    42   (*pairs*)
    43   val pair: 'a -> 'b -> 'a * 'b
    44   val rpair: 'a -> 'b -> 'b * 'a
    45   val fst: 'a * 'b -> 'a
    46   val snd: 'a * 'b -> 'b
    47   val eq_fst: ('a * 'c -> bool) -> ('a * 'b) * ('c * 'd) -> bool
    48   val eq_snd: ('b * 'd -> bool) -> ('a * 'b) * ('c * 'd) -> bool
    49   val eq_pair: ('a * 'c -> bool) -> ('b * 'd -> bool) -> ('a * 'b) * ('c * 'd) -> bool
    50   val swap: 'a * 'b -> 'b * 'a
    51   val apfst: ('a -> 'b) -> 'a * 'c -> 'b * 'c
    52   val apsnd: ('a -> 'b) -> 'c * 'a -> 'c * 'b
    53   val pairself: ('a -> 'b) -> 'a * 'a -> 'b * 'b
    54 
    55   (*booleans*)
    56   val equal: ''a -> ''a -> bool
    57   val not_equal: ''a -> ''a -> bool
    58   val orf: ('a -> bool) * ('a -> bool) -> 'a -> bool
    59   val andf: ('a -> bool) * ('a -> bool) -> 'a -> bool
    60   val exists: ('a -> bool) -> 'a list -> bool
    61   val forall: ('a -> bool) -> 'a list -> bool
    62   val set: bool ref -> bool
    63   val reset: bool ref -> bool
    64   val toggle: bool ref -> bool
    65   val change: 'a ref -> ('a -> 'a) -> unit
    66   val setmp_noncritical: 'a ref -> 'a -> ('b -> 'c) -> 'b -> 'c
    67   val setmp: 'a ref -> 'a -> ('b -> 'c) -> 'b -> 'c
    68 
    69   (*lists*)
    70   exception UnequalLengths
    71   val single: 'a -> 'a list
    72   val the_single: 'a list -> 'a
    73   val singleton: ('a list -> 'b list) -> 'a -> 'b
    74   val yield_singleton: ('a list -> 'c -> 'b list * 'c) -> 'a -> 'c -> 'b * 'c
    75   val apply: ('a -> 'a) list -> 'a -> 'a
    76   val perhaps_apply: ('a -> 'a option) list -> 'a -> 'a option
    77   val perhaps_loop: ('a -> 'a option) -> 'a -> 'a option
    78   val foldr1: ('a * 'a -> 'a) -> 'a list -> 'a
    79   val foldl_map: ('a * 'b -> 'a * 'c) -> 'a * 'b list -> 'a * 'c list
    80   val flat: 'a list list -> 'a list
    81   val unflat: 'a list list -> 'b list -> 'b list list
    82   val burrow: ('a list -> 'b list) -> 'a list list -> 'b list list
    83   val burrow_options: ('a list -> 'b list) -> 'a option list -> 'b option list
    84   val fold_burrow: ('a list -> 'c -> 'b list * 'd) -> 'a list list -> 'c -> 'b list list * 'd
    85   val maps: ('a -> 'b list) -> 'a list -> 'b list
    86   val chop: int -> 'a list -> 'a list * 'a list
    87   val dropwhile: ('a -> bool) -> 'a list -> 'a list
    88   val nth: 'a list -> int -> 'a
    89   val nth_map: int -> ('a -> 'a) -> 'a list -> 'a list
    90   val nth_drop: int -> 'a list -> 'a list
    91   val nth_list: 'a list list -> int -> 'a list
    92   val map_index: (int * 'a -> 'b) -> 'a list -> 'b list
    93   val fold_index: (int * 'a -> 'b -> 'b) -> 'a list -> 'b -> 'b
    94   val split_last: 'a list -> 'a list * 'a
    95   val find_index: ('a -> bool) -> 'a list -> int
    96   val find_index_eq: ''a -> ''a list -> int
    97   val find_first: ('a -> bool) -> 'a list -> 'a option
    98   val get_index: ('a -> 'b option) -> 'a list -> (int * 'b) option
    99   val get_first: ('a -> 'b option) -> 'a list -> 'b option
   100   val eq_list: ('a * 'b -> bool) -> 'a list * 'b list -> bool
   101   val map2: ('a -> 'b -> 'c) -> 'a list -> 'b list -> 'c list
   102   val fold2: ('a -> 'b -> 'c -> 'c) -> 'a list -> 'b list -> 'c -> 'c
   103   val zip_options: 'a list -> 'b option list -> ('a * 'b) list
   104   val ~~ : 'a list * 'b list -> ('a * 'b) list
   105   val split_list: ('a * 'b) list -> 'a list * 'b list
   106   val separate: 'a -> 'a list -> 'a list
   107   val replicate: int -> 'a -> 'a list
   108   val multiply: 'a list -> 'a list list -> 'a list list
   109   val product: 'a list -> 'b list -> ('a * 'b) list
   110   val filter: ('a -> bool) -> 'a list -> 'a list
   111   val filter_out: ('a -> bool) -> 'a list -> 'a list
   112   val map_filter: ('a -> 'b option) -> 'a list -> 'b list
   113   val is_prefix: ('a * 'a -> bool) -> 'a list -> 'a list -> bool
   114   val take_prefix: ('a -> bool) -> 'a list -> 'a list * 'a list
   115   val chop_prefix: ('a * 'b -> bool) -> 'a list * 'b list -> 'a list * ('a list * 'b list)
   116   val take_suffix: ('a -> bool) -> 'a list -> 'a list * 'a list
   117   val prefixes1: 'a list -> 'a list list
   118   val prefixes: 'a list -> 'a list list
   119   val suffixes1: 'a list -> 'a list list
   120   val suffixes: 'a list -> 'a list list
   121 
   122   (*integers*)
   123   val inc: int ref -> int
   124   val dec: int ref -> int
   125   val upto: int * int -> int list
   126   val downto: int * int -> int list
   127   val radixpand: int * int -> int list
   128   val radixstring: int * string * int -> string
   129   val string_of_int: int -> string
   130   val signed_string_of_int: int -> string
   131   val string_of_indexname: string * int -> string
   132   val read_radix_int: int -> string list -> int * string list
   133   val read_int: string list -> int * string list
   134   val oct_char: string -> string
   135 
   136   (*strings*)
   137   val nth_string: string -> int -> string
   138   val fold_string: (string -> 'a -> 'a) -> string -> 'a -> 'a
   139   val exists_string: (string -> bool) -> string -> bool
   140   val forall_string: (string -> bool) -> string -> bool
   141   val enclose: string -> string -> string -> string
   142   val unenclose: string -> string
   143   val quote: string -> string
   144   val space_implode: string -> string list -> string
   145   val commas: string list -> string
   146   val commas_quote: string list -> string
   147   val cat_lines: string list -> string
   148   val space_explode: string -> string -> string list
   149   val split_lines: string -> string list
   150   val prefix_lines: string -> string -> string
   151   val untabify: string list -> string list
   152   val prefix: string -> string -> string
   153   val suffix: string -> string -> string
   154   val unprefix: string -> string -> string
   155   val unsuffix: string -> string -> string
   156   val replicate_string: int -> string -> string
   157   val translate_string: (string -> string) -> string -> string
   158 
   159   (*lists as sets -- see also Pure/General/ord_list.ML*)
   160   val member: ('b * 'a -> bool) -> 'a list -> 'b -> bool
   161   val insert: ('a * 'a -> bool) -> 'a -> 'a list -> 'a list
   162   val remove: ('b * 'a -> bool) -> 'b -> 'a list -> 'a list
   163   val update: ('a * 'a -> bool) -> 'a -> 'a list -> 'a list
   164   val subtract: ('b * 'a -> bool) -> 'b list -> 'a list -> 'a list
   165   val merge: ('a * 'a -> bool) -> 'a list * 'a list -> 'a list
   166   val mem: ''a * ''a list -> bool
   167   val mem_int: int * int list -> bool
   168   val mem_string: string * string list -> bool
   169   val union: ''a list * ''a list -> ''a list
   170   val union_int: int list * int list -> int list
   171   val union_string: string list * string list -> string list
   172   val gen_union: ('a * 'a -> bool) -> 'a list * 'a list -> 'a list
   173   val gen_inter: ('a * 'b -> bool) -> 'a list * 'b list -> 'a list
   174   val inter: ''a list * ''a list -> ''a list
   175   val inter_int: int list * int list -> int list
   176   val inter_string: string list * string list -> string list
   177   val subset: ''a list * ''a list -> bool
   178   val subset_int: int list * int list -> bool
   179   val subset_string: string list * string list -> bool
   180   val eq_set: ''a list * ''a list -> bool
   181   val eq_set_string: string list * string list -> bool
   182   val gen_subset: ('a * 'b -> bool) -> 'a list * 'b list -> bool
   183   val gen_eq_set: ('a * 'b -> bool) -> 'a list * 'b list -> bool
   184   val \ : ''a list * ''a -> ''a list
   185   val \\ : ''a list * ''a list -> ''a list
   186   val distinct: ('a * 'a -> bool) -> 'a list -> 'a list
   187   val duplicates: ('a * 'a -> bool) -> 'a list -> 'a list
   188   val has_duplicates: ('a * 'a -> bool) -> 'a list -> bool
   189 
   190   (*lists as multisets*)
   191   val remove1: ('b * 'a -> bool) -> 'b -> 'a list -> 'a list
   192   val submultiset: ('a * 'b -> bool) -> 'a list * 'b list -> bool
   193 
   194   (*orders*)
   195   val is_equal: order -> bool
   196   val rev_order: order -> order
   197   val make_ord: ('a * 'a -> bool) -> 'a * 'a -> order
   198   val int_ord: int * int -> order
   199   val string_ord: string * string -> order
   200   val fast_string_ord: string * string -> order
   201   val option_ord: ('a * 'b -> order) -> 'a option * 'b option -> order
   202   val prod_ord: ('a * 'b -> order) -> ('c * 'd -> order) -> ('a * 'c) * ('b * 'd) -> order
   203   val dict_ord: ('a * 'b -> order) -> 'a list * 'b list -> order
   204   val list_ord: ('a * 'b -> order) -> 'a list * 'b list -> order
   205   val sort: ('a * 'a -> order) -> 'a list -> 'a list
   206   val sort_distinct: ('a * 'a -> order) -> 'a list -> 'a list
   207   val sort_strings: string list -> string list
   208   val sort_wrt: ('a -> string) -> 'a list -> 'a list
   209 
   210   (*random numbers*)
   211   exception RANDOM
   212   val random: unit -> real
   213   val random_range: int -> int -> int
   214   val one_of: 'a list -> 'a
   215   val frequency: (int * 'a) list -> 'a
   216 
   217   (*misc*)
   218   val divide_and_conquer: ('a -> 'a list * ('b list -> 'b)) -> 'a -> 'b
   219   val partition_eq: ('a * 'a -> bool) -> 'a list -> 'a list list
   220   val partition_list: (int -> 'a -> bool) -> int -> int -> 'a list -> 'a list list
   221   val gensym: string -> string
   222   type stamp
   223   val stamp: unit -> stamp
   224   type serial
   225   val serial: unit -> serial
   226   val serial_string: unit -> string
   227   structure Object: sig type T end
   228 end;
   229 
   230 signature LIBRARY =
   231 sig
   232   include BASIC_LIBRARY
   233   val foldl: ('a * 'b -> 'a) -> 'a * 'b list -> 'a
   234   val foldr: ('a * 'b -> 'b) -> 'a list * 'b -> 'b
   235   val take: int * 'a list -> 'a list
   236   val drop: int * 'a list -> 'a list
   237   val last_elem: 'a list -> 'a
   238 end;
   239 
   240 structure Library: LIBRARY =
   241 struct
   242 
   243 (* functions *)
   244 
   245 fun undefined _ = raise Match;
   246 
   247 fun I x = x;
   248 fun K x = fn _ => x;
   249 fun curry f x y = f (x, y);
   250 fun uncurry f (x, y) = f x y;
   251 
   252 (*application and structured results -- old version*)
   253 fun (x, y) |>>> f = let val (x', z) = f x in (x', (y, z)) end;
   254 
   255 (*conditional application*)
   256 fun b ? f = fn x => if b then f x else x;
   257 
   258 (*composition with multiple args*)
   259 fun (f oo g) x y = f (g x y);
   260 fun (f ooo g) x y z = f (g x y z);
   261 fun (f oooo g) x y z w = f (g x y z w);
   262 
   263 (*function exponentiation: f(...(f x)...) with n applications of f*)
   264 fun funpow (0: int) _ x = x
   265   | funpow n f x = funpow (n - 1) f (f x);
   266 
   267 
   268 (* errors *)
   269 
   270 exception SYS_ERROR of string;
   271 fun sys_error msg = raise SYS_ERROR msg;
   272 
   273 exception ERROR of string;
   274 fun error msg = raise ERROR msg;
   275 
   276 fun cat_error "" msg = error msg
   277   | cat_error msg1 msg2 = error (msg1 ^ "\n" ^ msg2);
   278 
   279 fun assert_all pred list msg =
   280   let
   281     fun ass [] = ()
   282       | ass (x :: xs) = if pred x then ass xs else error (msg x);
   283   in ass list end;
   284 
   285 
   286 (* pairs *)
   287 
   288 fun pair x y = (x, y);
   289 fun rpair x y = (y, x);
   290 
   291 fun fst (x, y) = x;
   292 fun snd (x, y) = y;
   293 
   294 fun eq_fst eq ((x1, _), (x2, _)) = eq (x1, x2);
   295 fun eq_snd eq ((_, y1), (_, y2)) = eq (y1, y2);
   296 fun eq_pair eqx eqy ((x1, y1), (x2, y2)) = eqx (x1, x2) andalso eqy (y1, y2);
   297 
   298 fun swap (x, y) = (y, x);
   299 
   300 fun apfst f (x, y) = (f x, y);
   301 fun apsnd f (x, y) = (x, f y);
   302 fun pairself f (x, y) = (f x, f y);
   303 
   304 
   305 (* booleans *)
   306 
   307 (*polymorphic equality*)
   308 fun equal x y = x = y;
   309 fun not_equal x y = x <> y;
   310 
   311 (*combining predicates*)
   312 fun p orf q = fn x => p x orelse q x;
   313 fun p andf q = fn x => p x andalso q x;
   314 
   315 (*exists pred [x1, ..., xn] ===> pred x1 orelse ... orelse pred xn*)
   316 fun exists (pred: 'a -> bool) : 'a list -> bool =
   317   let fun boolf [] = false
   318         | boolf (x :: xs) = pred x orelse boolf xs
   319   in boolf end;
   320 
   321 (*forall pred [x1, ..., xn] ===> pred x1 andalso ... andalso pred xn*)
   322 fun forall (pred: 'a -> bool) : 'a list -> bool =
   323   let fun boolf [] = true
   324         | boolf (x :: xs) = pred x andalso boolf xs
   325   in boolf end;
   326 
   327 
   328 (* flags *)
   329 
   330 fun set flag = (flag := true; true);
   331 fun reset flag = (flag := false; false);
   332 fun toggle flag = (flag := not (! flag); ! flag);
   333 
   334 fun change r f = r := f (! r);
   335 
   336 (*temporarily set flag during execution*)
   337 fun setmp_noncritical flag value f x =
   338   let
   339     val orig_value = ! flag;
   340     val _ = flag := value;
   341     val result = Exn.capture f x;
   342     val _ = flag := orig_value;
   343   in Exn.release result end;
   344 
   345 fun setmp flag value f x = NAMED_CRITICAL "setmp" (fn () => setmp_noncritical flag value f x);
   346 
   347 
   348 
   349 (** lists **)
   350 
   351 exception UnequalLengths;
   352 
   353 fun single x = [x];
   354 
   355 fun the_single [x] = x
   356   | the_single _ = raise Empty;
   357 
   358 fun singleton f x = the_single (f [x]);
   359 
   360 fun yield_singleton f x = f [x] #>> the_single;
   361 
   362 fun apply [] x = x
   363   | apply (f :: fs) x = apply fs (f x);
   364 
   365 fun perhaps_apply funs arg =
   366   let
   367     fun app [] res = res
   368       | app (f :: fs) (changed, x) =
   369           (case f x of
   370             NONE => app fs (changed, x)
   371           | SOME x' => app fs (true, x'));
   372   in (case app funs (false, arg) of (false, _) => NONE | (true, arg') => SOME arg') end;
   373 
   374 fun perhaps_loop f arg =
   375   let
   376     fun loop (changed, x) =
   377       (case f x of
   378         NONE => (changed, x)
   379       | SOME x' => loop (true, x'));
   380   in (case loop (false, arg) of (false, _) => NONE | (true, arg') => SOME arg') end;
   381 
   382 
   383 (* fold -- old versions *)
   384 
   385 (*the following versions of fold are designed to fit nicely with infixes*)
   386 
   387 (*  (op @) (e, [x1, ..., xn])  ===>  ((e @ x1) @ x2) ... @ xn
   388     for operators that associate to the left (TAIL RECURSIVE)*)
   389 fun foldl (f: 'a * 'b -> 'a) : 'a * 'b list -> 'a =
   390   let fun itl (e, [])  = e
   391         | itl (e, a::l) = itl (f(e, a), l)
   392   in  itl end;
   393 
   394 (*  (op @) ([x1, ..., xn], e)  ===>   x1 @ (x2 ... @ (xn @ e))
   395     for operators that associate to the right (not tail recursive)*)
   396 fun foldr f (l, e) =
   397   let fun itr [] = e
   398         | itr (a::l) = f(a, itr l)
   399   in  itr l  end;
   400 
   401 (*  (op @) [x1, ..., xn]  ===>   x1 @ (x2 ... @ (x[n-1] @ xn))
   402     for n > 0, operators that associate to the right (not tail recursive)*)
   403 fun foldr1 f [] = raise Empty
   404   | foldr1 f l =
   405       let fun itr [x] = x
   406             | itr (x::l) = f(x, itr l)
   407       in  itr l  end;
   408 
   409 fun foldl_map f =
   410   let
   411     fun fold_aux (x, []) = (x, [])
   412       | fold_aux (x, y :: ys) =
   413           let
   414             val (x', y') = f (x, y);
   415             val (x'', ys') = fold_aux (x', ys);
   416           in (x'', y' :: ys') end;
   417   in fold_aux end;
   418 
   419 
   420 (* basic list functions *)
   421 
   422 fun eq_list eq (list1, list2) =
   423   let
   424     fun eq_lst (x :: xs, y :: ys) = eq (x, y) andalso eq_lst (xs, ys)
   425       | eq_lst _ = true;
   426   in length list1 = length list2 andalso eq_lst (list1, list2) end;
   427 
   428 fun maps f [] = []
   429   | maps f (x :: xs) = f x @ maps f xs;
   430 
   431 fun chop (0: int) xs = ([], xs)
   432   | chop _ [] = ([], [])
   433   | chop n (x :: xs) = chop (n - 1) xs |>> cons x;
   434 
   435 (*take the first n elements from a list*)
   436 fun take (n: int, []) = []
   437   | take (n, x :: xs) =
   438       if n > 0 then x :: take (n - 1, xs) else [];
   439 
   440 (*drop the first n elements from a list*)
   441 fun drop (n: int, []) = []
   442   | drop (n, x :: xs) =
   443       if n > 0 then drop (n - 1, xs) else x :: xs;
   444 
   445 fun dropwhile P [] = []
   446   | dropwhile P (ys as x::xs) = if P x then dropwhile P xs else ys;
   447 
   448 (*return nth element of a list, where 0 designates the first element;
   449   raise Subscript if list too short*)
   450 fun nth xs i = List.nth (xs, i);
   451 
   452 fun nth_list xss i = nth xss i handle Subscript => [];
   453 
   454 fun nth_map 0 f (x :: xs) = f x :: xs
   455   | nth_map n f (x :: xs) = x :: nth_map (n - 1) f xs
   456   | nth_map (_: int) _ [] = raise Subscript;
   457 
   458 fun nth_drop n xs =
   459   List.take (xs, n) @ List.drop (xs, n + 1);
   460 
   461 fun map_index f =
   462   let
   463     fun mapp (_: int) [] = []
   464       | mapp i (x :: xs) = f (i, x) :: mapp (i + 1) xs
   465   in mapp 0 end;
   466 
   467 fun fold_index f =
   468   let
   469     fun fold_aux (_: int) [] y = y
   470       | fold_aux i (x :: xs) y = fold_aux (i + 1) xs (f (i, x) y);
   471   in fold_aux 0 end;
   472 
   473 val last_elem = List.last;
   474 
   475 (*rear decomposition*)
   476 fun split_last [] = raise Empty
   477   | split_last [x] = ([], x)
   478   | split_last (x :: xs) = apfst (cons x) (split_last xs);
   479 
   480 (*find the position of an element in a list*)
   481 fun find_index pred =
   482   let fun find (_: int) [] = ~1
   483         | find n (x :: xs) = if pred x then n else find (n + 1) xs;
   484   in find 0 end;
   485 
   486 fun find_index_eq x = find_index (equal x);
   487 
   488 (*find first element satisfying predicate*)
   489 val find_first = List.find;
   490 
   491 (*get first element by lookup function*)
   492 fun get_first _ [] = NONE
   493   | get_first f (x :: xs) =
   494       (case f x of
   495         NONE => get_first f xs
   496       | some => some);
   497 
   498 fun get_index f =
   499   let
   500     fun get (_: int) [] = NONE
   501       | get i (x :: xs) =
   502           case f x
   503            of NONE => get (i + 1) xs
   504             | SOME y => SOME (i, y)
   505   in get 0 end;
   506 
   507 val flat = List.concat;
   508 
   509 fun unflat (xs :: xss) ys =
   510       let val (ps, qs) = chop (length xs) ys
   511       in ps :: unflat xss qs end
   512   | unflat [] [] = []
   513   | unflat _ _ = raise UnequalLengths;
   514 
   515 fun burrow f xss = unflat xss (f (flat xss));
   516 
   517 fun burrow_options f os = map (try hd) (burrow f (map the_list os));
   518 
   519 fun fold_burrow f xss s =
   520   apfst (unflat xss) (f (flat xss) s);
   521 
   522 (*separate s [x1, x2, ..., xn]  ===>  [x1, s, x2, s, ..., s, xn]*)
   523 fun separate s (x :: (xs as _ :: _)) = x :: s :: separate s xs
   524   | separate _ xs = xs;
   525 
   526 (*make the list [x, x, ..., x] of length n*)
   527 fun replicate (n: int) x =
   528   let fun rep (0, xs) = xs
   529         | rep (n, xs) = rep (n - 1, x :: xs)
   530   in
   531     if n < 0 then raise Subscript
   532     else rep (n, [])
   533   end;
   534 
   535 fun translate_string f = String.translate (f o String.str);
   536 
   537 (*multiply [a, b, c, ...] * [xs, ys, zs, ...]*)
   538 fun multiply [] _ = []
   539   | multiply (x :: xs) yss = map (cons x) yss @ multiply xs yss;
   540 
   541 (*direct product*)
   542 fun product _ [] = []
   543   | product [] _ = []
   544   | product (x :: xs) ys = map (pair x) ys @ product xs ys;
   545 
   546 
   547 (* filter *)
   548 
   549 (*copy the list preserving elements that satisfy the predicate*)
   550 val filter = List.filter;
   551 fun filter_out f = filter (not o f);
   552 val map_filter = List.mapPartial;
   553 
   554 
   555 (* lists of pairs *)
   556 
   557 exception UnequalLengths;
   558 
   559 fun map2 _ [] [] = []
   560   | map2 f (x :: xs) (y :: ys) = f x y :: map2 f xs ys
   561   | map2 _ _ _ = raise UnequalLengths;
   562 
   563 fun fold2 f [] [] z = z
   564   | fold2 f (x :: xs) (y :: ys) z = fold2 f xs ys (f x y z)
   565   | fold2 f _ _ _ = raise UnequalLengths;
   566 
   567 fun zip_options (x :: xs) (SOME y :: ys) = (x, y) :: zip_options xs ys
   568   | zip_options (_ :: xs) (NONE :: ys) = zip_options xs ys
   569   | zip_options _ [] = []
   570   | zip_options [] _ = raise UnequalLengths;
   571 
   572 (*combine two lists forming a list of pairs:
   573   [x1, ..., xn] ~~ [y1, ..., yn]  ===>  [(x1, y1), ..., (xn, yn)]*)
   574 fun [] ~~ [] = []
   575   | (x :: xs) ~~ (y :: ys) = (x, y) :: (xs ~~ ys)
   576   | _ ~~ _ = raise UnequalLengths;
   577 
   578 (*inverse of ~~; the old 'split':
   579   [(x1, y1), ..., (xn, yn)]  ===>  ([x1, ..., xn], [y1, ..., yn])*)
   580 val split_list = ListPair.unzip;
   581 
   582 
   583 (* prefixes, suffixes *)
   584 
   585 fun is_prefix _ [] _ = true
   586   | is_prefix eq (x :: xs) (y :: ys) = eq (x, y) andalso is_prefix eq xs ys
   587   | is_prefix eq _ _ = false;
   588 
   589 (* [x1, ..., xi, ..., xn]  --->  ([x1, ..., x(i-1)], [xi, ..., xn])
   590    where xi is the first element that does not satisfy the predicate*)
   591 fun take_prefix (pred : 'a -> bool)  (xs: 'a list) : 'a list * 'a list =
   592   let fun take (rxs, []) = (rev rxs, [])
   593         | take (rxs, x :: xs) =
   594             if  pred x  then  take(x :: rxs, xs)  else  (rev rxs, x :: xs)
   595   in  take([], xs)  end;
   596 
   597 fun chop_prefix eq ([], ys) = ([], ([], ys))
   598   | chop_prefix eq (xs, []) = ([], (xs, []))
   599   | chop_prefix eq (xs as x :: xs', ys as y :: ys') =
   600       if eq (x, y) then
   601         let val (ps', xys'') = chop_prefix eq (xs', ys')
   602         in (x :: ps', xys'') end
   603       else ([], (xs, ys));
   604 
   605 (* [x1, ..., xi, ..., xn]  --->  ([x1, ..., xi], [x(i+1), ..., xn])
   606    where xi is the last element that does not satisfy the predicate*)
   607 fun take_suffix _ [] = ([], [])
   608   | take_suffix pred (x :: xs) =
   609       (case take_suffix pred xs of
   610         ([], sffx) => if pred x then ([], x :: sffx) else ([x], sffx)
   611       | (prfx, sffx) => (x :: prfx, sffx));
   612 
   613 fun prefixes1 [] = []
   614   | prefixes1 (x :: xs) = map (cons x) ([] :: prefixes1 xs);
   615 
   616 fun prefixes xs = [] :: prefixes1 xs;
   617 
   618 fun suffixes1 xs = map rev (prefixes1 (rev xs));
   619 fun suffixes xs = [] :: suffixes1 xs;
   620 
   621 
   622 
   623 (** integers **)
   624 
   625 fun inc i = (i := ! i + (1: int); ! i);
   626 fun dec i = (i := ! i - (1: int); ! i);
   627 
   628 
   629 (* lists of integers *)
   630 
   631 (*make the list [from, from + 1, ..., to]*)
   632 fun ((i: int) upto j) =
   633   if i > j then [] else i :: (i + 1 upto j);
   634 
   635 (*make the list [from, from - 1, ..., to]*)
   636 fun ((i: int) downto j) =
   637   if i < j then [] else i :: (i - 1 downto j);
   638 
   639 
   640 (* convert integers to strings *)
   641 
   642 (*expand the number in the given base;
   643   example: radixpand (2, 8) gives [1, 0, 0, 0]*)
   644 fun radixpand (base, num) : int list =
   645   let
   646     fun radix (n, tail) =
   647       if n < base then n :: tail
   648       else radix (n div base, (n mod base) :: tail)
   649   in radix (num, []) end;
   650 
   651 (*expands a number into a string of characters starting from "zerochar";
   652   example: radixstring (2, "0", 8) gives "1000"*)
   653 fun radixstring (base, zerochar, num) =
   654   let val offset = ord zerochar;
   655       fun chrof n = chr (offset + n)
   656   in implode (map chrof (radixpand (base, num))) end;
   657 
   658 
   659 val string_of_int = Int.toString;
   660 
   661 fun signed_string_of_int i =
   662   if i < 0 then "-" ^ string_of_int (~ i) else string_of_int i;
   663 
   664 fun string_of_indexname (a, 0) = a
   665   | string_of_indexname (a, i) = a ^ "_" ^ string_of_int i;
   666 
   667 
   668 (* read integers *)
   669 
   670 fun read_radix_int radix cs =
   671   let
   672     val zero = ord "0";
   673     val limit = zero + radix;
   674     fun scan (num, []) = (num, [])
   675       | scan (num, c :: cs) =
   676         if zero <= ord c andalso ord c < limit then
   677           scan (radix * num + (ord c - zero), cs)
   678         else (num, c :: cs);
   679   in scan (0, cs) end;
   680 
   681 val read_int = read_radix_int 10;
   682 
   683 fun oct_char s = chr (#1 (read_radix_int 8 (explode s)));
   684 
   685 
   686 
   687 (** strings **)
   688 
   689 (* functions tuned for strings, avoiding explode *)
   690 
   691 fun nth_string str i =
   692   (case try String.substring (str, i, 1) of
   693     SOME s => s
   694   | NONE => raise Subscript);
   695 
   696 fun fold_string f str x0 =
   697   let
   698     val n = size str;
   699     fun iter (x, i) =
   700       if i < n then iter (f (String.substring (str, i, 1)) x, i + 1) else x;
   701   in iter (x0, 0) end;
   702 
   703 fun exists_string pred str =
   704   let
   705     val n = size str;
   706     fun ex i = i < n andalso (pred (String.substring (str, i, 1)) orelse ex (i + 1));
   707   in ex 0 end;
   708 
   709 fun forall_string pred = not o exists_string (not o pred);
   710 
   711 (*enclose in brackets*)
   712 fun enclose lpar rpar str = lpar ^ str ^ rpar;
   713 fun unenclose str = String.substring (str, 1, size str - 2);
   714 
   715 (*simple quoting (does not escape special chars)*)
   716 val quote = enclose "\"" "\"";
   717 
   718 (*space_implode "..." (explode "hello") = "h...e...l...l...o"*)
   719 fun space_implode a bs = implode (separate a bs);
   720 
   721 val commas = space_implode ", ";
   722 val commas_quote = commas o map quote;
   723 
   724 (*concatenate messages, one per line, into a string*)
   725 val cat_lines = space_implode "\n";
   726 
   727 (*space_explode "." "h.e..l.lo" = ["h", "e", "", "l", "lo"]*)
   728 fun space_explode _ "" = []
   729   | space_explode sep s = String.fields (fn c => str c = sep) s;
   730 
   731 val split_lines = space_explode "\n";
   732 
   733 fun prefix_lines "" txt = txt
   734   | prefix_lines prfx txt = txt |> split_lines |> map (fn s => prfx ^ s) |> cat_lines;
   735 
   736 fun untabify chs =
   737   let
   738     val tab_width = 8;
   739 
   740     fun untab pos [] ys = rev ys
   741       | untab pos ("\n" :: xs) ys = untab 0 xs ("\n" :: ys)
   742       | untab pos ("\t" :: xs) ys =
   743           let val d = tab_width - (pos mod tab_width)
   744           in untab (pos + d) xs (funpow d (cons " ") ys) end
   745       | untab pos (c :: xs) ys = untab (pos + 1) xs (c :: ys);
   746   in
   747     if not (exists (fn c => c = "\t") chs) then chs
   748     else untab 0 chs []
   749   end;
   750 
   751 fun prefix prfx s = prfx ^ s;
   752 fun suffix sffx s = s ^ sffx;
   753 
   754 fun unprefix prfx s =
   755   if String.isPrefix prfx s then String.substring (s, size prfx, size s - size prfx)
   756   else raise Fail "unprefix";
   757 
   758 fun unsuffix sffx s =
   759   if String.isSuffix sffx s then String.substring (s, 0, size s - size sffx)
   760   else raise Fail "unsuffix";
   761 
   762 fun replicate_string (0: int) _ = ""
   763   | replicate_string 1 a = a
   764   | replicate_string k a =
   765       if k mod 2 = 0 then replicate_string (k div 2) (a ^ a)
   766       else replicate_string (k div 2) (a ^ a) ^ a;
   767 
   768 
   769 
   770 (** lists as sets -- see also Pure/General/ord_list.ML **)
   771 
   772 (*canonical member, insert, remove*)
   773 fun member eq list x =
   774   let
   775     fun memb [] = false
   776       | memb (y :: ys) = eq (x, y) orelse memb ys;
   777   in memb list end;
   778 
   779 fun insert eq x xs = if member eq xs x then xs else x :: xs;
   780 fun remove eq x xs = if member eq xs x then filter_out (fn y => eq (x, y)) xs else xs;
   781 fun update eq x xs = cons x (remove eq x xs);
   782 
   783 fun subtract eq = fold (remove eq);
   784 
   785 fun merge _ ([], ys) = ys
   786   | merge eq (xs, ys) = fold_rev (insert eq) ys xs;
   787 
   788 (*old-style infixes*)
   789 fun x mem xs = member (op =) xs x;
   790 fun (x: int) mem_int xs = member (op =) xs x;
   791 fun (x: string) mem_string xs = member (op =) xs x;
   792 
   793 
   794 (*union of sets represented as lists: no repetitions*)
   795 fun xs union [] = xs
   796   | [] union ys = ys
   797   | (x :: xs) union ys = xs union (insert (op =) x ys);
   798 
   799 (*union of sets, optimized version for ints*)
   800 fun (xs:int list) union_int [] = xs
   801   | [] union_int ys = ys
   802   | (x :: xs) union_int ys = xs union_int (insert (op =) x ys);
   803 
   804 (*union of sets, optimized version for strings*)
   805 fun (xs:string list) union_string [] = xs
   806   | [] union_string ys = ys
   807   | (x :: xs) union_string ys = xs union_string (insert (op =) x ys);
   808 
   809 (*generalized union*)
   810 fun gen_union eq (xs, []) = xs
   811   | gen_union eq ([], ys) = ys
   812   | gen_union eq (x :: xs, ys) = gen_union eq (xs, insert eq x ys);
   813 
   814 
   815 (*intersection*)
   816 fun [] inter ys = []
   817   | (x :: xs) inter ys =
   818       if x mem ys then x :: (xs inter ys) else xs inter ys;
   819 
   820 (*intersection, optimized version for ints*)
   821 fun ([]:int list) inter_int ys = []
   822   | (x :: xs) inter_int ys =
   823       if x mem_int ys then x :: (xs inter_int ys) else xs inter_int ys;
   824 
   825 (*intersection, optimized version for strings *)
   826 fun ([]:string list) inter_string ys = []
   827   | (x :: xs) inter_string ys =
   828       if x mem_string ys then x :: (xs inter_string ys) else xs inter_string ys;
   829 
   830 (*generalized intersection*)
   831 fun gen_inter eq ([], ys) = []
   832   | gen_inter eq (x::xs, ys) =
   833       if member eq ys x then x :: gen_inter eq (xs, ys)
   834       else gen_inter eq (xs, ys);
   835 
   836 
   837 (*subset*)
   838 fun [] subset ys = true
   839   | (x :: xs) subset ys = x mem ys andalso xs subset ys;
   840 
   841 (*subset, optimized version for ints*)
   842 fun ([]: int list) subset_int ys = true
   843   | (x :: xs) subset_int ys = x mem_int ys andalso xs subset_int ys;
   844 
   845 (*subset, optimized version for strings*)
   846 fun ([]: string list) subset_string ys = true
   847   | (x :: xs) subset_string ys = x mem_string ys andalso xs subset_string ys;
   848 
   849 (*set equality*)
   850 fun eq_set (xs, ys) =
   851   xs = ys orelse (xs subset ys andalso ys subset xs);
   852 
   853 (*set equality for strings*)
   854 fun eq_set_string ((xs: string list), ys) =
   855   xs = ys orelse (xs subset_string ys andalso ys subset_string xs);
   856 
   857 fun gen_subset eq (xs, ys) = forall (member eq ys) xs;
   858 
   859 fun gen_eq_set eq (xs, ys) =
   860   eq_list eq (xs, ys) orelse
   861     (gen_subset eq (xs, ys) andalso gen_subset (eq o swap) (ys, xs));
   862 
   863 
   864 (*removing an element from a list WITHOUT duplicates*)
   865 fun (y :: ys) \ x = if x = y then ys else y :: (ys \ x)
   866   | [] \ x = [];
   867 fun ys \\ xs = foldl (op \) (ys,xs);
   868 
   869 
   870 (*makes a list of the distinct members of the input; preserves order, takes
   871   first of equal elements*)
   872 fun distinct eq lst =
   873   let
   874     fun dist (rev_seen, []) = rev rev_seen
   875       | dist (rev_seen, x :: xs) =
   876           if member eq rev_seen x then dist (rev_seen, xs)
   877           else dist (x :: rev_seen, xs);
   878   in dist ([], lst) end;
   879 
   880 (*returns a list containing all repeated elements exactly once; preserves
   881   order, takes first of equal elements*)
   882 fun duplicates eq lst =
   883   let
   884     fun dups (rev_dups, []) = rev rev_dups
   885       | dups (rev_dups, x :: xs) =
   886           if member eq rev_dups x orelse not (member eq xs x) then
   887             dups (rev_dups, xs)
   888           else dups (x :: rev_dups, xs);
   889   in dups ([], lst) end;
   890 
   891 fun has_duplicates eq =
   892   let
   893     fun dups [] = false
   894       | dups (x :: xs) = member eq xs x orelse dups xs;
   895   in dups end;
   896 
   897 
   898 
   899 (** lists as multisets **)
   900 
   901 fun remove1 _ _ [] = raise Empty
   902   | remove1 eq y (x::xs) = if eq (y, x) then xs else x :: remove1 eq y xs;
   903 
   904 fun submultiset _ ([], _)  = true
   905   | submultiset eq (x :: xs, ys) = member eq ys x andalso submultiset eq (xs, remove1 eq x ys);
   906 
   907 
   908 
   909 (** orders **)
   910 
   911 fun is_equal EQUAL = true
   912   | is_equal _ = false;
   913 
   914 fun rev_order LESS = GREATER
   915   | rev_order EQUAL = EQUAL
   916   | rev_order GREATER = LESS;
   917 
   918 (*assume rel is a linear strict order*)
   919 fun make_ord rel (x, y) =
   920   if rel (x, y) then LESS
   921   else if rel (y, x) then GREATER
   922   else EQUAL;
   923 
   924 val int_ord = Int.compare;
   925 val string_ord = String.compare;
   926 
   927 fun fast_string_ord (s1, s2) =
   928   (case int_ord (size s1, size s2) of EQUAL => string_ord (s1, s2) | ord => ord);
   929 
   930 fun option_ord ord (SOME x, SOME y) = ord (x, y)
   931   | option_ord _ (NONE, NONE) = EQUAL
   932   | option_ord _ (NONE, SOME _) = LESS
   933   | option_ord _ (SOME _, NONE) = GREATER;
   934 
   935 (*lexicographic product*)
   936 fun prod_ord a_ord b_ord ((x, y), (x', y')) =
   937   (case a_ord (x, x') of EQUAL => b_ord (y, y') | ord => ord);
   938 
   939 (*dictionary order -- in general NOT well-founded!*)
   940 fun dict_ord elem_ord (x :: xs, y :: ys) =
   941       (case elem_ord (x, y) of EQUAL => dict_ord elem_ord (xs, ys) | ord => ord)
   942   | dict_ord _ ([], []) = EQUAL
   943   | dict_ord _ ([], _ :: _) = LESS
   944   | dict_ord _ (_ :: _, []) = GREATER;
   945 
   946 (*lexicographic product of lists*)
   947 fun list_ord elem_ord (xs, ys) =
   948   (case int_ord (length xs, length ys) of EQUAL => dict_ord elem_ord (xs, ys) | ord => ord);
   949 
   950 
   951 (* sorting *)
   952 
   953 (*quicksort -- stable, i.e. does not reorder equal elements*)
   954 fun quicksort unique ord =
   955   let
   956     fun qsort [] = []
   957       | qsort (xs as [_]) = xs
   958       | qsort (xs as [x, y]) =
   959           (case ord (x, y) of
   960             LESS => xs
   961           | EQUAL => if unique then [x] else xs
   962           | GREATER => [y, x])
   963       | qsort xs =
   964           let val (lts, eqs, gts) = part (nth xs (length xs div 2)) xs
   965           in qsort lts @ eqs @ qsort gts end
   966     and part _ [] = ([], [], [])
   967       | part pivot (x :: xs) = add (ord (x, pivot)) x (part pivot xs)
   968     and add LESS x (lts, eqs, gts) = (x :: lts, eqs, gts)
   969       | add EQUAL x (lts, [], gts) = (lts, [x], gts)
   970       | add EQUAL x (res as (lts, eqs, gts)) = if unique then res else (lts, x :: eqs, gts)
   971       | add GREATER x (lts, eqs, gts) = (lts, eqs, x :: gts);
   972   in qsort end;
   973 
   974 fun sort ord = quicksort false ord;
   975 fun sort_distinct ord = quicksort true ord;
   976 
   977 val sort_strings = sort string_ord;
   978 fun sort_wrt sel xs = sort (string_ord o pairself sel) xs;
   979 
   980 
   981 
   982 (** random numbers **)
   983 
   984 exception RANDOM;
   985 
   986 fun rmod x y = x - y * Real.realFloor (x / y);
   987 
   988 local
   989   val a = 16807.0;
   990   val m = 2147483647.0;
   991   val random_seed = ref 1.0;
   992 in
   993 
   994 fun random () = CRITICAL (fn () =>
   995   let val r = rmod (a * ! random_seed) m
   996   in (random_seed := r; r) end);
   997 
   998 end;
   999 
  1000 fun random_range l h =
  1001   if h < l orelse l < 0 then raise RANDOM
  1002   else l + Real.floor (rmod (random ()) (real (h - l + 1)));
  1003 
  1004 fun one_of xs = nth xs (random_range 0 (length xs - 1));
  1005 
  1006 fun frequency xs =
  1007   let
  1008     val sum = foldl op + (0, map fst xs);
  1009     fun pick n ((k: int, x) :: xs) =
  1010       if n <= k then x else pick (n - k) xs
  1011   in pick (random_range 1 sum) xs end;
  1012 
  1013 
  1014 
  1015 (** misc **)
  1016 
  1017 fun divide_and_conquer decomp x =
  1018   let val (ys, recomb) = decomp x
  1019   in recomb (map (divide_and_conquer decomp) ys) end;
  1020 
  1021 
  1022 (*Partition a list into buckets  [ bi, b(i+1), ..., bj ]
  1023    putting x in bk if p(k)(x) holds.  Preserve order of elements if possible.*)
  1024 fun partition_list p i j =
  1025   let fun part k xs =
  1026             if k>j then
  1027               (case xs of [] => []
  1028                          | _ => raise Fail "partition_list")
  1029             else
  1030             let val (ns, rest) = List.partition (p k) xs;
  1031             in  ns :: part(k+1)rest  end
  1032   in  part (i: int) end;
  1033 
  1034 fun partition_eq (eq:'a * 'a -> bool) =
  1035   let
  1036     fun part [] = []
  1037       | part (x :: ys) =
  1038           let val (xs, xs') = List.partition (fn y => eq (x, y)) ys
  1039           in (x::xs)::(part xs') end
  1040   in part end;
  1041 
  1042 
  1043 
  1044 (* generating identifiers *)
  1045 
  1046 (** Freshly generated identifiers; supplied prefix MUST start with a letter **)
  1047 local
  1048 (*Maps 0-61 to A-Z, a-z, 0-9; exclude _ or ' to avoid clash with internal/unusual indentifiers*)
  1049 fun gensym_char i =
  1050   if i<26 then chr (ord "A" + i)
  1051   else if i<52 then chr (ord "a" + i - 26)
  1052   else chr (ord "0" + i - 52);
  1053 
  1054 val char_vec = Vector.tabulate (62, gensym_char);
  1055 fun newid n = implode (map (fn i => Vector.sub (char_vec, i)) (radixpand (62, n)));
  1056 
  1057 val gensym_seed = ref (0: int);
  1058 
  1059 in
  1060   fun gensym pre = pre ^ newid (NAMED_CRITICAL "gensym" (fn () => inc gensym_seed));
  1061 end;
  1062 
  1063 
  1064 (* stamps and serial numbers *)
  1065 
  1066 type stamp = unit ref;
  1067 val stamp: unit -> stamp = ref;
  1068 
  1069 type serial = int;
  1070 local val count = ref (0: int)
  1071 in fun serial () = NAMED_CRITICAL "serial" (fn () => inc count) end;
  1072 
  1073 val serial_string = string_of_int o serial;
  1074 
  1075 
  1076 (* generic objects *)
  1077 
  1078 (*note that the builtin exception datatype may be extended by new
  1079   constructors at any time*)
  1080 structure Object = struct type T = exn end;
  1081 
  1082 end;
  1083 
  1084 structure BasicLibrary: BASIC_LIBRARY = Library;
  1085 open BasicLibrary;