src/HOL/Real_Vector_Spaces.thy
author hoelzl
Wed Apr 02 18:35:01 2014 +0200 (2014-04-02)
changeset 56369 2704ca85be98
parent 56194 9ffbb4004c81
child 56409 36489d77c484
permissions -rw-r--r--
moved generic theorems from Complex_Analysis_Basic; fixed some theorem names
     1 (*  Title:      HOL/Real_Vector_Spaces.thy
     2     Author:     Brian Huffman
     3     Author:     Johannes Hölzl
     4 *)
     5 
     6 header {* Vector Spaces and Algebras over the Reals *}
     7 
     8 theory Real_Vector_Spaces
     9 imports Real Topological_Spaces
    10 begin
    11 
    12 subsection {* Locale for additive functions *}
    13 
    14 locale additive =
    15   fixes f :: "'a::ab_group_add \<Rightarrow> 'b::ab_group_add"
    16   assumes add: "f (x + y) = f x + f y"
    17 begin
    18 
    19 lemma zero: "f 0 = 0"
    20 proof -
    21   have "f 0 = f (0 + 0)" by simp
    22   also have "\<dots> = f 0 + f 0" by (rule add)
    23   finally show "f 0 = 0" by simp
    24 qed
    25 
    26 lemma minus: "f (- x) = - f x"
    27 proof -
    28   have "f (- x) + f x = f (- x + x)" by (rule add [symmetric])
    29   also have "\<dots> = - f x + f x" by (simp add: zero)
    30   finally show "f (- x) = - f x" by (rule add_right_imp_eq)
    31 qed
    32 
    33 lemma diff: "f (x - y) = f x - f y"
    34   using add [of x "- y"] by (simp add: minus)
    35 
    36 lemma setsum: "f (setsum g A) = (\<Sum>x\<in>A. f (g x))"
    37 apply (cases "finite A")
    38 apply (induct set: finite)
    39 apply (simp add: zero)
    40 apply (simp add: add)
    41 apply (simp add: zero)
    42 done
    43 
    44 end
    45 
    46 subsection {* Vector spaces *}
    47 
    48 locale vector_space =
    49   fixes scale :: "'a::field \<Rightarrow> 'b::ab_group_add \<Rightarrow> 'b"
    50   assumes scale_right_distrib [algebra_simps]:
    51     "scale a (x + y) = scale a x + scale a y"
    52   and scale_left_distrib [algebra_simps]:
    53     "scale (a + b) x = scale a x + scale b x"
    54   and scale_scale [simp]: "scale a (scale b x) = scale (a * b) x"
    55   and scale_one [simp]: "scale 1 x = x"
    56 begin
    57 
    58 lemma scale_left_commute:
    59   "scale a (scale b x) = scale b (scale a x)"
    60 by (simp add: mult_commute)
    61 
    62 lemma scale_zero_left [simp]: "scale 0 x = 0"
    63   and scale_minus_left [simp]: "scale (- a) x = - (scale a x)"
    64   and scale_left_diff_distrib [algebra_simps]:
    65         "scale (a - b) x = scale a x - scale b x"
    66   and scale_setsum_left: "scale (setsum f A) x = (\<Sum>a\<in>A. scale (f a) x)"
    67 proof -
    68   interpret s: additive "\<lambda>a. scale a x"
    69     proof qed (rule scale_left_distrib)
    70   show "scale 0 x = 0" by (rule s.zero)
    71   show "scale (- a) x = - (scale a x)" by (rule s.minus)
    72   show "scale (a - b) x = scale a x - scale b x" by (rule s.diff)
    73   show "scale (setsum f A) x = (\<Sum>a\<in>A. scale (f a) x)" by (rule s.setsum)
    74 qed
    75 
    76 lemma scale_zero_right [simp]: "scale a 0 = 0"
    77   and scale_minus_right [simp]: "scale a (- x) = - (scale a x)"
    78   and scale_right_diff_distrib [algebra_simps]:
    79         "scale a (x - y) = scale a x - scale a y"
    80   and scale_setsum_right: "scale a (setsum f A) = (\<Sum>x\<in>A. scale a (f x))"
    81 proof -
    82   interpret s: additive "\<lambda>x. scale a x"
    83     proof qed (rule scale_right_distrib)
    84   show "scale a 0 = 0" by (rule s.zero)
    85   show "scale a (- x) = - (scale a x)" by (rule s.minus)
    86   show "scale a (x - y) = scale a x - scale a y" by (rule s.diff)
    87   show "scale a (setsum f A) = (\<Sum>x\<in>A. scale a (f x))" by (rule s.setsum)
    88 qed
    89 
    90 lemma scale_eq_0_iff [simp]:
    91   "scale a x = 0 \<longleftrightarrow> a = 0 \<or> x = 0"
    92 proof cases
    93   assume "a = 0" thus ?thesis by simp
    94 next
    95   assume anz [simp]: "a \<noteq> 0"
    96   { assume "scale a x = 0"
    97     hence "scale (inverse a) (scale a x) = 0" by simp
    98     hence "x = 0" by simp }
    99   thus ?thesis by force
   100 qed
   101 
   102 lemma scale_left_imp_eq:
   103   "\<lbrakk>a \<noteq> 0; scale a x = scale a y\<rbrakk> \<Longrightarrow> x = y"
   104 proof -
   105   assume nonzero: "a \<noteq> 0"
   106   assume "scale a x = scale a y"
   107   hence "scale a (x - y) = 0"
   108      by (simp add: scale_right_diff_distrib)
   109   hence "x - y = 0" by (simp add: nonzero)
   110   thus "x = y" by (simp only: right_minus_eq)
   111 qed
   112 
   113 lemma scale_right_imp_eq:
   114   "\<lbrakk>x \<noteq> 0; scale a x = scale b x\<rbrakk> \<Longrightarrow> a = b"
   115 proof -
   116   assume nonzero: "x \<noteq> 0"
   117   assume "scale a x = scale b x"
   118   hence "scale (a - b) x = 0"
   119      by (simp add: scale_left_diff_distrib)
   120   hence "a - b = 0" by (simp add: nonzero)
   121   thus "a = b" by (simp only: right_minus_eq)
   122 qed
   123 
   124 lemma scale_cancel_left [simp]:
   125   "scale a x = scale a y \<longleftrightarrow> x = y \<or> a = 0"
   126 by (auto intro: scale_left_imp_eq)
   127 
   128 lemma scale_cancel_right [simp]:
   129   "scale a x = scale b x \<longleftrightarrow> a = b \<or> x = 0"
   130 by (auto intro: scale_right_imp_eq)
   131 
   132 end
   133 
   134 subsection {* Real vector spaces *}
   135 
   136 class scaleR =
   137   fixes scaleR :: "real \<Rightarrow> 'a \<Rightarrow> 'a" (infixr "*\<^sub>R" 75)
   138 begin
   139 
   140 abbreviation
   141   divideR :: "'a \<Rightarrow> real \<Rightarrow> 'a" (infixl "'/\<^sub>R" 70)
   142 where
   143   "x /\<^sub>R r == scaleR (inverse r) x"
   144 
   145 end
   146 
   147 class real_vector = scaleR + ab_group_add +
   148   assumes scaleR_add_right: "scaleR a (x + y) = scaleR a x + scaleR a y"
   149   and scaleR_add_left: "scaleR (a + b) x = scaleR a x + scaleR b x"
   150   and scaleR_scaleR: "scaleR a (scaleR b x) = scaleR (a * b) x"
   151   and scaleR_one: "scaleR 1 x = x"
   152 
   153 interpretation real_vector:
   154   vector_space "scaleR :: real \<Rightarrow> 'a \<Rightarrow> 'a::real_vector"
   155 apply unfold_locales
   156 apply (rule scaleR_add_right)
   157 apply (rule scaleR_add_left)
   158 apply (rule scaleR_scaleR)
   159 apply (rule scaleR_one)
   160 done
   161 
   162 text {* Recover original theorem names *}
   163 
   164 lemmas scaleR_left_commute = real_vector.scale_left_commute
   165 lemmas scaleR_zero_left = real_vector.scale_zero_left
   166 lemmas scaleR_minus_left = real_vector.scale_minus_left
   167 lemmas scaleR_diff_left = real_vector.scale_left_diff_distrib
   168 lemmas scaleR_setsum_left = real_vector.scale_setsum_left
   169 lemmas scaleR_zero_right = real_vector.scale_zero_right
   170 lemmas scaleR_minus_right = real_vector.scale_minus_right
   171 lemmas scaleR_diff_right = real_vector.scale_right_diff_distrib
   172 lemmas scaleR_setsum_right = real_vector.scale_setsum_right
   173 lemmas scaleR_eq_0_iff = real_vector.scale_eq_0_iff
   174 lemmas scaleR_left_imp_eq = real_vector.scale_left_imp_eq
   175 lemmas scaleR_right_imp_eq = real_vector.scale_right_imp_eq
   176 lemmas scaleR_cancel_left = real_vector.scale_cancel_left
   177 lemmas scaleR_cancel_right = real_vector.scale_cancel_right
   178 
   179 text {* Legacy names *}
   180 
   181 lemmas scaleR_left_distrib = scaleR_add_left
   182 lemmas scaleR_right_distrib = scaleR_add_right
   183 lemmas scaleR_left_diff_distrib = scaleR_diff_left
   184 lemmas scaleR_right_diff_distrib = scaleR_diff_right
   185 
   186 lemma scaleR_minus1_left [simp]:
   187   fixes x :: "'a::real_vector"
   188   shows "scaleR (-1) x = - x"
   189   using scaleR_minus_left [of 1 x] by simp
   190 
   191 class real_algebra = real_vector + ring +
   192   assumes mult_scaleR_left [simp]: "scaleR a x * y = scaleR a (x * y)"
   193   and mult_scaleR_right [simp]: "x * scaleR a y = scaleR a (x * y)"
   194 
   195 class real_algebra_1 = real_algebra + ring_1
   196 
   197 class real_div_algebra = real_algebra_1 + division_ring
   198 
   199 class real_field = real_div_algebra + field
   200 
   201 instantiation real :: real_field
   202 begin
   203 
   204 definition
   205   real_scaleR_def [simp]: "scaleR a x = a * x"
   206 
   207 instance proof
   208 qed (simp_all add: algebra_simps)
   209 
   210 end
   211 
   212 interpretation scaleR_left: additive "(\<lambda>a. scaleR a x::'a::real_vector)"
   213 proof qed (rule scaleR_left_distrib)
   214 
   215 interpretation scaleR_right: additive "(\<lambda>x. scaleR a x::'a::real_vector)"
   216 proof qed (rule scaleR_right_distrib)
   217 
   218 lemma nonzero_inverse_scaleR_distrib:
   219   fixes x :: "'a::real_div_algebra" shows
   220   "\<lbrakk>a \<noteq> 0; x \<noteq> 0\<rbrakk> \<Longrightarrow> inverse (scaleR a x) = scaleR (inverse a) (inverse x)"
   221 by (rule inverse_unique, simp)
   222 
   223 lemma inverse_scaleR_distrib:
   224   fixes x :: "'a::{real_div_algebra, division_ring_inverse_zero}"
   225   shows "inverse (scaleR a x) = scaleR (inverse a) (inverse x)"
   226 apply (case_tac "a = 0", simp)
   227 apply (case_tac "x = 0", simp)
   228 apply (erule (1) nonzero_inverse_scaleR_distrib)
   229 done
   230 
   231 
   232 subsection {* Embedding of the Reals into any @{text real_algebra_1}:
   233 @{term of_real} *}
   234 
   235 definition
   236   of_real :: "real \<Rightarrow> 'a::real_algebra_1" where
   237   "of_real r = scaleR r 1"
   238 
   239 lemma scaleR_conv_of_real: "scaleR r x = of_real r * x"
   240 by (simp add: of_real_def)
   241 
   242 lemma of_real_0 [simp]: "of_real 0 = 0"
   243 by (simp add: of_real_def)
   244 
   245 lemma of_real_1 [simp]: "of_real 1 = 1"
   246 by (simp add: of_real_def)
   247 
   248 lemma of_real_add [simp]: "of_real (x + y) = of_real x + of_real y"
   249 by (simp add: of_real_def scaleR_left_distrib)
   250 
   251 lemma of_real_minus [simp]: "of_real (- x) = - of_real x"
   252 by (simp add: of_real_def)
   253 
   254 lemma of_real_diff [simp]: "of_real (x - y) = of_real x - of_real y"
   255 by (simp add: of_real_def scaleR_left_diff_distrib)
   256 
   257 lemma of_real_mult [simp]: "of_real (x * y) = of_real x * of_real y"
   258 by (simp add: of_real_def mult_commute)
   259 
   260 lemma nonzero_of_real_inverse:
   261   "x \<noteq> 0 \<Longrightarrow> of_real (inverse x) =
   262    inverse (of_real x :: 'a::real_div_algebra)"
   263 by (simp add: of_real_def nonzero_inverse_scaleR_distrib)
   264 
   265 lemma of_real_inverse [simp]:
   266   "of_real (inverse x) =
   267    inverse (of_real x :: 'a::{real_div_algebra, division_ring_inverse_zero})"
   268 by (simp add: of_real_def inverse_scaleR_distrib)
   269 
   270 lemma nonzero_of_real_divide:
   271   "y \<noteq> 0 \<Longrightarrow> of_real (x / y) =
   272    (of_real x / of_real y :: 'a::real_field)"
   273 by (simp add: divide_inverse nonzero_of_real_inverse)
   274 
   275 lemma of_real_divide [simp]:
   276   "of_real (x / y) =
   277    (of_real x / of_real y :: 'a::{real_field, field_inverse_zero})"
   278 by (simp add: divide_inverse)
   279 
   280 lemma of_real_power [simp]:
   281   "of_real (x ^ n) = (of_real x :: 'a::{real_algebra_1}) ^ n"
   282 by (induct n) simp_all
   283 
   284 lemma of_real_eq_iff [simp]: "(of_real x = of_real y) = (x = y)"
   285 by (simp add: of_real_def)
   286 
   287 lemma inj_of_real:
   288   "inj of_real"
   289   by (auto intro: injI)
   290 
   291 lemmas of_real_eq_0_iff [simp] = of_real_eq_iff [of _ 0, simplified]
   292 
   293 lemma of_real_eq_id [simp]: "of_real = (id :: real \<Rightarrow> real)"
   294 proof
   295   fix r
   296   show "of_real r = id r"
   297     by (simp add: of_real_def)
   298 qed
   299 
   300 text{*Collapse nested embeddings*}
   301 lemma of_real_of_nat_eq [simp]: "of_real (of_nat n) = of_nat n"
   302 by (induct n) auto
   303 
   304 lemma of_real_of_int_eq [simp]: "of_real (of_int z) = of_int z"
   305 by (cases z rule: int_diff_cases, simp)
   306 
   307 lemma of_real_numeral: "of_real (numeral w) = numeral w"
   308 using of_real_of_int_eq [of "numeral w"] by simp
   309 
   310 lemma of_real_neg_numeral: "of_real (- numeral w) = - numeral w"
   311 using of_real_of_int_eq [of "- numeral w"] by simp
   312 
   313 text{*Every real algebra has characteristic zero*}
   314 
   315 instance real_algebra_1 < ring_char_0
   316 proof
   317   from inj_of_real inj_of_nat have "inj (of_real \<circ> of_nat)" by (rule inj_comp)
   318   then show "inj (of_nat :: nat \<Rightarrow> 'a)" by (simp add: comp_def)
   319 qed
   320 
   321 instance real_field < field_char_0 ..
   322 
   323 
   324 subsection {* The Set of Real Numbers *}
   325 
   326 definition Reals :: "'a::real_algebra_1 set" where
   327   "Reals = range of_real"
   328 
   329 notation (xsymbols)
   330   Reals  ("\<real>")
   331 
   332 lemma Reals_of_real [simp]: "of_real r \<in> Reals"
   333 by (simp add: Reals_def)
   334 
   335 lemma Reals_of_int [simp]: "of_int z \<in> Reals"
   336 by (subst of_real_of_int_eq [symmetric], rule Reals_of_real)
   337 
   338 lemma Reals_of_nat [simp]: "of_nat n \<in> Reals"
   339 by (subst of_real_of_nat_eq [symmetric], rule Reals_of_real)
   340 
   341 lemma Reals_numeral [simp]: "numeral w \<in> Reals"
   342 by (subst of_real_numeral [symmetric], rule Reals_of_real)
   343 
   344 lemma Reals_0 [simp]: "0 \<in> Reals"
   345 apply (unfold Reals_def)
   346 apply (rule range_eqI)
   347 apply (rule of_real_0 [symmetric])
   348 done
   349 
   350 lemma Reals_1 [simp]: "1 \<in> Reals"
   351 apply (unfold Reals_def)
   352 apply (rule range_eqI)
   353 apply (rule of_real_1 [symmetric])
   354 done
   355 
   356 lemma Reals_add [simp]: "\<lbrakk>a \<in> Reals; b \<in> Reals\<rbrakk> \<Longrightarrow> a + b \<in> Reals"
   357 apply (auto simp add: Reals_def)
   358 apply (rule range_eqI)
   359 apply (rule of_real_add [symmetric])
   360 done
   361 
   362 lemma Reals_minus [simp]: "a \<in> Reals \<Longrightarrow> - a \<in> Reals"
   363 apply (auto simp add: Reals_def)
   364 apply (rule range_eqI)
   365 apply (rule of_real_minus [symmetric])
   366 done
   367 
   368 lemma Reals_diff [simp]: "\<lbrakk>a \<in> Reals; b \<in> Reals\<rbrakk> \<Longrightarrow> a - b \<in> Reals"
   369 apply (auto simp add: Reals_def)
   370 apply (rule range_eqI)
   371 apply (rule of_real_diff [symmetric])
   372 done
   373 
   374 lemma Reals_mult [simp]: "\<lbrakk>a \<in> Reals; b \<in> Reals\<rbrakk> \<Longrightarrow> a * b \<in> Reals"
   375 apply (auto simp add: Reals_def)
   376 apply (rule range_eqI)
   377 apply (rule of_real_mult [symmetric])
   378 done
   379 
   380 lemma nonzero_Reals_inverse:
   381   fixes a :: "'a::real_div_algebra"
   382   shows "\<lbrakk>a \<in> Reals; a \<noteq> 0\<rbrakk> \<Longrightarrow> inverse a \<in> Reals"
   383 apply (auto simp add: Reals_def)
   384 apply (rule range_eqI)
   385 apply (erule nonzero_of_real_inverse [symmetric])
   386 done
   387 
   388 lemma Reals_inverse:
   389   fixes a :: "'a::{real_div_algebra, division_ring_inverse_zero}"
   390   shows "a \<in> Reals \<Longrightarrow> inverse a \<in> Reals"
   391 apply (auto simp add: Reals_def)
   392 apply (rule range_eqI)
   393 apply (rule of_real_inverse [symmetric])
   394 done
   395 
   396 lemma Reals_inverse_iff [simp]: 
   397   fixes x:: "'a :: {real_div_algebra, division_ring_inverse_zero}"
   398   shows "inverse x \<in> \<real> \<longleftrightarrow> x \<in> \<real>"
   399 by (metis Reals_inverse inverse_inverse_eq)
   400 
   401 lemma nonzero_Reals_divide:
   402   fixes a b :: "'a::real_field"
   403   shows "\<lbrakk>a \<in> Reals; b \<in> Reals; b \<noteq> 0\<rbrakk> \<Longrightarrow> a / b \<in> Reals"
   404 apply (auto simp add: Reals_def)
   405 apply (rule range_eqI)
   406 apply (erule nonzero_of_real_divide [symmetric])
   407 done
   408 
   409 lemma Reals_divide [simp]:
   410   fixes a b :: "'a::{real_field, field_inverse_zero}"
   411   shows "\<lbrakk>a \<in> Reals; b \<in> Reals\<rbrakk> \<Longrightarrow> a / b \<in> Reals"
   412 apply (auto simp add: Reals_def)
   413 apply (rule range_eqI)
   414 apply (rule of_real_divide [symmetric])
   415 done
   416 
   417 lemma Reals_power [simp]:
   418   fixes a :: "'a::{real_algebra_1}"
   419   shows "a \<in> Reals \<Longrightarrow> a ^ n \<in> Reals"
   420 apply (auto simp add: Reals_def)
   421 apply (rule range_eqI)
   422 apply (rule of_real_power [symmetric])
   423 done
   424 
   425 lemma Reals_cases [cases set: Reals]:
   426   assumes "q \<in> \<real>"
   427   obtains (of_real) r where "q = of_real r"
   428   unfolding Reals_def
   429 proof -
   430   from `q \<in> \<real>` have "q \<in> range of_real" unfolding Reals_def .
   431   then obtain r where "q = of_real r" ..
   432   then show thesis ..
   433 qed
   434 
   435 lemma setsum_in_Reals: assumes "\<And>i. i \<in> s \<Longrightarrow> f i \<in> \<real>" shows "setsum f s \<in> \<real>"
   436 proof (cases "finite s")
   437   case True then show ?thesis using assms
   438     by (induct s rule: finite_induct) auto
   439 next
   440   case False then show ?thesis using assms
   441     by (metis Reals_0 setsum_infinite)
   442 qed
   443 
   444 lemma setprod_in_Reals: assumes "\<And>i. i \<in> s \<Longrightarrow> f i \<in> \<real>" shows "setprod f s \<in> \<real>"
   445 proof (cases "finite s")
   446   case True then show ?thesis using assms
   447     by (induct s rule: finite_induct) auto
   448 next
   449   case False then show ?thesis using assms
   450     by (metis Reals_1 setprod_infinite)
   451 qed
   452 
   453 lemma Reals_induct [case_names of_real, induct set: Reals]:
   454   "q \<in> \<real> \<Longrightarrow> (\<And>r. P (of_real r)) \<Longrightarrow> P q"
   455   by (rule Reals_cases) auto
   456 
   457 subsection {* Ordered real vector spaces *}
   458 
   459 class ordered_real_vector = real_vector + ordered_ab_group_add +
   460   assumes scaleR_left_mono: "x \<le> y \<Longrightarrow> 0 \<le> a \<Longrightarrow> a *\<^sub>R x \<le> a *\<^sub>R y"
   461   assumes scaleR_right_mono: "a \<le> b \<Longrightarrow> 0 \<le> x \<Longrightarrow> a *\<^sub>R x \<le> b *\<^sub>R x"
   462 begin
   463 
   464 lemma scaleR_mono:
   465   "a \<le> b \<Longrightarrow> x \<le> y \<Longrightarrow> 0 \<le> b \<Longrightarrow> 0 \<le> x \<Longrightarrow> a *\<^sub>R x \<le> b *\<^sub>R y"
   466 apply (erule scaleR_right_mono [THEN order_trans], assumption)
   467 apply (erule scaleR_left_mono, assumption)
   468 done
   469 
   470 lemma scaleR_mono':
   471   "a \<le> b \<Longrightarrow> c \<le> d \<Longrightarrow> 0 \<le> a \<Longrightarrow> 0 \<le> c \<Longrightarrow> a *\<^sub>R c \<le> b *\<^sub>R d"
   472   by (rule scaleR_mono) (auto intro: order.trans)
   473 
   474 lemma pos_le_divideRI:
   475   assumes "0 < c"
   476   assumes "c *\<^sub>R a \<le> b"
   477   shows "a \<le> b /\<^sub>R c"
   478 proof -
   479   from scaleR_left_mono[OF assms(2)] assms(1)
   480   have "c *\<^sub>R a /\<^sub>R c \<le> b /\<^sub>R c"
   481     by simp
   482   with assms show ?thesis
   483     by (simp add: scaleR_one scaleR_scaleR inverse_eq_divide)
   484 qed
   485 
   486 lemma pos_le_divideR_eq:
   487   assumes "0 < c"
   488   shows "a \<le> b /\<^sub>R c \<longleftrightarrow> c *\<^sub>R a \<le> b"
   489 proof rule
   490   assume "a \<le> b /\<^sub>R c"
   491   from scaleR_left_mono[OF this] assms
   492   have "c *\<^sub>R a \<le> c *\<^sub>R (b /\<^sub>R c)"
   493     by simp
   494   with assms show "c *\<^sub>R a \<le> b"
   495     by (simp add: scaleR_one scaleR_scaleR inverse_eq_divide)
   496 qed (rule pos_le_divideRI[OF assms])
   497 
   498 lemma scaleR_image_atLeastAtMost:
   499   "c > 0 \<Longrightarrow> scaleR c ` {x..y} = {c *\<^sub>R x..c *\<^sub>R y}"
   500   apply (auto intro!: scaleR_left_mono)
   501   apply (rule_tac x = "inverse c *\<^sub>R xa" in image_eqI)
   502   apply (simp_all add: pos_le_divideR_eq[symmetric] scaleR_scaleR scaleR_one)
   503   done
   504 
   505 end
   506 
   507 lemma scaleR_nonneg_nonneg: "0 \<le> a \<Longrightarrow> 0 \<le> (x::'a::ordered_real_vector) \<Longrightarrow> 0 \<le> a *\<^sub>R x"
   508   using scaleR_left_mono [of 0 x a]
   509   by simp
   510 
   511 lemma scaleR_nonneg_nonpos: "0 \<le> a \<Longrightarrow> (x::'a::ordered_real_vector) \<le> 0 \<Longrightarrow> a *\<^sub>R x \<le> 0"
   512   using scaleR_left_mono [of x 0 a] by simp
   513 
   514 lemma scaleR_nonpos_nonneg: "a \<le> 0 \<Longrightarrow> 0 \<le> (x::'a::ordered_real_vector) \<Longrightarrow> a *\<^sub>R x \<le> 0"
   515   using scaleR_right_mono [of a 0 x] by simp
   516 
   517 lemma split_scaleR_neg_le: "(0 \<le> a & x \<le> 0) | (a \<le> 0 & 0 \<le> x) \<Longrightarrow>
   518   a *\<^sub>R (x::'a::ordered_real_vector) \<le> 0"
   519   by (auto simp add: scaleR_nonneg_nonpos scaleR_nonpos_nonneg)
   520 
   521 lemma le_add_iff1:
   522   fixes c d e::"'a::ordered_real_vector"
   523   shows "a *\<^sub>R e + c \<le> b *\<^sub>R e + d \<longleftrightarrow> (a - b) *\<^sub>R e + c \<le> d"
   524   by (simp add: algebra_simps)
   525 
   526 lemma le_add_iff2:
   527   fixes c d e::"'a::ordered_real_vector"
   528   shows "a *\<^sub>R e + c \<le> b *\<^sub>R e + d \<longleftrightarrow> c \<le> (b - a) *\<^sub>R e + d"
   529   by (simp add: algebra_simps)
   530 
   531 lemma scaleR_left_mono_neg:
   532   fixes a b::"'a::ordered_real_vector"
   533   shows "b \<le> a \<Longrightarrow> c \<le> 0 \<Longrightarrow> c *\<^sub>R a \<le> c *\<^sub>R b"
   534   apply (drule scaleR_left_mono [of _ _ "- c"])
   535   apply simp_all
   536   done
   537 
   538 lemma scaleR_right_mono_neg:
   539   fixes c::"'a::ordered_real_vector"
   540   shows "b \<le> a \<Longrightarrow> c \<le> 0 \<Longrightarrow> a *\<^sub>R c \<le> b *\<^sub>R c"
   541   apply (drule scaleR_right_mono [of _ _ "- c"])
   542   apply simp_all
   543   done
   544 
   545 lemma scaleR_nonpos_nonpos: "a \<le> 0 \<Longrightarrow> (b::'a::ordered_real_vector) \<le> 0 \<Longrightarrow> 0 \<le> a *\<^sub>R b"
   546 using scaleR_right_mono_neg [of a 0 b] by simp
   547 
   548 lemma split_scaleR_pos_le:
   549   fixes b::"'a::ordered_real_vector"
   550   shows "(0 \<le> a \<and> 0 \<le> b) \<or> (a \<le> 0 \<and> b \<le> 0) \<Longrightarrow> 0 \<le> a *\<^sub>R b"
   551   by (auto simp add: scaleR_nonneg_nonneg scaleR_nonpos_nonpos)
   552 
   553 lemma zero_le_scaleR_iff:
   554   fixes b::"'a::ordered_real_vector"
   555   shows "0 \<le> a *\<^sub>R b \<longleftrightarrow> 0 < a \<and> 0 \<le> b \<or> a < 0 \<and> b \<le> 0 \<or> a = 0" (is "?lhs = ?rhs")
   556 proof cases
   557   assume "a \<noteq> 0"
   558   show ?thesis
   559   proof
   560     assume lhs: ?lhs
   561     {
   562       assume "0 < a"
   563       with lhs have "inverse a *\<^sub>R 0 \<le> inverse a *\<^sub>R (a *\<^sub>R b)"
   564         by (intro scaleR_mono) auto
   565       hence ?rhs using `0 < a`
   566         by simp
   567     } moreover {
   568       assume "0 > a"
   569       with lhs have "- inverse a *\<^sub>R 0 \<le> - inverse a *\<^sub>R (a *\<^sub>R b)"
   570         by (intro scaleR_mono) auto
   571       hence ?rhs using `0 > a`
   572         by simp
   573     } ultimately show ?rhs using `a \<noteq> 0` by arith
   574   qed (auto simp: not_le `a \<noteq> 0` intro!: split_scaleR_pos_le)
   575 qed simp
   576 
   577 lemma scaleR_le_0_iff:
   578   fixes b::"'a::ordered_real_vector"
   579   shows "a *\<^sub>R b \<le> 0 \<longleftrightarrow> 0 < a \<and> b \<le> 0 \<or> a < 0 \<and> 0 \<le> b \<or> a = 0"
   580   by (insert zero_le_scaleR_iff [of "-a" b]) force
   581 
   582 lemma scaleR_le_cancel_left:
   583   fixes b::"'a::ordered_real_vector"
   584   shows "c *\<^sub>R a \<le> c *\<^sub>R b \<longleftrightarrow> (0 < c \<longrightarrow> a \<le> b) \<and> (c < 0 \<longrightarrow> b \<le> a)"
   585   by (auto simp add: neq_iff scaleR_left_mono scaleR_left_mono_neg
   586     dest: scaleR_left_mono[where a="inverse c"] scaleR_left_mono_neg[where c="inverse c"])
   587 
   588 lemma scaleR_le_cancel_left_pos:
   589   fixes b::"'a::ordered_real_vector"
   590   shows "0 < c \<Longrightarrow> c *\<^sub>R a \<le> c *\<^sub>R b \<longleftrightarrow> a \<le> b"
   591   by (auto simp: scaleR_le_cancel_left)
   592 
   593 lemma scaleR_le_cancel_left_neg:
   594   fixes b::"'a::ordered_real_vector"
   595   shows "c < 0 \<Longrightarrow> c *\<^sub>R a \<le> c *\<^sub>R b \<longleftrightarrow> b \<le> a"
   596   by (auto simp: scaleR_le_cancel_left)
   597 
   598 lemma scaleR_left_le_one_le:
   599   fixes x::"'a::ordered_real_vector" and a::real
   600   shows "0 \<le> x \<Longrightarrow> a \<le> 1 \<Longrightarrow> a *\<^sub>R x \<le> x"
   601   using scaleR_right_mono[of a 1 x] by simp
   602 
   603 
   604 subsection {* Real normed vector spaces *}
   605 
   606 class dist =
   607   fixes dist :: "'a \<Rightarrow> 'a \<Rightarrow> real"
   608 
   609 class norm =
   610   fixes norm :: "'a \<Rightarrow> real"
   611 
   612 class sgn_div_norm = scaleR + norm + sgn +
   613   assumes sgn_div_norm: "sgn x = x /\<^sub>R norm x"
   614 
   615 class dist_norm = dist + norm + minus +
   616   assumes dist_norm: "dist x y = norm (x - y)"
   617 
   618 class open_dist = "open" + dist +
   619   assumes open_dist: "open S \<longleftrightarrow> (\<forall>x\<in>S. \<exists>e>0. \<forall>y. dist y x < e \<longrightarrow> y \<in> S)"
   620 
   621 class real_normed_vector = real_vector + sgn_div_norm + dist_norm + open_dist +
   622   assumes norm_eq_zero [simp]: "norm x = 0 \<longleftrightarrow> x = 0"
   623   and norm_triangle_ineq: "norm (x + y) \<le> norm x + norm y"
   624   and norm_scaleR [simp]: "norm (scaleR a x) = \<bar>a\<bar> * norm x"
   625 begin
   626 
   627 lemma norm_ge_zero [simp]: "0 \<le> norm x"
   628 proof -
   629   have "0 = norm (x + -1 *\<^sub>R x)" 
   630     using scaleR_add_left[of 1 "-1" x] norm_scaleR[of 0 x] by (simp add: scaleR_one)
   631   also have "\<dots> \<le> norm x + norm (-1 *\<^sub>R x)" by (rule norm_triangle_ineq)
   632   finally show ?thesis by simp
   633 qed
   634 
   635 end
   636 
   637 class real_normed_algebra = real_algebra + real_normed_vector +
   638   assumes norm_mult_ineq: "norm (x * y) \<le> norm x * norm y"
   639 
   640 class real_normed_algebra_1 = real_algebra_1 + real_normed_algebra +
   641   assumes norm_one [simp]: "norm 1 = 1"
   642 
   643 class real_normed_div_algebra = real_div_algebra + real_normed_vector +
   644   assumes norm_mult: "norm (x * y) = norm x * norm y"
   645 
   646 class real_normed_field = real_field + real_normed_div_algebra
   647 
   648 instance real_normed_div_algebra < real_normed_algebra_1
   649 proof
   650   fix x y :: 'a
   651   show "norm (x * y) \<le> norm x * norm y"
   652     by (simp add: norm_mult)
   653 next
   654   have "norm (1 * 1::'a) = norm (1::'a) * norm (1::'a)"
   655     by (rule norm_mult)
   656   thus "norm (1::'a) = 1" by simp
   657 qed
   658 
   659 lemma norm_zero [simp]: "norm (0::'a::real_normed_vector) = 0"
   660 by simp
   661 
   662 lemma zero_less_norm_iff [simp]:
   663   fixes x :: "'a::real_normed_vector"
   664   shows "(0 < norm x) = (x \<noteq> 0)"
   665 by (simp add: order_less_le)
   666 
   667 lemma norm_not_less_zero [simp]:
   668   fixes x :: "'a::real_normed_vector"
   669   shows "\<not> norm x < 0"
   670 by (simp add: linorder_not_less)
   671 
   672 lemma norm_le_zero_iff [simp]:
   673   fixes x :: "'a::real_normed_vector"
   674   shows "(norm x \<le> 0) = (x = 0)"
   675 by (simp add: order_le_less)
   676 
   677 lemma norm_minus_cancel [simp]:
   678   fixes x :: "'a::real_normed_vector"
   679   shows "norm (- x) = norm x"
   680 proof -
   681   have "norm (- x) = norm (scaleR (- 1) x)"
   682     by (simp only: scaleR_minus_left scaleR_one)
   683   also have "\<dots> = \<bar>- 1\<bar> * norm x"
   684     by (rule norm_scaleR)
   685   finally show ?thesis by simp
   686 qed
   687 
   688 lemma norm_minus_commute:
   689   fixes a b :: "'a::real_normed_vector"
   690   shows "norm (a - b) = norm (b - a)"
   691 proof -
   692   have "norm (- (b - a)) = norm (b - a)"
   693     by (rule norm_minus_cancel)
   694   thus ?thesis by simp
   695 qed
   696 
   697 lemma norm_triangle_ineq2:
   698   fixes a b :: "'a::real_normed_vector"
   699   shows "norm a - norm b \<le> norm (a - b)"
   700 proof -
   701   have "norm (a - b + b) \<le> norm (a - b) + norm b"
   702     by (rule norm_triangle_ineq)
   703   thus ?thesis by simp
   704 qed
   705 
   706 lemma norm_triangle_ineq3:
   707   fixes a b :: "'a::real_normed_vector"
   708   shows "\<bar>norm a - norm b\<bar> \<le> norm (a - b)"
   709 apply (subst abs_le_iff)
   710 apply auto
   711 apply (rule norm_triangle_ineq2)
   712 apply (subst norm_minus_commute)
   713 apply (rule norm_triangle_ineq2)
   714 done
   715 
   716 lemma norm_triangle_ineq4:
   717   fixes a b :: "'a::real_normed_vector"
   718   shows "norm (a - b) \<le> norm a + norm b"
   719 proof -
   720   have "norm (a + - b) \<le> norm a + norm (- b)"
   721     by (rule norm_triangle_ineq)
   722   then show ?thesis by simp
   723 qed
   724 
   725 lemma norm_diff_ineq:
   726   fixes a b :: "'a::real_normed_vector"
   727   shows "norm a - norm b \<le> norm (a + b)"
   728 proof -
   729   have "norm a - norm (- b) \<le> norm (a - - b)"
   730     by (rule norm_triangle_ineq2)
   731   thus ?thesis by simp
   732 qed
   733 
   734 lemma norm_diff_triangle_ineq:
   735   fixes a b c d :: "'a::real_normed_vector"
   736   shows "norm ((a + b) - (c + d)) \<le> norm (a - c) + norm (b - d)"
   737 proof -
   738   have "norm ((a + b) - (c + d)) = norm ((a - c) + (b - d))"
   739     by (simp add: algebra_simps)
   740   also have "\<dots> \<le> norm (a - c) + norm (b - d)"
   741     by (rule norm_triangle_ineq)
   742   finally show ?thesis .
   743 qed
   744 
   745 lemma norm_triangle_mono: 
   746   fixes a b :: "'a::real_normed_vector"
   747   shows "\<lbrakk>norm a \<le> r; norm b \<le> s\<rbrakk> \<Longrightarrow> norm (a + b) \<le> r + s"
   748 by (metis add_mono_thms_linordered_semiring(1) norm_triangle_ineq order.trans)
   749 
   750 lemma norm_setsum:
   751   fixes f :: "'a \<Rightarrow> 'b::real_normed_vector"
   752   shows "norm (setsum f A) \<le> (\<Sum>i\<in>A. norm (f i))"
   753   by (induct A rule: infinite_finite_induct) (auto intro: norm_triangle_mono)
   754 
   755 lemma setsum_norm_le:
   756   fixes f :: "'a \<Rightarrow> 'b::real_normed_vector"
   757   assumes fg: "\<forall>x \<in> S. norm (f x) \<le> g x"
   758   shows "norm (setsum f S) \<le> setsum g S"
   759   by (rule order_trans [OF norm_setsum setsum_mono]) (simp add: fg)
   760 
   761 lemma abs_norm_cancel [simp]:
   762   fixes a :: "'a::real_normed_vector"
   763   shows "\<bar>norm a\<bar> = norm a"
   764 by (rule abs_of_nonneg [OF norm_ge_zero])
   765 
   766 lemma norm_add_less:
   767   fixes x y :: "'a::real_normed_vector"
   768   shows "\<lbrakk>norm x < r; norm y < s\<rbrakk> \<Longrightarrow> norm (x + y) < r + s"
   769 by (rule order_le_less_trans [OF norm_triangle_ineq add_strict_mono])
   770 
   771 lemma norm_mult_less:
   772   fixes x y :: "'a::real_normed_algebra"
   773   shows "\<lbrakk>norm x < r; norm y < s\<rbrakk> \<Longrightarrow> norm (x * y) < r * s"
   774 apply (rule order_le_less_trans [OF norm_mult_ineq])
   775 apply (simp add: mult_strict_mono')
   776 done
   777 
   778 lemma norm_of_real [simp]:
   779   "norm (of_real r :: 'a::real_normed_algebra_1) = \<bar>r\<bar>"
   780 unfolding of_real_def by simp
   781 
   782 lemma norm_numeral [simp]:
   783   "norm (numeral w::'a::real_normed_algebra_1) = numeral w"
   784 by (subst of_real_numeral [symmetric], subst norm_of_real, simp)
   785 
   786 lemma norm_neg_numeral [simp]:
   787   "norm (- numeral w::'a::real_normed_algebra_1) = numeral w"
   788 by (subst of_real_neg_numeral [symmetric], subst norm_of_real, simp)
   789 
   790 lemma norm_of_int [simp]:
   791   "norm (of_int z::'a::real_normed_algebra_1) = \<bar>of_int z\<bar>"
   792 by (subst of_real_of_int_eq [symmetric], rule norm_of_real)
   793 
   794 lemma norm_of_nat [simp]:
   795   "norm (of_nat n::'a::real_normed_algebra_1) = of_nat n"
   796 apply (subst of_real_of_nat_eq [symmetric])
   797 apply (subst norm_of_real, simp)
   798 done
   799 
   800 lemma nonzero_norm_inverse:
   801   fixes a :: "'a::real_normed_div_algebra"
   802   shows "a \<noteq> 0 \<Longrightarrow> norm (inverse a) = inverse (norm a)"
   803 apply (rule inverse_unique [symmetric])
   804 apply (simp add: norm_mult [symmetric])
   805 done
   806 
   807 lemma norm_inverse:
   808   fixes a :: "'a::{real_normed_div_algebra, division_ring_inverse_zero}"
   809   shows "norm (inverse a) = inverse (norm a)"
   810 apply (case_tac "a = 0", simp)
   811 apply (erule nonzero_norm_inverse)
   812 done
   813 
   814 lemma nonzero_norm_divide:
   815   fixes a b :: "'a::real_normed_field"
   816   shows "b \<noteq> 0 \<Longrightarrow> norm (a / b) = norm a / norm b"
   817 by (simp add: divide_inverse norm_mult nonzero_norm_inverse)
   818 
   819 lemma norm_divide:
   820   fixes a b :: "'a::{real_normed_field, field_inverse_zero}"
   821   shows "norm (a / b) = norm a / norm b"
   822 by (simp add: divide_inverse norm_mult norm_inverse)
   823 
   824 lemma norm_power_ineq:
   825   fixes x :: "'a::{real_normed_algebra_1}"
   826   shows "norm (x ^ n) \<le> norm x ^ n"
   827 proof (induct n)
   828   case 0 show "norm (x ^ 0) \<le> norm x ^ 0" by simp
   829 next
   830   case (Suc n)
   831   have "norm (x * x ^ n) \<le> norm x * norm (x ^ n)"
   832     by (rule norm_mult_ineq)
   833   also from Suc have "\<dots> \<le> norm x * norm x ^ n"
   834     using norm_ge_zero by (rule mult_left_mono)
   835   finally show "norm (x ^ Suc n) \<le> norm x ^ Suc n"
   836     by simp
   837 qed
   838 
   839 lemma norm_power:
   840   fixes x :: "'a::{real_normed_div_algebra}"
   841   shows "norm (x ^ n) = norm x ^ n"
   842 by (induct n) (simp_all add: norm_mult)
   843 
   844 lemma setprod_norm:
   845   fixes f :: "'a \<Rightarrow> 'b::{comm_semiring_1,real_normed_div_algebra}"
   846   shows "setprod (\<lambda>x. norm(f x)) A = norm (setprod f A)"
   847 proof (cases "finite A")
   848   case True then show ?thesis 
   849     by (induct A rule: finite_induct) (auto simp: norm_mult)
   850 next
   851   case False then show ?thesis
   852     by (metis norm_one setprod.infinite) 
   853 qed
   854 
   855 
   856 subsection {* Metric spaces *}
   857 
   858 class metric_space = open_dist +
   859   assumes dist_eq_0_iff [simp]: "dist x y = 0 \<longleftrightarrow> x = y"
   860   assumes dist_triangle2: "dist x y \<le> dist x z + dist y z"
   861 begin
   862 
   863 lemma dist_self [simp]: "dist x x = 0"
   864 by simp
   865 
   866 lemma zero_le_dist [simp]: "0 \<le> dist x y"
   867 using dist_triangle2 [of x x y] by simp
   868 
   869 lemma zero_less_dist_iff: "0 < dist x y \<longleftrightarrow> x \<noteq> y"
   870 by (simp add: less_le)
   871 
   872 lemma dist_not_less_zero [simp]: "\<not> dist x y < 0"
   873 by (simp add: not_less)
   874 
   875 lemma dist_le_zero_iff [simp]: "dist x y \<le> 0 \<longleftrightarrow> x = y"
   876 by (simp add: le_less)
   877 
   878 lemma dist_commute: "dist x y = dist y x"
   879 proof (rule order_antisym)
   880   show "dist x y \<le> dist y x"
   881     using dist_triangle2 [of x y x] by simp
   882   show "dist y x \<le> dist x y"
   883     using dist_triangle2 [of y x y] by simp
   884 qed
   885 
   886 lemma dist_triangle: "dist x z \<le> dist x y + dist y z"
   887 using dist_triangle2 [of x z y] by (simp add: dist_commute)
   888 
   889 lemma dist_triangle3: "dist x y \<le> dist a x + dist a y"
   890 using dist_triangle2 [of x y a] by (simp add: dist_commute)
   891 
   892 lemma dist_triangle_alt:
   893   shows "dist y z <= dist x y + dist x z"
   894 by (rule dist_triangle3)
   895 
   896 lemma dist_pos_lt:
   897   shows "x \<noteq> y ==> 0 < dist x y"
   898 by (simp add: zero_less_dist_iff)
   899 
   900 lemma dist_nz:
   901   shows "x \<noteq> y \<longleftrightarrow> 0 < dist x y"
   902 by (simp add: zero_less_dist_iff)
   903 
   904 lemma dist_triangle_le:
   905   shows "dist x z + dist y z <= e \<Longrightarrow> dist x y <= e"
   906 by (rule order_trans [OF dist_triangle2])
   907 
   908 lemma dist_triangle_lt:
   909   shows "dist x z + dist y z < e ==> dist x y < e"
   910 by (rule le_less_trans [OF dist_triangle2])
   911 
   912 lemma dist_triangle_half_l:
   913   shows "dist x1 y < e / 2 \<Longrightarrow> dist x2 y < e / 2 \<Longrightarrow> dist x1 x2 < e"
   914 by (rule dist_triangle_lt [where z=y], simp)
   915 
   916 lemma dist_triangle_half_r:
   917   shows "dist y x1 < e / 2 \<Longrightarrow> dist y x2 < e / 2 \<Longrightarrow> dist x1 x2 < e"
   918 by (rule dist_triangle_half_l, simp_all add: dist_commute)
   919 
   920 subclass topological_space
   921 proof
   922   have "\<exists>e::real. 0 < e"
   923     by (fast intro: zero_less_one)
   924   then show "open UNIV"
   925     unfolding open_dist by simp
   926 next
   927   fix S T assume "open S" "open T"
   928   then show "open (S \<inter> T)"
   929     unfolding open_dist
   930     apply clarify
   931     apply (drule (1) bspec)+
   932     apply (clarify, rename_tac r s)
   933     apply (rule_tac x="min r s" in exI, simp)
   934     done
   935 next
   936   fix K assume "\<forall>S\<in>K. open S" thus "open (\<Union>K)"
   937     unfolding open_dist by fast
   938 qed
   939 
   940 lemma open_ball: "open {y. dist x y < d}"
   941 proof (unfold open_dist, intro ballI)
   942   fix y assume *: "y \<in> {y. dist x y < d}"
   943   then show "\<exists>e>0. \<forall>z. dist z y < e \<longrightarrow> z \<in> {y. dist x y < d}"
   944     by (auto intro!: exI[of _ "d - dist x y"] simp: field_simps dist_triangle_lt)
   945 qed
   946 
   947 subclass first_countable_topology
   948 proof
   949   fix x 
   950   show "\<exists>A::nat \<Rightarrow> 'a set. (\<forall>i. x \<in> A i \<and> open (A i)) \<and> (\<forall>S. open S \<and> x \<in> S \<longrightarrow> (\<exists>i. A i \<subseteq> S))"
   951   proof (safe intro!: exI[of _ "\<lambda>n. {y. dist x y < inverse (Suc n)}"])
   952     fix S assume "open S" "x \<in> S"
   953     then obtain e where e: "0 < e" and "{y. dist x y < e} \<subseteq> S"
   954       by (auto simp: open_dist subset_eq dist_commute)
   955     moreover
   956     from e obtain i where "inverse (Suc i) < e"
   957       by (auto dest!: reals_Archimedean)
   958     then have "{y. dist x y < inverse (Suc i)} \<subseteq> {y. dist x y < e}"
   959       by auto
   960     ultimately show "\<exists>i. {y. dist x y < inverse (Suc i)} \<subseteq> S"
   961       by blast
   962   qed (auto intro: open_ball)
   963 qed
   964 
   965 end
   966 
   967 instance metric_space \<subseteq> t2_space
   968 proof
   969   fix x y :: "'a::metric_space"
   970   assume xy: "x \<noteq> y"
   971   let ?U = "{y'. dist x y' < dist x y / 2}"
   972   let ?V = "{x'. dist y x' < dist x y / 2}"
   973   have th0: "\<And>d x y z. (d x z :: real) \<le> d x y + d y z \<Longrightarrow> d y z = d z y
   974                \<Longrightarrow> \<not>(d x y * 2 < d x z \<and> d z y * 2 < d x z)" by arith
   975   have "open ?U \<and> open ?V \<and> x \<in> ?U \<and> y \<in> ?V \<and> ?U \<inter> ?V = {}"
   976     using dist_pos_lt[OF xy] th0[of dist, OF dist_triangle dist_commute]
   977     using open_ball[of _ "dist x y / 2"] by auto
   978   then show "\<exists>U V. open U \<and> open V \<and> x \<in> U \<and> y \<in> V \<and> U \<inter> V = {}"
   979     by blast
   980 qed
   981 
   982 text {* Every normed vector space is a metric space. *}
   983 
   984 instance real_normed_vector < metric_space
   985 proof
   986   fix x y :: 'a show "dist x y = 0 \<longleftrightarrow> x = y"
   987     unfolding dist_norm by simp
   988 next
   989   fix x y z :: 'a show "dist x y \<le> dist x z + dist y z"
   990     unfolding dist_norm
   991     using norm_triangle_ineq4 [of "x - z" "y - z"] by simp
   992 qed
   993 
   994 subsection {* Class instances for real numbers *}
   995 
   996 instantiation real :: real_normed_field
   997 begin
   998 
   999 definition dist_real_def:
  1000   "dist x y = \<bar>x - y\<bar>"
  1001 
  1002 definition open_real_def [code del]:
  1003   "open (S :: real set) \<longleftrightarrow> (\<forall>x\<in>S. \<exists>e>0. \<forall>y. dist y x < e \<longrightarrow> y \<in> S)"
  1004 
  1005 definition real_norm_def [simp]:
  1006   "norm r = \<bar>r\<bar>"
  1007 
  1008 instance
  1009 apply (intro_classes, unfold real_norm_def real_scaleR_def)
  1010 apply (rule dist_real_def)
  1011 apply (rule open_real_def)
  1012 apply (simp add: sgn_real_def)
  1013 apply (rule abs_eq_0)
  1014 apply (rule abs_triangle_ineq)
  1015 apply (rule abs_mult)
  1016 apply (rule abs_mult)
  1017 done
  1018 
  1019 end
  1020 
  1021 declare [[code abort: "open :: real set \<Rightarrow> bool"]]
  1022 
  1023 instance real :: linorder_topology
  1024 proof
  1025   show "(open :: real set \<Rightarrow> bool) = generate_topology (range lessThan \<union> range greaterThan)"
  1026   proof (rule ext, safe)
  1027     fix S :: "real set" assume "open S"
  1028     then obtain f where "\<forall>x\<in>S. 0 < f x \<and> (\<forall>y. dist y x < f x \<longrightarrow> y \<in> S)"
  1029       unfolding open_real_def bchoice_iff ..
  1030     then have *: "S = (\<Union>x\<in>S. {x - f x <..} \<inter> {..< x + f x})"
  1031       by (fastforce simp: dist_real_def)
  1032     show "generate_topology (range lessThan \<union> range greaterThan) S"
  1033       apply (subst *)
  1034       apply (intro generate_topology_Union generate_topology.Int)
  1035       apply (auto intro: generate_topology.Basis)
  1036       done
  1037   next
  1038     fix S :: "real set" assume "generate_topology (range lessThan \<union> range greaterThan) S"
  1039     moreover have "\<And>a::real. open {..<a}"
  1040       unfolding open_real_def dist_real_def
  1041     proof clarify
  1042       fix x a :: real assume "x < a"
  1043       hence "0 < a - x \<and> (\<forall>y. \<bar>y - x\<bar> < a - x \<longrightarrow> y \<in> {..<a})" by auto
  1044       thus "\<exists>e>0. \<forall>y. \<bar>y - x\<bar> < e \<longrightarrow> y \<in> {..<a}" ..
  1045     qed
  1046     moreover have "\<And>a::real. open {a <..}"
  1047       unfolding open_real_def dist_real_def
  1048     proof clarify
  1049       fix x a :: real assume "a < x"
  1050       hence "0 < x - a \<and> (\<forall>y. \<bar>y - x\<bar> < x - a \<longrightarrow> y \<in> {a<..})" by auto
  1051       thus "\<exists>e>0. \<forall>y. \<bar>y - x\<bar> < e \<longrightarrow> y \<in> {a<..}" ..
  1052     qed
  1053     ultimately show "open S"
  1054       by induct auto
  1055   qed
  1056 qed
  1057 
  1058 instance real :: linear_continuum_topology ..
  1059 
  1060 lemmas open_real_greaterThan = open_greaterThan[where 'a=real]
  1061 lemmas open_real_lessThan = open_lessThan[where 'a=real]
  1062 lemmas open_real_greaterThanLessThan = open_greaterThanLessThan[where 'a=real]
  1063 lemmas closed_real_atMost = closed_atMost[where 'a=real]
  1064 lemmas closed_real_atLeast = closed_atLeast[where 'a=real]
  1065 lemmas closed_real_atLeastAtMost = closed_atLeastAtMost[where 'a=real]
  1066 
  1067 subsection {* Extra type constraints *}
  1068 
  1069 text {* Only allow @{term "open"} in class @{text topological_space}. *}
  1070 
  1071 setup {* Sign.add_const_constraint
  1072   (@{const_name "open"}, SOME @{typ "'a::topological_space set \<Rightarrow> bool"}) *}
  1073 
  1074 text {* Only allow @{term dist} in class @{text metric_space}. *}
  1075 
  1076 setup {* Sign.add_const_constraint
  1077   (@{const_name dist}, SOME @{typ "'a::metric_space \<Rightarrow> 'a \<Rightarrow> real"}) *}
  1078 
  1079 text {* Only allow @{term norm} in class @{text real_normed_vector}. *}
  1080 
  1081 setup {* Sign.add_const_constraint
  1082   (@{const_name norm}, SOME @{typ "'a::real_normed_vector \<Rightarrow> real"}) *}
  1083 
  1084 subsection {* Sign function *}
  1085 
  1086 lemma norm_sgn:
  1087   "norm (sgn(x::'a::real_normed_vector)) = (if x = 0 then 0 else 1)"
  1088 by (simp add: sgn_div_norm)
  1089 
  1090 lemma sgn_zero [simp]: "sgn(0::'a::real_normed_vector) = 0"
  1091 by (simp add: sgn_div_norm)
  1092 
  1093 lemma sgn_zero_iff: "(sgn(x::'a::real_normed_vector) = 0) = (x = 0)"
  1094 by (simp add: sgn_div_norm)
  1095 
  1096 lemma sgn_minus: "sgn (- x) = - sgn(x::'a::real_normed_vector)"
  1097 by (simp add: sgn_div_norm)
  1098 
  1099 lemma sgn_scaleR:
  1100   "sgn (scaleR r x) = scaleR (sgn r) (sgn(x::'a::real_normed_vector))"
  1101 by (simp add: sgn_div_norm mult_ac)
  1102 
  1103 lemma sgn_one [simp]: "sgn (1::'a::real_normed_algebra_1) = 1"
  1104 by (simp add: sgn_div_norm)
  1105 
  1106 lemma sgn_of_real:
  1107   "sgn (of_real r::'a::real_normed_algebra_1) = of_real (sgn r)"
  1108 unfolding of_real_def by (simp only: sgn_scaleR sgn_one)
  1109 
  1110 lemma sgn_mult:
  1111   fixes x y :: "'a::real_normed_div_algebra"
  1112   shows "sgn (x * y) = sgn x * sgn y"
  1113 by (simp add: sgn_div_norm norm_mult mult_commute)
  1114 
  1115 lemma real_sgn_eq: "sgn (x::real) = x / \<bar>x\<bar>"
  1116 by (simp add: sgn_div_norm divide_inverse)
  1117 
  1118 lemma real_sgn_pos: "0 < (x::real) \<Longrightarrow> sgn x = 1"
  1119 unfolding real_sgn_eq by simp
  1120 
  1121 lemma real_sgn_neg: "(x::real) < 0 \<Longrightarrow> sgn x = -1"
  1122 unfolding real_sgn_eq by simp
  1123 
  1124 lemma norm_conv_dist: "norm x = dist x 0"
  1125   unfolding dist_norm by simp
  1126 
  1127 subsection {* Bounded Linear and Bilinear Operators *}
  1128 
  1129 locale linear = additive f for f :: "'a::real_vector \<Rightarrow> 'b::real_vector" +
  1130   assumes scaleR: "f (scaleR r x) = scaleR r (f x)"
  1131 
  1132 lemma linearI:
  1133   assumes "\<And>x y. f (x + y) = f x + f y"
  1134   assumes "\<And>c x. f (c *\<^sub>R x) = c *\<^sub>R f x"
  1135   shows "linear f"
  1136   by default (rule assms)+
  1137 
  1138 locale bounded_linear = linear f for f :: "'a::real_normed_vector \<Rightarrow> 'b::real_normed_vector" +
  1139   assumes bounded: "\<exists>K. \<forall>x. norm (f x) \<le> norm x * K"
  1140 begin
  1141 
  1142 lemma pos_bounded:
  1143   "\<exists>K>0. \<forall>x. norm (f x) \<le> norm x * K"
  1144 proof -
  1145   obtain K where K: "\<And>x. norm (f x) \<le> norm x * K"
  1146     using bounded by fast
  1147   show ?thesis
  1148   proof (intro exI impI conjI allI)
  1149     show "0 < max 1 K"
  1150       by (rule order_less_le_trans [OF zero_less_one max.cobounded1])
  1151   next
  1152     fix x
  1153     have "norm (f x) \<le> norm x * K" using K .
  1154     also have "\<dots> \<le> norm x * max 1 K"
  1155       by (rule mult_left_mono [OF max.cobounded2 norm_ge_zero])
  1156     finally show "norm (f x) \<le> norm x * max 1 K" .
  1157   qed
  1158 qed
  1159 
  1160 lemma nonneg_bounded:
  1161   "\<exists>K\<ge>0. \<forall>x. norm (f x) \<le> norm x * K"
  1162 proof -
  1163   from pos_bounded
  1164   show ?thesis by (auto intro: order_less_imp_le)
  1165 qed
  1166 
  1167 lemma linear: "linear f" ..
  1168 
  1169 end
  1170 
  1171 lemma bounded_linear_intro:
  1172   assumes "\<And>x y. f (x + y) = f x + f y"
  1173   assumes "\<And>r x. f (scaleR r x) = scaleR r (f x)"
  1174   assumes "\<And>x. norm (f x) \<le> norm x * K"
  1175   shows "bounded_linear f"
  1176   by default (fast intro: assms)+
  1177 
  1178 locale bounded_bilinear =
  1179   fixes prod :: "['a::real_normed_vector, 'b::real_normed_vector]
  1180                  \<Rightarrow> 'c::real_normed_vector"
  1181     (infixl "**" 70)
  1182   assumes add_left: "prod (a + a') b = prod a b + prod a' b"
  1183   assumes add_right: "prod a (b + b') = prod a b + prod a b'"
  1184   assumes scaleR_left: "prod (scaleR r a) b = scaleR r (prod a b)"
  1185   assumes scaleR_right: "prod a (scaleR r b) = scaleR r (prod a b)"
  1186   assumes bounded: "\<exists>K. \<forall>a b. norm (prod a b) \<le> norm a * norm b * K"
  1187 begin
  1188 
  1189 lemma pos_bounded:
  1190   "\<exists>K>0. \<forall>a b. norm (a ** b) \<le> norm a * norm b * K"
  1191 apply (cut_tac bounded, erule exE)
  1192 apply (rule_tac x="max 1 K" in exI, safe)
  1193 apply (rule order_less_le_trans [OF zero_less_one max.cobounded1])
  1194 apply (drule spec, drule spec, erule order_trans)
  1195 apply (rule mult_left_mono [OF max.cobounded2])
  1196 apply (intro mult_nonneg_nonneg norm_ge_zero)
  1197 done
  1198 
  1199 lemma nonneg_bounded:
  1200   "\<exists>K\<ge>0. \<forall>a b. norm (a ** b) \<le> norm a * norm b * K"
  1201 proof -
  1202   from pos_bounded
  1203   show ?thesis by (auto intro: order_less_imp_le)
  1204 qed
  1205 
  1206 lemma additive_right: "additive (\<lambda>b. prod a b)"
  1207 by (rule additive.intro, rule add_right)
  1208 
  1209 lemma additive_left: "additive (\<lambda>a. prod a b)"
  1210 by (rule additive.intro, rule add_left)
  1211 
  1212 lemma zero_left: "prod 0 b = 0"
  1213 by (rule additive.zero [OF additive_left])
  1214 
  1215 lemma zero_right: "prod a 0 = 0"
  1216 by (rule additive.zero [OF additive_right])
  1217 
  1218 lemma minus_left: "prod (- a) b = - prod a b"
  1219 by (rule additive.minus [OF additive_left])
  1220 
  1221 lemma minus_right: "prod a (- b) = - prod a b"
  1222 by (rule additive.minus [OF additive_right])
  1223 
  1224 lemma diff_left:
  1225   "prod (a - a') b = prod a b - prod a' b"
  1226 by (rule additive.diff [OF additive_left])
  1227 
  1228 lemma diff_right:
  1229   "prod a (b - b') = prod a b - prod a b'"
  1230 by (rule additive.diff [OF additive_right])
  1231 
  1232 lemma bounded_linear_left:
  1233   "bounded_linear (\<lambda>a. a ** b)"
  1234 apply (cut_tac bounded, safe)
  1235 apply (rule_tac K="norm b * K" in bounded_linear_intro)
  1236 apply (rule add_left)
  1237 apply (rule scaleR_left)
  1238 apply (simp add: mult_ac)
  1239 done
  1240 
  1241 lemma bounded_linear_right:
  1242   "bounded_linear (\<lambda>b. a ** b)"
  1243 apply (cut_tac bounded, safe)
  1244 apply (rule_tac K="norm a * K" in bounded_linear_intro)
  1245 apply (rule add_right)
  1246 apply (rule scaleR_right)
  1247 apply (simp add: mult_ac)
  1248 done
  1249 
  1250 lemma prod_diff_prod:
  1251   "(x ** y - a ** b) = (x - a) ** (y - b) + (x - a) ** b + a ** (y - b)"
  1252 by (simp add: diff_left diff_right)
  1253 
  1254 end
  1255 
  1256 lemma bounded_linear_ident[simp]: "bounded_linear (\<lambda>x. x)"
  1257   by default (auto intro!: exI[of _ 1])
  1258 
  1259 lemma bounded_linear_zero[simp]: "bounded_linear (\<lambda>x. 0)"
  1260   by default (auto intro!: exI[of _ 1])
  1261 
  1262 lemma bounded_linear_add:
  1263   assumes "bounded_linear f"
  1264   assumes "bounded_linear g"
  1265   shows "bounded_linear (\<lambda>x. f x + g x)"
  1266 proof -
  1267   interpret f: bounded_linear f by fact
  1268   interpret g: bounded_linear g by fact
  1269   show ?thesis
  1270   proof
  1271     from f.bounded obtain Kf where Kf: "\<And>x. norm (f x) \<le> norm x * Kf" by blast
  1272     from g.bounded obtain Kg where Kg: "\<And>x. norm (g x) \<le> norm x * Kg" by blast
  1273     show "\<exists>K. \<forall>x. norm (f x + g x) \<le> norm x * K"
  1274       using add_mono[OF Kf Kg]
  1275       by (intro exI[of _ "Kf + Kg"]) (auto simp: field_simps intro: norm_triangle_ineq order_trans)
  1276   qed (simp_all add: f.add g.add f.scaleR g.scaleR scaleR_right_distrib)
  1277 qed
  1278 
  1279 lemma bounded_linear_minus:
  1280   assumes "bounded_linear f"
  1281   shows "bounded_linear (\<lambda>x. - f x)"
  1282 proof -
  1283   interpret f: bounded_linear f by fact
  1284   show ?thesis apply (unfold_locales)
  1285     apply (simp add: f.add)
  1286     apply (simp add: f.scaleR)
  1287     apply (simp add: f.bounded)
  1288     done
  1289 qed
  1290 
  1291 lemma bounded_linear_compose:
  1292   assumes "bounded_linear f"
  1293   assumes "bounded_linear g"
  1294   shows "bounded_linear (\<lambda>x. f (g x))"
  1295 proof -
  1296   interpret f: bounded_linear f by fact
  1297   interpret g: bounded_linear g by fact
  1298   show ?thesis proof (unfold_locales)
  1299     fix x y show "f (g (x + y)) = f (g x) + f (g y)"
  1300       by (simp only: f.add g.add)
  1301   next
  1302     fix r x show "f (g (scaleR r x)) = scaleR r (f (g x))"
  1303       by (simp only: f.scaleR g.scaleR)
  1304   next
  1305     from f.pos_bounded
  1306     obtain Kf where f: "\<And>x. norm (f x) \<le> norm x * Kf" and Kf: "0 < Kf" by fast
  1307     from g.pos_bounded
  1308     obtain Kg where g: "\<And>x. norm (g x) \<le> norm x * Kg" by fast
  1309     show "\<exists>K. \<forall>x. norm (f (g x)) \<le> norm x * K"
  1310     proof (intro exI allI)
  1311       fix x
  1312       have "norm (f (g x)) \<le> norm (g x) * Kf"
  1313         using f .
  1314       also have "\<dots> \<le> (norm x * Kg) * Kf"
  1315         using g Kf [THEN order_less_imp_le] by (rule mult_right_mono)
  1316       also have "(norm x * Kg) * Kf = norm x * (Kg * Kf)"
  1317         by (rule mult_assoc)
  1318       finally show "norm (f (g x)) \<le> norm x * (Kg * Kf)" .
  1319     qed
  1320   qed
  1321 qed
  1322 
  1323 lemma bounded_bilinear_mult:
  1324   "bounded_bilinear (op * :: 'a \<Rightarrow> 'a \<Rightarrow> 'a::real_normed_algebra)"
  1325 apply (rule bounded_bilinear.intro)
  1326 apply (rule distrib_right)
  1327 apply (rule distrib_left)
  1328 apply (rule mult_scaleR_left)
  1329 apply (rule mult_scaleR_right)
  1330 apply (rule_tac x="1" in exI)
  1331 apply (simp add: norm_mult_ineq)
  1332 done
  1333 
  1334 lemma bounded_linear_mult_left:
  1335   "bounded_linear (\<lambda>x::'a::real_normed_algebra. x * y)"
  1336   using bounded_bilinear_mult
  1337   by (rule bounded_bilinear.bounded_linear_left)
  1338 
  1339 lemma bounded_linear_mult_right:
  1340   "bounded_linear (\<lambda>y::'a::real_normed_algebra. x * y)"
  1341   using bounded_bilinear_mult
  1342   by (rule bounded_bilinear.bounded_linear_right)
  1343 
  1344 lemmas bounded_linear_mult_const =
  1345   bounded_linear_mult_left [THEN bounded_linear_compose]
  1346 
  1347 lemmas bounded_linear_const_mult =
  1348   bounded_linear_mult_right [THEN bounded_linear_compose]
  1349 
  1350 lemma bounded_linear_divide:
  1351   "bounded_linear (\<lambda>x::'a::real_normed_field. x / y)"
  1352   unfolding divide_inverse by (rule bounded_linear_mult_left)
  1353 
  1354 lemma bounded_bilinear_scaleR: "bounded_bilinear scaleR"
  1355 apply (rule bounded_bilinear.intro)
  1356 apply (rule scaleR_left_distrib)
  1357 apply (rule scaleR_right_distrib)
  1358 apply simp
  1359 apply (rule scaleR_left_commute)
  1360 apply (rule_tac x="1" in exI, simp)
  1361 done
  1362 
  1363 lemma bounded_linear_scaleR_left: "bounded_linear (\<lambda>r. scaleR r x)"
  1364   using bounded_bilinear_scaleR
  1365   by (rule bounded_bilinear.bounded_linear_left)
  1366 
  1367 lemma bounded_linear_scaleR_right: "bounded_linear (\<lambda>x. scaleR r x)"
  1368   using bounded_bilinear_scaleR
  1369   by (rule bounded_bilinear.bounded_linear_right)
  1370 
  1371 lemma bounded_linear_of_real: "bounded_linear (\<lambda>r. of_real r)"
  1372   unfolding of_real_def by (rule bounded_linear_scaleR_left)
  1373 
  1374 lemma real_bounded_linear:
  1375   fixes f :: "real \<Rightarrow> real"
  1376   shows "bounded_linear f \<longleftrightarrow> (\<exists>c::real. f = (\<lambda>x. x * c))"
  1377 proof -
  1378   { fix x assume "bounded_linear f"
  1379     then interpret bounded_linear f .
  1380     from scaleR[of x 1] have "f x = x * f 1"
  1381       by simp }
  1382   then show ?thesis
  1383     by (auto intro: exI[of _ "f 1"] bounded_linear_mult_left)
  1384 qed
  1385 
  1386 instance real_normed_algebra_1 \<subseteq> perfect_space
  1387 proof
  1388   fix x::'a
  1389   show "\<not> open {x}"
  1390     unfolding open_dist dist_norm
  1391     by (clarsimp, rule_tac x="x + of_real (e/2)" in exI, simp)
  1392 qed
  1393 
  1394 subsection {* Filters and Limits on Metric Space *}
  1395 
  1396 lemma eventually_nhds_metric:
  1397   fixes a :: "'a :: metric_space"
  1398   shows "eventually P (nhds a) \<longleftrightarrow> (\<exists>d>0. \<forall>x. dist x a < d \<longrightarrow> P x)"
  1399 unfolding eventually_nhds open_dist
  1400 apply safe
  1401 apply fast
  1402 apply (rule_tac x="{x. dist x a < d}" in exI, simp)
  1403 apply clarsimp
  1404 apply (rule_tac x="d - dist x a" in exI, clarsimp)
  1405 apply (simp only: less_diff_eq)
  1406 apply (erule le_less_trans [OF dist_triangle])
  1407 done
  1408 
  1409 lemma eventually_at:
  1410   fixes a :: "'a :: metric_space"
  1411   shows "eventually P (at a within S) \<longleftrightarrow> (\<exists>d>0. \<forall>x\<in>S. x \<noteq> a \<and> dist x a < d \<longrightarrow> P x)"
  1412   unfolding eventually_at_filter eventually_nhds_metric by (auto simp: dist_nz)
  1413 
  1414 lemma eventually_at_le:
  1415   fixes a :: "'a::metric_space"
  1416   shows "eventually P (at a within S) \<longleftrightarrow> (\<exists>d>0. \<forall>x\<in>S. x \<noteq> a \<and> dist x a \<le> d \<longrightarrow> P x)"
  1417   unfolding eventually_at_filter eventually_nhds_metric
  1418   apply auto
  1419   apply (rule_tac x="d / 2" in exI)
  1420   apply auto
  1421   done
  1422 
  1423 lemma tendstoI:
  1424   fixes l :: "'a :: metric_space"
  1425   assumes "\<And>e. 0 < e \<Longrightarrow> eventually (\<lambda>x. dist (f x) l < e) F"
  1426   shows "(f ---> l) F"
  1427   apply (rule topological_tendstoI)
  1428   apply (simp add: open_dist)
  1429   apply (drule (1) bspec, clarify)
  1430   apply (drule assms)
  1431   apply (erule eventually_elim1, simp)
  1432   done
  1433 
  1434 lemma tendstoD:
  1435   fixes l :: "'a :: metric_space"
  1436   shows "(f ---> l) F \<Longrightarrow> 0 < e \<Longrightarrow> eventually (\<lambda>x. dist (f x) l < e) F"
  1437   apply (drule_tac S="{x. dist x l < e}" in topological_tendstoD)
  1438   apply (clarsimp simp add: open_dist)
  1439   apply (rule_tac x="e - dist x l" in exI, clarsimp)
  1440   apply (simp only: less_diff_eq)
  1441   apply (erule le_less_trans [OF dist_triangle])
  1442   apply simp
  1443   apply simp
  1444   done
  1445 
  1446 lemma tendsto_iff:
  1447   fixes l :: "'a :: metric_space"
  1448   shows "(f ---> l) F \<longleftrightarrow> (\<forall>e>0. eventually (\<lambda>x. dist (f x) l < e) F)"
  1449   using tendstoI tendstoD by fast
  1450 
  1451 lemma metric_tendsto_imp_tendsto:
  1452   fixes a :: "'a :: metric_space" and b :: "'b :: metric_space"
  1453   assumes f: "(f ---> a) F"
  1454   assumes le: "eventually (\<lambda>x. dist (g x) b \<le> dist (f x) a) F"
  1455   shows "(g ---> b) F"
  1456 proof (rule tendstoI)
  1457   fix e :: real assume "0 < e"
  1458   with f have "eventually (\<lambda>x. dist (f x) a < e) F" by (rule tendstoD)
  1459   with le show "eventually (\<lambda>x. dist (g x) b < e) F"
  1460     using le_less_trans by (rule eventually_elim2)
  1461 qed
  1462 
  1463 lemma filterlim_real_sequentially: "LIM x sequentially. real x :> at_top"
  1464   unfolding filterlim_at_top
  1465   apply (intro allI)
  1466   apply (rule_tac c="natceiling (Z + 1)" in eventually_sequentiallyI)
  1467   apply (auto simp: natceiling_le_eq)
  1468   done
  1469 
  1470 subsubsection {* Limits of Sequences *}
  1471 
  1472 lemma LIMSEQ_def: "X ----> (L::'a::metric_space) \<longleftrightarrow> (\<forall>r>0. \<exists>no. \<forall>n\<ge>no. dist (X n) L < r)"
  1473   unfolding tendsto_iff eventually_sequentially ..
  1474 
  1475 lemma LIMSEQ_iff_nz: "X ----> (L::'a::metric_space) = (\<forall>r>0. \<exists>no>0. \<forall>n\<ge>no. dist (X n) L < r)"
  1476   unfolding LIMSEQ_def by (metis Suc_leD zero_less_Suc)
  1477 
  1478 lemma metric_LIMSEQ_I:
  1479   "(\<And>r. 0 < r \<Longrightarrow> \<exists>no. \<forall>n\<ge>no. dist (X n) L < r) \<Longrightarrow> X ----> (L::'a::metric_space)"
  1480 by (simp add: LIMSEQ_def)
  1481 
  1482 lemma metric_LIMSEQ_D:
  1483   "\<lbrakk>X ----> (L::'a::metric_space); 0 < r\<rbrakk> \<Longrightarrow> \<exists>no. \<forall>n\<ge>no. dist (X n) L < r"
  1484 by (simp add: LIMSEQ_def)
  1485 
  1486 
  1487 subsubsection {* Limits of Functions *}
  1488 
  1489 lemma LIM_def: "f -- (a::'a::metric_space) --> (L::'b::metric_space) =
  1490      (\<forall>r > 0. \<exists>s > 0. \<forall>x. x \<noteq> a & dist x a < s
  1491         --> dist (f x) L < r)"
  1492   unfolding tendsto_iff eventually_at by simp
  1493 
  1494 lemma metric_LIM_I:
  1495   "(\<And>r. 0 < r \<Longrightarrow> \<exists>s>0. \<forall>x. x \<noteq> a \<and> dist x a < s \<longrightarrow> dist (f x) L < r)
  1496     \<Longrightarrow> f -- (a::'a::metric_space) --> (L::'b::metric_space)"
  1497 by (simp add: LIM_def)
  1498 
  1499 lemma metric_LIM_D:
  1500   "\<lbrakk>f -- (a::'a::metric_space) --> (L::'b::metric_space); 0 < r\<rbrakk>
  1501     \<Longrightarrow> \<exists>s>0. \<forall>x. x \<noteq> a \<and> dist x a < s \<longrightarrow> dist (f x) L < r"
  1502 by (simp add: LIM_def)
  1503 
  1504 lemma metric_LIM_imp_LIM:
  1505   assumes f: "f -- a --> (l::'a::metric_space)"
  1506   assumes le: "\<And>x. x \<noteq> a \<Longrightarrow> dist (g x) m \<le> dist (f x) l"
  1507   shows "g -- a --> (m::'b::metric_space)"
  1508   by (rule metric_tendsto_imp_tendsto [OF f]) (auto simp add: eventually_at_topological le)
  1509 
  1510 lemma metric_LIM_equal2:
  1511   assumes 1: "0 < R"
  1512   assumes 2: "\<And>x. \<lbrakk>x \<noteq> a; dist x a < R\<rbrakk> \<Longrightarrow> f x = g x"
  1513   shows "g -- a --> l \<Longrightarrow> f -- (a::'a::metric_space) --> l"
  1514 apply (rule topological_tendstoI)
  1515 apply (drule (2) topological_tendstoD)
  1516 apply (simp add: eventually_at, safe)
  1517 apply (rule_tac x="min d R" in exI, safe)
  1518 apply (simp add: 1)
  1519 apply (simp add: 2)
  1520 done
  1521 
  1522 lemma metric_LIM_compose2:
  1523   assumes f: "f -- (a::'a::metric_space) --> b"
  1524   assumes g: "g -- b --> c"
  1525   assumes inj: "\<exists>d>0. \<forall>x. x \<noteq> a \<and> dist x a < d \<longrightarrow> f x \<noteq> b"
  1526   shows "(\<lambda>x. g (f x)) -- a --> c"
  1527   using inj
  1528   by (intro tendsto_compose_eventually[OF g f]) (auto simp: eventually_at)
  1529 
  1530 lemma metric_isCont_LIM_compose2:
  1531   fixes f :: "'a :: metric_space \<Rightarrow> _"
  1532   assumes f [unfolded isCont_def]: "isCont f a"
  1533   assumes g: "g -- f a --> l"
  1534   assumes inj: "\<exists>d>0. \<forall>x. x \<noteq> a \<and> dist x a < d \<longrightarrow> f x \<noteq> f a"
  1535   shows "(\<lambda>x. g (f x)) -- a --> l"
  1536 by (rule metric_LIM_compose2 [OF f g inj])
  1537 
  1538 subsection {* Complete metric spaces *}
  1539 
  1540 subsection {* Cauchy sequences *}
  1541 
  1542 definition (in metric_space) Cauchy :: "(nat \<Rightarrow> 'a) \<Rightarrow> bool" where
  1543   "Cauchy X = (\<forall>e>0. \<exists>M. \<forall>m \<ge> M. \<forall>n \<ge> M. dist (X m) (X n) < e)"
  1544 
  1545 subsection {* Cauchy Sequences *}
  1546 
  1547 lemma metric_CauchyI:
  1548   "(\<And>e. 0 < e \<Longrightarrow> \<exists>M. \<forall>m\<ge>M. \<forall>n\<ge>M. dist (X m) (X n) < e) \<Longrightarrow> Cauchy X"
  1549   by (simp add: Cauchy_def)
  1550 
  1551 lemma metric_CauchyD:
  1552   "Cauchy X \<Longrightarrow> 0 < e \<Longrightarrow> \<exists>M. \<forall>m\<ge>M. \<forall>n\<ge>M. dist (X m) (X n) < e"
  1553   by (simp add: Cauchy_def)
  1554 
  1555 lemma metric_Cauchy_iff2:
  1556   "Cauchy X = (\<forall>j. (\<exists>M. \<forall>m \<ge> M. \<forall>n \<ge> M. dist (X m) (X n) < inverse(real (Suc j))))"
  1557 apply (simp add: Cauchy_def, auto)
  1558 apply (drule reals_Archimedean, safe)
  1559 apply (drule_tac x = n in spec, auto)
  1560 apply (rule_tac x = M in exI, auto)
  1561 apply (drule_tac x = m in spec, simp)
  1562 apply (drule_tac x = na in spec, auto)
  1563 done
  1564 
  1565 lemma Cauchy_iff2:
  1566   "Cauchy X = (\<forall>j. (\<exists>M. \<forall>m \<ge> M. \<forall>n \<ge> M. \<bar>X m - X n\<bar> < inverse(real (Suc j))))"
  1567   unfolding metric_Cauchy_iff2 dist_real_def ..
  1568 
  1569 lemma Cauchy_subseq_Cauchy:
  1570   "\<lbrakk> Cauchy X; subseq f \<rbrakk> \<Longrightarrow> Cauchy (X o f)"
  1571 apply (auto simp add: Cauchy_def)
  1572 apply (drule_tac x=e in spec, clarify)
  1573 apply (rule_tac x=M in exI, clarify)
  1574 apply (blast intro: le_trans [OF _ seq_suble] dest!: spec)
  1575 done
  1576 
  1577 theorem LIMSEQ_imp_Cauchy:
  1578   assumes X: "X ----> a" shows "Cauchy X"
  1579 proof (rule metric_CauchyI)
  1580   fix e::real assume "0 < e"
  1581   hence "0 < e/2" by simp
  1582   with X have "\<exists>N. \<forall>n\<ge>N. dist (X n) a < e/2" by (rule metric_LIMSEQ_D)
  1583   then obtain N where N: "\<forall>n\<ge>N. dist (X n) a < e/2" ..
  1584   show "\<exists>N. \<forall>m\<ge>N. \<forall>n\<ge>N. dist (X m) (X n) < e"
  1585   proof (intro exI allI impI)
  1586     fix m assume "N \<le> m"
  1587     hence m: "dist (X m) a < e/2" using N by fast
  1588     fix n assume "N \<le> n"
  1589     hence n: "dist (X n) a < e/2" using N by fast
  1590     have "dist (X m) (X n) \<le> dist (X m) a + dist (X n) a"
  1591       by (rule dist_triangle2)
  1592     also from m n have "\<dots> < e" by simp
  1593     finally show "dist (X m) (X n) < e" .
  1594   qed
  1595 qed
  1596 
  1597 lemma convergent_Cauchy: "convergent X \<Longrightarrow> Cauchy X"
  1598 unfolding convergent_def
  1599 by (erule exE, erule LIMSEQ_imp_Cauchy)
  1600 
  1601 subsubsection {* Cauchy Sequences are Convergent *}
  1602 
  1603 class complete_space = metric_space +
  1604   assumes Cauchy_convergent: "Cauchy X \<Longrightarrow> convergent X"
  1605 
  1606 lemma Cauchy_convergent_iff:
  1607   fixes X :: "nat \<Rightarrow> 'a::complete_space"
  1608   shows "Cauchy X = convergent X"
  1609 by (fast intro: Cauchy_convergent convergent_Cauchy)
  1610 
  1611 subsection {* The set of real numbers is a complete metric space *}
  1612 
  1613 text {*
  1614 Proof that Cauchy sequences converge based on the one from
  1615 @{url "http://pirate.shu.edu/~wachsmut/ira/numseq/proofs/cauconv.html"}
  1616 *}
  1617 
  1618 text {*
  1619   If sequence @{term "X"} is Cauchy, then its limit is the lub of
  1620   @{term "{r::real. \<exists>N. \<forall>n\<ge>N. r < X n}"}
  1621 *}
  1622 
  1623 lemma increasing_LIMSEQ:
  1624   fixes f :: "nat \<Rightarrow> real"
  1625   assumes inc: "\<And>n. f n \<le> f (Suc n)"
  1626       and bdd: "\<And>n. f n \<le> l"
  1627       and en: "\<And>e. 0 < e \<Longrightarrow> \<exists>n. l \<le> f n + e"
  1628   shows "f ----> l"
  1629 proof (rule increasing_tendsto)
  1630   fix x assume "x < l"
  1631   with dense[of 0 "l - x"] obtain e where "0 < e" "e < l - x"
  1632     by auto
  1633   from en[OF `0 < e`] obtain n where "l - e \<le> f n"
  1634     by (auto simp: field_simps)
  1635   with `e < l - x` `0 < e` have "x < f n" by simp
  1636   with incseq_SucI[of f, OF inc] show "eventually (\<lambda>n. x < f n) sequentially"
  1637     by (auto simp: eventually_sequentially incseq_def intro: less_le_trans)
  1638 qed (insert bdd, auto)
  1639 
  1640 lemma real_Cauchy_convergent:
  1641   fixes X :: "nat \<Rightarrow> real"
  1642   assumes X: "Cauchy X"
  1643   shows "convergent X"
  1644 proof -
  1645   def S \<equiv> "{x::real. \<exists>N. \<forall>n\<ge>N. x < X n}"
  1646   then have mem_S: "\<And>N x. \<forall>n\<ge>N. x < X n \<Longrightarrow> x \<in> S" by auto
  1647 
  1648   { fix N x assume N: "\<forall>n\<ge>N. X n < x"
  1649   fix y::real assume "y \<in> S"
  1650   hence "\<exists>M. \<forall>n\<ge>M. y < X n"
  1651     by (simp add: S_def)
  1652   then obtain M where "\<forall>n\<ge>M. y < X n" ..
  1653   hence "y < X (max M N)" by simp
  1654   also have "\<dots> < x" using N by simp
  1655   finally have "y \<le> x"
  1656     by (rule order_less_imp_le) }
  1657   note bound_isUb = this 
  1658 
  1659   obtain N where "\<forall>m\<ge>N. \<forall>n\<ge>N. dist (X m) (X n) < 1"
  1660     using X[THEN metric_CauchyD, OF zero_less_one] by auto
  1661   hence N: "\<forall>n\<ge>N. dist (X n) (X N) < 1" by simp
  1662   have [simp]: "S \<noteq> {}"
  1663   proof (intro exI ex_in_conv[THEN iffD1])
  1664     from N have "\<forall>n\<ge>N. X N - 1 < X n"
  1665       by (simp add: abs_diff_less_iff dist_real_def)
  1666     thus "X N - 1 \<in> S" by (rule mem_S)
  1667   qed
  1668   have [simp]: "bdd_above S"
  1669   proof
  1670     from N have "\<forall>n\<ge>N. X n < X N + 1"
  1671       by (simp add: abs_diff_less_iff dist_real_def)
  1672     thus "\<And>s. s \<in> S \<Longrightarrow>  s \<le> X N + 1"
  1673       by (rule bound_isUb)
  1674   qed
  1675   have "X ----> Sup S"
  1676   proof (rule metric_LIMSEQ_I)
  1677   fix r::real assume "0 < r"
  1678   hence r: "0 < r/2" by simp
  1679   obtain N where "\<forall>n\<ge>N. \<forall>m\<ge>N. dist (X n) (X m) < r/2"
  1680     using metric_CauchyD [OF X r] by auto
  1681   hence "\<forall>n\<ge>N. dist (X n) (X N) < r/2" by simp
  1682   hence N: "\<forall>n\<ge>N. X N - r/2 < X n \<and> X n < X N + r/2"
  1683     by (simp only: dist_real_def abs_diff_less_iff)
  1684 
  1685   from N have "\<forall>n\<ge>N. X N - r/2 < X n" by fast
  1686   hence "X N - r/2 \<in> S" by (rule mem_S)
  1687   hence 1: "X N - r/2 \<le> Sup S" by (simp add: cSup_upper)
  1688 
  1689   from N have "\<forall>n\<ge>N. X n < X N + r/2" by fast
  1690   from bound_isUb[OF this]
  1691   have 2: "Sup S \<le> X N + r/2"
  1692     by (intro cSup_least) simp_all
  1693 
  1694   show "\<exists>N. \<forall>n\<ge>N. dist (X n) (Sup S) < r"
  1695   proof (intro exI allI impI)
  1696     fix n assume n: "N \<le> n"
  1697     from N n have "X n < X N + r/2" and "X N - r/2 < X n" by simp+
  1698     thus "dist (X n) (Sup S) < r" using 1 2
  1699       by (simp add: abs_diff_less_iff dist_real_def)
  1700   qed
  1701   qed
  1702   then show ?thesis unfolding convergent_def by auto
  1703 qed
  1704 
  1705 instance real :: complete_space
  1706   by intro_classes (rule real_Cauchy_convergent)
  1707 
  1708 class banach = real_normed_vector + complete_space
  1709 
  1710 instance real :: banach by default
  1711 
  1712 lemma tendsto_at_topI_sequentially:
  1713   fixes f :: "real \<Rightarrow> real"
  1714   assumes mono: "mono f"
  1715   assumes limseq: "(\<lambda>n. f (real n)) ----> y"
  1716   shows "(f ---> y) at_top"
  1717 proof (rule tendstoI)
  1718   fix e :: real assume "0 < e"
  1719   with limseq obtain N :: nat where N: "\<And>n. N \<le> n \<Longrightarrow> \<bar>f (real n) - y\<bar> < e"
  1720     by (auto simp: LIMSEQ_def dist_real_def)
  1721   { fix x :: real
  1722     obtain n where "x \<le> real_of_nat n"
  1723       using ex_le_of_nat[of x] ..
  1724     note monoD[OF mono this]
  1725     also have "f (real_of_nat n) \<le> y"
  1726       by (rule LIMSEQ_le_const[OF limseq])
  1727          (auto intro: exI[of _ n] monoD[OF mono] simp: real_eq_of_nat[symmetric])
  1728     finally have "f x \<le> y" . }
  1729   note le = this
  1730   have "eventually (\<lambda>x. real N \<le> x) at_top"
  1731     by (rule eventually_ge_at_top)
  1732   then show "eventually (\<lambda>x. dist (f x) y < e) at_top"
  1733   proof eventually_elim
  1734     fix x assume N': "real N \<le> x"
  1735     with N[of N] le have "y - f (real N) < e" by auto
  1736     moreover note monoD[OF mono N']
  1737     ultimately show "dist (f x) y < e"
  1738       using le[of x] by (auto simp: dist_real_def field_simps)
  1739   qed
  1740 qed
  1741 
  1742 end