src/HOL/Tools/res_axioms.ML
author wenzelm
Thu Oct 09 20:53:11 2008 +0200 (2008-10-09)
changeset 28544 26743a1591f5
parent 28262 aa7ca36d67fd
child 28674 08a77c495dc1
permissions -rw-r--r--
improved performance of skolem cache, due to parallel map;
misc tuning, less verbosity;
     1 (*  Author: Jia Meng, Cambridge University Computer Laboratory
     2     ID: $Id$
     3     Copyright 2004 University of Cambridge
     4 
     5 Transformation of axiom rules (elim/intro/etc) into CNF forms.
     6 *)
     7 
     8 signature RES_AXIOMS =
     9 sig
    10   val cnf_axiom: theory -> thm -> thm list
    11   val pairname: thm -> string * thm
    12   val multi_base_blacklist: string list
    13   val bad_for_atp: thm -> bool
    14   val type_has_empty_sort: typ -> bool
    15   val cnf_rules_pairs: theory -> (string * thm) list -> (thm * (string * int)) list
    16   val neg_clausify: thm list -> thm list
    17   val expand_defs_tac: thm -> tactic
    18   val combinators: thm -> thm
    19   val neg_conjecture_clauses: thm -> int -> thm list * (string * typ) list
    20   val claset_rules_of: Proof.context -> (string * thm) list   (*FIXME DELETE*)
    21   val simpset_rules_of: Proof.context -> (string * thm) list  (*FIXME DELETE*)
    22   val atpset_rules_of: Proof.context -> (string * thm) list
    23   val suppress_endtheory: bool ref     (*for emergency use where endtheory causes problems*)
    24   val setup: theory -> theory
    25 end;
    26 
    27 structure ResAxioms: RES_AXIOMS =
    28 struct
    29 
    30 (* FIXME legacy *)
    31 fun freeze_thm th = #1 (Drule.freeze_thaw th);
    32 
    33 fun type_has_empty_sort (TFree (_, [])) = true
    34   | type_has_empty_sort (TVar (_, [])) = true
    35   | type_has_empty_sort (Type (_, Ts)) = exists type_has_empty_sort Ts
    36   | type_has_empty_sort _ = false;
    37 
    38 
    39 (**** Transformation of Elimination Rules into First-Order Formulas****)
    40 
    41 val cfalse = cterm_of HOL.thy HOLogic.false_const;
    42 val ctp_false = cterm_of HOL.thy (HOLogic.mk_Trueprop HOLogic.false_const);
    43 
    44 (*Converts an elim-rule into an equivalent theorem that does not have the
    45   predicate variable.  Leaves other theorems unchanged.  We simply instantiate the
    46   conclusion variable to False.*)
    47 fun transform_elim th =
    48   case concl_of th of    (*conclusion variable*)
    49        Const("Trueprop",_) $ (v as Var(_,Type("bool",[]))) =>
    50            Thm.instantiate ([], [(cterm_of HOL.thy v, cfalse)]) th
    51     | v as Var(_, Type("prop",[])) =>
    52            Thm.instantiate ([], [(cterm_of HOL.thy v, ctp_false)]) th
    53     | _ => th;
    54 
    55 (*To enforce single-threading*)
    56 exception Clausify_failure of theory;
    57 
    58 
    59 (**** SKOLEMIZATION BY INFERENCE (lcp) ****)
    60 
    61 fun rhs_extra_types lhsT rhs =
    62   let val lhs_vars = Term.add_tfreesT lhsT []
    63       fun add_new_TFrees (TFree v) =
    64             if member (op =) lhs_vars v then I else insert (op =) (TFree v)
    65         | add_new_TFrees _ = I
    66       val rhs_consts = fold_aterms (fn Const c => insert (op =) c | _ => I) rhs []
    67   in fold (#2 #> Term.fold_atyps add_new_TFrees) rhs_consts [] end;
    68 
    69 (*Traverse a theorem, declaring Skolem function definitions. String s is the suggested
    70   prefix for the Skolem constant.*)
    71 fun declare_skofuns s th =
    72   let
    73     val nref = ref 0
    74     fun dec_sko (Const ("Ex",_) $ (xtp as Abs (_, T, p))) (axs, thy) =
    75           (*Existential: declare a Skolem function, then insert into body and continue*)
    76           let
    77             val cname = "sko_" ^ s ^ "_" ^ Int.toString (inc nref)
    78             val args0 = term_frees xtp  (*get the formal parameter list*)
    79             val Ts = map type_of args0
    80             val extraTs = rhs_extra_types (Ts ---> T) xtp
    81             val argsx = map (fn T => Free (gensym "vsk", T)) extraTs
    82             val args = argsx @ args0
    83             val cT = extraTs ---> Ts ---> T
    84             val rhs = list_abs_free (map dest_Free args, HOLogic.choice_const T $ xtp)
    85                     (*Forms a lambda-abstraction over the formal parameters*)
    86             val (c, thy') =
    87               Sign.declare_const [Markup.property_internal] ((Name.binding cname, cT), NoSyn) thy
    88             val cdef = cname ^ "_def"
    89             val thy'' = Theory.add_defs_i true false [(cdef, Logic.mk_equals (c, rhs))] thy'
    90             val ax = Thm.get_axiom_i thy'' (Sign.full_name thy'' cdef)
    91           in dec_sko (subst_bound (list_comb (c, args), p)) (ax :: axs, thy'') end
    92       | dec_sko (Const ("All", _) $ (xtp as Abs (a, T, p))) thx =
    93           (*Universal quant: insert a free variable into body and continue*)
    94           let val fname = Name.variant (add_term_names (p, [])) a
    95           in dec_sko (subst_bound (Free (fname, T), p)) thx end
    96       | dec_sko (Const ("op &", _) $ p $ q) thx = dec_sko q (dec_sko p thx)
    97       | dec_sko (Const ("op |", _) $ p $ q) thx = dec_sko q (dec_sko p thx)
    98       | dec_sko (Const ("Trueprop", _) $ p) thx = dec_sko p thx
    99       | dec_sko t thx = thx (*Do nothing otherwise*)
   100   in fn thy => dec_sko (Thm.prop_of th) ([], thy) end;
   101 
   102 (*Traverse a theorem, accumulating Skolem function definitions.*)
   103 fun assume_skofuns s th =
   104   let val sko_count = ref 0
   105       fun dec_sko (Const ("Ex",_) $ (xtp as Abs(_,T,p))) defs =
   106             (*Existential: declare a Skolem function, then insert into body and continue*)
   107             let val skos = map (#1 o Logic.dest_equals) defs  (*existing sko fns*)
   108                 val args = term_frees xtp \\ skos  (*the formal parameters*)
   109                 val Ts = map type_of args
   110                 val cT = Ts ---> T
   111                 val id = "sko_" ^ s ^ "_" ^ Int.toString (inc sko_count)
   112                 val c = Free (id, cT)
   113                 val rhs = list_abs_free (map dest_Free args,
   114                                          HOLogic.choice_const T $ xtp)
   115                       (*Forms a lambda-abstraction over the formal parameters*)
   116                 val def = Logic.mk_equals (c, rhs)
   117             in dec_sko (subst_bound (list_comb(c,args), p))
   118                        (def :: defs)
   119             end
   120         | dec_sko (Const ("All",_) $ (xtp as Abs(a,T,p))) defs =
   121             (*Universal quant: insert a free variable into body and continue*)
   122             let val fname = Name.variant (add_term_names (p,[])) a
   123             in dec_sko (subst_bound (Free(fname,T), p)) defs end
   124         | dec_sko (Const ("op &", _) $ p $ q) defs = dec_sko q (dec_sko p defs)
   125         | dec_sko (Const ("op |", _) $ p $ q) defs = dec_sko q (dec_sko p defs)
   126         | dec_sko (Const ("Trueprop", _) $ p) defs = dec_sko p defs
   127         | dec_sko t defs = defs (*Do nothing otherwise*)
   128   in  dec_sko (prop_of th) []  end;
   129 
   130 
   131 (**** REPLACING ABSTRACTIONS BY COMBINATORS ****)
   132 
   133 (*Returns the vars of a theorem*)
   134 fun vars_of_thm th =
   135   map (Thm.cterm_of (theory_of_thm th) o Var) (Thm.fold_terms Term.add_vars th []);
   136 
   137 (*Make a version of fun_cong with a given variable name*)
   138 local
   139     val fun_cong' = fun_cong RS asm_rl; (*renumber f, g to prevent clashes with (a,0)*)
   140     val cx = hd (vars_of_thm fun_cong');
   141     val ty = typ_of (ctyp_of_term cx);
   142     val thy = theory_of_thm fun_cong;
   143     fun mkvar a = cterm_of thy (Var((a,0),ty));
   144 in
   145 fun xfun_cong x = Thm.instantiate ([], [(cx, mkvar x)]) fun_cong'
   146 end;
   147 
   148 (*Removes the lambdas from an equation of the form t = (%x. u).  A non-negative n,
   149   serves as an upper bound on how many to remove.*)
   150 fun strip_lambdas 0 th = th
   151   | strip_lambdas n th =
   152       case prop_of th of
   153           _ $ (Const ("op =", _) $ _ $ Abs (x,_,_)) =>
   154               strip_lambdas (n-1) (freeze_thm (th RS xfun_cong x))
   155         | _ => th;
   156 
   157 val lambda_free = not o Term.has_abs;
   158 
   159 val monomorphic = not o Term.exists_type (Term.exists_subtype Term.is_TVar);
   160 
   161 val [f_B,g_B] = map (cterm_of (the_context ())) (term_vars (prop_of @{thm abs_B}));
   162 val [g_C,f_C] = map (cterm_of (the_context ())) (term_vars (prop_of @{thm abs_C}));
   163 val [f_S,g_S] = map (cterm_of (the_context ())) (term_vars (prop_of @{thm abs_S}));
   164 
   165 (*FIXME: requires more use of cterm constructors*)
   166 fun abstract ct =
   167   let
   168       val thy = theory_of_cterm ct
   169       val Abs(x,_,body) = term_of ct
   170       val Type("fun",[xT,bodyT]) = typ_of (ctyp_of_term ct)
   171       val cxT = ctyp_of thy xT and cbodyT = ctyp_of thy bodyT
   172       fun makeK() = instantiate' [SOME cxT, SOME cbodyT] [SOME (cterm_of thy body)] @{thm abs_K}
   173   in
   174       case body of
   175           Const _ => makeK()
   176         | Free _ => makeK()
   177         | Var _ => makeK()  (*though Var isn't expected*)
   178         | Bound 0 => instantiate' [SOME cxT] [] @{thm abs_I} (*identity: I*)
   179         | rator$rand =>
   180             if loose_bvar1 (rator,0) then (*C or S*)
   181                if loose_bvar1 (rand,0) then (*S*)
   182                  let val crator = cterm_of thy (Abs(x,xT,rator))
   183                      val crand = cterm_of thy (Abs(x,xT,rand))
   184                      val abs_S' = cterm_instantiate [(f_S,crator),(g_S,crand)] @{thm abs_S}
   185                      val (_,rhs) = Thm.dest_equals (cprop_of abs_S')
   186                  in
   187                    Thm.transitive abs_S' (Conv.binop_conv abstract rhs)
   188                  end
   189                else (*C*)
   190                  let val crator = cterm_of thy (Abs(x,xT,rator))
   191                      val abs_C' = cterm_instantiate [(f_C,crator),(g_C,cterm_of thy rand)] @{thm abs_C}
   192                      val (_,rhs) = Thm.dest_equals (cprop_of abs_C')
   193                  in
   194                    Thm.transitive abs_C' (Conv.fun_conv (Conv.arg_conv abstract) rhs)
   195                  end
   196             else if loose_bvar1 (rand,0) then (*B or eta*)
   197                if rand = Bound 0 then eta_conversion ct
   198                else (*B*)
   199                  let val crand = cterm_of thy (Abs(x,xT,rand))
   200                      val crator = cterm_of thy rator
   201                      val abs_B' = cterm_instantiate [(f_B,crator),(g_B,crand)] @{thm abs_B}
   202                      val (_,rhs) = Thm.dest_equals (cprop_of abs_B')
   203                  in
   204                    Thm.transitive abs_B' (Conv.arg_conv abstract rhs)
   205                  end
   206             else makeK()
   207         | _ => error "abstract: Bad term"
   208   end;
   209 
   210 (*Traverse a theorem, declaring abstraction function definitions. String s is the suggested
   211   prefix for the constants.*)
   212 fun combinators_aux ct =
   213   if lambda_free (term_of ct) then reflexive ct
   214   else
   215   case term_of ct of
   216       Abs _ =>
   217         let val (cv,cta) = Thm.dest_abs NONE ct
   218             val (v,Tv) = (dest_Free o term_of) cv
   219             val u_th = combinators_aux cta
   220             val cu = Thm.rhs_of u_th
   221             val comb_eq = abstract (Thm.cabs cv cu)
   222         in transitive (abstract_rule v cv u_th) comb_eq end
   223     | t1 $ t2 =>
   224         let val (ct1,ct2) = Thm.dest_comb ct
   225         in  combination (combinators_aux ct1) (combinators_aux ct2)  end;
   226 
   227 fun combinators th =
   228   if lambda_free (prop_of th) then th
   229   else
   230     let val th = Drule.eta_contraction_rule th
   231         val eqth = combinators_aux (cprop_of th)
   232     in  equal_elim eqth th   end
   233     handle THM (msg,_,_) =>
   234       (warning ("Error in the combinator translation of " ^ Display.string_of_thm th);
   235        warning ("  Exception message: " ^ msg);
   236        TrueI);  (*A type variable of sort {} will cause make abstraction fail.*)
   237 
   238 (*cterms are used throughout for efficiency*)
   239 val cTrueprop = Thm.cterm_of HOL.thy HOLogic.Trueprop;
   240 
   241 (*cterm version of mk_cTrueprop*)
   242 fun c_mkTrueprop A = Thm.capply cTrueprop A;
   243 
   244 (*Given an abstraction over n variables, replace the bound variables by free
   245   ones. Return the body, along with the list of free variables.*)
   246 fun c_variant_abs_multi (ct0, vars) =
   247       let val (cv,ct) = Thm.dest_abs NONE ct0
   248       in  c_variant_abs_multi (ct, cv::vars)  end
   249       handle CTERM _ => (ct0, rev vars);
   250 
   251 (*Given the definition of a Skolem function, return a theorem to replace
   252   an existential formula by a use of that function.
   253    Example: "EX x. x : A & x ~: B ==> sko A B : A & sko A B ~: B"  [.] *)
   254 fun skolem_of_def def =
   255   let val (c,rhs) = Thm.dest_equals (cprop_of (freeze_thm def))
   256       val (ch, frees) = c_variant_abs_multi (rhs, [])
   257       val (chilbert,cabs) = Thm.dest_comb ch
   258       val thy = Thm.theory_of_cterm chilbert
   259       val t = Thm.term_of chilbert
   260       val T = case t of Const ("Hilbert_Choice.Eps", Type("fun",[_,T])) => T
   261                       | _ => raise THM ("skolem_of_def: expected Eps", 0, [def])
   262       val cex = Thm.cterm_of thy (HOLogic.exists_const T)
   263       val ex_tm = c_mkTrueprop (Thm.capply cex cabs)
   264       and conc =  c_mkTrueprop (Drule.beta_conv cabs (Drule.list_comb(c,frees)));
   265       fun tacf [prem] = rewrite_goals_tac [def] THEN rtac (prem RS someI_ex) 1
   266   in  Goal.prove_internal [ex_tm] conc tacf
   267        |> forall_intr_list frees
   268        |> Thm.forall_elim_vars 0  (*Introduce Vars, but don't discharge defs.*)
   269        |> Thm.varifyT
   270   end;
   271 
   272 
   273 (*Converts an Isabelle theorem (intro, elim or simp format, even higher-order) into NNF.*)
   274 fun to_nnf th ctxt0 =
   275   let val th1 = th |> transform_elim |> zero_var_indexes
   276       val ((_,[th2]),ctxt) = Variable.import_thms true [th1] ctxt0
   277       val th3 = th2 |> Conv.fconv_rule ObjectLogic.atomize |> Meson.make_nnf |> strip_lambdas ~1
   278   in  (th3, ctxt)  end;
   279 
   280 (*Generate Skolem functions for a theorem supplied in nnf*)
   281 fun assume_skolem_of_def s th =
   282   map (skolem_of_def o assume o (cterm_of (theory_of_thm th))) (assume_skofuns s th);
   283 
   284 fun assert_lambda_free ths msg =
   285   case filter (not o lambda_free o prop_of) ths of
   286       [] => ()
   287     | ths' => error (msg ^ "\n" ^ cat_lines (map Display.string_of_thm ths'));
   288 
   289 
   290 (*** Blacklisting (duplicated in ResAtp?) ***)
   291 
   292 val max_lambda_nesting = 3;
   293 
   294 fun excessive_lambdas (f$t, k) = excessive_lambdas (f,k) orelse excessive_lambdas (t,k)
   295   | excessive_lambdas (Abs(_,_,t), k) = k=0 orelse excessive_lambdas (t,k-1)
   296   | excessive_lambdas _ = false;
   297 
   298 fun is_formula_type T = (T = HOLogic.boolT orelse T = propT);
   299 
   300 (*Don't count nested lambdas at the level of formulas, as they are quantifiers*)
   301 fun excessive_lambdas_fm Ts (Abs(_,T,t)) = excessive_lambdas_fm (T::Ts) t
   302   | excessive_lambdas_fm Ts t =
   303       if is_formula_type (fastype_of1 (Ts, t))
   304       then exists (excessive_lambdas_fm Ts) (#2 (strip_comb t))
   305       else excessive_lambdas (t, max_lambda_nesting);
   306 
   307 (*The max apply_depth of any metis call in MetisExamples (on 31-10-2007) was 11.*)
   308 val max_apply_depth = 15;
   309 
   310 fun apply_depth (f$t) = Int.max (apply_depth f, apply_depth t + 1)
   311   | apply_depth (Abs(_,_,t)) = apply_depth t
   312   | apply_depth _ = 0;
   313 
   314 fun too_complex t =
   315   apply_depth t > max_apply_depth orelse
   316   Meson.too_many_clauses NONE t orelse
   317   excessive_lambdas_fm [] t;
   318 
   319 fun is_strange_thm th =
   320   case head_of (concl_of th) of
   321       Const (a,_) => (a <> "Trueprop" andalso a <> "==")
   322     | _ => false;
   323 
   324 fun bad_for_atp th =
   325   Thm.is_internal th
   326   orelse too_complex (prop_of th)
   327   orelse exists_type type_has_empty_sort (prop_of th)
   328   orelse is_strange_thm th;
   329 
   330 val multi_base_blacklist =
   331   ["defs","select_defs","update_defs","induct","inducts","split","splits","split_asm",
   332    "cases","ext_cases"];  (*FIXME: put other record thms here, or use the "Internal" marker*)
   333 
   334 (*Keep the full complexity of the original name*)
   335 fun flatten_name s = space_implode "_X" (NameSpace.explode s);
   336 
   337 fun fake_name th =
   338   if Thm.has_name_hint th then flatten_name (Thm.get_name_hint th)
   339   else gensym "unknown_thm_";
   340 
   341 fun name_or_string th =
   342   if Thm.has_name_hint th then Thm.get_name_hint th
   343   else Display.string_of_thm th;
   344 
   345 (*Skolemize a named theorem, with Skolem functions as additional premises.*)
   346 fun skolem_thm (s, th) =
   347   if member (op =) multi_base_blacklist (Sign.base_name s) orelse bad_for_atp th then []
   348   else
   349     let
   350       val ctxt0 = Variable.thm_context th
   351       val (nnfth, ctxt1) = to_nnf th ctxt0
   352       val (cnfs, ctxt2) = Meson.make_cnf (assume_skolem_of_def s nnfth) nnfth ctxt1
   353     in  cnfs |> map combinators |> Variable.export ctxt2 ctxt0 |> Meson.finish_cnf  end
   354     handle THM _ => [];
   355 
   356 (*The cache prevents repeated clausification of a theorem, and also repeated declaration of
   357   Skolem functions.*)
   358 structure ThmCache = TheoryDataFun
   359 (
   360   type T = thm list Thmtab.table * unit Symtab.table;
   361   val empty = (Thmtab.empty, Symtab.empty);
   362   val copy = I;
   363   val extend = I;
   364   fun merge _ ((cache1, seen1), (cache2, seen2)) : T =
   365     (Thmtab.merge (K true) (cache1, cache2), Symtab.merge (K true) (seen1, seen2));
   366 );
   367 
   368 val lookup_cache = Thmtab.lookup o #1 o ThmCache.get;
   369 val already_seen = Symtab.defined o #2 o ThmCache.get;
   370 
   371 val update_cache = ThmCache.map o apfst o Thmtab.update;
   372 fun mark_seen name = ThmCache.map (apsnd (Symtab.update (name, ())));
   373 
   374 (*Exported function to convert Isabelle theorems into axiom clauses*)
   375 fun cnf_axiom thy th0 =
   376   let val th = Thm.transfer thy th0 in
   377     case lookup_cache thy th of
   378       NONE => map Thm.close_derivation (skolem_thm (fake_name th, th))
   379     | SOME cls => cls
   380   end;
   381 
   382 
   383 (**** Extract and Clausify theorems from a theory's claset and simpset ****)
   384 
   385 fun pairname th = (Thm.get_name_hint th, th);
   386 
   387 fun rules_of_claset cs =
   388   let val {safeIs,safeEs,hazIs,hazEs,...} = rep_cs cs
   389       val intros = safeIs @ hazIs
   390       val elims  = map Classical.classical_rule (safeEs @ hazEs)
   391   in map pairname (intros @ elims) end;
   392 
   393 fun rules_of_simpset ss =
   394   let val ({rules,...}, _) = rep_ss ss
   395       val simps = Net.entries rules
   396   in map (fn r => (#name r, #thm r)) simps end;
   397 
   398 fun claset_rules_of ctxt = rules_of_claset (local_claset_of ctxt);
   399 fun simpset_rules_of ctxt = rules_of_simpset (local_simpset_of ctxt);
   400 
   401 fun atpset_rules_of ctxt = map pairname (ResAtpset.get ctxt);
   402 
   403 
   404 (**** Translate a set of theorems into CNF ****)
   405 
   406 fun pair_name_cls k (n, []) = []
   407   | pair_name_cls k (n, cls::clss) = (cls, (n,k)) :: pair_name_cls (k+1) (n, clss)
   408 
   409 fun cnf_rules_pairs_aux _ pairs [] = pairs
   410   | cnf_rules_pairs_aux thy pairs ((name,th)::ths) =
   411       let val pairs' = (pair_name_cls 0 (name, cnf_axiom thy th)) @ pairs
   412                        handle THM _ => pairs | ResClause.CLAUSE _ => pairs
   413       in  cnf_rules_pairs_aux thy pairs' ths  end;
   414 
   415 (*The combination of rev and tail recursion preserves the original order*)
   416 fun cnf_rules_pairs thy l = cnf_rules_pairs_aux thy [] (rev l);
   417 
   418 
   419 (**** Convert all facts of the theory into clauses (ResClause.clause, or ResHolClause.clause) ****)
   420 
   421 local
   422 
   423 fun skolem_def (name, th) thy =
   424   let val ctxt0 = Variable.thm_context th in
   425     (case try (to_nnf th) ctxt0 of
   426       NONE => (NONE, thy)
   427     | SOME (nnfth, ctxt1) =>
   428         let val (defs, thy') = declare_skofuns (flatten_name name) nnfth thy
   429         in (SOME (th, ctxt0, ctxt1, nnfth, defs), thy') end)
   430   end;
   431 
   432 fun skolem_cnfs (th, ctxt0, ctxt1, nnfth, defs) =
   433   let
   434     val (cnfs, ctxt2) = Meson.make_cnf (map skolem_of_def defs) nnfth ctxt1;
   435     val cnfs' = cnfs
   436       |> map combinators
   437       |> Variable.export ctxt2 ctxt0
   438       |> Meson.finish_cnf
   439       |> map Thm.close_derivation;
   440     in (th, cnfs') end;
   441 
   442 in
   443 
   444 fun saturate_skolem_cache thy =
   445   let
   446     val new_facts = (PureThy.facts_of thy, []) |-> Facts.fold_static (fn (name, ths) =>
   447       if already_seen thy name then I else cons (name, ths));
   448     val new_thms = (new_facts, []) |-> fold (fn (name, ths) =>
   449       if member (op =) multi_base_blacklist (Sign.base_name name) then I
   450       else fold_index (fn (i, th) =>
   451         if bad_for_atp th orelse is_some (lookup_cache thy th) then I
   452         else cons (name ^ "_" ^ string_of_int (i + 1), Thm.transfer thy th)) ths);
   453   in
   454     if null new_facts then NONE
   455     else
   456       let
   457         val (defs, thy') = thy
   458           |> fold (mark_seen o #1) new_facts
   459           |> fold_map skolem_def (sort_distinct (Thm.thm_ord o pairself snd) new_thms)
   460           |>> map_filter I;
   461         val cache_entries = ParList.map skolem_cnfs defs;
   462       in SOME (fold update_cache cache_entries thy') end
   463   end;
   464 
   465 end;
   466 
   467 val suppress_endtheory = ref false;
   468 
   469 fun clause_cache_endtheory thy =
   470   if ! suppress_endtheory then NONE
   471   else saturate_skolem_cache thy;
   472 
   473 
   474 (*The cache can be kept smaller by inspecting the prop of each thm. Can ignore all that are
   475   lambda_free, but then the individual theory caches become much bigger.*)
   476 
   477 
   478 (*** meson proof methods ***)
   479 
   480 (*Expand all new definitions of abstraction or Skolem functions in a proof state.*)
   481 fun is_absko (Const ("==", _) $ Free (a,_) $ u) = String.isPrefix "sko_" a
   482   | is_absko _ = false;
   483 
   484 fun is_okdef xs (Const ("==", _) $ t $ u) =   (*Definition of Free, not in certain terms*)
   485       is_Free t andalso not (member (op aconv) xs t)
   486   | is_okdef _ _ = false
   487 
   488 (*This function tries to cope with open locales, which introduce hypotheses of the form
   489   Free == t, conjecture clauses, which introduce various hypotheses, and also definitions
   490   of sko_ functions. *)
   491 fun expand_defs_tac st0 st =
   492   let val hyps0 = #hyps (rep_thm st0)
   493       val hyps = #hyps (crep_thm st)
   494       val newhyps = filter_out (member (op aconv) hyps0 o Thm.term_of) hyps
   495       val defs = filter (is_absko o Thm.term_of) newhyps
   496       val remaining_hyps = filter_out (member (op aconv) (map Thm.term_of defs))
   497                                       (map Thm.term_of hyps)
   498       val fixed = term_frees (concl_of st) @
   499                   foldl (gen_union (op aconv)) [] (map term_frees remaining_hyps)
   500   in Seq.of_list [LocalDefs.expand (filter (is_okdef fixed o Thm.term_of) defs) st] end;
   501 
   502 
   503 fun meson_general_tac ths i st0 =
   504   let
   505     val thy = Thm.theory_of_thm st0
   506   in  (Meson.meson_claset_tac (maps (cnf_axiom thy) ths) HOL_cs i THEN expand_defs_tac st0) st0 end;
   507 
   508 val meson_method_setup = Method.add_methods
   509   [("meson", Method.thms_args (fn ths =>
   510       Method.SIMPLE_METHOD' (CHANGED_PROP o meson_general_tac ths)),
   511     "MESON resolution proof procedure")];
   512 
   513 
   514 (*** Converting a subgoal into negated conjecture clauses. ***)
   515 
   516 val neg_skolemize_tac = EVERY' [rtac ccontr, ObjectLogic.atomize_prems_tac, Meson.skolemize_tac];
   517 
   518 fun neg_clausify sts =
   519   sts |> Meson.make_clauses |> map combinators |> Meson.finish_cnf;
   520 
   521 fun neg_conjecture_clauses st0 n =
   522   let val st = Seq.hd (neg_skolemize_tac n st0)
   523       val (params,_,_) = strip_context (Logic.nth_prem (n, Thm.prop_of st))
   524   in (neg_clausify (the (metahyps_thms n st)), params) end
   525   handle Option => error "unable to Skolemize subgoal";
   526 
   527 (*Conversion of a subgoal to conjecture clauses. Each clause has
   528   leading !!-bound universal variables, to express generality. *)
   529 val neg_clausify_tac =
   530   neg_skolemize_tac THEN'
   531   SUBGOAL
   532     (fn (prop,_) =>
   533      let val ts = Logic.strip_assums_hyp prop
   534      in EVERY1
   535          [METAHYPS
   536             (fn hyps =>
   537               (Method.insert_tac
   538                 (map forall_intr_vars (neg_clausify hyps)) 1)),
   539           REPEAT_DETERM_N (length ts) o (etac thin_rl)]
   540      end);
   541 
   542 val setup_methods = Method.add_methods
   543   [("neg_clausify", Method.no_args (Method.SIMPLE_METHOD' neg_clausify_tac),
   544     "conversion of goal to conjecture clauses")];
   545 
   546 
   547 (** Attribute for converting a theorem into clauses **)
   548 
   549 val clausify = Attrib.syntax (Scan.lift OuterParse.nat
   550   >> (fn i => Thm.rule_attribute (fn context => fn th =>
   551       Meson.make_meta_clause (nth (cnf_axiom (Context.theory_of context) th) i))));
   552 
   553 val setup_attrs = Attrib.add_attributes
   554   [("clausify", clausify, "conversion of theorem to clauses")];
   555 
   556 
   557 
   558 (** setup **)
   559 
   560 val setup =
   561   meson_method_setup #>
   562   setup_methods #>
   563   setup_attrs #>
   564   perhaps saturate_skolem_cache #>
   565   Theory.at_end clause_cache_endtheory;
   566 
   567 end;