src/HOL/Multivariate_Analysis/Linear_Algebra.thy
author hoelzl
Fri Mar 22 10:41:43 2013 +0100 (2013-03-22)
changeset 51478 270b21f3ae0a
parent 51475 ebf9d4fd00ba
child 53015 a1119cf551e8
permissions -rw-r--r--
move continuous and continuous_on to the HOL image; isCont is an abbreviation for continuous (at x) (isCont is now restricted to a T2 space)
     1 (*  Title:      HOL/Multivariate_Analysis/Linear_Algebra.thy
     2     Author:     Amine Chaieb, University of Cambridge
     3 *)
     4 
     5 header {* Elementary linear algebra on Euclidean spaces *}
     6 
     7 theory Linear_Algebra
     8 imports
     9   Euclidean_Space
    10   "~~/src/HOL/Library/Infinite_Set"
    11 begin
    12 
    13 lemma cond_application_beta: "(if b then f else g) x = (if b then f x else g x)"
    14   by auto
    15 
    16 notation inner (infix "\<bullet>" 70)
    17 
    18 lemma square_bound_lemma: "(x::real) < (1 + x) * (1 + x)"
    19 proof -
    20   have "(x + 1/2)^2 + 3/4 > 0" using zero_le_power2[of "x+1/2"] by arith
    21   then show ?thesis by (simp add: field_simps power2_eq_square)
    22 qed
    23 
    24 lemma square_continuous: "0 < (e::real) ==> \<exists>d. 0 < d \<and> (\<forall>y. abs(y - x) < d \<longrightarrow> abs(y * y - x * x) < e)"
    25   using isCont_power[OF isCont_ident, of x, unfolded isCont_def LIM_eq, rule_format, of e 2]
    26   apply (auto simp add: power2_eq_square)
    27   apply (rule_tac x="s" in exI)
    28   apply auto
    29   apply (erule_tac x=y in allE)
    30   apply auto
    31   done
    32 
    33 lemma real_le_lsqrt: "0 <= x \<Longrightarrow> 0 <= y \<Longrightarrow> x <= y^2 ==> sqrt x <= y"
    34   using real_sqrt_le_iff[of x "y^2"] by simp
    35 
    36 lemma real_le_rsqrt: "x^2 \<le> y \<Longrightarrow> x \<le> sqrt y"
    37   using real_sqrt_le_mono[of "x^2" y] by simp
    38 
    39 lemma real_less_rsqrt: "x^2 < y \<Longrightarrow> x < sqrt y"
    40   using real_sqrt_less_mono[of "x^2" y] by simp
    41 
    42 lemma sqrt_even_pow2:
    43   assumes n: "even n"
    44   shows "sqrt(2 ^ n) = 2 ^ (n div 2)"
    45 proof -
    46   from n obtain m where m: "n = 2*m" unfolding even_mult_two_ex ..
    47   from m  have "sqrt(2 ^ n) = sqrt ((2 ^ m) ^ 2)"
    48     by (simp only: power_mult[symmetric] mult_commute)
    49   then show ?thesis  using m by simp
    50 qed
    51 
    52 lemma real_div_sqrt: "0 <= x ==> x / sqrt(x) = sqrt(x)"
    53   apply (cases "x = 0", simp_all)
    54   using sqrt_divide_self_eq[of x]
    55   apply (simp add: inverse_eq_divide field_simps)
    56   done
    57 
    58 text{* Hence derive more interesting properties of the norm. *}
    59 
    60 lemma norm_eq_0_dot: "(norm x = 0) \<longleftrightarrow> (inner x x = (0::real))"
    61   by simp (* TODO: delete *)
    62 
    63 lemma norm_cauchy_schwarz: "inner x y <= norm x * norm y"
    64   (* TODO: move to Inner_Product.thy *)
    65   using Cauchy_Schwarz_ineq2[of x y] by auto
    66 
    67 lemma norm_triangle_sub:
    68   fixes x y :: "'a::real_normed_vector"
    69   shows "norm x \<le> norm y  + norm (x - y)"
    70   using norm_triangle_ineq[of "y" "x - y"] by (simp add: field_simps)
    71 
    72 lemma norm_le: "norm(x) <= norm(y) \<longleftrightarrow> x \<bullet> x <= y \<bullet> y"
    73   by (simp add: norm_eq_sqrt_inner) 
    74 
    75 lemma norm_lt: "norm(x) < norm(y) \<longleftrightarrow> x \<bullet> x < y \<bullet> y"
    76   by (simp add: norm_eq_sqrt_inner)
    77 
    78 lemma norm_eq: "norm(x) = norm (y) \<longleftrightarrow> x \<bullet> x = y \<bullet> y"
    79   apply (subst order_eq_iff)
    80   apply (auto simp: norm_le)
    81   done
    82 
    83 lemma norm_eq_1: "norm(x) = 1 \<longleftrightarrow> x \<bullet> x = 1"
    84   by (simp add: norm_eq_sqrt_inner)
    85 
    86 text{* Squaring equations and inequalities involving norms.  *}
    87 
    88 lemma dot_square_norm: "x \<bullet> x = norm(x)^2"
    89   by (simp only: power2_norm_eq_inner) (* TODO: move? *)
    90 
    91 lemma norm_eq_square: "norm(x) = a \<longleftrightarrow> 0 <= a \<and> x \<bullet> x = a^2"
    92   by (auto simp add: norm_eq_sqrt_inner)
    93 
    94 lemma real_abs_le_square_iff: "\<bar>x\<bar> \<le> \<bar>y\<bar> \<longleftrightarrow> (x::real)^2 \<le> y^2"
    95 proof
    96   assume "\<bar>x\<bar> \<le> \<bar>y\<bar>"
    97   then have "\<bar>x\<bar>\<twosuperior> \<le> \<bar>y\<bar>\<twosuperior>" by (rule power_mono, simp)
    98   then show "x\<twosuperior> \<le> y\<twosuperior>" by simp
    99 next
   100   assume "x\<twosuperior> \<le> y\<twosuperior>"
   101   then have "sqrt (x\<twosuperior>) \<le> sqrt (y\<twosuperior>)" by (rule real_sqrt_le_mono)
   102   then show "\<bar>x\<bar> \<le> \<bar>y\<bar>" by simp
   103 qed
   104 
   105 lemma norm_le_square: "norm(x) <= a \<longleftrightarrow> 0 <= a \<and> x \<bullet> x <= a^2"
   106   apply (simp add: dot_square_norm real_abs_le_square_iff[symmetric])
   107   using norm_ge_zero[of x]
   108   apply arith
   109   done
   110 
   111 lemma norm_ge_square: "norm(x) >= a \<longleftrightarrow> a <= 0 \<or> x \<bullet> x >= a ^ 2"
   112   apply (simp add: dot_square_norm real_abs_le_square_iff[symmetric])
   113   using norm_ge_zero[of x]
   114   apply arith
   115   done
   116 
   117 lemma norm_lt_square: "norm(x) < a \<longleftrightarrow> 0 < a \<and> x \<bullet> x < a^2"
   118   by (metis not_le norm_ge_square)
   119 lemma norm_gt_square: "norm(x) > a \<longleftrightarrow> a < 0 \<or> x \<bullet> x > a^2"
   120   by (metis norm_le_square not_less)
   121 
   122 text{* Dot product in terms of the norm rather than conversely. *}
   123 
   124 lemmas inner_simps = inner_add_left inner_add_right inner_diff_right inner_diff_left 
   125   inner_scaleR_left inner_scaleR_right
   126 
   127 lemma dot_norm: "x \<bullet> y = (norm(x + y) ^2 - norm x ^ 2 - norm y ^ 2) / 2"
   128   unfolding power2_norm_eq_inner inner_simps inner_commute by auto 
   129 
   130 lemma dot_norm_neg: "x \<bullet> y = ((norm x ^ 2 + norm y ^ 2) - norm(x - y) ^ 2) / 2"
   131   unfolding power2_norm_eq_inner inner_simps inner_commute
   132   by (auto simp add: algebra_simps)
   133 
   134 text{* Equality of vectors in terms of @{term "op \<bullet>"} products.    *}
   135 
   136 lemma vector_eq: "x = y \<longleftrightarrow> x \<bullet> x = x \<bullet> y \<and> y \<bullet> y = x \<bullet> x" (is "?lhs \<longleftrightarrow> ?rhs")
   137 proof
   138   assume ?lhs
   139   then show ?rhs by simp
   140 next
   141   assume ?rhs
   142   then have "x \<bullet> x - x \<bullet> y = 0 \<and> x \<bullet> y - y \<bullet> y = 0" by simp
   143   then have "x \<bullet> (x - y) = 0 \<and> y \<bullet> (x - y) = 0" by (simp add: inner_diff inner_commute)
   144   then have "(x - y) \<bullet> (x - y) = 0" by (simp add: field_simps inner_diff inner_commute)
   145   then show "x = y" by (simp)
   146 qed
   147 
   148 lemma norm_triangle_half_r:
   149   shows "norm (y - x1) < e / 2 \<Longrightarrow> norm (y - x2) < e / 2 \<Longrightarrow> norm (x1 - x2) < e"
   150   using dist_triangle_half_r unfolding dist_norm[THEN sym] by auto
   151 
   152 lemma norm_triangle_half_l:
   153   assumes "norm (x - y) < e / 2" "norm (x' - (y)) < e / 2" 
   154   shows "norm (x - x') < e"
   155   using dist_triangle_half_l[OF assms[unfolded dist_norm[THEN sym]]]
   156   unfolding dist_norm[THEN sym] .
   157 
   158 lemma norm_triangle_le: "norm(x) + norm y <= e ==> norm(x + y) <= e"
   159   by (rule norm_triangle_ineq [THEN order_trans])
   160 
   161 lemma norm_triangle_lt: "norm(x) + norm(y) < e ==> norm(x + y) < e"
   162   by (rule norm_triangle_ineq [THEN le_less_trans])
   163 
   164 lemma setsum_clauses:
   165   shows "setsum f {} = 0"
   166     and "finite S \<Longrightarrow> setsum f (insert x S) = (if x \<in> S then setsum f S else f x + setsum f S)"
   167   by (auto simp add: insert_absorb)
   168 
   169 lemma setsum_norm_le:
   170   fixes f :: "'a \<Rightarrow> 'b::real_normed_vector"
   171   assumes fg: "\<forall>x \<in> S. norm (f x) \<le> g x"
   172   shows "norm (setsum f S) \<le> setsum g S"
   173   by (rule order_trans [OF norm_setsum setsum_mono]) (simp add: fg)
   174 
   175 lemma setsum_norm_bound:
   176   fixes f :: "'a \<Rightarrow> 'b::real_normed_vector"
   177   assumes fS: "finite S"
   178     and K: "\<forall>x \<in> S. norm (f x) \<le> K"
   179   shows "norm (setsum f S) \<le> of_nat (card S) * K"
   180   using setsum_norm_le[OF K] setsum_constant[symmetric]
   181   by simp
   182 
   183 lemma setsum_group:
   184   assumes fS: "finite S" and fT: "finite T" and fST: "f ` S \<subseteq> T"
   185   shows "setsum (\<lambda>y. setsum g {x. x\<in> S \<and> f x = y}) T = setsum g S"
   186   apply (subst setsum_image_gen[OF fS, of g f])
   187   apply (rule setsum_mono_zero_right[OF fT fST])
   188   apply (auto intro: setsum_0')
   189   done
   190 
   191 lemma vector_eq_ldot: "(\<forall>x. x \<bullet> y = x \<bullet> z) \<longleftrightarrow> y = z"
   192 proof
   193   assume "\<forall>x. x \<bullet> y = x \<bullet> z"
   194   then have "\<forall>x. x \<bullet> (y - z) = 0" by (simp add: inner_diff)
   195   then have "(y - z) \<bullet> (y - z) = 0" ..
   196   then show "y = z" by simp
   197 qed simp
   198 
   199 lemma vector_eq_rdot: "(\<forall>z. x \<bullet> z = y \<bullet> z) \<longleftrightarrow> x = y"
   200 proof
   201   assume "\<forall>z. x \<bullet> z = y \<bullet> z"
   202   then have "\<forall>z. (x - y) \<bullet> z = 0" by (simp add: inner_diff)
   203   then have "(x - y) \<bullet> (x - y) = 0" ..
   204   then show "x = y" by simp
   205 qed simp
   206 
   207 
   208 subsection {* Orthogonality. *}
   209 
   210 context real_inner
   211 begin
   212 
   213 definition "orthogonal x y \<longleftrightarrow> (x \<bullet> y = 0)"
   214 
   215 lemma orthogonal_clauses:
   216   "orthogonal a 0"
   217   "orthogonal a x \<Longrightarrow> orthogonal a (c *\<^sub>R x)"
   218   "orthogonal a x \<Longrightarrow> orthogonal a (-x)"
   219   "orthogonal a x \<Longrightarrow> orthogonal a y \<Longrightarrow> orthogonal a (x + y)"
   220   "orthogonal a x \<Longrightarrow> orthogonal a y \<Longrightarrow> orthogonal a (x - y)"
   221   "orthogonal 0 a"
   222   "orthogonal x a \<Longrightarrow> orthogonal (c *\<^sub>R x) a"
   223   "orthogonal x a \<Longrightarrow> orthogonal (-x) a"
   224   "orthogonal x a \<Longrightarrow> orthogonal y a \<Longrightarrow> orthogonal (x + y) a"
   225   "orthogonal x a \<Longrightarrow> orthogonal y a \<Longrightarrow> orthogonal (x - y) a"
   226   unfolding orthogonal_def inner_add inner_diff by auto
   227 
   228 end
   229 
   230 lemma orthogonal_commute: "orthogonal x y \<longleftrightarrow> orthogonal y x"
   231   by (simp add: orthogonal_def inner_commute)
   232 
   233 
   234 subsection {* Linear functions. *}
   235 
   236 definition linear :: "('a::real_vector \<Rightarrow> 'b::real_vector) \<Rightarrow> bool"
   237   where "linear f \<longleftrightarrow> (\<forall>x y. f(x + y) = f x + f y) \<and> (\<forall>c x. f(c *\<^sub>R x) = c *\<^sub>R f x)"
   238 
   239 lemma linearI:
   240   assumes "\<And>x y. f (x + y) = f x + f y" "\<And>c x. f (c *\<^sub>R x) = c *\<^sub>R f x"
   241   shows "linear f"
   242   using assms unfolding linear_def by auto
   243 
   244 lemma linear_compose_cmul: "linear f ==> linear (\<lambda>x. c *\<^sub>R f x)"
   245   by (simp add: linear_def algebra_simps)
   246 
   247 lemma linear_compose_neg: "linear f ==> linear (\<lambda>x. -(f(x)))"
   248   by (simp add: linear_def)
   249 
   250 lemma linear_compose_add: "linear f \<Longrightarrow> linear g ==> linear (\<lambda>x. f(x) + g(x))"
   251   by (simp add: linear_def algebra_simps)
   252 
   253 lemma linear_compose_sub: "linear f \<Longrightarrow> linear g ==> linear (\<lambda>x. f x - g x)"
   254   by (simp add: linear_def algebra_simps)
   255 
   256 lemma linear_compose: "linear f \<Longrightarrow> linear g ==> linear (g o f)"
   257   by (simp add: linear_def)
   258 
   259 lemma linear_id: "linear id" by (simp add: linear_def id_def)
   260 
   261 lemma linear_zero: "linear (\<lambda>x. 0)" by (simp add: linear_def)
   262 
   263 lemma linear_compose_setsum:
   264   assumes fS: "finite S" and lS: "\<forall>a \<in> S. linear (f a)"
   265   shows "linear(\<lambda>x. setsum (\<lambda>a. f a x) S)"
   266   using lS
   267   apply (induct rule: finite_induct[OF fS])
   268   apply (auto simp add: linear_zero intro: linear_compose_add)
   269   done
   270 
   271 lemma linear_0: "linear f \<Longrightarrow> f 0 = 0"
   272   unfolding linear_def
   273   apply clarsimp
   274   apply (erule allE[where x="0::'a"])
   275   apply simp
   276   done
   277 
   278 lemma linear_cmul: "linear f ==> f(c *\<^sub>R x) = c *\<^sub>R f x"
   279   by (simp add: linear_def)
   280 
   281 lemma linear_neg: "linear f ==> f (-x) = - f x"
   282   using linear_cmul [where c="-1"] by simp
   283 
   284 lemma linear_add: "linear f ==> f(x + y) = f x + f y"
   285   by (metis linear_def)
   286 
   287 lemma linear_sub: "linear f ==> f(x - y) = f x - f y"
   288   by (simp add: diff_minus linear_add linear_neg)
   289 
   290 lemma linear_setsum:
   291   assumes lf: "linear f" and fS: "finite S"
   292   shows "f (setsum g S) = setsum (f o g) S"
   293   using fS
   294 proof (induct rule: finite_induct)
   295   case empty
   296   then show ?case by (simp add: linear_0[OF lf])
   297 next
   298   case (insert x F)
   299   have "f (setsum g (insert x F)) = f (g x + setsum g F)" using insert.hyps
   300     by simp
   301   also have "\<dots> = f (g x) + f (setsum g F)" using linear_add[OF lf] by simp
   302   also have "\<dots> = setsum (f o g) (insert x F)" using insert.hyps by simp
   303   finally show ?case .
   304 qed
   305 
   306 lemma linear_setsum_mul:
   307   assumes lf: "linear f" and fS: "finite S"
   308   shows "f (setsum (\<lambda>i. c i *\<^sub>R v i) S) = setsum (\<lambda>i. c i *\<^sub>R f (v i)) S"
   309   using linear_setsum[OF lf fS, of "\<lambda>i. c i *\<^sub>R v i" , unfolded o_def] linear_cmul[OF lf]
   310   by simp
   311 
   312 lemma linear_injective_0:
   313   assumes lf: "linear f"
   314   shows "inj f \<longleftrightarrow> (\<forall>x. f x = 0 \<longrightarrow> x = 0)"
   315 proof -
   316   have "inj f \<longleftrightarrow> (\<forall> x y. f x = f y \<longrightarrow> x = y)" by (simp add: inj_on_def)
   317   also have "\<dots> \<longleftrightarrow> (\<forall> x y. f x - f y = 0 \<longrightarrow> x - y = 0)" by simp
   318   also have "\<dots> \<longleftrightarrow> (\<forall> x y. f (x - y) = 0 \<longrightarrow> x - y = 0)"
   319     by (simp add: linear_sub[OF lf])
   320   also have "\<dots> \<longleftrightarrow> (\<forall> x. f x = 0 \<longrightarrow> x = 0)" by auto
   321   finally show ?thesis .
   322 qed
   323 
   324 
   325 subsection {* Bilinear functions. *}
   326 
   327 definition "bilinear f \<longleftrightarrow> (\<forall>x. linear(\<lambda>y. f x y)) \<and> (\<forall>y. linear(\<lambda>x. f x y))"
   328 
   329 lemma bilinear_ladd: "bilinear h ==> h (x + y) z = (h x z) + (h y z)"
   330   by (simp add: bilinear_def linear_def)
   331 
   332 lemma bilinear_radd: "bilinear h ==> h x (y + z) = (h x y) + (h x z)"
   333   by (simp add: bilinear_def linear_def)
   334 
   335 lemma bilinear_lmul: "bilinear h ==> h (c *\<^sub>R x) y = c *\<^sub>R (h x y)"
   336   by (simp add: bilinear_def linear_def)
   337 
   338 lemma bilinear_rmul: "bilinear h ==> h x (c *\<^sub>R y) = c *\<^sub>R (h x y)"
   339   by (simp add: bilinear_def linear_def)
   340 
   341 lemma bilinear_lneg: "bilinear h ==> h (- x) y = -(h x y)"
   342   by (simp only: scaleR_minus1_left [symmetric] bilinear_lmul)
   343 
   344 lemma bilinear_rneg: "bilinear h ==> h x (- y) = - h x y"
   345   by (simp only: scaleR_minus1_left [symmetric] bilinear_rmul)
   346 
   347 lemma  (in ab_group_add) eq_add_iff: "x = x + y \<longleftrightarrow> y = 0"
   348   using add_imp_eq[of x y 0] by auto
   349 
   350 lemma bilinear_lzero: assumes "bilinear h" shows "h 0 x = 0"
   351   using bilinear_ladd [OF assms, of 0 0 x] by (simp add: eq_add_iff field_simps)
   352 
   353 lemma bilinear_rzero: assumes "bilinear h" shows "h x 0 = 0"
   354   using bilinear_radd [OF assms, of x 0 0 ] by (simp add: eq_add_iff field_simps)
   355 
   356 lemma bilinear_lsub: "bilinear h ==> h (x - y) z = h x z - h y z"
   357   by (simp  add: diff_minus bilinear_ladd bilinear_lneg)
   358 
   359 lemma bilinear_rsub: "bilinear h ==> h z (x - y) = h z x - h z y"
   360   by (simp  add: diff_minus bilinear_radd bilinear_rneg)
   361 
   362 lemma bilinear_setsum:
   363   assumes bh: "bilinear h"
   364     and fS: "finite S"
   365     and fT: "finite T"
   366   shows "h (setsum f S) (setsum g T) = setsum (\<lambda>(i,j). h (f i) (g j)) (S \<times> T) "
   367 proof -
   368   have "h (setsum f S) (setsum g T) = setsum (\<lambda>x. h (f x) (setsum g T)) S"
   369     apply (rule linear_setsum[unfolded o_def])
   370     using bh fS apply (auto simp add: bilinear_def)
   371     done
   372   also have "\<dots> = setsum (\<lambda>x. setsum (\<lambda>y. h (f x) (g y)) T) S"
   373     apply (rule setsum_cong, simp)
   374     apply (rule linear_setsum[unfolded o_def])
   375     using bh fT
   376     apply (auto simp add: bilinear_def)
   377     done
   378   finally show ?thesis unfolding setsum_cartesian_product .
   379 qed
   380 
   381 
   382 subsection {* Adjoints. *}
   383 
   384 definition "adjoint f = (SOME f'. \<forall>x y. f x \<bullet> y = x \<bullet> f' y)"
   385 
   386 lemma adjoint_unique:
   387   assumes "\<forall>x y. inner (f x) y = inner x (g y)"
   388   shows "adjoint f = g"
   389   unfolding adjoint_def
   390 proof (rule some_equality)
   391   show "\<forall>x y. inner (f x) y = inner x (g y)" using assms .
   392 next
   393   fix h assume "\<forall>x y. inner (f x) y = inner x (h y)"
   394   then have "\<forall>x y. inner x (g y) = inner x (h y)" using assms by simp
   395   then have "\<forall>x y. inner x (g y - h y) = 0" by (simp add: inner_diff_right)
   396   then have "\<forall>y. inner (g y - h y) (g y - h y) = 0" by simp
   397   then have "\<forall>y. h y = g y" by simp
   398   then show "h = g" by (simp add: ext)
   399 qed
   400 
   401 text {* TODO: The following lemmas about adjoints should hold for any
   402 Hilbert space (i.e. complete inner product space).
   403 (see \url{http://en.wikipedia.org/wiki/Hermitian_adjoint})
   404 *}
   405 
   406 lemma adjoint_works:
   407   fixes f:: "'n::euclidean_space \<Rightarrow> 'm::euclidean_space"
   408   assumes lf: "linear f"
   409   shows "x \<bullet> adjoint f y = f x \<bullet> y"
   410 proof -
   411   have "\<forall>y. \<exists>w. \<forall>x. f x \<bullet> y = x \<bullet> w"
   412   proof (intro allI exI)
   413     fix y :: "'m" and x
   414     let ?w = "(\<Sum>i\<in>Basis. (f i \<bullet> y) *\<^sub>R i) :: 'n"
   415     have "f x \<bullet> y = f (\<Sum>i\<in>Basis. (x \<bullet> i) *\<^sub>R i) \<bullet> y"
   416       by (simp add: euclidean_representation)
   417     also have "\<dots> = (\<Sum>i\<in>Basis. (x \<bullet> i) *\<^sub>R f i) \<bullet> y"
   418       unfolding linear_setsum[OF lf finite_Basis]
   419       by (simp add: linear_cmul[OF lf])
   420     finally show "f x \<bullet> y = x \<bullet> ?w"
   421         by (simp add: inner_setsum_left inner_setsum_right mult_commute)
   422   qed
   423   then show ?thesis
   424     unfolding adjoint_def choice_iff
   425     by (intro someI2_ex[where Q="\<lambda>f'. x \<bullet> f' y = f x \<bullet> y"]) auto
   426 qed
   427 
   428 lemma adjoint_clauses:
   429   fixes f:: "'n::euclidean_space \<Rightarrow> 'm::euclidean_space"
   430   assumes lf: "linear f"
   431   shows "x \<bullet> adjoint f y = f x \<bullet> y"
   432     and "adjoint f y \<bullet> x = y \<bullet> f x"
   433   by (simp_all add: adjoint_works[OF lf] inner_commute)
   434 
   435 lemma adjoint_linear:
   436   fixes f:: "'n::euclidean_space \<Rightarrow> 'm::euclidean_space"
   437   assumes lf: "linear f"
   438   shows "linear (adjoint f)"
   439   by (simp add: lf linear_def euclidean_eq_iff[where 'a='n] euclidean_eq_iff[where 'a='m]
   440     adjoint_clauses[OF lf] inner_simps)
   441 
   442 lemma adjoint_adjoint:
   443   fixes f:: "'n::euclidean_space \<Rightarrow> 'm::euclidean_space"
   444   assumes lf: "linear f"
   445   shows "adjoint (adjoint f) = f"
   446   by (rule adjoint_unique, simp add: adjoint_clauses [OF lf])
   447 
   448 subsection {* Interlude: Some properties of real sets *}
   449 
   450 lemma seq_mono_lemma: assumes "\<forall>(n::nat) \<ge> m. (d n :: real) < e n" and "\<forall>n \<ge> m. e n <= e m"
   451   shows "\<forall>n \<ge> m. d n < e m"
   452   using assms apply auto
   453   apply (erule_tac x="n" in allE)
   454   apply (erule_tac x="n" in allE)
   455   apply auto
   456   done
   457 
   458 
   459 lemma infinite_enumerate: assumes fS: "infinite S"
   460   shows "\<exists>r. subseq r \<and> (\<forall>n. r n \<in> S)"
   461   unfolding subseq_def
   462   using enumerate_in_set[OF fS] enumerate_mono[of _ _ S] fS by auto
   463 
   464 lemma approachable_lt_le: "(\<exists>(d::real)>0. \<forall>x. f x < d \<longrightarrow> P x) \<longleftrightarrow> (\<exists>d>0. \<forall>x. f x \<le> d \<longrightarrow> P x)"
   465   apply auto
   466   apply (rule_tac x="d/2" in exI)
   467   apply auto
   468   done
   469 
   470 
   471 lemma triangle_lemma:
   472   assumes x: "0 <= (x::real)" and y:"0 <= y" and z: "0 <= z" and xy: "x^2 <= y^2 + z^2"
   473   shows "x <= y + z"
   474 proof -
   475   have "y^2 + z^2 \<le> y^2 + 2*y*z + z^2" using z y by (simp add: mult_nonneg_nonneg)
   476   with xy have th: "x ^2 \<le> (y+z)^2" by (simp add: power2_eq_square field_simps)
   477   from y z have yz: "y + z \<ge> 0" by arith
   478   from power2_le_imp_le[OF th yz] show ?thesis .
   479 qed
   480 
   481 
   482 subsection {* A generic notion of "hull" (convex, affine, conic hull and closure). *}
   483 
   484 definition hull :: "('a set \<Rightarrow> bool) \<Rightarrow> 'a set \<Rightarrow> 'a set" (infixl "hull" 75)
   485   where "S hull s = Inter {t. S t \<and> s \<subseteq> t}"
   486 
   487 lemma hull_same: "S s \<Longrightarrow> S hull s = s"
   488   unfolding hull_def by auto
   489 
   490 lemma hull_in: "(\<And>T. Ball T S ==> S (Inter T)) ==> S (S hull s)"
   491   unfolding hull_def Ball_def by auto
   492 
   493 lemma hull_eq: "(\<And>T. Ball T S ==> S (Inter T)) ==> (S hull s) = s \<longleftrightarrow> S s"
   494   using hull_same[of S s] hull_in[of S s] by metis
   495 
   496 
   497 lemma hull_hull: "S hull (S hull s) = S hull s"
   498   unfolding hull_def by blast
   499 
   500 lemma hull_subset[intro]: "s \<subseteq> (S hull s)"
   501   unfolding hull_def by blast
   502 
   503 lemma hull_mono: " s \<subseteq> t ==> (S hull s) \<subseteq> (S hull t)"
   504   unfolding hull_def by blast
   505 
   506 lemma hull_antimono: "\<forall>x. S x \<longrightarrow> T x ==> (T hull s) \<subseteq> (S hull s)"
   507   unfolding hull_def by blast
   508 
   509 lemma hull_minimal: "s \<subseteq> t \<Longrightarrow> S t ==> (S hull s) \<subseteq> t"
   510   unfolding hull_def by blast
   511 
   512 lemma subset_hull: "S t ==> S hull s \<subseteq> t \<longleftrightarrow>  s \<subseteq> t"
   513   unfolding hull_def by blast
   514 
   515 lemma hull_unique: "s \<subseteq> t \<Longrightarrow> S t \<Longrightarrow>
   516     (\<And>t'. s \<subseteq> t' \<Longrightarrow> S t' \<Longrightarrow> t \<subseteq> t') \<Longrightarrow> (S hull s = t)"
   517   unfolding hull_def by auto
   518 
   519 lemma hull_induct: "(\<And>x. x\<in> S \<Longrightarrow> P x) \<Longrightarrow> Q {x. P x} \<Longrightarrow> \<forall>x\<in> Q hull S. P x"
   520   using hull_minimal[of S "{x. P x}" Q]
   521   by (auto simp add: subset_eq)
   522 
   523 lemma hull_inc: "x \<in> S \<Longrightarrow> x \<in> P hull S"
   524   by (metis hull_subset subset_eq)
   525 
   526 lemma hull_union_subset: "(S hull s) \<union> (S hull t) \<subseteq> (S hull (s \<union> t))"
   527   unfolding Un_subset_iff by (metis hull_mono Un_upper1 Un_upper2)
   528 
   529 lemma hull_union:
   530   assumes T: "\<And>T. Ball T S ==> S (Inter T)"
   531   shows "S hull (s \<union> t) = S hull (S hull s \<union> S hull t)"
   532   apply rule
   533   apply (rule hull_mono)
   534   unfolding Un_subset_iff
   535   apply (metis hull_subset Un_upper1 Un_upper2 subset_trans)
   536   apply (rule hull_minimal)
   537   apply (metis hull_union_subset)
   538   apply (metis hull_in T)
   539   done
   540 
   541 lemma hull_redundant_eq: "a \<in> (S hull s) \<longleftrightarrow> (S hull (insert a s) = S hull s)"
   542   unfolding hull_def by blast
   543 
   544 lemma hull_redundant: "a \<in> (S hull s) ==> (S hull (insert a s) = S hull s)"
   545   by (metis hull_redundant_eq)
   546 
   547 
   548 subsection {* Archimedean properties and useful consequences *}
   549 
   550 lemma real_arch_simple: "\<exists>n. x <= real (n::nat)"
   551   unfolding real_of_nat_def by (rule ex_le_of_nat)
   552 
   553 lemma real_arch_inv: "0 < e \<longleftrightarrow> (\<exists>n::nat. n \<noteq> 0 \<and> 0 < inverse (real n) \<and> inverse (real n) < e)"
   554   using reals_Archimedean
   555   apply (auto simp add: field_simps)
   556   apply (subgoal_tac "inverse (real n) > 0")
   557   apply arith
   558   apply simp
   559   done
   560 
   561 lemma real_pow_lbound: "0 <= x ==> 1 + real n * x <= (1 + x) ^ n"
   562 proof (induct n)
   563   case 0
   564   then show ?case by simp
   565 next
   566   case (Suc n)
   567   then have h: "1 + real n * x \<le> (1 + x) ^ n" by simp
   568   from h have p: "1 \<le> (1 + x) ^ n" using Suc.prems by simp
   569   from h have "1 + real n * x + x \<le> (1 + x) ^ n + x" by simp
   570   also have "\<dots> \<le> (1 + x) ^ Suc n" apply (subst diff_le_0_iff_le[symmetric])
   571     apply (simp add: field_simps)
   572     using mult_left_mono[OF p Suc.prems] apply simp
   573     done
   574   finally show ?case  by (simp add: real_of_nat_Suc field_simps)
   575 qed
   576 
   577 lemma real_arch_pow: assumes x: "1 < (x::real)" shows "\<exists>n. y < x^n"
   578 proof -
   579   from x have x0: "x - 1 > 0" by arith
   580   from reals_Archimedean3[OF x0, rule_format, of y]
   581   obtain n::nat where n:"y < real n * (x - 1)" by metis
   582   from x0 have x00: "x- 1 \<ge> 0" by arith
   583   from real_pow_lbound[OF x00, of n] n
   584   have "y < x^n" by auto
   585   then show ?thesis by metis
   586 qed
   587 
   588 lemma real_arch_pow2: "\<exists>n. (x::real) < 2^ n"
   589   using real_arch_pow[of 2 x] by simp
   590 
   591 lemma real_arch_pow_inv:
   592   assumes y: "(y::real) > 0" and x1: "x < 1"
   593   shows "\<exists>n. x^n < y"
   594 proof -
   595   { assume x0: "x > 0"
   596     from x0 x1 have ix: "1 < 1/x" by (simp add: field_simps)
   597     from real_arch_pow[OF ix, of "1/y"]
   598     obtain n where n: "1/y < (1/x)^n" by blast
   599     then have ?thesis using y x0
   600       by (auto simp add: field_simps power_divide) }
   601   moreover
   602   { assume "\<not> x > 0"
   603     with y x1 have ?thesis apply auto by (rule exI[where x=1], auto) }
   604   ultimately show ?thesis by metis
   605 qed
   606 
   607 lemma forall_pos_mono:
   608   "(\<And>d e::real. d < e \<Longrightarrow> P d ==> P e) \<Longrightarrow>
   609     (\<And>n::nat. n \<noteq> 0 ==> P(inverse(real n))) \<Longrightarrow> (\<And>e. 0 < e ==> P e)"
   610   by (metis real_arch_inv)
   611 
   612 lemma forall_pos_mono_1:
   613   "(\<And>d e::real. d < e \<Longrightarrow> P d ==> P e) \<Longrightarrow>
   614     (\<And>n. P(inverse(real (Suc n)))) ==> 0 < e ==> P e"
   615   apply (rule forall_pos_mono)
   616   apply auto
   617   apply (atomize)
   618   apply (erule_tac x="n - 1" in allE)
   619   apply auto
   620   done
   621 
   622 lemma real_archimedian_rdiv_eq_0:
   623   assumes x0: "x \<ge> 0" and c: "c \<ge> 0" and xc: "\<forall>(m::nat)>0. real m * x \<le> c"
   624   shows "x = 0"
   625 proof -
   626   { assume "x \<noteq> 0" with x0 have xp: "x > 0" by arith
   627     from reals_Archimedean3[OF xp, rule_format, of c]
   628     obtain n::nat where n: "c < real n * x" by blast
   629     with xc[rule_format, of n] have "n = 0" by arith
   630     with n c have False by simp }
   631   then show ?thesis by blast
   632 qed
   633 
   634 
   635 subsection{* A bit of linear algebra. *}
   636 
   637 definition (in real_vector) subspace :: "'a set \<Rightarrow> bool"
   638   where "subspace S \<longleftrightarrow> 0 \<in> S \<and> (\<forall>x\<in> S. \<forall>y \<in>S. x + y \<in> S) \<and> (\<forall>c. \<forall>x \<in>S. c *\<^sub>R x \<in>S )"
   639 
   640 definition (in real_vector) "span S = (subspace hull S)"
   641 definition (in real_vector) "dependent S \<longleftrightarrow> (\<exists>a \<in> S. a \<in> span(S - {a}))"
   642 abbreviation (in real_vector) "independent s == ~(dependent s)"
   643 
   644 text {* Closure properties of subspaces. *}
   645 
   646 lemma subspace_UNIV[simp]: "subspace(UNIV)" by (simp add: subspace_def)
   647 
   648 lemma (in real_vector) subspace_0: "subspace S ==> 0 \<in> S" by (metis subspace_def)
   649 
   650 lemma (in real_vector) subspace_add: "subspace S \<Longrightarrow> x \<in> S \<Longrightarrow> y \<in> S ==> x + y \<in> S"
   651   by (metis subspace_def)
   652 
   653 lemma (in real_vector) subspace_mul: "subspace S \<Longrightarrow> x \<in> S \<Longrightarrow> c *\<^sub>R x \<in> S"
   654   by (metis subspace_def)
   655 
   656 lemma subspace_neg: "subspace S \<Longrightarrow> x \<in> S \<Longrightarrow> - x \<in> S"
   657   by (metis scaleR_minus1_left subspace_mul)
   658 
   659 lemma subspace_sub: "subspace S \<Longrightarrow> x \<in> S \<Longrightarrow> y \<in> S \<Longrightarrow> x - y \<in> S"
   660   by (metis diff_minus subspace_add subspace_neg)
   661 
   662 lemma (in real_vector) subspace_setsum:
   663   assumes sA: "subspace A" and fB: "finite B"
   664     and f: "\<forall>x\<in> B. f x \<in> A"
   665   shows "setsum f B \<in> A"
   666   using  fB f sA
   667   by (induct rule: finite_induct[OF fB])
   668     (simp add: subspace_def sA, auto simp add: sA subspace_add)
   669 
   670 lemma subspace_linear_image:
   671   assumes lf: "linear f" and sS: "subspace S"
   672   shows "subspace(f ` S)"
   673   using lf sS linear_0[OF lf]
   674   unfolding linear_def subspace_def
   675   apply (auto simp add: image_iff)
   676   apply (rule_tac x="x + y" in bexI, auto)
   677   apply (rule_tac x="c *\<^sub>R x" in bexI, auto)
   678   done
   679 
   680 lemma subspace_linear_vimage: "linear f \<Longrightarrow> subspace S \<Longrightarrow> subspace (f -` S)"
   681   by (auto simp add: subspace_def linear_def linear_0[of f])
   682 
   683 lemma subspace_linear_preimage: "linear f ==> subspace S ==> subspace {x. f x \<in> S}"
   684   by (auto simp add: subspace_def linear_def linear_0[of f])
   685 
   686 lemma subspace_trivial: "subspace {0}"
   687   by (simp add: subspace_def)
   688 
   689 lemma (in real_vector) subspace_inter: "subspace A \<Longrightarrow> subspace B ==> subspace (A \<inter> B)"
   690   by (simp add: subspace_def)
   691 
   692 lemma subspace_Times: "\<lbrakk>subspace A; subspace B\<rbrakk> \<Longrightarrow> subspace (A \<times> B)"
   693   unfolding subspace_def zero_prod_def by simp
   694 
   695 text {* Properties of span. *}
   696 
   697 lemma (in real_vector) span_mono: "A \<subseteq> B ==> span A \<subseteq> span B"
   698   by (metis span_def hull_mono)
   699 
   700 lemma (in real_vector) subspace_span: "subspace(span S)"
   701   unfolding span_def
   702   apply (rule hull_in)
   703   apply (simp only: subspace_def Inter_iff Int_iff subset_eq)
   704   apply auto
   705   done
   706 
   707 lemma (in real_vector) span_clauses:
   708   "a \<in> S ==> a \<in> span S"
   709   "0 \<in> span S"
   710   "x\<in> span S \<Longrightarrow> y \<in> span S ==> x + y \<in> span S"
   711   "x \<in> span S \<Longrightarrow> c *\<^sub>R x \<in> span S"
   712   by (metis span_def hull_subset subset_eq)
   713      (metis subspace_span subspace_def)+
   714 
   715 lemma span_unique:
   716   "S \<subseteq> T \<Longrightarrow> subspace T \<Longrightarrow> (\<And>T'. S \<subseteq> T' \<Longrightarrow> subspace T' \<Longrightarrow> T \<subseteq> T') \<Longrightarrow> span S = T"
   717   unfolding span_def by (rule hull_unique)
   718 
   719 lemma span_minimal: "S \<subseteq> T \<Longrightarrow> subspace T \<Longrightarrow> span S \<subseteq> T"
   720   unfolding span_def by (rule hull_minimal)
   721 
   722 lemma (in real_vector) span_induct:
   723   assumes x: "x \<in> span S"
   724     and P: "subspace P"
   725     and SP: "\<And>x. x \<in> S ==> x \<in> P"
   726   shows "x \<in> P"
   727 proof -
   728   from SP have SP': "S \<subseteq> P" by (simp add: subset_eq)
   729   from x hull_minimal[where S=subspace, OF SP' P, unfolded span_def[symmetric]]
   730   show "x \<in> P" by (metis subset_eq)
   731 qed
   732 
   733 lemma span_empty[simp]: "span {} = {0}"
   734   apply (simp add: span_def)
   735   apply (rule hull_unique)
   736   apply (auto simp add: subspace_def)
   737   done
   738 
   739 lemma (in real_vector) independent_empty[intro]: "independent {}"
   740   by (simp add: dependent_def)
   741 
   742 lemma dependent_single[simp]: "dependent {x} \<longleftrightarrow> x = 0"
   743   unfolding dependent_def by auto
   744 
   745 lemma (in real_vector) independent_mono: "independent A \<Longrightarrow> B \<subseteq> A ==> independent B"
   746   apply (clarsimp simp add: dependent_def span_mono)
   747   apply (subgoal_tac "span (B - {a}) \<le> span (A - {a})")
   748   apply force
   749   apply (rule span_mono)
   750   apply auto
   751   done
   752 
   753 lemma (in real_vector) span_subspace: "A \<subseteq> B \<Longrightarrow> B \<le> span A \<Longrightarrow>  subspace B \<Longrightarrow> span A = B"
   754   by (metis order_antisym span_def hull_minimal)
   755 
   756 lemma (in real_vector) span_induct':
   757   assumes SP: "\<forall>x \<in> S. P x"
   758     and P: "subspace {x. P x}"
   759   shows "\<forall>x \<in> span S. P x"
   760   using span_induct SP P by blast
   761 
   762 inductive_set (in real_vector) span_induct_alt_help for S:: "'a set"
   763   where
   764   span_induct_alt_help_0: "0 \<in> span_induct_alt_help S"
   765 | span_induct_alt_help_S:
   766     "x \<in> S \<Longrightarrow> z \<in> span_induct_alt_help S \<Longrightarrow> (c *\<^sub>R x + z) \<in> span_induct_alt_help S"
   767 
   768 lemma span_induct_alt':
   769   assumes h0: "h 0" and hS: "\<And>c x y. x \<in> S \<Longrightarrow> h y \<Longrightarrow> h (c *\<^sub>R x + y)"
   770   shows "\<forall>x \<in> span S. h x"
   771 proof -
   772   { fix x:: "'a" assume x: "x \<in> span_induct_alt_help S"
   773     have "h x"
   774       apply (rule span_induct_alt_help.induct[OF x])
   775       apply (rule h0)
   776       apply (rule hS, assumption, assumption)
   777       done }
   778   note th0 = this
   779   { fix x assume x: "x \<in> span S"
   780     have "x \<in> span_induct_alt_help S"
   781     proof (rule span_induct[where x=x and S=S])
   782       show "x \<in> span S" using x .
   783     next
   784       fix x assume xS : "x \<in> S"
   785         from span_induct_alt_help_S[OF xS span_induct_alt_help_0, of 1]
   786         show "x \<in> span_induct_alt_help S" by simp
   787     next
   788       have "0 \<in> span_induct_alt_help S" by (rule span_induct_alt_help_0)
   789       moreover
   790       { fix x y
   791         assume h: "x \<in> span_induct_alt_help S" "y \<in> span_induct_alt_help S"
   792         from h have "(x + y) \<in> span_induct_alt_help S"
   793           apply (induct rule: span_induct_alt_help.induct)
   794           apply simp
   795           unfolding add_assoc
   796           apply (rule span_induct_alt_help_S)
   797           apply assumption
   798           apply simp
   799           done }
   800       moreover
   801       { fix c x
   802         assume xt: "x \<in> span_induct_alt_help S"
   803         then have "(c *\<^sub>R x) \<in> span_induct_alt_help S"
   804           apply (induct rule: span_induct_alt_help.induct)
   805           apply (simp add: span_induct_alt_help_0)
   806           apply (simp add: scaleR_right_distrib)
   807           apply (rule span_induct_alt_help_S)
   808           apply assumption
   809           apply simp
   810           done }
   811       ultimately
   812       show "subspace (span_induct_alt_help S)"
   813         unfolding subspace_def Ball_def by blast
   814     qed }
   815   with th0 show ?thesis by blast
   816 qed
   817 
   818 lemma span_induct_alt:
   819   assumes h0: "h 0" and hS: "\<And>c x y. x \<in> S \<Longrightarrow> h y \<Longrightarrow> h (c *\<^sub>R x + y)" and x: "x \<in> span S"
   820   shows "h x"
   821   using span_induct_alt'[of h S] h0 hS x by blast
   822 
   823 text {* Individual closure properties. *}
   824 
   825 lemma span_span: "span (span A) = span A"
   826   unfolding span_def hull_hull ..
   827 
   828 lemma (in real_vector) span_superset: "x \<in> S ==> x \<in> span S" by (metis span_clauses(1))
   829 
   830 lemma (in real_vector) span_0: "0 \<in> span S" by (metis subspace_span subspace_0)
   831 
   832 lemma span_inc: "S \<subseteq> span S"
   833   by (metis subset_eq span_superset)
   834 
   835 lemma (in real_vector) dependent_0: assumes "0\<in>A" shows "dependent A"
   836   unfolding dependent_def apply(rule_tac x=0 in bexI)
   837   using assms span_0 by auto
   838 
   839 lemma (in real_vector) span_add: "x \<in> span S \<Longrightarrow> y \<in> span S ==> x + y \<in> span S"
   840   by (metis subspace_add subspace_span)
   841 
   842 lemma (in real_vector) span_mul: "x \<in> span S ==> (c *\<^sub>R x) \<in> span S"
   843   by (metis subspace_span subspace_mul)
   844 
   845 lemma span_neg: "x \<in> span S ==> - x \<in> span S"
   846   by (metis subspace_neg subspace_span)
   847 
   848 lemma span_sub: "x \<in> span S \<Longrightarrow> y \<in> span S ==> x - y \<in> span S"
   849   by (metis subspace_span subspace_sub)
   850 
   851 lemma (in real_vector) span_setsum: "finite A \<Longrightarrow> \<forall>x \<in> A. f x \<in> span S ==> setsum f A \<in> span S"
   852   by (rule subspace_setsum, rule subspace_span)
   853 
   854 lemma span_add_eq: "x \<in> span S \<Longrightarrow> x + y \<in> span S \<longleftrightarrow> y \<in> span S"
   855   apply (auto simp only: span_add span_sub)
   856   apply (subgoal_tac "(x + y) - x \<in> span S", simp)
   857   apply (simp only: span_add span_sub)
   858   done
   859 
   860 text {* Mapping under linear image. *}
   861 
   862 lemma image_subset_iff_subset_vimage: "f ` A \<subseteq> B \<longleftrightarrow> A \<subseteq> f -` B"
   863   by auto (* TODO: move *)
   864 
   865 lemma span_linear_image:
   866   assumes lf: "linear f"
   867   shows "span (f ` S) = f ` (span S)"
   868 proof (rule span_unique)
   869   show "f ` S \<subseteq> f ` span S"
   870     by (intro image_mono span_inc)
   871   show "subspace (f ` span S)"
   872     using lf subspace_span by (rule subspace_linear_image)
   873 next
   874   fix T assume "f ` S \<subseteq> T" and "subspace T"
   875   then show "f ` span S \<subseteq> T"
   876     unfolding image_subset_iff_subset_vimage
   877     by (intro span_minimal subspace_linear_vimage lf)
   878 qed
   879 
   880 lemma span_union: "span (A \<union> B) = (\<lambda>(a, b). a + b) ` (span A \<times> span B)"
   881 proof (rule span_unique)
   882   show "A \<union> B \<subseteq> (\<lambda>(a, b). a + b) ` (span A \<times> span B)"
   883     by safe (force intro: span_clauses)+
   884 next
   885   have "linear (\<lambda>(a, b). a + b)"
   886     by (simp add: linear_def scaleR_add_right)
   887   moreover have "subspace (span A \<times> span B)"
   888     by (intro subspace_Times subspace_span)
   889   ultimately show "subspace ((\<lambda>(a, b). a + b) ` (span A \<times> span B))"
   890     by (rule subspace_linear_image)
   891 next
   892   fix T
   893   assume "A \<union> B \<subseteq> T" and "subspace T"
   894   then show "(\<lambda>(a, b). a + b) ` (span A \<times> span B) \<subseteq> T"
   895     by (auto intro!: subspace_add elim: span_induct)
   896 qed
   897 
   898 text {* The key breakdown property. *}
   899 
   900 lemma span_singleton: "span {x} = range (\<lambda>k. k *\<^sub>R x)"
   901 proof (rule span_unique)
   902   show "{x} \<subseteq> range (\<lambda>k. k *\<^sub>R x)"
   903     by (fast intro: scaleR_one [symmetric])
   904   show "subspace (range (\<lambda>k. k *\<^sub>R x))"
   905     unfolding subspace_def
   906     by (auto intro: scaleR_add_left [symmetric])
   907   fix T assume "{x} \<subseteq> T" and "subspace T" then show "range (\<lambda>k. k *\<^sub>R x) \<subseteq> T"
   908     unfolding subspace_def by auto
   909 qed
   910 
   911 lemma span_insert: "span (insert a S) = {x. \<exists>k. (x - k *\<^sub>R a) \<in> span S}"
   912 proof -
   913   have "span ({a} \<union> S) = {x. \<exists>k. (x - k *\<^sub>R a) \<in> span S}"
   914     unfolding span_union span_singleton
   915     apply safe
   916     apply (rule_tac x=k in exI, simp)
   917     apply (erule rev_image_eqI [OF SigmaI [OF rangeI]])
   918     apply simp
   919     apply (rule right_minus)
   920     done
   921   then show ?thesis by simp
   922 qed
   923 
   924 lemma span_breakdown:
   925   assumes bS: "b \<in> S" and aS: "a \<in> span S"
   926   shows "\<exists>k. a - k *\<^sub>R b \<in> span (S - {b})"
   927   using assms span_insert [of b "S - {b}"]
   928   by (simp add: insert_absorb)
   929 
   930 lemma span_breakdown_eq: "x \<in> span (insert a S) \<longleftrightarrow> (\<exists>k. (x - k *\<^sub>R a) \<in> span S)"
   931   by (simp add: span_insert)
   932 
   933 text {* Hence some "reversal" results. *}
   934 
   935 lemma in_span_insert:
   936   assumes a: "a \<in> span (insert b S)"
   937     and na: "a \<notin> span S"
   938   shows "b \<in> span (insert a S)"
   939 proof -
   940   from span_breakdown[of b "insert b S" a, OF insertI1 a]
   941   obtain k where k: "a - k*\<^sub>R b \<in> span (S - {b})" by auto
   942   { assume k0: "k = 0"
   943     with k have "a \<in> span S"
   944       apply (simp)
   945       apply (rule set_rev_mp)
   946       apply assumption
   947       apply (rule span_mono)
   948       apply blast
   949       done
   950     with na  have ?thesis by blast }
   951   moreover
   952   { assume k0: "k \<noteq> 0"
   953     have eq: "b = (1/k) *\<^sub>R a - ((1/k) *\<^sub>R a - b)" by simp
   954     from k0 have eq': "(1/k) *\<^sub>R (a - k*\<^sub>R b) = (1/k) *\<^sub>R a - b"
   955       by (simp add: algebra_simps)
   956     from k have "(1/k) *\<^sub>R (a - k*\<^sub>R b) \<in> span (S - {b})"
   957       by (rule span_mul)
   958     then have th: "(1/k) *\<^sub>R a - b \<in> span (S - {b})"
   959       unfolding eq' .
   960 
   961     from k
   962     have ?thesis
   963       apply (subst eq)
   964       apply (rule span_sub)
   965       apply (rule span_mul)
   966       apply (rule span_superset)
   967       apply blast
   968       apply (rule set_rev_mp)
   969       apply (rule th)
   970       apply (rule span_mono)
   971       using na by blast }
   972   ultimately show ?thesis by blast
   973 qed
   974 
   975 lemma in_span_delete:
   976   assumes a: "a \<in> span S"
   977     and na: "a \<notin> span (S-{b})"
   978   shows "b \<in> span (insert a (S - {b}))"
   979   apply (rule in_span_insert)
   980   apply (rule set_rev_mp)
   981   apply (rule a)
   982   apply (rule span_mono)
   983   apply blast
   984   apply (rule na)
   985   done
   986 
   987 text {* Transitivity property. *}
   988 
   989 lemma span_redundant: "x \<in> span S \<Longrightarrow> span (insert x S) = span S"
   990   unfolding span_def by (rule hull_redundant)
   991 
   992 lemma span_trans:
   993   assumes x: "x \<in> span S" and y: "y \<in> span (insert x S)"
   994   shows "y \<in> span S"
   995   using assms by (simp only: span_redundant)
   996 
   997 lemma span_insert_0[simp]: "span (insert 0 S) = span S"
   998   by (simp only: span_redundant span_0)
   999 
  1000 text {* An explicit expansion is sometimes needed. *}
  1001 
  1002 lemma span_explicit:
  1003   "span P = {y. \<exists>S u. finite S \<and> S \<subseteq> P \<and> setsum (\<lambda>v. u v *\<^sub>R v) S = y}"
  1004   (is "_ = ?E" is "_ = {y. ?h y}" is "_ = {y. \<exists>S u. ?Q S u y}")
  1005 proof -
  1006   { fix x assume x: "x \<in> ?E"
  1007     then obtain S u where fS: "finite S" and SP: "S\<subseteq>P" and u: "setsum (\<lambda>v. u v *\<^sub>R v) S = x"
  1008       by blast
  1009     have "x \<in> span P"
  1010       unfolding u[symmetric]
  1011       apply (rule span_setsum[OF fS])
  1012       using span_mono[OF SP]
  1013       apply (auto intro: span_superset span_mul)
  1014       done }
  1015   moreover
  1016   have "\<forall>x \<in> span P. x \<in> ?E"
  1017   proof (rule span_induct_alt')
  1018     show "0 \<in> Collect ?h"
  1019       unfolding mem_Collect_eq
  1020       apply (rule exI[where x="{}"])
  1021       apply simp
  1022       done
  1023   next
  1024     fix c x y
  1025     assume x: "x \<in> P" and hy: "y \<in> Collect ?h"
  1026     from hy obtain S u where fS: "finite S" and SP: "S\<subseteq>P"
  1027       and u: "setsum (\<lambda>v. u v *\<^sub>R v) S = y" by blast
  1028     let ?S = "insert x S"
  1029     let ?u = "\<lambda>y. if y = x then (if x \<in> S then u y + c else c) else u y"
  1030     from fS SP x have th0: "finite (insert x S)" "insert x S \<subseteq> P" by blast+
  1031     { assume xS: "x \<in> S"
  1032       have S1: "S = (S - {x}) \<union> {x}"
  1033         and Sss:"finite (S - {x})" "finite {x}" "(S -{x}) \<inter> {x} = {}" using xS fS by auto
  1034       have "setsum (\<lambda>v. ?u v *\<^sub>R v) ?S =(\<Sum>v\<in>S - {x}. u v *\<^sub>R v) + (u x + c) *\<^sub>R x"
  1035         using xS
  1036         by (simp add: setsum_Un_disjoint[OF Sss, unfolded S1[symmetric]]
  1037           setsum_clauses(2)[OF fS] cong del: if_weak_cong)
  1038       also have "\<dots> = (\<Sum>v\<in>S. u v *\<^sub>R v) + c *\<^sub>R x"
  1039         apply (simp add: setsum_Un_disjoint[OF Sss, unfolded S1[symmetric]])
  1040         apply (simp add: algebra_simps)
  1041         done
  1042       also have "\<dots> = c*\<^sub>R x + y"
  1043         by (simp add: add_commute u)
  1044       finally have "setsum (\<lambda>v. ?u v *\<^sub>R v) ?S = c*\<^sub>R x + y" .
  1045     then have "?Q ?S ?u (c*\<^sub>R x + y)" using th0 by blast }
  1046     moreover
  1047     { assume xS: "x \<notin> S"
  1048       have th00: "(\<Sum>v\<in>S. (if v = x then c else u v) *\<^sub>R v) = y"
  1049         unfolding u[symmetric]
  1050         apply (rule setsum_cong2)
  1051         using xS apply auto
  1052         done
  1053       have "?Q ?S ?u (c*\<^sub>R x + y)" using fS xS th0
  1054         by (simp add: th00 setsum_clauses add_commute cong del: if_weak_cong) }
  1055     ultimately have "?Q ?S ?u (c*\<^sub>R x + y)" by (cases "x \<in> S") simp_all
  1056     then show "(c*\<^sub>R x + y) \<in> Collect ?h"
  1057       unfolding mem_Collect_eq
  1058       apply -
  1059       apply (rule exI[where x="?S"])
  1060       apply (rule exI[where x="?u"])
  1061       apply metis
  1062       done
  1063   qed
  1064   ultimately show ?thesis by blast
  1065 qed
  1066 
  1067 lemma dependent_explicit:
  1068   "dependent P \<longleftrightarrow> (\<exists>S u. finite S \<and> S \<subseteq> P \<and> (\<exists>v\<in>S. u v \<noteq> 0 \<and> setsum (\<lambda>v. u v *\<^sub>R v) S = 0))"
  1069   (is "?lhs = ?rhs")
  1070 proof -
  1071   { assume dP: "dependent P"
  1072     then obtain a S u where aP: "a \<in> P" and fS: "finite S"
  1073       and SP: "S \<subseteq> P - {a}" and ua: "setsum (\<lambda>v. u v *\<^sub>R v) S = a"
  1074       unfolding dependent_def span_explicit by blast
  1075     let ?S = "insert a S"
  1076     let ?u = "\<lambda>y. if y = a then - 1 else u y"
  1077     let ?v = a
  1078     from aP SP have aS: "a \<notin> S" by blast
  1079     from fS SP aP have th0: "finite ?S" "?S \<subseteq> P" "?v \<in> ?S" "?u ?v \<noteq> 0" by auto
  1080     have s0: "setsum (\<lambda>v. ?u v *\<^sub>R v) ?S = 0"
  1081       using fS aS
  1082       apply (simp add: setsum_clauses field_simps)
  1083       apply (subst (2) ua[symmetric])
  1084       apply (rule setsum_cong2)
  1085       apply auto
  1086       done
  1087     with th0 have ?rhs
  1088       apply -
  1089       apply (rule exI[where x= "?S"])
  1090       apply (rule exI[where x= "?u"])
  1091       apply auto
  1092       done
  1093   }
  1094   moreover
  1095   { fix S u v
  1096     assume fS: "finite S"
  1097       and SP: "S \<subseteq> P" and vS: "v \<in> S" and uv: "u v \<noteq> 0"
  1098       and u: "setsum (\<lambda>v. u v *\<^sub>R v) S = 0"
  1099     let ?a = v
  1100     let ?S = "S - {v}"
  1101     let ?u = "\<lambda>i. (- u i) / u v"
  1102     have th0: "?a \<in> P" "finite ?S" "?S \<subseteq> P" using fS SP vS by auto
  1103     have "setsum (\<lambda>v. ?u v *\<^sub>R v) ?S = setsum (\<lambda>v. (- (inverse (u ?a))) *\<^sub>R (u v *\<^sub>R v)) S - ?u v *\<^sub>R v"
  1104       using fS vS uv by (simp add: setsum_diff1 divide_inverse field_simps)
  1105     also have "\<dots> = ?a" unfolding scaleR_right.setsum [symmetric] u using uv by simp
  1106     finally  have "setsum (\<lambda>v. ?u v *\<^sub>R v) ?S = ?a" .
  1107     with th0 have ?lhs
  1108       unfolding dependent_def span_explicit
  1109       apply -
  1110       apply (rule bexI[where x= "?a"])
  1111       apply (simp_all del: scaleR_minus_left)
  1112       apply (rule exI[where x= "?S"])
  1113       apply (auto simp del: scaleR_minus_left)
  1114       done
  1115   }
  1116   ultimately show ?thesis by blast
  1117 qed
  1118 
  1119 
  1120 lemma span_finite:
  1121   assumes fS: "finite S"
  1122   shows "span S = {y. \<exists>u. setsum (\<lambda>v. u v *\<^sub>R v) S = y}"
  1123   (is "_ = ?rhs")
  1124 proof -
  1125   { fix y
  1126     assume y: "y \<in> span S"
  1127     from y obtain S' u where fS': "finite S'" and SS': "S' \<subseteq> S" and
  1128       u: "setsum (\<lambda>v. u v *\<^sub>R v) S' = y" unfolding span_explicit by blast
  1129     let ?u = "\<lambda>x. if x \<in> S' then u x else 0"
  1130     have "setsum (\<lambda>v. ?u v *\<^sub>R v) S = setsum (\<lambda>v. u v *\<^sub>R v) S'"
  1131       using SS' fS by (auto intro!: setsum_mono_zero_cong_right)
  1132     then have "setsum (\<lambda>v. ?u v *\<^sub>R v) S = y" by (metis u)
  1133     then have "y \<in> ?rhs" by auto }
  1134   moreover
  1135   { fix y u
  1136     assume u: "setsum (\<lambda>v. u v *\<^sub>R v) S = y"
  1137     then have "y \<in> span S" using fS unfolding span_explicit by auto }
  1138   ultimately show ?thesis by blast
  1139 qed
  1140 
  1141 text {* This is useful for building a basis step-by-step. *}
  1142 
  1143 lemma independent_insert:
  1144   "independent(insert a S) \<longleftrightarrow>
  1145       (if a \<in> S then independent S
  1146                 else independent S \<and> a \<notin> span S)" (is "?lhs \<longleftrightarrow> ?rhs")
  1147 proof -
  1148   { assume aS: "a \<in> S"
  1149     then have ?thesis using insert_absorb[OF aS] by simp }
  1150   moreover
  1151   { assume aS: "a \<notin> S"
  1152     { assume i: ?lhs
  1153       then have ?rhs using aS
  1154         apply simp
  1155         apply (rule conjI)
  1156         apply (rule independent_mono)
  1157         apply assumption
  1158         apply blast
  1159         apply (simp add: dependent_def)
  1160         done }
  1161     moreover
  1162     { assume i: ?rhs
  1163       have ?lhs using i aS
  1164         apply simp
  1165         apply (auto simp add: dependent_def)
  1166         apply (case_tac "aa = a", auto)
  1167         apply (subgoal_tac "insert a S - {aa} = insert a (S - {aa})")
  1168         apply simp
  1169         apply (subgoal_tac "a \<in> span (insert aa (S - {aa}))")
  1170         apply (subgoal_tac "insert aa (S - {aa}) = S")
  1171         apply simp
  1172         apply blast
  1173         apply (rule in_span_insert)
  1174         apply assumption
  1175         apply blast
  1176         apply blast
  1177         done }
  1178     ultimately have ?thesis by blast }
  1179   ultimately show ?thesis by blast
  1180 qed
  1181 
  1182 text {* The degenerate case of the Exchange Lemma. *}
  1183 
  1184 lemma mem_delete: "x \<in> (A - {a}) \<longleftrightarrow> x \<noteq> a \<and> x \<in> A"
  1185   by blast
  1186 
  1187 lemma spanning_subset_independent:
  1188   assumes BA: "B \<subseteq> A"
  1189     and iA: "independent A"
  1190     and AsB: "A \<subseteq> span B"
  1191   shows "A = B"
  1192 proof
  1193   show "B \<subseteq> A" by (rule BA)
  1194 
  1195   from span_mono[OF BA] span_mono[OF AsB]
  1196   have sAB: "span A = span B" unfolding span_span by blast
  1197 
  1198   { fix x assume x: "x \<in> A"
  1199     from iA have th0: "x \<notin> span (A - {x})"
  1200       unfolding dependent_def using x by blast
  1201     from x have xsA: "x \<in> span A" by (blast intro: span_superset)
  1202     have "A - {x} \<subseteq> A" by blast
  1203     then have th1:"span (A - {x}) \<subseteq> span A" by (metis span_mono)
  1204     { assume xB: "x \<notin> B"
  1205       from xB BA have "B \<subseteq> A -{x}" by blast
  1206       then have "span B \<subseteq> span (A - {x})" by (metis span_mono)
  1207       with th1 th0 sAB have "x \<notin> span A" by blast
  1208       with x have False by (metis span_superset) }
  1209     then have "x \<in> B" by blast }
  1210   then show "A \<subseteq> B" by blast
  1211 qed
  1212 
  1213 text {* The general case of the Exchange Lemma, the key to what follows. *}
  1214 
  1215 lemma exchange_lemma:
  1216   assumes f:"finite t"
  1217     and i: "independent s"
  1218     and sp: "s \<subseteq> span t"
  1219   shows "\<exists>t'. (card t' = card t) \<and> finite t' \<and> s \<subseteq> t' \<and> t' \<subseteq> s \<union> t \<and> s \<subseteq> span t'"
  1220   using f i sp
  1221 proof (induct "card (t - s)" arbitrary: s t rule: less_induct)
  1222   case less
  1223   note ft = `finite t` and s = `independent s` and sp = `s \<subseteq> span t`
  1224   let ?P = "\<lambda>t'. (card t' = card t) \<and> finite t' \<and> s \<subseteq> t' \<and> t' \<subseteq> s \<union> t \<and> s \<subseteq> span t'"
  1225   let ?ths = "\<exists>t'. ?P t'"
  1226   { assume st: "s \<subseteq> t"
  1227     from st ft span_mono[OF st] have ?ths apply - apply (rule exI[where x=t])
  1228       apply (auto intro: span_superset)
  1229       done }
  1230   moreover
  1231   { assume st: "t \<subseteq> s"
  1232     from spanning_subset_independent[OF st s sp]
  1233       st ft span_mono[OF st] have ?ths
  1234         apply -
  1235         apply (rule exI[where x=t])
  1236         apply (auto intro: span_superset)
  1237         done }
  1238   moreover
  1239   { assume st: "\<not> s \<subseteq> t" "\<not> t \<subseteq> s"
  1240     from st(2) obtain b where b: "b \<in> t" "b \<notin> s" by blast
  1241       from b have "t - {b} - s \<subset> t - s" by blast
  1242       then have cardlt: "card (t - {b} - s) < card (t - s)" using ft
  1243         by (auto intro: psubset_card_mono)
  1244       from b ft have ct0: "card t \<noteq> 0" by auto
  1245     { assume stb: "s \<subseteq> span(t -{b})"
  1246       from ft have ftb: "finite (t -{b})" by auto
  1247       from less(1)[OF cardlt ftb s stb]
  1248       obtain u where u: "card u = card (t-{b})" "s \<subseteq> u" "u \<subseteq> s \<union> (t - {b})" "s \<subseteq> span u"
  1249         and fu: "finite u" by blast
  1250       let ?w = "insert b u"
  1251       have th0: "s \<subseteq> insert b u" using u by blast
  1252       from u(3) b have "u \<subseteq> s \<union> t" by blast
  1253       then have th1: "insert b u \<subseteq> s \<union> t" using u b by blast
  1254       have bu: "b \<notin> u" using b u by blast
  1255       from u(1) ft b have "card u = (card t - 1)" by auto
  1256       then have th2: "card (insert b u) = card t"
  1257         using card_insert_disjoint[OF fu bu] ct0 by auto
  1258       from u(4) have "s \<subseteq> span u" .
  1259       also have "\<dots> \<subseteq> span (insert b u)" apply (rule span_mono) by blast
  1260       finally have th3: "s \<subseteq> span (insert b u)" .
  1261       from th0 th1 th2 th3 fu have th: "?P ?w"  by blast
  1262       from th have ?ths by blast }
  1263     moreover
  1264     { assume stb: "\<not> s \<subseteq> span(t -{b})"
  1265       from stb obtain a where a: "a \<in> s" "a \<notin> span (t - {b})" by blast
  1266       have ab: "a \<noteq> b" using a b by blast
  1267       have at: "a \<notin> t" using a ab span_superset[of a "t- {b}"] by auto
  1268       have mlt: "card ((insert a (t - {b})) - s) < card (t - s)"
  1269         using cardlt ft a b by auto
  1270       have ft': "finite (insert a (t - {b}))" using ft by auto
  1271       { fix x assume xs: "x \<in> s"
  1272         have t: "t \<subseteq> (insert b (insert a (t -{b})))" using b by auto
  1273         from b(1) have "b \<in> span t" by (simp add: span_superset)
  1274         have bs: "b \<in> span (insert a (t - {b}))" apply(rule in_span_delete)
  1275           using a sp unfolding subset_eq apply auto done
  1276         from xs sp have "x \<in> span t" by blast
  1277         with span_mono[OF t]
  1278         have x: "x \<in> span (insert b (insert a (t - {b})))" ..
  1279         from span_trans[OF bs x] have "x \<in> span (insert a (t - {b}))" . }
  1280       then have sp': "s \<subseteq> span (insert a (t - {b}))" by blast
  1281 
  1282       from less(1)[OF mlt ft' s sp'] obtain u where
  1283         u: "card u = card (insert a (t -{b}))" "finite u" "s \<subseteq> u" "u \<subseteq> s \<union> insert a (t -{b})"
  1284           "s \<subseteq> span u" by blast
  1285       from u a b ft at ct0 have "?P u" by auto
  1286       then have ?ths by blast }
  1287     ultimately have ?ths by blast
  1288   }
  1289   ultimately show ?ths by blast
  1290 qed
  1291 
  1292 text {* This implies corresponding size bounds. *}
  1293 
  1294 lemma independent_span_bound:
  1295   assumes f: "finite t" and i: "independent s" and sp:"s \<subseteq> span t"
  1296   shows "finite s \<and> card s \<le> card t"
  1297   by (metis exchange_lemma[OF f i sp] finite_subset card_mono)
  1298 
  1299 
  1300 lemma finite_Atleast_Atmost_nat[simp]: "finite {f x |x. x\<in> (UNIV::'a::finite set)}"
  1301 proof -
  1302   have eq: "{f x |x. x\<in> UNIV} = f ` UNIV" by auto
  1303   show ?thesis unfolding eq
  1304     apply (rule finite_imageI)
  1305     apply (rule finite)
  1306     done
  1307 qed
  1308 
  1309 subsection{* Euclidean Spaces as Typeclass*}
  1310 
  1311 lemma independent_Basis: "independent Basis"
  1312   unfolding dependent_def
  1313   apply (subst span_finite)
  1314   apply simp
  1315   apply clarify
  1316   apply (drule_tac f="inner a" in arg_cong)
  1317   apply (simp add: inner_Basis inner_setsum_right eq_commute)
  1318   done
  1319 
  1320 lemma span_Basis[simp]: "span Basis = (UNIV :: 'a::euclidean_space set)"
  1321   apply (subst span_finite)
  1322   apply simp
  1323   apply (safe intro!: UNIV_I)
  1324   apply (rule_tac x="inner x" in exI)
  1325   apply (simp add: euclidean_representation)
  1326   done
  1327 
  1328 lemma in_span_Basis: "x \<in> span Basis"
  1329   unfolding span_Basis ..
  1330 
  1331 lemma Basis_le_norm: "b \<in> Basis \<Longrightarrow> \<bar>x \<bullet> b\<bar> \<le> norm x"
  1332   by (rule order_trans [OF Cauchy_Schwarz_ineq2]) simp
  1333 
  1334 lemma norm_bound_Basis_le: "b \<in> Basis \<Longrightarrow> norm x \<le> e \<Longrightarrow> \<bar>x \<bullet> b\<bar> \<le> e"
  1335   by (metis Basis_le_norm order_trans)
  1336 
  1337 lemma norm_bound_Basis_lt: "b \<in> Basis \<Longrightarrow> norm x < e \<Longrightarrow> \<bar>x \<bullet> b\<bar> < e"
  1338   by (metis Basis_le_norm basic_trans_rules(21))
  1339 
  1340 lemma norm_le_l1: "norm x \<le> (\<Sum>b\<in>Basis. \<bar>x \<bullet> b\<bar>)"
  1341   apply (subst euclidean_representation[of x, symmetric])
  1342   apply (rule order_trans[OF norm_setsum])
  1343   apply (auto intro!: setsum_mono)
  1344   done
  1345 
  1346 lemma setsum_norm_allsubsets_bound:
  1347   fixes f:: "'a \<Rightarrow> 'n::euclidean_space"
  1348   assumes fP: "finite P" and fPs: "\<And>Q. Q \<subseteq> P \<Longrightarrow> norm (setsum f Q) \<le> e"
  1349   shows "(\<Sum>x\<in>P. norm (f x)) \<le> 2 * real DIM('n) * e"
  1350 proof -
  1351   have "(\<Sum>x\<in>P. norm (f x)) \<le> (\<Sum>x\<in>P. \<Sum>b\<in>Basis. \<bar>f x \<bullet> b\<bar>)"
  1352     by (rule setsum_mono) (rule norm_le_l1)
  1353   also have "(\<Sum>x\<in>P. \<Sum>b\<in>Basis. \<bar>f x \<bullet> b\<bar>) = (\<Sum>b\<in>Basis. \<Sum>x\<in>P. \<bar>f x \<bullet> b\<bar>)"
  1354     by (rule setsum_commute)
  1355   also have "\<dots> \<le> of_nat (card (Basis :: 'n set)) * (2 * e)"
  1356   proof (rule setsum_bounded)
  1357     fix i :: 'n assume i: "i \<in> Basis"
  1358     have "norm (\<Sum>x\<in>P. \<bar>f x \<bullet> i\<bar>) \<le> 
  1359       norm ((\<Sum>x\<in>P \<inter> - {x. f x \<bullet> i < 0}. f x) \<bullet> i) + norm ((\<Sum>x\<in>P \<inter> {x. f x \<bullet> i < 0}. f x) \<bullet> i)"
  1360       by (simp add: abs_real_def setsum_cases[OF fP] setsum_negf uminus_add_conv_diff
  1361                     norm_triangle_ineq4 inner_setsum_left
  1362           del: real_norm_def)
  1363     also have "\<dots> \<le> e + e" unfolding real_norm_def
  1364       by (intro add_mono norm_bound_Basis_le i fPs) auto
  1365     finally show "(\<Sum>x\<in>P. \<bar>f x \<bullet> i\<bar>) \<le> 2*e" by simp
  1366   qed
  1367   also have "\<dots> = 2 * real DIM('n) * e"
  1368     by (simp add: real_of_nat_def)
  1369   finally show ?thesis .
  1370 qed
  1371 
  1372 subsection {* Linearity and Bilinearity continued *}
  1373 
  1374 lemma linear_bounded:
  1375   fixes f:: "'a::euclidean_space \<Rightarrow> 'b::real_normed_vector"
  1376   assumes lf: "linear f"
  1377   shows "\<exists>B. \<forall>x. norm (f x) \<le> B * norm x"
  1378 proof -
  1379   let ?B = "\<Sum>b\<in>Basis. norm (f b)"
  1380   { fix x:: "'a"
  1381     let ?g = "\<lambda>b. (x \<bullet> b) *\<^sub>R f b"
  1382     have "norm (f x) = norm (f (\<Sum>b\<in>Basis. (x \<bullet> b) *\<^sub>R b))"
  1383       unfolding euclidean_representation ..
  1384     also have "\<dots> = norm (setsum ?g Basis)"
  1385       using linear_setsum[OF lf finite_Basis, of "\<lambda>b. (x \<bullet> b) *\<^sub>R b", unfolded o_def] linear_cmul[OF lf] by auto
  1386     finally have th0: "norm (f x) = norm (setsum ?g Basis)" .
  1387     { fix i :: 'a assume i: "i \<in> Basis"
  1388       from Basis_le_norm[OF i, of x]
  1389       have "norm (?g i) \<le> norm (f i) * norm x"
  1390         unfolding norm_scaleR
  1391         apply (subst mult_commute)
  1392         apply (rule mult_mono)
  1393         apply (auto simp add: field_simps)
  1394         done }
  1395     then have th: "\<forall>b\<in>Basis. norm (?g b) \<le> norm (f b) * norm x"
  1396       by metis
  1397     from setsum_norm_le[of _ ?g, OF th]
  1398     have "norm (f x) \<le> ?B * norm x" unfolding th0 setsum_left_distrib by metis}
  1399   then show ?thesis by blast
  1400 qed
  1401 
  1402 lemma linear_bounded_pos:
  1403   fixes f:: "'a::euclidean_space \<Rightarrow> 'b::real_normed_vector"
  1404   assumes lf: "linear f"
  1405   shows "\<exists>B > 0. \<forall>x. norm (f x) \<le> B * norm x"
  1406 proof -
  1407   from linear_bounded[OF lf] obtain B where
  1408     B: "\<forall>x. norm (f x) \<le> B * norm x" by blast
  1409   let ?K = "\<bar>B\<bar> + 1"
  1410   have Kp: "?K > 0" by arith
  1411   { assume C: "B < 0"
  1412     def One \<equiv> "\<Sum>Basis ::'a"
  1413     then have "One \<noteq> 0"
  1414       unfolding euclidean_eq_iff[where 'a='a]
  1415       by (simp add: inner_setsum_left inner_Basis setsum_cases)
  1416     then have "norm One > 0" by auto
  1417     with C have "B * norm One < 0"
  1418       by (simp add: mult_less_0_iff)
  1419     with B[rule_format, of One] norm_ge_zero[of "f One"]
  1420     have False by simp
  1421   }
  1422   then have Bp: "B \<ge> 0" by (metis not_leE)
  1423   { fix x::"'a"
  1424     have "norm (f x) \<le> ?K *  norm x"
  1425       using B[rule_format, of x] norm_ge_zero[of x] norm_ge_zero[of "f x"] Bp
  1426       apply (auto simp add: field_simps split add: abs_split)
  1427       apply (erule order_trans, simp)
  1428       done
  1429   } then show ?thesis using Kp by blast
  1430 qed
  1431 
  1432 lemma linear_conv_bounded_linear:
  1433   fixes f :: "'a::euclidean_space \<Rightarrow> 'b::real_normed_vector"
  1434   shows "linear f \<longleftrightarrow> bounded_linear f"
  1435 proof
  1436   assume "linear f"
  1437   show "bounded_linear f"
  1438   proof
  1439     fix x y show "f (x + y) = f x + f y"
  1440       using `linear f` unfolding linear_def by simp
  1441   next
  1442     fix r x show "f (scaleR r x) = scaleR r (f x)"
  1443       using `linear f` unfolding linear_def by simp
  1444   next
  1445     have "\<exists>B. \<forall>x. norm (f x) \<le> B * norm x"
  1446       using `linear f` by (rule linear_bounded)
  1447     then show "\<exists>K. \<forall>x. norm (f x) \<le> norm x * K"
  1448       by (simp add: mult_commute)
  1449   qed
  1450 next
  1451   assume "bounded_linear f"
  1452   then interpret f: bounded_linear f .
  1453   show "linear f"
  1454     by (simp add: f.add f.scaleR linear_def)
  1455 qed
  1456 
  1457 lemma bounded_linearI':
  1458   fixes f::"'a::euclidean_space \<Rightarrow> 'b::real_normed_vector"
  1459   assumes "\<And>x y. f (x + y) = f x + f y" "\<And>c x. f (c *\<^sub>R x) = c *\<^sub>R f x"
  1460   shows "bounded_linear f"
  1461   unfolding linear_conv_bounded_linear[THEN sym]
  1462   by (rule linearI[OF assms])
  1463 
  1464 
  1465 lemma bilinear_bounded:
  1466   fixes h:: "'m::euclidean_space \<Rightarrow> 'n::euclidean_space \<Rightarrow> 'k::real_normed_vector"
  1467   assumes bh: "bilinear h"
  1468   shows "\<exists>B. \<forall>x y. norm (h x y) \<le> B * norm x * norm y"
  1469 proof (clarify intro!: exI[of _ "\<Sum>i\<in>Basis. \<Sum>j\<in>Basis. norm (h i j)"])
  1470   fix x:: "'m" and  y :: "'n"
  1471   have "norm (h x y) = norm (h (setsum (\<lambda>i. (x \<bullet> i) *\<^sub>R i) Basis) (setsum (\<lambda>i. (y \<bullet> i) *\<^sub>R i) Basis))" 
  1472     apply(subst euclidean_representation[where 'a='m])
  1473     apply(subst euclidean_representation[where 'a='n])
  1474     apply rule
  1475     done
  1476   also have "\<dots> = norm (setsum (\<lambda> (i,j). h ((x \<bullet> i) *\<^sub>R i) ((y \<bullet> j) *\<^sub>R j)) (Basis \<times> Basis))"  
  1477     unfolding bilinear_setsum[OF bh finite_Basis finite_Basis] ..
  1478   finally have th: "norm (h x y) = \<dots>" .
  1479   show "norm (h x y) \<le> (\<Sum>i\<in>Basis. \<Sum>j\<in>Basis. norm (h i j)) * norm x * norm y"
  1480       apply (auto simp add: setsum_left_distrib th setsum_cartesian_product)
  1481       apply (rule setsum_norm_le)
  1482       apply simp
  1483       apply (auto simp add: bilinear_rmul[OF bh] bilinear_lmul[OF bh]
  1484         field_simps simp del: scaleR_scaleR)
  1485       apply (rule mult_mono)
  1486       apply (auto simp add: zero_le_mult_iff Basis_le_norm)
  1487       apply (rule mult_mono)
  1488       apply (auto simp add: zero_le_mult_iff Basis_le_norm)
  1489       done
  1490 qed
  1491 
  1492 lemma bilinear_bounded_pos:
  1493   fixes h:: "'a::euclidean_space \<Rightarrow> 'b::euclidean_space \<Rightarrow> 'c::real_normed_vector"
  1494   assumes bh: "bilinear h"
  1495   shows "\<exists>B > 0. \<forall>x y. norm (h x y) \<le> B * norm x * norm y"
  1496 proof -
  1497   from bilinear_bounded[OF bh] obtain B where
  1498     B: "\<forall>x y. norm (h x y) \<le> B * norm x * norm y" by blast
  1499   let ?K = "\<bar>B\<bar> + 1"
  1500   have Kp: "?K > 0" by arith
  1501   have KB: "B < ?K" by arith
  1502   { fix x::'a and y::'b
  1503     from KB Kp
  1504     have "B * norm x * norm y \<le> ?K * norm x * norm y"
  1505       apply -
  1506       apply (rule mult_right_mono, rule mult_right_mono)
  1507       apply auto
  1508       done
  1509     then have "norm (h x y) \<le> ?K * norm x * norm y"
  1510       using B[rule_format, of x y] by simp }
  1511   with Kp show ?thesis by blast
  1512 qed
  1513 
  1514 lemma bilinear_conv_bounded_bilinear:
  1515   fixes h :: "'a::euclidean_space \<Rightarrow> 'b::euclidean_space \<Rightarrow> 'c::real_normed_vector"
  1516   shows "bilinear h \<longleftrightarrow> bounded_bilinear h"
  1517 proof
  1518   assume "bilinear h"
  1519   show "bounded_bilinear h"
  1520   proof
  1521     fix x y z show "h (x + y) z = h x z + h y z"
  1522       using `bilinear h` unfolding bilinear_def linear_def by simp
  1523   next
  1524     fix x y z show "h x (y + z) = h x y + h x z"
  1525       using `bilinear h` unfolding bilinear_def linear_def by simp
  1526   next
  1527     fix r x y show "h (scaleR r x) y = scaleR r (h x y)"
  1528       using `bilinear h` unfolding bilinear_def linear_def
  1529       by simp
  1530   next
  1531     fix r x y show "h x (scaleR r y) = scaleR r (h x y)"
  1532       using `bilinear h` unfolding bilinear_def linear_def
  1533       by simp
  1534   next
  1535     have "\<exists>B. \<forall>x y. norm (h x y) \<le> B * norm x * norm y"
  1536       using `bilinear h` by (rule bilinear_bounded)
  1537     then show "\<exists>K. \<forall>x y. norm (h x y) \<le> norm x * norm y * K"
  1538       by (simp add: mult_ac)
  1539   qed
  1540 next
  1541   assume "bounded_bilinear h"
  1542   then interpret h: bounded_bilinear h .
  1543   show "bilinear h"
  1544     unfolding bilinear_def linear_conv_bounded_linear
  1545     using h.bounded_linear_left h.bounded_linear_right by simp
  1546 qed
  1547 
  1548 
  1549 subsection {* We continue. *}
  1550 
  1551 lemma independent_bound:
  1552   fixes S:: "('a::euclidean_space) set"
  1553   shows "independent S \<Longrightarrow> finite S \<and> card S \<le> DIM('a::euclidean_space)"
  1554   using independent_span_bound[OF finite_Basis, of S] by auto
  1555 
  1556 lemma dependent_biggerset:
  1557   "(finite (S::('a::euclidean_space) set) ==> card S > DIM('a)) ==> dependent S"
  1558   by (metis independent_bound not_less)
  1559 
  1560 text {* Hence we can create a maximal independent subset. *}
  1561 
  1562 lemma maximal_independent_subset_extend:
  1563   assumes sv: "(S::('a::euclidean_space) set) \<subseteq> V"
  1564     and iS: "independent S"
  1565   shows "\<exists>B. S \<subseteq> B \<and> B \<subseteq> V \<and> independent B \<and> V \<subseteq> span B"
  1566   using sv iS
  1567 proof (induct "DIM('a) - card S" arbitrary: S rule: less_induct)
  1568   case less
  1569   note sv = `S \<subseteq> V` and i = `independent S`
  1570   let ?P = "\<lambda>B. S \<subseteq> B \<and> B \<subseteq> V \<and> independent B \<and> V \<subseteq> span B"
  1571   let ?ths = "\<exists>x. ?P x"
  1572   let ?d = "DIM('a)"
  1573   { assume "V \<subseteq> span S"
  1574     then have ?ths  using sv i by blast }
  1575   moreover
  1576   { assume VS: "\<not> V \<subseteq> span S"
  1577     from VS obtain a where a: "a \<in> V" "a \<notin> span S" by blast
  1578     from a have aS: "a \<notin> S" by (auto simp add: span_superset)
  1579     have th0: "insert a S \<subseteq> V" using a sv by blast
  1580     from independent_insert[of a S]  i a
  1581     have th1: "independent (insert a S)" by auto
  1582     have mlt: "?d - card (insert a S) < ?d - card S"
  1583       using aS a independent_bound[OF th1] by auto
  1584 
  1585     from less(1)[OF mlt th0 th1]
  1586     obtain B where B: "insert a S \<subseteq> B" "B \<subseteq> V" "independent B" " V \<subseteq> span B"
  1587       by blast
  1588     from B have "?P B" by auto
  1589     then have ?ths by blast }
  1590   ultimately show ?ths by blast
  1591 qed
  1592 
  1593 lemma maximal_independent_subset:
  1594   "\<exists>(B:: ('a::euclidean_space) set). B\<subseteq> V \<and> independent B \<and> V \<subseteq> span B"
  1595   by (metis maximal_independent_subset_extend[of "{}:: ('a::euclidean_space) set"]
  1596     empty_subsetI independent_empty)
  1597 
  1598 
  1599 text {* Notion of dimension. *}
  1600 
  1601 definition "dim V = (SOME n. \<exists>B. B \<subseteq> V \<and> independent B \<and> V \<subseteq> span B \<and> (card B = n))"
  1602 
  1603 lemma basis_exists:
  1604   "\<exists>B. (B :: ('a::euclidean_space) set) \<subseteq> V \<and> independent B \<and> V \<subseteq> span B \<and> (card B = dim V)"
  1605   unfolding dim_def some_eq_ex[of "\<lambda>n. \<exists>B. B \<subseteq> V \<and> independent B \<and> V \<subseteq> span B \<and> (card B = n)"]
  1606   using maximal_independent_subset[of V] independent_bound
  1607   by auto
  1608 
  1609 text {* Consequences of independence or spanning for cardinality. *}
  1610 
  1611 lemma independent_card_le_dim: 
  1612   assumes "(B::('a::euclidean_space) set) \<subseteq> V" and "independent B"
  1613   shows "card B \<le> dim V"
  1614 proof -
  1615   from basis_exists[of V] `B \<subseteq> V`
  1616   obtain B' where "independent B'" and "B \<subseteq> span B'" and "card B' = dim V" by blast
  1617   with independent_span_bound[OF _ `independent B` `B \<subseteq> span B'`] independent_bound[of B']
  1618   show ?thesis by auto
  1619 qed
  1620 
  1621 lemma span_card_ge_dim:
  1622   "(B::('a::euclidean_space) set) \<subseteq> V \<Longrightarrow> V \<subseteq> span B \<Longrightarrow> finite B \<Longrightarrow> dim V \<le> card B"
  1623   by (metis basis_exists[of V] independent_span_bound subset_trans)
  1624 
  1625 lemma basis_card_eq_dim:
  1626   "B \<subseteq> (V:: ('a::euclidean_space) set) \<Longrightarrow> V \<subseteq> span B \<Longrightarrow>
  1627     independent B \<Longrightarrow> finite B \<and> card B = dim V"
  1628   by (metis order_eq_iff independent_card_le_dim span_card_ge_dim independent_bound)
  1629 
  1630 lemma dim_unique: "(B::('a::euclidean_space) set) \<subseteq> V \<Longrightarrow> V \<subseteq> span B \<Longrightarrow>
  1631     independent B \<Longrightarrow> card B = n \<Longrightarrow> dim V = n"
  1632   by (metis basis_card_eq_dim)
  1633 
  1634 text {* More lemmas about dimension. *}
  1635 
  1636 lemma dim_UNIV: "dim (UNIV :: ('a::euclidean_space) set) = DIM('a)"
  1637   using independent_Basis
  1638   by (intro dim_unique[of Basis]) auto
  1639 
  1640 lemma dim_subset:
  1641   "(S:: ('a::euclidean_space) set) \<subseteq> T \<Longrightarrow> dim S \<le> dim T"
  1642   using basis_exists[of T] basis_exists[of S]
  1643   by (metis independent_card_le_dim subset_trans)
  1644 
  1645 lemma dim_subset_UNIV: "dim (S:: ('a::euclidean_space) set) \<le> DIM('a)"
  1646   by (metis dim_subset subset_UNIV dim_UNIV)
  1647 
  1648 text {* Converses to those. *}
  1649 
  1650 lemma card_ge_dim_independent:
  1651   assumes BV:"(B::('a::euclidean_space) set) \<subseteq> V"
  1652     and iB:"independent B" and dVB:"dim V \<le> card B"
  1653   shows "V \<subseteq> span B"
  1654 proof -
  1655   { fix a assume aV: "a \<in> V"
  1656     { assume aB: "a \<notin> span B"
  1657       then have iaB: "independent (insert a B)" using iB aV  BV by (simp add: independent_insert)
  1658       from aV BV have th0: "insert a B \<subseteq> V" by blast
  1659       from aB have "a \<notin>B" by (auto simp add: span_superset)
  1660       with independent_card_le_dim[OF th0 iaB] dVB independent_bound[OF iB] have False by auto }
  1661     then have "a \<in> span B"  by blast }
  1662   then show ?thesis by blast
  1663 qed
  1664 
  1665 lemma card_le_dim_spanning:
  1666   assumes BV: "(B:: ('a::euclidean_space) set) \<subseteq> V"
  1667     and VB: "V \<subseteq> span B"
  1668     and fB: "finite B"
  1669     and dVB: "dim V \<ge> card B"
  1670   shows "independent B"
  1671 proof -
  1672   { fix a assume a: "a \<in> B" "a \<in> span (B -{a})"
  1673     from a fB have c0: "card B \<noteq> 0" by auto
  1674     from a fB have cb: "card (B -{a}) = card B - 1" by auto
  1675     from BV a have th0: "B -{a} \<subseteq> V" by blast
  1676     { fix x assume x: "x \<in> V"
  1677       from a have eq: "insert a (B -{a}) = B" by blast
  1678       from x VB have x': "x \<in> span B" by blast
  1679       from span_trans[OF a(2), unfolded eq, OF x']
  1680       have "x \<in> span (B -{a})" . }
  1681     then have th1: "V \<subseteq> span (B -{a})" by blast
  1682     have th2: "finite (B -{a})" using fB by auto
  1683     from span_card_ge_dim[OF th0 th1 th2]
  1684     have c: "dim V \<le> card (B -{a})" .
  1685     from c c0 dVB cb have False by simp }
  1686   then show ?thesis unfolding dependent_def by blast
  1687 qed
  1688 
  1689 lemma card_eq_dim: "(B:: ('a::euclidean_space) set) \<subseteq> V \<Longrightarrow>
  1690     card B = dim V \<Longrightarrow> finite B \<Longrightarrow> independent B \<longleftrightarrow> V \<subseteq> span B"
  1691   by (metis order_eq_iff card_le_dim_spanning card_ge_dim_independent)
  1692 
  1693 text {* More general size bound lemmas. *}
  1694 
  1695 lemma independent_bound_general:
  1696   "independent (S:: ('a::euclidean_space) set) \<Longrightarrow> finite S \<and> card S \<le> dim S"
  1697   by (metis independent_card_le_dim independent_bound subset_refl)
  1698 
  1699 lemma dependent_biggerset_general:
  1700     "(finite (S:: ('a::euclidean_space) set) \<Longrightarrow> card S > dim S) \<Longrightarrow> dependent S"
  1701   using independent_bound_general[of S] by (metis linorder_not_le)
  1702 
  1703 lemma dim_span: "dim (span (S:: ('a::euclidean_space) set)) = dim S"
  1704 proof -
  1705   have th0: "dim S \<le> dim (span S)"
  1706     by (auto simp add: subset_eq intro: dim_subset span_superset)
  1707   from basis_exists[of S]
  1708   obtain B where B: "B \<subseteq> S" "independent B" "S \<subseteq> span B" "card B = dim S" by blast
  1709   from B have fB: "finite B" "card B = dim S" using independent_bound by blast+
  1710   have bSS: "B \<subseteq> span S" using B(1) by (metis subset_eq span_inc)
  1711   have sssB: "span S \<subseteq> span B" using span_mono[OF B(3)] by (simp add: span_span)
  1712   from span_card_ge_dim[OF bSS sssB fB(1)] th0 show ?thesis
  1713     using fB(2) by arith
  1714 qed
  1715 
  1716 lemma subset_le_dim: "(S:: ('a::euclidean_space) set) \<subseteq> span T \<Longrightarrow> dim S \<le> dim T"
  1717   by (metis dim_span dim_subset)
  1718 
  1719 lemma span_eq_dim: "span (S:: ('a::euclidean_space) set) = span T ==> dim S = dim T"
  1720   by (metis dim_span)
  1721 
  1722 lemma spans_image:
  1723   assumes lf: "linear f"
  1724     and VB: "V \<subseteq> span B"
  1725   shows "f ` V \<subseteq> span (f ` B)"
  1726   unfolding span_linear_image[OF lf] by (metis VB image_mono)
  1727 
  1728 lemma dim_image_le:
  1729   fixes f :: "'a::euclidean_space \<Rightarrow> 'b::euclidean_space"
  1730   assumes lf: "linear f"
  1731   shows "dim (f ` S) \<le> dim (S)"
  1732 proof -
  1733   from basis_exists[of S] obtain B where
  1734     B: "B \<subseteq> S" "independent B" "S \<subseteq> span B" "card B = dim S" by blast
  1735   from B have fB: "finite B" "card B = dim S" using independent_bound by blast+
  1736   have "dim (f ` S) \<le> card (f ` B)"
  1737     apply (rule span_card_ge_dim)
  1738     using lf B fB apply (auto simp add: span_linear_image spans_image subset_image_iff)
  1739     done
  1740   also have "\<dots> \<le> dim S" using card_image_le[OF fB(1)] fB by simp
  1741   finally show ?thesis .
  1742 qed
  1743 
  1744 text {* Relation between bases and injectivity/surjectivity of map. *}
  1745 
  1746 lemma spanning_surjective_image:
  1747   assumes us: "UNIV \<subseteq> span S"
  1748     and lf: "linear f" and sf: "surj f"
  1749   shows "UNIV \<subseteq> span (f ` S)"
  1750 proof -
  1751   have "UNIV \<subseteq> f ` UNIV" using sf by (auto simp add: surj_def)
  1752   also have " \<dots> \<subseteq> span (f ` S)" using spans_image[OF lf us] .
  1753 finally show ?thesis .
  1754 qed
  1755 
  1756 lemma independent_injective_image:
  1757   assumes iS: "independent S"
  1758     and lf: "linear f"
  1759     and fi: "inj f"
  1760   shows "independent (f ` S)"
  1761 proof -
  1762   { fix a
  1763     assume a: "a \<in> S" "f a \<in> span (f ` S - {f a})"
  1764     have eq: "f ` S - {f a} = f ` (S - {a})" using fi
  1765       by (auto simp add: inj_on_def)
  1766     from a have "f a \<in> f ` span (S -{a})"
  1767       unfolding eq span_linear_image[OF lf, of "S - {a}"]  by blast
  1768     then have "a \<in> span (S -{a})" using fi by (auto simp add: inj_on_def)
  1769     with a(1) iS  have False by (simp add: dependent_def) }
  1770   then show ?thesis unfolding dependent_def by blast
  1771 qed
  1772 
  1773 text {* Picking an orthogonal replacement for a spanning set. *}
  1774 
  1775     (* FIXME : Move to some general theory ?*)
  1776 definition "pairwise R S \<longleftrightarrow> (\<forall>x \<in> S. \<forall>y\<in> S. x\<noteq>y \<longrightarrow> R x y)"
  1777 
  1778 lemma vector_sub_project_orthogonal: "(b::'a::euclidean_space) \<bullet> (x - ((b \<bullet> x) / (b \<bullet> b)) *\<^sub>R b) = 0"
  1779   unfolding inner_simps by auto
  1780 
  1781 lemma pairwise_orthogonal_insert:
  1782   assumes "pairwise orthogonal S"
  1783     and "\<And>y. y \<in> S \<Longrightarrow> orthogonal x y"
  1784   shows "pairwise orthogonal (insert x S)"
  1785   using assms unfolding pairwise_def
  1786   by (auto simp add: orthogonal_commute)
  1787 
  1788 lemma basis_orthogonal:
  1789   fixes B :: "('a::real_inner) set"
  1790   assumes fB: "finite B"
  1791   shows "\<exists>C. finite C \<and> card C \<le> card B \<and> span C = span B \<and> pairwise orthogonal C"
  1792   (is " \<exists>C. ?P B C")
  1793   using fB
  1794 proof (induct rule: finite_induct)
  1795   case empty
  1796   then show ?case apply (rule exI[where x="{}"]) by (auto simp add: pairwise_def)
  1797 next
  1798   case (insert a B)
  1799   note fB = `finite B` and aB = `a \<notin> B`
  1800   from `\<exists>C. finite C \<and> card C \<le> card B \<and> span C = span B \<and> pairwise orthogonal C`
  1801   obtain C where C: "finite C" "card C \<le> card B"
  1802     "span C = span B" "pairwise orthogonal C" by blast
  1803   let ?a = "a - setsum (\<lambda>x. (x \<bullet> a / (x \<bullet> x)) *\<^sub>R x) C"
  1804   let ?C = "insert ?a C"
  1805   from C(1) have fC: "finite ?C" by simp
  1806   from fB aB C(1,2) have cC: "card ?C \<le> card (insert a B)"
  1807     by (simp add: card_insert_if)
  1808   { fix x k
  1809     have th0: "\<And>(a::'a) b c. a - (b - c) = c + (a - b)"
  1810       by (simp add: field_simps)
  1811     have "x - k *\<^sub>R (a - (\<Sum>x\<in>C. (x \<bullet> a / (x \<bullet> x)) *\<^sub>R x)) \<in> span C \<longleftrightarrow> x - k *\<^sub>R a \<in> span C"
  1812       apply (simp only: scaleR_right_diff_distrib th0)
  1813       apply (rule span_add_eq)
  1814       apply (rule span_mul)
  1815       apply (rule span_setsum[OF C(1)])
  1816       apply clarify
  1817       apply (rule span_mul)
  1818       apply (rule span_superset)
  1819       apply assumption
  1820       done }
  1821   then have SC: "span ?C = span (insert a B)"
  1822     unfolding set_eq_iff span_breakdown_eq C(3)[symmetric] by auto
  1823   { fix y assume yC: "y \<in> C"
  1824     then have Cy: "C = insert y (C - {y})" by blast
  1825     have fth: "finite (C - {y})" using C by simp
  1826     have "orthogonal ?a y"
  1827       unfolding orthogonal_def
  1828       unfolding inner_diff inner_setsum_left diff_eq_0_iff_eq
  1829       unfolding setsum_diff1' [OF `finite C` `y \<in> C`]
  1830       apply (clarsimp simp add: inner_commute[of y a])
  1831       apply (rule setsum_0')
  1832       apply clarsimp
  1833       apply (rule C(4)[unfolded pairwise_def orthogonal_def, rule_format])
  1834       using `y \<in> C` by auto }
  1835   with `pairwise orthogonal C` have CPO: "pairwise orthogonal ?C"
  1836     by (rule pairwise_orthogonal_insert)
  1837   from fC cC SC CPO have "?P (insert a B) ?C" by blast
  1838   then show ?case by blast
  1839 qed
  1840 
  1841 lemma orthogonal_basis_exists:
  1842   fixes V :: "('a::euclidean_space) set"
  1843   shows "\<exists>B. independent B \<and> B \<subseteq> span V \<and> V \<subseteq> span B \<and> (card B = dim V) \<and> pairwise orthogonal B"
  1844 proof -
  1845   from basis_exists[of V] obtain B where
  1846     B: "B \<subseteq> V" "independent B" "V \<subseteq> span B" "card B = dim V" by blast
  1847   from B have fB: "finite B" "card B = dim V" using independent_bound by auto
  1848   from basis_orthogonal[OF fB(1)] obtain C where
  1849     C: "finite C" "card C \<le> card B" "span C = span B" "pairwise orthogonal C" by blast
  1850   from C B have CSV: "C \<subseteq> span V" by (metis span_inc span_mono subset_trans)
  1851   from span_mono[OF B(3)]  C have SVC: "span V \<subseteq> span C" by (simp add: span_span)
  1852   from card_le_dim_spanning[OF CSV SVC C(1)] C(2,3) fB
  1853   have iC: "independent C" by (simp add: dim_span)
  1854   from C fB have "card C \<le> dim V" by simp
  1855   moreover have "dim V \<le> card C" using span_card_ge_dim[OF CSV SVC C(1)]
  1856     by (simp add: dim_span)
  1857   ultimately have CdV: "card C = dim V" using C(1) by simp
  1858   from C B CSV CdV iC show ?thesis by auto
  1859 qed
  1860 
  1861 lemma span_eq: "span S = span T \<longleftrightarrow> S \<subseteq> span T \<and> T \<subseteq> span S"
  1862   using span_inc[unfolded subset_eq] using span_mono[of T "span S"] span_mono[of S "span T"]
  1863   by (auto simp add: span_span)
  1864 
  1865 text {* Low-dimensional subset is in a hyperplane (weak orthogonal complement). *}
  1866 
  1867 lemma span_not_univ_orthogonal:
  1868   fixes S::"('a::euclidean_space) set"
  1869   assumes sU: "span S \<noteq> UNIV"
  1870   shows "\<exists>(a::'a). a \<noteq>0 \<and> (\<forall>x \<in> span S. a \<bullet> x = 0)"
  1871 proof -
  1872   from sU obtain a where a: "a \<notin> span S" by blast
  1873   from orthogonal_basis_exists obtain B where
  1874     B: "independent B" "B \<subseteq> span S" "S \<subseteq> span B" "card B = dim S" "pairwise orthogonal B"
  1875     by blast
  1876   from B have fB: "finite B" "card B = dim S" using independent_bound by auto
  1877   from span_mono[OF B(2)] span_mono[OF B(3)]
  1878   have sSB: "span S = span B" by (simp add: span_span)
  1879   let ?a = "a - setsum (\<lambda>b. (a \<bullet> b / (b \<bullet> b)) *\<^sub>R b) B"
  1880   have "setsum (\<lambda>b. (a \<bullet> b / (b \<bullet> b)) *\<^sub>R b) B \<in> span S"
  1881     unfolding sSB
  1882     apply (rule span_setsum[OF fB(1)])
  1883     apply clarsimp
  1884     apply (rule span_mul)
  1885     apply (rule span_superset)
  1886     apply assumption
  1887     done
  1888   with a have a0:"?a  \<noteq> 0" by auto
  1889   have "\<forall>x\<in>span B. ?a \<bullet> x = 0"
  1890   proof (rule span_induct')
  1891     show "subspace {x. ?a \<bullet> x = 0}"
  1892       by (auto simp add: subspace_def inner_add)
  1893   next
  1894     { fix x assume x: "x \<in> B"
  1895       from x have B': "B = insert x (B - {x})" by blast
  1896       have fth: "finite (B - {x})" using fB by simp
  1897       have "?a \<bullet> x = 0"
  1898         apply (subst B') using fB fth
  1899         unfolding setsum_clauses(2)[OF fth]
  1900         apply simp unfolding inner_simps
  1901         apply (clarsimp simp add: inner_add inner_setsum_left)
  1902         apply (rule setsum_0', rule ballI)
  1903         unfolding inner_commute
  1904         apply (auto simp add: x field_simps
  1905           intro: B(5)[unfolded pairwise_def orthogonal_def, rule_format])
  1906         done }
  1907     then show "\<forall>x \<in> B. ?a \<bullet> x = 0" by blast
  1908   qed
  1909   with a0 show ?thesis unfolding sSB by (auto intro: exI[where x="?a"])
  1910 qed
  1911 
  1912 lemma span_not_univ_subset_hyperplane:
  1913   assumes SU: "span S \<noteq> (UNIV ::('a::euclidean_space) set)"
  1914   shows "\<exists> a. a \<noteq>0 \<and> span S \<subseteq> {x. a \<bullet> x = 0}"
  1915   using span_not_univ_orthogonal[OF SU] by auto
  1916 
  1917 lemma lowdim_subset_hyperplane:
  1918   fixes S::"('a::euclidean_space) set"
  1919   assumes d: "dim S < DIM('a)"
  1920   shows "\<exists>(a::'a). a  \<noteq> 0 \<and> span S \<subseteq> {x. a \<bullet> x = 0}"
  1921 proof -
  1922   { assume "span S = UNIV"
  1923     then have "dim (span S) = dim (UNIV :: ('a) set)" by simp
  1924     then have "dim S = DIM('a)" by (simp add: dim_span dim_UNIV)
  1925     with d have False by arith }
  1926   then have th: "span S \<noteq> UNIV" by blast
  1927   from span_not_univ_subset_hyperplane[OF th] show ?thesis .
  1928 qed
  1929 
  1930 text {* We can extend a linear basis-basis injection to the whole set. *}
  1931 
  1932 lemma linear_indep_image_lemma:
  1933   assumes lf: "linear f"
  1934     and fB: "finite B"
  1935     and ifB: "independent (f ` B)"
  1936     and fi: "inj_on f B"
  1937     and xsB: "x \<in> span B"
  1938     and fx: "f x = 0"
  1939   shows "x = 0"
  1940   using fB ifB fi xsB fx
  1941 proof (induct arbitrary: x rule: finite_induct[OF fB])
  1942   case 1
  1943   then show ?case by auto
  1944 next
  1945   case (2 a b x)
  1946   have fb: "finite b" using "2.prems" by simp
  1947   have th0: "f ` b \<subseteq> f ` (insert a b)"
  1948     apply (rule image_mono) by blast
  1949   from independent_mono[ OF "2.prems"(2) th0]
  1950   have ifb: "independent (f ` b)"  .
  1951   have fib: "inj_on f b"
  1952     apply (rule subset_inj_on [OF "2.prems"(3)])
  1953     apply blast
  1954     done
  1955   from span_breakdown[of a "insert a b", simplified, OF "2.prems"(4)]
  1956   obtain k where k: "x - k*\<^sub>R a \<in> span (b -{a})" by blast
  1957   have "f (x - k*\<^sub>R a) \<in> span (f ` b)"
  1958     unfolding span_linear_image[OF lf]
  1959     apply (rule imageI)
  1960     using k span_mono[of "b-{a}" b] apply blast
  1961     done
  1962   then have "f x - k*\<^sub>R f a \<in> span (f ` b)"
  1963     by (simp add: linear_sub[OF lf] linear_cmul[OF lf])
  1964   then have th: "-k *\<^sub>R f a \<in> span (f ` b)"
  1965     using "2.prems"(5) by simp
  1966   { assume k0: "k = 0"
  1967     from k0 k have "x \<in> span (b -{a})" by simp
  1968     then have "x \<in> span b" using span_mono[of "b-{a}" b]
  1969       by blast }
  1970   moreover
  1971   { assume k0: "k \<noteq> 0"
  1972     from span_mul[OF th, of "- 1/ k"] k0
  1973     have th1: "f a \<in> span (f ` b)"
  1974       by auto
  1975     from inj_on_image_set_diff[OF "2.prems"(3), of "insert a b " "{a}", symmetric]
  1976     have tha: "f ` insert a b - f ` {a} = f ` (insert a b - {a})" by blast
  1977     from "2.prems"(2) [unfolded dependent_def bex_simps(8), rule_format, of "f a"]
  1978     have "f a \<notin> span (f ` b)" using tha
  1979       using "2.hyps"(2)
  1980       "2.prems"(3) by auto
  1981     with th1 have False by blast
  1982     then have "x \<in> span b" by blast }
  1983   ultimately have xsb: "x \<in> span b" by blast
  1984   from "2.hyps"(3)[OF fb ifb fib xsb "2.prems"(5)]
  1985   show "x = 0" .
  1986 qed
  1987 
  1988 text {* We can extend a linear mapping from basis. *}
  1989 
  1990 lemma linear_independent_extend_lemma:
  1991   fixes f :: "'a::real_vector \<Rightarrow> 'b::real_vector"
  1992   assumes fi: "finite B" and ib: "independent B"
  1993   shows "\<exists>g. (\<forall>x\<in> span B. \<forall>y\<in> span B. g (x + y) = g x + g y)
  1994            \<and> (\<forall>x\<in> span B. \<forall>c. g (c*\<^sub>R x) = c *\<^sub>R g x)
  1995            \<and> (\<forall>x\<in> B. g x = f x)"
  1996   using ib fi
  1997 proof (induct rule: finite_induct[OF fi])
  1998   case 1
  1999   then show ?case by auto
  2000 next
  2001   case (2 a b)
  2002   from "2.prems" "2.hyps" have ibf: "independent b" "finite b"
  2003     by (simp_all add: independent_insert)
  2004   from "2.hyps"(3)[OF ibf] obtain g where
  2005     g: "\<forall>x\<in>span b. \<forall>y\<in>span b. g (x + y) = g x + g y"
  2006     "\<forall>x\<in>span b. \<forall>c. g (c *\<^sub>R x) = c *\<^sub>R g x" "\<forall>x\<in>b. g x = f x" by blast
  2007   let ?h = "\<lambda>z. SOME k. (z - k *\<^sub>R a) \<in> span b"
  2008   { fix z assume z: "z \<in> span (insert a b)"
  2009     have th0: "z - ?h z *\<^sub>R a \<in> span b"
  2010       apply (rule someI_ex)
  2011       unfolding span_breakdown_eq[symmetric]
  2012       using z .
  2013     { fix k assume k: "z - k *\<^sub>R a \<in> span b"
  2014       have eq: "z - ?h z *\<^sub>R a - (z - k*\<^sub>R a) = (k - ?h z) *\<^sub>R a"
  2015         by (simp add: field_simps scaleR_left_distrib [symmetric])
  2016       from span_sub[OF th0 k]
  2017       have khz: "(k - ?h z) *\<^sub>R a \<in> span b" by (simp add: eq)
  2018       { assume "k \<noteq> ?h z" then have k0: "k - ?h z \<noteq> 0" by simp
  2019         from k0 span_mul[OF khz, of "1 /(k - ?h z)"]
  2020         have "a \<in> span b" by simp
  2021         with "2.prems"(1) "2.hyps"(2) have False
  2022           by (auto simp add: dependent_def)}
  2023       then have "k = ?h z" by blast}
  2024     with th0 have "z - ?h z *\<^sub>R a \<in> span b \<and> (\<forall>k. z - k *\<^sub>R a \<in> span b \<longrightarrow> k = ?h z)" by blast}
  2025   note h = this
  2026   let ?g = "\<lambda>z. ?h z *\<^sub>R f a + g (z - ?h z *\<^sub>R a)"
  2027   { fix x y assume x: "x \<in> span (insert a b)" and y: "y \<in> span (insert a b)"
  2028     have tha: "\<And>(x::'a) y a k l. (x + y) - (k + l) *\<^sub>R a = (x - k *\<^sub>R a) + (y - l *\<^sub>R a)"
  2029       by (simp add: algebra_simps)
  2030     have addh: "?h (x + y) = ?h x + ?h y"
  2031       apply (rule conjunct2[OF h, rule_format, symmetric])
  2032       apply (rule span_add[OF x y])
  2033       unfolding tha
  2034       by (metis span_add x y conjunct1[OF h, rule_format])
  2035     have "?g (x + y) = ?g x + ?g y"
  2036       unfolding addh tha
  2037       g(1)[rule_format,OF conjunct1[OF h, OF x] conjunct1[OF h, OF y]]
  2038       by (simp add: scaleR_left_distrib)}
  2039   moreover
  2040   { fix x:: "'a" and c:: real
  2041     assume x: "x \<in> span (insert a b)"
  2042     have tha: "\<And>(x::'a) c k a. c *\<^sub>R x - (c * k) *\<^sub>R a = c *\<^sub>R (x - k *\<^sub>R a)"
  2043       by (simp add: algebra_simps)
  2044     have hc: "?h (c *\<^sub>R x) = c * ?h x"
  2045       apply (rule conjunct2[OF h, rule_format, symmetric])
  2046       apply (metis span_mul x)
  2047       apply (metis tha span_mul x conjunct1[OF h])
  2048       done
  2049     have "?g (c *\<^sub>R x) = c*\<^sub>R ?g x"
  2050       unfolding hc tha g(2)[rule_format, OF conjunct1[OF h, OF x]]
  2051       by (simp add: algebra_simps) }
  2052   moreover
  2053   { fix x assume x: "x \<in> (insert a b)"
  2054     { assume xa: "x = a"
  2055       have ha1: "1 = ?h a"
  2056         apply (rule conjunct2[OF h, rule_format])
  2057         apply (metis span_superset insertI1)
  2058         using conjunct1[OF h, OF span_superset, OF insertI1]
  2059         apply (auto simp add: span_0)
  2060         done
  2061 
  2062       from xa ha1[symmetric] have "?g x = f x"
  2063         apply simp
  2064         using g(2)[rule_format, OF span_0, of 0]
  2065         apply simp
  2066         done }
  2067     moreover
  2068     { assume xb: "x \<in> b"
  2069       have h0: "0 = ?h x"
  2070         apply (rule conjunct2[OF h, rule_format])
  2071         apply (metis  span_superset x)
  2072         apply simp
  2073         apply (metis span_superset xb)
  2074         done
  2075       have "?g x = f x"
  2076         by (simp add: h0[symmetric] g(3)[rule_format, OF xb]) }
  2077     ultimately have "?g x = f x" using x by blast }
  2078   ultimately show ?case
  2079     apply -
  2080     apply (rule exI[where x="?g"])
  2081     apply blast
  2082     done
  2083 qed
  2084 
  2085 lemma linear_independent_extend:
  2086   assumes iB: "independent (B:: ('a::euclidean_space) set)"
  2087   shows "\<exists>g. linear g \<and> (\<forall>x\<in>B. g x = f x)"
  2088 proof -
  2089   from maximal_independent_subset_extend[of B UNIV] iB
  2090   obtain C where C: "B \<subseteq> C" "independent C" "\<And>x. x \<in> span C" by auto
  2091 
  2092   from C(2) independent_bound[of C] linear_independent_extend_lemma[of C f]
  2093   obtain g where g: "(\<forall>x\<in> span C. \<forall>y\<in> span C. g (x + y) = g x + g y)
  2094            \<and> (\<forall>x\<in> span C. \<forall>c. g (c*\<^sub>R x) = c *\<^sub>R g x)
  2095            \<and> (\<forall>x\<in> C. g x = f x)" by blast
  2096   from g show ?thesis unfolding linear_def using C
  2097     apply clarsimp
  2098     apply blast
  2099     done
  2100 qed
  2101 
  2102 text {* Can construct an isomorphism between spaces of same dimension. *}
  2103 
  2104 lemma card_le_inj:
  2105   assumes fA: "finite A"
  2106     and fB: "finite B"
  2107     and c: "card A \<le> card B"
  2108   shows "\<exists>f. f ` A \<subseteq> B \<and> inj_on f A"
  2109   using fA fB c
  2110 proof (induct arbitrary: B rule: finite_induct)
  2111   case empty
  2112   then show ?case by simp
  2113 next
  2114   case (insert x s t)
  2115   then show ?case
  2116   proof (induct rule: finite_induct[OF "insert.prems"(1)])
  2117     case 1
  2118     then show ?case by simp
  2119   next
  2120     case (2 y t)
  2121     from "2.prems"(1,2,5) "2.hyps"(1,2) have cst:"card s \<le> card t" by simp
  2122     from "2.prems"(3) [OF "2.hyps"(1) cst] obtain f where
  2123       f: "f ` s \<subseteq> t \<and> inj_on f s" by blast
  2124     from f "2.prems"(2) "2.hyps"(2) show ?case
  2125       apply -
  2126       apply (rule exI[where x = "\<lambda>z. if z = x then y else f z"])
  2127       apply (auto simp add: inj_on_def)
  2128       done
  2129   qed
  2130 qed
  2131 
  2132 lemma card_subset_eq:
  2133   assumes fB: "finite B"
  2134     and AB: "A \<subseteq> B"
  2135     and c: "card A = card B"
  2136   shows "A = B"
  2137 proof -
  2138   from fB AB have fA: "finite A" by (auto intro: finite_subset)
  2139   from fA fB have fBA: "finite (B - A)" by auto
  2140   have e: "A \<inter> (B - A) = {}" by blast
  2141   have eq: "A \<union> (B - A) = B" using AB by blast
  2142   from card_Un_disjoint[OF fA fBA e, unfolded eq c]
  2143   have "card (B - A) = 0" by arith
  2144   then have "B - A = {}" unfolding card_eq_0_iff using fA fB by simp
  2145   with AB show "A = B" by blast
  2146 qed
  2147 
  2148 lemma subspace_isomorphism:
  2149   assumes s: "subspace (S:: ('a::euclidean_space) set)"
  2150     and t: "subspace (T :: ('b::euclidean_space) set)"
  2151     and d: "dim S = dim T"
  2152   shows "\<exists>f. linear f \<and> f ` S = T \<and> inj_on f S"
  2153 proof -
  2154   from basis_exists[of S] independent_bound obtain B where
  2155     B: "B \<subseteq> S" "independent B" "S \<subseteq> span B" "card B = dim S" and fB: "finite B" by blast
  2156   from basis_exists[of T] independent_bound obtain C where
  2157     C: "C \<subseteq> T" "independent C" "T \<subseteq> span C" "card C = dim T" and fC: "finite C" by blast
  2158   from B(4) C(4) card_le_inj[of B C] d obtain f where
  2159     f: "f ` B \<subseteq> C" "inj_on f B" using `finite B` `finite C` by auto
  2160   from linear_independent_extend[OF B(2)] obtain g where
  2161     g: "linear g" "\<forall>x\<in> B. g x = f x" by blast
  2162   from inj_on_iff_eq_card[OF fB, of f] f(2)
  2163   have "card (f ` B) = card B" by simp
  2164   with B(4) C(4) have ceq: "card (f ` B) = card C" using d
  2165     by simp
  2166   have "g ` B = f ` B" using g(2)
  2167     by (auto simp add: image_iff)
  2168   also have "\<dots> = C" using card_subset_eq[OF fC f(1) ceq] .
  2169   finally have gBC: "g ` B = C" .
  2170   have gi: "inj_on g B" using f(2) g(2)
  2171     by (auto simp add: inj_on_def)
  2172   note g0 = linear_indep_image_lemma[OF g(1) fB, unfolded gBC, OF C(2) gi]
  2173   { fix x y assume x: "x \<in> S" and y: "y \<in> S" and gxy: "g x = g y"
  2174     from B(3) x y have x': "x \<in> span B" and y': "y \<in> span B" by blast+
  2175     from gxy have th0: "g (x - y) = 0" by (simp add: linear_sub[OF g(1)])
  2176     have th1: "x - y \<in> span B" using x' y' by (metis span_sub)
  2177     have "x=y" using g0[OF th1 th0] by simp }
  2178   then have giS: "inj_on g S"
  2179     unfolding inj_on_def by blast
  2180   from span_subspace[OF B(1,3) s]
  2181   have "g ` S = span (g ` B)" by (simp add: span_linear_image[OF g(1)])
  2182   also have "\<dots> = span C" unfolding gBC ..
  2183   also have "\<dots> = T" using span_subspace[OF C(1,3) t] .
  2184   finally have gS: "g ` S = T" .
  2185   from g(1) gS giS show ?thesis by blast
  2186 qed
  2187 
  2188 text {* Linear functions are equal on a subspace if they are on a spanning set. *}
  2189 
  2190 lemma subspace_kernel:
  2191   assumes lf: "linear f"
  2192   shows "subspace {x. f x = 0}"
  2193   apply (simp add: subspace_def)
  2194   apply (simp add: linear_add[OF lf] linear_cmul[OF lf] linear_0[OF lf])
  2195   done
  2196 
  2197 lemma linear_eq_0_span:
  2198   assumes lf: "linear f" and f0: "\<forall>x\<in>B. f x = 0"
  2199   shows "\<forall>x \<in> span B. f x = 0"
  2200   using f0 subspace_kernel[OF lf]
  2201   by (rule span_induct')
  2202 
  2203 lemma linear_eq_0:
  2204   assumes lf: "linear f"
  2205     and SB: "S \<subseteq> span B"
  2206     and f0: "\<forall>x\<in>B. f x = 0"
  2207   shows "\<forall>x \<in> S. f x = 0"
  2208   by (metis linear_eq_0_span[OF lf] subset_eq SB f0)
  2209 
  2210 lemma linear_eq:
  2211   assumes lf: "linear f"
  2212     and lg: "linear g"
  2213     and S: "S \<subseteq> span B"
  2214     and fg: "\<forall> x\<in> B. f x = g x"
  2215   shows "\<forall>x\<in> S. f x = g x"
  2216 proof -
  2217   let ?h = "\<lambda>x. f x - g x"
  2218   from fg have fg': "\<forall>x\<in> B. ?h x = 0" by simp
  2219   from linear_eq_0[OF linear_compose_sub[OF lf lg] S fg']
  2220   show ?thesis by simp
  2221 qed
  2222 
  2223 lemma linear_eq_stdbasis:
  2224   assumes lf: "linear (f::'a::euclidean_space \<Rightarrow> _)"
  2225     and lg: "linear g"
  2226     and fg: "\<forall>b\<in>Basis. f b = g b"
  2227   shows "f = g"
  2228   using linear_eq[OF lf lg, of _ Basis] fg by auto
  2229 
  2230 text {* Similar results for bilinear functions. *}
  2231 
  2232 lemma bilinear_eq:
  2233   assumes bf: "bilinear f"
  2234     and bg: "bilinear g"
  2235     and SB: "S \<subseteq> span B" and TC: "T \<subseteq> span C"
  2236     and fg: "\<forall>x\<in> B. \<forall>y\<in> C. f x y = g x y"
  2237   shows "\<forall>x\<in>S. \<forall>y\<in>T. f x y = g x y "
  2238 proof -
  2239   let ?P = "{x. \<forall>y\<in> span C. f x y = g x y}"
  2240   from bf bg have sp: "subspace ?P"
  2241     unfolding bilinear_def linear_def subspace_def bf bg
  2242     by (auto simp add: span_0 bilinear_lzero[OF bf] bilinear_lzero[OF bg] span_add Ball_def
  2243       intro: bilinear_ladd[OF bf])
  2244 
  2245   have "\<forall>x \<in> span B. \<forall>y\<in> span C. f x y = g x y"
  2246     apply (rule span_induct' [OF _ sp])
  2247     apply (rule ballI)
  2248     apply (rule span_induct')
  2249     apply (simp add: fg)
  2250     apply (auto simp add: subspace_def)
  2251     using bf bg unfolding bilinear_def linear_def
  2252     apply (auto simp add: span_0 bilinear_rzero[OF bf] bilinear_rzero[OF bg] span_add Ball_def
  2253       intro: bilinear_ladd[OF bf])
  2254     done
  2255   then show ?thesis using SB TC by auto
  2256 qed
  2257 
  2258 lemma bilinear_eq_stdbasis:
  2259   fixes f::"'a::euclidean_space \<Rightarrow> 'b::euclidean_space \<Rightarrow> _"
  2260   assumes bf: "bilinear f"
  2261     and bg: "bilinear g"
  2262     and fg: "\<forall>i\<in>Basis. \<forall>j\<in>Basis. f i j = g i j"
  2263   shows "f = g"
  2264   using bilinear_eq[OF bf bg equalityD2[OF span_Basis] equalityD2[OF span_Basis] fg] by blast
  2265 
  2266 text {* Detailed theorems about left and right invertibility in general case. *}
  2267 
  2268 lemma linear_injective_left_inverse:
  2269   fixes f::"'a::euclidean_space => 'b::euclidean_space"
  2270   assumes lf: "linear f" and fi: "inj f"
  2271   shows "\<exists>g. linear g \<and> g o f = id"
  2272 proof -
  2273   from linear_independent_extend[OF independent_injective_image, OF independent_Basis, OF lf fi]
  2274   obtain h:: "'b => 'a" where
  2275     h: "linear h" "\<forall>x \<in> f ` Basis. h x = inv f x" by blast
  2276   from h(2) have th: "\<forall>i\<in>Basis. (h \<circ> f) i = id i"
  2277     using inv_o_cancel[OF fi, unfolded fun_eq_iff id_def o_def]
  2278     by auto
  2279 
  2280   from linear_eq_stdbasis[OF linear_compose[OF lf h(1)] linear_id th]
  2281   have "h o f = id" .
  2282   then show ?thesis using h(1) by blast
  2283 qed
  2284 
  2285 lemma linear_surjective_right_inverse:
  2286   fixes f::"'a::euclidean_space => 'b::euclidean_space"
  2287   assumes lf: "linear f" and sf: "surj f"
  2288   shows "\<exists>g. linear g \<and> f o g = id"
  2289 proof -
  2290   from linear_independent_extend[OF independent_Basis[where 'a='b],of "inv f"]
  2291   obtain h:: "'b \<Rightarrow> 'a" where
  2292     h: "linear h" "\<forall>x\<in>Basis. h x = inv f x" by blast
  2293   from h(2)
  2294   have th: "\<forall>i\<in>Basis. (f o h) i = id i"
  2295     using sf by (auto simp add: surj_iff_all)
  2296   from linear_eq_stdbasis[OF linear_compose[OF h(1) lf] linear_id th]
  2297   have "f o h = id" .
  2298   then show ?thesis using h(1) by blast
  2299 qed
  2300 
  2301 text {* An injective map @{typ "'a::euclidean_space \<Rightarrow> 'b::euclidean_space"} is also surjective. *}
  2302 
  2303 lemma linear_injective_imp_surjective:
  2304   fixes f::"'a::euclidean_space => 'a::euclidean_space"
  2305   assumes lf: "linear f" and fi: "inj f"
  2306   shows "surj f"
  2307 proof -
  2308   let ?U = "UNIV :: 'a set"
  2309   from basis_exists[of ?U] obtain B
  2310     where B: "B \<subseteq> ?U" "independent B" "?U \<subseteq> span B" "card B = dim ?U"
  2311     by blast
  2312   from B(4) have d: "dim ?U = card B" by simp
  2313   have th: "?U \<subseteq> span (f ` B)"
  2314     apply (rule card_ge_dim_independent)
  2315     apply blast
  2316     apply (rule independent_injective_image[OF B(2) lf fi])
  2317     apply (rule order_eq_refl)
  2318     apply (rule sym)
  2319     unfolding d
  2320     apply (rule card_image)
  2321     apply (rule subset_inj_on[OF fi])
  2322     apply blast
  2323     done
  2324   from th show ?thesis
  2325     unfolding span_linear_image[OF lf] surj_def
  2326     using B(3) by blast
  2327 qed
  2328 
  2329 text {* And vice versa. *}
  2330 
  2331 lemma surjective_iff_injective_gen:
  2332   assumes fS: "finite S"
  2333     and fT: "finite T"
  2334     and c: "card S = card T"
  2335     and ST: "f ` S \<subseteq> T"
  2336   shows "(\<forall>y \<in> T. \<exists>x \<in> S. f x = y) \<longleftrightarrow> inj_on f S" (is "?lhs \<longleftrightarrow> ?rhs")
  2337 proof -
  2338   { assume h: "?lhs"
  2339     { fix x y
  2340       assume x: "x \<in> S" and y: "y \<in> S" and f: "f x = f y"
  2341       from x fS have S0: "card S \<noteq> 0" by auto
  2342       { assume xy: "x \<noteq> y"
  2343         have th: "card S \<le> card (f ` (S - {y}))"
  2344           unfolding c
  2345           apply (rule card_mono)
  2346           apply (rule finite_imageI)
  2347           using fS apply simp
  2348           using h xy x y f unfolding subset_eq image_iff
  2349           apply auto
  2350           apply (case_tac "xa = f x")
  2351           apply (rule bexI[where x=x])
  2352           apply auto
  2353           done
  2354         also have " \<dots> \<le> card (S -{y})"
  2355           apply (rule card_image_le)
  2356           using fS by simp
  2357         also have "\<dots> \<le> card S - 1" using y fS by simp
  2358         finally have False  using S0 by arith }
  2359       then have "x = y" by blast}
  2360     then have ?rhs unfolding inj_on_def by blast}
  2361   moreover
  2362   { assume h: ?rhs
  2363     have "f ` S = T"
  2364       apply (rule card_subset_eq[OF fT ST])
  2365       unfolding card_image[OF h] using c .
  2366     then have ?lhs by blast}
  2367   ultimately show ?thesis by blast
  2368 qed
  2369 
  2370 lemma linear_surjective_imp_injective:
  2371   fixes f::"'a::euclidean_space => 'a::euclidean_space"
  2372   assumes lf: "linear f" and sf: "surj f"
  2373   shows "inj f"
  2374 proof -
  2375   let ?U = "UNIV :: 'a set"
  2376   from basis_exists[of ?U] obtain B
  2377     where B: "B \<subseteq> ?U" "independent B" "?U \<subseteq> span B" and d: "card B = dim ?U"
  2378     by blast
  2379   { fix x assume x: "x \<in> span B" and fx: "f x = 0"
  2380     from B(2) have fB: "finite B" using independent_bound by auto
  2381     have fBi: "independent (f ` B)"
  2382       apply (rule card_le_dim_spanning[of "f ` B" ?U])
  2383       apply blast
  2384       using sf B(3)
  2385       unfolding span_linear_image[OF lf] surj_def subset_eq image_iff
  2386       apply blast
  2387       using fB apply blast
  2388       unfolding d[symmetric]
  2389       apply (rule card_image_le)
  2390       apply (rule fB)
  2391       done
  2392     have th0: "dim ?U \<le> card (f ` B)"
  2393       apply (rule span_card_ge_dim)
  2394       apply blast
  2395       unfolding span_linear_image[OF lf]
  2396       apply (rule subset_trans[where B = "f ` UNIV"])
  2397       using sf unfolding surj_def apply blast
  2398       apply (rule image_mono)
  2399       apply (rule B(3))
  2400       apply (metis finite_imageI fB)
  2401       done
  2402 
  2403     moreover have "card (f ` B) \<le> card B"
  2404       by (rule card_image_le, rule fB)
  2405     ultimately have th1: "card B = card (f ` B)" unfolding d by arith
  2406     have fiB: "inj_on f B"
  2407       unfolding surjective_iff_injective_gen[OF fB finite_imageI[OF fB] th1 subset_refl, symmetric]
  2408       by blast
  2409     from linear_indep_image_lemma[OF lf fB fBi fiB x] fx
  2410     have "x = 0" by blast}
  2411   note th = this
  2412   from th show ?thesis unfolding linear_injective_0[OF lf]
  2413     using B(3) by blast
  2414 qed
  2415 
  2416 text {* Hence either is enough for isomorphism. *}
  2417 
  2418 lemma left_right_inverse_eq:
  2419   assumes fg: "f o g = id" and gh: "g o h = id"
  2420   shows "f = h"
  2421 proof -
  2422   have "f = f o (g o h)" unfolding gh by simp
  2423   also have "\<dots> = (f o g) o h" by (simp add: o_assoc)
  2424   finally show "f = h" unfolding fg by simp
  2425 qed
  2426 
  2427 lemma isomorphism_expand:
  2428   "f o g = id \<and> g o f = id \<longleftrightarrow> (\<forall>x. f(g x) = x) \<and> (\<forall>x. g(f x) = x)"
  2429   by (simp add: fun_eq_iff o_def id_def)
  2430 
  2431 lemma linear_injective_isomorphism:
  2432   fixes f::"'a::euclidean_space => 'a::euclidean_space"
  2433   assumes lf: "linear f" and fi: "inj f"
  2434   shows "\<exists>f'. linear f' \<and> (\<forall>x. f' (f x) = x) \<and> (\<forall>x. f (f' x) = x)"
  2435   unfolding isomorphism_expand[symmetric]
  2436   using linear_surjective_right_inverse[OF lf linear_injective_imp_surjective[OF lf fi]]
  2437     linear_injective_left_inverse[OF lf fi]
  2438   by (metis left_right_inverse_eq)
  2439 
  2440 lemma linear_surjective_isomorphism: fixes f::"'a::euclidean_space => 'a::euclidean_space"
  2441   assumes lf: "linear f" and sf: "surj f"
  2442   shows "\<exists>f'. linear f' \<and> (\<forall>x. f' (f x) = x) \<and> (\<forall>x. f (f' x) = x)"
  2443   unfolding isomorphism_expand[symmetric]
  2444   using linear_surjective_right_inverse[OF lf sf]
  2445     linear_injective_left_inverse[OF lf linear_surjective_imp_injective[OF lf sf]]
  2446   by (metis left_right_inverse_eq)
  2447 
  2448 text {* Left and right inverses are the same for @{typ "'a::euclidean_space => 'a::euclidean_space"}. *}
  2449 
  2450 lemma linear_inverse_left:
  2451   fixes f::"'a::euclidean_space => 'a::euclidean_space"
  2452   assumes lf: "linear f" and lf': "linear f'"
  2453   shows "f o f' = id \<longleftrightarrow> f' o f = id"
  2454 proof -
  2455   { fix f f':: "'a => 'a"
  2456     assume lf: "linear f" "linear f'" and f: "f o f' = id"
  2457     from f have sf: "surj f"
  2458       apply (auto simp add: o_def id_def surj_def)
  2459       apply metis
  2460       done
  2461     from linear_surjective_isomorphism[OF lf(1) sf] lf f
  2462     have "f' o f = id" unfolding fun_eq_iff o_def id_def
  2463       by metis }
  2464   then show ?thesis using lf lf' by metis
  2465 qed
  2466 
  2467 text {* Moreover, a one-sided inverse is automatically linear. *}
  2468 
  2469 lemma left_inverse_linear:
  2470   fixes f::"'a::euclidean_space => 'a::euclidean_space"
  2471   assumes lf: "linear f" and gf: "g o f = id"
  2472   shows "linear g"
  2473 proof -
  2474   from gf have fi: "inj f"
  2475     apply (auto simp add: inj_on_def o_def id_def fun_eq_iff)
  2476     apply metis
  2477     done
  2478   from linear_injective_isomorphism[OF lf fi]
  2479   obtain h:: "'a \<Rightarrow> 'a" where
  2480     h: "linear h" "\<forall>x. h (f x) = x" "\<forall>x. f (h x) = x" by blast
  2481   have "h = g"
  2482     apply (rule ext) using gf h(2,3)
  2483     apply (simp add: o_def id_def fun_eq_iff)
  2484     apply metis
  2485     done
  2486   with h(1) show ?thesis by blast
  2487 qed
  2488 
  2489 
  2490 subsection {* Infinity norm *}
  2491 
  2492 definition "infnorm (x::'a::euclidean_space) = Sup { abs (x \<bullet> b) |b. b \<in> Basis}"
  2493 
  2494 lemma numseg_dimindex_nonempty: "\<exists>i. i \<in> (UNIV :: 'n set)"
  2495   by auto
  2496 
  2497 lemma infnorm_set_image:
  2498   "{ abs ((x::'a::euclidean_space) \<bullet> i) |i. i \<in> Basis} = (\<lambda>i. abs(x \<bullet> i)) ` Basis"
  2499   by blast
  2500 
  2501 lemma infnorm_Max: "infnorm (x::'a::euclidean_space) = Max ((\<lambda>i. abs(x \<bullet> i)) ` Basis)"
  2502   by (simp add: infnorm_def infnorm_set_image cSup_eq_Max)
  2503 
  2504 lemma infnorm_set_lemma:
  2505   shows "finite {abs((x::'a::euclidean_space) \<bullet> i) |i. i \<in> Basis}"
  2506   and "{abs(x \<bullet> i) |i. i \<in> Basis} \<noteq> {}"
  2507   unfolding infnorm_set_image
  2508   by auto
  2509 
  2510 lemma infnorm_pos_le: "0 \<le> infnorm (x::'a::euclidean_space)"
  2511   by (simp add: infnorm_Max Max_ge_iff ex_in_conv)
  2512 
  2513 lemma infnorm_triangle: "infnorm ((x::'a::euclidean_space) + y) \<le> infnorm x + infnorm y"
  2514 proof -
  2515   have *: "\<And>a b c d :: real. \<bar>a\<bar> \<le> c \<Longrightarrow> \<bar>b\<bar> \<le> d \<Longrightarrow> \<bar>a + b\<bar> \<le> c + d"
  2516     by simp
  2517   show ?thesis
  2518     by (auto simp: infnorm_Max inner_add_left intro!: *)
  2519 qed
  2520 
  2521 lemma infnorm_eq_0: "infnorm x = 0 \<longleftrightarrow> (x::_::euclidean_space) = 0"
  2522 proof -
  2523   have "infnorm x \<le> 0 \<longleftrightarrow> x = 0"
  2524     unfolding infnorm_Max by (simp add: euclidean_all_zero_iff)
  2525   then show ?thesis
  2526     using infnorm_pos_le[of x] by simp
  2527 qed
  2528 
  2529 lemma infnorm_0: "infnorm 0 = 0"
  2530   by (simp add: infnorm_eq_0)
  2531 
  2532 lemma infnorm_neg: "infnorm (- x) = infnorm x"
  2533   unfolding infnorm_def
  2534   apply (rule cong[of "Sup" "Sup"])
  2535   apply blast
  2536   apply auto
  2537   done
  2538 
  2539 lemma infnorm_sub: "infnorm (x - y) = infnorm (y - x)"
  2540 proof -
  2541   have "y - x = - (x - y)" by simp
  2542   then show ?thesis  by (metis infnorm_neg)
  2543 qed
  2544 
  2545 lemma real_abs_sub_infnorm: "\<bar> infnorm x - infnorm y\<bar> \<le> infnorm (x - y)"
  2546 proof -
  2547   have th: "\<And>(nx::real) n ny. nx <= n + ny \<Longrightarrow> ny <= n + nx ==> \<bar>nx - ny\<bar> <= n"
  2548     by arith
  2549   from infnorm_triangle[of "x - y" " y"] infnorm_triangle[of "x - y" "-x"]
  2550   have ths: "infnorm x \<le> infnorm (x - y) + infnorm y"
  2551     "infnorm y \<le> infnorm (x - y) + infnorm x"
  2552     by (simp_all add: field_simps infnorm_neg)
  2553   from th[OF ths]  show ?thesis .
  2554 qed
  2555 
  2556 lemma real_abs_infnorm: " \<bar>infnorm x\<bar> = infnorm x"
  2557   using infnorm_pos_le[of x] by arith
  2558 
  2559 lemma Basis_le_infnorm:
  2560   "b \<in> Basis \<Longrightarrow> \<bar>x \<bullet> b\<bar> \<le> infnorm (x::'a::euclidean_space)"
  2561   by (simp add: infnorm_Max)
  2562 
  2563 lemma infnorm_mul: "infnorm(a *\<^sub>R x) = abs a * infnorm x"
  2564   unfolding infnorm_Max
  2565 proof (safe intro!: Max_eqI)
  2566   let ?B = "(\<lambda>i. \<bar>x \<bullet> i\<bar>) ` Basis"
  2567   show "\<And>b :: 'a. b \<in> Basis \<Longrightarrow> \<bar>a *\<^sub>R x \<bullet> b\<bar> \<le> \<bar>a\<bar> * Max ?B"
  2568     by (simp add: abs_mult mult_left_mono)
  2569 
  2570   from Max_in[of ?B] obtain b where "b \<in> Basis" "Max ?B = \<bar>x \<bullet> b\<bar>"
  2571     by (auto simp del: Max_in)
  2572   then show "\<bar>a\<bar> * Max ((\<lambda>i. \<bar>x \<bullet> i\<bar>) ` Basis) \<in> (\<lambda>i. \<bar>a *\<^sub>R x \<bullet> i\<bar>) ` Basis"
  2573     by (intro image_eqI[where x=b]) (auto simp: abs_mult)
  2574 qed simp
  2575 
  2576 lemma infnorm_mul_lemma: "infnorm(a *\<^sub>R x) \<le> \<bar>a\<bar> * infnorm x"
  2577   unfolding infnorm_mul ..
  2578 
  2579 lemma infnorm_pos_lt: "infnorm x > 0 \<longleftrightarrow> x \<noteq> 0"
  2580   using infnorm_pos_le[of x] infnorm_eq_0[of x] by arith
  2581 
  2582 text {* Prove that it differs only up to a bound from Euclidean norm. *}
  2583 
  2584 lemma infnorm_le_norm: "infnorm x \<le> norm x"
  2585   by (simp add: Basis_le_norm infnorm_Max)
  2586 
  2587 lemma euclidean_inner: "inner x y = (\<Sum>b\<in>Basis. (x \<bullet> b) * (y \<bullet> b))"
  2588   by (subst (1 2) euclidean_representation[symmetric, where 'a='a])
  2589      (simp add: inner_setsum_left inner_setsum_right setsum_cases inner_Basis ac_simps if_distrib)
  2590 
  2591 lemma norm_le_infnorm: "norm x \<le> sqrt DIM('a) * infnorm(x::'a::euclidean_space)"
  2592 proof -
  2593   let ?d = "DIM('a)"
  2594   have "real ?d \<ge> 0" by simp
  2595   then have d2: "(sqrt (real ?d))^2 = real ?d"
  2596     by (auto intro: real_sqrt_pow2)
  2597   have th: "sqrt (real ?d) * infnorm x \<ge> 0"
  2598     by (simp add: zero_le_mult_iff infnorm_pos_le)
  2599   have th1: "x \<bullet> x \<le> (sqrt (real ?d) * infnorm x)^2"
  2600     unfolding power_mult_distrib d2
  2601     unfolding real_of_nat_def
  2602     apply(subst euclidean_inner)
  2603     apply (subst power2_abs[symmetric])
  2604     apply (rule order_trans[OF setsum_bounded[where K="\<bar>infnorm x\<bar>\<twosuperior>"]])
  2605     apply (auto simp add: power2_eq_square[symmetric])
  2606     apply (subst power2_abs[symmetric])
  2607     apply (rule power_mono)
  2608     apply (auto simp: infnorm_Max)
  2609     done
  2610   from real_le_lsqrt[OF inner_ge_zero th th1]
  2611   show ?thesis unfolding norm_eq_sqrt_inner id_def .
  2612 qed
  2613 
  2614 lemma tendsto_infnorm [tendsto_intros]:
  2615   assumes "(f ---> a) F"
  2616   shows "((\<lambda>x. infnorm (f x)) ---> infnorm a) F"
  2617 proof (rule tendsto_compose [OF LIM_I assms])
  2618   fix r :: real assume "0 < r"
  2619   then show "\<exists>s>0. \<forall>x. x \<noteq> a \<and> norm (x - a) < s \<longrightarrow> norm (infnorm x - infnorm a) < r"
  2620     by (metis real_norm_def le_less_trans real_abs_sub_infnorm infnorm_le_norm)
  2621 qed
  2622 
  2623 text {* Equality in Cauchy-Schwarz and triangle inequalities. *}
  2624 
  2625 lemma norm_cauchy_schwarz_eq: "x \<bullet> y = norm x * norm y \<longleftrightarrow> norm x *\<^sub>R y = norm y *\<^sub>R x" (is "?lhs \<longleftrightarrow> ?rhs")
  2626 proof -
  2627   { assume h: "x = 0"
  2628     then have ?thesis by simp }
  2629   moreover
  2630   { assume h: "y = 0"
  2631     then have ?thesis by simp }
  2632   moreover
  2633   { assume x: "x \<noteq> 0" and y: "y \<noteq> 0"
  2634     from inner_eq_zero_iff[of "norm y *\<^sub>R x - norm x *\<^sub>R y"]
  2635     have "?rhs \<longleftrightarrow>
  2636       (norm y * (norm y * norm x * norm x - norm x * (x \<bullet> y)) -
  2637         norm x * (norm y * (y \<bullet> x) - norm x * norm y * norm y) =  0)"
  2638       using x y
  2639       unfolding inner_simps
  2640       unfolding power2_norm_eq_inner[symmetric] power2_eq_square diff_eq_0_iff_eq
  2641       apply (simp add: inner_commute)
  2642       apply (simp add: field_simps)
  2643       apply metis
  2644       done
  2645     also have "\<dots> \<longleftrightarrow> (2 * norm x * norm y * (norm x * norm y - x \<bullet> y) = 0)" using x y
  2646       by (simp add: field_simps inner_commute)
  2647     also have "\<dots> \<longleftrightarrow> ?lhs" using x y
  2648       apply simp
  2649       apply metis
  2650       done
  2651     finally have ?thesis by blast }
  2652   ultimately show ?thesis by blast
  2653 qed
  2654 
  2655 lemma norm_cauchy_schwarz_abs_eq:
  2656   "abs(x \<bullet> y) = norm x * norm y \<longleftrightarrow>
  2657     norm x *\<^sub>R y = norm y *\<^sub>R x \<or> norm(x) *\<^sub>R y = - norm y *\<^sub>R x" (is "?lhs \<longleftrightarrow> ?rhs")
  2658 proof -
  2659   have th: "\<And>(x::real) a. a \<ge> 0 \<Longrightarrow> abs x = a \<longleftrightarrow> x = a \<or> x = - a" by arith
  2660   have "?rhs \<longleftrightarrow> norm x *\<^sub>R y = norm y *\<^sub>R x \<or> norm (- x) *\<^sub>R y = norm y *\<^sub>R (- x)"
  2661     by simp
  2662   also have "\<dots> \<longleftrightarrow>(x \<bullet> y = norm x * norm y \<or>
  2663      (-x) \<bullet> y = norm x * norm y)"
  2664     unfolding norm_cauchy_schwarz_eq[symmetric]
  2665     unfolding norm_minus_cancel norm_scaleR ..
  2666   also have "\<dots> \<longleftrightarrow> ?lhs"
  2667     unfolding th[OF mult_nonneg_nonneg, OF norm_ge_zero[of x] norm_ge_zero[of y]] inner_simps by auto
  2668   finally show ?thesis ..
  2669 qed
  2670 
  2671 lemma norm_triangle_eq:
  2672   fixes x y :: "'a::real_inner"
  2673   shows "norm(x + y) = norm x + norm y \<longleftrightarrow> norm x *\<^sub>R y = norm y *\<^sub>R x"
  2674 proof -
  2675   { assume x: "x = 0 \<or> y = 0"
  2676     then have ?thesis by (cases "x = 0") simp_all }
  2677   moreover
  2678   { assume x: "x \<noteq> 0" and y: "y \<noteq> 0"
  2679     then have "norm x \<noteq> 0" "norm y \<noteq> 0"
  2680       by simp_all
  2681     then have n: "norm x > 0" "norm y > 0"
  2682       using norm_ge_zero[of x] norm_ge_zero[of y] by arith+
  2683     have th: "\<And>(a::real) b c. a + b + c \<noteq> 0 ==> (a = b + c \<longleftrightarrow> a^2 = (b + c)^2)"
  2684       by algebra
  2685     have "norm(x + y) = norm x + norm y \<longleftrightarrow> norm(x + y)^ 2 = (norm x + norm y) ^2"
  2686       apply (rule th) using n norm_ge_zero[of "x + y"]
  2687       apply arith
  2688       done
  2689     also have "\<dots> \<longleftrightarrow> norm x *\<^sub>R y = norm y *\<^sub>R x"
  2690       unfolding norm_cauchy_schwarz_eq[symmetric]
  2691       unfolding power2_norm_eq_inner inner_simps
  2692       by (simp add: power2_norm_eq_inner[symmetric] power2_eq_square inner_commute field_simps)
  2693     finally have ?thesis .}
  2694   ultimately show ?thesis by blast
  2695 qed
  2696 
  2697 
  2698 subsection {* Collinearity *}
  2699 
  2700 definition collinear :: "'a::real_vector set \<Rightarrow> bool"
  2701   where "collinear S \<longleftrightarrow> (\<exists>u. \<forall>x \<in> S. \<forall> y \<in> S. \<exists>c. x - y = c *\<^sub>R u)"
  2702 
  2703 lemma collinear_empty:  "collinear {}" by (simp add: collinear_def)
  2704 
  2705 lemma collinear_sing: "collinear {x}"
  2706   by (simp add: collinear_def)
  2707 
  2708 lemma collinear_2: "collinear {x, y}"
  2709   apply (simp add: collinear_def)
  2710   apply (rule exI[where x="x - y"])
  2711   apply auto
  2712   apply (rule exI[where x=1], simp)
  2713   apply (rule exI[where x="- 1"], simp)
  2714   done
  2715 
  2716 lemma collinear_lemma:
  2717   "collinear {0,x,y} \<longleftrightarrow> x = 0 \<or> y = 0 \<or> (\<exists>c. y = c *\<^sub>R x)" (is "?lhs \<longleftrightarrow> ?rhs")
  2718 proof -
  2719   { assume "x=0 \<or> y = 0"
  2720     then have ?thesis by (cases "x = 0") (simp_all add: collinear_2 insert_commute) }
  2721   moreover
  2722   { assume x: "x \<noteq> 0" and y: "y \<noteq> 0"
  2723     { assume h: "?lhs"
  2724       then obtain u where u: "\<forall> x\<in> {0,x,y}. \<forall>y\<in> {0,x,y}. \<exists>c. x - y = c *\<^sub>R u"
  2725         unfolding collinear_def by blast
  2726       from u[rule_format, of x 0] u[rule_format, of y 0]
  2727       obtain cx and cy where
  2728         cx: "x = cx *\<^sub>R u" and cy: "y = cy *\<^sub>R u"
  2729         by auto
  2730       from cx x have cx0: "cx \<noteq> 0" by auto
  2731       from cy y have cy0: "cy \<noteq> 0" by auto
  2732       let ?d = "cy / cx"
  2733       from cx cy cx0 have "y = ?d *\<^sub>R x"
  2734         by simp
  2735       then have ?rhs using x y by blast }
  2736     moreover
  2737     { assume h: "?rhs"
  2738       then obtain c where c: "y = c *\<^sub>R x" using x y by blast
  2739       have ?lhs unfolding collinear_def c
  2740         apply (rule exI[where x=x])
  2741         apply auto
  2742         apply (rule exI[where x="- 1"], simp)
  2743         apply (rule exI[where x= "-c"], simp)
  2744         apply (rule exI[where x=1], simp)
  2745         apply (rule exI[where x="1 - c"], simp add: scaleR_left_diff_distrib)
  2746         apply (rule exI[where x="c - 1"], simp add: scaleR_left_diff_distrib)
  2747         done }
  2748     ultimately have ?thesis by blast }
  2749   ultimately show ?thesis by blast
  2750 qed
  2751 
  2752 lemma norm_cauchy_schwarz_equal: "abs(x \<bullet> y) = norm x * norm y \<longleftrightarrow> collinear {0,x,y}"
  2753   unfolding norm_cauchy_schwarz_abs_eq
  2754   apply (cases "x=0", simp_all add: collinear_2)
  2755   apply (cases "y=0", simp_all add: collinear_2 insert_commute)
  2756   unfolding collinear_lemma
  2757   apply simp
  2758   apply (subgoal_tac "norm x \<noteq> 0")
  2759   apply (subgoal_tac "norm y \<noteq> 0")
  2760   apply (rule iffI)
  2761   apply (cases "norm x *\<^sub>R y = norm y *\<^sub>R x")
  2762   apply (rule exI[where x="(1/norm x) * norm y"])
  2763   apply (drule sym)
  2764   unfolding scaleR_scaleR[symmetric]
  2765   apply (simp add: field_simps)
  2766   apply (rule exI[where x="(1/norm x) * - norm y"])
  2767   apply clarify
  2768   apply (drule sym)
  2769   unfolding scaleR_scaleR[symmetric]
  2770   apply (simp add: field_simps)
  2771   apply (erule exE)
  2772   apply (erule ssubst)
  2773   unfolding scaleR_scaleR
  2774   unfolding norm_scaleR
  2775   apply (subgoal_tac "norm x * c = \<bar>c\<bar> * norm x \<or> norm x * c = - \<bar>c\<bar> * norm x")
  2776   apply (case_tac "c <= 0", simp add: field_simps)
  2777   apply (simp add: field_simps)
  2778   apply (case_tac "c <= 0", simp add: field_simps)
  2779   apply (simp add: field_simps)
  2780   apply simp
  2781   apply simp
  2782   done
  2783 
  2784 
  2785 subsection {* An ordering on euclidean spaces that will allow us to talk about intervals *}
  2786 
  2787 class ordered_euclidean_space = ord + euclidean_space +
  2788   assumes eucl_le: "x \<le> y \<longleftrightarrow> (\<forall>i\<in>Basis. x \<bullet> i \<le> y \<bullet> i)"
  2789     and eucl_less: "x < y \<longleftrightarrow> (\<forall>i\<in>Basis. x \<bullet> i < y \<bullet> i)"
  2790 
  2791 lemma eucl_less_not_refl[simp, intro!]: "\<not> x < (x::'a::ordered_euclidean_space)"
  2792   unfolding eucl_less[where 'a='a] by auto
  2793 
  2794 lemma euclidean_trans[trans]:
  2795   fixes x y z :: "'a::ordered_euclidean_space"
  2796   shows "x < y \<Longrightarrow> y < z \<Longrightarrow> x < z"
  2797     and "x \<le> y \<Longrightarrow> y < z \<Longrightarrow> x < z"
  2798     and "x \<le> y \<Longrightarrow> y \<le> z \<Longrightarrow> x \<le> z"
  2799   unfolding eucl_less[where 'a='a] eucl_le[where 'a='a]
  2800   by (fast intro: less_trans, fast intro: le_less_trans,
  2801     fast intro: order_trans)
  2802 
  2803 lemma atLeastAtMost_singleton_euclidean[simp]:
  2804   fixes a :: "'a::ordered_euclidean_space" shows "{a .. a} = {a}"
  2805   by (force simp: eucl_le[where 'a='a] euclidean_eq_iff[where 'a='a])
  2806 
  2807 instance real :: ordered_euclidean_space
  2808   by default (auto simp add: Basis_real_def)
  2809 
  2810 instantiation prod :: (ordered_euclidean_space, ordered_euclidean_space) ordered_euclidean_space
  2811 begin
  2812 
  2813 definition "x \<le> (y::('a\<times>'b)) \<longleftrightarrow> (\<forall>i\<in>Basis. x \<bullet> i \<le> y \<bullet> i)"
  2814 definition "x < (y::('a\<times>'b)) \<longleftrightarrow> (\<forall>i\<in>Basis. x \<bullet> i < y \<bullet> i)"
  2815 
  2816 instance
  2817   by default (auto simp: less_prod_def less_eq_prod_def)
  2818 
  2819 end
  2820 
  2821 end