src/HOL/SEQ.thy
author huffman
Fri Jun 12 15:46:21 2009 -0700 (2009-06-12)
changeset 31588 2651f172c38b
parent 31488 5691ccb8d6b5
child 32064 53ca12ff305d
permissions -rw-r--r--
add lemma tendsto_setsum
     1 (*  Title       : SEQ.thy
     2     Author      : Jacques D. Fleuriot
     3     Copyright   : 1998  University of Cambridge
     4     Description : Convergence of sequences and series
     5     Conversion to Isar and new proofs by Lawrence C Paulson, 2004
     6     Additional contributions by Jeremy Avigad and Brian Huffman
     7 *)
     8 
     9 header {* Sequences and Convergence *}
    10 
    11 theory SEQ
    12 imports Limits
    13 begin
    14 
    15 definition
    16   Zseq :: "[nat \<Rightarrow> 'a::real_normed_vector] \<Rightarrow> bool" where
    17     --{*Standard definition of sequence converging to zero*}
    18   [code del]: "Zseq X = (\<forall>r>0. \<exists>no. \<forall>n\<ge>no. norm (X n) < r)"
    19 
    20 definition
    21   LIMSEQ :: "[nat \<Rightarrow> 'a::metric_space, 'a] \<Rightarrow> bool"
    22     ("((_)/ ----> (_))" [60, 60] 60) where
    23     --{*Standard definition of convergence of sequence*}
    24   [code del]: "X ----> L = (\<forall>r>0. \<exists>no. \<forall>n\<ge>no. dist (X n) L < r)"
    25 
    26 definition
    27   lim :: "(nat \<Rightarrow> 'a::metric_space) \<Rightarrow> 'a" where
    28     --{*Standard definition of limit using choice operator*}
    29   "lim X = (THE L. X ----> L)"
    30 
    31 definition
    32   convergent :: "(nat \<Rightarrow> 'a::metric_space) \<Rightarrow> bool" where
    33     --{*Standard definition of convergence*}
    34   "convergent X = (\<exists>L. X ----> L)"
    35 
    36 definition
    37   Bseq :: "(nat => 'a::real_normed_vector) => bool" where
    38     --{*Standard definition for bounded sequence*}
    39   [code del]: "Bseq X = (\<exists>K>0.\<forall>n. norm (X n) \<le> K)"
    40 
    41 definition
    42   monoseq :: "(nat=>real)=>bool" where
    43     --{*Definition of monotonicity. 
    44         The use of disjunction here complicates proofs considerably. 
    45         One alternative is to add a Boolean argument to indicate the direction. 
    46         Another is to develop the notions of increasing and decreasing first.*}
    47   [code del]: "monoseq X = ((\<forall>m. \<forall>n\<ge>m. X m \<le> X n) | (\<forall>m. \<forall>n\<ge>m. X n \<le> X m))"
    48 
    49 definition
    50   incseq :: "(nat=>real)=>bool" where
    51     --{*Increasing sequence*}
    52   [code del]: "incseq X = (\<forall>m. \<forall>n\<ge>m. X m \<le> X n)"
    53 
    54 definition
    55   decseq :: "(nat=>real)=>bool" where
    56     --{*Increasing sequence*}
    57   [code del]: "decseq X = (\<forall>m. \<forall>n\<ge>m. X n \<le> X m)"
    58 
    59 definition
    60   subseq :: "(nat => nat) => bool" where
    61     --{*Definition of subsequence*}
    62   [code del]:   "subseq f = (\<forall>m. \<forall>n>m. (f m) < (f n))"
    63 
    64 definition
    65   Cauchy :: "(nat \<Rightarrow> 'a::metric_space) \<Rightarrow> bool" where
    66     --{*Standard definition of the Cauchy condition*}
    67   [code del]: "Cauchy X = (\<forall>e>0. \<exists>M. \<forall>m \<ge> M. \<forall>n \<ge> M. dist (X m) (X n) < e)"
    68 
    69 
    70 subsection {* Bounded Sequences *}
    71 
    72 lemma BseqI': assumes K: "\<And>n. norm (X n) \<le> K" shows "Bseq X"
    73 unfolding Bseq_def
    74 proof (intro exI conjI allI)
    75   show "0 < max K 1" by simp
    76 next
    77   fix n::nat
    78   have "norm (X n) \<le> K" by (rule K)
    79   thus "norm (X n) \<le> max K 1" by simp
    80 qed
    81 
    82 lemma BseqE: "\<lbrakk>Bseq X; \<And>K. \<lbrakk>0 < K; \<forall>n. norm (X n) \<le> K\<rbrakk> \<Longrightarrow> Q\<rbrakk> \<Longrightarrow> Q"
    83 unfolding Bseq_def by auto
    84 
    85 lemma BseqI2': assumes K: "\<forall>n\<ge>N. norm (X n) \<le> K" shows "Bseq X"
    86 proof (rule BseqI')
    87   let ?A = "norm ` X ` {..N}"
    88   have 1: "finite ?A" by simp
    89   fix n::nat
    90   show "norm (X n) \<le> max K (Max ?A)"
    91   proof (cases rule: linorder_le_cases)
    92     assume "n \<ge> N"
    93     hence "norm (X n) \<le> K" using K by simp
    94     thus "norm (X n) \<le> max K (Max ?A)" by simp
    95   next
    96     assume "n \<le> N"
    97     hence "norm (X n) \<in> ?A" by simp
    98     with 1 have "norm (X n) \<le> Max ?A" by (rule Max_ge)
    99     thus "norm (X n) \<le> max K (Max ?A)" by simp
   100   qed
   101 qed
   102 
   103 lemma Bseq_ignore_initial_segment: "Bseq X \<Longrightarrow> Bseq (\<lambda>n. X (n + k))"
   104 unfolding Bseq_def by auto
   105 
   106 lemma Bseq_offset: "Bseq (\<lambda>n. X (n + k)) \<Longrightarrow> Bseq X"
   107 apply (erule BseqE)
   108 apply (rule_tac N="k" and K="K" in BseqI2')
   109 apply clarify
   110 apply (drule_tac x="n - k" in spec, simp)
   111 done
   112 
   113 lemma Bseq_conv_Bfun: "Bseq X \<longleftrightarrow> Bfun X sequentially"
   114 unfolding Bfun_def eventually_sequentially
   115 apply (rule iffI)
   116 apply (simp add: Bseq_def, fast)
   117 apply (fast intro: BseqI2')
   118 done
   119 
   120 
   121 subsection {* Sequences That Converge to Zero *}
   122 
   123 lemma ZseqI:
   124   "(\<And>r. 0 < r \<Longrightarrow> \<exists>no. \<forall>n\<ge>no. norm (X n) < r) \<Longrightarrow> Zseq X"
   125 unfolding Zseq_def by simp
   126 
   127 lemma ZseqD:
   128   "\<lbrakk>Zseq X; 0 < r\<rbrakk> \<Longrightarrow> \<exists>no. \<forall>n\<ge>no. norm (X n) < r"
   129 unfolding Zseq_def by simp
   130 
   131 lemma Zseq_conv_Zfun: "Zseq X \<longleftrightarrow> Zfun X sequentially"
   132 unfolding Zseq_def Zfun_def eventually_sequentially ..
   133 
   134 lemma Zseq_zero: "Zseq (\<lambda>n. 0)"
   135 unfolding Zseq_def by simp
   136 
   137 lemma Zseq_const_iff: "Zseq (\<lambda>n. k) = (k = 0)"
   138 unfolding Zseq_def by force
   139 
   140 lemma Zseq_norm_iff: "Zseq (\<lambda>n. norm (X n)) = Zseq (\<lambda>n. X n)"
   141 unfolding Zseq_def by simp
   142 
   143 lemma Zseq_imp_Zseq:
   144   assumes X: "Zseq X"
   145   assumes Y: "\<And>n. norm (Y n) \<le> norm (X n) * K"
   146   shows "Zseq (\<lambda>n. Y n)"
   147 using X Y Zfun_imp_Zfun [of X sequentially Y K]
   148 unfolding Zseq_conv_Zfun by simp
   149 
   150 lemma Zseq_le: "\<lbrakk>Zseq Y; \<forall>n. norm (X n) \<le> norm (Y n)\<rbrakk> \<Longrightarrow> Zseq X"
   151 by (erule_tac K="1" in Zseq_imp_Zseq, simp)
   152 
   153 lemma Zseq_add:
   154   "Zseq X \<Longrightarrow> Zseq Y \<Longrightarrow> Zseq (\<lambda>n. X n + Y n)"
   155 unfolding Zseq_conv_Zfun by (rule Zfun_add)
   156 
   157 lemma Zseq_minus: "Zseq X \<Longrightarrow> Zseq (\<lambda>n. - X n)"
   158 unfolding Zseq_def by simp
   159 
   160 lemma Zseq_diff: "\<lbrakk>Zseq X; Zseq Y\<rbrakk> \<Longrightarrow> Zseq (\<lambda>n. X n - Y n)"
   161 by (simp only: diff_minus Zseq_add Zseq_minus)
   162 
   163 lemma (in bounded_linear) Zseq:
   164   "Zseq X \<Longrightarrow> Zseq (\<lambda>n. f (X n))"
   165 unfolding Zseq_conv_Zfun by (rule Zfun)
   166 
   167 lemma (in bounded_bilinear) Zseq:
   168   "Zseq X \<Longrightarrow> Zseq Y \<Longrightarrow> Zseq (\<lambda>n. X n ** Y n)"
   169 unfolding Zseq_conv_Zfun by (rule Zfun)
   170 
   171 lemma (in bounded_bilinear) Zseq_prod_Bseq:
   172   "Zseq X \<Longrightarrow> Bseq Y \<Longrightarrow> Zseq (\<lambda>n. X n ** Y n)"
   173 unfolding Zseq_conv_Zfun Bseq_conv_Bfun
   174 by (rule Zfun_prod_Bfun)
   175 
   176 lemma (in bounded_bilinear) Bseq_prod_Zseq:
   177   "Bseq X \<Longrightarrow> Zseq Y \<Longrightarrow> Zseq (\<lambda>n. X n ** Y n)"
   178 unfolding Zseq_conv_Zfun Bseq_conv_Bfun
   179 by (rule Bfun_prod_Zfun)
   180 
   181 lemma (in bounded_bilinear) Zseq_left:
   182   "Zseq X \<Longrightarrow> Zseq (\<lambda>n. X n ** a)"
   183 by (rule bounded_linear_left [THEN bounded_linear.Zseq])
   184 
   185 lemma (in bounded_bilinear) Zseq_right:
   186   "Zseq X \<Longrightarrow> Zseq (\<lambda>n. a ** X n)"
   187 by (rule bounded_linear_right [THEN bounded_linear.Zseq])
   188 
   189 lemmas Zseq_mult = mult.Zseq
   190 lemmas Zseq_mult_right = mult.Zseq_right
   191 lemmas Zseq_mult_left = mult.Zseq_left
   192 
   193 
   194 subsection {* Limits of Sequences *}
   195 
   196 lemma LIMSEQ_conv_tendsto: "(X ----> L) \<longleftrightarrow> (X ---> L) sequentially"
   197 unfolding LIMSEQ_def tendsto_iff eventually_sequentially ..
   198 
   199 lemma LIMSEQ_iff:
   200   fixes L :: "'a::real_normed_vector"
   201   shows "(X ----> L) = (\<forall>r>0. \<exists>no. \<forall>n \<ge> no. norm (X n - L) < r)"
   202 unfolding LIMSEQ_def dist_norm ..
   203 
   204 lemma LIMSEQ_Zseq_iff: "((\<lambda>n. X n) ----> L) = Zseq (\<lambda>n. X n - L)"
   205 by (simp only: LIMSEQ_iff Zseq_def)
   206 
   207 lemma metric_LIMSEQ_I:
   208   "(\<And>r. 0 < r \<Longrightarrow> \<exists>no. \<forall>n\<ge>no. dist (X n) L < r) \<Longrightarrow> X ----> L"
   209 by (simp add: LIMSEQ_def)
   210 
   211 lemma metric_LIMSEQ_D:
   212   "\<lbrakk>X ----> L; 0 < r\<rbrakk> \<Longrightarrow> \<exists>no. \<forall>n\<ge>no. dist (X n) L < r"
   213 by (simp add: LIMSEQ_def)
   214 
   215 lemma LIMSEQ_I:
   216   fixes L :: "'a::real_normed_vector"
   217   shows "(\<And>r. 0 < r \<Longrightarrow> \<exists>no. \<forall>n\<ge>no. norm (X n - L) < r) \<Longrightarrow> X ----> L"
   218 by (simp add: LIMSEQ_iff)
   219 
   220 lemma LIMSEQ_D:
   221   fixes L :: "'a::real_normed_vector"
   222   shows "\<lbrakk>X ----> L; 0 < r\<rbrakk> \<Longrightarrow> \<exists>no. \<forall>n\<ge>no. norm (X n - L) < r"
   223 by (simp add: LIMSEQ_iff)
   224 
   225 lemma LIMSEQ_const: "(\<lambda>n. k) ----> k"
   226 by (simp add: LIMSEQ_def)
   227 
   228 lemma LIMSEQ_const_iff: "(\<lambda>n. k) ----> l \<longleftrightarrow> k = l"
   229 apply (safe intro!: LIMSEQ_const)
   230 apply (rule ccontr)
   231 apply (drule_tac r="dist k l" in metric_LIMSEQ_D)
   232 apply (simp add: zero_less_dist_iff)
   233 apply auto
   234 done
   235 
   236 lemma LIMSEQ_norm:
   237   fixes a :: "'a::real_normed_vector"
   238   shows "X ----> a \<Longrightarrow> (\<lambda>n. norm (X n)) ----> norm a"
   239 unfolding LIMSEQ_conv_tendsto by (rule tendsto_norm)
   240 
   241 lemma LIMSEQ_ignore_initial_segment:
   242   "f ----> a \<Longrightarrow> (\<lambda>n. f (n + k)) ----> a"
   243 apply (rule metric_LIMSEQ_I)
   244 apply (drule (1) metric_LIMSEQ_D)
   245 apply (erule exE, rename_tac N)
   246 apply (rule_tac x=N in exI)
   247 apply simp
   248 done
   249 
   250 lemma LIMSEQ_offset:
   251   "(\<lambda>n. f (n + k)) ----> a \<Longrightarrow> f ----> a"
   252 apply (rule metric_LIMSEQ_I)
   253 apply (drule (1) metric_LIMSEQ_D)
   254 apply (erule exE, rename_tac N)
   255 apply (rule_tac x="N + k" in exI)
   256 apply clarify
   257 apply (drule_tac x="n - k" in spec)
   258 apply (simp add: le_diff_conv2)
   259 done
   260 
   261 lemma LIMSEQ_Suc: "f ----> l \<Longrightarrow> (\<lambda>n. f (Suc n)) ----> l"
   262 by (drule_tac k="Suc 0" in LIMSEQ_ignore_initial_segment, simp)
   263 
   264 lemma LIMSEQ_imp_Suc: "(\<lambda>n. f (Suc n)) ----> l \<Longrightarrow> f ----> l"
   265 by (rule_tac k="Suc 0" in LIMSEQ_offset, simp)
   266 
   267 lemma LIMSEQ_Suc_iff: "(\<lambda>n. f (Suc n)) ----> l = f ----> l"
   268 by (blast intro: LIMSEQ_imp_Suc LIMSEQ_Suc)
   269 
   270 lemma LIMSEQ_linear: "\<lbrakk> X ----> x ; l > 0 \<rbrakk> \<Longrightarrow> (\<lambda> n. X (n * l)) ----> x"
   271   unfolding LIMSEQ_def
   272   by (metis div_le_dividend div_mult_self1_is_m le_trans nat_mult_commute)
   273 
   274 lemma LIMSEQ_add:
   275   fixes a b :: "'a::real_normed_vector"
   276   shows "\<lbrakk>X ----> a; Y ----> b\<rbrakk> \<Longrightarrow> (\<lambda>n. X n + Y n) ----> a + b"
   277 unfolding LIMSEQ_conv_tendsto by (rule tendsto_add)
   278 
   279 lemma LIMSEQ_minus:
   280   fixes a :: "'a::real_normed_vector"
   281   shows "X ----> a \<Longrightarrow> (\<lambda>n. - X n) ----> - a"
   282 unfolding LIMSEQ_conv_tendsto by (rule tendsto_minus)
   283 
   284 lemma LIMSEQ_minus_cancel:
   285   fixes a :: "'a::real_normed_vector"
   286   shows "(\<lambda>n. - X n) ----> - a \<Longrightarrow> X ----> a"
   287 by (drule LIMSEQ_minus, simp)
   288 
   289 lemma LIMSEQ_diff:
   290   fixes a b :: "'a::real_normed_vector"
   291   shows "\<lbrakk>X ----> a; Y ----> b\<rbrakk> \<Longrightarrow> (\<lambda>n. X n - Y n) ----> a - b"
   292 unfolding LIMSEQ_conv_tendsto by (rule tendsto_diff)
   293 
   294 lemma LIMSEQ_unique: "\<lbrakk>X ----> a; X ----> b\<rbrakk> \<Longrightarrow> a = b"
   295 apply (rule ccontr)
   296 apply (drule_tac r="dist a b / 2" in metric_LIMSEQ_D, simp add: zero_less_dist_iff)
   297 apply (drule_tac r="dist a b / 2" in metric_LIMSEQ_D, simp add: zero_less_dist_iff)
   298 apply (clarify, rename_tac M N)
   299 apply (subgoal_tac "dist a b < dist a b / 2 + dist a b / 2", simp)
   300 apply (subgoal_tac "dist a b \<le> dist (X (max M N)) a + dist (X (max M N)) b")
   301 apply (erule le_less_trans, rule add_strict_mono, simp, simp)
   302 apply (subst dist_commute, rule dist_triangle)
   303 done
   304 
   305 lemma (in bounded_linear) LIMSEQ:
   306   "X ----> a \<Longrightarrow> (\<lambda>n. f (X n)) ----> f a"
   307 unfolding LIMSEQ_conv_tendsto by (rule tendsto)
   308 
   309 lemma (in bounded_bilinear) LIMSEQ:
   310   "\<lbrakk>X ----> a; Y ----> b\<rbrakk> \<Longrightarrow> (\<lambda>n. X n ** Y n) ----> a ** b"
   311 unfolding LIMSEQ_conv_tendsto by (rule tendsto)
   312 
   313 lemma LIMSEQ_mult:
   314   fixes a b :: "'a::real_normed_algebra"
   315   shows "[| X ----> a; Y ----> b |] ==> (%n. X n * Y n) ----> a * b"
   316 by (rule mult.LIMSEQ)
   317 
   318 lemma Bseq_inverse_lemma:
   319   fixes x :: "'a::real_normed_div_algebra"
   320   shows "\<lbrakk>r \<le> norm x; 0 < r\<rbrakk> \<Longrightarrow> norm (inverse x) \<le> inverse r"
   321 apply (subst nonzero_norm_inverse, clarsimp)
   322 apply (erule (1) le_imp_inverse_le)
   323 done
   324 
   325 lemma Bseq_inverse:
   326   fixes a :: "'a::real_normed_div_algebra"
   327   shows "\<lbrakk>X ----> a; a \<noteq> 0\<rbrakk> \<Longrightarrow> Bseq (\<lambda>n. inverse (X n))"
   328 unfolding LIMSEQ_conv_tendsto Bseq_conv_Bfun
   329 by (rule Bfun_inverse)
   330 
   331 lemma LIMSEQ_inverse:
   332   fixes a :: "'a::real_normed_div_algebra"
   333   shows "\<lbrakk>X ----> a; a \<noteq> 0\<rbrakk> \<Longrightarrow> (\<lambda>n. inverse (X n)) ----> inverse a"
   334 unfolding LIMSEQ_conv_tendsto
   335 by (rule tendsto_inverse)
   336 
   337 lemma LIMSEQ_divide:
   338   fixes a b :: "'a::real_normed_field"
   339   shows "\<lbrakk>X ----> a; Y ----> b; b \<noteq> 0\<rbrakk> \<Longrightarrow> (\<lambda>n. X n / Y n) ----> a / b"
   340 by (simp add: LIMSEQ_mult LIMSEQ_inverse divide_inverse)
   341 
   342 lemma LIMSEQ_pow:
   343   fixes a :: "'a::{power, real_normed_algebra}"
   344   shows "X ----> a \<Longrightarrow> (\<lambda>n. (X n) ^ m) ----> a ^ m"
   345 by (induct m) (simp_all add: LIMSEQ_const LIMSEQ_mult)
   346 
   347 lemma LIMSEQ_setsum:
   348   fixes L :: "'a \<Rightarrow> 'b::real_normed_vector"
   349   assumes n: "\<And>n. n \<in> S \<Longrightarrow> X n ----> L n"
   350   shows "(\<lambda>m. \<Sum>n\<in>S. X n m) ----> (\<Sum>n\<in>S. L n)"
   351 using n unfolding LIMSEQ_conv_tendsto by (rule tendsto_setsum)
   352 
   353 lemma LIMSEQ_setprod:
   354   fixes L :: "'a \<Rightarrow> 'b::{real_normed_algebra,comm_ring_1}"
   355   assumes n: "\<And>n. n \<in> S \<Longrightarrow> X n ----> L n"
   356   shows "(\<lambda>m. \<Prod>n\<in>S. X n m) ----> (\<Prod>n\<in>S. L n)"
   357 proof (cases "finite S")
   358   case True
   359   thus ?thesis using n
   360   proof (induct)
   361     case empty
   362     show ?case
   363       by (simp add: LIMSEQ_const)
   364   next
   365     case insert
   366     thus ?case
   367       by (simp add: LIMSEQ_mult)
   368   qed
   369 next
   370   case False
   371   thus ?thesis
   372     by (simp add: setprod_def LIMSEQ_const)
   373 qed
   374 
   375 lemma LIMSEQ_add_const:
   376   fixes a :: "'a::real_normed_vector"
   377   shows "f ----> a ==> (%n.(f n + b)) ----> a + b"
   378 by (simp add: LIMSEQ_add LIMSEQ_const)
   379 
   380 (* FIXME: delete *)
   381 lemma LIMSEQ_add_minus:
   382   fixes a b :: "'a::real_normed_vector"
   383   shows "[| X ----> a; Y ----> b |] ==> (%n. X n + -Y n) ----> a + -b"
   384 by (simp only: LIMSEQ_add LIMSEQ_minus)
   385 
   386 lemma LIMSEQ_diff_const:
   387   fixes a b :: "'a::real_normed_vector"
   388   shows "f ----> a ==> (%n.(f n  - b)) ----> a - b"
   389 by (simp add: LIMSEQ_diff LIMSEQ_const)
   390 
   391 lemma LIMSEQ_diff_approach_zero:
   392   fixes L :: "'a::real_normed_vector"
   393   shows "g ----> L ==> (%x. f x - g x) ----> 0 ==> f ----> L"
   394 by (drule (1) LIMSEQ_add, simp)
   395 
   396 lemma LIMSEQ_diff_approach_zero2:
   397   fixes L :: "'a::real_normed_vector"
   398   shows "f ----> L ==> (%x. f x - g x) ----> 0 ==> g ----> L";
   399 by (drule (1) LIMSEQ_diff, simp)
   400 
   401 text{*A sequence tends to zero iff its abs does*}
   402 lemma LIMSEQ_norm_zero:
   403   fixes X :: "nat \<Rightarrow> 'a::real_normed_vector"
   404   shows "((\<lambda>n. norm (X n)) ----> 0) \<longleftrightarrow> (X ----> 0)"
   405 by (simp add: LIMSEQ_iff)
   406 
   407 lemma LIMSEQ_rabs_zero: "((%n. \<bar>f n\<bar>) ----> 0) = (f ----> (0::real))"
   408 by (simp add: LIMSEQ_iff)
   409 
   410 lemma LIMSEQ_imp_rabs: "f ----> (l::real) ==> (%n. \<bar>f n\<bar>) ----> \<bar>l\<bar>"
   411 by (drule LIMSEQ_norm, simp)
   412 
   413 text{*An unbounded sequence's inverse tends to 0*}
   414 
   415 lemma LIMSEQ_inverse_zero:
   416   "\<forall>r::real. \<exists>N. \<forall>n\<ge>N. r < X n \<Longrightarrow> (\<lambda>n. inverse (X n)) ----> 0"
   417 apply (rule LIMSEQ_I)
   418 apply (drule_tac x="inverse r" in spec, safe)
   419 apply (rule_tac x="N" in exI, safe)
   420 apply (drule_tac x="n" in spec, safe)
   421 apply (frule positive_imp_inverse_positive)
   422 apply (frule (1) less_imp_inverse_less)
   423 apply (subgoal_tac "0 < X n", simp)
   424 apply (erule (1) order_less_trans)
   425 done
   426 
   427 text{*The sequence @{term "1/n"} tends to 0 as @{term n} tends to infinity*}
   428 
   429 lemma LIMSEQ_inverse_real_of_nat: "(%n. inverse(real(Suc n))) ----> 0"
   430 apply (rule LIMSEQ_inverse_zero, safe)
   431 apply (cut_tac x = r in reals_Archimedean2)
   432 apply (safe, rule_tac x = n in exI)
   433 apply (auto simp add: real_of_nat_Suc)
   434 done
   435 
   436 text{*The sequence @{term "r + 1/n"} tends to @{term r} as @{term n} tends to
   437 infinity is now easily proved*}
   438 
   439 lemma LIMSEQ_inverse_real_of_nat_add:
   440      "(%n. r + inverse(real(Suc n))) ----> r"
   441 by (cut_tac LIMSEQ_add [OF LIMSEQ_const LIMSEQ_inverse_real_of_nat], auto)
   442 
   443 lemma LIMSEQ_inverse_real_of_nat_add_minus:
   444      "(%n. r + -inverse(real(Suc n))) ----> r"
   445 by (cut_tac LIMSEQ_add_minus [OF LIMSEQ_const LIMSEQ_inverse_real_of_nat], auto)
   446 
   447 lemma LIMSEQ_inverse_real_of_nat_add_minus_mult:
   448      "(%n. r*( 1 + -inverse(real(Suc n)))) ----> r"
   449 by (cut_tac b=1 in
   450         LIMSEQ_mult [OF LIMSEQ_const LIMSEQ_inverse_real_of_nat_add_minus], auto)
   451 
   452 lemma LIMSEQ_le_const:
   453   "\<lbrakk>X ----> (x::real); \<exists>N. \<forall>n\<ge>N. a \<le> X n\<rbrakk> \<Longrightarrow> a \<le> x"
   454 apply (rule ccontr, simp only: linorder_not_le)
   455 apply (drule_tac r="a - x" in LIMSEQ_D, simp)
   456 apply clarsimp
   457 apply (drule_tac x="max N no" in spec, drule mp, rule le_maxI1)
   458 apply (drule_tac x="max N no" in spec, drule mp, rule le_maxI2)
   459 apply simp
   460 done
   461 
   462 lemma LIMSEQ_le_const2:
   463   "\<lbrakk>X ----> (x::real); \<exists>N. \<forall>n\<ge>N. X n \<le> a\<rbrakk> \<Longrightarrow> x \<le> a"
   464 apply (subgoal_tac "- a \<le> - x", simp)
   465 apply (rule LIMSEQ_le_const)
   466 apply (erule LIMSEQ_minus)
   467 apply simp
   468 done
   469 
   470 lemma LIMSEQ_le:
   471   "\<lbrakk>X ----> x; Y ----> y; \<exists>N. \<forall>n\<ge>N. X n \<le> Y n\<rbrakk> \<Longrightarrow> x \<le> (y::real)"
   472 apply (subgoal_tac "0 \<le> y - x", simp)
   473 apply (rule LIMSEQ_le_const)
   474 apply (erule (1) LIMSEQ_diff)
   475 apply (simp add: le_diff_eq)
   476 done
   477 
   478 
   479 subsection {* Convergence *}
   480 
   481 lemma limI: "X ----> L ==> lim X = L"
   482 apply (simp add: lim_def)
   483 apply (blast intro: LIMSEQ_unique)
   484 done
   485 
   486 lemma convergentD: "convergent X ==> \<exists>L. (X ----> L)"
   487 by (simp add: convergent_def)
   488 
   489 lemma convergentI: "(X ----> L) ==> convergent X"
   490 by (auto simp add: convergent_def)
   491 
   492 lemma convergent_LIMSEQ_iff: "convergent X = (X ----> lim X)"
   493 by (auto intro: theI LIMSEQ_unique simp add: convergent_def lim_def)
   494 
   495 lemma convergent_minus_iff:
   496   fixes X :: "nat \<Rightarrow> 'a::real_normed_vector"
   497   shows "convergent X \<longleftrightarrow> convergent (\<lambda>n. - X n)"
   498 apply (simp add: convergent_def)
   499 apply (auto dest: LIMSEQ_minus)
   500 apply (drule LIMSEQ_minus, auto)
   501 done
   502 
   503 text{* Given a binary function @{text "f:: nat \<Rightarrow> 'a \<Rightarrow> 'a"}, its values are uniquely determined by a function g *}
   504 
   505 lemma nat_function_unique: "EX! g. g 0 = e \<and> (\<forall>n. g (Suc n) = f n (g n))"
   506   unfolding Ex1_def
   507   apply (rule_tac x="nat_rec e f" in exI)
   508   apply (rule conjI)+
   509 apply (rule def_nat_rec_0, simp)
   510 apply (rule allI, rule def_nat_rec_Suc, simp)
   511 apply (rule allI, rule impI, rule ext)
   512 apply (erule conjE)
   513 apply (induct_tac x)
   514 apply (simp add: nat_rec_0)
   515 apply (erule_tac x="n" in allE)
   516 apply (simp)
   517 done
   518 
   519 text{*Subsequence (alternative definition, (e.g. Hoskins)*}
   520 
   521 lemma subseq_Suc_iff: "subseq f = (\<forall>n. (f n) < (f (Suc n)))"
   522 apply (simp add: subseq_def)
   523 apply (auto dest!: less_imp_Suc_add)
   524 apply (induct_tac k)
   525 apply (auto intro: less_trans)
   526 done
   527 
   528 lemma monoseq_Suc:
   529    "monoseq X = ((\<forall>n. X n \<le> X (Suc n))
   530                  | (\<forall>n. X (Suc n) \<le> X n))"
   531 apply (simp add: monoseq_def)
   532 apply (auto dest!: le_imp_less_or_eq)
   533 apply (auto intro!: lessI [THEN less_imp_le] dest!: less_imp_Suc_add)
   534 apply (induct_tac "ka")
   535 apply (auto intro: order_trans)
   536 apply (erule contrapos_np)
   537 apply (induct_tac "k")
   538 apply (auto intro: order_trans)
   539 done
   540 
   541 lemma monoI1: "\<forall>m. \<forall> n \<ge> m. X m \<le> X n ==> monoseq X"
   542 by (simp add: monoseq_def)
   543 
   544 lemma monoI2: "\<forall>m. \<forall> n \<ge> m. X n \<le> X m ==> monoseq X"
   545 by (simp add: monoseq_def)
   546 
   547 lemma mono_SucI1: "\<forall>n. X n \<le> X (Suc n) ==> monoseq X"
   548 by (simp add: monoseq_Suc)
   549 
   550 lemma mono_SucI2: "\<forall>n. X (Suc n) \<le> X n ==> monoseq X"
   551 by (simp add: monoseq_Suc)
   552 
   553 lemma monoseq_minus: assumes "monoseq a"
   554   shows "monoseq (\<lambda> n. - a n)"
   555 proof (cases "\<forall> m. \<forall> n \<ge> m. a m \<le> a n")
   556   case True
   557   hence "\<forall> m. \<forall> n \<ge> m. - a n \<le> - a m" by auto
   558   thus ?thesis by (rule monoI2)
   559 next
   560   case False
   561   hence "\<forall> m. \<forall> n \<ge> m. - a m \<le> - a n" using `monoseq a`[unfolded monoseq_def] by auto
   562   thus ?thesis by (rule monoI1)
   563 qed
   564 
   565 lemma monoseq_le: assumes "monoseq a" and "a ----> x"
   566   shows "((\<forall> n. a n \<le> x) \<and> (\<forall>m. \<forall>n\<ge>m. a m \<le> a n)) \<or> 
   567          ((\<forall> n. x \<le> a n) \<and> (\<forall>m. \<forall>n\<ge>m. a n \<le> a m))"
   568 proof -
   569   { fix x n fix a :: "nat \<Rightarrow> real"
   570     assume "a ----> x" and "\<forall> m. \<forall> n \<ge> m. a m \<le> a n"
   571     hence monotone: "\<And> m n. m \<le> n \<Longrightarrow> a m \<le> a n" by auto
   572     have "a n \<le> x"
   573     proof (rule ccontr)
   574       assume "\<not> a n \<le> x" hence "x < a n" by auto
   575       hence "0 < a n - x" by auto
   576       from `a ----> x`[THEN LIMSEQ_D, OF this]
   577       obtain no where "\<And>n'. no \<le> n' \<Longrightarrow> norm (a n' - x) < a n - x" by blast
   578       hence "norm (a (max no n) - x) < a n - x" by auto
   579       moreover
   580       { fix n' have "n \<le> n' \<Longrightarrow> x < a n'" using monotone[where m=n and n=n'] and `x < a n` by auto }
   581       hence "x < a (max no n)" by auto
   582       ultimately
   583       have "a (max no n) < a n" by auto
   584       with monotone[where m=n and n="max no n"]
   585       show False by auto
   586     qed
   587   } note top_down = this
   588   { fix x n m fix a :: "nat \<Rightarrow> real"
   589     assume "a ----> x" and "monoseq a" and "a m < x"
   590     have "a n \<le> x \<and> (\<forall> m. \<forall> n \<ge> m. a m \<le> a n)"
   591     proof (cases "\<forall> m. \<forall> n \<ge> m. a m \<le> a n")
   592       case True with top_down and `a ----> x` show ?thesis by auto
   593     next
   594       case False with `monoseq a`[unfolded monoseq_def] have "\<forall> m. \<forall> n \<ge> m. - a m \<le> - a n" by auto
   595       hence "- a m \<le> - x" using top_down[OF LIMSEQ_minus[OF `a ----> x`]] by blast
   596       hence False using `a m < x` by auto
   597       thus ?thesis ..
   598     qed
   599   } note when_decided = this
   600 
   601   show ?thesis
   602   proof (cases "\<exists> m. a m \<noteq> x")
   603     case True then obtain m where "a m \<noteq> x" by auto
   604     show ?thesis
   605     proof (cases "a m < x")
   606       case True with when_decided[OF `a ----> x` `monoseq a`, where m2=m]
   607       show ?thesis by blast
   608     next
   609       case False hence "- a m < - x" using `a m \<noteq> x` by auto
   610       with when_decided[OF LIMSEQ_minus[OF `a ----> x`] monoseq_minus[OF `monoseq a`], where m2=m]
   611       show ?thesis by auto
   612     qed
   613   qed auto
   614 qed
   615 
   616 text{* for any sequence, there is a mootonic subsequence *}
   617 lemma seq_monosub: "\<exists>f. subseq f \<and> monoseq (\<lambda> n. (s (f n)))"
   618 proof-
   619   {assume H: "\<forall>n. \<exists>p >n. \<forall> m\<ge>p. s m \<le> s p"
   620     let ?P = "\<lambda> p n. p > n \<and> (\<forall>m \<ge> p. s m \<le> s p)"
   621     from nat_function_unique[of "SOME p. ?P p 0" "\<lambda>p n. SOME p. ?P p n"]
   622     obtain f where f: "f 0 = (SOME p. ?P p 0)" "\<forall>n. f (Suc n) = (SOME p. ?P p (f n))" by blast
   623     have "?P (f 0) 0"  unfolding f(1) some_eq_ex[of "\<lambda>p. ?P p 0"]
   624       using H apply - 
   625       apply (erule allE[where x=0], erule exE, rule_tac x="p" in exI) 
   626       unfolding order_le_less by blast 
   627     hence f0: "f 0 > 0" "\<forall>m \<ge> f 0. s m \<le> s (f 0)" by blast+
   628     {fix n
   629       have "?P (f (Suc n)) (f n)" 
   630 	unfolding f(2)[rule_format, of n] some_eq_ex[of "\<lambda>p. ?P p (f n)"]
   631 	using H apply - 
   632       apply (erule allE[where x="f n"], erule exE, rule_tac x="p" in exI) 
   633       unfolding order_le_less by blast 
   634     hence "f (Suc n) > f n" "\<forall>m \<ge> f (Suc n). s m \<le> s (f (Suc n))" by blast+}
   635   note fSuc = this
   636     {fix p q assume pq: "p \<ge> f q"
   637       have "s p \<le> s(f(q))"  using f0(2)[rule_format, of p] pq fSuc
   638 	by (cases q, simp_all) }
   639     note pqth = this
   640     {fix q
   641       have "f (Suc q) > f q" apply (induct q) 
   642 	using f0(1) fSuc(1)[of 0] apply simp by (rule fSuc(1))}
   643     note fss = this
   644     from fss have th1: "subseq f" unfolding subseq_Suc_iff ..
   645     {fix a b 
   646       have "f a \<le> f (a + b)"
   647       proof(induct b)
   648 	case 0 thus ?case by simp
   649       next
   650 	case (Suc b)
   651 	from fSuc(1)[of "a + b"] Suc.hyps show ?case by simp
   652       qed}
   653     note fmon0 = this
   654     have "monoseq (\<lambda>n. s (f n))" 
   655     proof-
   656       {fix n
   657 	have "s (f n) \<ge> s (f (Suc n))" 
   658 	proof(cases n)
   659 	  case 0
   660 	  assume n0: "n = 0"
   661 	  from fSuc(1)[of 0] have th0: "f 0 \<le> f (Suc 0)" by simp
   662 	  from f0(2)[rule_format, OF th0] show ?thesis  using n0 by simp
   663 	next
   664 	  case (Suc m)
   665 	  assume m: "n = Suc m"
   666 	  from fSuc(1)[of n] m have th0: "f (Suc m) \<le> f (Suc (Suc m))" by simp
   667 	  from m fSuc(2)[rule_format, OF th0] show ?thesis by simp 
   668 	qed}
   669       thus "monoseq (\<lambda>n. s (f n))" unfolding monoseq_Suc by blast 
   670     qed
   671     with th1 have ?thesis by blast}
   672   moreover
   673   {fix N assume N: "\<forall>p >N. \<exists> m\<ge>p. s m > s p"
   674     {fix p assume p: "p \<ge> Suc N" 
   675       hence pN: "p > N" by arith with N obtain m where m: "m \<ge> p" "s m > s p" by blast
   676       have "m \<noteq> p" using m(2) by auto 
   677       with m have "\<exists>m>p. s p < s m" by - (rule exI[where x=m], auto)}
   678     note th0 = this
   679     let ?P = "\<lambda>m x. m > x \<and> s x < s m"
   680     from nat_function_unique[of "SOME x. ?P x (Suc N)" "\<lambda>m x. SOME y. ?P y x"]
   681     obtain f where f: "f 0 = (SOME x. ?P x (Suc N))" 
   682       "\<forall>n. f (Suc n) = (SOME m. ?P m (f n))" by blast
   683     have "?P (f 0) (Suc N)"  unfolding f(1) some_eq_ex[of "\<lambda>p. ?P p (Suc N)"]
   684       using N apply - 
   685       apply (erule allE[where x="Suc N"], clarsimp)
   686       apply (rule_tac x="m" in exI)
   687       apply auto
   688       apply (subgoal_tac "Suc N \<noteq> m")
   689       apply simp
   690       apply (rule ccontr, simp)
   691       done
   692     hence f0: "f 0 > Suc N" "s (Suc N) < s (f 0)" by blast+
   693     {fix n
   694       have "f n > N \<and> ?P (f (Suc n)) (f n)"
   695 	unfolding f(2)[rule_format, of n] some_eq_ex[of "\<lambda>p. ?P p (f n)"]
   696       proof (induct n)
   697 	case 0 thus ?case
   698 	  using f0 N apply auto 
   699 	  apply (erule allE[where x="f 0"], clarsimp) 
   700 	  apply (rule_tac x="m" in exI, simp)
   701 	  by (subgoal_tac "f 0 \<noteq> m", auto)
   702       next
   703 	case (Suc n)
   704 	from Suc.hyps have Nfn: "N < f n" by blast
   705 	from Suc.hyps obtain m where m: "m > f n" "s (f n) < s m" by blast
   706 	with Nfn have mN: "m > N" by arith
   707 	note key = Suc.hyps[unfolded some_eq_ex[of "\<lambda>p. ?P p (f n)", symmetric] f(2)[rule_format, of n, symmetric]]
   708 	
   709 	from key have th0: "f (Suc n) > N" by simp
   710 	from N[rule_format, OF th0]
   711 	obtain m' where m': "m' \<ge> f (Suc n)" "s (f (Suc n)) < s m'" by blast
   712 	have "m' \<noteq> f (Suc (n))" apply (rule ccontr) using m'(2) by auto
   713 	hence "m' > f (Suc n)" using m'(1) by simp
   714 	with key m'(2) show ?case by auto
   715       qed}
   716     note fSuc = this
   717     {fix n
   718       have "f n \<ge> Suc N \<and> f(Suc n) > f n \<and> s(f n) < s(f(Suc n))" using fSuc[of n] by auto 
   719       hence "f n \<ge> Suc N" "f(Suc n) > f n" "s(f n) < s(f(Suc n))" by blast+}
   720     note thf = this
   721     have sqf: "subseq f" unfolding subseq_Suc_iff using thf by simp
   722     have "monoseq (\<lambda>n. s (f n))"  unfolding monoseq_Suc using thf
   723       apply -
   724       apply (rule disjI1)
   725       apply auto
   726       apply (rule order_less_imp_le)
   727       apply blast
   728       done
   729     then have ?thesis  using sqf by blast}
   730   ultimately show ?thesis unfolding linorder_not_less[symmetric] by blast
   731 qed
   732 
   733 lemma seq_suble: assumes sf: "subseq f" shows "n \<le> f n"
   734 proof(induct n)
   735   case 0 thus ?case by simp
   736 next
   737   case (Suc n)
   738   from sf[unfolded subseq_Suc_iff, rule_format, of n] Suc.hyps
   739   have "n < f (Suc n)" by arith 
   740   thus ?case by arith
   741 qed
   742 
   743 lemma LIMSEQ_subseq_LIMSEQ:
   744   "\<lbrakk> X ----> L; subseq f \<rbrakk> \<Longrightarrow> (X o f) ----> L"
   745 apply (auto simp add: LIMSEQ_def) 
   746 apply (drule_tac x=r in spec, clarify)  
   747 apply (rule_tac x=no in exI, clarify) 
   748 apply (blast intro: seq_suble le_trans dest!: spec) 
   749 done
   750 
   751 subsection {* Bounded Monotonic Sequences *}
   752 
   753 
   754 text{*Bounded Sequence*}
   755 
   756 lemma BseqD: "Bseq X ==> \<exists>K. 0 < K & (\<forall>n. norm (X n) \<le> K)"
   757 by (simp add: Bseq_def)
   758 
   759 lemma BseqI: "[| 0 < K; \<forall>n. norm (X n) \<le> K |] ==> Bseq X"
   760 by (auto simp add: Bseq_def)
   761 
   762 lemma lemma_NBseq_def:
   763      "(\<exists>K > 0. \<forall>n. norm (X n) \<le> K) =
   764       (\<exists>N. \<forall>n. norm (X n) \<le> real(Suc N))"
   765 apply auto
   766  prefer 2 apply force
   767 apply (cut_tac x = K in reals_Archimedean2, clarify)
   768 apply (rule_tac x = n in exI, clarify)
   769 apply (drule_tac x = na in spec)
   770 apply (auto simp add: real_of_nat_Suc)
   771 done
   772 
   773 text{* alternative definition for Bseq *}
   774 lemma Bseq_iff: "Bseq X = (\<exists>N. \<forall>n. norm (X n) \<le> real(Suc N))"
   775 apply (simp add: Bseq_def)
   776 apply (simp (no_asm) add: lemma_NBseq_def)
   777 done
   778 
   779 lemma lemma_NBseq_def2:
   780      "(\<exists>K > 0. \<forall>n. norm (X n) \<le> K) = (\<exists>N. \<forall>n. norm (X n) < real(Suc N))"
   781 apply (subst lemma_NBseq_def, auto)
   782 apply (rule_tac x = "Suc N" in exI)
   783 apply (rule_tac [2] x = N in exI)
   784 apply (auto simp add: real_of_nat_Suc)
   785  prefer 2 apply (blast intro: order_less_imp_le)
   786 apply (drule_tac x = n in spec, simp)
   787 done
   788 
   789 (* yet another definition for Bseq *)
   790 lemma Bseq_iff1a: "Bseq X = (\<exists>N. \<forall>n. norm (X n) < real(Suc N))"
   791 by (simp add: Bseq_def lemma_NBseq_def2)
   792 
   793 subsubsection{*Upper Bounds and Lubs of Bounded Sequences*}
   794 
   795 lemma Bseq_isUb:
   796   "!!(X::nat=>real). Bseq X ==> \<exists>U. isUb (UNIV::real set) {x. \<exists>n. X n = x} U"
   797 by (auto intro: isUbI setleI simp add: Bseq_def abs_le_iff)
   798 
   799 
   800 text{* Use completeness of reals (supremum property)
   801    to show that any bounded sequence has a least upper bound*}
   802 
   803 lemma Bseq_isLub:
   804   "!!(X::nat=>real). Bseq X ==>
   805    \<exists>U. isLub (UNIV::real set) {x. \<exists>n. X n = x} U"
   806 by (blast intro: reals_complete Bseq_isUb)
   807 
   808 subsubsection{*A Bounded and Monotonic Sequence Converges*}
   809 
   810 lemma lemma_converg1:
   811      "!!(X::nat=>real). [| \<forall>m. \<forall> n \<ge> m. X m \<le> X n;
   812                   isLub (UNIV::real set) {x. \<exists>n. X n = x} (X ma)
   813                |] ==> \<forall>n \<ge> ma. X n = X ma"
   814 apply safe
   815 apply (drule_tac y = "X n" in isLubD2)
   816 apply (blast dest: order_antisym)+
   817 done
   818 
   819 text{* The best of both worlds: Easier to prove this result as a standard
   820    theorem and then use equivalence to "transfer" it into the
   821    equivalent nonstandard form if needed!*}
   822 
   823 lemma Bmonoseq_LIMSEQ: "\<forall>n. m \<le> n --> X n = X m ==> \<exists>L. (X ----> L)"
   824 apply (simp add: LIMSEQ_def)
   825 apply (rule_tac x = "X m" in exI, safe)
   826 apply (rule_tac x = m in exI, safe)
   827 apply (drule spec, erule impE, auto)
   828 done
   829 
   830 lemma lemma_converg2:
   831    "!!(X::nat=>real).
   832     [| \<forall>m. X m ~= U;  isLub UNIV {x. \<exists>n. X n = x} U |] ==> \<forall>m. X m < U"
   833 apply safe
   834 apply (drule_tac y = "X m" in isLubD2)
   835 apply (auto dest!: order_le_imp_less_or_eq)
   836 done
   837 
   838 lemma lemma_converg3: "!!(X ::nat=>real). \<forall>m. X m \<le> U ==> isUb UNIV {x. \<exists>n. X n = x} U"
   839 by (rule setleI [THEN isUbI], auto)
   840 
   841 text{* FIXME: @{term "U - T < U"} is redundant *}
   842 lemma lemma_converg4: "!!(X::nat=> real).
   843                [| \<forall>m. X m ~= U;
   844                   isLub UNIV {x. \<exists>n. X n = x} U;
   845                   0 < T;
   846                   U + - T < U
   847                |] ==> \<exists>m. U + -T < X m & X m < U"
   848 apply (drule lemma_converg2, assumption)
   849 apply (rule ccontr, simp)
   850 apply (simp add: linorder_not_less)
   851 apply (drule lemma_converg3)
   852 apply (drule isLub_le_isUb, assumption)
   853 apply (auto dest: order_less_le_trans)
   854 done
   855 
   856 text{*A standard proof of the theorem for monotone increasing sequence*}
   857 
   858 lemma Bseq_mono_convergent:
   859      "[| Bseq X; \<forall>m. \<forall>n \<ge> m. X m \<le> X n |] ==> convergent (X::nat=>real)"
   860 apply (simp add: convergent_def)
   861 apply (frule Bseq_isLub, safe)
   862 apply (case_tac "\<exists>m. X m = U", auto)
   863 apply (blast dest: lemma_converg1 Bmonoseq_LIMSEQ)
   864 (* second case *)
   865 apply (rule_tac x = U in exI)
   866 apply (subst LIMSEQ_iff, safe)
   867 apply (frule lemma_converg2, assumption)
   868 apply (drule lemma_converg4, auto)
   869 apply (rule_tac x = m in exI, safe)
   870 apply (subgoal_tac "X m \<le> X n")
   871  prefer 2 apply blast
   872 apply (drule_tac x=n and P="%m. X m < U" in spec, arith)
   873 done
   874 
   875 lemma Bseq_minus_iff: "Bseq (%n. -(X n)) = Bseq X"
   876 by (simp add: Bseq_def)
   877 
   878 text{*Main monotonicity theorem*}
   879 lemma Bseq_monoseq_convergent: "[| Bseq X; monoseq X |] ==> convergent X"
   880 apply (simp add: monoseq_def, safe)
   881 apply (rule_tac [2] convergent_minus_iff [THEN ssubst])
   882 apply (drule_tac [2] Bseq_minus_iff [THEN ssubst])
   883 apply (auto intro!: Bseq_mono_convergent)
   884 done
   885 
   886 subsubsection{*Increasing and Decreasing Series*}
   887 
   888 lemma incseq_imp_monoseq:  "incseq X \<Longrightarrow> monoseq X"
   889   by (simp add: incseq_def monoseq_def) 
   890 
   891 lemma incseq_le: assumes inc: "incseq X" and lim: "X ----> L" shows "X n \<le> L"
   892   using monoseq_le [OF incseq_imp_monoseq [OF inc] lim]
   893 proof
   894   assume "(\<forall>n. X n \<le> L) \<and> (\<forall>m n. m \<le> n \<longrightarrow> X m \<le> X n)"
   895   thus ?thesis by simp
   896 next
   897   assume "(\<forall>n. L \<le> X n) \<and> (\<forall>m n. m \<le> n \<longrightarrow> X n \<le> X m)"
   898   hence const: "(!!m n. m \<le> n \<Longrightarrow> X n = X m)" using inc
   899     by (auto simp add: incseq_def intro: order_antisym)
   900   have X: "!!n. X n = X 0"
   901     by (blast intro: const [of 0]) 
   902   have "X = (\<lambda>n. X 0)"
   903     by (blast intro: ext X)
   904   hence "L = X 0" using LIMSEQ_const [of "X 0"]
   905     by (auto intro: LIMSEQ_unique lim) 
   906   thus ?thesis
   907     by (blast intro: eq_refl X)
   908 qed
   909 
   910 lemma decseq_imp_monoseq:  "decseq X \<Longrightarrow> monoseq X"
   911   by (simp add: decseq_def monoseq_def)
   912 
   913 lemma decseq_eq_incseq: "decseq X = incseq (\<lambda>n. - X n)" 
   914   by (simp add: decseq_def incseq_def)
   915 
   916 
   917 lemma decseq_le: assumes dec: "decseq X" and lim: "X ----> L" shows "L \<le> X n"
   918 proof -
   919   have inc: "incseq (\<lambda>n. - X n)" using dec
   920     by (simp add: decseq_eq_incseq)
   921   have "- X n \<le> - L" 
   922     by (blast intro: incseq_le [OF inc] LIMSEQ_minus lim) 
   923   thus ?thesis
   924     by simp
   925 qed
   926 
   927 subsubsection{*A Few More Equivalence Theorems for Boundedness*}
   928 
   929 text{*alternative formulation for boundedness*}
   930 lemma Bseq_iff2: "Bseq X = (\<exists>k > 0. \<exists>x. \<forall>n. norm (X(n) + -x) \<le> k)"
   931 apply (unfold Bseq_def, safe)
   932 apply (rule_tac [2] x = "k + norm x" in exI)
   933 apply (rule_tac x = K in exI, simp)
   934 apply (rule exI [where x = 0], auto)
   935 apply (erule order_less_le_trans, simp)
   936 apply (drule_tac x=n in spec, fold diff_def)
   937 apply (drule order_trans [OF norm_triangle_ineq2])
   938 apply simp
   939 done
   940 
   941 text{*alternative formulation for boundedness*}
   942 lemma Bseq_iff3: "Bseq X = (\<exists>k > 0. \<exists>N. \<forall>n. norm(X(n) + -X(N)) \<le> k)"
   943 apply safe
   944 apply (simp add: Bseq_def, safe)
   945 apply (rule_tac x = "K + norm (X N)" in exI)
   946 apply auto
   947 apply (erule order_less_le_trans, simp)
   948 apply (rule_tac x = N in exI, safe)
   949 apply (drule_tac x = n in spec)
   950 apply (rule order_trans [OF norm_triangle_ineq], simp)
   951 apply (auto simp add: Bseq_iff2)
   952 done
   953 
   954 lemma BseqI2: "(\<forall>n. k \<le> f n & f n \<le> (K::real)) ==> Bseq f"
   955 apply (simp add: Bseq_def)
   956 apply (rule_tac x = " (\<bar>k\<bar> + \<bar>K\<bar>) + 1" in exI, auto)
   957 apply (drule_tac x = n in spec, arith)
   958 done
   959 
   960 
   961 subsection {* Cauchy Sequences *}
   962 
   963 lemma metric_CauchyI:
   964   "(\<And>e. 0 < e \<Longrightarrow> \<exists>M. \<forall>m\<ge>M. \<forall>n\<ge>M. dist (X m) (X n) < e) \<Longrightarrow> Cauchy X"
   965 by (simp add: Cauchy_def)
   966 
   967 lemma metric_CauchyD:
   968   "\<lbrakk>Cauchy X; 0 < e\<rbrakk> \<Longrightarrow> \<exists>M. \<forall>m\<ge>M. \<forall>n\<ge>M. dist (X m) (X n) < e"
   969 by (simp add: Cauchy_def)
   970 
   971 lemma Cauchy_iff:
   972   fixes X :: "nat \<Rightarrow> 'a::real_normed_vector"
   973   shows "Cauchy X \<longleftrightarrow> (\<forall>e>0. \<exists>M. \<forall>m\<ge>M. \<forall>n\<ge>M. norm (X m - X n) < e)"
   974 unfolding Cauchy_def dist_norm ..
   975 
   976 lemma CauchyI:
   977   fixes X :: "nat \<Rightarrow> 'a::real_normed_vector"
   978   shows "(\<And>e. 0 < e \<Longrightarrow> \<exists>M. \<forall>m\<ge>M. \<forall>n\<ge>M. norm (X m - X n) < e) \<Longrightarrow> Cauchy X"
   979 by (simp add: Cauchy_iff)
   980 
   981 lemma CauchyD:
   982   fixes X :: "nat \<Rightarrow> 'a::real_normed_vector"
   983   shows "\<lbrakk>Cauchy X; 0 < e\<rbrakk> \<Longrightarrow> \<exists>M. \<forall>m\<ge>M. \<forall>n\<ge>M. norm (X m - X n) < e"
   984 by (simp add: Cauchy_iff)
   985 
   986 lemma Cauchy_subseq_Cauchy:
   987   "\<lbrakk> Cauchy X; subseq f \<rbrakk> \<Longrightarrow> Cauchy (X o f)"
   988 apply (auto simp add: Cauchy_def)
   989 apply (drule_tac x=e in spec, clarify)
   990 apply (rule_tac x=M in exI, clarify)
   991 apply (blast intro: le_trans [OF _ seq_suble] dest!: spec)
   992 done
   993 
   994 subsubsection {* Cauchy Sequences are Bounded *}
   995 
   996 text{*A Cauchy sequence is bounded -- this is the standard
   997   proof mechanization rather than the nonstandard proof*}
   998 
   999 lemma lemmaCauchy: "\<forall>n \<ge> M. norm (X M - X n) < (1::real)
  1000           ==>  \<forall>n \<ge> M. norm (X n :: 'a::real_normed_vector) < 1 + norm (X M)"
  1001 apply (clarify, drule spec, drule (1) mp)
  1002 apply (simp only: norm_minus_commute)
  1003 apply (drule order_le_less_trans [OF norm_triangle_ineq2])
  1004 apply simp
  1005 done
  1006 
  1007 lemma Cauchy_Bseq: "Cauchy X ==> Bseq X"
  1008 apply (simp add: Cauchy_iff)
  1009 apply (drule spec, drule mp, rule zero_less_one, safe)
  1010 apply (drule_tac x="M" in spec, simp)
  1011 apply (drule lemmaCauchy)
  1012 apply (rule_tac k="M" in Bseq_offset)
  1013 apply (simp add: Bseq_def)
  1014 apply (rule_tac x="1 + norm (X M)" in exI)
  1015 apply (rule conjI, rule order_less_le_trans [OF zero_less_one], simp)
  1016 apply (simp add: order_less_imp_le)
  1017 done
  1018 
  1019 subsubsection {* Cauchy Sequences are Convergent *}
  1020 
  1021 axclass complete_space \<subseteq> metric_space
  1022   Cauchy_convergent: "Cauchy X \<Longrightarrow> convergent X"
  1023 
  1024 axclass banach \<subseteq> real_normed_vector, complete_space
  1025 
  1026 theorem LIMSEQ_imp_Cauchy:
  1027   assumes X: "X ----> a" shows "Cauchy X"
  1028 proof (rule metric_CauchyI)
  1029   fix e::real assume "0 < e"
  1030   hence "0 < e/2" by simp
  1031   with X have "\<exists>N. \<forall>n\<ge>N. dist (X n) a < e/2" by (rule metric_LIMSEQ_D)
  1032   then obtain N where N: "\<forall>n\<ge>N. dist (X n) a < e/2" ..
  1033   show "\<exists>N. \<forall>m\<ge>N. \<forall>n\<ge>N. dist (X m) (X n) < e"
  1034   proof (intro exI allI impI)
  1035     fix m assume "N \<le> m"
  1036     hence m: "dist (X m) a < e/2" using N by fast
  1037     fix n assume "N \<le> n"
  1038     hence n: "dist (X n) a < e/2" using N by fast
  1039     have "dist (X m) (X n) \<le> dist (X m) a + dist (X n) a"
  1040       by (rule dist_triangle2)
  1041     also from m n have "\<dots> < e" by simp
  1042     finally show "dist (X m) (X n) < e" .
  1043   qed
  1044 qed
  1045 
  1046 lemma convergent_Cauchy: "convergent X \<Longrightarrow> Cauchy X"
  1047 unfolding convergent_def
  1048 by (erule exE, erule LIMSEQ_imp_Cauchy)
  1049 
  1050 lemma Cauchy_convergent_iff:
  1051   fixes X :: "nat \<Rightarrow> 'a::complete_space"
  1052   shows "Cauchy X = convergent X"
  1053 by (fast intro: Cauchy_convergent convergent_Cauchy)
  1054 
  1055 lemma convergent_subseq_convergent:
  1056   fixes X :: "nat \<Rightarrow> 'a::complete_space"
  1057   shows "\<lbrakk> convergent X; subseq f \<rbrakk> \<Longrightarrow> convergent (X o f)"
  1058   by (simp add: Cauchy_subseq_Cauchy Cauchy_convergent_iff [symmetric])
  1059 
  1060 text {*
  1061 Proof that Cauchy sequences converge based on the one from
  1062 http://pirate.shu.edu/~wachsmut/ira/numseq/proofs/cauconv.html
  1063 *}
  1064 
  1065 text {*
  1066   If sequence @{term "X"} is Cauchy, then its limit is the lub of
  1067   @{term "{r::real. \<exists>N. \<forall>n\<ge>N. r < X n}"}
  1068 *}
  1069 
  1070 lemma isUb_UNIV_I: "(\<And>y. y \<in> S \<Longrightarrow> y \<le> u) \<Longrightarrow> isUb UNIV S u"
  1071 by (simp add: isUbI setleI)
  1072 
  1073 lemma real_abs_diff_less_iff:
  1074   "(\<bar>x - a\<bar> < (r::real)) = (a - r < x \<and> x < a + r)"
  1075 by auto
  1076 
  1077 locale real_Cauchy =
  1078   fixes X :: "nat \<Rightarrow> real"
  1079   assumes X: "Cauchy X"
  1080   fixes S :: "real set"
  1081   defines S_def: "S \<equiv> {x::real. \<exists>N. \<forall>n\<ge>N. x < X n}"
  1082 
  1083 lemma real_CauchyI:
  1084   assumes "Cauchy X"
  1085   shows "real_Cauchy X"
  1086   proof qed (fact assms)
  1087 
  1088 lemma (in real_Cauchy) mem_S: "\<forall>n\<ge>N. x < X n \<Longrightarrow> x \<in> S"
  1089 by (unfold S_def, auto)
  1090 
  1091 lemma (in real_Cauchy) bound_isUb:
  1092   assumes N: "\<forall>n\<ge>N. X n < x"
  1093   shows "isUb UNIV S x"
  1094 proof (rule isUb_UNIV_I)
  1095   fix y::real assume "y \<in> S"
  1096   hence "\<exists>M. \<forall>n\<ge>M. y < X n"
  1097     by (simp add: S_def)
  1098   then obtain M where "\<forall>n\<ge>M. y < X n" ..
  1099   hence "y < X (max M N)" by simp
  1100   also have "\<dots> < x" using N by simp
  1101   finally show "y \<le> x"
  1102     by (rule order_less_imp_le)
  1103 qed
  1104 
  1105 lemma (in real_Cauchy) isLub_ex: "\<exists>u. isLub UNIV S u"
  1106 proof (rule reals_complete)
  1107   obtain N where "\<forall>m\<ge>N. \<forall>n\<ge>N. norm (X m - X n) < 1"
  1108     using CauchyD [OF X zero_less_one] by fast
  1109   hence N: "\<forall>n\<ge>N. norm (X n - X N) < 1" by simp
  1110   show "\<exists>x. x \<in> S"
  1111   proof
  1112     from N have "\<forall>n\<ge>N. X N - 1 < X n"
  1113       by (simp add: real_abs_diff_less_iff)
  1114     thus "X N - 1 \<in> S" by (rule mem_S)
  1115   qed
  1116   show "\<exists>u. isUb UNIV S u"
  1117   proof
  1118     from N have "\<forall>n\<ge>N. X n < X N + 1"
  1119       by (simp add: real_abs_diff_less_iff)
  1120     thus "isUb UNIV S (X N + 1)"
  1121       by (rule bound_isUb)
  1122   qed
  1123 qed
  1124 
  1125 lemma (in real_Cauchy) isLub_imp_LIMSEQ:
  1126   assumes x: "isLub UNIV S x"
  1127   shows "X ----> x"
  1128 proof (rule LIMSEQ_I)
  1129   fix r::real assume "0 < r"
  1130   hence r: "0 < r/2" by simp
  1131   obtain N where "\<forall>n\<ge>N. \<forall>m\<ge>N. norm (X n - X m) < r/2"
  1132     using CauchyD [OF X r] by fast
  1133   hence "\<forall>n\<ge>N. norm (X n - X N) < r/2" by simp
  1134   hence N: "\<forall>n\<ge>N. X N - r/2 < X n \<and> X n < X N + r/2"
  1135     by (simp only: real_norm_def real_abs_diff_less_iff)
  1136 
  1137   from N have "\<forall>n\<ge>N. X N - r/2 < X n" by fast
  1138   hence "X N - r/2 \<in> S" by (rule mem_S)
  1139   hence 1: "X N - r/2 \<le> x" using x isLub_isUb isUbD by fast
  1140 
  1141   from N have "\<forall>n\<ge>N. X n < X N + r/2" by fast
  1142   hence "isUb UNIV S (X N + r/2)" by (rule bound_isUb)
  1143   hence 2: "x \<le> X N + r/2" using x isLub_le_isUb by fast
  1144 
  1145   show "\<exists>N. \<forall>n\<ge>N. norm (X n - x) < r"
  1146   proof (intro exI allI impI)
  1147     fix n assume n: "N \<le> n"
  1148     from N n have "X n < X N + r/2" and "X N - r/2 < X n" by simp+
  1149     thus "norm (X n - x) < r" using 1 2
  1150       by (simp add: real_abs_diff_less_iff)
  1151   qed
  1152 qed
  1153 
  1154 lemma (in real_Cauchy) LIMSEQ_ex: "\<exists>x. X ----> x"
  1155 proof -
  1156   obtain x where "isLub UNIV S x"
  1157     using isLub_ex by fast
  1158   hence "X ----> x"
  1159     by (rule isLub_imp_LIMSEQ)
  1160   thus ?thesis ..
  1161 qed
  1162 
  1163 lemma real_Cauchy_convergent:
  1164   fixes X :: "nat \<Rightarrow> real"
  1165   shows "Cauchy X \<Longrightarrow> convergent X"
  1166 unfolding convergent_def
  1167 by (rule real_Cauchy.LIMSEQ_ex)
  1168  (rule real_CauchyI)
  1169 
  1170 instance real :: banach
  1171 by intro_classes (rule real_Cauchy_convergent)
  1172 
  1173 
  1174 subsection {* Power Sequences *}
  1175 
  1176 text{*The sequence @{term "x^n"} tends to 0 if @{term "0\<le>x"} and @{term
  1177 "x<1"}.  Proof will use (NS) Cauchy equivalence for convergence and
  1178   also fact that bounded and monotonic sequence converges.*}
  1179 
  1180 lemma Bseq_realpow: "[| 0 \<le> (x::real); x \<le> 1 |] ==> Bseq (%n. x ^ n)"
  1181 apply (simp add: Bseq_def)
  1182 apply (rule_tac x = 1 in exI)
  1183 apply (simp add: power_abs)
  1184 apply (auto dest: power_mono)
  1185 done
  1186 
  1187 lemma monoseq_realpow: "[| 0 \<le> x; x \<le> 1 |] ==> monoseq (%n. x ^ n)"
  1188 apply (clarify intro!: mono_SucI2)
  1189 apply (cut_tac n = n and N = "Suc n" and a = x in power_decreasing, auto)
  1190 done
  1191 
  1192 lemma convergent_realpow:
  1193   "[| 0 \<le> (x::real); x \<le> 1 |] ==> convergent (%n. x ^ n)"
  1194 by (blast intro!: Bseq_monoseq_convergent Bseq_realpow monoseq_realpow)
  1195 
  1196 lemma LIMSEQ_inverse_realpow_zero_lemma:
  1197   fixes x :: real
  1198   assumes x: "0 \<le> x"
  1199   shows "real n * x + 1 \<le> (x + 1) ^ n"
  1200 apply (induct n)
  1201 apply simp
  1202 apply simp
  1203 apply (rule order_trans)
  1204 prefer 2
  1205 apply (erule mult_left_mono)
  1206 apply (rule add_increasing [OF x], simp)
  1207 apply (simp add: real_of_nat_Suc)
  1208 apply (simp add: ring_distribs)
  1209 apply (simp add: mult_nonneg_nonneg x)
  1210 done
  1211 
  1212 lemma LIMSEQ_inverse_realpow_zero:
  1213   "1 < (x::real) \<Longrightarrow> (\<lambda>n. inverse (x ^ n)) ----> 0"
  1214 proof (rule LIMSEQ_inverse_zero [rule_format])
  1215   fix y :: real
  1216   assume x: "1 < x"
  1217   hence "0 < x - 1" by simp
  1218   hence "\<forall>y. \<exists>N::nat. y < real N * (x - 1)"
  1219     by (rule reals_Archimedean3)
  1220   hence "\<exists>N::nat. y < real N * (x - 1)" ..
  1221   then obtain N::nat where "y < real N * (x - 1)" ..
  1222   also have "\<dots> \<le> real N * (x - 1) + 1" by simp
  1223   also have "\<dots> \<le> (x - 1 + 1) ^ N"
  1224     by (rule LIMSEQ_inverse_realpow_zero_lemma, cut_tac x, simp)
  1225   also have "\<dots> = x ^ N" by simp
  1226   finally have "y < x ^ N" .
  1227   hence "\<forall>n\<ge>N. y < x ^ n"
  1228     apply clarify
  1229     apply (erule order_less_le_trans)
  1230     apply (erule power_increasing)
  1231     apply (rule order_less_imp_le [OF x])
  1232     done
  1233   thus "\<exists>N. \<forall>n\<ge>N. y < x ^ n" ..
  1234 qed
  1235 
  1236 lemma LIMSEQ_realpow_zero:
  1237   "\<lbrakk>0 \<le> (x::real); x < 1\<rbrakk> \<Longrightarrow> (\<lambda>n. x ^ n) ----> 0"
  1238 proof (cases)
  1239   assume "x = 0"
  1240   hence "(\<lambda>n. x ^ Suc n) ----> 0" by (simp add: LIMSEQ_const)
  1241   thus ?thesis by (rule LIMSEQ_imp_Suc)
  1242 next
  1243   assume "0 \<le> x" and "x \<noteq> 0"
  1244   hence x0: "0 < x" by simp
  1245   assume x1: "x < 1"
  1246   from x0 x1 have "1 < inverse x"
  1247     by (rule real_inverse_gt_one)
  1248   hence "(\<lambda>n. inverse (inverse x ^ n)) ----> 0"
  1249     by (rule LIMSEQ_inverse_realpow_zero)
  1250   thus ?thesis by (simp add: power_inverse)
  1251 qed
  1252 
  1253 lemma LIMSEQ_power_zero:
  1254   fixes x :: "'a::{real_normed_algebra_1}"
  1255   shows "norm x < 1 \<Longrightarrow> (\<lambda>n. x ^ n) ----> 0"
  1256 apply (drule LIMSEQ_realpow_zero [OF norm_ge_zero])
  1257 apply (simp only: LIMSEQ_Zseq_iff, erule Zseq_le)
  1258 apply (simp add: power_abs norm_power_ineq)
  1259 done
  1260 
  1261 lemma LIMSEQ_divide_realpow_zero:
  1262   "1 < (x::real) ==> (%n. a / (x ^ n)) ----> 0"
  1263 apply (cut_tac a = a and x1 = "inverse x" in
  1264         LIMSEQ_mult [OF LIMSEQ_const LIMSEQ_realpow_zero])
  1265 apply (auto simp add: divide_inverse power_inverse)
  1266 apply (simp add: inverse_eq_divide pos_divide_less_eq)
  1267 done
  1268 
  1269 text{*Limit of @{term "c^n"} for @{term"\<bar>c\<bar> < 1"}*}
  1270 
  1271 lemma LIMSEQ_rabs_realpow_zero: "\<bar>c\<bar> < (1::real) ==> (%n. \<bar>c\<bar> ^ n) ----> 0"
  1272 by (rule LIMSEQ_realpow_zero [OF abs_ge_zero])
  1273 
  1274 lemma LIMSEQ_rabs_realpow_zero2: "\<bar>c\<bar> < (1::real) ==> (%n. c ^ n) ----> 0"
  1275 apply (rule LIMSEQ_rabs_zero [THEN iffD1])
  1276 apply (auto intro: LIMSEQ_rabs_realpow_zero simp add: power_abs)
  1277 done
  1278 
  1279 end