src/HOL/Power.thy
author paulson <lp15@cam.ac.uk>
Fri Nov 13 12:27:13 2015 +0000 (2015-11-13)
changeset 61649 268d88ec9087
parent 61531 ab2e862263e7
child 61694 6571c78c9667
permissions -rw-r--r--
Tweaks for "real": Removal of [iff] status for some lemmas, adding [simp] for others. Plus fixes.
     1 (*  Title:      HOL/Power.thy
     2     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     3     Copyright   1997  University of Cambridge
     4 *)
     5 
     6 section \<open>Exponentiation\<close>
     7 
     8 theory Power
     9 imports Num Equiv_Relations
    10 begin
    11 
    12 context linordered_ring (* TODO: move *)
    13 begin
    14 
    15 lemma sum_squares_ge_zero:
    16   "0 \<le> x * x + y * y"
    17   by (intro add_nonneg_nonneg zero_le_square)
    18 
    19 lemma not_sum_squares_lt_zero:
    20   "\<not> x * x + y * y < 0"
    21   by (simp add: not_less sum_squares_ge_zero)
    22 
    23 end
    24 
    25 subsection \<open>Powers for Arbitrary Monoids\<close>
    26 
    27 class power = one + times
    28 begin
    29 
    30 primrec power :: "'a \<Rightarrow> nat \<Rightarrow> 'a" (infixr "^" 80) where
    31     power_0: "a ^ 0 = 1"
    32   | power_Suc: "a ^ Suc n = a * a ^ n"
    33 
    34 notation (latex output)
    35   power ("(_\<^bsup>_\<^esup>)" [1000] 1000)
    36 
    37 text \<open>Special syntax for squares.\<close>
    38 
    39 abbreviation (xsymbols)
    40   power2 :: "'a \<Rightarrow> 'a"  ("(_\<^sup>2)" [1000] 999) where
    41   "x\<^sup>2 \<equiv> x ^ 2"
    42 
    43 notation (latex output)
    44   power2  ("(_\<^sup>2)" [1000] 999)
    45 
    46 end
    47 
    48 context monoid_mult
    49 begin
    50 
    51 subclass power .
    52 
    53 lemma power_one [simp]:
    54   "1 ^ n = 1"
    55   by (induct n) simp_all
    56 
    57 lemma power_one_right [simp]:
    58   "a ^ 1 = a"
    59   by simp
    60 
    61 lemma power_Suc0_right [simp]:
    62   "a ^ Suc 0 = a"
    63   by simp
    64 
    65 lemma power_commutes:
    66   "a ^ n * a = a * a ^ n"
    67   by (induct n) (simp_all add: mult.assoc)
    68 
    69 lemma power_Suc2:
    70   "a ^ Suc n = a ^ n * a"
    71   by (simp add: power_commutes)
    72 
    73 lemma power_add:
    74   "a ^ (m + n) = a ^ m * a ^ n"
    75   by (induct m) (simp_all add: algebra_simps)
    76 
    77 lemma power_mult:
    78   "a ^ (m * n) = (a ^ m) ^ n"
    79   by (induct n) (simp_all add: power_add)
    80 
    81 lemma power2_eq_square: "a\<^sup>2 = a * a"
    82   by (simp add: numeral_2_eq_2)
    83 
    84 lemma power3_eq_cube: "a ^ 3 = a * a * a"
    85   by (simp add: numeral_3_eq_3 mult.assoc)
    86 
    87 lemma power_even_eq:
    88   "a ^ (2 * n) = (a ^ n)\<^sup>2"
    89   by (subst mult.commute) (simp add: power_mult)
    90 
    91 lemma power_odd_eq:
    92   "a ^ Suc (2*n) = a * (a ^ n)\<^sup>2"
    93   by (simp add: power_even_eq)
    94 
    95 lemma power_numeral_even:
    96   "z ^ numeral (Num.Bit0 w) = (let w = z ^ (numeral w) in w * w)"
    97   unfolding numeral_Bit0 power_add Let_def ..
    98 
    99 lemma power_numeral_odd:
   100   "z ^ numeral (Num.Bit1 w) = (let w = z ^ (numeral w) in z * w * w)"
   101   unfolding numeral_Bit1 One_nat_def add_Suc_right add_0_right
   102   unfolding power_Suc power_add Let_def mult.assoc ..
   103 
   104 lemma funpow_times_power:
   105   "(times x ^^ f x) = times (x ^ f x)"
   106 proof (induct "f x" arbitrary: f)
   107   case 0 then show ?case by (simp add: fun_eq_iff)
   108 next
   109   case (Suc n)
   110   def g \<equiv> "\<lambda>x. f x - 1"
   111   with Suc have "n = g x" by simp
   112   with Suc have "times x ^^ g x = times (x ^ g x)" by simp
   113   moreover from Suc g_def have "f x = g x + 1" by simp
   114   ultimately show ?case by (simp add: power_add funpow_add fun_eq_iff mult.assoc)
   115 qed
   116 
   117 lemma power_commuting_commutes:
   118   assumes "x * y = y * x"
   119   shows "x ^ n * y = y * x ^n"
   120 proof (induct n)
   121   case (Suc n)
   122   have "x ^ Suc n * y = x ^ n * y * x"
   123     by (subst power_Suc2) (simp add: assms ac_simps)
   124   also have "\<dots> = y * x ^ Suc n"
   125     unfolding Suc power_Suc2
   126     by (simp add: ac_simps)
   127   finally show ?case .
   128 qed simp
   129 
   130 end
   131 
   132 context comm_monoid_mult
   133 begin
   134 
   135 lemma power_mult_distrib [field_simps]:
   136   "(a * b) ^ n = (a ^ n) * (b ^ n)"
   137   by (induct n) (simp_all add: ac_simps)
   138 
   139 end
   140 
   141 text\<open>Extract constant factors from powers\<close>
   142 declare power_mult_distrib [where a = "numeral w" for w, simp]
   143 declare power_mult_distrib [where b = "numeral w" for w, simp]
   144 
   145 lemma power_add_numeral [simp]:
   146   fixes a :: "'a :: monoid_mult"
   147   shows "a^numeral m * a^numeral n = a^numeral (m + n)"
   148   by (simp add: power_add [symmetric])
   149 
   150 lemma power_add_numeral2 [simp]:
   151   fixes a :: "'a :: monoid_mult"
   152   shows "a^numeral m * (a^numeral n * b) = a^numeral (m + n) * b"
   153   by (simp add: mult.assoc [symmetric])
   154 
   155 lemma power_mult_numeral [simp]:
   156   fixes a :: "'a :: monoid_mult"
   157   shows"(a^numeral m)^numeral n = a^numeral (m * n)"
   158   by (simp only: numeral_mult power_mult)
   159 
   160 context semiring_numeral
   161 begin
   162 
   163 lemma numeral_sqr: "numeral (Num.sqr k) = numeral k * numeral k"
   164   by (simp only: sqr_conv_mult numeral_mult)
   165 
   166 lemma numeral_pow: "numeral (Num.pow k l) = numeral k ^ numeral l"
   167   by (induct l, simp_all only: numeral_class.numeral.simps pow.simps
   168     numeral_sqr numeral_mult power_add power_one_right)
   169 
   170 lemma power_numeral [simp]: "numeral k ^ numeral l = numeral (Num.pow k l)"
   171   by (rule numeral_pow [symmetric])
   172 
   173 end
   174 
   175 context semiring_1
   176 begin
   177 
   178 lemma of_nat_power [simp]:
   179   "of_nat (m ^ n) = of_nat m ^ n"
   180   by (induct n) (simp_all add: of_nat_mult)
   181 
   182 lemma zero_power:
   183   "0 < n \<Longrightarrow> 0 ^ n = 0"
   184   by (cases n) simp_all
   185 
   186 lemma power_zero_numeral [simp]:
   187   "0 ^ numeral k = 0"
   188   by (simp add: numeral_eq_Suc)
   189 
   190 lemma zero_power2: "0\<^sup>2 = 0" (* delete? *)
   191   by (rule power_zero_numeral)
   192 
   193 lemma one_power2: "1\<^sup>2 = 1" (* delete? *)
   194   by (rule power_one)
   195 
   196 lemma power_0_Suc [simp]:
   197   "0 ^ Suc n = 0"
   198   by simp
   199 
   200 text\<open>It looks plausible as a simprule, but its effect can be strange.\<close>
   201 lemma power_0_left:
   202   "0 ^ n = (if n = 0 then 1 else 0)"
   203   by (cases n) simp_all
   204 
   205 end
   206 
   207 context comm_semiring_1
   208 begin
   209 
   210 text \<open>The divides relation\<close>
   211 
   212 lemma le_imp_power_dvd:
   213   assumes "m \<le> n" shows "a ^ m dvd a ^ n"
   214 proof
   215   have "a ^ n = a ^ (m + (n - m))"
   216     using \<open>m \<le> n\<close> by simp
   217   also have "\<dots> = a ^ m * a ^ (n - m)"
   218     by (rule power_add)
   219   finally show "a ^ n = a ^ m * a ^ (n - m)" .
   220 qed
   221 
   222 lemma power_le_dvd:
   223   "a ^ n dvd b \<Longrightarrow> m \<le> n \<Longrightarrow> a ^ m dvd b"
   224   by (rule dvd_trans [OF le_imp_power_dvd])
   225 
   226 lemma dvd_power_same:
   227   "x dvd y \<Longrightarrow> x ^ n dvd y ^ n"
   228   by (induct n) (auto simp add: mult_dvd_mono)
   229 
   230 lemma dvd_power_le:
   231   "x dvd y \<Longrightarrow> m \<ge> n \<Longrightarrow> x ^ n dvd y ^ m"
   232   by (rule power_le_dvd [OF dvd_power_same])
   233 
   234 lemma dvd_power [simp]:
   235   assumes "n > (0::nat) \<or> x = 1"
   236   shows "x dvd (x ^ n)"
   237 using assms proof
   238   assume "0 < n"
   239   then have "x ^ n = x ^ Suc (n - 1)" by simp
   240   then show "x dvd (x ^ n)" by simp
   241 next
   242   assume "x = 1"
   243   then show "x dvd (x ^ n)" by simp
   244 qed
   245 
   246 end
   247 
   248 class semiring_1_no_zero_divisors = semiring_1 + semiring_no_zero_divisors
   249 begin
   250 
   251 subclass power .
   252 
   253 lemma power_eq_0_iff [simp]:
   254   "a ^ n = 0 \<longleftrightarrow> a = 0 \<and> n > 0"
   255   by (induct n) auto
   256 
   257 lemma power_not_zero:
   258   "a \<noteq> 0 \<Longrightarrow> a ^ n \<noteq> 0"
   259   by (induct n) auto
   260 
   261 lemma zero_eq_power2 [simp]:
   262   "a\<^sup>2 = 0 \<longleftrightarrow> a = 0"
   263   unfolding power2_eq_square by simp
   264 
   265 end
   266 
   267 context semidom
   268 begin
   269 
   270 subclass semiring_1_no_zero_divisors ..
   271 
   272 end
   273 
   274 context ring_1
   275 begin
   276 
   277 lemma power_minus:
   278   "(- a) ^ n = (- 1) ^ n * a ^ n"
   279 proof (induct n)
   280   case 0 show ?case by simp
   281 next
   282   case (Suc n) then show ?case
   283     by (simp del: power_Suc add: power_Suc2 mult.assoc)
   284 qed
   285 
   286 lemma power_minus': "NO_MATCH 1 x \<Longrightarrow> (-x) ^ n = (-1)^n * x ^ n"
   287   by (rule power_minus)
   288 
   289 lemma power_minus_Bit0:
   290   "(- x) ^ numeral (Num.Bit0 k) = x ^ numeral (Num.Bit0 k)"
   291   by (induct k, simp_all only: numeral_class.numeral.simps power_add
   292     power_one_right mult_minus_left mult_minus_right minus_minus)
   293 
   294 lemma power_minus_Bit1:
   295   "(- x) ^ numeral (Num.Bit1 k) = - (x ^ numeral (Num.Bit1 k))"
   296   by (simp only: eval_nat_numeral(3) power_Suc power_minus_Bit0 mult_minus_left)
   297 
   298 lemma power2_minus [simp]:
   299   "(- a)\<^sup>2 = a\<^sup>2"
   300   by (fact power_minus_Bit0)
   301 
   302 lemma power_minus1_even [simp]:
   303   "(- 1) ^ (2*n) = 1"
   304 proof (induct n)
   305   case 0 show ?case by simp
   306 next
   307   case (Suc n) then show ?case by (simp add: power_add power2_eq_square)
   308 qed
   309 
   310 lemma power_minus1_odd:
   311   "(- 1) ^ Suc (2*n) = -1"
   312   by simp
   313 
   314 lemma power_minus_even [simp]:
   315   "(-a) ^ (2*n) = a ^ (2*n)"
   316   by (simp add: power_minus [of a])
   317 
   318 end
   319 
   320 context ring_1_no_zero_divisors
   321 begin
   322 
   323 subclass semiring_1_no_zero_divisors ..
   324 
   325 lemma power2_eq_1_iff:
   326   "a\<^sup>2 = 1 \<longleftrightarrow> a = 1 \<or> a = - 1"
   327   using square_eq_1_iff [of a] by (simp add: power2_eq_square)
   328 
   329 end
   330 
   331 context idom
   332 begin
   333 
   334 lemma power2_eq_iff: "x\<^sup>2 = y\<^sup>2 \<longleftrightarrow> x = y \<or> x = - y"
   335   unfolding power2_eq_square by (rule square_eq_iff)
   336 
   337 end
   338 
   339 context algebraic_semidom
   340 begin
   341 
   342 lemma div_power:
   343   assumes "b dvd a"
   344   shows "(a div b) ^ n = a ^ n div b ^ n"
   345   using assms by (induct n) (simp_all add: div_mult_div_if_dvd dvd_power_same)
   346 
   347 end
   348 
   349 context normalization_semidom
   350 begin
   351 
   352 lemma normalize_power:
   353   "normalize (a ^ n) = normalize a ^ n"
   354   by (induct n) (simp_all add: normalize_mult)
   355 
   356 lemma unit_factor_power:
   357   "unit_factor (a ^ n) = unit_factor a ^ n"
   358   by (induct n) (simp_all add: unit_factor_mult)
   359 
   360 end
   361 
   362 context division_ring
   363 begin
   364 
   365 text\<open>Perhaps these should be simprules.\<close>
   366 lemma power_inverse [field_simps, divide_simps]:
   367   "inverse a ^ n = inverse (a ^ n)"
   368 proof (cases "a = 0")
   369   case True then show ?thesis by (simp add: power_0_left)
   370 next
   371   case False then have "inverse (a ^ n) = inverse a ^ n"
   372     by (induct n) (simp_all add: nonzero_inverse_mult_distrib power_commutes)
   373   then show ?thesis by simp
   374 qed
   375 
   376 lemma power_one_over [field_simps, divide_simps]:
   377   "(1 / a) ^ n = 1 / a ^ n"
   378   using power_inverse [of a] by (simp add: divide_inverse)
   379 
   380 end
   381 
   382 context field
   383 begin
   384 
   385 lemma power_diff:
   386   assumes nz: "a \<noteq> 0"
   387   shows "n \<le> m \<Longrightarrow> a ^ (m - n) = a ^ m / a ^ n"
   388   by (induct m n rule: diff_induct) (simp_all add: nz power_not_zero)
   389 
   390 lemma power_divide [field_simps, divide_simps]:
   391   "(a / b) ^ n = a ^ n / b ^ n"
   392   by (induct n) simp_all
   393 
   394 declare power_divide [where b = "numeral w" for w, simp]
   395 
   396 end
   397 
   398 
   399 subsection \<open>Exponentiation on ordered types\<close>
   400 
   401 context linordered_semidom
   402 begin
   403 
   404 lemma zero_less_power [simp]:
   405   "0 < a \<Longrightarrow> 0 < a ^ n"
   406   by (induct n) simp_all
   407 
   408 lemma zero_le_power [simp]:
   409   "0 \<le> a \<Longrightarrow> 0 \<le> a ^ n"
   410   by (induct n) simp_all
   411 
   412 lemma power_mono:
   413   "a \<le> b \<Longrightarrow> 0 \<le> a \<Longrightarrow> a ^ n \<le> b ^ n"
   414   by (induct n) (auto intro: mult_mono order_trans [of 0 a b])
   415 
   416 lemma one_le_power [simp]: "1 \<le> a \<Longrightarrow> 1 \<le> a ^ n"
   417   using power_mono [of 1 a n] by simp
   418 
   419 lemma power_le_one: "\<lbrakk>0 \<le> a; a \<le> 1\<rbrakk> \<Longrightarrow> a ^ n \<le> 1"
   420   using power_mono [of a 1 n] by simp
   421 
   422 lemma power_gt1_lemma:
   423   assumes gt1: "1 < a"
   424   shows "1 < a * a ^ n"
   425 proof -
   426   from gt1 have "0 \<le> a"
   427     by (fact order_trans [OF zero_le_one less_imp_le])
   428   have "1 * 1 < a * 1" using gt1 by simp
   429   also have "\<dots> \<le> a * a ^ n" using gt1
   430     by (simp only: mult_mono \<open>0 \<le> a\<close> one_le_power order_less_imp_le
   431         zero_le_one order_refl)
   432   finally show ?thesis by simp
   433 qed
   434 
   435 lemma power_gt1:
   436   "1 < a \<Longrightarrow> 1 < a ^ Suc n"
   437   by (simp add: power_gt1_lemma)
   438 
   439 lemma one_less_power [simp]:
   440   "1 < a \<Longrightarrow> 0 < n \<Longrightarrow> 1 < a ^ n"
   441   by (cases n) (simp_all add: power_gt1_lemma)
   442 
   443 lemma power_le_imp_le_exp:
   444   assumes gt1: "1 < a"
   445   shows "a ^ m \<le> a ^ n \<Longrightarrow> m \<le> n"
   446 proof (induct m arbitrary: n)
   447   case 0
   448   show ?case by simp
   449 next
   450   case (Suc m)
   451   show ?case
   452   proof (cases n)
   453     case 0
   454     with Suc.prems Suc.hyps have "a * a ^ m \<le> 1" by simp
   455     with gt1 show ?thesis
   456       by (force simp only: power_gt1_lemma
   457           not_less [symmetric])
   458   next
   459     case (Suc n)
   460     with Suc.prems Suc.hyps show ?thesis
   461       by (force dest: mult_left_le_imp_le
   462           simp add: less_trans [OF zero_less_one gt1])
   463   qed
   464 qed
   465 
   466 lemma of_nat_zero_less_power_iff [simp]:
   467   "of_nat x ^ n > 0 \<longleftrightarrow> x > 0 \<or> n = 0"
   468   by (induct n) auto
   469 
   470 text\<open>Surely we can strengthen this? It holds for @{text "0<a<1"} too.\<close>
   471 lemma power_inject_exp [simp]:
   472   "1 < a \<Longrightarrow> a ^ m = a ^ n \<longleftrightarrow> m = n"
   473   by (force simp add: order_antisym power_le_imp_le_exp)
   474 
   475 text\<open>Can relax the first premise to @{term "0<a"} in the case of the
   476 natural numbers.\<close>
   477 lemma power_less_imp_less_exp:
   478   "1 < a \<Longrightarrow> a ^ m < a ^ n \<Longrightarrow> m < n"
   479   by (simp add: order_less_le [of m n] less_le [of "a^m" "a^n"]
   480     power_le_imp_le_exp)
   481 
   482 lemma power_strict_mono [rule_format]:
   483   "a < b \<Longrightarrow> 0 \<le> a \<Longrightarrow> 0 < n \<longrightarrow> a ^ n < b ^ n"
   484   by (induct n)
   485    (auto simp add: mult_strict_mono le_less_trans [of 0 a b])
   486 
   487 text\<open>Lemma for @{text power_strict_decreasing}\<close>
   488 lemma power_Suc_less:
   489   "0 < a \<Longrightarrow> a < 1 \<Longrightarrow> a * a ^ n < a ^ n"
   490   by (induct n)
   491     (auto simp add: mult_strict_left_mono)
   492 
   493 lemma power_strict_decreasing [rule_format]:
   494   "n < N \<Longrightarrow> 0 < a \<Longrightarrow> a < 1 \<longrightarrow> a ^ N < a ^ n"
   495 proof (induct N)
   496   case 0 then show ?case by simp
   497 next
   498   case (Suc N) then show ?case
   499   apply (auto simp add: power_Suc_less less_Suc_eq)
   500   apply (subgoal_tac "a * a^N < 1 * a^n")
   501   apply simp
   502   apply (rule mult_strict_mono) apply auto
   503   done
   504 qed
   505 
   506 text\<open>Proof resembles that of @{text power_strict_decreasing}\<close>
   507 lemma power_decreasing [rule_format]:
   508   "n \<le> N \<Longrightarrow> 0 \<le> a \<Longrightarrow> a \<le> 1 \<longrightarrow> a ^ N \<le> a ^ n"
   509 proof (induct N)
   510   case 0 then show ?case by simp
   511 next
   512   case (Suc N) then show ?case
   513   apply (auto simp add: le_Suc_eq)
   514   apply (subgoal_tac "a * a^N \<le> 1 * a^n", simp)
   515   apply (rule mult_mono) apply auto
   516   done
   517 qed
   518 
   519 lemma power_Suc_less_one:
   520   "0 < a \<Longrightarrow> a < 1 \<Longrightarrow> a ^ Suc n < 1"
   521   using power_strict_decreasing [of 0 "Suc n" a] by simp
   522 
   523 text\<open>Proof again resembles that of @{text power_strict_decreasing}\<close>
   524 lemma power_increasing [rule_format]:
   525   "n \<le> N \<Longrightarrow> 1 \<le> a \<Longrightarrow> a ^ n \<le> a ^ N"
   526 proof (induct N)
   527   case 0 then show ?case by simp
   528 next
   529   case (Suc N) then show ?case
   530   apply (auto simp add: le_Suc_eq)
   531   apply (subgoal_tac "1 * a^n \<le> a * a^N", simp)
   532   apply (rule mult_mono) apply (auto simp add: order_trans [OF zero_le_one])
   533   done
   534 qed
   535 
   536 text\<open>Lemma for @{text power_strict_increasing}\<close>
   537 lemma power_less_power_Suc:
   538   "1 < a \<Longrightarrow> a ^ n < a * a ^ n"
   539   by (induct n) (auto simp add: mult_strict_left_mono less_trans [OF zero_less_one])
   540 
   541 lemma power_strict_increasing [rule_format]:
   542   "n < N \<Longrightarrow> 1 < a \<longrightarrow> a ^ n < a ^ N"
   543 proof (induct N)
   544   case 0 then show ?case by simp
   545 next
   546   case (Suc N) then show ?case
   547   apply (auto simp add: power_less_power_Suc less_Suc_eq)
   548   apply (subgoal_tac "1 * a^n < a * a^N", simp)
   549   apply (rule mult_strict_mono) apply (auto simp add: less_trans [OF zero_less_one] less_imp_le)
   550   done
   551 qed
   552 
   553 lemma power_increasing_iff [simp]:
   554   "1 < b \<Longrightarrow> b ^ x \<le> b ^ y \<longleftrightarrow> x \<le> y"
   555   by (blast intro: power_le_imp_le_exp power_increasing less_imp_le)
   556 
   557 lemma power_strict_increasing_iff [simp]:
   558   "1 < b \<Longrightarrow> b ^ x < b ^ y \<longleftrightarrow> x < y"
   559 by (blast intro: power_less_imp_less_exp power_strict_increasing)
   560 
   561 lemma power_le_imp_le_base:
   562   assumes le: "a ^ Suc n \<le> b ^ Suc n"
   563     and ynonneg: "0 \<le> b"
   564   shows "a \<le> b"
   565 proof (rule ccontr)
   566   assume "~ a \<le> b"
   567   then have "b < a" by (simp only: linorder_not_le)
   568   then have "b ^ Suc n < a ^ Suc n"
   569     by (simp only: assms power_strict_mono)
   570   from le and this show False
   571     by (simp add: linorder_not_less [symmetric])
   572 qed
   573 
   574 lemma power_less_imp_less_base:
   575   assumes less: "a ^ n < b ^ n"
   576   assumes nonneg: "0 \<le> b"
   577   shows "a < b"
   578 proof (rule contrapos_pp [OF less])
   579   assume "~ a < b"
   580   hence "b \<le> a" by (simp only: linorder_not_less)
   581   hence "b ^ n \<le> a ^ n" using nonneg by (rule power_mono)
   582   thus "\<not> a ^ n < b ^ n" by (simp only: linorder_not_less)
   583 qed
   584 
   585 lemma power_inject_base:
   586   "a ^ Suc n = b ^ Suc n \<Longrightarrow> 0 \<le> a \<Longrightarrow> 0 \<le> b \<Longrightarrow> a = b"
   587 by (blast intro: power_le_imp_le_base antisym eq_refl sym)
   588 
   589 lemma power_eq_imp_eq_base:
   590   "a ^ n = b ^ n \<Longrightarrow> 0 \<le> a \<Longrightarrow> 0 \<le> b \<Longrightarrow> 0 < n \<Longrightarrow> a = b"
   591   by (cases n) (simp_all del: power_Suc, rule power_inject_base)
   592 
   593 lemma power2_le_imp_le:
   594   "x\<^sup>2 \<le> y\<^sup>2 \<Longrightarrow> 0 \<le> y \<Longrightarrow> x \<le> y"
   595   unfolding numeral_2_eq_2 by (rule power_le_imp_le_base)
   596 
   597 lemma power2_less_imp_less:
   598   "x\<^sup>2 < y\<^sup>2 \<Longrightarrow> 0 \<le> y \<Longrightarrow> x < y"
   599   by (rule power_less_imp_less_base)
   600 
   601 lemma power2_eq_imp_eq:
   602   "x\<^sup>2 = y\<^sup>2 \<Longrightarrow> 0 \<le> x \<Longrightarrow> 0 \<le> y \<Longrightarrow> x = y"
   603   unfolding numeral_2_eq_2 by (erule (2) power_eq_imp_eq_base) simp
   604 
   605 end
   606 
   607 context linordered_ring_strict
   608 begin
   609 
   610 lemma sum_squares_eq_zero_iff:
   611   "x * x + y * y = 0 \<longleftrightarrow> x = 0 \<and> y = 0"
   612   by (simp add: add_nonneg_eq_0_iff)
   613 
   614 lemma sum_squares_le_zero_iff:
   615   "x * x + y * y \<le> 0 \<longleftrightarrow> x = 0 \<and> y = 0"
   616   by (simp add: le_less not_sum_squares_lt_zero sum_squares_eq_zero_iff)
   617 
   618 lemma sum_squares_gt_zero_iff:
   619   "0 < x * x + y * y \<longleftrightarrow> x \<noteq> 0 \<or> y \<noteq> 0"
   620   by (simp add: not_le [symmetric] sum_squares_le_zero_iff)
   621 
   622 end
   623 
   624 context linordered_idom
   625 begin
   626 
   627 lemma power_abs:
   628   "abs (a ^ n) = abs a ^ n"
   629   by (induct n) (auto simp add: abs_mult)
   630 
   631 lemma abs_power_minus [simp]:
   632   "abs ((-a) ^ n) = abs (a ^ n)"
   633   by (simp add: power_abs)
   634 
   635 lemma zero_less_power_abs_iff [simp]:
   636   "0 < abs a ^ n \<longleftrightarrow> a \<noteq> 0 \<or> n = 0"
   637 proof (induct n)
   638   case 0 show ?case by simp
   639 next
   640   case (Suc n) show ?case by (auto simp add: Suc zero_less_mult_iff)
   641 qed
   642 
   643 lemma zero_le_power_abs [simp]:
   644   "0 \<le> abs a ^ n"
   645   by (rule zero_le_power [OF abs_ge_zero])
   646 
   647 lemma zero_le_power2 [simp]:
   648   "0 \<le> a\<^sup>2"
   649   by (simp add: power2_eq_square)
   650 
   651 lemma zero_less_power2 [simp]:
   652   "0 < a\<^sup>2 \<longleftrightarrow> a \<noteq> 0"
   653   by (force simp add: power2_eq_square zero_less_mult_iff linorder_neq_iff)
   654 
   655 lemma power2_less_0 [simp]:
   656   "\<not> a\<^sup>2 < 0"
   657   by (force simp add: power2_eq_square mult_less_0_iff)
   658 
   659 lemma power2_less_eq_zero_iff [simp]:
   660   "a\<^sup>2 \<le> 0 \<longleftrightarrow> a = 0"
   661   by (simp add: le_less)
   662 
   663 lemma abs_power2 [simp]:
   664   "abs (a\<^sup>2) = a\<^sup>2"
   665   by (simp add: power2_eq_square abs_mult abs_mult_self)
   666 
   667 lemma power2_abs [simp]:
   668   "(abs a)\<^sup>2 = a\<^sup>2"
   669   by (simp add: power2_eq_square abs_mult_self)
   670 
   671 lemma odd_power_less_zero:
   672   "a < 0 \<Longrightarrow> a ^ Suc (2*n) < 0"
   673 proof (induct n)
   674   case 0
   675   then show ?case by simp
   676 next
   677   case (Suc n)
   678   have "a ^ Suc (2 * Suc n) = (a*a) * a ^ Suc(2*n)"
   679     by (simp add: ac_simps power_add power2_eq_square)
   680   thus ?case
   681     by (simp del: power_Suc add: Suc mult_less_0_iff mult_neg_neg)
   682 qed
   683 
   684 lemma odd_0_le_power_imp_0_le:
   685   "0 \<le> a ^ Suc (2*n) \<Longrightarrow> 0 \<le> a"
   686   using odd_power_less_zero [of a n]
   687     by (force simp add: linorder_not_less [symmetric])
   688 
   689 lemma zero_le_even_power'[simp]:
   690   "0 \<le> a ^ (2*n)"
   691 proof (induct n)
   692   case 0
   693     show ?case by simp
   694 next
   695   case (Suc n)
   696     have "a ^ (2 * Suc n) = (a*a) * a ^ (2*n)"
   697       by (simp add: ac_simps power_add power2_eq_square)
   698     thus ?case
   699       by (simp add: Suc zero_le_mult_iff)
   700 qed
   701 
   702 lemma sum_power2_ge_zero:
   703   "0 \<le> x\<^sup>2 + y\<^sup>2"
   704   by (intro add_nonneg_nonneg zero_le_power2)
   705 
   706 lemma not_sum_power2_lt_zero:
   707   "\<not> x\<^sup>2 + y\<^sup>2 < 0"
   708   unfolding not_less by (rule sum_power2_ge_zero)
   709 
   710 lemma sum_power2_eq_zero_iff:
   711   "x\<^sup>2 + y\<^sup>2 = 0 \<longleftrightarrow> x = 0 \<and> y = 0"
   712   unfolding power2_eq_square by (simp add: add_nonneg_eq_0_iff)
   713 
   714 lemma sum_power2_le_zero_iff:
   715   "x\<^sup>2 + y\<^sup>2 \<le> 0 \<longleftrightarrow> x = 0 \<and> y = 0"
   716   by (simp add: le_less sum_power2_eq_zero_iff not_sum_power2_lt_zero)
   717 
   718 lemma sum_power2_gt_zero_iff:
   719   "0 < x\<^sup>2 + y\<^sup>2 \<longleftrightarrow> x \<noteq> 0 \<or> y \<noteq> 0"
   720   unfolding not_le [symmetric] by (simp add: sum_power2_le_zero_iff)
   721 
   722 lemma abs_le_square_iff:
   723    "\<bar>x\<bar> \<le> \<bar>y\<bar> \<longleftrightarrow> x\<^sup>2 \<le> y\<^sup>2"
   724 proof
   725   assume "\<bar>x\<bar> \<le> \<bar>y\<bar>"
   726   then have "\<bar>x\<bar>\<^sup>2 \<le> \<bar>y\<bar>\<^sup>2" by (rule power_mono, simp)
   727   then show "x\<^sup>2 \<le> y\<^sup>2" by simp
   728 next
   729   assume "x\<^sup>2 \<le> y\<^sup>2"
   730   then show "\<bar>x\<bar> \<le> \<bar>y\<bar>"
   731     by (auto intro!: power2_le_imp_le [OF _ abs_ge_zero])
   732 qed
   733 
   734 lemma abs_square_le_1:"x\<^sup>2 \<le> 1 \<longleftrightarrow> abs(x) \<le> 1"
   735   using abs_le_square_iff [of x 1]
   736   by simp
   737 
   738 lemma abs_square_eq_1: "x\<^sup>2 = 1 \<longleftrightarrow> abs(x) = 1"
   739   by (auto simp add: abs_if power2_eq_1_iff)
   740 
   741 lemma abs_square_less_1: "x\<^sup>2 < 1 \<longleftrightarrow> abs(x) < 1"
   742   using  abs_square_eq_1 [of x] abs_square_le_1 [of x]
   743   by (auto simp add: le_less)
   744 
   745 end
   746 
   747 
   748 subsection \<open>Miscellaneous rules\<close>
   749 
   750 lemma (in linordered_semidom) self_le_power:
   751   "1 \<le> a \<Longrightarrow> 0 < n \<Longrightarrow> a \<le> a ^ n"
   752   using power_increasing [of 1 n a] power_one_right [of a] by auto
   753 
   754 lemma (in power) power_eq_if:
   755   "p ^ m = (if m=0 then 1 else p * (p ^ (m - 1)))"
   756   unfolding One_nat_def by (cases m) simp_all
   757 
   758 lemma (in comm_semiring_1) power2_sum:
   759   "(x + y)\<^sup>2 = x\<^sup>2 + y\<^sup>2 + 2 * x * y"
   760   by (simp add: algebra_simps power2_eq_square mult_2_right)
   761 
   762 lemma (in comm_ring_1) power2_diff:
   763   "(x - y)\<^sup>2 = x\<^sup>2 + y\<^sup>2 - 2 * x * y"
   764   by (simp add: algebra_simps power2_eq_square mult_2_right)
   765 
   766 lemma (in comm_ring_1) power2_commute:
   767   "(x - y)\<^sup>2 = (y - x)\<^sup>2"
   768   by (simp add: algebra_simps power2_eq_square)
   769 
   770 
   771 text \<open>Simprules for comparisons where common factors can be cancelled.\<close>
   772 
   773 lemmas zero_compare_simps =
   774     add_strict_increasing add_strict_increasing2 add_increasing
   775     zero_le_mult_iff zero_le_divide_iff
   776     zero_less_mult_iff zero_less_divide_iff
   777     mult_le_0_iff divide_le_0_iff
   778     mult_less_0_iff divide_less_0_iff
   779     zero_le_power2 power2_less_0
   780 
   781 
   782 subsection \<open>Exponentiation for the Natural Numbers\<close>
   783 
   784 lemma nat_one_le_power [simp]:
   785   "Suc 0 \<le> i \<Longrightarrow> Suc 0 \<le> i ^ n"
   786   by (rule one_le_power [of i n, unfolded One_nat_def])
   787 
   788 lemma nat_zero_less_power_iff [simp]:
   789   "x ^ n > 0 \<longleftrightarrow> x > (0::nat) \<or> n = 0"
   790   by (induct n) auto
   791 
   792 lemma nat_power_eq_Suc_0_iff [simp]:
   793   "x ^ m = Suc 0 \<longleftrightarrow> m = 0 \<or> x = Suc 0"
   794   by (induct m) auto
   795 
   796 lemma power_Suc_0 [simp]:
   797   "Suc 0 ^ n = Suc 0"
   798   by simp
   799 
   800 text\<open>Valid for the naturals, but what if @{text"0<i<1"}?
   801 Premises cannot be weakened: consider the case where @{term "i=0"},
   802 @{term "m=1"} and @{term "n=0"}.\<close>
   803 lemma nat_power_less_imp_less:
   804   assumes nonneg: "0 < (i::nat)"
   805   assumes less: "i ^ m < i ^ n"
   806   shows "m < n"
   807 proof (cases "i = 1")
   808   case True with less power_one [where 'a = nat] show ?thesis by simp
   809 next
   810   case False with nonneg have "1 < i" by auto
   811   from power_strict_increasing_iff [OF this] less show ?thesis ..
   812 qed
   813 
   814 lemma power_dvd_imp_le:
   815   "i ^ m dvd i ^ n \<Longrightarrow> (1::nat) < i \<Longrightarrow> m \<le> n"
   816   apply (rule power_le_imp_le_exp, assumption)
   817   apply (erule dvd_imp_le, simp)
   818   done
   819 
   820 lemma power2_nat_le_eq_le:
   821   fixes m n :: nat
   822   shows "m\<^sup>2 \<le> n\<^sup>2 \<longleftrightarrow> m \<le> n"
   823   by (auto intro: power2_le_imp_le power_mono)
   824 
   825 lemma power2_nat_le_imp_le:
   826   fixes m n :: nat
   827   assumes "m\<^sup>2 \<le> n"
   828   shows "m \<le> n"
   829 proof (cases m)
   830   case 0 then show ?thesis by simp
   831 next
   832   case (Suc k)
   833   show ?thesis
   834   proof (rule ccontr)
   835     assume "\<not> m \<le> n"
   836     then have "n < m" by simp
   837     with assms Suc show False
   838       by (simp add: power2_eq_square)
   839   qed
   840 qed
   841 
   842 subsubsection \<open>Cardinality of the Powerset\<close>
   843 
   844 lemma card_UNIV_bool [simp]: "card (UNIV :: bool set) = 2"
   845   unfolding UNIV_bool by simp
   846 
   847 lemma card_Pow: "finite A \<Longrightarrow> card (Pow A) = 2 ^ card A"
   848 proof (induct rule: finite_induct)
   849   case empty
   850     show ?case by auto
   851 next
   852   case (insert x A)
   853   then have "inj_on (insert x) (Pow A)"
   854     unfolding inj_on_def by (blast elim!: equalityE)
   855   then have "card (Pow A) + card (insert x ` Pow A) = 2 * 2 ^ card A"
   856     by (simp add: mult_2 card_image Pow_insert insert.hyps)
   857   then show ?case using insert
   858     apply (simp add: Pow_insert)
   859     apply (subst card_Un_disjoint, auto)
   860     done
   861 qed
   862 
   863 
   864 subsubsection \<open>Generalized sum over a set\<close>
   865 
   866 lemma setsum_zero_power [simp]:
   867   fixes c :: "nat \<Rightarrow> 'a::division_ring"
   868   shows "(\<Sum>i\<in>A. c i * 0^i) = (if finite A \<and> 0 \<in> A then c 0 else 0)"
   869 apply (cases "finite A")
   870   by (induction A rule: finite_induct) auto
   871 
   872 lemma setsum_zero_power' [simp]:
   873   fixes c :: "nat \<Rightarrow> 'a::field"
   874   shows "(\<Sum>i\<in>A. c i * 0^i / d i) = (if finite A \<and> 0 \<in> A then c 0 / d 0 else 0)"
   875   using setsum_zero_power [of "\<lambda>i. c i / d i" A]
   876   by auto
   877 
   878 
   879 subsubsection \<open>Generalized product over a set\<close>
   880 
   881 lemma setprod_constant: "finite A ==> (\<Prod>x\<in> A. (y::'a::{comm_monoid_mult})) = y^(card A)"
   882 apply (erule finite_induct)
   883 apply auto
   884 done
   885 
   886 lemma setprod_power_distrib:
   887   fixes f :: "'a \<Rightarrow> 'b::comm_semiring_1"
   888   shows "setprod f A ^ n = setprod (\<lambda>x. (f x) ^ n) A"
   889 proof (cases "finite A")
   890   case True then show ?thesis
   891     by (induct A rule: finite_induct) (auto simp add: power_mult_distrib)
   892 next
   893   case False then show ?thesis
   894     by simp
   895 qed
   896 
   897 lemma power_setsum:
   898   "c ^ (\<Sum>a\<in>A. f a) = (\<Prod>a\<in>A. c ^ f a)"
   899   by (induct A rule: infinite_finite_induct) (simp_all add: power_add)
   900 
   901 lemma setprod_gen_delta:
   902   assumes fS: "finite S"
   903   shows "setprod (\<lambda>k. if k=a then b k else c) S = (if a \<in> S then (b a ::'a::comm_monoid_mult) * c^ (card S - 1) else c^ card S)"
   904 proof-
   905   let ?f = "(\<lambda>k. if k=a then b k else c)"
   906   {assume a: "a \<notin> S"
   907     hence "\<forall> k\<in> S. ?f k = c" by simp
   908     hence ?thesis  using a setprod_constant[OF fS, of c] by simp }
   909   moreover
   910   {assume a: "a \<in> S"
   911     let ?A = "S - {a}"
   912     let ?B = "{a}"
   913     have eq: "S = ?A \<union> ?B" using a by blast
   914     have dj: "?A \<inter> ?B = {}" by simp
   915     from fS have fAB: "finite ?A" "finite ?B" by auto
   916     have fA0:"setprod ?f ?A = setprod (\<lambda>i. c) ?A"
   917       apply (rule setprod.cong) by auto
   918     have cA: "card ?A = card S - 1" using fS a by auto
   919     have fA1: "setprod ?f ?A = c ^ card ?A"  unfolding fA0 apply (rule setprod_constant) using fS by auto
   920     have "setprod ?f ?A * setprod ?f ?B = setprod ?f S"
   921       using setprod.union_disjoint[OF fAB dj, of ?f, unfolded eq[symmetric]]
   922       by simp
   923     then have ?thesis using a cA
   924       by (simp add: fA1 field_simps cong add: setprod.cong cong del: if_weak_cong)}
   925   ultimately show ?thesis by blast
   926 qed
   927 
   928 subsection \<open>Code generator tweak\<close>
   929 
   930 code_identifier
   931   code_module Power \<rightharpoonup> (SML) Arith and (OCaml) Arith and (Haskell) Arith
   932 
   933 end