src/Pure/pattern.ML
author haftmann
Tue Sep 06 08:30:43 2005 +0200 (2005-09-06)
changeset 17271 2756a73f63a5
parent 17221 6cd180204582
child 17412 e26cb20ef0cc
permissions -rw-r--r--
introduced some new-style AList operations
     1 (*  Title:      Pure/pattern.ML
     2     ID:         $Id$
     3     Author:     Tobias Nipkow, Christine Heinzelmann, and Stefan Berghofer
     4 
     5 Unification of Higher-Order Patterns.
     6 
     7 See also:
     8 Tobias Nipkow. Functional Unification of Higher-Order Patterns.
     9 In Proceedings of the 8th IEEE Symposium Logic in Computer Science, 1993.
    10 
    11 TODO: optimize red by special-casing it
    12 *)
    13 
    14 infix aeconv;
    15 
    16 signature PATTERN =
    17 sig
    18   val trace_unify_fail: bool ref
    19   val aeconv: term * term -> bool
    20   val eta_contract: term -> term
    21   val eta_long: typ list -> term -> term
    22   val beta_eta_contract: term -> term
    23   val eta_contract_atom: term -> term
    24   val match: theory -> term * term -> Type.tyenv * Envir.tenv
    25   val first_order_match: theory -> term * term -> Type.tyenv * Envir.tenv
    26   val matches: theory -> term * term -> bool
    27   val matches_subterm: theory -> term * term -> bool
    28   val unify: theory * Envir.env * (term * term)list -> Envir.env
    29   val first_order: term -> bool
    30   val pattern: term -> bool
    31   val rewrite_term: theory -> (term * term) list -> (term -> term option) list -> term -> term
    32   exception Unif
    33   exception MATCH
    34   exception Pattern
    35 end;
    36 
    37 structure Pattern: PATTERN =
    38 struct
    39 
    40 exception Unif;
    41 exception Pattern;
    42 
    43 val trace_unify_fail = ref false;
    44 
    45 fun string_of_term thy env binders t = Sign.string_of_term thy
    46   (Envir.norm_term env (subst_bounds(map Free binders,t)));
    47 
    48 fun bname binders i = fst(List.nth(binders,i));
    49 fun bnames binders is = space_implode " " (map (bname binders) is);
    50 
    51 fun typ_clash thy (tye,T,U) =
    52   if !trace_unify_fail
    53   then let val t = Sign.string_of_typ thy (Envir.norm_type tye T)
    54            and u = Sign.string_of_typ thy (Envir.norm_type tye U)
    55        in tracing("The following types do not unify:\n" ^ t ^ "\n" ^ u) end
    56   else ()
    57 
    58 fun clash a b =
    59   if !trace_unify_fail then tracing("Clash: " ^ a ^ " =/= " ^ b) else ()
    60 
    61 fun boundVar binders i =
    62   "bound variable " ^ bname binders i ^ " (depth " ^ string_of_int i ^ ")";
    63 
    64 fun clashBB binders i j =
    65   if !trace_unify_fail then clash (boundVar binders i) (boundVar binders j)
    66   else ()
    67 
    68 fun clashB binders i s =
    69   if !trace_unify_fail then clash (boundVar binders i) s
    70   else ()
    71 
    72 fun proj_fail thy (env,binders,F,_,is,t) =
    73   if !trace_unify_fail
    74   then let val f = Syntax.string_of_vname F
    75            val xs = bnames binders is
    76            val u = string_of_term thy env binders t
    77            val ys = bnames binders (loose_bnos t \\ is)
    78        in tracing("Cannot unify variable " ^ f ^
    79                " (depending on bound variables " ^ xs ^ ")\nwith term " ^ u ^
    80                "\nTerm contains additional bound variable(s) " ^ ys)
    81        end
    82   else ()
    83 
    84 fun ocheck_fail thy (F,t,binders,env) =
    85   if !trace_unify_fail
    86   then let val f = Syntax.string_of_vname F
    87            val u = string_of_term thy env binders t
    88        in tracing("Variable " ^ f ^ " occurs in term\n" ^ u ^
    89                   "\nCannot unify!\n")
    90        end
    91   else ()
    92 
    93 fun occurs(F,t,env) =
    94     let fun occ(Var (G, T))   = (case Envir.lookup (env, (G, T)) of
    95                                  SOME(t) => occ t
    96                                | NONE    => F=G)
    97           | occ(t1$t2)      = occ t1 orelse occ t2
    98           | occ(Abs(_,_,t)) = occ t
    99           | occ _           = false
   100     in occ t end;
   101 
   102 
   103 fun mapbnd f =
   104     let fun mpb d (Bound(i))     = if i < d then Bound(i) else Bound(f(i-d)+d)
   105           | mpb d (Abs(s,T,t))   = Abs(s,T,mpb(d+1) t)
   106           | mpb d ((u1 $ u2))    = (mpb d u1)$(mpb d u2)
   107           | mpb _ atom           = atom
   108     in mpb 0 end;
   109 
   110 fun idx [] j     = raise Unif
   111   | idx(i::is) j = if (i:int) =j then length is else idx is j;
   112 
   113 fun at xs i = List.nth (xs,i);
   114 
   115 fun mkabs (binders,is,t)  =
   116     let fun mk(i::is) = let val (x,T) = List.nth(binders,i)
   117                         in Abs(x,T,mk is) end
   118           | mk []     = t
   119     in mk is end;
   120 
   121 val incr = mapbnd (fn i => i+1);
   122 
   123 fun ints_of []             = []
   124   | ints_of (Bound i ::bs) =
   125       let val is = ints_of bs
   126       in if i mem_int is then raise Pattern else i::is end
   127   | ints_of _              = raise Pattern;
   128 
   129 fun ints_of' env ts = ints_of (map (Envir.head_norm env) ts);
   130 
   131 
   132 fun app (s,(i::is)) = app (s$Bound(i),is)
   133   | app (s,[])      = s;
   134 
   135 fun red (Abs(_,_,s)) (i::is) js = red s is (i::js)
   136   | red t            []      [] = t
   137   | red t            is      jn = app (mapbnd (at jn) t,is);
   138 
   139 
   140 (* split_type ([T1,....,Tn]---> T,n,[]) = ([Tn,...,T1],T) *)
   141 fun split_type (T,0,Ts)                    = (Ts,T)
   142   | split_type (Type ("fun",[T1,T2]),n,Ts) = split_type (T2,n-1,T1::Ts)
   143   | split_type _                           = error("split_type");
   144 
   145 fun type_of_G (env as Envir.Envir {iTs, ...}) (T,n,is) =
   146   let val (Ts, U) = split_type (Envir.norm_type iTs T, n, [])
   147   in map (at Ts) is ---> U end;
   148 
   149 fun mkhnf (binders,is,G,js) = mkabs (binders, is, app(G,js));
   150 
   151 fun mknewhnf(env,binders,is,F as (a,_),T,js) =
   152   let val (env',G) = Envir.genvar a (env,type_of_G env (T,length is,js))
   153   in Envir.update (((F, T), mkhnf (binders, is, G, js)), env') end;
   154 
   155 
   156 (* mk_proj_list(is) = [ |is| - k | 1 <= k <= |is| and is[k] >= 0 ] *)
   157 fun mk_proj_list is =
   158     let fun mk(i::is,j) = if isSome i then j :: mk(is,j-1) else mk(is,j-1)
   159           | mk([],_)    = []
   160     in mk(is,length is - 1) end;
   161 
   162 fun proj(s,env,binders,is) =
   163     let fun trans d i = if i<d then i else (idx is (i-d))+d;
   164         fun pr(s,env,d,binders) = (case Envir.head_norm env s of
   165               Abs(a,T,t) => let val (t',env') = pr(t,env,d+1,((a,T)::binders))
   166                             in (Abs(a,T,t'),env') end
   167             | t => (case strip_comb t of
   168                 (c as Const _,ts) =>
   169                          let val (ts',env') = prs(ts,env,d,binders)
   170                          in (list_comb(c,ts'),env') end
   171                  | (f as Free _,ts) =>
   172                          let val (ts',env') = prs(ts,env,d,binders)
   173                          in (list_comb(f,ts'),env') end
   174                  | (Bound(i),ts) =>
   175                          let val j = trans d i
   176                              val (ts',env') = prs(ts,env,d,binders)
   177                          in (list_comb(Bound j,ts'),env') end
   178                  | (Var(F as (a,_),Fty),ts) =>
   179                       let val js = ints_of' env ts;
   180                           val js' = map (try (trans d)) js;
   181                           val ks = mk_proj_list js';
   182                           val ls = List.mapPartial I js'
   183                           val Hty = type_of_G env (Fty,length js,ks)
   184                           val (env',H) = Envir.genvar a (env,Hty)
   185                           val env'' =
   186                             Envir.update (((F, Fty), mkhnf (binders, js, H, ks)), env')
   187                       in (app(H,ls),env'') end
   188                  | _  => raise Pattern))
   189         and prs(s::ss,env,d,binders) =
   190               let val (s',env1) = pr(s,env,d,binders)
   191                   val (ss',env2) = prs(ss,env1,d,binders)
   192               in (s'::ss',env2) end
   193           | prs([],env,_,_) = ([],env)
   194    in if downto0(is,length binders - 1) then (s,env)
   195       else pr(s,env,0,binders)
   196    end;
   197 
   198 
   199 (* mk_ff_list(is,js) = [ length(is) - k | 1 <= k <= |is| and is[k] = js[k] ] *)
   200 fun mk_ff_list(is,js) =
   201     let fun mk([],[],_)        = []
   202           | mk(i::is,j::js, k) = if (i:int) = j then k :: mk(is,js,k-1)
   203                                         else mk(is,js,k-1)
   204           | mk _               = error"mk_ff_list"
   205     in mk(is,js,length is-1) end;
   206 
   207 fun flexflex1(env,binders,F,Fty,is,js) =
   208   if is=js then env
   209   else let val ks = mk_ff_list(is,js)
   210        in mknewhnf(env,binders,is,F,Fty,ks) end;
   211 
   212 fun flexflex2(env,binders,F,Fty,is,G,Gty,js) =
   213   let fun ff(F,Fty,is,G as (a,_),Gty,js) =
   214             if js subset_int is
   215             then let val t= mkabs(binders,is,app(Var(G,Gty),map (idx is) js))
   216                  in Envir.update (((F, Fty), t), env) end
   217             else let val ks = is inter_int js
   218                      val Hty = type_of_G env (Fty,length is,map (idx is) ks)
   219                      val (env',H) = Envir.genvar a (env,Hty)
   220                      fun lam(is) = mkabs(binders,is,app(H,map (idx is) ks));
   221                  in Envir.update (((G, Gty), lam js), Envir.update (((F, Fty), lam is), env'))
   222                  end;
   223   in if xless(G,F) then ff(F,Fty,is,G,Gty,js) else ff(G,Gty,js,F,Fty,is) end
   224 
   225 fun unify_types thy (T,U, env as Envir.Envir{asol,iTs,maxidx}) =
   226   if T=U then env
   227   else let val (iTs',maxidx') = Sign.typ_unify thy (U, T) (iTs, maxidx)
   228        in Envir.Envir{asol=asol,maxidx=maxidx',iTs=iTs'} end
   229        handle Type.TUNIFY => (typ_clash thy (iTs,T,U); raise Unif);
   230 
   231 fun unif thy binders (env,(s,t)) = case (Envir.head_norm env s, Envir.head_norm env t) of
   232       (Abs(ns,Ts,ts),Abs(nt,Tt,tt)) =>
   233          let val name = if ns = "" then nt else ns
   234          in unif thy ((name,Ts)::binders) (env,(ts,tt)) end
   235     | (Abs(ns,Ts,ts),t) => unif thy ((ns,Ts)::binders) (env,(ts,(incr t)$Bound(0)))
   236     | (t,Abs(nt,Tt,tt)) => unif thy ((nt,Tt)::binders) (env,((incr t)$Bound(0),tt))
   237     | p => cases thy (binders,env,p)
   238 
   239 and cases thy (binders,env,(s,t)) = case (strip_comb s,strip_comb t) of
   240        ((Var(F,Fty),ss),(Var(G,Gty),ts)) =>
   241          if F = G then flexflex1(env,binders,F,Fty,ints_of' env ss,ints_of' env ts)
   242                   else flexflex2(env,binders,F,Fty,ints_of' env ss,G,Gty,ints_of' env ts)
   243       | ((Var(F,Fty),ss),_)           => flexrigid thy (env,binders,F,Fty,ints_of' env ss,t)
   244       | (_,(Var(F,Fty),ts))           => flexrigid thy (env,binders,F,Fty,ints_of' env ts,s)
   245       | ((Const c,ss),(Const d,ts))   => rigidrigid thy (env,binders,c,d,ss,ts)
   246       | ((Free(f),ss),(Free(g),ts))   => rigidrigid thy (env,binders,f,g,ss,ts)
   247       | ((Bound(i),ss),(Bound(j),ts)) => rigidrigidB thy (env,binders,i,j,ss,ts)
   248       | ((Abs(_),_),_)                => raise Pattern
   249       | (_,(Abs(_),_))                => raise Pattern
   250       | ((Const(c,_),_),(Free(f,_),_)) => (clash c f; raise Unif)
   251       | ((Const(c,_),_),(Bound i,_))   => (clashB binders i c; raise Unif)
   252       | ((Free(f,_),_),(Const(c,_),_)) => (clash f c; raise Unif)
   253       | ((Free(f,_),_),(Bound i,_))    => (clashB binders i f; raise Unif)
   254       | ((Bound i,_),(Const(c,_),_))   => (clashB binders i c; raise Unif)
   255       | ((Bound i,_),(Free(f,_),_))    => (clashB binders i f; raise Unif)
   256 
   257 
   258 and rigidrigid thy (env,binders,(a,Ta),(b,Tb),ss,ts) =
   259       if a<>b then (clash a b; raise Unif)
   260       else Library.foldl (unif thy binders) (unify_types thy (Ta,Tb,env), ss~~ts)
   261 
   262 and rigidrigidB thy (env,binders,i,j,ss,ts) =
   263      if i <> j then (clashBB binders i j; raise Unif)
   264      else Library.foldl (unif thy binders) (env ,ss~~ts)
   265 
   266 and flexrigid thy (params as (env,binders,F,Fty,is,t)) =
   267       if occurs(F,t,env) then (ocheck_fail thy (F,t,binders,env); raise Unif)
   268       else (let val (u,env') = proj(t,env,binders,is)
   269             in Envir.update (((F, Fty), mkabs (binders, is, u)), env') end
   270             handle Unif => (proj_fail thy params; raise Unif));
   271 
   272 fun unify(thy,env,tus) = Library.foldl (unif thy []) (env,tus);
   273 
   274 
   275 (*Eta-contract a term (fully)*)
   276 
   277 fun eta_contract t =
   278   let
   279     exception SAME;
   280     fun eta (Abs (a, T, body)) =
   281       ((case eta body of
   282           body' as (f $ Bound 0) =>
   283             if loose_bvar1 (f, 0) then Abs(a, T, body')
   284             else incr_boundvars ~1 f
   285         | body' => Abs (a, T, body')) handle SAME =>
   286        (case body of
   287           (f $ Bound 0) =>
   288             if loose_bvar1 (f, 0) then raise SAME
   289             else incr_boundvars ~1 f
   290         | _ => raise SAME))
   291       | eta (f $ t) =
   292           (let val f' = eta f
   293            in f' $ etah t end handle SAME => f $ eta t)
   294       | eta _ = raise SAME
   295     and etah t = (eta t handle SAME => t)
   296   in etah t end;
   297 
   298 val beta_eta_contract = eta_contract o Envir.beta_norm;
   299 
   300 (*Eta-contract a term from outside: just enough to reduce it to an atom
   301 DOESN'T QUITE WORK!
   302 *)
   303 fun eta_contract_atom (t0 as Abs(a, T, body)) =
   304       (case  eta_contract2 body  of
   305         body' as (f $ Bound 0) =>
   306             if loose_bvar1(f,0) then Abs(a,T,body')
   307             else eta_contract_atom (incr_boundvars ~1 f)
   308       | _ => t0)
   309   | eta_contract_atom t = t
   310 and eta_contract2 (f$t) = f $ eta_contract_atom t
   311   | eta_contract2 t     = eta_contract_atom t;
   312 
   313 (* put a term into eta long beta normal form *)
   314 fun eta_long Ts (Abs (s, T, t)) = Abs (s, T, eta_long (T :: Ts) t)
   315   | eta_long Ts t = (case strip_comb t of
   316       (Abs _, _) => eta_long Ts (Envir.beta_norm t)
   317     | (u, ts) =>
   318       let
   319         val Us = binder_types (fastype_of1 (Ts, t));
   320         val i = length Us
   321       in list_abs (map (pair "x") Us,
   322         list_comb (incr_boundvars i u, map (eta_long (rev Us @ Ts))
   323           (map (incr_boundvars i) ts @ map Bound (i - 1 downto 0))))
   324       end);
   325 
   326 
   327 (*Tests whether 2 terms are alpha/eta-convertible and have same type.
   328   Note that Consts and Vars may have more than one type.*)
   329 fun t aeconv u = aconv_aux (eta_contract_atom t, eta_contract_atom u)
   330 and aconv_aux (Const(a,T), Const(b,U)) = a=b  andalso  T=U
   331   | aconv_aux (Free(a,T),  Free(b,U))  = a=b  andalso  T=U
   332   | aconv_aux (Var(v,T),   Var(w,U))   = eq_ix(v,w) andalso  T=U
   333   | aconv_aux (Bound i,    Bound j)    = i=j
   334   | aconv_aux (Abs(_,T,t), Abs(_,U,u)) = (t aeconv u)  andalso  T=U
   335   | aconv_aux (f$t,        g$u)        = (f aeconv g)  andalso (t aeconv u)
   336   | aconv_aux _ =  false;
   337 
   338 
   339 (*** Matching ***)
   340 
   341 exception MATCH;
   342 
   343 fun typ_match thy (tyenv, TU) = Sign.typ_match thy TU tyenv
   344   handle Type.TYPE_MATCH => raise MATCH;
   345 
   346 (*First-order matching;
   347   fomatch thy (pattern, object) returns a (tyvar,typ)list and (var,term)list.
   348   The pattern and object may have variables in common.
   349   Instantiation does not affect the object, so matching ?a with ?a+1 works.
   350   Object is eta-contracted on the fly (by eta-expanding the pattern).
   351   Precondition: the pattern is already eta-contracted!
   352   Note: types are matched on the fly *)
   353 fun fomatch thy =
   354   let
   355     fun mtch (instsp as (tyinsts,insts)) = fn
   356         (Var(ixn,T), t)  =>
   357           if loose_bvar(t,0) then raise MATCH
   358           else (case Envir.lookup' (insts, (ixn, T)) of
   359                   NONE => (typ_match thy (tyinsts, (T, fastype_of t)),
   360                            Vartab.curried_update_new (ixn, (T, t)) insts)
   361                 | SOME u => if t aeconv u then instsp else raise MATCH)
   362       | (Free (a,T), Free (b,U)) =>
   363           if a=b then (typ_match thy (tyinsts,(T,U)), insts) else raise MATCH
   364       | (Const (a,T), Const (b,U))  =>
   365           if a=b then (typ_match thy (tyinsts,(T,U)), insts) else raise MATCH
   366       | (Bound i, Bound j)  =>  if  i=j  then  instsp  else raise MATCH
   367       | (Abs(_,T,t), Abs(_,U,u))  =>
   368           mtch (typ_match thy (tyinsts,(T,U)),insts) (t,u)
   369       | (f$t, g$u) => mtch (mtch instsp (f,g)) (t, u)
   370       | (t, Abs(_,U,u))  =>  mtch instsp ((incr t)$(Bound 0), u)
   371       | _ => raise MATCH
   372   in mtch end;
   373 
   374 fun first_order_match thy = fomatch thy (Vartab.empty, Vartab.empty);
   375 
   376 (* Matching of higher-order patterns *)
   377 
   378 fun match_bind(itms,binders,ixn,T,is,t) =
   379   let val js = loose_bnos t
   380   in if null is
   381      then if null js then Vartab.curried_update_new (ixn, (T, t)) itms else raise MATCH
   382      else if js subset_int is
   383           then let val t' = if downto0(is,length binders - 1) then t
   384                             else mapbnd (idx is) t
   385                in Vartab.curried_update_new (ixn, (T, mkabs (binders, is, t'))) itms end
   386           else raise MATCH
   387   end;
   388 
   389 fun match thy (po as (pat,obj)) =
   390 let
   391   (* Pre: pat and obj have same type *)
   392   fun mtch binders (env as (iTs,itms),(pat,obj)) =
   393     case pat of
   394       Abs(ns,Ts,ts) =>
   395         (case obj of
   396            Abs(nt,Tt,tt) => mtch ((nt,Tt)::binders) (env,(ts,tt))
   397          | _ => let val Tt = Envir.typ_subst_TVars iTs Ts
   398                 in mtch((ns,Tt)::binders)(env,(ts,(incr obj)$Bound(0))) end)
   399     | _ => (case obj of
   400               Abs(nt,Tt,tt) =>
   401                 mtch((nt,Tt)::binders)(env,((incr pat)$Bound(0),tt))
   402             | _ => cases(binders,env,pat,obj))
   403 
   404   and cases(binders,env as (iTs,itms),pat,obj) =
   405     let val (ph,pargs) = strip_comb pat
   406         fun rigrig1(iTs,oargs) =
   407               Library.foldl (mtch binders) ((iTs,itms), pargs~~oargs)
   408         fun rigrig2((a:string,Ta),(b,Tb),oargs) =
   409               if a <> b then raise MATCH
   410               else rigrig1(typ_match thy (iTs,(Ta,Tb)), oargs)
   411     in case ph of
   412          Var(ixn,T) =>
   413            let val is = ints_of pargs
   414            in case Envir.lookup' (itms, (ixn, T)) of
   415                 NONE => (iTs,match_bind(itms,binders,ixn,T,is,obj))
   416               | SOME u => if obj aeconv (red u is []) then env
   417                           else raise MATCH
   418            end
   419        | _ =>
   420            let val (oh,oargs) = strip_comb obj
   421            in case (ph,oh) of
   422                 (Const c,Const d) => rigrig2(c,d,oargs)
   423               | (Free f,Free g)   => rigrig2(f,g,oargs)
   424               | (Bound i,Bound j) => if i<>j then raise MATCH
   425                                      else rigrig1(iTs,oargs)
   426               | (Abs _, _)        => raise Pattern
   427               | (_, Abs _)        => raise Pattern
   428               | _                 => raise MATCH
   429            end
   430     end;
   431 
   432   val pT = fastype_of pat
   433   and oT = fastype_of obj
   434   val iTs = typ_match thy (Vartab.empty, (pT,oT))
   435   val insts2 = (iTs, Vartab.empty)
   436 
   437 in mtch [] (insts2, po)
   438    handle Pattern => fomatch thy insts2 po
   439 end;
   440 
   441 (*Predicate: does the pattern match the object?*)
   442 fun matches thy po = (match thy po; true) handle MATCH => false;
   443 
   444 (* Does pat match a subterm of obj? *)
   445 fun matches_subterm thy (pat,obj) =
   446   let fun msub(bounds,obj) = matches thy (pat,obj) orelse
   447             case obj of
   448               Abs(x,T,t) => let val y = variant bounds x
   449                                 val f = Free(":" ^ y,T)
   450                             in msub(x::bounds,subst_bound(f,t)) end
   451             | s$t => msub(bounds,s) orelse msub(bounds,t)
   452             | _ => false
   453   in msub([],obj) end;
   454 
   455 fun first_order(Abs(_,_,t)) = first_order t
   456   | first_order(t $ u) = first_order t andalso first_order u andalso
   457                          not(is_Var t)
   458   | first_order _ = true;
   459 
   460 fun pattern(Abs(_,_,t)) = pattern t
   461   | pattern(t) = let val (head,args) = strip_comb t
   462                  in if is_Var head
   463                     then let val _ = ints_of args in true end
   464                          handle Pattern => false
   465                     else forall pattern args
   466                  end;
   467 
   468 
   469 (* rewriting -- simple but fast *)
   470 
   471 fun rewrite_term thy rules procs tm =
   472   let
   473     val skel0 = Bound 0;
   474 
   475     fun variant_absfree bounds (x, T, t) =
   476       let
   477         val (x', t') = Term.dest_abs (Term.bound bounds, T, t);
   478         fun abs u = Abs (x, T, abstract_over (Free (x', T), u));
   479       in (abs, t') end;
   480 
   481     fun match_rew tm (tm1, tm2) =
   482       let val rtm = if_none (Term.rename_abs tm1 tm tm2) tm2 in
   483         SOME (Envir.subst_vars (match thy (tm1, tm)) rtm, rtm)
   484           handle MATCH => NONE
   485       end;
   486 
   487     fun rew (Abs (_, _, body) $ t) = SOME (subst_bound (t, body), skel0)
   488       | rew tm = (case get_first (match_rew tm) rules of
   489           NONE => Option.map (rpair skel0) (get_first (fn p => p tm) procs)
   490         | x => x);
   491 
   492     fun rew1 bounds (Var _) _ = NONE
   493       | rew1 bounds skel tm = (case rew2 bounds skel tm of
   494           SOME tm1 => (case rew tm1 of
   495               SOME (tm2, skel') => SOME (if_none (rew1 bounds skel' tm2) tm2)
   496             | NONE => SOME tm1)
   497         | NONE => (case rew tm of
   498               SOME (tm1, skel') => SOME (if_none (rew1 bounds skel' tm1) tm1)
   499             | NONE => NONE))
   500 
   501     and rew2 bounds skel (tm1 $ tm2) = (case tm1 of
   502             Abs (_, _, body) =>
   503               let val tm' = subst_bound (tm2, body)
   504               in SOME (if_none (rew2 bounds skel0 tm') tm') end
   505           | _ =>
   506             let val (skel1, skel2) = (case skel of
   507                 skel1 $ skel2 => (skel1, skel2)
   508               | _ => (skel0, skel0))
   509             in case rew1 bounds skel1 tm1 of
   510                 SOME tm1' => (case rew1 bounds skel2 tm2 of
   511                     SOME tm2' => SOME (tm1' $ tm2')
   512                   | NONE => SOME (tm1' $ tm2))
   513               | NONE => (case rew1 bounds skel2 tm2 of
   514                     SOME tm2' => SOME (tm1 $ tm2')
   515                   | NONE => NONE)
   516             end)
   517       | rew2 bounds skel (Abs body) =
   518           let
   519             val (abs, tm') = variant_absfree bounds body;
   520             val skel' = (case skel of Abs (_, _, skel') => skel' | _ => skel0)
   521           in case rew1 (bounds + 1) skel' tm' of
   522               SOME tm'' => SOME (abs tm'')
   523             | NONE => NONE
   524           end
   525       | rew2 _ _ _ = NONE;
   526 
   527   in if_none (rew1 0 skel0 tm) tm end;
   528 
   529 end;
   530 
   531 val trace_unify_fail = Pattern.trace_unify_fail;