src/FOLP/intprover.ML
 author wenzelm Mon Nov 10 21:49:48 2014 +0100 (2014-11-10) changeset 58963 26bf09b95dda parent 52457 c3b4b74a54fd child 59498 50b60f501b05 permissions -rw-r--r--
proper context for assume_tac (atac remains as fall-back without context);
1 (*  Title:      FOLP/intprover.ML
2     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
3     Copyright   1992  University of Cambridge
5 A naive prover for intuitionistic logic
7 BEWARE OF NAME CLASHES WITH CLASSICAL TACTICS -- use IntPr.fast_tac ...
9 Completeness (for propositional logic) is proved in
11 Roy Dyckhoff.
12 Contraction-Free Sequent Calculi for Intuitionistic Logic.
13 J. Symbolic Logic (in press)
14 *)
16 signature INT_PROVER =
17   sig
18   val best_tac: Proof.context -> int -> tactic
19   val fast_tac: Proof.context -> int -> tactic
20   val inst_step_tac: Proof.context -> int -> tactic
21   val safe_step_tac: Proof.context -> int -> tactic
22   val safe_brls: (bool * thm) list
23   val safe_tac: Proof.context -> tactic
24   val step_tac: Proof.context -> int -> tactic
25   val haz_brls: (bool * thm) list
26   end;
29 structure IntPr : INT_PROVER   =
30 struct
32 (*Negation is treated as a primitive symbol, with rules notI (introduction),
33   not_to_imp (converts the assumption ~P to P-->False), and not_impE
34   (handles double negations).  Could instead rewrite by not_def as the first
35   step of an intuitionistic proof.
36 *)
37 val safe_brls = sort (make_ord lessb)
38     [ (true, @{thm FalseE}), (false, @{thm TrueI}), (false, @{thm refl}),
39       (false, @{thm impI}), (false, @{thm notI}), (false, @{thm allI}),
40       (true, @{thm conjE}), (true, @{thm exE}),
41       (false, @{thm conjI}), (true, @{thm conj_impE}),
42       (true, @{thm disj_impE}), (true, @{thm disjE}),
43       (false, @{thm iffI}), (true, @{thm iffE}), (true, @{thm not_to_imp}) ];
45 val haz_brls =
46     [ (false, @{thm disjI1}), (false, @{thm disjI2}), (false, @{thm exI}),
47       (true, @{thm allE}), (true, @{thm not_impE}), (true, @{thm imp_impE}), (true, @{thm iff_impE}),
48       (true, @{thm all_impE}), (true, @{thm ex_impE}), (true, @{thm impE}) ];
50 (*0 subgoals vs 1 or more: the p in safep is for positive*)
51 val (safe0_brls, safep_brls) =
52     List.partition (curry (op =) 0 o subgoals_of_brl) safe_brls;
54 (*Attack subgoals using safe inferences*)
55 fun safe_step_tac ctxt = FIRST' [uniq_assume_tac ctxt,
56                             int_uniq_mp_tac ctxt,
57                             biresolve_tac safe0_brls,
58                             hyp_subst_tac,
59                             biresolve_tac safep_brls] ;
61 (*Repeatedly attack subgoals using safe inferences*)
62 fun safe_tac ctxt = DETERM (REPEAT_FIRST (safe_step_tac ctxt));
64 (*These steps could instantiate variables and are therefore unsafe.*)
65 fun inst_step_tac ctxt = assume_tac ctxt APPEND' mp_tac ctxt;
67 (*One safe or unsafe step. *)
68 fun step_tac ctxt i = FIRST [safe_tac ctxt, inst_step_tac ctxt i, biresolve_tac haz_brls i];
70 (*Dumb but fast*)
71 fun fast_tac ctxt = SELECT_GOAL (DEPTH_SOLVE (step_tac ctxt 1));
73 (*Slower but smarter than fast_tac*)
74 fun best_tac ctxt =
75   SELECT_GOAL (BEST_FIRST (has_fewer_prems 1, size_of_thm) (step_tac ctxt 1));
77 end;