src/HOL/Number_Theory/Euclidean_Algorithm.thy
 author Manuel Eberl Sun Feb 28 12:05:52 2016 +0100 (2016-02-28) changeset 62442 26e4be6a680f parent 62429 25271ff79171 child 62457 a3c7bd201da7 permissions -rw-r--r--
More efficient Extended Euclidean Algorithm
1 (* Author: Manuel Eberl *)
3 section \<open>Abstract euclidean algorithm\<close>
5 theory Euclidean_Algorithm
6 imports "~~/src/HOL/GCD" "~~/src/HOL/Library/Polynomial"
7 begin
9 text \<open>
10   A Euclidean semiring is a semiring upon which the Euclidean algorithm can be
11   implemented. It must provide:
12   \begin{itemize}
13   \item division with remainder
14   \item a size function such that @{term "size (a mod b) < size b"}
15         for any @{term "b \<noteq> 0"}
16   \end{itemize}
17   The existence of these functions makes it possible to derive gcd and lcm functions
18   for any Euclidean semiring.
19 \<close>
20 class euclidean_semiring = semiring_div + normalization_semidom +
21   fixes euclidean_size :: "'a \<Rightarrow> nat"
22   assumes size_0 [simp]: "euclidean_size 0 = 0"
23   assumes mod_size_less:
24     "b \<noteq> 0 \<Longrightarrow> euclidean_size (a mod b) < euclidean_size b"
25   assumes size_mult_mono:
26     "b \<noteq> 0 \<Longrightarrow> euclidean_size a \<le> euclidean_size (a * b)"
27 begin
29 lemma euclidean_division:
30   fixes a :: 'a and b :: 'a
31   assumes "b \<noteq> 0"
32   obtains s and t where "a = s * b + t"
33     and "euclidean_size t < euclidean_size b"
34 proof -
35   from div_mod_equality [of a b 0]
36      have "a = a div b * b + a mod b" by simp
37   with that and assms show ?thesis by (auto simp add: mod_size_less)
38 qed
40 lemma dvd_euclidean_size_eq_imp_dvd:
41   assumes "a \<noteq> 0" and b_dvd_a: "b dvd a" and size_eq: "euclidean_size a = euclidean_size b"
42   shows "a dvd b"
43 proof (rule ccontr)
44   assume "\<not> a dvd b"
45   then have "b mod a \<noteq> 0" by (simp add: mod_eq_0_iff_dvd)
46   from b_dvd_a have b_dvd_mod: "b dvd b mod a" by (simp add: dvd_mod_iff)
47   from b_dvd_mod obtain c where "b mod a = b * c" unfolding dvd_def by blast
48     with \<open>b mod a \<noteq> 0\<close> have "c \<noteq> 0" by auto
49   with \<open>b mod a = b * c\<close> have "euclidean_size (b mod a) \<ge> euclidean_size b"
50       using size_mult_mono by force
51   moreover from \<open>\<not> a dvd b\<close> and \<open>a \<noteq> 0\<close>
52   have "euclidean_size (b mod a) < euclidean_size a"
53       using mod_size_less by blast
54   ultimately show False using size_eq by simp
55 qed
57 function gcd_eucl :: "'a \<Rightarrow> 'a \<Rightarrow> 'a"
58 where
59   "gcd_eucl a b = (if b = 0 then normalize a else gcd_eucl b (a mod b))"
60   by pat_completeness simp
61 termination
62   by (relation "measure (euclidean_size \<circ> snd)") (simp_all add: mod_size_less)
64 declare gcd_eucl.simps [simp del]
66 lemma gcd_eucl_induct [case_names zero mod]:
67   assumes H1: "\<And>b. P b 0"
68   and H2: "\<And>a b. b \<noteq> 0 \<Longrightarrow> P b (a mod b) \<Longrightarrow> P a b"
69   shows "P a b"
70 proof (induct a b rule: gcd_eucl.induct)
71   case ("1" a b)
72   show ?case
73   proof (cases "b = 0")
74     case True then show "P a b" by simp (rule H1)
75   next
76     case False
77     then have "P b (a mod b)"
78       by (rule "1.hyps")
79     with \<open>b \<noteq> 0\<close> show "P a b"
80       by (blast intro: H2)
81   qed
82 qed
84 definition lcm_eucl :: "'a \<Rightarrow> 'a \<Rightarrow> 'a"
85 where
86   "lcm_eucl a b = normalize (a * b) div gcd_eucl a b"
88 definition Lcm_eucl :: "'a set \<Rightarrow> 'a" -- \<open>
89   Somewhat complicated definition of Lcm that has the advantage of working
90   for infinite sets as well\<close>
91 where
92   "Lcm_eucl A = (if \<exists>l. l \<noteq> 0 \<and> (\<forall>a\<in>A. a dvd l) then
93      let l = SOME l. l \<noteq> 0 \<and> (\<forall>a\<in>A. a dvd l) \<and> euclidean_size l =
94        (LEAST n. \<exists>l. l \<noteq> 0 \<and> (\<forall>a\<in>A. a dvd l) \<and> euclidean_size l = n)
95        in normalize l
96       else 0)"
98 definition Gcd_eucl :: "'a set \<Rightarrow> 'a"
99 where
100   "Gcd_eucl A = Lcm_eucl {d. \<forall>a\<in>A. d dvd a}"
102 declare Lcm_eucl_def Gcd_eucl_def [code del]
104 lemma gcd_eucl_0:
105   "gcd_eucl a 0 = normalize a"
106   by (simp add: gcd_eucl.simps [of a 0])
108 lemma gcd_eucl_0_left:
109   "gcd_eucl 0 a = normalize a"
110   by (simp_all add: gcd_eucl_0 gcd_eucl.simps [of 0 a])
112 lemma gcd_eucl_non_0:
113   "b \<noteq> 0 \<Longrightarrow> gcd_eucl a b = gcd_eucl b (a mod b)"
114   by (simp add: gcd_eucl.simps [of a b] gcd_eucl.simps [of b 0])
116 lemma gcd_eucl_dvd1 [iff]: "gcd_eucl a b dvd a"
117   and gcd_eucl_dvd2 [iff]: "gcd_eucl a b dvd b"
118   by (induct a b rule: gcd_eucl_induct)
119      (simp_all add: gcd_eucl_0 gcd_eucl_non_0 dvd_mod_iff)
121 lemma normalize_gcd_eucl [simp]:
122   "normalize (gcd_eucl a b) = gcd_eucl a b"
123   by (induct a b rule: gcd_eucl_induct) (simp_all add: gcd_eucl_0 gcd_eucl_non_0)
125 lemma gcd_eucl_greatest:
126   fixes k a b :: 'a
127   shows "k dvd a \<Longrightarrow> k dvd b \<Longrightarrow> k dvd gcd_eucl a b"
128 proof (induct a b rule: gcd_eucl_induct)
129   case (zero a) from zero(1) show ?case by (rule dvd_trans) (simp add: gcd_eucl_0)
130 next
131   case (mod a b)
132   then show ?case
133     by (simp add: gcd_eucl_non_0 dvd_mod_iff)
134 qed
136 lemma eq_gcd_euclI:
137   fixes gcd :: "'a \<Rightarrow> 'a \<Rightarrow> 'a"
138   assumes "\<And>a b. gcd a b dvd a" "\<And>a b. gcd a b dvd b" "\<And>a b. normalize (gcd a b) = gcd a b"
139           "\<And>a b k. k dvd a \<Longrightarrow> k dvd b \<Longrightarrow> k dvd gcd a b"
140   shows   "gcd = gcd_eucl"
141   by (intro ext, rule associated_eqI) (simp_all add: gcd_eucl_greatest assms)
143 lemma gcd_eucl_zero [simp]:
144   "gcd_eucl a b = 0 \<longleftrightarrow> a = 0 \<and> b = 0"
145   by (metis dvd_0_left dvd_refl gcd_eucl_dvd1 gcd_eucl_dvd2 gcd_eucl_greatest)+
148 lemma dvd_Lcm_eucl [simp]: "a \<in> A \<Longrightarrow> a dvd Lcm_eucl A"
149   and Lcm_eucl_least: "(\<And>a. a \<in> A \<Longrightarrow> a dvd b) \<Longrightarrow> Lcm_eucl A dvd b"
150   and unit_factor_Lcm_eucl [simp]:
151           "unit_factor (Lcm_eucl A) = (if Lcm_eucl A = 0 then 0 else 1)"
152 proof -
153   have "(\<forall>a\<in>A. a dvd Lcm_eucl A) \<and> (\<forall>l'. (\<forall>a\<in>A. a dvd l') \<longrightarrow> Lcm_eucl A dvd l') \<and>
154     unit_factor (Lcm_eucl A) = (if Lcm_eucl A = 0 then 0 else 1)" (is ?thesis)
155   proof (cases "\<exists>l. l \<noteq>  0 \<and> (\<forall>a\<in>A. a dvd l)")
156     case False
157     hence "Lcm_eucl A = 0" by (auto simp: Lcm_eucl_def)
158     with False show ?thesis by auto
159   next
160     case True
161     then obtain l\<^sub>0 where l\<^sub>0_props: "l\<^sub>0 \<noteq> 0 \<and> (\<forall>a\<in>A. a dvd l\<^sub>0)" by blast
162     def n \<equiv> "LEAST n. \<exists>l. l \<noteq> 0 \<and> (\<forall>a\<in>A. a dvd l) \<and> euclidean_size l = n"
163     def l \<equiv> "SOME l. l \<noteq> 0 \<and> (\<forall>a\<in>A. a dvd l) \<and> euclidean_size l = n"
164     have "\<exists>l. l \<noteq> 0 \<and> (\<forall>a\<in>A. a dvd l) \<and> euclidean_size l = n"
165       apply (subst n_def)
166       apply (rule LeastI[of _ "euclidean_size l\<^sub>0"])
167       apply (rule exI[of _ l\<^sub>0])
169       done
170     from someI_ex[OF this] have "l \<noteq> 0" and "\<forall>a\<in>A. a dvd l" and "euclidean_size l = n"
171       unfolding l_def by simp_all
172     {
173       fix l' assume "\<forall>a\<in>A. a dvd l'"
174       with \<open>\<forall>a\<in>A. a dvd l\<close> have "\<forall>a\<in>A. a dvd gcd_eucl l l'" by (auto intro: gcd_eucl_greatest)
175       moreover from \<open>l \<noteq> 0\<close> have "gcd_eucl l l' \<noteq> 0" by simp
176       ultimately have "\<exists>b. b \<noteq> 0 \<and> (\<forall>a\<in>A. a dvd b) \<and>
177                           euclidean_size b = euclidean_size (gcd_eucl l l')"
178         by (intro exI[of _ "gcd_eucl l l'"], auto)
179       hence "euclidean_size (gcd_eucl l l') \<ge> n" by (subst n_def) (rule Least_le)
180       moreover have "euclidean_size (gcd_eucl l l') \<le> n"
181       proof -
182         have "gcd_eucl l l' dvd l" by simp
183         then obtain a where "l = gcd_eucl l l' * a" unfolding dvd_def by blast
184         with \<open>l \<noteq> 0\<close> have "a \<noteq> 0" by auto
185         hence "euclidean_size (gcd_eucl l l') \<le> euclidean_size (gcd_eucl l l' * a)"
186           by (rule size_mult_mono)
187         also have "gcd_eucl l l' * a = l" using \<open>l = gcd_eucl l l' * a\<close> ..
188         also note \<open>euclidean_size l = n\<close>
189         finally show "euclidean_size (gcd_eucl l l') \<le> n" .
190       qed
191       ultimately have *: "euclidean_size l = euclidean_size (gcd_eucl l l')"
192         by (intro le_antisym, simp_all add: \<open>euclidean_size l = n\<close>)
193       from \<open>l \<noteq> 0\<close> have "l dvd gcd_eucl l l'"
194         by (rule dvd_euclidean_size_eq_imp_dvd) (auto simp add: *)
195       hence "l dvd l'" by (rule dvd_trans[OF _ gcd_eucl_dvd2])
196     }
198     with \<open>(\<forall>a\<in>A. a dvd l)\<close> and unit_factor_is_unit[OF \<open>l \<noteq> 0\<close>] and \<open>l \<noteq> 0\<close>
199       have "(\<forall>a\<in>A. a dvd normalize l) \<and>
200         (\<forall>l'. (\<forall>a\<in>A. a dvd l') \<longrightarrow> normalize l dvd l') \<and>
201         unit_factor (normalize l) =
202         (if normalize l = 0 then 0 else 1)"
203       by (auto simp: unit_simps)
204     also from True have "normalize l = Lcm_eucl A"
205       by (simp add: Lcm_eucl_def Let_def n_def l_def)
206     finally show ?thesis .
207   qed
208   note A = this
210   {fix a assume "a \<in> A" then show "a dvd Lcm_eucl A" using A by blast}
211   {fix b assume "\<And>a. a \<in> A \<Longrightarrow> a dvd b" then show "Lcm_eucl A dvd b" using A by blast}
212   from A show "unit_factor (Lcm_eucl A) = (if Lcm_eucl A = 0 then 0 else 1)" by blast
213 qed
215 lemma normalize_Lcm_eucl [simp]:
216   "normalize (Lcm_eucl A) = Lcm_eucl A"
217 proof (cases "Lcm_eucl A = 0")
218   case True then show ?thesis by simp
219 next
220   case False
221   have "unit_factor (Lcm_eucl A) * normalize (Lcm_eucl A) = Lcm_eucl A"
222     by (fact unit_factor_mult_normalize)
223   with False show ?thesis by simp
224 qed
226 lemma eq_Lcm_euclI:
227   fixes lcm :: "'a set \<Rightarrow> 'a"
228   assumes "\<And>A a. a \<in> A \<Longrightarrow> a dvd lcm A" and "\<And>A c. (\<And>a. a \<in> A \<Longrightarrow> a dvd c) \<Longrightarrow> lcm A dvd c"
229           "\<And>A. normalize (lcm A) = lcm A" shows "lcm = Lcm_eucl"
230   by (intro ext, rule associated_eqI) (auto simp: assms intro: Lcm_eucl_least)
232 end
234 class euclidean_ring = euclidean_semiring + idom
235 begin
237 function euclid_ext_aux :: "'a \<Rightarrow> _" where
238   "euclid_ext_aux r' r s' s t' t = (
239      if r = 0 then let c = 1 div unit_factor r' in (s' * c, t' * c, normalize r')
240      else let q = r' div r
241           in  euclid_ext_aux r (r' mod r) s (s' - q * s) t (t' - q * t))"
242 by auto
243 termination by (relation "measure (\<lambda>(_,b,_,_,_,_). euclidean_size b)") (simp_all add: mod_size_less)
245 declare euclid_ext_aux.simps [simp del]
247 lemma euclid_ext_aux_correct:
248   assumes "gcd_eucl r' r = gcd_eucl x y"
249   assumes "s' * x + t' * y = r'"
250   assumes "s * x + t * y = r"
251   shows   "case euclid_ext_aux r' r s' s t' t of (a,b,c) \<Rightarrow>
252              a * x + b * y = c \<and> c = gcd_eucl x y" (is "?P (euclid_ext_aux r' r s' s t' t)")
253 using assms
254 proof (induction r' r s' s t' t rule: euclid_ext_aux.induct)
255   case (1 r' r s' s t' t)
256   show ?case
257   proof (cases "r = 0")
258     case True
259     hence "euclid_ext_aux r' r s' s t' t =
260              (s' div unit_factor r', t' div unit_factor r', normalize r')"
261       by (subst euclid_ext_aux.simps) (simp add: Let_def)
262     also have "?P \<dots>"
263     proof safe
264       have "s' div unit_factor r' * x + t' div unit_factor r' * y =
265                 (s' * x + t' * y) div unit_factor r'"
266         by (cases "r' = 0") (simp_all add: unit_div_commute)
267       also have "s' * x + t' * y = r'" by fact
268       also have "\<dots> div unit_factor r' = normalize r'" by simp
269       finally show "s' div unit_factor r' * x + t' div unit_factor r' * y = normalize r'" .
270     next
271       from "1.prems" True show "normalize r' = gcd_eucl x y" by (simp add: gcd_eucl_0)
272     qed
273     finally show ?thesis .
274   next
275     case False
276     hence "euclid_ext_aux r' r s' s t' t =
277              euclid_ext_aux r (r' mod r) s (s' - r' div r * s) t (t' - r' div r * t)"
278       by (subst euclid_ext_aux.simps) (simp add: Let_def)
279     also from "1.prems" False have "?P \<dots>"
280     proof (intro "1.IH")
281       have "(s' - r' div r * s) * x + (t' - r' div r * t) * y =
282               (s' * x + t' * y) - r' div r * (s * x + t * y)" by (simp add: algebra_simps)
283       also have "s' * x + t' * y = r'" by fact
284       also have "s * x + t * y = r" by fact
285       also have "r' - r' div r * r = r' mod r" using mod_div_equality[of r' r]
287       finally show "(s' - r' div r * s) * x + (t' - r' div r * t) * y = r' mod r" .
288     qed (auto simp: gcd_eucl_non_0 algebra_simps div_mod_equality')
289     finally show ?thesis .
290   qed
291 qed
293 definition euclid_ext where
294   "euclid_ext a b = euclid_ext_aux a b 1 0 0 1"
296 lemma euclid_ext_0:
297   "euclid_ext a 0 = (1 div unit_factor a, 0, normalize a)"
298   by (simp add: euclid_ext_def euclid_ext_aux.simps)
300 lemma euclid_ext_left_0:
301   "euclid_ext 0 a = (0, 1 div unit_factor a, normalize a)"
302   by (simp add: euclid_ext_def euclid_ext_aux.simps)
304 lemma euclid_ext_correct':
305   "case euclid_ext x y of (a,b,c) \<Rightarrow> a * x + b * y = c \<and> c = gcd_eucl x y"
306   unfolding euclid_ext_def by (rule euclid_ext_aux_correct) simp_all
308 definition euclid_ext' where
309   "euclid_ext' x y = (case euclid_ext x y of (a, b, _) \<Rightarrow> (a, b))"
311 lemma euclid_ext'_correct':
312   "case euclid_ext' x y of (a,b) \<Rightarrow> a * x + b * y = gcd_eucl x y"
313   using euclid_ext_correct'[of x y] by (simp add: case_prod_unfold euclid_ext'_def)
315 lemma euclid_ext'_0: "euclid_ext' a 0 = (1 div unit_factor a, 0)"
316   by (simp add: euclid_ext'_def euclid_ext_0)
318 lemma euclid_ext'_left_0: "euclid_ext' 0 a = (0, 1 div unit_factor a)"
319   by (simp add: euclid_ext'_def euclid_ext_left_0)
321 end
323 class euclidean_semiring_gcd = euclidean_semiring + gcd + Gcd +
324   assumes gcd_gcd_eucl: "gcd = gcd_eucl" and lcm_lcm_eucl: "lcm = lcm_eucl"
325   assumes Gcd_Gcd_eucl: "Gcd = Gcd_eucl" and Lcm_Lcm_eucl: "Lcm = Lcm_eucl"
326 begin
328 subclass semiring_gcd
329   by standard (simp_all add: gcd_gcd_eucl gcd_eucl_greatest lcm_lcm_eucl lcm_eucl_def)
331 subclass semiring_Gcd
332   by standard (auto simp: Gcd_Gcd_eucl Lcm_Lcm_eucl Gcd_eucl_def intro: Lcm_eucl_least)
334 lemma gcd_non_0:
335   "b \<noteq> 0 \<Longrightarrow> gcd a b = gcd b (a mod b)"
336   unfolding gcd_gcd_eucl by (fact gcd_eucl_non_0)
338 lemmas gcd_0 = gcd_0_right
339 lemmas dvd_gcd_iff = gcd_greatest_iff
340 lemmas gcd_greatest_iff = dvd_gcd_iff
342 lemma gcd_mod1 [simp]:
343   "gcd (a mod b) b = gcd a b"
344   by (rule gcdI, metis dvd_mod_iff gcd_dvd1 gcd_dvd2, simp_all add: gcd_greatest dvd_mod_iff)
346 lemma gcd_mod2 [simp]:
347   "gcd a (b mod a) = gcd a b"
348   by (rule gcdI, simp, metis dvd_mod_iff gcd_dvd1 gcd_dvd2, simp_all add: gcd_greatest dvd_mod_iff)
350 lemma euclidean_size_gcd_le1 [simp]:
351   assumes "a \<noteq> 0"
352   shows "euclidean_size (gcd a b) \<le> euclidean_size a"
353 proof -
354    have "gcd a b dvd a" by (rule gcd_dvd1)
355    then obtain c where A: "a = gcd a b * c" unfolding dvd_def by blast
356    with \<open>a \<noteq> 0\<close> show ?thesis by (subst (2) A, intro size_mult_mono) auto
357 qed
359 lemma euclidean_size_gcd_le2 [simp]:
360   "b \<noteq> 0 \<Longrightarrow> euclidean_size (gcd a b) \<le> euclidean_size b"
361   by (subst gcd.commute, rule euclidean_size_gcd_le1)
363 lemma euclidean_size_gcd_less1:
364   assumes "a \<noteq> 0" and "\<not>a dvd b"
365   shows "euclidean_size (gcd a b) < euclidean_size a"
366 proof (rule ccontr)
367   assume "\<not>euclidean_size (gcd a b) < euclidean_size a"
368   with \<open>a \<noteq> 0\<close> have A: "euclidean_size (gcd a b) = euclidean_size a"
369     by (intro le_antisym, simp_all)
370   have "a dvd gcd a b"
371     by (rule dvd_euclidean_size_eq_imp_dvd) (simp_all add: assms A)
372   hence "a dvd b" using dvd_gcdD2 by blast
373   with \<open>\<not>a dvd b\<close> show False by contradiction
374 qed
376 lemma euclidean_size_gcd_less2:
377   assumes "b \<noteq> 0" and "\<not>b dvd a"
378   shows "euclidean_size (gcd a b) < euclidean_size b"
379   using assms by (subst gcd.commute, rule euclidean_size_gcd_less1)
381 lemma euclidean_size_lcm_le1:
382   assumes "a \<noteq> 0" and "b \<noteq> 0"
383   shows "euclidean_size a \<le> euclidean_size (lcm a b)"
384 proof -
385   have "a dvd lcm a b" by (rule dvd_lcm1)
386   then obtain c where A: "lcm a b = a * c" ..
387   with \<open>a \<noteq> 0\<close> and \<open>b \<noteq> 0\<close> have "c \<noteq> 0" by (auto simp: lcm_eq_0_iff)
388   then show ?thesis by (subst A, intro size_mult_mono)
389 qed
391 lemma euclidean_size_lcm_le2:
392   "a \<noteq> 0 \<Longrightarrow> b \<noteq> 0 \<Longrightarrow> euclidean_size b \<le> euclidean_size (lcm a b)"
393   using euclidean_size_lcm_le1 [of b a] by (simp add: ac_simps)
395 lemma euclidean_size_lcm_less1:
396   assumes "b \<noteq> 0" and "\<not>b dvd a"
397   shows "euclidean_size a < euclidean_size (lcm a b)"
398 proof (rule ccontr)
399   from assms have "a \<noteq> 0" by auto
400   assume "\<not>euclidean_size a < euclidean_size (lcm a b)"
401   with \<open>a \<noteq> 0\<close> and \<open>b \<noteq> 0\<close> have "euclidean_size (lcm a b) = euclidean_size a"
402     by (intro le_antisym, simp, intro euclidean_size_lcm_le1)
403   with assms have "lcm a b dvd a"
404     by (rule_tac dvd_euclidean_size_eq_imp_dvd) (auto simp: lcm_eq_0_iff)
405   hence "b dvd a" by (rule lcm_dvdD2)
406   with \<open>\<not>b dvd a\<close> show False by contradiction
407 qed
409 lemma euclidean_size_lcm_less2:
410   assumes "a \<noteq> 0" and "\<not>a dvd b"
411   shows "euclidean_size b < euclidean_size (lcm a b)"
412   using assms euclidean_size_lcm_less1 [of a b] by (simp add: ac_simps)
414 lemma Lcm_eucl_set [code]:
415   "Lcm_eucl (set xs) = foldl lcm_eucl 1 xs"
416   by (simp add: Lcm_Lcm_eucl [symmetric] lcm_lcm_eucl Lcm_set)
418 lemma Gcd_eucl_set [code]:
419   "Gcd_eucl (set xs) = foldl gcd_eucl 0 xs"
420   by (simp add: Gcd_Gcd_eucl [symmetric] gcd_gcd_eucl Gcd_set)
422 end
424 text \<open>
425   A Euclidean ring is a Euclidean semiring with additive inverses. It provides a
426   few more lemmas; in particular, Bezout's lemma holds for any Euclidean ring.
427 \<close>
429 class euclidean_ring_gcd = euclidean_semiring_gcd + idom
430 begin
432 subclass euclidean_ring ..
433 subclass ring_gcd ..
435 lemma euclid_ext_gcd [simp]:
436   "(case euclid_ext a b of (_, _ , t) \<Rightarrow> t) = gcd a b"
437   using euclid_ext_correct'[of a b] by (simp add: case_prod_unfold Let_def gcd_gcd_eucl)
439 lemma euclid_ext_gcd' [simp]:
440   "euclid_ext a b = (r, s, t) \<Longrightarrow> t = gcd a b"
441   by (insert euclid_ext_gcd[of a b], drule (1) subst, simp)
443 lemma euclid_ext_correct:
444   "case euclid_ext x y of (a,b,c) \<Rightarrow> a * x + b * y = c \<and> c = gcd x y"
445   using euclid_ext_correct'[of x y]
446   by (simp add: gcd_gcd_eucl case_prod_unfold)
448 lemma euclid_ext'_correct:
449   "fst (euclid_ext' a b) * a + snd (euclid_ext' a b) * b = gcd a b"
450   using euclid_ext_correct'[of a b]
451   by (simp add: gcd_gcd_eucl case_prod_unfold euclid_ext'_def)
453 lemma bezout: "\<exists>s t. s * a + t * b = gcd a b"
454   using euclid_ext'_correct by blast
456 end
459 subsection \<open>Typical instances\<close>
461 instantiation nat :: euclidean_semiring
462 begin
464 definition [simp]:
465   "euclidean_size_nat = (id :: nat \<Rightarrow> nat)"
467 instance proof
468 qed simp_all
470 end
473 instantiation int :: euclidean_ring
474 begin
476 definition [simp]:
477   "euclidean_size_int = (nat \<circ> abs :: int \<Rightarrow> nat)"
479 instance
480 by standard (auto simp add: abs_mult nat_mult_distrib split: abs_split)
482 end
485 instantiation poly :: (field) euclidean_ring
486 begin
488 definition euclidean_size_poly :: "'a poly \<Rightarrow> nat"
489   where "euclidean_size p = (if p = 0 then 0 else 2 ^ degree p)"
491 lemma euclidean_size_poly_0 [simp]:
492   "euclidean_size (0::'a poly) = 0"
495 lemma euclidean_size_poly_not_0 [simp]:
496   "p \<noteq> 0 \<Longrightarrow> euclidean_size p = 2 ^ degree p"
499 instance
500 proof
501   fix p q :: "'a poly"
502   assume "q \<noteq> 0"
503   then have "p mod q = 0 \<or> degree (p mod q) < degree q"
504     by (rule degree_mod_less [of q p])
505   with \<open>q \<noteq> 0\<close> show "euclidean_size (p mod q) < euclidean_size q"
506     by (cases "p mod q = 0") simp_all
507 next
508   fix p q :: "'a poly"
509   assume "q \<noteq> 0"
510   from \<open>q \<noteq> 0\<close> have "degree p \<le> degree (p * q)"
511     by (rule degree_mult_right_le)
512   with \<open>q \<noteq> 0\<close> show "euclidean_size p \<le> euclidean_size (p * q)"
513     by (cases "p = 0") simp_all
514 qed simp
516 end
519 instance nat :: euclidean_semiring_gcd
520 proof
521   show [simp]: "gcd = (gcd_eucl :: nat \<Rightarrow> _)" "Lcm = (Lcm_eucl :: nat set \<Rightarrow> _)"
522     by (simp_all add: eq_gcd_euclI eq_Lcm_euclI)
523   show "lcm = (lcm_eucl :: nat \<Rightarrow> _)" "Gcd = (Gcd_eucl :: nat set \<Rightarrow> _)"
524     by (intro ext, simp add: lcm_eucl_def lcm_nat_def Gcd_nat_def Gcd_eucl_def)+
525 qed
527 instance int :: euclidean_ring_gcd
528 proof
529   show [simp]: "gcd = (gcd_eucl :: int \<Rightarrow> _)" "Lcm = (Lcm_eucl :: int set \<Rightarrow> _)"
530     by (simp_all add: eq_gcd_euclI eq_Lcm_euclI)
531   show "lcm = (lcm_eucl :: int \<Rightarrow> _)" "Gcd = (Gcd_eucl :: int set \<Rightarrow> _)"
532     by (intro ext, simp add: lcm_eucl_def lcm_altdef_int
533           semiring_Gcd_class.Gcd_Lcm Gcd_eucl_def abs_mult)+
534 qed
537 instantiation poly :: (field) euclidean_ring_gcd
538 begin
540 definition gcd_poly :: "'a poly \<Rightarrow> 'a poly \<Rightarrow> 'a poly" where
541   "gcd_poly = gcd_eucl"
543 definition lcm_poly :: "'a poly \<Rightarrow> 'a poly \<Rightarrow> 'a poly" where
544   "lcm_poly = lcm_eucl"
546 definition Gcd_poly :: "'a poly set \<Rightarrow> 'a poly" where
547   "Gcd_poly = Gcd_eucl"
549 definition Lcm_poly :: "'a poly set \<Rightarrow> 'a poly" where
550   "Lcm_poly = Lcm_eucl"
552 instance by standard (simp_all only: gcd_poly_def lcm_poly_def Gcd_poly_def Lcm_poly_def)
553 end
555 lemma poly_gcd_monic:
556   "lead_coeff (gcd x y) = (if x = 0 \<and> y = 0 then 0 else 1)"
557   using unit_factor_gcd[of x y]
560 lemma poly_dvd_antisym:
561   fixes p q :: "'a::idom poly"
562   assumes coeff: "coeff p (degree p) = coeff q (degree q)"
563   assumes dvd1: "p dvd q" and dvd2: "q dvd p" shows "p = q"
564 proof (cases "p = 0")
565   case True with coeff show "p = q" by simp
566 next
567   case False with coeff have "q \<noteq> 0" by auto
568   have degree: "degree p = degree q"
569     using \<open>p dvd q\<close> \<open>q dvd p\<close> \<open>p \<noteq> 0\<close> \<open>q \<noteq> 0\<close>
570     by (intro order_antisym dvd_imp_degree_le)
572   from \<open>p dvd q\<close> obtain a where a: "q = p * a" ..
573   with \<open>q \<noteq> 0\<close> have "a \<noteq> 0" by auto
574   with degree a \<open>p \<noteq> 0\<close> have "degree a = 0"
576   with coeff a show "p = q"
577     by (cases a, auto split: if_splits)
578 qed
580 lemma poly_gcd_unique:
581   fixes d x y :: "_ poly"
582   assumes dvd1: "d dvd x" and dvd2: "d dvd y"
583     and greatest: "\<And>k. k dvd x \<Longrightarrow> k dvd y \<Longrightarrow> k dvd d"
584     and monic: "coeff d (degree d) = (if x = 0 \<and> y = 0 then 0 else 1)"
585   shows "d = gcd x y"
586   using assms by (intro gcdI) (auto simp: normalize_poly_def split: if_split_asm)
588 lemma poly_gcd_code [code]:
589   "gcd x y = (if y = 0 then normalize x else gcd y (x mod (y :: _ poly)))"
590   by (simp add: gcd_0 gcd_non_0)
592 end