src/Pure/tctical.ML
author haftmann
Tue Sep 06 08:30:43 2005 +0200 (2005-09-06)
changeset 17271 2756a73f63a5
parent 16510 606d919ad3c3
child 17344 8b2f56aff711
permissions -rw-r--r--
introduced some new-style AList operations
     1 (*  Title:      Pure/tctical.ML
     2     ID:         $Id$
     3     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     4     Copyright   1993  University of Cambridge
     5 
     6 Tacticals.
     7 *)
     8 
     9 infix 1 THEN THEN' THEN_ALL_NEW;
    10 infix 0 ORELSE APPEND INTLEAVE ORELSE' APPEND' INTLEAVE';
    11 infix 0 THEN_ELSE;
    12 
    13 
    14 signature TACTICAL =
    15 sig
    16   type tactic  (* = thm -> thm Seq.seq*)
    17   val all_tac           : tactic
    18   val ALLGOALS          : (int -> tactic) -> tactic
    19   val APPEND            : tactic * tactic -> tactic
    20   val APPEND'           : ('a -> tactic) * ('a -> tactic) -> 'a -> tactic
    21   val CHANGED           : tactic -> tactic
    22   val CHANGED_PROP      : tactic -> tactic
    23   val CHANGED_GOAL      : (int -> tactic) -> int -> tactic
    24   val COND              : (thm -> bool) -> tactic -> tactic -> tactic
    25   val DETERM            : tactic -> tactic
    26   val EVERY             : tactic list -> tactic
    27   val EVERY'            : ('a -> tactic) list -> 'a -> tactic
    28   val EVERY1            : (int -> tactic) list -> tactic
    29   val FILTER            : (thm -> bool) -> tactic -> tactic
    30   val FIRST             : tactic list -> tactic
    31   val FIRST'            : ('a -> tactic) list -> 'a -> tactic
    32   val FIRST1            : (int -> tactic) list -> tactic
    33   val FIRSTGOAL         : (int -> tactic) -> tactic
    34   val INTLEAVE          : tactic * tactic -> tactic
    35   val INTLEAVE'         : ('a -> tactic) * ('a -> tactic) -> 'a -> tactic
    36   val METAHYPS          : (thm list -> tactic) -> int -> tactic
    37   val no_tac            : tactic
    38   val ORELSE            : tactic * tactic -> tactic
    39   val ORELSE'           : ('a -> tactic) * ('a -> tactic) -> 'a -> tactic
    40   val pause_tac         : tactic
    41   val print_tac         : string -> tactic
    42   val PRIMITIVE         : (thm -> thm) -> tactic
    43   val PRIMSEQ           : (thm -> thm Seq.seq) -> tactic
    44   val RANGE             : (int -> tactic) list -> int -> tactic
    45   val REPEAT            : tactic -> tactic
    46   val REPEAT1           : tactic -> tactic
    47   val REPEAT_FIRST      : (int -> tactic) -> tactic
    48   val REPEAT_SOME       : (int -> tactic) -> tactic
    49   val REPEAT_DETERM_N   : int -> tactic -> tactic
    50   val REPEAT_DETERM     : tactic -> tactic
    51   val REPEAT_DETERM1    : tactic -> tactic
    52   val REPEAT_DETERM_FIRST: (int -> tactic) -> tactic
    53   val REPEAT_DETERM_SOME: (int -> tactic) -> tactic
    54   val DETERM_UNTIL      : (thm -> bool) -> tactic -> tactic
    55   val SELECT_GOAL       : tactic -> int -> tactic
    56   val SINGLE            : tactic -> thm -> thm option
    57   val SOMEGOAL          : (int -> tactic) -> tactic
    58   val strip_context     : term -> (string * typ) list * term list * term
    59   val SUBGOAL           : ((term*int) -> tactic) -> int -> tactic
    60   val suppress_tracing  : bool ref
    61   val THEN              : tactic * tactic -> tactic
    62   val THEN'             : ('a -> tactic) * ('a -> tactic) -> 'a -> tactic
    63   val THEN_ALL_NEW      : (int -> tactic) * (int -> tactic) -> int -> tactic
    64   val REPEAT_ALL_NEW    : (int -> tactic) -> int -> tactic
    65   val THEN_ELSE         : tactic * (tactic*tactic) -> tactic
    66   val traced_tac        : (thm -> (thm * thm Seq.seq) option) -> tactic
    67   val tracify           : bool ref -> tactic -> tactic
    68   val trace_REPEAT      : bool ref
    69   val TRY               : tactic -> tactic
    70   val TRYALL            : (int -> tactic) -> tactic
    71 end;
    72 
    73 
    74 structure Tactical : TACTICAL =
    75 struct
    76 
    77 (**** Tactics ****)
    78 
    79 (*A tactic maps a proof tree to a sequence of proof trees:
    80     if length of sequence = 0 then the tactic does not apply;
    81     if length > 1 then backtracking on the alternatives can occur.*)
    82 
    83 type tactic = thm -> thm Seq.seq;
    84 
    85 
    86 (*** LCF-style tacticals ***)
    87 
    88 (*the tactical THEN performs one tactic followed by another*)
    89 fun (tac1 THEN tac2) st = Seq.flat (Seq.map tac2 (tac1 st));
    90 
    91 
    92 (*The tactical ORELSE uses the first tactic that returns a nonempty sequence.
    93   Like in LCF, ORELSE commits to either tac1 or tac2 immediately.
    94   Does not backtrack to tac2 if tac1 was initially chosen. *)
    95 fun (tac1 ORELSE tac2) st =
    96     case Seq.pull(tac1 st) of
    97         NONE       => tac2 st
    98       | sequencecell => Seq.make(fn()=> sequencecell);
    99 
   100 
   101 (*The tactical APPEND combines the results of two tactics.
   102   Like ORELSE, but allows backtracking on both tac1 and tac2.
   103   The tactic tac2 is not applied until needed.*)
   104 fun (tac1 APPEND tac2) st =
   105   Seq.append(tac1 st,
   106                   Seq.make(fn()=> Seq.pull (tac2 st)));
   107 
   108 (*Like APPEND, but interleaves results of tac1 and tac2.*)
   109 fun (tac1 INTLEAVE tac2) st =
   110     Seq.interleave(tac1 st,
   111                         Seq.make(fn()=> Seq.pull (tac2 st)));
   112 
   113 (*Conditional tactic.
   114         tac1 ORELSE tac2 = tac1 THEN_ELSE (all_tac, tac2)
   115         tac1 THEN tac2   = tac1 THEN_ELSE (tac2, no_tac)
   116 *)
   117 fun (tac THEN_ELSE (tac1, tac2)) st =
   118     case Seq.pull(tac st) of
   119         NONE    => tac2 st              (*failed; try tactic 2*)
   120       | seqcell => Seq.flat       (*succeeded; use tactic 1*)
   121                     (Seq.map tac1 (Seq.make(fn()=> seqcell)));
   122 
   123 
   124 (*Versions for combining tactic-valued functions, as in
   125      SOMEGOAL (resolve_tac rls THEN' assume_tac) *)
   126 fun (tac1 THEN' tac2) x = tac1 x THEN tac2 x;
   127 fun (tac1 ORELSE' tac2) x = tac1 x ORELSE tac2 x;
   128 fun (tac1 APPEND' tac2) x = tac1 x APPEND tac2 x;
   129 fun (tac1 INTLEAVE' tac2) x = tac1 x INTLEAVE tac2 x;
   130 
   131 (*passes all proofs through unchanged;  identity of THEN*)
   132 fun all_tac st = Seq.single st;
   133 
   134 (*passes no proofs through;  identity of ORELSE and APPEND*)
   135 fun no_tac st  = Seq.empty;
   136 
   137 
   138 (*Make a tactic deterministic by chopping the tail of the proof sequence*)
   139 fun DETERM tac = Seq.DETERM tac;
   140 
   141 (*Conditional tactical: testfun controls which tactic to use next.
   142   Beware: due to eager evaluation, both thentac and elsetac are evaluated.*)
   143 fun COND testfun thenf elsef = (fn prf =>
   144     if testfun prf then  thenf prf   else  elsef prf);
   145 
   146 (*Do the tactic or else do nothing*)
   147 fun TRY tac = tac ORELSE all_tac;
   148 
   149 (*** List-oriented tactics ***)
   150 
   151 local
   152   (*This version of EVERY avoids backtracking over repeated states*)
   153 
   154   fun EVY (trail, []) st =
   155         Seq.make (fn()=> SOME(st,
   156                         Seq.make (fn()=> Seq.pull (evyBack trail))))
   157     | EVY (trail, tac::tacs) st =
   158           case Seq.pull(tac st) of
   159               NONE    => evyBack trail              (*failed: backtrack*)
   160             | SOME(st',q) => EVY ((st',q,tacs)::trail, tacs) st'
   161   and evyBack [] = Seq.empty (*no alternatives*)
   162     | evyBack ((st',q,tacs)::trail) =
   163           case Seq.pull q of
   164               NONE        => evyBack trail
   165             | SOME(st,q') => if eq_thm (st',st)
   166                              then evyBack ((st',q',tacs)::trail)
   167                              else EVY ((st,q',tacs)::trail, tacs) st
   168 in
   169 
   170 (* EVERY [tac1,...,tacn]   equals    tac1 THEN ... THEN tacn   *)
   171 fun EVERY tacs = EVY ([], tacs);
   172 end;
   173 
   174 
   175 (* EVERY' [tac1,...,tacn] i  equals    tac1 i THEN ... THEN tacn i   *)
   176 fun EVERY' tacs i = EVERY (map (fn f => f i) tacs);
   177 
   178 (*Apply every tactic to 1*)
   179 fun EVERY1 tacs = EVERY' tacs 1;
   180 
   181 (* FIRST [tac1,...,tacn]   equals    tac1 ORELSE ... ORELSE tacn   *)
   182 fun FIRST tacs = foldr (op ORELSE) no_tac tacs;
   183 
   184 (* FIRST' [tac1,...,tacn] i  equals    tac1 i ORELSE ... ORELSE tacn i   *)
   185 fun FIRST' tacs = foldr (op ORELSE') (K no_tac) tacs;
   186 
   187 (*Apply first tactic to 1*)
   188 fun FIRST1 tacs = FIRST' tacs 1;
   189 
   190 (*Apply tactics on consecutive subgoals*)
   191 fun RANGE [] _ = all_tac
   192   | RANGE (tac :: tacs) i = RANGE tacs (i + 1) THEN tac i;
   193 
   194 
   195 (*** Tracing tactics ***)
   196 
   197 (*Print the current proof state and pass it on.*)
   198 fun print_tac msg =
   199     (fn st =>
   200      (tracing msg;
   201       tracing ((Pretty.string_of o Pretty.chunks o 
   202                  Display.pretty_goals (! Display.goals_limit)) st); 
   203       Seq.single st));
   204 
   205 (*Pause until a line is typed -- if non-empty then fail. *)
   206 fun pause_tac st =
   207   (tracing "** Press RETURN to continue:";
   208    if TextIO.inputLine TextIO.stdIn = "\n" then Seq.single st
   209    else (tracing "Goodbye";  Seq.empty));
   210 
   211 exception TRACE_EXIT of thm
   212 and TRACE_QUIT;
   213 
   214 (*Tracing flags*)
   215 val trace_REPEAT= ref false
   216 and suppress_tracing = ref false;
   217 
   218 (*Handle all tracing commands for current state and tactic *)
   219 fun exec_trace_command flag (tac, st) =
   220    case TextIO.inputLine(TextIO.stdIn) of
   221        "\n" => tac st
   222      | "f\n" => Seq.empty
   223      | "o\n" => (flag:=false;  tac st)
   224      | "s\n" => (suppress_tracing:=true;  tac st)
   225      | "x\n" => (tracing "Exiting now";  raise (TRACE_EXIT st))
   226      | "quit\n" => raise TRACE_QUIT
   227      | _     => (tracing
   228 "Type RETURN to continue or...\n\
   229 \     f    - to fail here\n\
   230 \     o    - to switch tracing off\n\
   231 \     s    - to suppress tracing until next entry to a tactical\n\
   232 \     x    - to exit at this point\n\
   233 \     quit - to abort this tracing run\n\
   234 \** Well? "     ;  exec_trace_command flag (tac, st));
   235 
   236 
   237 (*Extract from a tactic, a thm->thm seq function that handles tracing*)
   238 fun tracify flag tac st =
   239   if !flag andalso not (!suppress_tracing)
   240            then (Display.print_goals (! Display.goals_limit) st;
   241                  tracing "** Press RETURN to continue:";
   242                  exec_trace_command flag (tac,st))
   243   else tac st;
   244 
   245 (*Create a tactic whose outcome is given by seqf, handling TRACE_EXIT*)
   246 fun traced_tac seqf st =
   247     (suppress_tracing := false;
   248      Seq.make (fn()=> seqf st
   249                          handle TRACE_EXIT st' => SOME(st', Seq.empty)));
   250 
   251 
   252 (*Deterministic DO..UNTIL: only retains the first outcome; tail recursive.
   253   Forces repitition until predicate on state is fulfilled.*)
   254 fun DETERM_UNTIL p tac =
   255 let val tac = tracify trace_REPEAT tac
   256     fun drep st = if p st then SOME (st, Seq.empty)
   257                           else (case Seq.pull(tac st) of
   258                                   NONE        => NONE
   259                                 | SOME(st',_) => drep st')
   260 in  traced_tac drep  end;
   261 
   262 (*Deterministic REPEAT: only retains the first outcome;
   263   uses less space than REPEAT; tail recursive.
   264   If non-negative, n bounds the number of repetitions.*)
   265 fun REPEAT_DETERM_N n tac =
   266   let val tac = tracify trace_REPEAT tac
   267       fun drep 0 st = SOME(st, Seq.empty)
   268         | drep n st =
   269            (case Seq.pull(tac st) of
   270                 NONE       => SOME(st, Seq.empty)
   271               | SOME(st',_) => drep (n-1) st')
   272   in  traced_tac (drep n)  end;
   273 
   274 (*Allows any number of repetitions*)
   275 val REPEAT_DETERM = REPEAT_DETERM_N ~1;
   276 
   277 (*General REPEAT: maintains a stack of alternatives; tail recursive*)
   278 fun REPEAT tac =
   279   let val tac = tracify trace_REPEAT tac
   280       fun rep qs st =
   281         case Seq.pull(tac st) of
   282             NONE       => SOME(st, Seq.make(fn()=> repq qs))
   283           | SOME(st',q) => rep (q::qs) st'
   284       and repq [] = NONE
   285         | repq(q::qs) = case Seq.pull q of
   286             NONE       => repq qs
   287           | SOME(st,q) => rep (q::qs) st
   288   in  traced_tac (rep [])  end;
   289 
   290 (*Repeat 1 or more times*)
   291 fun REPEAT_DETERM1 tac = DETERM tac THEN REPEAT_DETERM tac;
   292 fun REPEAT1 tac = tac THEN REPEAT tac;
   293 
   294 
   295 (** Filtering tacticals **)
   296 
   297 fun FILTER pred tac st = Seq.filter pred (tac st);
   298 
   299 (*Accept only next states that change the theorem somehow*)
   300 fun CHANGED tac st =
   301   let fun diff st' = not (Thm.eq_thm (st, st'));
   302   in Seq.filter diff (tac st) end;
   303 
   304 (*Accept only next states that change the theorem's prop field
   305   (changes to signature, hyps, etc. don't count)*)
   306 fun CHANGED_PROP tac st =
   307   let fun diff st' = not (Drule.eq_thm_prop (st, st'));
   308   in Seq.filter diff (tac st) end;
   309 
   310 
   311 (*** Tacticals based on subgoal numbering ***)
   312 
   313 (*For n subgoals, performs tac(n) THEN ... THEN tac(1)
   314   Essential to work backwards since tac(i) may add/delete subgoals at i. *)
   315 fun ALLGOALS tac st =
   316   let fun doall 0 = all_tac
   317         | doall n = tac(n) THEN doall(n-1)
   318   in  doall(nprems_of st)st  end;
   319 
   320 (*For n subgoals, performs tac(n) ORELSE ... ORELSE tac(1)  *)
   321 fun SOMEGOAL tac st =
   322   let fun find 0 = no_tac
   323         | find n = tac(n) ORELSE find(n-1)
   324   in  find(nprems_of st)st  end;
   325 
   326 (*For n subgoals, performs tac(1) ORELSE ... ORELSE tac(n).
   327   More appropriate than SOMEGOAL in some cases.*)
   328 fun FIRSTGOAL tac st =
   329   let fun find (i,n) = if i>n then no_tac else  tac(i) ORELSE find (i+1,n)
   330   in  find(1, nprems_of st)st  end;
   331 
   332 (*Repeatedly solve some using tac. *)
   333 fun REPEAT_SOME tac = REPEAT1 (SOMEGOAL (REPEAT1 o tac));
   334 fun REPEAT_DETERM_SOME tac = REPEAT_DETERM1 (SOMEGOAL (REPEAT_DETERM1 o tac));
   335 
   336 (*Repeatedly solve the first possible subgoal using tac. *)
   337 fun REPEAT_FIRST tac = REPEAT1 (FIRSTGOAL (REPEAT1 o tac));
   338 fun REPEAT_DETERM_FIRST tac = REPEAT_DETERM1 (FIRSTGOAL (REPEAT_DETERM1 o tac));
   339 
   340 (*For n subgoals, tries to apply tac to n,...1  *)
   341 fun TRYALL tac = ALLGOALS (TRY o tac);
   342 
   343 
   344 (*Make a tactic for subgoal i, if there is one.  *)
   345 fun SUBGOAL goalfun i st =
   346   (case try Logic.nth_prem (i, Thm.prop_of st) of
   347     SOME goal => goalfun (goal, i) st
   348   | NONE => Seq.empty);
   349 
   350 (*Returns all states that have changed in subgoal i, counted from the LAST
   351   subgoal.  For stac, for example.*)
   352 fun CHANGED_GOAL tac i st =
   353     let val np = nprems_of st
   354         val d = np-i                 (*distance from END*)
   355         val t = List.nth(prems_of st, i-1)
   356         fun diff st' =
   357             nprems_of st' - d <= 0   (*the subgoal no longer exists*)
   358             orelse
   359              not (Pattern.aeconv (t,
   360                                   List.nth(prems_of st',
   361                                            nprems_of st' - d - 1)))
   362     in  Seq.filter diff (tac i st)  end
   363     handle Subscript => Seq.empty  (*no subgoal i*);
   364 
   365 fun (tac1 THEN_ALL_NEW tac2) i st =
   366   st |> (tac1 i THEN (fn st' => Seq.INTERVAL tac2 i (i + nprems_of st' - nprems_of st) st'));
   367 
   368 (*repeatedly dig into any emerging subgoals*)
   369 fun REPEAT_ALL_NEW tac =
   370   tac THEN_ALL_NEW (TRY o (fn i => REPEAT_ALL_NEW tac i));
   371 
   372 
   373 (*** SELECT_GOAL ***)
   374 
   375 (*Tactical for restricting the effect of a tactic to subgoal i.
   376   Works by making a new state from subgoal i, applying tac to it, and
   377   composing the resulting metathm with the original state.*)
   378 
   379 (*Does the work of SELECT_GOAL. *)
   380 fun select tac st i =
   381   let
   382     val thm = Drule.mk_triv_goal (adjust_maxidx (List.nth (cprems_of st, i-1)));
   383     fun restore th = Seq.hd (bicompose false (false, th, nprems_of th) 1
   384       (Thm.incr_indexes (#maxidx (rep_thm th) + 1) Drule.rev_triv_goal));
   385     fun next st' = bicompose false (false, restore st', nprems_of st') i st;
   386   in  Seq.flat (Seq.map next (tac thm))
   387   end;
   388 
   389 fun SELECT_GOAL tac i st =
   390   let val np = nprems_of st
   391   in  if 1<=i andalso i<=np then
   392           (*If only one subgoal, then just apply tactic*)
   393           if np=1 then tac st else select tac st i
   394       else Seq.empty
   395   end;
   396 
   397 
   398 (*Strips assumptions in goal yielding  ( [x1,...,xm], [H1,...,Hn], B )
   399     H1,...,Hn are the hypotheses;  x1...xm are variants of the parameters.
   400   Main difference from strip_assums concerns parameters:
   401     it replaces the bound variables by free variables.  *)
   402 fun strip_context_aux (params, Hs, Const("==>", _) $ H $ B) =
   403         strip_context_aux (params, H::Hs, B)
   404   | strip_context_aux (params, Hs, Const("all",_)$Abs(a,T,t)) =
   405         let val (b,u) = variant_abs(a,T,t)
   406         in  strip_context_aux ((b,T)::params, Hs, u)  end
   407   | strip_context_aux (params, Hs, B) = (rev params, rev Hs, B);
   408 
   409 fun strip_context A = strip_context_aux ([],[],A);
   410 
   411 
   412 (**** METAHYPS -- tactical for using hypotheses as meta-level assumptions
   413        METAHYPS (fn prems => tac prems) i
   414 
   415 converts subgoal i, of the form !!x1...xm. [| A1;...;An] ==> A into a new
   416 proof state A==>A, supplying A1,...,An as meta-level assumptions (in
   417 "prems").  The parameters x1,...,xm become free variables.  If the
   418 resulting proof state is [| B1;...;Bk] ==> C (possibly assuming A1,...,An)
   419 then it is lifted back into the original context, yielding k subgoals.
   420 
   421 Replaces unknowns in the context by Frees having the prefix METAHYP_
   422 New unknowns in [| B1;...;Bk] ==> C are lifted over x1,...,xm.
   423 DOES NOT HANDLE TYPE UNKNOWNS.
   424 ****)
   425 
   426 local
   427 
   428   (*Left-to-right replacements: ctpairs = [...,(vi,ti),...].
   429     Instantiates distinct free variables by terms of same type.*)
   430   fun free_instantiate ctpairs =
   431       forall_elim_list (map snd ctpairs) o forall_intr_list (map fst ctpairs);
   432 
   433   fun free_of s ((a,i), T) =
   434         Free(s ^ (case i of 0 => a | _ => a ^ "_" ^ string_of_int i),
   435              T)
   436 
   437   fun mk_inst (var as Var(v,T))  = (var,  free_of "METAHYP1_" (v,T))
   438 in
   439 
   440 fun metahyps_aux_tac tacf (prem,i) state =
   441   let val {sign,maxidx,...} = rep_thm state
   442       val cterm = cterm_of sign
   443       (*find all vars in the hyps -- should find tvars also!*)
   444       val hyps_vars = foldr add_term_vars [] (Logic.strip_assums_hyp prem)
   445       val insts = map mk_inst hyps_vars
   446       (*replace the hyps_vars by Frees*)
   447       val prem' = subst_atomic insts prem
   448       val (params,hyps,concl) = strip_context prem'
   449       val fparams = map Free params
   450       val cparams = map cterm fparams
   451       and chyps = map cterm hyps
   452       val hypths = map assume chyps
   453       fun swap_ctpair (t,u) = (cterm u, cterm t)
   454       (*Subgoal variables: make Free; lift type over params*)
   455       fun mk_subgoal_inst concl_vars (var as Var(v,T)) =
   456           if var mem concl_vars
   457           then (var, true, free_of "METAHYP2_" (v,T))
   458           else (var, false,
   459                 free_of "METAHYP2_" (v, map #2 params --->T))
   460       (*Instantiate subgoal vars by Free applied to params*)
   461       fun mk_ctpair (t,in_concl,u) =
   462           if in_concl then (cterm t,  cterm u)
   463           else (cterm t,  cterm (list_comb (u,fparams)))
   464       (*Restore Vars with higher type and index*)
   465       fun mk_subgoal_swap_ctpair
   466                 (t as Var((a,i),_), in_concl, u as Free(_,U)) =
   467           if in_concl then (cterm u, cterm t)
   468           else (cterm u, cterm(Var((a, i+maxidx), U)))
   469       (*Embed B in the original context of params and hyps*)
   470       fun embed B = list_all_free (params, Logic.list_implies (hyps, B))
   471       (*Strip the context using elimination rules*)
   472       fun elim Bhyp = implies_elim_list (forall_elim_list cparams Bhyp) hypths
   473       (*A form of lifting that discharges assumptions.*)
   474       fun relift st =
   475         let val prop = #prop(rep_thm st)
   476             val subgoal_vars = (*Vars introduced in the subgoals*)
   477                   foldr add_term_vars [] (Logic.strip_imp_prems prop)
   478             and concl_vars = add_term_vars (Logic.strip_imp_concl prop, [])
   479             val subgoal_insts = map (mk_subgoal_inst concl_vars) subgoal_vars
   480             val st' = Thm.instantiate ([], map mk_ctpair subgoal_insts) st
   481             val emBs = map (cterm o embed) (prems_of st')
   482             val Cth  = implies_elim_list st' (map (elim o assume) emBs)
   483         in  (*restore the unknowns to the hypotheses*)
   484             free_instantiate (map swap_ctpair insts @
   485                               map mk_subgoal_swap_ctpair subgoal_insts)
   486                 (*discharge assumptions from state in same order*)
   487                 (implies_intr_list emBs
   488                   (forall_intr_list cparams (implies_intr_list chyps Cth)))
   489         end
   490       val subprems = map (forall_elim_vars 0) hypths
   491       and st0 = trivial (cterm concl)
   492       (*function to replace the current subgoal*)
   493       fun next st = bicompose false (false, relift st, nprems_of st)
   494                     i state
   495   in  Seq.flat (Seq.map next (tacf subprems st0))
   496   end;
   497 end;
   498 
   499 fun METAHYPS tacf = SUBGOAL (metahyps_aux_tac tacf);
   500 
   501 (*Makes a tactic whose effect on a state is given by thmfun: thm->thm seq.*)
   502 fun PRIMSEQ thmfun st =  thmfun st handle THM _ => Seq.empty;
   503 
   504 (*Makes a tactic whose effect on a state is given by thmfun: thm->thm.*)
   505 fun PRIMITIVE thmfun = PRIMSEQ (Seq.single o thmfun);
   506 
   507 (* Inverse (more or less) of PRIMITIVE *)
   508 fun SINGLE tacf = Option.map fst o Seq.pull o tacf
   509 		  
   510 end;
   511 
   512 open Tactical;