src/HOL/Topological_Spaces.thy
author hoelzl
Tue Jan 27 16:12:40 2015 +0100 (2015-01-27)
changeset 59452 2538b2c51769
parent 59106 af691e67f71f
child 59582 0fbed69ff081
permissions -rw-r--r--
ereal: tuned proofs concerning continuity and suprema
     1 (*  Title:      HOL/Topological_Spaces.thy
     2     Author:     Brian Huffman
     3     Author:     Johannes Hölzl
     4 *)
     5 
     6 section {* Topological Spaces *}
     7 
     8 theory Topological_Spaces
     9 imports Main Conditionally_Complete_Lattices
    10 begin
    11 
    12 named_theorems continuous_intros "structural introduction rules for continuity"
    13 
    14 
    15 subsection {* Topological space *}
    16 
    17 class "open" =
    18   fixes "open" :: "'a set \<Rightarrow> bool"
    19 
    20 class topological_space = "open" +
    21   assumes open_UNIV [simp, intro]: "open UNIV"
    22   assumes open_Int [intro]: "open S \<Longrightarrow> open T \<Longrightarrow> open (S \<inter> T)"
    23   assumes open_Union [intro]: "\<forall>S\<in>K. open S \<Longrightarrow> open (\<Union> K)"
    24 begin
    25 
    26 definition
    27   closed :: "'a set \<Rightarrow> bool" where
    28   "closed S \<longleftrightarrow> open (- S)"
    29 
    30 lemma open_empty [continuous_intros, intro, simp]: "open {}"
    31   using open_Union [of "{}"] by simp
    32 
    33 lemma open_Un [continuous_intros, intro]: "open S \<Longrightarrow> open T \<Longrightarrow> open (S \<union> T)"
    34   using open_Union [of "{S, T}"] by simp
    35 
    36 lemma open_UN [continuous_intros, intro]: "\<forall>x\<in>A. open (B x) \<Longrightarrow> open (\<Union>x\<in>A. B x)"
    37   using open_Union [of "B ` A"] by simp
    38 
    39 lemma open_Inter [continuous_intros, intro]: "finite S \<Longrightarrow> \<forall>T\<in>S. open T \<Longrightarrow> open (\<Inter>S)"
    40   by (induct set: finite) auto
    41 
    42 lemma open_INT [continuous_intros, intro]: "finite A \<Longrightarrow> \<forall>x\<in>A. open (B x) \<Longrightarrow> open (\<Inter>x\<in>A. B x)"
    43   using open_Inter [of "B ` A"] by simp
    44 
    45 lemma openI:
    46   assumes "\<And>x. x \<in> S \<Longrightarrow> \<exists>T. open T \<and> x \<in> T \<and> T \<subseteq> S"
    47   shows "open S"
    48 proof -
    49   have "open (\<Union>{T. open T \<and> T \<subseteq> S})" by auto
    50   moreover have "\<Union>{T. open T \<and> T \<subseteq> S} = S" by (auto dest!: assms)
    51   ultimately show "open S" by simp
    52 qed
    53 
    54 lemma closed_empty [continuous_intros, intro, simp]:  "closed {}"
    55   unfolding closed_def by simp
    56 
    57 lemma closed_Un [continuous_intros, intro]: "closed S \<Longrightarrow> closed T \<Longrightarrow> closed (S \<union> T)"
    58   unfolding closed_def by auto
    59 
    60 lemma closed_UNIV [continuous_intros, intro, simp]: "closed UNIV"
    61   unfolding closed_def by simp
    62 
    63 lemma closed_Int [continuous_intros, intro]: "closed S \<Longrightarrow> closed T \<Longrightarrow> closed (S \<inter> T)"
    64   unfolding closed_def by auto
    65 
    66 lemma closed_INT [continuous_intros, intro]: "\<forall>x\<in>A. closed (B x) \<Longrightarrow> closed (\<Inter>x\<in>A. B x)"
    67   unfolding closed_def by auto
    68 
    69 lemma closed_Inter [continuous_intros, intro]: "\<forall>S\<in>K. closed S \<Longrightarrow> closed (\<Inter> K)"
    70   unfolding closed_def uminus_Inf by auto
    71 
    72 lemma closed_Union [continuous_intros, intro]: "finite S \<Longrightarrow> \<forall>T\<in>S. closed T \<Longrightarrow> closed (\<Union>S)"
    73   by (induct set: finite) auto
    74 
    75 lemma closed_UN [continuous_intros, intro]: "finite A \<Longrightarrow> \<forall>x\<in>A. closed (B x) \<Longrightarrow> closed (\<Union>x\<in>A. B x)"
    76   using closed_Union [of "B ` A"] by simp
    77 
    78 lemma open_closed: "open S \<longleftrightarrow> closed (- S)"
    79   unfolding closed_def by simp
    80 
    81 lemma closed_open: "closed S \<longleftrightarrow> open (- S)"
    82   unfolding closed_def by simp
    83 
    84 lemma open_Diff [continuous_intros, intro]: "open S \<Longrightarrow> closed T \<Longrightarrow> open (S - T)"
    85   unfolding closed_open Diff_eq by (rule open_Int)
    86 
    87 lemma closed_Diff [continuous_intros, intro]: "closed S \<Longrightarrow> open T \<Longrightarrow> closed (S - T)"
    88   unfolding open_closed Diff_eq by (rule closed_Int)
    89 
    90 lemma open_Compl [continuous_intros, intro]: "closed S \<Longrightarrow> open (- S)"
    91   unfolding closed_open .
    92 
    93 lemma closed_Compl [continuous_intros, intro]: "open S \<Longrightarrow> closed (- S)"
    94   unfolding open_closed .
    95 
    96 lemma open_Collect_neg: "closed {x. P x} \<Longrightarrow> open {x. \<not> P x}"
    97   unfolding Collect_neg_eq by (rule open_Compl)
    98 
    99 lemma open_Collect_conj: assumes "open {x. P x}" "open {x. Q x}" shows "open {x. P x \<and> Q x}"
   100   using open_Int[OF assms] by (simp add: Int_def)
   101 
   102 lemma open_Collect_disj: assumes "open {x. P x}" "open {x. Q x}" shows "open {x. P x \<or> Q x}"
   103   using open_Un[OF assms] by (simp add: Un_def)
   104 
   105 lemma open_Collect_ex: "(\<And>i. open {x. P i x}) \<Longrightarrow> open {x. \<exists>i. P i x}"
   106   using open_UN[of UNIV "\<lambda>i. {x. P i x}"] unfolding Collect_ex_eq by simp 
   107 
   108 lemma open_Collect_imp: "closed {x. P x} \<Longrightarrow> open {x. Q x} \<Longrightarrow> open {x. P x \<longrightarrow> Q x}"
   109   unfolding imp_conv_disj by (intro open_Collect_disj open_Collect_neg)
   110 
   111 lemma open_Collect_const: "open {x. P}"
   112   by (cases P) auto
   113 
   114 lemma closed_Collect_neg: "open {x. P x} \<Longrightarrow> closed {x. \<not> P x}"
   115   unfolding Collect_neg_eq by (rule closed_Compl)
   116 
   117 lemma closed_Collect_conj: assumes "closed {x. P x}" "closed {x. Q x}" shows "closed {x. P x \<and> Q x}"
   118   using closed_Int[OF assms] by (simp add: Int_def)
   119 
   120 lemma closed_Collect_disj: assumes "closed {x. P x}" "closed {x. Q x}" shows "closed {x. P x \<or> Q x}"
   121   using closed_Un[OF assms] by (simp add: Un_def)
   122 
   123 lemma closed_Collect_all: "(\<And>i. closed {x. P i x}) \<Longrightarrow> closed {x. \<forall>i. P i x}"
   124   using closed_INT[of UNIV "\<lambda>i. {x. P i x}"] unfolding Collect_all_eq by simp 
   125 
   126 lemma closed_Collect_imp: "open {x. P x} \<Longrightarrow> closed {x. Q x} \<Longrightarrow> closed {x. P x \<longrightarrow> Q x}"
   127   unfolding imp_conv_disj by (intro closed_Collect_disj closed_Collect_neg)
   128 
   129 lemma closed_Collect_const: "closed {x. P}"
   130   by (cases P) auto
   131 
   132 end
   133 
   134 subsection{* Hausdorff and other separation properties *}
   135 
   136 class t0_space = topological_space +
   137   assumes t0_space: "x \<noteq> y \<Longrightarrow> \<exists>U. open U \<and> \<not> (x \<in> U \<longleftrightarrow> y \<in> U)"
   138 
   139 class t1_space = topological_space +
   140   assumes t1_space: "x \<noteq> y \<Longrightarrow> \<exists>U. open U \<and> x \<in> U \<and> y \<notin> U"
   141 
   142 instance t1_space \<subseteq> t0_space
   143 proof qed (fast dest: t1_space)
   144 
   145 lemma separation_t1:
   146   fixes x y :: "'a::t1_space"
   147   shows "x \<noteq> y \<longleftrightarrow> (\<exists>U. open U \<and> x \<in> U \<and> y \<notin> U)"
   148   using t1_space[of x y] by blast
   149 
   150 lemma closed_singleton:
   151   fixes a :: "'a::t1_space"
   152   shows "closed {a}"
   153 proof -
   154   let ?T = "\<Union>{S. open S \<and> a \<notin> S}"
   155   have "open ?T" by (simp add: open_Union)
   156   also have "?T = - {a}"
   157     by (simp add: set_eq_iff separation_t1, auto)
   158   finally show "closed {a}" unfolding closed_def .
   159 qed
   160 
   161 lemma closed_insert [continuous_intros, simp]:
   162   fixes a :: "'a::t1_space"
   163   assumes "closed S" shows "closed (insert a S)"
   164 proof -
   165   from closed_singleton assms
   166   have "closed ({a} \<union> S)" by (rule closed_Un)
   167   thus "closed (insert a S)" by simp
   168 qed
   169 
   170 lemma finite_imp_closed:
   171   fixes S :: "'a::t1_space set"
   172   shows "finite S \<Longrightarrow> closed S"
   173 by (induct set: finite, simp_all)
   174 
   175 text {* T2 spaces are also known as Hausdorff spaces. *}
   176 
   177 class t2_space = topological_space +
   178   assumes hausdorff: "x \<noteq> y \<Longrightarrow> \<exists>U V. open U \<and> open V \<and> x \<in> U \<and> y \<in> V \<and> U \<inter> V = {}"
   179 
   180 instance t2_space \<subseteq> t1_space
   181 proof qed (fast dest: hausdorff)
   182 
   183 lemma separation_t2:
   184   fixes x y :: "'a::t2_space"
   185   shows "x \<noteq> y \<longleftrightarrow> (\<exists>U V. open U \<and> open V \<and> x \<in> U \<and> y \<in> V \<and> U \<inter> V = {})"
   186   using hausdorff[of x y] by blast
   187 
   188 lemma separation_t0:
   189   fixes x y :: "'a::t0_space"
   190   shows "x \<noteq> y \<longleftrightarrow> (\<exists>U. open U \<and> ~(x\<in>U \<longleftrightarrow> y\<in>U))"
   191   using t0_space[of x y] by blast
   192 
   193 text {* A perfect space is a topological space with no isolated points. *}
   194 
   195 class perfect_space = topological_space +
   196   assumes not_open_singleton: "\<not> open {x}"
   197 
   198 
   199 subsection {* Generators for toplogies *}
   200 
   201 inductive generate_topology for S where
   202   UNIV: "generate_topology S UNIV"
   203 | Int: "generate_topology S a \<Longrightarrow> generate_topology S b \<Longrightarrow> generate_topology S (a \<inter> b)"
   204 | UN: "(\<And>k. k \<in> K \<Longrightarrow> generate_topology S k) \<Longrightarrow> generate_topology S (\<Union>K)"
   205 | Basis: "s \<in> S \<Longrightarrow> generate_topology S s"
   206 
   207 hide_fact (open) UNIV Int UN Basis 
   208 
   209 lemma generate_topology_Union: 
   210   "(\<And>k. k \<in> I \<Longrightarrow> generate_topology S (K k)) \<Longrightarrow> generate_topology S (\<Union>k\<in>I. K k)"
   211   using generate_topology.UN [of "K ` I"] by auto
   212 
   213 lemma topological_space_generate_topology:
   214   "class.topological_space (generate_topology S)"
   215   by default (auto intro: generate_topology.intros)
   216 
   217 subsection {* Order topologies *}
   218 
   219 class order_topology = order + "open" +
   220   assumes open_generated_order: "open = generate_topology (range (\<lambda>a. {..< a}) \<union> range (\<lambda>a. {a <..}))"
   221 begin
   222 
   223 subclass topological_space
   224   unfolding open_generated_order
   225   by (rule topological_space_generate_topology)
   226 
   227 lemma open_greaterThan [continuous_intros, simp]: "open {a <..}"
   228   unfolding open_generated_order by (auto intro: generate_topology.Basis)
   229 
   230 lemma open_lessThan [continuous_intros, simp]: "open {..< a}"
   231   unfolding open_generated_order by (auto intro: generate_topology.Basis)
   232 
   233 lemma open_greaterThanLessThan [continuous_intros, simp]: "open {a <..< b}"
   234    unfolding greaterThanLessThan_eq by (simp add: open_Int)
   235 
   236 end
   237 
   238 class linorder_topology = linorder + order_topology
   239 
   240 lemma closed_atMost [continuous_intros, simp]: "closed {.. a::'a::linorder_topology}"
   241   by (simp add: closed_open)
   242 
   243 lemma closed_atLeast [continuous_intros, simp]: "closed {a::'a::linorder_topology ..}"
   244   by (simp add: closed_open)
   245 
   246 lemma closed_atLeastAtMost [continuous_intros, simp]: "closed {a::'a::linorder_topology .. b}"
   247 proof -
   248   have "{a .. b} = {a ..} \<inter> {.. b}"
   249     by auto
   250   then show ?thesis
   251     by (simp add: closed_Int)
   252 qed
   253 
   254 lemma (in linorder) less_separate:
   255   assumes "x < y"
   256   shows "\<exists>a b. x \<in> {..< a} \<and> y \<in> {b <..} \<and> {..< a} \<inter> {b <..} = {}"
   257 proof (cases "\<exists>z. x < z \<and> z < y")
   258   case True
   259   then obtain z where "x < z \<and> z < y" ..
   260   then have "x \<in> {..< z} \<and> y \<in> {z <..} \<and> {z <..} \<inter> {..< z} = {}"
   261     by auto
   262   then show ?thesis by blast
   263 next
   264   case False
   265   with `x < y` have "x \<in> {..< y} \<and> y \<in> {x <..} \<and> {x <..} \<inter> {..< y} = {}"
   266     by auto
   267   then show ?thesis by blast
   268 qed
   269 
   270 instance linorder_topology \<subseteq> t2_space
   271 proof
   272   fix x y :: 'a
   273   from less_separate[of x y] less_separate[of y x]
   274   show "x \<noteq> y \<Longrightarrow> \<exists>U V. open U \<and> open V \<and> x \<in> U \<and> y \<in> V \<and> U \<inter> V = {}"
   275     by (elim neqE) (metis open_lessThan open_greaterThan Int_commute)+
   276 qed
   277 
   278 lemma (in linorder_topology) open_right:
   279   assumes "open S" "x \<in> S" and gt_ex: "x < y" shows "\<exists>b>x. {x ..< b} \<subseteq> S"
   280   using assms unfolding open_generated_order
   281 proof induction
   282   case (Int A B)
   283   then obtain a b where "a > x" "{x ..< a} \<subseteq> A"  "b > x" "{x ..< b} \<subseteq> B" by auto
   284   then show ?case by (auto intro!: exI[of _ "min a b"])
   285 next
   286   case (Basis S) then show ?case by (fastforce intro: exI[of _ y] gt_ex)
   287 qed blast+
   288 
   289 lemma (in linorder_topology) open_left:
   290   assumes "open S" "x \<in> S" and lt_ex: "y < x" shows "\<exists>b<x. {b <.. x} \<subseteq> S"
   291   using assms unfolding open_generated_order
   292 proof induction
   293   case (Int A B)
   294   then obtain a b where "a < x" "{a <.. x} \<subseteq> A"  "b < x" "{b <.. x} \<subseteq> B" by auto
   295   then show ?case by (auto intro!: exI[of _ "max a b"])
   296 next
   297   case (Basis S) then show ?case by (fastforce intro: exI[of _ y] lt_ex)
   298 qed blast+
   299 
   300 subsubsection {* Boolean is an order topology *}
   301 
   302 text {* It also is a discrete topology, but don't have a type class for it (yet). *}
   303 
   304 instantiation bool :: order_topology
   305 begin
   306 
   307 definition open_bool :: "bool set \<Rightarrow> bool" where
   308   "open_bool = generate_topology (range (\<lambda>a. {..< a}) \<union> range (\<lambda>a. {a <..}))"
   309 
   310 instance
   311   proof qed (rule open_bool_def)
   312 
   313 end
   314 
   315 lemma open_bool[simp, intro!]: "open (A::bool set)"
   316 proof -
   317   have *: "{False <..} = {True}" "{..< True} = {False}"
   318     by auto
   319   have "A = UNIV \<or> A = {} \<or> A = {False <..} \<or> A = {..< True}"
   320     using subset_UNIV[of A] unfolding UNIV_bool * by auto
   321   then show "open A"
   322     by auto
   323 qed
   324 
   325 subsection {* Filters *}
   326 
   327 text {*
   328   This definition also allows non-proper filters.
   329 *}
   330 
   331 locale is_filter =
   332   fixes F :: "('a \<Rightarrow> bool) \<Rightarrow> bool"
   333   assumes True: "F (\<lambda>x. True)"
   334   assumes conj: "F (\<lambda>x. P x) \<Longrightarrow> F (\<lambda>x. Q x) \<Longrightarrow> F (\<lambda>x. P x \<and> Q x)"
   335   assumes mono: "\<forall>x. P x \<longrightarrow> Q x \<Longrightarrow> F (\<lambda>x. P x) \<Longrightarrow> F (\<lambda>x. Q x)"
   336 
   337 typedef 'a filter = "{F :: ('a \<Rightarrow> bool) \<Rightarrow> bool. is_filter F}"
   338 proof
   339   show "(\<lambda>x. True) \<in> ?filter" by (auto intro: is_filter.intro)
   340 qed
   341 
   342 lemma is_filter_Rep_filter: "is_filter (Rep_filter F)"
   343   using Rep_filter [of F] by simp
   344 
   345 lemma Abs_filter_inverse':
   346   assumes "is_filter F" shows "Rep_filter (Abs_filter F) = F"
   347   using assms by (simp add: Abs_filter_inverse)
   348 
   349 
   350 subsubsection {* Eventually *}
   351 
   352 definition eventually :: "('a \<Rightarrow> bool) \<Rightarrow> 'a filter \<Rightarrow> bool"
   353   where "eventually P F \<longleftrightarrow> Rep_filter F P"
   354 
   355 lemma eventually_Abs_filter:
   356   assumes "is_filter F" shows "eventually P (Abs_filter F) = F P"
   357   unfolding eventually_def using assms by (simp add: Abs_filter_inverse)
   358 
   359 lemma filter_eq_iff:
   360   shows "F = F' \<longleftrightarrow> (\<forall>P. eventually P F = eventually P F')"
   361   unfolding Rep_filter_inject [symmetric] fun_eq_iff eventually_def ..
   362 
   363 lemma eventually_True [simp]: "eventually (\<lambda>x. True) F"
   364   unfolding eventually_def
   365   by (rule is_filter.True [OF is_filter_Rep_filter])
   366 
   367 lemma always_eventually: "\<forall>x. P x \<Longrightarrow> eventually P F"
   368 proof -
   369   assume "\<forall>x. P x" hence "P = (\<lambda>x. True)" by (simp add: ext)
   370   thus "eventually P F" by simp
   371 qed
   372 
   373 lemma eventually_mono:
   374   "(\<forall>x. P x \<longrightarrow> Q x) \<Longrightarrow> eventually P F \<Longrightarrow> eventually Q F"
   375   unfolding eventually_def
   376   by (rule is_filter.mono [OF is_filter_Rep_filter])
   377 
   378 lemma eventually_conj:
   379   assumes P: "eventually (\<lambda>x. P x) F"
   380   assumes Q: "eventually (\<lambda>x. Q x) F"
   381   shows "eventually (\<lambda>x. P x \<and> Q x) F"
   382   using assms unfolding eventually_def
   383   by (rule is_filter.conj [OF is_filter_Rep_filter])
   384 
   385 lemma eventually_Ball_finite:
   386   assumes "finite A" and "\<forall>y\<in>A. eventually (\<lambda>x. P x y) net"
   387   shows "eventually (\<lambda>x. \<forall>y\<in>A. P x y) net"
   388 using assms by (induct set: finite, simp, simp add: eventually_conj)
   389 
   390 lemma eventually_all_finite:
   391   fixes P :: "'a \<Rightarrow> 'b::finite \<Rightarrow> bool"
   392   assumes "\<And>y. eventually (\<lambda>x. P x y) net"
   393   shows "eventually (\<lambda>x. \<forall>y. P x y) net"
   394 using eventually_Ball_finite [of UNIV P] assms by simp
   395 
   396 lemma eventually_mp:
   397   assumes "eventually (\<lambda>x. P x \<longrightarrow> Q x) F"
   398   assumes "eventually (\<lambda>x. P x) F"
   399   shows "eventually (\<lambda>x. Q x) F"
   400 proof (rule eventually_mono)
   401   show "\<forall>x. (P x \<longrightarrow> Q x) \<and> P x \<longrightarrow> Q x" by simp
   402   show "eventually (\<lambda>x. (P x \<longrightarrow> Q x) \<and> P x) F"
   403     using assms by (rule eventually_conj)
   404 qed
   405 
   406 lemma eventually_rev_mp:
   407   assumes "eventually (\<lambda>x. P x) F"
   408   assumes "eventually (\<lambda>x. P x \<longrightarrow> Q x) F"
   409   shows "eventually (\<lambda>x. Q x) F"
   410 using assms(2) assms(1) by (rule eventually_mp)
   411 
   412 lemma eventually_conj_iff:
   413   "eventually (\<lambda>x. P x \<and> Q x) F \<longleftrightarrow> eventually P F \<and> eventually Q F"
   414   by (auto intro: eventually_conj elim: eventually_rev_mp)
   415 
   416 lemma eventually_elim1:
   417   assumes "eventually (\<lambda>i. P i) F"
   418   assumes "\<And>i. P i \<Longrightarrow> Q i"
   419   shows "eventually (\<lambda>i. Q i) F"
   420   using assms by (auto elim!: eventually_rev_mp)
   421 
   422 lemma eventually_elim2:
   423   assumes "eventually (\<lambda>i. P i) F"
   424   assumes "eventually (\<lambda>i. Q i) F"
   425   assumes "\<And>i. P i \<Longrightarrow> Q i \<Longrightarrow> R i"
   426   shows "eventually (\<lambda>i. R i) F"
   427   using assms by (auto elim!: eventually_rev_mp)
   428 
   429 lemma not_eventually_impI: "eventually P F \<Longrightarrow> \<not> eventually Q F \<Longrightarrow> \<not> eventually (\<lambda>x. P x \<longrightarrow> Q x) F"
   430   by (auto intro: eventually_mp)
   431 
   432 lemma not_eventuallyD: "\<not> eventually P F \<Longrightarrow> \<exists>x. \<not> P x"
   433   by (metis always_eventually)
   434 
   435 lemma eventually_subst:
   436   assumes "eventually (\<lambda>n. P n = Q n) F"
   437   shows "eventually P F = eventually Q F" (is "?L = ?R")
   438 proof -
   439   from assms have "eventually (\<lambda>x. P x \<longrightarrow> Q x) F"
   440       and "eventually (\<lambda>x. Q x \<longrightarrow> P x) F"
   441     by (auto elim: eventually_elim1)
   442   then show ?thesis by (auto elim: eventually_elim2)
   443 qed
   444 
   445 ML {*
   446   fun eventually_elim_tac ctxt thms = SUBGOAL_CASES (fn (_, _, st) =>
   447     let
   448       val thy = Proof_Context.theory_of ctxt
   449       val mp_thms = thms RL [@{thm eventually_rev_mp}]
   450       val raw_elim_thm =
   451         (@{thm allI} RS @{thm always_eventually})
   452         |> fold (fn thm1 => fn thm2 => thm2 RS thm1) mp_thms
   453         |> fold (fn _ => fn thm => @{thm impI} RS thm) thms
   454       val cases_prop = prop_of (raw_elim_thm RS st)
   455       val cases = (Rule_Cases.make_common (thy, cases_prop) [(("elim", []), [])])
   456     in
   457       CASES cases (rtac raw_elim_thm 1)
   458     end) 1
   459 *}
   460 
   461 method_setup eventually_elim = {*
   462   Scan.succeed (fn ctxt => METHOD_CASES (eventually_elim_tac ctxt))
   463 *} "elimination of eventually quantifiers"
   464 
   465 
   466 subsubsection {* Finer-than relation *}
   467 
   468 text {* @{term "F \<le> F'"} means that filter @{term F} is finer than
   469 filter @{term F'}. *}
   470 
   471 instantiation filter :: (type) complete_lattice
   472 begin
   473 
   474 definition le_filter_def:
   475   "F \<le> F' \<longleftrightarrow> (\<forall>P. eventually P F' \<longrightarrow> eventually P F)"
   476 
   477 definition
   478   "(F :: 'a filter) < F' \<longleftrightarrow> F \<le> F' \<and> \<not> F' \<le> F"
   479 
   480 definition
   481   "top = Abs_filter (\<lambda>P. \<forall>x. P x)"
   482 
   483 definition
   484   "bot = Abs_filter (\<lambda>P. True)"
   485 
   486 definition
   487   "sup F F' = Abs_filter (\<lambda>P. eventually P F \<and> eventually P F')"
   488 
   489 definition
   490   "inf F F' = Abs_filter
   491       (\<lambda>P. \<exists>Q R. eventually Q F \<and> eventually R F' \<and> (\<forall>x. Q x \<and> R x \<longrightarrow> P x))"
   492 
   493 definition
   494   "Sup S = Abs_filter (\<lambda>P. \<forall>F\<in>S. eventually P F)"
   495 
   496 definition
   497   "Inf S = Sup {F::'a filter. \<forall>F'\<in>S. F \<le> F'}"
   498 
   499 lemma eventually_top [simp]: "eventually P top \<longleftrightarrow> (\<forall>x. P x)"
   500   unfolding top_filter_def
   501   by (rule eventually_Abs_filter, rule is_filter.intro, auto)
   502 
   503 lemma eventually_bot [simp]: "eventually P bot"
   504   unfolding bot_filter_def
   505   by (subst eventually_Abs_filter, rule is_filter.intro, auto)
   506 
   507 lemma eventually_sup:
   508   "eventually P (sup F F') \<longleftrightarrow> eventually P F \<and> eventually P F'"
   509   unfolding sup_filter_def
   510   by (rule eventually_Abs_filter, rule is_filter.intro)
   511      (auto elim!: eventually_rev_mp)
   512 
   513 lemma eventually_inf:
   514   "eventually P (inf F F') \<longleftrightarrow>
   515    (\<exists>Q R. eventually Q F \<and> eventually R F' \<and> (\<forall>x. Q x \<and> R x \<longrightarrow> P x))"
   516   unfolding inf_filter_def
   517   apply (rule eventually_Abs_filter, rule is_filter.intro)
   518   apply (fast intro: eventually_True)
   519   apply clarify
   520   apply (intro exI conjI)
   521   apply (erule (1) eventually_conj)
   522   apply (erule (1) eventually_conj)
   523   apply simp
   524   apply auto
   525   done
   526 
   527 lemma eventually_Sup:
   528   "eventually P (Sup S) \<longleftrightarrow> (\<forall>F\<in>S. eventually P F)"
   529   unfolding Sup_filter_def
   530   apply (rule eventually_Abs_filter, rule is_filter.intro)
   531   apply (auto intro: eventually_conj elim!: eventually_rev_mp)
   532   done
   533 
   534 instance proof
   535   fix F F' F'' :: "'a filter" and S :: "'a filter set"
   536   { show "F < F' \<longleftrightarrow> F \<le> F' \<and> \<not> F' \<le> F"
   537     by (rule less_filter_def) }
   538   { show "F \<le> F"
   539     unfolding le_filter_def by simp }
   540   { assume "F \<le> F'" and "F' \<le> F''" thus "F \<le> F''"
   541     unfolding le_filter_def by simp }
   542   { assume "F \<le> F'" and "F' \<le> F" thus "F = F'"
   543     unfolding le_filter_def filter_eq_iff by fast }
   544   { show "inf F F' \<le> F" and "inf F F' \<le> F'"
   545     unfolding le_filter_def eventually_inf by (auto intro: eventually_True) }
   546   { assume "F \<le> F'" and "F \<le> F''" thus "F \<le> inf F' F''"
   547     unfolding le_filter_def eventually_inf
   548     by (auto elim!: eventually_mono intro: eventually_conj) }
   549   { show "F \<le> sup F F'" and "F' \<le> sup F F'"
   550     unfolding le_filter_def eventually_sup by simp_all }
   551   { assume "F \<le> F''" and "F' \<le> F''" thus "sup F F' \<le> F''"
   552     unfolding le_filter_def eventually_sup by simp }
   553   { assume "F'' \<in> S" thus "Inf S \<le> F''"
   554     unfolding le_filter_def Inf_filter_def eventually_Sup Ball_def by simp }
   555   { assume "\<And>F'. F' \<in> S \<Longrightarrow> F \<le> F'" thus "F \<le> Inf S"
   556     unfolding le_filter_def Inf_filter_def eventually_Sup Ball_def by simp }
   557   { assume "F \<in> S" thus "F \<le> Sup S"
   558     unfolding le_filter_def eventually_Sup by simp }
   559   { assume "\<And>F. F \<in> S \<Longrightarrow> F \<le> F'" thus "Sup S \<le> F'"
   560     unfolding le_filter_def eventually_Sup by simp }
   561   { show "Inf {} = (top::'a filter)"
   562     by (auto simp: top_filter_def Inf_filter_def Sup_filter_def)
   563       (metis (full_types) top_filter_def always_eventually eventually_top) }
   564   { show "Sup {} = (bot::'a filter)"
   565     by (auto simp: bot_filter_def Sup_filter_def) }
   566 qed
   567 
   568 end
   569 
   570 lemma filter_leD:
   571   "F \<le> F' \<Longrightarrow> eventually P F' \<Longrightarrow> eventually P F"
   572   unfolding le_filter_def by simp
   573 
   574 lemma filter_leI:
   575   "(\<And>P. eventually P F' \<Longrightarrow> eventually P F) \<Longrightarrow> F \<le> F'"
   576   unfolding le_filter_def by simp
   577 
   578 lemma eventually_False:
   579   "eventually (\<lambda>x. False) F \<longleftrightarrow> F = bot"
   580   unfolding filter_eq_iff by (auto elim: eventually_rev_mp)
   581 
   582 abbreviation (input) trivial_limit :: "'a filter \<Rightarrow> bool"
   583   where "trivial_limit F \<equiv> F = bot"
   584 
   585 lemma trivial_limit_def: "trivial_limit F \<longleftrightarrow> eventually (\<lambda>x. False) F"
   586   by (rule eventually_False [symmetric])
   587 
   588 lemma eventually_const: "\<not> trivial_limit net \<Longrightarrow> eventually (\<lambda>x. P) net \<longleftrightarrow> P"
   589   by (cases P) (simp_all add: eventually_False)
   590 
   591 lemma eventually_Inf: "eventually P (Inf B) \<longleftrightarrow> (\<exists>X\<subseteq>B. finite X \<and> eventually P (Inf X))"
   592 proof -
   593   let ?F = "\<lambda>P. \<exists>X\<subseteq>B. finite X \<and> eventually P (Inf X)"
   594   
   595   { fix P have "eventually P (Abs_filter ?F) \<longleftrightarrow> ?F P"
   596     proof (rule eventually_Abs_filter is_filter.intro)+
   597       show "?F (\<lambda>x. True)"
   598         by (rule exI[of _ "{}"]) (simp add: le_fun_def)
   599     next
   600       fix P Q
   601       assume "?F P" then guess X ..
   602       moreover
   603       assume "?F Q" then guess Y ..
   604       ultimately show "?F (\<lambda>x. P x \<and> Q x)"
   605         by (intro exI[of _ "X \<union> Y"])
   606            (auto simp: Inf_union_distrib eventually_inf)
   607     next
   608       fix P Q
   609       assume "?F P" then guess X ..
   610       moreover assume "\<forall>x. P x \<longrightarrow> Q x"
   611       ultimately show "?F Q"
   612         by (intro exI[of _ X]) (auto elim: eventually_elim1)
   613     qed }
   614   note eventually_F = this
   615 
   616   have "Inf B = Abs_filter ?F"
   617   proof (intro antisym Inf_greatest)
   618     show "Inf B \<le> Abs_filter ?F"
   619       by (auto simp: le_filter_def eventually_F dest: Inf_superset_mono)
   620   next
   621     fix F assume "F \<in> B" then show "Abs_filter ?F \<le> F"
   622       by (auto simp add: le_filter_def eventually_F intro!: exI[of _ "{F}"])
   623   qed
   624   then show ?thesis
   625     by (simp add: eventually_F)
   626 qed
   627 
   628 lemma eventually_INF: "eventually P (INF b:B. F b) \<longleftrightarrow> (\<exists>X\<subseteq>B. finite X \<and> eventually P (INF b:X. F b))"
   629   unfolding INF_def[of B] eventually_Inf[of P "F`B"]
   630   by (metis Inf_image_eq finite_imageI image_mono finite_subset_image)
   631 
   632 lemma Inf_filter_not_bot:
   633   fixes B :: "'a filter set"
   634   shows "(\<And>X. X \<subseteq> B \<Longrightarrow> finite X \<Longrightarrow> Inf X \<noteq> bot) \<Longrightarrow> Inf B \<noteq> bot"
   635   unfolding trivial_limit_def eventually_Inf[of _ B]
   636     bot_bool_def [symmetric] bot_fun_def [symmetric] bot_unique by simp
   637 
   638 lemma INF_filter_not_bot:
   639   fixes F :: "'i \<Rightarrow> 'a filter"
   640   shows "(\<And>X. X \<subseteq> B \<Longrightarrow> finite X \<Longrightarrow> (INF b:X. F b) \<noteq> bot) \<Longrightarrow> (INF b:B. F b) \<noteq> bot"
   641   unfolding trivial_limit_def eventually_INF[of _ B]
   642     bot_bool_def [symmetric] bot_fun_def [symmetric] bot_unique by simp
   643 
   644 lemma eventually_Inf_base:
   645   assumes "B \<noteq> {}" and base: "\<And>F G. F \<in> B \<Longrightarrow> G \<in> B \<Longrightarrow> \<exists>x\<in>B. x \<le> inf F G"
   646   shows "eventually P (Inf B) \<longleftrightarrow> (\<exists>b\<in>B. eventually P b)"
   647 proof (subst eventually_Inf, safe)
   648   fix X assume "finite X" "X \<subseteq> B"
   649   then have "\<exists>b\<in>B. \<forall>x\<in>X. b \<le> x"
   650   proof induct
   651     case empty then show ?case
   652       using `B \<noteq> {}` by auto
   653   next
   654     case (insert x X)
   655     then obtain b where "b \<in> B" "\<And>x. x \<in> X \<Longrightarrow> b \<le> x"
   656       by auto
   657     with `insert x X \<subseteq> B` base[of b x] show ?case
   658       by (auto intro: order_trans)
   659   qed
   660   then obtain b where "b \<in> B" "b \<le> Inf X"
   661     by (auto simp: le_Inf_iff)
   662   then show "eventually P (Inf X) \<Longrightarrow> Bex B (eventually P)"
   663     by (intro bexI[of _ b]) (auto simp: le_filter_def)
   664 qed (auto intro!: exI[of _ "{x}" for x])
   665 
   666 lemma eventually_INF_base:
   667   "B \<noteq> {} \<Longrightarrow> (\<And>a b. a \<in> B \<Longrightarrow> b \<in> B \<Longrightarrow> \<exists>x\<in>B. F x \<le> inf (F a) (F b)) \<Longrightarrow>
   668     eventually P (INF b:B. F b) \<longleftrightarrow> (\<exists>b\<in>B. eventually P (F b))"
   669   unfolding INF_def by (subst eventually_Inf_base) auto
   670 
   671 
   672 subsubsection {* Map function for filters *}
   673 
   674 definition filtermap :: "('a \<Rightarrow> 'b) \<Rightarrow> 'a filter \<Rightarrow> 'b filter"
   675   where "filtermap f F = Abs_filter (\<lambda>P. eventually (\<lambda>x. P (f x)) F)"
   676 
   677 lemma eventually_filtermap:
   678   "eventually P (filtermap f F) = eventually (\<lambda>x. P (f x)) F"
   679   unfolding filtermap_def
   680   apply (rule eventually_Abs_filter)
   681   apply (rule is_filter.intro)
   682   apply (auto elim!: eventually_rev_mp)
   683   done
   684 
   685 lemma filtermap_ident: "filtermap (\<lambda>x. x) F = F"
   686   by (simp add: filter_eq_iff eventually_filtermap)
   687 
   688 lemma filtermap_filtermap:
   689   "filtermap f (filtermap g F) = filtermap (\<lambda>x. f (g x)) F"
   690   by (simp add: filter_eq_iff eventually_filtermap)
   691 
   692 lemma filtermap_mono: "F \<le> F' \<Longrightarrow> filtermap f F \<le> filtermap f F'"
   693   unfolding le_filter_def eventually_filtermap by simp
   694 
   695 lemma filtermap_bot [simp]: "filtermap f bot = bot"
   696   by (simp add: filter_eq_iff eventually_filtermap)
   697 
   698 lemma filtermap_sup: "filtermap f (sup F1 F2) = sup (filtermap f F1) (filtermap f F2)"
   699   by (auto simp: filter_eq_iff eventually_filtermap eventually_sup)
   700 
   701 lemma filtermap_inf: "filtermap f (inf F1 F2) \<le> inf (filtermap f F1) (filtermap f F2)"
   702   by (auto simp: le_filter_def eventually_filtermap eventually_inf)
   703 
   704 lemma filtermap_INF: "filtermap f (INF b:B. F b) \<le> (INF b:B. filtermap f (F b))"
   705 proof -
   706   { fix X :: "'c set" assume "finite X"
   707     then have "filtermap f (INFIMUM X F) \<le> (INF b:X. filtermap f (F b))"
   708     proof induct
   709       case (insert x X)
   710       have "filtermap f (INF a:insert x X. F a) \<le> inf (filtermap f (F x)) (filtermap f (INF a:X. F a))"
   711         by (rule order_trans[OF _ filtermap_inf]) simp
   712       also have "\<dots> \<le> inf (filtermap f (F x)) (INF a:X. filtermap f (F a))"
   713         by (intro inf_mono insert order_refl)
   714       finally show ?case
   715         by simp
   716     qed simp }
   717   then show ?thesis
   718     unfolding le_filter_def eventually_filtermap
   719     by (subst (1 2) eventually_INF) auto
   720 qed
   721 subsubsection {* Standard filters *}
   722 
   723 definition principal :: "'a set \<Rightarrow> 'a filter" where
   724   "principal S = Abs_filter (\<lambda>P. \<forall>x\<in>S. P x)"
   725 
   726 lemma eventually_principal: "eventually P (principal S) \<longleftrightarrow> (\<forall>x\<in>S. P x)"
   727   unfolding principal_def
   728   by (rule eventually_Abs_filter, rule is_filter.intro) auto
   729 
   730 lemma eventually_inf_principal: "eventually P (inf F (principal s)) \<longleftrightarrow> eventually (\<lambda>x. x \<in> s \<longrightarrow> P x) F"
   731   unfolding eventually_inf eventually_principal by (auto elim: eventually_elim1)
   732 
   733 lemma principal_UNIV[simp]: "principal UNIV = top"
   734   by (auto simp: filter_eq_iff eventually_principal)
   735 
   736 lemma principal_empty[simp]: "principal {} = bot"
   737   by (auto simp: filter_eq_iff eventually_principal)
   738 
   739 lemma principal_eq_bot_iff: "principal X = bot \<longleftrightarrow> X = {}"
   740   by (auto simp add: filter_eq_iff eventually_principal)
   741 
   742 lemma principal_le_iff[iff]: "principal A \<le> principal B \<longleftrightarrow> A \<subseteq> B"
   743   by (auto simp: le_filter_def eventually_principal)
   744 
   745 lemma le_principal: "F \<le> principal A \<longleftrightarrow> eventually (\<lambda>x. x \<in> A) F"
   746   unfolding le_filter_def eventually_principal
   747   apply safe
   748   apply (erule_tac x="\<lambda>x. x \<in> A" in allE)
   749   apply (auto elim: eventually_elim1)
   750   done
   751 
   752 lemma principal_inject[iff]: "principal A = principal B \<longleftrightarrow> A = B"
   753   unfolding eq_iff by simp
   754 
   755 lemma sup_principal[simp]: "sup (principal A) (principal B) = principal (A \<union> B)"
   756   unfolding filter_eq_iff eventually_sup eventually_principal by auto
   757 
   758 lemma inf_principal[simp]: "inf (principal A) (principal B) = principal (A \<inter> B)"
   759   unfolding filter_eq_iff eventually_inf eventually_principal
   760   by (auto intro: exI[of _ "\<lambda>x. x \<in> A"] exI[of _ "\<lambda>x. x \<in> B"])
   761 
   762 lemma SUP_principal[simp]: "(SUP i : I. principal (A i)) = principal (\<Union>i\<in>I. A i)"
   763   unfolding filter_eq_iff eventually_Sup SUP_def by (auto simp: eventually_principal)
   764 
   765 lemma INF_principal_finite: "finite X \<Longrightarrow> (INF x:X. principal (f x)) = principal (\<Inter>x\<in>X. f x)"
   766   by (induct X rule: finite_induct) auto
   767 
   768 lemma filtermap_principal[simp]: "filtermap f (principal A) = principal (f ` A)"
   769   unfolding filter_eq_iff eventually_filtermap eventually_principal by simp
   770 
   771 subsubsection {* Order filters *}
   772 
   773 definition at_top :: "('a::order) filter"
   774   where "at_top = (INF k. principal {k ..})"
   775 
   776 lemma at_top_sub: "at_top = (INF k:{c::'a::linorder..}. principal {k ..})"
   777   by (auto intro!: INF_eq max.cobounded1 max.cobounded2 simp: at_top_def)
   778 
   779 lemma eventually_at_top_linorder: "eventually P at_top \<longleftrightarrow> (\<exists>N::'a::linorder. \<forall>n\<ge>N. P n)"
   780   unfolding at_top_def
   781   by (subst eventually_INF_base) (auto simp: eventually_principal intro: max.cobounded1 max.cobounded2)
   782 
   783 lemma eventually_ge_at_top:
   784   "eventually (\<lambda>x. (c::_::linorder) \<le> x) at_top"
   785   unfolding eventually_at_top_linorder by auto
   786 
   787 lemma eventually_at_top_dense: "eventually P at_top \<longleftrightarrow> (\<exists>N::'a::{no_top, linorder}. \<forall>n>N. P n)"
   788 proof -
   789   have "eventually P (INF k. principal {k <..}) \<longleftrightarrow> (\<exists>N::'a. \<forall>n>N. P n)"
   790     by (subst eventually_INF_base) (auto simp: eventually_principal intro: max.cobounded1 max.cobounded2)
   791   also have "(INF k. principal {k::'a <..}) = at_top"
   792     unfolding at_top_def 
   793     by (intro INF_eq) (auto intro: less_imp_le simp: Ici_subset_Ioi_iff gt_ex)
   794   finally show ?thesis .
   795 qed
   796 
   797 lemma eventually_gt_at_top:
   798   "eventually (\<lambda>x. (c::_::unbounded_dense_linorder) < x) at_top"
   799   unfolding eventually_at_top_dense by auto
   800 
   801 definition at_bot :: "('a::order) filter"
   802   where "at_bot = (INF k. principal {.. k})"
   803 
   804 lemma at_bot_sub: "at_bot = (INF k:{.. c::'a::linorder}. principal {.. k})"
   805   by (auto intro!: INF_eq min.cobounded1 min.cobounded2 simp: at_bot_def)
   806 
   807 lemma eventually_at_bot_linorder:
   808   fixes P :: "'a::linorder \<Rightarrow> bool" shows "eventually P at_bot \<longleftrightarrow> (\<exists>N. \<forall>n\<le>N. P n)"
   809   unfolding at_bot_def
   810   by (subst eventually_INF_base) (auto simp: eventually_principal intro: min.cobounded1 min.cobounded2)
   811 
   812 lemma eventually_le_at_bot:
   813   "eventually (\<lambda>x. x \<le> (c::_::linorder)) at_bot"
   814   unfolding eventually_at_bot_linorder by auto
   815 
   816 lemma eventually_at_bot_dense: "eventually P at_bot \<longleftrightarrow> (\<exists>N::'a::{no_bot, linorder}. \<forall>n<N. P n)"
   817 proof -
   818   have "eventually P (INF k. principal {..< k}) \<longleftrightarrow> (\<exists>N::'a. \<forall>n<N. P n)"
   819     by (subst eventually_INF_base) (auto simp: eventually_principal intro: min.cobounded1 min.cobounded2)
   820   also have "(INF k. principal {..< k::'a}) = at_bot"
   821     unfolding at_bot_def 
   822     by (intro INF_eq) (auto intro: less_imp_le simp: Iic_subset_Iio_iff lt_ex)
   823   finally show ?thesis .
   824 qed
   825 
   826 lemma eventually_gt_at_bot:
   827   "eventually (\<lambda>x. x < (c::_::unbounded_dense_linorder)) at_bot"
   828   unfolding eventually_at_bot_dense by auto
   829 
   830 lemma trivial_limit_at_bot_linorder: "\<not> trivial_limit (at_bot ::('a::linorder) filter)"
   831   unfolding trivial_limit_def
   832   by (metis eventually_at_bot_linorder order_refl)
   833 
   834 lemma trivial_limit_at_top_linorder: "\<not> trivial_limit (at_top ::('a::linorder) filter)"
   835   unfolding trivial_limit_def
   836   by (metis eventually_at_top_linorder order_refl)
   837 
   838 subsection {* Sequentially *}
   839 
   840 abbreviation sequentially :: "nat filter"
   841   where "sequentially \<equiv> at_top"
   842 
   843 lemma eventually_sequentially:
   844   "eventually P sequentially \<longleftrightarrow> (\<exists>N. \<forall>n\<ge>N. P n)"
   845   by (rule eventually_at_top_linorder)
   846 
   847 lemma sequentially_bot [simp, intro]: "sequentially \<noteq> bot"
   848   unfolding filter_eq_iff eventually_sequentially by auto
   849 
   850 lemmas trivial_limit_sequentially = sequentially_bot
   851 
   852 lemma eventually_False_sequentially [simp]:
   853   "\<not> eventually (\<lambda>n. False) sequentially"
   854   by (simp add: eventually_False)
   855 
   856 lemma le_sequentially:
   857   "F \<le> sequentially \<longleftrightarrow> (\<forall>N. eventually (\<lambda>n. N \<le> n) F)"
   858   by (simp add: at_top_def le_INF_iff le_principal)
   859 
   860 lemma eventually_sequentiallyI:
   861   assumes "\<And>x. c \<le> x \<Longrightarrow> P x"
   862   shows "eventually P sequentially"
   863 using assms by (auto simp: eventually_sequentially)
   864 
   865 lemma eventually_sequentially_seg:
   866   "eventually (\<lambda>n. P (n + k)) sequentially \<longleftrightarrow> eventually P sequentially"
   867   unfolding eventually_sequentially
   868   apply safe
   869    apply (rule_tac x="N + k" in exI)
   870    apply rule
   871    apply (erule_tac x="n - k" in allE)
   872    apply auto []
   873   apply (rule_tac x=N in exI)
   874   apply auto []
   875   done
   876 
   877 subsubsection {* Topological filters *}
   878 
   879 definition (in topological_space) nhds :: "'a \<Rightarrow> 'a filter"
   880   where "nhds a = (INF S:{S. open S \<and> a \<in> S}. principal S)"
   881 
   882 definition (in topological_space) at_within :: "'a \<Rightarrow> 'a set \<Rightarrow> 'a filter" ("at (_) within (_)" [1000, 60] 60)
   883   where "at a within s = inf (nhds a) (principal (s - {a}))"
   884 
   885 abbreviation (in topological_space) at :: "'a \<Rightarrow> 'a filter" ("at") where
   886   "at x \<equiv> at x within (CONST UNIV)"
   887 
   888 abbreviation (in order_topology) at_right :: "'a \<Rightarrow> 'a filter" where
   889   "at_right x \<equiv> at x within {x <..}"
   890 
   891 abbreviation (in order_topology) at_left :: "'a \<Rightarrow> 'a filter" where
   892   "at_left x \<equiv> at x within {..< x}"
   893 
   894 lemma (in topological_space) nhds_generated_topology:
   895   "open = generate_topology T \<Longrightarrow> nhds x = (INF S:{S\<in>T. x \<in> S}. principal S)"
   896   unfolding nhds_def
   897 proof (safe intro!: antisym INF_greatest)
   898   fix S assume "generate_topology T S" "x \<in> S"
   899   then show "(INF S:{S \<in> T. x \<in> S}. principal S) \<le> principal S"
   900     by induction 
   901        (auto intro: INF_lower order_trans simp add: inf_principal[symmetric] simp del: inf_principal)
   902 qed (auto intro!: INF_lower intro: generate_topology.intros)
   903 
   904 lemma (in topological_space) eventually_nhds:
   905   "eventually P (nhds a) \<longleftrightarrow> (\<exists>S. open S \<and> a \<in> S \<and> (\<forall>x\<in>S. P x))"
   906   unfolding nhds_def by (subst eventually_INF_base) (auto simp: eventually_principal)
   907 
   908 lemma nhds_neq_bot [simp]: "nhds a \<noteq> bot"
   909   unfolding trivial_limit_def eventually_nhds by simp
   910 
   911 lemma at_within_eq: "at x within s = (INF S:{S. open S \<and> x \<in> S}. principal (S \<inter> s - {x}))"
   912   unfolding nhds_def at_within_def by (subst INF_inf_const2[symmetric]) (auto simp add: Diff_Int_distrib)
   913 
   914 lemma eventually_at_filter:
   915   "eventually P (at a within s) \<longleftrightarrow> eventually (\<lambda>x. x \<noteq> a \<longrightarrow> x \<in> s \<longrightarrow> P x) (nhds a)"
   916   unfolding at_within_def eventually_inf_principal by (simp add: imp_conjL[symmetric] conj_commute)
   917 
   918 lemma at_le: "s \<subseteq> t \<Longrightarrow> at x within s \<le> at x within t"
   919   unfolding at_within_def by (intro inf_mono) auto
   920 
   921 lemma eventually_at_topological:
   922   "eventually P (at a within s) \<longleftrightarrow> (\<exists>S. open S \<and> a \<in> S \<and> (\<forall>x\<in>S. x \<noteq> a \<longrightarrow> x \<in> s \<longrightarrow> P x))"
   923   unfolding eventually_nhds eventually_at_filter by simp
   924 
   925 lemma at_within_open: "a \<in> S \<Longrightarrow> open S \<Longrightarrow> at a within S = at a"
   926   unfolding filter_eq_iff eventually_at_topological by (metis open_Int Int_iff UNIV_I)
   927 
   928 lemma at_within_empty [simp]: "at a within {} = bot"
   929   unfolding at_within_def by simp
   930 
   931 lemma at_within_union: "at x within (S \<union> T) = sup (at x within S) (at x within T)"
   932   unfolding filter_eq_iff eventually_sup eventually_at_filter
   933   by (auto elim!: eventually_rev_mp)
   934 
   935 lemma at_eq_bot_iff: "at a = bot \<longleftrightarrow> open {a}"
   936   unfolding trivial_limit_def eventually_at_topological
   937   by (safe, case_tac "S = {a}", simp, fast, fast)
   938 
   939 lemma at_neq_bot [simp]: "at (a::'a::perfect_space) \<noteq> bot"
   940   by (simp add: at_eq_bot_iff not_open_singleton)
   941 
   942 lemma (in order_topology) nhds_order: "nhds x =
   943   inf (INF a:{x <..}. principal {..< a}) (INF a:{..< x}. principal {a <..})"
   944 proof -
   945   have 1: "{S \<in> range lessThan \<union> range greaterThan. x \<in> S} = 
   946       (\<lambda>a. {..< a}) ` {x <..} \<union> (\<lambda>a. {a <..}) ` {..< x}"
   947     by auto
   948   show ?thesis
   949     unfolding nhds_generated_topology[OF open_generated_order] INF_union 1 INF_image comp_def ..
   950 qed
   951 
   952 lemma (in linorder_topology) at_within_order: "UNIV \<noteq> {x} \<Longrightarrow> 
   953   at x within s = inf (INF a:{x <..}. principal ({..< a} \<inter> s - {x}))
   954                       (INF a:{..< x}. principal ({a <..} \<inter> s - {x}))"
   955 proof (cases "{x <..} = {}" "{..< x} = {}" rule: case_split[case_product case_split])
   956   assume "UNIV \<noteq> {x}" "{x<..} = {}" "{..< x} = {}"
   957   moreover have "UNIV = {..< x} \<union> {x} \<union> {x <..}"
   958     by auto
   959   ultimately show ?thesis
   960     by auto
   961 qed (auto simp: at_within_def nhds_order Int_Diff inf_principal[symmetric] INF_inf_const2
   962                 inf_sup_aci[where 'a="'a filter"]
   963           simp del: inf_principal)
   964 
   965 lemma (in linorder_topology) at_left_eq:
   966   "y < x \<Longrightarrow> at_left x = (INF a:{..< x}. principal {a <..< x})"
   967   by (subst at_within_order)
   968      (auto simp: greaterThan_Int_greaterThan greaterThanLessThan_eq[symmetric] min.absorb2 INF_constant
   969            intro!: INF_lower2 inf_absorb2)
   970 
   971 lemma (in linorder_topology) eventually_at_left:
   972   "y < x \<Longrightarrow> eventually P (at_left x) \<longleftrightarrow> (\<exists>b<x. \<forall>y>b. y < x \<longrightarrow> P y)"
   973   unfolding at_left_eq by (subst eventually_INF_base) (auto simp: eventually_principal Ball_def)
   974 
   975 lemma (in linorder_topology) at_right_eq:
   976   "x < y \<Longrightarrow> at_right x = (INF a:{x <..}. principal {x <..< a})"
   977   by (subst at_within_order)
   978      (auto simp: lessThan_Int_lessThan greaterThanLessThan_eq[symmetric] max.absorb2 INF_constant Int_commute
   979            intro!: INF_lower2 inf_absorb1)
   980 
   981 lemma (in linorder_topology) eventually_at_right:
   982   "x < y \<Longrightarrow> eventually P (at_right x) \<longleftrightarrow> (\<exists>b>x. \<forall>y>x. y < b \<longrightarrow> P y)"
   983   unfolding at_right_eq by (subst eventually_INF_base) (auto simp: eventually_principal Ball_def)
   984 
   985 lemma trivial_limit_at_right_top: "at_right (top::_::{order_top, linorder_topology}) = bot"
   986   unfolding filter_eq_iff eventually_at_topological by auto
   987 
   988 lemma trivial_limit_at_left_bot: "at_left (bot::_::{order_bot, linorder_topology}) = bot"
   989   unfolding filter_eq_iff eventually_at_topological by auto
   990 
   991 lemma trivial_limit_at_left_real [simp]:
   992   "\<not> trivial_limit (at_left (x::'a::{no_bot, dense_order, linorder_topology}))"
   993   using lt_ex[of x]
   994   by safe (auto simp add: trivial_limit_def eventually_at_left dest: dense)
   995 
   996 lemma trivial_limit_at_right_real [simp]:
   997   "\<not> trivial_limit (at_right (x::'a::{no_top, dense_order, linorder_topology}))"
   998   using gt_ex[of x]
   999   by safe (auto simp add: trivial_limit_def eventually_at_right dest: dense)
  1000 
  1001 lemma at_eq_sup_left_right: "at (x::'a::linorder_topology) = sup (at_left x) (at_right x)"
  1002   by (auto simp: eventually_at_filter filter_eq_iff eventually_sup 
  1003            elim: eventually_elim2 eventually_elim1)
  1004 
  1005 lemma eventually_at_split:
  1006   "eventually P (at (x::'a::linorder_topology)) \<longleftrightarrow> eventually P (at_left x) \<and> eventually P (at_right x)"
  1007   by (subst at_eq_sup_left_right) (simp add: eventually_sup)
  1008 
  1009 subsection {* Limits *}
  1010 
  1011 definition filterlim :: "('a \<Rightarrow> 'b) \<Rightarrow> 'b filter \<Rightarrow> 'a filter \<Rightarrow> bool" where
  1012   "filterlim f F2 F1 \<longleftrightarrow> filtermap f F1 \<le> F2"
  1013 
  1014 syntax
  1015   "_LIM" :: "pttrns \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'a \<Rightarrow> bool" ("(3LIM (_)/ (_)./ (_) :> (_))" [1000, 10, 0, 10] 10)
  1016 
  1017 translations
  1018   "LIM x F1. f :> F2"   == "CONST filterlim (%x. f) F2 F1"
  1019 
  1020 lemma filterlim_iff:
  1021   "(LIM x F1. f x :> F2) \<longleftrightarrow> (\<forall>P. eventually P F2 \<longrightarrow> eventually (\<lambda>x. P (f x)) F1)"
  1022   unfolding filterlim_def le_filter_def eventually_filtermap ..
  1023 
  1024 lemma filterlim_compose:
  1025   "filterlim g F3 F2 \<Longrightarrow> filterlim f F2 F1 \<Longrightarrow> filterlim (\<lambda>x. g (f x)) F3 F1"
  1026   unfolding filterlim_def filtermap_filtermap[symmetric] by (metis filtermap_mono order_trans)
  1027 
  1028 lemma filterlim_mono:
  1029   "filterlim f F2 F1 \<Longrightarrow> F2 \<le> F2' \<Longrightarrow> F1' \<le> F1 \<Longrightarrow> filterlim f F2' F1'"
  1030   unfolding filterlim_def by (metis filtermap_mono order_trans)
  1031 
  1032 lemma filterlim_ident: "LIM x F. x :> F"
  1033   by (simp add: filterlim_def filtermap_ident)
  1034 
  1035 lemma filterlim_cong:
  1036   "F1 = F1' \<Longrightarrow> F2 = F2' \<Longrightarrow> eventually (\<lambda>x. f x = g x) F2 \<Longrightarrow> filterlim f F1 F2 = filterlim g F1' F2'"
  1037   by (auto simp: filterlim_def le_filter_def eventually_filtermap elim: eventually_elim2)
  1038 
  1039 lemma filterlim_mono_eventually:
  1040   assumes "filterlim f F G" and ord: "F \<le> F'" "G' \<le> G"
  1041   assumes eq: "eventually (\<lambda>x. f x = f' x) G'"
  1042   shows "filterlim f' F' G'"
  1043   apply (rule filterlim_cong[OF refl refl eq, THEN iffD1])
  1044   apply (rule filterlim_mono[OF _ ord])
  1045   apply fact
  1046   done
  1047 
  1048 lemma filtermap_mono_strong: "inj f \<Longrightarrow> filtermap f F \<le> filtermap f G \<longleftrightarrow> F \<le> G"
  1049   apply (auto intro!: filtermap_mono) []
  1050   apply (auto simp: le_filter_def eventually_filtermap)
  1051   apply (erule_tac x="\<lambda>x. P (inv f x)" in allE)
  1052   apply auto
  1053   done
  1054 
  1055 lemma filtermap_eq_strong: "inj f \<Longrightarrow> filtermap f F = filtermap f G \<longleftrightarrow> F = G"
  1056   by (simp add: filtermap_mono_strong eq_iff)
  1057 
  1058 lemma filterlim_principal:
  1059   "(LIM x F. f x :> principal S) \<longleftrightarrow> (eventually (\<lambda>x. f x \<in> S) F)"
  1060   unfolding filterlim_def eventually_filtermap le_principal ..
  1061 
  1062 lemma filterlim_inf:
  1063   "(LIM x F1. f x :> inf F2 F3) \<longleftrightarrow> ((LIM x F1. f x :> F2) \<and> (LIM x F1. f x :> F3))"
  1064   unfolding filterlim_def by simp
  1065 
  1066 lemma filterlim_INF:
  1067   "(LIM x F. f x :> (INF b:B. G b)) \<longleftrightarrow> (\<forall>b\<in>B. LIM x F. f x :> G b)"
  1068   unfolding filterlim_def le_INF_iff ..
  1069 
  1070 lemma filterlim_INF_INF:
  1071   "(\<And>m. m \<in> J \<Longrightarrow> \<exists>i\<in>I. filtermap f (F i) \<le> G m) \<Longrightarrow> LIM x (INF i:I. F i). f x :> (INF j:J. G j)"
  1072   unfolding filterlim_def by (rule order_trans[OF filtermap_INF INF_mono])
  1073 
  1074 lemma filterlim_base:
  1075   "(\<And>m x. m \<in> J \<Longrightarrow> i m \<in> I) \<Longrightarrow> (\<And>m x. m \<in> J \<Longrightarrow> x \<in> F (i m) \<Longrightarrow> f x \<in> G m) \<Longrightarrow> 
  1076     LIM x (INF i:I. principal (F i)). f x :> (INF j:J. principal (G j))"
  1077   by (force intro!: filterlim_INF_INF simp: image_subset_iff)
  1078 
  1079 lemma filterlim_base_iff: 
  1080   assumes "I \<noteq> {}" and chain: "\<And>i j. i \<in> I \<Longrightarrow> j \<in> I \<Longrightarrow> F i \<subseteq> F j \<or> F j \<subseteq> F i"
  1081   shows "(LIM x (INF i:I. principal (F i)). f x :> INF j:J. principal (G j)) \<longleftrightarrow>
  1082     (\<forall>j\<in>J. \<exists>i\<in>I. \<forall>x\<in>F i. f x \<in> G j)"
  1083   unfolding filterlim_INF filterlim_principal
  1084 proof (subst eventually_INF_base)
  1085   fix i j assume "i \<in> I" "j \<in> I"
  1086   with chain[OF this] show "\<exists>x\<in>I. principal (F x) \<le> inf (principal (F i)) (principal (F j))"
  1087     by auto
  1088 qed (auto simp: eventually_principal `I \<noteq> {}`)
  1089 
  1090 lemma filterlim_filtermap: "filterlim f F1 (filtermap g F2) = filterlim (\<lambda>x. f (g x)) F1 F2"
  1091   unfolding filterlim_def filtermap_filtermap ..
  1092 
  1093 lemma filterlim_sup:
  1094   "filterlim f F F1 \<Longrightarrow> filterlim f F F2 \<Longrightarrow> filterlim f F (sup F1 F2)"
  1095   unfolding filterlim_def filtermap_sup by auto
  1096 
  1097 lemma eventually_sequentially_Suc: "eventually (\<lambda>i. P (Suc i)) sequentially \<longleftrightarrow> eventually P sequentially"
  1098   unfolding eventually_sequentially by (metis Suc_le_D Suc_le_mono le_Suc_eq)
  1099 
  1100 lemma filterlim_sequentially_Suc:
  1101   "(LIM x sequentially. f (Suc x) :> F) \<longleftrightarrow> (LIM x sequentially. f x :> F)"
  1102   unfolding filterlim_iff by (subst eventually_sequentially_Suc) simp
  1103 
  1104 lemma filterlim_Suc: "filterlim Suc sequentially sequentially"
  1105   by (simp add: filterlim_iff eventually_sequentially) (metis le_Suc_eq)
  1106 
  1107 subsubsection {* Tendsto *}
  1108 
  1109 abbreviation (in topological_space)
  1110   tendsto :: "('b \<Rightarrow> 'a) \<Rightarrow> 'a \<Rightarrow> 'b filter \<Rightarrow> bool" (infixr "--->" 55) where
  1111   "(f ---> l) F \<equiv> filterlim f (nhds l) F"
  1112 
  1113 definition (in t2_space) Lim :: "'f filter \<Rightarrow> ('f \<Rightarrow> 'a) \<Rightarrow> 'a" where
  1114   "Lim A f = (THE l. (f ---> l) A)"
  1115 
  1116 lemma tendsto_eq_rhs: "(f ---> x) F \<Longrightarrow> x = y \<Longrightarrow> (f ---> y) F"
  1117   by simp
  1118 
  1119 named_theorems tendsto_intros "introduction rules for tendsto"
  1120 setup {*
  1121   Global_Theory.add_thms_dynamic (@{binding tendsto_eq_intros},
  1122     fn context =>
  1123       Named_Theorems.get (Context.proof_of context) @{named_theorems tendsto_intros}
  1124       |> map_filter (try (fn thm => @{thm tendsto_eq_rhs} OF [thm])))
  1125 *}
  1126 
  1127 lemma (in topological_space) tendsto_def:
  1128    "(f ---> l) F \<longleftrightarrow> (\<forall>S. open S \<longrightarrow> l \<in> S \<longrightarrow> eventually (\<lambda>x. f x \<in> S) F)"
  1129    unfolding nhds_def filterlim_INF filterlim_principal by auto
  1130 
  1131 lemma tendsto_mono: "F \<le> F' \<Longrightarrow> (f ---> l) F' \<Longrightarrow> (f ---> l) F"
  1132   unfolding tendsto_def le_filter_def by fast
  1133 
  1134 lemma tendsto_within_subset: "(f ---> l) (at x within S) \<Longrightarrow> T \<subseteq> S \<Longrightarrow> (f ---> l) (at x within T)"
  1135   by (blast intro: tendsto_mono at_le)
  1136 
  1137 lemma filterlim_at:
  1138   "(LIM x F. f x :> at b within s) \<longleftrightarrow> (eventually (\<lambda>x. f x \<in> s \<and> f x \<noteq> b) F \<and> (f ---> b) F)"
  1139   by (simp add: at_within_def filterlim_inf filterlim_principal conj_commute)
  1140 
  1141 lemma (in topological_space) topological_tendstoI:
  1142   "(\<And>S. open S \<Longrightarrow> l \<in> S \<Longrightarrow> eventually (\<lambda>x. f x \<in> S) F) \<Longrightarrow> (f ---> l) F"
  1143   unfolding tendsto_def by auto
  1144 
  1145 lemma (in topological_space) topological_tendstoD:
  1146   "(f ---> l) F \<Longrightarrow> open S \<Longrightarrow> l \<in> S \<Longrightarrow> eventually (\<lambda>x. f x \<in> S) F"
  1147   unfolding tendsto_def by auto
  1148 
  1149 lemma (in order_topology) order_tendsto_iff:
  1150   "(f ---> x) F \<longleftrightarrow> (\<forall>l<x. eventually (\<lambda>x. l < f x) F) \<and> (\<forall>u>x. eventually (\<lambda>x. f x < u) F)"
  1151   unfolding nhds_order filterlim_inf filterlim_INF filterlim_principal by auto
  1152 
  1153 lemma (in order_topology) order_tendstoI:
  1154   "(\<And>a. a < y \<Longrightarrow> eventually (\<lambda>x. a < f x) F) \<Longrightarrow> (\<And>a. y < a \<Longrightarrow> eventually (\<lambda>x. f x < a) F) \<Longrightarrow>
  1155     (f ---> y) F"
  1156   unfolding order_tendsto_iff by auto
  1157 
  1158 lemma (in order_topology) order_tendstoD:
  1159   assumes "(f ---> y) F"
  1160   shows "a < y \<Longrightarrow> eventually (\<lambda>x. a < f x) F"
  1161     and "y < a \<Longrightarrow> eventually (\<lambda>x. f x < a) F"
  1162   using assms unfolding order_tendsto_iff by auto
  1163 
  1164 lemma tendsto_bot [simp]: "(f ---> a) bot"
  1165   unfolding tendsto_def by simp
  1166 
  1167 lemma (in linorder_topology) tendsto_max:
  1168   assumes X: "(X ---> x) net"
  1169   assumes Y: "(Y ---> y) net"
  1170   shows "((\<lambda>x. max (X x) (Y x)) ---> max x y) net"
  1171 proof (rule order_tendstoI)
  1172   fix a assume "a < max x y"
  1173   then show "eventually (\<lambda>x. a < max (X x) (Y x)) net"
  1174     using order_tendstoD(1)[OF X, of a] order_tendstoD(1)[OF Y, of a]
  1175     by (auto simp: less_max_iff_disj elim: eventually_elim1)
  1176 next
  1177   fix a assume "max x y < a"
  1178   then show "eventually (\<lambda>x. max (X x) (Y x) < a) net"
  1179     using order_tendstoD(2)[OF X, of a] order_tendstoD(2)[OF Y, of a]
  1180     by (auto simp: eventually_conj_iff)
  1181 qed
  1182 
  1183 lemma (in linorder_topology) tendsto_min:
  1184   assumes X: "(X ---> x) net"
  1185   assumes Y: "(Y ---> y) net"
  1186   shows "((\<lambda>x. min (X x) (Y x)) ---> min x y) net"
  1187 proof (rule order_tendstoI)
  1188   fix a assume "a < min x y"
  1189   then show "eventually (\<lambda>x. a < min (X x) (Y x)) net"
  1190     using order_tendstoD(1)[OF X, of a] order_tendstoD(1)[OF Y, of a]
  1191     by (auto simp: eventually_conj_iff)
  1192 next
  1193   fix a assume "min x y < a"
  1194   then show "eventually (\<lambda>x. min (X x) (Y x) < a) net"
  1195     using order_tendstoD(2)[OF X, of a] order_tendstoD(2)[OF Y, of a]
  1196     by (auto simp: min_less_iff_disj elim: eventually_elim1)
  1197 qed
  1198 
  1199 lemma tendsto_ident_at [tendsto_intros, simp, intro]: "((\<lambda>x. x) ---> a) (at a within s)"
  1200   unfolding tendsto_def eventually_at_topological by auto
  1201 
  1202 lemma (in topological_space) tendsto_const [tendsto_intros, simp, intro]: "((\<lambda>x. k) ---> k) F"
  1203   by (simp add: tendsto_def)
  1204 
  1205 lemma (in t2_space) tendsto_unique:
  1206   assumes "F \<noteq> bot" and "(f ---> a) F" and "(f ---> b) F"
  1207   shows "a = b"
  1208 proof (rule ccontr)
  1209   assume "a \<noteq> b"
  1210   obtain U V where "open U" "open V" "a \<in> U" "b \<in> V" "U \<inter> V = {}"
  1211     using hausdorff [OF `a \<noteq> b`] by fast
  1212   have "eventually (\<lambda>x. f x \<in> U) F"
  1213     using `(f ---> a) F` `open U` `a \<in> U` by (rule topological_tendstoD)
  1214   moreover
  1215   have "eventually (\<lambda>x. f x \<in> V) F"
  1216     using `(f ---> b) F` `open V` `b \<in> V` by (rule topological_tendstoD)
  1217   ultimately
  1218   have "eventually (\<lambda>x. False) F"
  1219   proof eventually_elim
  1220     case (elim x)
  1221     hence "f x \<in> U \<inter> V" by simp
  1222     with `U \<inter> V = {}` show ?case by simp
  1223   qed
  1224   with `\<not> trivial_limit F` show "False"
  1225     by (simp add: trivial_limit_def)
  1226 qed
  1227 
  1228 lemma (in t2_space) tendsto_const_iff:
  1229   assumes "\<not> trivial_limit F" shows "((\<lambda>x. a :: 'a) ---> b) F \<longleftrightarrow> a = b"
  1230   by (auto intro!: tendsto_unique [OF assms tendsto_const])
  1231 
  1232 lemma increasing_tendsto:
  1233   fixes f :: "_ \<Rightarrow> 'a::order_topology"
  1234   assumes bdd: "eventually (\<lambda>n. f n \<le> l) F"
  1235       and en: "\<And>x. x < l \<Longrightarrow> eventually (\<lambda>n. x < f n) F"
  1236   shows "(f ---> l) F"
  1237   using assms by (intro order_tendstoI) (auto elim!: eventually_elim1)
  1238 
  1239 lemma decreasing_tendsto:
  1240   fixes f :: "_ \<Rightarrow> 'a::order_topology"
  1241   assumes bdd: "eventually (\<lambda>n. l \<le> f n) F"
  1242       and en: "\<And>x. l < x \<Longrightarrow> eventually (\<lambda>n. f n < x) F"
  1243   shows "(f ---> l) F"
  1244   using assms by (intro order_tendstoI) (auto elim!: eventually_elim1)
  1245 
  1246 lemma tendsto_sandwich:
  1247   fixes f g h :: "'a \<Rightarrow> 'b::order_topology"
  1248   assumes ev: "eventually (\<lambda>n. f n \<le> g n) net" "eventually (\<lambda>n. g n \<le> h n) net"
  1249   assumes lim: "(f ---> c) net" "(h ---> c) net"
  1250   shows "(g ---> c) net"
  1251 proof (rule order_tendstoI)
  1252   fix a show "a < c \<Longrightarrow> eventually (\<lambda>x. a < g x) net"
  1253     using order_tendstoD[OF lim(1), of a] ev by (auto elim: eventually_elim2)
  1254 next
  1255   fix a show "c < a \<Longrightarrow> eventually (\<lambda>x. g x < a) net"
  1256     using order_tendstoD[OF lim(2), of a] ev by (auto elim: eventually_elim2)
  1257 qed
  1258 
  1259 lemma tendsto_le:
  1260   fixes f g :: "'a \<Rightarrow> 'b::linorder_topology"
  1261   assumes F: "\<not> trivial_limit F"
  1262   assumes x: "(f ---> x) F" and y: "(g ---> y) F"
  1263   assumes ev: "eventually (\<lambda>x. g x \<le> f x) F"
  1264   shows "y \<le> x"
  1265 proof (rule ccontr)
  1266   assume "\<not> y \<le> x"
  1267   with less_separate[of x y] obtain a b where xy: "x < a" "b < y" "{..<a} \<inter> {b<..} = {}"
  1268     by (auto simp: not_le)
  1269   then have "eventually (\<lambda>x. f x < a) F" "eventually (\<lambda>x. b < g x) F"
  1270     using x y by (auto intro: order_tendstoD)
  1271   with ev have "eventually (\<lambda>x. False) F"
  1272     by eventually_elim (insert xy, fastforce)
  1273   with F show False
  1274     by (simp add: eventually_False)
  1275 qed
  1276 
  1277 lemma tendsto_le_const:
  1278   fixes f :: "'a \<Rightarrow> 'b::linorder_topology"
  1279   assumes F: "\<not> trivial_limit F"
  1280   assumes x: "(f ---> x) F" and a: "eventually (\<lambda>i. a \<le> f i) F"
  1281   shows "a \<le> x"
  1282   using F x tendsto_const a by (rule tendsto_le)
  1283 
  1284 lemma tendsto_ge_const:
  1285   fixes f :: "'a \<Rightarrow> 'b::linorder_topology"
  1286   assumes F: "\<not> trivial_limit F"
  1287   assumes x: "(f ---> x) F" and a: "eventually (\<lambda>i. a \<ge> f i) F"
  1288   shows "a \<ge> x"
  1289   by (rule tendsto_le [OF F tendsto_const x a])
  1290 
  1291 subsubsection {* Rules about @{const Lim} *}
  1292 
  1293 lemma tendsto_Lim:
  1294   "\<not>(trivial_limit net) \<Longrightarrow> (f ---> l) net \<Longrightarrow> Lim net f = l"
  1295   unfolding Lim_def using tendsto_unique[of net f] by auto
  1296 
  1297 lemma Lim_ident_at: "\<not> trivial_limit (at x within s) \<Longrightarrow> Lim (at x within s) (\<lambda>x. x) = x"
  1298   by (rule tendsto_Lim[OF _ tendsto_ident_at]) auto
  1299 
  1300 subsection {* Limits to @{const at_top} and @{const at_bot} *}
  1301 
  1302 lemma filterlim_at_top:
  1303   fixes f :: "'a \<Rightarrow> ('b::linorder)"
  1304   shows "(LIM x F. f x :> at_top) \<longleftrightarrow> (\<forall>Z. eventually (\<lambda>x. Z \<le> f x) F)"
  1305   by (auto simp: filterlim_iff eventually_at_top_linorder elim!: eventually_elim1)
  1306 
  1307 lemma filterlim_at_top_mono:
  1308   "LIM x F. f x :> at_top \<Longrightarrow> eventually (\<lambda>x. f x \<le> (g x::'a::linorder)) F \<Longrightarrow>
  1309     LIM x F. g x :> at_top"
  1310   by (auto simp: filterlim_at_top elim: eventually_elim2 intro: order_trans)
  1311 
  1312 lemma filterlim_at_top_dense:
  1313   fixes f :: "'a \<Rightarrow> ('b::unbounded_dense_linorder)"
  1314   shows "(LIM x F. f x :> at_top) \<longleftrightarrow> (\<forall>Z. eventually (\<lambda>x. Z < f x) F)"
  1315   by (metis eventually_elim1[of _ F] eventually_gt_at_top order_less_imp_le
  1316             filterlim_at_top[of f F] filterlim_iff[of f at_top F])
  1317 
  1318 lemma filterlim_at_top_ge:
  1319   fixes f :: "'a \<Rightarrow> ('b::linorder)" and c :: "'b"
  1320   shows "(LIM x F. f x :> at_top) \<longleftrightarrow> (\<forall>Z\<ge>c. eventually (\<lambda>x. Z \<le> f x) F)"
  1321   unfolding at_top_sub[of c] filterlim_INF by (auto simp add: filterlim_principal)
  1322 
  1323 lemma filterlim_at_top_at_top:
  1324   fixes f :: "'a::linorder \<Rightarrow> 'b::linorder"
  1325   assumes mono: "\<And>x y. Q x \<Longrightarrow> Q y \<Longrightarrow> x \<le> y \<Longrightarrow> f x \<le> f y"
  1326   assumes bij: "\<And>x. P x \<Longrightarrow> f (g x) = x" "\<And>x. P x \<Longrightarrow> Q (g x)"
  1327   assumes Q: "eventually Q at_top"
  1328   assumes P: "eventually P at_top"
  1329   shows "filterlim f at_top at_top"
  1330 proof -
  1331   from P obtain x where x: "\<And>y. x \<le> y \<Longrightarrow> P y"
  1332     unfolding eventually_at_top_linorder by auto
  1333   show ?thesis
  1334   proof (intro filterlim_at_top_ge[THEN iffD2] allI impI)
  1335     fix z assume "x \<le> z"
  1336     with x have "P z" by auto
  1337     have "eventually (\<lambda>x. g z \<le> x) at_top"
  1338       by (rule eventually_ge_at_top)
  1339     with Q show "eventually (\<lambda>x. z \<le> f x) at_top"
  1340       by eventually_elim (metis mono bij `P z`)
  1341   qed
  1342 qed
  1343 
  1344 lemma filterlim_at_top_gt:
  1345   fixes f :: "'a \<Rightarrow> ('b::unbounded_dense_linorder)" and c :: "'b"
  1346   shows "(LIM x F. f x :> at_top) \<longleftrightarrow> (\<forall>Z>c. eventually (\<lambda>x. Z \<le> f x) F)"
  1347   by (metis filterlim_at_top order_less_le_trans gt_ex filterlim_at_top_ge)
  1348 
  1349 lemma filterlim_at_bot: 
  1350   fixes f :: "'a \<Rightarrow> ('b::linorder)"
  1351   shows "(LIM x F. f x :> at_bot) \<longleftrightarrow> (\<forall>Z. eventually (\<lambda>x. f x \<le> Z) F)"
  1352   by (auto simp: filterlim_iff eventually_at_bot_linorder elim!: eventually_elim1)
  1353 
  1354 lemma filterlim_at_bot_dense:
  1355   fixes f :: "'a \<Rightarrow> ('b::{dense_linorder, no_bot})"
  1356   shows "(LIM x F. f x :> at_bot) \<longleftrightarrow> (\<forall>Z. eventually (\<lambda>x. f x < Z) F)"
  1357 proof (auto simp add: filterlim_at_bot[of f F])
  1358   fix Z :: 'b
  1359   from lt_ex [of Z] obtain Z' where 1: "Z' < Z" ..
  1360   assume "\<forall>Z. eventually (\<lambda>x. f x \<le> Z) F"
  1361   hence "eventually (\<lambda>x. f x \<le> Z') F" by auto
  1362   thus "eventually (\<lambda>x. f x < Z) F"
  1363     apply (rule eventually_mono[rotated])
  1364     using 1 by auto
  1365   next 
  1366     fix Z :: 'b 
  1367     show "\<forall>Z. eventually (\<lambda>x. f x < Z) F \<Longrightarrow> eventually (\<lambda>x. f x \<le> Z) F"
  1368       by (drule spec [of _ Z], erule eventually_mono[rotated], auto simp add: less_imp_le)
  1369 qed
  1370 
  1371 lemma filterlim_at_bot_le:
  1372   fixes f :: "'a \<Rightarrow> ('b::linorder)" and c :: "'b"
  1373   shows "(LIM x F. f x :> at_bot) \<longleftrightarrow> (\<forall>Z\<le>c. eventually (\<lambda>x. Z \<ge> f x) F)"
  1374   unfolding filterlim_at_bot
  1375 proof safe
  1376   fix Z assume *: "\<forall>Z\<le>c. eventually (\<lambda>x. Z \<ge> f x) F"
  1377   with *[THEN spec, of "min Z c"] show "eventually (\<lambda>x. Z \<ge> f x) F"
  1378     by (auto elim!: eventually_elim1)
  1379 qed simp
  1380 
  1381 lemma filterlim_at_bot_lt:
  1382   fixes f :: "'a \<Rightarrow> ('b::unbounded_dense_linorder)" and c :: "'b"
  1383   shows "(LIM x F. f x :> at_bot) \<longleftrightarrow> (\<forall>Z<c. eventually (\<lambda>x. Z \<ge> f x) F)"
  1384   by (metis filterlim_at_bot filterlim_at_bot_le lt_ex order_le_less_trans)
  1385 
  1386 lemma filterlim_at_bot_at_right:
  1387   fixes f :: "'a::linorder_topology \<Rightarrow> 'b::linorder"
  1388   assumes mono: "\<And>x y. Q x \<Longrightarrow> Q y \<Longrightarrow> x \<le> y \<Longrightarrow> f x \<le> f y"
  1389   assumes bij: "\<And>x. P x \<Longrightarrow> f (g x) = x" "\<And>x. P x \<Longrightarrow> Q (g x)"
  1390   assumes Q: "eventually Q (at_right a)" and bound: "\<And>b. Q b \<Longrightarrow> a < b"
  1391   assumes P: "eventually P at_bot"
  1392   shows "filterlim f at_bot (at_right a)"
  1393 proof -
  1394   from P obtain x where x: "\<And>y. y \<le> x \<Longrightarrow> P y"
  1395     unfolding eventually_at_bot_linorder by auto
  1396   show ?thesis
  1397   proof (intro filterlim_at_bot_le[THEN iffD2] allI impI)
  1398     fix z assume "z \<le> x"
  1399     with x have "P z" by auto
  1400     have "eventually (\<lambda>x. x \<le> g z) (at_right a)"
  1401       using bound[OF bij(2)[OF `P z`]]
  1402       unfolding eventually_at_right[OF bound[OF bij(2)[OF `P z`]]] by (auto intro!: exI[of _ "g z"])
  1403     with Q show "eventually (\<lambda>x. f x \<le> z) (at_right a)"
  1404       by eventually_elim (metis bij `P z` mono)
  1405   qed
  1406 qed
  1407 
  1408 lemma filterlim_at_top_at_left:
  1409   fixes f :: "'a::linorder_topology \<Rightarrow> 'b::linorder"
  1410   assumes mono: "\<And>x y. Q x \<Longrightarrow> Q y \<Longrightarrow> x \<le> y \<Longrightarrow> f x \<le> f y"
  1411   assumes bij: "\<And>x. P x \<Longrightarrow> f (g x) = x" "\<And>x. P x \<Longrightarrow> Q (g x)"
  1412   assumes Q: "eventually Q (at_left a)" and bound: "\<And>b. Q b \<Longrightarrow> b < a"
  1413   assumes P: "eventually P at_top"
  1414   shows "filterlim f at_top (at_left a)"
  1415 proof -
  1416   from P obtain x where x: "\<And>y. x \<le> y \<Longrightarrow> P y"
  1417     unfolding eventually_at_top_linorder by auto
  1418   show ?thesis
  1419   proof (intro filterlim_at_top_ge[THEN iffD2] allI impI)
  1420     fix z assume "x \<le> z"
  1421     with x have "P z" by auto
  1422     have "eventually (\<lambda>x. g z \<le> x) (at_left a)"
  1423       using bound[OF bij(2)[OF `P z`]]
  1424       unfolding eventually_at_left[OF bound[OF bij(2)[OF `P z`]]] by (auto intro!: exI[of _ "g z"])
  1425     with Q show "eventually (\<lambda>x. z \<le> f x) (at_left a)"
  1426       by eventually_elim (metis bij `P z` mono)
  1427   qed
  1428 qed
  1429 
  1430 lemma filterlim_split_at:
  1431   "filterlim f F (at_left x) \<Longrightarrow> filterlim f F (at_right x) \<Longrightarrow> filterlim f F (at (x::'a::linorder_topology))"
  1432   by (subst at_eq_sup_left_right) (rule filterlim_sup)
  1433 
  1434 lemma filterlim_at_split:
  1435   "filterlim f F (at (x::'a::linorder_topology)) \<longleftrightarrow> filterlim f F (at_left x) \<and> filterlim f F (at_right x)"
  1436   by (subst at_eq_sup_left_right) (simp add: filterlim_def filtermap_sup)
  1437 
  1438 lemma eventually_nhds_top:
  1439   fixes P :: "'a :: {order_top, linorder_topology} \<Rightarrow> bool"
  1440   assumes "(b::'a) < top"
  1441   shows "eventually P (nhds top) \<longleftrightarrow> (\<exists>b<top. (\<forall>z. b < z \<longrightarrow> P z))"
  1442   unfolding eventually_nhds
  1443 proof safe
  1444   fix S :: "'a set" assume "open S" "top \<in> S"
  1445   note open_left[OF this `b < top`]
  1446   moreover assume "\<forall>s\<in>S. P s"
  1447   ultimately show "\<exists>b<top. \<forall>z>b. P z"
  1448     by (auto simp: subset_eq Ball_def)
  1449 next
  1450   fix b assume "b < top" "\<forall>z>b. P z"
  1451   then show "\<exists>S. open S \<and> top \<in> S \<and> (\<forall>xa\<in>S. P xa)"
  1452     by (intro exI[of _ "{b <..}"]) auto
  1453 qed
  1454 
  1455 lemma tendsto_at_within_iff_tendsto_nhds:
  1456   "(g ---> g l) (at l within S) \<longleftrightarrow> (g ---> g l) (inf (nhds l) (principal S))"
  1457   unfolding tendsto_def eventually_at_filter eventually_inf_principal
  1458   by (intro ext all_cong imp_cong) (auto elim!: eventually_elim1)
  1459 
  1460 subsection {* Limits on sequences *}
  1461 
  1462 abbreviation (in topological_space)
  1463   LIMSEQ :: "[nat \<Rightarrow> 'a, 'a] \<Rightarrow> bool"
  1464     ("((_)/ ----> (_))" [60, 60] 60) where
  1465   "X ----> L \<equiv> (X ---> L) sequentially"
  1466 
  1467 abbreviation (in t2_space) lim :: "(nat \<Rightarrow> 'a) \<Rightarrow> 'a" where
  1468   "lim X \<equiv> Lim sequentially X"
  1469 
  1470 definition (in topological_space) convergent :: "(nat \<Rightarrow> 'a) \<Rightarrow> bool" where
  1471   "convergent X = (\<exists>L. X ----> L)"
  1472 
  1473 lemma lim_def: "lim X = (THE L. X ----> L)"
  1474   unfolding Lim_def ..
  1475 
  1476 subsubsection {* Monotone sequences and subsequences *}
  1477 
  1478 definition
  1479   monoseq :: "(nat \<Rightarrow> 'a::order) \<Rightarrow> bool" where
  1480     --{*Definition of monotonicity.
  1481         The use of disjunction here complicates proofs considerably.
  1482         One alternative is to add a Boolean argument to indicate the direction.
  1483         Another is to develop the notions of increasing and decreasing first.*}
  1484   "monoseq X = ((\<forall>m. \<forall>n\<ge>m. X m \<le> X n) \<or> (\<forall>m. \<forall>n\<ge>m. X n \<le> X m))"
  1485 
  1486 abbreviation incseq :: "(nat \<Rightarrow> 'a::order) \<Rightarrow> bool" where
  1487   "incseq X \<equiv> mono X"
  1488 
  1489 lemma incseq_def: "incseq X \<longleftrightarrow> (\<forall>m. \<forall>n\<ge>m. X n \<ge> X m)"
  1490   unfolding mono_def ..
  1491 
  1492 abbreviation decseq :: "(nat \<Rightarrow> 'a::order) \<Rightarrow> bool" where
  1493   "decseq X \<equiv> antimono X"
  1494 
  1495 lemma decseq_def: "decseq X \<longleftrightarrow> (\<forall>m. \<forall>n\<ge>m. X n \<le> X m)"
  1496   unfolding antimono_def ..
  1497 
  1498 definition
  1499   subseq :: "(nat \<Rightarrow> nat) \<Rightarrow> bool" where
  1500     --{*Definition of subsequence*}
  1501   "subseq f \<longleftrightarrow> (\<forall>m. \<forall>n>m. f m < f n)"
  1502 
  1503 lemma incseq_SucI:
  1504   "(\<And>n. X n \<le> X (Suc n)) \<Longrightarrow> incseq X"
  1505   using lift_Suc_mono_le[of X]
  1506   by (auto simp: incseq_def)
  1507 
  1508 lemma incseqD: "\<And>i j. incseq f \<Longrightarrow> i \<le> j \<Longrightarrow> f i \<le> f j"
  1509   by (auto simp: incseq_def)
  1510 
  1511 lemma incseq_SucD: "incseq A \<Longrightarrow> A i \<le> A (Suc i)"
  1512   using incseqD[of A i "Suc i"] by auto
  1513 
  1514 lemma incseq_Suc_iff: "incseq f \<longleftrightarrow> (\<forall>n. f n \<le> f (Suc n))"
  1515   by (auto intro: incseq_SucI dest: incseq_SucD)
  1516 
  1517 lemma incseq_const[simp, intro]: "incseq (\<lambda>x. k)"
  1518   unfolding incseq_def by auto
  1519 
  1520 lemma decseq_SucI:
  1521   "(\<And>n. X (Suc n) \<le> X n) \<Longrightarrow> decseq X"
  1522   using order.lift_Suc_mono_le[OF dual_order, of X]
  1523   by (auto simp: decseq_def)
  1524 
  1525 lemma decseqD: "\<And>i j. decseq f \<Longrightarrow> i \<le> j \<Longrightarrow> f j \<le> f i"
  1526   by (auto simp: decseq_def)
  1527 
  1528 lemma decseq_SucD: "decseq A \<Longrightarrow> A (Suc i) \<le> A i"
  1529   using decseqD[of A i "Suc i"] by auto
  1530 
  1531 lemma decseq_Suc_iff: "decseq f \<longleftrightarrow> (\<forall>n. f (Suc n) \<le> f n)"
  1532   by (auto intro: decseq_SucI dest: decseq_SucD)
  1533 
  1534 lemma decseq_const[simp, intro]: "decseq (\<lambda>x. k)"
  1535   unfolding decseq_def by auto
  1536 
  1537 lemma monoseq_iff: "monoseq X \<longleftrightarrow> incseq X \<or> decseq X"
  1538   unfolding monoseq_def incseq_def decseq_def ..
  1539 
  1540 lemma monoseq_Suc:
  1541   "monoseq X \<longleftrightarrow> (\<forall>n. X n \<le> X (Suc n)) \<or> (\<forall>n. X (Suc n) \<le> X n)"
  1542   unfolding monoseq_iff incseq_Suc_iff decseq_Suc_iff ..
  1543 
  1544 lemma monoI1: "\<forall>m. \<forall> n \<ge> m. X m \<le> X n ==> monoseq X"
  1545 by (simp add: monoseq_def)
  1546 
  1547 lemma monoI2: "\<forall>m. \<forall> n \<ge> m. X n \<le> X m ==> monoseq X"
  1548 by (simp add: monoseq_def)
  1549 
  1550 lemma mono_SucI1: "\<forall>n. X n \<le> X (Suc n) ==> monoseq X"
  1551 by (simp add: monoseq_Suc)
  1552 
  1553 lemma mono_SucI2: "\<forall>n. X (Suc n) \<le> X n ==> monoseq X"
  1554 by (simp add: monoseq_Suc)
  1555 
  1556 lemma monoseq_minus:
  1557   fixes a :: "nat \<Rightarrow> 'a::ordered_ab_group_add"
  1558   assumes "monoseq a"
  1559   shows "monoseq (\<lambda> n. - a n)"
  1560 proof (cases "\<forall> m. \<forall> n \<ge> m. a m \<le> a n")
  1561   case True
  1562   hence "\<forall> m. \<forall> n \<ge> m. - a n \<le> - a m" by auto
  1563   thus ?thesis by (rule monoI2)
  1564 next
  1565   case False
  1566   hence "\<forall> m. \<forall> n \<ge> m. - a m \<le> - a n" using `monoseq a`[unfolded monoseq_def] by auto
  1567   thus ?thesis by (rule monoI1)
  1568 qed
  1569 
  1570 text{*Subsequence (alternative definition, (e.g. Hoskins)*}
  1571 
  1572 lemma subseq_Suc_iff: "subseq f = (\<forall>n. (f n) < (f (Suc n)))"
  1573 apply (simp add: subseq_def)
  1574 apply (auto dest!: less_imp_Suc_add)
  1575 apply (induct_tac k)
  1576 apply (auto intro: less_trans)
  1577 done
  1578 
  1579 text{* for any sequence, there is a monotonic subsequence *}
  1580 lemma seq_monosub:
  1581   fixes s :: "nat => 'a::linorder"
  1582   shows "\<exists>f. subseq f \<and> monoseq (\<lambda>n. (s (f n)))"
  1583 proof cases
  1584   assume "\<forall>n. \<exists>p>n. \<forall>m\<ge>p. s m \<le> s p"
  1585   then have "\<exists>f. \<forall>n. (\<forall>m\<ge>f n. s m \<le> s (f n)) \<and> f n < f (Suc n)"
  1586     by (intro dependent_nat_choice) (auto simp: conj_commute)
  1587   then obtain f where "subseq f" and mono: "\<And>n m. f n \<le> m \<Longrightarrow> s m \<le> s (f n)"
  1588     by (auto simp: subseq_Suc_iff)
  1589   moreover 
  1590   then have "incseq f"
  1591     unfolding subseq_Suc_iff incseq_Suc_iff by (auto intro: less_imp_le)
  1592   then have "monoseq (\<lambda>n. s (f n))"
  1593     by (auto simp add: incseq_def intro!: mono monoI2)
  1594   ultimately show ?thesis
  1595     by auto
  1596 next
  1597   assume "\<not> (\<forall>n. \<exists>p>n. (\<forall>m\<ge>p. s m \<le> s p))"
  1598   then obtain N where N: "\<And>p. p > N \<Longrightarrow> \<exists>m>p. s p < s m" by (force simp: not_le le_less)
  1599   have "\<exists>f. \<forall>n. N < f n \<and> f n < f (Suc n) \<and> s (f n) \<le> s (f (Suc n))"
  1600   proof (intro dependent_nat_choice)
  1601     fix x assume "N < x" with N[of x] show "\<exists>y>N. x < y \<and> s x \<le> s y"
  1602       by (auto intro: less_trans)
  1603   qed auto
  1604   then show ?thesis
  1605     by (auto simp: monoseq_iff incseq_Suc_iff subseq_Suc_iff)
  1606 qed
  1607 
  1608 lemma seq_suble: assumes sf: "subseq f" shows "n \<le> f n"
  1609 proof(induct n)
  1610   case 0 thus ?case by simp
  1611 next
  1612   case (Suc n)
  1613   from sf[unfolded subseq_Suc_iff, rule_format, of n] Suc.hyps
  1614   have "n < f (Suc n)" by arith
  1615   thus ?case by arith
  1616 qed
  1617 
  1618 lemma eventually_subseq:
  1619   "subseq r \<Longrightarrow> eventually P sequentially \<Longrightarrow> eventually (\<lambda>n. P (r n)) sequentially"
  1620   unfolding eventually_sequentially by (metis seq_suble le_trans)
  1621 
  1622 lemma not_eventually_sequentiallyD:
  1623   assumes P: "\<not> eventually P sequentially"
  1624   shows "\<exists>r. subseq r \<and> (\<forall>n. \<not> P (r n))"
  1625 proof -
  1626   from P have "\<forall>n. \<exists>m\<ge>n. \<not> P m"
  1627     unfolding eventually_sequentially by (simp add: not_less)
  1628   then obtain r where "\<And>n. r n \<ge> n" "\<And>n. \<not> P (r n)"
  1629     by (auto simp: choice_iff)
  1630   then show ?thesis
  1631     by (auto intro!: exI[of _ "\<lambda>n. r (((Suc \<circ> r) ^^ Suc n) 0)"]
  1632              simp: less_eq_Suc_le subseq_Suc_iff)
  1633 qed
  1634 
  1635 lemma filterlim_subseq: "subseq f \<Longrightarrow> filterlim f sequentially sequentially"
  1636   unfolding filterlim_iff by (metis eventually_subseq)
  1637 
  1638 lemma subseq_o: "subseq r \<Longrightarrow> subseq s \<Longrightarrow> subseq (r \<circ> s)"
  1639   unfolding subseq_def by simp
  1640 
  1641 lemma subseq_mono: assumes "subseq r" "m < n" shows "r m < r n"
  1642   using assms by (auto simp: subseq_def)
  1643 
  1644 lemma incseq_imp_monoseq:  "incseq X \<Longrightarrow> monoseq X"
  1645   by (simp add: incseq_def monoseq_def)
  1646 
  1647 lemma decseq_imp_monoseq:  "decseq X \<Longrightarrow> monoseq X"
  1648   by (simp add: decseq_def monoseq_def)
  1649 
  1650 lemma decseq_eq_incseq:
  1651   fixes X :: "nat \<Rightarrow> 'a::ordered_ab_group_add" shows "decseq X = incseq (\<lambda>n. - X n)" 
  1652   by (simp add: decseq_def incseq_def)
  1653 
  1654 lemma INT_decseq_offset:
  1655   assumes "decseq F"
  1656   shows "(\<Inter>i. F i) = (\<Inter>i\<in>{n..}. F i)"
  1657 proof safe
  1658   fix x i assume x: "x \<in> (\<Inter>i\<in>{n..}. F i)"
  1659   show "x \<in> F i"
  1660   proof cases
  1661     from x have "x \<in> F n" by auto
  1662     also assume "i \<le> n" with `decseq F` have "F n \<subseteq> F i"
  1663       unfolding decseq_def by simp
  1664     finally show ?thesis .
  1665   qed (insert x, simp)
  1666 qed auto
  1667 
  1668 lemma LIMSEQ_const_iff:
  1669   fixes k l :: "'a::t2_space"
  1670   shows "(\<lambda>n. k) ----> l \<longleftrightarrow> k = l"
  1671   using trivial_limit_sequentially by (rule tendsto_const_iff)
  1672 
  1673 lemma LIMSEQ_SUP:
  1674   "incseq X \<Longrightarrow> X ----> (SUP i. X i :: 'a :: {complete_linorder, linorder_topology})"
  1675   by (intro increasing_tendsto)
  1676      (auto simp: SUP_upper less_SUP_iff incseq_def eventually_sequentially intro: less_le_trans)
  1677 
  1678 lemma LIMSEQ_INF:
  1679   "decseq X \<Longrightarrow> X ----> (INF i. X i :: 'a :: {complete_linorder, linorder_topology})"
  1680   by (intro decreasing_tendsto)
  1681      (auto simp: INF_lower INF_less_iff decseq_def eventually_sequentially intro: le_less_trans)
  1682 
  1683 lemma LIMSEQ_ignore_initial_segment:
  1684   "f ----> a \<Longrightarrow> (\<lambda>n. f (n + k)) ----> a"
  1685   unfolding tendsto_def
  1686   by (subst eventually_sequentially_seg[where k=k])
  1687 
  1688 lemma LIMSEQ_offset:
  1689   "(\<lambda>n. f (n + k)) ----> a \<Longrightarrow> f ----> a"
  1690   unfolding tendsto_def
  1691   by (subst (asm) eventually_sequentially_seg[where k=k])
  1692 
  1693 lemma LIMSEQ_Suc: "f ----> l \<Longrightarrow> (\<lambda>n. f (Suc n)) ----> l"
  1694 by (drule_tac k="Suc 0" in LIMSEQ_ignore_initial_segment, simp)
  1695 
  1696 lemma LIMSEQ_imp_Suc: "(\<lambda>n. f (Suc n)) ----> l \<Longrightarrow> f ----> l"
  1697 by (rule_tac k="Suc 0" in LIMSEQ_offset, simp)
  1698 
  1699 lemma LIMSEQ_Suc_iff: "(\<lambda>n. f (Suc n)) ----> l = f ----> l"
  1700 by (blast intro: LIMSEQ_imp_Suc LIMSEQ_Suc)
  1701 
  1702 lemma LIMSEQ_unique:
  1703   fixes a b :: "'a::t2_space"
  1704   shows "\<lbrakk>X ----> a; X ----> b\<rbrakk> \<Longrightarrow> a = b"
  1705   using trivial_limit_sequentially by (rule tendsto_unique)
  1706 
  1707 lemma LIMSEQ_le_const:
  1708   "\<lbrakk>X ----> (x::'a::linorder_topology); \<exists>N. \<forall>n\<ge>N. a \<le> X n\<rbrakk> \<Longrightarrow> a \<le> x"
  1709   using tendsto_le_const[of sequentially X x a] by (simp add: eventually_sequentially)
  1710 
  1711 lemma LIMSEQ_le:
  1712   "\<lbrakk>X ----> x; Y ----> y; \<exists>N. \<forall>n\<ge>N. X n \<le> Y n\<rbrakk> \<Longrightarrow> x \<le> (y::'a::linorder_topology)"
  1713   using tendsto_le[of sequentially Y y X x] by (simp add: eventually_sequentially)
  1714 
  1715 lemma LIMSEQ_le_const2:
  1716   "\<lbrakk>X ----> (x::'a::linorder_topology); \<exists>N. \<forall>n\<ge>N. X n \<le> a\<rbrakk> \<Longrightarrow> x \<le> a"
  1717   by (rule LIMSEQ_le[of X x "\<lambda>n. a"]) auto
  1718 
  1719 lemma convergentD: "convergent X ==> \<exists>L. (X ----> L)"
  1720 by (simp add: convergent_def)
  1721 
  1722 lemma convergentI: "(X ----> L) ==> convergent X"
  1723 by (auto simp add: convergent_def)
  1724 
  1725 lemma convergent_LIMSEQ_iff: "convergent X = (X ----> lim X)"
  1726 by (auto intro: theI LIMSEQ_unique simp add: convergent_def lim_def)
  1727 
  1728 lemma convergent_const: "convergent (\<lambda>n. c)"
  1729   by (rule convergentI, rule tendsto_const)
  1730 
  1731 lemma monoseq_le:
  1732   "monoseq a \<Longrightarrow> a ----> (x::'a::linorder_topology) \<Longrightarrow>
  1733     ((\<forall> n. a n \<le> x) \<and> (\<forall>m. \<forall>n\<ge>m. a m \<le> a n)) \<or> ((\<forall> n. x \<le> a n) \<and> (\<forall>m. \<forall>n\<ge>m. a n \<le> a m))"
  1734   by (metis LIMSEQ_le_const LIMSEQ_le_const2 decseq_def incseq_def monoseq_iff)
  1735 
  1736 lemma LIMSEQ_subseq_LIMSEQ:
  1737   "\<lbrakk> X ----> L; subseq f \<rbrakk> \<Longrightarrow> (X o f) ----> L"
  1738   unfolding comp_def by (rule filterlim_compose[of X, OF _ filterlim_subseq])
  1739 
  1740 lemma convergent_subseq_convergent:
  1741   "\<lbrakk>convergent X; subseq f\<rbrakk> \<Longrightarrow> convergent (X o f)"
  1742   unfolding convergent_def by (auto intro: LIMSEQ_subseq_LIMSEQ)
  1743 
  1744 lemma limI: "X ----> L ==> lim X = L"
  1745   by (rule tendsto_Lim) (rule trivial_limit_sequentially)
  1746 
  1747 lemma lim_le: "convergent f \<Longrightarrow> (\<And>n. f n \<le> (x::'a::linorder_topology)) \<Longrightarrow> lim f \<le> x"
  1748   using LIMSEQ_le_const2[of f "lim f" x] by (simp add: convergent_LIMSEQ_iff)
  1749 
  1750 subsubsection{*Increasing and Decreasing Series*}
  1751 
  1752 lemma incseq_le: "incseq X \<Longrightarrow> X ----> L \<Longrightarrow> X n \<le> (L::'a::linorder_topology)"
  1753   by (metis incseq_def LIMSEQ_le_const)
  1754 
  1755 lemma decseq_le: "decseq X \<Longrightarrow> X ----> L \<Longrightarrow> (L::'a::linorder_topology) \<le> X n"
  1756   by (metis decseq_def LIMSEQ_le_const2)
  1757 
  1758 subsection {* First countable topologies *}
  1759 
  1760 class first_countable_topology = topological_space +
  1761   assumes first_countable_basis:
  1762     "\<exists>A::nat \<Rightarrow> 'a set. (\<forall>i. x \<in> A i \<and> open (A i)) \<and> (\<forall>S. open S \<and> x \<in> S \<longrightarrow> (\<exists>i. A i \<subseteq> S))"
  1763 
  1764 lemma (in first_countable_topology) countable_basis_at_decseq:
  1765   obtains A :: "nat \<Rightarrow> 'a set" where
  1766     "\<And>i. open (A i)" "\<And>i. x \<in> (A i)"
  1767     "\<And>S. open S \<Longrightarrow> x \<in> S \<Longrightarrow> eventually (\<lambda>i. A i \<subseteq> S) sequentially"
  1768 proof atomize_elim
  1769   from first_countable_basis[of x] obtain A :: "nat \<Rightarrow> 'a set" where
  1770     nhds: "\<And>i. open (A i)" "\<And>i. x \<in> A i"
  1771     and incl: "\<And>S. open S \<Longrightarrow> x \<in> S \<Longrightarrow> \<exists>i. A i \<subseteq> S"  by auto
  1772   def F \<equiv> "\<lambda>n. \<Inter>i\<le>n. A i"
  1773   show "\<exists>A. (\<forall>i. open (A i)) \<and> (\<forall>i. x \<in> A i) \<and>
  1774       (\<forall>S. open S \<longrightarrow> x \<in> S \<longrightarrow> eventually (\<lambda>i. A i \<subseteq> S) sequentially)"
  1775   proof (safe intro!: exI[of _ F])
  1776     fix i
  1777     show "open (F i)" using nhds(1) by (auto simp: F_def)
  1778     show "x \<in> F i" using nhds(2) by (auto simp: F_def)
  1779   next
  1780     fix S assume "open S" "x \<in> S"
  1781     from incl[OF this] obtain i where "F i \<subseteq> S" unfolding F_def by auto
  1782     moreover have "\<And>j. i \<le> j \<Longrightarrow> F j \<subseteq> F i"
  1783       by (auto simp: F_def)
  1784     ultimately show "eventually (\<lambda>i. F i \<subseteq> S) sequentially"
  1785       by (auto simp: eventually_sequentially)
  1786   qed
  1787 qed
  1788 
  1789 lemma (in first_countable_topology) nhds_countable:
  1790   obtains X :: "nat \<Rightarrow> 'a set"
  1791   where "decseq X" "\<And>n. open (X n)" "\<And>n. x \<in> X n" "nhds x = (INF n. principal (X n))"
  1792 proof -
  1793   from first_countable_basis obtain A :: "nat \<Rightarrow> 'a set"
  1794     where A: "\<And>n. x \<in> A n" "\<And>n. open (A n)" "\<And>S. open S \<Longrightarrow> x \<in> S \<Longrightarrow> \<exists>i. A i \<subseteq> S"
  1795     by metis
  1796   show thesis
  1797   proof
  1798     show "decseq (\<lambda>n. \<Inter>i\<le>n. A i)"
  1799       by (auto simp: decseq_def)
  1800     show "\<And>n. x \<in> (\<Inter>i\<le>n. A i)" "\<And>n. open (\<Inter>i\<le>n. A i)"
  1801       using A by auto
  1802     show "nhds x = (INF n. principal (\<Inter> i\<le>n. A i))"
  1803       using A unfolding nhds_def
  1804       apply (intro INF_eq)
  1805       apply simp_all
  1806       apply force
  1807       apply (intro exI[of _ "\<Inter> i\<le>n. A i" for n] conjI open_INT)
  1808       apply auto
  1809       done
  1810   qed
  1811 qed
  1812 
  1813 lemma (in first_countable_topology) countable_basis:
  1814   obtains A :: "nat \<Rightarrow> 'a set" where
  1815     "\<And>i. open (A i)" "\<And>i. x \<in> A i"
  1816     "\<And>F. (\<forall>n. F n \<in> A n) \<Longrightarrow> F ----> x"
  1817 proof atomize_elim
  1818   obtain A :: "nat \<Rightarrow> 'a set" where A:
  1819     "\<And>i. open (A i)"
  1820     "\<And>i. x \<in> A i"
  1821     "\<And>S. open S \<Longrightarrow> x \<in> S \<Longrightarrow> eventually (\<lambda>i. A i \<subseteq> S) sequentially"
  1822     by (rule countable_basis_at_decseq) blast
  1823   {
  1824     fix F S assume "\<forall>n. F n \<in> A n" "open S" "x \<in> S"
  1825     with A(3)[of S] have "eventually (\<lambda>n. F n \<in> S) sequentially"
  1826       by (auto elim: eventually_elim1 simp: subset_eq)
  1827   }
  1828   with A show "\<exists>A. (\<forall>i. open (A i)) \<and> (\<forall>i. x \<in> A i) \<and> (\<forall>F. (\<forall>n. F n \<in> A n) \<longrightarrow> F ----> x)"
  1829     by (intro exI[of _ A]) (auto simp: tendsto_def)
  1830 qed
  1831 
  1832 lemma (in first_countable_topology) sequentially_imp_eventually_nhds_within:
  1833   assumes "\<forall>f. (\<forall>n. f n \<in> s) \<and> f ----> a \<longrightarrow> eventually (\<lambda>n. P (f n)) sequentially"
  1834   shows "eventually P (inf (nhds a) (principal s))"
  1835 proof (rule ccontr)
  1836   obtain A :: "nat \<Rightarrow> 'a set" where A:
  1837     "\<And>i. open (A i)"
  1838     "\<And>i. a \<in> A i"
  1839     "\<And>F. \<forall>n. F n \<in> A n \<Longrightarrow> F ----> a"
  1840     by (rule countable_basis) blast
  1841   assume "\<not> ?thesis"
  1842   with A have P: "\<exists>F. \<forall>n. F n \<in> s \<and> F n \<in> A n \<and> \<not> P (F n)"
  1843     unfolding eventually_inf_principal eventually_nhds by (intro choice) fastforce
  1844   then obtain F where F0: "\<forall>n. F n \<in> s" and F2: "\<forall>n. F n \<in> A n" and F3: "\<forall>n. \<not> P (F n)"
  1845     by blast
  1846   with A have "F ----> a" by auto
  1847   hence "eventually (\<lambda>n. P (F n)) sequentially"
  1848     using assms F0 by simp
  1849   thus "False" by (simp add: F3)
  1850 qed
  1851 
  1852 lemma (in first_countable_topology) eventually_nhds_within_iff_sequentially:
  1853   "eventually P (inf (nhds a) (principal s)) \<longleftrightarrow> 
  1854     (\<forall>f. (\<forall>n. f n \<in> s) \<and> f ----> a \<longrightarrow> eventually (\<lambda>n. P (f n)) sequentially)"
  1855 proof (safe intro!: sequentially_imp_eventually_nhds_within)
  1856   assume "eventually P (inf (nhds a) (principal s))" 
  1857   then obtain S where "open S" "a \<in> S" "\<forall>x\<in>S. x \<in> s \<longrightarrow> P x"
  1858     by (auto simp: eventually_inf_principal eventually_nhds)
  1859   moreover fix f assume "\<forall>n. f n \<in> s" "f ----> a"
  1860   ultimately show "eventually (\<lambda>n. P (f n)) sequentially"
  1861     by (auto dest!: topological_tendstoD elim: eventually_elim1)
  1862 qed
  1863 
  1864 lemma (in first_countable_topology) eventually_nhds_iff_sequentially:
  1865   "eventually P (nhds a) \<longleftrightarrow> (\<forall>f. f ----> a \<longrightarrow> eventually (\<lambda>n. P (f n)) sequentially)"
  1866   using eventually_nhds_within_iff_sequentially[of P a UNIV] by simp
  1867 
  1868 lemma tendsto_at_iff_sequentially:
  1869   fixes f :: "'a :: first_countable_topology \<Rightarrow> _"
  1870   shows "(f ---> a) (at x within s) \<longleftrightarrow> (\<forall>X. (\<forall>i. X i \<in> s - {x}) \<longrightarrow> X ----> x \<longrightarrow> ((f \<circ> X) ----> a))"
  1871   unfolding filterlim_def[of _ "nhds a"] le_filter_def eventually_filtermap at_within_def eventually_nhds_within_iff_sequentially comp_def
  1872   by metis
  1873 
  1874 subsection {* Function limit at a point *}
  1875 
  1876 abbreviation
  1877   LIM :: "('a::topological_space \<Rightarrow> 'b::topological_space) \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> bool"
  1878         ("((_)/ -- (_)/ --> (_))" [60, 0, 60] 60) where
  1879   "f -- a --> L \<equiv> (f ---> L) (at a)"
  1880 
  1881 lemma tendsto_within_open: "a \<in> S \<Longrightarrow> open S \<Longrightarrow> (f ---> l) (at a within S) \<longleftrightarrow> (f -- a --> l)"
  1882   unfolding tendsto_def by (simp add: at_within_open[where S=S])
  1883 
  1884 lemma LIM_const_not_eq[tendsto_intros]:
  1885   fixes a :: "'a::perfect_space"
  1886   fixes k L :: "'b::t2_space"
  1887   shows "k \<noteq> L \<Longrightarrow> \<not> (\<lambda>x. k) -- a --> L"
  1888   by (simp add: tendsto_const_iff)
  1889 
  1890 lemmas LIM_not_zero = LIM_const_not_eq [where L = 0]
  1891 
  1892 lemma LIM_const_eq:
  1893   fixes a :: "'a::perfect_space"
  1894   fixes k L :: "'b::t2_space"
  1895   shows "(\<lambda>x. k) -- a --> L \<Longrightarrow> k = L"
  1896   by (simp add: tendsto_const_iff)
  1897 
  1898 lemma LIM_unique:
  1899   fixes a :: "'a::perfect_space" and L M :: "'b::t2_space"
  1900   shows "f -- a --> L \<Longrightarrow> f -- a --> M \<Longrightarrow> L = M"
  1901   using at_neq_bot by (rule tendsto_unique)
  1902 
  1903 text {* Limits are equal for functions equal except at limit point *}
  1904 
  1905 lemma LIM_equal: "\<forall>x. x \<noteq> a --> (f x = g x) \<Longrightarrow> (f -- a --> l) \<longleftrightarrow> (g -- a --> l)"
  1906   unfolding tendsto_def eventually_at_topological by simp
  1907 
  1908 lemma LIM_cong: "a = b \<Longrightarrow> (\<And>x. x \<noteq> b \<Longrightarrow> f x = g x) \<Longrightarrow> l = m \<Longrightarrow> (f -- a --> l) \<longleftrightarrow> (g -- b --> m)"
  1909   by (simp add: LIM_equal)
  1910 
  1911 lemma LIM_cong_limit: "f -- x --> L \<Longrightarrow> K = L \<Longrightarrow> f -- x --> K"
  1912   by simp
  1913 
  1914 lemma tendsto_at_iff_tendsto_nhds:
  1915   "g -- l --> g l \<longleftrightarrow> (g ---> g l) (nhds l)"
  1916   unfolding tendsto_def eventually_at_filter
  1917   by (intro ext all_cong imp_cong) (auto elim!: eventually_elim1)
  1918 
  1919 lemma tendsto_compose:
  1920   "g -- l --> g l \<Longrightarrow> (f ---> l) F \<Longrightarrow> ((\<lambda>x. g (f x)) ---> g l) F"
  1921   unfolding tendsto_at_iff_tendsto_nhds by (rule filterlim_compose[of g])
  1922 
  1923 lemma LIM_o: "\<lbrakk>g -- l --> g l; f -- a --> l\<rbrakk> \<Longrightarrow> (g \<circ> f) -- a --> g l"
  1924   unfolding o_def by (rule tendsto_compose)
  1925 
  1926 lemma tendsto_compose_eventually:
  1927   "g -- l --> m \<Longrightarrow> (f ---> l) F \<Longrightarrow> eventually (\<lambda>x. f x \<noteq> l) F \<Longrightarrow> ((\<lambda>x. g (f x)) ---> m) F"
  1928   by (rule filterlim_compose[of g _ "at l"]) (auto simp add: filterlim_at)
  1929 
  1930 lemma LIM_compose_eventually:
  1931   assumes f: "f -- a --> b"
  1932   assumes g: "g -- b --> c"
  1933   assumes inj: "eventually (\<lambda>x. f x \<noteq> b) (at a)"
  1934   shows "(\<lambda>x. g (f x)) -- a --> c"
  1935   using g f inj by (rule tendsto_compose_eventually)
  1936 
  1937 lemma tendsto_compose_filtermap: "((g \<circ> f) ---> T) F \<longleftrightarrow> (g ---> T) (filtermap f F)"
  1938   by (simp add: filterlim_def filtermap_filtermap comp_def)
  1939 
  1940 subsubsection {* Relation of LIM and LIMSEQ *}
  1941 
  1942 lemma (in first_countable_topology) sequentially_imp_eventually_within:
  1943   "(\<forall>f. (\<forall>n. f n \<in> s \<and> f n \<noteq> a) \<and> f ----> a \<longrightarrow> eventually (\<lambda>n. P (f n)) sequentially) \<Longrightarrow>
  1944     eventually P (at a within s)"
  1945   unfolding at_within_def
  1946   by (intro sequentially_imp_eventually_nhds_within) auto
  1947 
  1948 lemma (in first_countable_topology) sequentially_imp_eventually_at:
  1949   "(\<forall>f. (\<forall>n. f n \<noteq> a) \<and> f ----> a \<longrightarrow> eventually (\<lambda>n. P (f n)) sequentially) \<Longrightarrow> eventually P (at a)"
  1950   using assms sequentially_imp_eventually_within [where s=UNIV] by simp
  1951 
  1952 lemma LIMSEQ_SEQ_conv1:
  1953   fixes f :: "'a::topological_space \<Rightarrow> 'b::topological_space"
  1954   assumes f: "f -- a --> l"
  1955   shows "\<forall>S. (\<forall>n. S n \<noteq> a) \<and> S ----> a \<longrightarrow> (\<lambda>n. f (S n)) ----> l"
  1956   using tendsto_compose_eventually [OF f, where F=sequentially] by simp
  1957 
  1958 lemma LIMSEQ_SEQ_conv2:
  1959   fixes f :: "'a::first_countable_topology \<Rightarrow> 'b::topological_space"
  1960   assumes "\<forall>S. (\<forall>n. S n \<noteq> a) \<and> S ----> a \<longrightarrow> (\<lambda>n. f (S n)) ----> l"
  1961   shows "f -- a --> l"
  1962   using assms unfolding tendsto_def [where l=l] by (simp add: sequentially_imp_eventually_at)
  1963 
  1964 lemma LIMSEQ_SEQ_conv:
  1965   "(\<forall>S. (\<forall>n. S n \<noteq> a) \<and> S ----> (a::'a::first_countable_topology) \<longrightarrow> (\<lambda>n. X (S n)) ----> L) =
  1966    (X -- a --> (L::'b::topological_space))"
  1967   using LIMSEQ_SEQ_conv2 LIMSEQ_SEQ_conv1 ..
  1968 
  1969 lemma sequentially_imp_eventually_at_left:
  1970   fixes a :: "'a :: {dense_linorder, linorder_topology, first_countable_topology}"
  1971   assumes b[simp]: "b < a"
  1972   assumes *: "\<And>f. (\<And>n. b < f n) \<Longrightarrow> (\<And>n. f n < a) \<Longrightarrow> incseq f \<Longrightarrow> f ----> a \<Longrightarrow> eventually (\<lambda>n. P (f n)) sequentially"
  1973   shows "eventually P (at_left a)"
  1974 proof (safe intro!: sequentially_imp_eventually_within)
  1975   fix X assume X: "\<forall>n. X n \<in> {..< a} \<and> X n \<noteq> a" "X ----> a"
  1976   show "eventually (\<lambda>n. P (X n)) sequentially"
  1977   proof (rule ccontr)
  1978     assume neg: "\<not> eventually (\<lambda>n. P (X n)) sequentially"
  1979     have "\<exists>s. \<forall>n. (\<not> P (X (s n)) \<and> b < X (s n)) \<and> (X (s n) \<le> X (s (Suc n)) \<and> Suc (s n) \<le> s (Suc n))"
  1980     proof (rule dependent_nat_choice)
  1981       have "\<not> eventually (\<lambda>n. b < X n \<longrightarrow> P (X n)) sequentially"
  1982         by (intro not_eventually_impI neg order_tendstoD(1) [OF X(2) b])
  1983       then show "\<exists>x. \<not> P (X x) \<and> b < X x"
  1984         by (auto dest!: not_eventuallyD)
  1985     next
  1986       fix x n
  1987       have "\<not> eventually (\<lambda>n. Suc x \<le> n \<longrightarrow> b < X n \<longrightarrow> X x < X n \<longrightarrow> P (X n)) sequentially"
  1988         using X by (intro not_eventually_impI order_tendstoD(1)[OF X(2)] eventually_ge_at_top neg) auto
  1989       then show "\<exists>n. (\<not> P (X n) \<and> b < X n) \<and> (X x \<le> X n \<and> Suc x \<le> n)"
  1990         by (auto dest!: not_eventuallyD)
  1991     qed
  1992     then guess s ..
  1993     then have "\<And>n. b < X (s n)" "\<And>n. X (s n) < a" "incseq (\<lambda>n. X (s n))" "(\<lambda>n. X (s n)) ----> a" "\<And>n. \<not> P (X (s n))"
  1994       using X by (auto simp: subseq_Suc_iff Suc_le_eq incseq_Suc_iff intro!: LIMSEQ_subseq_LIMSEQ[OF `X ----> a`, unfolded comp_def])
  1995     from *[OF this(1,2,3,4)] this(5) show False by auto
  1996   qed
  1997 qed
  1998 
  1999 lemma tendsto_at_left_sequentially:
  2000   fixes a :: "_ :: {dense_linorder, linorder_topology, first_countable_topology}"
  2001   assumes "b < a"
  2002   assumes *: "\<And>S. (\<And>n. S n < a) \<Longrightarrow> (\<And>n. b < S n) \<Longrightarrow> incseq S \<Longrightarrow> S ----> a \<Longrightarrow> (\<lambda>n. X (S n)) ----> L"
  2003   shows "(X ---> L) (at_left a)"
  2004   using assms unfolding tendsto_def [where l=L]
  2005   by (simp add: sequentially_imp_eventually_at_left)
  2006 
  2007 lemma sequentially_imp_eventually_at_right:
  2008   fixes a :: "'a :: {dense_linorder, linorder_topology, first_countable_topology}"
  2009   assumes b[simp]: "a < b"
  2010   assumes *: "\<And>f. (\<And>n. a < f n) \<Longrightarrow> (\<And>n. f n < b) \<Longrightarrow> decseq f \<Longrightarrow> f ----> a \<Longrightarrow> eventually (\<lambda>n. P (f n)) sequentially"
  2011   shows "eventually P (at_right a)"
  2012 proof (safe intro!: sequentially_imp_eventually_within)
  2013   fix X assume X: "\<forall>n. X n \<in> {a <..} \<and> X n \<noteq> a" "X ----> a"
  2014   show "eventually (\<lambda>n. P (X n)) sequentially"
  2015   proof (rule ccontr)
  2016     assume neg: "\<not> eventually (\<lambda>n. P (X n)) sequentially"
  2017     have "\<exists>s. \<forall>n. (\<not> P (X (s n)) \<and> X (s n) < b) \<and> (X (s (Suc n)) \<le> X (s n) \<and> Suc (s n) \<le> s (Suc n))"
  2018     proof (rule dependent_nat_choice)
  2019       have "\<not> eventually (\<lambda>n. X n < b \<longrightarrow> P (X n)) sequentially"
  2020         by (intro not_eventually_impI neg order_tendstoD(2) [OF X(2) b])
  2021       then show "\<exists>x. \<not> P (X x) \<and> X x < b"
  2022         by (auto dest!: not_eventuallyD)
  2023     next
  2024       fix x n
  2025       have "\<not> eventually (\<lambda>n. Suc x \<le> n \<longrightarrow> X n < b \<longrightarrow> X n < X x \<longrightarrow> P (X n)) sequentially"
  2026         using X by (intro not_eventually_impI order_tendstoD(2)[OF X(2)] eventually_ge_at_top neg) auto
  2027       then show "\<exists>n. (\<not> P (X n) \<and> X n < b) \<and> (X n \<le> X x \<and> Suc x \<le> n)"
  2028         by (auto dest!: not_eventuallyD)
  2029     qed
  2030     then guess s ..
  2031     then have "\<And>n. a < X (s n)" "\<And>n. X (s n) < b" "decseq (\<lambda>n. X (s n))" "(\<lambda>n. X (s n)) ----> a" "\<And>n. \<not> P (X (s n))"
  2032       using X by (auto simp: subseq_Suc_iff Suc_le_eq decseq_Suc_iff intro!: LIMSEQ_subseq_LIMSEQ[OF `X ----> a`, unfolded comp_def])
  2033     from *[OF this(1,2,3,4)] this(5) show False by auto
  2034   qed
  2035 qed
  2036 
  2037 lemma tendsto_at_right_sequentially:
  2038   fixes a :: "_ :: {dense_linorder, linorder_topology, first_countable_topology}"
  2039   assumes "a < b"
  2040   assumes *: "\<And>S. (\<And>n. a < S n) \<Longrightarrow> (\<And>n. S n < b) \<Longrightarrow> decseq S \<Longrightarrow> S ----> a \<Longrightarrow> (\<lambda>n. X (S n)) ----> L"
  2041   shows "(X ---> L) (at_right a)"
  2042   using assms unfolding tendsto_def [where l=L]
  2043   by (simp add: sequentially_imp_eventually_at_right)
  2044 
  2045 subsection {* Continuity *}
  2046 
  2047 subsubsection {* Continuity on a set *}
  2048 
  2049 definition continuous_on :: "'a set \<Rightarrow> ('a :: topological_space \<Rightarrow> 'b :: topological_space) \<Rightarrow> bool" where
  2050   "continuous_on s f \<longleftrightarrow> (\<forall>x\<in>s. (f ---> f x) (at x within s))"
  2051 
  2052 lemma continuous_on_cong [cong]:
  2053   "s = t \<Longrightarrow> (\<And>x. x \<in> t \<Longrightarrow> f x = g x) \<Longrightarrow> continuous_on s f \<longleftrightarrow> continuous_on t g"
  2054   unfolding continuous_on_def by (intro ball_cong filterlim_cong) (auto simp: eventually_at_filter)
  2055 
  2056 lemma continuous_on_topological:
  2057   "continuous_on s f \<longleftrightarrow>
  2058     (\<forall>x\<in>s. \<forall>B. open B \<longrightarrow> f x \<in> B \<longrightarrow> (\<exists>A. open A \<and> x \<in> A \<and> (\<forall>y\<in>s. y \<in> A \<longrightarrow> f y \<in> B)))"
  2059   unfolding continuous_on_def tendsto_def eventually_at_topological by metis
  2060 
  2061 lemma continuous_on_open_invariant:
  2062   "continuous_on s f \<longleftrightarrow> (\<forall>B. open B \<longrightarrow> (\<exists>A. open A \<and> A \<inter> s = f -` B \<inter> s))"
  2063 proof safe
  2064   fix B :: "'b set" assume "continuous_on s f" "open B"
  2065   then have "\<forall>x\<in>f -` B \<inter> s. (\<exists>A. open A \<and> x \<in> A \<and> s \<inter> A \<subseteq> f -` B)"
  2066     by (auto simp: continuous_on_topological subset_eq Ball_def imp_conjL)
  2067   then obtain A where "\<forall>x\<in>f -` B \<inter> s. open (A x) \<and> x \<in> A x \<and> s \<inter> A x \<subseteq> f -` B"
  2068     unfolding bchoice_iff ..
  2069   then show "\<exists>A. open A \<and> A \<inter> s = f -` B \<inter> s"
  2070     by (intro exI[of _ "\<Union>x\<in>f -` B \<inter> s. A x"]) auto
  2071 next
  2072   assume B: "\<forall>B. open B \<longrightarrow> (\<exists>A. open A \<and> A \<inter> s = f -` B \<inter> s)"
  2073   show "continuous_on s f"
  2074     unfolding continuous_on_topological
  2075   proof safe
  2076     fix x B assume "x \<in> s" "open B" "f x \<in> B"
  2077     with B obtain A where A: "open A" "A \<inter> s = f -` B \<inter> s" by auto
  2078     with `x \<in> s` `f x \<in> B` show "\<exists>A. open A \<and> x \<in> A \<and> (\<forall>y\<in>s. y \<in> A \<longrightarrow> f y \<in> B)"
  2079       by (intro exI[of _ A]) auto
  2080   qed
  2081 qed
  2082 
  2083 lemma continuous_on_open_vimage:
  2084   "open s \<Longrightarrow> continuous_on s f \<longleftrightarrow> (\<forall>B. open B \<longrightarrow> open (f -` B \<inter> s))"
  2085   unfolding continuous_on_open_invariant
  2086   by (metis open_Int Int_absorb Int_commute[of s] Int_assoc[of _ _ s])
  2087 
  2088 corollary continuous_imp_open_vimage:
  2089   assumes "continuous_on s f" "open s" "open B" "f -` B \<subseteq> s"
  2090     shows "open (f -` B)"
  2091 by (metis assms continuous_on_open_vimage le_iff_inf)
  2092 
  2093 corollary open_vimage[continuous_intros]:
  2094   assumes "open s" and "continuous_on UNIV f"
  2095   shows "open (f -` s)"
  2096   using assms unfolding continuous_on_open_vimage [OF open_UNIV]
  2097   by simp
  2098 
  2099 lemma continuous_on_closed_invariant:
  2100   "continuous_on s f \<longleftrightarrow> (\<forall>B. closed B \<longrightarrow> (\<exists>A. closed A \<and> A \<inter> s = f -` B \<inter> s))"
  2101 proof -
  2102   have *: "\<And>P Q::'b set\<Rightarrow>bool. (\<And>A. P A \<longleftrightarrow> Q (- A)) \<Longrightarrow> (\<forall>A. P A) \<longleftrightarrow> (\<forall>A. Q A)"
  2103     by (metis double_compl)
  2104   show ?thesis
  2105     unfolding continuous_on_open_invariant by (intro *) (auto simp: open_closed[symmetric])
  2106 qed
  2107 
  2108 lemma continuous_on_closed_vimage:
  2109   "closed s \<Longrightarrow> continuous_on s f \<longleftrightarrow> (\<forall>B. closed B \<longrightarrow> closed (f -` B \<inter> s))"
  2110   unfolding continuous_on_closed_invariant
  2111   by (metis closed_Int Int_absorb Int_commute[of s] Int_assoc[of _ _ s])
  2112 
  2113 corollary closed_vimage[continuous_intros]:
  2114   assumes "closed s" and "continuous_on UNIV f"
  2115   shows "closed (f -` s)"
  2116   using assms unfolding continuous_on_closed_vimage [OF closed_UNIV]
  2117   by simp
  2118 
  2119 lemma continuous_on_open_Union:
  2120   "(\<And>s. s \<in> S \<Longrightarrow> open s) \<Longrightarrow> (\<And>s. s \<in> S \<Longrightarrow> continuous_on s f) \<Longrightarrow> continuous_on (\<Union>S) f"
  2121   unfolding continuous_on_def by safe (metis open_Union at_within_open UnionI)
  2122 
  2123 lemma continuous_on_open_UN:
  2124   "(\<And>s. s \<in> S \<Longrightarrow> open (A s)) \<Longrightarrow> (\<And>s. s \<in> S \<Longrightarrow> continuous_on (A s) f) \<Longrightarrow> continuous_on (\<Union>s\<in>S. A s) f"
  2125   unfolding Union_image_eq[symmetric] by (rule continuous_on_open_Union) auto
  2126 
  2127 lemma continuous_on_closed_Un:
  2128   "closed s \<Longrightarrow> closed t \<Longrightarrow> continuous_on s f \<Longrightarrow> continuous_on t f \<Longrightarrow> continuous_on (s \<union> t) f"
  2129   by (auto simp add: continuous_on_closed_vimage closed_Un Int_Un_distrib)
  2130 
  2131 lemma continuous_on_If:
  2132   assumes closed: "closed s" "closed t" and cont: "continuous_on s f" "continuous_on t g"
  2133     and P: "\<And>x. x \<in> s \<Longrightarrow> \<not> P x \<Longrightarrow> f x = g x" "\<And>x. x \<in> t \<Longrightarrow> P x \<Longrightarrow> f x = g x"
  2134   shows "continuous_on (s \<union> t) (\<lambda>x. if P x then f x else g x)" (is "continuous_on _ ?h")
  2135 proof-
  2136   from P have "\<forall>x\<in>s. f x = ?h x" "\<forall>x\<in>t. g x = ?h x"
  2137     by auto
  2138   with cont have "continuous_on s ?h" "continuous_on t ?h"
  2139     by simp_all
  2140   with closed show ?thesis
  2141     by (rule continuous_on_closed_Un)
  2142 qed
  2143 
  2144 lemma continuous_on_id[continuous_intros]: "continuous_on s (\<lambda>x. x)"
  2145   unfolding continuous_on_def by fast
  2146 
  2147 lemma continuous_on_const[continuous_intros]: "continuous_on s (\<lambda>x. c)"
  2148   unfolding continuous_on_def by auto
  2149 
  2150 lemma continuous_on_compose[continuous_intros]:
  2151   "continuous_on s f \<Longrightarrow> continuous_on (f ` s) g \<Longrightarrow> continuous_on s (g o f)"
  2152   unfolding continuous_on_topological by simp metis
  2153 
  2154 lemma continuous_on_compose2:
  2155   "continuous_on t g \<Longrightarrow> continuous_on s f \<Longrightarrow> t = f ` s \<Longrightarrow> continuous_on s (\<lambda>x. g (f x))"
  2156   using continuous_on_compose[of s f g] by (simp add: comp_def)
  2157 
  2158 subsubsection {* Continuity at a point *}
  2159 
  2160 definition continuous :: "'a::t2_space filter \<Rightarrow> ('a \<Rightarrow> 'b::topological_space) \<Rightarrow> bool" where
  2161   "continuous F f \<longleftrightarrow> (f ---> f (Lim F (\<lambda>x. x))) F"
  2162 
  2163 lemma continuous_bot[continuous_intros, simp]: "continuous bot f"
  2164   unfolding continuous_def by auto
  2165 
  2166 lemma continuous_trivial_limit: "trivial_limit net \<Longrightarrow> continuous net f"
  2167   by simp
  2168 
  2169 lemma continuous_within: "continuous (at x within s) f \<longleftrightarrow> (f ---> f x) (at x within s)"
  2170   by (cases "trivial_limit (at x within s)") (auto simp add: Lim_ident_at continuous_def)
  2171 
  2172 lemma continuous_within_topological:
  2173   "continuous (at x within s) f \<longleftrightarrow>
  2174     (\<forall>B. open B \<longrightarrow> f x \<in> B \<longrightarrow> (\<exists>A. open A \<and> x \<in> A \<and> (\<forall>y\<in>s. y \<in> A \<longrightarrow> f y \<in> B)))"
  2175   unfolding continuous_within tendsto_def eventually_at_topological by metis
  2176 
  2177 lemma continuous_within_compose[continuous_intros]:
  2178   "continuous (at x within s) f \<Longrightarrow> continuous (at (f x) within f ` s) g \<Longrightarrow>
  2179   continuous (at x within s) (g o f)"
  2180   by (simp add: continuous_within_topological) metis
  2181 
  2182 lemma continuous_within_compose2:
  2183   "continuous (at x within s) f \<Longrightarrow> continuous (at (f x) within f ` s) g \<Longrightarrow>
  2184   continuous (at x within s) (\<lambda>x. g (f x))"
  2185   using continuous_within_compose[of x s f g] by (simp add: comp_def)
  2186 
  2187 lemma continuous_at: "continuous (at x) f \<longleftrightarrow> f -- x --> f x"
  2188   using continuous_within[of x UNIV f] by simp
  2189 
  2190 lemma continuous_ident[continuous_intros, simp]: "continuous (at x within S) (\<lambda>x. x)"
  2191   unfolding continuous_within by (rule tendsto_ident_at)
  2192 
  2193 lemma continuous_const[continuous_intros, simp]: "continuous F (\<lambda>x. c)"
  2194   unfolding continuous_def by (rule tendsto_const)
  2195 
  2196 lemma continuous_on_eq_continuous_within:
  2197   "continuous_on s f \<longleftrightarrow> (\<forall>x\<in>s. continuous (at x within s) f)"
  2198   unfolding continuous_on_def continuous_within ..
  2199 
  2200 abbreviation isCont :: "('a::t2_space \<Rightarrow> 'b::topological_space) \<Rightarrow> 'a \<Rightarrow> bool" where
  2201   "isCont f a \<equiv> continuous (at a) f"
  2202 
  2203 lemma isCont_def: "isCont f a \<longleftrightarrow> f -- a --> f a"
  2204   by (rule continuous_at)
  2205 
  2206 lemma continuous_at_within: "isCont f x \<Longrightarrow> continuous (at x within s) f"
  2207   by (auto intro: tendsto_mono at_le simp: continuous_at continuous_within)
  2208 
  2209 lemma continuous_on_eq_continuous_at: "open s \<Longrightarrow> continuous_on s f \<longleftrightarrow> (\<forall>x\<in>s. isCont f x)"
  2210   by (simp add: continuous_on_def continuous_at at_within_open[of _ s])
  2211 
  2212 lemma continuous_on_subset: "continuous_on s f \<Longrightarrow> t \<subseteq> s \<Longrightarrow> continuous_on t f"
  2213   unfolding continuous_on_def by (metis subset_eq tendsto_within_subset)
  2214 
  2215 lemma continuous_at_imp_continuous_on: "\<forall>x\<in>s. isCont f x \<Longrightarrow> continuous_on s f"
  2216   by (auto intro: continuous_at_within simp: continuous_on_eq_continuous_within)
  2217 
  2218 lemma isContI_continuous: "continuous (at x within UNIV) f \<Longrightarrow> isCont f x"
  2219   by simp
  2220 
  2221 lemma isCont_ident[continuous_intros, simp]: "isCont (\<lambda>x. x) a"
  2222   using continuous_ident by (rule isContI_continuous)
  2223 
  2224 lemmas isCont_const = continuous_const
  2225 
  2226 lemma isCont_o2: "isCont f a \<Longrightarrow> isCont g (f a) \<Longrightarrow> isCont (\<lambda>x. g (f x)) a"
  2227   unfolding isCont_def by (rule tendsto_compose)
  2228 
  2229 lemma isCont_o[continuous_intros]: "isCont f a \<Longrightarrow> isCont g (f a) \<Longrightarrow> isCont (g \<circ> f) a"
  2230   unfolding o_def by (rule isCont_o2)
  2231 
  2232 lemma isCont_tendsto_compose: "isCont g l \<Longrightarrow> (f ---> l) F \<Longrightarrow> ((\<lambda>x. g (f x)) ---> g l) F"
  2233   unfolding isCont_def by (rule tendsto_compose)
  2234 
  2235 lemma continuous_within_compose3:
  2236   "isCont g (f x) \<Longrightarrow> continuous (at x within s) f \<Longrightarrow> continuous (at x within s) (\<lambda>x. g (f x))"
  2237   using continuous_within_compose2[of x s f g] by (simp add: continuous_at_within)
  2238 
  2239 lemma filtermap_nhds_open_map:
  2240   assumes cont: "isCont f a" and open_map: "\<And>S. open S \<Longrightarrow> open (f`S)"
  2241   shows "filtermap f (nhds a) = nhds (f a)"
  2242   unfolding filter_eq_iff
  2243 proof safe
  2244   fix P assume "eventually P (filtermap f (nhds a))"
  2245   then guess S unfolding eventually_filtermap eventually_nhds ..
  2246   then show "eventually P (nhds (f a))"
  2247     unfolding eventually_nhds by (intro exI[of _ "f`S"]) (auto intro!: open_map)
  2248 qed (metis filterlim_iff tendsto_at_iff_tendsto_nhds isCont_def eventually_filtermap cont)
  2249 
  2250 lemma continuous_at_split: 
  2251   "continuous (at (x::'a::linorder_topology)) f = (continuous (at_left x) f \<and> continuous (at_right x) f)"
  2252   by (simp add: continuous_within filterlim_at_split)
  2253 
  2254 subsubsection{* Open-cover compactness *}
  2255 
  2256 context topological_space
  2257 begin
  2258 
  2259 definition compact :: "'a set \<Rightarrow> bool" where
  2260   compact_eq_heine_borel: -- "This name is used for backwards compatibility"
  2261     "compact S \<longleftrightarrow> (\<forall>C. (\<forall>c\<in>C. open c) \<and> S \<subseteq> \<Union>C \<longrightarrow> (\<exists>D\<subseteq>C. finite D \<and> S \<subseteq> \<Union>D))"
  2262 
  2263 lemma compactI:
  2264   assumes "\<And>C. \<forall>t\<in>C. open t \<Longrightarrow> s \<subseteq> \<Union> C \<Longrightarrow> \<exists>C'. C' \<subseteq> C \<and> finite C' \<and> s \<subseteq> \<Union> C'"
  2265   shows "compact s"
  2266   unfolding compact_eq_heine_borel using assms by metis
  2267 
  2268 lemma compact_empty[simp]: "compact {}"
  2269   by (auto intro!: compactI)
  2270 
  2271 lemma compactE:
  2272   assumes "compact s" and "\<forall>t\<in>C. open t" and "s \<subseteq> \<Union>C"
  2273   obtains C' where "C' \<subseteq> C" and "finite C'" and "s \<subseteq> \<Union>C'"
  2274   using assms unfolding compact_eq_heine_borel by metis
  2275 
  2276 lemma compactE_image:
  2277   assumes "compact s" and "\<forall>t\<in>C. open (f t)" and "s \<subseteq> (\<Union>c\<in>C. f c)"
  2278   obtains C' where "C' \<subseteq> C" and "finite C'" and "s \<subseteq> (\<Union>c\<in>C'. f c)"
  2279   using assms unfolding ball_simps[symmetric] SUP_def
  2280   by (metis (lifting) finite_subset_image compact_eq_heine_borel[of s])
  2281 
  2282 lemma compact_inter_closed [intro]:
  2283   assumes "compact s" and "closed t"
  2284   shows "compact (s \<inter> t)"
  2285 proof (rule compactI)
  2286   fix C assume C: "\<forall>c\<in>C. open c" and cover: "s \<inter> t \<subseteq> \<Union>C"
  2287   from C `closed t` have "\<forall>c\<in>C \<union> {-t}. open c" by auto
  2288   moreover from cover have "s \<subseteq> \<Union>(C \<union> {-t})" by auto
  2289   ultimately have "\<exists>D\<subseteq>C \<union> {-t}. finite D \<and> s \<subseteq> \<Union>D"
  2290     using `compact s` unfolding compact_eq_heine_borel by auto
  2291   then obtain D where "D \<subseteq> C \<union> {- t} \<and> finite D \<and> s \<subseteq> \<Union>D" ..
  2292   then show "\<exists>D\<subseteq>C. finite D \<and> s \<inter> t \<subseteq> \<Union>D"
  2293     by (intro exI[of _ "D - {-t}"]) auto
  2294 qed
  2295 
  2296 lemma inj_setminus: "inj_on uminus (A::'a set set)"
  2297   by (auto simp: inj_on_def)
  2298 
  2299 lemma compact_fip:
  2300   "compact U \<longleftrightarrow>
  2301     (\<forall>A. (\<forall>a\<in>A. closed a) \<longrightarrow> (\<forall>B \<subseteq> A. finite B \<longrightarrow> U \<inter> \<Inter>B \<noteq> {}) \<longrightarrow> U \<inter> \<Inter>A \<noteq> {})"
  2302   (is "_ \<longleftrightarrow> ?R")
  2303 proof (safe intro!: compact_eq_heine_borel[THEN iffD2])
  2304   fix A
  2305   assume "compact U"
  2306     and A: "\<forall>a\<in>A. closed a" "U \<inter> \<Inter>A = {}"
  2307     and fi: "\<forall>B \<subseteq> A. finite B \<longrightarrow> U \<inter> \<Inter>B \<noteq> {}"
  2308   from A have "(\<forall>a\<in>uminus`A. open a) \<and> U \<subseteq> \<Union>(uminus`A)"
  2309     by auto
  2310   with `compact U` obtain B where "B \<subseteq> A" "finite (uminus`B)" "U \<subseteq> \<Union>(uminus`B)"
  2311     unfolding compact_eq_heine_borel by (metis subset_image_iff)
  2312   with fi[THEN spec, of B] show False
  2313     by (auto dest: finite_imageD intro: inj_setminus)
  2314 next
  2315   fix A
  2316   assume ?R
  2317   assume "\<forall>a\<in>A. open a" "U \<subseteq> \<Union>A"
  2318   then have "U \<inter> \<Inter>(uminus`A) = {}" "\<forall>a\<in>uminus`A. closed a"
  2319     by auto
  2320   with `?R` obtain B where "B \<subseteq> A" "finite (uminus`B)" "U \<inter> \<Inter>(uminus`B) = {}"
  2321     by (metis subset_image_iff)
  2322   then show "\<exists>T\<subseteq>A. finite T \<and> U \<subseteq> \<Union>T"
  2323     by  (auto intro!: exI[of _ B] inj_setminus dest: finite_imageD)
  2324 qed
  2325 
  2326 lemma compact_imp_fip:
  2327   "compact s \<Longrightarrow> \<forall>t \<in> f. closed t \<Longrightarrow> \<forall>f'. finite f' \<and> f' \<subseteq> f \<longrightarrow> (s \<inter> (\<Inter> f') \<noteq> {}) \<Longrightarrow>
  2328     s \<inter> (\<Inter> f) \<noteq> {}"
  2329   unfolding compact_fip by auto
  2330 
  2331 lemma compact_imp_fip_image:
  2332   assumes "compact s"
  2333     and P: "\<And>i. i \<in> I \<Longrightarrow> closed (f i)"
  2334     and Q: "\<And>I'. finite I' \<Longrightarrow> I' \<subseteq> I \<Longrightarrow> (s \<inter> (\<Inter>i\<in>I'. f i) \<noteq> {})"
  2335   shows "s \<inter> (\<Inter>i\<in>I. f i) \<noteq> {}"
  2336 proof -
  2337   note `compact s`
  2338   moreover from P have "\<forall>i \<in> f ` I. closed i" by blast
  2339   moreover have "\<forall>A. finite A \<and> A \<subseteq> f ` I \<longrightarrow> (s \<inter> (\<Inter>A) \<noteq> {})"
  2340   proof (rule, rule, erule conjE)
  2341     fix A :: "'a set set"
  2342     assume "finite A"
  2343     moreover assume "A \<subseteq> f ` I"
  2344     ultimately obtain B where "B \<subseteq> I" and "finite B" and "A = f ` B"
  2345       using finite_subset_image [of A f I] by blast
  2346     with Q [of B] show "s \<inter> \<Inter>A \<noteq> {}" by simp
  2347   qed
  2348   ultimately have "s \<inter> (\<Inter>(f ` I)) \<noteq> {}" by (rule compact_imp_fip)
  2349   then show ?thesis by simp
  2350 qed
  2351 
  2352 end
  2353 
  2354 lemma (in t2_space) compact_imp_closed:
  2355   assumes "compact s" shows "closed s"
  2356 unfolding closed_def
  2357 proof (rule openI)
  2358   fix y assume "y \<in> - s"
  2359   let ?C = "\<Union>x\<in>s. {u. open u \<and> x \<in> u \<and> eventually (\<lambda>y. y \<notin> u) (nhds y)}"
  2360   note `compact s`
  2361   moreover have "\<forall>u\<in>?C. open u" by simp
  2362   moreover have "s \<subseteq> \<Union>?C"
  2363   proof
  2364     fix x assume "x \<in> s"
  2365     with `y \<in> - s` have "x \<noteq> y" by clarsimp
  2366     hence "\<exists>u v. open u \<and> open v \<and> x \<in> u \<and> y \<in> v \<and> u \<inter> v = {}"
  2367       by (rule hausdorff)
  2368     with `x \<in> s` show "x \<in> \<Union>?C"
  2369       unfolding eventually_nhds by auto
  2370   qed
  2371   ultimately obtain D where "D \<subseteq> ?C" and "finite D" and "s \<subseteq> \<Union>D"
  2372     by (rule compactE)
  2373   from `D \<subseteq> ?C` have "\<forall>x\<in>D. eventually (\<lambda>y. y \<notin> x) (nhds y)" by auto
  2374   with `finite D` have "eventually (\<lambda>y. y \<notin> \<Union>D) (nhds y)"
  2375     by (simp add: eventually_Ball_finite)
  2376   with `s \<subseteq> \<Union>D` have "eventually (\<lambda>y. y \<notin> s) (nhds y)"
  2377     by (auto elim!: eventually_mono [rotated])
  2378   thus "\<exists>t. open t \<and> y \<in> t \<and> t \<subseteq> - s"
  2379     by (simp add: eventually_nhds subset_eq)
  2380 qed
  2381 
  2382 lemma compact_continuous_image:
  2383   assumes f: "continuous_on s f" and s: "compact s"
  2384   shows "compact (f ` s)"
  2385 proof (rule compactI)
  2386   fix C assume "\<forall>c\<in>C. open c" and cover: "f`s \<subseteq> \<Union>C"
  2387   with f have "\<forall>c\<in>C. \<exists>A. open A \<and> A \<inter> s = f -` c \<inter> s"
  2388     unfolding continuous_on_open_invariant by blast
  2389   then obtain A where A: "\<forall>c\<in>C. open (A c) \<and> A c \<inter> s = f -` c \<inter> s"
  2390     unfolding bchoice_iff ..
  2391   with cover have "\<forall>c\<in>C. open (A c)" "s \<subseteq> (\<Union>c\<in>C. A c)"
  2392     by (fastforce simp add: subset_eq set_eq_iff)+
  2393   from compactE_image[OF s this] obtain D where "D \<subseteq> C" "finite D" "s \<subseteq> (\<Union>c\<in>D. A c)" .
  2394   with A show "\<exists>D \<subseteq> C. finite D \<and> f`s \<subseteq> \<Union>D"
  2395     by (intro exI[of _ D]) (fastforce simp add: subset_eq set_eq_iff)+
  2396 qed
  2397 
  2398 lemma continuous_on_inv:
  2399   fixes f :: "'a::topological_space \<Rightarrow> 'b::t2_space"
  2400   assumes "continuous_on s f"  "compact s"  "\<forall>x\<in>s. g (f x) = x"
  2401   shows "continuous_on (f ` s) g"
  2402 unfolding continuous_on_topological
  2403 proof (clarsimp simp add: assms(3))
  2404   fix x :: 'a and B :: "'a set"
  2405   assume "x \<in> s" and "open B" and "x \<in> B"
  2406   have 1: "\<forall>x\<in>s. f x \<in> f ` (s - B) \<longleftrightarrow> x \<in> s - B"
  2407     using assms(3) by (auto, metis)
  2408   have "continuous_on (s - B) f"
  2409     using `continuous_on s f` Diff_subset
  2410     by (rule continuous_on_subset)
  2411   moreover have "compact (s - B)"
  2412     using `open B` and `compact s`
  2413     unfolding Diff_eq by (intro compact_inter_closed closed_Compl)
  2414   ultimately have "compact (f ` (s - B))"
  2415     by (rule compact_continuous_image)
  2416   hence "closed (f ` (s - B))"
  2417     by (rule compact_imp_closed)
  2418   hence "open (- f ` (s - B))"
  2419     by (rule open_Compl)
  2420   moreover have "f x \<in> - f ` (s - B)"
  2421     using `x \<in> s` and `x \<in> B` by (simp add: 1)
  2422   moreover have "\<forall>y\<in>s. f y \<in> - f ` (s - B) \<longrightarrow> y \<in> B"
  2423     by (simp add: 1)
  2424   ultimately show "\<exists>A. open A \<and> f x \<in> A \<and> (\<forall>y\<in>s. f y \<in> A \<longrightarrow> y \<in> B)"
  2425     by fast
  2426 qed
  2427 
  2428 lemma continuous_on_inv_into:
  2429   fixes f :: "'a::topological_space \<Rightarrow> 'b::t2_space"
  2430   assumes s: "continuous_on s f" "compact s" and f: "inj_on f s"
  2431   shows "continuous_on (f ` s) (the_inv_into s f)"
  2432   by (rule continuous_on_inv[OF s]) (auto simp: the_inv_into_f_f[OF f])
  2433 
  2434 lemma (in linorder_topology) compact_attains_sup:
  2435   assumes "compact S" "S \<noteq> {}"
  2436   shows "\<exists>s\<in>S. \<forall>t\<in>S. t \<le> s"
  2437 proof (rule classical)
  2438   assume "\<not> (\<exists>s\<in>S. \<forall>t\<in>S. t \<le> s)"
  2439   then obtain t where t: "\<forall>s\<in>S. t s \<in> S" and "\<forall>s\<in>S. s < t s"
  2440     by (metis not_le)
  2441   then have "\<forall>s\<in>S. open {..< t s}" "S \<subseteq> (\<Union>s\<in>S. {..< t s})"
  2442     by auto
  2443   with `compact S` obtain C where "C \<subseteq> S" "finite C" and C: "S \<subseteq> (\<Union>s\<in>C. {..< t s})"
  2444     by (erule compactE_image)
  2445   with `S \<noteq> {}` have Max: "Max (t`C) \<in> t`C" and "\<forall>s\<in>t`C. s \<le> Max (t`C)"
  2446     by (auto intro!: Max_in)
  2447   with C have "S \<subseteq> {..< Max (t`C)}"
  2448     by (auto intro: less_le_trans simp: subset_eq)
  2449   with t Max `C \<subseteq> S` show ?thesis
  2450     by fastforce
  2451 qed
  2452 
  2453 lemma (in linorder_topology) compact_attains_inf:
  2454   assumes "compact S" "S \<noteq> {}"
  2455   shows "\<exists>s\<in>S. \<forall>t\<in>S. s \<le> t"
  2456 proof (rule classical)
  2457   assume "\<not> (\<exists>s\<in>S. \<forall>t\<in>S. s \<le> t)"
  2458   then obtain t where t: "\<forall>s\<in>S. t s \<in> S" and "\<forall>s\<in>S. t s < s"
  2459     by (metis not_le)
  2460   then have "\<forall>s\<in>S. open {t s <..}" "S \<subseteq> (\<Union>s\<in>S. {t s <..})"
  2461     by auto
  2462   with `compact S` obtain C where "C \<subseteq> S" "finite C" and C: "S \<subseteq> (\<Union>s\<in>C. {t s <..})"
  2463     by (erule compactE_image)
  2464   with `S \<noteq> {}` have Min: "Min (t`C) \<in> t`C" and "\<forall>s\<in>t`C. Min (t`C) \<le> s"
  2465     by (auto intro!: Min_in)
  2466   with C have "S \<subseteq> {Min (t`C) <..}"
  2467     by (auto intro: le_less_trans simp: subset_eq)
  2468   with t Min `C \<subseteq> S` show ?thesis
  2469     by fastforce
  2470 qed
  2471 
  2472 lemma continuous_attains_sup:
  2473   fixes f :: "'a::topological_space \<Rightarrow> 'b::linorder_topology"
  2474   shows "compact s \<Longrightarrow> s \<noteq> {} \<Longrightarrow> continuous_on s f \<Longrightarrow> (\<exists>x\<in>s. \<forall>y\<in>s.  f y \<le> f x)"
  2475   using compact_attains_sup[of "f ` s"] compact_continuous_image[of s f] by auto
  2476 
  2477 lemma continuous_attains_inf:
  2478   fixes f :: "'a::topological_space \<Rightarrow> 'b::linorder_topology"
  2479   shows "compact s \<Longrightarrow> s \<noteq> {} \<Longrightarrow> continuous_on s f \<Longrightarrow> (\<exists>x\<in>s. \<forall>y\<in>s. f x \<le> f y)"
  2480   using compact_attains_inf[of "f ` s"] compact_continuous_image[of s f] by auto
  2481 
  2482 subsection {* Connectedness *}
  2483 
  2484 context topological_space
  2485 begin
  2486 
  2487 definition "connected S \<longleftrightarrow>
  2488   \<not> (\<exists>A B. open A \<and> open B \<and> S \<subseteq> A \<union> B \<and> A \<inter> B \<inter> S = {} \<and> A \<inter> S \<noteq> {} \<and> B \<inter> S \<noteq> {})"
  2489 
  2490 lemma connectedI:
  2491   "(\<And>A B. open A \<Longrightarrow> open B \<Longrightarrow> A \<inter> U \<noteq> {} \<Longrightarrow> B \<inter> U \<noteq> {} \<Longrightarrow> A \<inter> B \<inter> U = {} \<Longrightarrow> U \<subseteq> A \<union> B \<Longrightarrow> False)
  2492   \<Longrightarrow> connected U"
  2493   by (auto simp: connected_def)
  2494 
  2495 lemma connected_empty[simp]: "connected {}"
  2496   by (auto intro!: connectedI)
  2497 
  2498 lemma connectedD:
  2499   "connected A \<Longrightarrow> open U \<Longrightarrow> open V \<Longrightarrow> U \<inter> V \<inter> A = {} \<Longrightarrow> A \<subseteq> U \<union> V \<Longrightarrow> U \<inter> A = {} \<or> V \<inter> A = {}" 
  2500   by (auto simp: connected_def)
  2501 
  2502 end
  2503 
  2504 lemma connected_iff_const:
  2505   fixes S :: "'a::topological_space set"
  2506   shows "connected S \<longleftrightarrow> (\<forall>P::'a \<Rightarrow> bool. continuous_on S P \<longrightarrow> (\<exists>c. \<forall>s\<in>S. P s = c))"
  2507 proof safe
  2508   fix P :: "'a \<Rightarrow> bool" assume "connected S" "continuous_on S P"
  2509   then have "\<And>b. \<exists>A. open A \<and> A \<inter> S = P -` {b} \<inter> S"
  2510     unfolding continuous_on_open_invariant by simp
  2511   from this[of True] this[of False]
  2512   obtain t f where "open t" "open f" and *: "f \<inter> S = P -` {False} \<inter> S" "t \<inter> S = P -` {True} \<inter> S"
  2513     by auto
  2514   then have "t \<inter> S = {} \<or> f \<inter> S = {}"
  2515     by (intro connectedD[OF `connected S`])  auto
  2516   then show "\<exists>c. \<forall>s\<in>S. P s = c"
  2517   proof (rule disjE)
  2518     assume "t \<inter> S = {}" then show ?thesis
  2519       unfolding * by (intro exI[of _ False]) auto
  2520   next
  2521     assume "f \<inter> S = {}" then show ?thesis
  2522       unfolding * by (intro exI[of _ True]) auto
  2523   qed
  2524 next
  2525   assume P: "\<forall>P::'a \<Rightarrow> bool. continuous_on S P \<longrightarrow> (\<exists>c. \<forall>s\<in>S. P s = c)"
  2526   show "connected S"
  2527   proof (rule connectedI)
  2528     fix A B assume *: "open A" "open B" "A \<inter> S \<noteq> {}" "B \<inter> S \<noteq> {}" "A \<inter> B \<inter> S = {}" "S \<subseteq> A \<union> B"
  2529     have "continuous_on S (\<lambda>x. x \<in> A)"
  2530       unfolding continuous_on_open_invariant
  2531     proof safe
  2532       fix C :: "bool set"
  2533       have "C = UNIV \<or> C = {True} \<or> C = {False} \<or> C = {}"
  2534         using subset_UNIV[of C] unfolding UNIV_bool by auto
  2535       with * show "\<exists>T. open T \<and> T \<inter> S = (\<lambda>x. x \<in> A) -` C \<inter> S"
  2536         by (intro exI[of _ "(if True \<in> C then A else {}) \<union> (if False \<in> C then B else {})"]) auto
  2537     qed
  2538     from P[rule_format, OF this] obtain c where "\<And>s. s \<in> S \<Longrightarrow> (s \<in> A) = c" by blast
  2539     with * show False
  2540       by (cases c) auto
  2541   qed
  2542 qed
  2543 
  2544 lemma connectedD_const:
  2545   fixes P :: "'a::topological_space \<Rightarrow> bool"
  2546   shows "connected S \<Longrightarrow> continuous_on S P \<Longrightarrow> \<exists>c. \<forall>s\<in>S. P s = c"
  2547   unfolding connected_iff_const by auto
  2548 
  2549 lemma connectedI_const:
  2550   "(\<And>P::'a::topological_space \<Rightarrow> bool. continuous_on S P \<Longrightarrow> \<exists>c. \<forall>s\<in>S. P s = c) \<Longrightarrow> connected S"
  2551   unfolding connected_iff_const by auto
  2552 
  2553 lemma connected_local_const:
  2554   assumes "connected A" "a \<in> A" "b \<in> A"
  2555   assumes *: "\<forall>a\<in>A. eventually (\<lambda>b. f a = f b) (at a within A)"
  2556   shows "f a = f b"
  2557 proof -
  2558   obtain S where S: "\<And>a. a \<in> A \<Longrightarrow> a \<in> S a" "\<And>a. a \<in> A \<Longrightarrow> open (S a)"
  2559     "\<And>a x. a \<in> A \<Longrightarrow> x \<in> S a \<Longrightarrow> x \<in> A \<Longrightarrow> f a = f x"
  2560     using * unfolding eventually_at_topological by metis
  2561 
  2562   let ?P = "\<Union>b\<in>{b\<in>A. f a = f b}. S b" and ?N = "\<Union>b\<in>{b\<in>A. f a \<noteq> f b}. S b"
  2563   have "?P \<inter> A = {} \<or> ?N \<inter> A = {}"
  2564     using `connected A` S `a\<in>A`
  2565     by (intro connectedD) (auto, metis)
  2566   then show "f a = f b"
  2567   proof
  2568     assume "?N \<inter> A = {}"
  2569     then have "\<forall>x\<in>A. f a = f x"
  2570       using S(1) by auto
  2571     with `b\<in>A` show ?thesis by auto
  2572   next
  2573     assume "?P \<inter> A = {}" then show ?thesis
  2574       using `a \<in> A` S(1)[of a] by auto
  2575   qed
  2576 qed
  2577 
  2578 lemma (in linorder_topology) connectedD_interval:
  2579   assumes "connected U" and xy: "x \<in> U" "y \<in> U" and "x \<le> z" "z \<le> y"
  2580   shows "z \<in> U"
  2581 proof -
  2582   have eq: "{..<z} \<union> {z<..} = - {z}"
  2583     by auto
  2584   { assume "z \<notin> U" "x < z" "z < y"
  2585     with xy have "\<not> connected U"
  2586       unfolding connected_def simp_thms
  2587       apply (rule_tac exI[of _ "{..< z}"])
  2588       apply (rule_tac exI[of _ "{z <..}"])
  2589       apply (auto simp add: eq)
  2590       done }
  2591   with assms show "z \<in> U"
  2592     by (metis less_le)
  2593 qed
  2594 
  2595 lemma connected_continuous_image:
  2596   assumes *: "continuous_on s f"
  2597   assumes "connected s"
  2598   shows "connected (f ` s)"
  2599 proof (rule connectedI_const)
  2600   fix P :: "'b \<Rightarrow> bool" assume "continuous_on (f ` s) P"
  2601   then have "continuous_on s (P \<circ> f)"
  2602     by (rule continuous_on_compose[OF *])
  2603   from connectedD_const[OF `connected s` this] show "\<exists>c. \<forall>s\<in>f ` s. P s = c"
  2604     by auto
  2605 qed
  2606 
  2607 section {* Connectedness *}
  2608 
  2609 class linear_continuum_topology = linorder_topology + linear_continuum
  2610 begin
  2611 
  2612 lemma Inf_notin_open:
  2613   assumes A: "open A" and bnd: "\<forall>a\<in>A. x < a"
  2614   shows "Inf A \<notin> A"
  2615 proof
  2616   assume "Inf A \<in> A"
  2617   then obtain b where "b < Inf A" "{b <.. Inf A} \<subseteq> A"
  2618     using open_left[of A "Inf A" x] assms by auto
  2619   with dense[of b "Inf A"] obtain c where "c < Inf A" "c \<in> A"
  2620     by (auto simp: subset_eq)
  2621   then show False
  2622     using cInf_lower[OF `c \<in> A`] bnd by (metis not_le less_imp_le bdd_belowI)
  2623 qed
  2624 
  2625 lemma Sup_notin_open:
  2626   assumes A: "open A" and bnd: "\<forall>a\<in>A. a < x"
  2627   shows "Sup A \<notin> A"
  2628 proof
  2629   assume "Sup A \<in> A"
  2630   then obtain b where "Sup A < b" "{Sup A ..< b} \<subseteq> A"
  2631     using open_right[of A "Sup A" x] assms by auto
  2632   with dense[of "Sup A" b] obtain c where "Sup A < c" "c \<in> A"
  2633     by (auto simp: subset_eq)
  2634   then show False
  2635     using cSup_upper[OF `c \<in> A`] bnd by (metis less_imp_le not_le bdd_aboveI)
  2636 qed
  2637 
  2638 end
  2639 
  2640 instance linear_continuum_topology \<subseteq> perfect_space
  2641 proof
  2642   fix x :: 'a
  2643   obtain y where "x < y \<or> y < x"
  2644     using ex_gt_or_lt [of x] ..
  2645   with Inf_notin_open[of "{x}" y] Sup_notin_open[of "{x}" y]
  2646   show "\<not> open {x}"
  2647     by auto
  2648 qed
  2649 
  2650 lemma connectedI_interval:
  2651   fixes U :: "'a :: linear_continuum_topology set"
  2652   assumes *: "\<And>x y z. x \<in> U \<Longrightarrow> y \<in> U \<Longrightarrow> x \<le> z \<Longrightarrow> z \<le> y \<Longrightarrow> z \<in> U"
  2653   shows "connected U"
  2654 proof (rule connectedI)
  2655   { fix A B assume "open A" "open B" "A \<inter> B \<inter> U = {}" "U \<subseteq> A \<union> B"
  2656     fix x y assume "x < y" "x \<in> A" "y \<in> B" "x \<in> U" "y \<in> U"
  2657 
  2658     let ?z = "Inf (B \<inter> {x <..})"
  2659 
  2660     have "x \<le> ?z" "?z \<le> y"
  2661       using `y \<in> B` `x < y` by (auto intro: cInf_lower cInf_greatest)
  2662     with `x \<in> U` `y \<in> U` have "?z \<in> U"
  2663       by (rule *)
  2664     moreover have "?z \<notin> B \<inter> {x <..}"
  2665       using `open B` by (intro Inf_notin_open) auto
  2666     ultimately have "?z \<in> A"
  2667       using `x \<le> ?z` `A \<inter> B \<inter> U = {}` `x \<in> A` `U \<subseteq> A \<union> B` by auto
  2668 
  2669     { assume "?z < y"
  2670       obtain a where "?z < a" "{?z ..< a} \<subseteq> A"
  2671         using open_right[OF `open A` `?z \<in> A` `?z < y`] by auto
  2672       moreover obtain b where "b \<in> B" "x < b" "b < min a y"
  2673         using cInf_less_iff[of "B \<inter> {x <..}" "min a y"] `?z < a` `?z < y` `x < y` `y \<in> B`
  2674         by (auto intro: less_imp_le)
  2675       moreover have "?z \<le> b"
  2676         using `b \<in> B` `x < b`
  2677         by (intro cInf_lower) auto
  2678       moreover have "b \<in> U"
  2679         using `x \<le> ?z` `?z \<le> b` `b < min a y`
  2680         by (intro *[OF `x \<in> U` `y \<in> U`]) (auto simp: less_imp_le)
  2681       ultimately have "\<exists>b\<in>B. b \<in> A \<and> b \<in> U"
  2682         by (intro bexI[of _ b]) auto }
  2683     then have False
  2684       using `?z \<le> y` `?z \<in> A` `y \<in> B` `y \<in> U` `A \<inter> B \<inter> U = {}` unfolding le_less by blast }
  2685   note not_disjoint = this
  2686 
  2687   fix A B assume AB: "open A" "open B" "U \<subseteq> A \<union> B" "A \<inter> B \<inter> U = {}"
  2688   moreover assume "A \<inter> U \<noteq> {}" then obtain x where x: "x \<in> U" "x \<in> A" by auto
  2689   moreover assume "B \<inter> U \<noteq> {}" then obtain y where y: "y \<in> U" "y \<in> B" by auto
  2690   moreover note not_disjoint[of B A y x] not_disjoint[of A B x y]
  2691   ultimately show False by (cases x y rule: linorder_cases) auto
  2692 qed
  2693 
  2694 lemma connected_iff_interval:
  2695   fixes U :: "'a :: linear_continuum_topology set"
  2696   shows "connected U \<longleftrightarrow> (\<forall>x\<in>U. \<forall>y\<in>U. \<forall>z. x \<le> z \<longrightarrow> z \<le> y \<longrightarrow> z \<in> U)"
  2697   by (auto intro: connectedI_interval dest: connectedD_interval)
  2698 
  2699 lemma connected_UNIV[simp]: "connected (UNIV::'a::linear_continuum_topology set)"
  2700   unfolding connected_iff_interval by auto
  2701 
  2702 lemma connected_Ioi[simp]: "connected {a::'a::linear_continuum_topology <..}"
  2703   unfolding connected_iff_interval by auto
  2704 
  2705 lemma connected_Ici[simp]: "connected {a::'a::linear_continuum_topology ..}"
  2706   unfolding connected_iff_interval by auto
  2707 
  2708 lemma connected_Iio[simp]: "connected {..< a::'a::linear_continuum_topology}"
  2709   unfolding connected_iff_interval by auto
  2710 
  2711 lemma connected_Iic[simp]: "connected {.. a::'a::linear_continuum_topology}"
  2712   unfolding connected_iff_interval by auto
  2713 
  2714 lemma connected_Ioo[simp]: "connected {a <..< b::'a::linear_continuum_topology}"
  2715   unfolding connected_iff_interval by auto
  2716 
  2717 lemma connected_Ioc[simp]: "connected {a <.. b::'a::linear_continuum_topology}"
  2718   unfolding connected_iff_interval by auto
  2719 
  2720 lemma connected_Ico[simp]: "connected {a ..< b::'a::linear_continuum_topology}"
  2721   unfolding connected_iff_interval by auto
  2722 
  2723 lemma connected_Icc[simp]: "connected {a .. b::'a::linear_continuum_topology}"
  2724   unfolding connected_iff_interval by auto
  2725 
  2726 lemma connected_contains_Ioo: 
  2727   fixes A :: "'a :: linorder_topology set"
  2728   assumes A: "connected A" "a \<in> A" "b \<in> A" shows "{a <..< b} \<subseteq> A"
  2729   using connectedD_interval[OF A] by (simp add: subset_eq Ball_def less_imp_le)
  2730 
  2731 subsection {* Intermediate Value Theorem *}
  2732 
  2733 lemma IVT':
  2734   fixes f :: "'a :: linear_continuum_topology \<Rightarrow> 'b :: linorder_topology"
  2735   assumes y: "f a \<le> y" "y \<le> f b" "a \<le> b"
  2736   assumes *: "continuous_on {a .. b} f"
  2737   shows "\<exists>x. a \<le> x \<and> x \<le> b \<and> f x = y"
  2738 proof -
  2739   have "connected {a..b}"
  2740     unfolding connected_iff_interval by auto
  2741   from connected_continuous_image[OF * this, THEN connectedD_interval, of "f a" "f b" y] y
  2742   show ?thesis
  2743     by (auto simp add: atLeastAtMost_def atLeast_def atMost_def)
  2744 qed
  2745 
  2746 lemma IVT2':
  2747   fixes f :: "'a :: linear_continuum_topology \<Rightarrow> 'b :: linorder_topology"
  2748   assumes y: "f b \<le> y" "y \<le> f a" "a \<le> b"
  2749   assumes *: "continuous_on {a .. b} f"
  2750   shows "\<exists>x. a \<le> x \<and> x \<le> b \<and> f x = y"
  2751 proof -
  2752   have "connected {a..b}"
  2753     unfolding connected_iff_interval by auto
  2754   from connected_continuous_image[OF * this, THEN connectedD_interval, of "f b" "f a" y] y
  2755   show ?thesis
  2756     by (auto simp add: atLeastAtMost_def atLeast_def atMost_def)
  2757 qed
  2758 
  2759 lemma IVT:
  2760   fixes f :: "'a :: linear_continuum_topology \<Rightarrow> 'b :: linorder_topology"
  2761   shows "f a \<le> y \<Longrightarrow> y \<le> f b \<Longrightarrow> a \<le> b \<Longrightarrow> (\<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> isCont f x) \<Longrightarrow> \<exists>x. a \<le> x \<and> x \<le> b \<and> f x = y"
  2762   by (rule IVT') (auto intro: continuous_at_imp_continuous_on)
  2763 
  2764 lemma IVT2:
  2765   fixes f :: "'a :: linear_continuum_topology \<Rightarrow> 'b :: linorder_topology"
  2766   shows "f b \<le> y \<Longrightarrow> y \<le> f a \<Longrightarrow> a \<le> b \<Longrightarrow> (\<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> isCont f x) \<Longrightarrow> \<exists>x. a \<le> x \<and> x \<le> b \<and> f x = y"
  2767   by (rule IVT2') (auto intro: continuous_at_imp_continuous_on)
  2768 
  2769 lemma continuous_inj_imp_mono:
  2770   fixes f :: "'a::linear_continuum_topology \<Rightarrow> 'b :: linorder_topology"
  2771   assumes x: "a < x" "x < b"
  2772   assumes cont: "continuous_on {a..b} f"
  2773   assumes inj: "inj_on f {a..b}"
  2774   shows "(f a < f x \<and> f x < f b) \<or> (f b < f x \<and> f x < f a)"
  2775 proof -
  2776   note I = inj_on_iff[OF inj]
  2777   { assume "f x < f a" "f x < f b"
  2778     then obtain s t where "x \<le> s" "s \<le> b" "a \<le> t" "t \<le> x" "f s = f t" "f x < f s"
  2779       using IVT'[of f x "min (f a) (f b)" b] IVT2'[of f x "min (f a) (f b)" a] x
  2780       by (auto simp: continuous_on_subset[OF cont] less_imp_le)
  2781     with x I have False by auto }
  2782   moreover
  2783   { assume "f a < f x" "f b < f x"
  2784     then obtain s t where "x \<le> s" "s \<le> b" "a \<le> t" "t \<le> x" "f s = f t" "f s < f x"
  2785       using IVT'[of f a "max (f a) (f b)" x] IVT2'[of f b "max (f a) (f b)" x] x
  2786       by (auto simp: continuous_on_subset[OF cont] less_imp_le)
  2787     with x I have False by auto }
  2788   ultimately show ?thesis
  2789     using I[of a x] I[of x b] x less_trans[OF x] by (auto simp add: le_less less_imp_neq neq_iff)
  2790 qed
  2791 
  2792 lemma continuous_at_Sup_mono:
  2793   fixes f :: "'a :: {linorder_topology, conditionally_complete_linorder} \<Rightarrow> 'b :: {linorder_topology, conditionally_complete_linorder}"
  2794   assumes "mono f"
  2795   assumes cont: "continuous (at_left (Sup S)) f"
  2796   assumes S: "S \<noteq> {}" "bdd_above S"
  2797   shows "f (Sup S) = (SUP s:S. f s)"
  2798 proof (rule antisym)
  2799   have f: "(f ---> f (Sup S)) (at_left (Sup S))"
  2800     using cont unfolding continuous_within .
  2801 
  2802   show "f (Sup S) \<le> (SUP s:S. f s)"
  2803   proof cases
  2804     assume "Sup S \<in> S" then show ?thesis
  2805       by (rule cSUP_upper) (auto intro: bdd_above_image_mono S `mono f`)
  2806   next
  2807     assume "Sup S \<notin> S"
  2808     from `S \<noteq> {}` obtain s where "s \<in> S"
  2809       by auto
  2810     with `Sup S \<notin> S` S have "s < Sup S"
  2811       unfolding less_le by (blast intro: cSup_upper)
  2812     show ?thesis
  2813     proof (rule ccontr)
  2814       assume "\<not> ?thesis"
  2815       with order_tendstoD(1)[OF f, of "SUP s:S. f s"] obtain b where "b < Sup S"
  2816         and *: "\<And>y. b < y \<Longrightarrow> y < Sup S \<Longrightarrow> (SUP s:S. f s) < f y"
  2817         by (auto simp: not_le eventually_at_left[OF `s < Sup S`])
  2818       with `S \<noteq> {}` obtain c where "c \<in> S" "b < c"
  2819         using less_cSupD[of S b] by auto
  2820       with `Sup S \<notin> S` S have "c < Sup S"
  2821         unfolding less_le by (blast intro: cSup_upper)
  2822       from *[OF `b < c` `c < Sup S`] cSUP_upper[OF `c \<in> S` bdd_above_image_mono[of f]]
  2823       show False
  2824         by (auto simp: assms)
  2825     qed
  2826   qed
  2827 qed (intro cSUP_least `mono f`[THEN monoD] cSup_upper S)
  2828 
  2829 lemma continuous_at_Sup_antimono:
  2830   fixes f :: "'a :: {linorder_topology, conditionally_complete_linorder} \<Rightarrow> 'b :: {linorder_topology, conditionally_complete_linorder}"
  2831   assumes "antimono f"
  2832   assumes cont: "continuous (at_left (Sup S)) f"
  2833   assumes S: "S \<noteq> {}" "bdd_above S"
  2834   shows "f (Sup S) = (INF s:S. f s)"
  2835 proof (rule antisym)
  2836   have f: "(f ---> f (Sup S)) (at_left (Sup S))"
  2837     using cont unfolding continuous_within .
  2838 
  2839   show "(INF s:S. f s) \<le> f (Sup S)"
  2840   proof cases
  2841     assume "Sup S \<in> S" then show ?thesis
  2842       by (intro cINF_lower) (auto intro: bdd_below_image_antimono S `antimono f`)
  2843   next
  2844     assume "Sup S \<notin> S"
  2845     from `S \<noteq> {}` obtain s where "s \<in> S"
  2846       by auto
  2847     with `Sup S \<notin> S` S have "s < Sup S"
  2848       unfolding less_le by (blast intro: cSup_upper)
  2849     show ?thesis
  2850     proof (rule ccontr)
  2851       assume "\<not> ?thesis"
  2852       with order_tendstoD(2)[OF f, of "INF s:S. f s"] obtain b where "b < Sup S"
  2853         and *: "\<And>y. b < y \<Longrightarrow> y < Sup S \<Longrightarrow> f y < (INF s:S. f s)"
  2854         by (auto simp: not_le eventually_at_left[OF `s < Sup S`])
  2855       with `S \<noteq> {}` obtain c where "c \<in> S" "b < c"
  2856         using less_cSupD[of S b] by auto
  2857       with `Sup S \<notin> S` S have "c < Sup S"
  2858         unfolding less_le by (blast intro: cSup_upper)
  2859       from *[OF `b < c` `c < Sup S`] cINF_lower[OF bdd_below_image_antimono, of f S c] `c \<in> S`
  2860       show False
  2861         by (auto simp: assms)
  2862     qed
  2863   qed
  2864 qed (intro cINF_greatest `antimono f`[THEN antimonoD] cSup_upper S)
  2865 
  2866 lemma continuous_at_Inf_mono:
  2867   fixes f :: "'a :: {linorder_topology, conditionally_complete_linorder} \<Rightarrow> 'b :: {linorder_topology, conditionally_complete_linorder}"
  2868   assumes "mono f"
  2869   assumes cont: "continuous (at_right (Inf S)) f"
  2870   assumes S: "S \<noteq> {}" "bdd_below S"
  2871   shows "f (Inf S) = (INF s:S. f s)"
  2872 proof (rule antisym)
  2873   have f: "(f ---> f (Inf S)) (at_right (Inf S))"
  2874     using cont unfolding continuous_within .
  2875 
  2876   show "(INF s:S. f s) \<le> f (Inf S)"
  2877   proof cases
  2878     assume "Inf S \<in> S" then show ?thesis
  2879       by (rule cINF_lower[rotated]) (auto intro: bdd_below_image_mono S `mono f`)
  2880   next
  2881     assume "Inf S \<notin> S"
  2882     from `S \<noteq> {}` obtain s where "s \<in> S"
  2883       by auto
  2884     with `Inf S \<notin> S` S have "Inf S < s"
  2885       unfolding less_le by (blast intro: cInf_lower)
  2886     show ?thesis
  2887     proof (rule ccontr)
  2888       assume "\<not> ?thesis"
  2889       with order_tendstoD(2)[OF f, of "INF s:S. f s"] obtain b where "Inf S < b"
  2890         and *: "\<And>y. Inf S < y \<Longrightarrow> y < b \<Longrightarrow> f y < (INF s:S. f s)"
  2891         by (auto simp: not_le eventually_at_right[OF `Inf S < s`])
  2892       with `S \<noteq> {}` obtain c where "c \<in> S" "c < b"
  2893         using cInf_lessD[of S b] by auto
  2894       with `Inf S \<notin> S` S have "Inf S < c"
  2895         unfolding less_le by (blast intro: cInf_lower)
  2896       from *[OF `Inf S < c` `c < b`] cINF_lower[OF bdd_below_image_mono[of f] `c \<in> S`]
  2897       show False
  2898         by (auto simp: assms)
  2899     qed
  2900   qed
  2901 qed (intro cINF_greatest `mono f`[THEN monoD] cInf_lower `bdd_below S` `S \<noteq> {}`)
  2902 
  2903 lemma continuous_at_Inf_antimono:
  2904   fixes f :: "'a :: {linorder_topology, conditionally_complete_linorder} \<Rightarrow> 'b :: {linorder_topology, conditionally_complete_linorder}"
  2905   assumes "antimono f"
  2906   assumes cont: "continuous (at_right (Inf S)) f"
  2907   assumes S: "S \<noteq> {}" "bdd_below S"
  2908   shows "f (Inf S) = (SUP s:S. f s)"
  2909 proof (rule antisym)
  2910   have f: "(f ---> f (Inf S)) (at_right (Inf S))"
  2911     using cont unfolding continuous_within .
  2912 
  2913   show "f (Inf S) \<le> (SUP s:S. f s)"
  2914   proof cases
  2915     assume "Inf S \<in> S" then show ?thesis
  2916       by (rule cSUP_upper) (auto intro: bdd_above_image_antimono S `antimono f`)
  2917   next
  2918     assume "Inf S \<notin> S"
  2919     from `S \<noteq> {}` obtain s where "s \<in> S"
  2920       by auto
  2921     with `Inf S \<notin> S` S have "Inf S < s"
  2922       unfolding less_le by (blast intro: cInf_lower)
  2923     show ?thesis
  2924     proof (rule ccontr)
  2925       assume "\<not> ?thesis"
  2926       with order_tendstoD(1)[OF f, of "SUP s:S. f s"] obtain b where "Inf S < b"
  2927         and *: "\<And>y. Inf S < y \<Longrightarrow> y < b \<Longrightarrow> (SUP s:S. f s) < f y"
  2928         by (auto simp: not_le eventually_at_right[OF `Inf S < s`])
  2929       with `S \<noteq> {}` obtain c where "c \<in> S" "c < b"
  2930         using cInf_lessD[of S b] by auto
  2931       with `Inf S \<notin> S` S have "Inf S < c"
  2932         unfolding less_le by (blast intro: cInf_lower)
  2933       from *[OF `Inf S < c` `c < b`] cSUP_upper[OF `c \<in> S` bdd_above_image_antimono[of f]]
  2934       show False
  2935         by (auto simp: assms)
  2936     qed
  2937   qed
  2938 qed (intro cSUP_least `antimono f`[THEN antimonoD] cInf_lower S)
  2939 
  2940 subsection {* Setup @{typ "'a filter"} for lifting and transfer *}
  2941 
  2942 context begin interpretation lifting_syntax .
  2943 
  2944 definition rel_filter :: "('a \<Rightarrow> 'b \<Rightarrow> bool) \<Rightarrow> 'a filter \<Rightarrow> 'b filter \<Rightarrow> bool"
  2945 where "rel_filter R F G = ((R ===> op =) ===> op =) (Rep_filter F) (Rep_filter G)"
  2946 
  2947 lemma rel_filter_eventually:
  2948   "rel_filter R F G \<longleftrightarrow> 
  2949   ((R ===> op =) ===> op =) (\<lambda>P. eventually P F) (\<lambda>P. eventually P G)"
  2950 by(simp add: rel_filter_def eventually_def)
  2951 
  2952 lemma filtermap_id [simp, id_simps]: "filtermap id = id"
  2953 by(simp add: fun_eq_iff id_def filtermap_ident)
  2954 
  2955 lemma filtermap_id' [simp]: "filtermap (\<lambda>x. x) = (\<lambda>F. F)"
  2956 using filtermap_id unfolding id_def .
  2957 
  2958 lemma Quotient_filter [quot_map]:
  2959   assumes Q: "Quotient R Abs Rep T"
  2960   shows "Quotient (rel_filter R) (filtermap Abs) (filtermap Rep) (rel_filter T)"
  2961 unfolding Quotient_alt_def
  2962 proof(intro conjI strip)
  2963   from Q have *: "\<And>x y. T x y \<Longrightarrow> Abs x = y"
  2964     unfolding Quotient_alt_def by blast
  2965 
  2966   fix F G
  2967   assume "rel_filter T F G"
  2968   thus "filtermap Abs F = G" unfolding filter_eq_iff
  2969     by(auto simp add: eventually_filtermap rel_filter_eventually * rel_funI del: iffI elim!: rel_funD)
  2970 next
  2971   from Q have *: "\<And>x. T (Rep x) x" unfolding Quotient_alt_def by blast
  2972 
  2973   fix F
  2974   show "rel_filter T (filtermap Rep F) F" 
  2975     by(auto elim: rel_funD intro: * intro!: ext arg_cong[where f="\<lambda>P. eventually P F"] rel_funI
  2976             del: iffI simp add: eventually_filtermap rel_filter_eventually)
  2977 qed(auto simp add: map_fun_def o_def eventually_filtermap filter_eq_iff fun_eq_iff rel_filter_eventually
  2978          fun_quotient[OF fun_quotient[OF Q identity_quotient] identity_quotient, unfolded Quotient_alt_def])
  2979 
  2980 lemma eventually_parametric [transfer_rule]:
  2981   "((A ===> op =) ===> rel_filter A ===> op =) eventually eventually"
  2982 by(simp add: rel_fun_def rel_filter_eventually)
  2983 
  2984 lemma rel_filter_eq [relator_eq]: "rel_filter op = = op ="
  2985 by(auto simp add: rel_filter_eventually rel_fun_eq fun_eq_iff filter_eq_iff)
  2986 
  2987 lemma rel_filter_mono [relator_mono]:
  2988   "A \<le> B \<Longrightarrow> rel_filter A \<le> rel_filter B"
  2989 unfolding rel_filter_eventually[abs_def]
  2990 by(rule le_funI)+(intro fun_mono fun_mono[THEN le_funD, THEN le_funD] order.refl)
  2991 
  2992 lemma rel_filter_conversep [simp]: "rel_filter A\<inverse>\<inverse> = (rel_filter A)\<inverse>\<inverse>"
  2993 by(auto simp add: rel_filter_eventually fun_eq_iff rel_fun_def)
  2994 
  2995 lemma is_filter_parametric_aux:
  2996   assumes "is_filter F"
  2997   assumes [transfer_rule]: "bi_total A" "bi_unique A"
  2998   and [transfer_rule]: "((A ===> op =) ===> op =) F G"
  2999   shows "is_filter G"
  3000 proof -
  3001   interpret is_filter F by fact
  3002   show ?thesis
  3003   proof
  3004     have "F (\<lambda>_. True) = G (\<lambda>x. True)" by transfer_prover
  3005     thus "G (\<lambda>x. True)" by(simp add: True)
  3006   next
  3007     fix P' Q'
  3008     assume "G P'" "G Q'"
  3009     moreover
  3010     from bi_total_fun[OF `bi_unique A` bi_total_eq, unfolded bi_total_def]
  3011     obtain P Q where [transfer_rule]: "(A ===> op =) P P'" "(A ===> op =) Q Q'" by blast
  3012     have "F P = G P'" "F Q = G Q'" by transfer_prover+
  3013     ultimately have "F (\<lambda>x. P x \<and> Q x)" by(simp add: conj)
  3014     moreover have "F (\<lambda>x. P x \<and> Q x) = G (\<lambda>x. P' x \<and> Q' x)" by transfer_prover
  3015     ultimately show "G (\<lambda>x. P' x \<and> Q' x)" by simp
  3016   next
  3017     fix P' Q'
  3018     assume "\<forall>x. P' x \<longrightarrow> Q' x" "G P'"
  3019     moreover
  3020     from bi_total_fun[OF `bi_unique A` bi_total_eq, unfolded bi_total_def]
  3021     obtain P Q where [transfer_rule]: "(A ===> op =) P P'" "(A ===> op =) Q Q'" by blast
  3022     have "F P = G P'" by transfer_prover
  3023     moreover have "(\<forall>x. P x \<longrightarrow> Q x) \<longleftrightarrow> (\<forall>x. P' x \<longrightarrow> Q' x)" by transfer_prover
  3024     ultimately have "F Q" by(simp add: mono)
  3025     moreover have "F Q = G Q'" by transfer_prover
  3026     ultimately show "G Q'" by simp
  3027   qed
  3028 qed
  3029 
  3030 lemma is_filter_parametric [transfer_rule]:
  3031   "\<lbrakk> bi_total A; bi_unique A \<rbrakk>
  3032   \<Longrightarrow> (((A ===> op =) ===> op =) ===> op =) is_filter is_filter"
  3033 apply(rule rel_funI)
  3034 apply(rule iffI)
  3035  apply(erule (3) is_filter_parametric_aux)
  3036 apply(erule is_filter_parametric_aux[where A="conversep A"])
  3037 apply(auto simp add: rel_fun_def)
  3038 done
  3039 
  3040 lemma left_total_rel_filter [transfer_rule]:
  3041   assumes [transfer_rule]: "bi_total A" "bi_unique A"
  3042   shows "left_total (rel_filter A)"
  3043 proof(rule left_totalI)
  3044   fix F :: "'a filter"
  3045   from bi_total_fun[OF bi_unique_fun[OF `bi_total A` bi_unique_eq] bi_total_eq]
  3046   obtain G where [transfer_rule]: "((A ===> op =) ===> op =) (\<lambda>P. eventually P F) G" 
  3047     unfolding  bi_total_def by blast
  3048   moreover have "is_filter (\<lambda>P. eventually P F) \<longleftrightarrow> is_filter G" by transfer_prover
  3049   hence "is_filter G" by(simp add: eventually_def is_filter_Rep_filter)
  3050   ultimately have "rel_filter A F (Abs_filter G)"
  3051     by(simp add: rel_filter_eventually eventually_Abs_filter)
  3052   thus "\<exists>G. rel_filter A F G" ..
  3053 qed
  3054 
  3055 lemma right_total_rel_filter [transfer_rule]:
  3056   "\<lbrakk> bi_total A; bi_unique A \<rbrakk> \<Longrightarrow> right_total (rel_filter A)"
  3057 using left_total_rel_filter[of "A\<inverse>\<inverse>"] by simp
  3058 
  3059 lemma bi_total_rel_filter [transfer_rule]:
  3060   assumes "bi_total A" "bi_unique A"
  3061   shows "bi_total (rel_filter A)"
  3062 unfolding bi_total_alt_def using assms
  3063 by(simp add: left_total_rel_filter right_total_rel_filter)
  3064 
  3065 lemma left_unique_rel_filter [transfer_rule]:
  3066   assumes "left_unique A"
  3067   shows "left_unique (rel_filter A)"
  3068 proof(rule left_uniqueI)
  3069   fix F F' G
  3070   assume [transfer_rule]: "rel_filter A F G" "rel_filter A F' G"
  3071   show "F = F'"
  3072     unfolding filter_eq_iff
  3073   proof
  3074     fix P :: "'a \<Rightarrow> bool"
  3075     obtain P' where [transfer_rule]: "(A ===> op =) P P'"
  3076       using left_total_fun[OF assms left_total_eq] unfolding left_total_def by blast
  3077     have "eventually P F = eventually P' G" 
  3078       and "eventually P F' = eventually P' G" by transfer_prover+
  3079     thus "eventually P F = eventually P F'" by simp
  3080   qed
  3081 qed
  3082 
  3083 lemma right_unique_rel_filter [transfer_rule]:
  3084   "right_unique A \<Longrightarrow> right_unique (rel_filter A)"
  3085 using left_unique_rel_filter[of "A\<inverse>\<inverse>"] by simp
  3086 
  3087 lemma bi_unique_rel_filter [transfer_rule]:
  3088   "bi_unique A \<Longrightarrow> bi_unique (rel_filter A)"
  3089 by(simp add: bi_unique_alt_def left_unique_rel_filter right_unique_rel_filter)
  3090 
  3091 lemma top_filter_parametric [transfer_rule]:
  3092   "bi_total A \<Longrightarrow> (rel_filter A) top top"
  3093 by(simp add: rel_filter_eventually All_transfer)
  3094 
  3095 lemma bot_filter_parametric [transfer_rule]: "(rel_filter A) bot bot"
  3096 by(simp add: rel_filter_eventually rel_fun_def)
  3097 
  3098 lemma sup_filter_parametric [transfer_rule]:
  3099   "(rel_filter A ===> rel_filter A ===> rel_filter A) sup sup"
  3100 by(fastforce simp add: rel_filter_eventually[abs_def] eventually_sup dest: rel_funD)
  3101 
  3102 lemma Sup_filter_parametric [transfer_rule]:
  3103   "(rel_set (rel_filter A) ===> rel_filter A) Sup Sup"
  3104 proof(rule rel_funI)
  3105   fix S T
  3106   assume [transfer_rule]: "rel_set (rel_filter A) S T"
  3107   show "rel_filter A (Sup S) (Sup T)"
  3108     by(simp add: rel_filter_eventually eventually_Sup) transfer_prover
  3109 qed
  3110 
  3111 lemma principal_parametric [transfer_rule]:
  3112   "(rel_set A ===> rel_filter A) principal principal"
  3113 proof(rule rel_funI)
  3114   fix S S'
  3115   assume [transfer_rule]: "rel_set A S S'"
  3116   show "rel_filter A (principal S) (principal S')"
  3117     by(simp add: rel_filter_eventually eventually_principal) transfer_prover
  3118 qed
  3119 
  3120 context
  3121   fixes A :: "'a \<Rightarrow> 'b \<Rightarrow> bool"
  3122   assumes [transfer_rule]: "bi_unique A" 
  3123 begin
  3124 
  3125 lemma le_filter_parametric [transfer_rule]:
  3126   "(rel_filter A ===> rel_filter A ===> op =) op \<le> op \<le>"
  3127 unfolding le_filter_def[abs_def] by transfer_prover
  3128 
  3129 lemma less_filter_parametric [transfer_rule]:
  3130   "(rel_filter A ===> rel_filter A ===> op =) op < op <"
  3131 unfolding less_filter_def[abs_def] by transfer_prover
  3132 
  3133 context
  3134   assumes [transfer_rule]: "bi_total A"
  3135 begin
  3136 
  3137 lemma Inf_filter_parametric [transfer_rule]:
  3138   "(rel_set (rel_filter A) ===> rel_filter A) Inf Inf"
  3139 unfolding Inf_filter_def[abs_def] by transfer_prover
  3140 
  3141 lemma inf_filter_parametric [transfer_rule]:
  3142   "(rel_filter A ===> rel_filter A ===> rel_filter A) inf inf"
  3143 proof(intro rel_funI)+
  3144   fix F F' G G'
  3145   assume [transfer_rule]: "rel_filter A F F'" "rel_filter A G G'"
  3146   have "rel_filter A (Inf {F, G}) (Inf {F', G'})" by transfer_prover
  3147   thus "rel_filter A (inf F G) (inf F' G')" by simp
  3148 qed
  3149 
  3150 end
  3151 
  3152 end
  3153 
  3154 end
  3155 
  3156 end