src/HOL/List.ML
author nipkow
Fri Sep 04 11:01:59 1998 +0200 (1998-09-04)
changeset 5427 26c9a7c0b36b
parent 5425 157c6663dedd
child 5443 e2459d18ff47
permissions -rw-r--r--
Arith: less_diff_conv
List: [i..j]
     1 (*  Title:      HOL/List
     2     ID:         $Id$
     3     Author:     Tobias Nipkow
     4     Copyright   1994 TU Muenchen
     5 
     6 List lemmas
     7 *)
     8 
     9 Goal "!x. xs ~= x#xs";
    10 by (induct_tac "xs" 1);
    11 by Auto_tac;
    12 qed_spec_mp "not_Cons_self";
    13 bind_thm("not_Cons_self2",not_Cons_self RS not_sym);
    14 Addsimps [not_Cons_self,not_Cons_self2];
    15 
    16 Goal "(xs ~= []) = (? y ys. xs = y#ys)";
    17 by (induct_tac "xs" 1);
    18 by Auto_tac;
    19 qed "neq_Nil_conv";
    20 
    21 (* Induction over the length of a list: *)
    22 val [prem] = Goal
    23   "(!!xs. (!ys. length ys < length xs --> P ys) ==> P xs) ==> P(xs)";
    24 by (rtac measure_induct 1 THEN etac prem 1);
    25 qed "length_induct";
    26 
    27 
    28 (** "lists": the list-forming operator over sets **)
    29 
    30 Goalw lists.defs "A<=B ==> lists A <= lists B";
    31 by (rtac lfp_mono 1);
    32 by (REPEAT (ares_tac basic_monos 1));
    33 qed "lists_mono";
    34 
    35 val listsE = lists.mk_cases list.simps  "x#l : lists A";
    36 AddSEs [listsE];
    37 AddSIs lists.intrs;
    38 
    39 Goal "l: lists A ==> l: lists B --> l: lists (A Int B)";
    40 by (etac lists.induct 1);
    41 by (ALLGOALS Blast_tac);
    42 qed_spec_mp "lists_IntI";
    43 
    44 Goal "lists (A Int B) = lists A Int lists B";
    45 by (rtac (mono_Int RS equalityI) 1);
    46 by (simp_tac (simpset() addsimps [mono_def, lists_mono]) 1);
    47 by (blast_tac (claset() addSIs [lists_IntI]) 1);
    48 qed "lists_Int_eq";
    49 Addsimps [lists_Int_eq];
    50 
    51 
    52 (**  Case analysis **)
    53 section "Case analysis";
    54 
    55 val prems = Goal "[| P([]); !!x xs. P(x#xs) |] ==> P(xs)";
    56 by (induct_tac "xs" 1);
    57 by (REPEAT(resolve_tac prems 1));
    58 qed "list_cases";
    59 
    60 Goal "(xs=[] --> P([])) & (!y ys. xs=y#ys --> P(y#ys)) --> P(xs)";
    61 by (induct_tac "xs" 1);
    62 by (Blast_tac 1);
    63 by (Blast_tac 1);
    64 bind_thm("list_eq_cases",
    65   impI RSN (2,allI RSN (2,allI RSN (2,impI RS (conjI RS (result() RS mp))))));
    66 
    67 (** length **)
    68 (* needs to come before "@" because of thm append_eq_append_conv *)
    69 
    70 section "length";
    71 
    72 Goal "length(xs@ys) = length(xs)+length(ys)";
    73 by (induct_tac "xs" 1);
    74 by Auto_tac;
    75 qed"length_append";
    76 Addsimps [length_append];
    77 
    78 Goal "length (map f xs) = length xs";
    79 by (induct_tac "xs" 1);
    80 by Auto_tac;
    81 qed "length_map";
    82 Addsimps [length_map];
    83 
    84 Goal "length(rev xs) = length(xs)";
    85 by (induct_tac "xs" 1);
    86 by Auto_tac;
    87 qed "length_rev";
    88 Addsimps [length_rev];
    89 
    90 Goal "xs ~= [] ==> length(tl xs) = (length xs) - 1";
    91 by (exhaust_tac "xs" 1);
    92 by Auto_tac;
    93 qed "length_tl";
    94 Addsimps [length_tl];
    95 
    96 Goal "(length xs = 0) = (xs = [])";
    97 by (induct_tac "xs" 1);
    98 by Auto_tac;
    99 qed "length_0_conv";
   100 AddIffs [length_0_conv];
   101 
   102 Goal "(0 = length xs) = (xs = [])";
   103 by (induct_tac "xs" 1);
   104 by Auto_tac;
   105 qed "zero_length_conv";
   106 AddIffs [zero_length_conv];
   107 
   108 Goal "(0 < length xs) = (xs ~= [])";
   109 by (induct_tac "xs" 1);
   110 by Auto_tac;
   111 qed "length_greater_0_conv";
   112 AddIffs [length_greater_0_conv];
   113 
   114 Goal "(length xs = Suc n) = (? y ys. xs = y#ys & length ys = n)";
   115 by (induct_tac "xs" 1);
   116 by (Auto_tac);
   117 qed "length_Suc_conv";
   118 AddIffs [length_Suc_conv];
   119 
   120 (** @ - append **)
   121 
   122 section "@ - append";
   123 
   124 Goal "(xs@ys)@zs = xs@(ys@zs)";
   125 by (induct_tac "xs" 1);
   126 by Auto_tac;
   127 qed "append_assoc";
   128 Addsimps [append_assoc];
   129 
   130 Goal "xs @ [] = xs";
   131 by (induct_tac "xs" 1);
   132 by Auto_tac;
   133 qed "append_Nil2";
   134 Addsimps [append_Nil2];
   135 
   136 Goal "(xs@ys = []) = (xs=[] & ys=[])";
   137 by (induct_tac "xs" 1);
   138 by Auto_tac;
   139 qed "append_is_Nil_conv";
   140 AddIffs [append_is_Nil_conv];
   141 
   142 Goal "([] = xs@ys) = (xs=[] & ys=[])";
   143 by (induct_tac "xs" 1);
   144 by Auto_tac;
   145 qed "Nil_is_append_conv";
   146 AddIffs [Nil_is_append_conv];
   147 
   148 Goal "(xs @ ys = xs) = (ys=[])";
   149 by (induct_tac "xs" 1);
   150 by Auto_tac;
   151 qed "append_self_conv";
   152 
   153 Goal "(xs = xs @ ys) = (ys=[])";
   154 by (induct_tac "xs" 1);
   155 by Auto_tac;
   156 qed "self_append_conv";
   157 AddIffs [append_self_conv,self_append_conv];
   158 
   159 Goal "!ys. length xs = length ys | length us = length vs \
   160 \              --> (xs@us = ys@vs) = (xs=ys & us=vs)";
   161 by (induct_tac "xs" 1);
   162  by (rtac allI 1);
   163  by (exhaust_tac "ys" 1);
   164   by (Asm_simp_tac 1);
   165  by (fast_tac (claset() addIs [less_add_Suc2] addss simpset()
   166                       addEs [less_not_refl2 RSN (2,rev_notE)]) 1);
   167 by (rtac allI 1);
   168 by (exhaust_tac "ys" 1);
   169 by (fast_tac (claset() addIs [less_add_Suc2] 
   170 		       addss (simpset() delsimps [length_Suc_conv])
   171                        addEs [(less_not_refl3) RSN (2,rev_notE)]) 1);
   172 by (Asm_simp_tac 1);
   173 qed_spec_mp "append_eq_append_conv";
   174 Addsimps [append_eq_append_conv];
   175 
   176 Goal "(xs @ ys = xs @ zs) = (ys=zs)";
   177 by (Simp_tac 1);
   178 qed "same_append_eq";
   179 
   180 Goal "(xs @ [x] = ys @ [y]) = (xs = ys & x = y)"; 
   181 by (Simp_tac 1);
   182 qed "append1_eq_conv";
   183 
   184 Goal "(ys @ xs = zs @ xs) = (ys=zs)";
   185 by (Simp_tac 1);
   186 qed "append_same_eq";
   187 
   188 AddSIs
   189  [same_append_eq RS iffD2, append1_eq_conv RS iffD2, append_same_eq RS iffD2];
   190 AddSDs
   191  [same_append_eq RS iffD1, append1_eq_conv RS iffD1, append_same_eq RS iffD1];
   192 
   193 Goal "(xs @ ys = ys) = (xs=[])";
   194 by (cut_inst_tac [("zs","[]")] append_same_eq 1);
   195 by Auto_tac;
   196 qed "append_self_conv2";
   197 
   198 Goal "(ys = xs @ ys) = (xs=[])";
   199 by (simp_tac (simpset() addsimps
   200      [simplify (simpset()) (read_instantiate[("ys","[]")]append_same_eq)]) 1);
   201 by (Blast_tac 1);
   202 qed "self_append_conv2";
   203 AddIffs [append_self_conv2,self_append_conv2];
   204 
   205 Goal "xs ~= [] --> hd xs # tl xs = xs";
   206 by (induct_tac "xs" 1);
   207 by Auto_tac;
   208 qed_spec_mp "hd_Cons_tl";
   209 Addsimps [hd_Cons_tl];
   210 
   211 Goal "hd(xs@ys) = (if xs=[] then hd ys else hd xs)";
   212 by (induct_tac "xs" 1);
   213 by Auto_tac;
   214 qed "hd_append";
   215 
   216 Goal "xs ~= [] ==> hd(xs @ ys) = hd xs";
   217 by (asm_simp_tac (simpset() addsimps [hd_append]
   218                            addsplits [list.split]) 1);
   219 qed "hd_append2";
   220 Addsimps [hd_append2];
   221 
   222 Goal "tl(xs@ys) = (case xs of [] => tl(ys) | z#zs => zs@ys)";
   223 by (simp_tac (simpset() addsplits [list.split]) 1);
   224 qed "tl_append";
   225 
   226 Goal "xs ~= [] ==> tl(xs @ ys) = (tl xs) @ ys";
   227 by (asm_simp_tac (simpset() addsimps [tl_append]
   228                            addsplits [list.split]) 1);
   229 qed "tl_append2";
   230 Addsimps [tl_append2];
   231 
   232 (* trivial rules for solving @-equations automatically *)
   233 
   234 Goal "xs = ys ==> xs = [] @ ys";
   235 by (Asm_simp_tac 1);
   236 qed "eq_Nil_appendI";
   237 
   238 Goal "[| x#xs1 = ys; xs = xs1 @ zs |] ==> x#xs = ys@zs";
   239 by (dtac sym 1);
   240 by (Asm_simp_tac 1);
   241 qed "Cons_eq_appendI";
   242 
   243 Goal "[| xs@xs1 = zs; ys = xs1 @ us |] ==> xs@ys = zs@us";
   244 by (dtac sym 1);
   245 by (Asm_simp_tac 1);
   246 qed "append_eq_appendI";
   247 
   248 
   249 (***
   250 Simplification procedure for all list equalities.
   251 Currently only tries to rearranges @ to see if
   252 - both lists end in a singleton list,
   253 - or both lists end in the same list.
   254 ***)
   255 local
   256 
   257 val list_eq_pattern =
   258   read_cterm (sign_of List.thy) ("(xs::'a list) = ys",HOLogic.boolT);
   259 
   260 fun last (cons as Const("List.list.op #",_) $ _ $ xs) =
   261       (case xs of Const("List.list.[]",_) => cons | _ => last xs)
   262   | last (Const("List.op @",_) $ _ $ ys) = last ys
   263   | last t = t;
   264 
   265 fun list1 (Const("List.list.op #",_) $ _ $ Const("List.list.[]",_)) = true
   266   | list1 _ = false;
   267 
   268 fun butlast ((cons as Const("List.list.op #",_) $ x) $ xs) =
   269       (case xs of Const("List.list.[]",_) => xs | _ => cons $ butlast xs)
   270   | butlast ((app as Const("List.op @",_) $ xs) $ ys) = app $ butlast ys
   271   | butlast xs = Const("List.list.[]",fastype_of xs);
   272 
   273 val rearr_tac =
   274   simp_tac (HOL_basic_ss addsimps [append_assoc,append_Nil,append_Cons]);
   275 
   276 fun list_eq sg _ (F as (eq as Const(_,eqT)) $ lhs $ rhs) =
   277   let
   278     val lastl = last lhs and lastr = last rhs
   279     fun rearr conv =
   280       let val lhs1 = butlast lhs and rhs1 = butlast rhs
   281           val Type(_,listT::_) = eqT
   282           val appT = [listT,listT] ---> listT
   283           val app = Const("List.op @",appT)
   284           val F2 = eq $ (app$lhs1$lastl) $ (app$rhs1$lastr)
   285           val ct = cterm_of sg (HOLogic.mk_Trueprop(HOLogic.mk_eq(F,F2)))
   286           val thm = prove_goalw_cterm [] ct (K [rearr_tac 1])
   287             handle ERROR =>
   288             error("The error(s) above occurred while trying to prove " ^
   289                   string_of_cterm ct)
   290       in Some((conv RS (thm RS trans)) RS eq_reflection) end
   291 
   292   in if list1 lastl andalso list1 lastr
   293      then rearr append1_eq_conv
   294      else
   295      if lastl aconv lastr
   296      then rearr append_same_eq
   297      else None
   298   end;
   299 in
   300 val list_eq_simproc = mk_simproc "list_eq" [list_eq_pattern] list_eq;
   301 end;
   302 
   303 Addsimprocs [list_eq_simproc];
   304 
   305 
   306 (** map **)
   307 
   308 section "map";
   309 
   310 Goal "(!x. x : set xs --> f x = g x) --> map f xs = map g xs";
   311 by (induct_tac "xs" 1);
   312 by Auto_tac;
   313 bind_thm("map_ext", impI RS (allI RS (result() RS mp)));
   314 
   315 Goal "map (%x. x) = (%xs. xs)";
   316 by (rtac ext 1);
   317 by (induct_tac "xs" 1);
   318 by Auto_tac;
   319 qed "map_ident";
   320 Addsimps[map_ident];
   321 
   322 Goal "map f (xs@ys) = map f xs @ map f ys";
   323 by (induct_tac "xs" 1);
   324 by Auto_tac;
   325 qed "map_append";
   326 Addsimps[map_append];
   327 
   328 Goalw [o_def] "map (f o g) xs = map f (map g xs)";
   329 by (induct_tac "xs" 1);
   330 by Auto_tac;
   331 qed "map_compose";
   332 Addsimps[map_compose];
   333 
   334 Goal "rev(map f xs) = map f (rev xs)";
   335 by (induct_tac "xs" 1);
   336 by Auto_tac;
   337 qed "rev_map";
   338 
   339 (* a congruence rule for map: *)
   340 Goal "(xs=ys) --> (!x. x : set ys --> f x = g x) --> map f xs = map g ys";
   341 by (rtac impI 1);
   342 by (hyp_subst_tac 1);
   343 by (induct_tac "ys" 1);
   344 by Auto_tac;
   345 val lemma = result();
   346 bind_thm("map_cong",impI RSN (2,allI RSN (2,lemma RS mp RS mp)));
   347 
   348 Goal "(map f xs = []) = (xs = [])";
   349 by (induct_tac "xs" 1);
   350 by Auto_tac;
   351 qed "map_is_Nil_conv";
   352 AddIffs [map_is_Nil_conv];
   353 
   354 Goal "([] = map f xs) = (xs = [])";
   355 by (induct_tac "xs" 1);
   356 by Auto_tac;
   357 qed "Nil_is_map_conv";
   358 AddIffs [Nil_is_map_conv];
   359 
   360 
   361 (** rev **)
   362 
   363 section "rev";
   364 
   365 Goal "rev(xs@ys) = rev(ys) @ rev(xs)";
   366 by (induct_tac "xs" 1);
   367 by Auto_tac;
   368 qed "rev_append";
   369 Addsimps[rev_append];
   370 
   371 Goal "rev(rev l) = l";
   372 by (induct_tac "l" 1);
   373 by Auto_tac;
   374 qed "rev_rev_ident";
   375 Addsimps[rev_rev_ident];
   376 
   377 Goal "(rev xs = []) = (xs = [])";
   378 by (induct_tac "xs" 1);
   379 by Auto_tac;
   380 qed "rev_is_Nil_conv";
   381 AddIffs [rev_is_Nil_conv];
   382 
   383 Goal "([] = rev xs) = (xs = [])";
   384 by (induct_tac "xs" 1);
   385 by Auto_tac;
   386 qed "Nil_is_rev_conv";
   387 AddIffs [Nil_is_rev_conv];
   388 
   389 val prems = Goal "[| P []; !!x xs. P xs ==> P(xs@[x]) |] ==> P xs";
   390 by (stac (rev_rev_ident RS sym) 1);
   391 br(read_instantiate [("P","%xs. ?P(rev xs)")]list.induct)1;
   392 by (ALLGOALS Simp_tac);
   393 by (resolve_tac prems 1);
   394 by (eresolve_tac prems 1);
   395 qed "rev_induct";
   396 
   397 fun rev_induct_tac xs = res_inst_tac [("xs",xs)] rev_induct;
   398 
   399 Goal  "(xs = [] --> P) -->  (!ys y. xs = ys@[y] --> P) --> P";
   400 by (res_inst_tac [("xs","xs")] rev_induct 1);
   401 by Auto_tac;
   402 bind_thm ("rev_exhaust",
   403   impI RSN (2,allI RSN (2,allI RSN (2,impI RS (result() RS mp RS mp)))));
   404 
   405 
   406 (** mem **)
   407 
   408 section "mem";
   409 
   410 Goal "x mem (xs@ys) = (x mem xs | x mem ys)";
   411 by (induct_tac "xs" 1);
   412 by Auto_tac;
   413 qed "mem_append";
   414 Addsimps[mem_append];
   415 
   416 Goal "x mem [x:xs. P(x)] = (x mem xs & P(x))";
   417 by (induct_tac "xs" 1);
   418 by Auto_tac;
   419 qed "mem_filter";
   420 Addsimps[mem_filter];
   421 
   422 (** set **)
   423 
   424 section "set";
   425 
   426 qed_goal "finite_set" thy "finite (set xs)" 
   427 	(K [induct_tac "xs" 1, Auto_tac]);
   428 Addsimps[finite_set];
   429 AddSIs[finite_set];
   430 
   431 Goal "set (xs@ys) = (set xs Un set ys)";
   432 by (induct_tac "xs" 1);
   433 by Auto_tac;
   434 qed "set_append";
   435 Addsimps[set_append];
   436 
   437 Goal "(x mem xs) = (x: set xs)";
   438 by (induct_tac "xs" 1);
   439 by Auto_tac;
   440 qed "set_mem_eq";
   441 
   442 Goal "set l <= set (x#l)";
   443 by Auto_tac;
   444 qed "set_subset_Cons";
   445 
   446 Goal "(set xs = {}) = (xs = [])";
   447 by (induct_tac "xs" 1);
   448 by Auto_tac;
   449 qed "set_empty";
   450 Addsimps [set_empty];
   451 
   452 Goal "set(rev xs) = set(xs)";
   453 by (induct_tac "xs" 1);
   454 by Auto_tac;
   455 qed "set_rev";
   456 Addsimps [set_rev];
   457 
   458 Goal "set(map f xs) = f``(set xs)";
   459 by (induct_tac "xs" 1);
   460 by Auto_tac;
   461 qed "set_map";
   462 Addsimps [set_map];
   463 
   464 Goal "(x : set(filter P xs)) = (x : set xs & P x)";
   465 by (induct_tac "xs" 1);
   466 by Auto_tac;
   467 qed "in_set_filter";
   468 Addsimps [in_set_filter];
   469 
   470 Goal "(x : set xs) = (? ys zs. xs = ys@x#zs)";
   471 by (induct_tac "xs" 1);
   472  by (Simp_tac 1);
   473 by (Asm_simp_tac 1);
   474 by (rtac iffI 1);
   475 by (blast_tac (claset() addIs [eq_Nil_appendI,Cons_eq_appendI]) 1);
   476 by (REPEAT(etac exE 1));
   477 by (exhaust_tac "ys" 1);
   478 by Auto_tac;
   479 qed "in_set_conv_decomp";
   480 
   481 (* eliminate `lists' in favour of `set' *)
   482 
   483 Goal "(xs : lists A) = (!x : set xs. x : A)";
   484 by (induct_tac "xs" 1);
   485 by Auto_tac;
   486 qed "in_lists_conv_set";
   487 
   488 bind_thm("in_listsD",in_lists_conv_set RS iffD1);
   489 AddSDs [in_listsD];
   490 bind_thm("in_listsI",in_lists_conv_set RS iffD2);
   491 AddSIs [in_listsI];
   492 
   493 (** list_all **)
   494 
   495 section "list_all";
   496 
   497 Goal "list_all (%x. True) xs = True";
   498 by (induct_tac "xs" 1);
   499 by Auto_tac;
   500 qed "list_all_True";
   501 Addsimps [list_all_True];
   502 
   503 Goal "list_all p (xs@ys) = (list_all p xs & list_all p ys)";
   504 by (induct_tac "xs" 1);
   505 by Auto_tac;
   506 qed "list_all_append";
   507 Addsimps [list_all_append];
   508 
   509 Goal "list_all P xs = (!x. x mem xs --> P(x))";
   510 by (induct_tac "xs" 1);
   511 by Auto_tac;
   512 qed "list_all_mem_conv";
   513 
   514 
   515 (** filter **)
   516 
   517 section "filter";
   518 
   519 Goal "filter P (xs@ys) = filter P xs @ filter P ys";
   520 by (induct_tac "xs" 1);
   521 by Auto_tac;
   522 qed "filter_append";
   523 Addsimps [filter_append];
   524 
   525 Goal "filter (%x. True) xs = xs";
   526 by (induct_tac "xs" 1);
   527 by Auto_tac;
   528 qed "filter_True";
   529 Addsimps [filter_True];
   530 
   531 Goal "filter (%x. False) xs = []";
   532 by (induct_tac "xs" 1);
   533 by Auto_tac;
   534 qed "filter_False";
   535 Addsimps [filter_False];
   536 
   537 Goal "length (filter P xs) <= length xs";
   538 by (induct_tac "xs" 1);
   539 by Auto_tac;
   540 qed "length_filter";
   541 
   542 
   543 (** concat **)
   544 
   545 section "concat";
   546 
   547 Goal  "concat(xs@ys) = concat(xs)@concat(ys)";
   548 by (induct_tac "xs" 1);
   549 by Auto_tac;
   550 qed"concat_append";
   551 Addsimps [concat_append];
   552 
   553 Goal "(concat xss = []) = (!xs:set xss. xs=[])";
   554 by (induct_tac "xss" 1);
   555 by Auto_tac;
   556 qed "concat_eq_Nil_conv";
   557 AddIffs [concat_eq_Nil_conv];
   558 
   559 Goal "([] = concat xss) = (!xs:set xss. xs=[])";
   560 by (induct_tac "xss" 1);
   561 by Auto_tac;
   562 qed "Nil_eq_concat_conv";
   563 AddIffs [Nil_eq_concat_conv];
   564 
   565 Goal  "set(concat xs) = Union(set `` set xs)";
   566 by (induct_tac "xs" 1);
   567 by Auto_tac;
   568 qed"set_concat";
   569 Addsimps [set_concat];
   570 
   571 Goal "map f (concat xs) = concat (map (map f) xs)"; 
   572 by (induct_tac "xs" 1);
   573 by Auto_tac;
   574 qed "map_concat";
   575 
   576 Goal "filter p (concat xs) = concat (map (filter p) xs)"; 
   577 by (induct_tac "xs" 1);
   578 by Auto_tac;
   579 qed"filter_concat"; 
   580 
   581 Goal "rev(concat xs) = concat (map rev (rev xs))";
   582 by (induct_tac "xs" 1);
   583 by Auto_tac;
   584 qed "rev_concat";
   585 
   586 (** nth **)
   587 
   588 section "nth";
   589 
   590 Goal "!xs. (xs@ys)!n = (if n < length xs then xs!n else ys!(n - length xs))";
   591 by (induct_tac "n" 1);
   592  by (Asm_simp_tac 1);
   593  by (rtac allI 1);
   594  by (exhaust_tac "xs" 1);
   595   by Auto_tac;
   596 qed_spec_mp "nth_append";
   597 
   598 Goal "!n. n < length xs --> (map f xs)!n = f(xs!n)";
   599 by (induct_tac "xs" 1);
   600 (* case [] *)
   601 by (Asm_full_simp_tac 1);
   602 (* case x#xl *)
   603 by (rtac allI 1);
   604 by (induct_tac "n" 1);
   605 by Auto_tac;
   606 qed_spec_mp "nth_map";
   607 Addsimps [nth_map];
   608 
   609 Goal "!n. n < length xs --> list_all P xs --> P(xs!n)";
   610 by (induct_tac "xs" 1);
   611 (* case [] *)
   612 by (Simp_tac 1);
   613 (* case x#xl *)
   614 by (rtac allI 1);
   615 by (induct_tac "n" 1);
   616 by Auto_tac;
   617 qed_spec_mp "list_all_nth";
   618 
   619 Goal "!n. n < length xs --> xs!n mem xs";
   620 by (induct_tac "xs" 1);
   621 (* case [] *)
   622 by (Simp_tac 1);
   623 (* case x#xl *)
   624 by (rtac allI 1);
   625 by (induct_tac "n" 1);
   626 (* case 0 *)
   627 by (Asm_full_simp_tac 1);
   628 (* case Suc x *)
   629 by (Asm_full_simp_tac 1);
   630 qed_spec_mp "nth_mem";
   631 Addsimps [nth_mem];
   632 
   633 (** list update **)
   634 
   635 section "list update";
   636 
   637 Goal "!i. length(xs[i:=x]) = length xs";
   638 by (induct_tac "xs" 1);
   639 by (Simp_tac 1);
   640 by (asm_full_simp_tac (simpset() addsplits [nat.split]) 1);
   641 qed_spec_mp "length_list_update";
   642 Addsimps [length_list_update];
   643 
   644 
   645 (** last & butlast **)
   646 
   647 Goal "last(xs@[x]) = x";
   648 by (induct_tac "xs" 1);
   649 by Auto_tac;
   650 qed "last_snoc";
   651 Addsimps [last_snoc];
   652 
   653 Goal "butlast(xs@[x]) = xs";
   654 by (induct_tac "xs" 1);
   655 by Auto_tac;
   656 qed "butlast_snoc";
   657 Addsimps [butlast_snoc];
   658 
   659 Goal "length(butlast xs) = length xs - 1";
   660 by (res_inst_tac [("xs","xs")] rev_induct 1);
   661 by Auto_tac;
   662 qed "length_butlast";
   663 Addsimps [length_butlast];
   664 
   665 Goal "!ys. butlast (xs@ys) = (if ys=[] then butlast xs else xs@butlast ys)";
   666 by (induct_tac "xs" 1);
   667 by Auto_tac;
   668 qed_spec_mp "butlast_append";
   669 
   670 Goal "x:set(butlast xs) --> x:set xs";
   671 by (induct_tac "xs" 1);
   672 by Auto_tac;
   673 qed_spec_mp "in_set_butlastD";
   674 
   675 Goal "x:set(butlast xs) ==> x:set(butlast(xs@ys))";
   676 by (asm_simp_tac (simpset() addsimps [butlast_append]) 1);
   677 by (blast_tac (claset() addDs [in_set_butlastD]) 1);
   678 qed "in_set_butlast_appendI1";
   679 
   680 Goal "x:set(butlast ys) ==> x:set(butlast(xs@ys))";
   681 by (asm_simp_tac (simpset() addsimps [butlast_append]) 1);
   682 by (Clarify_tac 1);
   683 by (Full_simp_tac 1);
   684 qed "in_set_butlast_appendI2";
   685 
   686 (** take  & drop **)
   687 section "take & drop";
   688 
   689 Goal "take 0 xs = []";
   690 by (induct_tac "xs" 1);
   691 by Auto_tac;
   692 qed "take_0";
   693 
   694 Goal "drop 0 xs = xs";
   695 by (induct_tac "xs" 1);
   696 by Auto_tac;
   697 qed "drop_0";
   698 
   699 Goal "take (Suc n) (x#xs) = x # take n xs";
   700 by (Simp_tac 1);
   701 qed "take_Suc_Cons";
   702 
   703 Goal "drop (Suc n) (x#xs) = drop n xs";
   704 by (Simp_tac 1);
   705 qed "drop_Suc_Cons";
   706 
   707 Delsimps [take_Cons,drop_Cons];
   708 Addsimps [take_0,take_Suc_Cons,drop_0,drop_Suc_Cons];
   709 
   710 Goal "!xs. length(take n xs) = min (length xs) n";
   711 by (induct_tac "n" 1);
   712  by Auto_tac;
   713 by (exhaust_tac "xs" 1);
   714  by Auto_tac;
   715 qed_spec_mp "length_take";
   716 Addsimps [length_take];
   717 
   718 Goal "!xs. length(drop n xs) = (length xs - n)";
   719 by (induct_tac "n" 1);
   720  by Auto_tac;
   721 by (exhaust_tac "xs" 1);
   722  by Auto_tac;
   723 qed_spec_mp "length_drop";
   724 Addsimps [length_drop];
   725 
   726 Goal "!xs. length xs <= n --> take n xs = xs";
   727 by (induct_tac "n" 1);
   728  by Auto_tac;
   729 by (exhaust_tac "xs" 1);
   730  by Auto_tac;
   731 qed_spec_mp "take_all";
   732 
   733 Goal "!xs. length xs <= n --> drop n xs = []";
   734 by (induct_tac "n" 1);
   735  by Auto_tac;
   736 by (exhaust_tac "xs" 1);
   737  by Auto_tac;
   738 qed_spec_mp "drop_all";
   739 
   740 Goal "!xs. take n (xs @ ys) = (take n xs @ take (n - length xs) ys)";
   741 by (induct_tac "n" 1);
   742  by Auto_tac;
   743 by (exhaust_tac "xs" 1);
   744  by Auto_tac;
   745 qed_spec_mp "take_append";
   746 Addsimps [take_append];
   747 
   748 Goal "!xs. drop n (xs@ys) = drop n xs @ drop (n - length xs) ys"; 
   749 by (induct_tac "n" 1);
   750  by Auto_tac;
   751 by (exhaust_tac "xs" 1);
   752  by Auto_tac;
   753 qed_spec_mp "drop_append";
   754 Addsimps [drop_append];
   755 
   756 Goal "!xs n. take n (take m xs) = take (min n m) xs"; 
   757 by (induct_tac "m" 1);
   758  by Auto_tac;
   759 by (exhaust_tac "xs" 1);
   760  by Auto_tac;
   761 by (exhaust_tac "na" 1);
   762  by Auto_tac;
   763 qed_spec_mp "take_take";
   764 
   765 Goal "!xs. drop n (drop m xs) = drop (n + m) xs"; 
   766 by (induct_tac "m" 1);
   767  by Auto_tac;
   768 by (exhaust_tac "xs" 1);
   769  by Auto_tac;
   770 qed_spec_mp "drop_drop";
   771 
   772 Goal "!xs n. take n (drop m xs) = drop m (take (n + m) xs)"; 
   773 by (induct_tac "m" 1);
   774  by Auto_tac;
   775 by (exhaust_tac "xs" 1);
   776  by Auto_tac;
   777 qed_spec_mp "take_drop";
   778 
   779 Goal "!xs. take n (map f xs) = map f (take n xs)"; 
   780 by (induct_tac "n" 1);
   781  by Auto_tac;
   782 by (exhaust_tac "xs" 1);
   783  by Auto_tac;
   784 qed_spec_mp "take_map"; 
   785 
   786 Goal "!xs. drop n (map f xs) = map f (drop n xs)"; 
   787 by (induct_tac "n" 1);
   788  by Auto_tac;
   789 by (exhaust_tac "xs" 1);
   790  by Auto_tac;
   791 qed_spec_mp "drop_map";
   792 
   793 Goal "!n i. i < n --> (take n xs)!i = xs!i";
   794 by (induct_tac "xs" 1);
   795  by Auto_tac;
   796 by (exhaust_tac "n" 1);
   797  by (Blast_tac 1);
   798 by (exhaust_tac "i" 1);
   799  by Auto_tac;
   800 qed_spec_mp "nth_take";
   801 Addsimps [nth_take];
   802 
   803 Goal  "!xs i. n + i <= length xs --> (drop n xs)!i = xs!(n+i)";
   804 by (induct_tac "n" 1);
   805  by Auto_tac;
   806 by (exhaust_tac "xs" 1);
   807  by Auto_tac;
   808 qed_spec_mp "nth_drop";
   809 Addsimps [nth_drop];
   810 
   811 (** takeWhile & dropWhile **)
   812 
   813 section "takeWhile & dropWhile";
   814 
   815 Goal "takeWhile P xs @ dropWhile P xs = xs";
   816 by (induct_tac "xs" 1);
   817 by Auto_tac;
   818 qed "takeWhile_dropWhile_id";
   819 Addsimps [takeWhile_dropWhile_id];
   820 
   821 Goal  "x:set xs & ~P(x) --> takeWhile P (xs @ ys) = takeWhile P xs";
   822 by (induct_tac "xs" 1);
   823 by Auto_tac;
   824 bind_thm("takeWhile_append1", conjI RS (result() RS mp));
   825 Addsimps [takeWhile_append1];
   826 
   827 Goal "(!x:set xs. P(x)) --> takeWhile P (xs @ ys) = xs @ takeWhile P ys";
   828 by (induct_tac "xs" 1);
   829 by Auto_tac;
   830 bind_thm("takeWhile_append2", ballI RS (result() RS mp));
   831 Addsimps [takeWhile_append2];
   832 
   833 Goal "x:set xs & ~P(x) --> dropWhile P (xs @ ys) = (dropWhile P xs)@ys";
   834 by (induct_tac "xs" 1);
   835 by Auto_tac;
   836 bind_thm("dropWhile_append1", conjI RS (result() RS mp));
   837 Addsimps [dropWhile_append1];
   838 
   839 Goal "(!x:set xs. P(x)) --> dropWhile P (xs @ ys) = dropWhile P ys";
   840 by (induct_tac "xs" 1);
   841 by Auto_tac;
   842 bind_thm("dropWhile_append2", ballI RS (result() RS mp));
   843 Addsimps [dropWhile_append2];
   844 
   845 Goal "x:set(takeWhile P xs) --> x:set xs & P x";
   846 by (induct_tac "xs" 1);
   847 by Auto_tac;
   848 qed_spec_mp"set_take_whileD";
   849 
   850 qed_goal "zip_Nil_Nil"   thy "zip []     []     = []" (K [Simp_tac 1]);
   851 qed_goal "zip_Cons_Cons" thy "zip (x#xs) (y#ys) = (x,y)#zip xs ys" 
   852 						      (K [Simp_tac 1]);
   853 
   854 
   855 (** foldl **)
   856 section "foldl";
   857 
   858 Goal "!a. foldl f a (xs @ ys) = foldl f (foldl f a xs) ys";
   859 by (induct_tac "xs" 1);
   860 by Auto_tac;
   861 qed_spec_mp "foldl_append";
   862 Addsimps [foldl_append];
   863 
   864 (* Note: `n <= foldl op+ n ns' looks simpler, but is more difficult to use
   865    because it requires an additional transitivity step
   866 *)
   867 Goal "!n::nat. m <= n --> m <= foldl op+ n ns";
   868 by (induct_tac "ns" 1);
   869  by (Simp_tac 1);
   870 by (Asm_full_simp_tac 1);
   871 by (blast_tac (claset() addIs [trans_le_add1]) 1);
   872 qed_spec_mp "start_le_sum";
   873 
   874 Goal "n : set ns ==> n <= foldl op+ 0 ns";
   875 by (auto_tac (claset() addIs [start_le_sum],
   876              simpset() addsimps [in_set_conv_decomp]));
   877 qed "elem_le_sum";
   878 
   879 Goal "!m. (foldl op+ m ns = 0) = (m=0 & (!n : set ns. n=0))";
   880 by (induct_tac "ns" 1);
   881 by Auto_tac;
   882 qed_spec_mp "sum_eq_0_conv";
   883 AddIffs [sum_eq_0_conv];
   884 
   885 (** upto **)
   886 
   887 (* Does not terminate! *)
   888 Goal "[i..j(] = (if i<j then i#[Suc i..j(] else [])";
   889 by(induct_tac "j" 1);
   890 by Auto_tac;
   891 by(REPEAT(trans_tac 1));
   892 qed "upt_rec";
   893 
   894 Goal "j<=i ==> [i..j(] = []";
   895 by(stac upt_rec 1);
   896 by(asm_simp_tac (simpset() addSolver cut_trans_tac) 1);
   897 qed "upt_conv_Nil";
   898 Addsimps [upt_conv_Nil];
   899 
   900 Goal "i<=j ==> [i..(Suc j)(] = [i..j(]@[j]";
   901 by (Asm_simp_tac 1);
   902 qed "upt_Suc";
   903 
   904 Goal "i<j ==> [i..j(] = i#[Suc i..j(]";
   905 br trans 1;
   906 by(stac upt_rec 1);
   907 br refl 2;
   908 by (Asm_simp_tac 1);
   909 qed "upt_conv_Cons";
   910 
   911 Goal "length [i..j(] = j-i";
   912 by(induct_tac "j" 1);
   913  by (Simp_tac 1);
   914 by(asm_simp_tac (simpset() addsimps [Suc_diff_le] addSolver cut_trans_tac) 1);
   915 qed "length_upt";
   916 Addsimps [length_upt];
   917 
   918 Goal "i+k < j --> [i..j(] ! k = i+k";
   919 by(induct_tac "j" 1);
   920  by(Simp_tac 1);
   921 by(asm_simp_tac (simpset() addsimps ([nth_append,less_diff_conv]@add_ac)
   922                            addSolver cut_trans_tac) 1);
   923 br conjI 1;
   924  by(Clarify_tac 1);
   925  bd add_lessD1 1;
   926  by(trans_tac 1);
   927 by(Clarify_tac 1);
   928 br conjI 1;
   929  by(Clarify_tac 1);
   930  by(subgoal_tac "n=i+k" 1);
   931   by(Asm_full_simp_tac 1);
   932  by(trans_tac 1);
   933 by(Clarify_tac 1);
   934 by(subgoal_tac "n=i+k" 1);
   935  by(Asm_full_simp_tac 1);
   936 by(trans_tac 1);
   937 qed_spec_mp "nth_upt";
   938 Addsimps [nth_upt];
   939 
   940 
   941 (** nodups & remdups **)
   942 section "nodups & remdups";
   943 
   944 Goal "set(remdups xs) = set xs";
   945 by (induct_tac "xs" 1);
   946  by (Simp_tac 1);
   947 by (asm_full_simp_tac (simpset() addsimps [insert_absorb]) 1);
   948 qed "set_remdups";
   949 Addsimps [set_remdups];
   950 
   951 Goal "nodups(remdups xs)";
   952 by (induct_tac "xs" 1);
   953 by Auto_tac;
   954 qed "nodups_remdups";
   955 
   956 Goal "nodups xs --> nodups (filter P xs)";
   957 by (induct_tac "xs" 1);
   958 by Auto_tac;
   959 qed_spec_mp "nodups_filter";
   960 
   961 (** replicate **)
   962 section "replicate";
   963 
   964 Goal "set(replicate (Suc n) x) = {x}";
   965 by (induct_tac "n" 1);
   966 by Auto_tac;
   967 val lemma = result();
   968 
   969 Goal "n ~= 0 ==> set(replicate n x) = {x}";
   970 by (fast_tac (claset() addSDs [not0_implies_Suc] addSIs [lemma]) 1);
   971 qed "set_replicate";
   972 Addsimps [set_replicate];
   973 
   974 
   975 (*** Lexcicographic orderings on lists ***)
   976 section"Lexcicographic orderings on lists";
   977 
   978 Goal "wf r ==> wf(lexn r n)";
   979 by (induct_tac "n" 1);
   980 by (Simp_tac 1);
   981 by (Simp_tac 1);
   982 by (rtac wf_subset 1);
   983 by (rtac Int_lower1 2);
   984 by (rtac wf_prod_fun_image 1);
   985 by (rtac injI 2);
   986 by (Auto_tac);
   987 qed "wf_lexn";
   988 
   989 Goal "!xs ys. (xs,ys) : lexn r n --> length xs = n & length ys = n";
   990 by (induct_tac "n" 1);
   991 by (Auto_tac);
   992 qed_spec_mp "lexn_length";
   993 
   994 Goalw [lex_def] "wf r ==> wf(lex r)";
   995 by (rtac wf_UN 1);
   996 by (blast_tac (claset() addIs [wf_lexn]) 1);
   997 by (Clarify_tac 1);
   998 by (rename_tac "m n" 1);
   999 by (subgoal_tac "m ~= n" 1);
  1000  by (Blast_tac 2);
  1001 by (blast_tac (claset() addDs [lexn_length,not_sym]) 1);
  1002 qed "wf_lex";
  1003 AddSIs [wf_lex];
  1004 
  1005 Goal
  1006  "lexn r n = \
  1007 \ {(xs,ys). length xs = n & length ys = n & \
  1008 \           (? xys x y xs' ys'. xs= xys @ x#xs' & ys= xys @ y#ys' & (x,y):r)}";
  1009 by (induct_tac "n" 1);
  1010  by (Simp_tac 1);
  1011  by (Blast_tac 1);
  1012 by (asm_full_simp_tac (simpset() delsimps [length_Suc_conv] 
  1013 				addsimps [lex_prod_def]) 1);
  1014 by (auto_tac (claset(), simpset() delsimps [length_Suc_conv]));
  1015   by (Blast_tac 1);
  1016  by (rename_tac "a xys x xs' y ys'" 1);
  1017  by (res_inst_tac [("x","a#xys")] exI 1);
  1018  by (Simp_tac 1);
  1019 by (exhaust_tac "xys" 1);
  1020  by (ALLGOALS (asm_full_simp_tac (simpset() delsimps [length_Suc_conv])));
  1021 by (Blast_tac 1);
  1022 qed "lexn_conv";
  1023 
  1024 Goalw [lex_def]
  1025  "lex r = \
  1026 \ {(xs,ys). length xs = length ys & \
  1027 \           (? xys x y xs' ys'. xs= xys @ x#xs' & ys= xys @ y#ys' & (x,y):r)}";
  1028 by (force_tac (claset(), simpset() delsimps [length_Suc_conv] addsimps [lexn_conv]) 1);
  1029 qed "lex_conv";
  1030 
  1031 Goalw [lexico_def] "wf r ==> wf(lexico r)";
  1032 by (Blast_tac 1);
  1033 qed "wf_lexico";
  1034 AddSIs [wf_lexico];
  1035 
  1036 Goalw
  1037  [lexico_def,diag_def,lex_prod_def,measure_def,inv_image_def]
  1038 "lexico r = {(xs,ys). length xs < length ys | \
  1039 \                     length xs = length ys & (xs,ys) : lex r}";
  1040 by (Simp_tac 1);
  1041 qed "lexico_conv";
  1042 
  1043 Goal "([],ys) ~: lex r";
  1044 by (simp_tac (simpset() addsimps [lex_conv]) 1);
  1045 qed "Nil_notin_lex";
  1046 
  1047 Goal "(xs,[]) ~: lex r";
  1048 by (simp_tac (simpset() addsimps [lex_conv]) 1);
  1049 qed "Nil2_notin_lex";
  1050 
  1051 AddIffs [Nil_notin_lex,Nil2_notin_lex];
  1052 
  1053 Goal "((x#xs,y#ys) : lex r) = \
  1054 \     ((x,y) : r & length xs = length ys | x=y & (xs,ys) : lex r)";
  1055 by (simp_tac (simpset() addsimps [lex_conv]) 1);
  1056 by (rtac iffI 1);
  1057  by (blast_tac (claset() addIs [Cons_eq_appendI]) 2);
  1058 by (REPEAT(eresolve_tac [conjE, exE] 1));
  1059 by (exhaust_tac "xys" 1);
  1060 by (Asm_full_simp_tac 1);
  1061 by (Asm_full_simp_tac 1);
  1062 by (Blast_tac 1);
  1063 qed "Cons_in_lex";
  1064 AddIffs [Cons_in_lex];