src/Pure/library.ML
author wenzelm
Sat Dec 30 16:08:00 2006 +0100 (2006-12-30)
changeset 21962 279b129498b6
parent 21942 d6218d0f9ec3
child 22142 2b54aa7586e2
permissions -rw-r--r--
removed conditional combinator;
     1 (*  Title:      Pure/library.ML
     2     ID:         $Id$
     3     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     4     Author:     Markus Wenzel, TU Muenchen
     5 
     6 Basic library: functions, options, pairs, booleans, lists, integers,
     7 strings, lists as sets, balanced trees, orders, current directory, misc.
     8 
     9 See also General/basics.ML for the most fundamental concepts.
    10 *)
    11 
    12 infix 1 |>>>
    13 infix 2 ?
    14 infix 3 o oo ooo oooo
    15 infix 4 ~~ upto downto
    16 infix orf andf \ \\ mem mem_int mem_string union union_int
    17   union_string inter inter_int inter_string subset subset_int subset_string
    18 
    19 signature BASIC_LIBRARY =
    20 sig
    21   (*functions*)
    22   val I: 'a -> 'a
    23   val K: 'a -> 'b -> 'a
    24   val curry: ('a * 'b -> 'c) -> 'a -> 'b -> 'c
    25   val uncurry: ('a -> 'b -> 'c) -> 'a * 'b -> 'c
    26   val |>>> : ('a * 'c) * ('a -> 'b * 'd) -> 'b * ('c * 'd)
    27   val ? : bool * ('a -> 'a) -> 'a -> 'a
    28   val oo: ('a -> 'b) * ('c -> 'd -> 'a) -> 'c -> 'd -> 'b
    29   val ooo: ('a -> 'b) * ('c -> 'd -> 'e -> 'a) -> 'c -> 'd -> 'e -> 'b
    30   val oooo: ('a -> 'b) * ('c -> 'd -> 'e -> 'f -> 'a) -> 'c -> 'd -> 'e -> 'f -> 'b
    31   val funpow: int -> ('a -> 'a) -> 'a -> 'a
    32 
    33   (*exceptions*)
    34   exception EXCEPTION of exn * string
    35   val do_transform_failure: bool ref
    36   val transform_failure: (exn -> exn) -> ('a -> 'b) -> 'a -> 'b
    37   datatype 'a result = Result of 'a | Exn of exn
    38   val capture: ('a -> 'b) -> 'a -> 'b result
    39   val release: 'a result -> 'a
    40   val get_result: 'a result -> 'a option
    41   val get_exn: 'a result -> exn option
    42 
    43   (*errors*)
    44   exception SYS_ERROR of string
    45   val sys_error: string -> 'a
    46   exception ERROR of string
    47   val error: string -> 'a
    48   val cat_error: string -> string -> 'a
    49   val assert: bool -> string -> unit
    50   val deny: bool -> string -> unit
    51   val assert_all: ('a -> bool) -> 'a list -> ('a -> string) -> unit
    52 
    53   (*pairs*)
    54   val pair: 'a -> 'b -> 'a * 'b
    55   val rpair: 'a -> 'b -> 'b * 'a
    56   val fst: 'a * 'b -> 'a
    57   val snd: 'a * 'b -> 'b
    58   val eq_fst: ('a * 'c -> bool) -> ('a * 'b) * ('c * 'd) -> bool
    59   val eq_snd: ('b * 'd -> bool) -> ('a * 'b) * ('c * 'd) -> bool
    60   val eq_pair: ('a * 'c -> bool) -> ('b * 'd -> bool) -> ('a * 'b) * ('c * 'd) -> bool
    61   val swap: 'a * 'b -> 'b * 'a
    62   val apfst: ('a -> 'b) -> 'a * 'c -> 'b * 'c
    63   val apsnd: ('a -> 'b) -> 'c * 'a -> 'c * 'b
    64   val pairself: ('a -> 'b) -> 'a * 'a -> 'b * 'b
    65 
    66   (*booleans*)
    67   val equal: ''a -> ''a -> bool
    68   val not_equal: ''a -> ''a -> bool
    69   val orf: ('a -> bool) * ('a -> bool) -> 'a -> bool
    70   val andf: ('a -> bool) * ('a -> bool) -> 'a -> bool
    71   val exists: ('a -> bool) -> 'a list -> bool
    72   val forall: ('a -> bool) -> 'a list -> bool
    73   val set: bool ref -> bool
    74   val reset: bool ref -> bool
    75   val toggle: bool ref -> bool
    76   val change: 'a ref -> ('a -> 'a) -> unit
    77   val setmp: 'a ref -> 'a -> ('b -> 'c) -> 'b -> 'c
    78 
    79   (*lists*)
    80   exception UnequalLengths
    81   val single: 'a -> 'a list
    82   val the_single: 'a list -> 'a
    83   val singleton: ('a list -> 'b list) -> 'a -> 'b
    84   val apply: ('a -> 'a) list -> 'a -> 'a
    85   val foldr1: ('a * 'a -> 'a) -> 'a list -> 'a
    86   val foldl_map: ('a * 'b -> 'a * 'c) -> 'a * 'b list -> 'a * 'c list
    87   val flat: 'a list list -> 'a list
    88   val unflat: 'a list list -> 'b list -> 'b list list
    89   val burrow: ('a list -> 'b list) -> 'a list list -> 'b list list
    90   val fold_burrow: ('a list -> 'c -> 'b list * 'd) -> 'a list list -> 'c -> 'b list list * 'd
    91   val maps: ('a -> 'b list) -> 'a list -> 'b list
    92   val chop: int -> 'a list -> 'a list * 'a list
    93   val dropwhile: ('a -> bool) -> 'a list -> 'a list
    94   val nth: 'a list -> int -> 'a
    95   val nth_map: int -> ('a -> 'a) -> 'a list -> 'a list
    96   val nth_list: 'a list list -> int -> 'a list
    97   val map_index: (int * 'a -> 'b) -> 'a list -> 'b list
    98   val fold_index: (int * 'a -> 'b -> 'b) -> 'a list -> 'b -> 'b
    99   val split_last: 'a list -> 'a list * 'a
   100   val find_index: ('a -> bool) -> 'a list -> int
   101   val find_index_eq: ''a -> ''a list -> int
   102   val find_first: ('a -> bool) -> 'a list -> 'a option
   103   val get_index: ('a -> 'b option) -> 'a list -> (int * 'b) option
   104   val get_first: ('a -> 'b option) -> 'a list -> 'b option
   105   val eq_list: ('a * 'b -> bool) -> 'a list * 'b list -> bool
   106   val map2: ('a -> 'b -> 'c) -> 'a list -> 'b list -> 'c list
   107   val fold2: ('a -> 'b -> 'c -> 'c) -> 'a list -> 'b list -> 'c -> 'c
   108   val zip_options: 'a list -> 'b option list -> ('a * 'b) list
   109   val ~~ : 'a list * 'b list -> ('a * 'b) list
   110   val split_list: ('a * 'b) list -> 'a list * 'b list
   111   val separate: 'a -> 'a list -> 'a list
   112   val replicate: int -> 'a -> 'a list
   113   val multiply: 'a list -> 'a list list -> 'a list list
   114   val product: 'a list -> 'b list -> ('a * 'b) list
   115   val filter: ('a -> bool) -> 'a list -> 'a list
   116   val filter_out: ('a -> bool) -> 'a list -> 'a list
   117   val map_filter: ('a -> 'b option) -> 'a list -> 'b list
   118   val is_prefix: ('a * 'a -> bool) -> 'a list -> 'a list -> bool
   119   val take_prefix: ('a -> bool) -> 'a list -> 'a list * 'a list
   120   val chop_prefix: ('a * 'b -> bool) -> 'a list * 'b list -> 'a list * ('a list * 'b list)
   121   val take_suffix: ('a -> bool) -> 'a list -> 'a list * 'a list
   122   val prefixes1: 'a list -> 'a list list
   123   val prefixes: 'a list -> 'a list list
   124   val suffixes1: 'a list -> 'a list list
   125   val suffixes: 'a list -> 'a list list
   126 
   127   (*integers*)
   128   val gcd: IntInf.int * IntInf.int -> IntInf.int
   129   val lcm: IntInf.int * IntInf.int -> IntInf.int
   130   val inc: int ref -> int
   131   val dec: int ref -> int
   132   val upto: int * int -> int list
   133   val downto: int * int -> int list
   134   val downto0: int list * int -> bool
   135   val radixpand: int * int -> int list
   136   val radixstring: int * string * int -> string
   137   val string_of_int: int -> string
   138   val signed_string_of_int: int -> string
   139   val string_of_indexname: string * int -> string
   140   val read_intinf: int -> string list -> IntInf.int * string list
   141   val read_int: string list -> int * string list
   142   val oct_char: string -> string
   143 
   144   (*strings*)
   145   val nth_string: string -> int -> string
   146   val fold_string: (string -> 'a -> 'a) -> string -> 'a -> 'a
   147   val exists_string: (string -> bool) -> string -> bool
   148   val forall_string: (string -> bool) -> string -> bool
   149   val enclose: string -> string -> string -> string
   150   val unenclose: string -> string
   151   val quote: string -> string
   152   val space_implode: string -> string list -> string
   153   val commas: string list -> string
   154   val commas_quote: string list -> string
   155   val cat_lines: string list -> string
   156   val space_explode: string -> string -> string list
   157   val split_lines: string -> string list
   158   val prefix_lines: string -> string -> string
   159   val untabify: string list -> string list
   160   val prefix: string -> string -> string
   161   val suffix: string -> string -> string
   162   val unprefix: string -> string -> string
   163   val unsuffix: string -> string -> string
   164   val replicate_string: int -> string -> string
   165   val translate_string: (string -> string) -> string -> string
   166 
   167   (*lists as sets -- see also Pure/General/ord_list.ML*)
   168   val member: ('b * 'a -> bool) -> 'a list -> 'b -> bool
   169   val insert: ('a * 'a -> bool) -> 'a -> 'a list -> 'a list
   170   val remove: ('b * 'a -> bool) -> 'b -> 'a list -> 'a list
   171   val subtract: ('b * 'a -> bool) -> 'b list -> 'a list -> 'a list
   172   val merge: ('a * 'a -> bool) -> 'a list * 'a list -> 'a list
   173   val mem: ''a * ''a list -> bool
   174   val mem_int: int * int list -> bool
   175   val mem_string: string * string list -> bool
   176   val union: ''a list * ''a list -> ''a list
   177   val union_int: int list * int list -> int list
   178   val union_string: string list * string list -> string list
   179   val gen_union: ('a * 'a -> bool) -> 'a list * 'a list -> 'a list
   180   val gen_inter: ('a * 'b -> bool) -> 'a list * 'b list -> 'a list
   181   val inter: ''a list * ''a list -> ''a list
   182   val inter_int: int list * int list -> int list
   183   val inter_string: string list * string list -> string list
   184   val subset: ''a list * ''a list -> bool
   185   val subset_int: int list * int list -> bool
   186   val subset_string: string list * string list -> bool
   187   val eq_set: ''a list * ''a list -> bool
   188   val eq_set_string: string list * string list -> bool
   189   val gen_subset: ('a * 'b -> bool) -> 'a list * 'b list -> bool
   190   val gen_eq_set: ('a * 'b -> bool) -> 'a list * 'b list -> bool
   191   val \ : ''a list * ''a -> ''a list
   192   val \\ : ''a list * ''a list -> ''a list
   193   val distinct: ('a * 'a -> bool) -> 'a list -> 'a list
   194   val duplicates: ('a * 'a -> bool) -> 'a list -> 'a list
   195   val has_duplicates: ('a * 'a -> bool) -> 'a list -> bool
   196 
   197   (*lists as tables -- see also Pure/General/alist.ML*)
   198   val gen_merge_lists: ('a * 'a -> bool) -> 'a list -> 'a list -> 'a list
   199   val merge_lists: ''a list -> ''a list -> ''a list
   200   val merge_alists: (''a * 'b) list -> (''a * 'b) list -> (''a * 'b) list
   201 
   202   (*balanced trees*)
   203   exception Balance
   204   val fold_bal: ('a * 'a -> 'a) -> 'a list -> 'a
   205   val access_bal: ('a -> 'a) * ('a -> 'a) * 'a -> int -> int -> 'a
   206   val accesses_bal: ('a -> 'a) * ('a -> 'a) * 'a -> int -> 'a list
   207 
   208   (*orders*)
   209   val is_equal: order -> bool
   210   val rev_order: order -> order
   211   val make_ord: ('a * 'a -> bool) -> 'a * 'a -> order
   212   val int_ord: int * int -> order
   213   val string_ord: string * string -> order
   214   val fast_string_ord: string * string -> order
   215   val option_ord: ('a * 'b -> order) -> 'a option * 'b option -> order
   216   val prod_ord: ('a * 'b -> order) -> ('c * 'd -> order) -> ('a * 'c) * ('b * 'd) -> order
   217   val dict_ord: ('a * 'b -> order) -> 'a list * 'b list -> order
   218   val list_ord: ('a * 'b -> order) -> 'a list * 'b list -> order
   219   val sort: ('a * 'a -> order) -> 'a list -> 'a list
   220   val sort_distinct: ('a * 'a -> order) -> 'a list -> 'a list
   221   val sort_strings: string list -> string list
   222   val sort_wrt: ('a -> string) -> 'a list -> 'a list
   223 
   224   (*random numbers*)
   225   exception RANDOM
   226   val random: unit -> real
   227   val random_range: int -> int -> int
   228   val one_of: 'a list -> 'a
   229   val frequency: (int * 'a) list -> 'a
   230 
   231   (*current directory*)
   232   val cd: string -> unit
   233   val pwd: unit -> string
   234 
   235   (*misc*)
   236   val divide_and_conquer: ('a -> 'a list * ('b list -> 'b)) -> 'a -> 'b
   237   val partition_eq: ('a * 'a -> bool) -> 'a list -> 'a list list
   238   val partition_list: (int -> 'a -> bool) -> int -> int -> 'a list -> 'a list list
   239   val gensym: string -> string
   240   val scanwords: (string -> bool) -> string list -> string list
   241   type stamp
   242   val stamp: unit -> stamp
   243   type serial
   244   val serial: unit -> serial
   245   val serial_string: unit -> string
   246   structure Object: sig type T end
   247 end;
   248 
   249 signature LIBRARY =
   250 sig
   251   include BASIC_LIBRARY
   252   val foldl: ('a * 'b -> 'a) -> 'a * 'b list -> 'a
   253   val foldr: ('a * 'b -> 'b) -> 'a list * 'b -> 'b
   254   val take: int * 'a list -> 'a list
   255   val drop: int * 'a list -> 'a list
   256   val last_elem: 'a list -> 'a
   257   val seq: ('a -> unit) -> 'a list -> unit
   258 end;
   259 
   260 structure Library: LIBRARY =
   261 struct
   262 
   263 (* functions *)
   264 
   265 fun I x = x;
   266 fun K x = fn _ => x;
   267 fun curry f x y = f (x, y);
   268 fun uncurry f (x, y) = f x y;
   269 
   270 (*application and structured results -- old version*)
   271 fun (x, y) |>>> f = let val (x', z) = f x in (x', (y, z)) end;
   272 
   273 (*conditional application*)
   274 fun b ? f = fn x => if b then f x else x;
   275 
   276 (*composition with multiple args*)
   277 fun (f oo g) x y = f (g x y);
   278 fun (f ooo g) x y z = f (g x y z);
   279 fun (f oooo g) x y z w = f (g x y z w);
   280 
   281 (*function exponentiation: f(...(f x)...) with n applications of f*)
   282 fun funpow n f x =
   283   let fun rep (0, x) = x
   284         | rep (n, x) = rep (n - 1, f x)
   285   in rep (n, x) end;
   286 
   287 
   288 (* exceptions *)
   289 
   290 val do_transform_failure = ref true;
   291 
   292 fun transform_failure exn f x =
   293   if ! do_transform_failure then
   294     f x handle Interrupt => raise Interrupt | e => raise exn e
   295   else f x;
   296 
   297 exception EXCEPTION of exn * string;
   298 
   299 datatype 'a result =
   300   Result of 'a |
   301   Exn of exn;
   302 
   303 fun capture f x = Result (f x) handle e => Exn e;
   304 
   305 fun release (Result y) = y
   306   | release (Exn e) = raise e;
   307 
   308 fun get_result (Result x) = SOME x
   309   | get_result _ = NONE;
   310 
   311 fun get_exn (Exn exn) = SOME exn
   312   | get_exn _ = NONE;
   313 
   314 
   315 (* errors *)
   316 
   317 exception SYS_ERROR of string;
   318 fun sys_error msg = raise SYS_ERROR msg;
   319 
   320 exception ERROR of string;
   321 fun error msg = raise ERROR msg;
   322 
   323 fun cat_error "" msg = error msg
   324   | cat_error msg1 msg2 = error (msg1 ^ "\n" ^ msg2);
   325 
   326 fun assert p msg = if p then () else error msg;
   327 fun deny p msg = if p then error msg else ();
   328 
   329 fun assert_all pred list msg =
   330   let
   331     fun ass [] = ()
   332       | ass (x :: xs) = if pred x then ass xs else error (msg x);
   333   in ass list end;
   334 
   335 
   336 (* pairs *)
   337 
   338 fun pair x y = (x, y);
   339 fun rpair x y = (y, x);
   340 
   341 fun fst (x, y) = x;
   342 fun snd (x, y) = y;
   343 
   344 fun eq_fst eq ((x1, _), (x2, _)) = eq (x1, x2);
   345 fun eq_snd eq ((_, y1), (_, y2)) = eq (y1, y2);
   346 fun eq_pair eqx eqy ((x1, y1), (x2, y2)) = eqx (x1, x2) andalso eqy (y1, y2);
   347 
   348 fun swap (x, y) = (y, x);
   349 
   350 (*apply function to components*)
   351 fun apfst f (x, y) = (f x, y);
   352 fun apsnd f (x, y) = (x, f y);
   353 fun pairself f (x, y) = (f x, f y);
   354 
   355 
   356 (* booleans *)
   357 
   358 (*polymorphic equality*)
   359 fun equal x y = x = y;
   360 fun not_equal x y = x <> y;
   361 
   362 (*combining predicates*)
   363 fun p orf q = fn x => p x orelse q x;
   364 fun p andf q = fn x => p x andalso q x;
   365 
   366 (*exists pred [x1, ..., xn] ===> pred x1 orelse ... orelse pred xn*)
   367 fun exists (pred: 'a -> bool) : 'a list -> bool =
   368   let fun boolf [] = false
   369         | boolf (x :: xs) = pred x orelse boolf xs
   370   in boolf end;
   371 
   372 (*forall pred [x1, ..., xn] ===> pred x1 andalso ... andalso pred xn*)
   373 fun forall (pred: 'a -> bool) : 'a list -> bool =
   374   let fun boolf [] = true
   375         | boolf (x :: xs) = pred x andalso boolf xs
   376   in boolf end;
   377 
   378 
   379 (* flags *)
   380 
   381 fun set flag = (flag := true; true);
   382 fun reset flag = (flag := false; false);
   383 fun toggle flag = (flag := not (! flag); ! flag);
   384 
   385 fun change r f = r := f (! r);
   386 
   387 (*temporarily set flag during execution*)
   388 fun setmp flag value f x =
   389   let
   390     val orig_value = ! flag;
   391     val _ = flag := value;
   392     val result = capture f x;
   393     val _ = flag := orig_value;
   394   in release result end;
   395 
   396 
   397 
   398 (** lists **)
   399 
   400 exception UnequalLengths;
   401 
   402 fun single x = [x];
   403 
   404 fun the_single [x] = x
   405   | the_single _ = raise Empty;
   406 
   407 fun singleton f x = the_single (f [x]);
   408 
   409 fun apply [] x = x
   410   | apply (f :: fs) x = apply fs (f x);
   411 
   412 
   413 (* fold -- old versions *)
   414 
   415 (*the following versions of fold are designed to fit nicely with infixes*)
   416 
   417 (*  (op @) (e, [x1, ..., xn])  ===>  ((e @ x1) @ x2) ... @ xn
   418     for operators that associate to the left (TAIL RECURSIVE)*)
   419 fun foldl (f: 'a * 'b -> 'a) : 'a * 'b list -> 'a =
   420   let fun itl (e, [])  = e
   421         | itl (e, a::l) = itl (f(e, a), l)
   422   in  itl end;
   423 
   424 (*  (op @) ([x1, ..., xn], e)  ===>   x1 @ (x2 ... @ (xn @ e))
   425     for operators that associate to the right (not tail recursive)*)
   426 fun foldr f (l, e) =
   427   let fun itr [] = e
   428         | itr (a::l) = f(a, itr l)
   429   in  itr l  end;
   430 
   431 (*  (op @) [x1, ..., xn]  ===>   x1 @ (x2 ... @ (x[n-1] @ xn))
   432     for n > 0, operators that associate to the right (not tail recursive)*)
   433 fun foldr1 f [] = raise Empty
   434   | foldr1 f l =
   435       let fun itr [x] = x
   436             | itr (x::l) = f(x, itr l)
   437       in  itr l  end;
   438 
   439 fun foldl_map f =
   440   let
   441     fun fold_aux (x, []) = (x, [])
   442       | fold_aux (x, y :: ys) =
   443           let
   444             val (x', y') = f (x, y);
   445             val (x'', ys') = fold_aux (x', ys);
   446           in (x'', y' :: ys') end;
   447   in fold_aux end;
   448 
   449 
   450 (* basic list functions *)
   451 
   452 fun eq_list eq (list1, list2) =
   453   let
   454     fun eq_lst (x :: xs, y :: ys) = eq (x, y) andalso eq_lst (xs, ys)
   455       | eq_lst _ = true;
   456   in length list1 = length list2 andalso eq_lst (list1, list2) end;
   457 
   458 fun maps f [] = []
   459   | maps f (x :: xs) = f x @ maps f xs;
   460 
   461 fun chop n xs = unfold_rev n dest xs;
   462 
   463 (*take the first n elements from a list*)
   464 fun take (n, []) = []
   465   | take (n, x :: xs) =
   466       if n > 0 then x :: take (n - 1, xs) else [];
   467 
   468 (*drop the first n elements from a list*)
   469 fun drop (n, []) = []
   470   | drop (n, x :: xs) =
   471       if n > 0 then drop (n - 1, xs) else x :: xs;
   472 
   473 fun dropwhile P [] = []
   474   | dropwhile P (ys as x::xs) = if P x then dropwhile P xs else ys;
   475 
   476 (*return nth element of a list, where 0 designates the first element;
   477   raise Subscript if list too short*)
   478 fun nth xs i = List.nth (xs, i);
   479 
   480 fun nth_list xss i = nth xss i handle Subscript => [];
   481 
   482 fun nth_map 0 f (x :: xs) = f x :: xs
   483   | nth_map n f (x :: xs) = x :: nth_map (n - 1) f xs
   484   | nth_map _ _ [] = raise Subscript;
   485 
   486 fun map_index f =
   487   let
   488     fun mapp _ [] = []
   489       | mapp i (x :: xs) = f (i, x) :: mapp (i+1) xs
   490   in mapp 0 end;
   491 
   492 fun fold_index f =
   493   let
   494     fun fold_aux _ [] y = y
   495       | fold_aux i (x :: xs) y = fold_aux (i+1) xs (f (i, x) y);
   496   in fold_aux 0 end;
   497 
   498 val last_elem = List.last;
   499 
   500 (*rear decomposition*)
   501 fun split_last [] = raise Empty
   502   | split_last [x] = ([], x)
   503   | split_last (x :: xs) = apfst (cons x) (split_last xs);
   504 
   505 (*find the position of an element in a list*)
   506 fun find_index pred =
   507   let fun find _ [] = ~1
   508         | find n (x :: xs) = if pred x then n else find (n + 1) xs;
   509   in find 0 end;
   510 
   511 fun find_index_eq x = find_index (equal x);
   512 
   513 (*find first element satisfying predicate*)
   514 fun find_first _ [] = NONE
   515   | find_first pred (x :: xs) =
   516       if pred x then SOME x else find_first pred xs;
   517 
   518 (*get first element by lookup function*)
   519 fun get_first _ [] = NONE
   520   | get_first f (x :: xs) =
   521       (case f x of
   522         NONE => get_first f xs
   523       | some => some);
   524 
   525 fun get_index f =
   526   let
   527     fun get _ [] = NONE
   528       | get i (x :: xs) =
   529           case f x
   530            of NONE => get (i + 1) xs
   531             | SOME y => SOME (i, y)
   532   in get 0 end;
   533 
   534 val flat = List.concat;
   535 
   536 fun unflat (xs :: xss) ys =
   537       let val (ps, qs) = chop (length xs) ys
   538       in ps :: unflat xss qs end
   539   | unflat [] [] = []
   540   | unflat _ _ = raise UnequalLengths;
   541 
   542 fun burrow f xss = unflat xss (f (flat xss));
   543 
   544 fun fold_burrow f xss s =
   545   apfst (unflat xss) (f (flat xss) s);
   546 
   547 (*like Lisp's MAPC -- seq proc [x1, ..., xn] evaluates
   548   (proc x1; ...; proc xn) for side effects*)
   549 val seq = List.app;
   550 
   551 (*separate s [x1, x2, ..., xn]  ===>  [x1, s, x2, s, ..., s, xn]*)
   552 fun separate s (x :: (xs as _ :: _)) = x :: s :: separate s xs
   553   | separate _ xs = xs;
   554 
   555 (*make the list [x, x, ..., x] of length n*)
   556 fun replicate n (x: 'a) : 'a list =
   557   let fun rep (0, xs) = xs
   558         | rep (n, xs) = rep (n - 1, x :: xs)
   559   in
   560     if n < 0 then raise Subscript
   561     else rep (n, [])
   562   end;
   563 
   564 fun translate_string f = String.translate (f o String.str);
   565 
   566 (*multiply [a, b, c, ...] * [xs, ys, zs, ...]*)
   567 fun multiply [] _ = []
   568   | multiply (x :: xs) yss = map (cons x) yss @ multiply xs yss;
   569 
   570 (*direct product*)
   571 fun product _ [] = []
   572   | product [] _ = []
   573   | product (x :: xs) ys = map (pair x) ys @ product xs ys;
   574 
   575 
   576 (* filter *)
   577 
   578 (*copy the list preserving elements that satisfy the predicate*)
   579 val filter = List.filter;
   580 fun filter_out f = filter (not o f);
   581 val map_filter = List.mapPartial;
   582 
   583 
   584 (* lists of pairs *)
   585 
   586 exception UnequalLengths;
   587 
   588 fun map2 _ [] [] = []
   589   | map2 f (x :: xs) (y :: ys) = f x y :: map2 f xs ys
   590   | map2 _ _ _ = raise UnequalLengths;
   591 
   592 fun fold2 f =
   593   let
   594     fun fold_aux [] [] z = z
   595       | fold_aux (x :: xs) (y :: ys) z = fold_aux xs ys (f x y z)
   596       | fold_aux _ _ _ = raise UnequalLengths;
   597   in fold_aux end;
   598 
   599 fun zip_options (x :: xs) (SOME y :: ys) = (x, y) :: zip_options xs ys
   600   | zip_options (_ :: xs) (NONE :: ys) = zip_options xs ys
   601   | zip_options _ [] = []
   602   | zip_options [] _ = raise UnequalLengths;
   603 
   604 (*combine two lists forming a list of pairs:
   605   [x1, ..., xn] ~~ [y1, ..., yn]  ===>  [(x1, y1), ..., (xn, yn)]*)
   606 fun [] ~~ [] = []
   607   | (x :: xs) ~~ (y :: ys) = (x, y) :: (xs ~~ ys)
   608   | _ ~~ _ = raise UnequalLengths;
   609 
   610 (*inverse of ~~; the old 'split':
   611   [(x1, y1), ..., (xn, yn)]  ===>  ([x1, ..., xn], [y1, ..., yn])*)
   612 val split_list = ListPair.unzip;
   613 
   614 
   615 (* prefixes, suffixes *)
   616 
   617 fun is_prefix _ [] _ = true
   618   | is_prefix eq (x :: xs) (y :: ys) = eq (x, y) andalso is_prefix eq xs ys
   619   | is_prefix eq _ _ = false;
   620 
   621 (* [x1, ..., xi, ..., xn]  --->  ([x1, ..., x(i-1)], [xi, ..., xn])
   622    where xi is the first element that does not satisfy the predicate*)
   623 fun take_prefix (pred : 'a -> bool)  (xs: 'a list) : 'a list * 'a list =
   624   let fun take (rxs, []) = (rev rxs, [])
   625         | take (rxs, x :: xs) =
   626             if  pred x  then  take(x :: rxs, xs)  else  (rev rxs, x :: xs)
   627   in  take([], xs)  end;
   628 
   629 fun chop_prefix eq ([], ys) = ([], ([], ys))
   630   | chop_prefix eq (xs, []) = ([], (xs, []))
   631   | chop_prefix eq (xs as x::xs', ys as y::ys') =
   632       if eq (x, y) then
   633         let val (ps', xys'') = chop_prefix eq (xs', ys')
   634         in (x::ps', xys'') end
   635       else ([], (xs, ys));
   636 
   637 (* [x1, ..., xi, ..., xn]  --->  ([x1, ..., xi], [x(i+1), ..., xn])
   638    where xi is the last element that does not satisfy the predicate*)
   639 fun take_suffix _ [] = ([], [])
   640   | take_suffix pred (x :: xs) =
   641       (case take_suffix pred xs of
   642         ([], sffx) => if pred x then ([], x :: sffx) else ([x], sffx)
   643       | (prfx, sffx) => (x :: prfx, sffx));
   644 
   645 fun prefixes1 [] = []
   646   | prefixes1 (x :: xs) = map (cons x) ([] :: prefixes1 xs);
   647 
   648 fun prefixes xs = [] :: prefixes1 xs;
   649 
   650 fun suffixes1 xs = map rev (prefixes1 (rev xs));
   651 fun suffixes xs = [] :: suffixes1 xs;
   652 
   653 
   654 (** integers **)
   655 
   656 fun gcd (x, y) =
   657   let fun gxd x y : IntInf.int =
   658     if y = IntInf.fromInt 0 then x else gxd y (x mod y)
   659   in if x < y then gxd y x else gxd x y end;
   660 
   661 fun lcm (x, y) = (x * y) div gcd (x, y);
   662 
   663 fun inc i = (i := ! i + 1; ! i);
   664 fun dec i = (i := ! i - 1; ! i);
   665 
   666 
   667 (* lists of integers *)
   668 
   669 (*make the list [from, from + 1, ..., to]*)
   670 fun (i upto j) =
   671   if i > j then [] else i :: (i + 1 upto j);
   672 
   673 (*make the list [from, from - 1, ..., to]*)
   674 fun (i downto j) =
   675   if i < j then [] else i :: (i - 1 downto j);
   676 
   677 (*predicate: downto0 (is, n) <=> is = [n, n - 1, ..., 0]*)
   678 fun downto0 (i :: is, n) = i = n andalso downto0 (is, n - 1)
   679   | downto0 ([], n) = n = ~1;
   680 
   681 
   682 (* convert integers to strings *)
   683 
   684 (*expand the number in the given base;
   685   example: radixpand (2, 8) gives [1, 0, 0, 0]*)
   686 fun radixpand (base, num) : int list =
   687   let
   688     fun radix (n, tail) =
   689       if n < base then n :: tail
   690       else radix (n div base, (n mod base) :: tail)
   691   in radix (num, []) end;
   692 
   693 (*expands a number into a string of characters starting from "zerochar";
   694   example: radixstring (2, "0", 8) gives "1000"*)
   695 fun radixstring (base, zerochar, num) =
   696   let val offset = ord zerochar;
   697       fun chrof n = chr (offset + n)
   698   in implode (map chrof (radixpand (base, num))) end;
   699 
   700 
   701 val string_of_int = Int.toString;
   702 
   703 fun signed_string_of_int i =
   704   if i < 0 then "-" ^ string_of_int (~ i) else string_of_int i;
   705 
   706 fun string_of_indexname (a,0) = a
   707   | string_of_indexname (a,i) = a ^ "_" ^ Int.toString i;
   708 
   709 
   710 (* read integers *)
   711 
   712 fun read_intinf radix cs =
   713   let
   714     val zero = ord "0";
   715     val limit = zero + radix;
   716     fun scan (num, []) = (num, [])
   717       | scan (num, c :: cs) =
   718         if zero <= ord c andalso ord c < limit then
   719           scan (IntInf.fromInt radix * num + IntInf.fromInt (ord c - zero), cs)
   720         else (num, c :: cs);
   721   in scan (IntInf.fromInt 0, cs) end;
   722 
   723 fun read_int cs = apfst IntInf.toInt (read_intinf 10 cs);
   724 
   725 fun oct_char s = chr (IntInf.toInt (#1 (read_intinf 8 (explode s))));
   726 
   727 
   728 
   729 (** strings **)
   730 
   731 (* functions tuned for strings, avoiding explode *)
   732 
   733 fun nth_string str i =
   734   (case try String.substring (str, i, 1) of
   735     SOME s => s
   736   | NONE => raise Subscript);
   737 
   738 fun fold_string f str x0 =
   739   let
   740     val n = size str;
   741     fun iter (x, i) =
   742       if i < n then iter (f (String.substring (str, i, 1)) x, i + 1) else x;
   743   in iter (x0, 0) end;
   744 
   745 fun exists_string pred str =
   746   let
   747     val n = size str;
   748     fun ex i = i < n andalso (pred (String.substring (str, i, 1)) orelse ex (i + 1));
   749   in ex 0 end;
   750 
   751 fun forall_string pred = not o exists_string (not o pred);
   752 
   753 (*enclose in brackets*)
   754 fun enclose lpar rpar str = lpar ^ str ^ rpar;
   755 fun unenclose str = String.substring (str, 1, size str - 2);
   756 
   757 (*simple quoting (does not escape special chars)*)
   758 val quote = enclose "\"" "\"";
   759 
   760 (*space_implode "..." (explode "hello") = "h...e...l...l...o"*)
   761 fun space_implode a bs = implode (separate a bs);
   762 
   763 val commas = space_implode ", ";
   764 val commas_quote = commas o map quote;
   765 
   766 (*concatenate messages, one per line, into a string*)
   767 val cat_lines = space_implode "\n";
   768 
   769 (*space_explode "." "h.e..l.lo" = ["h", "e", "", "l", "lo"]*)
   770 fun space_explode _ "" = []
   771   | space_explode sep s = String.fields (fn c => str c = sep) s;
   772 
   773 val split_lines = space_explode "\n";
   774 
   775 fun prefix_lines "" txt = txt
   776   | prefix_lines prfx txt = txt |> split_lines |> map (fn s => prfx ^ s) |> cat_lines;
   777 
   778 fun untabify chs =
   779   let
   780     val tab_width = 8;
   781 
   782     fun untab (_, "\n") = (0, ["\n"])
   783       | untab (pos, "\t") =
   784           let val d = tab_width - (pos mod tab_width) in (pos + d, replicate d " ") end
   785       | untab (pos, c) = (pos + 1, [c]);
   786   in
   787     if not (exists (fn c => c = "\t") chs) then chs
   788     else flat (#2 (foldl_map untab (0, chs)))
   789   end;
   790 
   791 fun prefix prfx s = prfx ^ s;
   792 fun suffix sffx s = s ^ sffx;
   793 
   794 fun unprefix prfx s =
   795   if String.isPrefix prfx s then String.substring (s, size prfx, size s - size prfx)
   796   else raise Fail "unprefix";
   797 
   798 fun unsuffix sffx s =
   799   if String.isSuffix sffx s then String.substring (s, 0, size s - size sffx)
   800   else raise Fail "unsuffix";
   801 
   802 fun replicate_string 0 _ = ""
   803   | replicate_string 1 a = a
   804   | replicate_string k a =
   805       if k mod 2 = 0 then replicate_string (k div 2) (a ^ a)
   806       else replicate_string (k div 2) (a ^ a) ^ a;
   807 
   808 
   809 (** lists as sets -- see also Pure/General/ord_list.ML **)
   810 
   811 (*canonical member, insert, remove*)
   812 fun member eq list x =
   813   let
   814     fun memb [] = false
   815       | memb (y :: ys) = eq (x, y) orelse memb ys;
   816   in memb list end;
   817 
   818 fun insert eq x xs = if member eq xs x then xs else x :: xs;
   819 fun remove eq x xs = if member eq xs x then filter_out (fn y => eq (x, y)) xs else xs;
   820 
   821 fun subtract eq = fold (remove eq);
   822 
   823 fun merge _ ([], ys) = ys
   824   | merge eq (xs, ys) = fold_rev (insert eq) ys xs;
   825 
   826 (*old-style infixes*)
   827 fun x mem xs = member (op =) xs x;
   828 fun (x: int) mem_int xs = member (op =) xs x;
   829 fun (x: string) mem_string xs = member (op =) xs x;
   830 
   831 
   832 (*union of sets represented as lists: no repetitions*)
   833 fun xs union [] = xs
   834   | [] union ys = ys
   835   | (x :: xs) union ys = xs union (insert (op =) x ys);
   836 
   837 (*union of sets, optimized version for ints*)
   838 fun (xs:int list) union_int [] = xs
   839   | [] union_int ys = ys
   840   | (x :: xs) union_int ys = xs union_int (insert (op =) x ys);
   841 
   842 (*union of sets, optimized version for strings*)
   843 fun (xs:string list) union_string [] = xs
   844   | [] union_string ys = ys
   845   | (x :: xs) union_string ys = xs union_string (insert (op =) x ys);
   846 
   847 (*generalized union*)
   848 fun gen_union eq (xs, []) = xs
   849   | gen_union eq ([], ys) = ys
   850   | gen_union eq (x :: xs, ys) = gen_union eq (xs, insert eq x ys);
   851 
   852 
   853 (*intersection*)
   854 fun [] inter ys = []
   855   | (x :: xs) inter ys =
   856       if x mem ys then x :: (xs inter ys) else xs inter ys;
   857 
   858 (*intersection, optimized version for ints*)
   859 fun ([]:int list) inter_int ys = []
   860   | (x :: xs) inter_int ys =
   861       if x mem_int ys then x :: (xs inter_int ys) else xs inter_int ys;
   862 
   863 (*intersection, optimized version for strings *)
   864 fun ([]:string list) inter_string ys = []
   865   | (x :: xs) inter_string ys =
   866       if x mem_string ys then x :: (xs inter_string ys) else xs inter_string ys;
   867 
   868 (*generalized intersection*)
   869 fun gen_inter eq ([], ys) = []
   870   | gen_inter eq (x::xs, ys) =
   871       if member eq ys x then x :: gen_inter eq (xs, ys)
   872       else gen_inter eq (xs, ys);
   873 
   874 
   875 (*subset*)
   876 fun [] subset ys = true
   877   | (x :: xs) subset ys = x mem ys andalso xs subset ys;
   878 
   879 (*subset, optimized version for ints*)
   880 fun ([]: int list) subset_int ys = true
   881   | (x :: xs) subset_int ys = x mem_int ys andalso xs subset_int ys;
   882 
   883 (*subset, optimized version for strings*)
   884 fun ([]: string list) subset_string ys = true
   885   | (x :: xs) subset_string ys = x mem_string ys andalso xs subset_string ys;
   886 
   887 (*set equality*)
   888 fun eq_set (xs, ys) =
   889   xs = ys orelse (xs subset ys andalso ys subset xs);
   890 
   891 (*set equality for strings*)
   892 fun eq_set_string ((xs: string list), ys) =
   893   xs = ys orelse (xs subset_string ys andalso ys subset_string xs);
   894 
   895 fun gen_subset eq (xs, ys) = forall (member eq ys) xs;
   896 
   897 fun gen_eq_set eq (xs, ys) =
   898   eq_list eq (xs, ys) orelse
   899     (gen_subset eq (xs, ys) andalso gen_subset (eq o swap) (ys, xs));
   900 
   901 
   902 (*removing an element from a list WITHOUT duplicates*)
   903 fun (y :: ys) \ x = if x = y then ys else y :: (ys \ x)
   904   | [] \ x = [];
   905 fun ys \\ xs = foldl (op \) (ys,xs);
   906 
   907 
   908 (*makes a list of the distinct members of the input; preserves order, takes
   909   first of equal elements*)
   910 fun distinct eq lst =
   911   let
   912     fun dist (rev_seen, []) = rev rev_seen
   913       | dist (rev_seen, x :: xs) =
   914           if member eq rev_seen x then dist (rev_seen, xs)
   915           else dist (x :: rev_seen, xs);
   916   in dist ([], lst) end;
   917 
   918 (*returns a list containing all repeated elements exactly once; preserves
   919   order, takes first of equal elements*)
   920 fun duplicates eq lst =
   921   let
   922     fun dups (rev_dups, []) = rev rev_dups
   923       | dups (rev_dups, x :: xs) =
   924           if member eq rev_dups x orelse not (member eq xs x) then
   925             dups (rev_dups, xs)
   926           else dups (x :: rev_dups, xs);
   927   in dups ([], lst) end;
   928 
   929 fun has_duplicates eq =
   930   let
   931     fun dups [] = false
   932       | dups (x :: xs) = member eq xs x orelse dups xs;
   933   in dups end;
   934 
   935 
   936 (** association lists -- legacy operations **)
   937 
   938 fun gen_merge_lists _ xs [] = xs
   939   | gen_merge_lists _ [] ys = ys
   940   | gen_merge_lists eq xs ys = xs @ filter_out (member eq xs) ys;
   941 
   942 fun merge_lists xs ys = gen_merge_lists (op =) xs ys;
   943 fun merge_alists xs = gen_merge_lists (eq_fst (op =)) xs;
   944 
   945 
   946 (** balanced trees **)
   947 
   948 exception Balance;      (*indicates non-positive argument to balancing fun*)
   949 
   950 (*balanced folding; avoids deep nesting*)
   951 fun fold_bal f [x] = x
   952   | fold_bal f [] = raise Balance
   953   | fold_bal f xs =
   954       let val (ps, qs) = chop (length xs div 2) xs
   955       in  f (fold_bal f ps, fold_bal f qs)  end;
   956 
   957 (*construct something of the form f(...g(...(x)...)) for balanced access*)
   958 fun access_bal (f, g, x) n i =
   959   let fun acc n i =     (*1<=i<=n*)
   960           if n=1 then x else
   961           let val n2 = n div 2
   962           in  if i<=n2 then f (acc n2 i)
   963                        else g (acc (n-n2) (i-n2))
   964           end
   965   in  if 1<=i andalso i<=n then acc n i else raise Balance  end;
   966 
   967 (*construct ALL such accesses; could try harder to share recursive calls!*)
   968 fun accesses_bal (f, g, x) n =
   969   let fun acc n =
   970           if n=1 then [x] else
   971           let val n2 = n div 2
   972               val acc2 = acc n2
   973           in  if n-n2=n2 then map f acc2 @ map g acc2
   974                          else map f acc2 @ map g (acc (n-n2)) end
   975   in  if 1<=n then acc n else raise Balance  end;
   976 
   977 
   978 
   979 (** orders **)
   980 
   981 fun is_equal EQUAL = true
   982   | is_equal _ = false;
   983 
   984 fun rev_order LESS = GREATER
   985   | rev_order EQUAL = EQUAL
   986   | rev_order GREATER = LESS;
   987 
   988 (*assume rel is a linear strict order*)
   989 fun make_ord rel (x, y) =
   990   if rel (x, y) then LESS
   991   else if rel (y, x) then GREATER
   992   else EQUAL;
   993 
   994 val int_ord = Int.compare;
   995 val string_ord = String.compare;
   996 
   997 fun fast_string_ord (s1, s2) =
   998   (case int_ord (size s1, size s2) of EQUAL => string_ord (s1, s2) | ord => ord);
   999 
  1000 fun option_ord ord (SOME x, SOME y) = ord (x, y)
  1001   | option_ord _ (NONE, NONE) = EQUAL
  1002   | option_ord _ (NONE, SOME _) = LESS
  1003   | option_ord _ (SOME _, NONE) = GREATER;
  1004 
  1005 (*lexicographic product*)
  1006 fun prod_ord a_ord b_ord ((x, y), (x', y')) =
  1007   (case a_ord (x, x') of EQUAL => b_ord (y, y') | ord => ord);
  1008 
  1009 (*dictionary order -- in general NOT well-founded!*)
  1010 fun dict_ord elem_ord (x :: xs, y :: ys) =
  1011       (case elem_ord (x, y) of EQUAL => dict_ord elem_ord (xs, ys) | ord => ord)
  1012   | dict_ord _ ([], []) = EQUAL
  1013   | dict_ord _ ([], _ :: _) = LESS
  1014   | dict_ord _ (_ :: _, []) = GREATER;
  1015 
  1016 (*lexicographic product of lists*)
  1017 fun list_ord elem_ord (xs, ys) =
  1018   (case int_ord (length xs, length ys) of EQUAL => dict_ord elem_ord (xs, ys) | ord => ord);
  1019 
  1020 
  1021 (* sorting *)
  1022 
  1023 (*quicksort -- stable, i.e. does not reorder equal elements*)
  1024 fun quicksort unique ord =
  1025   let
  1026     fun qsort [] = []
  1027       | qsort (xs as [_]) = xs
  1028       | qsort (xs as [x, y]) =
  1029           (case ord (x, y) of
  1030             LESS => xs
  1031           | EQUAL => if unique then [x] else xs
  1032           | GREATER => [y, x])
  1033       | qsort xs =
  1034           let val (lts, eqs, gts) = part (nth xs (length xs div 2)) xs
  1035           in qsort lts @ eqs @ qsort gts end
  1036     and part _ [] = ([], [], [])
  1037       | part pivot (x :: xs) = add (ord (x, pivot)) x (part pivot xs)
  1038     and add LESS x (lts, eqs, gts) = (x :: lts, eqs, gts)
  1039       | add EQUAL x (lts, [], gts) = (lts, [x], gts)
  1040       | add EQUAL x (res as (lts, eqs, gts)) = if unique then res else (lts, x :: eqs, gts)
  1041       | add GREATER x (lts, eqs, gts) = (lts, eqs, x :: gts);
  1042   in qsort end;
  1043 
  1044 fun sort ord = quicksort false ord;
  1045 fun sort_distinct ord = quicksort true ord;
  1046 
  1047 val sort_strings = sort string_ord;
  1048 fun sort_wrt sel xs = sort (string_ord o pairself sel) xs;
  1049 
  1050 
  1051 
  1052 (** random numbers **)
  1053 
  1054 exception RANDOM;
  1055 
  1056 fun rmod x y = x - y * Real.realFloor (x / y);
  1057 
  1058 local
  1059   val a = 16807.0;
  1060   val m = 2147483647.0;
  1061   val random_seed = ref 1.0;
  1062 in
  1063 
  1064 fun random () =
  1065   let val r = rmod (a * !random_seed) m
  1066   in (random_seed := r; r) end;
  1067 
  1068 end;
  1069 
  1070 fun random_range l h =
  1071   if h < l orelse l < 0 then raise RANDOM
  1072   else l + Real.floor (rmod (random ()) (real (h - l + 1)));
  1073 
  1074 fun one_of xs = nth xs (random_range 0 (length xs - 1));
  1075 
  1076 fun frequency xs =
  1077   let
  1078     val sum = foldl op + (0, map fst xs);
  1079     fun pick n ((k: int, x) :: xs) =
  1080       if n <= k then x else pick (n - k) xs
  1081   in pick (random_range 1 sum) xs end;
  1082 
  1083 
  1084 (** current directory **)
  1085 
  1086 val cd = OS.FileSys.chDir;
  1087 val pwd = OS.FileSys.getDir;
  1088 
  1089 
  1090 
  1091 (** misc **)
  1092 
  1093 fun divide_and_conquer decomp x =
  1094   let val (ys, recomb) = decomp x
  1095   in recomb (map (divide_and_conquer decomp) ys) end;
  1096 
  1097 
  1098 (*Partition a list into buckets  [ bi, b(i+1), ..., bj ]
  1099    putting x in bk if p(k)(x) holds.  Preserve order of elements if possible.*)
  1100 fun partition_list p i j =
  1101   let fun part k xs =
  1102             if k>j then
  1103               (case xs of [] => []
  1104                          | _ => raise Fail "partition_list")
  1105             else
  1106             let val (ns, rest) = List.partition (p k) xs;
  1107             in  ns :: part(k+1)rest  end
  1108   in  part i end;
  1109 
  1110 fun partition_eq (eq:'a * 'a -> bool) =
  1111   let
  1112     fun part [] = []
  1113       | part (x :: ys) =
  1114           let val (xs, xs') = List.partition (fn y => eq (x, y)) ys
  1115           in (x::xs)::(part xs') end
  1116   in part end;
  1117 
  1118 
  1119 
  1120 (* generating identifiers *)
  1121 
  1122 (** Freshly generated identifiers; supplied prefix MUST start with a letter **)
  1123 local
  1124 (*Maps 0-63 to A-Z, a-z, 0-9 or _ or ' for generating random identifiers*)
  1125 fun char i =      if i<26 then chr (ord "A" + i)
  1126              else if i<52 then chr (ord "a" + i - 26)
  1127              else if i<62 then chr (ord"0" + i - 52)
  1128              else if i=62 then "_"
  1129              else  (*i=63*)    "'";
  1130 
  1131 val charVec = Vector.tabulate (64, char);
  1132 
  1133 fun newid n =
  1134   let
  1135   in  implode (map (fn i => Vector.sub(charVec,i)) (radixpand (64,n)))  end;
  1136 
  1137 val seedr = ref 0;
  1138 
  1139 in
  1140 
  1141 fun gensym pre = pre ^ (#1(newid (!seedr), inc seedr));
  1142 
  1143 end;
  1144 
  1145 
  1146 (* lexical scanning *)
  1147 
  1148 (*scan a list of characters into "words" composed of "letters" (recognized by
  1149   is_let) and separated by any number of non-"letters"*)
  1150 fun scanwords is_let cs =
  1151   let fun scan1 [] = []
  1152         | scan1 cs =
  1153             let val (lets, rest) = take_prefix is_let cs
  1154             in implode lets :: scanwords is_let rest end;
  1155   in scan1 (#2 (take_prefix (not o is_let) cs)) end;
  1156 
  1157 
  1158 (* stamps and serial numbers *)
  1159 
  1160 type stamp = unit ref;
  1161 val stamp: unit -> stamp = ref;
  1162 
  1163 type serial = int;
  1164 local val count = ref 0
  1165 in fun serial () = inc count end;
  1166 
  1167 val serial_string = string_of_int o serial;
  1168 
  1169 
  1170 (* generic objects *)
  1171 
  1172 (*note that the builtin exception datatype may be extended by new
  1173   constructors at any time*)
  1174 structure Object = struct type T = exn end;
  1175 
  1176 end;
  1177 
  1178 structure BasicLibrary: BASIC_LIBRARY = Library;
  1179 open BasicLibrary;