src/HOL/Map.thy
author nipkow
Sun Sep 14 17:53:27 2003 +0200 (2003-09-14)
changeset 14187 26dfcd0ac436
parent 14186 6d2a494e33be
child 14208 144f45277d5a
permissions -rw-r--r--
Added new theorems
     1 (*  Title:      HOL/Map.thy
     2     ID:         $Id$
     3     Author:     Tobias Nipkow, based on a theory by David von Oheimb
     4     Copyright   1997-2003 TU Muenchen
     5 
     6 The datatype of `maps' (written ~=>); strongly resembles maps in VDM.
     7 *)
     8 
     9 header {* Maps *}
    10 
    11 theory Map = List:
    12 
    13 types ('a,'b) "~=>" = "'a => 'b option" (infixr 0)
    14 translations (type) "a ~=> b " <= (type) "a => b option"
    15 
    16 consts
    17 chg_map	:: "('b => 'b) => 'a => ('a ~=> 'b) => ('a ~=> 'b)"
    18 map_add :: "('a ~=> 'b) => ('a ~=> 'b) => ('a ~=> 'b)" (infixl "++" 100)
    19 map_image::"('b => 'c)  => ('a ~=> 'b) => ('a ~=> 'c)" (infixr "`>" 90)
    20 restrict_map :: "('a ~=> 'b) => 'a set => ('a ~=> 'b)" ("_|'__" [90, 91] 90)
    21 dom	:: "('a ~=> 'b) => 'a set"
    22 ran	:: "('a ~=> 'b) => 'b set"
    23 map_of	:: "('a * 'b)list => 'a ~=> 'b"
    24 map_upds:: "('a ~=> 'b) => 'a list => 'b list => 
    25 	    ('a ~=> 'b)"
    26 map_upd_s::"('a ~=> 'b) => 'a set => 'b => 
    27 	    ('a ~=> 'b)"			 ("_/'(_{|->}_/')" [900,0,0]900)
    28 map_subst::"('a ~=> 'b) => 'b => 'b => 
    29 	    ('a ~=> 'b)"			 ("_/'(_~>_/')"    [900,0,0]900)
    30 map_le  :: "('a ~=> 'b) => ('a ~=> 'b) => bool" (infix "\<subseteq>\<^sub>m" 50)
    31 
    32 nonterminals
    33   maplets maplet
    34 
    35 syntax
    36   empty	    ::  "'a ~=> 'b"
    37   "_maplet"  :: "['a, 'a] => maplet"             ("_ /|->/ _")
    38   "_maplets" :: "['a, 'a] => maplet"             ("_ /[|->]/ _")
    39   ""         :: "maplet => maplets"             ("_")
    40   "_Maplets" :: "[maplet, maplets] => maplets" ("_,/ _")
    41   "_MapUpd"  :: "['a ~=> 'b, maplets] => 'a ~=> 'b" ("_/'(_')" [900,0]900)
    42   "_Map"     :: "maplets => 'a ~=> 'b"            ("(1[_])")
    43 
    44 syntax (xsymbols)
    45   "_maplet"  :: "['a, 'a] => maplet"             ("_ /\<mapsto>/ _")
    46   "_maplets" :: "['a, 'a] => maplet"             ("_ /[\<mapsto>]/ _")
    47 
    48   "~=>"     :: "[type, type] => type"    (infixr "\<rightharpoonup>" 0)
    49   restrict_map :: "('a ~=> 'b) => 'a set => ('a ~=> 'b)" ("_\<lfloor>_" [90, 91] 90)
    50   map_upd_s  :: "('a ~=> 'b) => 'a set => 'b => ('a ~=> 'b)"
    51 				    		 ("_/'(_/{\<mapsto>}/_')" [900,0,0]900)
    52   map_subst :: "('a ~=> 'b) => 'b => 'b => 
    53 	        ('a ~=> 'b)"			 ("_/'(_\<leadsto>_/')"    [900,0,0]900)
    54  "@chg_map" :: "('a ~=> 'b) => 'a => ('b => 'b) => ('a ~=> 'b)"
    55 					  ("_/'(_/\<mapsto>\<lambda>_. _')"  [900,0,0,0] 900)
    56 
    57 translations
    58   "empty"    => "_K None"
    59   "empty"    <= "%x. None"
    60 
    61   "m(x\<mapsto>\<lambda>y. f)" == "chg_map (\<lambda>y. f) x m"
    62 
    63   "_MapUpd m (_Maplets xy ms)"  == "_MapUpd (_MapUpd m xy) ms"
    64   "_MapUpd m (_maplet  x y)"    == "m(x:=Some y)"
    65   "_MapUpd m (_maplets x y)"    == "map_upds m x y"
    66   "_Map ms"                     == "_MapUpd empty ms"
    67   "_Map (_Maplets ms1 ms2)"     <= "_MapUpd (_Map ms1) ms2"
    68   "_Maplets ms1 (_Maplets ms2 ms3)" <= "_Maplets (_Maplets ms1 ms2) ms3"
    69 
    70 defs
    71 chg_map_def:  "chg_map f a m == case m a of None => m | Some b => m(a|->f b)"
    72 
    73 map_add_def:   "m1++m2 == %x. case m2 x of None => m1 x | Some y => Some y"
    74 map_image_def: "f`>m == option_map f o m"
    75 restrict_map_def: "m|_A == %x. if x : A then m x else None"
    76 
    77 map_upds_def: "m(xs [|->] ys) == m ++ map_of (rev(zip xs ys))"
    78 map_upd_s_def: "m(as{|->}b) == %x. if x : as then Some b else m x"
    79 map_subst_def: "m(a~>b)     == %x. if m x = Some a then Some b else m x"
    80 
    81 dom_def: "dom(m) == {a. m a ~= None}"
    82 ran_def: "ran(m) == {b. EX a. m a = Some b}"
    83 
    84 map_le_def: "m1 \<subseteq>\<^sub>m m2  ==  ALL a : dom m1. m1 a = m2 a"
    85 
    86 primrec
    87   "map_of [] = empty"
    88   "map_of (p#ps) = (map_of ps)(fst p |-> snd p)"
    89 
    90 
    91 subsection {* @{term empty} *}
    92 
    93 lemma empty_upd_none[simp]: "empty(x := None) = empty"
    94 apply (rule ext)
    95 apply (simp (no_asm))
    96 done
    97 
    98 
    99 (* FIXME: what is this sum_case nonsense?? *)
   100 lemma sum_case_empty_empty[simp]: "sum_case empty empty = empty"
   101 apply (rule ext)
   102 apply (simp (no_asm) split add: sum.split)
   103 done
   104 
   105 subsection {* @{term map_upd} *}
   106 
   107 lemma map_upd_triv: "t k = Some x ==> t(k|->x) = t"
   108 apply (rule ext)
   109 apply (simp (no_asm_simp))
   110 done
   111 
   112 lemma map_upd_nonempty[simp]: "t(k|->x) ~= empty"
   113 apply safe
   114 apply (drule_tac x = "k" in fun_cong)
   115 apply (simp (no_asm_use))
   116 done
   117 
   118 lemma map_upd_eqD1: "m(a\<mapsto>x) = n(a\<mapsto>y) \<Longrightarrow> x = y"
   119 by (drule fun_cong [of _ _ a], auto)
   120 
   121 lemma map_upd_Some_unfold: 
   122   "((m(a|->b)) x = Some y) = (x = a \<and> b = y \<or> x \<noteq> a \<and> m x = Some y)"
   123 by auto
   124 
   125 lemma finite_range_updI: "finite (range f) ==> finite (range (f(a|->b)))"
   126 apply (unfold image_def)
   127 apply (simp (no_asm_use) add: full_SetCompr_eq)
   128 apply (rule finite_subset)
   129 prefer 2 apply (assumption)
   130 apply auto
   131 done
   132 
   133 
   134 (* FIXME: what is this sum_case nonsense?? *)
   135 subsection {* @{term sum_case} and @{term empty}/@{term map_upd} *}
   136 
   137 lemma sum_case_map_upd_empty[simp]:
   138  "sum_case (m(k|->y)) empty =  (sum_case m empty)(Inl k|->y)"
   139 apply (rule ext)
   140 apply (simp (no_asm) split add: sum.split)
   141 done
   142 
   143 lemma sum_case_empty_map_upd[simp]:
   144  "sum_case empty (m(k|->y)) =  (sum_case empty m)(Inr k|->y)"
   145 apply (rule ext)
   146 apply (simp (no_asm) split add: sum.split)
   147 done
   148 
   149 lemma sum_case_map_upd_map_upd[simp]:
   150  "sum_case (m1(k1|->y1)) (m2(k2|->y2)) = (sum_case (m1(k1|->y1)) m2)(Inr k2|->y2)"
   151 apply (rule ext)
   152 apply (simp (no_asm) split add: sum.split)
   153 done
   154 
   155 
   156 subsection {* @{term chg_map} *}
   157 
   158 lemma chg_map_new[simp]: "m a = None   ==> chg_map f a m = m"
   159 apply (unfold chg_map_def)
   160 apply auto
   161 done
   162 
   163 lemma chg_map_upd[simp]: "m a = Some b ==> chg_map f a m = m(a|->f b)"
   164 apply (unfold chg_map_def)
   165 apply auto
   166 done
   167 
   168 
   169 subsection {* @{term map_of} *}
   170 
   171 lemma map_of_SomeD [rule_format (no_asm)]: "map_of xs k = Some y --> (k,y):set xs"
   172 apply (induct_tac "xs")
   173 apply  auto
   174 done
   175 
   176 lemma map_of_mapk_SomeI [rule_format (no_asm)]: "inj f ==> map_of t k = Some x -->  
   177    map_of (map (split (%k. Pair (f k))) t) (f k) = Some x"
   178 apply (induct_tac "t")
   179 apply  (auto simp add: inj_eq)
   180 done
   181 
   182 lemma weak_map_of_SomeI [rule_format (no_asm)]: "(k, x) : set l --> (? x. map_of l k = Some x)"
   183 apply (induct_tac "l")
   184 apply  auto
   185 done
   186 
   187 lemma map_of_filter_in: 
   188 "[| map_of xs k = Some z; P k z |] ==> map_of (filter (split P) xs) k = Some z"
   189 apply (rule mp)
   190 prefer 2 apply (assumption)
   191 apply (erule thin_rl)
   192 apply (induct_tac "xs")
   193 apply  auto
   194 done
   195 
   196 lemma finite_range_map_of: "finite (range (map_of l))"
   197 apply (induct_tac "l")
   198 apply  (simp_all (no_asm) add: image_constant)
   199 apply (rule finite_subset)
   200 prefer 2 apply (assumption)
   201 apply auto
   202 done
   203 
   204 lemma map_of_map: "map_of (map (%(a,b). (a,f b)) xs) x = option_map f (map_of xs x)"
   205 apply (induct_tac "xs")
   206 apply auto
   207 done
   208 
   209 
   210 subsection {* @{term option_map} related *}
   211 
   212 lemma option_map_o_empty[simp]: "option_map f o empty = empty"
   213 apply (rule ext)
   214 apply (simp (no_asm))
   215 done
   216 
   217 lemma option_map_o_map_upd[simp]:
   218  "option_map f o m(a|->b) = (option_map f o m)(a|->f b)"
   219 apply (rule ext)
   220 apply (simp (no_asm))
   221 done
   222 
   223 
   224 subsection {* @{text "++"} *}
   225 
   226 lemma map_add_empty[simp]: "m ++ empty = m"
   227 apply (unfold map_add_def)
   228 apply (simp (no_asm))
   229 done
   230 
   231 lemma empty_map_add[simp]: "empty ++ m = m"
   232 apply (unfold map_add_def)
   233 apply (rule ext)
   234 apply (simp split add: option.split)
   235 done
   236 
   237 lemma map_add_assoc[simp]: "m1 ++ (m2 ++ m3) = (m1 ++ m2) ++ m3"
   238 apply(rule ext)
   239 apply(simp add: map_add_def split:option.split)
   240 done
   241 
   242 lemma map_add_Some_iff: 
   243  "((m ++ n) k = Some x) = (n k = Some x | n k = None & m k = Some x)"
   244 apply (unfold map_add_def)
   245 apply (simp (no_asm) split add: option.split)
   246 done
   247 
   248 lemmas map_add_SomeD = map_add_Some_iff [THEN iffD1, standard]
   249 declare map_add_SomeD [dest!]
   250 
   251 lemma map_add_find_right[simp]: "!!xx. n k = Some xx ==> (m ++ n) k = Some xx"
   252 apply (subst map_add_Some_iff)
   253 apply fast
   254 done
   255 
   256 lemma map_add_None [iff]: "((m ++ n) k = None) = (n k = None & m k = None)"
   257 apply (unfold map_add_def)
   258 apply (simp (no_asm) split add: option.split)
   259 done
   260 
   261 lemma map_add_upd[simp]: "f ++ g(x|->y) = (f ++ g)(x|->y)"
   262 apply (unfold map_add_def)
   263 apply (rule ext)
   264 apply auto
   265 done
   266 
   267 lemma map_add_upds[simp]: "m1 ++ (m2(xs[\<mapsto>]ys)) = (m1++m2)(xs[\<mapsto>]ys)"
   268 by(simp add:map_upds_def)
   269 
   270 lemma map_of_append[simp]: "map_of (xs@ys) = map_of ys ++ map_of xs"
   271 apply (unfold map_add_def)
   272 apply (induct_tac "xs")
   273 apply (simp (no_asm))
   274 apply (rule ext)
   275 apply (simp (no_asm_simp) split add: option.split)
   276 done
   277 
   278 declare fun_upd_apply [simp del]
   279 lemma finite_range_map_of_map_add:
   280  "finite (range f) ==> finite (range (f ++ map_of l))"
   281 apply (induct_tac "l")
   282 apply  auto
   283 apply (erule finite_range_updI)
   284 done
   285 declare fun_upd_apply [simp]
   286 
   287 subsection {* @{term map_image} *}
   288 
   289 lemma map_image_empty [simp]: "f`>empty = empty" 
   290 by (auto simp: map_image_def empty_def)
   291 
   292 lemma map_image_upd [simp]: "f`>m(a|->b) = (f`>m)(a|->f b)" 
   293 apply (auto simp: map_image_def fun_upd_def)
   294 by (rule ext, auto)
   295 
   296 subsection {* @{term restrict_map} *}
   297 
   298 lemma restrict_map_to_empty[simp]: "m\<lfloor>{} = empty"
   299 by(simp add: restrict_map_def)
   300 
   301 lemma restrict_map_empty[simp]: "empty\<lfloor>D = empty"
   302 by(simp add: restrict_map_def)
   303 
   304 lemma restrict_in [simp]: "x \<in> A \<Longrightarrow> (m\<lfloor>A) x = m x"
   305 by (auto simp: restrict_map_def)
   306 
   307 lemma restrict_out [simp]: "x \<notin> A \<Longrightarrow> (m\<lfloor>A) x = None"
   308 by (auto simp: restrict_map_def)
   309 
   310 lemma ran_restrictD: "y \<in> ran (m\<lfloor>A) \<Longrightarrow> \<exists>x\<in>A. m x = Some y"
   311 by (auto simp: restrict_map_def ran_def split: split_if_asm)
   312 
   313 lemma dom_restrict [simp]: "dom (m\<lfloor>A) = dom m \<inter> A"
   314 by (auto simp: restrict_map_def dom_def split: split_if_asm)
   315 
   316 lemma restrict_upd_same [simp]: "m(x\<mapsto>y)\<lfloor>(-{x}) = m\<lfloor>(-{x})"
   317 by (rule ext, auto simp: restrict_map_def)
   318 
   319 lemma restrict_restrict [simp]: "m\<lfloor>A\<lfloor>B = m\<lfloor>(A\<inter>B)"
   320 by (rule ext, auto simp: restrict_map_def)
   321 
   322 lemma restrict_fun_upd[simp]:
   323  "m(x := y)\<lfloor>D = (if x \<in> D then (m\<lfloor>(D-{x}))(x := y) else m\<lfloor>D)"
   324 by(simp add: restrict_map_def expand_fun_eq)
   325 
   326 lemma fun_upd_None_restrict[simp]:
   327   "(m\<lfloor>D)(x := None) = (if x:D then m\<lfloor>(D - {x}) else m\<lfloor>D)"
   328 by(simp add: restrict_map_def expand_fun_eq)
   329 
   330 lemma fun_upd_restrict:
   331  "(m\<lfloor>D)(x := y) = (m\<lfloor>(D-{x}))(x := y)"
   332 by(simp add: restrict_map_def expand_fun_eq)
   333 
   334 lemma fun_upd_restrict_conv[simp]:
   335  "x \<in> D \<Longrightarrow> (m\<lfloor>D)(x := y) = (m\<lfloor>(D-{x}))(x := y)"
   336 by(simp add: restrict_map_def expand_fun_eq)
   337 
   338 
   339 subsection {* @{term map_upds} *}
   340 
   341 lemma map_upds_Nil1[simp]: "m([] [|->] bs) = m"
   342 by(simp add:map_upds_def)
   343 
   344 lemma map_upds_Nil2[simp]: "m(as [|->] []) = m"
   345 by(simp add:map_upds_def)
   346 
   347 lemma map_upds_Cons[simp]: "m(a#as [|->] b#bs) = (m(a|->b))(as[|->]bs)"
   348 by(simp add:map_upds_def)
   349 
   350 lemma map_upds_append1[simp]: "\<And>ys m. size xs < size ys \<Longrightarrow>
   351   m(xs@[x] [\<mapsto>] ys) = m(xs [\<mapsto>] ys)(x \<mapsto> ys!size xs)"
   352 apply(induct xs)
   353  apply(clarsimp simp add:neq_Nil_conv)
   354 apply(case_tac ys)
   355  apply simp
   356 apply simp
   357 done
   358 
   359 lemma map_upds_list_update2_drop[simp]:
   360  "\<And>m ys i. \<lbrakk>size xs \<le> i; i < size ys\<rbrakk>
   361      \<Longrightarrow> m(xs[\<mapsto>]ys[i:=y]) = m(xs[\<mapsto>]ys)"
   362 apply(induct xs)
   363  apply simp
   364 apply(case_tac ys)
   365  apply simp
   366 apply(simp split:nat.split)
   367 done
   368 
   369 lemma map_upd_upds_conv_if: "!!x y ys f.
   370  (f(x|->y))(xs [|->] ys) =
   371  (if x : set(take (length ys) xs) then f(xs [|->] ys)
   372                                   else (f(xs [|->] ys))(x|->y))"
   373 apply(induct xs)
   374  apply simp
   375 apply(case_tac ys)
   376  apply(auto split:split_if simp:fun_upd_twist)
   377 done
   378 
   379 lemma map_upds_twist [simp]:
   380  "a ~: set as ==> m(a|->b)(as[|->]bs) = m(as[|->]bs)(a|->b)"
   381 apply(insert set_take_subset)
   382 apply (fastsimp simp add: map_upd_upds_conv_if)
   383 done
   384 
   385 lemma map_upds_apply_nontin[simp]:
   386  "!!ys. x ~: set xs ==> (f(xs[|->]ys)) x = f x"
   387 apply(induct xs)
   388  apply simp
   389 apply(case_tac ys)
   390  apply(auto simp: map_upd_upds_conv_if)
   391 done
   392 
   393 lemma restrict_map_upds[simp]: "!!m ys.
   394  \<lbrakk> length xs = length ys; set xs \<subseteq> D \<rbrakk>
   395  \<Longrightarrow> m(xs [\<mapsto>] ys)\<lfloor>D = (m\<lfloor>(D - set xs))(xs [\<mapsto>] ys)"
   396 apply(induct xs)
   397  apply simp
   398 apply(case_tac ys)
   399  apply simp
   400 apply(simp add:Diff_insert[symmetric] insert_absorb)
   401 apply(simp add: map_upd_upds_conv_if)
   402 done
   403 
   404 
   405 subsection {* @{term map_upd_s} *}
   406 
   407 lemma map_upd_s_apply [simp]: 
   408   "(m(as{|->}b)) x = (if x : as then Some b else m x)"
   409 by (simp add: map_upd_s_def)
   410 
   411 lemma map_subst_apply [simp]: 
   412   "(m(a~>b)) x = (if m x = Some a then Some b else m x)" 
   413 by (simp add: map_subst_def)
   414 
   415 subsection {* @{term dom} *}
   416 
   417 lemma domI: "m a = Some b ==> a : dom m"
   418 apply (unfold dom_def)
   419 apply auto
   420 done
   421 (* declare domI [intro]? *)
   422 
   423 lemma domD: "a : dom m ==> ? b. m a = Some b"
   424 apply (unfold dom_def)
   425 apply auto
   426 done
   427 
   428 lemma domIff[iff]: "(a : dom m) = (m a ~= None)"
   429 apply (unfold dom_def)
   430 apply auto
   431 done
   432 declare domIff [simp del]
   433 
   434 lemma dom_empty[simp]: "dom empty = {}"
   435 apply (unfold dom_def)
   436 apply (simp (no_asm))
   437 done
   438 
   439 lemma dom_fun_upd[simp]:
   440  "dom(f(x := y)) = (if y=None then dom f - {x} else insert x (dom f))"
   441 by (simp add:dom_def) blast
   442 
   443 lemma dom_map_of: "dom(map_of xys) = {x. \<exists>y. (x,y) : set xys}"
   444 apply(induct xys)
   445 apply(auto simp del:fun_upd_apply)
   446 done
   447 
   448 lemma finite_dom_map_of: "finite (dom (map_of l))"
   449 apply (unfold dom_def)
   450 apply (induct_tac "l")
   451 apply (auto simp add: insert_Collect [symmetric])
   452 done
   453 
   454 lemma dom_map_upds[simp]:
   455  "!!m ys. dom(m(xs[|->]ys)) = set(take (length ys) xs) Un dom m"
   456 apply(induct xs)
   457  apply simp
   458 apply(case_tac ys)
   459  apply auto
   460 done
   461 
   462 lemma dom_map_add[simp]: "dom(m++n) = dom n Un dom m"
   463 apply (unfold dom_def)
   464 apply auto
   465 done
   466 
   467 lemma dom_overwrite[simp]:
   468  "dom(f(g|A)) = (dom f  - {a. a : A - dom g}) Un {a. a : A Int dom g}"
   469 by(auto simp add: dom_def overwrite_def)
   470 
   471 lemma map_add_comm: "dom m1 \<inter> dom m2 = {} \<Longrightarrow> m1++m2 = m2++m1"
   472 apply(rule ext)
   473 apply(fastsimp simp:map_add_def split:option.split)
   474 done
   475 
   476 subsection {* @{term ran} *}
   477 
   478 lemma ranI: "m a = Some b ==> b : ran m" 
   479 by (auto simp add: ran_def)
   480 (* declare ranI [intro]? *)
   481 
   482 lemma ran_empty[simp]: "ran empty = {}"
   483 apply (unfold ran_def)
   484 apply (simp (no_asm))
   485 done
   486 
   487 lemma ran_map_upd[simp]: "m a = None ==> ran(m(a|->b)) = insert b (ran m)"
   488 apply (unfold ran_def)
   489 apply auto
   490 apply (subgoal_tac "~ (aa = a) ")
   491 apply auto
   492 done
   493 
   494 subsection {* @{text "map_le"} *}
   495 
   496 lemma map_le_empty [simp]: "empty \<subseteq>\<^sub>m g"
   497 by(simp add:map_le_def)
   498 
   499 lemma [simp]: "f(x := None) \<subseteq>\<^sub>m f"
   500 by(force simp add:map_le_def)
   501 
   502 lemma map_le_upd[simp]: "f \<subseteq>\<^sub>m g ==> f(a := b) \<subseteq>\<^sub>m g(a := b)"
   503 by(fastsimp simp add:map_le_def)
   504 
   505 lemma [simp]: "m1 \<subseteq>\<^sub>m m2 \<Longrightarrow> m1(x := None) \<subseteq>\<^sub>m m2(x \<mapsto> y)"
   506 by(force simp add:map_le_def)
   507 
   508 lemma map_le_upds[simp]:
   509  "!!f g bs. f \<subseteq>\<^sub>m g ==> f(as [|->] bs) \<subseteq>\<^sub>m g(as [|->] bs)"
   510 apply(induct as)
   511  apply simp
   512 apply(case_tac bs)
   513  apply auto
   514 done
   515 
   516 lemma map_le_implies_dom_le: "(f \<subseteq>\<^sub>m g) \<Longrightarrow> (dom f \<subseteq> dom g)"
   517   by (fastsimp simp add: map_le_def dom_def)
   518 
   519 lemma map_le_refl [simp]: "f \<subseteq>\<^sub>m f"
   520   by (simp add: map_le_def)
   521 
   522 lemma map_le_trans[trans]: "\<lbrakk> m1 \<subseteq>\<^sub>m m2; m2 \<subseteq>\<^sub>m m3\<rbrakk> \<Longrightarrow> m1 \<subseteq>\<^sub>m m3"
   523 by(force simp add:map_le_def)
   524 
   525 lemma map_le_antisym: "\<lbrakk> f \<subseteq>\<^sub>m g; g \<subseteq>\<^sub>m f \<rbrakk> \<Longrightarrow> f = g"
   526   apply (unfold map_le_def)
   527   apply (rule ext)
   528   apply (case_tac "x \<in> dom f")
   529     apply simp
   530   apply (case_tac "x \<in> dom g")
   531     apply simp
   532   apply fastsimp
   533 done
   534 
   535 lemma map_le_map_add [simp]: "f \<subseteq>\<^sub>m (g ++ f)"
   536   by (fastsimp simp add: map_le_def)
   537 
   538 end