src/HOL/Fields.thy
author paulson <lp15@cam.ac.uk>
Mon May 23 15:33:24 2016 +0100 (2016-05-23)
changeset 63114 27afe7af7379
parent 62481 b5d8e57826df
child 63952 354808e9f44b
permissions -rw-r--r--
Lots of new material for multivariate analysis
     1 (*  Title:      HOL/Fields.thy
     2     Author:     Gertrud Bauer
     3     Author:     Steven Obua
     4     Author:     Tobias Nipkow
     5     Author:     Lawrence C Paulson
     6     Author:     Markus Wenzel
     7     Author:     Jeremy Avigad
     8 *)
     9 
    10 section \<open>Fields\<close>
    11 
    12 theory Fields
    13 imports Nat
    14 begin
    15 
    16 subsection \<open>Division rings\<close>
    17 
    18 text \<open>
    19   A division ring is like a field, but without the commutativity requirement.
    20 \<close>
    21 
    22 class inverse = divide +
    23   fixes inverse :: "'a \<Rightarrow> 'a"
    24 begin
    25   
    26 abbreviation inverse_divide :: "'a \<Rightarrow> 'a \<Rightarrow> 'a"  (infixl "'/" 70)
    27 where
    28   "inverse_divide \<equiv> divide"
    29 
    30 end
    31 
    32 text \<open>Setup for linear arithmetic prover\<close>
    33 
    34 ML_file "~~/src/Provers/Arith/fast_lin_arith.ML"
    35 ML_file "Tools/lin_arith.ML"
    36 setup \<open>Lin_Arith.global_setup\<close>
    37 declaration \<open>K Lin_Arith.setup\<close>
    38 
    39 simproc_setup fast_arith_nat ("(m::nat) < n" | "(m::nat) \<le> n" | "(m::nat) = n") =
    40   \<open>K Lin_Arith.simproc\<close>
    41 (* Because of this simproc, the arithmetic solver is really only
    42 useful to detect inconsistencies among the premises for subgoals which are
    43 *not* themselves (in)equalities, because the latter activate
    44 fast_nat_arith_simproc anyway. However, it seems cheaper to activate the
    45 solver all the time rather than add the additional check. *)
    46 
    47 lemmas [arith_split] = nat_diff_split split_min split_max
    48 
    49 
    50 text\<open>Lemmas \<open>divide_simps\<close> move division to the outside and eliminates them on (in)equalities.\<close>
    51 
    52 named_theorems divide_simps "rewrite rules to eliminate divisions"
    53 
    54 class division_ring = ring_1 + inverse +
    55   assumes left_inverse [simp]:  "a \<noteq> 0 \<Longrightarrow> inverse a * a = 1"
    56   assumes right_inverse [simp]: "a \<noteq> 0 \<Longrightarrow> a * inverse a = 1"
    57   assumes divide_inverse: "a / b = a * inverse b"
    58   assumes inverse_zero [simp]: "inverse 0 = 0"
    59 begin
    60 
    61 subclass ring_1_no_zero_divisors
    62 proof
    63   fix a b :: 'a
    64   assume a: "a \<noteq> 0" and b: "b \<noteq> 0"
    65   show "a * b \<noteq> 0"
    66   proof
    67     assume ab: "a * b = 0"
    68     hence "0 = inverse a * (a * b) * inverse b" by simp
    69     also have "\<dots> = (inverse a * a) * (b * inverse b)"
    70       by (simp only: mult.assoc)
    71     also have "\<dots> = 1" using a b by simp
    72     finally show False by simp
    73   qed
    74 qed
    75 
    76 lemma nonzero_imp_inverse_nonzero:
    77   "a \<noteq> 0 \<Longrightarrow> inverse a \<noteq> 0"
    78 proof
    79   assume ianz: "inverse a = 0"
    80   assume "a \<noteq> 0"
    81   hence "1 = a * inverse a" by simp
    82   also have "... = 0" by (simp add: ianz)
    83   finally have "1 = 0" .
    84   thus False by (simp add: eq_commute)
    85 qed
    86 
    87 lemma inverse_zero_imp_zero:
    88   "inverse a = 0 \<Longrightarrow> a = 0"
    89 apply (rule classical)
    90 apply (drule nonzero_imp_inverse_nonzero)
    91 apply auto
    92 done
    93 
    94 lemma inverse_unique:
    95   assumes ab: "a * b = 1"
    96   shows "inverse a = b"
    97 proof -
    98   have "a \<noteq> 0" using ab by (cases "a = 0") simp_all
    99   moreover have "inverse a * (a * b) = inverse a" by (simp add: ab)
   100   ultimately show ?thesis by (simp add: mult.assoc [symmetric])
   101 qed
   102 
   103 lemma nonzero_inverse_minus_eq:
   104   "a \<noteq> 0 \<Longrightarrow> inverse (- a) = - inverse a"
   105 by (rule inverse_unique) simp
   106 
   107 lemma nonzero_inverse_inverse_eq:
   108   "a \<noteq> 0 \<Longrightarrow> inverse (inverse a) = a"
   109 by (rule inverse_unique) simp
   110 
   111 lemma nonzero_inverse_eq_imp_eq:
   112   assumes "inverse a = inverse b" and "a \<noteq> 0" and "b \<noteq> 0"
   113   shows "a = b"
   114 proof -
   115   from \<open>inverse a = inverse b\<close>
   116   have "inverse (inverse a) = inverse (inverse b)" by (rule arg_cong)
   117   with \<open>a \<noteq> 0\<close> and \<open>b \<noteq> 0\<close> show "a = b"
   118     by (simp add: nonzero_inverse_inverse_eq)
   119 qed
   120 
   121 lemma inverse_1 [simp]: "inverse 1 = 1"
   122 by (rule inverse_unique) simp
   123 
   124 lemma nonzero_inverse_mult_distrib:
   125   assumes "a \<noteq> 0" and "b \<noteq> 0"
   126   shows "inverse (a * b) = inverse b * inverse a"
   127 proof -
   128   have "a * (b * inverse b) * inverse a = 1" using assms by simp
   129   hence "a * b * (inverse b * inverse a) = 1" by (simp only: mult.assoc)
   130   thus ?thesis by (rule inverse_unique)
   131 qed
   132 
   133 lemma division_ring_inverse_add:
   134   "a \<noteq> 0 \<Longrightarrow> b \<noteq> 0 \<Longrightarrow> inverse a + inverse b = inverse a * (a + b) * inverse b"
   135 by (simp add: algebra_simps)
   136 
   137 lemma division_ring_inverse_diff:
   138   "a \<noteq> 0 \<Longrightarrow> b \<noteq> 0 \<Longrightarrow> inverse a - inverse b = inverse a * (b - a) * inverse b"
   139 by (simp add: algebra_simps)
   140 
   141 lemma right_inverse_eq: "b \<noteq> 0 \<Longrightarrow> a / b = 1 \<longleftrightarrow> a = b"
   142 proof
   143   assume neq: "b \<noteq> 0"
   144   {
   145     hence "a = (a / b) * b" by (simp add: divide_inverse mult.assoc)
   146     also assume "a / b = 1"
   147     finally show "a = b" by simp
   148   next
   149     assume "a = b"
   150     with neq show "a / b = 1" by (simp add: divide_inverse)
   151   }
   152 qed
   153 
   154 lemma nonzero_inverse_eq_divide: "a \<noteq> 0 \<Longrightarrow> inverse a = 1 / a"
   155 by (simp add: divide_inverse)
   156 
   157 lemma divide_self [simp]: "a \<noteq> 0 \<Longrightarrow> a / a = 1"
   158 by (simp add: divide_inverse)
   159 
   160 lemma inverse_eq_divide [field_simps, divide_simps]: "inverse a = 1 / a"
   161 by (simp add: divide_inverse)
   162 
   163 lemma add_divide_distrib: "(a+b) / c = a/c + b/c"
   164 by (simp add: divide_inverse algebra_simps)
   165 
   166 lemma times_divide_eq_right [simp]: "a * (b / c) = (a * b) / c"
   167   by (simp add: divide_inverse mult.assoc)
   168 
   169 lemma minus_divide_left: "- (a / b) = (-a) / b"
   170   by (simp add: divide_inverse)
   171 
   172 lemma nonzero_minus_divide_right: "b \<noteq> 0 ==> - (a / b) = a / (- b)"
   173   by (simp add: divide_inverse nonzero_inverse_minus_eq)
   174 
   175 lemma nonzero_minus_divide_divide: "b \<noteq> 0 ==> (-a) / (-b) = a / b"
   176   by (simp add: divide_inverse nonzero_inverse_minus_eq)
   177 
   178 lemma divide_minus_left [simp]: "(-a) / b = - (a / b)"
   179   by (simp add: divide_inverse)
   180 
   181 lemma diff_divide_distrib: "(a - b) / c = a / c - b / c"
   182   using add_divide_distrib [of a "- b" c] by simp
   183 
   184 lemma nonzero_eq_divide_eq [field_simps]: "c \<noteq> 0 \<Longrightarrow> a = b / c \<longleftrightarrow> a * c = b"
   185 proof -
   186   assume [simp]: "c \<noteq> 0"
   187   have "a = b / c \<longleftrightarrow> a * c = (b / c) * c" by simp
   188   also have "... \<longleftrightarrow> a * c = b" by (simp add: divide_inverse mult.assoc)
   189   finally show ?thesis .
   190 qed
   191 
   192 lemma nonzero_divide_eq_eq [field_simps]: "c \<noteq> 0 \<Longrightarrow> b / c = a \<longleftrightarrow> b = a * c"
   193 proof -
   194   assume [simp]: "c \<noteq> 0"
   195   have "b / c = a \<longleftrightarrow> (b / c) * c = a * c" by simp
   196   also have "... \<longleftrightarrow> b = a * c" by (simp add: divide_inverse mult.assoc)
   197   finally show ?thesis .
   198 qed
   199 
   200 lemma nonzero_neg_divide_eq_eq [field_simps]: "b \<noteq> 0 \<Longrightarrow> - (a / b) = c \<longleftrightarrow> - a = c * b"
   201   using nonzero_divide_eq_eq[of b "-a" c] by simp
   202 
   203 lemma nonzero_neg_divide_eq_eq2 [field_simps]: "b \<noteq> 0 \<Longrightarrow> c = - (a / b) \<longleftrightarrow> c * b = - a"
   204   using nonzero_neg_divide_eq_eq[of b a c] by auto
   205 
   206 lemma divide_eq_imp: "c \<noteq> 0 \<Longrightarrow> b = a * c \<Longrightarrow> b / c = a"
   207   by (simp add: divide_inverse mult.assoc)
   208 
   209 lemma eq_divide_imp: "c \<noteq> 0 \<Longrightarrow> a * c = b \<Longrightarrow> a = b / c"
   210   by (drule sym) (simp add: divide_inverse mult.assoc)
   211 
   212 lemma add_divide_eq_iff [field_simps]:
   213   "z \<noteq> 0 \<Longrightarrow> x + y / z = (x * z + y) / z"
   214   by (simp add: add_divide_distrib nonzero_eq_divide_eq)
   215 
   216 lemma divide_add_eq_iff [field_simps]:
   217   "z \<noteq> 0 \<Longrightarrow> x / z + y = (x + y * z) / z"
   218   by (simp add: add_divide_distrib nonzero_eq_divide_eq)
   219 
   220 lemma diff_divide_eq_iff [field_simps]:
   221   "z \<noteq> 0 \<Longrightarrow> x - y / z = (x * z - y) / z"
   222   by (simp add: diff_divide_distrib nonzero_eq_divide_eq eq_diff_eq)
   223 
   224 lemma minus_divide_add_eq_iff [field_simps]:
   225   "z \<noteq> 0 \<Longrightarrow> - (x / z) + y = (- x + y * z) / z"
   226   by (simp add: add_divide_distrib diff_divide_eq_iff)
   227 
   228 lemma divide_diff_eq_iff [field_simps]:
   229   "z \<noteq> 0 \<Longrightarrow> x / z - y = (x - y * z) / z"
   230   by (simp add: field_simps)
   231 
   232 lemma minus_divide_diff_eq_iff [field_simps]:
   233   "z \<noteq> 0 \<Longrightarrow> - (x / z) - y = (- x - y * z) / z"
   234   by (simp add: divide_diff_eq_iff[symmetric])
   235 
   236 lemma division_ring_divide_zero [simp]:
   237   "a / 0 = 0"
   238   by (simp add: divide_inverse)
   239 
   240 lemma divide_self_if [simp]:
   241   "a / a = (if a = 0 then 0 else 1)"
   242   by simp
   243 
   244 lemma inverse_nonzero_iff_nonzero [simp]:
   245   "inverse a = 0 \<longleftrightarrow> a = 0"
   246   by rule (fact inverse_zero_imp_zero, simp)
   247 
   248 lemma inverse_minus_eq [simp]:
   249   "inverse (- a) = - inverse a"
   250 proof cases
   251   assume "a=0" thus ?thesis by simp
   252 next
   253   assume "a\<noteq>0"
   254   thus ?thesis by (simp add: nonzero_inverse_minus_eq)
   255 qed
   256 
   257 lemma inverse_inverse_eq [simp]:
   258   "inverse (inverse a) = a"
   259 proof cases
   260   assume "a=0" thus ?thesis by simp
   261 next
   262   assume "a\<noteq>0"
   263   thus ?thesis by (simp add: nonzero_inverse_inverse_eq)
   264 qed
   265 
   266 lemma inverse_eq_imp_eq:
   267   "inverse a = inverse b \<Longrightarrow> a = b"
   268   by (drule arg_cong [where f="inverse"], simp)
   269 
   270 lemma inverse_eq_iff_eq [simp]:
   271   "inverse a = inverse b \<longleftrightarrow> a = b"
   272   by (force dest!: inverse_eq_imp_eq)
   273 
   274 lemma add_divide_eq_if_simps [divide_simps]:
   275     "a + b / z = (if z = 0 then a else (a * z + b) / z)"
   276     "a / z + b = (if z = 0 then b else (a + b * z) / z)"
   277     "- (a / z) + b = (if z = 0 then b else (-a + b * z) / z)"
   278     "a - b / z = (if z = 0 then a else (a * z - b) / z)"
   279     "a / z - b = (if z = 0 then -b else (a - b * z) / z)"
   280     "- (a / z) - b = (if z = 0 then -b else (- a - b * z) / z)"
   281   by (simp_all add: add_divide_eq_iff divide_add_eq_iff diff_divide_eq_iff divide_diff_eq_iff
   282       minus_divide_diff_eq_iff)
   283 
   284 lemma [divide_simps]:
   285   shows divide_eq_eq: "b / c = a \<longleftrightarrow> (if c \<noteq> 0 then b = a * c else a = 0)"
   286     and eq_divide_eq: "a = b / c \<longleftrightarrow> (if c \<noteq> 0 then a * c = b else a = 0)"
   287     and minus_divide_eq_eq: "- (b / c) = a \<longleftrightarrow> (if c \<noteq> 0 then - b = a * c else a = 0)"
   288     and eq_minus_divide_eq: "a = - (b / c) \<longleftrightarrow> (if c \<noteq> 0 then a * c = - b else a = 0)"
   289   by (auto simp add:  field_simps)
   290 
   291 end
   292 
   293 subsection \<open>Fields\<close>
   294 
   295 class field = comm_ring_1 + inverse +
   296   assumes field_inverse: "a \<noteq> 0 \<Longrightarrow> inverse a * a = 1"
   297   assumes field_divide_inverse: "a / b = a * inverse b"
   298   assumes field_inverse_zero: "inverse 0 = 0"
   299 begin
   300 
   301 subclass division_ring
   302 proof
   303   fix a :: 'a
   304   assume "a \<noteq> 0"
   305   thus "inverse a * a = 1" by (rule field_inverse)
   306   thus "a * inverse a = 1" by (simp only: mult.commute)
   307 next
   308   fix a b :: 'a
   309   show "a / b = a * inverse b" by (rule field_divide_inverse)
   310 next
   311   show "inverse 0 = 0"
   312     by (fact field_inverse_zero) 
   313 qed
   314 
   315 subclass idom_divide
   316 proof
   317   fix b a
   318   assume "b \<noteq> 0"
   319   then show "a * b / b = a"
   320     by (simp add: divide_inverse ac_simps)
   321 next
   322   fix a
   323   show "a / 0 = 0"
   324     by (simp add: divide_inverse)
   325 qed
   326 
   327 text\<open>There is no slick version using division by zero.\<close>
   328 lemma inverse_add:
   329   "a \<noteq> 0 \<Longrightarrow> b \<noteq> 0 \<Longrightarrow> inverse a + inverse b = (a + b) * inverse a * inverse b"
   330   by (simp add: division_ring_inverse_add ac_simps)
   331 
   332 lemma nonzero_mult_divide_mult_cancel_left [simp]:
   333   assumes [simp]: "c \<noteq> 0"
   334   shows "(c * a) / (c * b) = a / b"
   335 proof (cases "b = 0")
   336   case True then show ?thesis by simp
   337 next
   338   case False
   339   then have "(c*a)/(c*b) = c * a * (inverse b * inverse c)"
   340     by (simp add: divide_inverse nonzero_inverse_mult_distrib)
   341   also have "... =  a * inverse b * (inverse c * c)"
   342     by (simp only: ac_simps)
   343   also have "... =  a * inverse b" by simp
   344     finally show ?thesis by (simp add: divide_inverse)
   345 qed
   346 
   347 lemma nonzero_mult_divide_mult_cancel_right [simp]:
   348   "c \<noteq> 0 \<Longrightarrow> (a * c) / (b * c) = a / b"
   349   using nonzero_mult_divide_mult_cancel_left [of c a b] by (simp add: ac_simps)
   350 
   351 lemma times_divide_eq_left [simp]: "(b / c) * a = (b * a) / c"
   352   by (simp add: divide_inverse ac_simps)
   353 
   354 lemma divide_inverse_commute: "a / b = inverse b * a"
   355   by (simp add: divide_inverse mult.commute)
   356 
   357 lemma add_frac_eq:
   358   assumes "y \<noteq> 0" and "z \<noteq> 0"
   359   shows "x / y + w / z = (x * z + w * y) / (y * z)"
   360 proof -
   361   have "x / y + w / z = (x * z) / (y * z) + (y * w) / (y * z)"
   362     using assms by simp
   363   also have "\<dots> = (x * z + y * w) / (y * z)"
   364     by (simp only: add_divide_distrib)
   365   finally show ?thesis
   366     by (simp only: mult.commute)
   367 qed
   368 
   369 text\<open>Special Cancellation Simprules for Division\<close>
   370 
   371 lemma nonzero_divide_mult_cancel_right [simp]:
   372   "b \<noteq> 0 \<Longrightarrow> b / (a * b) = 1 / a"
   373   using nonzero_mult_divide_mult_cancel_right [of b 1 a] by simp
   374 
   375 lemma nonzero_divide_mult_cancel_left [simp]:
   376   "a \<noteq> 0 \<Longrightarrow> a / (a * b) = 1 / b"
   377   using nonzero_mult_divide_mult_cancel_left [of a 1 b] by simp
   378 
   379 lemma nonzero_mult_divide_mult_cancel_left2 [simp]:
   380   "c \<noteq> 0 \<Longrightarrow> (c * a) / (b * c) = a / b"
   381   using nonzero_mult_divide_mult_cancel_left [of c a b] by (simp add: ac_simps)
   382 
   383 lemma nonzero_mult_divide_mult_cancel_right2 [simp]:
   384   "c \<noteq> 0 \<Longrightarrow> (a * c) / (c * b) = a / b"
   385   using nonzero_mult_divide_mult_cancel_right [of b c a] by (simp add: ac_simps)
   386 
   387 lemma diff_frac_eq:
   388   "y \<noteq> 0 \<Longrightarrow> z \<noteq> 0 \<Longrightarrow> x / y - w / z = (x * z - w * y) / (y * z)"
   389   by (simp add: field_simps)
   390 
   391 lemma frac_eq_eq:
   392   "y \<noteq> 0 \<Longrightarrow> z \<noteq> 0 \<Longrightarrow> (x / y = w / z) = (x * z = w * y)"
   393   by (simp add: field_simps)
   394 
   395 lemma divide_minus1 [simp]: "x / - 1 = - x"
   396   using nonzero_minus_divide_right [of "1" x] by simp
   397 
   398 text\<open>This version builds in division by zero while also re-orienting
   399       the right-hand side.\<close>
   400 lemma inverse_mult_distrib [simp]:
   401   "inverse (a * b) = inverse a * inverse b"
   402 proof cases
   403   assume "a \<noteq> 0 & b \<noteq> 0"
   404   thus ?thesis by (simp add: nonzero_inverse_mult_distrib ac_simps)
   405 next
   406   assume "~ (a \<noteq> 0 & b \<noteq> 0)"
   407   thus ?thesis by force
   408 qed
   409 
   410 lemma inverse_divide [simp]:
   411   "inverse (a / b) = b / a"
   412   by (simp add: divide_inverse mult.commute)
   413 
   414 
   415 text \<open>Calculations with fractions\<close>
   416 
   417 text\<open>There is a whole bunch of simp-rules just for class \<open>field\<close> but none for class \<open>field\<close> and \<open>nonzero_divides\<close>
   418 because the latter are covered by a simproc.\<close>
   419 
   420 lemma mult_divide_mult_cancel_left:
   421   "c \<noteq> 0 \<Longrightarrow> (c * a) / (c * b) = a / b"
   422 apply (cases "b = 0")
   423 apply simp_all
   424 done
   425 
   426 lemma mult_divide_mult_cancel_right:
   427   "c \<noteq> 0 \<Longrightarrow> (a * c) / (b * c) = a / b"
   428 apply (cases "b = 0")
   429 apply simp_all
   430 done
   431 
   432 lemma divide_divide_eq_right [simp]:
   433   "a / (b / c) = (a * c) / b"
   434   by (simp add: divide_inverse ac_simps)
   435 
   436 lemma divide_divide_eq_left [simp]:
   437   "(a / b) / c = a / (b * c)"
   438   by (simp add: divide_inverse mult.assoc)
   439 
   440 lemma divide_divide_times_eq:
   441   "(x / y) / (z / w) = (x * w) / (y * z)"
   442   by simp
   443 
   444 text \<open>Special Cancellation Simprules for Division\<close>
   445 
   446 lemma mult_divide_mult_cancel_left_if [simp]:
   447   shows "(c * a) / (c * b) = (if c = 0 then 0 else a / b)"
   448   by simp
   449 
   450 
   451 text \<open>Division and Unary Minus\<close>
   452 
   453 lemma minus_divide_right:
   454   "- (a / b) = a / - b"
   455   by (simp add: divide_inverse)
   456 
   457 lemma divide_minus_right [simp]:
   458   "a / - b = - (a / b)"
   459   by (simp add: divide_inverse)
   460 
   461 lemma minus_divide_divide:
   462   "(- a) / (- b) = a / b"
   463 apply (cases "b=0", simp)
   464 apply (simp add: nonzero_minus_divide_divide)
   465 done
   466 
   467 lemma inverse_eq_1_iff [simp]:
   468   "inverse x = 1 \<longleftrightarrow> x = 1"
   469   by (insert inverse_eq_iff_eq [of x 1], simp)
   470 
   471 lemma divide_eq_0_iff [simp]:
   472   "a / b = 0 \<longleftrightarrow> a = 0 \<or> b = 0"
   473   by (simp add: divide_inverse)
   474 
   475 lemma divide_cancel_right [simp]:
   476   "a / c = b / c \<longleftrightarrow> c = 0 \<or> a = b"
   477   apply (cases "c=0", simp)
   478   apply (simp add: divide_inverse)
   479   done
   480 
   481 lemma divide_cancel_left [simp]:
   482   "c / a = c / b \<longleftrightarrow> c = 0 \<or> a = b"
   483   apply (cases "c=0", simp)
   484   apply (simp add: divide_inverse)
   485   done
   486 
   487 lemma divide_eq_1_iff [simp]:
   488   "a / b = 1 \<longleftrightarrow> b \<noteq> 0 \<and> a = b"
   489   apply (cases "b=0", simp)
   490   apply (simp add: right_inverse_eq)
   491   done
   492 
   493 lemma one_eq_divide_iff [simp]:
   494   "1 = a / b \<longleftrightarrow> b \<noteq> 0 \<and> a = b"
   495   by (simp add: eq_commute [of 1])
   496 
   497 lemma times_divide_times_eq:
   498   "(x / y) * (z / w) = (x * z) / (y * w)"
   499   by simp
   500 
   501 lemma add_frac_num:
   502   "y \<noteq> 0 \<Longrightarrow> x / y + z = (x + z * y) / y"
   503   by (simp add: add_divide_distrib)
   504 
   505 lemma add_num_frac:
   506   "y \<noteq> 0 \<Longrightarrow> z + x / y = (x + z * y) / y"
   507   by (simp add: add_divide_distrib add.commute)
   508 
   509 end
   510 
   511 class field_char_0 = field + ring_char_0
   512 
   513 
   514 subsection \<open>Ordered fields\<close>
   515 
   516 class linordered_field = field + linordered_idom
   517 begin
   518 
   519 lemma positive_imp_inverse_positive:
   520   assumes a_gt_0: "0 < a"
   521   shows "0 < inverse a"
   522 proof -
   523   have "0 < a * inverse a"
   524     by (simp add: a_gt_0 [THEN less_imp_not_eq2])
   525   thus "0 < inverse a"
   526     by (simp add: a_gt_0 [THEN less_not_sym] zero_less_mult_iff)
   527 qed
   528 
   529 lemma negative_imp_inverse_negative:
   530   "a < 0 \<Longrightarrow> inverse a < 0"
   531   by (insert positive_imp_inverse_positive [of "-a"],
   532     simp add: nonzero_inverse_minus_eq less_imp_not_eq)
   533 
   534 lemma inverse_le_imp_le:
   535   assumes invle: "inverse a \<le> inverse b" and apos: "0 < a"
   536   shows "b \<le> a"
   537 proof (rule classical)
   538   assume "~ b \<le> a"
   539   hence "a < b"  by (simp add: linorder_not_le)
   540   hence bpos: "0 < b"  by (blast intro: apos less_trans)
   541   hence "a * inverse a \<le> a * inverse b"
   542     by (simp add: apos invle less_imp_le mult_left_mono)
   543   hence "(a * inverse a) * b \<le> (a * inverse b) * b"
   544     by (simp add: bpos less_imp_le mult_right_mono)
   545   thus "b \<le> a"  by (simp add: mult.assoc apos bpos less_imp_not_eq2)
   546 qed
   547 
   548 lemma inverse_positive_imp_positive:
   549   assumes inv_gt_0: "0 < inverse a" and nz: "a \<noteq> 0"
   550   shows "0 < a"
   551 proof -
   552   have "0 < inverse (inverse a)"
   553     using inv_gt_0 by (rule positive_imp_inverse_positive)
   554   thus "0 < a"
   555     using nz by (simp add: nonzero_inverse_inverse_eq)
   556 qed
   557 
   558 lemma inverse_negative_imp_negative:
   559   assumes inv_less_0: "inverse a < 0" and nz: "a \<noteq> 0"
   560   shows "a < 0"
   561 proof -
   562   have "inverse (inverse a) < 0"
   563     using inv_less_0 by (rule negative_imp_inverse_negative)
   564   thus "a < 0" using nz by (simp add: nonzero_inverse_inverse_eq)
   565 qed
   566 
   567 lemma linordered_field_no_lb:
   568   "\<forall>x. \<exists>y. y < x"
   569 proof
   570   fix x::'a
   571   have m1: "- (1::'a) < 0" by simp
   572   from add_strict_right_mono[OF m1, where c=x]
   573   have "(- 1) + x < x" by simp
   574   thus "\<exists>y. y < x" by blast
   575 qed
   576 
   577 lemma linordered_field_no_ub:
   578   "\<forall> x. \<exists>y. y > x"
   579 proof
   580   fix x::'a
   581   have m1: " (1::'a) > 0" by simp
   582   from add_strict_right_mono[OF m1, where c=x]
   583   have "1 + x > x" by simp
   584   thus "\<exists>y. y > x" by blast
   585 qed
   586 
   587 lemma less_imp_inverse_less:
   588   assumes less: "a < b" and apos:  "0 < a"
   589   shows "inverse b < inverse a"
   590 proof (rule ccontr)
   591   assume "~ inverse b < inverse a"
   592   hence "inverse a \<le> inverse b" by simp
   593   hence "~ (a < b)"
   594     by (simp add: not_less inverse_le_imp_le [OF _ apos])
   595   thus False by (rule notE [OF _ less])
   596 qed
   597 
   598 lemma inverse_less_imp_less:
   599   "inverse a < inverse b \<Longrightarrow> 0 < a \<Longrightarrow> b < a"
   600 apply (simp add: less_le [of "inverse a"] less_le [of "b"])
   601 apply (force dest!: inverse_le_imp_le nonzero_inverse_eq_imp_eq)
   602 done
   603 
   604 text\<open>Both premises are essential. Consider -1 and 1.\<close>
   605 lemma inverse_less_iff_less [simp]:
   606   "0 < a \<Longrightarrow> 0 < b \<Longrightarrow> inverse a < inverse b \<longleftrightarrow> b < a"
   607   by (blast intro: less_imp_inverse_less dest: inverse_less_imp_less)
   608 
   609 lemma le_imp_inverse_le:
   610   "a \<le> b \<Longrightarrow> 0 < a \<Longrightarrow> inverse b \<le> inverse a"
   611   by (force simp add: le_less less_imp_inverse_less)
   612 
   613 lemma inverse_le_iff_le [simp]:
   614   "0 < a \<Longrightarrow> 0 < b \<Longrightarrow> inverse a \<le> inverse b \<longleftrightarrow> b \<le> a"
   615   by (blast intro: le_imp_inverse_le dest: inverse_le_imp_le)
   616 
   617 
   618 text\<open>These results refer to both operands being negative.  The opposite-sign
   619 case is trivial, since inverse preserves signs.\<close>
   620 lemma inverse_le_imp_le_neg:
   621   "inverse a \<le> inverse b \<Longrightarrow> b < 0 \<Longrightarrow> b \<le> a"
   622 apply (rule classical)
   623 apply (subgoal_tac "a < 0")
   624  prefer 2 apply force
   625 apply (insert inverse_le_imp_le [of "-b" "-a"])
   626 apply (simp add: nonzero_inverse_minus_eq)
   627 done
   628 
   629 lemma less_imp_inverse_less_neg:
   630    "a < b \<Longrightarrow> b < 0 \<Longrightarrow> inverse b < inverse a"
   631 apply (subgoal_tac "a < 0")
   632  prefer 2 apply (blast intro: less_trans)
   633 apply (insert less_imp_inverse_less [of "-b" "-a"])
   634 apply (simp add: nonzero_inverse_minus_eq)
   635 done
   636 
   637 lemma inverse_less_imp_less_neg:
   638    "inverse a < inverse b \<Longrightarrow> b < 0 \<Longrightarrow> b < a"
   639 apply (rule classical)
   640 apply (subgoal_tac "a < 0")
   641  prefer 2
   642  apply force
   643 apply (insert inverse_less_imp_less [of "-b" "-a"])
   644 apply (simp add: nonzero_inverse_minus_eq)
   645 done
   646 
   647 lemma inverse_less_iff_less_neg [simp]:
   648   "a < 0 \<Longrightarrow> b < 0 \<Longrightarrow> inverse a < inverse b \<longleftrightarrow> b < a"
   649 apply (insert inverse_less_iff_less [of "-b" "-a"])
   650 apply (simp del: inverse_less_iff_less
   651             add: nonzero_inverse_minus_eq)
   652 done
   653 
   654 lemma le_imp_inverse_le_neg:
   655   "a \<le> b \<Longrightarrow> b < 0 ==> inverse b \<le> inverse a"
   656   by (force simp add: le_less less_imp_inverse_less_neg)
   657 
   658 lemma inverse_le_iff_le_neg [simp]:
   659   "a < 0 \<Longrightarrow> b < 0 \<Longrightarrow> inverse a \<le> inverse b \<longleftrightarrow> b \<le> a"
   660   by (blast intro: le_imp_inverse_le_neg dest: inverse_le_imp_le_neg)
   661 
   662 lemma one_less_inverse:
   663   "0 < a \<Longrightarrow> a < 1 \<Longrightarrow> 1 < inverse a"
   664   using less_imp_inverse_less [of a 1, unfolded inverse_1] .
   665 
   666 lemma one_le_inverse:
   667   "0 < a \<Longrightarrow> a \<le> 1 \<Longrightarrow> 1 \<le> inverse a"
   668   using le_imp_inverse_le [of a 1, unfolded inverse_1] .
   669 
   670 lemma pos_le_divide_eq [field_simps]:
   671   assumes "0 < c"
   672   shows "a \<le> b / c \<longleftrightarrow> a * c \<le> b"
   673 proof -
   674   from assms have "a \<le> b / c \<longleftrightarrow> a * c \<le> (b / c) * c"
   675     using mult_le_cancel_right [of a c "b * inverse c"] by (auto simp add: field_simps)
   676   also have "... \<longleftrightarrow> a * c \<le> b"
   677     by (simp add: less_imp_not_eq2 [OF assms] divide_inverse mult.assoc)
   678   finally show ?thesis .
   679 qed
   680 
   681 lemma pos_less_divide_eq [field_simps]:
   682   assumes "0 < c"
   683   shows "a < b / c \<longleftrightarrow> a * c < b"
   684 proof -
   685   from assms have "a < b / c \<longleftrightarrow> a * c < (b / c) * c"
   686     using mult_less_cancel_right [of a c "b / c"] by auto
   687   also have "... = (a*c < b)"
   688     by (simp add: less_imp_not_eq2 [OF assms] divide_inverse mult.assoc)
   689   finally show ?thesis .
   690 qed
   691 
   692 lemma neg_less_divide_eq [field_simps]:
   693   assumes "c < 0"
   694   shows "a < b / c \<longleftrightarrow> b < a * c"
   695 proof -
   696   from assms have "a < b / c \<longleftrightarrow> (b / c) * c < a * c"
   697     using mult_less_cancel_right [of "b / c" c a] by auto
   698   also have "... \<longleftrightarrow> b < a * c"
   699     by (simp add: less_imp_not_eq [OF assms] divide_inverse mult.assoc)
   700   finally show ?thesis .
   701 qed
   702 
   703 lemma neg_le_divide_eq [field_simps]:
   704   assumes "c < 0"
   705   shows "a \<le> b / c \<longleftrightarrow> b \<le> a * c"
   706 proof -
   707   from assms have "a \<le> b / c \<longleftrightarrow> (b / c) * c \<le> a * c"
   708     using mult_le_cancel_right [of "b * inverse c" c a] by (auto simp add: field_simps)
   709   also have "... \<longleftrightarrow> b \<le> a * c"
   710     by (simp add: less_imp_not_eq [OF assms] divide_inverse mult.assoc)
   711   finally show ?thesis .
   712 qed
   713 
   714 lemma pos_divide_le_eq [field_simps]:
   715   assumes "0 < c"
   716   shows "b / c \<le> a \<longleftrightarrow> b \<le> a * c"
   717 proof -
   718   from assms have "b / c \<le> a \<longleftrightarrow> (b / c) * c \<le> a * c"
   719     using mult_le_cancel_right [of "b / c" c a] by auto
   720   also have "... \<longleftrightarrow> b \<le> a * c"
   721     by (simp add: less_imp_not_eq2 [OF assms] divide_inverse mult.assoc)
   722   finally show ?thesis .
   723 qed
   724 
   725 lemma pos_divide_less_eq [field_simps]:
   726   assumes "0 < c"
   727   shows "b / c < a \<longleftrightarrow> b < a * c"
   728 proof -
   729   from assms have "b / c < a \<longleftrightarrow> (b / c) * c < a * c"
   730     using mult_less_cancel_right [of "b / c" c a] by auto
   731   also have "... \<longleftrightarrow> b < a * c"
   732     by (simp add: less_imp_not_eq2 [OF assms] divide_inverse mult.assoc)
   733   finally show ?thesis .
   734 qed
   735 
   736 lemma neg_divide_le_eq [field_simps]:
   737   assumes "c < 0"
   738   shows "b / c \<le> a \<longleftrightarrow> a * c \<le> b"
   739 proof -
   740   from assms have "b / c \<le> a \<longleftrightarrow> a * c \<le> (b / c) * c"
   741     using mult_le_cancel_right [of a c "b / c"] by auto
   742   also have "... \<longleftrightarrow> a * c \<le> b"
   743     by (simp add: less_imp_not_eq [OF assms] divide_inverse mult.assoc)
   744   finally show ?thesis .
   745 qed
   746 
   747 lemma neg_divide_less_eq [field_simps]:
   748   assumes "c < 0"
   749   shows "b / c < a \<longleftrightarrow> a * c < b"
   750 proof -
   751   from assms have "b / c < a \<longleftrightarrow> a * c < b / c * c"
   752     using mult_less_cancel_right [of a c "b / c"] by auto
   753   also have "... \<longleftrightarrow> a * c < b"
   754     by (simp add: less_imp_not_eq [OF assms] divide_inverse mult.assoc)
   755   finally show ?thesis .
   756 qed
   757 
   758 text\<open>The following \<open>field_simps\<close> rules are necessary, as minus is always moved atop of
   759 division but we want to get rid of division.\<close>
   760 
   761 lemma pos_le_minus_divide_eq [field_simps]: "0 < c \<Longrightarrow> a \<le> - (b / c) \<longleftrightarrow> a * c \<le> - b"
   762   unfolding minus_divide_left by (rule pos_le_divide_eq)
   763 
   764 lemma neg_le_minus_divide_eq [field_simps]: "c < 0 \<Longrightarrow> a \<le> - (b / c) \<longleftrightarrow> - b \<le> a * c"
   765   unfolding minus_divide_left by (rule neg_le_divide_eq)
   766 
   767 lemma pos_less_minus_divide_eq [field_simps]: "0 < c \<Longrightarrow> a < - (b / c) \<longleftrightarrow> a * c < - b"
   768   unfolding minus_divide_left by (rule pos_less_divide_eq)
   769 
   770 lemma neg_less_minus_divide_eq [field_simps]: "c < 0 \<Longrightarrow> a < - (b / c) \<longleftrightarrow> - b < a * c"
   771   unfolding minus_divide_left by (rule neg_less_divide_eq)
   772 
   773 lemma pos_minus_divide_less_eq [field_simps]: "0 < c \<Longrightarrow> - (b / c) < a \<longleftrightarrow> - b < a * c"
   774   unfolding minus_divide_left by (rule pos_divide_less_eq)
   775 
   776 lemma neg_minus_divide_less_eq [field_simps]: "c < 0 \<Longrightarrow> - (b / c) < a \<longleftrightarrow> a * c < - b"
   777   unfolding minus_divide_left by (rule neg_divide_less_eq)
   778 
   779 lemma pos_minus_divide_le_eq [field_simps]: "0 < c \<Longrightarrow> - (b / c) \<le> a \<longleftrightarrow> - b \<le> a * c"
   780   unfolding minus_divide_left by (rule pos_divide_le_eq)
   781 
   782 lemma neg_minus_divide_le_eq [field_simps]: "c < 0 \<Longrightarrow> - (b / c) \<le> a \<longleftrightarrow> a * c \<le> - b"
   783   unfolding minus_divide_left by (rule neg_divide_le_eq)
   784 
   785 lemma frac_less_eq:
   786   "y \<noteq> 0 \<Longrightarrow> z \<noteq> 0 \<Longrightarrow> x / y < w / z \<longleftrightarrow> (x * z - w * y) / (y * z) < 0"
   787   by (subst less_iff_diff_less_0) (simp add: diff_frac_eq )
   788 
   789 lemma frac_le_eq:
   790   "y \<noteq> 0 \<Longrightarrow> z \<noteq> 0 \<Longrightarrow> x / y \<le> w / z \<longleftrightarrow> (x * z - w * y) / (y * z) \<le> 0"
   791   by (subst le_iff_diff_le_0) (simp add: diff_frac_eq )
   792 
   793 text\<open>Lemmas \<open>sign_simps\<close> is a first attempt to automate proofs
   794 of positivity/negativity needed for \<open>field_simps\<close>. Have not added \<open>sign_simps\<close> to \<open>field_simps\<close> because the former can lead to case
   795 explosions.\<close>
   796 
   797 lemmas sign_simps = algebra_simps zero_less_mult_iff mult_less_0_iff
   798 
   799 lemmas (in -) sign_simps = algebra_simps zero_less_mult_iff mult_less_0_iff
   800 
   801 (* Only works once linear arithmetic is installed:
   802 text{*An example:*}
   803 lemma fixes a b c d e f :: "'a::linordered_field"
   804 shows "\<lbrakk>a>b; c<d; e<f; 0 < u \<rbrakk> \<Longrightarrow>
   805  ((a-b)*(c-d)*(e-f))/((c-d)*(e-f)*(a-b)) <
   806  ((e-f)*(a-b)*(c-d))/((e-f)*(a-b)*(c-d)) + u"
   807 apply(subgoal_tac "(c-d)*(e-f)*(a-b) > 0")
   808  prefer 2 apply(simp add:sign_simps)
   809 apply(subgoal_tac "(c-d)*(e-f)*(a-b)*u > 0")
   810  prefer 2 apply(simp add:sign_simps)
   811 apply(simp add:field_simps)
   812 done
   813 *)
   814 
   815 lemma divide_pos_pos[simp]:
   816   "0 < x ==> 0 < y ==> 0 < x / y"
   817 by(simp add:field_simps)
   818 
   819 lemma divide_nonneg_pos:
   820   "0 <= x ==> 0 < y ==> 0 <= x / y"
   821 by(simp add:field_simps)
   822 
   823 lemma divide_neg_pos:
   824   "x < 0 ==> 0 < y ==> x / y < 0"
   825 by(simp add:field_simps)
   826 
   827 lemma divide_nonpos_pos:
   828   "x <= 0 ==> 0 < y ==> x / y <= 0"
   829 by(simp add:field_simps)
   830 
   831 lemma divide_pos_neg:
   832   "0 < x ==> y < 0 ==> x / y < 0"
   833 by(simp add:field_simps)
   834 
   835 lemma divide_nonneg_neg:
   836   "0 <= x ==> y < 0 ==> x / y <= 0"
   837 by(simp add:field_simps)
   838 
   839 lemma divide_neg_neg:
   840   "x < 0 ==> y < 0 ==> 0 < x / y"
   841 by(simp add:field_simps)
   842 
   843 lemma divide_nonpos_neg:
   844   "x <= 0 ==> y < 0 ==> 0 <= x / y"
   845 by(simp add:field_simps)
   846 
   847 lemma divide_strict_right_mono:
   848      "[|a < b; 0 < c|] ==> a / c < b / c"
   849 by (simp add: less_imp_not_eq2 divide_inverse mult_strict_right_mono
   850               positive_imp_inverse_positive)
   851 
   852 
   853 lemma divide_strict_right_mono_neg:
   854      "[|b < a; c < 0|] ==> a / c < b / c"
   855 apply (drule divide_strict_right_mono [of _ _ "-c"], simp)
   856 apply (simp add: less_imp_not_eq nonzero_minus_divide_right [symmetric])
   857 done
   858 
   859 text\<open>The last premise ensures that @{term a} and @{term b}
   860       have the same sign\<close>
   861 lemma divide_strict_left_mono:
   862   "[|b < a; 0 < c; 0 < a*b|] ==> c / a < c / b"
   863   by (auto simp: field_simps zero_less_mult_iff mult_strict_right_mono)
   864 
   865 lemma divide_left_mono:
   866   "[|b \<le> a; 0 \<le> c; 0 < a*b|] ==> c / a \<le> c / b"
   867   by (auto simp: field_simps zero_less_mult_iff mult_right_mono)
   868 
   869 lemma divide_strict_left_mono_neg:
   870   "[|a < b; c < 0; 0 < a*b|] ==> c / a < c / b"
   871   by (auto simp: field_simps zero_less_mult_iff mult_strict_right_mono_neg)
   872 
   873 lemma mult_imp_div_pos_le: "0 < y ==> x <= z * y ==>
   874     x / y <= z"
   875 by (subst pos_divide_le_eq, assumption+)
   876 
   877 lemma mult_imp_le_div_pos: "0 < y ==> z * y <= x ==>
   878     z <= x / y"
   879 by(simp add:field_simps)
   880 
   881 lemma mult_imp_div_pos_less: "0 < y ==> x < z * y ==>
   882     x / y < z"
   883 by(simp add:field_simps)
   884 
   885 lemma mult_imp_less_div_pos: "0 < y ==> z * y < x ==>
   886     z < x / y"
   887 by(simp add:field_simps)
   888 
   889 lemma frac_le: "0 <= x ==>
   890     x <= y ==> 0 < w ==> w <= z  ==> x / z <= y / w"
   891   apply (rule mult_imp_div_pos_le)
   892   apply simp
   893   apply (subst times_divide_eq_left)
   894   apply (rule mult_imp_le_div_pos, assumption)
   895   apply (rule mult_mono)
   896   apply simp_all
   897 done
   898 
   899 lemma frac_less: "0 <= x ==>
   900     x < y ==> 0 < w ==> w <= z  ==> x / z < y / w"
   901   apply (rule mult_imp_div_pos_less)
   902   apply simp
   903   apply (subst times_divide_eq_left)
   904   apply (rule mult_imp_less_div_pos, assumption)
   905   apply (erule mult_less_le_imp_less)
   906   apply simp_all
   907 done
   908 
   909 lemma frac_less2: "0 < x ==>
   910     x <= y ==> 0 < w ==> w < z  ==> x / z < y / w"
   911   apply (rule mult_imp_div_pos_less)
   912   apply simp_all
   913   apply (rule mult_imp_less_div_pos, assumption)
   914   apply (erule mult_le_less_imp_less)
   915   apply simp_all
   916 done
   917 
   918 lemma less_half_sum: "a < b ==> a < (a+b) / (1+1)"
   919 by (simp add: field_simps zero_less_two)
   920 
   921 lemma gt_half_sum: "a < b ==> (a+b)/(1+1) < b"
   922 by (simp add: field_simps zero_less_two)
   923 
   924 subclass unbounded_dense_linorder
   925 proof
   926   fix x y :: 'a
   927   from less_add_one show "\<exists>y. x < y" ..
   928   from less_add_one have "x + (- 1) < (x + 1) + (- 1)" by (rule add_strict_right_mono)
   929   then have "x - 1 < x + 1 - 1" by simp
   930   then have "x - 1 < x" by (simp add: algebra_simps)
   931   then show "\<exists>y. y < x" ..
   932   show "x < y \<Longrightarrow> \<exists>z>x. z < y" by (blast intro!: less_half_sum gt_half_sum)
   933 qed
   934 
   935 lemma nonzero_abs_inverse:
   936      "a \<noteq> 0 ==> \<bar>inverse a\<bar> = inverse \<bar>a\<bar>"
   937 apply (auto simp add: neq_iff abs_if nonzero_inverse_minus_eq
   938                       negative_imp_inverse_negative)
   939 apply (blast intro: positive_imp_inverse_positive elim: less_asym)
   940 done
   941 
   942 lemma nonzero_abs_divide:
   943      "b \<noteq> 0 ==> \<bar>a / b\<bar> = \<bar>a\<bar> / \<bar>b\<bar>"
   944   by (simp add: divide_inverse abs_mult nonzero_abs_inverse)
   945 
   946 lemma field_le_epsilon:
   947   assumes e: "\<And>e. 0 < e \<Longrightarrow> x \<le> y + e"
   948   shows "x \<le> y"
   949 proof (rule dense_le)
   950   fix t assume "t < x"
   951   hence "0 < x - t" by (simp add: less_diff_eq)
   952   from e [OF this] have "x + 0 \<le> x + (y - t)" by (simp add: algebra_simps)
   953   then have "0 \<le> y - t" by (simp only: add_le_cancel_left)
   954   then show "t \<le> y" by (simp add: algebra_simps)
   955 qed
   956 
   957 lemma inverse_positive_iff_positive [simp]:
   958   "(0 < inverse a) = (0 < a)"
   959 apply (cases "a = 0", simp)
   960 apply (blast intro: inverse_positive_imp_positive positive_imp_inverse_positive)
   961 done
   962 
   963 lemma inverse_negative_iff_negative [simp]:
   964   "(inverse a < 0) = (a < 0)"
   965 apply (cases "a = 0", simp)
   966 apply (blast intro: inverse_negative_imp_negative negative_imp_inverse_negative)
   967 done
   968 
   969 lemma inverse_nonnegative_iff_nonnegative [simp]:
   970   "0 \<le> inverse a \<longleftrightarrow> 0 \<le> a"
   971   by (simp add: not_less [symmetric])
   972 
   973 lemma inverse_nonpositive_iff_nonpositive [simp]:
   974   "inverse a \<le> 0 \<longleftrightarrow> a \<le> 0"
   975   by (simp add: not_less [symmetric])
   976 
   977 lemma one_less_inverse_iff: "1 < inverse x \<longleftrightarrow> 0 < x \<and> x < 1"
   978   using less_trans[of 1 x 0 for x]
   979   by (cases x 0 rule: linorder_cases) (auto simp add: field_simps)
   980 
   981 lemma one_le_inverse_iff: "1 \<le> inverse x \<longleftrightarrow> 0 < x \<and> x \<le> 1"
   982 proof (cases "x = 1")
   983   case True then show ?thesis by simp
   984 next
   985   case False then have "inverse x \<noteq> 1" by simp
   986   then have "1 \<noteq> inverse x" by blast
   987   then have "1 \<le> inverse x \<longleftrightarrow> 1 < inverse x" by (simp add: le_less)
   988   with False show ?thesis by (auto simp add: one_less_inverse_iff)
   989 qed
   990 
   991 lemma inverse_less_1_iff: "inverse x < 1 \<longleftrightarrow> x \<le> 0 \<or> 1 < x"
   992   by (simp add: not_le [symmetric] one_le_inverse_iff)
   993 
   994 lemma inverse_le_1_iff: "inverse x \<le> 1 \<longleftrightarrow> x \<le> 0 \<or> 1 \<le> x"
   995   by (simp add: not_less [symmetric] one_less_inverse_iff)
   996 
   997 lemma [divide_simps]:
   998   shows le_divide_eq: "a \<le> b / c \<longleftrightarrow> (if 0 < c then a * c \<le> b else if c < 0 then b \<le> a * c else a \<le> 0)"
   999     and divide_le_eq: "b / c \<le> a \<longleftrightarrow> (if 0 < c then b \<le> a * c else if c < 0 then a * c \<le> b else 0 \<le> a)"
  1000     and less_divide_eq: "a < b / c \<longleftrightarrow> (if 0 < c then a * c < b else if c < 0 then b < a * c else a < 0)"
  1001     and divide_less_eq: "b / c < a \<longleftrightarrow> (if 0 < c then b < a * c else if c < 0 then a * c < b else 0 < a)"
  1002     and le_minus_divide_eq: "a \<le> - (b / c) \<longleftrightarrow> (if 0 < c then a * c \<le> - b else if c < 0 then - b \<le> a * c else a \<le> 0)"
  1003     and minus_divide_le_eq: "- (b / c) \<le> a \<longleftrightarrow> (if 0 < c then - b \<le> a * c else if c < 0 then a * c \<le> - b else 0 \<le> a)"
  1004     and less_minus_divide_eq: "a < - (b / c) \<longleftrightarrow> (if 0 < c then a * c < - b else if c < 0 then - b < a * c else  a < 0)"
  1005     and minus_divide_less_eq: "- (b / c) < a \<longleftrightarrow> (if 0 < c then - b < a * c else if c < 0 then a * c < - b else 0 < a)"
  1006   by (auto simp: field_simps not_less dest: antisym)
  1007 
  1008 text \<open>Division and Signs\<close>
  1009 
  1010 lemma
  1011   shows zero_less_divide_iff: "0 < a / b \<longleftrightarrow> 0 < a \<and> 0 < b \<or> a < 0 \<and> b < 0"
  1012     and divide_less_0_iff: "a / b < 0 \<longleftrightarrow> 0 < a \<and> b < 0 \<or> a < 0 \<and> 0 < b"
  1013     and zero_le_divide_iff: "0 \<le> a / b \<longleftrightarrow> 0 \<le> a \<and> 0 \<le> b \<or> a \<le> 0 \<and> b \<le> 0"
  1014     and divide_le_0_iff: "a / b \<le> 0 \<longleftrightarrow> 0 \<le> a \<and> b \<le> 0 \<or> a \<le> 0 \<and> 0 \<le> b"
  1015   by (auto simp add: divide_simps)
  1016 
  1017 text \<open>Division and the Number One\<close>
  1018 
  1019 text\<open>Simplify expressions equated with 1\<close>
  1020 
  1021 lemma zero_eq_1_divide_iff [simp]: "0 = 1 / a \<longleftrightarrow> a = 0"
  1022   by (cases "a = 0") (auto simp: field_simps)
  1023 
  1024 lemma one_divide_eq_0_iff [simp]: "1 / a = 0 \<longleftrightarrow> a = 0"
  1025   using zero_eq_1_divide_iff[of a] by simp
  1026 
  1027 text\<open>Simplify expressions such as \<open>0 < 1/x\<close> to \<open>0 < x\<close>\<close>
  1028 
  1029 lemma zero_le_divide_1_iff [simp]:
  1030   "0 \<le> 1 / a \<longleftrightarrow> 0 \<le> a"
  1031   by (simp add: zero_le_divide_iff)
  1032 
  1033 lemma zero_less_divide_1_iff [simp]:
  1034   "0 < 1 / a \<longleftrightarrow> 0 < a"
  1035   by (simp add: zero_less_divide_iff)
  1036 
  1037 lemma divide_le_0_1_iff [simp]:
  1038   "1 / a \<le> 0 \<longleftrightarrow> a \<le> 0"
  1039   by (simp add: divide_le_0_iff)
  1040 
  1041 lemma divide_less_0_1_iff [simp]:
  1042   "1 / a < 0 \<longleftrightarrow> a < 0"
  1043   by (simp add: divide_less_0_iff)
  1044 
  1045 lemma divide_right_mono:
  1046      "[|a \<le> b; 0 \<le> c|] ==> a/c \<le> b/c"
  1047 by (force simp add: divide_strict_right_mono le_less)
  1048 
  1049 lemma divide_right_mono_neg: "a <= b
  1050     ==> c <= 0 ==> b / c <= a / c"
  1051 apply (drule divide_right_mono [of _ _ "- c"])
  1052 apply auto
  1053 done
  1054 
  1055 lemma divide_left_mono_neg: "a <= b
  1056     ==> c <= 0 ==> 0 < a * b ==> c / a <= c / b"
  1057   apply (drule divide_left_mono [of _ _ "- c"])
  1058   apply (auto simp add: mult.commute)
  1059 done
  1060 
  1061 lemma inverse_le_iff: "inverse a \<le> inverse b \<longleftrightarrow> (0 < a * b \<longrightarrow> b \<le> a) \<and> (a * b \<le> 0 \<longrightarrow> a \<le> b)"
  1062   by (cases a 0 b 0 rule: linorder_cases[case_product linorder_cases])
  1063      (auto simp add: field_simps zero_less_mult_iff mult_le_0_iff)
  1064 
  1065 lemma inverse_less_iff: "inverse a < inverse b \<longleftrightarrow> (0 < a * b \<longrightarrow> b < a) \<and> (a * b \<le> 0 \<longrightarrow> a < b)"
  1066   by (subst less_le) (auto simp: inverse_le_iff)
  1067 
  1068 lemma divide_le_cancel: "a / c \<le> b / c \<longleftrightarrow> (0 < c \<longrightarrow> a \<le> b) \<and> (c < 0 \<longrightarrow> b \<le> a)"
  1069   by (simp add: divide_inverse mult_le_cancel_right)
  1070 
  1071 lemma divide_less_cancel: "a / c < b / c \<longleftrightarrow> (0 < c \<longrightarrow> a < b) \<and> (c < 0 \<longrightarrow> b < a) \<and> c \<noteq> 0"
  1072   by (auto simp add: divide_inverse mult_less_cancel_right)
  1073 
  1074 text\<open>Simplify quotients that are compared with the value 1.\<close>
  1075 
  1076 lemma le_divide_eq_1:
  1077   "(1 \<le> b / a) = ((0 < a & a \<le> b) | (a < 0 & b \<le> a))"
  1078 by (auto simp add: le_divide_eq)
  1079 
  1080 lemma divide_le_eq_1:
  1081   "(b / a \<le> 1) = ((0 < a & b \<le> a) | (a < 0 & a \<le> b) | a=0)"
  1082 by (auto simp add: divide_le_eq)
  1083 
  1084 lemma less_divide_eq_1:
  1085   "(1 < b / a) = ((0 < a & a < b) | (a < 0 & b < a))"
  1086 by (auto simp add: less_divide_eq)
  1087 
  1088 lemma divide_less_eq_1:
  1089   "(b / a < 1) = ((0 < a & b < a) | (a < 0 & a < b) | a=0)"
  1090 by (auto simp add: divide_less_eq)
  1091 
  1092 lemma divide_nonneg_nonneg [simp]:
  1093   "0 \<le> x \<Longrightarrow> 0 \<le> y \<Longrightarrow> 0 \<le> x / y"
  1094   by (auto simp add: divide_simps)
  1095 
  1096 lemma divide_nonpos_nonpos:
  1097   "x \<le> 0 \<Longrightarrow> y \<le> 0 \<Longrightarrow> 0 \<le> x / y"
  1098   by (auto simp add: divide_simps)
  1099 
  1100 lemma divide_nonneg_nonpos:
  1101   "0 \<le> x \<Longrightarrow> y \<le> 0 \<Longrightarrow> x / y \<le> 0"
  1102   by (auto simp add: divide_simps)
  1103 
  1104 lemma divide_nonpos_nonneg:
  1105   "x \<le> 0 \<Longrightarrow> 0 \<le> y \<Longrightarrow> x / y \<le> 0"
  1106   by (auto simp add: divide_simps)
  1107 
  1108 text \<open>Conditional Simplification Rules: No Case Splits\<close>
  1109 
  1110 lemma le_divide_eq_1_pos [simp]:
  1111   "0 < a \<Longrightarrow> (1 \<le> b/a) = (a \<le> b)"
  1112 by (auto simp add: le_divide_eq)
  1113 
  1114 lemma le_divide_eq_1_neg [simp]:
  1115   "a < 0 \<Longrightarrow> (1 \<le> b/a) = (b \<le> a)"
  1116 by (auto simp add: le_divide_eq)
  1117 
  1118 lemma divide_le_eq_1_pos [simp]:
  1119   "0 < a \<Longrightarrow> (b/a \<le> 1) = (b \<le> a)"
  1120 by (auto simp add: divide_le_eq)
  1121 
  1122 lemma divide_le_eq_1_neg [simp]:
  1123   "a < 0 \<Longrightarrow> (b/a \<le> 1) = (a \<le> b)"
  1124 by (auto simp add: divide_le_eq)
  1125 
  1126 lemma less_divide_eq_1_pos [simp]:
  1127   "0 < a \<Longrightarrow> (1 < b/a) = (a < b)"
  1128 by (auto simp add: less_divide_eq)
  1129 
  1130 lemma less_divide_eq_1_neg [simp]:
  1131   "a < 0 \<Longrightarrow> (1 < b/a) = (b < a)"
  1132 by (auto simp add: less_divide_eq)
  1133 
  1134 lemma divide_less_eq_1_pos [simp]:
  1135   "0 < a \<Longrightarrow> (b/a < 1) = (b < a)"
  1136 by (auto simp add: divide_less_eq)
  1137 
  1138 lemma divide_less_eq_1_neg [simp]:
  1139   "a < 0 \<Longrightarrow> b/a < 1 \<longleftrightarrow> a < b"
  1140 by (auto simp add: divide_less_eq)
  1141 
  1142 lemma eq_divide_eq_1 [simp]:
  1143   "(1 = b/a) = ((a \<noteq> 0 & a = b))"
  1144 by (auto simp add: eq_divide_eq)
  1145 
  1146 lemma divide_eq_eq_1 [simp]:
  1147   "(b/a = 1) = ((a \<noteq> 0 & a = b))"
  1148 by (auto simp add: divide_eq_eq)
  1149 
  1150 lemma abs_inverse [simp]:
  1151      "\<bar>inverse a\<bar> =
  1152       inverse \<bar>a\<bar>"
  1153 apply (cases "a=0", simp)
  1154 apply (simp add: nonzero_abs_inverse)
  1155 done
  1156 
  1157 lemma abs_divide [simp]:
  1158      "\<bar>a / b\<bar> = \<bar>a\<bar> / \<bar>b\<bar>"
  1159 apply (cases "b=0", simp)
  1160 apply (simp add: nonzero_abs_divide)
  1161 done
  1162 
  1163 lemma abs_div_pos: "0 < y ==>
  1164     \<bar>x\<bar> / y = \<bar>x / y\<bar>"
  1165   apply (subst abs_divide)
  1166   apply (simp add: order_less_imp_le)
  1167 done
  1168 
  1169 lemma zero_le_divide_abs_iff [simp]: "(0 \<le> a / \<bar>b\<bar>) = (0 \<le> a | b = 0)"
  1170 by (auto simp: zero_le_divide_iff)
  1171 
  1172 lemma divide_le_0_abs_iff [simp]: "(a / \<bar>b\<bar> \<le> 0) = (a \<le> 0 | b = 0)"
  1173 by (auto simp: divide_le_0_iff)
  1174 
  1175 lemma inverse_sgn:
  1176   "sgn (inverse a) = inverse (sgn a)"
  1177   by (simp add: sgn_if)
  1178 
  1179 lemma field_le_mult_one_interval:
  1180   assumes *: "\<And>z. \<lbrakk> 0 < z ; z < 1 \<rbrakk> \<Longrightarrow> z * x \<le> y"
  1181   shows "x \<le> y"
  1182 proof (cases "0 < x")
  1183   assume "0 < x"
  1184   thus ?thesis
  1185     using dense_le_bounded[of 0 1 "y/x"] *
  1186     unfolding le_divide_eq if_P[OF \<open>0 < x\<close>] by simp
  1187 next
  1188   assume "\<not>0 < x" hence "x \<le> 0" by simp
  1189   obtain s::'a where s: "0 < s" "s < 1" using dense[of 0 "1::'a"] by auto
  1190   hence "x \<le> s * x" using mult_le_cancel_right[of 1 x s] \<open>x \<le> 0\<close> by auto
  1191   also note *[OF s]
  1192   finally show ?thesis .
  1193 qed
  1194 
  1195 end
  1196 
  1197 text \<open>Min/max Simplification Rules\<close>
  1198 
  1199 lemma min_mult_distrib_left:
  1200   fixes x::"'a::linordered_idom" 
  1201   shows "p * min x y = (if 0 \<le> p then min (p*x) (p*y) else max (p*x) (p*y))"
  1202 by (auto simp add: min_def max_def mult_le_cancel_left)
  1203 
  1204 lemma min_mult_distrib_right:
  1205   fixes x::"'a::linordered_idom" 
  1206   shows "min x y * p = (if 0 \<le> p then min (x*p) (y*p) else max (x*p) (y*p))"
  1207 by (auto simp add: min_def max_def mult_le_cancel_right)
  1208 
  1209 lemma min_divide_distrib_right:
  1210   fixes x::"'a::linordered_field" 
  1211   shows "min x y / p = (if 0 \<le> p then min (x/p) (y/p) else max (x/p) (y/p))"
  1212 by (simp add: min_mult_distrib_right divide_inverse)
  1213 
  1214 lemma max_mult_distrib_left:
  1215   fixes x::"'a::linordered_idom" 
  1216   shows "p * max x y = (if 0 \<le> p then max (p*x) (p*y) else min (p*x) (p*y))"
  1217 by (auto simp add: min_def max_def mult_le_cancel_left)
  1218 
  1219 lemma max_mult_distrib_right:
  1220   fixes x::"'a::linordered_idom" 
  1221   shows "max x y * p = (if 0 \<le> p then max (x*p) (y*p) else min (x*p) (y*p))"
  1222 by (auto simp add: min_def max_def mult_le_cancel_right)
  1223 
  1224 lemma max_divide_distrib_right:
  1225   fixes x::"'a::linordered_field" 
  1226   shows "max x y / p = (if 0 \<le> p then max (x/p) (y/p) else min (x/p) (y/p))"
  1227 by (simp add: max_mult_distrib_right divide_inverse)
  1228 
  1229 hide_fact (open) field_inverse field_divide_inverse field_inverse_zero
  1230 
  1231 code_identifier
  1232   code_module Fields \<rightharpoonup> (SML) Arith and (OCaml) Arith and (Haskell) Arith
  1233 
  1234 end