src/HOL/Library/Product_Vector.thy
author hoelzl
Fri Mar 22 10:41:43 2013 +0100 (2013-03-22)
changeset 51478 270b21f3ae0a
parent 51002 496013a6eb38
child 51642 400ec5ae7f8f
permissions -rw-r--r--
move continuous and continuous_on to the HOL image; isCont is an abbreviation for continuous (at x) (isCont is now restricted to a T2 space)
     1 (*  Title:      HOL/Library/Product_Vector.thy
     2     Author:     Brian Huffman
     3 *)
     4 
     5 header {* Cartesian Products as Vector Spaces *}
     6 
     7 theory Product_Vector
     8 imports Inner_Product Product_plus
     9 begin
    10 
    11 subsection {* Product is a real vector space *}
    12 
    13 instantiation prod :: (real_vector, real_vector) real_vector
    14 begin
    15 
    16 definition scaleR_prod_def:
    17   "scaleR r A = (scaleR r (fst A), scaleR r (snd A))"
    18 
    19 lemma fst_scaleR [simp]: "fst (scaleR r A) = scaleR r (fst A)"
    20   unfolding scaleR_prod_def by simp
    21 
    22 lemma snd_scaleR [simp]: "snd (scaleR r A) = scaleR r (snd A)"
    23   unfolding scaleR_prod_def by simp
    24 
    25 lemma scaleR_Pair [simp]: "scaleR r (a, b) = (scaleR r a, scaleR r b)"
    26   unfolding scaleR_prod_def by simp
    27 
    28 instance proof
    29   fix a b :: real and x y :: "'a \<times> 'b"
    30   show "scaleR a (x + y) = scaleR a x + scaleR a y"
    31     by (simp add: prod_eq_iff scaleR_right_distrib)
    32   show "scaleR (a + b) x = scaleR a x + scaleR b x"
    33     by (simp add: prod_eq_iff scaleR_left_distrib)
    34   show "scaleR a (scaleR b x) = scaleR (a * b) x"
    35     by (simp add: prod_eq_iff)
    36   show "scaleR 1 x = x"
    37     by (simp add: prod_eq_iff)
    38 qed
    39 
    40 end
    41 
    42 subsection {* Product is a topological space *}
    43 
    44 instantiation prod :: (topological_space, topological_space) topological_space
    45 begin
    46 
    47 definition open_prod_def:
    48   "open (S :: ('a \<times> 'b) set) \<longleftrightarrow>
    49     (\<forall>x\<in>S. \<exists>A B. open A \<and> open B \<and> x \<in> A \<times> B \<and> A \<times> B \<subseteq> S)"
    50 
    51 lemma open_prod_elim:
    52   assumes "open S" and "x \<in> S"
    53   obtains A B where "open A" and "open B" and "x \<in> A \<times> B" and "A \<times> B \<subseteq> S"
    54 using assms unfolding open_prod_def by fast
    55 
    56 lemma open_prod_intro:
    57   assumes "\<And>x. x \<in> S \<Longrightarrow> \<exists>A B. open A \<and> open B \<and> x \<in> A \<times> B \<and> A \<times> B \<subseteq> S"
    58   shows "open S"
    59 using assms unfolding open_prod_def by fast
    60 
    61 instance proof
    62   show "open (UNIV :: ('a \<times> 'b) set)"
    63     unfolding open_prod_def by auto
    64 next
    65   fix S T :: "('a \<times> 'b) set"
    66   assume "open S" "open T"
    67   show "open (S \<inter> T)"
    68   proof (rule open_prod_intro)
    69     fix x assume x: "x \<in> S \<inter> T"
    70     from x have "x \<in> S" by simp
    71     obtain Sa Sb where A: "open Sa" "open Sb" "x \<in> Sa \<times> Sb" "Sa \<times> Sb \<subseteq> S"
    72       using `open S` and `x \<in> S` by (rule open_prod_elim)
    73     from x have "x \<in> T" by simp
    74     obtain Ta Tb where B: "open Ta" "open Tb" "x \<in> Ta \<times> Tb" "Ta \<times> Tb \<subseteq> T"
    75       using `open T` and `x \<in> T` by (rule open_prod_elim)
    76     let ?A = "Sa \<inter> Ta" and ?B = "Sb \<inter> Tb"
    77     have "open ?A \<and> open ?B \<and> x \<in> ?A \<times> ?B \<and> ?A \<times> ?B \<subseteq> S \<inter> T"
    78       using A B by (auto simp add: open_Int)
    79     thus "\<exists>A B. open A \<and> open B \<and> x \<in> A \<times> B \<and> A \<times> B \<subseteq> S \<inter> T"
    80       by fast
    81   qed
    82 next
    83   fix K :: "('a \<times> 'b) set set"
    84   assume "\<forall>S\<in>K. open S" thus "open (\<Union>K)"
    85     unfolding open_prod_def by fast
    86 qed
    87 
    88 end
    89 
    90 lemma open_Times: "open S \<Longrightarrow> open T \<Longrightarrow> open (S \<times> T)"
    91 unfolding open_prod_def by auto
    92 
    93 lemma fst_vimage_eq_Times: "fst -` S = S \<times> UNIV"
    94 by auto
    95 
    96 lemma snd_vimage_eq_Times: "snd -` S = UNIV \<times> S"
    97 by auto
    98 
    99 lemma open_vimage_fst: "open S \<Longrightarrow> open (fst -` S)"
   100 by (simp add: fst_vimage_eq_Times open_Times)
   101 
   102 lemma open_vimage_snd: "open S \<Longrightarrow> open (snd -` S)"
   103 by (simp add: snd_vimage_eq_Times open_Times)
   104 
   105 lemma closed_vimage_fst: "closed S \<Longrightarrow> closed (fst -` S)"
   106 unfolding closed_open vimage_Compl [symmetric]
   107 by (rule open_vimage_fst)
   108 
   109 lemma closed_vimage_snd: "closed S \<Longrightarrow> closed (snd -` S)"
   110 unfolding closed_open vimage_Compl [symmetric]
   111 by (rule open_vimage_snd)
   112 
   113 lemma closed_Times: "closed S \<Longrightarrow> closed T \<Longrightarrow> closed (S \<times> T)"
   114 proof -
   115   have "S \<times> T = (fst -` S) \<inter> (snd -` T)" by auto
   116   thus "closed S \<Longrightarrow> closed T \<Longrightarrow> closed (S \<times> T)"
   117     by (simp add: closed_vimage_fst closed_vimage_snd closed_Int)
   118 qed
   119 
   120 lemma subset_fst_imageI: "A \<times> B \<subseteq> S \<Longrightarrow> y \<in> B \<Longrightarrow> A \<subseteq> fst ` S"
   121   unfolding image_def subset_eq by force
   122 
   123 lemma subset_snd_imageI: "A \<times> B \<subseteq> S \<Longrightarrow> x \<in> A \<Longrightarrow> B \<subseteq> snd ` S"
   124   unfolding image_def subset_eq by force
   125 
   126 lemma open_image_fst: assumes "open S" shows "open (fst ` S)"
   127 proof (rule openI)
   128   fix x assume "x \<in> fst ` S"
   129   then obtain y where "(x, y) \<in> S" by auto
   130   then obtain A B where "open A" "open B" "x \<in> A" "y \<in> B" "A \<times> B \<subseteq> S"
   131     using `open S` unfolding open_prod_def by auto
   132   from `A \<times> B \<subseteq> S` `y \<in> B` have "A \<subseteq> fst ` S" by (rule subset_fst_imageI)
   133   with `open A` `x \<in> A` have "open A \<and> x \<in> A \<and> A \<subseteq> fst ` S" by simp
   134   then show "\<exists>T. open T \<and> x \<in> T \<and> T \<subseteq> fst ` S" by - (rule exI)
   135 qed
   136 
   137 lemma open_image_snd: assumes "open S" shows "open (snd ` S)"
   138 proof (rule openI)
   139   fix y assume "y \<in> snd ` S"
   140   then obtain x where "(x, y) \<in> S" by auto
   141   then obtain A B where "open A" "open B" "x \<in> A" "y \<in> B" "A \<times> B \<subseteq> S"
   142     using `open S` unfolding open_prod_def by auto
   143   from `A \<times> B \<subseteq> S` `x \<in> A` have "B \<subseteq> snd ` S" by (rule subset_snd_imageI)
   144   with `open B` `y \<in> B` have "open B \<and> y \<in> B \<and> B \<subseteq> snd ` S" by simp
   145   then show "\<exists>T. open T \<and> y \<in> T \<and> T \<subseteq> snd ` S" by - (rule exI)
   146 qed
   147 
   148 subsubsection {* Continuity of operations *}
   149 
   150 lemma tendsto_fst [tendsto_intros]:
   151   assumes "(f ---> a) F"
   152   shows "((\<lambda>x. fst (f x)) ---> fst a) F"
   153 proof (rule topological_tendstoI)
   154   fix S assume "open S" and "fst a \<in> S"
   155   then have "open (fst -` S)" and "a \<in> fst -` S"
   156     by (simp_all add: open_vimage_fst)
   157   with assms have "eventually (\<lambda>x. f x \<in> fst -` S) F"
   158     by (rule topological_tendstoD)
   159   then show "eventually (\<lambda>x. fst (f x) \<in> S) F"
   160     by simp
   161 qed
   162 
   163 lemma tendsto_snd [tendsto_intros]:
   164   assumes "(f ---> a) F"
   165   shows "((\<lambda>x. snd (f x)) ---> snd a) F"
   166 proof (rule topological_tendstoI)
   167   fix S assume "open S" and "snd a \<in> S"
   168   then have "open (snd -` S)" and "a \<in> snd -` S"
   169     by (simp_all add: open_vimage_snd)
   170   with assms have "eventually (\<lambda>x. f x \<in> snd -` S) F"
   171     by (rule topological_tendstoD)
   172   then show "eventually (\<lambda>x. snd (f x) \<in> S) F"
   173     by simp
   174 qed
   175 
   176 lemma tendsto_Pair [tendsto_intros]:
   177   assumes "(f ---> a) F" and "(g ---> b) F"
   178   shows "((\<lambda>x. (f x, g x)) ---> (a, b)) F"
   179 proof (rule topological_tendstoI)
   180   fix S assume "open S" and "(a, b) \<in> S"
   181   then obtain A B where "open A" "open B" "a \<in> A" "b \<in> B" "A \<times> B \<subseteq> S"
   182     unfolding open_prod_def by fast
   183   have "eventually (\<lambda>x. f x \<in> A) F"
   184     using `(f ---> a) F` `open A` `a \<in> A`
   185     by (rule topological_tendstoD)
   186   moreover
   187   have "eventually (\<lambda>x. g x \<in> B) F"
   188     using `(g ---> b) F` `open B` `b \<in> B`
   189     by (rule topological_tendstoD)
   190   ultimately
   191   show "eventually (\<lambda>x. (f x, g x) \<in> S) F"
   192     by (rule eventually_elim2)
   193        (simp add: subsetD [OF `A \<times> B \<subseteq> S`])
   194 qed
   195 
   196 lemma continuous_fst[continuous_intros]: "continuous F f \<Longrightarrow> continuous F (\<lambda>x. fst (f x))"
   197   unfolding continuous_def by (rule tendsto_fst)
   198 
   199 lemma continuous_snd[continuous_intros]: "continuous F f \<Longrightarrow> continuous F (\<lambda>x. snd (f x))"
   200   unfolding continuous_def by (rule tendsto_snd)
   201 
   202 lemma continuous_Pair[continuous_intros]: "continuous F f \<Longrightarrow> continuous F g \<Longrightarrow> continuous F (\<lambda>x. (f x, g x))"
   203   unfolding continuous_def by (rule tendsto_Pair)
   204 
   205 lemma isCont_fst [simp]: "isCont f a \<Longrightarrow> isCont (\<lambda>x. fst (f x)) a"
   206   by (fact continuous_fst)
   207 
   208 lemma isCont_snd [simp]: "isCont f a \<Longrightarrow> isCont (\<lambda>x. snd (f x)) a"
   209   by (fact continuous_snd)
   210 
   211 lemma isCont_Pair [simp]: "\<lbrakk>isCont f a; isCont g a\<rbrakk> \<Longrightarrow> isCont (\<lambda>x. (f x, g x)) a"
   212   by (fact continuous_Pair)
   213 
   214 subsubsection {* Separation axioms *}
   215 
   216 lemma mem_Times_iff: "x \<in> A \<times> B \<longleftrightarrow> fst x \<in> A \<and> snd x \<in> B"
   217   by (induct x) simp (* TODO: move elsewhere *)
   218 
   219 instance prod :: (t0_space, t0_space) t0_space
   220 proof
   221   fix x y :: "'a \<times> 'b" assume "x \<noteq> y"
   222   hence "fst x \<noteq> fst y \<or> snd x \<noteq> snd y"
   223     by (simp add: prod_eq_iff)
   224   thus "\<exists>U. open U \<and> (x \<in> U) \<noteq> (y \<in> U)"
   225     apply (rule disjE)
   226     apply (drule t0_space, erule exE, rule_tac x="U \<times> UNIV" in exI)
   227     apply (simp add: open_Times mem_Times_iff)
   228     apply (drule t0_space, erule exE, rule_tac x="UNIV \<times> U" in exI)
   229     apply (simp add: open_Times mem_Times_iff)
   230     done
   231 qed
   232 
   233 instance prod :: (t1_space, t1_space) t1_space
   234 proof
   235   fix x y :: "'a \<times> 'b" assume "x \<noteq> y"
   236   hence "fst x \<noteq> fst y \<or> snd x \<noteq> snd y"
   237     by (simp add: prod_eq_iff)
   238   thus "\<exists>U. open U \<and> x \<in> U \<and> y \<notin> U"
   239     apply (rule disjE)
   240     apply (drule t1_space, erule exE, rule_tac x="U \<times> UNIV" in exI)
   241     apply (simp add: open_Times mem_Times_iff)
   242     apply (drule t1_space, erule exE, rule_tac x="UNIV \<times> U" in exI)
   243     apply (simp add: open_Times mem_Times_iff)
   244     done
   245 qed
   246 
   247 instance prod :: (t2_space, t2_space) t2_space
   248 proof
   249   fix x y :: "'a \<times> 'b" assume "x \<noteq> y"
   250   hence "fst x \<noteq> fst y \<or> snd x \<noteq> snd y"
   251     by (simp add: prod_eq_iff)
   252   thus "\<exists>U V. open U \<and> open V \<and> x \<in> U \<and> y \<in> V \<and> U \<inter> V = {}"
   253     apply (rule disjE)
   254     apply (drule hausdorff, clarify)
   255     apply (rule_tac x="U \<times> UNIV" in exI, rule_tac x="V \<times> UNIV" in exI)
   256     apply (simp add: open_Times mem_Times_iff disjoint_iff_not_equal)
   257     apply (drule hausdorff, clarify)
   258     apply (rule_tac x="UNIV \<times> U" in exI, rule_tac x="UNIV \<times> V" in exI)
   259     apply (simp add: open_Times mem_Times_iff disjoint_iff_not_equal)
   260     done
   261 qed
   262 
   263 subsection {* Product is a metric space *}
   264 
   265 instantiation prod :: (metric_space, metric_space) metric_space
   266 begin
   267 
   268 definition dist_prod_def:
   269   "dist x y = sqrt ((dist (fst x) (fst y))\<twosuperior> + (dist (snd x) (snd y))\<twosuperior>)"
   270 
   271 lemma dist_Pair_Pair: "dist (a, b) (c, d) = sqrt ((dist a c)\<twosuperior> + (dist b d)\<twosuperior>)"
   272   unfolding dist_prod_def by simp
   273 
   274 lemma dist_fst_le: "dist (fst x) (fst y) \<le> dist x y"
   275 unfolding dist_prod_def by (rule real_sqrt_sum_squares_ge1)
   276 
   277 lemma dist_snd_le: "dist (snd x) (snd y) \<le> dist x y"
   278 unfolding dist_prod_def by (rule real_sqrt_sum_squares_ge2)
   279 
   280 instance proof
   281   fix x y :: "'a \<times> 'b"
   282   show "dist x y = 0 \<longleftrightarrow> x = y"
   283     unfolding dist_prod_def prod_eq_iff by simp
   284 next
   285   fix x y z :: "'a \<times> 'b"
   286   show "dist x y \<le> dist x z + dist y z"
   287     unfolding dist_prod_def
   288     by (intro order_trans [OF _ real_sqrt_sum_squares_triangle_ineq]
   289         real_sqrt_le_mono add_mono power_mono dist_triangle2 zero_le_dist)
   290 next
   291   fix S :: "('a \<times> 'b) set"
   292   show "open S \<longleftrightarrow> (\<forall>x\<in>S. \<exists>e>0. \<forall>y. dist y x < e \<longrightarrow> y \<in> S)"
   293   proof
   294     assume "open S" show "\<forall>x\<in>S. \<exists>e>0. \<forall>y. dist y x < e \<longrightarrow> y \<in> S"
   295     proof
   296       fix x assume "x \<in> S"
   297       obtain A B where "open A" "open B" "x \<in> A \<times> B" "A \<times> B \<subseteq> S"
   298         using `open S` and `x \<in> S` by (rule open_prod_elim)
   299       obtain r where r: "0 < r" "\<forall>y. dist y (fst x) < r \<longrightarrow> y \<in> A"
   300         using `open A` and `x \<in> A \<times> B` unfolding open_dist by auto
   301       obtain s where s: "0 < s" "\<forall>y. dist y (snd x) < s \<longrightarrow> y \<in> B"
   302         using `open B` and `x \<in> A \<times> B` unfolding open_dist by auto
   303       let ?e = "min r s"
   304       have "0 < ?e \<and> (\<forall>y. dist y x < ?e \<longrightarrow> y \<in> S)"
   305       proof (intro allI impI conjI)
   306         show "0 < min r s" by (simp add: r(1) s(1))
   307       next
   308         fix y assume "dist y x < min r s"
   309         hence "dist y x < r" and "dist y x < s"
   310           by simp_all
   311         hence "dist (fst y) (fst x) < r" and "dist (snd y) (snd x) < s"
   312           by (auto intro: le_less_trans dist_fst_le dist_snd_le)
   313         hence "fst y \<in> A" and "snd y \<in> B"
   314           by (simp_all add: r(2) s(2))
   315         hence "y \<in> A \<times> B" by (induct y, simp)
   316         with `A \<times> B \<subseteq> S` show "y \<in> S" ..
   317       qed
   318       thus "\<exists>e>0. \<forall>y. dist y x < e \<longrightarrow> y \<in> S" ..
   319     qed
   320   next
   321     assume *: "\<forall>x\<in>S. \<exists>e>0. \<forall>y. dist y x < e \<longrightarrow> y \<in> S" show "open S"
   322     proof (rule open_prod_intro)
   323       fix x assume "x \<in> S"
   324       then obtain e where "0 < e" and S: "\<forall>y. dist y x < e \<longrightarrow> y \<in> S"
   325         using * by fast
   326       def r \<equiv> "e / sqrt 2" and s \<equiv> "e / sqrt 2"
   327       from `0 < e` have "0 < r" and "0 < s"
   328         unfolding r_def s_def by (simp_all add: divide_pos_pos)
   329       from `0 < e` have "e = sqrt (r\<twosuperior> + s\<twosuperior>)"
   330         unfolding r_def s_def by (simp add: power_divide)
   331       def A \<equiv> "{y. dist (fst x) y < r}" and B \<equiv> "{y. dist (snd x) y < s}"
   332       have "open A" and "open B"
   333         unfolding A_def B_def by (simp_all add: open_ball)
   334       moreover have "x \<in> A \<times> B"
   335         unfolding A_def B_def mem_Times_iff
   336         using `0 < r` and `0 < s` by simp
   337       moreover have "A \<times> B \<subseteq> S"
   338       proof (clarify)
   339         fix a b assume "a \<in> A" and "b \<in> B"
   340         hence "dist a (fst x) < r" and "dist b (snd x) < s"
   341           unfolding A_def B_def by (simp_all add: dist_commute)
   342         hence "dist (a, b) x < e"
   343           unfolding dist_prod_def `e = sqrt (r\<twosuperior> + s\<twosuperior>)`
   344           by (simp add: add_strict_mono power_strict_mono)
   345         thus "(a, b) \<in> S"
   346           by (simp add: S)
   347       qed
   348       ultimately show "\<exists>A B. open A \<and> open B \<and> x \<in> A \<times> B \<and> A \<times> B \<subseteq> S" by fast
   349     qed
   350   qed
   351 qed
   352 
   353 end
   354 
   355 lemma Cauchy_fst: "Cauchy X \<Longrightarrow> Cauchy (\<lambda>n. fst (X n))"
   356 unfolding Cauchy_def by (fast elim: le_less_trans [OF dist_fst_le])
   357 
   358 lemma Cauchy_snd: "Cauchy X \<Longrightarrow> Cauchy (\<lambda>n. snd (X n))"
   359 unfolding Cauchy_def by (fast elim: le_less_trans [OF dist_snd_le])
   360 
   361 lemma Cauchy_Pair:
   362   assumes "Cauchy X" and "Cauchy Y"
   363   shows "Cauchy (\<lambda>n. (X n, Y n))"
   364 proof (rule metric_CauchyI)
   365   fix r :: real assume "0 < r"
   366   then have "0 < r / sqrt 2" (is "0 < ?s")
   367     by (simp add: divide_pos_pos)
   368   obtain M where M: "\<forall>m\<ge>M. \<forall>n\<ge>M. dist (X m) (X n) < ?s"
   369     using metric_CauchyD [OF `Cauchy X` `0 < ?s`] ..
   370   obtain N where N: "\<forall>m\<ge>N. \<forall>n\<ge>N. dist (Y m) (Y n) < ?s"
   371     using metric_CauchyD [OF `Cauchy Y` `0 < ?s`] ..
   372   have "\<forall>m\<ge>max M N. \<forall>n\<ge>max M N. dist (X m, Y m) (X n, Y n) < r"
   373     using M N by (simp add: real_sqrt_sum_squares_less dist_Pair_Pair)
   374   then show "\<exists>n0. \<forall>m\<ge>n0. \<forall>n\<ge>n0. dist (X m, Y m) (X n, Y n) < r" ..
   375 qed
   376 
   377 subsection {* Product is a complete metric space *}
   378 
   379 instance prod :: (complete_space, complete_space) complete_space
   380 proof
   381   fix X :: "nat \<Rightarrow> 'a \<times> 'b" assume "Cauchy X"
   382   have 1: "(\<lambda>n. fst (X n)) ----> lim (\<lambda>n. fst (X n))"
   383     using Cauchy_fst [OF `Cauchy X`]
   384     by (simp add: Cauchy_convergent_iff convergent_LIMSEQ_iff)
   385   have 2: "(\<lambda>n. snd (X n)) ----> lim (\<lambda>n. snd (X n))"
   386     using Cauchy_snd [OF `Cauchy X`]
   387     by (simp add: Cauchy_convergent_iff convergent_LIMSEQ_iff)
   388   have "X ----> (lim (\<lambda>n. fst (X n)), lim (\<lambda>n. snd (X n)))"
   389     using tendsto_Pair [OF 1 2] by simp
   390   then show "convergent X"
   391     by (rule convergentI)
   392 qed
   393 
   394 subsection {* Product is a normed vector space *}
   395 
   396 instantiation prod :: (real_normed_vector, real_normed_vector) real_normed_vector
   397 begin
   398 
   399 definition norm_prod_def:
   400   "norm x = sqrt ((norm (fst x))\<twosuperior> + (norm (snd x))\<twosuperior>)"
   401 
   402 definition sgn_prod_def:
   403   "sgn (x::'a \<times> 'b) = scaleR (inverse (norm x)) x"
   404 
   405 lemma norm_Pair: "norm (a, b) = sqrt ((norm a)\<twosuperior> + (norm b)\<twosuperior>)"
   406   unfolding norm_prod_def by simp
   407 
   408 instance proof
   409   fix r :: real and x y :: "'a \<times> 'b"
   410   show "norm x = 0 \<longleftrightarrow> x = 0"
   411     unfolding norm_prod_def
   412     by (simp add: prod_eq_iff)
   413   show "norm (x + y) \<le> norm x + norm y"
   414     unfolding norm_prod_def
   415     apply (rule order_trans [OF _ real_sqrt_sum_squares_triangle_ineq])
   416     apply (simp add: add_mono power_mono norm_triangle_ineq)
   417     done
   418   show "norm (scaleR r x) = \<bar>r\<bar> * norm x"
   419     unfolding norm_prod_def
   420     apply (simp add: power_mult_distrib)
   421     apply (simp add: distrib_left [symmetric])
   422     apply (simp add: real_sqrt_mult_distrib)
   423     done
   424   show "sgn x = scaleR (inverse (norm x)) x"
   425     by (rule sgn_prod_def)
   426   show "dist x y = norm (x - y)"
   427     unfolding dist_prod_def norm_prod_def
   428     by (simp add: dist_norm)
   429 qed
   430 
   431 end
   432 
   433 instance prod :: (banach, banach) banach ..
   434 
   435 subsubsection {* Pair operations are linear *}
   436 
   437 lemma bounded_linear_fst: "bounded_linear fst"
   438   using fst_add fst_scaleR
   439   by (rule bounded_linear_intro [where K=1], simp add: norm_prod_def)
   440 
   441 lemma bounded_linear_snd: "bounded_linear snd"
   442   using snd_add snd_scaleR
   443   by (rule bounded_linear_intro [where K=1], simp add: norm_prod_def)
   444 
   445 text {* TODO: move to NthRoot *}
   446 lemma sqrt_add_le_add_sqrt:
   447   assumes x: "0 \<le> x" and y: "0 \<le> y"
   448   shows "sqrt (x + y) \<le> sqrt x + sqrt y"
   449 apply (rule power2_le_imp_le)
   450 apply (simp add: power2_sum x y)
   451 apply (simp add: mult_nonneg_nonneg x y)
   452 apply (simp add: x y)
   453 done
   454 
   455 lemma bounded_linear_Pair:
   456   assumes f: "bounded_linear f"
   457   assumes g: "bounded_linear g"
   458   shows "bounded_linear (\<lambda>x. (f x, g x))"
   459 proof
   460   interpret f: bounded_linear f by fact
   461   interpret g: bounded_linear g by fact
   462   fix x y and r :: real
   463   show "(f (x + y), g (x + y)) = (f x, g x) + (f y, g y)"
   464     by (simp add: f.add g.add)
   465   show "(f (r *\<^sub>R x), g (r *\<^sub>R x)) = r *\<^sub>R (f x, g x)"
   466     by (simp add: f.scaleR g.scaleR)
   467   obtain Kf where "0 < Kf" and norm_f: "\<And>x. norm (f x) \<le> norm x * Kf"
   468     using f.pos_bounded by fast
   469   obtain Kg where "0 < Kg" and norm_g: "\<And>x. norm (g x) \<le> norm x * Kg"
   470     using g.pos_bounded by fast
   471   have "\<forall>x. norm (f x, g x) \<le> norm x * (Kf + Kg)"
   472     apply (rule allI)
   473     apply (simp add: norm_Pair)
   474     apply (rule order_trans [OF sqrt_add_le_add_sqrt], simp, simp)
   475     apply (simp add: distrib_left)
   476     apply (rule add_mono [OF norm_f norm_g])
   477     done
   478   then show "\<exists>K. \<forall>x. norm (f x, g x) \<le> norm x * K" ..
   479 qed
   480 
   481 subsubsection {* Frechet derivatives involving pairs *}
   482 
   483 lemma FDERIV_Pair:
   484   assumes f: "FDERIV f x :> f'" and g: "FDERIV g x :> g'"
   485   shows "FDERIV (\<lambda>x. (f x, g x)) x :> (\<lambda>h. (f' h, g' h))"
   486 proof (rule FDERIV_I)
   487   show "bounded_linear (\<lambda>h. (f' h, g' h))"
   488     using f g by (intro bounded_linear_Pair FDERIV_bounded_linear)
   489   let ?Rf = "\<lambda>h. f (x + h) - f x - f' h"
   490   let ?Rg = "\<lambda>h. g (x + h) - g x - g' h"
   491   let ?R = "\<lambda>h. ((f (x + h), g (x + h)) - (f x, g x) - (f' h, g' h))"
   492   show "(\<lambda>h. norm (?R h) / norm h) -- 0 --> 0"
   493   proof (rule real_LIM_sandwich_zero)
   494     show "(\<lambda>h. norm (?Rf h) / norm h + norm (?Rg h) / norm h) -- 0 --> 0"
   495       using f g by (intro tendsto_add_zero FDERIV_D)
   496     fix h :: 'a assume "h \<noteq> 0"
   497     thus "0 \<le> norm (?R h) / norm h"
   498       by (simp add: divide_nonneg_pos)
   499     show "norm (?R h) / norm h \<le> norm (?Rf h) / norm h + norm (?Rg h) / norm h"
   500       unfolding add_divide_distrib [symmetric]
   501       by (simp add: norm_Pair divide_right_mono
   502         order_trans [OF sqrt_add_le_add_sqrt])
   503   qed
   504 qed
   505 
   506 subsection {* Product is an inner product space *}
   507 
   508 instantiation prod :: (real_inner, real_inner) real_inner
   509 begin
   510 
   511 definition inner_prod_def:
   512   "inner x y = inner (fst x) (fst y) + inner (snd x) (snd y)"
   513 
   514 lemma inner_Pair [simp]: "inner (a, b) (c, d) = inner a c + inner b d"
   515   unfolding inner_prod_def by simp
   516 
   517 instance proof
   518   fix r :: real
   519   fix x y z :: "'a::real_inner \<times> 'b::real_inner"
   520   show "inner x y = inner y x"
   521     unfolding inner_prod_def
   522     by (simp add: inner_commute)
   523   show "inner (x + y) z = inner x z + inner y z"
   524     unfolding inner_prod_def
   525     by (simp add: inner_add_left)
   526   show "inner (scaleR r x) y = r * inner x y"
   527     unfolding inner_prod_def
   528     by (simp add: distrib_left)
   529   show "0 \<le> inner x x"
   530     unfolding inner_prod_def
   531     by (intro add_nonneg_nonneg inner_ge_zero)
   532   show "inner x x = 0 \<longleftrightarrow> x = 0"
   533     unfolding inner_prod_def prod_eq_iff
   534     by (simp add: add_nonneg_eq_0_iff)
   535   show "norm x = sqrt (inner x x)"
   536     unfolding norm_prod_def inner_prod_def
   537     by (simp add: power2_norm_eq_inner)
   538 qed
   539 
   540 end
   541 
   542 end