src/Pure/meta_simplifier.ML
author haftmann
Tue Sep 06 08:30:43 2005 +0200 (2005-09-06)
changeset 17271 2756a73f63a5
parent 17232 148c241d2492
child 17496 26535df536ae
permissions -rw-r--r--
introduced some new-style AList operations
     1 (*  Title:      Pure/meta_simplifier.ML
     2     ID:         $Id$
     3     Author:     Tobias Nipkow and Stefan Berghofer
     4 
     5 Meta-level Simplification.
     6 *)
     7 
     8 infix 4
     9   addsimps delsimps addeqcongs deleqcongs addcongs delcongs addsimprocs delsimprocs
    10   setmksimps setmkcong setmksym setmkeqTrue settermless setsubgoaler
    11   setloop addloop delloop setSSolver addSSolver setSolver addSolver;
    12 
    13 signature BASIC_META_SIMPLIFIER =
    14 sig
    15   val debug_simp: bool ref
    16   val trace_simp: bool ref
    17   val simp_depth_limit: int ref
    18   val trace_simp_depth_limit: int ref
    19   type rrule
    20   val eq_rrule: rrule * rrule -> bool
    21   type cong
    22   type solver
    23   val mk_solver: string -> (thm list -> int -> tactic) -> solver
    24   type simpset
    25   type proc
    26   val rep_ss: simpset ->
    27    {rules: rrule Net.net,
    28     prems: thm list,
    29     bounds: int * (string * (string * typ)) list} *
    30    {congs: (string * cong) list * string list,
    31     procs: proc Net.net,
    32     mk_rews:
    33      {mk: thm -> thm list,
    34       mk_cong: thm -> thm,
    35       mk_sym: thm -> thm option,
    36       mk_eq_True: thm -> thm option},
    37     termless: term * term -> bool,
    38     subgoal_tac: simpset -> int -> tactic,
    39     loop_tacs: (string * (int -> tactic)) list,
    40     solvers: solver list * solver list}
    41   val print_ss: simpset -> unit
    42   val empty_ss: simpset
    43   val merge_ss: simpset * simpset -> simpset
    44   type simproc
    45   val mk_simproc: string -> cterm list ->
    46     (theory -> simpset -> term -> thm option) -> simproc
    47   val add_prems: thm list -> simpset -> simpset
    48   val prems_of_ss: simpset -> thm list
    49   val addsimps: simpset * thm list -> simpset
    50   val delsimps: simpset * thm list -> simpset
    51   val addeqcongs: simpset * thm list -> simpset
    52   val deleqcongs: simpset * thm list -> simpset
    53   val addcongs: simpset * thm list -> simpset
    54   val delcongs: simpset * thm list -> simpset
    55   val addsimprocs: simpset * simproc list -> simpset
    56   val delsimprocs: simpset * simproc list -> simpset
    57   val setmksimps: simpset * (thm -> thm list) -> simpset
    58   val setmkcong: simpset * (thm -> thm) -> simpset
    59   val setmksym: simpset * (thm -> thm option) -> simpset
    60   val setmkeqTrue: simpset * (thm -> thm option) -> simpset
    61   val settermless: simpset * (term * term -> bool) -> simpset
    62   val setsubgoaler: simpset * (simpset -> int -> tactic) -> simpset
    63   val setloop: simpset * (int -> tactic) -> simpset
    64   val addloop: simpset * (string * (int -> tactic)) -> simpset
    65   val delloop: simpset * string -> simpset
    66   val setSSolver: simpset * solver -> simpset
    67   val addSSolver: simpset * solver -> simpset
    68   val setSolver: simpset * solver -> simpset
    69   val addSolver: simpset * solver -> simpset
    70   val generic_simp_tac: bool -> bool * bool * bool -> simpset -> int -> tactic
    71 end;
    72 
    73 signature META_SIMPLIFIER =
    74 sig
    75   include BASIC_META_SIMPLIFIER
    76   exception SIMPLIFIER of string * thm
    77   val clear_ss: simpset -> simpset
    78   exception SIMPROC_FAIL of string * exn
    79   val simproc_i: theory -> string -> term list
    80     -> (theory -> simpset -> term -> thm option) -> simproc
    81   val simproc: theory -> string -> string list
    82     -> (theory -> simpset -> term -> thm option) -> simproc
    83   val inherit_bounds: simpset -> simpset -> simpset
    84   val rewrite_cterm: bool * bool * bool ->
    85     (simpset -> thm -> thm option) -> simpset -> cterm -> thm
    86   val rewrite_aux: (simpset -> thm -> thm option) -> bool -> thm list -> cterm -> thm
    87   val simplify_aux: (simpset -> thm -> thm option) -> bool -> thm list -> thm -> thm
    88   val rewrite_term: theory -> thm list -> (term -> term option) list -> term -> term
    89   val rewrite_thm: bool * bool * bool ->
    90     (simpset -> thm -> thm option) -> simpset -> thm -> thm
    91   val rewrite_goals_rule_aux: (simpset -> thm -> thm option) -> thm list -> thm -> thm
    92   val rewrite_goal_rule: bool * bool * bool ->
    93     (simpset -> thm -> thm option) -> simpset -> int -> thm -> thm
    94   val asm_rewrite_goal_tac: bool * bool * bool ->
    95     (simpset -> tactic) -> simpset -> int -> tactic
    96   val simp_thm: bool * bool * bool -> simpset -> thm -> thm
    97   val simp_cterm: bool * bool * bool -> simpset -> cterm -> thm
    98 end;
    99 
   100 structure MetaSimplifier: META_SIMPLIFIER =
   101 struct
   102 
   103 
   104 (** datatype simpset **)
   105 
   106 (* rewrite rules *)
   107 
   108 type rrule = {thm: thm, name: string, lhs: term, elhs: cterm, fo: bool, perm: bool};
   109 
   110 (*thm: the rewrite rule;
   111   name: name of theorem from which rewrite rule was extracted;
   112   lhs: the left-hand side;
   113   elhs: the etac-contracted lhs;
   114   fo: use first-order matching;
   115   perm: the rewrite rule is permutative;
   116 
   117 Remarks:
   118   - elhs is used for matching,
   119     lhs only for preservation of bound variable names;
   120   - fo is set iff
   121     either elhs is first-order (no Var is applied),
   122       in which case fo-matching is complete,
   123     or elhs is not a pattern,
   124       in which case there is nothing better to do;*)
   125 
   126 fun eq_rrule ({thm = thm1, ...}: rrule, {thm = thm2, ...}: rrule) =
   127   Drule.eq_thm_prop (thm1, thm2);
   128 
   129 
   130 (* congruences *)
   131 
   132 type cong = {thm: thm, lhs: cterm};
   133 
   134 fun eq_cong ({thm = thm1, ...}: cong, {thm = thm2, ...}: cong) =
   135   Drule.eq_thm_prop (thm1, thm2);
   136 
   137 
   138 (* solvers *)
   139 
   140 datatype solver =
   141   Solver of
   142    {name: string,
   143     solver: thm list -> int -> tactic,
   144     id: stamp};
   145 
   146 fun mk_solver name solver = Solver {name = name, solver = solver, id = stamp ()};
   147 
   148 fun solver_name (Solver {name, ...}) = name;
   149 fun solver ths (Solver {solver = tacf, ...}) = tacf ths;
   150 fun eq_solver (Solver {id = id1, ...}, Solver {id = id2, ...}) = (id1 = id2);
   151 val merge_solvers = gen_merge_lists eq_solver;
   152 
   153 
   154 (* simplification sets and procedures *)
   155 
   156 (*A simpset contains data required during conversion:
   157     rules: discrimination net of rewrite rules;
   158     prems: current premises;
   159     bounds: maximal index of bound variables already used
   160       (for generating new names when rewriting under lambda abstractions);
   161     congs: association list of congruence rules and
   162            a list of `weak' congruence constants.
   163            A congruence is `weak' if it avoids normalization of some argument.
   164     procs: discrimination net of simplification procedures
   165       (functions that prove rewrite rules on the fly);
   166     mk_rews:
   167       mk: turn simplification thms into rewrite rules;
   168       mk_cong: prepare congruence rules;
   169       mk_sym: turn == around;
   170       mk_eq_True: turn P into P == True;
   171     termless: relation for ordered rewriting;*)
   172 
   173 type mk_rews =
   174  {mk: thm -> thm list,
   175   mk_cong: thm -> thm,
   176   mk_sym: thm -> thm option,
   177   mk_eq_True: thm -> thm option};
   178 
   179 datatype simpset =
   180   Simpset of
   181    {rules: rrule Net.net,
   182     prems: thm list,
   183     bounds: int * (string * (string * typ)) list} *
   184    {congs: (string * cong) list * string list,
   185     procs: proc Net.net,
   186     mk_rews: mk_rews,
   187     termless: term * term -> bool,
   188     subgoal_tac: simpset -> int -> tactic,
   189     loop_tacs: (string * (int -> tactic)) list,
   190     solvers: solver list * solver list}
   191 and proc =
   192   Proc of
   193    {name: string,
   194     lhs: cterm,
   195     proc: theory -> simpset -> term -> thm option,
   196     id: stamp};
   197 
   198 fun eq_proc (Proc {id = id1, ...}, Proc {id = id2, ...}) = (id1 = id2);
   199 
   200 fun rep_ss (Simpset args) = args;
   201 
   202 fun make_ss1 (rules, prems, bounds) =
   203   {rules = rules, prems = prems, bounds = bounds};
   204 
   205 fun map_ss1 f {rules, prems, bounds} =
   206   make_ss1 (f (rules, prems, bounds));
   207 
   208 fun make_ss2 (congs, procs, mk_rews, termless, subgoal_tac, loop_tacs, solvers) =
   209   {congs = congs, procs = procs, mk_rews = mk_rews, termless = termless,
   210     subgoal_tac = subgoal_tac, loop_tacs = loop_tacs, solvers = solvers};
   211 
   212 fun map_ss2 f {congs, procs, mk_rews, termless, subgoal_tac, loop_tacs, solvers} =
   213   make_ss2 (f (congs, procs, mk_rews, termless, subgoal_tac, loop_tacs, solvers));
   214 
   215 fun make_simpset (args1, args2) = Simpset (make_ss1 args1, make_ss2 args2);
   216 
   217 fun map_simpset f (Simpset ({rules, prems, bounds},
   218     {congs, procs, mk_rews, termless, subgoal_tac, loop_tacs, solvers})) =
   219   make_simpset (f ((rules, prems, bounds),
   220     (congs, procs, mk_rews, termless, subgoal_tac, loop_tacs, solvers)));
   221 
   222 fun map_simpset1 f (Simpset (r1, r2)) = Simpset (map_ss1 f r1, r2);
   223 fun map_simpset2 f (Simpset (r1, r2)) = Simpset (r1, map_ss2 f r2);
   224 
   225 
   226 (* diagnostics *)
   227 
   228 exception SIMPLIFIER of string * thm;
   229 
   230 val debug_simp = ref false;
   231 val trace_simp = ref false;
   232 val simp_depth = ref 0;
   233 val simp_depth_limit = ref 100;
   234 val trace_simp_depth_limit = ref 100;
   235 
   236 local
   237 
   238 fun println a =
   239   if ! simp_depth > ! trace_simp_depth_limit then ()
   240   else tracing (enclose "[" "]" (string_of_int (! simp_depth)) ^ a);
   241 
   242 fun prnt warn a = if warn then warning a else println a;
   243 
   244 fun show_bounds (Simpset ({bounds = (_, bs), ...}, _)) t =
   245   let
   246     val used = Term.add_term_names (t, []);
   247     val xs = rev (Term.variantlist (rev (map #1 bs), used));
   248     fun subst ((_, (b, T)), x) = (Free (b, T), Syntax.mark_boundT (x, T));
   249   in Term.subst_atomic (ListPair.map subst (bs, xs)) t end;
   250 
   251 fun prtm warn a ss thy t = prnt warn (a ^ "\n" ^
   252   Sign.string_of_term thy (if ! debug_simp then t else show_bounds ss t));
   253 
   254 in
   255 
   256 fun debug warn a = if ! debug_simp then prnt warn a else ();
   257 fun trace warn a = if ! trace_simp then prnt warn a else ();
   258 
   259 fun debug_term warn a ss thy t = if ! debug_simp then prtm warn a ss thy t else ();
   260 fun trace_term warn a ss thy t = if ! trace_simp then prtm warn a ss thy t else ();
   261 
   262 fun trace_cterm warn a ss ct =
   263   if ! trace_simp then prtm warn a ss (Thm.theory_of_cterm ct) (Thm.term_of ct) else ();
   264 
   265 fun trace_thm a ss th =
   266   if ! trace_simp then prtm false a ss (Thm.theory_of_thm th) (Thm.full_prop_of th) else ();
   267 
   268 fun trace_named_thm a ss (th, name) =
   269   if ! trace_simp then
   270     prtm false (if name = "" then a else a ^ " " ^ quote name ^ ":") ss
   271       (Thm.theory_of_thm th) (Thm.full_prop_of th)
   272   else ();
   273 
   274 fun warn_thm a ss th = prtm true a ss (Thm.theory_of_thm th) (Thm.full_prop_of th);
   275 
   276 end;
   277 
   278 
   279 (* print simpsets *)
   280 
   281 fun print_ss ss =
   282   let
   283     val pretty_thms = map Display.pretty_thm;
   284 
   285     fun pretty_cong (name, th) =
   286       Pretty.block [Pretty.str (name ^ ":"), Pretty.brk 1, Display.pretty_thm th];
   287     fun pretty_proc (name, lhss) =
   288       Pretty.big_list (name ^ ":") (map Display.pretty_cterm lhss);
   289 
   290     val Simpset ({rules, ...}, {congs, procs, loop_tacs, solvers, ...}) = ss;
   291     val smps = map #thm (Net.entries rules);
   292     val cngs = map (fn (name, {thm, ...}) => (name, thm)) (#1 congs);
   293     val prcs = Net.entries procs |>
   294       map (fn Proc {name, lhs, id, ...} => ((name, lhs), id))
   295       |> partition_eq eq_snd
   296       |> map (fn ps => (#1 (#1 (hd ps)), map (#2 o #1) ps))
   297       |> Library.sort_wrt #1;
   298   in
   299     [Pretty.big_list "simplification rules:" (pretty_thms smps),
   300       Pretty.big_list "simplification procedures:" (map pretty_proc prcs),
   301       Pretty.big_list "congruences:" (map pretty_cong cngs),
   302       Pretty.strs ("loopers:" :: map (quote o #1) loop_tacs),
   303       Pretty.strs ("unsafe solvers:" :: map (quote o solver_name) (#1 solvers)),
   304       Pretty.strs ("safe solvers:" :: map (quote o solver_name) (#2 solvers))]
   305     |> Pretty.chunks |> Pretty.writeln
   306   end;
   307 
   308 
   309 (* empty simpsets *)
   310 
   311 local
   312 
   313 fun init_ss mk_rews termless subgoal_tac solvers =
   314   make_simpset ((Net.empty, [], (0, [])),
   315     (([], []), Net.empty, mk_rews, termless, subgoal_tac, [], solvers));
   316 
   317 val basic_mk_rews: mk_rews =
   318  {mk = fn th => if can Logic.dest_equals (Thm.concl_of th) then [th] else [],
   319   mk_cong = I,
   320   mk_sym = SOME o Drule.symmetric_fun,
   321   mk_eq_True = K NONE};
   322 
   323 in
   324 
   325 val empty_ss = init_ss basic_mk_rews Term.termless (K (K no_tac)) ([], []);
   326 
   327 fun clear_ss (Simpset (_, {mk_rews, termless, subgoal_tac, solvers, ...})) =
   328   init_ss mk_rews termless subgoal_tac solvers;
   329 
   330 end;
   331 
   332 
   333 (* merge simpsets *)            (*NOTE: ignores some fields of 2nd simpset*)
   334 
   335 fun merge_ss (ss1, ss2) =
   336   let
   337     val Simpset ({rules = rules1, prems = prems1, bounds = bounds1},
   338      {congs = (congs1, weak1), procs = procs1, mk_rews, termless, subgoal_tac,
   339       loop_tacs = loop_tacs1, solvers = (unsafe_solvers1, solvers1)}) = ss1;
   340     val Simpset ({rules = rules2, prems = prems2, bounds = bounds2},
   341      {congs = (congs2, weak2), procs = procs2, mk_rews = _, termless = _, subgoal_tac = _,
   342       loop_tacs = loop_tacs2, solvers = (unsafe_solvers2, solvers2)}) = ss2;
   343 
   344     val rules' = Net.merge eq_rrule (rules1, rules2);
   345     val prems' = gen_merge_lists Drule.eq_thm_prop prems1 prems2;
   346     val bounds' = if #1 bounds1 < #1 bounds2 then bounds2 else bounds1;
   347     val congs' = gen_merge_lists (eq_cong o pairself #2) congs1 congs2;
   348     val weak' = merge_lists weak1 weak2;
   349     val procs' = Net.merge eq_proc (procs1, procs2);
   350     val loop_tacs' = merge_alists loop_tacs1 loop_tacs2;
   351     val unsafe_solvers' = merge_solvers unsafe_solvers1 unsafe_solvers2;
   352     val solvers' = merge_solvers solvers1 solvers2;
   353   in
   354     make_simpset ((rules', prems', bounds'), ((congs', weak'), procs',
   355       mk_rews, termless, subgoal_tac, loop_tacs', (unsafe_solvers', solvers')))
   356   end;
   357 
   358 
   359 (* simprocs *)
   360 
   361 exception SIMPROC_FAIL of string * exn;
   362 
   363 datatype simproc = Simproc of proc list;
   364 
   365 fun mk_simproc name lhss proc =
   366   let val id = stamp () in
   367     Simproc (lhss |> map (fn lhs =>
   368       Proc {name = name, lhs = lhs, proc = proc, id = id}))
   369   end;
   370 
   371 fun simproc_i thy name = mk_simproc name o map (Thm.cterm_of thy o Logic.varify);
   372 fun simproc thy name = simproc_i thy name o map (Sign.read_term thy);
   373 
   374 
   375 
   376 (** simpset operations **)
   377 
   378 (* bounds and prems *)
   379 
   380 fun inherit_bounds (Simpset ({bounds, ...}, _)) =
   381   map_simpset1 (fn (rules, prems, _) => (rules, prems, bounds));
   382 
   383 fun add_bound bound = map_simpset1 (fn (rules, prems, (count, bounds)) =>
   384   (rules, prems, (count + 1, bound :: bounds)));
   385 
   386 fun add_prems ths = map_simpset1 (fn (rules, prems, bounds) =>
   387   (rules, ths @ prems, bounds));
   388 
   389 fun prems_of_ss (Simpset ({prems, ...}, _)) = prems;
   390 
   391 
   392 (* addsimps *)
   393 
   394 fun mk_rrule2 {thm, name, lhs, elhs, perm} =
   395   let
   396     val fo = Pattern.first_order (term_of elhs) orelse not (Pattern.pattern (term_of elhs))
   397   in {thm = thm, name = name, lhs = lhs, elhs = elhs, fo = fo, perm = perm} end;
   398 
   399 fun insert_rrule quiet (ss, rrule as {thm, name, lhs, elhs, perm}) =
   400  (trace_named_thm "Adding rewrite rule" ss (thm, name);
   401   ss |> map_simpset1 (fn (rules, prems, bounds) =>
   402     let
   403       val rrule2 as {elhs, ...} = mk_rrule2 rrule;
   404       val rules' = Net.insert_term eq_rrule (term_of elhs, rrule2) rules;
   405     in (rules', prems, bounds) end)
   406   handle Net.INSERT =>
   407     (if quiet then () else warn_thm "Ignoring duplicate rewrite rule:" ss thm; ss));
   408 
   409 fun vperm (Var _, Var _) = true
   410   | vperm (Abs (_, _, s), Abs (_, _, t)) = vperm (s, t)
   411   | vperm (t1 $ t2, u1 $ u2) = vperm (t1, u1) andalso vperm (t2, u2)
   412   | vperm (t, u) = (t = u);
   413 
   414 fun var_perm (t, u) =
   415   vperm (t, u) andalso eq_set (term_varnames t, term_varnames u);
   416 
   417 (* FIXME: it seems that the conditions on extra variables are too liberal if
   418 prems are nonempty: does solving the prems really guarantee instantiation of
   419 all its Vars? Better: a dynamic check each time a rule is applied.
   420 *)
   421 fun rewrite_rule_extra_vars prems elhs erhs =
   422   not (term_varnames erhs subset fold add_term_varnames prems (term_varnames elhs))
   423   orelse
   424   not (term_tvars erhs subset (term_tvars elhs union List.concat (map term_tvars prems)));
   425 
   426 (*simple test for looping rewrite rules and stupid orientations*)
   427 fun reorient thy prems lhs rhs =
   428   rewrite_rule_extra_vars prems lhs rhs
   429     orelse
   430   is_Var (head_of lhs)
   431     orelse
   432 (* turns t = x around, which causes a headache if x is a local variable -
   433    usually it is very useful :-(
   434   is_Free rhs andalso not(is_Free lhs) andalso not(Logic.occs(rhs,lhs))
   435   andalso not(exists_subterm is_Var lhs)
   436     orelse
   437 *)
   438   exists (fn t => Logic.occs (lhs, t)) (rhs :: prems)
   439     orelse
   440   null prems andalso Pattern.matches thy (lhs, rhs)
   441     (*the condition "null prems" is necessary because conditional rewrites
   442       with extra variables in the conditions may terminate although
   443       the rhs is an instance of the lhs; example: ?m < ?n ==> f(?n) == f(?m)*)
   444     orelse
   445   is_Const lhs andalso not (is_Const rhs);
   446 
   447 fun decomp_simp thm =
   448   let
   449     val {thy, prop, ...} = Thm.rep_thm thm;
   450     val prems = Logic.strip_imp_prems prop;
   451     val concl = Drule.strip_imp_concl (Thm.cprop_of thm);
   452     val (lhs, rhs) = Drule.dest_equals concl handle TERM _ =>
   453       raise SIMPLIFIER ("Rewrite rule not a meta-equality", thm);
   454     val (_, elhs) = Drule.dest_equals (Thm.cprop_of (Thm.eta_conversion lhs));
   455     val elhs = if term_of elhs aconv term_of lhs then lhs else elhs;  (*share identical copies*)
   456     val erhs = Pattern.eta_contract (term_of rhs);
   457     val perm =
   458       var_perm (term_of elhs, erhs) andalso
   459       not (term_of elhs aconv erhs) andalso
   460       not (is_Var (term_of elhs));
   461   in (thy, prems, term_of lhs, elhs, term_of rhs, perm) end;
   462 
   463 fun decomp_simp' thm =
   464   let val (_, _, lhs, _, rhs, _) = decomp_simp thm in
   465     if Thm.nprems_of thm > 0 then raise SIMPLIFIER ("Bad conditional rewrite rule", thm)
   466     else (lhs, rhs)
   467   end;
   468 
   469 fun mk_eq_True (Simpset (_, {mk_rews = {mk_eq_True, ...}, ...})) (thm, name) =
   470   (case mk_eq_True thm of
   471     NONE => []
   472   | SOME eq_True =>
   473       let val (_, _, lhs, elhs, _, _) = decomp_simp eq_True
   474       in [{thm = eq_True, name = name, lhs = lhs, elhs = elhs, perm = false}] end);
   475 
   476 (*create the rewrite rule and possibly also the eq_True variant,
   477   in case there are extra vars on the rhs*)
   478 fun rrule_eq_True (thm, name, lhs, elhs, rhs, ss, thm2) =
   479   let val rrule = {thm = thm, name = name, lhs = lhs, elhs = elhs, perm = false} in
   480     if term_varnames rhs subset term_varnames lhs andalso
   481       term_tvars rhs subset term_tvars lhs then [rrule]
   482     else mk_eq_True ss (thm2, name) @ [rrule]
   483   end;
   484 
   485 fun mk_rrule ss (thm, name) =
   486   let val (_, prems, lhs, elhs, rhs, perm) = decomp_simp thm in
   487     if perm then [{thm = thm, name = name, lhs = lhs, elhs = elhs, perm = true}]
   488     else
   489       (*weak test for loops*)
   490       if rewrite_rule_extra_vars prems lhs rhs orelse is_Var (term_of elhs)
   491       then mk_eq_True ss (thm, name)
   492       else rrule_eq_True (thm, name, lhs, elhs, rhs, ss, thm)
   493   end;
   494 
   495 fun orient_rrule ss (thm, name) =
   496   let val (thy, prems, lhs, elhs, rhs, perm) = decomp_simp thm in
   497     if perm then [{thm = thm, name = name, lhs = lhs, elhs = elhs, perm = true}]
   498     else if reorient thy prems lhs rhs then
   499       if reorient thy prems rhs lhs
   500       then mk_eq_True ss (thm, name)
   501       else
   502         let val Simpset (_, {mk_rews = {mk_sym, ...}, ...}) = ss in
   503           (case mk_sym thm of
   504             NONE => []
   505           | SOME thm' =>
   506               let val (_, _, lhs', elhs', rhs', _) = decomp_simp thm'
   507               in rrule_eq_True (thm', name, lhs', elhs', rhs', ss, thm) end)
   508         end
   509     else rrule_eq_True (thm, name, lhs, elhs, rhs, ss, thm)
   510   end;
   511 
   512 fun extract_rews (Simpset (_, {mk_rews = {mk, ...}, ...}), thms) =
   513   List.concat (map (fn thm => map (rpair (Thm.name_of_thm thm)) (mk thm)) thms);
   514 
   515 fun orient_comb_simps comb mk_rrule (ss, thms) =
   516   let
   517     val rews = extract_rews (ss, thms);
   518     val rrules = List.concat (map mk_rrule rews);
   519   in Library.foldl comb (ss, rrules) end;
   520 
   521 fun extract_safe_rrules (ss, thm) =
   522   List.concat (map (orient_rrule ss) (extract_rews (ss, [thm])));
   523 
   524 (*add rewrite rules explicitly; do not reorient!*)
   525 fun ss addsimps thms =
   526   orient_comb_simps (insert_rrule false) (mk_rrule ss) (ss, thms);
   527 
   528 
   529 (* delsimps *)
   530 
   531 fun del_rrule (ss, rrule as {thm, elhs, ...}) =
   532   ss |> map_simpset1 (fn (rules, prems, bounds) =>
   533     (Net.delete_term eq_rrule (term_of elhs, rrule) rules, prems, bounds))
   534   handle Net.DELETE => (warn_thm "Rewrite rule not in simpset:" ss thm; ss);
   535 
   536 fun ss delsimps thms =
   537   orient_comb_simps del_rrule (map mk_rrule2 o mk_rrule ss) (ss, thms);
   538 
   539 
   540 (* congs *)
   541 
   542 fun cong_name (Const (a, _)) = SOME a
   543   | cong_name (Free (a, _)) = SOME ("Free: " ^ a)
   544   | cong_name _ = NONE;
   545 
   546 local
   547 
   548 fun is_full_cong_prems [] [] = true
   549   | is_full_cong_prems [] _ = false
   550   | is_full_cong_prems (p :: prems) varpairs =
   551       (case Logic.strip_assums_concl p of
   552         Const ("==", _) $ lhs $ rhs =>
   553           let val (x, xs) = strip_comb lhs and (y, ys) = strip_comb rhs in
   554             is_Var x andalso forall is_Bound xs andalso
   555             null (findrep xs) andalso xs = ys andalso
   556             (x, y) mem varpairs andalso
   557             is_full_cong_prems prems (varpairs \ (x, y))
   558           end
   559       | _ => false);
   560 
   561 fun is_full_cong thm =
   562   let
   563     val prems = prems_of thm and concl = concl_of thm;
   564     val (lhs, rhs) = Logic.dest_equals concl;
   565     val (f, xs) = strip_comb lhs and (g, ys) = strip_comb rhs;
   566   in
   567     f = g andalso null (findrep (xs @ ys)) andalso length xs = length ys andalso
   568     is_full_cong_prems prems (xs ~~ ys)
   569   end;
   570 
   571 fun add_cong (ss, thm) = ss |>
   572   map_simpset2 (fn (congs, procs, mk_rews, termless, subgoal_tac, loop_tacs, solvers) =>
   573     let
   574       val (lhs, _) = Drule.dest_equals (Drule.strip_imp_concl (Thm.cprop_of thm))
   575         handle TERM _ => raise SIMPLIFIER ("Congruence not a meta-equality", thm);
   576     (*val lhs = Pattern.eta_contract lhs;*)
   577       val a = valOf (cong_name (head_of (term_of lhs))) handle Option =>
   578         raise SIMPLIFIER ("Congruence must start with a constant or free variable", thm);
   579       val (alist, weak) = congs;
   580       val alist2 = overwrite_warn (alist, (a, {lhs = lhs, thm = thm}))
   581         ("Overwriting congruence rule for " ^ quote a);
   582       val weak2 = if is_full_cong thm then weak else a :: weak;
   583     in ((alist2, weak2), procs, mk_rews, termless, subgoal_tac, loop_tacs, solvers) end);
   584 
   585 fun del_cong (ss, thm) = ss |>
   586   map_simpset2 (fn (congs, procs, mk_rews, termless, subgoal_tac, loop_tacs, solvers) =>
   587     let
   588       val (lhs, _) = Logic.dest_equals (Thm.concl_of thm) handle TERM _ =>
   589         raise SIMPLIFIER ("Congruence not a meta-equality", thm);
   590     (*val lhs = Pattern.eta_contract lhs;*)
   591       val a = valOf (cong_name (head_of lhs)) handle Option =>
   592         raise SIMPLIFIER ("Congruence must start with a constant", thm);
   593       val (alist, _) = congs;
   594       val alist2 = List.filter (fn (x, _) => x <> a) alist;
   595       val weak2 = alist2 |> List.mapPartial (fn (a, {thm, ...}) =>
   596         if is_full_cong thm then NONE else SOME a);
   597     in ((alist2, weak2), procs, mk_rews, termless, subgoal_tac, loop_tacs, solvers) end);
   598 
   599 fun mk_cong (Simpset (_, {mk_rews = {mk_cong = f, ...}, ...})) = f;
   600 
   601 in
   602 
   603 val (op addeqcongs) = Library.foldl add_cong;
   604 val (op deleqcongs) = Library.foldl del_cong;
   605 
   606 fun ss addcongs congs = ss addeqcongs map (mk_cong ss) congs;
   607 fun ss delcongs congs = ss deleqcongs map (mk_cong ss) congs;
   608 
   609 end;
   610 
   611 
   612 (* simprocs *)
   613 
   614 local
   615 
   616 fun add_proc (proc as Proc {name, lhs, ...}) ss =
   617  (trace_cterm false ("Adding simplification procedure " ^ quote name ^ " for") ss lhs;
   618   map_simpset2 (fn (congs, procs, mk_rews, termless, subgoal_tac, loop_tacs, solvers) =>
   619     (congs, Net.insert_term eq_proc (term_of lhs, proc) procs,
   620       mk_rews, termless, subgoal_tac, loop_tacs, solvers)) ss
   621   handle Net.INSERT =>
   622     (warning ("Ignoring duplicate simplification procedure " ^ quote name); ss));
   623 
   624 fun del_proc (proc as Proc {name, lhs, ...}) ss =
   625   map_simpset2 (fn (congs, procs, mk_rews, termless, subgoal_tac, loop_tacs, solvers) =>
   626     (congs, Net.delete_term eq_proc (term_of lhs, proc) procs,
   627       mk_rews, termless, subgoal_tac, loop_tacs, solvers)) ss
   628   handle Net.DELETE =>
   629     (warning ("Simplification procedure " ^ quote name ^ " not in simpset"); ss);
   630 
   631 in
   632 
   633 fun ss addsimprocs ps = fold (fn Simproc procs => fold add_proc procs) ps ss;
   634 fun ss delsimprocs ps = fold (fn Simproc procs => fold del_proc procs) ps ss;
   635 
   636 end;
   637 
   638 
   639 (* mk_rews *)
   640 
   641 local
   642 
   643 fun map_mk_rews f = map_simpset2 (fn (congs, procs, {mk, mk_cong, mk_sym, mk_eq_True},
   644       termless, subgoal_tac, loop_tacs, solvers) =>
   645   let val (mk', mk_cong', mk_sym', mk_eq_True') = f (mk, mk_cong, mk_sym, mk_eq_True) in
   646     (congs, procs, {mk = mk', mk_cong = mk_cong', mk_sym = mk_sym', mk_eq_True = mk_eq_True'},
   647       termless, subgoal_tac, loop_tacs, solvers)
   648   end);
   649 
   650 in
   651 
   652 fun ss setmksimps mk = ss |> map_mk_rews (fn (_, mk_cong, mk_sym, mk_eq_True) =>
   653   (mk, mk_cong, mk_sym, mk_eq_True));
   654 
   655 fun ss setmkcong mk_cong = ss |> map_mk_rews (fn (mk, _, mk_sym, mk_eq_True) =>
   656   (mk, mk_cong, mk_sym, mk_eq_True));
   657 
   658 fun ss setmksym mk_sym = ss |> map_mk_rews (fn (mk, mk_cong, _, mk_eq_True) =>
   659   (mk, mk_cong, mk_sym, mk_eq_True));
   660 
   661 fun ss setmkeqTrue mk_eq_True = ss |> map_mk_rews (fn (mk, mk_cong, mk_sym, _) =>
   662   (mk, mk_cong, mk_sym, mk_eq_True));
   663 
   664 end;
   665 
   666 
   667 (* termless *)
   668 
   669 fun ss settermless termless = ss |>
   670   map_simpset2 (fn (congs, procs, mk_rews, _, subgoal_tac, loop_tacs, solvers) =>
   671    (congs, procs, mk_rews, termless, subgoal_tac, loop_tacs, solvers));
   672 
   673 
   674 (* tactics *)
   675 
   676 fun ss setsubgoaler subgoal_tac = ss |>
   677   map_simpset2 (fn (congs, procs, mk_rews, termless, _, loop_tacs, solvers) =>
   678    (congs, procs, mk_rews, termless, subgoal_tac, loop_tacs, solvers));
   679 
   680 fun ss setloop tac = ss |>
   681   map_simpset2 (fn (congs, procs, mk_rews, termless, subgoal_tac, _, solvers) =>
   682    (congs, procs, mk_rews, termless, subgoal_tac, [("", tac)], solvers));
   683 
   684 fun ss addloop (name, tac) = ss |>
   685   map_simpset2 (fn (congs, procs, mk_rews, termless, subgoal_tac, loop_tacs, solvers) =>
   686     (congs, procs, mk_rews, termless, subgoal_tac,
   687       overwrite_warn (loop_tacs, (name, tac)) ("Overwriting looper " ^ quote name),
   688       solvers));
   689 
   690 fun ss delloop name = ss |>
   691   map_simpset2 (fn (congs, procs, mk_rews, termless, subgoal_tac, loop_tacs, solvers) =>
   692     let val loop_tacs' = filter_out (equal name o #1) loop_tacs in
   693       if length loop_tacs <> length loop_tacs' then ()
   694       else warning ("No such looper in simpset: " ^ quote name);
   695       (congs, procs, mk_rews, termless, subgoal_tac, loop_tacs', solvers)
   696     end);
   697 
   698 fun ss setSSolver solver = ss |> map_simpset2 (fn (congs, procs, mk_rews, termless,
   699   subgoal_tac, loop_tacs, (unsafe_solvers, _)) =>
   700     (congs, procs, mk_rews, termless, subgoal_tac, loop_tacs, (unsafe_solvers, [solver])));
   701 
   702 fun ss addSSolver solver = ss |> map_simpset2 (fn (congs, procs, mk_rews, termless,
   703   subgoal_tac, loop_tacs, (unsafe_solvers, solvers)) => (congs, procs, mk_rews, termless,
   704     subgoal_tac, loop_tacs, (unsafe_solvers, merge_solvers solvers [solver])));
   705 
   706 fun ss setSolver solver = ss |> map_simpset2 (fn (congs, procs, mk_rews, termless,
   707   subgoal_tac, loop_tacs, (_, solvers)) => (congs, procs, mk_rews, termless,
   708     subgoal_tac, loop_tacs, ([solver], solvers)));
   709 
   710 fun ss addSolver solver = ss |> map_simpset2 (fn (congs, procs, mk_rews, termless,
   711   subgoal_tac, loop_tacs, (unsafe_solvers, solvers)) => (congs, procs, mk_rews, termless,
   712     subgoal_tac, loop_tacs, (merge_solvers unsafe_solvers [solver], solvers)));
   713 
   714 fun set_solvers solvers = map_simpset2 (fn (congs, procs, mk_rews, termless,
   715   subgoal_tac, loop_tacs, _) => (congs, procs, mk_rews, termless,
   716   subgoal_tac, loop_tacs, (solvers, solvers)));
   717 
   718 
   719 
   720 (** rewriting **)
   721 
   722 (*
   723   Uses conversions, see:
   724     L C Paulson, A higher-order implementation of rewriting,
   725     Science of Computer Programming 3 (1983), pages 119-149.
   726 *)
   727 
   728 val dest_eq = Drule.dest_equals o Thm.cprop_of;
   729 val lhs_of = #1 o dest_eq;
   730 val rhs_of = #2 o dest_eq;
   731 
   732 fun check_conv msg ss thm thm' =
   733   let
   734     val thm'' = transitive thm (transitive
   735       (symmetric (Drule.beta_eta_conversion (lhs_of thm'))) thm')
   736   in if msg then trace_thm "SUCCEEDED" ss thm' else (); SOME thm'' end
   737   handle THM _ =>
   738     let val {thy, prop = _ $ _ $ prop0, ...} = Thm.rep_thm thm in
   739       trace_thm "Proved wrong thm (Check subgoaler?)" ss thm';
   740       trace_term false "Should have proved:" ss thy prop0;
   741       NONE
   742     end;
   743 
   744 
   745 (* mk_procrule *)
   746 
   747 fun mk_procrule ss thm =
   748   let val (_, prems, lhs, elhs, rhs, _) = decomp_simp thm in
   749     if rewrite_rule_extra_vars prems lhs rhs
   750     then (warn_thm "Extra vars on rhs:" ss thm; [])
   751     else [mk_rrule2 {thm = thm, name = "", lhs = lhs, elhs = elhs, perm = false}]
   752   end;
   753 
   754 
   755 (* rewritec: conversion to apply the meta simpset to a term *)
   756 
   757 (*Since the rewriting strategy is bottom-up, we avoid re-normalizing already
   758   normalized terms by carrying around the rhs of the rewrite rule just
   759   applied. This is called the `skeleton'. It is decomposed in parallel
   760   with the term. Once a Var is encountered, the corresponding term is
   761   already in normal form.
   762   skel0 is a dummy skeleton that is to enforce complete normalization.*)
   763 
   764 val skel0 = Bound 0;
   765 
   766 (*Use rhs as skeleton only if the lhs does not contain unnormalized bits.
   767   The latter may happen iff there are weak congruence rules for constants
   768   in the lhs.*)
   769 
   770 fun uncond_skel ((_, weak), (lhs, rhs)) =
   771   if null weak then rhs  (*optimization*)
   772   else if exists_Const (fn (c, _) => c mem weak) lhs then skel0
   773   else rhs;
   774 
   775 (*Behaves like unconditional rule if rhs does not contain vars not in the lhs.
   776   Otherwise those vars may become instantiated with unnormalized terms
   777   while the premises are solved.*)
   778 
   779 fun cond_skel (args as (congs, (lhs, rhs))) =
   780   if term_varnames rhs subset term_varnames lhs then uncond_skel args
   781   else skel0;
   782 
   783 (*
   784   Rewriting -- we try in order:
   785     (1) beta reduction
   786     (2) unconditional rewrite rules
   787     (3) conditional rewrite rules
   788     (4) simplification procedures
   789 
   790   IMPORTANT: rewrite rules must not introduce new Vars or TVars!
   791 *)
   792 
   793 fun rewritec (prover, thyt, maxt) ss t =
   794   let
   795     val Simpset ({rules, ...}, {congs, procs, termless, ...}) = ss;
   796     val eta_thm = Thm.eta_conversion t;
   797     val eta_t' = rhs_of eta_thm;
   798     val eta_t = term_of eta_t';
   799     fun rew {thm, name, lhs, elhs, fo, perm} =
   800       let
   801         val {thy, prop, maxidx, ...} = rep_thm thm;
   802         val (rthm, elhs') = if maxt = ~1 then (thm, elhs)
   803           else (Thm.incr_indexes (maxt+1) thm, Thm.cterm_incr_indexes (maxt+1) elhs);
   804         val insts = if fo then Thm.cterm_first_order_match (elhs', eta_t')
   805                           else Thm.cterm_match (elhs', eta_t');
   806         val thm' = Thm.instantiate insts (Thm.rename_boundvars lhs eta_t rthm);
   807         val prop' = Thm.prop_of thm';
   808         val unconditional = (Logic.count_prems (prop',0) = 0);
   809         val (lhs', rhs') = Logic.dest_equals (Logic.strip_imp_concl prop')
   810       in
   811         if perm andalso not (termless (rhs', lhs'))
   812         then (trace_named_thm "Cannot apply permutative rewrite rule" ss (thm, name);
   813               trace_thm "Term does not become smaller:" ss thm'; NONE)
   814         else (trace_named_thm "Applying instance of rewrite rule" ss (thm, name);
   815            if unconditional
   816            then
   817              (trace_thm "Rewriting:" ss thm';
   818               let val lr = Logic.dest_equals prop;
   819                   val SOME thm'' = check_conv false ss eta_thm thm'
   820               in SOME (thm'', uncond_skel (congs, lr)) end)
   821            else
   822              (trace_thm "Trying to rewrite:" ss thm';
   823               if !simp_depth > !simp_depth_limit
   824               then let val s = "simp_depth_limit exceeded - giving up"
   825                    in trace false s; warning s; NONE end
   826               else
   827               case prover ss thm' of
   828                 NONE => (trace_thm "FAILED" ss thm'; NONE)
   829               | SOME thm2 =>
   830                   (case check_conv true ss eta_thm thm2 of
   831                      NONE => NONE |
   832                      SOME thm2' =>
   833                        let val concl = Logic.strip_imp_concl prop
   834                            val lr = Logic.dest_equals concl
   835                        in SOME (thm2', cond_skel (congs, lr)) end)))
   836       end
   837 
   838     fun rews [] = NONE
   839       | rews (rrule :: rrules) =
   840           let val opt = rew rrule handle Pattern.MATCH => NONE
   841           in case opt of NONE => rews rrules | some => some end;
   842 
   843     fun sort_rrules rrs = let
   844       fun is_simple({thm, ...}:rrule) = case Thm.prop_of thm of
   845                                       Const("==",_) $ _ $ _ => true
   846                                       | _                   => false
   847       fun sort []        (re1,re2) = re1 @ re2
   848         | sort (rr::rrs) (re1,re2) = if is_simple rr
   849                                      then sort rrs (rr::re1,re2)
   850                                      else sort rrs (re1,rr::re2)
   851     in sort rrs ([],[]) end
   852 
   853     fun proc_rews [] = NONE
   854       | proc_rews (Proc {name, proc, lhs, ...} :: ps) =
   855           if Pattern.matches thyt (Thm.term_of lhs, Thm.term_of t) then
   856             (debug_term false ("Trying procedure " ^ quote name ^ " on:") ss thyt eta_t;
   857              case transform_failure (curry SIMPROC_FAIL name)
   858                  (fn () => proc thyt ss eta_t) () of
   859                NONE => (debug false "FAILED"; proc_rews ps)
   860              | SOME raw_thm =>
   861                  (trace_thm ("Procedure " ^ quote name ^ " produced rewrite rule:") ss raw_thm;
   862                   (case rews (mk_procrule ss raw_thm) of
   863                     NONE => (trace_cterm true ("IGNORED result of simproc " ^ quote name ^
   864                       " -- does not match") ss t; proc_rews ps)
   865                   | some => some)))
   866           else proc_rews ps;
   867   in case eta_t of
   868        Abs _ $ _ => SOME (transitive eta_thm
   869          (beta_conversion false eta_t'), skel0)
   870      | _ => (case rews (sort_rrules (Net.match_term rules eta_t)) of
   871                NONE => proc_rews (Net.match_term procs eta_t)
   872              | some => some)
   873   end;
   874 
   875 
   876 (* conversion to apply a congruence rule to a term *)
   877 
   878 fun congc prover ss maxt {thm=cong,lhs=lhs} t =
   879   let val rthm = Thm.incr_indexes (maxt+1) cong;
   880       val rlhs = fst (Drule.dest_equals (Drule.strip_imp_concl (cprop_of rthm)));
   881       val insts = Thm.cterm_match (rlhs, t)
   882       (* Pattern.match can raise Pattern.MATCH;
   883          is handled when congc is called *)
   884       val thm' = Thm.instantiate insts (Thm.rename_boundvars (term_of rlhs) (term_of t) rthm);
   885       val unit = trace_thm "Applying congruence rule:" ss thm';
   886       fun err (msg, thm) = (trace_thm msg ss thm; NONE)
   887   in case prover thm' of
   888        NONE => err ("Congruence proof failed.  Could not prove", thm')
   889      | SOME thm2 => (case check_conv true ss (Drule.beta_eta_conversion t) thm2 of
   890           NONE => err ("Congruence proof failed.  Should not have proved", thm2)
   891         | SOME thm2' =>
   892             if op aconv (pairself term_of (dest_equals (cprop_of thm2')))
   893             then NONE else SOME thm2')
   894   end;
   895 
   896 val (cA, (cB, cC)) =
   897   apsnd dest_equals (dest_implies (hd (cprems_of Drule.imp_cong)));
   898 
   899 fun transitive1 NONE NONE = NONE
   900   | transitive1 (SOME thm1) NONE = SOME thm1
   901   | transitive1 NONE (SOME thm2) = SOME thm2
   902   | transitive1 (SOME thm1) (SOME thm2) = SOME (transitive thm1 thm2)
   903 
   904 fun transitive2 thm = transitive1 (SOME thm);
   905 fun transitive3 thm = transitive1 thm o SOME;
   906 
   907 fun bottomc ((simprem, useprem, mutsimp), prover, thy, maxidx) =
   908   let
   909     fun botc skel ss t =
   910           if is_Var skel then NONE
   911           else
   912           (case subc skel ss t of
   913              some as SOME thm1 =>
   914                (case rewritec (prover, thy, maxidx) ss (rhs_of thm1) of
   915                   SOME (thm2, skel2) =>
   916                     transitive2 (transitive thm1 thm2)
   917                       (botc skel2 ss (rhs_of thm2))
   918                 | NONE => some)
   919            | NONE =>
   920                (case rewritec (prover, thy, maxidx) ss t of
   921                   SOME (thm2, skel2) => transitive2 thm2
   922                     (botc skel2 ss (rhs_of thm2))
   923                 | NONE => NONE))
   924 
   925     and try_botc ss t =
   926           (case botc skel0 ss t of
   927              SOME trec1 => trec1 | NONE => (reflexive t))
   928 
   929     and subc skel (ss as Simpset ({bounds, ...}, {congs, ...})) t0 =
   930        (case term_of t0 of
   931            Abs (a, T, t) =>
   932              let
   933                  val b = Term.bound (#1 bounds);
   934                  val (v, t') = Thm.dest_abs (SOME b) t0;
   935                  val b' = #1 (Term.dest_Free (Thm.term_of v));
   936                  val _ = conditional (b <> b') (fn () =>
   937                    warning ("Simplifier: renamed bound variable " ^ quote b ^ " to " ^ quote b'));
   938                  val ss' = add_bound (a, (b', T)) ss;
   939                  val skel' = case skel of Abs (_, _, sk) => sk | _ => skel0;
   940              in case botc skel' ss' t' of
   941                   SOME thm => SOME (abstract_rule a v thm)
   942                 | NONE => NONE
   943              end
   944          | t $ _ => (case t of
   945              Const ("==>", _) $ _  => impc t0 ss
   946            | Abs _ =>
   947                let val thm = beta_conversion false t0
   948                in case subc skel0 ss (rhs_of thm) of
   949                     NONE => SOME thm
   950                   | SOME thm' => SOME (transitive thm thm')
   951                end
   952            | _  =>
   953                let fun appc () =
   954                      let
   955                        val (tskel, uskel) = case skel of
   956                            tskel $ uskel => (tskel, uskel)
   957                          | _ => (skel0, skel0);
   958                        val (ct, cu) = Thm.dest_comb t0
   959                      in
   960                      (case botc tskel ss ct of
   961                         SOME thm1 =>
   962                           (case botc uskel ss cu of
   963                              SOME thm2 => SOME (combination thm1 thm2)
   964                            | NONE => SOME (combination thm1 (reflexive cu)))
   965                       | NONE =>
   966                           (case botc uskel ss cu of
   967                              SOME thm1 => SOME (combination (reflexive ct) thm1)
   968                            | NONE => NONE))
   969                      end
   970                    val (h, ts) = strip_comb t
   971                in case cong_name h of
   972                     SOME a =>
   973                       (case AList.lookup (op =) (fst congs) a of
   974                          NONE => appc ()
   975                        | SOME cong =>
   976   (*post processing: some partial applications h t1 ... tj, j <= length ts,
   977     may be a redex. Example: map (%x. x) = (%xs. xs) wrt map_cong*)
   978                           (let
   979                              val thm = congc (prover ss) ss maxidx cong t0;
   980                              val t = getOpt (Option.map rhs_of thm, t0);
   981                              val (cl, cr) = Thm.dest_comb t
   982                              val dVar = Var(("", 0), dummyT)
   983                              val skel =
   984                                list_comb (h, replicate (length ts) dVar)
   985                            in case botc skel ss cl of
   986                                 NONE => thm
   987                               | SOME thm' => transitive3 thm
   988                                   (combination thm' (reflexive cr))
   989                            end handle TERM _ => error "congc result"
   990                                     | Pattern.MATCH => appc ()))
   991                   | _ => appc ()
   992                end)
   993          | _ => NONE)
   994 
   995     and impc ct ss =
   996       if mutsimp then mut_impc0 [] ct [] [] ss else nonmut_impc ct ss
   997 
   998     and rules_of_prem ss prem =
   999       if maxidx_of_term (term_of prem) <> ~1
  1000       then (trace_cterm true
  1001         "Cannot add premise as rewrite rule because it contains (type) unknowns:" ss prem; ([], NONE))
  1002       else
  1003         let val asm = assume prem
  1004         in (extract_safe_rrules (ss, asm), SOME asm) end
  1005 
  1006     and add_rrules (rrss, asms) ss =
  1007       Library.foldl (insert_rrule true) (ss, List.concat rrss) |> add_prems (List.mapPartial I asms)
  1008 
  1009     and disch r (prem, eq) =
  1010       let
  1011         val (lhs, rhs) = dest_eq eq;
  1012         val eq' = implies_elim (Thm.instantiate
  1013           ([], [(cA, prem), (cB, lhs), (cC, rhs)]) Drule.imp_cong)
  1014           (implies_intr prem eq)
  1015       in if not r then eq' else
  1016         let
  1017           val (prem', concl) = dest_implies lhs;
  1018           val (prem'', _) = dest_implies rhs
  1019         in transitive (transitive
  1020           (Thm.instantiate ([], [(cA, prem'), (cB, prem), (cC, concl)])
  1021              Drule.swap_prems_eq) eq')
  1022           (Thm.instantiate ([], [(cA, prem), (cB, prem''), (cC, concl)])
  1023              Drule.swap_prems_eq)
  1024         end
  1025       end
  1026 
  1027     and rebuild [] _ _ _ _ eq = eq
  1028       | rebuild (prem :: prems) concl (rrs :: rrss) (asm :: asms) ss eq =
  1029           let
  1030             val ss' = add_rrules (rev rrss, rev asms) ss;
  1031             val concl' =
  1032               Drule.mk_implies (prem, getOpt (Option.map rhs_of eq, concl));
  1033             val dprem = Option.map (curry (disch false) prem)
  1034           in case rewritec (prover, thy, maxidx) ss' concl' of
  1035               NONE => rebuild prems concl' rrss asms ss (dprem eq)
  1036             | SOME (eq', _) => transitive2 (Library.foldl (disch false o swap)
  1037                   (valOf (transitive3 (dprem eq) eq'), prems))
  1038                 (mut_impc0 (rev prems) (rhs_of eq') (rev rrss) (rev asms) ss)
  1039           end
  1040 
  1041     and mut_impc0 prems concl rrss asms ss =
  1042       let
  1043         val prems' = strip_imp_prems concl;
  1044         val (rrss', asms') = split_list (map (rules_of_prem ss) prems')
  1045       in mut_impc (prems @ prems') (strip_imp_concl concl) (rrss @ rrss')
  1046         (asms @ asms') [] [] [] [] ss ~1 ~1
  1047       end
  1048 
  1049     and mut_impc [] concl [] [] prems' rrss' asms' eqns ss changed k =
  1050         transitive1 (Library.foldl (fn (eq2, (eq1, prem)) => transitive1 eq1
  1051             (Option.map (curry (disch false) prem) eq2)) (NONE, eqns ~~ prems'))
  1052           (if changed > 0 then
  1053              mut_impc (rev prems') concl (rev rrss') (rev asms')
  1054                [] [] [] [] ss ~1 changed
  1055            else rebuild prems' concl rrss' asms' ss
  1056              (botc skel0 (add_rrules (rev rrss', rev asms') ss) concl))
  1057 
  1058       | mut_impc (prem :: prems) concl (rrs :: rrss) (asm :: asms)
  1059           prems' rrss' asms' eqns ss changed k =
  1060         case (if k = 0 then NONE else botc skel0 (add_rrules
  1061           (rev rrss' @ rrss, rev asms' @ asms) ss) prem) of
  1062             NONE => mut_impc prems concl rrss asms (prem :: prems')
  1063               (rrs :: rrss') (asm :: asms') (NONE :: eqns) ss changed
  1064               (if k = 0 then 0 else k - 1)
  1065           | SOME eqn =>
  1066             let
  1067               val prem' = rhs_of eqn;
  1068               val tprems = map term_of prems;
  1069               val i = 1 + Library.foldl Int.max (~1, map (fn p =>
  1070                 find_index_eq p tprems) (#hyps (rep_thm eqn)));
  1071               val (rrs', asm') = rules_of_prem ss prem'
  1072             in mut_impc prems concl rrss asms (prem' :: prems')
  1073               (rrs' :: rrss') (asm' :: asms') (SOME (foldr (disch true)
  1074                 (Drule.imp_cong' eqn (reflexive (Drule.list_implies
  1075                   (Library.drop (i, prems), concl)))) (Library.take (i, prems))) :: eqns) ss (length prems') ~1
  1076             end
  1077 
  1078      (*legacy code - only for backwards compatibility*)
  1079      and nonmut_impc ct ss =
  1080        let val (prem, conc) = dest_implies ct;
  1081            val thm1 = if simprem then botc skel0 ss prem else NONE;
  1082            val prem1 = getOpt (Option.map rhs_of thm1, prem);
  1083            val ss1 = if not useprem then ss else add_rrules
  1084              (apsnd single (apfst single (rules_of_prem ss prem1))) ss
  1085        in (case botc skel0 ss1 conc of
  1086            NONE => (case thm1 of
  1087                NONE => NONE
  1088              | SOME thm1' => SOME (Drule.imp_cong' thm1' (reflexive conc)))
  1089          | SOME thm2 =>
  1090            let val thm2' = disch false (prem1, thm2)
  1091            in (case thm1 of
  1092                NONE => SOME thm2'
  1093              | SOME thm1' =>
  1094                  SOME (transitive (Drule.imp_cong' thm1' (reflexive conc)) thm2'))
  1095            end)
  1096        end
  1097 
  1098  in try_botc end;
  1099 
  1100 
  1101 (* Meta-rewriting: rewrites t to u and returns the theorem t==u *)
  1102 
  1103 (*
  1104   Parameters:
  1105     mode = (simplify A,
  1106             use A in simplifying B,
  1107             use prems of B (if B is again a meta-impl.) to simplify A)
  1108            when simplifying A ==> B
  1109     prover: how to solve premises in conditional rewrites and congruences
  1110 *)
  1111 
  1112 fun rewrite_cterm mode prover ss ct =
  1113   (inc simp_depth;
  1114    if !simp_depth mod 20 = 0
  1115    then warning ("Simplification depth " ^ string_of_int (!simp_depth))
  1116    else ();
  1117    trace_cterm false "SIMPLIFIER INVOKED ON THE FOLLOWING TERM:" ss ct;
  1118    let val {thy, t, maxidx, ...} = Thm.rep_cterm ct
  1119        val res = bottomc (mode, prover, thy, maxidx) ss ct
  1120          handle THM (s, _, thms) =>
  1121          error ("Exception THM was raised in simplifier:\n" ^ s ^ "\n" ^
  1122            Pretty.string_of (Display.pretty_thms thms))
  1123    in dec simp_depth; res end
  1124   ) handle exn => (dec simp_depth; raise exn);
  1125 
  1126 (*Rewrite a cterm*)
  1127 fun rewrite_aux _ _ [] = (fn ct => Thm.reflexive ct)
  1128   | rewrite_aux prover full thms =
  1129       rewrite_cterm (full, false, false) prover (empty_ss addsimps thms);
  1130 
  1131 (*Rewrite a theorem*)
  1132 fun simplify_aux _ _ [] = (fn th => th)
  1133   | simplify_aux prover full thms =
  1134       Drule.fconv_rule (rewrite_cterm (full, false, false) prover (empty_ss addsimps thms));
  1135 
  1136 (*simple term rewriting -- no proof*)
  1137 fun rewrite_term thy rules procs =
  1138   Pattern.rewrite_term thy (map decomp_simp' rules) procs;
  1139 
  1140 fun rewrite_thm mode prover ss = Drule.fconv_rule (rewrite_cterm mode prover ss);
  1141 
  1142 (*Rewrite the subgoals of a proof state (represented by a theorem) *)
  1143 fun rewrite_goals_rule_aux _ []   th = th
  1144   | rewrite_goals_rule_aux prover thms th =
  1145       Drule.fconv_rule (Drule.goals_conv (K true) (rewrite_cterm (true, true, false) prover
  1146         (empty_ss addsimps thms))) th;
  1147 
  1148 (*Rewrite the subgoal of a proof state (represented by a theorem)*)
  1149 fun rewrite_goal_rule mode prover ss i thm =
  1150   if 0 < i  andalso  i <= nprems_of thm
  1151   then Drule.fconv_rule (Drule.goals_conv (fn j => j=i) (rewrite_cterm mode prover ss)) thm
  1152   else raise THM("rewrite_goal_rule",i,[thm]);
  1153 
  1154 (*Rewrite subgoal i only.  SELECT_GOAL avoids inefficiencies in goals_conv.*)
  1155 fun asm_rewrite_goal_tac mode prover_tac ss =
  1156   SELECT_GOAL
  1157     (PRIMITIVE (rewrite_goal_rule mode (SINGLE o prover_tac) ss 1));
  1158 
  1159 
  1160 
  1161 (** simplification tactics and rules **)
  1162 
  1163 fun solve_all_tac solvers ss =
  1164   let
  1165     val Simpset (_, {subgoal_tac, ...}) = ss;
  1166     val solve_tac = subgoal_tac (set_solvers solvers ss) THEN_ALL_NEW (K no_tac);
  1167   in DEPTH_SOLVE (solve_tac 1) end;
  1168 
  1169 (*NOTE: may instantiate unknowns that appear also in other subgoals*)
  1170 fun generic_simp_tac safe mode ss =
  1171   let
  1172     val Simpset ({prems, ...}, {loop_tacs, solvers = (unsafe_solvers, solvers), ...}) = ss;
  1173     val loop_tac = FIRST' (map #2 loop_tacs);
  1174     val solve_tac = FIRST' (map (solver prems) (if safe then solvers else unsafe_solvers));
  1175 
  1176     fun simp_loop_tac i =
  1177       asm_rewrite_goal_tac mode (solve_all_tac unsafe_solvers) ss i THEN
  1178       (solve_tac i ORELSE TRY ((loop_tac THEN_ALL_NEW simp_loop_tac) i));
  1179   in simp_loop_tac end;
  1180 
  1181 fun simp rew mode ss thm =
  1182   let
  1183     val Simpset (_, {solvers = (unsafe_solvers, _), ...}) = ss;
  1184     val tacf = solve_all_tac unsafe_solvers;
  1185     fun prover s th = Option.map #1 (Seq.pull (tacf s th));
  1186   in rew mode prover ss thm end;
  1187 
  1188 val simp_thm = simp rewrite_thm;
  1189 val simp_cterm = simp rewrite_cterm;
  1190 
  1191 end;
  1192 
  1193 structure BasicMetaSimplifier: BASIC_META_SIMPLIFIER = MetaSimplifier;
  1194 open BasicMetaSimplifier;