src/HOL/Library/Multiset.thy
author blanchet
Fri Jan 24 11:51:45 2014 +0100 (2014-01-24)
changeset 55129 26bd1cba3ab5
parent 54868 bab6cade3cc5
child 55417 01fbfb60c33e
permissions -rw-r--r--
killed 'More_BNFs' by moving its various bits where they (now) belong
     1 (*  Title:      HOL/Library/Multiset.thy
     2     Author:     Tobias Nipkow, Markus Wenzel, Lawrence C Paulson, Norbert Voelker
     3     Author:     Andrei Popescu, TU Muenchen
     4 *)
     5 
     6 header {* (Finite) multisets *}
     7 
     8 theory Multiset
     9 imports Main
    10 begin
    11 
    12 subsection {* The type of multisets *}
    13 
    14 definition "multiset = {f :: 'a => nat. finite {x. f x > 0}}"
    15 
    16 typedef 'a multiset = "multiset :: ('a => nat) set"
    17   morphisms count Abs_multiset
    18   unfolding multiset_def
    19 proof
    20   show "(\<lambda>x. 0::nat) \<in> {f. finite {x. f x > 0}}" by simp
    21 qed
    22 
    23 setup_lifting type_definition_multiset
    24 
    25 abbreviation Melem :: "'a => 'a multiset => bool"  ("(_/ :# _)" [50, 51] 50) where
    26   "a :# M == 0 < count M a"
    27 
    28 notation (xsymbols)
    29   Melem (infix "\<in>#" 50)
    30 
    31 lemma multiset_eq_iff:
    32   "M = N \<longleftrightarrow> (\<forall>a. count M a = count N a)"
    33   by (simp only: count_inject [symmetric] fun_eq_iff)
    34 
    35 lemma multiset_eqI:
    36   "(\<And>x. count A x = count B x) \<Longrightarrow> A = B"
    37   using multiset_eq_iff by auto
    38 
    39 text {*
    40  \medskip Preservation of the representing set @{term multiset}.
    41 *}
    42 
    43 lemma const0_in_multiset:
    44   "(\<lambda>a. 0) \<in> multiset"
    45   by (simp add: multiset_def)
    46 
    47 lemma only1_in_multiset:
    48   "(\<lambda>b. if b = a then n else 0) \<in> multiset"
    49   by (simp add: multiset_def)
    50 
    51 lemma union_preserves_multiset:
    52   "M \<in> multiset \<Longrightarrow> N \<in> multiset \<Longrightarrow> (\<lambda>a. M a + N a) \<in> multiset"
    53   by (simp add: multiset_def)
    54 
    55 lemma diff_preserves_multiset:
    56   assumes "M \<in> multiset"
    57   shows "(\<lambda>a. M a - N a) \<in> multiset"
    58 proof -
    59   have "{x. N x < M x} \<subseteq> {x. 0 < M x}"
    60     by auto
    61   with assms show ?thesis
    62     by (auto simp add: multiset_def intro: finite_subset)
    63 qed
    64 
    65 lemma filter_preserves_multiset:
    66   assumes "M \<in> multiset"
    67   shows "(\<lambda>x. if P x then M x else 0) \<in> multiset"
    68 proof -
    69   have "{x. (P x \<longrightarrow> 0 < M x) \<and> P x} \<subseteq> {x. 0 < M x}"
    70     by auto
    71   with assms show ?thesis
    72     by (auto simp add: multiset_def intro: finite_subset)
    73 qed
    74 
    75 lemmas in_multiset = const0_in_multiset only1_in_multiset
    76   union_preserves_multiset diff_preserves_multiset filter_preserves_multiset
    77 
    78 
    79 subsection {* Representing multisets *}
    80 
    81 text {* Multiset enumeration *}
    82 
    83 instantiation multiset :: (type) cancel_comm_monoid_add
    84 begin
    85 
    86 lift_definition zero_multiset :: "'a multiset" is "\<lambda>a. 0"
    87 by (rule const0_in_multiset)
    88 
    89 abbreviation Mempty :: "'a multiset" ("{#}") where
    90   "Mempty \<equiv> 0"
    91 
    92 lift_definition plus_multiset :: "'a multiset => 'a multiset => 'a multiset" is "\<lambda>M N. (\<lambda>a. M a + N a)"
    93 by (rule union_preserves_multiset)
    94 
    95 instance
    96 by default (transfer, simp add: fun_eq_iff)+
    97 
    98 end
    99 
   100 lift_definition single :: "'a => 'a multiset" is "\<lambda>a b. if b = a then 1 else 0"
   101 by (rule only1_in_multiset)
   102 
   103 syntax
   104   "_multiset" :: "args => 'a multiset"    ("{#(_)#}")
   105 translations
   106   "{#x, xs#}" == "{#x#} + {#xs#}"
   107   "{#x#}" == "CONST single x"
   108 
   109 lemma count_empty [simp]: "count {#} a = 0"
   110   by (simp add: zero_multiset.rep_eq)
   111 
   112 lemma count_single [simp]: "count {#b#} a = (if b = a then 1 else 0)"
   113   by (simp add: single.rep_eq)
   114 
   115 
   116 subsection {* Basic operations *}
   117 
   118 subsubsection {* Union *}
   119 
   120 lemma count_union [simp]: "count (M + N) a = count M a + count N a"
   121   by (simp add: plus_multiset.rep_eq)
   122 
   123 
   124 subsubsection {* Difference *}
   125 
   126 instantiation multiset :: (type) comm_monoid_diff
   127 begin
   128 
   129 lift_definition minus_multiset :: "'a multiset => 'a multiset => 'a multiset" is "\<lambda> M N. \<lambda>a. M a - N a"
   130 by (rule diff_preserves_multiset)
   131  
   132 instance
   133 by default (transfer, simp add: fun_eq_iff)+
   134 
   135 end
   136 
   137 lemma count_diff [simp]: "count (M - N) a = count M a - count N a"
   138   by (simp add: minus_multiset.rep_eq)
   139 
   140 lemma diff_empty [simp]: "M - {#} = M \<and> {#} - M = {#}"
   141   by rule (fact Groups.diff_zero, fact Groups.zero_diff)
   142 
   143 lemma diff_cancel[simp]: "A - A = {#}"
   144   by (fact Groups.diff_cancel)
   145 
   146 lemma diff_union_cancelR [simp]: "M + N - N = (M::'a multiset)"
   147   by (fact add_diff_cancel_right')
   148 
   149 lemma diff_union_cancelL [simp]: "N + M - N = (M::'a multiset)"
   150   by (fact add_diff_cancel_left')
   151 
   152 lemma diff_right_commute:
   153   "(M::'a multiset) - N - Q = M - Q - N"
   154   by (fact diff_right_commute)
   155 
   156 lemma diff_add:
   157   "(M::'a multiset) - (N + Q) = M - N - Q"
   158   by (rule sym) (fact diff_diff_add)
   159   
   160 lemma insert_DiffM:
   161   "x \<in># M \<Longrightarrow> {#x#} + (M - {#x#}) = M"
   162   by (clarsimp simp: multiset_eq_iff)
   163 
   164 lemma insert_DiffM2 [simp]:
   165   "x \<in># M \<Longrightarrow> M - {#x#} + {#x#} = M"
   166   by (clarsimp simp: multiset_eq_iff)
   167 
   168 lemma diff_union_swap:
   169   "a \<noteq> b \<Longrightarrow> M - {#a#} + {#b#} = M + {#b#} - {#a#}"
   170   by (auto simp add: multiset_eq_iff)
   171 
   172 lemma diff_union_single_conv:
   173   "a \<in># J \<Longrightarrow> I + J - {#a#} = I + (J - {#a#})"
   174   by (simp add: multiset_eq_iff)
   175 
   176 
   177 subsubsection {* Equality of multisets *}
   178 
   179 lemma single_not_empty [simp]: "{#a#} \<noteq> {#} \<and> {#} \<noteq> {#a#}"
   180   by (simp add: multiset_eq_iff)
   181 
   182 lemma single_eq_single [simp]: "{#a#} = {#b#} \<longleftrightarrow> a = b"
   183   by (auto simp add: multiset_eq_iff)
   184 
   185 lemma union_eq_empty [iff]: "M + N = {#} \<longleftrightarrow> M = {#} \<and> N = {#}"
   186   by (auto simp add: multiset_eq_iff)
   187 
   188 lemma empty_eq_union [iff]: "{#} = M + N \<longleftrightarrow> M = {#} \<and> N = {#}"
   189   by (auto simp add: multiset_eq_iff)
   190 
   191 lemma multi_self_add_other_not_self [simp]: "M = M + {#x#} \<longleftrightarrow> False"
   192   by (auto simp add: multiset_eq_iff)
   193 
   194 lemma diff_single_trivial:
   195   "\<not> x \<in># M \<Longrightarrow> M - {#x#} = M"
   196   by (auto simp add: multiset_eq_iff)
   197 
   198 lemma diff_single_eq_union:
   199   "x \<in># M \<Longrightarrow> M - {#x#} = N \<longleftrightarrow> M = N + {#x#}"
   200   by auto
   201 
   202 lemma union_single_eq_diff:
   203   "M + {#x#} = N \<Longrightarrow> M = N - {#x#}"
   204   by (auto dest: sym)
   205 
   206 lemma union_single_eq_member:
   207   "M + {#x#} = N \<Longrightarrow> x \<in># N"
   208   by auto
   209 
   210 lemma union_is_single:
   211   "M + N = {#a#} \<longleftrightarrow> M = {#a#} \<and> N={#} \<or> M = {#} \<and> N = {#a#}" (is "?lhs = ?rhs")
   212 proof
   213   assume ?rhs then show ?lhs by auto
   214 next
   215   assume ?lhs then show ?rhs
   216     by (simp add: multiset_eq_iff split:if_splits) (metis add_is_1)
   217 qed
   218 
   219 lemma single_is_union:
   220   "{#a#} = M + N \<longleftrightarrow> {#a#} = M \<and> N = {#} \<or> M = {#} \<and> {#a#} = N"
   221   by (auto simp add: eq_commute [of "{#a#}" "M + N"] union_is_single)
   222 
   223 lemma add_eq_conv_diff:
   224   "M + {#a#} = N + {#b#} \<longleftrightarrow> M = N \<and> a = b \<or> M = N - {#a#} + {#b#} \<and> N = M - {#b#} + {#a#}"  (is "?lhs = ?rhs")
   225 (* shorter: by (simp add: multiset_eq_iff) fastforce *)
   226 proof
   227   assume ?rhs then show ?lhs
   228   by (auto simp add: add_assoc add_commute [of "{#b#}"])
   229     (drule sym, simp add: add_assoc [symmetric])
   230 next
   231   assume ?lhs
   232   show ?rhs
   233   proof (cases "a = b")
   234     case True with `?lhs` show ?thesis by simp
   235   next
   236     case False
   237     from `?lhs` have "a \<in># N + {#b#}" by (rule union_single_eq_member)
   238     with False have "a \<in># N" by auto
   239     moreover from `?lhs` have "M = N + {#b#} - {#a#}" by (rule union_single_eq_diff)
   240     moreover note False
   241     ultimately show ?thesis by (auto simp add: diff_right_commute [of _ "{#a#}"] diff_union_swap)
   242   qed
   243 qed
   244 
   245 lemma insert_noteq_member: 
   246   assumes BC: "B + {#b#} = C + {#c#}"
   247    and bnotc: "b \<noteq> c"
   248   shows "c \<in># B"
   249 proof -
   250   have "c \<in># C + {#c#}" by simp
   251   have nc: "\<not> c \<in># {#b#}" using bnotc by simp
   252   then have "c \<in># B + {#b#}" using BC by simp
   253   then show "c \<in># B" using nc by simp
   254 qed
   255 
   256 lemma add_eq_conv_ex:
   257   "(M + {#a#} = N + {#b#}) =
   258     (M = N \<and> a = b \<or> (\<exists>K. M = K + {#b#} \<and> N = K + {#a#}))"
   259   by (auto simp add: add_eq_conv_diff)
   260 
   261 lemma multi_member_split:
   262   "x \<in># M \<Longrightarrow> \<exists>A. M = A + {#x#}"
   263   by (rule_tac x = "M - {#x#}" in exI, simp)
   264 
   265 
   266 subsubsection {* Pointwise ordering induced by count *}
   267 
   268 instantiation multiset :: (type) ordered_ab_semigroup_add_imp_le
   269 begin
   270 
   271 lift_definition less_eq_multiset :: "'a multiset \<Rightarrow> 'a multiset \<Rightarrow> bool" is "\<lambda> A B. (\<forall>a. A a \<le> B a)"
   272 by simp
   273 lemmas mset_le_def = less_eq_multiset_def
   274 
   275 definition less_multiset :: "'a multiset \<Rightarrow> 'a multiset \<Rightarrow> bool" where
   276   mset_less_def: "(A::'a multiset) < B \<longleftrightarrow> A \<le> B \<and> A \<noteq> B"
   277 
   278 instance
   279   by default (auto simp add: mset_le_def mset_less_def multiset_eq_iff intro: order_trans antisym)
   280 
   281 end
   282 
   283 lemma mset_less_eqI:
   284   "(\<And>x. count A x \<le> count B x) \<Longrightarrow> A \<le> B"
   285   by (simp add: mset_le_def)
   286 
   287 lemma mset_le_exists_conv:
   288   "(A::'a multiset) \<le> B \<longleftrightarrow> (\<exists>C. B = A + C)"
   289 apply (unfold mset_le_def, rule iffI, rule_tac x = "B - A" in exI)
   290 apply (auto intro: multiset_eq_iff [THEN iffD2])
   291 done
   292 
   293 instance multiset :: (type) ordered_cancel_comm_monoid_diff
   294   by default (simp, fact mset_le_exists_conv)
   295 
   296 lemma mset_le_mono_add_right_cancel [simp]:
   297   "(A::'a multiset) + C \<le> B + C \<longleftrightarrow> A \<le> B"
   298   by (fact add_le_cancel_right)
   299 
   300 lemma mset_le_mono_add_left_cancel [simp]:
   301   "C + (A::'a multiset) \<le> C + B \<longleftrightarrow> A \<le> B"
   302   by (fact add_le_cancel_left)
   303 
   304 lemma mset_le_mono_add:
   305   "(A::'a multiset) \<le> B \<Longrightarrow> C \<le> D \<Longrightarrow> A + C \<le> B + D"
   306   by (fact add_mono)
   307 
   308 lemma mset_le_add_left [simp]:
   309   "(A::'a multiset) \<le> A + B"
   310   unfolding mset_le_def by auto
   311 
   312 lemma mset_le_add_right [simp]:
   313   "B \<le> (A::'a multiset) + B"
   314   unfolding mset_le_def by auto
   315 
   316 lemma mset_le_single:
   317   "a :# B \<Longrightarrow> {#a#} \<le> B"
   318   by (simp add: mset_le_def)
   319 
   320 lemma multiset_diff_union_assoc:
   321   "C \<le> B \<Longrightarrow> (A::'a multiset) + B - C = A + (B - C)"
   322   by (simp add: multiset_eq_iff mset_le_def)
   323 
   324 lemma mset_le_multiset_union_diff_commute:
   325   "B \<le> A \<Longrightarrow> (A::'a multiset) - B + C = A + C - B"
   326 by (simp add: multiset_eq_iff mset_le_def)
   327 
   328 lemma diff_le_self[simp]: "(M::'a multiset) - N \<le> M"
   329 by(simp add: mset_le_def)
   330 
   331 lemma mset_lessD: "A < B \<Longrightarrow> x \<in># A \<Longrightarrow> x \<in># B"
   332 apply (clarsimp simp: mset_le_def mset_less_def)
   333 apply (erule_tac x=x in allE)
   334 apply auto
   335 done
   336 
   337 lemma mset_leD: "A \<le> B \<Longrightarrow> x \<in># A \<Longrightarrow> x \<in># B"
   338 apply (clarsimp simp: mset_le_def mset_less_def)
   339 apply (erule_tac x = x in allE)
   340 apply auto
   341 done
   342   
   343 lemma mset_less_insertD: "(A + {#x#} < B) \<Longrightarrow> (x \<in># B \<and> A < B)"
   344 apply (rule conjI)
   345  apply (simp add: mset_lessD)
   346 apply (clarsimp simp: mset_le_def mset_less_def)
   347 apply safe
   348  apply (erule_tac x = a in allE)
   349  apply (auto split: split_if_asm)
   350 done
   351 
   352 lemma mset_le_insertD: "(A + {#x#} \<le> B) \<Longrightarrow> (x \<in># B \<and> A \<le> B)"
   353 apply (rule conjI)
   354  apply (simp add: mset_leD)
   355 apply (force simp: mset_le_def mset_less_def split: split_if_asm)
   356 done
   357 
   358 lemma mset_less_of_empty[simp]: "A < {#} \<longleftrightarrow> False"
   359   by (auto simp add: mset_less_def mset_le_def multiset_eq_iff)
   360 
   361 lemma multi_psub_of_add_self[simp]: "A < A + {#x#}"
   362   by (auto simp: mset_le_def mset_less_def)
   363 
   364 lemma multi_psub_self[simp]: "(A::'a multiset) < A = False"
   365   by simp
   366 
   367 lemma mset_less_add_bothsides:
   368   "T + {#x#} < S + {#x#} \<Longrightarrow> T < S"
   369   by (fact add_less_imp_less_right)
   370 
   371 lemma mset_less_empty_nonempty:
   372   "{#} < S \<longleftrightarrow> S \<noteq> {#}"
   373   by (auto simp: mset_le_def mset_less_def)
   374 
   375 lemma mset_less_diff_self:
   376   "c \<in># B \<Longrightarrow> B - {#c#} < B"
   377   by (auto simp: mset_le_def mset_less_def multiset_eq_iff)
   378 
   379 
   380 subsubsection {* Intersection *}
   381 
   382 instantiation multiset :: (type) semilattice_inf
   383 begin
   384 
   385 definition inf_multiset :: "'a multiset \<Rightarrow> 'a multiset \<Rightarrow> 'a multiset" where
   386   multiset_inter_def: "inf_multiset A B = A - (A - B)"
   387 
   388 instance
   389 proof -
   390   have aux: "\<And>m n q :: nat. m \<le> n \<Longrightarrow> m \<le> q \<Longrightarrow> m \<le> n - (n - q)" by arith
   391   show "OFCLASS('a multiset, semilattice_inf_class)"
   392     by default (auto simp add: multiset_inter_def mset_le_def aux)
   393 qed
   394 
   395 end
   396 
   397 abbreviation multiset_inter :: "'a multiset \<Rightarrow> 'a multiset \<Rightarrow> 'a multiset" (infixl "#\<inter>" 70) where
   398   "multiset_inter \<equiv> inf"
   399 
   400 lemma multiset_inter_count [simp]:
   401   "count (A #\<inter> B) x = min (count A x) (count B x)"
   402   by (simp add: multiset_inter_def)
   403 
   404 lemma multiset_inter_single: "a \<noteq> b \<Longrightarrow> {#a#} #\<inter> {#b#} = {#}"
   405   by (rule multiset_eqI) auto
   406 
   407 lemma multiset_union_diff_commute:
   408   assumes "B #\<inter> C = {#}"
   409   shows "A + B - C = A - C + B"
   410 proof (rule multiset_eqI)
   411   fix x
   412   from assms have "min (count B x) (count C x) = 0"
   413     by (auto simp add: multiset_eq_iff)
   414   then have "count B x = 0 \<or> count C x = 0"
   415     by auto
   416   then show "count (A + B - C) x = count (A - C + B) x"
   417     by auto
   418 qed
   419 
   420 lemma empty_inter [simp]:
   421   "{#} #\<inter> M = {#}"
   422   by (simp add: multiset_eq_iff)
   423 
   424 lemma inter_empty [simp]:
   425   "M #\<inter> {#} = {#}"
   426   by (simp add: multiset_eq_iff)
   427 
   428 lemma inter_add_left1:
   429   "\<not> x \<in># N \<Longrightarrow> (M + {#x#}) #\<inter> N = M #\<inter> N"
   430   by (simp add: multiset_eq_iff)
   431 
   432 lemma inter_add_left2:
   433   "x \<in># N \<Longrightarrow> (M + {#x#}) #\<inter> N = (M #\<inter> (N - {#x#})) + {#x#}"
   434   by (simp add: multiset_eq_iff)
   435 
   436 lemma inter_add_right1:
   437   "\<not> x \<in># N \<Longrightarrow> N #\<inter> (M + {#x#}) = N #\<inter> M"
   438   by (simp add: multiset_eq_iff)
   439 
   440 lemma inter_add_right2:
   441   "x \<in># N \<Longrightarrow> N #\<inter> (M + {#x#}) = ((N - {#x#}) #\<inter> M) + {#x#}"
   442   by (simp add: multiset_eq_iff)
   443 
   444 
   445 subsubsection {* Bounded union *}
   446 
   447 instantiation multiset :: (type) semilattice_sup
   448 begin
   449 
   450 definition sup_multiset :: "'a multiset \<Rightarrow> 'a multiset \<Rightarrow> 'a multiset" where
   451   "sup_multiset A B = A + (B - A)"
   452 
   453 instance
   454 proof -
   455   have aux: "\<And>m n q :: nat. m \<le> n \<Longrightarrow> q \<le> n \<Longrightarrow> m + (q - m) \<le> n" by arith
   456   show "OFCLASS('a multiset, semilattice_sup_class)"
   457     by default (auto simp add: sup_multiset_def mset_le_def aux)
   458 qed
   459 
   460 end
   461 
   462 abbreviation sup_multiset :: "'a multiset \<Rightarrow> 'a multiset \<Rightarrow> 'a multiset" (infixl "#\<union>" 70) where
   463   "sup_multiset \<equiv> sup"
   464 
   465 lemma sup_multiset_count [simp]:
   466   "count (A #\<union> B) x = max (count A x) (count B x)"
   467   by (simp add: sup_multiset_def)
   468 
   469 lemma empty_sup [simp]:
   470   "{#} #\<union> M = M"
   471   by (simp add: multiset_eq_iff)
   472 
   473 lemma sup_empty [simp]:
   474   "M #\<union> {#} = M"
   475   by (simp add: multiset_eq_iff)
   476 
   477 lemma sup_add_left1:
   478   "\<not> x \<in># N \<Longrightarrow> (M + {#x#}) #\<union> N = (M #\<union> N) + {#x#}"
   479   by (simp add: multiset_eq_iff)
   480 
   481 lemma sup_add_left2:
   482   "x \<in># N \<Longrightarrow> (M + {#x#}) #\<union> N = (M #\<union> (N - {#x#})) + {#x#}"
   483   by (simp add: multiset_eq_iff)
   484 
   485 lemma sup_add_right1:
   486   "\<not> x \<in># N \<Longrightarrow> N #\<union> (M + {#x#}) = (N #\<union> M) + {#x#}"
   487   by (simp add: multiset_eq_iff)
   488 
   489 lemma sup_add_right2:
   490   "x \<in># N \<Longrightarrow> N #\<union> (M + {#x#}) = ((N - {#x#}) #\<union> M) + {#x#}"
   491   by (simp add: multiset_eq_iff)
   492 
   493 
   494 subsubsection {* Filter (with comprehension syntax) *}
   495 
   496 text {* Multiset comprehension *}
   497 
   498 lift_definition filter :: "('a \<Rightarrow> bool) \<Rightarrow> 'a multiset \<Rightarrow> 'a multiset" is "\<lambda>P M. \<lambda>x. if P x then M x else 0"
   499 by (rule filter_preserves_multiset)
   500 
   501 hide_const (open) filter
   502 
   503 lemma count_filter [simp]:
   504   "count (Multiset.filter P M) a = (if P a then count M a else 0)"
   505   by (simp add: filter.rep_eq)
   506 
   507 lemma filter_empty [simp]:
   508   "Multiset.filter P {#} = {#}"
   509   by (rule multiset_eqI) simp
   510 
   511 lemma filter_single [simp]:
   512   "Multiset.filter P {#x#} = (if P x then {#x#} else {#})"
   513   by (rule multiset_eqI) simp
   514 
   515 lemma filter_union [simp]:
   516   "Multiset.filter P (M + N) = Multiset.filter P M + Multiset.filter P N"
   517   by (rule multiset_eqI) simp
   518 
   519 lemma filter_diff [simp]:
   520   "Multiset.filter P (M - N) = Multiset.filter P M - Multiset.filter P N"
   521   by (rule multiset_eqI) simp
   522 
   523 lemma filter_inter [simp]:
   524   "Multiset.filter P (M #\<inter> N) = Multiset.filter P M #\<inter> Multiset.filter P N"
   525   by (rule multiset_eqI) simp
   526 
   527 syntax
   528   "_MCollect" :: "pttrn \<Rightarrow> 'a multiset \<Rightarrow> bool \<Rightarrow> 'a multiset"    ("(1{# _ :# _./ _#})")
   529 syntax (xsymbol)
   530   "_MCollect" :: "pttrn \<Rightarrow> 'a multiset \<Rightarrow> bool \<Rightarrow> 'a multiset"    ("(1{# _ \<in># _./ _#})")
   531 translations
   532   "{#x \<in># M. P#}" == "CONST Multiset.filter (\<lambda>x. P) M"
   533 
   534 
   535 subsubsection {* Set of elements *}
   536 
   537 definition set_of :: "'a multiset => 'a set" where
   538   "set_of M = {x. x :# M}"
   539 
   540 lemma set_of_empty [simp]: "set_of {#} = {}"
   541 by (simp add: set_of_def)
   542 
   543 lemma set_of_single [simp]: "set_of {#b#} = {b}"
   544 by (simp add: set_of_def)
   545 
   546 lemma set_of_union [simp]: "set_of (M + N) = set_of M \<union> set_of N"
   547 by (auto simp add: set_of_def)
   548 
   549 lemma set_of_eq_empty_iff [simp]: "(set_of M = {}) = (M = {#})"
   550 by (auto simp add: set_of_def multiset_eq_iff)
   551 
   552 lemma mem_set_of_iff [simp]: "(x \<in> set_of M) = (x :# M)"
   553 by (auto simp add: set_of_def)
   554 
   555 lemma set_of_filter [simp]: "set_of {# x:#M. P x #} = set_of M \<inter> {x. P x}"
   556 by (auto simp add: set_of_def)
   557 
   558 lemma finite_set_of [iff]: "finite (set_of M)"
   559   using count [of M] by (simp add: multiset_def set_of_def)
   560 
   561 lemma finite_Collect_mem [iff]: "finite {x. x :# M}"
   562   unfolding set_of_def[symmetric] by simp
   563 
   564 subsubsection {* Size *}
   565 
   566 instantiation multiset :: (type) size
   567 begin
   568 
   569 definition size_def:
   570   "size M = setsum (count M) (set_of M)"
   571 
   572 instance ..
   573 
   574 end
   575 
   576 lemma size_empty [simp]: "size {#} = 0"
   577 by (simp add: size_def)
   578 
   579 lemma size_single [simp]: "size {#b#} = 1"
   580 by (simp add: size_def)
   581 
   582 lemma setsum_count_Int:
   583   "finite A ==> setsum (count N) (A \<inter> set_of N) = setsum (count N) A"
   584 apply (induct rule: finite_induct)
   585  apply simp
   586 apply (simp add: Int_insert_left set_of_def)
   587 done
   588 
   589 lemma size_union [simp]: "size (M + N::'a multiset) = size M + size N"
   590 apply (unfold size_def)
   591 apply (subgoal_tac "count (M + N) = (\<lambda>a. count M a + count N a)")
   592  prefer 2
   593  apply (rule ext, simp)
   594 apply (simp (no_asm_simp) add: setsum_Un_nat setsum_addf setsum_count_Int)
   595 apply (subst Int_commute)
   596 apply (simp (no_asm_simp) add: setsum_count_Int)
   597 done
   598 
   599 lemma size_eq_0_iff_empty [iff]: "(size M = 0) = (M = {#})"
   600 by (auto simp add: size_def multiset_eq_iff)
   601 
   602 lemma nonempty_has_size: "(S \<noteq> {#}) = (0 < size S)"
   603 by (metis gr0I gr_implies_not0 size_empty size_eq_0_iff_empty)
   604 
   605 lemma size_eq_Suc_imp_elem: "size M = Suc n ==> \<exists>a. a :# M"
   606 apply (unfold size_def)
   607 apply (drule setsum_SucD)
   608 apply auto
   609 done
   610 
   611 lemma size_eq_Suc_imp_eq_union:
   612   assumes "size M = Suc n"
   613   shows "\<exists>a N. M = N + {#a#}"
   614 proof -
   615   from assms obtain a where "a \<in># M"
   616     by (erule size_eq_Suc_imp_elem [THEN exE])
   617   then have "M = M - {#a#} + {#a#}" by simp
   618   then show ?thesis by blast
   619 qed
   620 
   621 
   622 subsection {* Induction and case splits *}
   623 
   624 theorem multiset_induct [case_names empty add, induct type: multiset]:
   625   assumes empty: "P {#}"
   626   assumes add: "\<And>M x. P M \<Longrightarrow> P (M + {#x#})"
   627   shows "P M"
   628 proof (induct n \<equiv> "size M" arbitrary: M)
   629   case 0 thus "P M" by (simp add: empty)
   630 next
   631   case (Suc k)
   632   obtain N x where "M = N + {#x#}"
   633     using `Suc k = size M` [symmetric]
   634     using size_eq_Suc_imp_eq_union by fast
   635   with Suc add show "P M" by simp
   636 qed
   637 
   638 lemma multi_nonempty_split: "M \<noteq> {#} \<Longrightarrow> \<exists>A a. M = A + {#a#}"
   639 by (induct M) auto
   640 
   641 lemma multiset_cases [cases type, case_names empty add]:
   642 assumes em:  "M = {#} \<Longrightarrow> P"
   643 assumes add: "\<And>N x. M = N + {#x#} \<Longrightarrow> P"
   644 shows "P"
   645 using assms by (induct M) simp_all
   646 
   647 lemma multi_drop_mem_not_eq: "c \<in># B \<Longrightarrow> B - {#c#} \<noteq> B"
   648 by (cases "B = {#}") (auto dest: multi_member_split)
   649 
   650 lemma multiset_partition: "M = {# x:#M. P x #} + {# x:#M. \<not> P x #}"
   651 apply (subst multiset_eq_iff)
   652 apply auto
   653 done
   654 
   655 lemma mset_less_size: "(A::'a multiset) < B \<Longrightarrow> size A < size B"
   656 proof (induct A arbitrary: B)
   657   case (empty M)
   658   then have "M \<noteq> {#}" by (simp add: mset_less_empty_nonempty)
   659   then obtain M' x where "M = M' + {#x#}" 
   660     by (blast dest: multi_nonempty_split)
   661   then show ?case by simp
   662 next
   663   case (add S x T)
   664   have IH: "\<And>B. S < B \<Longrightarrow> size S < size B" by fact
   665   have SxsubT: "S + {#x#} < T" by fact
   666   then have "x \<in># T" and "S < T" by (auto dest: mset_less_insertD)
   667   then obtain T' where T: "T = T' + {#x#}" 
   668     by (blast dest: multi_member_split)
   669   then have "S < T'" using SxsubT 
   670     by (blast intro: mset_less_add_bothsides)
   671   then have "size S < size T'" using IH by simp
   672   then show ?case using T by simp
   673 qed
   674 
   675 
   676 subsubsection {* Strong induction and subset induction for multisets *}
   677 
   678 text {* Well-foundedness of proper subset operator: *}
   679 
   680 text {* proper multiset subset *}
   681 
   682 definition
   683   mset_less_rel :: "('a multiset * 'a multiset) set" where
   684   "mset_less_rel = {(A,B). A < B}"
   685 
   686 lemma multiset_add_sub_el_shuffle: 
   687   assumes "c \<in># B" and "b \<noteq> c" 
   688   shows "B - {#c#} + {#b#} = B + {#b#} - {#c#}"
   689 proof -
   690   from `c \<in># B` obtain A where B: "B = A + {#c#}" 
   691     by (blast dest: multi_member_split)
   692   have "A + {#b#} = A + {#b#} + {#c#} - {#c#}" by simp
   693   then have "A + {#b#} = A + {#c#} + {#b#} - {#c#}" 
   694     by (simp add: add_ac)
   695   then show ?thesis using B by simp
   696 qed
   697 
   698 lemma wf_mset_less_rel: "wf mset_less_rel"
   699 apply (unfold mset_less_rel_def)
   700 apply (rule wf_measure [THEN wf_subset, where f1=size])
   701 apply (clarsimp simp: measure_def inv_image_def mset_less_size)
   702 done
   703 
   704 text {* The induction rules: *}
   705 
   706 lemma full_multiset_induct [case_names less]:
   707 assumes ih: "\<And>B. \<forall>(A::'a multiset). A < B \<longrightarrow> P A \<Longrightarrow> P B"
   708 shows "P B"
   709 apply (rule wf_mset_less_rel [THEN wf_induct])
   710 apply (rule ih, auto simp: mset_less_rel_def)
   711 done
   712 
   713 lemma multi_subset_induct [consumes 2, case_names empty add]:
   714 assumes "F \<le> A"
   715   and empty: "P {#}"
   716   and insert: "\<And>a F. a \<in># A \<Longrightarrow> P F \<Longrightarrow> P (F + {#a#})"
   717 shows "P F"
   718 proof -
   719   from `F \<le> A`
   720   show ?thesis
   721   proof (induct F)
   722     show "P {#}" by fact
   723   next
   724     fix x F
   725     assume P: "F \<le> A \<Longrightarrow> P F" and i: "F + {#x#} \<le> A"
   726     show "P (F + {#x#})"
   727     proof (rule insert)
   728       from i show "x \<in># A" by (auto dest: mset_le_insertD)
   729       from i have "F \<le> A" by (auto dest: mset_le_insertD)
   730       with P show "P F" .
   731     qed
   732   qed
   733 qed
   734 
   735 
   736 subsection {* The fold combinator *}
   737 
   738 definition fold :: "('a \<Rightarrow> 'b \<Rightarrow> 'b) \<Rightarrow> 'b \<Rightarrow> 'a multiset \<Rightarrow> 'b"
   739 where
   740   "fold f s M = Finite_Set.fold (\<lambda>x. f x ^^ count M x) s (set_of M)"
   741 
   742 lemma fold_mset_empty [simp]:
   743   "fold f s {#} = s"
   744   by (simp add: fold_def)
   745 
   746 context comp_fun_commute
   747 begin
   748 
   749 lemma fold_mset_insert:
   750   "fold f s (M + {#x#}) = f x (fold f s M)"
   751 proof -
   752   interpret mset: comp_fun_commute "\<lambda>y. f y ^^ count M y"
   753     by (fact comp_fun_commute_funpow)
   754   interpret mset_union: comp_fun_commute "\<lambda>y. f y ^^ count (M + {#x#}) y"
   755     by (fact comp_fun_commute_funpow)
   756   show ?thesis
   757   proof (cases "x \<in> set_of M")
   758     case False
   759     then have *: "count (M + {#x#}) x = 1" by simp
   760     from False have "Finite_Set.fold (\<lambda>y. f y ^^ count (M + {#x#}) y) s (set_of M) =
   761       Finite_Set.fold (\<lambda>y. f y ^^ count M y) s (set_of M)"
   762       by (auto intro!: Finite_Set.fold_cong comp_fun_commute_funpow)
   763     with False * show ?thesis
   764       by (simp add: fold_def del: count_union)
   765   next
   766     case True
   767     def N \<equiv> "set_of M - {x}"
   768     from N_def True have *: "set_of M = insert x N" "x \<notin> N" "finite N" by auto
   769     then have "Finite_Set.fold (\<lambda>y. f y ^^ count (M + {#x#}) y) s N =
   770       Finite_Set.fold (\<lambda>y. f y ^^ count M y) s N"
   771       by (auto intro!: Finite_Set.fold_cong comp_fun_commute_funpow)
   772     with * show ?thesis by (simp add: fold_def del: count_union) simp
   773   qed
   774 qed
   775 
   776 corollary fold_mset_single [simp]:
   777   "fold f s {#x#} = f x s"
   778 proof -
   779   have "fold f s ({#} + {#x#}) = f x s" by (simp only: fold_mset_insert) simp
   780   then show ?thesis by simp
   781 qed
   782 
   783 lemma fold_mset_fun_left_comm:
   784   "f x (fold f s M) = fold f (f x s) M"
   785   by (induct M) (simp_all add: fold_mset_insert fun_left_comm)
   786 
   787 lemma fold_mset_union [simp]:
   788   "fold f s (M + N) = fold f (fold f s M) N"
   789 proof (induct M)
   790   case empty then show ?case by simp
   791 next
   792   case (add M x)
   793   have "M + {#x#} + N = (M + N) + {#x#}"
   794     by (simp add: add_ac)
   795   with add show ?case by (simp add: fold_mset_insert fold_mset_fun_left_comm)
   796 qed
   797 
   798 lemma fold_mset_fusion:
   799   assumes "comp_fun_commute g"
   800   shows "(\<And>x y. h (g x y) = f x (h y)) \<Longrightarrow> h (fold g w A) = fold f (h w) A" (is "PROP ?P")
   801 proof -
   802   interpret comp_fun_commute g by (fact assms)
   803   show "PROP ?P" by (induct A) auto
   804 qed
   805 
   806 end
   807 
   808 text {*
   809   A note on code generation: When defining some function containing a
   810   subterm @{term "fold F"}, code generation is not automatic. When
   811   interpreting locale @{text left_commutative} with @{text F}, the
   812   would be code thms for @{const fold} become thms like
   813   @{term "fold F z {#} = z"} where @{text F} is not a pattern but
   814   contains defined symbols, i.e.\ is not a code thm. Hence a separate
   815   constant with its own code thms needs to be introduced for @{text
   816   F}. See the image operator below.
   817 *}
   818 
   819 
   820 subsection {* Image *}
   821 
   822 definition image_mset :: "('a \<Rightarrow> 'b) \<Rightarrow> 'a multiset \<Rightarrow> 'b multiset" where
   823   "image_mset f = fold (plus o single o f) {#}"
   824 
   825 lemma comp_fun_commute_mset_image:
   826   "comp_fun_commute (plus o single o f)"
   827 proof
   828 qed (simp add: add_ac fun_eq_iff)
   829 
   830 lemma image_mset_empty [simp]: "image_mset f {#} = {#}"
   831   by (simp add: image_mset_def)
   832 
   833 lemma image_mset_single [simp]: "image_mset f {#x#} = {#f x#}"
   834 proof -
   835   interpret comp_fun_commute "plus o single o f"
   836     by (fact comp_fun_commute_mset_image)
   837   show ?thesis by (simp add: image_mset_def)
   838 qed
   839 
   840 lemma image_mset_union [simp]:
   841   "image_mset f (M + N) = image_mset f M + image_mset f N"
   842 proof -
   843   interpret comp_fun_commute "plus o single o f"
   844     by (fact comp_fun_commute_mset_image)
   845   show ?thesis by (induct N) (simp_all add: image_mset_def add_ac)
   846 qed
   847 
   848 corollary image_mset_insert:
   849   "image_mset f (M + {#a#}) = image_mset f M + {#f a#}"
   850   by simp
   851 
   852 lemma set_of_image_mset [simp]:
   853   "set_of (image_mset f M) = image f (set_of M)"
   854   by (induct M) simp_all
   855 
   856 lemma size_image_mset [simp]:
   857   "size (image_mset f M) = size M"
   858   by (induct M) simp_all
   859 
   860 lemma image_mset_is_empty_iff [simp]:
   861   "image_mset f M = {#} \<longleftrightarrow> M = {#}"
   862   by (cases M) auto
   863 
   864 syntax
   865   "_comprehension1_mset" :: "'a \<Rightarrow> 'b \<Rightarrow> 'b multiset \<Rightarrow> 'a multiset"
   866       ("({#_/. _ :# _#})")
   867 translations
   868   "{#e. x:#M#}" == "CONST image_mset (%x. e) M"
   869 
   870 syntax
   871   "_comprehension2_mset" :: "'a \<Rightarrow> 'b \<Rightarrow> 'b multiset \<Rightarrow> bool \<Rightarrow> 'a multiset"
   872       ("({#_/ | _ :# _./ _#})")
   873 translations
   874   "{#e | x:#M. P#}" => "{#e. x :# {# x:#M. P#}#}"
   875 
   876 text {*
   877   This allows to write not just filters like @{term "{#x:#M. x<c#}"}
   878   but also images like @{term "{#x+x. x:#M #}"} and @{term [source]
   879   "{#x+x|x:#M. x<c#}"}, where the latter is currently displayed as
   880   @{term "{#x+x|x:#M. x<c#}"}.
   881 *}
   882 
   883 enriched_type image_mset: image_mset
   884 proof -
   885   fix f g show "image_mset f \<circ> image_mset g = image_mset (f \<circ> g)"
   886   proof
   887     fix A
   888     show "(image_mset f \<circ> image_mset g) A = image_mset (f \<circ> g) A"
   889       by (induct A) simp_all
   890   qed
   891   show "image_mset id = id"
   892   proof
   893     fix A
   894     show "image_mset id A = id A"
   895       by (induct A) simp_all
   896   qed
   897 qed
   898 
   899 declare image_mset.identity [simp]
   900 
   901 
   902 subsection {* Further conversions *}
   903 
   904 primrec multiset_of :: "'a list \<Rightarrow> 'a multiset" where
   905   "multiset_of [] = {#}" |
   906   "multiset_of (a # x) = multiset_of x + {# a #}"
   907 
   908 lemma in_multiset_in_set:
   909   "x \<in># multiset_of xs \<longleftrightarrow> x \<in> set xs"
   910   by (induct xs) simp_all
   911 
   912 lemma count_multiset_of:
   913   "count (multiset_of xs) x = length (filter (\<lambda>y. x = y) xs)"
   914   by (induct xs) simp_all
   915 
   916 lemma multiset_of_zero_iff[simp]: "(multiset_of x = {#}) = (x = [])"
   917 by (induct x) auto
   918 
   919 lemma multiset_of_zero_iff_right[simp]: "({#} = multiset_of x) = (x = [])"
   920 by (induct x) auto
   921 
   922 lemma set_of_multiset_of[simp]: "set_of (multiset_of x) = set x"
   923 by (induct x) auto
   924 
   925 lemma mem_set_multiset_eq: "x \<in> set xs = (x :# multiset_of xs)"
   926 by (induct xs) auto
   927 
   928 lemma size_multiset_of [simp]: "size (multiset_of xs) = length xs"
   929   by (induct xs) simp_all
   930 
   931 lemma multiset_of_append [simp]:
   932   "multiset_of (xs @ ys) = multiset_of xs + multiset_of ys"
   933   by (induct xs arbitrary: ys) (auto simp: add_ac)
   934 
   935 lemma multiset_of_filter:
   936   "multiset_of (filter P xs) = {#x :# multiset_of xs. P x #}"
   937   by (induct xs) simp_all
   938 
   939 lemma multiset_of_rev [simp]:
   940   "multiset_of (rev xs) = multiset_of xs"
   941   by (induct xs) simp_all
   942 
   943 lemma surj_multiset_of: "surj multiset_of"
   944 apply (unfold surj_def)
   945 apply (rule allI)
   946 apply (rule_tac M = y in multiset_induct)
   947  apply auto
   948 apply (rule_tac x = "x # xa" in exI)
   949 apply auto
   950 done
   951 
   952 lemma set_count_greater_0: "set x = {a. count (multiset_of x) a > 0}"
   953 by (induct x) auto
   954 
   955 lemma distinct_count_atmost_1:
   956   "distinct x = (! a. count (multiset_of x) a = (if a \<in> set x then 1 else 0))"
   957 apply (induct x, simp, rule iffI, simp_all)
   958 apply (rule conjI)
   959 apply (simp_all add: set_of_multiset_of [THEN sym] del: set_of_multiset_of)
   960 apply (erule_tac x = a in allE, simp, clarify)
   961 apply (erule_tac x = aa in allE, simp)
   962 done
   963 
   964 lemma multiset_of_eq_setD:
   965   "multiset_of xs = multiset_of ys \<Longrightarrow> set xs = set ys"
   966 by (rule) (auto simp add:multiset_eq_iff set_count_greater_0)
   967 
   968 lemma set_eq_iff_multiset_of_eq_distinct:
   969   "distinct x \<Longrightarrow> distinct y \<Longrightarrow>
   970     (set x = set y) = (multiset_of x = multiset_of y)"
   971 by (auto simp: multiset_eq_iff distinct_count_atmost_1)
   972 
   973 lemma set_eq_iff_multiset_of_remdups_eq:
   974    "(set x = set y) = (multiset_of (remdups x) = multiset_of (remdups y))"
   975 apply (rule iffI)
   976 apply (simp add: set_eq_iff_multiset_of_eq_distinct[THEN iffD1])
   977 apply (drule distinct_remdups [THEN distinct_remdups
   978       [THEN set_eq_iff_multiset_of_eq_distinct [THEN iffD2]]])
   979 apply simp
   980 done
   981 
   982 lemma multiset_of_compl_union [simp]:
   983   "multiset_of [x\<leftarrow>xs. P x] + multiset_of [x\<leftarrow>xs. \<not>P x] = multiset_of xs"
   984   by (induct xs) (auto simp: add_ac)
   985 
   986 lemma count_multiset_of_length_filter:
   987   "count (multiset_of xs) x = length (filter (\<lambda>y. x = y) xs)"
   988   by (induct xs) auto
   989 
   990 lemma nth_mem_multiset_of: "i < length ls \<Longrightarrow> (ls ! i) :# multiset_of ls"
   991 apply (induct ls arbitrary: i)
   992  apply simp
   993 apply (case_tac i)
   994  apply auto
   995 done
   996 
   997 lemma multiset_of_remove1[simp]:
   998   "multiset_of (remove1 a xs) = multiset_of xs - {#a#}"
   999 by (induct xs) (auto simp add: multiset_eq_iff)
  1000 
  1001 lemma multiset_of_eq_length:
  1002   assumes "multiset_of xs = multiset_of ys"
  1003   shows "length xs = length ys"
  1004   using assms by (metis size_multiset_of)
  1005 
  1006 lemma multiset_of_eq_length_filter:
  1007   assumes "multiset_of xs = multiset_of ys"
  1008   shows "length (filter (\<lambda>x. z = x) xs) = length (filter (\<lambda>y. z = y) ys)"
  1009   using assms by (metis count_multiset_of)
  1010 
  1011 lemma fold_multiset_equiv:
  1012   assumes f: "\<And>x y. x \<in> set xs \<Longrightarrow> y \<in> set xs \<Longrightarrow> f x \<circ> f y = f y \<circ> f x"
  1013     and equiv: "multiset_of xs = multiset_of ys"
  1014   shows "List.fold f xs = List.fold f ys"
  1015 using f equiv [symmetric]
  1016 proof (induct xs arbitrary: ys)
  1017   case Nil then show ?case by simp
  1018 next
  1019   case (Cons x xs)
  1020   then have *: "set ys = set (x # xs)" by (blast dest: multiset_of_eq_setD)
  1021   have "\<And>x y. x \<in> set ys \<Longrightarrow> y \<in> set ys \<Longrightarrow> f x \<circ> f y = f y \<circ> f x" 
  1022     by (rule Cons.prems(1)) (simp_all add: *)
  1023   moreover from * have "x \<in> set ys" by simp
  1024   ultimately have "List.fold f ys = List.fold f (remove1 x ys) \<circ> f x" by (fact fold_remove1_split)
  1025   moreover from Cons.prems have "List.fold f xs = List.fold f (remove1 x ys)" by (auto intro: Cons.hyps)
  1026   ultimately show ?case by simp
  1027 qed
  1028 
  1029 lemma multiset_of_insort [simp]:
  1030   "multiset_of (insort x xs) = multiset_of xs + {#x#}"
  1031   by (induct xs) (simp_all add: ac_simps)
  1032 
  1033 lemma in_multiset_of:
  1034   "x \<in># multiset_of xs \<longleftrightarrow> x \<in> set xs"
  1035   by (induct xs) simp_all
  1036 
  1037 lemma multiset_of_map:
  1038   "multiset_of (map f xs) = image_mset f (multiset_of xs)"
  1039   by (induct xs) simp_all
  1040 
  1041 definition multiset_of_set :: "'a set \<Rightarrow> 'a multiset"
  1042 where
  1043   "multiset_of_set = folding.F (\<lambda>x M. {#x#} + M) {#}"
  1044 
  1045 interpretation multiset_of_set!: folding "\<lambda>x M. {#x#} + M" "{#}"
  1046 where
  1047   "folding.F (\<lambda>x M. {#x#} + M) {#} = multiset_of_set"
  1048 proof -
  1049   interpret comp_fun_commute "\<lambda>x M. {#x#} + M" by default (simp add: fun_eq_iff ac_simps)
  1050   show "folding (\<lambda>x M. {#x#} + M)" by default (fact comp_fun_commute)
  1051   from multiset_of_set_def show "folding.F (\<lambda>x M. {#x#} + M) {#} = multiset_of_set" ..
  1052 qed
  1053 
  1054 lemma count_multiset_of_set [simp]:
  1055   "finite A \<Longrightarrow> x \<in> A \<Longrightarrow> count (multiset_of_set A) x = 1" (is "PROP ?P")
  1056   "\<not> finite A \<Longrightarrow> count (multiset_of_set A) x = 0" (is "PROP ?Q")
  1057   "x \<notin> A \<Longrightarrow> count (multiset_of_set A) x = 0" (is "PROP ?R")
  1058 proof -
  1059   { fix A
  1060     assume "x \<notin> A"
  1061     have "count (multiset_of_set A) x = 0"
  1062     proof (cases "finite A")
  1063       case False then show ?thesis by simp
  1064     next
  1065       case True from True `x \<notin> A` show ?thesis by (induct A) auto
  1066     qed
  1067   } note * = this
  1068   then show "PROP ?P" "PROP ?Q" "PROP ?R"
  1069   by (auto elim!: Set.set_insert)
  1070 qed -- {* TODO: maybe define @{const multiset_of_set} also in terms of @{const Abs_multiset} *}
  1071 
  1072 context linorder
  1073 begin
  1074 
  1075 definition sorted_list_of_multiset :: "'a multiset \<Rightarrow> 'a list"
  1076 where
  1077   "sorted_list_of_multiset M = fold insort [] M"
  1078 
  1079 lemma sorted_list_of_multiset_empty [simp]:
  1080   "sorted_list_of_multiset {#} = []"
  1081   by (simp add: sorted_list_of_multiset_def)
  1082 
  1083 lemma sorted_list_of_multiset_singleton [simp]:
  1084   "sorted_list_of_multiset {#x#} = [x]"
  1085 proof -
  1086   interpret comp_fun_commute insort by (fact comp_fun_commute_insort)
  1087   show ?thesis by (simp add: sorted_list_of_multiset_def)
  1088 qed
  1089 
  1090 lemma sorted_list_of_multiset_insert [simp]:
  1091   "sorted_list_of_multiset (M + {#x#}) = List.insort x (sorted_list_of_multiset M)"
  1092 proof -
  1093   interpret comp_fun_commute insort by (fact comp_fun_commute_insort)
  1094   show ?thesis by (simp add: sorted_list_of_multiset_def)
  1095 qed
  1096 
  1097 end
  1098 
  1099 lemma multiset_of_sorted_list_of_multiset [simp]:
  1100   "multiset_of (sorted_list_of_multiset M) = M"
  1101   by (induct M) simp_all
  1102 
  1103 lemma sorted_list_of_multiset_multiset_of [simp]:
  1104   "sorted_list_of_multiset (multiset_of xs) = sort xs"
  1105   by (induct xs) simp_all
  1106 
  1107 lemma finite_set_of_multiset_of_set:
  1108   assumes "finite A"
  1109   shows "set_of (multiset_of_set A) = A"
  1110   using assms by (induct A) simp_all
  1111 
  1112 lemma infinite_set_of_multiset_of_set:
  1113   assumes "\<not> finite A"
  1114   shows "set_of (multiset_of_set A) = {}"
  1115   using assms by simp
  1116 
  1117 lemma set_sorted_list_of_multiset [simp]:
  1118   "set (sorted_list_of_multiset M) = set_of M"
  1119   by (induct M) (simp_all add: set_insort)
  1120 
  1121 lemma sorted_list_of_multiset_of_set [simp]:
  1122   "sorted_list_of_multiset (multiset_of_set A) = sorted_list_of_set A"
  1123   by (cases "finite A") (induct A rule: finite_induct, simp_all add: ac_simps)
  1124 
  1125 
  1126 subsection {* Big operators *}
  1127 
  1128 no_notation times (infixl "*" 70)
  1129 no_notation Groups.one ("1")
  1130 
  1131 locale comm_monoid_mset = comm_monoid
  1132 begin
  1133 
  1134 definition F :: "'a multiset \<Rightarrow> 'a"
  1135 where
  1136   eq_fold: "F M = Multiset.fold f 1 M"
  1137 
  1138 lemma empty [simp]:
  1139   "F {#} = 1"
  1140   by (simp add: eq_fold)
  1141 
  1142 lemma singleton [simp]:
  1143   "F {#x#} = x"
  1144 proof -
  1145   interpret comp_fun_commute
  1146     by default (simp add: fun_eq_iff left_commute)
  1147   show ?thesis by (simp add: eq_fold)
  1148 qed
  1149 
  1150 lemma union [simp]:
  1151   "F (M + N) = F M * F N"
  1152 proof -
  1153   interpret comp_fun_commute f
  1154     by default (simp add: fun_eq_iff left_commute)
  1155   show ?thesis by (induct N) (simp_all add: left_commute eq_fold)
  1156 qed
  1157 
  1158 end
  1159 
  1160 notation times (infixl "*" 70)
  1161 notation Groups.one ("1")
  1162 
  1163 context comm_monoid_add
  1164 begin
  1165 
  1166 definition msetsum :: "'a multiset \<Rightarrow> 'a"
  1167 where
  1168   "msetsum = comm_monoid_mset.F plus 0"
  1169 
  1170 sublocale msetsum!: comm_monoid_mset plus 0
  1171 where
  1172   "comm_monoid_mset.F plus 0 = msetsum"
  1173 proof -
  1174   show "comm_monoid_mset plus 0" ..
  1175   from msetsum_def show "comm_monoid_mset.F plus 0 = msetsum" ..
  1176 qed
  1177 
  1178 lemma setsum_unfold_msetsum:
  1179   "setsum f A = msetsum (image_mset f (multiset_of_set A))"
  1180   by (cases "finite A") (induct A rule: finite_induct, simp_all)
  1181 
  1182 abbreviation msetsum_image :: "('b \<Rightarrow> 'a) \<Rightarrow> 'b multiset \<Rightarrow> 'a"
  1183 where
  1184   "msetsum_image f M \<equiv> msetsum (image_mset f M)"
  1185 
  1186 end
  1187 
  1188 syntax
  1189   "_msetsum_image" :: "pttrn \<Rightarrow> 'b set \<Rightarrow> 'a \<Rightarrow> 'a::comm_monoid_add" 
  1190       ("(3SUM _:#_. _)" [0, 51, 10] 10)
  1191 
  1192 syntax (xsymbols)
  1193   "_msetsum_image" :: "pttrn \<Rightarrow> 'b set \<Rightarrow> 'a \<Rightarrow> 'a::comm_monoid_add" 
  1194       ("(3\<Sum>_:#_. _)" [0, 51, 10] 10)
  1195 
  1196 syntax (HTML output)
  1197   "_msetsum_image" :: "pttrn \<Rightarrow> 'b set \<Rightarrow> 'a \<Rightarrow> 'a::comm_monoid_add" 
  1198       ("(3\<Sum>_\<in>#_. _)" [0, 51, 10] 10)
  1199 
  1200 translations
  1201   "SUM i :# A. b" == "CONST msetsum_image (\<lambda>i. b) A"
  1202 
  1203 context comm_monoid_mult
  1204 begin
  1205 
  1206 definition msetprod :: "'a multiset \<Rightarrow> 'a"
  1207 where
  1208   "msetprod = comm_monoid_mset.F times 1"
  1209 
  1210 sublocale msetprod!: comm_monoid_mset times 1
  1211 where
  1212   "comm_monoid_mset.F times 1 = msetprod"
  1213 proof -
  1214   show "comm_monoid_mset times 1" ..
  1215   from msetprod_def show "comm_monoid_mset.F times 1 = msetprod" ..
  1216 qed
  1217 
  1218 lemma msetprod_empty:
  1219   "msetprod {#} = 1"
  1220   by (fact msetprod.empty)
  1221 
  1222 lemma msetprod_singleton:
  1223   "msetprod {#x#} = x"
  1224   by (fact msetprod.singleton)
  1225 
  1226 lemma msetprod_Un:
  1227   "msetprod (A + B) = msetprod A * msetprod B" 
  1228   by (fact msetprod.union)
  1229 
  1230 lemma setprod_unfold_msetprod:
  1231   "setprod f A = msetprod (image_mset f (multiset_of_set A))"
  1232   by (cases "finite A") (induct A rule: finite_induct, simp_all)
  1233 
  1234 lemma msetprod_multiplicity:
  1235   "msetprod M = setprod (\<lambda>x. x ^ count M x) (set_of M)"
  1236   by (simp add: Multiset.fold_def setprod.eq_fold msetprod.eq_fold funpow_times_power comp_def)
  1237 
  1238 abbreviation msetprod_image :: "('b \<Rightarrow> 'a) \<Rightarrow> 'b multiset \<Rightarrow> 'a"
  1239 where
  1240   "msetprod_image f M \<equiv> msetprod (image_mset f M)"
  1241 
  1242 end
  1243 
  1244 syntax
  1245   "_msetprod_image" :: "pttrn \<Rightarrow> 'b set \<Rightarrow> 'a \<Rightarrow> 'a::comm_monoid_mult" 
  1246       ("(3PROD _:#_. _)" [0, 51, 10] 10)
  1247 
  1248 syntax (xsymbols)
  1249   "_msetprod_image" :: "pttrn \<Rightarrow> 'b set \<Rightarrow> 'a \<Rightarrow> 'a::comm_monoid_mult" 
  1250       ("(3\<Prod>_\<in>#_. _)" [0, 51, 10] 10)
  1251 
  1252 syntax (HTML output)
  1253   "_msetprod_image" :: "pttrn \<Rightarrow> 'b set \<Rightarrow> 'a \<Rightarrow> 'a::comm_monoid_mult" 
  1254       ("(3\<Prod>_\<in>#_. _)" [0, 51, 10] 10)
  1255 
  1256 translations
  1257   "PROD i :# A. b" == "CONST msetprod_image (\<lambda>i. b) A"
  1258 
  1259 lemma (in comm_semiring_1) dvd_msetprod:
  1260   assumes "x \<in># A"
  1261   shows "x dvd msetprod A"
  1262 proof -
  1263   from assms have "A = (A - {#x#}) + {#x#}" by simp
  1264   then obtain B where "A = B + {#x#}" ..
  1265   then show ?thesis by simp
  1266 qed
  1267 
  1268 
  1269 subsection {* Cardinality *}
  1270 
  1271 definition mcard :: "'a multiset \<Rightarrow> nat"
  1272 where
  1273   "mcard = msetsum \<circ> image_mset (\<lambda>_. 1)"
  1274 
  1275 lemma mcard_empty [simp]:
  1276   "mcard {#} = 0"
  1277   by (simp add: mcard_def)
  1278 
  1279 lemma mcard_singleton [simp]:
  1280   "mcard {#a#} = Suc 0"
  1281   by (simp add: mcard_def)
  1282 
  1283 lemma mcard_plus [simp]:
  1284   "mcard (M + N) = mcard M + mcard N"
  1285   by (simp add: mcard_def)
  1286 
  1287 lemma mcard_empty_iff [simp]:
  1288   "mcard M = 0 \<longleftrightarrow> M = {#}"
  1289   by (induct M) simp_all
  1290 
  1291 lemma mcard_unfold_setsum:
  1292   "mcard M = setsum (count M) (set_of M)"
  1293 proof (induct M)
  1294   case empty then show ?case by simp
  1295 next
  1296   case (add M x) then show ?case
  1297     by (cases "x \<in> set_of M")
  1298       (simp_all del: mem_set_of_iff add: setsum.distrib setsum.delta' insert_absorb, simp)
  1299 qed
  1300 
  1301 lemma size_eq_mcard:
  1302   "size = mcard"
  1303   by (simp add: fun_eq_iff size_def mcard_unfold_setsum)
  1304 
  1305 lemma mcard_multiset_of:
  1306   "mcard (multiset_of xs) = length xs"
  1307   by (induct xs) simp_all
  1308 
  1309 
  1310 subsection {* Alternative representations *}
  1311 
  1312 subsubsection {* Lists *}
  1313 
  1314 context linorder
  1315 begin
  1316 
  1317 lemma multiset_of_insort [simp]:
  1318   "multiset_of (insort_key k x xs) = {#x#} + multiset_of xs"
  1319   by (induct xs) (simp_all add: ac_simps)
  1320  
  1321 lemma multiset_of_sort [simp]:
  1322   "multiset_of (sort_key k xs) = multiset_of xs"
  1323   by (induct xs) (simp_all add: ac_simps)
  1324 
  1325 text {*
  1326   This lemma shows which properties suffice to show that a function
  1327   @{text "f"} with @{text "f xs = ys"} behaves like sort.
  1328 *}
  1329 
  1330 lemma properties_for_sort_key:
  1331   assumes "multiset_of ys = multiset_of xs"
  1332   and "\<And>k. k \<in> set ys \<Longrightarrow> filter (\<lambda>x. f k = f x) ys = filter (\<lambda>x. f k = f x) xs"
  1333   and "sorted (map f ys)"
  1334   shows "sort_key f xs = ys"
  1335 using assms
  1336 proof (induct xs arbitrary: ys)
  1337   case Nil then show ?case by simp
  1338 next
  1339   case (Cons x xs)
  1340   from Cons.prems(2) have
  1341     "\<forall>k \<in> set ys. filter (\<lambda>x. f k = f x) (remove1 x ys) = filter (\<lambda>x. f k = f x) xs"
  1342     by (simp add: filter_remove1)
  1343   with Cons.prems have "sort_key f xs = remove1 x ys"
  1344     by (auto intro!: Cons.hyps simp add: sorted_map_remove1)
  1345   moreover from Cons.prems have "x \<in> set ys"
  1346     by (auto simp add: mem_set_multiset_eq intro!: ccontr)
  1347   ultimately show ?case using Cons.prems by (simp add: insort_key_remove1)
  1348 qed
  1349 
  1350 lemma properties_for_sort:
  1351   assumes multiset: "multiset_of ys = multiset_of xs"
  1352   and "sorted ys"
  1353   shows "sort xs = ys"
  1354 proof (rule properties_for_sort_key)
  1355   from multiset show "multiset_of ys = multiset_of xs" .
  1356   from `sorted ys` show "sorted (map (\<lambda>x. x) ys)" by simp
  1357   from multiset have "\<And>k. length (filter (\<lambda>y. k = y) ys) = length (filter (\<lambda>x. k = x) xs)"
  1358     by (rule multiset_of_eq_length_filter)
  1359   then have "\<And>k. replicate (length (filter (\<lambda>y. k = y) ys)) k = replicate (length (filter (\<lambda>x. k = x) xs)) k"
  1360     by simp
  1361   then show "\<And>k. k \<in> set ys \<Longrightarrow> filter (\<lambda>y. k = y) ys = filter (\<lambda>x. k = x) xs"
  1362     by (simp add: replicate_length_filter)
  1363 qed
  1364 
  1365 lemma sort_key_by_quicksort:
  1366   "sort_key f xs = sort_key f [x\<leftarrow>xs. f x < f (xs ! (length xs div 2))]
  1367     @ [x\<leftarrow>xs. f x = f (xs ! (length xs div 2))]
  1368     @ sort_key f [x\<leftarrow>xs. f x > f (xs ! (length xs div 2))]" (is "sort_key f ?lhs = ?rhs")
  1369 proof (rule properties_for_sort_key)
  1370   show "multiset_of ?rhs = multiset_of ?lhs"
  1371     by (rule multiset_eqI) (auto simp add: multiset_of_filter)
  1372 next
  1373   show "sorted (map f ?rhs)"
  1374     by (auto simp add: sorted_append intro: sorted_map_same)
  1375 next
  1376   fix l
  1377   assume "l \<in> set ?rhs"
  1378   let ?pivot = "f (xs ! (length xs div 2))"
  1379   have *: "\<And>x. f l = f x \<longleftrightarrow> f x = f l" by auto
  1380   have "[x \<leftarrow> sort_key f xs . f x = f l] = [x \<leftarrow> xs. f x = f l]"
  1381     unfolding filter_sort by (rule properties_for_sort_key) (auto intro: sorted_map_same)
  1382   with * have **: "[x \<leftarrow> sort_key f xs . f l = f x] = [x \<leftarrow> xs. f l = f x]" by simp
  1383   have "\<And>x P. P (f x) ?pivot \<and> f l = f x \<longleftrightarrow> P (f l) ?pivot \<and> f l = f x" by auto
  1384   then have "\<And>P. [x \<leftarrow> sort_key f xs . P (f x) ?pivot \<and> f l = f x] =
  1385     [x \<leftarrow> sort_key f xs. P (f l) ?pivot \<and> f l = f x]" by simp
  1386   note *** = this [of "op <"] this [of "op >"] this [of "op ="]
  1387   show "[x \<leftarrow> ?rhs. f l = f x] = [x \<leftarrow> ?lhs. f l = f x]"
  1388   proof (cases "f l" ?pivot rule: linorder_cases)
  1389     case less
  1390     then have "f l \<noteq> ?pivot" and "\<not> f l > ?pivot" by auto
  1391     with less show ?thesis
  1392       by (simp add: filter_sort [symmetric] ** ***)
  1393   next
  1394     case equal then show ?thesis
  1395       by (simp add: * less_le)
  1396   next
  1397     case greater
  1398     then have "f l \<noteq> ?pivot" and "\<not> f l < ?pivot" by auto
  1399     with greater show ?thesis
  1400       by (simp add: filter_sort [symmetric] ** ***)
  1401   qed
  1402 qed
  1403 
  1404 lemma sort_by_quicksort:
  1405   "sort xs = sort [x\<leftarrow>xs. x < xs ! (length xs div 2)]
  1406     @ [x\<leftarrow>xs. x = xs ! (length xs div 2)]
  1407     @ sort [x\<leftarrow>xs. x > xs ! (length xs div 2)]" (is "sort ?lhs = ?rhs")
  1408   using sort_key_by_quicksort [of "\<lambda>x. x", symmetric] by simp
  1409 
  1410 text {* A stable parametrized quicksort *}
  1411 
  1412 definition part :: "('b \<Rightarrow> 'a) \<Rightarrow> 'a \<Rightarrow> 'b list \<Rightarrow> 'b list \<times> 'b list \<times> 'b list" where
  1413   "part f pivot xs = ([x \<leftarrow> xs. f x < pivot], [x \<leftarrow> xs. f x = pivot], [x \<leftarrow> xs. pivot < f x])"
  1414 
  1415 lemma part_code [code]:
  1416   "part f pivot [] = ([], [], [])"
  1417   "part f pivot (x # xs) = (let (lts, eqs, gts) = part f pivot xs; x' = f x in
  1418      if x' < pivot then (x # lts, eqs, gts)
  1419      else if x' > pivot then (lts, eqs, x # gts)
  1420      else (lts, x # eqs, gts))"
  1421   by (auto simp add: part_def Let_def split_def)
  1422 
  1423 lemma sort_key_by_quicksort_code [code]:
  1424   "sort_key f xs = (case xs of [] \<Rightarrow> []
  1425     | [x] \<Rightarrow> xs
  1426     | [x, y] \<Rightarrow> (if f x \<le> f y then xs else [y, x])
  1427     | _ \<Rightarrow> (let (lts, eqs, gts) = part f (f (xs ! (length xs div 2))) xs
  1428        in sort_key f lts @ eqs @ sort_key f gts))"
  1429 proof (cases xs)
  1430   case Nil then show ?thesis by simp
  1431 next
  1432   case (Cons _ ys) note hyps = Cons show ?thesis
  1433   proof (cases ys)
  1434     case Nil with hyps show ?thesis by simp
  1435   next
  1436     case (Cons _ zs) note hyps = hyps Cons show ?thesis
  1437     proof (cases zs)
  1438       case Nil with hyps show ?thesis by auto
  1439     next
  1440       case Cons 
  1441       from sort_key_by_quicksort [of f xs]
  1442       have "sort_key f xs = (let (lts, eqs, gts) = part f (f (xs ! (length xs div 2))) xs
  1443         in sort_key f lts @ eqs @ sort_key f gts)"
  1444       by (simp only: split_def Let_def part_def fst_conv snd_conv)
  1445       with hyps Cons show ?thesis by (simp only: list.cases)
  1446     qed
  1447   qed
  1448 qed
  1449 
  1450 end
  1451 
  1452 hide_const (open) part
  1453 
  1454 lemma multiset_of_remdups_le: "multiset_of (remdups xs) \<le> multiset_of xs"
  1455   by (induct xs) (auto intro: order_trans)
  1456 
  1457 lemma multiset_of_update:
  1458   "i < length ls \<Longrightarrow> multiset_of (ls[i := v]) = multiset_of ls - {#ls ! i#} + {#v#}"
  1459 proof (induct ls arbitrary: i)
  1460   case Nil then show ?case by simp
  1461 next
  1462   case (Cons x xs)
  1463   show ?case
  1464   proof (cases i)
  1465     case 0 then show ?thesis by simp
  1466   next
  1467     case (Suc i')
  1468     with Cons show ?thesis
  1469       apply simp
  1470       apply (subst add_assoc)
  1471       apply (subst add_commute [of "{#v#}" "{#x#}"])
  1472       apply (subst add_assoc [symmetric])
  1473       apply simp
  1474       apply (rule mset_le_multiset_union_diff_commute)
  1475       apply (simp add: mset_le_single nth_mem_multiset_of)
  1476       done
  1477   qed
  1478 qed
  1479 
  1480 lemma multiset_of_swap:
  1481   "i < length ls \<Longrightarrow> j < length ls \<Longrightarrow>
  1482     multiset_of (ls[j := ls ! i, i := ls ! j]) = multiset_of ls"
  1483   by (cases "i = j") (simp_all add: multiset_of_update nth_mem_multiset_of)
  1484 
  1485 
  1486 subsection {* The multiset order *}
  1487 
  1488 subsubsection {* Well-foundedness *}
  1489 
  1490 definition mult1 :: "('a \<times> 'a) set => ('a multiset \<times> 'a multiset) set" where
  1491   "mult1 r = {(N, M). \<exists>a M0 K. M = M0 + {#a#} \<and> N = M0 + K \<and>
  1492       (\<forall>b. b :# K --> (b, a) \<in> r)}"
  1493 
  1494 definition mult :: "('a \<times> 'a) set => ('a multiset \<times> 'a multiset) set" where
  1495   "mult r = (mult1 r)\<^sup>+"
  1496 
  1497 lemma not_less_empty [iff]: "(M, {#}) \<notin> mult1 r"
  1498 by (simp add: mult1_def)
  1499 
  1500 lemma less_add: "(N, M0 + {#a#}) \<in> mult1 r ==>
  1501     (\<exists>M. (M, M0) \<in> mult1 r \<and> N = M + {#a#}) \<or>
  1502     (\<exists>K. (\<forall>b. b :# K --> (b, a) \<in> r) \<and> N = M0 + K)"
  1503   (is "_ \<Longrightarrow> ?case1 (mult1 r) \<or> ?case2")
  1504 proof (unfold mult1_def)
  1505   let ?r = "\<lambda>K a. \<forall>b. b :# K --> (b, a) \<in> r"
  1506   let ?R = "\<lambda>N M. \<exists>a M0 K. M = M0 + {#a#} \<and> N = M0 + K \<and> ?r K a"
  1507   let ?case1 = "?case1 {(N, M). ?R N M}"
  1508 
  1509   assume "(N, M0 + {#a#}) \<in> {(N, M). ?R N M}"
  1510   then have "\<exists>a' M0' K.
  1511       M0 + {#a#} = M0' + {#a'#} \<and> N = M0' + K \<and> ?r K a'" by simp
  1512   then show "?case1 \<or> ?case2"
  1513   proof (elim exE conjE)
  1514     fix a' M0' K
  1515     assume N: "N = M0' + K" and r: "?r K a'"
  1516     assume "M0 + {#a#} = M0' + {#a'#}"
  1517     then have "M0 = M0' \<and> a = a' \<or>
  1518         (\<exists>K'. M0 = K' + {#a'#} \<and> M0' = K' + {#a#})"
  1519       by (simp only: add_eq_conv_ex)
  1520     then show ?thesis
  1521     proof (elim disjE conjE exE)
  1522       assume "M0 = M0'" "a = a'"
  1523       with N r have "?r K a \<and> N = M0 + K" by simp
  1524       then have ?case2 .. then show ?thesis ..
  1525     next
  1526       fix K'
  1527       assume "M0' = K' + {#a#}"
  1528       with N have n: "N = K' + K + {#a#}" by (simp add: add_ac)
  1529 
  1530       assume "M0 = K' + {#a'#}"
  1531       with r have "?R (K' + K) M0" by blast
  1532       with n have ?case1 by simp then show ?thesis ..
  1533     qed
  1534   qed
  1535 qed
  1536 
  1537 lemma all_accessible: "wf r ==> \<forall>M. M \<in> Wellfounded.acc (mult1 r)"
  1538 proof
  1539   let ?R = "mult1 r"
  1540   let ?W = "Wellfounded.acc ?R"
  1541   {
  1542     fix M M0 a
  1543     assume M0: "M0 \<in> ?W"
  1544       and wf_hyp: "!!b. (b, a) \<in> r ==> (\<forall>M \<in> ?W. M + {#b#} \<in> ?W)"
  1545       and acc_hyp: "\<forall>M. (M, M0) \<in> ?R --> M + {#a#} \<in> ?W"
  1546     have "M0 + {#a#} \<in> ?W"
  1547     proof (rule accI [of "M0 + {#a#}"])
  1548       fix N
  1549       assume "(N, M0 + {#a#}) \<in> ?R"
  1550       then have "((\<exists>M. (M, M0) \<in> ?R \<and> N = M + {#a#}) \<or>
  1551           (\<exists>K. (\<forall>b. b :# K --> (b, a) \<in> r) \<and> N = M0 + K))"
  1552         by (rule less_add)
  1553       then show "N \<in> ?W"
  1554       proof (elim exE disjE conjE)
  1555         fix M assume "(M, M0) \<in> ?R" and N: "N = M + {#a#}"
  1556         from acc_hyp have "(M, M0) \<in> ?R --> M + {#a#} \<in> ?W" ..
  1557         from this and `(M, M0) \<in> ?R` have "M + {#a#} \<in> ?W" ..
  1558         then show "N \<in> ?W" by (simp only: N)
  1559       next
  1560         fix K
  1561         assume N: "N = M0 + K"
  1562         assume "\<forall>b. b :# K --> (b, a) \<in> r"
  1563         then have "M0 + K \<in> ?W"
  1564         proof (induct K)
  1565           case empty
  1566           from M0 show "M0 + {#} \<in> ?W" by simp
  1567         next
  1568           case (add K x)
  1569           from add.prems have "(x, a) \<in> r" by simp
  1570           with wf_hyp have "\<forall>M \<in> ?W. M + {#x#} \<in> ?W" by blast
  1571           moreover from add have "M0 + K \<in> ?W" by simp
  1572           ultimately have "(M0 + K) + {#x#} \<in> ?W" ..
  1573           then show "M0 + (K + {#x#}) \<in> ?W" by (simp only: add_assoc)
  1574         qed
  1575         then show "N \<in> ?W" by (simp only: N)
  1576       qed
  1577     qed
  1578   } note tedious_reasoning = this
  1579 
  1580   assume wf: "wf r"
  1581   fix M
  1582   show "M \<in> ?W"
  1583   proof (induct M)
  1584     show "{#} \<in> ?W"
  1585     proof (rule accI)
  1586       fix b assume "(b, {#}) \<in> ?R"
  1587       with not_less_empty show "b \<in> ?W" by contradiction
  1588     qed
  1589 
  1590     fix M a assume "M \<in> ?W"
  1591     from wf have "\<forall>M \<in> ?W. M + {#a#} \<in> ?W"
  1592     proof induct
  1593       fix a
  1594       assume r: "!!b. (b, a) \<in> r ==> (\<forall>M \<in> ?W. M + {#b#} \<in> ?W)"
  1595       show "\<forall>M \<in> ?W. M + {#a#} \<in> ?W"
  1596       proof
  1597         fix M assume "M \<in> ?W"
  1598         then show "M + {#a#} \<in> ?W"
  1599           by (rule acc_induct) (rule tedious_reasoning [OF _ r])
  1600       qed
  1601     qed
  1602     from this and `M \<in> ?W` show "M + {#a#} \<in> ?W" ..
  1603   qed
  1604 qed
  1605 
  1606 theorem wf_mult1: "wf r ==> wf (mult1 r)"
  1607 by (rule acc_wfI) (rule all_accessible)
  1608 
  1609 theorem wf_mult: "wf r ==> wf (mult r)"
  1610 unfolding mult_def by (rule wf_trancl) (rule wf_mult1)
  1611 
  1612 
  1613 subsubsection {* Closure-free presentation *}
  1614 
  1615 text {* One direction. *}
  1616 
  1617 lemma mult_implies_one_step:
  1618   "trans r ==> (M, N) \<in> mult r ==>
  1619     \<exists>I J K. N = I + J \<and> M = I + K \<and> J \<noteq> {#} \<and>
  1620     (\<forall>k \<in> set_of K. \<exists>j \<in> set_of J. (k, j) \<in> r)"
  1621 apply (unfold mult_def mult1_def set_of_def)
  1622 apply (erule converse_trancl_induct, clarify)
  1623  apply (rule_tac x = M0 in exI, simp, clarify)
  1624 apply (case_tac "a :# K")
  1625  apply (rule_tac x = I in exI)
  1626  apply (simp (no_asm))
  1627  apply (rule_tac x = "(K - {#a#}) + Ka" in exI)
  1628  apply (simp (no_asm_simp) add: add_assoc [symmetric])
  1629  apply (drule_tac f = "\<lambda>M. M - {#a#}" in arg_cong)
  1630  apply (simp add: diff_union_single_conv)
  1631  apply (simp (no_asm_use) add: trans_def)
  1632  apply blast
  1633 apply (subgoal_tac "a :# I")
  1634  apply (rule_tac x = "I - {#a#}" in exI)
  1635  apply (rule_tac x = "J + {#a#}" in exI)
  1636  apply (rule_tac x = "K + Ka" in exI)
  1637  apply (rule conjI)
  1638   apply (simp add: multiset_eq_iff split: nat_diff_split)
  1639  apply (rule conjI)
  1640   apply (drule_tac f = "\<lambda>M. M - {#a#}" in arg_cong, simp)
  1641   apply (simp add: multiset_eq_iff split: nat_diff_split)
  1642  apply (simp (no_asm_use) add: trans_def)
  1643  apply blast
  1644 apply (subgoal_tac "a :# (M0 + {#a#})")
  1645  apply simp
  1646 apply (simp (no_asm))
  1647 done
  1648 
  1649 lemma one_step_implies_mult_aux:
  1650   "trans r ==>
  1651     \<forall>I J K. (size J = n \<and> J \<noteq> {#} \<and> (\<forall>k \<in> set_of K. \<exists>j \<in> set_of J. (k, j) \<in> r))
  1652       --> (I + K, I + J) \<in> mult r"
  1653 apply (induct_tac n, auto)
  1654 apply (frule size_eq_Suc_imp_eq_union, clarify)
  1655 apply (rename_tac "J'", simp)
  1656 apply (erule notE, auto)
  1657 apply (case_tac "J' = {#}")
  1658  apply (simp add: mult_def)
  1659  apply (rule r_into_trancl)
  1660  apply (simp add: mult1_def set_of_def, blast)
  1661 txt {* Now we know @{term "J' \<noteq> {#}"}. *}
  1662 apply (cut_tac M = K and P = "\<lambda>x. (x, a) \<in> r" in multiset_partition)
  1663 apply (erule_tac P = "\<forall>k \<in> set_of K. ?P k" in rev_mp)
  1664 apply (erule ssubst)
  1665 apply (simp add: Ball_def, auto)
  1666 apply (subgoal_tac
  1667   "((I + {# x :# K. (x, a) \<in> r #}) + {# x :# K. (x, a) \<notin> r #},
  1668     (I + {# x :# K. (x, a) \<in> r #}) + J') \<in> mult r")
  1669  prefer 2
  1670  apply force
  1671 apply (simp (no_asm_use) add: add_assoc [symmetric] mult_def)
  1672 apply (erule trancl_trans)
  1673 apply (rule r_into_trancl)
  1674 apply (simp add: mult1_def set_of_def)
  1675 apply (rule_tac x = a in exI)
  1676 apply (rule_tac x = "I + J'" in exI)
  1677 apply (simp add: add_ac)
  1678 done
  1679 
  1680 lemma one_step_implies_mult:
  1681   "trans r ==> J \<noteq> {#} ==> \<forall>k \<in> set_of K. \<exists>j \<in> set_of J. (k, j) \<in> r
  1682     ==> (I + K, I + J) \<in> mult r"
  1683 using one_step_implies_mult_aux by blast
  1684 
  1685 
  1686 subsubsection {* Partial-order properties *}
  1687 
  1688 definition less_multiset :: "'a\<Colon>order multiset \<Rightarrow> 'a multiset \<Rightarrow> bool" (infix "<#" 50) where
  1689   "M' <# M \<longleftrightarrow> (M', M) \<in> mult {(x', x). x' < x}"
  1690 
  1691 definition le_multiset :: "'a\<Colon>order multiset \<Rightarrow> 'a multiset \<Rightarrow> bool" (infix "<=#" 50) where
  1692   "M' <=# M \<longleftrightarrow> M' <# M \<or> M' = M"
  1693 
  1694 notation (xsymbols) less_multiset (infix "\<subset>#" 50)
  1695 notation (xsymbols) le_multiset (infix "\<subseteq>#" 50)
  1696 
  1697 interpretation multiset_order: order le_multiset less_multiset
  1698 proof -
  1699   have irrefl: "\<And>M :: 'a multiset. \<not> M \<subset># M"
  1700   proof
  1701     fix M :: "'a multiset"
  1702     assume "M \<subset># M"
  1703     then have MM: "(M, M) \<in> mult {(x, y). x < y}" by (simp add: less_multiset_def)
  1704     have "trans {(x'::'a, x). x' < x}"
  1705       by (rule transI) simp
  1706     moreover note MM
  1707     ultimately have "\<exists>I J K. M = I + J \<and> M = I + K
  1708       \<and> J \<noteq> {#} \<and> (\<forall>k\<in>set_of K. \<exists>j\<in>set_of J. (k, j) \<in> {(x, y). x < y})"
  1709       by (rule mult_implies_one_step)
  1710     then obtain I J K where "M = I + J" and "M = I + K"
  1711       and "J \<noteq> {#}" and "(\<forall>k\<in>set_of K. \<exists>j\<in>set_of J. (k, j) \<in> {(x, y). x < y})" by blast
  1712     then have aux1: "K \<noteq> {#}" and aux2: "\<forall>k\<in>set_of K. \<exists>j\<in>set_of K. k < j" by auto
  1713     have "finite (set_of K)" by simp
  1714     moreover note aux2
  1715     ultimately have "set_of K = {}"
  1716       by (induct rule: finite_induct) (auto intro: order_less_trans)
  1717     with aux1 show False by simp
  1718   qed
  1719   have trans: "\<And>K M N :: 'a multiset. K \<subset># M \<Longrightarrow> M \<subset># N \<Longrightarrow> K \<subset># N"
  1720     unfolding less_multiset_def mult_def by (blast intro: trancl_trans)
  1721   show "class.order (le_multiset :: 'a multiset \<Rightarrow> _) less_multiset"
  1722     by default (auto simp add: le_multiset_def irrefl dest: trans)
  1723 qed
  1724 
  1725 lemma mult_less_irrefl [elim!]: "M \<subset># (M::'a::order multiset) ==> R"
  1726   by simp
  1727 
  1728 
  1729 subsubsection {* Monotonicity of multiset union *}
  1730 
  1731 lemma mult1_union: "(B, D) \<in> mult1 r ==> (C + B, C + D) \<in> mult1 r"
  1732 apply (unfold mult1_def)
  1733 apply auto
  1734 apply (rule_tac x = a in exI)
  1735 apply (rule_tac x = "C + M0" in exI)
  1736 apply (simp add: add_assoc)
  1737 done
  1738 
  1739 lemma union_less_mono2: "B \<subset># D ==> C + B \<subset># C + (D::'a::order multiset)"
  1740 apply (unfold less_multiset_def mult_def)
  1741 apply (erule trancl_induct)
  1742  apply (blast intro: mult1_union)
  1743 apply (blast intro: mult1_union trancl_trans)
  1744 done
  1745 
  1746 lemma union_less_mono1: "B \<subset># D ==> B + C \<subset># D + (C::'a::order multiset)"
  1747 apply (subst add_commute [of B C])
  1748 apply (subst add_commute [of D C])
  1749 apply (erule union_less_mono2)
  1750 done
  1751 
  1752 lemma union_less_mono:
  1753   "A \<subset># C ==> B \<subset># D ==> A + B \<subset># C + (D::'a::order multiset)"
  1754   by (blast intro!: union_less_mono1 union_less_mono2 multiset_order.less_trans)
  1755 
  1756 interpretation multiset_order: ordered_ab_semigroup_add plus le_multiset less_multiset
  1757 proof
  1758 qed (auto simp add: le_multiset_def intro: union_less_mono2)
  1759 
  1760 
  1761 subsection {* Termination proofs with multiset orders *}
  1762 
  1763 lemma multi_member_skip: "x \<in># XS \<Longrightarrow> x \<in># {# y #} + XS"
  1764   and multi_member_this: "x \<in># {# x #} + XS"
  1765   and multi_member_last: "x \<in># {# x #}"
  1766   by auto
  1767 
  1768 definition "ms_strict = mult pair_less"
  1769 definition "ms_weak = ms_strict \<union> Id"
  1770 
  1771 lemma ms_reduction_pair: "reduction_pair (ms_strict, ms_weak)"
  1772 unfolding reduction_pair_def ms_strict_def ms_weak_def pair_less_def
  1773 by (auto intro: wf_mult1 wf_trancl simp: mult_def)
  1774 
  1775 lemma smsI:
  1776   "(set_of A, set_of B) \<in> max_strict \<Longrightarrow> (Z + A, Z + B) \<in> ms_strict"
  1777   unfolding ms_strict_def
  1778 by (rule one_step_implies_mult) (auto simp add: max_strict_def pair_less_def elim!:max_ext.cases)
  1779 
  1780 lemma wmsI:
  1781   "(set_of A, set_of B) \<in> max_strict \<or> A = {#} \<and> B = {#}
  1782   \<Longrightarrow> (Z + A, Z + B) \<in> ms_weak"
  1783 unfolding ms_weak_def ms_strict_def
  1784 by (auto simp add: pair_less_def max_strict_def elim!:max_ext.cases intro: one_step_implies_mult)
  1785 
  1786 inductive pw_leq
  1787 where
  1788   pw_leq_empty: "pw_leq {#} {#}"
  1789 | pw_leq_step:  "\<lbrakk>(x,y) \<in> pair_leq; pw_leq X Y \<rbrakk> \<Longrightarrow> pw_leq ({#x#} + X) ({#y#} + Y)"
  1790 
  1791 lemma pw_leq_lstep:
  1792   "(x, y) \<in> pair_leq \<Longrightarrow> pw_leq {#x#} {#y#}"
  1793 by (drule pw_leq_step) (rule pw_leq_empty, simp)
  1794 
  1795 lemma pw_leq_split:
  1796   assumes "pw_leq X Y"
  1797   shows "\<exists>A B Z. X = A + Z \<and> Y = B + Z \<and> ((set_of A, set_of B) \<in> max_strict \<or> (B = {#} \<and> A = {#}))"
  1798   using assms
  1799 proof (induct)
  1800   case pw_leq_empty thus ?case by auto
  1801 next
  1802   case (pw_leq_step x y X Y)
  1803   then obtain A B Z where
  1804     [simp]: "X = A + Z" "Y = B + Z" 
  1805       and 1[simp]: "(set_of A, set_of B) \<in> max_strict \<or> (B = {#} \<and> A = {#})" 
  1806     by auto
  1807   from pw_leq_step have "x = y \<or> (x, y) \<in> pair_less" 
  1808     unfolding pair_leq_def by auto
  1809   thus ?case
  1810   proof
  1811     assume [simp]: "x = y"
  1812     have
  1813       "{#x#} + X = A + ({#y#}+Z) 
  1814       \<and> {#y#} + Y = B + ({#y#}+Z)
  1815       \<and> ((set_of A, set_of B) \<in> max_strict \<or> (B = {#} \<and> A = {#}))"
  1816       by (auto simp: add_ac)
  1817     thus ?case by (intro exI)
  1818   next
  1819     assume A: "(x, y) \<in> pair_less"
  1820     let ?A' = "{#x#} + A" and ?B' = "{#y#} + B"
  1821     have "{#x#} + X = ?A' + Z"
  1822       "{#y#} + Y = ?B' + Z"
  1823       by (auto simp add: add_ac)
  1824     moreover have 
  1825       "(set_of ?A', set_of ?B') \<in> max_strict"
  1826       using 1 A unfolding max_strict_def 
  1827       by (auto elim!: max_ext.cases)
  1828     ultimately show ?thesis by blast
  1829   qed
  1830 qed
  1831 
  1832 lemma 
  1833   assumes pwleq: "pw_leq Z Z'"
  1834   shows ms_strictI: "(set_of A, set_of B) \<in> max_strict \<Longrightarrow> (Z + A, Z' + B) \<in> ms_strict"
  1835   and   ms_weakI1:  "(set_of A, set_of B) \<in> max_strict \<Longrightarrow> (Z + A, Z' + B) \<in> ms_weak"
  1836   and   ms_weakI2:  "(Z + {#}, Z' + {#}) \<in> ms_weak"
  1837 proof -
  1838   from pw_leq_split[OF pwleq] 
  1839   obtain A' B' Z''
  1840     where [simp]: "Z = A' + Z''" "Z' = B' + Z''"
  1841     and mx_or_empty: "(set_of A', set_of B') \<in> max_strict \<or> (A' = {#} \<and> B' = {#})"
  1842     by blast
  1843   {
  1844     assume max: "(set_of A, set_of B) \<in> max_strict"
  1845     from mx_or_empty
  1846     have "(Z'' + (A + A'), Z'' + (B + B')) \<in> ms_strict"
  1847     proof
  1848       assume max': "(set_of A', set_of B') \<in> max_strict"
  1849       with max have "(set_of (A + A'), set_of (B + B')) \<in> max_strict"
  1850         by (auto simp: max_strict_def intro: max_ext_additive)
  1851       thus ?thesis by (rule smsI) 
  1852     next
  1853       assume [simp]: "A' = {#} \<and> B' = {#}"
  1854       show ?thesis by (rule smsI) (auto intro: max)
  1855     qed
  1856     thus "(Z + A, Z' + B) \<in> ms_strict" by (simp add:add_ac)
  1857     thus "(Z + A, Z' + B) \<in> ms_weak" by (simp add: ms_weak_def)
  1858   }
  1859   from mx_or_empty
  1860   have "(Z'' + A', Z'' + B') \<in> ms_weak" by (rule wmsI)
  1861   thus "(Z + {#}, Z' + {#}) \<in> ms_weak" by (simp add:add_ac)
  1862 qed
  1863 
  1864 lemma empty_neutral: "{#} + x = x" "x + {#} = x"
  1865 and nonempty_plus: "{# x #} + rs \<noteq> {#}"
  1866 and nonempty_single: "{# x #} \<noteq> {#}"
  1867 by auto
  1868 
  1869 setup {*
  1870 let
  1871   fun msetT T = Type (@{type_name multiset}, [T]);
  1872 
  1873   fun mk_mset T [] = Const (@{const_abbrev Mempty}, msetT T)
  1874     | mk_mset T [x] = Const (@{const_name single}, T --> msetT T) $ x
  1875     | mk_mset T (x :: xs) =
  1876           Const (@{const_name plus}, msetT T --> msetT T --> msetT T) $
  1877                 mk_mset T [x] $ mk_mset T xs
  1878 
  1879   fun mset_member_tac m i =
  1880       (if m <= 0 then
  1881            rtac @{thm multi_member_this} i ORELSE rtac @{thm multi_member_last} i
  1882        else
  1883            rtac @{thm multi_member_skip} i THEN mset_member_tac (m - 1) i)
  1884 
  1885   val mset_nonempty_tac =
  1886       rtac @{thm nonempty_plus} ORELSE' rtac @{thm nonempty_single}
  1887 
  1888   val regroup_munion_conv =
  1889       Function_Lib.regroup_conv @{const_abbrev Mempty} @{const_name plus}
  1890         (map (fn t => t RS eq_reflection) (@{thms add_ac} @ @{thms empty_neutral}))
  1891 
  1892   fun unfold_pwleq_tac i =
  1893     (rtac @{thm pw_leq_step} i THEN (fn st => unfold_pwleq_tac (i + 1) st))
  1894       ORELSE (rtac @{thm pw_leq_lstep} i)
  1895       ORELSE (rtac @{thm pw_leq_empty} i)
  1896 
  1897   val set_of_simps = [@{thm set_of_empty}, @{thm set_of_single}, @{thm set_of_union},
  1898                       @{thm Un_insert_left}, @{thm Un_empty_left}]
  1899 in
  1900   ScnpReconstruct.multiset_setup (ScnpReconstruct.Multiset 
  1901   {
  1902     msetT=msetT, mk_mset=mk_mset, mset_regroup_conv=regroup_munion_conv,
  1903     mset_member_tac=mset_member_tac, mset_nonempty_tac=mset_nonempty_tac,
  1904     mset_pwleq_tac=unfold_pwleq_tac, set_of_simps=set_of_simps,
  1905     smsI'= @{thm ms_strictI}, wmsI2''= @{thm ms_weakI2}, wmsI1= @{thm ms_weakI1},
  1906     reduction_pair= @{thm ms_reduction_pair}
  1907   })
  1908 end
  1909 *}
  1910 
  1911 
  1912 subsection {* Legacy theorem bindings *}
  1913 
  1914 lemmas multi_count_eq = multiset_eq_iff [symmetric]
  1915 
  1916 lemma union_commute: "M + N = N + (M::'a multiset)"
  1917   by (fact add_commute)
  1918 
  1919 lemma union_assoc: "(M + N) + K = M + (N + (K::'a multiset))"
  1920   by (fact add_assoc)
  1921 
  1922 lemma union_lcomm: "M + (N + K) = N + (M + (K::'a multiset))"
  1923   by (fact add_left_commute)
  1924 
  1925 lemmas union_ac = union_assoc union_commute union_lcomm
  1926 
  1927 lemma union_right_cancel: "M + K = N + K \<longleftrightarrow> M = (N::'a multiset)"
  1928   by (fact add_right_cancel)
  1929 
  1930 lemma union_left_cancel: "K + M = K + N \<longleftrightarrow> M = (N::'a multiset)"
  1931   by (fact add_left_cancel)
  1932 
  1933 lemma multi_union_self_other_eq: "(A::'a multiset) + X = A + Y \<Longrightarrow> X = Y"
  1934   by (fact add_imp_eq)
  1935 
  1936 lemma mset_less_trans: "(M::'a multiset) < K \<Longrightarrow> K < N \<Longrightarrow> M < N"
  1937   by (fact order_less_trans)
  1938 
  1939 lemma multiset_inter_commute: "A #\<inter> B = B #\<inter> A"
  1940   by (fact inf.commute)
  1941 
  1942 lemma multiset_inter_assoc: "A #\<inter> (B #\<inter> C) = A #\<inter> B #\<inter> C"
  1943   by (fact inf.assoc [symmetric])
  1944 
  1945 lemma multiset_inter_left_commute: "A #\<inter> (B #\<inter> C) = B #\<inter> (A #\<inter> C)"
  1946   by (fact inf.left_commute)
  1947 
  1948 lemmas multiset_inter_ac =
  1949   multiset_inter_commute
  1950   multiset_inter_assoc
  1951   multiset_inter_left_commute
  1952 
  1953 lemma mult_less_not_refl:
  1954   "\<not> M \<subset># (M::'a::order multiset)"
  1955   by (fact multiset_order.less_irrefl)
  1956 
  1957 lemma mult_less_trans:
  1958   "K \<subset># M ==> M \<subset># N ==> K \<subset># (N::'a::order multiset)"
  1959   by (fact multiset_order.less_trans)
  1960     
  1961 lemma mult_less_not_sym:
  1962   "M \<subset># N ==> \<not> N \<subset># (M::'a::order multiset)"
  1963   by (fact multiset_order.less_not_sym)
  1964 
  1965 lemma mult_less_asym:
  1966   "M \<subset># N ==> (\<not> P ==> N \<subset># (M::'a::order multiset)) ==> P"
  1967   by (fact multiset_order.less_asym)
  1968 
  1969 ML {*
  1970 fun multiset_postproc _ maybe_name all_values (T as Type (_, [elem_T]))
  1971                       (Const _ $ t') =
  1972     let
  1973       val (maybe_opt, ps) =
  1974         Nitpick_Model.dest_plain_fun t' ||> op ~~
  1975         ||> map (apsnd (snd o HOLogic.dest_number))
  1976       fun elems_for t =
  1977         case AList.lookup (op =) ps t of
  1978           SOME n => replicate n t
  1979         | NONE => [Const (maybe_name, elem_T --> elem_T) $ t]
  1980     in
  1981       case maps elems_for (all_values elem_T) @
  1982            (if maybe_opt then [Const (Nitpick_Model.unrep (), elem_T)]
  1983             else []) of
  1984         [] => Const (@{const_name zero_class.zero}, T)
  1985       | ts => foldl1 (fn (t1, t2) =>
  1986                          Const (@{const_name plus_class.plus}, T --> T --> T)
  1987                          $ t1 $ t2)
  1988                      (map (curry (op $) (Const (@{const_name single},
  1989                                                 elem_T --> T))) ts)
  1990     end
  1991   | multiset_postproc _ _ _ _ t = t
  1992 *}
  1993 
  1994 declaration {*
  1995 Nitpick_Model.register_term_postprocessor @{typ "'a multiset"}
  1996     multiset_postproc
  1997 *}
  1998 
  1999 hide_const (open) fold
  2000 
  2001 
  2002 subsection {* Naive implementation using lists *}
  2003 
  2004 code_datatype multiset_of
  2005 
  2006 lemma [code]:
  2007   "{#} = multiset_of []"
  2008   by simp
  2009 
  2010 lemma [code]:
  2011   "{#x#} = multiset_of [x]"
  2012   by simp
  2013 
  2014 lemma union_code [code]:
  2015   "multiset_of xs + multiset_of ys = multiset_of (xs @ ys)"
  2016   by simp
  2017 
  2018 lemma [code]:
  2019   "image_mset f (multiset_of xs) = multiset_of (map f xs)"
  2020   by (simp add: multiset_of_map)
  2021 
  2022 lemma [code]:
  2023   "Multiset.filter f (multiset_of xs) = multiset_of (filter f xs)"
  2024   by (simp add: multiset_of_filter)
  2025 
  2026 lemma [code]:
  2027   "multiset_of xs - multiset_of ys = multiset_of (fold remove1 ys xs)"
  2028   by (rule sym, induct ys arbitrary: xs) (simp_all add: diff_add diff_right_commute)
  2029 
  2030 lemma [code]:
  2031   "multiset_of xs #\<inter> multiset_of ys =
  2032     multiset_of (snd (fold (\<lambda>x (ys, zs).
  2033       if x \<in> set ys then (remove1 x ys, x # zs) else (ys, zs)) xs (ys, [])))"
  2034 proof -
  2035   have "\<And>zs. multiset_of (snd (fold (\<lambda>x (ys, zs).
  2036     if x \<in> set ys then (remove1 x ys, x # zs) else (ys, zs)) xs (ys, zs))) =
  2037       (multiset_of xs #\<inter> multiset_of ys) + multiset_of zs"
  2038     by (induct xs arbitrary: ys)
  2039       (auto simp add: mem_set_multiset_eq inter_add_right1 inter_add_right2 ac_simps)
  2040   then show ?thesis by simp
  2041 qed
  2042 
  2043 lemma [code]:
  2044   "multiset_of xs #\<union> multiset_of ys =
  2045     multiset_of (split append (fold (\<lambda>x (ys, zs). (remove1 x ys, x # zs)) xs (ys, [])))"
  2046 proof -
  2047   have "\<And>zs. multiset_of (split append (fold (\<lambda>x (ys, zs). (remove1 x ys, x # zs)) xs (ys, zs))) =
  2048       (multiset_of xs #\<union> multiset_of ys) + multiset_of zs"
  2049     by (induct xs arbitrary: ys) (simp_all add: multiset_eq_iff)
  2050   then show ?thesis by simp
  2051 qed
  2052 
  2053 lemma [code_unfold]:
  2054   "x \<in># multiset_of xs \<longleftrightarrow> x \<in> set xs"
  2055   by (simp add: in_multiset_of)
  2056 
  2057 lemma [code]:
  2058   "count (multiset_of xs) x = fold (\<lambda>y. if x = y then Suc else id) xs 0"
  2059 proof -
  2060   have "\<And>n. fold (\<lambda>y. if x = y then Suc else id) xs n = count (multiset_of xs) x + n"
  2061     by (induct xs) simp_all
  2062   then show ?thesis by simp
  2063 qed
  2064 
  2065 lemma [code]:
  2066   "set_of (multiset_of xs) = set xs"
  2067   by simp
  2068 
  2069 lemma [code]:
  2070   "sorted_list_of_multiset (multiset_of xs) = sort xs"
  2071   by (induct xs) simp_all
  2072 
  2073 lemma [code]: -- {* not very efficient, but representation-ignorant! *}
  2074   "multiset_of_set A = multiset_of (sorted_list_of_set A)"
  2075   apply (cases "finite A")
  2076   apply simp_all
  2077   apply (induct A rule: finite_induct)
  2078   apply (simp_all add: union_commute)
  2079   done
  2080 
  2081 lemma [code]:
  2082   "mcard (multiset_of xs) = length xs"
  2083   by (simp add: mcard_multiset_of)
  2084 
  2085 lemma [code]:
  2086   "A \<le> B \<longleftrightarrow> A #\<inter> B = A" 
  2087   by (auto simp add: inf.order_iff)
  2088 
  2089 instantiation multiset :: (equal) equal
  2090 begin
  2091 
  2092 definition
  2093   [code]: "HOL.equal A B \<longleftrightarrow> (A::'a multiset) \<le> B \<and> B \<le> A"
  2094 
  2095 instance
  2096   by default (simp add: equal_multiset_def eq_iff)
  2097 
  2098 end
  2099 
  2100 lemma [code]:
  2101   "(A::'a multiset) < B \<longleftrightarrow> A \<le> B \<and> A \<noteq> B"
  2102   by auto
  2103 
  2104 lemma [code]:
  2105   "msetsum (multiset_of xs) = listsum xs"
  2106   by (induct xs) (simp_all add: add.commute)
  2107 
  2108 lemma [code]:
  2109   "msetprod (multiset_of xs) = fold times xs 1"
  2110 proof -
  2111   have "\<And>x. fold times xs x = msetprod (multiset_of xs) * x"
  2112     by (induct xs) (simp_all add: mult.assoc)
  2113   then show ?thesis by simp
  2114 qed
  2115 
  2116 lemma [code]:
  2117   "size = mcard"
  2118   by (fact size_eq_mcard)
  2119 
  2120 text {*
  2121   Exercise for the casual reader: add implementations for @{const le_multiset}
  2122   and @{const less_multiset} (multiset order).
  2123 *}
  2124 
  2125 text {* Quickcheck generators *}
  2126 
  2127 definition (in term_syntax)
  2128   msetify :: "'a\<Colon>typerep list \<times> (unit \<Rightarrow> Code_Evaluation.term)
  2129     \<Rightarrow> 'a multiset \<times> (unit \<Rightarrow> Code_Evaluation.term)" where
  2130   [code_unfold]: "msetify xs = Code_Evaluation.valtermify multiset_of {\<cdot>} xs"
  2131 
  2132 notation fcomp (infixl "\<circ>>" 60)
  2133 notation scomp (infixl "\<circ>\<rightarrow>" 60)
  2134 
  2135 instantiation multiset :: (random) random
  2136 begin
  2137 
  2138 definition
  2139   "Quickcheck_Random.random i = Quickcheck_Random.random i \<circ>\<rightarrow> (\<lambda>xs. Pair (msetify xs))"
  2140 
  2141 instance ..
  2142 
  2143 end
  2144 
  2145 no_notation fcomp (infixl "\<circ>>" 60)
  2146 no_notation scomp (infixl "\<circ>\<rightarrow>" 60)
  2147 
  2148 instantiation multiset :: (full_exhaustive) full_exhaustive
  2149 begin
  2150 
  2151 definition full_exhaustive_multiset :: "('a multiset \<times> (unit \<Rightarrow> term) \<Rightarrow> (bool \<times> term list) option) \<Rightarrow> natural \<Rightarrow> (bool \<times> term list) option"
  2152 where
  2153   "full_exhaustive_multiset f i = Quickcheck_Exhaustive.full_exhaustive (\<lambda>xs. f (msetify xs)) i"
  2154 
  2155 instance ..
  2156 
  2157 end
  2158 
  2159 hide_const (open) msetify
  2160 
  2161 
  2162 subsection {* BNF setup *}
  2163 
  2164 lemma setsum_gt_0_iff:
  2165 fixes f :: "'a \<Rightarrow> nat" assumes "finite A"
  2166 shows "setsum f A > 0 \<longleftrightarrow> (\<exists> a \<in> A. f a > 0)"
  2167 (is "?L \<longleftrightarrow> ?R")
  2168 proof-
  2169   have "?L \<longleftrightarrow> \<not> setsum f A = 0" by fast
  2170   also have "... \<longleftrightarrow> (\<exists> a \<in> A. f a \<noteq> 0)" using assms by simp
  2171   also have "... \<longleftrightarrow> ?R" by simp
  2172   finally show ?thesis .
  2173 qed
  2174 
  2175 lift_definition mmap :: "('a \<Rightarrow> 'b) \<Rightarrow> 'a multiset \<Rightarrow> 'b multiset" is
  2176   "\<lambda>h f b. setsum f {a. h a = b \<and> f a > 0} :: nat"
  2177 unfolding multiset_def proof safe
  2178   fix h :: "'a \<Rightarrow> 'b" and f :: "'a \<Rightarrow> nat"
  2179   assume fin: "finite {a. 0 < f a}"  (is "finite ?A")
  2180   show "finite {b. 0 < setsum f {a. h a = b \<and> 0 < f a}}"
  2181   (is "finite {b. 0 < setsum f (?As b)}")
  2182   proof- let ?B = "{b. 0 < setsum f (?As b)}"
  2183     have "\<And> b. finite (?As b)" using fin by simp
  2184     hence B: "?B = {b. ?As b \<noteq> {}}" by (auto simp add: setsum_gt_0_iff)
  2185     hence "?B \<subseteq> h ` ?A" by auto
  2186     thus ?thesis using finite_surj[OF fin] by auto
  2187   qed
  2188 qed
  2189 
  2190 lemma mmap_id0: "mmap id = id"
  2191 proof (intro ext multiset_eqI)
  2192   fix f a show "count (mmap id f) a = count (id f) a"
  2193   proof (cases "count f a = 0")
  2194     case False
  2195     hence 1: "{aa. aa = a \<and> aa \<in># f} = {a}" by auto
  2196     thus ?thesis by transfer auto
  2197   qed (transfer, simp)
  2198 qed
  2199 
  2200 lemma inj_on_setsum_inv:
  2201 assumes 1: "(0::nat) < setsum (count f) {a. h a = b' \<and> a \<in># f}" (is "0 < setsum (count f) ?A'")
  2202 and     2: "{a. h a = b \<and> a \<in># f} = {a. h a = b' \<and> a \<in># f}" (is "?A = ?A'")
  2203 shows "b = b'"
  2204 using assms by (auto simp add: setsum_gt_0_iff)
  2205 
  2206 lemma mmap_comp:
  2207 fixes h1 :: "'a \<Rightarrow> 'b" and h2 :: "'b \<Rightarrow> 'c"
  2208 shows "mmap (h2 o h1) = mmap h2 o mmap h1"
  2209 proof (intro ext multiset_eqI)
  2210   fix f :: "'a multiset" fix c :: 'c
  2211   let ?A = "{a. h2 (h1 a) = c \<and> a \<in># f}"
  2212   let ?As = "\<lambda> b. {a. h1 a = b \<and> a \<in># f}"
  2213   let ?B = "{b. h2 b = c \<and> 0 < setsum (count f) (?As b)}"
  2214   have 0: "{?As b | b.  b \<in> ?B} = ?As ` ?B" by auto
  2215   have "\<And> b. finite (?As b)" by transfer (simp add: multiset_def)
  2216   hence "?B = {b. h2 b = c \<and> ?As b \<noteq> {}}" by (auto simp add: setsum_gt_0_iff)
  2217   hence A: "?A = \<Union> {?As b | b.  b \<in> ?B}" by auto
  2218   have "setsum (count f) ?A = setsum (setsum (count f)) {?As b | b.  b \<in> ?B}"
  2219     unfolding A by transfer (intro setsum_Union_disjoint, auto simp: multiset_def)
  2220   also have "... = setsum (setsum (count f)) (?As ` ?B)" unfolding 0 ..
  2221   also have "... = setsum (setsum (count f) o ?As) ?B"
  2222     by(intro setsum_reindex) (auto simp add: setsum_gt_0_iff inj_on_def)
  2223   also have "... = setsum (\<lambda> b. setsum (count f) (?As b)) ?B" unfolding comp_def ..
  2224   finally have "setsum (count f) ?A = setsum (\<lambda> b. setsum (count f) (?As b)) ?B" .
  2225   thus "count (mmap (h2 \<circ> h1) f) c = count ((mmap h2 \<circ> mmap h1) f) c"
  2226     by transfer (unfold comp_apply, blast)
  2227 qed
  2228 
  2229 lemma mmap_cong:
  2230 assumes "\<And>a. a \<in># M \<Longrightarrow> f a = g a"
  2231 shows "mmap f M = mmap g M"
  2232 using assms by transfer (auto intro!: setsum_cong)
  2233 
  2234 context
  2235 begin
  2236 interpretation lifting_syntax .
  2237 
  2238 lemma set_of_transfer[transfer_rule]: "(pcr_multiset op = ===> op =) (\<lambda>f. {a. 0 < f a}) set_of"
  2239   unfolding set_of_def pcr_multiset_def cr_multiset_def fun_rel_def by auto
  2240 
  2241 end
  2242 
  2243 lemma set_of_mmap: "set_of o mmap h = image h o set_of"
  2244 proof (rule ext, unfold comp_apply)
  2245   fix M show "set_of (mmap h M) = h ` set_of M"
  2246     by transfer (auto simp add: multiset_def setsum_gt_0_iff)
  2247 qed
  2248 
  2249 lemma multiset_of_surj:
  2250   "multiset_of ` {as. set as \<subseteq> A} = {M. set_of M \<subseteq> A}"
  2251 proof safe
  2252   fix M assume M: "set_of M \<subseteq> A"
  2253   obtain as where eq: "M = multiset_of as" using surj_multiset_of unfolding surj_def by auto
  2254   hence "set as \<subseteq> A" using M by auto
  2255   thus "M \<in> multiset_of ` {as. set as \<subseteq> A}" using eq by auto
  2256 next
  2257   show "\<And>x xa xb. \<lbrakk>set xa \<subseteq> A; xb \<in> set_of (multiset_of xa)\<rbrakk> \<Longrightarrow> xb \<in> A"
  2258   by (erule set_mp) (unfold set_of_multiset_of)
  2259 qed
  2260 
  2261 lemma card_of_set_of:
  2262 "(card_of {M. set_of M \<subseteq> A}, card_of {as. set as \<subseteq> A}) \<in> ordLeq"
  2263 apply(rule card_of_ordLeqI2[of _ multiset_of]) using multiset_of_surj by auto
  2264 
  2265 lemma nat_sum_induct:
  2266 assumes "\<And>n1 n2. (\<And> m1 m2. m1 + m2 < n1 + n2 \<Longrightarrow> phi m1 m2) \<Longrightarrow> phi n1 n2"
  2267 shows "phi (n1::nat) (n2::nat)"
  2268 proof-
  2269   let ?chi = "\<lambda> n1n2 :: nat * nat. phi (fst n1n2) (snd n1n2)"
  2270   have "?chi (n1,n2)"
  2271   apply(induct rule: measure_induct[of "\<lambda> n1n2. fst n1n2 + snd n1n2" ?chi])
  2272   using assms by (metis fstI sndI)
  2273   thus ?thesis by simp
  2274 qed
  2275 
  2276 lemma matrix_count:
  2277 fixes ct1 ct2 :: "nat \<Rightarrow> nat"
  2278 assumes "setsum ct1 {..<Suc n1} = setsum ct2 {..<Suc n2}"
  2279 shows
  2280 "\<exists> ct. (\<forall> i1 \<le> n1. setsum (\<lambda> i2. ct i1 i2) {..<Suc n2} = ct1 i1) \<and>
  2281        (\<forall> i2 \<le> n2. setsum (\<lambda> i1. ct i1 i2) {..<Suc n1} = ct2 i2)"
  2282 (is "?phi ct1 ct2 n1 n2")
  2283 proof-
  2284   have "\<forall> ct1 ct2 :: nat \<Rightarrow> nat.
  2285         setsum ct1 {..<Suc n1} = setsum ct2 {..<Suc n2} \<longrightarrow> ?phi ct1 ct2 n1 n2"
  2286   proof(induct rule: nat_sum_induct[of
  2287 "\<lambda> n1 n2. \<forall> ct1 ct2 :: nat \<Rightarrow> nat.
  2288      setsum ct1 {..<Suc n1} = setsum ct2 {..<Suc n2} \<longrightarrow> ?phi ct1 ct2 n1 n2"],
  2289       clarify)
  2290   fix n1 n2 :: nat and ct1 ct2 :: "nat \<Rightarrow> nat"
  2291   assume IH: "\<And> m1 m2. m1 + m2 < n1 + n2 \<Longrightarrow>
  2292                 \<forall> dt1 dt2 :: nat \<Rightarrow> nat.
  2293                 setsum dt1 {..<Suc m1} = setsum dt2 {..<Suc m2} \<longrightarrow> ?phi dt1 dt2 m1 m2"
  2294   and ss: "setsum ct1 {..<Suc n1} = setsum ct2 {..<Suc n2}"
  2295   show "?phi ct1 ct2 n1 n2"
  2296   proof(cases n1)
  2297     case 0 note n1 = 0
  2298     show ?thesis
  2299     proof(cases n2)
  2300       case 0 note n2 = 0
  2301       let ?ct = "\<lambda> i1 i2. ct2 0"
  2302       show ?thesis apply(rule exI[of _ ?ct]) using n1 n2 ss by simp
  2303     next
  2304       case (Suc m2) note n2 = Suc
  2305       let ?ct = "\<lambda> i1 i2. ct2 i2"
  2306       show ?thesis apply(rule exI[of _ ?ct]) using n1 n2 ss by auto
  2307     qed
  2308   next
  2309     case (Suc m1) note n1 = Suc
  2310     show ?thesis
  2311     proof(cases n2)
  2312       case 0 note n2 = 0
  2313       let ?ct = "\<lambda> i1 i2. ct1 i1"
  2314       show ?thesis apply(rule exI[of _ ?ct]) using n1 n2 ss by auto
  2315     next
  2316       case (Suc m2) note n2 = Suc
  2317       show ?thesis
  2318       proof(cases "ct1 n1 \<le> ct2 n2")
  2319         case True
  2320         def dt2 \<equiv> "\<lambda> i2. if i2 = n2 then ct2 i2 - ct1 n1 else ct2 i2"
  2321         have "setsum ct1 {..<Suc m1} = setsum dt2 {..<Suc n2}"
  2322         unfolding dt2_def using ss n1 True by auto
  2323         hence "?phi ct1 dt2 m1 n2" using IH[of m1 n2] n1 by simp
  2324         then obtain dt where
  2325         1: "\<And> i1. i1 \<le> m1 \<Longrightarrow> setsum (\<lambda> i2. dt i1 i2) {..<Suc n2} = ct1 i1" and
  2326         2: "\<And> i2. i2 \<le> n2 \<Longrightarrow> setsum (\<lambda> i1. dt i1 i2) {..<Suc m1} = dt2 i2" by auto
  2327         let ?ct = "\<lambda> i1 i2. if i1 = n1 then (if i2 = n2 then ct1 n1 else 0)
  2328                                        else dt i1 i2"
  2329         show ?thesis apply(rule exI[of _ ?ct])
  2330         using n1 n2 1 2 True unfolding dt2_def by simp
  2331       next
  2332         case False
  2333         hence False: "ct2 n2 < ct1 n1" by simp
  2334         def dt1 \<equiv> "\<lambda> i1. if i1 = n1 then ct1 i1 - ct2 n2 else ct1 i1"
  2335         have "setsum dt1 {..<Suc n1} = setsum ct2 {..<Suc m2}"
  2336         unfolding dt1_def using ss n2 False by auto
  2337         hence "?phi dt1 ct2 n1 m2" using IH[of n1 m2] n2 by simp
  2338         then obtain dt where
  2339         1: "\<And> i1. i1 \<le> n1 \<Longrightarrow> setsum (\<lambda> i2. dt i1 i2) {..<Suc m2} = dt1 i1" and
  2340         2: "\<And> i2. i2 \<le> m2 \<Longrightarrow> setsum (\<lambda> i1. dt i1 i2) {..<Suc n1} = ct2 i2" by force
  2341         let ?ct = "\<lambda> i1 i2. if i2 = n2 then (if i1 = n1 then ct2 n2 else 0)
  2342                                        else dt i1 i2"
  2343         show ?thesis apply(rule exI[of _ ?ct])
  2344         using n1 n2 1 2 False unfolding dt1_def by simp
  2345       qed
  2346     qed
  2347   qed
  2348   qed
  2349   thus ?thesis using assms by auto
  2350 qed
  2351 
  2352 definition
  2353 "inj2 u B1 B2 \<equiv>
  2354  \<forall> b1 b1' b2 b2'. {b1,b1'} \<subseteq> B1 \<and> {b2,b2'} \<subseteq> B2 \<and> u b1 b2 = u b1' b2'
  2355                   \<longrightarrow> b1 = b1' \<and> b2 = b2'"
  2356 
  2357 lemma matrix_setsum_finite:
  2358 assumes B1: "B1 \<noteq> {}" "finite B1" and B2: "B2 \<noteq> {}" "finite B2" and u: "inj2 u B1 B2"
  2359 and ss: "setsum N1 B1 = setsum N2 B2"
  2360 shows "\<exists> M :: 'a \<Rightarrow> nat.
  2361             (\<forall> b1 \<in> B1. setsum (\<lambda> b2. M (u b1 b2)) B2 = N1 b1) \<and>
  2362             (\<forall> b2 \<in> B2. setsum (\<lambda> b1. M (u b1 b2)) B1 = N2 b2)"
  2363 proof-
  2364   obtain n1 where "card B1 = Suc n1" using B1 by (metis card_insert finite.simps)
  2365   then obtain e1 where e1: "bij_betw e1 {..<Suc n1} B1"
  2366   using ex_bij_betw_finite_nat[OF B1(2)] by (metis atLeast0LessThan bij_betw_the_inv_into)
  2367   hence e1_inj: "inj_on e1 {..<Suc n1}" and e1_surj: "e1 ` {..<Suc n1} = B1"
  2368   unfolding bij_betw_def by auto
  2369   def f1 \<equiv> "inv_into {..<Suc n1} e1"
  2370   have f1: "bij_betw f1 B1 {..<Suc n1}"
  2371   and f1e1[simp]: "\<And> i1. i1 < Suc n1 \<Longrightarrow> f1 (e1 i1) = i1"
  2372   and e1f1[simp]: "\<And> b1. b1 \<in> B1 \<Longrightarrow> e1 (f1 b1) = b1" unfolding f1_def
  2373   apply (metis bij_betw_inv_into e1, metis bij_betw_inv_into_left e1 lessThan_iff)
  2374   by (metis e1_surj f_inv_into_f)
  2375   (*  *)
  2376   obtain n2 where "card B2 = Suc n2" using B2 by (metis card_insert finite.simps)
  2377   then obtain e2 where e2: "bij_betw e2 {..<Suc n2} B2"
  2378   using ex_bij_betw_finite_nat[OF B2(2)] by (metis atLeast0LessThan bij_betw_the_inv_into)
  2379   hence e2_inj: "inj_on e2 {..<Suc n2}" and e2_surj: "e2 ` {..<Suc n2} = B2"
  2380   unfolding bij_betw_def by auto
  2381   def f2 \<equiv> "inv_into {..<Suc n2} e2"
  2382   have f2: "bij_betw f2 B2 {..<Suc n2}"
  2383   and f2e2[simp]: "\<And> i2. i2 < Suc n2 \<Longrightarrow> f2 (e2 i2) = i2"
  2384   and e2f2[simp]: "\<And> b2. b2 \<in> B2 \<Longrightarrow> e2 (f2 b2) = b2" unfolding f2_def
  2385   apply (metis bij_betw_inv_into e2, metis bij_betw_inv_into_left e2 lessThan_iff)
  2386   by (metis e2_surj f_inv_into_f)
  2387   (*  *)
  2388   let ?ct1 = "N1 o e1"  let ?ct2 = "N2 o e2"
  2389   have ss: "setsum ?ct1 {..<Suc n1} = setsum ?ct2 {..<Suc n2}"
  2390   unfolding setsum_reindex[OF e1_inj, symmetric] setsum_reindex[OF e2_inj, symmetric]
  2391   e1_surj e2_surj using ss .
  2392   obtain ct where
  2393   ct1: "\<And> i1. i1 \<le> n1 \<Longrightarrow> setsum (\<lambda> i2. ct i1 i2) {..<Suc n2} = ?ct1 i1" and
  2394   ct2: "\<And> i2. i2 \<le> n2 \<Longrightarrow> setsum (\<lambda> i1. ct i1 i2) {..<Suc n1} = ?ct2 i2"
  2395   using matrix_count[OF ss] by blast
  2396   (*  *)
  2397   def A \<equiv> "{u b1 b2 | b1 b2. b1 \<in> B1 \<and> b2 \<in> B2}"
  2398   have "\<forall> a \<in> A. \<exists> b1b2 \<in> B1 <*> B2. u (fst b1b2) (snd b1b2) = a"
  2399   unfolding A_def Ball_def mem_Collect_eq by auto
  2400   then obtain h1h2 where h12:
  2401   "\<And>a. a \<in> A \<Longrightarrow> u (fst (h1h2 a)) (snd (h1h2 a)) = a \<and> h1h2 a \<in> B1 <*> B2" by metis
  2402   def h1 \<equiv> "fst o h1h2"  def h2 \<equiv> "snd o h1h2"
  2403   have h12[simp]: "\<And>a. a \<in> A \<Longrightarrow> u (h1 a) (h2 a) = a"
  2404                   "\<And> a. a \<in> A \<Longrightarrow> h1 a \<in> B1"  "\<And> a. a \<in> A \<Longrightarrow> h2 a \<in> B2"
  2405   using h12 unfolding h1_def h2_def by force+
  2406   {fix b1 b2 assume b1: "b1 \<in> B1" and b2: "b2 \<in> B2"
  2407    hence inA: "u b1 b2 \<in> A" unfolding A_def by auto
  2408    hence "u b1 b2 = u (h1 (u b1 b2)) (h2 (u b1 b2))" by auto
  2409    moreover have "h1 (u b1 b2) \<in> B1" "h2 (u b1 b2) \<in> B2" using inA by auto
  2410    ultimately have "h1 (u b1 b2) = b1 \<and> h2 (u b1 b2) = b2"
  2411    using u b1 b2 unfolding inj2_def by fastforce
  2412   }
  2413   hence h1[simp]: "\<And> b1 b2. \<lbrakk>b1 \<in> B1; b2 \<in> B2\<rbrakk> \<Longrightarrow> h1 (u b1 b2) = b1" and
  2414         h2[simp]: "\<And> b1 b2. \<lbrakk>b1 \<in> B1; b2 \<in> B2\<rbrakk> \<Longrightarrow> h2 (u b1 b2) = b2" by auto
  2415   def M \<equiv> "\<lambda> a. ct (f1 (h1 a)) (f2 (h2 a))"
  2416   show ?thesis
  2417   apply(rule exI[of _ M]) proof safe
  2418     fix b1 assume b1: "b1 \<in> B1"
  2419     hence f1b1: "f1 b1 \<le> n1" using f1 unfolding bij_betw_def
  2420     by (metis image_eqI lessThan_iff less_Suc_eq_le)
  2421     have "(\<Sum>b2\<in>B2. M (u b1 b2)) = (\<Sum>i2<Suc n2. ct (f1 b1) (f2 (e2 i2)))"
  2422     unfolding e2_surj[symmetric] setsum_reindex[OF e2_inj]
  2423     unfolding M_def comp_def apply(intro setsum_cong) apply force
  2424     by (metis e2_surj b1 h1 h2 imageI)
  2425     also have "... = N1 b1" using b1 ct1[OF f1b1] by simp
  2426     finally show "(\<Sum>b2\<in>B2. M (u b1 b2)) = N1 b1" .
  2427   next
  2428     fix b2 assume b2: "b2 \<in> B2"
  2429     hence f2b2: "f2 b2 \<le> n2" using f2 unfolding bij_betw_def
  2430     by (metis image_eqI lessThan_iff less_Suc_eq_le)
  2431     have "(\<Sum>b1\<in>B1. M (u b1 b2)) = (\<Sum>i1<Suc n1. ct (f1 (e1 i1)) (f2 b2))"
  2432     unfolding e1_surj[symmetric] setsum_reindex[OF e1_inj]
  2433     unfolding M_def comp_def apply(intro setsum_cong) apply force
  2434     by (metis e1_surj b2 h1 h2 imageI)
  2435     also have "... = N2 b2" using b2 ct2[OF f2b2] by simp
  2436     finally show "(\<Sum>b1\<in>B1. M (u b1 b2)) = N2 b2" .
  2437   qed
  2438 qed
  2439 
  2440 lemma supp_vimage_mmap: "set_of M \<subseteq> f -` (set_of (mmap f M))"
  2441   by transfer (auto simp: multiset_def setsum_gt_0_iff)
  2442 
  2443 lemma mmap_ge_0: "b \<in># mmap f M \<longleftrightarrow> (\<exists>a. a \<in># M \<and> f a = b)"
  2444   by transfer (auto simp: multiset_def setsum_gt_0_iff)
  2445 
  2446 lemma finite_twosets:
  2447 assumes "finite B1" and "finite B2"
  2448 shows "finite {u b1 b2 |b1 b2. b1 \<in> B1 \<and> b2 \<in> B2}"  (is "finite ?A")
  2449 proof-
  2450   have A: "?A = (\<lambda> b1b2. u (fst b1b2) (snd b1b2)) ` (B1 <*> B2)" by force
  2451   show ?thesis unfolding A using finite_cartesian_product[OF assms] by auto
  2452 qed
  2453 
  2454 (* Weak pullbacks: *)
  2455 definition wpull where
  2456 "wpull A B1 B2 f1 f2 p1 p2 \<longleftrightarrow>
  2457  (\<forall> b1 b2. b1 \<in> B1 \<and> b2 \<in> B2 \<and> f1 b1 = f2 b2 \<longrightarrow> (\<exists> a \<in> A. p1 a = b1 \<and> p2 a = b2))"
  2458 
  2459 (* Weak pseudo-pullbacks *)
  2460 definition wppull where
  2461 "wppull A B1 B2 f1 f2 e1 e2 p1 p2 \<longleftrightarrow>
  2462  (\<forall> b1 b2. b1 \<in> B1 \<and> b2 \<in> B2 \<and> f1 b1 = f2 b2 \<longrightarrow>
  2463            (\<exists> a \<in> A. e1 (p1 a) = e1 b1 \<and> e2 (p2 a) = e2 b2))"
  2464 
  2465 
  2466 (* The pullback of sets *)
  2467 definition thePull where
  2468 "thePull B1 B2 f1 f2 = {(b1,b2). b1 \<in> B1 \<and> b2 \<in> B2 \<and> f1 b1 = f2 b2}"
  2469 
  2470 lemma wpull_thePull:
  2471 "wpull (thePull B1 B2 f1 f2) B1 B2 f1 f2 fst snd"
  2472 unfolding wpull_def thePull_def by auto
  2473 
  2474 lemma wppull_thePull:
  2475 assumes "wppull A B1 B2 f1 f2 e1 e2 p1 p2"
  2476 shows
  2477 "\<exists> j. \<forall> a' \<in> thePull B1 B2 f1 f2.
  2478    j a' \<in> A \<and>
  2479    e1 (p1 (j a')) = e1 (fst a') \<and> e2 (p2 (j a')) = e2 (snd a')"
  2480 (is "\<exists> j. \<forall> a' \<in> ?A'. ?phi a' (j a')")
  2481 proof(rule bchoice[of ?A' ?phi], default)
  2482   fix a' assume a': "a' \<in> ?A'"
  2483   hence "fst a' \<in> B1" unfolding thePull_def by auto
  2484   moreover
  2485   from a' have "snd a' \<in> B2" unfolding thePull_def by auto
  2486   moreover have "f1 (fst a') = f2 (snd a')"
  2487   using a' unfolding csquare_def thePull_def by auto
  2488   ultimately show "\<exists> ja'. ?phi a' ja'"
  2489   using assms unfolding wppull_def by blast
  2490 qed
  2491 
  2492 lemma wpull_wppull:
  2493 assumes wp: "wpull A' B1 B2 f1 f2 p1' p2'" and
  2494 1: "\<forall> a' \<in> A'. j a' \<in> A \<and> e1 (p1 (j a')) = e1 (p1' a') \<and> e2 (p2 (j a')) = e2 (p2' a')"
  2495 shows "wppull A B1 B2 f1 f2 e1 e2 p1 p2"
  2496 unfolding wppull_def proof safe
  2497   fix b1 b2
  2498   assume b1: "b1 \<in> B1" and b2: "b2 \<in> B2" and f: "f1 b1 = f2 b2"
  2499   then obtain a' where a': "a' \<in> A'" and b1: "b1 = p1' a'" and b2: "b2 = p2' a'"
  2500   using wp unfolding wpull_def by blast
  2501   show "\<exists>a\<in>A. e1 (p1 a) = e1 b1 \<and> e2 (p2 a) = e2 b2"
  2502   apply (rule bexI[of _ "j a'"]) unfolding b1 b2 using a' 1 by auto
  2503 qed
  2504 
  2505 lemma wppull_fstOp_sndOp:
  2506 shows "wppull (Collect (split (P OO Q))) (Collect (split P)) (Collect (split Q))
  2507   snd fst fst snd (BNF_Def.fstOp P Q) (BNF_Def.sndOp P Q)"
  2508 using pick_middlep unfolding wppull_def fstOp_def sndOp_def relcompp.simps by auto
  2509 
  2510 lemma wpull_mmap:
  2511 fixes A :: "'a set" and B1 :: "'b1 set" and B2 :: "'b2 set"
  2512 assumes wp: "wpull A B1 B2 f1 f2 p1 p2"
  2513 shows
  2514 "wpull {M. set_of M \<subseteq> A}
  2515        {N1. set_of N1 \<subseteq> B1} {N2. set_of N2 \<subseteq> B2}
  2516        (mmap f1) (mmap f2) (mmap p1) (mmap p2)"
  2517 unfolding wpull_def proof (safe, unfold Bex_def mem_Collect_eq)
  2518   fix N1 :: "'b1 multiset" and N2 :: "'b2 multiset"
  2519   assume mmap': "mmap f1 N1 = mmap f2 N2"
  2520   and N1[simp]: "set_of N1 \<subseteq> B1"
  2521   and N2[simp]: "set_of N2 \<subseteq> B2"
  2522   def P \<equiv> "mmap f1 N1"
  2523   have P1: "P = mmap f1 N1" and P2: "P = mmap f2 N2" unfolding P_def using mmap' by auto
  2524   note P = P1 P2
  2525   have fin_N1[simp]: "finite (set_of N1)"
  2526    and fin_N2[simp]: "finite (set_of N2)"
  2527    and fin_P[simp]: "finite (set_of P)" by auto
  2528 
  2529   def set1 \<equiv> "\<lambda> c. {b1 \<in> set_of N1. f1 b1 = c}"
  2530   have set1[simp]: "\<And> c b1. b1 \<in> set1 c \<Longrightarrow> f1 b1 = c" unfolding set1_def by auto
  2531   have fin_set1: "\<And> c. c \<in> set_of P \<Longrightarrow> finite (set1 c)"
  2532     using N1(1) unfolding set1_def multiset_def by auto
  2533   have set1_NE: "\<And> c. c \<in> set_of P \<Longrightarrow> set1 c \<noteq> {}"
  2534    unfolding set1_def set_of_def P mmap_ge_0 by auto
  2535   have supp_N1_set1: "set_of N1 = (\<Union> c \<in> set_of P. set1 c)"
  2536     using supp_vimage_mmap[of N1 f1] unfolding set1_def P1 by auto
  2537   hence set1_inclN1: "\<And>c. c \<in> set_of P \<Longrightarrow> set1 c \<subseteq> set_of N1" by auto
  2538   hence set1_incl: "\<And> c. c \<in> set_of P \<Longrightarrow> set1 c \<subseteq> B1" using N1 by blast
  2539   have set1_disj: "\<And> c c'. c \<noteq> c' \<Longrightarrow> set1 c \<inter> set1 c' = {}"
  2540     unfolding set1_def by auto
  2541   have setsum_set1: "\<And> c. setsum (count N1) (set1 c) = count P c"
  2542     unfolding P1 set1_def by transfer (auto intro: setsum_cong)
  2543 
  2544   def set2 \<equiv> "\<lambda> c. {b2 \<in> set_of N2. f2 b2 = c}"
  2545   have set2[simp]: "\<And> c b2. b2 \<in> set2 c \<Longrightarrow> f2 b2 = c" unfolding set2_def by auto
  2546   have fin_set2: "\<And> c. c \<in> set_of P \<Longrightarrow> finite (set2 c)"
  2547   using N2(1) unfolding set2_def multiset_def by auto
  2548   have set2_NE: "\<And> c. c \<in> set_of P \<Longrightarrow> set2 c \<noteq> {}"
  2549     unfolding set2_def P2 mmap_ge_0 set_of_def by auto
  2550   have supp_N2_set2: "set_of N2 = (\<Union> c \<in> set_of P. set2 c)"
  2551     using supp_vimage_mmap[of N2 f2] unfolding set2_def P2 by auto
  2552   hence set2_inclN2: "\<And>c. c \<in> set_of P \<Longrightarrow> set2 c \<subseteq> set_of N2" by auto
  2553   hence set2_incl: "\<And> c. c \<in> set_of P \<Longrightarrow> set2 c \<subseteq> B2" using N2 by blast
  2554   have set2_disj: "\<And> c c'. c \<noteq> c' \<Longrightarrow> set2 c \<inter> set2 c' = {}"
  2555     unfolding set2_def by auto
  2556   have setsum_set2: "\<And> c. setsum (count N2) (set2 c) = count P c"
  2557     unfolding P2 set2_def by transfer (auto intro: setsum_cong)
  2558 
  2559   have ss: "\<And> c. c \<in> set_of P \<Longrightarrow> setsum (count N1) (set1 c) = setsum (count N2) (set2 c)"
  2560     unfolding setsum_set1 setsum_set2 ..
  2561   have "\<forall> c \<in> set_of P. \<forall> b1b2 \<in> (set1 c) \<times> (set2 c).
  2562           \<exists> a \<in> A. p1 a = fst b1b2 \<and> p2 a = snd b1b2"
  2563     using wp set1_incl set2_incl unfolding wpull_def Ball_def mem_Collect_eq
  2564     by simp (metis set1 set2 set_rev_mp)
  2565   then obtain uu where uu:
  2566   "\<forall> c \<in> set_of P. \<forall> b1b2 \<in> (set1 c) \<times> (set2 c).
  2567      uu c b1b2 \<in> A \<and> p1 (uu c b1b2) = fst b1b2 \<and> p2 (uu c b1b2) = snd b1b2" by metis
  2568   def u \<equiv> "\<lambda> c b1 b2. uu c (b1,b2)"
  2569   have u[simp]:
  2570   "\<And> c b1 b2. \<lbrakk>c \<in> set_of P; b1 \<in> set1 c; b2 \<in> set2 c\<rbrakk> \<Longrightarrow> u c b1 b2 \<in> A"
  2571   "\<And> c b1 b2. \<lbrakk>c \<in> set_of P; b1 \<in> set1 c; b2 \<in> set2 c\<rbrakk> \<Longrightarrow> p1 (u c b1 b2) = b1"
  2572   "\<And> c b1 b2. \<lbrakk>c \<in> set_of P; b1 \<in> set1 c; b2 \<in> set2 c\<rbrakk> \<Longrightarrow> p2 (u c b1 b2) = b2"
  2573     using uu unfolding u_def by auto
  2574   {fix c assume c: "c \<in> set_of P"
  2575    have "inj2 (u c) (set1 c) (set2 c)" unfolding inj2_def proof clarify
  2576      fix b1 b1' b2 b2'
  2577      assume "{b1, b1'} \<subseteq> set1 c" "{b2, b2'} \<subseteq> set2 c" and 0: "u c b1 b2 = u c b1' b2'"
  2578      hence "p1 (u c b1 b2) = b1 \<and> p2 (u c b1 b2) = b2 \<and>
  2579             p1 (u c b1' b2') = b1' \<and> p2 (u c b1' b2') = b2'"
  2580      using u(2)[OF c] u(3)[OF c] by simp metis
  2581      thus "b1 = b1' \<and> b2 = b2'" using 0 by auto
  2582    qed
  2583   } note inj = this
  2584   def sset \<equiv> "\<lambda> c. {u c b1 b2 | b1 b2. b1 \<in> set1 c \<and> b2 \<in> set2 c}"
  2585   have fin_sset[simp]: "\<And> c. c \<in> set_of P \<Longrightarrow> finite (sset c)" unfolding sset_def
  2586     using fin_set1 fin_set2 finite_twosets by blast
  2587   have sset_A: "\<And> c. c \<in> set_of P \<Longrightarrow> sset c \<subseteq> A" unfolding sset_def by auto
  2588   {fix c a assume c: "c \<in> set_of P" and ac: "a \<in> sset c"
  2589    then obtain b1 b2 where b1: "b1 \<in> set1 c" and b2: "b2 \<in> set2 c"
  2590    and a: "a = u c b1 b2" unfolding sset_def by auto
  2591    have "p1 a \<in> set1 c" and p2a: "p2 a \<in> set2 c"
  2592    using ac a b1 b2 c u(2) u(3) by simp+
  2593    hence "u c (p1 a) (p2 a) = a" unfolding a using b1 b2 inj[OF c]
  2594    unfolding inj2_def by (metis c u(2) u(3))
  2595   } note u_p12[simp] = this
  2596   {fix c a assume c: "c \<in> set_of P" and ac: "a \<in> sset c"
  2597    hence "p1 a \<in> set1 c" unfolding sset_def by auto
  2598   }note p1[simp] = this
  2599   {fix c a assume c: "c \<in> set_of P" and ac: "a \<in> sset c"
  2600    hence "p2 a \<in> set2 c" unfolding sset_def by auto
  2601   }note p2[simp] = this
  2602 
  2603   {fix c assume c: "c \<in> set_of P"
  2604    hence "\<exists> M. (\<forall> b1 \<in> set1 c. setsum (\<lambda> b2. M (u c b1 b2)) (set2 c) = count N1 b1) \<and>
  2605                (\<forall> b2 \<in> set2 c. setsum (\<lambda> b1. M (u c b1 b2)) (set1 c) = count N2 b2)"
  2606    unfolding sset_def
  2607    using matrix_setsum_finite[OF set1_NE[OF c] fin_set1[OF c]
  2608                                  set2_NE[OF c] fin_set2[OF c] inj[OF c] ss[OF c]] by auto
  2609   }
  2610   then obtain Ms where
  2611   ss1: "\<And> c b1. \<lbrakk>c \<in> set_of P; b1 \<in> set1 c\<rbrakk> \<Longrightarrow>
  2612                    setsum (\<lambda> b2. Ms c (u c b1 b2)) (set2 c) = count N1 b1" and
  2613   ss2: "\<And> c b2. \<lbrakk>c \<in> set_of P; b2 \<in> set2 c\<rbrakk> \<Longrightarrow>
  2614                    setsum (\<lambda> b1. Ms c (u c b1 b2)) (set1 c) = count N2 b2"
  2615   by metis
  2616   def SET \<equiv> "\<Union> c \<in> set_of P. sset c"
  2617   have fin_SET[simp]: "finite SET" unfolding SET_def apply(rule finite_UN_I) by auto
  2618   have SET_A: "SET \<subseteq> A" unfolding SET_def using sset_A by blast
  2619   have u_SET[simp]: "\<And> c b1 b2. \<lbrakk>c \<in> set_of P; b1 \<in> set1 c; b2 \<in> set2 c\<rbrakk> \<Longrightarrow> u c b1 b2 \<in> SET"
  2620     unfolding SET_def sset_def by blast
  2621   {fix c a assume c: "c \<in> set_of P" and a: "a \<in> SET" and p1a: "p1 a \<in> set1 c"
  2622    then obtain c' where c': "c' \<in> set_of P" and ac': "a \<in> sset c'"
  2623     unfolding SET_def by auto
  2624    hence "p1 a \<in> set1 c'" unfolding sset_def by auto
  2625    hence eq: "c = c'" using p1a c c' set1_disj by auto
  2626    hence "a \<in> sset c" using ac' by simp
  2627   } note p1_rev = this
  2628   {fix c a assume c: "c \<in> set_of P" and a: "a \<in> SET" and p2a: "p2 a \<in> set2 c"
  2629    then obtain c' where c': "c' \<in> set_of P" and ac': "a \<in> sset c'"
  2630    unfolding SET_def by auto
  2631    hence "p2 a \<in> set2 c'" unfolding sset_def by auto
  2632    hence eq: "c = c'" using p2a c c' set2_disj by auto
  2633    hence "a \<in> sset c" using ac' by simp
  2634   } note p2_rev = this
  2635 
  2636   have "\<forall> a \<in> SET. \<exists> c \<in> set_of P. a \<in> sset c" unfolding SET_def by auto
  2637   then obtain h where h: "\<forall> a \<in> SET. h a \<in> set_of P \<and> a \<in> sset (h a)" by metis
  2638   have h_u[simp]: "\<And> c b1 b2. \<lbrakk>c \<in> set_of P; b1 \<in> set1 c; b2 \<in> set2 c\<rbrakk>
  2639                       \<Longrightarrow> h (u c b1 b2) = c"
  2640   by (metis h p2 set2 u(3) u_SET)
  2641   have h_u1: "\<And> c b1 b2. \<lbrakk>c \<in> set_of P; b1 \<in> set1 c; b2 \<in> set2 c\<rbrakk>
  2642                       \<Longrightarrow> h (u c b1 b2) = f1 b1"
  2643   using h unfolding sset_def by auto
  2644   have h_u2: "\<And> c b1 b2. \<lbrakk>c \<in> set_of P; b1 \<in> set1 c; b2 \<in> set2 c\<rbrakk>
  2645                       \<Longrightarrow> h (u c b1 b2) = f2 b2"
  2646   using h unfolding sset_def by auto
  2647   def M \<equiv>
  2648     "Abs_multiset (\<lambda> a. if a \<in> SET \<and> p1 a \<in> set_of N1 \<and> p2 a \<in> set_of N2 then Ms (h a) a else 0)"
  2649   have "(\<lambda> a. if a \<in> SET \<and> p1 a \<in> set_of N1 \<and> p2 a \<in> set_of N2 then Ms (h a) a else 0) \<in> multiset"
  2650     unfolding multiset_def by auto
  2651   hence [transfer_rule]: "pcr_multiset op = (\<lambda> a. if a \<in> SET \<and> p1 a \<in> set_of N1 \<and> p2 a \<in> set_of N2 then Ms (h a) a else 0) M"
  2652     unfolding M_def pcr_multiset_def cr_multiset_def by (auto simp: Abs_multiset_inverse)
  2653   have sM: "set_of M \<subseteq> SET" "set_of M \<subseteq> p1 -` (set_of N1)" "set_of M \<subseteq> p2 -` set_of N2"
  2654     by (transfer, auto split: split_if_asm)+
  2655   show "\<exists>M. set_of M \<subseteq> A \<and> mmap p1 M = N1 \<and> mmap p2 M = N2"
  2656   proof(rule exI[of _ M], safe)
  2657     fix a assume *: "a \<in> set_of M"
  2658     from SET_A show "a \<in> A"
  2659     proof (cases "a \<in> SET")
  2660       case False thus ?thesis using * by transfer' auto
  2661     qed blast
  2662   next
  2663     show "mmap p1 M = N1"
  2664     proof(intro multiset_eqI)
  2665       fix b1
  2666       let ?K = "{a. p1 a = b1 \<and> a \<in># M}"
  2667       have "setsum (count M) ?K = count N1 b1"
  2668       proof(cases "b1 \<in> set_of N1")
  2669         case False
  2670         hence "?K = {}" using sM(2) by auto
  2671         thus ?thesis using False by auto
  2672       next
  2673         case True
  2674         def c \<equiv> "f1 b1"
  2675         have c: "c \<in> set_of P" and b1: "b1 \<in> set1 c"
  2676           unfolding set1_def c_def P1 using True by (auto simp: comp_eq_dest[OF set_of_mmap])
  2677         with sM(1) have "setsum (count M) ?K = setsum (count M) {a. p1 a = b1 \<and> a \<in> SET}"
  2678           by transfer (force intro: setsum_mono_zero_cong_left split: split_if_asm)
  2679         also have "... = setsum (count M) ((\<lambda> b2. u c b1 b2) ` (set2 c))"
  2680           apply(rule setsum_cong) using c b1 proof safe
  2681           fix a assume p1a: "p1 a \<in> set1 c" and "c \<in> set_of P" and "a \<in> SET"
  2682           hence ac: "a \<in> sset c" using p1_rev by auto
  2683           hence "a = u c (p1 a) (p2 a)" using c by auto
  2684           moreover have "p2 a \<in> set2 c" using ac c by auto
  2685           ultimately show "a \<in> u c (p1 a) ` set2 c" by auto
  2686         qed auto
  2687         also have "... = setsum (\<lambda> b2. count M (u c b1 b2)) (set2 c)"
  2688           unfolding comp_def[symmetric] apply(rule setsum_reindex)
  2689           using inj unfolding inj_on_def inj2_def using b1 c u(3) by blast
  2690         also have "... = count N1 b1" unfolding ss1[OF c b1, symmetric]
  2691           apply(rule setsum_cong[OF refl]) apply (transfer fixing: Ms u c b1 set2)
  2692           using True h_u[OF c b1] set2_def u(2,3)[OF c b1] u_SET[OF c b1] by fastforce
  2693         finally show ?thesis .
  2694       qed
  2695       thus "count (mmap p1 M) b1 = count N1 b1" by transfer
  2696     qed
  2697   next
  2698     show "mmap p2 M = N2"
  2699     proof(intro multiset_eqI)
  2700       fix b2
  2701       let ?K = "{a. p2 a = b2 \<and> a \<in># M}"
  2702       have "setsum (count M) ?K = count N2 b2"
  2703       proof(cases "b2 \<in> set_of N2")
  2704         case False
  2705         hence "?K = {}" using sM(3) by auto
  2706         thus ?thesis using False by auto
  2707       next
  2708         case True
  2709         def c \<equiv> "f2 b2"
  2710         have c: "c \<in> set_of P" and b2: "b2 \<in> set2 c"
  2711           unfolding set2_def c_def P2 using True by (auto simp: comp_eq_dest[OF set_of_mmap])
  2712         with sM(1) have "setsum (count M) ?K = setsum (count M) {a. p2 a = b2 \<and> a \<in> SET}"
  2713           by transfer (force intro: setsum_mono_zero_cong_left split: split_if_asm)
  2714         also have "... = setsum (count M) ((\<lambda> b1. u c b1 b2) ` (set1 c))"
  2715           apply(rule setsum_cong) using c b2 proof safe
  2716           fix a assume p2a: "p2 a \<in> set2 c" and "c \<in> set_of P" and "a \<in> SET"
  2717           hence ac: "a \<in> sset c" using p2_rev by auto
  2718           hence "a = u c (p1 a) (p2 a)" using c by auto
  2719           moreover have "p1 a \<in> set1 c" using ac c by auto
  2720           ultimately show "a \<in> (\<lambda>x. u c x (p2 a)) ` set1 c" by auto
  2721         qed auto
  2722         also have "... = setsum (count M o (\<lambda> b1. u c b1 b2)) (set1 c)"
  2723           apply(rule setsum_reindex)
  2724           using inj unfolding inj_on_def inj2_def using b2 c u(2) by blast
  2725         also have "... = setsum (\<lambda> b1. count M (u c b1 b2)) (set1 c)" by simp
  2726         also have "... = count N2 b2" unfolding ss2[OF c b2, symmetric] comp_def
  2727           apply(rule setsum_cong[OF refl]) apply (transfer fixing: Ms u c b2 set1)
  2728           using True h_u1[OF c _ b2] u(2,3)[OF c _ b2] u_SET[OF c _ b2] set1_def by fastforce
  2729         finally show ?thesis .
  2730       qed
  2731       thus "count (mmap p2 M) b2 = count N2 b2" by transfer
  2732     qed
  2733   qed
  2734 qed
  2735 
  2736 lemma set_of_bd: "(card_of (set_of x), natLeq) \<in> ordLeq"
  2737   by transfer
  2738     (auto intro!: ordLess_imp_ordLeq simp: finite_iff_ordLess_natLeq[symmetric] multiset_def)
  2739 
  2740 lemma wppull_mmap:
  2741   assumes "wppull A B1 B2 f1 f2 e1 e2 p1 p2"
  2742   shows "wppull {M. set_of M \<subseteq> A} {N1. set_of N1 \<subseteq> B1} {N2. set_of N2 \<subseteq> B2}
  2743     (mmap f1) (mmap f2) (mmap e1) (mmap e2) (mmap p1) (mmap p2)"
  2744 proof -
  2745   from assms obtain j where j: "\<forall>a'\<in>thePull B1 B2 f1 f2.
  2746     j a' \<in> A \<and> e1 (p1 (j a')) = e1 (fst a') \<and> e2 (p2 (j a')) = e2 (snd a')" 
  2747     by (blast dest: wppull_thePull)
  2748   then show ?thesis
  2749     by (intro wpull_wppull[OF wpull_mmap[OF wpull_thePull], of _ _ _ _ "mmap j"])
  2750       (auto simp: comp_eq_dest_lhs[OF mmap_comp[symmetric]] comp_eq_dest[OF set_of_mmap]
  2751         intro!: mmap_cong simp del: mem_set_of_iff simp: mem_set_of_iff[symmetric])
  2752 qed
  2753 
  2754 bnf "'a multiset"
  2755   map: mmap
  2756   sets: set_of 
  2757   bd: natLeq
  2758   wits: "{#}"
  2759 by (auto simp add: mmap_id0 mmap_comp set_of_mmap natLeq_card_order natLeq_cinfinite set_of_bd
  2760   Grp_def relcompp.simps intro: mmap_cong)
  2761   (metis wppull_mmap[OF wppull_fstOp_sndOp, unfolded wppull_def
  2762     o_eq_dest_lhs[OF mmap_comp[symmetric]] fstOp_def sndOp_def comp_def, simplified])
  2763 
  2764 inductive rel_multiset' where
  2765   Zero[intro]: "rel_multiset' R {#} {#}"
  2766 | Plus[intro]: "\<lbrakk>R a b; rel_multiset' R M N\<rbrakk> \<Longrightarrow> rel_multiset' R (M + {#a#}) (N + {#b#})"
  2767 
  2768 lemma map_multiset_Zero_iff[simp]: "mmap f M = {#} \<longleftrightarrow> M = {#}"
  2769 by (metis image_is_empty multiset.set_map set_of_eq_empty_iff)
  2770 
  2771 lemma map_multiset_Zero[simp]: "mmap f {#} = {#}" by simp
  2772 
  2773 lemma rel_multiset_Zero: "rel_multiset R {#} {#}"
  2774 unfolding rel_multiset_def Grp_def by auto
  2775 
  2776 declare multiset.count[simp]
  2777 declare Abs_multiset_inverse[simp]
  2778 declare multiset.count_inverse[simp]
  2779 declare union_preserves_multiset[simp]
  2780 
  2781 lemma map_multiset_Plus[simp]: "mmap f (M1 + M2) = mmap f M1 + mmap f M2"
  2782 proof (intro multiset_eqI, transfer fixing: f)
  2783   fix x :: 'a and M1 M2 :: "'b \<Rightarrow> nat"
  2784   assume "M1 \<in> multiset" "M2 \<in> multiset"
  2785   hence "setsum M1 {a. f a = x \<and> 0 < M1 a} = setsum M1 {a. f a = x \<and> 0 < M1 a + M2 a}"
  2786         "setsum M2 {a. f a = x \<and> 0 < M2 a} = setsum M2 {a. f a = x \<and> 0 < M1 a + M2 a}"
  2787     by (auto simp: multiset_def intro!: setsum_mono_zero_cong_left)
  2788   then show "(\<Sum>a | f a = x \<and> 0 < M1 a + M2 a. M1 a + M2 a) =
  2789        setsum M1 {a. f a = x \<and> 0 < M1 a} +
  2790        setsum M2 {a. f a = x \<and> 0 < M2 a}"
  2791     by (auto simp: setsum.distrib[symmetric])
  2792 qed
  2793 
  2794 lemma map_multiset_single[simp]: "mmap f {#a#} = {#f a#}"
  2795   by transfer auto
  2796 
  2797 lemma rel_multiset_Plus:
  2798 assumes ab: "R a b" and MN: "rel_multiset R M N"
  2799 shows "rel_multiset R (M + {#a#}) (N + {#b#})"
  2800 proof-
  2801   {fix y assume "R a b" and "set_of y \<subseteq> {(x, y). R x y}"
  2802    hence "\<exists>ya. mmap fst y + {#a#} = mmap fst ya \<and>
  2803                mmap snd y + {#b#} = mmap snd ya \<and>
  2804                set_of ya \<subseteq> {(x, y). R x y}"
  2805    apply(intro exI[of _ "y + {#(a,b)#}"]) by auto
  2806   }
  2807   thus ?thesis
  2808   using assms
  2809   unfolding rel_multiset_def Grp_def by force
  2810 qed
  2811 
  2812 lemma rel_multiset'_imp_rel_multiset:
  2813 "rel_multiset' R M N \<Longrightarrow> rel_multiset R M N"
  2814 apply(induct rule: rel_multiset'.induct)
  2815 using rel_multiset_Zero rel_multiset_Plus by auto
  2816 
  2817 lemma mcard_mmap[simp]: "mcard (mmap f M) = mcard M"
  2818 proof -
  2819   def A \<equiv> "\<lambda> b. {a. f a = b \<and> a \<in># M}"
  2820   let ?B = "{b. 0 < setsum (count M) (A b)}"
  2821   have "{b. \<exists>a. f a = b \<and> a \<in># M} \<subseteq> f ` {a. a \<in># M}" by auto
  2822   moreover have "finite (f ` {a. a \<in># M})" apply(rule finite_imageI)
  2823   using finite_Collect_mem .
  2824   ultimately have fin: "finite {b. \<exists>a. f a = b \<and> a \<in># M}" by(rule finite_subset)
  2825   have i: "inj_on A ?B" unfolding inj_on_def A_def apply clarsimp
  2826     by (metis (lifting, full_types) mem_Collect_eq neq0_conv setsum.neutral)
  2827   have 0: "\<And> b. 0 < setsum (count M) (A b) \<longleftrightarrow> (\<exists> a \<in> A b. count M a > 0)"
  2828   apply safe
  2829     apply (metis less_not_refl setsum_gt_0_iff setsum_infinite)
  2830     by (metis A_def finite_Collect_conjI finite_Collect_mem setsum_gt_0_iff)
  2831   hence AB: "A ` ?B = {A b | b. \<exists> a \<in> A b. count M a > 0}" by auto
  2832 
  2833   have "setsum (\<lambda> x. setsum (count M) (A x)) ?B = setsum (setsum (count M) o A) ?B"
  2834   unfolding comp_def ..
  2835   also have "... = (\<Sum>x\<in> A ` ?B. setsum (count M) x)"
  2836   unfolding setsum.reindex [OF i, symmetric] ..
  2837   also have "... = setsum (count M) (\<Union>x\<in>A ` {b. 0 < setsum (count M) (A b)}. x)"
  2838   (is "_ = setsum (count M) ?J")
  2839   apply(rule setsum.UNION_disjoint[symmetric])
  2840   using 0 fin unfolding A_def by auto
  2841   also have "?J = {a. a \<in># M}" unfolding AB unfolding A_def by auto
  2842   finally have "setsum (\<lambda> x. setsum (count M) (A x)) ?B =
  2843                 setsum (count M) {a. a \<in># M}" .
  2844   then show ?thesis unfolding mcard_unfold_setsum A_def by transfer
  2845 qed
  2846 
  2847 lemma rel_multiset_mcard:
  2848 assumes "rel_multiset R M N"
  2849 shows "mcard M = mcard N"
  2850 using assms unfolding rel_multiset_def Grp_def by auto
  2851 
  2852 lemma multiset_induct2[case_names empty addL addR]:
  2853 assumes empty: "P {#} {#}"
  2854 and addL: "\<And>M N a. P M N \<Longrightarrow> P (M + {#a#}) N"
  2855 and addR: "\<And>M N a. P M N \<Longrightarrow> P M (N + {#a#})"
  2856 shows "P M N"
  2857 apply(induct N rule: multiset_induct)
  2858   apply(induct M rule: multiset_induct, rule empty, erule addL)
  2859   apply(induct M rule: multiset_induct, erule addR, erule addR)
  2860 done
  2861 
  2862 lemma multiset_induct2_mcard[consumes 1, case_names empty add]:
  2863 assumes c: "mcard M = mcard N"
  2864 and empty: "P {#} {#}"
  2865 and add: "\<And>M N a b. P M N \<Longrightarrow> P (M + {#a#}) (N + {#b#})"
  2866 shows "P M N"
  2867 using c proof(induct M arbitrary: N rule: measure_induct_rule[of mcard])
  2868   case (less M)  show ?case
  2869   proof(cases "M = {#}")
  2870     case True hence "N = {#}" using less.prems by auto
  2871     thus ?thesis using True empty by auto
  2872   next
  2873     case False then obtain M1 a where M: "M = M1 + {#a#}" by (metis multi_nonempty_split)
  2874     have "N \<noteq> {#}" using False less.prems by auto
  2875     then obtain N1 b where N: "N = N1 + {#b#}" by (metis multi_nonempty_split)
  2876     have "mcard M1 = mcard N1" using less.prems unfolding M N by auto
  2877     thus ?thesis using M N less.hyps add by auto
  2878   qed
  2879 qed
  2880 
  2881 lemma msed_map_invL:
  2882 assumes "mmap f (M + {#a#}) = N"
  2883 shows "\<exists> N1. N = N1 + {#f a#} \<and> mmap f M = N1"
  2884 proof-
  2885   have "f a \<in># N"
  2886   using assms multiset.set_map[of f "M + {#a#}"] by auto
  2887   then obtain N1 where N: "N = N1 + {#f a#}" using multi_member_split by metis
  2888   have "mmap f M = N1" using assms unfolding N by simp
  2889   thus ?thesis using N by blast
  2890 qed
  2891 
  2892 lemma msed_map_invR:
  2893 assumes "mmap f M = N + {#b#}"
  2894 shows "\<exists> M1 a. M = M1 + {#a#} \<and> f a = b \<and> mmap f M1 = N"
  2895 proof-
  2896   obtain a where a: "a \<in># M" and fa: "f a = b"
  2897   using multiset.set_map[of f M] unfolding assms
  2898   by (metis image_iff mem_set_of_iff union_single_eq_member)
  2899   then obtain M1 where M: "M = M1 + {#a#}" using multi_member_split by metis
  2900   have "mmap f M1 = N" using assms unfolding M fa[symmetric] by simp
  2901   thus ?thesis using M fa by blast
  2902 qed
  2903 
  2904 lemma msed_rel_invL:
  2905 assumes "rel_multiset R (M + {#a#}) N"
  2906 shows "\<exists> N1 b. N = N1 + {#b#} \<and> R a b \<and> rel_multiset R M N1"
  2907 proof-
  2908   obtain K where KM: "mmap fst K = M + {#a#}"
  2909   and KN: "mmap snd K = N" and sK: "set_of K \<subseteq> {(a, b). R a b}"
  2910   using assms
  2911   unfolding rel_multiset_def Grp_def by auto
  2912   obtain K1 ab where K: "K = K1 + {#ab#}" and a: "fst ab = a"
  2913   and K1M: "mmap fst K1 = M" using msed_map_invR[OF KM] by auto
  2914   obtain N1 where N: "N = N1 + {#snd ab#}" and K1N1: "mmap snd K1 = N1"
  2915   using msed_map_invL[OF KN[unfolded K]] by auto
  2916   have Rab: "R a (snd ab)" using sK a unfolding K by auto
  2917   have "rel_multiset R M N1" using sK K1M K1N1
  2918   unfolding K rel_multiset_def Grp_def by auto
  2919   thus ?thesis using N Rab by auto
  2920 qed
  2921 
  2922 lemma msed_rel_invR:
  2923 assumes "rel_multiset R M (N + {#b#})"
  2924 shows "\<exists> M1 a. M = M1 + {#a#} \<and> R a b \<and> rel_multiset R M1 N"
  2925 proof-
  2926   obtain K where KN: "mmap snd K = N + {#b#}"
  2927   and KM: "mmap fst K = M" and sK: "set_of K \<subseteq> {(a, b). R a b}"
  2928   using assms
  2929   unfolding rel_multiset_def Grp_def by auto
  2930   obtain K1 ab where K: "K = K1 + {#ab#}" and b: "snd ab = b"
  2931   and K1N: "mmap snd K1 = N" using msed_map_invR[OF KN] by auto
  2932   obtain M1 where M: "M = M1 + {#fst ab#}" and K1M1: "mmap fst K1 = M1"
  2933   using msed_map_invL[OF KM[unfolded K]] by auto
  2934   have Rab: "R (fst ab) b" using sK b unfolding K by auto
  2935   have "rel_multiset R M1 N" using sK K1N K1M1
  2936   unfolding K rel_multiset_def Grp_def by auto
  2937   thus ?thesis using M Rab by auto
  2938 qed
  2939 
  2940 lemma rel_multiset_imp_rel_multiset':
  2941 assumes "rel_multiset R M N"
  2942 shows "rel_multiset' R M N"
  2943 using assms proof(induct M arbitrary: N rule: measure_induct_rule[of mcard])
  2944   case (less M)
  2945   have c: "mcard M = mcard N" using rel_multiset_mcard[OF less.prems] .
  2946   show ?case
  2947   proof(cases "M = {#}")
  2948     case True hence "N = {#}" using c by simp
  2949     thus ?thesis using True rel_multiset'.Zero by auto
  2950   next
  2951     case False then obtain M1 a where M: "M = M1 + {#a#}" by (metis multi_nonempty_split)
  2952     obtain N1 b where N: "N = N1 + {#b#}" and R: "R a b" and ms: "rel_multiset R M1 N1"
  2953     using msed_rel_invL[OF less.prems[unfolded M]] by auto
  2954     have "rel_multiset' R M1 N1" using less.hyps[of M1 N1] ms unfolding M by simp
  2955     thus ?thesis using rel_multiset'.Plus[of R a b, OF R] unfolding M N by simp
  2956   qed
  2957 qed
  2958 
  2959 lemma rel_multiset_rel_multiset':
  2960 "rel_multiset R M N = rel_multiset' R M N"
  2961 using  rel_multiset_imp_rel_multiset' rel_multiset'_imp_rel_multiset by auto
  2962 
  2963 (* The main end product for rel_multiset: inductive characterization *)
  2964 theorems rel_multiset_induct[case_names empty add, induct pred: rel_multiset] =
  2965          rel_multiset'.induct[unfolded rel_multiset_rel_multiset'[symmetric]]
  2966 
  2967 end