src/HOL/Tools/res_axioms.ML
author wenzelm
Thu Aug 14 16:52:46 2008 +0200 (2008-08-14)
changeset 27865 27a8ad9612a3
parent 27809 a1e409db516b
child 28110 9d121b171a0a
permissions -rw-r--r--
moved basic thm operations from structure PureThy to Thm (cf. more_thm.ML);
     1 (*  Author: Jia Meng, Cambridge University Computer Laboratory
     2     ID: $Id$
     3     Copyright 2004 University of Cambridge
     4 
     5 Transformation of axiom rules (elim/intro/etc) into CNF forms.
     6 *)
     7 
     8 signature RES_AXIOMS =
     9 sig
    10   val cnf_axiom: theory -> thm -> thm list
    11   val pairname: thm -> string * thm
    12   val multi_base_blacklist: string list
    13   val bad_for_atp: thm -> bool
    14   val type_has_empty_sort: typ -> bool
    15   val cnf_rules_pairs: theory -> (string * thm) list -> (thm * (string * int)) list
    16   val neg_clausify: thm list -> thm list
    17   val expand_defs_tac: thm -> tactic
    18   val combinators: thm -> thm
    19   val neg_conjecture_clauses: thm -> int -> thm list * (string * typ) list
    20   val claset_rules_of: Proof.context -> (string * thm) list   (*FIXME DELETE*)
    21   val simpset_rules_of: Proof.context -> (string * thm) list  (*FIXME DELETE*)
    22   val atpset_rules_of: Proof.context -> (string * thm) list
    23   val suppress_endtheory: bool ref     (*for emergency use where endtheory causes problems*)
    24   val setup: theory -> theory
    25 end;
    26 
    27 structure ResAxioms: RES_AXIOMS =
    28 struct
    29 
    30 (* FIXME legacy *)
    31 fun freeze_thm th = #1 (Drule.freeze_thaw th);
    32 
    33 fun type_has_empty_sort (TFree (_, [])) = true
    34   | type_has_empty_sort (TVar (_, [])) = true
    35   | type_has_empty_sort (Type (_, Ts)) = exists type_has_empty_sort Ts
    36   | type_has_empty_sort _ = false;
    37 
    38 (**** Transformation of Elimination Rules into First-Order Formulas****)
    39 
    40 val cfalse = cterm_of HOL.thy HOLogic.false_const;
    41 val ctp_false = cterm_of HOL.thy (HOLogic.mk_Trueprop HOLogic.false_const);
    42 
    43 (*Converts an elim-rule into an equivalent theorem that does not have the
    44   predicate variable.  Leaves other theorems unchanged.  We simply instantiate the
    45   conclusion variable to False.*)
    46 fun transform_elim th =
    47   case concl_of th of    (*conclusion variable*)
    48        Const("Trueprop",_) $ (v as Var(_,Type("bool",[]))) =>
    49            Thm.instantiate ([], [(cterm_of HOL.thy v, cfalse)]) th
    50     | v as Var(_, Type("prop",[])) =>
    51            Thm.instantiate ([], [(cterm_of HOL.thy v, ctp_false)]) th
    52     | _ => th;
    53 
    54 (*To enforce single-threading*)
    55 exception Clausify_failure of theory;
    56 
    57 (**** SKOLEMIZATION BY INFERENCE (lcp) ****)
    58 
    59 fun rhs_extra_types lhsT rhs =
    60   let val lhs_vars = Term.add_tfreesT lhsT []
    61       fun add_new_TFrees (TFree v) =
    62             if member (op =) lhs_vars v then I else insert (op =) (TFree v)
    63         | add_new_TFrees _ = I
    64       val rhs_consts = fold_aterms (fn Const c => insert (op =) c | _ => I) rhs []
    65   in fold (#2 #> Term.fold_atyps add_new_TFrees) rhs_consts [] end;
    66 
    67 (*Traverse a theorem, declaring Skolem function definitions. String s is the suggested
    68   prefix for the Skolem constant.*)
    69 fun declare_skofuns s th =
    70   let
    71     val nref = ref 0
    72     fun dec_sko (Const ("Ex",_) $ (xtp as Abs (_, T, p))) (axs, thy) =
    73           (*Existential: declare a Skolem function, then insert into body and continue*)
    74           let
    75             val cname = "sko_" ^ s ^ "_" ^ Int.toString (inc nref)
    76             val args0 = term_frees xtp  (*get the formal parameter list*)
    77             val Ts = map type_of args0
    78             val extraTs = rhs_extra_types (Ts ---> T) xtp
    79             val _ = if null extraTs then () else
    80               warning ("Skolemization: extra type vars: " ^
    81                 commas_quote (map (Syntax.string_of_typ_global thy) extraTs))
    82             val argsx = map (fn T => Free (gensym "vsk", T)) extraTs
    83             val args = argsx @ args0
    84             val cT = extraTs ---> Ts ---> T
    85             val rhs = list_abs_free (map dest_Free args, HOLogic.choice_const T $ xtp)
    86                     (*Forms a lambda-abstraction over the formal parameters*)
    87             val (c, thy') = Sign.declare_const [Markup.property_internal] (cname, cT, NoSyn) thy
    88             val cdef = cname ^ "_def"
    89             val thy'' = Theory.add_defs_i true false [(cdef, Logic.mk_equals (c, rhs))] thy'
    90             val ax = Thm.get_axiom_i thy'' (Sign.full_name thy'' cdef)
    91           in dec_sko (subst_bound (list_comb (c, args), p)) (ax :: axs, thy'') end
    92       | dec_sko (Const ("All", _) $ (xtp as Abs (a, T, p))) thx =
    93           (*Universal quant: insert a free variable into body and continue*)
    94           let val fname = Name.variant (add_term_names (p, [])) a
    95           in dec_sko (subst_bound (Free (fname, T), p)) thx end
    96       | dec_sko (Const ("op &", _) $ p $ q) thx = dec_sko q (dec_sko p thx)
    97       | dec_sko (Const ("op |", _) $ p $ q) thx = dec_sko q (dec_sko p thx)
    98       | dec_sko (Const ("Trueprop", _) $ p) thx = dec_sko p thx
    99       | dec_sko t thx = thx (*Do nothing otherwise*)
   100   in fn thy => dec_sko (Thm.prop_of th) ([], thy) end;
   101 
   102 (*Traverse a theorem, accumulating Skolem function definitions.*)
   103 fun assume_skofuns s th =
   104   let val sko_count = ref 0
   105       fun dec_sko (Const ("Ex",_) $ (xtp as Abs(_,T,p))) defs =
   106             (*Existential: declare a Skolem function, then insert into body and continue*)
   107             let val skos = map (#1 o Logic.dest_equals) defs  (*existing sko fns*)
   108                 val args = term_frees xtp \\ skos  (*the formal parameters*)
   109                 val Ts = map type_of args
   110                 val cT = Ts ---> T
   111                 val id = "sko_" ^ s ^ "_" ^ Int.toString (inc sko_count)
   112                 val c = Free (id, cT)
   113                 val rhs = list_abs_free (map dest_Free args,
   114                                          HOLogic.choice_const T $ xtp)
   115                       (*Forms a lambda-abstraction over the formal parameters*)
   116                 val def = Logic.mk_equals (c, rhs)
   117             in dec_sko (subst_bound (list_comb(c,args), p))
   118                        (def :: defs)
   119             end
   120         | dec_sko (Const ("All",_) $ (xtp as Abs(a,T,p))) defs =
   121             (*Universal quant: insert a free variable into body and continue*)
   122             let val fname = Name.variant (add_term_names (p,[])) a
   123             in dec_sko (subst_bound (Free(fname,T), p)) defs end
   124         | dec_sko (Const ("op &", _) $ p $ q) defs = dec_sko q (dec_sko p defs)
   125         | dec_sko (Const ("op |", _) $ p $ q) defs = dec_sko q (dec_sko p defs)
   126         | dec_sko (Const ("Trueprop", _) $ p) defs = dec_sko p defs
   127         | dec_sko t defs = defs (*Do nothing otherwise*)
   128   in  dec_sko (prop_of th) []  end;
   129 
   130 
   131 (**** REPLACING ABSTRACTIONS BY COMBINATORS ****)
   132 
   133 (*Returns the vars of a theorem*)
   134 fun vars_of_thm th =
   135   map (Thm.cterm_of (theory_of_thm th) o Var) (Thm.fold_terms Term.add_vars th []);
   136 
   137 (*Make a version of fun_cong with a given variable name*)
   138 local
   139     val fun_cong' = fun_cong RS asm_rl; (*renumber f, g to prevent clashes with (a,0)*)
   140     val cx = hd (vars_of_thm fun_cong');
   141     val ty = typ_of (ctyp_of_term cx);
   142     val thy = theory_of_thm fun_cong;
   143     fun mkvar a = cterm_of thy (Var((a,0),ty));
   144 in
   145 fun xfun_cong x = Thm.instantiate ([], [(cx, mkvar x)]) fun_cong'
   146 end;
   147 
   148 (*Removes the lambdas from an equation of the form t = (%x. u).  A non-negative n,
   149   serves as an upper bound on how many to remove.*)
   150 fun strip_lambdas 0 th = th
   151   | strip_lambdas n th =
   152       case prop_of th of
   153           _ $ (Const ("op =", _) $ _ $ Abs (x,_,_)) =>
   154               strip_lambdas (n-1) (freeze_thm (th RS xfun_cong x))
   155         | _ => th;
   156 
   157 val lambda_free = not o Term.has_abs;
   158 
   159 val monomorphic = not o Term.exists_type (Term.exists_subtype Term.is_TVar);
   160 
   161 val [f_B,g_B] = map (cterm_of @{theory}) (term_vars (prop_of @{thm abs_B}));
   162 val [g_C,f_C] = map (cterm_of @{theory}) (term_vars (prop_of @{thm abs_C}));
   163 val [f_S,g_S] = map (cterm_of @{theory}) (term_vars (prop_of @{thm abs_S}));
   164 
   165 (*FIXME: requires more use of cterm constructors*)
   166 fun abstract ct =
   167   let val _ = Output.debug (fn()=>"  abstraction: " ^ Display.string_of_cterm ct)
   168       val Abs(x,_,body) = term_of ct
   169       val thy = theory_of_cterm ct
   170       val Type("fun",[xT,bodyT]) = typ_of (ctyp_of_term ct)
   171       val cxT = ctyp_of thy xT and cbodyT = ctyp_of thy bodyT
   172       fun makeK() = instantiate' [SOME cxT, SOME cbodyT] [SOME (cterm_of thy body)] @{thm abs_K}
   173   in
   174       case body of
   175           Const _ => makeK()
   176         | Free _ => makeK()
   177         | Var _ => makeK()  (*though Var isn't expected*)
   178         | Bound 0 => instantiate' [SOME cxT] [] @{thm abs_I} (*identity: I*)
   179         | rator$rand =>
   180             if loose_bvar1 (rator,0) then (*C or S*)
   181                if loose_bvar1 (rand,0) then (*S*)
   182                  let val crator = cterm_of thy (Abs(x,xT,rator))
   183                      val crand = cterm_of thy (Abs(x,xT,rand))
   184                      val abs_S' = cterm_instantiate [(f_S,crator),(g_S,crand)] @{thm abs_S}
   185                      val (_,rhs) = Thm.dest_equals (cprop_of abs_S')
   186                  in
   187                    Thm.transitive abs_S' (Conv.binop_conv abstract rhs)
   188                  end
   189                else (*C*)
   190                  let val crator = cterm_of thy (Abs(x,xT,rator))
   191                      val abs_C' = cterm_instantiate [(f_C,crator),(g_C,cterm_of thy rand)] @{thm abs_C}
   192                      val (_,rhs) = Thm.dest_equals (cprop_of abs_C')
   193                  in
   194                    Thm.transitive abs_C' (Conv.fun_conv (Conv.arg_conv abstract) rhs)
   195                  end
   196             else if loose_bvar1 (rand,0) then (*B or eta*)
   197                if rand = Bound 0 then eta_conversion ct
   198                else (*B*)
   199                  let val crand = cterm_of thy (Abs(x,xT,rand))
   200                      val crator = cterm_of thy rator
   201                      val abs_B' = cterm_instantiate [(f_B,crator),(g_B,crand)] @{thm abs_B}
   202                      val (_,rhs) = Thm.dest_equals (cprop_of abs_B')
   203                  in
   204                    Thm.transitive abs_B' (Conv.arg_conv abstract rhs)
   205                  end
   206             else makeK()
   207         | _ => error "abstract: Bad term"
   208   end;
   209 
   210 (*Traverse a theorem, declaring abstraction function definitions. String s is the suggested
   211   prefix for the constants. Resulting theory is returned in the first theorem. *)
   212 fun combinators_aux ct =
   213   if lambda_free (term_of ct) then reflexive ct
   214   else
   215   case term_of ct of
   216       Abs _ =>
   217         let val (cv,cta) = Thm.dest_abs NONE ct
   218             val (v,Tv) = (dest_Free o term_of) cv
   219             val _ = Output.debug (fn()=>"  recursion: " ^ Display.string_of_cterm cta);
   220             val u_th = combinators_aux cta
   221             val _ = Output.debug (fn()=>"  returned " ^ Display.string_of_thm u_th);
   222             val cu = Thm.rhs_of u_th
   223             val comb_eq = abstract (Thm.cabs cv cu)
   224         in Output.debug (fn()=>"  abstraction result: " ^ Display.string_of_thm comb_eq);
   225            (transitive (abstract_rule v cv u_th) comb_eq) end
   226     | t1 $ t2 =>
   227         let val (ct1,ct2) = Thm.dest_comb ct
   228         in  combination (combinators_aux ct1) (combinators_aux ct2)  end;
   229 
   230 fun combinators th =
   231   if lambda_free (prop_of th) then th
   232   else
   233     let val _ = Output.debug (fn()=>"Conversion to combinators: " ^ Display.string_of_thm th);
   234         val th = Drule.eta_contraction_rule th
   235         val eqth = combinators_aux (cprop_of th)
   236         val _ = Output.debug (fn()=>"Conversion result: " ^ Display.string_of_thm eqth);
   237     in  equal_elim eqth th   end
   238     handle THM (msg,_,_) =>
   239       (warning ("Error in the combinator translation of " ^ Display.string_of_thm th);
   240        warning ("  Exception message: " ^ msg);
   241        TrueI);  (*A type variable of sort {} will cause make abstraction fail.*)
   242 
   243 (*cterms are used throughout for efficiency*)
   244 val cTrueprop = Thm.cterm_of HOL.thy HOLogic.Trueprop;
   245 
   246 (*cterm version of mk_cTrueprop*)
   247 fun c_mkTrueprop A = Thm.capply cTrueprop A;
   248 
   249 (*Given an abstraction over n variables, replace the bound variables by free
   250   ones. Return the body, along with the list of free variables.*)
   251 fun c_variant_abs_multi (ct0, vars) =
   252       let val (cv,ct) = Thm.dest_abs NONE ct0
   253       in  c_variant_abs_multi (ct, cv::vars)  end
   254       handle CTERM _ => (ct0, rev vars);
   255 
   256 (*Given the definition of a Skolem function, return a theorem to replace
   257   an existential formula by a use of that function.
   258    Example: "EX x. x : A & x ~: B ==> sko A B : A & sko A B ~: B"  [.] *)
   259 fun skolem_of_def def =
   260   let val (c,rhs) = Thm.dest_equals (cprop_of (freeze_thm def))
   261       val (ch, frees) = c_variant_abs_multi (rhs, [])
   262       val (chilbert,cabs) = Thm.dest_comb ch
   263       val thy = Thm.theory_of_cterm chilbert
   264       val t = Thm.term_of chilbert
   265       val T = case t of Const ("Hilbert_Choice.Eps", Type("fun",[_,T])) => T
   266                       | _ => raise THM ("skolem_of_def: expected Eps", 0, [def])
   267       val cex = Thm.cterm_of thy (HOLogic.exists_const T)
   268       val ex_tm = c_mkTrueprop (Thm.capply cex cabs)
   269       and conc =  c_mkTrueprop (Drule.beta_conv cabs (Drule.list_comb(c,frees)));
   270       fun tacf [prem] = rewrite_goals_tac [def] THEN rtac (prem RS someI_ex) 1
   271   in  Goal.prove_internal [ex_tm] conc tacf
   272        |> forall_intr_list frees
   273        |> Thm.forall_elim_vars 0  (*Introduce Vars, but don't discharge defs.*)
   274        |> Thm.varifyT
   275   end;
   276 
   277 
   278 (*Converts an Isabelle theorem (intro, elim or simp format, even higher-order) into NNF.*)
   279 fun to_nnf th ctxt0 =
   280   let val th1 = th |> transform_elim |> zero_var_indexes
   281       val ((_,[th2]),ctxt) = Variable.import_thms true [th1] ctxt0
   282       val th3 = th2 |> Conv.fconv_rule ObjectLogic.atomize |> Meson.make_nnf |> strip_lambdas ~1
   283   in  (th3, ctxt)  end;
   284 
   285 (*Generate Skolem functions for a theorem supplied in nnf*)
   286 fun assume_skolem_of_def s th =
   287   map (skolem_of_def o assume o (cterm_of (theory_of_thm th))) (assume_skofuns s th);
   288 
   289 fun assert_lambda_free ths msg =
   290   case filter (not o lambda_free o prop_of) ths of
   291       [] => ()
   292     | ths' => error (msg ^ "\n" ^ cat_lines (map Display.string_of_thm ths'));
   293 
   294 
   295 (*** Blacklisting (duplicated in ResAtp?) ***)
   296 
   297 val max_lambda_nesting = 3;
   298 
   299 fun excessive_lambdas (f$t, k) = excessive_lambdas (f,k) orelse excessive_lambdas (t,k)
   300   | excessive_lambdas (Abs(_,_,t), k) = k=0 orelse excessive_lambdas (t,k-1)
   301   | excessive_lambdas _ = false;
   302 
   303 fun is_formula_type T = (T = HOLogic.boolT orelse T = propT);
   304 
   305 (*Don't count nested lambdas at the level of formulas, as they are quantifiers*)
   306 fun excessive_lambdas_fm Ts (Abs(_,T,t)) = excessive_lambdas_fm (T::Ts) t
   307   | excessive_lambdas_fm Ts t =
   308       if is_formula_type (fastype_of1 (Ts, t))
   309       then exists (excessive_lambdas_fm Ts) (#2 (strip_comb t))
   310       else excessive_lambdas (t, max_lambda_nesting);
   311 
   312 (*The max apply_depth of any metis call in MetisExamples (on 31-10-2007) was 11.*)
   313 val max_apply_depth = 15;
   314 
   315 fun apply_depth (f$t) = Int.max (apply_depth f, apply_depth t + 1)
   316   | apply_depth (Abs(_,_,t)) = apply_depth t
   317   | apply_depth _ = 0;
   318 
   319 fun too_complex t =
   320   apply_depth t > max_apply_depth orelse
   321   Meson.too_many_clauses NONE t orelse
   322   excessive_lambdas_fm [] t;
   323 
   324 fun is_strange_thm th =
   325   case head_of (concl_of th) of
   326       Const (a,_) => (a <> "Trueprop" andalso a <> "==")
   327     | _ => false;
   328 
   329 fun bad_for_atp th =
   330   Thm.is_internal th
   331   orelse too_complex (prop_of th)
   332   orelse exists_type type_has_empty_sort (prop_of th)
   333   orelse is_strange_thm th;
   334 
   335 val multi_base_blacklist =
   336   ["defs","select_defs","update_defs","induct","inducts","split","splits","split_asm",
   337    "cases","ext_cases"];  (*FIXME: put other record thms here, or use the "Internal" marker*)
   338 
   339 (*Keep the full complexity of the original name*)
   340 fun flatten_name s = space_implode "_X" (NameSpace.explode s);
   341 
   342 fun fake_name th =
   343   if Thm.has_name_hint th then flatten_name (Thm.get_name_hint th)
   344   else gensym "unknown_thm_";
   345 
   346 fun name_or_string th =
   347   if Thm.has_name_hint th then Thm.get_name_hint th
   348   else Display.string_of_thm th;
   349 
   350 (*Skolemize a named theorem, with Skolem functions as additional premises.*)
   351 fun skolem_thm (s, th) =
   352   if member (op =) multi_base_blacklist (Sign.base_name s) orelse bad_for_atp th then []
   353   else
   354     let
   355       val ctxt0 = Variable.thm_context th
   356       val (nnfth, ctxt1) = to_nnf th ctxt0
   357       val (cnfs, ctxt2) = Meson.make_cnf (assume_skolem_of_def s nnfth) nnfth ctxt1
   358     in  cnfs |> map combinators |> Variable.export ctxt2 ctxt0 |> Meson.finish_cnf  end
   359     handle THM _ => [];
   360 
   361 (*Declare Skolem functions for a theorem, supplied in nnf and with its name.
   362   It returns a modified theory, unless skolemization fails.*)
   363 fun skolem (name, th0) thy =
   364   let
   365     val th = Thm.transfer thy th0
   366     val ctxt0 = Variable.thm_context th
   367   in
   368     try (to_nnf th) ctxt0 |> Option.map (fn (nnfth, ctxt1) =>
   369       let
   370         val s = flatten_name name
   371         val (defs, thy') = declare_skofuns s nnfth thy
   372         val (cnfs, ctxt2) = Meson.make_cnf (map skolem_of_def defs) nnfth ctxt1
   373         val cnfs' = cnfs |> map combinators |> Variable.export ctxt2 ctxt0
   374                          |> Meson.finish_cnf |> map Thm.close_derivation
   375       in (cnfs', thy') end)
   376   end;
   377 
   378 (*The cache prevents repeated clausification of a theorem, and also repeated declaration of
   379   Skolem functions.*)
   380 structure ThmCache = TheoryDataFun
   381 (
   382   type T = thm list Thmtab.table * unit Symtab.table
   383   val empty = (Thmtab.empty, Symtab.empty)
   384   val copy = I;
   385   val extend = I;
   386   fun merge _ ((cache1, seen1), (cache2, seen2)) : T =
   387     (Thmtab.merge (K true) (cache1, cache2), Symtab.merge (K true) (seen1, seen2));
   388 );
   389 
   390 val lookup_cache = Thmtab.lookup o #1 o ThmCache.get;
   391 val already_seen = Symtab.defined o #2 o ThmCache.get;
   392 
   393 val update_cache = ThmCache.map o apfst o Thmtab.update;
   394 fun mark_seen name = ThmCache.map (apsnd (Symtab.update (name, ())));
   395 
   396 (*Exported function to convert Isabelle theorems into axiom clauses*)
   397 fun cnf_axiom thy th0 =
   398   let val th = Thm.transfer thy th0 in
   399     case lookup_cache thy th of
   400       NONE => map Thm.close_derivation (skolem_thm (fake_name th, th))
   401     | SOME cls => cls
   402   end;
   403 
   404 
   405 (**** Extract and Clausify theorems from a theory's claset and simpset ****)
   406 
   407 fun pairname th = (Thm.get_name_hint th, th);
   408 
   409 fun rules_of_claset cs =
   410   let val {safeIs,safeEs,hazIs,hazEs,...} = rep_cs cs
   411       val intros = safeIs @ hazIs
   412       val elims  = map Classical.classical_rule (safeEs @ hazEs)
   413   in
   414      Output.debug (fn () => "rules_of_claset intros: " ^ Int.toString(length intros) ^
   415             " elims: " ^ Int.toString(length elims));
   416      map pairname (intros @ elims)
   417   end;
   418 
   419 fun rules_of_simpset ss =
   420   let val ({rules,...}, _) = rep_ss ss
   421       val simps = Net.entries rules
   422   in
   423     Output.debug (fn () => "rules_of_simpset: " ^ Int.toString(length simps));
   424     map (fn r => (#name r, #thm r)) simps
   425   end;
   426 
   427 fun claset_rules_of ctxt = rules_of_claset (local_claset_of ctxt);
   428 fun simpset_rules_of ctxt = rules_of_simpset (local_simpset_of ctxt);
   429 
   430 fun atpset_rules_of ctxt = map pairname (ResAtpset.get ctxt);
   431 
   432 
   433 (**** Translate a set of theorems into CNF ****)
   434 
   435 fun pair_name_cls k (n, []) = []
   436   | pair_name_cls k (n, cls::clss) = (cls, (n,k)) :: pair_name_cls (k+1) (n, clss)
   437 
   438 fun cnf_rules_pairs_aux _ pairs [] = pairs
   439   | cnf_rules_pairs_aux thy pairs ((name,th)::ths) =
   440       let val pairs' = (pair_name_cls 0 (name, cnf_axiom thy th)) @ pairs
   441                        handle THM _ => pairs | ResClause.CLAUSE _ => pairs
   442       in  cnf_rules_pairs_aux thy pairs' ths  end;
   443 
   444 (*The combination of rev and tail recursion preserves the original order*)
   445 fun cnf_rules_pairs thy l = cnf_rules_pairs_aux thy [] (rev l);
   446 
   447 
   448 (**** Convert all facts of the theory into clauses (ResClause.clause, or ResHolClause.clause) ****)
   449 
   450 (*Populate the clause cache using the supplied theorem. Return the clausal form
   451   and modified theory.*)
   452 fun skolem_cache_thm name (i, th) thy =
   453   if bad_for_atp th then thy
   454   else
   455     (case lookup_cache thy th of
   456       SOME _ => thy
   457     | NONE =>
   458         (case skolem (name ^ "_" ^ string_of_int (i + 1), th) thy of
   459           NONE => thy
   460         | SOME (cls, thy') => update_cache (th, cls) thy'));
   461 
   462 fun skolem_cache_fact (name, ths) (changed, thy) =
   463   if (Sign.base_name name) mem_string multi_base_blacklist orelse already_seen thy name
   464   then (changed, thy)
   465   else (true, thy |> mark_seen name |> fold_index (skolem_cache_thm name) ths);
   466 
   467 fun saturate_skolem_cache thy =
   468   (case Facts.fold_static skolem_cache_fact (PureThy.facts_of thy) (false, thy) of
   469     (false, _) => NONE
   470   | (true, thy') => SOME thy');
   471 
   472 
   473 val suppress_endtheory = ref false;
   474 
   475 fun clause_cache_endtheory thy =
   476   if ! suppress_endtheory then NONE
   477   else saturate_skolem_cache thy;
   478 
   479 
   480 (*The cache can be kept smaller by inspecting the prop of each thm. Can ignore all that are
   481   lambda_free, but then the individual theory caches become much bigger.*)
   482 
   483 
   484 (*** meson proof methods ***)
   485 
   486 (*Expand all new*definitions of abstraction or Skolem functions in a proof state.*)
   487 fun is_absko (Const ("==", _) $ Free (a,_) $ u) = String.isPrefix "sko_" a
   488   | is_absko _ = false;
   489 
   490 fun is_okdef xs (Const ("==", _) $ t $ u) =   (*Definition of Free, not in certain terms*)
   491       is_Free t andalso not (member (op aconv) xs t)
   492   | is_okdef _ _ = false
   493 
   494 (*This function tries to cope with open locales, which introduce hypotheses of the form
   495   Free == t, conjecture clauses, which introduce various hypotheses, and also definitions
   496   of sko_ functions. *)
   497 fun expand_defs_tac st0 st =
   498   let val hyps0 = #hyps (rep_thm st0)
   499       val hyps = #hyps (crep_thm st)
   500       val newhyps = filter_out (member (op aconv) hyps0 o Thm.term_of) hyps
   501       val defs = filter (is_absko o Thm.term_of) newhyps
   502       val remaining_hyps = filter_out (member (op aconv) (map Thm.term_of defs))
   503                                       (map Thm.term_of hyps)
   504       val fixed = term_frees (concl_of st) @
   505                   foldl (gen_union (op aconv)) [] (map term_frees remaining_hyps)
   506   in  Output.debug (fn _ => "expand_defs_tac: " ^ Display.string_of_thm st);
   507       Output.debug (fn _ => "  st0: " ^ Display.string_of_thm st0);
   508       Output.debug (fn _ => "  defs: " ^ commas (map Display.string_of_cterm defs));
   509       Seq.of_list [LocalDefs.expand (filter (is_okdef fixed o Thm.term_of) defs) st]
   510   end;
   511 
   512 
   513 fun meson_general_tac ths i st0 =
   514   let
   515     val thy = Thm.theory_of_thm st0
   516     val _ = Output.debug (fn () => "Meson called: " ^ cat_lines (map Display.string_of_thm ths))
   517   in  (Meson.meson_claset_tac (maps (cnf_axiom thy) ths) HOL_cs i THEN expand_defs_tac st0) st0 end;
   518 
   519 val meson_method_setup = Method.add_methods
   520   [("meson", Method.thms_args (fn ths =>
   521       Method.SIMPLE_METHOD' (CHANGED_PROP o meson_general_tac ths)),
   522     "MESON resolution proof procedure")];
   523 
   524 
   525 (*** Converting a subgoal into negated conjecture clauses. ***)
   526 
   527 val neg_skolemize_tac = EVERY' [rtac ccontr, ObjectLogic.atomize_prems_tac, Meson.skolemize_tac];
   528 
   529 fun neg_clausify sts =
   530   sts |> Meson.make_clauses |> map combinators |> Meson.finish_cnf;
   531 
   532 fun neg_conjecture_clauses st0 n =
   533   let val st = Seq.hd (neg_skolemize_tac n st0)
   534       val (params,_,_) = strip_context (Logic.nth_prem (n, Thm.prop_of st))
   535   in (neg_clausify (the (metahyps_thms n st)), params) end
   536   handle Option => error "unable to Skolemize subgoal";
   537 
   538 (*Conversion of a subgoal to conjecture clauses. Each clause has
   539   leading !!-bound universal variables, to express generality. *)
   540 val neg_clausify_tac =
   541   neg_skolemize_tac THEN'
   542   SUBGOAL
   543     (fn (prop,_) =>
   544      let val ts = Logic.strip_assums_hyp prop
   545      in EVERY1
   546          [METAHYPS
   547             (fn hyps =>
   548               (Method.insert_tac
   549                 (map forall_intr_vars (neg_clausify hyps)) 1)),
   550           REPEAT_DETERM_N (length ts) o (etac thin_rl)]
   551      end);
   552 
   553 val setup_methods = Method.add_methods
   554   [("neg_clausify", Method.no_args (Method.SIMPLE_METHOD' neg_clausify_tac),
   555     "conversion of goal to conjecture clauses")];
   556 
   557 
   558 (** Attribute for converting a theorem into clauses **)
   559 
   560 val clausify = Attrib.syntax (Scan.lift OuterParse.nat
   561   >> (fn i => Thm.rule_attribute (fn context => fn th =>
   562       Meson.make_meta_clause (nth (cnf_axiom (Context.theory_of context) th) i))));
   563 
   564 val setup_attrs = Attrib.add_attributes
   565   [("clausify", clausify, "conversion of theorem to clauses")];
   566 
   567 
   568 
   569 (** setup **)
   570 
   571 val setup =
   572   meson_method_setup #>
   573   setup_methods #>
   574   setup_attrs #>
   575   perhaps saturate_skolem_cache #>
   576   Theory.at_end clause_cache_endtheory;
   577 
   578 end;
   579