src/HOL/Deriv.thy
author paulson <lp15@cam.ac.uk>
Mon May 23 15:33:24 2016 +0100 (2016-05-23)
changeset 63114 27afe7af7379
parent 63092 a949b2a5f51d
child 63170 eae6549dbea2
permissions -rw-r--r--
Lots of new material for multivariate analysis
     1 (*  Title       : Deriv.thy
     2     Author      : Jacques D. Fleuriot
     3     Copyright   : 1998  University of Cambridge
     4     Author      : Brian Huffman
     5     Conversion to Isar and new proofs by Lawrence C Paulson, 2004
     6     GMVT by Benjamin Porter, 2005
     7 *)
     8 
     9 section\<open>Differentiation\<close>
    10 
    11 theory Deriv
    12 imports Limits
    13 begin
    14 
    15 subsection \<open>Frechet derivative\<close>
    16 
    17 definition
    18   has_derivative :: "('a::real_normed_vector \<Rightarrow> 'b::real_normed_vector) \<Rightarrow> ('a \<Rightarrow> 'b) \<Rightarrow> 'a filter \<Rightarrow>  bool"
    19   (infix "(has'_derivative)" 50)
    20 where
    21   "(f has_derivative f') F \<longleftrightarrow>
    22     (bounded_linear f' \<and>
    23      ((\<lambda>y. ((f y - f (Lim F (\<lambda>x. x))) - f' (y - Lim F (\<lambda>x. x))) /\<^sub>R norm (y - Lim F (\<lambda>x. x))) \<longlongrightarrow> 0) F)"
    24 
    25 text \<open>
    26   Usually the filter @{term F} is @{term "at x within s"}.  @{term "(f has_derivative D)
    27   (at x within s)"} means: @{term D} is the derivative of function @{term f} at point @{term x}
    28   within the set @{term s}. Where @{term s} is used to express left or right sided derivatives. In
    29   most cases @{term s} is either a variable or @{term UNIV}.
    30 \<close>
    31 
    32 lemma has_derivative_eq_rhs: "(f has_derivative f') F \<Longrightarrow> f' = g' \<Longrightarrow> (f has_derivative g') F"
    33   by simp
    34 
    35 definition 
    36   has_field_derivative :: "('a::real_normed_field \<Rightarrow> 'a) \<Rightarrow> 'a \<Rightarrow> 'a filter \<Rightarrow> bool"
    37   (infix "(has'_field'_derivative)" 50)
    38 where
    39   "(f has_field_derivative D) F \<longleftrightarrow> (f has_derivative op * D) F"
    40 
    41 lemma DERIV_cong: "(f has_field_derivative X) F \<Longrightarrow> X = Y \<Longrightarrow> (f has_field_derivative Y) F"
    42   by simp
    43 
    44 definition
    45   has_vector_derivative :: "(real \<Rightarrow> 'b::real_normed_vector) \<Rightarrow> 'b \<Rightarrow> real filter \<Rightarrow> bool"
    46   (infix "has'_vector'_derivative" 50)
    47 where
    48   "(f has_vector_derivative f') net \<longleftrightarrow> (f has_derivative (\<lambda>x. x *\<^sub>R f')) net"
    49 
    50 lemma has_vector_derivative_eq_rhs: "(f has_vector_derivative X) F \<Longrightarrow> X = Y \<Longrightarrow> (f has_vector_derivative Y) F"
    51   by simp
    52 
    53 named_theorems derivative_intros "structural introduction rules for derivatives"
    54 setup \<open>
    55   let
    56     val eq_thms = @{thms has_derivative_eq_rhs DERIV_cong has_vector_derivative_eq_rhs}
    57     fun eq_rule thm = get_first (try (fn eq_thm => eq_thm OF [thm])) eq_thms
    58   in
    59     Global_Theory.add_thms_dynamic
    60       (@{binding derivative_eq_intros},
    61         fn context =>
    62           Named_Theorems.get (Context.proof_of context) @{named_theorems derivative_intros}
    63           |> map_filter eq_rule)
    64   end;
    65 \<close>
    66 
    67 text \<open>
    68   The following syntax is only used as a legacy syntax.
    69 \<close>
    70 abbreviation (input)
    71   FDERIV :: "('a::real_normed_vector \<Rightarrow> 'b::real_normed_vector) \<Rightarrow> 'a \<Rightarrow>  ('a \<Rightarrow> 'b) \<Rightarrow> bool"
    72   ("(FDERIV (_)/ (_)/ :> (_))" [1000, 1000, 60] 60)
    73 where
    74   "FDERIV f x :> f' \<equiv> (f has_derivative f') (at x)"
    75 
    76 lemma has_derivative_bounded_linear: "(f has_derivative f') F \<Longrightarrow> bounded_linear f'"
    77   by (simp add: has_derivative_def)
    78 
    79 lemma has_derivative_linear: "(f has_derivative f') F \<Longrightarrow> linear f'"
    80   using bounded_linear.linear[OF has_derivative_bounded_linear] .
    81 
    82 lemma has_derivative_ident[derivative_intros, simp]: "((\<lambda>x. x) has_derivative (\<lambda>x. x)) F"
    83   by (simp add: has_derivative_def)
    84 
    85 lemma has_derivative_const[derivative_intros, simp]: "((\<lambda>x. c) has_derivative (\<lambda>x. 0)) F"
    86   by (simp add: has_derivative_def)
    87 
    88 lemma (in bounded_linear) bounded_linear: "bounded_linear f" ..
    89 
    90 lemma (in bounded_linear) has_derivative:
    91   "(g has_derivative g') F \<Longrightarrow> ((\<lambda>x. f (g x)) has_derivative (\<lambda>x. f (g' x))) F"
    92   unfolding has_derivative_def
    93   apply safe
    94   apply (erule bounded_linear_compose [OF bounded_linear])
    95   apply (drule tendsto)
    96   apply (simp add: scaleR diff add zero)
    97   done
    98 
    99 lemmas has_derivative_scaleR_right [derivative_intros] =
   100   bounded_linear.has_derivative [OF bounded_linear_scaleR_right]
   101 
   102 lemmas has_derivative_scaleR_left [derivative_intros] =
   103   bounded_linear.has_derivative [OF bounded_linear_scaleR_left]
   104 
   105 lemmas has_derivative_mult_right [derivative_intros] =
   106   bounded_linear.has_derivative [OF bounded_linear_mult_right]
   107 
   108 lemmas has_derivative_mult_left [derivative_intros] =
   109   bounded_linear.has_derivative [OF bounded_linear_mult_left]
   110 
   111 lemma has_derivative_add[simp, derivative_intros]:
   112   assumes f: "(f has_derivative f') F" and g: "(g has_derivative g') F"
   113   shows "((\<lambda>x. f x + g x) has_derivative (\<lambda>x. f' x + g' x)) F"
   114   unfolding has_derivative_def
   115 proof safe
   116   let ?x = "Lim F (\<lambda>x. x)"
   117   let ?D = "\<lambda>f f' y. ((f y - f ?x) - f' (y - ?x)) /\<^sub>R norm (y - ?x)"
   118   have "((\<lambda>x. ?D f f' x + ?D g g' x) \<longlongrightarrow> (0 + 0)) F"
   119     using f g by (intro tendsto_add) (auto simp: has_derivative_def)
   120   then show "(?D (\<lambda>x. f x + g x) (\<lambda>x. f' x + g' x) \<longlongrightarrow> 0) F"
   121     by (simp add: field_simps scaleR_add_right scaleR_diff_right)
   122 qed (blast intro: bounded_linear_add f g has_derivative_bounded_linear)
   123 
   124 lemma has_derivative_setsum[simp, derivative_intros]:
   125   assumes f: "\<And>i. i \<in> I \<Longrightarrow> (f i has_derivative f' i) F"
   126   shows "((\<lambda>x. \<Sum>i\<in>I. f i x) has_derivative (\<lambda>x. \<Sum>i\<in>I. f' i x)) F"
   127 proof cases
   128   assume "finite I" from this f show ?thesis
   129     by induct (simp_all add: f)
   130 qed simp
   131 
   132 lemma has_derivative_minus[simp, derivative_intros]: "(f has_derivative f') F \<Longrightarrow> ((\<lambda>x. - f x) has_derivative (\<lambda>x. - f' x)) F"
   133   using has_derivative_scaleR_right[of f f' F "-1"] by simp
   134 
   135 lemma has_derivative_diff[simp, derivative_intros]:
   136   "(f has_derivative f') F \<Longrightarrow> (g has_derivative g') F \<Longrightarrow> ((\<lambda>x. f x - g x) has_derivative (\<lambda>x. f' x - g' x)) F"
   137   by (simp only: diff_conv_add_uminus has_derivative_add has_derivative_minus)
   138 
   139 lemma has_derivative_at_within:
   140   "(f has_derivative f') (at x within s) \<longleftrightarrow>
   141     (bounded_linear f' \<and> ((\<lambda>y. ((f y - f x) - f' (y - x)) /\<^sub>R norm (y - x)) \<longlongrightarrow> 0) (at x within s))"
   142   by (cases "at x within s = bot") (simp_all add: has_derivative_def Lim_ident_at)
   143 
   144 lemma has_derivative_iff_norm:
   145   "(f has_derivative f') (at x within s) \<longleftrightarrow>
   146     (bounded_linear f' \<and> ((\<lambda>y. norm ((f y - f x) - f' (y - x)) / norm (y - x)) \<longlongrightarrow> 0) (at x within s))"
   147   using tendsto_norm_zero_iff[of _ "at x within s", where 'b="'b", symmetric]
   148   by (simp add: has_derivative_at_within divide_inverse ac_simps)
   149 
   150 lemma has_derivative_at:
   151   "(f has_derivative D) (at x) \<longleftrightarrow> (bounded_linear D \<and> (\<lambda>h. norm (f (x + h) - f x - D h) / norm h) \<midarrow>0\<rightarrow> 0)"
   152   unfolding has_derivative_iff_norm LIM_offset_zero_iff[of _ _ x] by simp
   153 
   154 lemma field_has_derivative_at:
   155   fixes x :: "'a::real_normed_field"
   156   shows "(f has_derivative op * D) (at x) \<longleftrightarrow> (\<lambda>h. (f (x + h) - f x) / h) \<midarrow>0\<rightarrow> D"
   157   apply (unfold has_derivative_at)
   158   apply (simp add: bounded_linear_mult_right)
   159   apply (simp cong: LIM_cong add: nonzero_norm_divide [symmetric])
   160   apply (subst diff_divide_distrib)
   161   apply (subst times_divide_eq_left [symmetric])
   162   apply (simp cong: LIM_cong)
   163   apply (simp add: tendsto_norm_zero_iff LIM_zero_iff)
   164   done
   165 
   166 lemma has_derivativeI:
   167   "bounded_linear f' \<Longrightarrow> ((\<lambda>y. ((f y - f x) - f' (y - x)) /\<^sub>R norm (y - x)) \<longlongrightarrow> 0) (at x within s) \<Longrightarrow>
   168   (f has_derivative f') (at x within s)"
   169   by (simp add: has_derivative_at_within)
   170 
   171 lemma has_derivativeI_sandwich:
   172   assumes e: "0 < e" and bounded: "bounded_linear f'"
   173     and sandwich: "(\<And>y. y \<in> s \<Longrightarrow> y \<noteq> x \<Longrightarrow> dist y x < e \<Longrightarrow> norm ((f y - f x) - f' (y - x)) / norm (y - x) \<le> H y)"
   174     and "(H \<longlongrightarrow> 0) (at x within s)"
   175   shows "(f has_derivative f') (at x within s)"
   176   unfolding has_derivative_iff_norm
   177 proof safe
   178   show "((\<lambda>y. norm (f y - f x - f' (y - x)) / norm (y - x)) \<longlongrightarrow> 0) (at x within s)"
   179   proof (rule tendsto_sandwich[where f="\<lambda>x. 0"])
   180     show "(H \<longlongrightarrow> 0) (at x within s)" by fact
   181     show "eventually (\<lambda>n. norm (f n - f x - f' (n - x)) / norm (n - x) \<le> H n) (at x within s)"
   182       unfolding eventually_at using e sandwich by auto
   183   qed (auto simp: le_divide_eq)
   184 qed fact
   185 
   186 lemma has_derivative_subset: "(f has_derivative f') (at x within s) \<Longrightarrow> t \<subseteq> s \<Longrightarrow> (f has_derivative f') (at x within t)"
   187   by (auto simp add: has_derivative_iff_norm intro: tendsto_within_subset)
   188 
   189 lemmas has_derivative_within_subset = has_derivative_subset 
   190 
   191 
   192 subsection \<open>Continuity\<close>
   193 
   194 lemma has_derivative_continuous:
   195   assumes f: "(f has_derivative f') (at x within s)"
   196   shows "continuous (at x within s) f"
   197 proof -
   198   from f interpret F: bounded_linear f' by (rule has_derivative_bounded_linear)
   199   note F.tendsto[tendsto_intros]
   200   let ?L = "\<lambda>f. (f \<longlongrightarrow> 0) (at x within s)"
   201   have "?L (\<lambda>y. norm ((f y - f x) - f' (y - x)) / norm (y - x))"
   202     using f unfolding has_derivative_iff_norm by blast
   203   then have "?L (\<lambda>y. norm ((f y - f x) - f' (y - x)) / norm (y - x) * norm (y - x))" (is ?m)
   204     by (rule tendsto_mult_zero) (auto intro!: tendsto_eq_intros)
   205   also have "?m \<longleftrightarrow> ?L (\<lambda>y. norm ((f y - f x) - f' (y - x)))"
   206     by (intro filterlim_cong) (simp_all add: eventually_at_filter)
   207   finally have "?L (\<lambda>y. (f y - f x) - f' (y - x))"
   208     by (rule tendsto_norm_zero_cancel)
   209   then have "?L (\<lambda>y. ((f y - f x) - f' (y - x)) + f' (y - x))"
   210     by (rule tendsto_eq_intros) (auto intro!: tendsto_eq_intros simp: F.zero)
   211   then have "?L (\<lambda>y. f y - f x)"
   212     by simp
   213   from tendsto_add[OF this tendsto_const, of "f x"] show ?thesis
   214     by (simp add: continuous_within)
   215 qed
   216 
   217 subsection \<open>Composition\<close>
   218 
   219 lemma tendsto_at_iff_tendsto_nhds_within: "f x = y \<Longrightarrow> (f \<longlongrightarrow> y) (at x within s) \<longleftrightarrow> (f \<longlongrightarrow> y) (inf (nhds x) (principal s))"
   220   unfolding tendsto_def eventually_inf_principal eventually_at_filter
   221   by (intro ext all_cong imp_cong) (auto elim!: eventually_mono)
   222 
   223 lemma has_derivative_in_compose:
   224   assumes f: "(f has_derivative f') (at x within s)"
   225   assumes g: "(g has_derivative g') (at (f x) within (f`s))"
   226   shows "((\<lambda>x. g (f x)) has_derivative (\<lambda>x. g' (f' x))) (at x within s)"
   227 proof -
   228   from f interpret F: bounded_linear f' by (rule has_derivative_bounded_linear)
   229   from g interpret G: bounded_linear g' by (rule has_derivative_bounded_linear)
   230   from F.bounded obtain kF where kF: "\<And>x. norm (f' x) \<le> norm x * kF" by fast
   231   from G.bounded obtain kG where kG: "\<And>x. norm (g' x) \<le> norm x * kG" by fast
   232   note G.tendsto[tendsto_intros]
   233 
   234   let ?L = "\<lambda>f. (f \<longlongrightarrow> 0) (at x within s)"
   235   let ?D = "\<lambda>f f' x y. (f y - f x) - f' (y - x)"
   236   let ?N = "\<lambda>f f' x y. norm (?D f f' x y) / norm (y - x)"
   237   let ?gf = "\<lambda>x. g (f x)" and ?gf' = "\<lambda>x. g' (f' x)"
   238   define Nf where "Nf = ?N f f' x"
   239   define Ng where [abs_def]: "Ng y = ?N g g' (f x) (f y)" for y
   240 
   241   show ?thesis
   242   proof (rule has_derivativeI_sandwich[of 1])
   243     show "bounded_linear (\<lambda>x. g' (f' x))"
   244       using f g by (blast intro: bounded_linear_compose has_derivative_bounded_linear)
   245   next
   246     fix y::'a assume neq: "y \<noteq> x"
   247     have "?N ?gf ?gf' x y = norm (g' (?D f f' x y) + ?D g g' (f x) (f y)) / norm (y - x)"
   248       by (simp add: G.diff G.add field_simps)
   249     also have "\<dots> \<le> norm (g' (?D f f' x y)) / norm (y - x) + Ng y * (norm (f y - f x) / norm (y - x))"
   250       by (simp add: add_divide_distrib[symmetric] divide_right_mono norm_triangle_ineq G.zero Ng_def)
   251     also have "\<dots> \<le> Nf y * kG + Ng y * (Nf y + kF)"
   252     proof (intro add_mono mult_left_mono)
   253       have "norm (f y - f x) = norm (?D f f' x y + f' (y - x))"
   254         by simp
   255       also have "\<dots> \<le> norm (?D f f' x y) + norm (f' (y - x))"
   256         by (rule norm_triangle_ineq)
   257       also have "\<dots> \<le> norm (?D f f' x y) + norm (y - x) * kF"
   258         using kF by (intro add_mono) simp
   259       finally show "norm (f y - f x) / norm (y - x) \<le> Nf y + kF"
   260         by (simp add: neq Nf_def field_simps)
   261     qed (insert kG, simp_all add: Ng_def Nf_def neq zero_le_divide_iff field_simps)
   262     finally show "?N ?gf ?gf' x y \<le> Nf y * kG + Ng y * (Nf y + kF)" .
   263   next
   264     have [tendsto_intros]: "?L Nf"
   265       using f unfolding has_derivative_iff_norm Nf_def ..
   266     from f have "(f \<longlongrightarrow> f x) (at x within s)"
   267       by (blast intro: has_derivative_continuous continuous_within[THEN iffD1])
   268     then have f': "LIM x at x within s. f x :> inf (nhds (f x)) (principal (f`s))"
   269       unfolding filterlim_def
   270       by (simp add: eventually_filtermap eventually_at_filter le_principal)
   271 
   272     have "((?N g  g' (f x)) \<longlongrightarrow> 0) (at (f x) within f`s)"
   273       using g unfolding has_derivative_iff_norm ..
   274     then have g': "((?N g  g' (f x)) \<longlongrightarrow> 0) (inf (nhds (f x)) (principal (f`s)))"
   275       by (rule tendsto_at_iff_tendsto_nhds_within[THEN iffD1, rotated]) simp
   276 
   277     have [tendsto_intros]: "?L Ng"
   278       unfolding Ng_def by (rule filterlim_compose[OF g' f'])
   279     show "((\<lambda>y. Nf y * kG + Ng y * (Nf y + kF)) \<longlongrightarrow> 0) (at x within s)"
   280       by (intro tendsto_eq_intros) auto
   281   qed simp
   282 qed
   283 
   284 lemma has_derivative_compose:
   285   "(f has_derivative f') (at x within s) \<Longrightarrow> (g has_derivative g') (at (f x)) \<Longrightarrow>
   286   ((\<lambda>x. g (f x)) has_derivative (\<lambda>x. g' (f' x))) (at x within s)"
   287   by (blast intro: has_derivative_in_compose has_derivative_subset)
   288 
   289 lemma (in bounded_bilinear) FDERIV:
   290   assumes f: "(f has_derivative f') (at x within s)" and g: "(g has_derivative g') (at x within s)"
   291   shows "((\<lambda>x. f x ** g x) has_derivative (\<lambda>h. f x ** g' h + f' h ** g x)) (at x within s)"
   292 proof -
   293   from bounded_linear.bounded [OF has_derivative_bounded_linear [OF f]]
   294   obtain KF where norm_F: "\<And>x. norm (f' x) \<le> norm x * KF" by fast
   295 
   296   from pos_bounded obtain K where K: "0 < K" and norm_prod:
   297     "\<And>a b. norm (a ** b) \<le> norm a * norm b * K" by fast
   298   let ?D = "\<lambda>f f' y. f y - f x - f' (y - x)"
   299   let ?N = "\<lambda>f f' y. norm (?D f f' y) / norm (y - x)"
   300   define Ng where "Ng = ?N g g'"
   301   define Nf where "Nf = ?N f f'"
   302 
   303   let ?fun1 = "\<lambda>y. norm (f y ** g y - f x ** g x - (f x ** g' (y - x) + f' (y - x) ** g x)) / norm (y - x)"
   304   let ?fun2 = "\<lambda>y. norm (f x) * Ng y * K + Nf y * norm (g y) * K + KF * norm (g y - g x) * K"
   305   let ?F = "at x within s"
   306 
   307   show ?thesis
   308   proof (rule has_derivativeI_sandwich[of 1])
   309     show "bounded_linear (\<lambda>h. f x ** g' h + f' h ** g x)"
   310       by (intro bounded_linear_add
   311         bounded_linear_compose [OF bounded_linear_right] bounded_linear_compose [OF bounded_linear_left]
   312         has_derivative_bounded_linear [OF g] has_derivative_bounded_linear [OF f])
   313   next
   314     from g have "(g \<longlongrightarrow> g x) ?F"
   315       by (intro continuous_within[THEN iffD1] has_derivative_continuous)
   316     moreover from f g have "(Nf \<longlongrightarrow> 0) ?F" "(Ng \<longlongrightarrow> 0) ?F"
   317       by (simp_all add: has_derivative_iff_norm Ng_def Nf_def)
   318     ultimately have "(?fun2 \<longlongrightarrow> norm (f x) * 0 * K + 0 * norm (g x) * K + KF * norm (0::'b) * K) ?F"
   319       by (intro tendsto_intros) (simp_all add: LIM_zero_iff)
   320     then show "(?fun2 \<longlongrightarrow> 0) ?F"
   321       by simp
   322   next
   323     fix y::'d assume "y \<noteq> x"
   324     have "?fun1 y = norm (f x ** ?D g g' y + ?D f f' y ** g y + f' (y - x) ** (g y - g x)) / norm (y - x)"
   325       by (simp add: diff_left diff_right add_left add_right field_simps)
   326     also have "\<dots> \<le> (norm (f x) * norm (?D g g' y) * K + norm (?D f f' y) * norm (g y) * K +
   327         norm (y - x) * KF * norm (g y - g x) * K) / norm (y - x)"
   328       by (intro divide_right_mono mult_mono'
   329                 order_trans [OF norm_triangle_ineq add_mono]
   330                 order_trans [OF norm_prod mult_right_mono]
   331                 mult_nonneg_nonneg order_refl norm_ge_zero norm_F
   332                 K [THEN order_less_imp_le])
   333     also have "\<dots> = ?fun2 y"
   334       by (simp add: add_divide_distrib Ng_def Nf_def)
   335     finally show "?fun1 y \<le> ?fun2 y" .
   336   qed simp
   337 qed
   338 
   339 lemmas has_derivative_mult[simp, derivative_intros] = bounded_bilinear.FDERIV[OF bounded_bilinear_mult]
   340 lemmas has_derivative_scaleR[simp, derivative_intros] = bounded_bilinear.FDERIV[OF bounded_bilinear_scaleR]
   341 
   342 lemma has_derivative_setprod[simp, derivative_intros]:
   343   fixes f :: "'i \<Rightarrow> 'a :: real_normed_vector \<Rightarrow> 'b :: real_normed_field"
   344   assumes f: "\<And>i. i \<in> I \<Longrightarrow> (f i has_derivative f' i) (at x within s)"
   345   shows "((\<lambda>x. \<Prod>i\<in>I. f i x) has_derivative (\<lambda>y. \<Sum>i\<in>I. f' i y * (\<Prod>j\<in>I - {i}. f j x))) (at x within s)"
   346 proof cases
   347   assume "finite I" from this f show ?thesis
   348   proof induct
   349     case (insert i I)
   350     let ?P = "\<lambda>y. f i x * (\<Sum>i\<in>I. f' i y * (\<Prod>j\<in>I - {i}. f j x)) + (f' i y) * (\<Prod>i\<in>I. f i x)"
   351     have "((\<lambda>x. f i x * (\<Prod>i\<in>I. f i x)) has_derivative ?P) (at x within s)"
   352       using insert by (intro has_derivative_mult) auto
   353     also have "?P = (\<lambda>y. \<Sum>i'\<in>insert i I. f' i' y * (\<Prod>j\<in>insert i I - {i'}. f j x))"
   354       using insert(1,2) by (auto simp add: setsum_right_distrib insert_Diff_if intro!: ext setsum.cong)
   355     finally show ?case
   356       using insert by simp
   357   qed simp  
   358 qed simp
   359 
   360 lemma has_derivative_power[simp, derivative_intros]:
   361   fixes f :: "'a :: real_normed_vector \<Rightarrow> 'b :: real_normed_field"
   362   assumes f: "(f has_derivative f') (at x within s)"
   363   shows "((\<lambda>x. f x^n) has_derivative (\<lambda>y. of_nat n * f' y * f x^(n - 1))) (at x within s)"
   364   using has_derivative_setprod[OF f, of "{..< n}"] by (simp add: setprod_constant ac_simps)
   365 
   366 lemma has_derivative_inverse':
   367   fixes x :: "'a::real_normed_div_algebra"
   368   assumes x: "x \<noteq> 0"
   369   shows "(inverse has_derivative (\<lambda>h. - (inverse x * h * inverse x))) (at x within s)"
   370         (is "(?inv has_derivative ?f) _")
   371 proof (rule has_derivativeI_sandwich)
   372   show "bounded_linear (\<lambda>h. - (?inv x * h * ?inv x))"
   373     apply (rule bounded_linear_minus)
   374     apply (rule bounded_linear_mult_const)
   375     apply (rule bounded_linear_const_mult)
   376     apply (rule bounded_linear_ident)
   377     done
   378 next
   379   show "0 < norm x" using x by simp
   380 next
   381   show "((\<lambda>y. norm (?inv y - ?inv x) * norm (?inv x)) \<longlongrightarrow> 0) (at x within s)"
   382     apply (rule tendsto_mult_left_zero)
   383     apply (rule tendsto_norm_zero)
   384     apply (rule LIM_zero)
   385     apply (rule tendsto_inverse)
   386     apply (rule tendsto_ident_at)
   387     apply (rule x)
   388     done
   389 next
   390   fix y::'a assume h: "y \<noteq> x" "dist y x < norm x"
   391   then have "y \<noteq> 0" by auto
   392   have "norm (?inv y - ?inv x - ?f (y -x)) / norm (y - x) = norm ((?inv y - ?inv x) * (y - x) * ?inv x) / norm (y - x)"
   393     apply (subst inverse_diff_inverse [OF \<open>y \<noteq> 0\<close> x])
   394     apply (subst minus_diff_minus)
   395     apply (subst norm_minus_cancel)
   396     apply (simp add: left_diff_distrib)
   397     done
   398   also have "\<dots> \<le> norm (?inv y - ?inv x) * norm (y - x) * norm (?inv x) / norm (y - x)"
   399     apply (rule divide_right_mono [OF _ norm_ge_zero])
   400     apply (rule order_trans [OF norm_mult_ineq])
   401     apply (rule mult_right_mono [OF _ norm_ge_zero])
   402     apply (rule norm_mult_ineq)
   403     done
   404   also have "\<dots> = norm (?inv y - ?inv x) * norm (?inv x)"
   405     by simp
   406   finally show "norm (?inv y - ?inv x - ?f (y -x)) / norm (y - x) \<le>
   407       norm (?inv y - ?inv x) * norm (?inv x)" .
   408 qed
   409 
   410 lemma has_derivative_inverse[simp, derivative_intros]:
   411   fixes f :: "_ \<Rightarrow> 'a::real_normed_div_algebra"
   412   assumes x:  "f x \<noteq> 0" and f: "(f has_derivative f') (at x within s)"
   413   shows "((\<lambda>x. inverse (f x)) has_derivative (\<lambda>h. - (inverse (f x) * f' h * inverse (f x)))) (at x within s)"
   414   using has_derivative_compose[OF f has_derivative_inverse', OF x] .
   415 
   416 lemma has_derivative_divide[simp, derivative_intros]:
   417   fixes f :: "_ \<Rightarrow> 'a::real_normed_div_algebra"
   418   assumes f: "(f has_derivative f') (at x within s)" and g: "(g has_derivative g') (at x within s)" 
   419   assumes x: "g x \<noteq> 0"
   420   shows "((\<lambda>x. f x / g x) has_derivative
   421                 (\<lambda>h. - f x * (inverse (g x) * g' h * inverse (g x)) + f' h / g x)) (at x within s)"
   422   using has_derivative_mult[OF f has_derivative_inverse[OF x g]]
   423   by (simp add: field_simps)
   424 
   425 text\<open>Conventional form requires mult-AC laws. Types real and complex only.\<close>
   426 
   427 lemma has_derivative_divide'[derivative_intros]: 
   428   fixes f :: "_ \<Rightarrow> 'a::real_normed_field"
   429   assumes f: "(f has_derivative f') (at x within s)" and g: "(g has_derivative g') (at x within s)" and x: "g x \<noteq> 0"
   430   shows "((\<lambda>x. f x / g x) has_derivative (\<lambda>h. (f' h * g x - f x * g' h) / (g x * g x))) (at x within s)"
   431 proof -
   432   { fix h
   433     have "f' h / g x - f x * (inverse (g x) * g' h * inverse (g x)) =
   434           (f' h * g x - f x * g' h) / (g x * g x)"
   435       by (simp add: field_simps x)
   436    }
   437   then show ?thesis
   438     using has_derivative_divide [OF f g] x
   439     by simp
   440 qed
   441 
   442 subsection \<open>Uniqueness\<close>
   443 
   444 text \<open>
   445 
   446 This can not generally shown for @{const has_derivative}, as we need to approach the point from
   447 all directions. There is a proof in \<open>Multivariate_Analysis\<close> for \<open>euclidean_space\<close>.
   448 
   449 \<close>
   450 
   451 lemma has_derivative_zero_unique:
   452   assumes "((\<lambda>x. 0) has_derivative F) (at x)" shows "F = (\<lambda>h. 0)"
   453 proof -
   454   interpret F: bounded_linear F
   455     using assms by (rule has_derivative_bounded_linear)
   456   let ?r = "\<lambda>h. norm (F h) / norm h"
   457   have *: "?r \<midarrow>0\<rightarrow> 0"
   458     using assms unfolding has_derivative_at by simp
   459   show "F = (\<lambda>h. 0)"
   460   proof
   461     fix h show "F h = 0"
   462     proof (rule ccontr)
   463       assume **: "F h \<noteq> 0"
   464       hence h: "h \<noteq> 0" by (clarsimp simp add: F.zero)
   465       with ** have "0 < ?r h" by simp
   466       from LIM_D [OF * this] obtain s where s: "0 < s"
   467         and r: "\<And>x. x \<noteq> 0 \<Longrightarrow> norm x < s \<Longrightarrow> ?r x < ?r h" by auto
   468       from dense [OF s] obtain t where t: "0 < t \<and> t < s" ..
   469       let ?x = "scaleR (t / norm h) h"
   470       have "?x \<noteq> 0" and "norm ?x < s" using t h by simp_all
   471       hence "?r ?x < ?r h" by (rule r)
   472       thus "False" using t h by (simp add: F.scaleR)
   473     qed
   474   qed
   475 qed
   476 
   477 lemma has_derivative_unique:
   478   assumes "(f has_derivative F) (at x)" and "(f has_derivative F') (at x)" shows "F = F'"
   479 proof -
   480   have "((\<lambda>x. 0) has_derivative (\<lambda>h. F h - F' h)) (at x)"
   481     using has_derivative_diff [OF assms] by simp
   482   hence "(\<lambda>h. F h - F' h) = (\<lambda>h. 0)"
   483     by (rule has_derivative_zero_unique)
   484   thus "F = F'"
   485     unfolding fun_eq_iff right_minus_eq .
   486 qed
   487 
   488 subsection \<open>Differentiability predicate\<close>
   489 
   490 definition
   491   differentiable :: "('a::real_normed_vector \<Rightarrow> 'b::real_normed_vector) \<Rightarrow> 'a filter \<Rightarrow> bool"
   492   (infix "differentiable" 50)
   493 where
   494   "f differentiable F \<longleftrightarrow> (\<exists>D. (f has_derivative D) F)"
   495 
   496 lemma differentiable_subset: "f differentiable (at x within s) \<Longrightarrow> t \<subseteq> s \<Longrightarrow> f differentiable (at x within t)"
   497   unfolding differentiable_def by (blast intro: has_derivative_subset)
   498 
   499 lemmas differentiable_within_subset = differentiable_subset
   500 
   501 lemma differentiable_ident [simp, derivative_intros]: "(\<lambda>x. x) differentiable F"
   502   unfolding differentiable_def by (blast intro: has_derivative_ident)
   503 
   504 lemma differentiable_const [simp, derivative_intros]: "(\<lambda>z. a) differentiable F"
   505   unfolding differentiable_def by (blast intro: has_derivative_const)
   506 
   507 lemma differentiable_in_compose:
   508   "f differentiable (at (g x) within (g`s)) \<Longrightarrow> g differentiable (at x within s) \<Longrightarrow> (\<lambda>x. f (g x)) differentiable (at x within s)"
   509   unfolding differentiable_def by (blast intro: has_derivative_in_compose)
   510 
   511 lemma differentiable_compose:
   512   "f differentiable (at (g x)) \<Longrightarrow> g differentiable (at x within s) \<Longrightarrow> (\<lambda>x. f (g x)) differentiable (at x within s)"
   513   by (blast intro: differentiable_in_compose differentiable_subset)
   514 
   515 lemma differentiable_sum [simp, derivative_intros]:
   516   "f differentiable F \<Longrightarrow> g differentiable F \<Longrightarrow> (\<lambda>x. f x + g x) differentiable F"
   517   unfolding differentiable_def by (blast intro: has_derivative_add)
   518 
   519 lemma differentiable_minus [simp, derivative_intros]:
   520   "f differentiable F \<Longrightarrow> (\<lambda>x. - f x) differentiable F"
   521   unfolding differentiable_def by (blast intro: has_derivative_minus)
   522 
   523 lemma differentiable_diff [simp, derivative_intros]:
   524   "f differentiable F \<Longrightarrow> g differentiable F \<Longrightarrow> (\<lambda>x. f x - g x) differentiable F"
   525   unfolding differentiable_def by (blast intro: has_derivative_diff)
   526 
   527 lemma differentiable_mult [simp, derivative_intros]:
   528   fixes f g :: "'a :: real_normed_vector \<Rightarrow> 'b :: real_normed_algebra"
   529   shows "f differentiable (at x within s) \<Longrightarrow> g differentiable (at x within s) \<Longrightarrow> (\<lambda>x. f x * g x) differentiable (at x within s)"
   530   unfolding differentiable_def by (blast intro: has_derivative_mult)
   531 
   532 lemma differentiable_inverse [simp, derivative_intros]:
   533   fixes f :: "'a :: real_normed_vector \<Rightarrow> 'b :: real_normed_field"
   534   shows "f differentiable (at x within s) \<Longrightarrow> f x \<noteq> 0 \<Longrightarrow> (\<lambda>x. inverse (f x)) differentiable (at x within s)"
   535   unfolding differentiable_def by (blast intro: has_derivative_inverse)
   536 
   537 lemma differentiable_divide [simp, derivative_intros]:
   538   fixes f g :: "'a :: real_normed_vector \<Rightarrow> 'b :: real_normed_field"
   539   shows "f differentiable (at x within s) \<Longrightarrow> g differentiable (at x within s) \<Longrightarrow> g x \<noteq> 0 \<Longrightarrow> (\<lambda>x. f x / g x) differentiable (at x within s)"
   540   unfolding divide_inverse by simp
   541 
   542 lemma differentiable_power [simp, derivative_intros]:
   543   fixes f g :: "'a :: real_normed_vector \<Rightarrow> 'b :: real_normed_field"
   544   shows "f differentiable (at x within s) \<Longrightarrow> (\<lambda>x. f x ^ n) differentiable (at x within s)"
   545   unfolding differentiable_def by (blast intro: has_derivative_power)
   546 
   547 lemma differentiable_scaleR [simp, derivative_intros]:
   548   "f differentiable (at x within s) \<Longrightarrow> g differentiable (at x within s) \<Longrightarrow> (\<lambda>x. f x *\<^sub>R g x) differentiable (at x within s)"
   549   unfolding differentiable_def by (blast intro: has_derivative_scaleR)
   550 
   551 lemma has_derivative_imp_has_field_derivative:
   552   "(f has_derivative D) F \<Longrightarrow> (\<And>x. x * D' = D x) \<Longrightarrow> (f has_field_derivative D') F"
   553   unfolding has_field_derivative_def 
   554   by (rule has_derivative_eq_rhs[of f D]) (simp_all add: fun_eq_iff mult.commute)
   555 
   556 lemma has_field_derivative_imp_has_derivative: "(f has_field_derivative D) F \<Longrightarrow> (f has_derivative op * D) F"
   557   by (simp add: has_field_derivative_def)
   558 
   559 lemma DERIV_subset: 
   560   "(f has_field_derivative f') (at x within s) \<Longrightarrow> t \<subseteq> s 
   561    \<Longrightarrow> (f has_field_derivative f') (at x within t)"
   562   by (simp add: has_field_derivative_def has_derivative_within_subset)
   563 
   564 lemma has_field_derivative_at_within:
   565     "(f has_field_derivative f') (at x) \<Longrightarrow> (f has_field_derivative f') (at x within s)"
   566   using DERIV_subset by blast
   567 
   568 abbreviation (input)
   569   DERIV :: "('a::real_normed_field \<Rightarrow> 'a) \<Rightarrow> 'a \<Rightarrow> 'a \<Rightarrow> bool"
   570   ("(DERIV (_)/ (_)/ :> (_))" [1000, 1000, 60] 60)
   571 where
   572   "DERIV f x :> D \<equiv> (f has_field_derivative D) (at x)"
   573 
   574 abbreviation 
   575   has_real_derivative :: "(real \<Rightarrow> real) \<Rightarrow> real \<Rightarrow> real filter \<Rightarrow> bool"
   576   (infix "(has'_real'_derivative)" 50)
   577 where
   578   "(f has_real_derivative D) F \<equiv> (f has_field_derivative D) F"
   579 
   580 lemma real_differentiable_def:
   581   "f differentiable at x within s \<longleftrightarrow> (\<exists>D. (f has_real_derivative D) (at x within s))"
   582 proof safe
   583   assume "f differentiable at x within s"
   584   then obtain f' where *: "(f has_derivative f') (at x within s)"
   585     unfolding differentiable_def by auto
   586   then obtain c where "f' = (op * c)"
   587     by (metis real_bounded_linear has_derivative_bounded_linear mult.commute fun_eq_iff)
   588   with * show "\<exists>D. (f has_real_derivative D) (at x within s)"
   589     unfolding has_field_derivative_def by auto
   590 qed (auto simp: differentiable_def has_field_derivative_def)
   591 
   592 lemma real_differentiableE [elim?]:
   593   assumes f: "f differentiable (at x within s)" obtains df where "(f has_real_derivative df) (at x within s)"
   594   using assms by (auto simp: real_differentiable_def)
   595 
   596 lemma differentiableD: "f differentiable (at x within s) \<Longrightarrow> \<exists>D. (f has_real_derivative D) (at x within s)"
   597   by (auto elim: real_differentiableE)
   598 
   599 lemma differentiableI: "(f has_real_derivative D) (at x within s) \<Longrightarrow> f differentiable (at x within s)"
   600   by (force simp add: real_differentiable_def)
   601 
   602 lemma has_field_derivative_iff:
   603   "(f has_field_derivative D) (at x within S) \<longleftrightarrow>
   604     ((\<lambda>y. (f y - f x) / (y - x)) \<longlongrightarrow> D) (at x within S)"
   605   apply (simp add: has_field_derivative_def has_derivative_iff_norm bounded_linear_mult_right
   606     LIM_zero_iff[symmetric, of _ D])
   607   apply (subst (2) tendsto_norm_zero_iff[symmetric])
   608   apply (rule filterlim_cong)
   609   apply (simp_all add: eventually_at_filter field_simps nonzero_norm_divide)
   610   done
   611 
   612 lemma DERIV_def: "DERIV f x :> D \<longleftrightarrow> (\<lambda>h. (f (x + h) - f x) / h) \<midarrow>0\<rightarrow> D"
   613   unfolding field_has_derivative_at has_field_derivative_def has_field_derivative_iff ..
   614 
   615 lemma mult_commute_abs: "(\<lambda>x. x * c) = op * (c::'a::ab_semigroup_mult)"
   616   by (simp add: fun_eq_iff mult.commute)
   617 
   618 subsection \<open>Vector derivative\<close>
   619 
   620 lemma has_field_derivative_iff_has_vector_derivative:
   621   "(f has_field_derivative y) F \<longleftrightarrow> (f has_vector_derivative y) F"
   622   unfolding has_vector_derivative_def has_field_derivative_def real_scaleR_def mult_commute_abs ..
   623 
   624 lemma has_field_derivative_subset:
   625   "(f has_field_derivative y) (at x within s) \<Longrightarrow> t \<subseteq> s \<Longrightarrow> (f has_field_derivative y) (at x within t)"
   626   unfolding has_field_derivative_def by (rule has_derivative_subset)
   627 
   628 lemma has_vector_derivative_const[simp, derivative_intros]: "((\<lambda>x. c) has_vector_derivative 0) net"
   629   by (auto simp: has_vector_derivative_def)
   630 
   631 lemma has_vector_derivative_id[simp, derivative_intros]: "((\<lambda>x. x) has_vector_derivative 1) net"
   632   by (auto simp: has_vector_derivative_def)
   633 
   634 lemma has_vector_derivative_minus[derivative_intros]:
   635   "(f has_vector_derivative f') net \<Longrightarrow> ((\<lambda>x. - f x) has_vector_derivative (- f')) net"
   636   by (auto simp: has_vector_derivative_def)
   637 
   638 lemma has_vector_derivative_add[derivative_intros]:
   639   "(f has_vector_derivative f') net \<Longrightarrow> (g has_vector_derivative g') net \<Longrightarrow>
   640     ((\<lambda>x. f x + g x) has_vector_derivative (f' + g')) net"
   641   by (auto simp: has_vector_derivative_def scaleR_right_distrib)
   642 
   643 lemma has_vector_derivative_setsum[derivative_intros]:
   644   "(\<And>i. i \<in> I \<Longrightarrow> (f i has_vector_derivative f' i) net) \<Longrightarrow>
   645     ((\<lambda>x. \<Sum>i\<in>I. f i x) has_vector_derivative (\<Sum>i\<in>I. f' i)) net"
   646   by (auto simp: has_vector_derivative_def fun_eq_iff scaleR_setsum_right intro!: derivative_eq_intros)
   647 
   648 lemma has_vector_derivative_diff[derivative_intros]:
   649   "(f has_vector_derivative f') net \<Longrightarrow> (g has_vector_derivative g') net \<Longrightarrow>
   650     ((\<lambda>x. f x - g x) has_vector_derivative (f' - g')) net"
   651   by (auto simp: has_vector_derivative_def scaleR_diff_right)
   652 
   653 lemma has_vector_derivative_add_const:
   654      "((\<lambda>t. g t + z) has_vector_derivative f') net = ((\<lambda>t. g t) has_vector_derivative f') net"
   655 apply (intro iffI)
   656 apply (drule has_vector_derivative_diff [where g = "\<lambda>t. z", OF _ has_vector_derivative_const], simp)
   657 apply (drule has_vector_derivative_add [OF _ has_vector_derivative_const], simp)
   658 done
   659 
   660 lemma has_vector_derivative_diff_const:
   661      "((\<lambda>t. g t - z) has_vector_derivative f') net = ((\<lambda>t. g t) has_vector_derivative f') net"
   662 using has_vector_derivative_add_const [where z = "-z"]
   663 by simp
   664 
   665 lemma (in bounded_linear) has_vector_derivative:
   666   assumes "(g has_vector_derivative g') F"
   667   shows "((\<lambda>x. f (g x)) has_vector_derivative f g') F"
   668   using has_derivative[OF assms[unfolded has_vector_derivative_def]]
   669   by (simp add: has_vector_derivative_def scaleR)
   670 
   671 lemma (in bounded_bilinear) has_vector_derivative:
   672   assumes "(f has_vector_derivative f') (at x within s)"
   673     and "(g has_vector_derivative g') (at x within s)"
   674   shows "((\<lambda>x. f x ** g x) has_vector_derivative (f x ** g' + f' ** g x)) (at x within s)"
   675   using FDERIV[OF assms(1-2)[unfolded has_vector_derivative_def]]
   676   by (simp add: has_vector_derivative_def scaleR_right scaleR_left scaleR_right_distrib)
   677 
   678 lemma has_vector_derivative_scaleR[derivative_intros]:
   679   "(f has_field_derivative f') (at x within s) \<Longrightarrow> (g has_vector_derivative g') (at x within s) \<Longrightarrow>
   680     ((\<lambda>x. f x *\<^sub>R g x) has_vector_derivative (f x *\<^sub>R g' + f' *\<^sub>R g x)) (at x within s)"
   681   unfolding has_field_derivative_iff_has_vector_derivative
   682   by (rule bounded_bilinear.has_vector_derivative[OF bounded_bilinear_scaleR])
   683 
   684 lemma has_vector_derivative_mult[derivative_intros]:
   685   "(f has_vector_derivative f') (at x within s) \<Longrightarrow> (g has_vector_derivative g') (at x within s) \<Longrightarrow>
   686     ((\<lambda>x. f x * g x) has_vector_derivative (f x * g' + f' * g x :: 'a :: real_normed_algebra)) (at x within s)"
   687   by (rule bounded_bilinear.has_vector_derivative[OF bounded_bilinear_mult])
   688 
   689 lemma has_vector_derivative_of_real[derivative_intros]:
   690   "(f has_field_derivative D) F \<Longrightarrow> ((\<lambda>x. of_real (f x)) has_vector_derivative (of_real D)) F"
   691   by (rule bounded_linear.has_vector_derivative[OF bounded_linear_of_real])
   692      (simp add: has_field_derivative_iff_has_vector_derivative)
   693 
   694 lemma has_vector_derivative_continuous: "(f has_vector_derivative D) (at x within s) \<Longrightarrow> continuous (at x within s) f"
   695   by (auto intro: has_derivative_continuous simp: has_vector_derivative_def)
   696 
   697 lemma has_vector_derivative_mult_right[derivative_intros]:
   698   fixes a :: "'a :: real_normed_algebra"
   699   shows "(f has_vector_derivative x) F \<Longrightarrow> ((\<lambda>x. a * f x) has_vector_derivative (a * x)) F"
   700   by (rule bounded_linear.has_vector_derivative[OF bounded_linear_mult_right])
   701 
   702 lemma has_vector_derivative_mult_left[derivative_intros]:
   703   fixes a :: "'a :: real_normed_algebra"
   704   shows "(f has_vector_derivative x) F \<Longrightarrow> ((\<lambda>x. f x * a) has_vector_derivative (x * a)) F"
   705   by (rule bounded_linear.has_vector_derivative[OF bounded_linear_mult_left])
   706 
   707 
   708 subsection \<open>Derivatives\<close>
   709 
   710 lemma DERIV_D: "DERIV f x :> D \<Longrightarrow> (\<lambda>h. (f (x + h) - f x) / h) \<midarrow>0\<rightarrow> D"
   711   by (simp add: DERIV_def)
   712 
   713 lemma has_field_derivativeD:
   714   "(f has_field_derivative D) (at x within S) \<Longrightarrow>
   715     ((\<lambda>y. (f y - f x) / (y - x)) \<longlongrightarrow> D) (at x within S)"
   716   by (simp add: has_field_derivative_iff)
   717 
   718 lemma DERIV_const [simp, derivative_intros]: "((\<lambda>x. k) has_field_derivative 0) F"
   719   by (rule has_derivative_imp_has_field_derivative[OF has_derivative_const]) auto
   720 
   721 lemma DERIV_ident [simp, derivative_intros]: "((\<lambda>x. x) has_field_derivative 1) F"
   722   by (rule has_derivative_imp_has_field_derivative[OF has_derivative_ident]) auto
   723 
   724 lemma field_differentiable_add[derivative_intros]:
   725   "(f has_field_derivative f') F \<Longrightarrow> (g has_field_derivative g') F \<Longrightarrow> 
   726     ((\<lambda>z. f z + g z) has_field_derivative f' + g') F"
   727   by (rule has_derivative_imp_has_field_derivative[OF has_derivative_add])
   728      (auto simp: has_field_derivative_def field_simps mult_commute_abs)
   729 
   730 corollary DERIV_add:
   731   "(f has_field_derivative D) (at x within s) \<Longrightarrow> (g has_field_derivative E) (at x within s) \<Longrightarrow>
   732   ((\<lambda>x. f x + g x) has_field_derivative D + E) (at x within s)"
   733   by (rule field_differentiable_add)
   734 
   735 lemma field_differentiable_minus[derivative_intros]:
   736   "(f has_field_derivative f') F \<Longrightarrow> ((\<lambda>z. - (f z)) has_field_derivative -f') F"
   737   by (rule has_derivative_imp_has_field_derivative[OF has_derivative_minus])
   738      (auto simp: has_field_derivative_def field_simps mult_commute_abs)
   739 
   740 corollary DERIV_minus: "(f has_field_derivative D) (at x within s) \<Longrightarrow> ((\<lambda>x. - f x) has_field_derivative -D) (at x within s)"
   741   by (rule field_differentiable_minus)
   742 
   743 lemma field_differentiable_diff[derivative_intros]:
   744   "(f has_field_derivative f') F \<Longrightarrow> (g has_field_derivative g') F \<Longrightarrow> ((\<lambda>z. f z - g z) has_field_derivative f' - g') F"
   745   by (simp only: diff_conv_add_uminus field_differentiable_add field_differentiable_minus)
   746 
   747 corollary DERIV_diff:
   748   "(f has_field_derivative D) (at x within s) \<Longrightarrow> (g has_field_derivative E) (at x within s) \<Longrightarrow>
   749   ((\<lambda>x. f x - g x) has_field_derivative D - E) (at x within s)"
   750   by (rule field_differentiable_diff)
   751 
   752 lemma DERIV_continuous: "(f has_field_derivative D) (at x within s) \<Longrightarrow> continuous (at x within s) f"
   753   by (drule has_derivative_continuous[OF has_field_derivative_imp_has_derivative]) simp
   754 
   755 corollary DERIV_isCont: "DERIV f x :> D \<Longrightarrow> isCont f x"
   756   by (rule DERIV_continuous)
   757 
   758 lemma DERIV_continuous_on:
   759   "(\<And>x. x \<in> s \<Longrightarrow> (f has_field_derivative (D x)) (at x)) \<Longrightarrow> continuous_on s f"
   760   by (metis DERIV_continuous continuous_at_imp_continuous_on)
   761 
   762 lemma DERIV_mult':
   763   "(f has_field_derivative D) (at x within s) \<Longrightarrow> (g has_field_derivative E) (at x within s) \<Longrightarrow>
   764   ((\<lambda>x. f x * g x) has_field_derivative f x * E + D * g x) (at x within s)"
   765   by (rule has_derivative_imp_has_field_derivative[OF has_derivative_mult])
   766      (auto simp: field_simps mult_commute_abs dest: has_field_derivative_imp_has_derivative)
   767 
   768 lemma DERIV_mult[derivative_intros]:
   769   "(f has_field_derivative Da) (at x within s) \<Longrightarrow> (g has_field_derivative Db) (at x within s) \<Longrightarrow>
   770   ((\<lambda>x. f x * g x) has_field_derivative Da * g x + Db * f x) (at x within s)"
   771   by (rule has_derivative_imp_has_field_derivative[OF has_derivative_mult])
   772      (auto simp: field_simps dest: has_field_derivative_imp_has_derivative)
   773 
   774 text \<open>Derivative of linear multiplication\<close>
   775 
   776 lemma DERIV_cmult:
   777   "(f has_field_derivative D) (at x within s) ==> ((\<lambda>x. c * f x) has_field_derivative c * D) (at x within s)"
   778   by (drule DERIV_mult' [OF DERIV_const], simp)
   779 
   780 lemma DERIV_cmult_right:
   781   "(f has_field_derivative D) (at x within s) ==> ((\<lambda>x. f x * c) has_field_derivative D * c) (at x within s)"
   782   using DERIV_cmult by (force simp add: ac_simps)
   783 
   784 lemma DERIV_cmult_Id [simp]: "(op * c has_field_derivative c) (at x within s)"
   785   by (cut_tac c = c and x = x in DERIV_ident [THEN DERIV_cmult], simp)
   786 
   787 lemma DERIV_cdivide:
   788   "(f has_field_derivative D) (at x within s) \<Longrightarrow> ((\<lambda>x. f x / c) has_field_derivative D / c) (at x within s)"
   789   using DERIV_cmult_right[of f D x s "1 / c"] by simp
   790 
   791 lemma DERIV_unique:
   792   "DERIV f x :> D \<Longrightarrow> DERIV f x :> E \<Longrightarrow> D = E"
   793   unfolding DERIV_def by (rule LIM_unique) 
   794 
   795 lemma DERIV_setsum[derivative_intros]:
   796   "(\<And> n. n \<in> S \<Longrightarrow> ((\<lambda>x. f x n) has_field_derivative (f' x n)) F) \<Longrightarrow> 
   797     ((\<lambda>x. setsum (f x) S) has_field_derivative setsum (f' x) S) F"
   798   by (rule has_derivative_imp_has_field_derivative[OF has_derivative_setsum])
   799      (auto simp: setsum_right_distrib mult_commute_abs dest: has_field_derivative_imp_has_derivative)
   800 
   801 lemma DERIV_inverse'[derivative_intros]:
   802   assumes "(f has_field_derivative D) (at x within s)"
   803     and "f x \<noteq> 0"
   804   shows "((\<lambda>x. inverse (f x)) has_field_derivative - (inverse (f x) * D * inverse (f x))) (at x within s)"
   805 proof -
   806   have "(f has_derivative (\<lambda>x. x * D)) = (f has_derivative op * D)"
   807     by (rule arg_cong [of "\<lambda>x. x * D"]) (simp add: fun_eq_iff)
   808   with assms have "(f has_derivative (\<lambda>x. x * D)) (at x within s)"
   809     by (auto dest!: has_field_derivative_imp_has_derivative)
   810   then show ?thesis using \<open>f x \<noteq> 0\<close>
   811     by (auto intro: has_derivative_imp_has_field_derivative has_derivative_inverse)
   812 qed
   813 
   814 text \<open>Power of \<open>-1\<close>\<close>
   815 
   816 lemma DERIV_inverse:
   817   "x \<noteq> 0 \<Longrightarrow> ((\<lambda>x. inverse(x)) has_field_derivative - (inverse x ^ Suc (Suc 0))) (at x within s)"
   818   by (drule DERIV_inverse' [OF DERIV_ident]) simp
   819 
   820 text \<open>Derivative of inverse\<close>
   821 
   822 lemma DERIV_inverse_fun:
   823   "(f has_field_derivative d) (at x within s) \<Longrightarrow> f x \<noteq> 0 \<Longrightarrow>
   824   ((\<lambda>x. inverse (f x)) has_field_derivative (- (d * inverse(f x ^ Suc (Suc 0))))) (at x within s)"
   825   by (drule (1) DERIV_inverse') (simp add: ac_simps nonzero_inverse_mult_distrib)
   826 
   827 text \<open>Derivative of quotient\<close>
   828 
   829 lemma DERIV_divide[derivative_intros]:
   830   "(f has_field_derivative D) (at x within s) \<Longrightarrow>
   831   (g has_field_derivative E) (at x within s) \<Longrightarrow> g x \<noteq> 0 \<Longrightarrow>
   832   ((\<lambda>x. f x / g x) has_field_derivative (D * g x - f x * E) / (g x * g x)) (at x within s)"
   833   by (rule has_derivative_imp_has_field_derivative[OF has_derivative_divide])
   834      (auto dest: has_field_derivative_imp_has_derivative simp: field_simps)
   835 
   836 lemma DERIV_quotient:
   837   "(f has_field_derivative d) (at x within s) \<Longrightarrow>
   838   (g has_field_derivative e) (at x within s)\<Longrightarrow> g x \<noteq> 0 \<Longrightarrow> 
   839   ((\<lambda>y. f y / g y) has_field_derivative (d * g x - (e * f x)) / (g x ^ Suc (Suc 0))) (at x within s)"
   840   by (drule (2) DERIV_divide) (simp add: mult.commute)
   841 
   842 lemma DERIV_power_Suc:
   843   "(f has_field_derivative D) (at x within s) \<Longrightarrow>
   844   ((\<lambda>x. f x ^ Suc n) has_field_derivative (1 + of_nat n) * (D * f x ^ n)) (at x within s)"
   845   by (rule has_derivative_imp_has_field_derivative[OF has_derivative_power])
   846      (auto simp: has_field_derivative_def)
   847 
   848 lemma DERIV_power[derivative_intros]:
   849   "(f has_field_derivative D) (at x within s) \<Longrightarrow>
   850   ((\<lambda>x. f x ^ n) has_field_derivative of_nat n * (D * f x ^ (n - Suc 0))) (at x within s)"
   851   by (rule has_derivative_imp_has_field_derivative[OF has_derivative_power])
   852      (auto simp: has_field_derivative_def)
   853 
   854 lemma DERIV_pow: "((\<lambda>x. x ^ n) has_field_derivative real n * (x ^ (n - Suc 0))) (at x within s)"
   855   using DERIV_power [OF DERIV_ident] by simp
   856 
   857 lemma DERIV_chain': "(f has_field_derivative D) (at x within s) \<Longrightarrow> DERIV g (f x) :> E \<Longrightarrow> 
   858   ((\<lambda>x. g (f x)) has_field_derivative E * D) (at x within s)"
   859   using has_derivative_compose[of f "op * D" x s g "op * E"]
   860   unfolding has_field_derivative_def mult_commute_abs ac_simps .
   861 
   862 corollary DERIV_chain2: "DERIV f (g x) :> Da \<Longrightarrow> (g has_field_derivative Db) (at x within s) \<Longrightarrow>
   863   ((\<lambda>x. f (g x)) has_field_derivative Da * Db) (at x within s)"
   864   by (rule DERIV_chain')
   865 
   866 text \<open>Standard version\<close>
   867 
   868 lemma DERIV_chain:
   869   "DERIV f (g x) :> Da \<Longrightarrow> (g has_field_derivative Db) (at x within s) \<Longrightarrow> 
   870   (f o g has_field_derivative Da * Db) (at x within s)"
   871   by (drule (1) DERIV_chain', simp add: o_def mult.commute)
   872 
   873 lemma DERIV_image_chain: 
   874   "(f has_field_derivative Da) (at (g x) within (g ` s)) \<Longrightarrow> (g has_field_derivative Db) (at x within s) \<Longrightarrow>
   875   (f o g has_field_derivative Da * Db) (at x within s)"
   876   using has_derivative_in_compose [of g "op * Db" x s f "op * Da "]
   877   by (simp add: has_field_derivative_def o_def mult_commute_abs ac_simps)
   878 
   879 (*These two are from HOL Light: HAS_COMPLEX_DERIVATIVE_CHAIN*)
   880 lemma DERIV_chain_s:
   881   assumes "(\<And>x. x \<in> s \<Longrightarrow> DERIV g x :> g'(x))"
   882       and "DERIV f x :> f'" 
   883       and "f x \<in> s"
   884     shows "DERIV (\<lambda>x. g(f x)) x :> f' * g'(f x)"
   885   by (metis (full_types) DERIV_chain' mult.commute assms)
   886 
   887 lemma DERIV_chain3: (*HAS_COMPLEX_DERIVATIVE_CHAIN_UNIV*)
   888   assumes "(\<And>x. DERIV g x :> g'(x))"
   889       and "DERIV f x :> f'" 
   890     shows "DERIV (\<lambda>x. g(f x)) x :> f' * g'(f x)"
   891   by (metis UNIV_I DERIV_chain_s [of UNIV] assms)
   892 
   893 text\<open>Alternative definition for differentiability\<close>
   894 
   895 lemma DERIV_LIM_iff:
   896   fixes f :: "'a::{real_normed_vector,inverse} \<Rightarrow> 'a" shows
   897      "((%h. (f(a + h) - f(a)) / h) \<midarrow>0\<rightarrow> D) =
   898       ((%x. (f(x)-f(a)) / (x-a)) \<midarrow>a\<rightarrow> D)"
   899 apply (rule iffI)
   900 apply (drule_tac k="- a" in LIM_offset)
   901 apply simp
   902 apply (drule_tac k="a" in LIM_offset)
   903 apply (simp add: add.commute)
   904 done
   905 
   906 lemmas DERIV_iff2 = has_field_derivative_iff
   907 
   908 lemma has_field_derivative_cong_ev:
   909   assumes "x = y"
   910     and *: "eventually (\<lambda>x. x \<in> s \<longrightarrow> f x = g x) (nhds x)"
   911     and "u = v" "s = t" "x \<in> s"
   912     shows "(f has_field_derivative u) (at x within s) = (g has_field_derivative v) (at y within t)"
   913   unfolding DERIV_iff2
   914 proof (rule filterlim_cong)
   915   from assms have "f y = g y" by (auto simp: eventually_nhds)
   916   with * show "\<forall>\<^sub>F xa in at x within s. (f xa - f x) / (xa - x) = (g xa - g y) / (xa - y)"
   917     unfolding eventually_at_filter
   918     by eventually_elim (auto simp: assms \<open>f y = g y\<close>)
   919 qed (simp_all add: assms)
   920 
   921 lemma DERIV_cong_ev: "x = y \<Longrightarrow> eventually (\<lambda>x. f x = g x) (nhds x) \<Longrightarrow> u = v \<Longrightarrow>
   922     DERIV f x :> u \<longleftrightarrow> DERIV g y :> v"
   923   by (rule has_field_derivative_cong_ev) simp_all
   924 
   925 lemma DERIV_shift:
   926   "(f has_field_derivative y) (at (x + z)) = ((\<lambda>x. f (x + z)) has_field_derivative y) (at x)"
   927   by (simp add: DERIV_def field_simps)
   928 
   929 lemma DERIV_mirror:
   930   "(DERIV f (- x) :> y) \<longleftrightarrow> (DERIV (\<lambda>x. f (- x::real) :: real) x :> - y)"
   931   by (simp add: DERIV_def filterlim_at_split filterlim_at_left_to_right
   932                 tendsto_minus_cancel_left field_simps conj_commute)
   933 
   934 text \<open>Caratheodory formulation of derivative at a point\<close>
   935 
   936 lemma CARAT_DERIV: (*FIXME: SUPERSEDED BY THE ONE IN Deriv.thy. But still used by NSA/HDeriv.thy*)
   937   "(DERIV f x :> l) \<longleftrightarrow> (\<exists>g. (\<forall>z. f z - f x = g z * (z - x)) \<and> isCont g x \<and> g x = l)"
   938       (is "?lhs = ?rhs")
   939 proof
   940   assume der: "DERIV f x :> l"
   941   show "\<exists>g. (\<forall>z. f z - f x = g z * (z-x)) \<and> isCont g x \<and> g x = l"
   942   proof (intro exI conjI)
   943     let ?g = "(%z. if z = x then l else (f z - f x) / (z-x))"
   944     show "\<forall>z. f z - f x = ?g z * (z-x)" by simp
   945     show "isCont ?g x" using der
   946       by (simp add: isCont_iff DERIV_def cong: LIM_equal [rule_format])
   947     show "?g x = l" by simp
   948   qed
   949 next
   950   assume "?rhs"
   951   then obtain g where
   952     "(\<forall>z. f z - f x = g z * (z-x))" and "isCont g x" and "g x = l" by blast
   953   thus "(DERIV f x :> l)"
   954      by (auto simp add: isCont_iff DERIV_def cong: LIM_cong)
   955 qed
   956 
   957 
   958 subsection \<open>Local extrema\<close>
   959 
   960 text\<open>If @{term "0 < f'(x)"} then @{term x} is Locally Strictly Increasing At The Right\<close>
   961 
   962 lemma has_real_derivative_pos_inc_right:
   963   fixes f :: "real => real"
   964   assumes der: "(f has_real_derivative l) (at x within S)"
   965       and l:   "0 < l"
   966   shows "\<exists>d > 0. \<forall>h > 0. x + h \<in> S \<longrightarrow> h < d \<longrightarrow> f x < f (x + h)"
   967   using assms
   968 proof -
   969   from der [THEN has_field_derivativeD, THEN tendstoD, OF l, unfolded eventually_at]
   970   obtain s where s:   "0 < s"
   971     and all: "\<And>xa. xa\<in>S \<Longrightarrow> xa \<noteq> x \<and> dist xa x < s \<longrightarrow> abs ((f xa - f x) / (xa - x) - l) < l"
   972     by (auto simp: dist_real_def)
   973   then show ?thesis
   974   proof (intro exI conjI strip)
   975     show "0<s" using s .
   976     fix h::real
   977     assume "0 < h" "h < s" "x + h \<in> S"
   978     with all [of "x + h"] show "f x < f (x+h)"
   979     proof (simp add: abs_if dist_real_def pos_less_divide_eq split: if_split_asm)
   980       assume "\<not> (f (x+h) - f x) / h < l" and h: "0 < h"
   981       with l
   982       have "0 < (f (x+h) - f x) / h" by arith
   983       thus "f x < f (x+h)"
   984         by (simp add: pos_less_divide_eq h)
   985     qed
   986   qed
   987 qed
   988 
   989 lemma DERIV_pos_inc_right:
   990   fixes f :: "real => real"
   991   assumes der: "DERIV f x :> l"
   992       and l:   "0 < l"
   993   shows "\<exists>d > 0. \<forall>h > 0. h < d --> f(x) < f(x + h)"
   994   using has_real_derivative_pos_inc_right[OF assms]
   995   by auto
   996 
   997 lemma has_real_derivative_neg_dec_left:
   998   fixes f :: "real => real"
   999   assumes der: "(f has_real_derivative l) (at x within S)"
  1000       and "l < 0"
  1001   shows "\<exists>d > 0. \<forall>h > 0. x - h \<in> S \<longrightarrow> h < d \<longrightarrow> f x < f (x - h)"
  1002 proof -
  1003   from \<open>l < 0\<close> have l: "- l > 0" by simp
  1004   from der [THEN has_field_derivativeD, THEN tendstoD, OF l, unfolded eventually_at]
  1005   obtain s where s:   "0 < s"
  1006     and all: "\<And>xa. xa\<in>S \<Longrightarrow> xa \<noteq> x \<and> dist xa x < s \<longrightarrow> abs ((f xa - f x) / (xa - x) - l) < - l"
  1007     by (auto simp: dist_real_def)
  1008   thus ?thesis
  1009   proof (intro exI conjI strip)
  1010     show "0<s" using s .
  1011     fix h::real
  1012     assume "0 < h" "h < s" "x - h \<in> S"
  1013     with all [of "x - h"] show "f x < f (x-h)"
  1014     proof (simp add: abs_if pos_less_divide_eq dist_real_def split add: if_split_asm)
  1015       assume " - ((f (x-h) - f x) / h) < l" and h: "0 < h"
  1016       with l
  1017       have "0 < (f (x-h) - f x) / h" by arith
  1018       thus "f x < f (x-h)"
  1019         by (simp add: pos_less_divide_eq h)
  1020     qed
  1021   qed
  1022 qed
  1023 
  1024 lemma DERIV_neg_dec_left:
  1025   fixes f :: "real => real"
  1026   assumes der: "DERIV f x :> l"
  1027       and l:   "l < 0"
  1028   shows "\<exists>d > 0. \<forall>h > 0. h < d --> f(x) < f(x-h)"
  1029   using has_real_derivative_neg_dec_left[OF assms]
  1030   by auto
  1031 
  1032 lemma has_real_derivative_pos_inc_left:
  1033   fixes f :: "real => real"
  1034   shows "(f has_real_derivative l) (at x within S) \<Longrightarrow> 0 < l \<Longrightarrow> \<exists>d>0. \<forall>h>0. x - h \<in> S \<longrightarrow> h < d \<longrightarrow> f (x - h) < f x"
  1035   by (rule has_real_derivative_neg_dec_left [of "%x. - f x" "-l" x S, simplified])
  1036       (auto simp add: DERIV_minus)
  1037 
  1038 lemma DERIV_pos_inc_left:
  1039   fixes f :: "real => real"
  1040   shows "DERIV f x :> l \<Longrightarrow> 0 < l \<Longrightarrow> \<exists>d > 0. \<forall>h > 0. h < d --> f(x - h) < f(x)"
  1041   using has_real_derivative_pos_inc_left
  1042   by blast
  1043 
  1044 lemma has_real_derivative_neg_dec_right:
  1045   fixes f :: "real => real"
  1046   shows "(f has_real_derivative l) (at x within S) \<Longrightarrow> l < 0 \<Longrightarrow> \<exists>d > 0. \<forall>h > 0. x + h \<in> S \<longrightarrow> h < d \<longrightarrow> f(x) > f(x + h)"
  1047   by (rule has_real_derivative_pos_inc_right [of "%x. - f x" "-l" x S, simplified])
  1048       (auto simp add: DERIV_minus)
  1049 
  1050 lemma DERIV_neg_dec_right:
  1051   fixes f :: "real => real"
  1052   shows "DERIV f x :> l \<Longrightarrow> l < 0 \<Longrightarrow> \<exists>d > 0. \<forall>h > 0. h < d --> f(x) > f(x + h)"
  1053   using has_real_derivative_neg_dec_right by blast
  1054 
  1055 lemma DERIV_local_max:
  1056   fixes f :: "real => real"
  1057   assumes der: "DERIV f x :> l"
  1058       and d:   "0 < d"
  1059       and le:  "\<forall>y. \<bar>x-y\<bar> < d --> f(y) \<le> f(x)"
  1060   shows "l = 0"
  1061 proof (cases rule: linorder_cases [of l 0])
  1062   case equal thus ?thesis .
  1063 next
  1064   case less
  1065   from DERIV_neg_dec_left [OF der less]
  1066   obtain d' where d': "0 < d'"
  1067              and lt: "\<forall>h > 0. h < d' \<longrightarrow> f x < f (x-h)" by blast
  1068   from real_lbound_gt_zero [OF d d']
  1069   obtain e where "0 < e \<and> e < d \<and> e < d'" ..
  1070   with lt le [THEN spec [where x="x-e"]]
  1071   show ?thesis by (auto simp add: abs_if)
  1072 next
  1073   case greater
  1074   from DERIV_pos_inc_right [OF der greater]
  1075   obtain d' where d': "0 < d'"
  1076              and lt: "\<forall>h > 0. h < d' \<longrightarrow> f x < f (x + h)" by blast
  1077   from real_lbound_gt_zero [OF d d']
  1078   obtain e where "0 < e \<and> e < d \<and> e < d'" ..
  1079   with lt le [THEN spec [where x="x+e"]]
  1080   show ?thesis by (auto simp add: abs_if)
  1081 qed
  1082 
  1083 
  1084 text\<open>Similar theorem for a local minimum\<close>
  1085 lemma DERIV_local_min:
  1086   fixes f :: "real => real"
  1087   shows "[| DERIV f x :> l; 0 < d; \<forall>y. \<bar>x-y\<bar> < d --> f(x) \<le> f(y) |] ==> l = 0"
  1088 by (drule DERIV_minus [THEN DERIV_local_max], auto)
  1089 
  1090 
  1091 text\<open>In particular, if a function is locally flat\<close>
  1092 lemma DERIV_local_const:
  1093   fixes f :: "real => real"
  1094   shows "[| DERIV f x :> l; 0 < d; \<forall>y. \<bar>x-y\<bar> < d --> f(x) = f(y) |] ==> l = 0"
  1095 by (auto dest!: DERIV_local_max)
  1096 
  1097 
  1098 subsection \<open>Rolle's Theorem\<close>
  1099 
  1100 text\<open>Lemma about introducing open ball in open interval\<close>
  1101 lemma lemma_interval_lt:
  1102      "[| a < x;  x < b |]
  1103       ==> \<exists>d::real. 0 < d & (\<forall>y. \<bar>x-y\<bar> < d --> a < y & y < b)"
  1104 
  1105 apply (simp add: abs_less_iff)
  1106 apply (insert linorder_linear [of "x-a" "b-x"], safe)
  1107 apply (rule_tac x = "x-a" in exI)
  1108 apply (rule_tac [2] x = "b-x" in exI, auto)
  1109 done
  1110 
  1111 lemma lemma_interval: "[| a < x;  x < b |] ==>
  1112         \<exists>d::real. 0 < d &  (\<forall>y. \<bar>x-y\<bar> < d --> a \<le> y & y \<le> b)"
  1113 apply (drule lemma_interval_lt, auto)
  1114 apply force
  1115 done
  1116 
  1117 text\<open>Rolle's Theorem.
  1118    If @{term f} is defined and continuous on the closed interval
  1119    \<open>[a,b]\<close> and differentiable on the open interval \<open>(a,b)\<close>,
  1120    and @{term "f(a) = f(b)"},
  1121    then there exists \<open>x0 \<in> (a,b)\<close> such that @{term "f'(x0) = 0"}\<close>
  1122 theorem Rolle:
  1123   assumes lt: "a < b"
  1124       and eq: "f(a) = f(b)"
  1125       and con: "\<forall>x. a \<le> x & x \<le> b --> isCont f x"
  1126       and dif [rule_format]: "\<forall>x. a < x & x < b --> f differentiable (at x)"
  1127   shows "\<exists>z::real. a < z & z < b & DERIV f z :> 0"
  1128 proof -
  1129   have le: "a \<le> b" using lt by simp
  1130   from isCont_eq_Ub [OF le con]
  1131   obtain x where x_max: "\<forall>z. a \<le> z \<and> z \<le> b \<longrightarrow> f z \<le> f x"
  1132              and alex: "a \<le> x" and xleb: "x \<le> b"
  1133     by blast
  1134   from isCont_eq_Lb [OF le con]
  1135   obtain x' where x'_min: "\<forall>z. a \<le> z \<and> z \<le> b \<longrightarrow> f x' \<le> f z"
  1136               and alex': "a \<le> x'" and x'leb: "x' \<le> b"
  1137     by blast
  1138   show ?thesis
  1139   proof cases
  1140     assume axb: "a < x & x < b"
  1141         \<comment>\<open>@{term f} attains its maximum within the interval\<close>
  1142     hence ax: "a<x" and xb: "x<b" by arith + 
  1143     from lemma_interval [OF ax xb]
  1144     obtain d where d: "0<d" and bound: "\<forall>y. \<bar>x-y\<bar> < d \<longrightarrow> a \<le> y \<and> y \<le> b"
  1145       by blast
  1146     hence bound': "\<forall>y. \<bar>x-y\<bar> < d \<longrightarrow> f y \<le> f x" using x_max
  1147       by blast
  1148     from differentiableD [OF dif [OF axb]]
  1149     obtain l where der: "DERIV f x :> l" ..
  1150     have "l=0" by (rule DERIV_local_max [OF der d bound'])
  1151         \<comment>\<open>the derivative at a local maximum is zero\<close>
  1152     thus ?thesis using ax xb der by auto
  1153   next
  1154     assume notaxb: "~ (a < x & x < b)"
  1155     hence xeqab: "x=a | x=b" using alex xleb by arith
  1156     hence fb_eq_fx: "f b = f x" by (auto simp add: eq)
  1157     show ?thesis
  1158     proof cases
  1159       assume ax'b: "a < x' & x' < b"
  1160         \<comment>\<open>@{term f} attains its minimum within the interval\<close>
  1161       hence ax': "a<x'" and x'b: "x'<b" by arith+ 
  1162       from lemma_interval [OF ax' x'b]
  1163       obtain d where d: "0<d" and bound: "\<forall>y. \<bar>x'-y\<bar> < d \<longrightarrow> a \<le> y \<and> y \<le> b"
  1164   by blast
  1165       hence bound': "\<forall>y. \<bar>x'-y\<bar> < d \<longrightarrow> f x' \<le> f y" using x'_min
  1166   by blast
  1167       from differentiableD [OF dif [OF ax'b]]
  1168       obtain l where der: "DERIV f x' :> l" ..
  1169       have "l=0" by (rule DERIV_local_min [OF der d bound'])
  1170         \<comment>\<open>the derivative at a local minimum is zero\<close>
  1171       thus ?thesis using ax' x'b der by auto
  1172     next
  1173       assume notax'b: "~ (a < x' & x' < b)"
  1174         \<comment>\<open>@{term f} is constant througout the interval\<close>
  1175       hence x'eqab: "x'=a | x'=b" using alex' x'leb by arith
  1176       hence fb_eq_fx': "f b = f x'" by (auto simp add: eq)
  1177       from dense [OF lt]
  1178       obtain r where ar: "a < r" and rb: "r < b" by blast
  1179       from lemma_interval [OF ar rb]
  1180       obtain d where d: "0<d" and bound: "\<forall>y. \<bar>r-y\<bar> < d \<longrightarrow> a \<le> y \<and> y \<le> b"
  1181   by blast
  1182       have eq_fb: "\<forall>z. a \<le> z --> z \<le> b --> f z = f b"
  1183       proof (clarify)
  1184         fix z::real
  1185         assume az: "a \<le> z" and zb: "z \<le> b"
  1186         show "f z = f b"
  1187         proof (rule order_antisym)
  1188           show "f z \<le> f b" by (simp add: fb_eq_fx x_max az zb)
  1189           show "f b \<le> f z" by (simp add: fb_eq_fx' x'_min az zb)
  1190         qed
  1191       qed
  1192       have bound': "\<forall>y. \<bar>r-y\<bar> < d \<longrightarrow> f r = f y"
  1193       proof (intro strip)
  1194         fix y::real
  1195         assume lt: "\<bar>r-y\<bar> < d"
  1196         hence "f y = f b" by (simp add: eq_fb bound)
  1197         thus "f r = f y" by (simp add: eq_fb ar rb order_less_imp_le)
  1198       qed
  1199       from differentiableD [OF dif [OF conjI [OF ar rb]]]
  1200       obtain l where der: "DERIV f r :> l" ..
  1201       have "l=0" by (rule DERIV_local_const [OF der d bound'])
  1202         \<comment>\<open>the derivative of a constant function is zero\<close>
  1203       thus ?thesis using ar rb der by auto
  1204     qed
  1205   qed
  1206 qed
  1207 
  1208 
  1209 subsection\<open>Mean Value Theorem\<close>
  1210 
  1211 lemma lemma_MVT:
  1212      "f a - (f b - f a)/(b-a) * a = f b - (f b - f a)/(b-a) * (b::real)"
  1213   by (cases "a = b") (simp_all add: field_simps)
  1214 
  1215 theorem MVT:
  1216   assumes lt:  "a < b"
  1217       and con: "\<forall>x. a \<le> x & x \<le> b --> isCont f x"
  1218       and dif [rule_format]: "\<forall>x. a < x & x < b --> f differentiable (at x)"
  1219   shows "\<exists>l z::real. a < z & z < b & DERIV f z :> l &
  1220                    (f(b) - f(a) = (b-a) * l)"
  1221 proof -
  1222   let ?F = "%x. f x - ((f b - f a) / (b-a)) * x"
  1223   have contF: "\<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> isCont ?F x"
  1224     using con by (fast intro: continuous_intros)
  1225   have difF: "\<forall>x. a < x \<and> x < b \<longrightarrow> ?F differentiable (at x)"
  1226   proof (clarify)
  1227     fix x::real
  1228     assume ax: "a < x" and xb: "x < b"
  1229     from differentiableD [OF dif [OF conjI [OF ax xb]]]
  1230     obtain l where der: "DERIV f x :> l" ..
  1231     show "?F differentiable (at x)"
  1232       by (rule differentiableI [where D = "l - (f b - f a)/(b-a)"],
  1233           blast intro: DERIV_diff DERIV_cmult_Id der)
  1234   qed
  1235   from Rolle [where f = ?F, OF lt lemma_MVT contF difF]
  1236   obtain z where az: "a < z" and zb: "z < b" and der: "DERIV ?F z :> 0"
  1237     by blast
  1238   have "DERIV (%x. ((f b - f a)/(b-a)) * x) z :> (f b - f a)/(b-a)"
  1239     by (rule DERIV_cmult_Id)
  1240   hence derF: "DERIV (\<lambda>x. ?F x + (f b - f a) / (b - a) * x) z
  1241                    :> 0 + (f b - f a) / (b - a)"
  1242     by (rule DERIV_add [OF der])
  1243   show ?thesis
  1244   proof (intro exI conjI)
  1245     show "a < z" using az .
  1246     show "z < b" using zb .
  1247     show "f b - f a = (b - a) * ((f b - f a)/(b-a))" by (simp)
  1248     show "DERIV f z :> ((f b - f a)/(b-a))"  using derF by simp
  1249   qed
  1250 qed
  1251 
  1252 lemma MVT2:
  1253      "[| a < b; \<forall>x. a \<le> x & x \<le> b --> DERIV f x :> f'(x) |]
  1254       ==> \<exists>z::real. a < z & z < b & (f b - f a = (b - a) * f'(z))"
  1255 apply (drule MVT)
  1256 apply (blast intro: DERIV_isCont)
  1257 apply (force dest: order_less_imp_le simp add: real_differentiable_def)
  1258 apply (blast dest: DERIV_unique order_less_imp_le)
  1259 done
  1260 
  1261 
  1262 text\<open>A function is constant if its derivative is 0 over an interval.\<close>
  1263 
  1264 lemma DERIV_isconst_end:
  1265   fixes f :: "real => real"
  1266   shows "[| a < b;
  1267          \<forall>x. a \<le> x & x \<le> b --> isCont f x;
  1268          \<forall>x. a < x & x < b --> DERIV f x :> 0 |]
  1269         ==> f b = f a"
  1270 apply (drule MVT, assumption)
  1271 apply (blast intro: differentiableI)
  1272 apply (auto dest!: DERIV_unique simp add: diff_eq_eq)
  1273 done
  1274 
  1275 lemma DERIV_isconst1:
  1276   fixes f :: "real => real"
  1277   shows "[| a < b;
  1278          \<forall>x. a \<le> x & x \<le> b --> isCont f x;
  1279          \<forall>x. a < x & x < b --> DERIV f x :> 0 |]
  1280         ==> \<forall>x. a \<le> x & x \<le> b --> f x = f a"
  1281 apply safe
  1282 apply (drule_tac x = a in order_le_imp_less_or_eq, safe)
  1283 apply (drule_tac b = x in DERIV_isconst_end, auto)
  1284 done
  1285 
  1286 lemma DERIV_isconst2:
  1287   fixes f :: "real => real"
  1288   shows "[| a < b;
  1289          \<forall>x. a \<le> x & x \<le> b --> isCont f x;
  1290          \<forall>x. a < x & x < b --> DERIV f x :> 0;
  1291          a \<le> x; x \<le> b |]
  1292         ==> f x = f a"
  1293 apply (blast dest: DERIV_isconst1)
  1294 done
  1295 
  1296 lemma DERIV_isconst3: fixes a b x y :: real
  1297   assumes "a < b" and "x \<in> {a <..< b}" and "y \<in> {a <..< b}"
  1298   assumes derivable: "\<And>x. x \<in> {a <..< b} \<Longrightarrow> DERIV f x :> 0"
  1299   shows "f x = f y"
  1300 proof (cases "x = y")
  1301   case False
  1302   let ?a = "min x y"
  1303   let ?b = "max x y"
  1304   
  1305   have "\<forall>z. ?a \<le> z \<and> z \<le> ?b \<longrightarrow> DERIV f z :> 0"
  1306   proof (rule allI, rule impI)
  1307     fix z :: real assume "?a \<le> z \<and> z \<le> ?b"
  1308     hence "a < z" and "z < b" using \<open>x \<in> {a <..< b}\<close> and \<open>y \<in> {a <..< b}\<close> by auto
  1309     hence "z \<in> {a<..<b}" by auto
  1310     thus "DERIV f z :> 0" by (rule derivable)
  1311   qed
  1312   hence isCont: "\<forall>z. ?a \<le> z \<and> z \<le> ?b \<longrightarrow> isCont f z"
  1313     and DERIV: "\<forall>z. ?a < z \<and> z < ?b \<longrightarrow> DERIV f z :> 0" using DERIV_isCont by auto
  1314 
  1315   have "?a < ?b" using \<open>x \<noteq> y\<close> by auto
  1316   from DERIV_isconst2[OF this isCont DERIV, of x] and DERIV_isconst2[OF this isCont DERIV, of y]
  1317   show ?thesis by auto
  1318 qed auto
  1319 
  1320 lemma DERIV_isconst_all:
  1321   fixes f :: "real => real"
  1322   shows "\<forall>x. DERIV f x :> 0 ==> f(x) = f(y)"
  1323 apply (rule linorder_cases [of x y])
  1324 apply (blast intro: sym DERIV_isCont DERIV_isconst_end)+
  1325 done
  1326 
  1327 lemma DERIV_const_ratio_const:
  1328   fixes f :: "real => real"
  1329   shows "[|a \<noteq> b; \<forall>x. DERIV f x :> k |] ==> (f(b) - f(a)) = (b-a) * k"
  1330 apply (rule linorder_cases [of a b], auto)
  1331 apply (drule_tac [!] f = f in MVT)
  1332 apply (auto dest: DERIV_isCont DERIV_unique simp add: real_differentiable_def)
  1333 apply (auto dest: DERIV_unique simp add: ring_distribs)
  1334 done
  1335 
  1336 lemma DERIV_const_ratio_const2:
  1337   fixes f :: "real => real"
  1338   shows "[|a \<noteq> b; \<forall>x. DERIV f x :> k |] ==> (f(b) - f(a))/(b-a) = k"
  1339 apply (rule_tac c1 = "b-a" in mult_right_cancel [THEN iffD1])
  1340 apply (auto dest!: DERIV_const_ratio_const simp add: mult.assoc)
  1341 done
  1342 
  1343 lemma real_average_minus_first [simp]: "((a + b) /2 - a) = (b-a)/(2::real)"
  1344 by (simp)
  1345 
  1346 lemma real_average_minus_second [simp]: "((b + a)/2 - a) = (b-a)/(2::real)"
  1347 by (simp)
  1348 
  1349 text\<open>Gallileo's "trick": average velocity = av. of end velocities\<close>
  1350 
  1351 lemma DERIV_const_average:
  1352   fixes v :: "real => real"
  1353   assumes neq: "a \<noteq> (b::real)"
  1354       and der: "\<forall>x. DERIV v x :> k"
  1355   shows "v ((a + b)/2) = (v a + v b)/2"
  1356 proof (cases rule: linorder_cases [of a b])
  1357   case equal with neq show ?thesis by simp
  1358 next
  1359   case less
  1360   have "(v b - v a) / (b - a) = k"
  1361     by (rule DERIV_const_ratio_const2 [OF neq der])
  1362   hence "(b-a) * ((v b - v a) / (b-a)) = (b-a) * k" by simp
  1363   moreover have "(v ((a + b) / 2) - v a) / ((a + b) / 2 - a) = k"
  1364     by (rule DERIV_const_ratio_const2 [OF _ der], simp add: neq)
  1365   ultimately show ?thesis using neq by force
  1366 next
  1367   case greater
  1368   have "(v b - v a) / (b - a) = k"
  1369     by (rule DERIV_const_ratio_const2 [OF neq der])
  1370   hence "(b-a) * ((v b - v a) / (b-a)) = (b-a) * k" by simp
  1371   moreover have " (v ((b + a) / 2) - v a) / ((b + a) / 2 - a) = k"
  1372     by (rule DERIV_const_ratio_const2 [OF _ der], simp add: neq)
  1373   ultimately show ?thesis using neq by (force simp add: add.commute)
  1374 qed
  1375 
  1376 (* A function with positive derivative is increasing. 
  1377    A simple proof using the MVT, by Jeremy Avigad. And variants.
  1378 *)
  1379 lemma DERIV_pos_imp_increasing_open:
  1380   fixes a::real and b::real and f::"real => real"
  1381   assumes "a < b" and "\<And>x. a < x \<Longrightarrow> x < b \<Longrightarrow> (EX y. DERIV f x :> y & y > 0)"
  1382       and con: "\<And>x. a \<le> x \<Longrightarrow> x \<le> b \<Longrightarrow> isCont f x"
  1383   shows "f a < f b"
  1384 proof (rule ccontr)
  1385   assume f: "~ f a < f b"
  1386   have "EX l z. a < z & z < b & DERIV f z :> l
  1387       & f b - f a = (b - a) * l"
  1388     apply (rule MVT)
  1389       using assms Deriv.differentiableI
  1390       apply force+
  1391     done
  1392   then obtain l z where z: "a < z" "z < b" "DERIV f z :> l"
  1393       and "f b - f a = (b - a) * l"
  1394     by auto
  1395   with assms f have "~(l > 0)"
  1396     by (metis linorder_not_le mult_le_0_iff diff_le_0_iff_le)
  1397   with assms z show False
  1398     by (metis DERIV_unique)
  1399 qed
  1400 
  1401 lemma DERIV_pos_imp_increasing:
  1402   fixes a::real and b::real and f::"real => real"
  1403   assumes "a < b" and "\<forall>x. a \<le> x & x \<le> b --> (EX y. DERIV f x :> y & y > 0)"
  1404   shows "f a < f b"
  1405 by (metis DERIV_pos_imp_increasing_open [of a b f] assms DERIV_continuous less_imp_le)
  1406 
  1407 lemma DERIV_nonneg_imp_nondecreasing:
  1408   fixes a::real and b::real and f::"real => real"
  1409   assumes "a \<le> b" and
  1410     "\<forall>x. a \<le> x & x \<le> b --> (\<exists>y. DERIV f x :> y & y \<ge> 0)"
  1411   shows "f a \<le> f b"
  1412 proof (rule ccontr, cases "a = b")
  1413   assume "~ f a \<le> f b" and "a = b"
  1414   then show False by auto
  1415 next
  1416   assume A: "~ f a \<le> f b"
  1417   assume B: "a ~= b"
  1418   with assms have "EX l z. a < z & z < b & DERIV f z :> l
  1419       & f b - f a = (b - a) * l"
  1420     apply -
  1421     apply (rule MVT)
  1422       apply auto
  1423       apply (metis DERIV_isCont)
  1424      apply (metis differentiableI less_le)
  1425     done
  1426   then obtain l z where z: "a < z" "z < b" "DERIV f z :> l"
  1427       and C: "f b - f a = (b - a) * l"
  1428     by auto
  1429   with A have "a < b" "f b < f a" by auto
  1430   with C have "\<not> l \<ge> 0" by (auto simp add: not_le algebra_simps)
  1431     (metis A add_le_cancel_right assms(1) less_eq_real_def mult_right_mono add_left_mono linear order_refl)
  1432   with assms z show False
  1433     by (metis DERIV_unique order_less_imp_le)
  1434 qed
  1435 
  1436 lemma DERIV_neg_imp_decreasing_open:
  1437   fixes a::real and b::real and f::"real => real"
  1438   assumes "a < b" and "\<And>x. a < x \<Longrightarrow> x < b \<Longrightarrow> (EX y. DERIV f x :> y & y < 0)"
  1439       and con: "\<And>x. a \<le> x \<Longrightarrow> x \<le> b \<Longrightarrow> isCont f x"
  1440   shows "f a > f b"
  1441 proof -
  1442   have "(%x. -f x) a < (%x. -f x) b"
  1443     apply (rule DERIV_pos_imp_increasing_open [of a b "%x. -f x"])
  1444     using assms
  1445     apply auto
  1446     apply (metis field_differentiable_minus neg_0_less_iff_less)
  1447     done
  1448   thus ?thesis
  1449     by simp
  1450 qed
  1451 
  1452 lemma DERIV_neg_imp_decreasing:
  1453   fixes a::real and b::real and f::"real => real"
  1454   assumes "a < b" and
  1455     "\<forall>x. a \<le> x & x \<le> b --> (\<exists>y. DERIV f x :> y & y < 0)"
  1456   shows "f a > f b"
  1457 by (metis DERIV_neg_imp_decreasing_open [of a b f] assms DERIV_continuous less_imp_le)
  1458 
  1459 lemma DERIV_nonpos_imp_nonincreasing:
  1460   fixes a::real and b::real and f::"real => real"
  1461   assumes "a \<le> b" and
  1462     "\<forall>x. a \<le> x & x \<le> b --> (\<exists>y. DERIV f x :> y & y \<le> 0)"
  1463   shows "f a \<ge> f b"
  1464 proof -
  1465   have "(%x. -f x) a \<le> (%x. -f x) b"
  1466     apply (rule DERIV_nonneg_imp_nondecreasing [of a b "%x. -f x"])
  1467     using assms
  1468     apply auto
  1469     apply (metis DERIV_minus neg_0_le_iff_le)
  1470     done
  1471   thus ?thesis
  1472     by simp
  1473 qed
  1474 
  1475 lemma DERIV_pos_imp_increasing_at_bot:
  1476   fixes f :: "real => real"
  1477   assumes "\<And>x. x \<le> b \<Longrightarrow> (EX y. DERIV f x :> y & y > 0)"
  1478       and lim: "(f \<longlongrightarrow> flim) at_bot"
  1479   shows "flim < f b"
  1480 proof -
  1481   have "flim \<le> f (b - 1)"
  1482     apply (rule tendsto_ge_const [OF _ lim])
  1483     apply (auto simp: trivial_limit_at_bot_linorder eventually_at_bot_linorder)
  1484     apply (rule_tac x="b - 2" in exI)
  1485     apply (force intro: order.strict_implies_order DERIV_pos_imp_increasing [where f=f] assms)
  1486     done
  1487   also have "... < f b"
  1488     by (force intro: DERIV_pos_imp_increasing [where f=f] assms)
  1489   finally show ?thesis .
  1490 qed
  1491 
  1492 lemma DERIV_neg_imp_decreasing_at_top:
  1493   fixes f :: "real => real"
  1494   assumes der: "\<And>x. x \<ge> b \<Longrightarrow> (EX y. DERIV f x :> y & y < 0)"
  1495       and lim: "(f \<longlongrightarrow> flim) at_top"
  1496   shows "flim < f b"
  1497   apply (rule DERIV_pos_imp_increasing_at_bot [where f = "\<lambda>i. f (-i)" and b = "-b", simplified])
  1498   apply (metis DERIV_mirror der le_minus_iff neg_0_less_iff_less)
  1499   apply (metis filterlim_at_top_mirror lim)
  1500   done
  1501 
  1502 text \<open>Derivative of inverse function\<close>
  1503 
  1504 lemma DERIV_inverse_function:
  1505   fixes f g :: "real \<Rightarrow> real"
  1506   assumes der: "DERIV f (g x) :> D"
  1507   assumes neq: "D \<noteq> 0"
  1508   assumes a: "a < x" and b: "x < b"
  1509   assumes inj: "\<forall>y. a < y \<and> y < b \<longrightarrow> f (g y) = y"
  1510   assumes cont: "isCont g x"
  1511   shows "DERIV g x :> inverse D"
  1512 unfolding DERIV_iff2
  1513 proof (rule LIM_equal2)
  1514   show "0 < min (x - a) (b - x)"
  1515     using a b by arith 
  1516 next
  1517   fix y
  1518   assume "norm (y - x) < min (x - a) (b - x)"
  1519   hence "a < y" and "y < b" 
  1520     by (simp_all add: abs_less_iff)
  1521   thus "(g y - g x) / (y - x) =
  1522         inverse ((f (g y) - x) / (g y - g x))"
  1523     by (simp add: inj)
  1524 next
  1525   have "(\<lambda>z. (f z - f (g x)) / (z - g x)) \<midarrow>g x\<rightarrow> D"
  1526     by (rule der [unfolded DERIV_iff2])
  1527   hence 1: "(\<lambda>z. (f z - x) / (z - g x)) \<midarrow>g x\<rightarrow> D"
  1528     using inj a b by simp
  1529   have 2: "\<exists>d>0. \<forall>y. y \<noteq> x \<and> norm (y - x) < d \<longrightarrow> g y \<noteq> g x"
  1530   proof (rule exI, safe)
  1531     show "0 < min (x - a) (b - x)"
  1532       using a b by simp
  1533   next
  1534     fix y
  1535     assume "norm (y - x) < min (x - a) (b - x)"
  1536     hence y: "a < y" "y < b"
  1537       by (simp_all add: abs_less_iff)
  1538     assume "g y = g x"
  1539     hence "f (g y) = f (g x)" by simp
  1540     hence "y = x" using inj y a b by simp
  1541     also assume "y \<noteq> x"
  1542     finally show False by simp
  1543   qed
  1544   have "(\<lambda>y. (f (g y) - x) / (g y - g x)) \<midarrow>x\<rightarrow> D"
  1545     using cont 1 2 by (rule isCont_LIM_compose2)
  1546   thus "(\<lambda>y. inverse ((f (g y) - x) / (g y - g x)))
  1547         \<midarrow>x\<rightarrow> inverse D"
  1548     using neq by (rule tendsto_inverse)
  1549 qed
  1550 
  1551 subsection \<open>Generalized Mean Value Theorem\<close>
  1552 
  1553 theorem GMVT:
  1554   fixes a b :: real
  1555   assumes alb: "a < b"
  1556     and fc: "\<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> isCont f x"
  1557     and fd: "\<forall>x. a < x \<and> x < b \<longrightarrow> f differentiable (at x)"
  1558     and gc: "\<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> isCont g x"
  1559     and gd: "\<forall>x. a < x \<and> x < b \<longrightarrow> g differentiable (at x)"
  1560   shows "\<exists>g'c f'c c.
  1561     DERIV g c :> g'c \<and> DERIV f c :> f'c \<and> a < c \<and> c < b \<and> ((f b - f a) * g'c) = ((g b - g a) * f'c)"
  1562 proof -
  1563   let ?h = "\<lambda>x. (f b - f a)*(g x) - (g b - g a)*(f x)"
  1564   from assms have "a < b" by simp
  1565   moreover have "\<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> isCont ?h x"
  1566     using fc gc by simp
  1567   moreover have "\<forall>x. a < x \<and> x < b \<longrightarrow> ?h differentiable (at x)"
  1568     using fd gd by simp
  1569   ultimately have "\<exists>l z. a < z \<and> z < b \<and> DERIV ?h z :> l \<and> ?h b - ?h a = (b - a) * l" by (rule MVT)
  1570   then obtain l where ldef: "\<exists>z. a < z \<and> z < b \<and> DERIV ?h z :> l \<and> ?h b - ?h a = (b - a) * l" ..
  1571   then obtain c where cdef: "a < c \<and> c < b \<and> DERIV ?h c :> l \<and> ?h b - ?h a = (b - a) * l" ..
  1572 
  1573   from cdef have cint: "a < c \<and> c < b" by auto
  1574   with gd have "g differentiable (at c)" by simp
  1575   hence "\<exists>D. DERIV g c :> D" by (rule differentiableD)
  1576   then obtain g'c where g'cdef: "DERIV g c :> g'c" ..
  1577 
  1578   from cdef have "a < c \<and> c < b" by auto
  1579   with fd have "f differentiable (at c)" by simp
  1580   hence "\<exists>D. DERIV f c :> D" by (rule differentiableD)
  1581   then obtain f'c where f'cdef: "DERIV f c :> f'c" ..
  1582 
  1583   from cdef have "DERIV ?h c :> l" by auto
  1584   moreover have "DERIV ?h c :>  g'c * (f b - f a) - f'c * (g b - g a)"
  1585     using g'cdef f'cdef by (auto intro!: derivative_eq_intros)
  1586   ultimately have leq: "l =  g'c * (f b - f a) - f'c * (g b - g a)" by (rule DERIV_unique)
  1587 
  1588   {
  1589     from cdef have "?h b - ?h a = (b - a) * l" by auto
  1590     also from leq have "\<dots> = (b - a) * (g'c * (f b - f a) - f'c * (g b - g a))" by simp
  1591     finally have "?h b - ?h a = (b - a) * (g'c * (f b - f a) - f'c * (g b - g a))" by simp
  1592   }
  1593   moreover
  1594   {
  1595     have "?h b - ?h a =
  1596          ((f b)*(g b) - (f a)*(g b) - (g b)*(f b) + (g a)*(f b)) -
  1597           ((f b)*(g a) - (f a)*(g a) - (g b)*(f a) + (g a)*(f a))"
  1598       by (simp add: algebra_simps)
  1599     hence "?h b - ?h a = 0" by auto
  1600   }
  1601   ultimately have "(b - a) * (g'c * (f b - f a) - f'c * (g b - g a)) = 0" by auto
  1602   with alb have "g'c * (f b - f a) - f'c * (g b - g a) = 0" by simp
  1603   hence "g'c * (f b - f a) = f'c * (g b - g a)" by simp
  1604   hence "(f b - f a) * g'c = (g b - g a) * f'c" by (simp add: ac_simps)
  1605 
  1606   with g'cdef f'cdef cint show ?thesis by auto
  1607 qed
  1608 
  1609 lemma GMVT':
  1610   fixes f g :: "real \<Rightarrow> real"
  1611   assumes "a < b"
  1612   assumes isCont_f: "\<And>z. a \<le> z \<Longrightarrow> z \<le> b \<Longrightarrow> isCont f z"
  1613   assumes isCont_g: "\<And>z. a \<le> z \<Longrightarrow> z \<le> b \<Longrightarrow> isCont g z"
  1614   assumes DERIV_g: "\<And>z. a < z \<Longrightarrow> z < b \<Longrightarrow> DERIV g z :> (g' z)"
  1615   assumes DERIV_f: "\<And>z. a < z \<Longrightarrow> z < b \<Longrightarrow> DERIV f z :> (f' z)"
  1616   shows "\<exists>c. a < c \<and> c < b \<and> (f b - f a) * g' c = (g b - g a) * f' c"
  1617 proof -
  1618   have "\<exists>g'c f'c c. DERIV g c :> g'c \<and> DERIV f c :> f'c \<and>
  1619     a < c \<and> c < b \<and> (f b - f a) * g'c = (g b - g a) * f'c"
  1620     using assms by (intro GMVT) (force simp: real_differentiable_def)+
  1621   then obtain c where "a < c" "c < b" "(f b - f a) * g' c = (g b - g a) * f' c"
  1622     using DERIV_f DERIV_g by (force dest: DERIV_unique)
  1623   then show ?thesis
  1624     by auto
  1625 qed
  1626 
  1627 
  1628 subsection \<open>L'Hopitals rule\<close>
  1629 
  1630 lemma isCont_If_ge:
  1631   fixes a :: "'a :: linorder_topology"
  1632   shows "continuous (at_left a) g \<Longrightarrow> (f \<longlongrightarrow> g a) (at_right a) \<Longrightarrow> isCont (\<lambda>x. if x \<le> a then g x else f x) a"
  1633   unfolding isCont_def continuous_within
  1634   apply (intro filterlim_split_at)
  1635   apply (subst filterlim_cong[OF refl refl, where g=g])
  1636   apply (simp_all add: eventually_at_filter less_le)
  1637   apply (subst filterlim_cong[OF refl refl, where g=f])
  1638   apply (simp_all add: eventually_at_filter less_le)
  1639   done
  1640 
  1641 lemma lhopital_right_0:
  1642   fixes f0 g0 :: "real \<Rightarrow> real"
  1643   assumes f_0: "(f0 \<longlongrightarrow> 0) (at_right 0)"
  1644   assumes g_0: "(g0 \<longlongrightarrow> 0) (at_right 0)"
  1645   assumes ev:
  1646     "eventually (\<lambda>x. g0 x \<noteq> 0) (at_right 0)"
  1647     "eventually (\<lambda>x. g' x \<noteq> 0) (at_right 0)"
  1648     "eventually (\<lambda>x. DERIV f0 x :> f' x) (at_right 0)"
  1649     "eventually (\<lambda>x. DERIV g0 x :> g' x) (at_right 0)"
  1650   assumes lim: "((\<lambda> x. (f' x / g' x)) \<longlongrightarrow> x) (at_right 0)"
  1651   shows "((\<lambda> x. f0 x / g0 x) \<longlongrightarrow> x) (at_right 0)"
  1652 proof -
  1653   define f where [abs_def]: "f x = (if x \<le> 0 then 0 else f0 x)" for x
  1654   then have "f 0 = 0" by simp
  1655 
  1656   define g where [abs_def]: "g x = (if x \<le> 0 then 0 else g0 x)" for x
  1657   then have "g 0 = 0" by simp
  1658 
  1659   have "eventually (\<lambda>x. g0 x \<noteq> 0 \<and> g' x \<noteq> 0 \<and>
  1660       DERIV f0 x :> (f' x) \<and> DERIV g0 x :> (g' x)) (at_right 0)"
  1661     using ev by eventually_elim auto
  1662   then obtain a where [arith]: "0 < a"
  1663     and g0_neq_0: "\<And>x. 0 < x \<Longrightarrow> x < a \<Longrightarrow> g0 x \<noteq> 0"
  1664     and g'_neq_0: "\<And>x. 0 < x \<Longrightarrow> x < a \<Longrightarrow> g' x \<noteq> 0"
  1665     and f0: "\<And>x. 0 < x \<Longrightarrow> x < a \<Longrightarrow> DERIV f0 x :> (f' x)"
  1666     and g0: "\<And>x. 0 < x \<Longrightarrow> x < a \<Longrightarrow> DERIV g0 x :> (g' x)"
  1667     unfolding eventually_at by (auto simp: dist_real_def)
  1668 
  1669   have g_neq_0: "\<And>x. 0 < x \<Longrightarrow> x < a \<Longrightarrow> g x \<noteq> 0"
  1670     using g0_neq_0 by (simp add: g_def)
  1671 
  1672   { fix x assume x: "0 < x" "x < a" then have "DERIV f x :> (f' x)"
  1673       by (intro DERIV_cong_ev[THEN iffD1, OF _ _ _ f0[OF x]])
  1674          (auto simp: f_def eventually_nhds_metric dist_real_def intro!: exI[of _ x]) }
  1675   note f = this
  1676 
  1677   { fix x assume x: "0 < x" "x < a" then have "DERIV g x :> (g' x)"
  1678       by (intro DERIV_cong_ev[THEN iffD1, OF _ _ _ g0[OF x]])
  1679          (auto simp: g_def eventually_nhds_metric dist_real_def intro!: exI[of _ x]) }
  1680   note g = this
  1681 
  1682   have "isCont f 0"
  1683     unfolding f_def by (intro isCont_If_ge f_0 continuous_const)
  1684 
  1685   have "isCont g 0"
  1686     unfolding g_def by (intro isCont_If_ge g_0 continuous_const)
  1687 
  1688   have "\<exists>\<zeta>. \<forall>x\<in>{0 <..< a}. 0 < \<zeta> x \<and> \<zeta> x < x \<and> f x / g x = f' (\<zeta> x) / g' (\<zeta> x)"
  1689   proof (rule bchoice, rule)
  1690     fix x assume "x \<in> {0 <..< a}"
  1691     then have x[arith]: "0 < x" "x < a" by auto
  1692     with g'_neq_0 g_neq_0 \<open>g 0 = 0\<close> have g': "\<And>x. 0 < x \<Longrightarrow> x < a  \<Longrightarrow> 0 \<noteq> g' x" "g 0 \<noteq> g x"
  1693       by auto
  1694     have "\<And>x. 0 \<le> x \<Longrightarrow> x < a \<Longrightarrow> isCont f x"
  1695       using \<open>isCont f 0\<close> f by (auto intro: DERIV_isCont simp: le_less)
  1696     moreover have "\<And>x. 0 \<le> x \<Longrightarrow> x < a \<Longrightarrow> isCont g x"
  1697       using \<open>isCont g 0\<close> g by (auto intro: DERIV_isCont simp: le_less)
  1698     ultimately have "\<exists>c. 0 < c \<and> c < x \<and> (f x - f 0) * g' c = (g x - g 0) * f' c"
  1699       using f g \<open>x < a\<close> by (intro GMVT') auto
  1700     then obtain c where *: "0 < c" "c < x" "(f x - f 0) * g' c = (g x - g 0) * f' c"
  1701       by blast
  1702     moreover
  1703     from * g'(1)[of c] g'(2) have "(f x - f 0)  / (g x - g 0) = f' c / g' c"
  1704       by (simp add: field_simps)
  1705     ultimately show "\<exists>y. 0 < y \<and> y < x \<and> f x / g x = f' y / g' y"
  1706       using \<open>f 0 = 0\<close> \<open>g 0 = 0\<close> by (auto intro!: exI[of _ c])
  1707   qed
  1708   then obtain \<zeta> where "\<forall>x\<in>{0 <..< a}. 0 < \<zeta> x \<and> \<zeta> x < x \<and> f x / g x = f' (\<zeta> x) / g' (\<zeta> x)" ..
  1709   then have \<zeta>: "eventually (\<lambda>x. 0 < \<zeta> x \<and> \<zeta> x < x \<and> f x / g x = f' (\<zeta> x) / g' (\<zeta> x)) (at_right 0)"
  1710     unfolding eventually_at by (intro exI[of _ a]) (auto simp: dist_real_def)
  1711   moreover
  1712   from \<zeta> have "eventually (\<lambda>x. norm (\<zeta> x) \<le> x) (at_right 0)"
  1713     by eventually_elim auto
  1714   then have "((\<lambda>x. norm (\<zeta> x)) \<longlongrightarrow> 0) (at_right 0)"
  1715     by (rule_tac real_tendsto_sandwich[where f="\<lambda>x. 0" and h="\<lambda>x. x"]) auto
  1716   then have "(\<zeta> \<longlongrightarrow> 0) (at_right 0)"
  1717     by (rule tendsto_norm_zero_cancel)
  1718   with \<zeta> have "filterlim \<zeta> (at_right 0) (at_right 0)"
  1719     by (auto elim!: eventually_mono simp: filterlim_at)
  1720   from this lim have "((\<lambda>t. f' (\<zeta> t) / g' (\<zeta> t)) \<longlongrightarrow> x) (at_right 0)"
  1721     by (rule_tac filterlim_compose[of _ _ _ \<zeta>])
  1722   ultimately have "((\<lambda>t. f t / g t) \<longlongrightarrow> x) (at_right 0)" (is ?P)
  1723     by (rule_tac filterlim_cong[THEN iffD1, OF refl refl])
  1724        (auto elim: eventually_mono)
  1725   also have "?P \<longleftrightarrow> ?thesis"
  1726     by (rule filterlim_cong) (auto simp: f_def g_def eventually_at_filter)
  1727   finally show ?thesis .
  1728 qed
  1729 
  1730 lemma lhopital_right:
  1731   "((f::real \<Rightarrow> real) \<longlongrightarrow> 0) (at_right x) \<Longrightarrow> (g \<longlongrightarrow> 0) (at_right x) \<Longrightarrow>
  1732     eventually (\<lambda>x. g x \<noteq> 0) (at_right x) \<Longrightarrow>
  1733     eventually (\<lambda>x. g' x \<noteq> 0) (at_right x) \<Longrightarrow>
  1734     eventually (\<lambda>x. DERIV f x :> f' x) (at_right x) \<Longrightarrow>
  1735     eventually (\<lambda>x. DERIV g x :> g' x) (at_right x) \<Longrightarrow>
  1736     ((\<lambda> x. (f' x / g' x)) \<longlongrightarrow> y) (at_right x) \<Longrightarrow>
  1737   ((\<lambda> x. f x / g x) \<longlongrightarrow> y) (at_right x)"
  1738   unfolding eventually_at_right_to_0[of _ x] filterlim_at_right_to_0[of _ _ x] DERIV_shift
  1739   by (rule lhopital_right_0)
  1740 
  1741 lemma lhopital_left:
  1742   "((f::real \<Rightarrow> real) \<longlongrightarrow> 0) (at_left x) \<Longrightarrow> (g \<longlongrightarrow> 0) (at_left x) \<Longrightarrow>
  1743     eventually (\<lambda>x. g x \<noteq> 0) (at_left x) \<Longrightarrow>
  1744     eventually (\<lambda>x. g' x \<noteq> 0) (at_left x) \<Longrightarrow>
  1745     eventually (\<lambda>x. DERIV f x :> f' x) (at_left x) \<Longrightarrow>
  1746     eventually (\<lambda>x. DERIV g x :> g' x) (at_left x) \<Longrightarrow>
  1747     ((\<lambda> x. (f' x / g' x)) \<longlongrightarrow> y) (at_left x) \<Longrightarrow>
  1748   ((\<lambda> x. f x / g x) \<longlongrightarrow> y) (at_left x)"
  1749   unfolding eventually_at_left_to_right filterlim_at_left_to_right DERIV_mirror
  1750   by (rule lhopital_right[where f'="\<lambda>x. - f' (- x)"]) (auto simp: DERIV_mirror)
  1751 
  1752 lemma lhopital:
  1753   "((f::real \<Rightarrow> real) \<longlongrightarrow> 0) (at x) \<Longrightarrow> (g \<longlongrightarrow> 0) (at x) \<Longrightarrow>
  1754     eventually (\<lambda>x. g x \<noteq> 0) (at x) \<Longrightarrow>
  1755     eventually (\<lambda>x. g' x \<noteq> 0) (at x) \<Longrightarrow>
  1756     eventually (\<lambda>x. DERIV f x :> f' x) (at x) \<Longrightarrow>
  1757     eventually (\<lambda>x. DERIV g x :> g' x) (at x) \<Longrightarrow>
  1758     ((\<lambda> x. (f' x / g' x)) \<longlongrightarrow> y) (at x) \<Longrightarrow>
  1759   ((\<lambda> x. f x / g x) \<longlongrightarrow> y) (at x)"
  1760   unfolding eventually_at_split filterlim_at_split
  1761   by (auto intro!: lhopital_right[of f x g g' f'] lhopital_left[of f x g g' f'])
  1762 
  1763 lemma lhopital_right_0_at_top:
  1764   fixes f g :: "real \<Rightarrow> real"
  1765   assumes g_0: "LIM x at_right 0. g x :> at_top"
  1766   assumes ev:
  1767     "eventually (\<lambda>x. g' x \<noteq> 0) (at_right 0)"
  1768     "eventually (\<lambda>x. DERIV f x :> f' x) (at_right 0)"
  1769     "eventually (\<lambda>x. DERIV g x :> g' x) (at_right 0)"
  1770   assumes lim: "((\<lambda> x. (f' x / g' x)) \<longlongrightarrow> x) (at_right 0)"
  1771   shows "((\<lambda> x. f x / g x) \<longlongrightarrow> x) (at_right 0)"
  1772   unfolding tendsto_iff
  1773 proof safe
  1774   fix e :: real assume "0 < e"
  1775 
  1776   with lim[unfolded tendsto_iff, rule_format, of "e / 4"]
  1777   have "eventually (\<lambda>t. dist (f' t / g' t) x < e / 4) (at_right 0)" by simp
  1778   from eventually_conj[OF eventually_conj[OF ev(1) ev(2)] eventually_conj[OF ev(3) this]]
  1779   obtain a where [arith]: "0 < a"
  1780     and g'_neq_0: "\<And>x. 0 < x \<Longrightarrow> x < a \<Longrightarrow> g' x \<noteq> 0"
  1781     and f0: "\<And>x. 0 < x \<Longrightarrow> x \<le> a \<Longrightarrow> DERIV f x :> (f' x)"
  1782     and g0: "\<And>x. 0 < x \<Longrightarrow> x \<le> a \<Longrightarrow> DERIV g x :> (g' x)"
  1783     and Df: "\<And>t. 0 < t \<Longrightarrow> t < a \<Longrightarrow> dist (f' t / g' t) x < e / 4"
  1784     unfolding eventually_at_le by (auto simp: dist_real_def)
  1785     
  1786 
  1787   from Df have
  1788     "eventually (\<lambda>t. t < a) (at_right 0)" "eventually (\<lambda>t::real. 0 < t) (at_right 0)"
  1789     unfolding eventually_at by (auto intro!: exI[of _ a] simp: dist_real_def)
  1790 
  1791   moreover
  1792   have "eventually (\<lambda>t. 0 < g t) (at_right 0)" "eventually (\<lambda>t. g a < g t) (at_right 0)"
  1793     using g_0 by (auto elim: eventually_mono simp: filterlim_at_top_dense)
  1794 
  1795   moreover
  1796   have inv_g: "((\<lambda>x. inverse (g x)) \<longlongrightarrow> 0) (at_right 0)"
  1797     using tendsto_inverse_0 filterlim_mono[OF g_0 at_top_le_at_infinity order_refl]
  1798     by (rule filterlim_compose)
  1799   then have "((\<lambda>x. norm (1 - g a * inverse (g x))) \<longlongrightarrow> norm (1 - g a * 0)) (at_right 0)"
  1800     by (intro tendsto_intros)
  1801   then have "((\<lambda>x. norm (1 - g a / g x)) \<longlongrightarrow> 1) (at_right 0)"
  1802     by (simp add: inverse_eq_divide)
  1803   from this[unfolded tendsto_iff, rule_format, of 1]
  1804   have "eventually (\<lambda>x. norm (1 - g a / g x) < 2) (at_right 0)"
  1805     by (auto elim!: eventually_mono simp: dist_real_def)
  1806 
  1807   moreover
  1808   from inv_g have "((\<lambda>t. norm ((f a - x * g a) * inverse (g t))) \<longlongrightarrow> norm ((f a - x * g a) * 0)) (at_right 0)"
  1809     by (intro tendsto_intros)
  1810   then have "((\<lambda>t. norm (f a - x * g a) / norm (g t)) \<longlongrightarrow> 0) (at_right 0)"
  1811     by (simp add: inverse_eq_divide)
  1812   from this[unfolded tendsto_iff, rule_format, of "e / 2"] \<open>0 < e\<close>
  1813   have "eventually (\<lambda>t. norm (f a - x * g a) / norm (g t) < e / 2) (at_right 0)"
  1814     by (auto simp: dist_real_def)
  1815 
  1816   ultimately show "eventually (\<lambda>t. dist (f t / g t) x < e) (at_right 0)"
  1817   proof eventually_elim
  1818     fix t assume t[arith]: "0 < t" "t < a" "g a < g t" "0 < g t"
  1819     assume ineq: "norm (1 - g a / g t) < 2" "norm (f a - x * g a) / norm (g t) < e / 2"
  1820 
  1821     have "\<exists>y. t < y \<and> y < a \<and> (g a - g t) * f' y = (f a - f t) * g' y"
  1822       using f0 g0 t(1,2) by (intro GMVT') (force intro!: DERIV_isCont)+
  1823     then obtain y where [arith]: "t < y" "y < a"
  1824       and D_eq0: "(g a - g t) * f' y = (f a - f t) * g' y"
  1825       by blast
  1826     from D_eq0 have D_eq: "(f t - f a) / (g t - g a) = f' y / g' y"
  1827       using \<open>g a < g t\<close> g'_neq_0[of y] by (auto simp add: field_simps)
  1828 
  1829     have *: "f t / g t - x = ((f t - f a) / (g t - g a) - x) * (1 - g a / g t) + (f a - x * g a) / g t"
  1830       by (simp add: field_simps)
  1831     have "norm (f t / g t - x) \<le>
  1832         norm (((f t - f a) / (g t - g a) - x) * (1 - g a / g t)) + norm ((f a - x * g a) / g t)"
  1833       unfolding * by (rule norm_triangle_ineq)
  1834     also have "\<dots> = dist (f' y / g' y) x * norm (1 - g a / g t) + norm (f a - x * g a) / norm (g t)"
  1835       by (simp add: abs_mult D_eq dist_real_def)
  1836     also have "\<dots> < (e / 4) * 2 + e / 2"
  1837       using ineq Df[of y] \<open>0 < e\<close> by (intro add_le_less_mono mult_mono) auto
  1838     finally show "dist (f t / g t) x < e"
  1839       by (simp add: dist_real_def)
  1840   qed
  1841 qed
  1842 
  1843 lemma lhopital_right_at_top:
  1844   "LIM x at_right x. (g::real \<Rightarrow> real) x :> at_top \<Longrightarrow>
  1845     eventually (\<lambda>x. g' x \<noteq> 0) (at_right x) \<Longrightarrow>
  1846     eventually (\<lambda>x. DERIV f x :> f' x) (at_right x) \<Longrightarrow>
  1847     eventually (\<lambda>x. DERIV g x :> g' x) (at_right x) \<Longrightarrow>
  1848     ((\<lambda> x. (f' x / g' x)) \<longlongrightarrow> y) (at_right x) \<Longrightarrow>
  1849     ((\<lambda> x. f x / g x) \<longlongrightarrow> y) (at_right x)"
  1850   unfolding eventually_at_right_to_0[of _ x] filterlim_at_right_to_0[of _ _ x] DERIV_shift
  1851   by (rule lhopital_right_0_at_top)
  1852 
  1853 lemma lhopital_left_at_top:
  1854   "LIM x at_left x. (g::real \<Rightarrow> real) x :> at_top \<Longrightarrow>
  1855     eventually (\<lambda>x. g' x \<noteq> 0) (at_left x) \<Longrightarrow>
  1856     eventually (\<lambda>x. DERIV f x :> f' x) (at_left x) \<Longrightarrow>
  1857     eventually (\<lambda>x. DERIV g x :> g' x) (at_left x) \<Longrightarrow>
  1858     ((\<lambda> x. (f' x / g' x)) \<longlongrightarrow> y) (at_left x) \<Longrightarrow>
  1859     ((\<lambda> x. f x / g x) \<longlongrightarrow> y) (at_left x)"
  1860   unfolding eventually_at_left_to_right filterlim_at_left_to_right DERIV_mirror
  1861   by (rule lhopital_right_at_top[where f'="\<lambda>x. - f' (- x)"]) (auto simp: DERIV_mirror)
  1862 
  1863 lemma lhopital_at_top:
  1864   "LIM x at x. (g::real \<Rightarrow> real) x :> at_top \<Longrightarrow>
  1865     eventually (\<lambda>x. g' x \<noteq> 0) (at x) \<Longrightarrow>
  1866     eventually (\<lambda>x. DERIV f x :> f' x) (at x) \<Longrightarrow>
  1867     eventually (\<lambda>x. DERIV g x :> g' x) (at x) \<Longrightarrow>
  1868     ((\<lambda> x. (f' x / g' x)) \<longlongrightarrow> y) (at x) \<Longrightarrow>
  1869     ((\<lambda> x. f x / g x) \<longlongrightarrow> y) (at x)"
  1870   unfolding eventually_at_split filterlim_at_split
  1871   by (auto intro!: lhopital_right_at_top[of g x g' f f'] lhopital_left_at_top[of g x g' f f'])
  1872 
  1873 lemma lhospital_at_top_at_top:
  1874   fixes f g :: "real \<Rightarrow> real"
  1875   assumes g_0: "LIM x at_top. g x :> at_top"
  1876   assumes g': "eventually (\<lambda>x. g' x \<noteq> 0) at_top"
  1877   assumes Df: "eventually (\<lambda>x. DERIV f x :> f' x) at_top"
  1878   assumes Dg: "eventually (\<lambda>x. DERIV g x :> g' x) at_top"
  1879   assumes lim: "((\<lambda> x. (f' x / g' x)) \<longlongrightarrow> x) at_top"
  1880   shows "((\<lambda> x. f x / g x) \<longlongrightarrow> x) at_top"
  1881   unfolding filterlim_at_top_to_right
  1882 proof (rule lhopital_right_0_at_top)
  1883   let ?F = "\<lambda>x. f (inverse x)"
  1884   let ?G = "\<lambda>x. g (inverse x)"
  1885   let ?R = "at_right (0::real)"
  1886   let ?D = "\<lambda>f' x. f' (inverse x) * - (inverse x ^ Suc (Suc 0))"
  1887 
  1888   show "LIM x ?R. ?G x :> at_top"
  1889     using g_0 unfolding filterlim_at_top_to_right .
  1890 
  1891   show "eventually (\<lambda>x. DERIV ?G x  :> ?D g' x) ?R"
  1892     unfolding eventually_at_right_to_top
  1893     using Dg eventually_ge_at_top[where c="1::real"]
  1894     apply eventually_elim
  1895     apply (rule DERIV_cong)
  1896     apply (rule DERIV_chain'[where f=inverse])
  1897     apply (auto intro!:  DERIV_inverse)
  1898     done
  1899 
  1900   show "eventually (\<lambda>x. DERIV ?F x  :> ?D f' x) ?R"
  1901     unfolding eventually_at_right_to_top
  1902     using Df eventually_ge_at_top[where c="1::real"]
  1903     apply eventually_elim
  1904     apply (rule DERIV_cong)
  1905     apply (rule DERIV_chain'[where f=inverse])
  1906     apply (auto intro!:  DERIV_inverse)
  1907     done
  1908 
  1909   show "eventually (\<lambda>x. ?D g' x \<noteq> 0) ?R"
  1910     unfolding eventually_at_right_to_top
  1911     using g' eventually_ge_at_top[where c="1::real"]
  1912     by eventually_elim auto
  1913     
  1914   show "((\<lambda>x. ?D f' x / ?D g' x) \<longlongrightarrow> x) ?R"
  1915     unfolding filterlim_at_right_to_top
  1916     apply (intro filterlim_cong[THEN iffD2, OF refl refl _ lim])
  1917     using eventually_ge_at_top[where c="1::real"]
  1918     by eventually_elim simp
  1919 qed
  1920 
  1921 end