src/Pure/term.ML
author wenzelm
Thu Jul 13 13:42:00 2006 +0200 (2006-07-13)
changeset 20122 27255556b762
parent 20116 f2aecd6e58ec
child 20129 95e84d2c9f2c
permissions -rw-r--r--
strip_abs_eta: proper use of Name.context;
     1 (*  Title:      Pure/term.ML
     2     ID:         $Id$
     3     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     4     Copyright   Cambridge University 1992
     5 
     6 Simply typed lambda-calculus: types, terms, and basic operations.
     7 *)
     8 
     9 infix 9  $;
    10 infixr 5 -->;
    11 infixr --->;
    12 infix aconv;
    13 
    14 signature BASIC_TERM =
    15 sig
    16   type indexname
    17   type class
    18   type sort
    19   type arity
    20   datatype typ =
    21     Type  of string * typ list |
    22     TFree of string * sort |
    23     TVar  of indexname * sort
    24   datatype term =
    25     Const of string * typ |
    26     Free of string * typ |
    27     Var of indexname * typ |
    28     Bound of int |
    29     Abs of string * typ * term |
    30     $ of term * term
    31   exception TYPE of string * typ list * term list
    32   exception TERM of string * term list
    33   val dummyT: typ
    34   val no_dummyT: typ -> typ
    35   val --> : typ * typ -> typ
    36   val ---> : typ list * typ -> typ
    37   val dest_Type: typ -> string * typ list
    38   val dest_TVar: typ -> indexname * sort
    39   val dest_TFree: typ -> string * sort
    40   val is_Bound: term -> bool
    41   val is_Const: term -> bool
    42   val is_Free: term -> bool
    43   val is_Var: term -> bool
    44   val is_TVar: typ -> bool
    45   val is_funtype: typ -> bool
    46   val dest_Const: term -> string * typ
    47   val dest_Free: term -> string * typ
    48   val dest_Var: term -> indexname * typ
    49   val domain_type: typ -> typ
    50   val range_type: typ -> typ
    51   val binder_types: typ -> typ list
    52   val body_type: typ -> typ
    53   val strip_type: typ -> typ list * typ
    54   val type_of1: typ list * term -> typ
    55   val type_of: term -> typ
    56   val fastype_of1: typ list * term -> typ
    57   val fastype_of: term -> typ
    58   val list_abs: (string * typ) list * term -> term
    59   val strip_abs: term -> (string * typ) list * term
    60   val strip_abs_body: term -> term
    61   val strip_abs_vars: term -> (string * typ) list
    62   val strip_qnt_body: string -> term -> term
    63   val strip_qnt_vars: string -> term -> (string * typ) list
    64   val list_comb: term * term list -> term
    65   val strip_comb: term -> term * term list
    66   val head_of: term -> term
    67   val size_of_term: term -> int
    68   val map_atyps: (typ -> typ) -> typ -> typ
    69   val map_aterms: (term -> term) -> term -> term
    70   val map_type_tvar: (indexname * sort -> typ) -> typ -> typ
    71   val map_type_tfree: (string * sort -> typ) -> typ -> typ
    72   val map_term_types: (typ -> typ) -> term -> term
    73   val fold_atyps: (typ -> 'a -> 'a) -> typ -> 'a -> 'a
    74   val fold_aterms: (term -> 'a -> 'a) -> term -> 'a -> 'a
    75   val fold_term_types: (term -> typ -> 'a -> 'a) -> term -> 'a -> 'a
    76   val fold_types: (typ -> 'a -> 'a) -> term -> 'a -> 'a
    77   val it_term_types: (typ * 'a -> 'a) -> term * 'a -> 'a
    78   val add_term_names: term * string list -> string list
    79   val add_term_varnames: term -> indexname list -> indexname list
    80   val term_varnames: term -> indexname list
    81   val find_free: term -> string -> term option
    82   val aconv: term * term -> bool
    83   val aconvs: term list * term list -> bool
    84   structure Vartab: TABLE
    85   structure Typtab: TABLE
    86   structure Termtab: TABLE
    87   val propT: typ
    88   val implies: term
    89   val all: typ -> term
    90   val equals: typ -> term
    91   val strip_all_body: term -> term
    92   val strip_all_vars: term -> (string * typ) list
    93   val incr_bv: int * int * term -> term
    94   val incr_boundvars: int -> term -> term
    95   val add_loose_bnos: term * int * int list -> int list
    96   val loose_bnos: term -> int list
    97   val loose_bvar: term * int -> bool
    98   val loose_bvar1: term * int -> bool
    99   val subst_bounds: term list * term -> term
   100   val subst_bound: term * term -> term
   101   val betapply: term * term -> term
   102   val betapplys: term * term list -> term
   103   val eq_ix: indexname * indexname -> bool
   104   val could_unify: term * term -> bool
   105   val subst_free: (term * term) list -> term -> term
   106   val abstract_over: term * term -> term
   107   val lambda: term -> term -> term
   108   val absfree: string * typ * term -> term
   109   val absdummy: typ * term -> term
   110   val list_abs_free: (string * typ) list * term -> term
   111   val list_all_free: (string * typ) list * term -> term
   112   val list_all: (string * typ) list * term -> term
   113   val subst_atomic: (term * term) list -> term -> term
   114   val typ_subst_atomic: (typ * typ) list -> typ -> typ
   115   val subst_atomic_types: (typ * typ) list -> term -> term
   116   val typ_subst_TVars: (indexname * typ) list -> typ -> typ
   117   val subst_TVars: (indexname * typ) list -> term -> term
   118   val subst_Vars: (indexname * term) list -> term -> term
   119   val subst_vars: (indexname * typ) list * (indexname * term) list -> term -> term
   120   val is_first_order: string list -> term -> bool
   121   val maxidx_of_typ: typ -> int
   122   val maxidx_of_typs: typ list -> int
   123   val maxidx_of_term: term -> int
   124   val add_term_consts: term * string list -> string list
   125   val term_consts: term -> string list
   126   val exists_subtype: (typ -> bool) -> typ -> bool
   127   val exists_subterm: (term -> bool) -> term -> bool
   128   val exists_Const: (string * typ -> bool) -> term -> bool
   129   val add_term_free_names: term * string list -> string list
   130   val add_typ_tvars: typ * (indexname * sort) list -> (indexname * sort) list
   131   val add_typ_tfree_names: typ * string list -> string list
   132   val add_typ_tfrees: typ * (string * sort) list -> (string * sort) list
   133   val add_typ_varnames: typ * string list -> string list
   134   val add_term_tvars: term * (indexname * sort) list -> (indexname * sort) list
   135   val add_term_tfrees: term * (string * sort) list -> (string * sort) list
   136   val add_term_tfree_names: term * string list -> string list
   137   val add_term_tvarnames: term * string list -> string list
   138   val typ_tfrees: typ -> (string * sort) list
   139   val typ_tvars: typ -> (indexname * sort) list
   140   val term_tfrees: term -> (string * sort) list
   141   val term_tvars: term -> (indexname * sort) list
   142   val add_typ_ixns: indexname list * typ -> indexname list
   143   val add_term_tvar_ixns: term * indexname list -> indexname list
   144   val add_term_vars: term * term list -> term list
   145   val term_vars: term -> term list
   146   val add_term_frees: term * term list -> term list
   147   val term_frees: term -> term list
   148   val variant_abs: string * typ * term -> string * term
   149   val rename_wrt_term: term -> (string * typ) list -> (string * typ) list
   150   val show_question_marks: bool ref
   151 end;
   152 
   153 signature TERM =
   154 sig
   155   include BASIC_TERM
   156   val aT: sort -> typ
   157   val itselfT: typ -> typ
   158   val a_itselfT: typ
   159   val argument_type_of: term -> typ
   160   val add_tvarsT: typ -> (indexname * sort) list -> (indexname * sort) list
   161   val add_tvars: term -> (indexname * sort) list -> (indexname * sort) list
   162   val add_vars: term -> (indexname * typ) list -> (indexname * typ) list
   163   val add_tfreesT: typ -> (string * sort) list -> (string * sort) list
   164   val add_tfrees: term -> (string * sort) list -> (string * sort) list
   165   val add_frees: term -> (string * typ) list -> (string * typ) list
   166   val strip_abs_eta: int -> term -> (string * typ) list * term
   167   val fast_indexname_ord: indexname * indexname -> order
   168   val indexname_ord: indexname * indexname -> order
   169   val sort_ord: sort * sort -> order
   170   val typ_ord: typ * typ -> order
   171   val fast_term_ord: term * term -> order
   172   val term_ord: term * term -> order
   173   val hd_ord: term * term -> order
   174   val termless: term * term -> bool
   175   val term_lpo: (string -> int) -> term * term -> order
   176   val match_bvars: (term * term) * (string * string) list -> (string * string) list
   177   val rename_abs: term -> term -> term -> term option
   178   val eq_tvar: (indexname * sort) * (indexname * sort) -> bool
   179   val eq_var: (indexname * typ) * (indexname * typ) -> bool
   180   val tvar_ord: (indexname * sort) * (indexname * sort) -> order
   181   val var_ord: (indexname * typ) * (indexname * typ) -> order
   182   val generalize: string list * string list -> int -> term -> term
   183   val generalizeT: string list -> int -> typ -> typ
   184   val generalize_option: string list * string list -> int -> term -> term option
   185   val generalizeT_option: string list -> int -> typ -> typ option
   186   val instantiate: ((indexname * sort) * typ) list * ((indexname * typ) * term) list
   187     -> term -> term
   188   val instantiateT: ((indexname * sort) * typ) list -> typ -> typ
   189   val instantiate_option: ((indexname * sort) * typ) list * ((indexname * typ) * term) list
   190     -> term -> term option
   191   val instantiateT_option: ((indexname * sort) * typ) list -> typ -> typ option
   192   val maxidx_typ: typ -> int -> int
   193   val maxidx_typs: typ list -> int -> int
   194   val maxidx_term: term -> int -> int
   195   val dest_abs: string * typ * term -> string * term
   196   val zero_var_indexesT: typ -> typ
   197   val zero_var_indexes: term -> term
   198   val zero_var_indexes_inst: term ->
   199     ((indexname * sort) * typ) list * ((indexname * typ) * term) list
   200   val dummy_patternN: string
   201   val dummy_pattern: typ -> term
   202   val no_dummy_patterns: term -> term
   203   val replace_dummy_patterns: int * term -> int * term
   204   val is_replaced_dummy_pattern: indexname -> bool
   205   val show_dummy_patterns: term -> term
   206   val string_of_vname: indexname -> string
   207   val string_of_vname': indexname -> string
   208 end;
   209 
   210 structure Term: TERM =
   211 struct
   212 
   213 (*Indexnames can be quickly renamed by adding an offset to the integer part,
   214   for resolution.*)
   215 type indexname = string * int;
   216 
   217 (* Types are classified by sorts. *)
   218 type class = string;
   219 type sort  = class list;
   220 type arity = string * sort list * sort;
   221 
   222 (* The sorts attached to TFrees and TVars specify the sort of that variable *)
   223 datatype typ = Type  of string * typ list
   224              | TFree of string * sort
   225              | TVar  of indexname * sort;
   226 
   227 (*Terms.  Bound variables are indicated by depth number.
   228   Free variables, (scheme) variables and constants have names.
   229   An term is "closed" if every bound variable of level "lev"
   230   is enclosed by at least "lev" abstractions.
   231 
   232   It is possible to create meaningless terms containing loose bound vars
   233   or type mismatches.  But such terms are not allowed in rules. *)
   234 
   235 datatype term =
   236     Const of string * typ
   237   | Free  of string * typ
   238   | Var   of indexname * typ
   239   | Bound of int
   240   | Abs   of string*typ*term
   241   | op $  of term*term;
   242 
   243 (*Errors involving type mismatches*)
   244 exception TYPE of string * typ list * term list;
   245 
   246 (*Errors errors involving terms*)
   247 exception TERM of string * term list;
   248 
   249 (*Note variable naming conventions!
   250     a,b,c: string
   251     f,g,h: functions (including terms of function type)
   252     i,j,m,n: int
   253     t,u: term
   254     v,w: indexnames
   255     x,y: any
   256     A,B,C: term (denoting formulae)
   257     T,U: typ
   258 *)
   259 
   260 
   261 (** Types **)
   262 
   263 (*dummy type for parsing and printing etc.*)
   264 val dummyT = Type ("dummy", []);
   265 
   266 fun no_dummyT typ =
   267   let
   268     fun check (T as Type ("dummy", _)) =
   269           raise TYPE ("Illegal occurrence of '_' dummy type", [T], [])
   270       | check (Type (_, Ts)) = List.app check Ts
   271       | check _ = ();
   272   in check typ; typ end;
   273 
   274 fun S --> T = Type("fun",[S,T]);
   275 
   276 (*handy for multiple args: [T1,...,Tn]--->T  gives  T1-->(T2--> ... -->T)*)
   277 val op ---> = Library.foldr (op -->);
   278 
   279 fun dest_Type (Type x) = x
   280   | dest_Type T = raise TYPE ("dest_Type", [T], []);
   281 fun dest_TVar (TVar x) = x
   282   | dest_TVar T = raise TYPE ("dest_TVar", [T], []);
   283 fun dest_TFree (TFree x) = x
   284   | dest_TFree T = raise TYPE ("dest_TFree", [T], []);
   285 
   286 
   287 (** Discriminators **)
   288 
   289 fun is_Bound (Bound _) = true
   290   | is_Bound _         = false;
   291 
   292 fun is_Const (Const _) = true
   293   | is_Const _ = false;
   294 
   295 fun is_Free (Free _) = true
   296   | is_Free _ = false;
   297 
   298 fun is_Var (Var _) = true
   299   | is_Var _ = false;
   300 
   301 fun is_TVar (TVar _) = true
   302   | is_TVar _ = false;
   303 
   304 (*Differs from proofterm/is_fun in its treatment of TVar*)
   305 fun is_funtype (Type("fun",[_,_])) = true
   306   | is_funtype _ = false;
   307 
   308 
   309 (** Destructors **)
   310 
   311 fun dest_Const (Const x) =  x
   312   | dest_Const t = raise TERM("dest_Const", [t]);
   313 
   314 fun dest_Free (Free x) =  x
   315   | dest_Free t = raise TERM("dest_Free", [t]);
   316 
   317 fun dest_Var (Var x) =  x
   318   | dest_Var t = raise TERM("dest_Var", [t]);
   319 
   320 
   321 fun domain_type (Type("fun", [T,_])) = T
   322 and range_type  (Type("fun", [_,T])) = T;
   323 
   324 (* maps  [T1,...,Tn]--->T  to the list  [T1,T2,...,Tn]*)
   325 fun binder_types (Type("fun",[S,T])) = S :: binder_types T
   326   | binder_types _   =  [];
   327 
   328 (* maps  [T1,...,Tn]--->T  to T*)
   329 fun body_type (Type("fun",[S,T])) = body_type T
   330   | body_type T   =  T;
   331 
   332 (* maps  [T1,...,Tn]--->T  to   ([T1,T2,...,Tn], T)  *)
   333 fun strip_type T : typ list * typ =
   334   (binder_types T, body_type T);
   335 
   336 
   337 (*Compute the type of the term, checking that combinations are well-typed
   338   Ts = [T0,T1,...] holds types of bound variables 0, 1, ...*)
   339 fun type_of1 (Ts, Const (_,T)) = T
   340   | type_of1 (Ts, Free  (_,T)) = T
   341   | type_of1 (Ts, Bound i) = (List.nth (Ts,i)
   342         handle Subscript => raise TYPE("type_of: bound variable", [], [Bound i]))
   343   | type_of1 (Ts, Var (_,T)) = T
   344   | type_of1 (Ts, Abs (_,T,body)) = T --> type_of1(T::Ts, body)
   345   | type_of1 (Ts, f$u) =
   346       let val U = type_of1(Ts,u)
   347           and T = type_of1(Ts,f)
   348       in case T of
   349             Type("fun",[T1,T2]) =>
   350               if T1=U then T2  else raise TYPE
   351                     ("type_of: type mismatch in application", [T1,U], [f$u])
   352           | _ => raise TYPE
   353                     ("type_of: function type is expected in application",
   354                      [T,U], [f$u])
   355       end;
   356 
   357 fun type_of t : typ = type_of1 ([],t);
   358 
   359 (*Determines the type of a term, with minimal checking*)
   360 fun fastype_of1 (Ts, f$u) =
   361     (case fastype_of1 (Ts,f) of
   362         Type("fun",[_,T]) => T
   363         | _ => raise TERM("fastype_of: expected function type", [f$u]))
   364   | fastype_of1 (_, Const (_,T)) = T
   365   | fastype_of1 (_, Free (_,T)) = T
   366   | fastype_of1 (Ts, Bound i) = (List.nth(Ts,i)
   367          handle Subscript => raise TERM("fastype_of: Bound", [Bound i]))
   368   | fastype_of1 (_, Var (_,T)) = T
   369   | fastype_of1 (Ts, Abs (_,T,u)) = T --> fastype_of1 (T::Ts, u);
   370 
   371 fun fastype_of t : typ = fastype_of1 ([],t);
   372 
   373 (*Determine the argument type of a function*)
   374 fun argument_type_of tm =
   375   let
   376     fun argT i (Type ("fun", [T, U])) = if i = 0 then T else argT (i - 1) U
   377       | argT _ T = raise TYPE ("argument_type_of", [T], []);
   378 
   379     fun arg 0 _ (Abs (_, T, _)) = T
   380       | arg i Ts (Abs (_, T, t)) = arg (i - 1) (T :: Ts) t
   381       | arg i Ts (t $ _) = arg (i + 1) Ts t
   382       | arg i Ts a = argT i (fastype_of1 (Ts, a));
   383   in arg 0 [] tm end;
   384 
   385 
   386 val list_abs = uncurry (fold_rev (fn (x, T) => fn t => Abs (x, T, t)));
   387 
   388 fun strip_abs (Abs (a, T, t)) =
   389       let val (a', t') = strip_abs t
   390       in ((a, T) :: a', t') end
   391   | strip_abs t = ([], t);
   392 
   393 (* maps  (x1,...,xn)t   to   t  *)
   394 fun strip_abs_body (Abs(_,_,t))  =  strip_abs_body t
   395   | strip_abs_body u  =  u;
   396 
   397 (* maps  (x1,...,xn)t   to   [x1, ..., xn]  *)
   398 fun strip_abs_vars (Abs(a,T,t))  =  (a,T) :: strip_abs_vars t
   399   | strip_abs_vars u  =  [] : (string*typ) list;
   400 
   401 
   402 fun strip_qnt_body qnt =
   403 let fun strip(tm as Const(c,_)$Abs(_,_,t)) = if c=qnt then strip t else tm
   404       | strip t = t
   405 in strip end;
   406 
   407 fun strip_qnt_vars qnt =
   408 let fun strip(Const(c,_)$Abs(a,T,t)) = if c=qnt then (a,T)::strip t else []
   409       | strip t  =  [] : (string*typ) list
   410 in strip end;
   411 
   412 
   413 (* maps   (f, [t1,...,tn])  to  f(t1,...,tn) *)
   414 val list_comb : term * term list -> term = Library.foldl (op $);
   415 
   416 
   417 (* maps   f(t1,...,tn)  to  (f, [t1,...,tn]) ; naturally tail-recursive*)
   418 fun strip_comb u : term * term list =
   419     let fun stripc (f$t, ts) = stripc (f, t::ts)
   420         |   stripc  x =  x
   421     in  stripc(u,[])  end;
   422 
   423 
   424 (* maps   f(t1,...,tn)  to  f , which is never a combination *)
   425 fun head_of (f$t) = head_of f
   426   | head_of u = u;
   427 
   428 
   429 (*number of atoms and abstractions in a term*)
   430 fun size_of_term tm =
   431   let
   432     fun add_size (t $ u, n) = add_size (t, add_size (u, n))
   433       | add_size (Abs (_ ,_, t), n) = add_size (t, n + 1)
   434       | add_size (_, n) = n + 1;
   435   in add_size (tm, 0) end;
   436 
   437 fun map_atyps f (Type (a, Ts)) = Type (a, map (map_atyps f) Ts)
   438   | map_atyps f T = f T;
   439 
   440 fun map_aterms f (t $ u) = map_aterms f t $ map_aterms f u
   441   | map_aterms f (Abs (a, T, t)) = Abs (a, T, map_aterms f t)
   442   | map_aterms f t = f t;
   443 
   444 fun map_type_tvar f = map_atyps (fn TVar x => f x | T => T);
   445 fun map_type_tfree f = map_atyps (fn TFree x => f x | T => T);
   446 
   447 fun map_term_types f =
   448   let
   449     fun map_aux (Const (a, T)) = Const (a, f T)
   450       | map_aux (Free (a, T)) = Free (a, f T)
   451       | map_aux (Var (v, T)) = Var (v, f T)
   452       | map_aux (t as Bound _)  = t
   453       | map_aux (Abs (a, T, t)) = Abs (a, f T, map_aux t)
   454       | map_aux (t $ u) = map_aux t $ map_aux u;
   455   in map_aux end;
   456 
   457 (* iterate a function over all types in a term *)
   458 fun it_term_types f =
   459 let fun iter(Const(_,T), a) = f(T,a)
   460       | iter(Free(_,T), a) = f(T,a)
   461       | iter(Var(_,T), a) = f(T,a)
   462       | iter(Abs(_,T,t), a) = iter(t,f(T,a))
   463       | iter(f$u, a) = iter(f, iter(u, a))
   464       | iter(Bound _, a) = a
   465 in iter end
   466 
   467 
   468 (* fold types and terms *)
   469 
   470 (*fold atoms of type*)
   471 fun fold_atyps f (Type (_, Ts)) = fold (fold_atyps f) Ts
   472   | fold_atyps f T = f T;
   473 
   474 (*fold atoms of term*)
   475 fun fold_aterms f (t $ u) = fold_aterms f t #> fold_aterms f u
   476   | fold_aterms f (Abs (_, _, t)) = fold_aterms f t
   477   | fold_aterms f a = f a;
   478 
   479 (*fold types of term*)
   480 fun fold_term_types f (t as Const (_, T)) = f t T
   481   | fold_term_types f (t as Free (_, T)) = f t T
   482   | fold_term_types f (t as Var (_, T)) = f t T
   483   | fold_term_types f (Bound _) = I
   484   | fold_term_types f (t as Abs (_, T, b)) = f t T #> fold_term_types f b
   485   | fold_term_types f (t $ u) = fold_term_types f t #> fold_term_types f u;
   486 
   487 fun fold_types f = fold_term_types (K f);
   488 
   489 (*collect variables*)
   490 val add_tvarsT = fold_atyps (fn TVar v => insert (op =) v | _ => I);
   491 val add_tvars = fold_types add_tvarsT;
   492 val add_vars = fold_aterms (fn Var v => insert (op =) v | _ => I);
   493 val add_tfreesT = fold_atyps (fn TFree v => insert (op =) v | _ => I);
   494 val add_tfrees = fold_types add_tfreesT;
   495 val add_frees = fold_aterms (fn Free v => insert (op =) v | _ => I);
   496 
   497 (*collect variable names*)
   498 val add_term_varnames = fold_aterms (fn Var (xi, _) => insert (op =) xi | _ => I);
   499 fun term_varnames t = add_term_varnames t [];
   500 
   501 fun find_free t x =
   502   let
   503     exception Found of term;
   504     fun find (t as Free (x', _)) = if x = x' then raise Found t else I
   505       | find _ = I;
   506   in (fold_aterms find t (); NONE) handle Found v => SOME v end;
   507 
   508 
   509 
   510 (** Comparing terms, types, sorts etc. **)
   511 
   512 (* fast syntactic comparison *)
   513 
   514 fun fast_indexname_ord ((x, i), (y, j)) =
   515   (case int_ord (i, j) of EQUAL => fast_string_ord (x, y) | ord => ord);
   516 
   517 fun sort_ord SS =
   518   if pointer_eq SS then EQUAL
   519   else dict_ord fast_string_ord SS;
   520 
   521 local
   522 
   523 fun cons_nr (TVar _) = 0
   524   | cons_nr (TFree _) = 1
   525   | cons_nr (Type _) = 2;
   526 
   527 in
   528 
   529 fun typ_ord TU =
   530   if pointer_eq TU then EQUAL
   531   else
   532     (case TU of
   533       (Type (a, Ts), Type (b, Us)) =>
   534         (case fast_string_ord (a, b) of EQUAL => dict_ord typ_ord (Ts, Us) | ord => ord)
   535     | (TFree (a, S), TFree (b, S')) =>
   536         (case fast_string_ord (a, b) of EQUAL => sort_ord (S, S') | ord => ord)
   537     | (TVar (xi, S), TVar (yj, S')) =>
   538         (case fast_indexname_ord (xi, yj) of EQUAL => sort_ord (S, S') | ord => ord)
   539     | (T, U) => int_ord (cons_nr T, cons_nr U));
   540 
   541 end;
   542 
   543 local
   544 
   545 fun cons_nr (Const _) = 0
   546   | cons_nr (Free _) = 1
   547   | cons_nr (Var _) = 2
   548   | cons_nr (Bound _) = 3
   549   | cons_nr (Abs _) = 4
   550   | cons_nr (_ $ _) = 5;
   551 
   552 fun struct_ord (Abs (_, _, t), Abs (_, _, u)) = struct_ord (t, u)
   553   | struct_ord (t1 $ t2, u1 $ u2) =
   554       (case struct_ord (t1, u1) of EQUAL => struct_ord (t2, u2) | ord => ord)
   555   | struct_ord (t, u) = int_ord (cons_nr t, cons_nr u);
   556 
   557 fun atoms_ord (Abs (_, _, t), Abs (_, _, u)) = atoms_ord (t, u)
   558   | atoms_ord (t1 $ t2, u1 $ u2) =
   559       (case atoms_ord (t1, u1) of EQUAL => atoms_ord (t2, u2) | ord => ord)
   560   | atoms_ord (Const (a, _), Const (b, _)) = fast_string_ord (a, b)
   561   | atoms_ord (Free (x, _), Free (y, _)) = fast_string_ord (x, y)
   562   | atoms_ord (Var (xi, _), Var (yj, _)) = fast_indexname_ord (xi, yj)
   563   | atoms_ord (Bound i, Bound j) = int_ord (i, j)
   564   | atoms_ord _ = sys_error "atoms_ord";
   565 
   566 fun types_ord (Abs (_, T, t), Abs (_, U, u)) =
   567       (case typ_ord (T, U) of EQUAL => types_ord (t, u) | ord => ord)
   568   | types_ord (t1 $ t2, u1 $ u2) =
   569       (case types_ord (t1, u1) of EQUAL => types_ord (t2, u2) | ord => ord)
   570   | types_ord (Const (_, T), Const (_, U)) = typ_ord (T, U)
   571   | types_ord (Free (_, T), Free (_, U)) = typ_ord (T, U)
   572   | types_ord (Var (_, T), Var (_, U)) = typ_ord (T, U)
   573   | types_ord (Bound _, Bound _) = EQUAL
   574   | types_ord _ = sys_error "types_ord";
   575 
   576 in
   577 
   578 fun fast_term_ord tu =
   579   if pointer_eq tu then EQUAL
   580   else
   581     (case struct_ord tu of
   582       EQUAL => (case atoms_ord tu of EQUAL => types_ord tu | ord => ord)
   583     | ord => ord);
   584 
   585 fun op aconv tu = (fast_term_ord tu = EQUAL);
   586 fun aconvs ts_us = (list_ord fast_term_ord ts_us = EQUAL);
   587 
   588 structure Vartab = TableFun(type key = indexname val ord = fast_indexname_ord);
   589 structure Typtab = TableFun(type key = typ val ord = typ_ord);
   590 structure Termtab = TableFun(type key = term val ord = fast_term_ord);
   591 
   592 end;
   593 
   594 
   595 (* term_ord *)
   596 
   597 (*a linear well-founded AC-compatible ordering for terms:
   598   s < t <=> 1. size(s) < size(t) or
   599             2. size(s) = size(t) and s=f(...) and t=g(...) and f<g or
   600             3. size(s) = size(t) and s=f(s1..sn) and t=f(t1..tn) and
   601                (s1..sn) < (t1..tn) (lexicographically)*)
   602 
   603 fun indexname_ord ((x, i), (y, j)) =
   604   (case int_ord (i, j) of EQUAL => string_ord (x, y) | ord => ord);
   605 
   606 local
   607 
   608 fun hd_depth (t $ _, n) = hd_depth (t, n + 1)
   609   | hd_depth p = p;
   610 
   611 fun dest_hd (Const (a, T)) = (((a, 0), T), 0)
   612   | dest_hd (Free (a, T)) = (((a, 0), T), 1)
   613   | dest_hd (Var v) = (v, 2)
   614   | dest_hd (Bound i) = ((("", i), dummyT), 3)
   615   | dest_hd (Abs (_, T, _)) = ((("", 0), T), 4);
   616 
   617 in
   618 
   619 fun term_ord tu =
   620   if pointer_eq tu then EQUAL
   621   else
   622     (case tu of
   623       (Abs (_, T, t), Abs(_, U, u)) =>
   624         (case term_ord (t, u) of EQUAL => typ_ord (T, U) | ord => ord)
   625     | (t, u) =>
   626         (case int_ord (size_of_term t, size_of_term u) of
   627           EQUAL =>
   628             (case prod_ord hd_ord int_ord (hd_depth (t, 0), hd_depth (u, 0)) of
   629               EQUAL => args_ord (t, u) | ord => ord)
   630         | ord => ord))
   631 and hd_ord (f, g) =
   632   prod_ord (prod_ord indexname_ord typ_ord) int_ord (dest_hd f, dest_hd g)
   633 and args_ord (f $ t, g $ u) =
   634       (case args_ord (f, g) of EQUAL => term_ord (t, u) | ord => ord)
   635   | args_ord _ = EQUAL;
   636 
   637 fun termless tu = (term_ord tu = LESS);
   638 
   639 end;
   640 
   641 
   642 (** Lexicographic path order on terms **)
   643 
   644 (*
   645   See Baader & Nipkow, Term rewriting, CUP 1998.
   646   Without variables.  Const, Var, Bound, Free and Abs are treated all as
   647   constants.
   648 
   649   f_ord maps strings to integers and serves two purposes:
   650   - Predicate on constant symbols.  Those that are not recognised by f_ord
   651     must be mapped to ~1.
   652   - Order on the recognised symbols.  These must be mapped to distinct
   653     integers >= 0.
   654 
   655 *)
   656 
   657 local
   658 fun dest_hd f_ord (Const (a, T)) =
   659       let val ord = f_ord a in
   660         if ord = ~1 then ((1, ((a, 0), T)), 0) else ((0, (("", ord), T)), 0)
   661       end
   662   | dest_hd _ (Free (a, T)) = ((1, ((a, 0), T)), 0)
   663   | dest_hd _ (Var v) = ((1, v), 1)
   664   | dest_hd _ (Bound i) = ((1, (("", i), dummyT)), 2)
   665   | dest_hd _ (Abs (_, T, _)) = ((1, (("", 0), T)), 3);
   666 
   667 fun term_lpo f_ord (s, t) =
   668   let val (f, ss) = strip_comb s and (g, ts) = strip_comb t in
   669     if forall (fn si => term_lpo f_ord (si, t) = LESS) ss
   670     then case hd_ord f_ord (f, g) of
   671         GREATER =>
   672           if forall (fn ti => term_lpo f_ord (s, ti) = GREATER) ts
   673           then GREATER else LESS
   674       | EQUAL =>
   675           if forall (fn ti => term_lpo f_ord (s, ti) = GREATER) ts
   676           then list_ord (term_lpo f_ord) (ss, ts)
   677           else LESS
   678       | LESS => LESS
   679     else GREATER
   680   end
   681 and hd_ord f_ord (f, g) = case (f, g) of
   682     (Abs (_, T, t), Abs (_, U, u)) =>
   683       (case term_lpo f_ord (t, u) of EQUAL => typ_ord (T, U) | ord => ord)
   684   | (_, _) => prod_ord (prod_ord int_ord
   685                   (prod_ord indexname_ord typ_ord)) int_ord
   686                 (dest_hd f_ord f, dest_hd f_ord g)
   687 in
   688 val term_lpo = term_lpo
   689 end;
   690 
   691 
   692 (** Connectives of higher order logic **)
   693 
   694 fun aT S = TFree ("'a", S);
   695 
   696 fun itselfT ty = Type ("itself", [ty]);
   697 val a_itselfT = itselfT (TFree ("'a", []));
   698 
   699 val propT : typ = Type("prop",[]);
   700 
   701 val implies = Const("==>", propT-->propT-->propT);
   702 
   703 fun all T = Const("all", (T-->propT)-->propT);
   704 
   705 fun equals T = Const("==", T-->T-->propT);
   706 
   707 (* maps  !!x1...xn. t   to   t  *)
   708 fun strip_all_body (Const("all",_)$Abs(_,_,t))  =  strip_all_body t
   709   | strip_all_body t  =  t;
   710 
   711 (* maps  !!x1...xn. t   to   [x1, ..., xn]  *)
   712 fun strip_all_vars (Const("all",_)$Abs(a,T,t))  =
   713                 (a,T) :: strip_all_vars t
   714   | strip_all_vars t  =  [] : (string*typ) list;
   715 
   716 (*increments a term's non-local bound variables
   717   required when moving a term within abstractions
   718      inc is  increment for bound variables
   719      lev is  level at which a bound variable is considered 'loose'*)
   720 fun incr_bv (inc, lev, u as Bound i) = if i>=lev then Bound(i+inc) else u
   721   | incr_bv (inc, lev, Abs(a,T,body)) =
   722         Abs(a, T, incr_bv(inc,lev+1,body))
   723   | incr_bv (inc, lev, f$t) =
   724       incr_bv(inc,lev,f) $ incr_bv(inc,lev,t)
   725   | incr_bv (inc, lev, u) = u;
   726 
   727 fun incr_boundvars  0  t = t
   728   | incr_boundvars inc t = incr_bv(inc,0,t);
   729 
   730 (*Scan a pair of terms; while they are similar,
   731   accumulate corresponding bound vars in "al"*)
   732 fun match_bvs(Abs(x,_,s),Abs(y,_,t), al) =
   733       match_bvs(s, t, if x="" orelse y="" then al
   734                                           else (x,y)::al)
   735   | match_bvs(f$s, g$t, al) = match_bvs(f,g,match_bvs(s,t,al))
   736   | match_bvs(_,_,al) = al;
   737 
   738 (* strip abstractions created by parameters *)
   739 fun match_bvars((s,t),al) = match_bvs(strip_abs_body s, strip_abs_body t, al);
   740 
   741 fun rename_abs pat obj t =
   742   let
   743     val ren = match_bvs (pat, obj, []);
   744     fun ren_abs (Abs (x, T, b)) =
   745           Abs (the_default x (AList.lookup (op =) ren x), T, ren_abs b)
   746       | ren_abs (f $ t) = ren_abs f $ ren_abs t
   747       | ren_abs t = t
   748   in if null ren then NONE else SOME (ren_abs t) end;
   749 
   750 (*Accumulate all 'loose' bound vars referring to level 'lev' or beyond.
   751    (Bound 0) is loose at level 0 *)
   752 fun add_loose_bnos (Bound i, lev, js) =
   753         if i<lev then js  else  (i-lev) ins_int js
   754   | add_loose_bnos (Abs (_,_,t), lev, js) = add_loose_bnos (t, lev+1, js)
   755   | add_loose_bnos (f$t, lev, js) =
   756         add_loose_bnos (f, lev, add_loose_bnos (t, lev, js))
   757   | add_loose_bnos (_, _, js) = js;
   758 
   759 fun loose_bnos t = add_loose_bnos (t, 0, []);
   760 
   761 (* loose_bvar(t,k) iff t contains a 'loose' bound variable referring to
   762    level k or beyond. *)
   763 fun loose_bvar(Bound i,k) = i >= k
   764   | loose_bvar(f$t, k) = loose_bvar(f,k) orelse loose_bvar(t,k)
   765   | loose_bvar(Abs(_,_,t),k) = loose_bvar(t,k+1)
   766   | loose_bvar _ = false;
   767 
   768 fun loose_bvar1(Bound i,k) = i = k
   769   | loose_bvar1(f$t, k) = loose_bvar1(f,k) orelse loose_bvar1(t,k)
   770   | loose_bvar1(Abs(_,_,t),k) = loose_bvar1(t,k+1)
   771   | loose_bvar1 _ = false;
   772 
   773 (*Substitute arguments for loose bound variables.
   774   Beta-reduction of arg(n-1)...arg0 into t replacing (Bound i) with (argi).
   775   Note that for ((%x y. c) a b), the bound vars in c are x=1 and y=0
   776         and the appropriate call is  subst_bounds([b,a], c) .
   777   Loose bound variables >=n are reduced by "n" to
   778      compensate for the disappearance of lambdas.
   779 *)
   780 fun subst_bounds (args: term list, t) : term =
   781   let
   782     exception SAME;
   783     val n = length args;
   784     fun subst (t as Bound i, lev) =
   785          (if i < lev then raise SAME   (*var is locally bound*)
   786           else incr_boundvars lev (List.nth (args, i - lev))
   787             handle Subscript => Bound (i - n))  (*loose: change it*)
   788       | subst (Abs (a, T, body), lev) = Abs (a, T, subst (body, lev + 1))
   789       | subst (f $ t, lev) =
   790           (subst (f, lev) $ (subst (t, lev) handle SAME => t) handle SAME => f $ subst (t, lev))
   791       | subst _ = raise SAME;
   792   in case args of [] => t | _ => (subst (t, 0) handle SAME => t) end;
   793 
   794 (*Special case: one argument*)
   795 fun subst_bound (arg, t) : term =
   796   let
   797     exception SAME;
   798     fun subst (Bound i, lev) =
   799           if i < lev then raise SAME   (*var is locally bound*)
   800           else if i = lev then incr_boundvars lev arg
   801           else Bound (i - 1)   (*loose: change it*)
   802       | subst (Abs (a, T, body), lev) = Abs (a, T, subst (body, lev + 1))
   803       | subst (f $ t, lev) =
   804           (subst (f, lev) $ (subst (t, lev) handle SAME => t) handle SAME => f $ subst (t, lev))
   805       | subst _ = raise SAME;
   806   in subst (t, 0) handle SAME => t end;
   807 
   808 (*beta-reduce if possible, else form application*)
   809 fun betapply (Abs(_,_,t), u) = subst_bound (u,t)
   810   | betapply (f,u) = f$u;
   811 
   812 val betapplys = Library.foldl betapply;
   813 
   814 
   815 (*unfolding abstractions with substitution
   816   of bound variables and implicit eta-expansion*)
   817 fun strip_abs_eta k t =
   818   let
   819     val used = fold_aterms (fn Free (v, _) => Name.declare v | _ => I) t Name.context;
   820     fun strip_abs t (0, used) = (([], t), (0, used))
   821       | strip_abs (Abs (v, T, t)) (k, used) =
   822           let
   823             val ([v'], used') = Name.variants [v] used;
   824             val t' = subst_bound (Free (v, T), t);
   825             val ((vs, t''), (k', used'')) = strip_abs t' (k - 1, used');
   826           in (((v', T) :: vs, t''), (k', used'')) end
   827       | strip_abs t (k, used) = (([], t), (k, used));
   828     fun expand_eta [] t _ = ([], t)
   829       | expand_eta (T::Ts) t used =
   830           let
   831             val ([v], used') = Name.variants [""] used;
   832             val (vs, t') = expand_eta Ts (t $ Free (v, T)) used';
   833           in ((v, T) :: vs, t') end;
   834     val ((vs1, t'), (k', used')) = strip_abs t (k, used);
   835     val Ts = (fst o chop k' o fst o strip_type o fastype_of) t';
   836     val (vs2, t'') = expand_eta Ts t' used';
   837   in (vs1 @ vs2, t'') end;
   838 
   839 
   840 (** Specialized equality, membership, insertion etc. **)
   841 
   842 (* variables *)
   843 
   844 fun eq_ix ((x, i): indexname, (y, j)) = i = j andalso x = y;
   845 
   846 fun eq_tvar ((xi, S: sort), (xi', S')) = eq_ix (xi, xi') andalso S = S';
   847 fun eq_var ((xi, T: typ), (xi', T')) = eq_ix (xi, xi') andalso T = T';
   848 
   849 val tvar_ord = prod_ord indexname_ord sort_ord;
   850 val var_ord = prod_ord indexname_ord typ_ord;
   851 
   852 
   853 (*A fast unification filter: true unless the two terms cannot be unified.
   854   Terms must be NORMAL.  Treats all Vars as distinct. *)
   855 fun could_unify (t,u) =
   856   let fun matchrands (f$t, g$u) = could_unify(t,u) andalso  matchrands(f,g)
   857         | matchrands _ = true
   858   in case (head_of t , head_of u) of
   859         (_, Var _) => true
   860       | (Var _, _) => true
   861       | (Const(a,_), Const(b,_)) =>  a=b andalso matchrands(t,u)
   862       | (Free(a,_), Free(b,_)) =>  a=b andalso matchrands(t,u)
   863       | (Bound i, Bound j) =>  i=j andalso matchrands(t,u)
   864       | (Abs _, _) =>  true   (*because of possible eta equality*)
   865       | (_, Abs _) =>  true
   866       | _ => false
   867   end;
   868 
   869 (*Substitute new for free occurrences of old in a term*)
   870 fun subst_free [] = (fn t=>t)
   871   | subst_free pairs =
   872       let fun substf u =
   873             case AList.lookup (op aconv) pairs u of
   874                 SOME u' => u'
   875               | NONE => (case u of Abs(a,T,t) => Abs(a, T, substf t)
   876                                  | t$u' => substf t $ substf u'
   877                                  | _ => u)
   878       in  substf  end;
   879 
   880 (*Abstraction of the term "body" over its occurrences of v,
   881     which must contain no loose bound variables.
   882   The resulting term is ready to become the body of an Abs.*)
   883 fun abstract_over (v, body) =
   884   let
   885     exception SAME;
   886     fun abs lev tm =
   887       if v aconv tm then Bound lev
   888       else
   889         (case tm of
   890           Abs (a, T, t) => Abs (a, T, abs (lev + 1) t)
   891         | t $ u => (abs lev t $ (abs lev u handle SAME => u) handle SAME => t $ abs lev u)
   892         | _ => raise SAME);
   893   in abs 0 body handle SAME => body end;
   894 
   895 fun lambda (v as Const (x, T)) t = Abs (NameSpace.base x, T, abstract_over (v, t))
   896   | lambda (v as Free (x, T)) t = Abs (x, T, abstract_over (v, t))
   897   | lambda (v as Var ((x, _), T)) t = Abs (x, T, abstract_over (v, t))
   898   | lambda v t = raise TERM ("lambda", [v, t]);
   899 
   900 (*Form an abstraction over a free variable.*)
   901 fun absfree (a,T,body) = Abs(a, T, abstract_over (Free(a,T), body));
   902 fun absdummy (T, body) = Abs ("uu", T, body);
   903 
   904 (*Abstraction over a list of free variables*)
   905 fun list_abs_free ([ ] ,     t) = t
   906   | list_abs_free ((a,T)::vars, t) =
   907       absfree(a, T, list_abs_free(vars,t));
   908 
   909 (*Quantification over a list of free variables*)
   910 fun list_all_free ([], t: term) = t
   911   | list_all_free ((a,T)::vars, t) =
   912         (all T) $ (absfree(a, T, list_all_free(vars,t)));
   913 
   914 (*Quantification over a list of variables (already bound in body) *)
   915 fun list_all ([], t) = t
   916   | list_all ((a,T)::vars, t) =
   917         (all T) $ (Abs(a, T, list_all(vars,t)));
   918 
   919 (*Replace the ATOMIC term ti by ui;    inst = [(t1,u1), ..., (tn,un)].
   920   A simultaneous substitution:  [ (a,b), (b,a) ] swaps a and b.  *)
   921 fun subst_atomic [] tm = tm
   922   | subst_atomic inst tm =
   923       let
   924         fun subst (Abs (a, T, body)) = Abs (a, T, subst body)
   925           | subst (t $ u) = subst t $ subst u
   926           | subst t = the_default t (AList.lookup (op aconv) inst t);
   927       in subst tm end;
   928 
   929 (*Replace the ATOMIC type Ti by Ui;    inst = [(T1,U1), ..., (Tn,Un)].*)
   930 fun typ_subst_atomic [] ty = ty
   931   | typ_subst_atomic inst ty =
   932       let
   933         fun subst (Type (a, Ts)) = Type (a, map subst Ts)
   934           | subst T = the_default T (AList.lookup (op = : typ * typ -> bool) inst T);
   935       in subst ty end;
   936 
   937 fun subst_atomic_types [] tm = tm
   938   | subst_atomic_types inst tm = map_term_types (typ_subst_atomic inst) tm;
   939 
   940 fun typ_subst_TVars [] ty = ty
   941   | typ_subst_TVars inst ty =
   942       let
   943         fun subst (Type (a, Ts)) = Type (a, map subst Ts)
   944           | subst (T as TVar (xi, _)) = the_default T (AList.lookup (op =) inst xi)
   945           | subst T = T;
   946       in subst ty end;
   947 
   948 fun subst_TVars [] tm = tm
   949   | subst_TVars inst tm = map_term_types (typ_subst_TVars inst) tm;
   950 
   951 fun subst_Vars [] tm = tm
   952   | subst_Vars inst tm =
   953       let
   954         fun subst (t as Var (xi, _)) = the_default t (AList.lookup (op =) inst xi)
   955           | subst (Abs (a, T, t)) = Abs (a, T, subst t)
   956           | subst (t $ u) = subst t $ subst u
   957           | subst t = t;
   958       in subst tm end;
   959 
   960 fun subst_vars ([], []) tm = tm
   961   | subst_vars ([], inst) tm = subst_Vars inst tm
   962   | subst_vars (instT, inst) tm =
   963       let
   964         fun subst (Const (a, T)) = Const (a, typ_subst_TVars instT T)
   965           | subst (Free (a, T)) = Free (a, typ_subst_TVars instT T)
   966           | subst (t as Var (xi, T)) =
   967               (case AList.lookup (op =) inst xi of
   968                 NONE => Var (xi, typ_subst_TVars instT T)
   969               | SOME t => t)
   970           | subst (t as Bound _) = t
   971           | subst (Abs (a, T, t)) = Abs (a, typ_subst_TVars instT T, subst t)
   972           | subst (t $ u) = subst t $ subst u;
   973       in subst tm end;
   974 
   975 
   976 (* generalization of fixed variables *)
   977 
   978 local exception SAME in
   979 
   980 fun generalizeT_same [] _ _ = raise SAME
   981   | generalizeT_same tfrees idx ty =
   982       let
   983         fun gen_typ (Type (a, Ts)) = Type (a, gen_typs Ts)
   984           | gen_typ (TFree (a, S)) =
   985               if member (op =) tfrees a then TVar ((a, idx), S)
   986               else raise SAME
   987           | gen_typ _ = raise SAME
   988         and gen_typs (T :: Ts) =
   989             (gen_typ T :: (gen_typs Ts handle SAME => Ts)
   990               handle SAME => T :: gen_typs Ts)
   991           | gen_typs [] = raise SAME;
   992       in gen_typ ty end;
   993 
   994 fun generalize_same ([], []) _ _ = raise SAME
   995   | generalize_same (tfrees, frees) idx tm =
   996       let
   997         val genT = generalizeT_same tfrees idx;
   998         fun gen (Free (x, T)) =
   999               if member (op =) frees x then
  1000                 Var (Name.clean_index (x, idx), genT T handle SAME => T)
  1001               else Free (x, genT T)
  1002           | gen (Var (xi, T)) = Var (xi, genT T)
  1003           | gen (Const (c, T)) = Const (c, genT T)
  1004           | gen (Bound _) = raise SAME
  1005           | gen (Abs (x, T, t)) =
  1006               (Abs (x, genT T, gen t handle SAME => t)
  1007                 handle SAME => Abs (x, T, gen t))
  1008           | gen (t $ u) = (gen t $ (gen u handle SAME => u) handle SAME => t $ gen u);
  1009       in gen tm end;
  1010 
  1011 fun generalize names i tm = generalize_same names i tm handle SAME => tm;
  1012 fun generalizeT names i ty = generalizeT_same names i ty handle SAME => ty;
  1013 
  1014 fun generalize_option names i tm = SOME (generalize_same names i tm) handle SAME => NONE;
  1015 fun generalizeT_option names i ty = SOME (generalizeT_same names i ty) handle SAME => NONE;
  1016 
  1017 end;
  1018 
  1019 
  1020 (* instantiation of schematic variables (types before terms) *)
  1021 
  1022 local exception SAME in
  1023 
  1024 fun instantiateT_same [] _ = raise SAME
  1025   | instantiateT_same instT ty =
  1026       let
  1027         fun subst_typ (Type (a, Ts)) = Type (a, subst_typs Ts)
  1028           | subst_typ (TVar v) =
  1029               (case AList.lookup eq_tvar instT v of
  1030                 SOME T => T
  1031               | NONE => raise SAME)
  1032           | subst_typ _ = raise SAME
  1033         and subst_typs (T :: Ts) =
  1034             (subst_typ T :: (subst_typs Ts handle SAME => Ts)
  1035               handle SAME => T :: subst_typs Ts)
  1036           | subst_typs [] = raise SAME;
  1037       in subst_typ ty end;
  1038 
  1039 fun instantiate_same ([], []) _ = raise SAME
  1040   | instantiate_same (instT, inst) tm =
  1041       let
  1042         val substT = instantiateT_same instT;
  1043         fun subst (Const (c, T)) = Const (c, substT T)
  1044           | subst (Free (x, T)) = Free (x, substT T)
  1045           | subst (Var (xi, T)) =
  1046               let val (T', same) = (substT T, false) handle SAME => (T, true) in
  1047                 (case AList.lookup eq_var inst (xi, T') of
  1048                    SOME t => t
  1049                  | NONE => if same then raise SAME else Var (xi, T'))
  1050               end
  1051           | subst (Bound _) = raise SAME
  1052           | subst (Abs (x, T, t)) =
  1053               (Abs (x, substT T, subst t handle SAME => t)
  1054                 handle SAME => Abs (x, T, subst t))
  1055           | subst (t $ u) = (subst t $ (subst u handle SAME => u) handle SAME => t $ subst u);
  1056       in subst tm end;
  1057 
  1058 fun instantiate insts tm = instantiate_same insts tm handle SAME => tm;
  1059 fun instantiateT insts ty = instantiateT_same insts ty handle SAME => ty;
  1060 
  1061 fun instantiate_option insts tm = SOME (instantiate_same insts tm) handle SAME => NONE;
  1062 fun instantiateT_option insts ty = SOME (instantiateT_same insts ty) handle SAME => NONE;
  1063 
  1064 end;
  1065 
  1066 
  1067 (** Identifying first-order terms **)
  1068 
  1069 (*Argument Ts is a reverse list of binder types, needed if term t contains Bound vars*)
  1070 fun has_not_funtype Ts t = not (is_funtype (fastype_of1 (Ts,t)));
  1071 
  1072 (*First order means in all terms of the form f(t1,...,tn) no argument has a
  1073   function type. The supplied quantifiers are excluded: their argument always
  1074   has a function type through a recursive call into its body.*)
  1075 fun is_first_order quants =
  1076   let fun first_order1 Ts (Abs (_,T,body)) = first_order1 (T::Ts) body
  1077         | first_order1 Ts (Const(q,_) $ Abs(a,T,body)) =
  1078             q mem_string quants  andalso   (*it is a known quantifier*)
  1079             not (is_funtype T)   andalso first_order1 (T::Ts) body
  1080         | first_order1 Ts t =
  1081             case strip_comb t of
  1082                  (Var _, ts) => forall (first_order1 Ts andf has_not_funtype Ts) ts
  1083                | (Free _, ts) => forall (first_order1 Ts andf has_not_funtype Ts) ts
  1084                | (Const _, ts) => forall (first_order1 Ts andf has_not_funtype Ts) ts
  1085                | (Bound _, ts) => forall (first_order1 Ts andf has_not_funtype Ts) ts
  1086                | (Abs _, ts) => false (*not in beta-normal form*)
  1087                | _ => error "first_order: unexpected case"
  1088     in  first_order1 []  end;
  1089 
  1090 
  1091 (* maximum index of typs and terms *)
  1092 
  1093 fun maxidx_typ (TVar ((_, j), _)) i = Int.max (i, j)
  1094   | maxidx_typ (Type (_, Ts)) i = maxidx_typs Ts i
  1095   | maxidx_typ (TFree _) i = i
  1096 and maxidx_typs [] i = i
  1097   | maxidx_typs (T :: Ts) i = maxidx_typs Ts (maxidx_typ T i);
  1098 
  1099 fun maxidx_term (Var ((_, j), T)) i = maxidx_typ T (Int.max (i, j))
  1100   | maxidx_term (Const (_, T)) i = maxidx_typ T i
  1101   | maxidx_term (Free (_, T)) i = maxidx_typ T i
  1102   | maxidx_term (Bound _) i = i
  1103   | maxidx_term (Abs (_, T, t)) i = maxidx_term t (maxidx_typ T i)
  1104   | maxidx_term (t $ u) i = maxidx_term u (maxidx_term t i);
  1105 
  1106 fun maxidx_of_typ T = maxidx_typ T ~1;
  1107 fun maxidx_of_typs Ts = maxidx_typs Ts ~1;
  1108 fun maxidx_of_term t = maxidx_term t ~1;
  1109 
  1110 
  1111 
  1112 (**** Syntax-related declarations ****)
  1113 
  1114 (* substructure *)
  1115 
  1116 fun exists_subtype P =
  1117   let
  1118     fun ex ty = P ty orelse
  1119       (case ty of Type (_, Ts) => exists ex Ts | _ => false);
  1120   in ex end;
  1121 
  1122 fun exists_subterm P =
  1123   let
  1124     fun ex tm = P tm orelse
  1125       (case tm of
  1126         t $ u => ex t orelse ex u
  1127       | Abs (_, _, t) => ex t
  1128       | _ => false);
  1129   in ex end;
  1130 
  1131 
  1132 (** Consts etc. **)
  1133 
  1134 fun add_term_consts (Const (c, _), cs) = insert (op =) c cs
  1135   | add_term_consts (t $ u, cs) = add_term_consts (t, add_term_consts (u, cs))
  1136   | add_term_consts (Abs (_, _, t), cs) = add_term_consts (t, cs)
  1137   | add_term_consts (_, cs) = cs;
  1138 
  1139 fun term_consts t = add_term_consts(t,[]);
  1140 
  1141 fun exists_Const P = exists_subterm (fn Const c => P c | _ => false);
  1142 
  1143 
  1144 (** TFrees and TVars **)
  1145 
  1146 (*Accumulates the names of Frees in the term, suppressing duplicates.*)
  1147 fun add_term_free_names (Free(a,_), bs) = a ins_string bs
  1148   | add_term_free_names (f$u, bs) = add_term_free_names (f, add_term_free_names(u, bs))
  1149   | add_term_free_names (Abs(_,_,t), bs) = add_term_free_names(t,bs)
  1150   | add_term_free_names (_, bs) = bs;
  1151 
  1152 (*Accumulates the names in the term, suppressing duplicates.
  1153   Includes Frees and Consts.  For choosing unambiguous bound var names.*)
  1154 fun add_term_names (Const(a,_), bs) = NameSpace.base a ins_string bs
  1155   | add_term_names (Free(a,_), bs) = a ins_string bs
  1156   | add_term_names (f$u, bs) = add_term_names (f, add_term_names(u, bs))
  1157   | add_term_names (Abs(_,_,t), bs) = add_term_names(t,bs)
  1158   | add_term_names (_, bs) = bs;
  1159 
  1160 (*Accumulates the TVars in a type, suppressing duplicates. *)
  1161 fun add_typ_tvars(Type(_,Ts),vs) = foldr add_typ_tvars vs Ts
  1162   | add_typ_tvars(TFree(_),vs) = vs
  1163   | add_typ_tvars(TVar(v),vs) = insert (op =) v vs;
  1164 
  1165 (*Accumulates the TFrees in a type, suppressing duplicates. *)
  1166 fun add_typ_tfree_names(Type(_,Ts),fs) = foldr add_typ_tfree_names fs Ts
  1167   | add_typ_tfree_names(TFree(f,_),fs) = f ins_string fs
  1168   | add_typ_tfree_names(TVar(_),fs) = fs;
  1169 
  1170 fun add_typ_tfrees(Type(_,Ts),fs) = foldr add_typ_tfrees fs Ts
  1171   | add_typ_tfrees(TFree(f),fs) = insert (op =) f fs
  1172   | add_typ_tfrees(TVar(_),fs) = fs;
  1173 
  1174 fun add_typ_varnames(Type(_,Ts),nms) = foldr add_typ_varnames nms Ts
  1175   | add_typ_varnames(TFree(nm,_),nms) = nm ins_string nms
  1176   | add_typ_varnames(TVar((nm,_),_),nms) = nm ins_string nms;
  1177 
  1178 (*Accumulates the TVars in a term, suppressing duplicates. *)
  1179 val add_term_tvars = it_term_types add_typ_tvars;
  1180 
  1181 (*Accumulates the TFrees in a term, suppressing duplicates. *)
  1182 val add_term_tfrees = it_term_types add_typ_tfrees;
  1183 val add_term_tfree_names = it_term_types add_typ_tfree_names;
  1184 
  1185 val add_term_tvarnames = it_term_types add_typ_varnames;
  1186 
  1187 (*Non-list versions*)
  1188 fun typ_tfrees T = add_typ_tfrees(T,[]);
  1189 fun typ_tvars T = add_typ_tvars(T,[]);
  1190 fun term_tfrees t = add_term_tfrees(t,[]);
  1191 fun term_tvars t = add_term_tvars(t,[]);
  1192 
  1193 (*special code to enforce left-to-right collection of TVar-indexnames*)
  1194 
  1195 fun add_typ_ixns(ixns,Type(_,Ts)) = Library.foldl add_typ_ixns (ixns,Ts)
  1196   | add_typ_ixns(ixns,TVar(ixn,_)) = if member (op =) ixns ixn then ixns
  1197                                      else ixns@[ixn]
  1198   | add_typ_ixns(ixns,TFree(_)) = ixns;
  1199 
  1200 fun add_term_tvar_ixns(Const(_,T),ixns) = add_typ_ixns(ixns,T)
  1201   | add_term_tvar_ixns(Free(_,T),ixns) = add_typ_ixns(ixns,T)
  1202   | add_term_tvar_ixns(Var(_,T),ixns) = add_typ_ixns(ixns,T)
  1203   | add_term_tvar_ixns(Bound _,ixns) = ixns
  1204   | add_term_tvar_ixns(Abs(_,T,t),ixns) =
  1205       add_term_tvar_ixns(t,add_typ_ixns(ixns,T))
  1206   | add_term_tvar_ixns(f$t,ixns) =
  1207       add_term_tvar_ixns(t,add_term_tvar_ixns(f,ixns));
  1208 
  1209 
  1210 (** Frees and Vars **)
  1211 
  1212 (*Accumulates the Vars in the term, suppressing duplicates*)
  1213 fun add_term_vars (t, vars: term list) = case t of
  1214     Var   _ => OrdList.insert term_ord t vars
  1215   | Abs (_,_,body) => add_term_vars(body,vars)
  1216   | f$t =>  add_term_vars (f, add_term_vars(t, vars))
  1217   | _ => vars;
  1218 
  1219 fun term_vars t = add_term_vars(t,[]);
  1220 
  1221 (*Accumulates the Frees in the term, suppressing duplicates*)
  1222 fun add_term_frees (t, frees: term list) = case t of
  1223     Free   _ => OrdList.insert term_ord t frees
  1224   | Abs (_,_,body) => add_term_frees(body,frees)
  1225   | f$t =>  add_term_frees (f, add_term_frees(t, frees))
  1226   | _ => frees;
  1227 
  1228 fun term_frees t = add_term_frees(t,[]);
  1229 
  1230 (*Given an abstraction over P, replaces the bound variable by a Free variable
  1231   having a unique name -- SLOW!*)
  1232 fun variant_abs (a,T,P) =
  1233   let val b = Name.variant (add_term_names(P,[])) a
  1234   in  (b,  subst_bound (Free(b,T), P))  end;
  1235 
  1236 fun dest_abs (x, T, body) =
  1237   let
  1238     fun name_clash (Free (y, _)) = (x = y)
  1239       | name_clash (t $ u) = name_clash t orelse name_clash u
  1240       | name_clash (Abs (_, _, t)) = name_clash t
  1241       | name_clash _ = false;
  1242   in
  1243     if name_clash body then
  1244       dest_abs (Name.variant [x] x, T, body)    (*potentially slow, but rarely happens*)
  1245     else (x, subst_bound (Free (x, T), body))
  1246   end;
  1247 
  1248 (* renames and reverses the strings in vars away from names *)
  1249 fun rename_aTs names vars : (string*typ)list =
  1250   let fun rename_aT (vars,(a,T)) =
  1251                 (Name.variant (map #1 vars @ names) a, T) :: vars
  1252   in Library.foldl rename_aT ([],vars) end;
  1253 
  1254 fun rename_wrt_term t = rename_aTs (add_term_names(t,[]));
  1255 
  1256 
  1257 (* zero var indexes *)
  1258 
  1259 fun zero_var_inst vars =
  1260   fold (fn v as ((x, i), X) => fn (used, inst) =>
  1261     let
  1262       val ([x'], used') = Name.variants [if Name.is_bound x then "u" else x] used;
  1263     in if x = x' andalso i = 0 then (used', inst) else (used', (v, ((x', 0), X)) :: inst) end)
  1264   vars (Name.context, []) |> #2;
  1265 
  1266 fun zero_var_indexesT ty =
  1267   instantiateT (map (apsnd TVar) (zero_var_inst (sort tvar_ord (add_tvarsT ty [])))) ty;
  1268 
  1269 fun zero_var_indexes_inst tm =
  1270   let
  1271     val instT = map (apsnd TVar) (zero_var_inst (sort tvar_ord (fold_types add_tvarsT tm [])));
  1272     val inst =
  1273       add_vars tm [] |> map (apsnd (instantiateT instT))
  1274       |> sort var_ord |> zero_var_inst |> map (apsnd Var);
  1275   in (instT, inst) end;
  1276 
  1277 fun zero_var_indexes tm = instantiate (zero_var_indexes_inst tm) tm;
  1278 
  1279 
  1280 (* dummy patterns *)
  1281 
  1282 val dummy_patternN = "dummy_pattern";
  1283 
  1284 fun dummy_pattern T = Const (dummy_patternN, T);
  1285 
  1286 fun is_dummy_pattern (Const ("dummy_pattern", _)) = true
  1287   | is_dummy_pattern _ = false;
  1288 
  1289 fun no_dummy_patterns tm =
  1290   if not (fold_aterms (fn t => fn b => b orelse is_dummy_pattern t) tm false) then tm
  1291   else raise TERM ("Illegal occurrence of '_' dummy pattern", [tm]);
  1292 
  1293 fun replace_dummy Ts (i, Const ("dummy_pattern", T)) =
  1294       (i + 1, list_comb (Var (("_dummy_", i), Ts ---> T), map Bound (0 upto length Ts - 1)))
  1295   | replace_dummy Ts (i, Abs (x, T, t)) =
  1296       let val (i', t') = replace_dummy (T :: Ts) (i, t)
  1297       in (i', Abs (x, T, t')) end
  1298   | replace_dummy Ts (i, t $ u) =
  1299       let val (i', t') = replace_dummy Ts (i, t); val (i'', u') = replace_dummy Ts (i', u)
  1300       in (i'', t' $ u') end
  1301   | replace_dummy _ (i, a) = (i, a);
  1302 
  1303 val replace_dummy_patterns = replace_dummy [];
  1304 
  1305 fun is_replaced_dummy_pattern ("_dummy_", _) = true
  1306   | is_replaced_dummy_pattern _ = false;
  1307 
  1308 fun show_dummy_patterns (Var (("_dummy_", _), T)) = Const ("dummy_pattern", T)
  1309   | show_dummy_patterns (t $ u) = show_dummy_patterns t $ show_dummy_patterns u
  1310   | show_dummy_patterns (Abs (x, T, t)) = Abs (x, T, show_dummy_patterns t)
  1311   | show_dummy_patterns a = a;
  1312 
  1313 
  1314 (* display variables *)
  1315 
  1316 val show_question_marks = ref true;
  1317 
  1318 fun string_of_vname (x, i) =
  1319   let
  1320     val question_mark = if ! show_question_marks then "?" else "";
  1321     val idx = string_of_int i;
  1322     val dot =
  1323       (case rev (Symbol.explode x) of
  1324         _ :: "\\<^isub>" :: _ => false
  1325       | _ :: "\\<^isup>" :: _ => false
  1326       | c :: _ => Symbol.is_digit c
  1327       | _ => true);
  1328   in
  1329     if dot then question_mark ^ x ^ "." ^ idx
  1330     else if i <> 0 then question_mark ^ x ^ idx
  1331     else question_mark ^ x
  1332   end;
  1333 
  1334 fun string_of_vname' (x, ~1) = x
  1335   | string_of_vname' xi = string_of_vname xi;
  1336 
  1337 end;
  1338 
  1339 structure BasicTerm: BASIC_TERM = Term;
  1340 open BasicTerm;